code.delx.au - gnu-emacs-elpa/blob - admin/archive-contents.el

   1 ;;; archive-contents.el --- Auto-generate an Emacs Lisp package archive.  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 2011, 2012, 2013  Free Software Foundation, Inc
   4
   5 ;; Author: Stefan Monnier <monnier@iro.umontreal.ca>
   6
   7 ;; This program is free software; you can redistribute it and/or modify
   8 ;; it under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11
  12 ;; This program is distributed in the hope that it will be useful,
  13 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;; GNU General Public License for more details.
  16
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 ;;; Commentary:
  21
  22 ;;; Code:
  23
  24 (eval-when-compile (require 'cl))
  25 (require 'lisp-mnt)
  26 (require 'package)
  27 (require 'pcase)
  28
  29 (defconst archive-contents-subdirectory-regexp
  30   "\\([^.].*?\\)-\\([0-9]+\\(?:[.][0-9]+\\|\\(?:pre\\|beta\\|alpha\\)[0-9]+\\)*\\)")
  31
  32 (defconst archive-re-no-dot "\\`\\([^.]\\|\\.\\([^.]\\|\\..\\)\\).*"
  33   "Regular expression matching all files except \".\" and \"..\".")
  34
  35 (defun archive--version-to-list (vers)
  36   (when vers
  37     (let ((l (version-to-list vers)))
  38       ;; Signal an error for things like "1.02" which is parsed as "1.2".
  39       (assert (equal vers (package-version-join l)) nil
  40               "Unsupported version syntax %S" vers)
  41       l)))
  42
  43 (defun archive--convert-require (elt)
  44   (list (car elt)
  45         (archive--version-to-list (car (cdr elt)))))
  46
  47 (defun archive--strip-rcs-id (str)
  48   "Strip RCS version ID from the version string STR.
  49 If the result looks like a dotted numeric version, return it.
  50 Otherwise return nil."
  51   (when str
  52     (when (string-match "\\`[ \t]*[$]Revision:[ \t]+" str)
  53       (setq str (substring str (match-end 0))))
  54     (condition-case nil
  55         (if (archive--version-to-list str)
  56             str)
  57       (error str))))
  58
  59 (defun archive--delete-elc-files (dir &optional only-orphans)
  60   "Recursively delete all .elc files in DIR.
  61 Delete backup files also."
  62   (dolist (f (directory-files dir t archive-re-no-dot))
  63     (cond ((file-directory-p f)
  64            (archive--delete-elc-files f))
  65           ((or (and (string-match "\\.elc\\'" f)
  66                     (not (and only-orphans
  67                               (file-readable-p (replace-match ".el" t t f)))))
  68                (backup-file-name-p f))
  69            (delete-file f)))))
  70
  71 (defun batch-make-archive ()
  72   "Process package content directories and generate the archive-contents file."
  73   (let ((packages '(1))) ; format-version.
  74     (dolist (dir (directory-files default-directory nil archive-re-no-dot))
  75       (condition-case v
  76           (if (not (file-directory-p dir))
  77               (message "Skipping non-package file %s" dir)
  78             (let* ((pkg (file-name-nondirectory dir))
  79                    (autoloads-file (expand-file-name (concat pkg "-autoloads.el") dir))
  80                    simple-p)
  81               ;; Omit autoloads and .elc files from the package.
  82               (if (file-exists-p autoloads-file)
  83                   (delete-file autoloads-file))
  84               (archive--delete-elc-files dir)
  85               ;; Test whether this is a simple or multi-file package.
  86               (setq simple-p (archive--simple-package-p dir pkg))
  87               (push (if (car simple-p)
  88                         (apply #'archive--process-simple-package
  89                                dir pkg (cdr simple-p))
  90                       (if simple-p
  91                           (apply #'archive--write-pkg-file
  92                                  dir pkg (cdr simple-p)))
  93                       (archive--process-multi-file-package dir pkg))
  94                     packages)))
  95         ((debug error) (error "Error in %s: %S" dir v))))
  96     (with-temp-buffer
  97       (pp (nreverse packages) (current-buffer))
  98       (write-region nil nil "archive-contents"))))
  99
 100 (defconst archive--revno-re "[0-9a-f]+")
 101
 102 (defun archive-prepare-packages (srcdir)
 103   "Prepare the `packages' directory inside the Git checkout.
 104 Expects to be called from within the `packages' directory.
 105 \"Prepare\" here is for subsequent construction of the packages and archive,
 106 so it is meant to refresh any generated files we may need.
 107 Currently only refreshes the ChangeLog files."
 108   (setq srcdir (file-name-as-directory (expand-file-name srcdir)))
 109   (let* ((wit ".changelog-witness")
 110          (prevno (with-temp-buffer
 111                    (ignore-errors (insert-file-contents wit))
 112                    (if (looking-at (concat archive--revno-re "$"))
 113                        (match-string 0)
 114                      (error "Can't find previous revision name"))))
 115          (new-revno
 116           (or (with-temp-buffer
 117                 (let ((default-directory srcdir))
 118                   (call-process "git" nil '(t) nil "rev-parse" "HEAD")
 119                   (goto-char (point-min))
 120                   (when (looking-at (concat archive--revno-re "$"))
 121                     (match-string 0))))
 122               (error "Couldn't find the current revision's name")))
 123          (pkgs '()))
 124     (unless (equal prevno new-revno)
 125       (with-temp-buffer
 126         (let ((default-directory srcdir))
 127           (unless (zerop (call-process "git" nil '(t) nil "diff"
 128                                        "--dirstat=cumulative,0"
 129                                        prevno))
 130             (error "Error signaled by git diff --dirstat %d" prevno)))
 131         (goto-char (point-min))
 132         (while (re-search-forward "^[ \t.0-9%]* packages/\\([-[:alnum:]]+\\)/$"
 133                                   nil t)
 134           (push (match-string 1) pkgs))))
 135     (let ((default-directory (expand-file-name "packages/")))
 136       (dolist (pkg pkgs)
 137         (condition-case v
 138             (if (file-directory-p pkg)
 139                 (archive--make-changelog pkg (expand-file-name "packages/"
 140                                                                srcdir)))
 141           (error (message "Error: %S" v)))))
 142     (write-region new-revno nil wit nil 'quiet)
 143     ;; Also update the ChangeLog of external packages.
 144     (let ((default-directory (expand-file-name "packages/")))
 145       (dolist (dir (directory-files "."))
 146         (and (not (member dir '("." "..")))
 147              (file-directory-p dir)
 148              (let ((index (expand-file-name
 149                            (concat "packages/" dir "/.git/index")
 150                            srcdir))
 151                    (cl (expand-file-name "ChangeLog" dir)))
 152                (and (file-exists-p index)
 153                     (or (not (file-exists-p cl))
 154                         (file-newer-than-file-p index cl))))
 155              (archive--make-changelog
 156               dir (expand-file-name "packages/" srcdir)))))
 157     ))
 158
 159 (defun archive--simple-package-p (dir pkg)
 160   "Test whether DIR contains a simple package named PKG.
 161 Return a list (SIMPLE VERSION DESCRIPTION REQ), where
 162 SIMPLE is non-nil if the package is indeed simple;
 163 VERSION is the version string of the simple package;
 164 DESCRIPTION is the brief description of the package;
 165 REQ is a list of requirements.
 166 Otherwise, return nil."
 167   (let* ((pkg-file (expand-file-name (concat pkg "-pkg.el") dir))
 168          (mainfile (expand-file-name (concat pkg ".el") dir))
 169          (files (directory-files dir nil "\\.el\\'")))
 170     (setq files (delete (concat pkg "-pkg.el") files))
 171     (setq files (delete (concat pkg "-autoloads.el") files))
 172     (cond
 173      ((and (not (file-exists-p pkg-file))
 174            (file-exists-p mainfile))
 175       (with-temp-buffer
 176         (insert-file-contents mainfile)
 177         (goto-char (point-min))
 178         (if (not (looking-at ";;;.*---[ \t]*\\(.*?\\)[ \t]*\\(-\\*-.*-\\*-[ \t]*\\)?$"))
 179             (error "Can't parse first line of %s" mainfile)
 180           ;; Grab the other fields, which are not mandatory.
 181           (let* ((description (match-string 1))
 182                  (version
 183                   (or (archive--strip-rcs-id (lm-header "package-version"))
 184                       (archive--strip-rcs-id (lm-header "version"))
 185                       (error "Missing `version' header")))
 186                  (requires-str (lm-header "package-requires"))
 187                  (pt (lm-header "package-type"))
 188                  (simple (if pt (equal pt "simple") (= (length files) 1)))
 189                  (req
 190                   (if requires-str
 191                       (mapcar 'archive--convert-require
 192                               (car (read-from-string requires-str))))))
 193             (list simple version description req)))))
 194      ((not (file-exists-p pkg-file))
 195       (error "Can find single file nor package desc file in %s" dir)))))
 196
 197 (defun archive--process-simple-package (dir pkg vers desc req)
 198   "Deploy the contents of DIR into the archive as a simple package.
 199 Rename DIR/PKG.el to PKG-VERS.el, delete DIR, and return the descriptor."
 200   ;; Write DIR/foo.el to foo-VERS.el and delete DIR
 201   (rename-file (expand-file-name (concat pkg ".el") dir)
 202                (concat pkg "-" vers ".el"))
 203   ;; Add the content of the ChangeLog.
 204   (let ((cl (expand-file-name "ChangeLog" dir)))
 205     (with-current-buffer (find-file-noselect (concat pkg "-" vers ".el"))
 206       (goto-char (point-max))
 207       (re-search-backward "^;;;.*ends here")
 208       (re-search-backward "^(provide")
 209       (skip-chars-backward " \t\n")
 210       (insert "\n\n;;;; ChangeLog:\n\n")
 211       (let* ((start (point))
 212              (end (copy-marker start t)))
 213         (insert-file-contents cl)
 214         (goto-char end)
 215         (unless (bolp) (insert "\n"))
 216         (while (progn (forward-line -1) (>= (point) start))
 217           (insert ";; ")))
 218       (set (make-local-variable 'backup-inhibited) t)
 219       (basic-save-buffer)               ;Less chatty than save-buffer.
 220       (kill-buffer)))
 221   (delete-directory dir t)
 222   (cons (intern pkg) (vector (archive--version-to-list vers)
 223                              req desc 'single)))
 224
 225 (defun archive--make-changelog (dir srcdir)
 226   "Export Git log info of DIR into a ChangeLog file."
 227   (message "Refreshing ChangeLog in %S" dir)
 228   (let ((default-directory (file-name-as-directory (expand-file-name dir))))
 229     (with-temp-buffer
 230       (set-buffer-multibyte nil)
 231       (let ((coding-system-for-read 'binary)
 232             (coding-system-for-write 'binary))
 233         (if (file-readable-p "ChangeLog") (insert-file-contents "ChangeLog"))
 234         (let ((old-md5 (md5 (current-buffer))))
 235           (erase-buffer)
 236           (let ((default-directory
 237                   (file-name-as-directory (expand-file-name dir srcdir))))
 238             (call-process "git" nil (current-buffer) nil
 239                           "log" "--date=short"
 240                           "--format=%cd  %aN  <%ae>%n%n%w(80,8,8)%B%n"
 241                           "."))
 242           (tabify (point-min) (point-max))
 243           (goto-char (point-min))
 244           (while (re-search-forward "\n\n\n+" nil t)
 245             (replace-match "\n\n"))
 246           (if (equal old-md5 (md5 (current-buffer)))
 247               (message "ChangeLog's md5 unchanged for %S" dir)
 248             (write-region (point-min) (point-max) "ChangeLog" nil 'quiet)))))))
 249
 250 (defun archive--process-multi-file-package (dir pkg)
 251   "Deploy the contents of DIR into the archive as a multi-file package.
 252 Rename DIR/ to PKG-VERS/, and return the descriptor."
 253   (let* ((exp (archive--multi-file-package-def dir pkg))
 254          (vers (nth 2 exp))
 255          (req-exp (nth 4 exp))
 256          (req (mapcar 'archive--convert-require
 257                       (if (eq 'quote (car-safe req-exp)) (nth 1 req-exp)
 258                         (when req-exp
 259                           (error "REQ should be a quoted constant: %S"
 260                                  req-exp))))))
 261     (unless (equal (nth 1 exp) pkg)
 262       (error (format "Package name %s doesn't match file name %s"
 263                      (nth 1 exp) pkg)))
 264     (rename-file dir (concat pkg "-" vers))
 265     (cons (intern pkg) (vector (archive--version-to-list vers)
 266                                req (nth 3 exp) 'tar))))
 267
 268 (defun archive--multi-file-package-def (dir pkg)
 269   "Return the `define-package' form in the file DIR/PKG-pkg.el."
 270   (let ((pkg-file (expand-file-name (concat pkg "-pkg.el") dir)))
 271     (with-temp-buffer
 272       (unless (file-exists-p pkg-file)
 273         (error "File not found: %s" pkg-file))
 274       (insert-file-contents pkg-file)
 275       (goto-char (point-min))
 276       (read (current-buffer)))))
 277
 278 (defun archive--refresh-pkg-file ()
 279   (let* ((dir (directory-file-name default-directory))
 280          (pkg (file-name-nondirectory dir))
 281          (simple-p (archive--simple-package-p dir pkg)))
 282     (if simple-p
 283         (progn
 284           ;; (message "Refreshing pkg description of %s" pkg)
 285           (apply 'archive--write-pkg-file dir pkg (cdr simple-p)))
 286       ;; (message "Not refreshing pkg description of %s" pkg)
 287       )))
 288
 289 (defun archive--write-pkg-file (pkg-dir name version desc requires &rest ignored)
 290   (let ((pkg-file (expand-file-name (concat name "-pkg.el") pkg-dir))
 291         (print-level nil)
 292         (print-quoted t)
 293         (print-length nil))
 294     (write-region
 295      (concat (format ";; Generated package description from %s.el\n"
 296                      name)
 297              (prin1-to-string
 298               (list 'define-package
 299                     name
 300                     version
 301                     desc
 302                     (list 'quote
 303                           ;; Turn version lists into string form.
 304                           (mapcar
 305                            (lambda (elt)
 306                              (list (car elt)
 307                                    (package-version-join (cadr elt))))
 308                            requires))))
 309              "\n")
 310      nil
 311      pkg-file)))
 312
 313 ;;; Make the HTML pages for online browsing.
 314
 315 (defun archive--html-header (title)
 316   (format "<!DOCTYPE HTML PUBLIC \"-//W3C//DTD HTML 3.2 Final//EN\">
 317 <html>
 318 <head>
 319   <title>%s</title>
 320   <meta http-equiv=\"Content-Type\" content=\"text/html; charset=utf-8\">
 321 </head>
 322 <body>
 323 <h1 align=\"center\">%s</h1>\n"
 324           title title))
 325
 326 (defun archive--html-bytes-format (bytes) ;Aka memory-usage-format.
 327   (setq bytes (/ bytes 1024.0))
 328   (let ((units '(;; "B"
 329                  "kB" "MB" "GB" "TB")))
 330     (while (>= bytes 1024)
 331       (setq bytes (/ bytes 1024.0))
 332       (setq units (cdr units)))
 333     (cond
 334      ;; ((integerp bytes) (format "%4d%s" bytes (car units)))
 335      ((>= bytes 100) (format "%4.0f%s" bytes (car units)))
 336      ((>= bytes 10) (format "%4.1f%s" bytes (car units)))
 337      (t (format "%4.2f%s" bytes (car units))))))
 338
 339 (defun archive--get-prop (prop name srcdir mainsrcfile)
 340   (let ((kprop (intern (format ":%s" (downcase prop)))))
 341     (or
 342      (let ((pkgdescfile (expand-file-name (format "%s-pkg.el" name)
 343                                           srcdir)))
 344        (when (file-readable-p pkgdescfile)
 345          (with-temp-buffer
 346            (insert-file-contents pkgdescfile)
 347            (let ((desc (read (current-buffer))))
 348              (plist-get (cdr desc) kprop)))))
 349      (when (file-readable-p mainsrcfile)
 350        (with-temp-buffer
 351          (insert-file-contents mainsrcfile)
 352          (lm-header prop))))))
 353
 354 (defun archive--get-section (hsection fsection srcdir mainsrcfile)
 355   (when (consp fsection)
 356     (while (cdr-safe fsection)
 357       (setq fsection
 358             (if (file-readable-p (expand-file-name (car fsection) srcdir))
 359                 (car fsection)
 360               (cdr fsection))))
 361     (when (consp fsection) (setq fsection (car fsection))))
 362   (cond
 363    ((file-readable-p (expand-file-name fsection srcdir))
 364     (with-temp-buffer
 365       (insert-file-contents (expand-file-name fsection srcdir))
 366       (buffer-string)))
 367    ((file-readable-p mainsrcfile)
 368     (with-temp-buffer
 369       (insert-file-contents mainsrcfile)
 370       (let ((start (lm-section-start hsection)))
 371         (when start
 372           (insert
 373            (prog1
 374                (buffer-substring start (lm-section-end hsection))
 375              (erase-buffer)))
 376           (emacs-lisp-mode)
 377           (goto-char (point-min))
 378           (delete-region (point) (line-beginning-position 2))
 379           (uncomment-region (point-min) (point-max))
 380           (when (looking-at "^\\([ \t]*\n\\)+")
 381             (replace-match ""))
 382           (goto-char (point-max))
 383           (skip-chars-backward " \t\n")
 384           (delete-region (point) (point-max))
 385           (buffer-string)))))))
 386
 387 (defun archive--quote (txt)
 388   (replace-regexp-in-string "<" "&lt;"
 389                             (replace-regexp-in-string "&" "&amp;" txt)))
 390
 391 (defun archive--insert-repolinks (name srcdir mainsrcfile)
 392   (let ((url (archive--get-prop "URL" name srcdir mainsrcfile)))
 393     (if url
 394         (insert (format "<p>Origin: <a href=%S>%s</a></p>\n"
 395                         url (archive--quote url)))
 396       (let* ((externals
 397               (with-temp-buffer
 398                 (insert-file-contents
 399                  (expand-file-name "../../../elpa/externals-list" srcdir))
 400                 (read (current-buffer))))
 401              (external (eq :external (nth 1 (assoc name externals))))
 402              (git-sv "http://git.savannah.gnu.org/")
 403              (urls (if external
 404                        '("cgit/emacs/elpa.git/?h=externals/"
 405                          "gitweb/?p=emacs/elpa.git;a=shortlog;h=refs/heads/externals/")
 406                      '("cgit/emacs/elpa.git/tree/packages/"
 407                        "gitweb/?p=emacs/elpa.git;a=tree;f=packages/"))))
 408         (insert (format
 409                  (concat "<p>Browse repository: <a href=%S>%s</a>"
 410                          " or <a href=%S>%s</a></p>\n")
 411                  (concat git-sv (nth 0 urls) name)
 412                  'CGit
 413                  (concat git-sv (nth 1 urls) name)
 414                  'Gitweb))))))
 415
 416 (defun archive--html-make-pkg (pkg files)
 417   (let* ((name (symbol-name (car pkg)))
 418          (latest (package-version-join (aref (cdr pkg) 0)))
 419          (srcdir (expand-file-name name "../../build/packages"))
 420          (mainsrcfile (expand-file-name (format "%s.el" name) srcdir))
 421          (desc (aref (cdr pkg) 2)))
 422     (with-temp-buffer
 423       (insert (archive--html-header (format "GNU ELPA - %s" name)))
 424       (insert (format "<p>Description: %s</p>\n" (archive--quote desc)))
 425       (let* ((file (cdr (assoc latest files)))
 426              (attrs (file-attributes file)))
 427         (insert (format "<p>Latest: <a href=%S>%s</a>, %s, %s</p>\n"
 428                         file (archive--quote file)
 429                         (format-time-string "%Y-%b-%d" (nth 5 attrs))
 430                         (archive--html-bytes-format (nth 7 attrs)))))
 431       (let ((maint (archive--get-prop "Maintainer" name srcdir mainsrcfile)))
 432         (when maint
 433           (insert (format "<p>Maintainer: %s</p>\n" (archive--quote maint)))))
 434       (archive--insert-repolinks name srcdir mainsrcfile)
 435       (let ((rm (archive--get-section
 436                  "Commentary" '("README" "README.rst" "README.md" "README.org")
 437                  srcdir mainsrcfile)))
 438         (when rm
 439           (write-region rm nil (concat name "-readme.txt"))
 440           (insert "<h2>Full description</h2><pre>\n" (archive--quote rm)
 441                   "\n</pre>\n")))
 442       (unless (< (length files) 2)
 443         (insert (format "<h2>Old versions</h2><table cellpadding=\"3\" border=\"1\">\n"))
 444         (dolist (file files)
 445           (unless (equal (pop file) latest)
 446             (let ((attrs (file-attributes file)))
 447               (insert (format "<tr><td><a href=%S>%s</a></td><td>%s</td><td>%s</td>\n"
 448                               file (archive--quote file)
 449                               (format-time-string "%Y-%b-%d" (nth 5 attrs))
 450                               (archive--html-bytes-format (nth 7 attrs)))))))
 451         (insert "</table>\n"))
 452       (let ((news (archive--get-section
 453                    "News" '("NEWS" "NEWS.rst" "NEWS.md" "NEWS.org")
 454                    srcdir mainsrcfile)))
 455         (when news
 456           (insert "<h2>News</h2><pre>\n" (archive--quote news) "\n</pre>\n")))
 457       (insert "</body>\n")
 458       (write-region (point-min) (point-max) (concat name ".html")))))
 459
 460 (defun archive--html-make-index (pkgs)
 461   (with-temp-buffer
 462     (insert (archive--html-header "GNU ELPA Packages"))
 463     (insert "<table cellpadding=\"3\" border=\"1\">\n")
 464     (insert "<tr><th>Package</th><th>Version</th><th>Description</th></tr>\n")
 465     (dolist (pkg pkgs)
 466       (insert (format "<tr><td><a href=\"%s.html\">%s</a></td><td>%s</td><td>%s</td></tr>\n"
 467                       (car pkg) (car pkg)
 468                       (package-version-join (aref (cdr pkg) 0))
 469                       (aref (cdr pkg) 2))))
 470     (insert "</table></body>\n")
 471     (write-region (point-min) (point-max) "index.html")))
 472
 473 (defun batch-html-make-index ()
 474   (let ((packages (make-hash-table :test #'equal))
 475         (archive-contents
 476          (with-temp-buffer
 477            (insert-file-contents "archive-contents")
 478            (goto-char (point-min))
 479            ;; Skip the first element which is a version number.
 480            (cdr (read (current-buffer))))))
 481     (dolist (file (directory-files default-directory nil))
 482       (cond
 483        ((member file '("." ".." "elpa.rss" "index.html" "archive-contents")))
 484        ((string-match "\\.html\\'" file))
 485        ((string-match "-readme\\.txt\\'" file)
 486         (let ((name (substring file 0 (match-beginning 0))))
 487           (puthash name (gethash name packages) packages)))
 488        ((string-match "-\\([0-9][^-]*\\)\\.\\(tar\\|el\\)\\'" file)
 489         (let ((name (substring file 0 (match-beginning 0)))
 490               (version (match-string 1 file)))
 491           (push (cons version file) (gethash name packages))))
 492        (t (message "Unknown file %S" file))))
 493     (dolist (pkg archive-contents)
 494       (archive--html-make-pkg pkg (gethash (symbol-name (car pkg)) packages)))
 495     ;; FIXME: Add (old?) packages that are in `packages' but not in
 496     ;; archive-contents.
 497     (archive--html-make-index archive-contents)))
 498
 499 ;;; Maintain external packages.
 500
 501 (defconst archive--elpa-git-url "git://git.sv.gnu.org/emacs/elpa")
 502
 503 (defun archive-add/remove/update-externals ()
 504   (let ((exts (with-current-buffer (find-file-noselect "externals-list")
 505                 (goto-char (point-min))
 506                 (read (current-buffer)))))
 507     (let ((default-directory (expand-file-name "packages/")))
 508       ;; Remove "old/odd" externals.
 509       (dolist (dir (directory-files "."))
 510         (cond
 511          ((member dir '("." "..")) nil)
 512          ((assoc dir exts) nil)
 513          ((file-directory-p (expand-file-name (format "%s/.git" dir)))
 514           (let ((status
 515                  (with-temp-buffer
 516                    (let ((default-directory (file-name-as-directory
 517                                              (expand-file-name dir))))
 518                      (call-process "git" nil t nil "status" "--porcelain")
 519                      (buffer-string)))))
 520             (if (zerop (length status))
 521                 (progn (delete-directory dir 'recursive t)
 522                        (message "Deleted all of %s" dir))
 523               (message "Keeping leftover unclean %s:\n%s" dir status))))))
 524       (pcase-dolist (`(,dir ,kind ,_url) exts)
 525         (cond
 526          ((eq kind :subtree) nil)       ;Nothing to do.
 527          ((not (eq kind :external))
 528           (message "Unknown external package kind `%S' for %s" kind dir))
 529          ((not (file-exists-p dir))
 530           (let* ((branch (concat "externals/" dir))
 531                  (output
 532                   (with-temp-buffer
 533                     ;; FIXME: Use git-new-workdir!
 534                     (call-process "git" nil t nil "clone"
 535                                   "--reference" ".." "--branch" branch
 536                                   archive--elpa-git-url dir)
 537                     (buffer-string))))
 538             (message "Cloning branch %s:\n%s" dir output)))
 539          ((not (file-directory-p (concat dir "/.git")))
 540           (message "%s is in the way of an external, please remove!" dir))
 541          (t
 542           (let ((default-directory (file-name-as-directory
 543                                     (expand-file-name dir))))
 544             (with-temp-buffer
 545               (message "Running git pull in %S" default-directory)
 546               (call-process "git" nil t nil "pull")
 547               (message "Updated %s:%s" dir (buffer-string))))
 548           ))))))
 549
 550 (provide 'archive-contents)
 551 ;;; archive-contents.el ends here