code.delx.au - gnu-emacs-elpa/blob - packages/f90-interface-browser/f90-interface-browser.el

   1 ;;; f90-interface-browser.el --- Parse and browse f90 interfaces
   2
   3 ;; Copyright (C) 2011, 2012, 2013  Free Software Foundation, Inc
   4
   5 ;; Author: Lawrence Mitchell <wence@gmx.li>
   6 ;; Created: 2011-07-06
   7 ;; URL: http://github.com/wence-/f90-iface/
   8 ;; Version: 1.1
   9 ;; Package-Type: simple
  10
  11 ;; COPYRIGHT NOTICE
  12
  13 ;; This program is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; This program is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27 ;; You write (or work on) large, modern fortran code bases.  These
  28 ;; make heavy use of function overloading and generic interfaces.  Your
  29 ;; brain is too small to remember what all the specialisers are
  30 ;; called.  Therefore, your editor should help you.
  31
  32 ;; Load this file and tell it to parse all the fortran files in your
  33 ;; code base.  You can do this one directory at a time by calling
  34 ;; `f90-parse-interfaces-in-dir' (M-x f90-parse-interfaces-in-dir
  35 ;; RET).  Or you can parse all the fortran files in a directory and
  36 ;; recursively in its subdirectories by calling
  37 ;; `f90-parse-all-interfaces'.
  38
  39 ;; Now you are able to browse (with completion) all defined interfaces
  40 ;; in your code by calling `f90-browse-interface-specialisers'.
  41 ;; Alternatively, if `point' is on a procedure call, you can call
  42 ;; `f90-find-tag-interface' and you'll be shown a list of the
  43 ;; interfaces that match the (possibly typed) argument list of the
  44 ;; current procedure.  This latter hooks into the `find-tag' machinery
  45 ;; so that you can use it on the M-.  keybinding and it will fall back
  46 ;; to completing tag names if you don't want to look for an interface
  47 ;; definition.
  48 ;; In addition, if you're in a large procedure and want the list of
  49 ;; the variables in scope (perhaps you want to define a new loop
  50 ;; variable), you can use `f90-list-in-scope-vars' to pop up a buffer
  51 ;; giving a reasonable guess.  Note this doesn't give you module
  52 ;; variables, or the variables of parent procedures if the current
  53 ;; subroutine is contained within another.
  54
  55 ;; Derived types are also parsed, so that slot types of derived types
  56 ;; are given the correct type (rather than a UNION-TYPE) when arglist
  57 ;; matching.  You can show the definition of a known derived type by
  58 ;; calling `f90-show-type-definition' which prompts (with completion)
  59 ;; for a typename to show.
  60
  61 ;; The parser assumes you write Fortran in the style espoused in
  62 ;; Metcalf, Reid and Cohen.  Particularly, variable declarations use a
  63 ;; double colon to separate the type from the name list.
  64
  65 ;; Here's an example of a derived type definition
  66 ;;     type foo
  67 ;;        real, allocatable, dimension(:) :: a
  68 ;;        integer, pointer :: b, c(:)
  69 ;;        type(bar) :: d
  70 ;;     end type
  71
  72 ;; Here's a subroutine declaration
  73 ;;     subroutine foo(a, b)
  74 ;;        integer, intent(in) :: a
  75 ;;        real, intent(inout), dimension(:,:) :: b
  76 ;;        ...
  77 ;;     end subroutine foo
  78
  79 ;; Local procedures whose names conflict with global ones will likely
  80 ;; confuse the parser.  For example
  81
  82 ;;    subroutine foo(a, b)
  83 ;;       ...
  84 ;;    end subroutine foo
  85 ;;
  86 ;;    subroutine bar(a, b)
  87 ;;       ...
  88 ;;       call subroutine foo
  89 ;;       ...
  90 ;;     contains
  91 ;;       subroutine foo
  92 ;;          ...
  93 ;;       end subroutine foo
  94 ;;    end subroutine bar
  95
  96 ;; Also not handled are overloaded operators, scalar precision
  97 ;; modifiers, like integer(kind=c_int), for which the precision is
  98 ;; just ignored, and many other aspects.
  99
 100 ;; Some tests of the parser are available in f90-tests.el (in the same
 101 ;; repository as this file).
 102
 103 ;;; Code:
 104
 105 ;;; Preamble
 106 (eval-when-compile (require 'cl))
 107 (require 'thingatpt)
 108 (require 'f90)
 109 (require 'etags)
 110
 111 (defgroup f90-iface nil
 112   "Static parser for Fortran 90 code"
 113   :prefix "f90-"
 114   :group 'f90)
 115
 116 (defcustom f90-file-extensions (list "f90" "F90" "fpp")
 117   "Extensions to consider when looking for Fortran 90 files."
 118   :type '(repeat string)
 119   :group 'f90-iface)
 120
 121 (defcustom f90-file-name-check-functions '(f90-check-fluidity-refcount)
 122   "List of functions to call to check if a file should be parsed.
 123
 124 In addition to checking if a file exists and is readable, you can
 125 add extra checks before deciding to parse a file.  Each function
 126 will be called with one argument, the fully qualified name of the
 127 file to test, it should return non-nil if the file should be
 128 parsed.  For an example test function see
 129 `f90-check-fluidity-refcount'."
 130   :type '(repeat function)
 131   :group 'f90-iface)
 132
 133 (defcustom f90-extra-file-functions '(f90-insert-fluidity-refcount)
 134   "List of functions to call to insert extra files to parse.
 135
 136 Each function should be a function of two arguments, the first is the
 137 fully qualified filename (with directory) the second is the
 138 unqualified filename."
 139   :type '(repeat function)
 140   :group 'f90-iface)
 141
 142 ;;; Internal variables
 143 (defvar f90-interface-type nil)
 144 (make-variable-buffer-local 'f90-interface-type)
 145
 146 (defvar f90-buffer-to-switch-to nil)
 147 (make-variable-buffer-local 'f90-buffer-to-switch-to)
 148
 149 (defvar f90-invocation-marker nil)
 150 (make-variable-buffer-local 'f90-invocation-marker)
 151
 152 ;; Data types for storing interface and specialiser definitions
 153 (defstruct f90-interface
 154   (name "" :read-only t)
 155   (publicp nil)
 156   specialisers)
 157
 158 (defstruct f90-specialiser
 159   (name "" :read-only t)
 160   (type "")
 161   (arglist "")
 162   location)
 163
 164 (defvar f90-all-interfaces (make-hash-table :test 'equal)
 165   "Hash table populated with all known f90 interfaces.")
 166
 167 (defvar f90-types (make-hash-table :test 'equal)
 168   "Hash table populated with all known f90 derived types.")
 169
 170 ;;; Inlineable utility functions
 171 (defsubst f90-specialisers (name interfaces)
 172   "Return all specialisers for NAME in INTERFACES."
 173   (f90-interface-specialisers (f90-get-interface name interfaces)))
 174
 175 (defsubst f90-valid-interface-name (name)
 176   "Return non-nil if NAME is an interface name."
 177   (gethash name f90-all-interfaces))
 178
 179 (defsubst f90-count-commas (str &optional level)
 180   "Count commas in STR.
 181
 182 If LEVEL is non-nil, only count commas up to the specified nesting
 183 level.  For example, a LEVEL of 0 counts top-level commas."
 184   (1- (length (f90-split-arglist str level))))
 185
 186 (defsubst f90-get-parsed-type-varname (type)
 187   "Return the variable name of TYPE."
 188   (car type))
 189
 190 (defsubst f90-get-parsed-type-typename (type)
 191   "Return the type name of TYPE."
 192   (cadr type))
 193
 194 (defsubst f90-get-parsed-type-modifiers (type)
 195   "Return the modifiers of TYPE."
 196   (cddr type))
 197
 198 (defsubst f90-get-type (type)
 199   "Return the struct definition corresponding to TYPE."
 200   (gethash (f90-get-parsed-type-typename type) f90-types))
 201
 202 (defsubst f90-get-slot-type (slot type)
 203   "Get the type of SLOT in TYPE."
 204   (let ((fn (intern-soft (format "f90-type.%s.%s"
 205                                  (f90-get-parsed-type-typename type) slot))))
 206     (when fn
 207       (funcall fn (f90-get-type type)))))
 208
 209 (defsubst f90-merge-into-tags-completion-table (ctable)
 210   "Merge completions in CTABLE into the tags completion table."
 211   (if (or tags-file-name tags-table-list)
 212       (let ((table (tags-completion-table)))
 213         (maphash (lambda (k v)
 214                    (ignore v)
 215                    (intern k table))
 216                  ctable)
 217         table)
 218     ctable))
 219
 220 (defun f90-lazy-completion-table ()
 221   "Lazily produce a completion table of all interfaces and tag names."
 222   (lexical-let ((buf (current-buffer)))
 223     (lambda (string pred action)
 224       (with-current-buffer buf
 225         (save-excursion
 226           ;; If we need to ask for the tag table, allow that.
 227           (let ((enable-recursive-minibuffers t))
 228             (visit-tags-table-buffer))
 229           (complete-with-action action (f90-merge-into-tags-completion-table f90-all-interfaces) string pred))))))
 230
 231 (defsubst f90-extract-type-name (name)
 232   "Return the typename from NAME.
 233
 234 If NAME is like type(TYPENAME) return TYPENAME, otherwise just NAME."
 235   (if (and name (string-match "\\`type(\\([^)]+\\))\\'" name))
 236       (match-string 1 name)
 237     name))
 238
 239 ;;; User-visible routines
 240
 241 (defun f90-parse-all-interfaces (dir)
 242   "Parse all interfaces found in DIR and its subdirectories.
 243
 244 Recurse over all (non-hidden) directories below DIR and parse
 245 interfaces found within them using `f90-parse-interfaces-in-dir',
 246 a directory is considered hidden if it's name doesn't start with
 247 an alphanumeric character."
 248   (interactive "DParse files in tree: ")
 249   (let (dirs
 250         attrs
 251         seen
 252         (pending (list (expand-file-name dir))))
 253     (while pending
 254       (push (pop pending) dirs)
 255       (let* ((this-dir (car dirs))
 256              (contents (directory-files this-dir))
 257              (default-directory this-dir))
 258         (setq attrs (nthcdr 10 (file-attributes this-dir)))
 259         (unless (member attrs seen)
 260           (push attrs seen)
 261           (dolist (file contents)
 262             ;; Ignore hidden directories
 263             (and (string-match "\\`[[:alnum:]]" file)
 264                  (file-directory-p file)
 265                  (setq pending (nconc pending
 266                                       (list (expand-file-name file)))))))))
 267     (mapc 'f90-parse-interfaces-in-dir dirs)))
 268
 269 (defun f90-parse-interfaces-in-dir (dir)
 270   "Parse all Fortran 90 files in DIR to populate `f90-all-interfaces'."
 271   (interactive "DParse files in directory: ")
 272   (loop for file in (directory-files dir t
 273                                      (rx-to-string
 274                                       `(and "." (or ,@f90-file-extensions)
 275                                             eos) t))
 276         do (f90-parse-interfaces file f90-all-interfaces)))
 277
 278 (defun f90-find-tag-interface (name &optional match-sublist)
 279   "List all interfaces matching NAME.
 280
 281 Restricts list to those matching the (possibly typed) arglist of
 282 the word at point.  If MATCH-SUBLIST is non-nil, only check if
 283 the arglist is a sublist of the specialiser's arglist.  For more
 284 details see `f90-approx-arglist-match' and
 285 `f90-browse-interface-specialisers'."
 286   (interactive (let ((def (word-at-point)))
 287                  (list (completing-read
 288                         (format "Find interface/tag (default %s): " def)
 289                         (f90-lazy-completion-table)
 290                         nil t nil nil def)
 291                        current-prefix-arg)))
 292   (if (f90-valid-interface-name name)
 293       (f90-browse-interface-specialisers name (f90-arglist-types)
 294                                          match-sublist
 295                                          (point-marker))
 296     (find-tag name match-sublist)))
 297
 298 (defun f90-browse-interface-specialisers (name &optional arglist-to-match
 299                                                match-sublist
 300                                                invocation-point)
 301   "Browse all interfaces matching NAME.
 302
 303 If ARGLIST-TO-MATCH is non-nil restrict to those interfaces that match
 304 it.
 305 If MATCH-SUBLIST is non-nil only restrict to those interfaces for
 306 which ARGLIST-TO-MATCH is a sublist of the specialiser's arglist.
 307
 308 If INVOCATION-POINT is non-nil it should be a `point-marker'
 309 indicating where we were called from, for jumping back to with
 310 `pop-tag-mark'."
 311   (interactive (let ((def (word-at-point)))
 312                  (list (completing-read
 313                         (format "Interface%s: "
 314                                 (if def
 315                                     (format " (default %s)" def)
 316                                   ""))
 317                         f90-all-interfaces
 318                         nil t nil nil def))))
 319   (let ((buf (current-buffer)))
 320     (or invocation-point (setq invocation-point (point-marker)))
 321     (with-current-buffer (get-buffer-create "*Interface Browser*")
 322       (let ((interface (f90-get-interface name f90-all-interfaces))
 323             (type nil)
 324             (n-specs 0))
 325         (setq buffer-read-only nil)
 326         (erase-buffer)
 327         (setq n-specs
 328               (loop for s being the hash-values of
 329                     (f90-interface-specialisers interface)
 330                     do (setq type (f90-specialiser-type s))
 331                     when (or (null arglist-to-match)
 332                              (f90-approx-arglist-match
 333                               arglist-to-match s match-sublist))
 334                     do (insert
 335                         (propertize
 336                          (concat
 337                           (propertize
 338                            (format "%s [defined in %s]\n    (%s)\n"
 339                                    (propertize (f90-specialiser-name s)
 340                                                'face 'bold)
 341                                    (let ((f (car
 342                                              (f90-specialiser-location s))))
 343                                      (format "%s/%s"
 344                                              (file-name-nondirectory
 345                                               (directory-file-name
 346                                                (file-name-directory f)))
 347                                              (file-name-nondirectory f)))
 348                                    (f90-fontify-arglist
 349                                     (f90-specialiser-arglist s)))
 350                            'f90-specialiser-location
 351                            (f90-specialiser-location s)
 352                            'f90-specialiser-name (f90-specialiser-name s)
 353                            'mouse-face 'highlight
 354                            'help-echo
 355                            "mouse-1: find definition in other window")
 356                           "\n")
 357                          'f90-specialiser-extent (f90-specialiser-name s)))
 358                     and count 1))
 359         (goto-char (point-min))
 360         (insert (format "Interfaces for %s:\n\n"
 361                         (f90-interface-name interface)))
 362         (when arglist-to-match
 363           (insert (format "%s\n%s\n\n"
 364                           (if (zerop n-specs)
 365                               "No interfaces matching arglist (intrinsic?):"
 366                             "Only showing interfaces matching arglist:")
 367                           (f90-fontify-arglist arglist-to-match))))
 368         (f90-interface-browser-mode)
 369         (setq f90-buffer-to-switch-to buf)
 370         (setq f90-interface-type type)
 371         (setq f90-invocation-marker invocation-point)
 372         (pop-to-buffer (current-buffer))))))
 373
 374 (defun f90-next-definition (&optional arg)
 375   "Go to the next ARG'th specialiser definition."
 376   (interactive "p")
 377   (unless arg
 378     (setq arg 1))
 379   (while (> arg 0)
 380     (goto-char (next-single-property-change
 381                 (point)
 382                 'f90-specialiser-extent
 383                 nil (point-max)))
 384     (decf arg)))
 385
 386 (defun f90-previous-definition (&optional arg)
 387   "Go to the previous ARG'th specialiser definition."
 388   (interactive "p")
 389   (unless arg
 390     (setq arg 1))
 391   (while (> arg 0)
 392     (loop repeat 2
 393           do (goto-char (previous-single-property-change
 394                          (point)
 395                          'f90-specialiser-extent
 396                          nil (point-min))))
 397     (f90-next-definition 1)
 398     (decf arg)))
 399
 400 (defun f90-mouse-find-definition (e)
 401   "Visit the definition at the position of the event E."
 402   (interactive "e")
 403   (let ((win (posn-window (event-end e)))
 404         (point (posn-point (event-end e))))
 405     (when (not (windowp win))
 406       (error "No definition here"))
 407     (with-current-buffer (window-buffer win)
 408       (goto-char point)
 409       (f90-find-definition))))
 410
 411 (defun f90-quit-browser ()
 412   "Quit the interface browser."
 413   (interactive)
 414   (let ((buf f90-buffer-to-switch-to))
 415     (kill-buffer (current-buffer))
 416     (pop-to-buffer buf)))
 417
 418 (defun f90-find-definition ()
 419   "Visit the definition at `point'."
 420   (interactive)
 421   (let ((location (get-text-property (point) 'f90-specialiser-location))
 422         (name (get-text-property (point) 'f90-specialiser-name))
 423         (type f90-interface-type)
 424         (buf (current-buffer))
 425         buf-to)
 426     (if location
 427         (progn (ring-insert find-tag-marker-ring f90-invocation-marker)
 428                (find-file-other-window (car location))
 429                (setq buf-to (current-buffer))
 430                (goto-char (cadr location))
 431                ;; Try forwards then backwards near the recorded
 432                ;; location
 433                (or (re-search-forward (format "%s[ \t]+%s[ \t]*("
 434                                               type name) nil t)
 435                    (re-search-backward (format "%s[ \t]+%s[ \t]*("
 436                                                type name) nil t))
 437                (beginning-of-line)
 438                (recenter 0)
 439                (pop-to-buffer buf)
 440                (setq f90-buffer-to-switch-to buf-to))
 441       (error "No definition at point"))))
 442
 443 (defvar f90-interface-browser-mode-map
 444   (let ((map (make-sparse-keymap)))
 445     (define-key map (kbd "RET") 'f90-find-definition)
 446     (define-key map (kbd "<down>") 'f90-next-definition)
 447     (define-key map (kbd "TAB") 'f90-next-definition)
 448     (define-key map (kbd "<up>") 'f90-previous-definition)
 449     (define-key map (kbd "<backtab>") 'f90-previous-definition)
 450     (define-key map (kbd "q") 'f90-quit-browser)
 451     (define-key map (kbd "<mouse-1>") 'f90-mouse-find-definition)
 452     map)
 453   "Keymap for `f90-interface-browser-mode'.")
 454
 455 (define-derived-mode f90-interface-browser-mode fundamental-mode "IBrowse"
 456   "Major mode for browsing f90 interfaces."
 457   (setq buffer-read-only t)
 458   (set-buffer-modified-p nil))
 459
 460 ;;; Type definitions
 461
 462 (defun f90-type-at-point ()
 463   "Return a guess for the type of the thing at `point'.
 464
 465 If `point' is currently on a line containing a variable declaration,
 466 return the typename of the declaration.  Otherwise try and figure out
 467 the typename of the variable at point (possibly including slot
 468 references)."
 469   (let ((name (or
 470                ;; Are we on a line with type(TYPENAME)?
 471                (save-excursion
 472                  (forward-line 0)
 473                  (f90-parse-single-type-declaration))
 474                ;; No, try and derive the type of the variable at point
 475                (save-excursion
 476                  (let ((syntax (copy-syntax-table f90-mode-syntax-table)))
 477                    (modify-syntax-entry ?% "w" syntax)
 478                    (with-syntax-table syntax
 479                      (skip-syntax-backward "w")
 480                      (f90-arg-types
 481                       (list
 482                        (buffer-substring-no-properties
 483                         (point)
 484                         (progn (skip-syntax-forward "w") (point)))))))))))
 485     (f90-extract-type-name (f90-get-parsed-type-typename (car name)))))
 486
 487 (defun f90-show-type-definition (type)
 488   "Show the definition of TYPE.
 489
 490 This formats the parsed definition of TYPE, rather than jumping to the
 491 existing definition.
 492
 493 When called interactively, default to the type of the thing at `point'.
 494 If `point' is on a type declaration line, the default is the
 495 declaration type.
 496 If `point' is on a variable name (possibly with slot references) the
 497 default is the type of the variable."
 498   (interactive (list (let ((def (f90-type-at-point)))
 499                        (completing-read
 500                         (if def (format "Type (default %s): " def) "Type: ")
 501                         (loop for type being the hash-keys of f90-types
 502                               collect (f90-extract-type-name type))
 503                         nil t nil nil def))))
 504   (with-current-buffer (get-buffer-create "*Type definition*")
 505     (setq buffer-read-only nil)
 506     (fundamental-mode)
 507     (erase-buffer)
 508     (let* ((tname (format "type(%s)" type))
 509            (type-struct (f90-get-type (list nil tname)))
 510            fns)
 511       (when type-struct
 512         (setq fns (loop for name in (funcall (intern-soft
 513                                               (format "f90-type.%s.-varnames"
 514                                                       tname))
 515                                              type-struct)
 516                         collect (intern-soft (format "f90-type.%s.%s"
 517                                                      tname name)))))
 518       (if (null type-struct)
 519           (insert (format "The type %s is not a known derived type."
 520                           type))
 521         (insert (format "type %s\n" type))
 522         (loop for fn in fns
 523               for parsed = (funcall fn type-struct)
 524               then (funcall fn type-struct)
 525               do
 526               (insert (format "  %s :: %s\n"
 527                               (f90-format-parsed-slot-type parsed)
 528                               (f90-get-parsed-type-varname parsed))))
 529         (insert (format "end type %s\n" type))
 530         (f90-mode))
 531       (goto-char (point-min))
 532       (view-mode)
 533       (pop-to-buffer (current-buffer)))))
 534
 535 ;;; Arglist matching/formatting
 536
 537 (defun f90-format-parsed-slot-type (type)
 538   "Turn a parsed TYPE into a valid f90 type declaration."
 539   (if (null type)
 540       "UNION-TYPE"
 541     ;; Ignore name
 542     (setq type (cdr type))
 543     (mapconcat 'identity (loop for a in type
 544                                if (and (consp a)
 545                                        (string= (car a) "dimension"))
 546                                collect (format "dimension(%s)"
 547                                                (mapconcat 'identity
 548                                                           (make-list (cdr a)
 549                                                                      ":")
 550                                                           ","))
 551                                else if (not
 552                                         (string-match
 553                                          "\\`intent(\\(?:in\\|out\\|inout\\))"
 554                                          a))
 555                                collect a)
 556                ", ")))
 557
 558 (defun f90-fontify-arglist (arglist)
 559   "Fontify ARGLIST using `f90-mode'."
 560   (with-temp-buffer
 561     (if (stringp arglist)
 562         (insert (format "%s :: foo\n" arglist))
 563       (insert (mapconcat (lambda (x)
 564                            (format "%s :: foo" (f90-format-parsed-slot-type x)))
 565                          arglist "\n")))
 566     (f90-mode)
 567     (font-lock-fontify-buffer)
 568     (goto-char (point-min))
 569     (mapconcat 'identity
 570                (loop while (not (eobp))
 571                      collect (buffer-substring (line-beginning-position)
 572                                                (- (line-end-position)
 573                                                   (length " :: foo")))
 574                      do (forward-line 1))
 575                "; ")))
 576
 577 (defun f90-count-non-optional-args (arglist)
 578   "Count non-optional args in ARGLIST."
 579   (loop for arg in arglist
 580         count (not (member "optional" (f90-get-parsed-type-modifiers arg)))))
 581
 582 (defun f90-approx-arglist-match (arglist specialiser &optional match-sub-list)
 583   "Return non-nil if ARGLIST matches the arglist of SPECIALISER.
 584
 585 If MATCH-SUB-LIST is non-nil just require that ARGLIST matches the
 586 first (length ARGLIST) args of SPECIALISER."
 587   (let* ((n-passed-args (length arglist))
 588          (spec-arglist (f90-specialiser-arglist specialiser))
 589          (n-spec-args (length spec-arglist))
 590          (n-required-args (f90-count-non-optional-args spec-arglist)))
 591     (when (or match-sub-list
 592               (and (<= n-required-args n-passed-args)
 593                    (<= n-passed-args n-spec-args)))
 594       (loop for arg in arglist
 595             for spec-arg in spec-arglist
 596             unless (or (null arg)
 597                        (string= (f90-get-parsed-type-typename arg)
 598                                 (f90-get-parsed-type-typename spec-arg)))
 599             do (return nil)
 600             finally (return t)))))
 601
 602 ;;; Internal functions
 603
 604 (defun f90-clean-comments ()
 605   "Clean Fortran 90 comments from the current buffer."
 606   (save-excursion
 607     (goto-char (point-min))
 608     (set-syntax-table f90-mode-syntax-table)
 609     (while (search-forward "!" nil t)
 610       (when (nth 4 (parse-partial-sexp (line-beginning-position) (point)))
 611         (delete-region (max (1- (point)) (line-beginning-position))
 612                        (line-end-position))))))
 613
 614 (defun f90-clean-continuation-lines ()
 615   "Splat Fortran continuation lines in the current buffer onto one line."
 616   (save-excursion
 617     (goto-char (point-min))
 618     (while (re-search-forward "&[ \t]*\n[ \t]*&?" nil t)
 619       (replace-match "" nil t))))
 620
 621 (defun f90-normalise-string (string)
 622   "Return a suitably normalised version of STRING."
 623   ;; Trim whitespace
 624   (save-match-data
 625     (when (string-match "\\`[ \t]+" string)
 626       (setq string (replace-match "" t t string)))
 627     (when (string-match "[ \t]+\\'" string)
 628       (setq string (replace-match "" t t string)))
 629     (downcase string)))
 630
 631 (defun f90-get-interface (name &optional interfaces)
 632   "Get the interface with NAME from INTERFACES.
 633
 634 If INTERFACES is nil use `f90-all-interfaces' instead."
 635   (gethash name (or interfaces f90-all-interfaces)))
 636
 637 (defsetf f90-get-interface (name &optional interfaces) (val)
 638   `(setf (gethash ,name (or ,interfaces f90-all-interfaces)) ,val))
 639
 640 ;;; Entry point to parsing routines
 641
 642 (defun f90-parse-file-p (file)
 643   "Return non-nil if FILE should be parsed.
 644
 645 This checks that FILE exists and is readable, and then calls
 646 additional test functions from `f90-file-name-check-functions'."
 647   (and (file-exists-p file)
 648        (file-readable-p file)
 649        (loop for test in f90-file-name-check-functions
 650              unless (funcall test file)
 651              do (return nil)
 652              finally (return t))))
 653
 654 (defun f90-check-fluidity-refcount (file)
 655   "Return nil if FILE is that of a Fluidity refcount template."
 656   (let ((fname (file-name-nondirectory file)))
 657     (and (not (string-match "\\`Reference_count_interface" fname))
 658          (not (string-equal "Refcount_interface_templates.F90" fname))
 659          (not (string-equal "Refcount_templates.F90" fname)))))
 660
 661 (defun f90-maybe-insert-extra-files (file)
 662   "Maybe insert extra files corresponding to FILE when parsing.
 663
 664 To actually insert extra files, customize the variable
 665 `f90-extra-file-functions'.  For an example insertion function
 666 see `f90-insert-fluidity-refcount'."
 667   (let ((fname (file-name-nondirectory file)))
 668     (loop for fn in f90-extra-file-functions
 669           do (funcall fn file fname))))
 670
 671 (defun f90-insert-fluidity-refcount (file fname)
 672   "Insert a Fluidity reference count template for FILE.
 673
 674 If FNAME matches \\\\`Reference_count_.*\\\\.F90 then this file
 675 needs a reference count interface, so insert one."
 676   (when (string-match "\\`Reference_count_\\([^\\.]+\\)\\.F90" fname)
 677     (insert-file-contents-literally
 678      (expand-file-name
 679       (format "Reference_count_interface_%s.F90"
 680               (match-string 1 fname))
 681       (file-name-directory file)))))
 682
 683 (defun f90-parse-interfaces (file existing)
 684   "Parse interfaces in FILE and merge into EXISTING interface data."
 685   (with-temp-buffer
 686     (let ((interfaces (make-hash-table :test 'equal)))
 687       ;; Is this file valid for parsing
 688       (when (f90-parse-file-p file)
 689         (insert-file-contents-literally file)
 690         ;; Does this file have other parts elsewhere?
 691         (f90-maybe-insert-extra-files file)
 692         ;; Easier if we don't have to worry about line wrap
 693         (f90-clean-comments)
 694         (f90-clean-continuation-lines)
 695         (goto-char (point-min))
 696         ;; Search forward for a named interface block
 697         (while (re-search-forward
 698                 "^[ \t]*interface[ \t]+\\([^ \t\n]+\\)[ \t]*$" nil t)
 699           (let* ((name (f90-normalise-string (match-string 1)))
 700                  interface)
 701             (unless (string= name "")
 702               (setq interface (make-f90-interface :name name))
 703               (save-restriction
 704                 ;; Figure out all the specialisers for this generic name
 705                 (narrow-to-region
 706                  (point)
 707                  (re-search-forward
 708                   (format "[ \t]*end interface\\(?:[ \t]+%s\\)?[ \t]*$" name)
 709                   nil t))
 710                 (f90-populate-specialisers interface))
 711               ;; Multiple interface blocks with same name (this seems to
 712               ;; be allowed).  In which case merge rather than overwrite.
 713               (if (f90-get-interface name interfaces)
 714                   (f90-merge-interface interface interfaces)
 715                 (setf (f90-get-interface name interfaces) interface)))))
 716         (goto-char (point-min))
 717         ;; Parse type definitions
 718         (save-excursion
 719           (while (re-search-forward
 720                   "^[ \t]*type[ \t]+\\(?:[^ \t\n]+\\)[ \t]*$" nil t)
 721             (let ((beg (match-beginning 0)))
 722               (unless (re-search-forward "^[ \t]*end[ \t]+type.*$" nil t)
 723                 (error "Unable to find end of type definition"))
 724               (save-restriction
 725                 (narrow-to-region beg (match-beginning 0))
 726                 (f90-parse-type-definition)))))
 727
 728         ;; Now find out if an interface is public or private to the module
 729         (f90-set-public-attribute interfaces)
 730
 731         ;; Now find the arglists corresponding to the interface (so we
 732         ;; can disambiguate) and record their location in the file.
 733         (loop for interface being the hash-values of interfaces
 734               do (when (f90-interface-specialisers interface)
 735                    (maphash (lambda (specialiser val)
 736                               (save-excursion
 737                                 (goto-char (point-min))
 738                                 (let ((thing (f90-argument-list specialiser)))
 739                                   (setf (f90-specialiser-arglist
 740                                          val)
 741                                         (cadr thing))
 742                                   (setf (f90-specialiser-location
 743                                          val)
 744                                         (list file (caddr thing)))
 745                                   (setf (f90-specialiser-type
 746                                          val)
 747                                         (car thing)))))
 748                             (f90-interface-specialisers interface))))
 749         ;; Finally merge these new interfaces into the existing data.
 750         (f90-merge-interfaces interfaces existing)))))
 751
 752 (defun f90-merge-interface (interface interfaces)
 753   "Merge INTERFACE into the existing set of INTERFACES."
 754   (let ((name (f90-interface-name interface))
 755         spec-name)
 756     (when (f90-interface-specialisers interface)
 757       (loop for val being the hash-values of
 758             (f90-interface-specialisers interface)
 759             do (setq spec-name (f90-specialiser-name val))
 760             (setf (gethash spec-name (f90-specialisers name interfaces))
 761                   val)))))
 762
 763 (defun f90-merge-interfaces (new existing)
 764   "Merge NEW interfaces into EXISTING ones."
 765   (maphash (lambda (name val)
 766              (if (gethash name existing)
 767                  (f90-merge-interface val existing)
 768                (setf (gethash name existing)
 769                      val)))
 770            new))
 771
 772 (defun f90-populate-specialisers (interface)
 773   "Find all specialisers for INTERFACE."
 774   (save-excursion
 775     (goto-char (point-min))
 776     (setf (f90-interface-specialisers interface)
 777           (make-hash-table :test 'equal))
 778     (while (search-forward "module procedure" nil t)
 779       (let ((names (buffer-substring-no-properties
 780                     (point)
 781                     (line-end-position))))
 782         (mapc (lambda (x)
 783                 (setq x (f90-normalise-string x))
 784                 (setf (gethash x (f90-interface-specialisers interface))
 785                       (make-f90-specialiser :name x)))
 786               (split-string names "[, \n]+" t))))))
 787
 788 (defun f90-set-public-attribute (interfaces)
 789   "Set public/private flag on all INTERFACES."
 790   (save-excursion
 791     ;; Default public unless private is specified.
 792     (let ((public (not (save-excursion
 793                          (re-search-forward "^[ \t]*private[ \t]*$" nil t)))))
 794       (while (re-search-forward (format "^[ \t]*%s[ \t]+"
 795                                         (if public "private" "public"))
 796                                 nil t)
 797         (let ((names (buffer-substring-no-properties
 798                       (match-end 0)
 799                       (line-end-position))))
 800           ;; Set default
 801           (maphash (lambda (k v)
 802                      (ignore k)
 803                      (setf (f90-interface-publicp v) public))
 804                    interfaces)
 805           ;; Override for those specified
 806           (mapc (lambda (name)
 807                   (let ((interface (f90-get-interface name interfaces)))
 808                     (when interface
 809                       (setf (f90-interface-publicp interface) (not public)))))
 810                 (split-string names "[, \t]" t)))))))
 811
 812 ;;; Type/arglist parsing
 813 (defun f90-argument-list (name)
 814   "Return typed argument list of function or subroutine NAME."
 815   (save-excursion
 816     (when (re-search-forward
 817            (format "\\(function\\|subroutine\\)[ \t]+%s[ \t]*("
 818                    name)
 819            nil t)
 820       (let* ((point (match-beginning 0))
 821              (type (match-string 1))
 822              (args (f90-split-arglist (buffer-substring-no-properties
 823                                        (point)
 824                                        (f90-end-of-arglist)))))
 825         (list type (f90-arg-types args) point)))))
 826
 827 (defun f90-parse-type-definition ()
 828   "Parse a type definition at (or in front of) `point'."
 829   (let (type slots slot fn)
 830     (goto-char (point-min))
 831     (unless (re-search-forward "^[ \t]*type[ \t]+\\(.+?\\)[ \t]*$" nil t)
 832       (error "Trying parse a type but no type found"))
 833     (setq type (format "type(%s)" (f90-normalise-string (match-string 1))))
 834     (while (not (eobp))
 835       (setq slot (f90-parse-single-type-declaration))
 836       (when slot
 837         (setf slots (nconc slot slots)))
 838       (forward-line 1))
 839     (eval (f90-make-type-struct type slots))
 840     (setq fn (intern-soft (format "make-f90-type.%s" type)))
 841     (unless fn
 842       (error "Something bad went wrong parsing type definition %s" type))
 843     (setf (gethash type f90-types) (funcall fn))))
 844
 845 (defun f90-make-type-struct (type slots)
 846   "Create a struct describing TYPE with SLOTS."
 847   (let ((struct-name (make-symbol (format "f90-type.%s" type)))
 848         (varnames (reverse (mapcar (lambda (x)
 849                                      (setq x (car x))
 850                                      (if (string-match "\\([^(]+\\)(" x)
 851                                          (match-string 1 x)
 852                                        x)) slots))))
 853     `(defstruct (,struct-name
 854                  (:conc-name ,(make-symbol (format "f90-type.%s." type))))
 855        (-varnames ',varnames :read-only t)
 856        ,@(loop for (name . rest) in slots
 857                collect `(,(make-symbol name) (cons ',name ',rest)
 858                          :read-only t)))))
 859
 860 (defun f90-arglist-types ()
 861   "Return the types of the arguments to the function at `point'."
 862   (save-excursion
 863     (let* ((e (save-excursion (f90-end-of-subprogram) (point)))
 864            (b (save-excursion (f90-beginning-of-subprogram) (point)))
 865            (str (buffer-substring-no-properties b e))
 866            (p (point))
 867            names)
 868       (with-temp-buffer
 869         (with-syntax-table f90-mode-syntax-table
 870           (insert str)
 871           (goto-char (- p b))
 872           (setq p (point-marker))
 873           (f90-clean-continuation-lines)
 874           (goto-char p)
 875           (search-forward "(")
 876           (setq names (f90-split-arglist (buffer-substring
 877                                           (point)
 878                                           (f90-end-of-arglist))))
 879           (goto-char (point-min))
 880           (f90-arg-types names))))))
 881
 882 (defun f90-list-in-scope-vars ()
 883   "Pop up a buffer showing all variables in scope in the procedure at `point'"
 884   (interactive)
 885   (let* ((e (save-excursion (f90-end-of-subprogram) (point)))
 886          (b (save-excursion (f90-beginning-of-subprogram) (point)))
 887          (str (buffer-substring-no-properties b e))
 888          types)
 889     (with-temp-buffer
 890       (with-syntax-table f90-mode-syntax-table
 891         (insert str)
 892         (goto-char (point-min))
 893         (f90-clean-comments)
 894         (f90-clean-continuation-lines)
 895         (forward-line 1)                ; skip procedure name
 896         (let ((not-done t)
 897               type)
 898           (while (and not-done (not (eobp)))
 899             ;; skip "implicit none" which may appear at top of procedure
 900             (when (looking-at "\\s-*implicit\\s-+none")
 901               (forward-line 1))
 902             (when (not (looking-at "^\\s-*$"))
 903               (setq type (ignore-errors (f90-parse-single-type-declaration)))
 904               ;; If we were on a line with text and failed to parse a
 905               ;; type, we must have reached the end of the type
 906               ;; definitions, so don't push it on and finish.
 907               (if type
 908                   (push type types)
 909                 (setq not-done nil)))
 910             (forward-line 1)))))
 911     (with-current-buffer (get-buffer-create "*Variables in scope*")
 912       (setq buffer-read-only nil)
 913       (erase-buffer)
 914       (f90-mode)
 915       ;; Show types of the same type together
 916       (setq types (sort types (lambda (x y)
 917                                 (string< (cadar x) (cadar y)))))
 918       (loop for (type name) in types
 919             do
 920             (insert (format "%s :: %s\n"
 921                             (f90-format-parsed-slot-type type)
 922                             (f90-get-parsed-type-varname type))))
 923       (pop-to-buffer (current-buffer))
 924       (goto-char (point-min))
 925       (setq buffer-read-only t))))
 926
 927 (defun f90-arg-types (names)
 928   "Given NAMES of arguments return their types.
 929
 930 This works even with derived type subtypes (e.g. if A is a type(foo)
 931 with slot B of type REAL, then A%B is returned being a REAL)."
 932   (loop for arg in names
 933         for subspec = nil then nil
 934         do (setq arg (f90-normalise-string arg))
 935         if (string-match "\\`\\([^%]+?\\)[ \t]*%\\(.+\\)\\'" arg)
 936         do (setq subspec (match-string 2 arg)
 937                  arg (match-string 1 arg))
 938         collect (save-excursion
 939                   (save-restriction
 940                     (when (re-search-forward
 941                            (format "^[ \t]*\\([^!\n].+?\\)[ \t]*::.*\\<%s\\>"
 942                                    arg) nil t)
 943                       (goto-char (match-beginning 0))
 944                       (let ((type (assoc arg
 945                                          (f90-parse-single-type-declaration))))
 946                         (f90-get-type-subtype type subspec)))))))
 947
 948 (defun f90-get-type-subtype (type subspec)
 949   "Return the type of TYPE possibly including slot references in SUBSPEC."
 950   (cond ((null subspec)
 951          type)
 952         ((string-match "\\`\\([^%]+?\\)[ \t]*%\\(.+\\)\\'" subspec)
 953          (f90-get-type-subtype (f90-get-slot-type (match-string 1 subspec)
 954                                                   type)
 955                                (match-string 2 subspec)))
 956         (t
 957          (f90-get-slot-type subspec type))))
 958
 959 (defun f90-split-arglist (arglist &optional level)
 960   "Split ARGLIST into words.
 961
 962 Split based on top-level commas.  For example
 963
 964   (f90-split-arglist \"foo, bar, baz(quux, zot)\")
 965     => (\"foo\" \"bar\" \"baz(quux, zot)\").
 966
 967 If LEVEL is non-nil split on commas up to and including LEVEL.
 968 For example:
 969
 970   (f90-split-arglist \"foo, bar, baz(quux, zot)\" 1)
 971     => (\"foo\" \"bar\" \"baz(quux\" \"zot)\")."
 972   (setq level (or level 0))
 973   (loop for c across arglist
 974         for i = 0 then (1+ i)
 975         with cur-level = 0
 976         with b = 0
 977         with len = (length arglist)
 978         if (eq c ?\()
 979         do (incf cur-level)
 980         else if (eq c ?\))
 981         do (decf cur-level)
 982         if (and (<= cur-level level)
 983                 (eq c ?,))
 984         collect (f90-normalise-string (substring arglist b i))
 985         and do (setq b (1+ i))
 986         if (and (<= cur-level level)
 987                 (= (1+ i) len))
 988         collect (f90-normalise-string (substring arglist b))))
 989
 990 (defun f90-end-of-arglist ()
 991   "Find the end of the arglist at `point'."
 992   (save-excursion
 993     (let ((level 0))
 994       (while (> level -1)
 995         (cond ((eq (char-after) ?\()
 996                (incf level))
 997               ((eq (char-after) ?\))
 998                (decf level))
 999               (t nil))
1000         (forward-char)))
1001     (1- (point))))
1002
1003 (defun f90-parse-names-list (names)
1004   "Return a list of NAMES from the RHS of a :: type declaration."
1005   (let ((names-list (f90-split-arglist names)))
1006     (loop for name in names-list
1007           if (string-match "\\`\\([^=]+\\)[ \t]*=.*\\'" name)
1008           collect (f90-normalise-string (match-string 1 name))
1009           else
1010           collect (f90-normalise-string name))))
1011
1012 (defun f90-parse-single-type-declaration ()
1013   "Parse a single f90 type declaration at `point'.
1014
1015 Assumes that this has the form
1016   TYPENAME[, MODIFIERS]* :: NAME[, NAMES]*
1017
1018 NAMES can optionally have initialisation attached to them which is
1019 dealt with correctly."
1020   (when (looking-at "^[ \t]*\\(.*?\\)[ \t]*::[ \t]*\\(.*\\)$")
1021     (let ((dec-orig (match-string 1))
1022           (names (f90-parse-names-list (match-string 2))))
1023       (loop for name in names
1024             for dec = (f90-split-declaration dec-orig)
1025             then (f90-split-declaration dec-orig)
1026             if (string-match "\\([^(]+\\)(\\([^)]+\\))" name)
1027             do (progn (if (assoc "dimension" dec)
1028                           (setcdr (assoc "dimension" dec)
1029                                   (1+ (f90-count-commas
1030                                        (match-string 2 name))))
1031                         (push (cons "dimension"
1032                                     (1+ (f90-count-commas
1033                                          (match-string 2 name))))
1034                               dec))
1035                       (setq name (match-string 1 name)))
1036             collect (cons name (nreverse dec))))))
1037
1038 (defun f90-split-declaration (dec)
1039   "Split and parse a type declaration DEC.
1040
1041 This takes the bit before the :: and returns a list of the typename
1042 and any modifiers."
1043   (let ((things (f90-split-arglist dec)))
1044     (cons (if (string-match
1045                "\\([^(]+?\\)[ \t]*([ \t]*\\(:?len\\|kind\\)[ \t]*=[^)]+)"
1046                (car things))
1047               (match-string 1 (car things))
1048             (car things))
1049           (loop for thing in (cdr things)
1050                 if (string-match "dimension[ \t]*(\\(.+\\))" thing)
1051                 collect (cons "dimension"
1052                               (1+ (f90-count-commas (match-string 1 thing))))
1053                 else
1054                 collect thing))))
1055
1056 (provide 'f90-interface-browser)
1057
1058 ;;; f90-interface-browser.el ends here