code.delx.au - gnu-emacs-elpa/blob - swiper.el

   1 ;;; swiper.el --- Isearch with an overview. Oh, man! -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2015  Free Software Foundation, Inc.
   4
   5 ;; Author: Oleh Krehel <ohwoeowho@gmail.com>
   6 ;; URL: https://github.com/abo-abo/swiper
   7 ;; Version: 0.7.0
   8 ;; Package-Requires: ((emacs "24.1"))
   9 ;; Keywords: matching
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; This file is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 3, or (at your option)
  16 ;; any later version.
  17
  18 ;; This program is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; For a full copy of the GNU General Public License
  24 ;; see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27 ;;
  28 ;; This package gives an overview of the current regex search
  29 ;; candidates.  The search regex can be split into groups with a
  30 ;; space.  Each group is highlighted with a different face.
  31 ;;
  32 ;; It can double as a quick `regex-builder', although only single
  33 ;; lines will be matched.
  34 ;;
  35 ;; It also provides `ivy-mode': a global minor mode that uses the
  36 ;; matching back end of `swiper' for all matching on your system,
  37 ;; including file matching. You can use it in place of `ido-mode'
  38 ;; (can't have both on at once).
  39
  40 ;;; Code:
  41 (require 'ivy)
  42
  43 (defgroup swiper nil
  44   "`isearch' with an overview."
  45   :group 'matching
  46   :prefix "swiper-")
  47
  48 (defface swiper-match-face-1
  49   '((t (:inherit isearch-lazy-highlight-face)))
  50   "The background face for `swiper' matches.")
  51
  52 (defface swiper-match-face-2
  53   '((t (:inherit isearch)))
  54   "Face for `swiper' matches modulo 1.")
  55
  56 (defface swiper-match-face-3
  57   '((t (:inherit match)))
  58   "Face for `swiper' matches modulo 2.")
  59
  60 (defface swiper-match-face-4
  61   '((t (:inherit isearch-fail)))
  62   "Face for `swiper' matches modulo 3.")
  63
  64 (defface swiper-line-face
  65   '((t (:inherit highlight)))
  66   "Face for current `swiper' line.")
  67
  68 (defcustom swiper-faces '(swiper-match-face-1
  69                           swiper-match-face-2
  70                           swiper-match-face-3
  71                           swiper-match-face-4)
  72   "List of `swiper' faces for group matches."
  73   :group 'ivy-faces
  74   :type 'list)
  75
  76 (defcustom swiper-min-highlight 2
  77   "Only highlight matches for regexps at least this long."
  78   :type 'integer)
  79
  80 (defvar swiper-map
  81   (let ((map (make-sparse-keymap)))
  82     (define-key map (kbd "M-q") 'swiper-query-replace)
  83     (define-key map (kbd "C-l") 'swiper-recenter-top-bottom)
  84     (define-key map (kbd "C-'") 'swiper-avy)
  85     (define-key map (kbd "C-7") 'swiper-mc)
  86     (define-key map (kbd "C-c C-f") 'swiper-toggle-face-matching)
  87     map)
  88   "Keymap for swiper.")
  89
  90 (defun swiper-query-replace ()
  91   "Start `query-replace' with string to replace from last search string."
  92   (interactive)
  93   (if (null (window-minibuffer-p))
  94       (user-error "Should only be called in the minibuffer through `swiper-map'")
  95     (let* ((enable-recursive-minibuffers t)
  96            (from (ivy--regex ivy-text))
  97            (to (query-replace-read-to from "Query replace" t)))
  98       (swiper--cleanup)
  99       (ivy-exit-with-action
 100        (lambda (_)
 101          (with-ivy-window
 102            (move-beginning-of-line 1)
 103            (perform-replace from to
 104                             t t nil)))))))
 105
 106 (defvar avy-background)
 107 (defvar avy-all-windows)
 108 (defvar avy-style)
 109 (defvar avy-keys)
 110 (declare-function avy--regex-candidates "ext:avy")
 111 (declare-function avy--process "ext:avy")
 112 (declare-function avy--overlay-post "ext:avy")
 113 (declare-function avy-action-goto "ext:avy")
 114 (declare-function avy--done "ext:avy")
 115 (declare-function avy--make-backgrounds "ext:avy")
 116 (declare-function avy-window-list "ext:avy")
 117 (declare-function avy-read "ext:avy")
 118 (declare-function avy-read-de-bruijn "ext:avy")
 119 (declare-function avy-tree "ext:avy")
 120 (declare-function avy-push-mark "ext:avy")
 121 (declare-function avy--remove-leading-chars "ext:avy")
 122
 123 ;;;###autoload
 124 (defun swiper-avy ()
 125   "Jump to one of the current swiper candidates."
 126   (interactive)
 127   (unless (string= ivy-text "")
 128     (let* ((avy-all-windows nil)
 129            (candidates (append
 130                         (with-ivy-window
 131                           (avy--regex-candidates
 132                            (ivy--regex ivy-text)))
 133                         (save-excursion
 134                           (save-restriction
 135                             (narrow-to-region (window-start) (window-end))
 136                             (goto-char (point-min))
 137                             (forward-line)
 138                             (let ((cands))
 139                               (while (< (point) (point-max))
 140                                 (push (cons (1+ (point))
 141                                             (selected-window))
 142                                       cands)
 143                                 (forward-line))
 144                               cands)))))
 145            (candidate (unwind-protect
 146                            (prog2
 147                                (avy--make-backgrounds
 148                                 (append (avy-window-list)
 149                                         (list (ivy-state-window ivy-last))))
 150                                (if (eq avy-style 'de-bruijn)
 151                                    (avy-read-de-bruijn
 152                                     candidates avy-keys)
 153                                  (avy-read (avy-tree candidates avy-keys)
 154                                            #'avy--overlay-post
 155                                            #'avy--remove-leading-chars))
 156                              (avy-push-mark))
 157                         (avy--done))))
 158       (if (window-minibuffer-p (cdr candidate))
 159           (progn
 160             (ivy-set-index (- (line-number-at-pos (car candidate)) 2))
 161             (ivy--exhibit)
 162             (ivy-done)
 163             (ivy-call))
 164         (ivy-quit-and-run
 165          (avy-action-goto (caar candidate)))))))
 166
 167 (declare-function mc/create-fake-cursor-at-point "ext:multiple-cursors-core")
 168 (declare-function multiple-cursors-mode "ext:multiple-cursors-core")
 169
 170 ;;;###autoload
 171 (defun swiper-mc ()
 172   (interactive)
 173   (unless (require 'multiple-cursors nil t)
 174     (error "multiple-cursors isn't installed"))
 175   (let ((cands (nreverse ivy--old-cands)))
 176     (unless (string= ivy-text "")
 177       (ivy-exit-with-action
 178        (lambda (_)
 179          (let (cand)
 180            (while (setq cand (pop cands))
 181              (swiper--action cand)
 182              (when cands
 183                (mc/create-fake-cursor-at-point))))
 184          (multiple-cursors-mode 1))))))
 185
 186 (defun swiper-recenter-top-bottom (&optional arg)
 187   "Call (`recenter-top-bottom' ARG)."
 188   (interactive "P")
 189   (with-ivy-window
 190     (recenter-top-bottom arg)))
 191
 192 (defvar swiper-font-lock-exclude
 193   '(package-menu-mode
 194     gnus-summary-mode
 195     gnus-article-mode
 196     gnus-group-mode
 197     emms-playlist-mode
 198     emms-stream-mode
 199     erc-mode
 200     org-agenda-mode
 201     dired-mode
 202     jabber-chat-mode
 203     elfeed-search-mode
 204     elfeed-show-mode
 205     fundamental-mode
 206     Man-mode
 207     woman-mode
 208     mu4e-view-mode
 209     mu4e-headers-mode
 210     help-mode
 211     debbugs-gnu-mode
 212     occur-mode
 213     occur-edit-mode
 214     bongo-mode
 215     bongo-library-mode
 216     bongo-playlist-mode
 217     eww-mode
 218     twittering-mode
 219     vc-dir-mode
 220     rcirc-mode
 221     sauron-mode
 222     w3m-mode)
 223   "List of major-modes that are incompatible with font-lock-ensure.")
 224
 225 (defun swiper-font-lock-ensure-p ()
 226   "Return non-nil if we should font-lock-ensure."
 227   (or (derived-mode-p 'magit-mode)
 228               (bound-and-true-p magit-blame-mode)
 229               (memq major-mode swiper-font-lock-exclude)))
 230
 231 (defun swiper-font-lock-ensure ()
 232   "Ensure the entired buffer is highlighted."
 233   (unless (swiper-font-lock-ensure-p)
 234     (unless (or (> (buffer-size) 100000) (null font-lock-mode))
 235       (if (fboundp 'font-lock-ensure)
 236           (font-lock-ensure)
 237         (with-no-warnings (font-lock-fontify-buffer))))))
 238
 239 (defvar swiper--format-spec ""
 240   "Store the current candidates format spec.")
 241
 242 (defvar swiper--width nil
 243   "Store the number of digits needed for the longest line nubmer.")
 244
 245 (defvar swiper-use-visual-line nil
 246   "When non-nil, use `line-move' instead of `forward-line'.")
 247
 248 (declare-function outline-show-all "outline")
 249
 250 (defun swiper--candidates (&optional numbers-width)
 251   "Return a list of this buffer lines.
 252
 253 NUMBERS-WIDTH, when specified, is used for width spec of line
 254 numbers; replaces calculating the width from buffer line count."
 255   (if (and visual-line-mode
 256            ;; super-slow otherwise
 257            (< (buffer-size) 20000))
 258       (progn
 259         (when (eq major-mode 'org-mode)
 260           (require 'outline)
 261           (if (fboundp 'outline-show-all)
 262               (outline-show-all)
 263             (with-no-warnings
 264               (show-all))))
 265         (setq swiper-use-visual-line t))
 266     (setq swiper-use-visual-line nil))
 267   (let ((n-lines (count-lines (point-min) (point-max))))
 268     (unless (zerop n-lines)
 269       (setq swiper--width (or numbers-width
 270                               (1+ (floor (log n-lines 10)))))
 271       (setq swiper--format-spec
 272             (format "%%-%dd " swiper--width))
 273       (let ((line-number 0)
 274             (advancer (if swiper-use-visual-line
 275                           (lambda (arg) (line-move arg t))
 276                         #'forward-line))
 277             candidates)
 278         (save-excursion
 279           (goto-char (point-min))
 280           (swiper-font-lock-ensure)
 281           (while (< (point) (point-max))
 282             (let ((str (concat
 283                         " "
 284                         (replace-regexp-in-string
 285                          "\t" "    "
 286                          (if swiper-use-visual-line
 287                              (buffer-substring
 288                               (save-excursion
 289                                 (beginning-of-visual-line)
 290                                 (point))
 291                               (save-excursion
 292                                 (end-of-visual-line)
 293                                 (point)))
 294                            (buffer-substring
 295                             (point)
 296                             (line-end-position)))))))
 297               (when (eq major-mode 'twittering-mode)
 298                 (remove-text-properties 0 (length str) '(field) str))
 299               (put-text-property 0 1 'display
 300                                  (format swiper--format-spec
 301                                          (cl-incf line-number))
 302                                  str)
 303               (push str candidates))
 304             (funcall advancer 1))
 305           (nreverse candidates))))))
 306
 307 (defvar swiper--opoint 1
 308   "The point when `swiper' starts.")
 309
 310 ;;;###autoload
 311 (defun swiper (&optional initial-input)
 312   "`isearch' with an overview.
 313 When non-nil, INITIAL-INPUT is the initial search pattern."
 314   (interactive)
 315   (swiper--ivy (swiper--candidates) initial-input))
 316
 317 (declare-function string-trim-right "subr-x")
 318
 319 (defun swiper-occur (&optional revert)
 320   "Generate a custom occur buffer for `swiper'."
 321   (let* ((buffer (ivy-state-buffer ivy-last))
 322          (fname (propertize
 323                  (with-ivy-window
 324                    (file-name-nondirectory
 325                     (buffer-file-name buffer)))
 326                  'face
 327                  'compilation-info))
 328          (cands (mapcar
 329                  (lambda (s)
 330                    (format "%s:%s:%s"
 331                            fname
 332                            (propertize
 333                             (string-trim-right
 334                              (get-text-property 0 'display s))
 335                             'face 'compilation-line-number)
 336                            (substring s 1)))
 337                  (if (null revert)
 338                      ivy--old-cands
 339                    (setq ivy--old-re nil)
 340                    (ivy--filter
 341                     (progn (string-match "\"\\(.*\\)\"" (buffer-name))
 342                            (match-string 1 (buffer-name)))
 343                     (with-current-buffer buffer
 344                       (swiper--candidates)))))))
 345     (unless (eq major-mode 'ivy-occur-grep-mode)
 346       (ivy-occur-grep-mode)
 347       (font-lock-mode -1))
 348     (insert (format "-*- mode:grep; default-directory: %S -*-\n\n\n"
 349                     default-directory))
 350     (insert (format "%d candidates:\n" (length cands)))
 351     (ivy--occur-insert-lines
 352      (mapcar
 353       (lambda (cand) (concat "./" cand))
 354       cands))
 355     (goto-char (point-min))
 356     (forward-line 4)))
 357
 358 (ivy-set-occur 'swiper 'swiper-occur)
 359
 360 (declare-function evil-jumper--set-jump "ext:evil-jumper")
 361
 362 (defvar swiper--current-line nil)
 363 (defvar swiper--current-match-start nil)
 364
 365 (defun swiper--init ()
 366   "Perform initialization common to both completion methods."
 367   (setq swiper--current-line nil)
 368   (setq swiper--current-match-start nil)
 369   (setq swiper--opoint (point))
 370   (when (bound-and-true-p evil-jumper-mode)
 371     (evil-jumper--set-jump)))
 372
 373 (defun swiper--re-builder (str)
 374   "Transform STR into a swiper regex.
 375 This is the regex used in the minibuffer where candidates have
 376 line numbers. For the buffer, use `ivy--regex' instead."
 377   (replace-regexp-in-string
 378    "\t" "    "
 379    (cond
 380      ((equal str "")
 381       "")
 382      ((equal str "^")
 383       (setq ivy--subexps 0)
 384       ".")
 385      ((string-match "^\\^" str)
 386       (setq ivy--old-re "")
 387       (let ((re (ivy--regex-plus (substring str 1))))
 388         (if (zerop ivy--subexps)
 389             (prog1 (format "^ ?\\(%s\\)" re)
 390               (setq ivy--subexps 1))
 391           (format "^ %s" re))))
 392      (t
 393       (ivy--regex-plus str)))))
 394
 395 (defvar swiper-history nil
 396   "History for `swiper'.")
 397
 398 (defvar swiper-invocation-face nil
 399   "The face at the point of invocation of `swiper'.")
 400
 401 (defun swiper--ivy (candidates &optional initial-input)
 402   "Select one of CANDIDATES and move there.
 403 When non-nil, INITIAL-INPUT is the initial search pattern."
 404   (interactive)
 405   (swiper--init)
 406   (setq swiper-invocation-face
 407         (plist-get (text-properties-at (point)) 'face))
 408   (let ((preselect
 409          (if swiper-use-visual-line
 410              (count-screen-lines
 411               (point-min)
 412               (save-excursion (beginning-of-visual-line) (point)))
 413            (1- (line-number-at-pos))))
 414         (minibuffer-allow-text-properties t)
 415         res)
 416     (unwind-protect
 417          (and
 418           (setq res
 419                 (ivy-read
 420                  "Swiper: "
 421                  candidates
 422                  :initial-input initial-input
 423                  :keymap swiper-map
 424                  :preselect preselect
 425                  :require-match t
 426                  :update-fn #'swiper--update-input-ivy
 427                  :unwind #'swiper--cleanup
 428                  :action #'swiper--action
 429                  :re-builder #'swiper--re-builder
 430                  :history 'swiper-history
 431                  :caller 'swiper))
 432           (point))
 433       (unless res
 434         (goto-char swiper--opoint)))))
 435
 436 (defun swiper-toggle-face-matching ()
 437   "Toggle matching only the candidates with `swiper-invocation-face'."
 438   (interactive)
 439   (setf (ivy-state-matcher ivy-last)
 440         (if (ivy-state-matcher ivy-last)
 441             nil
 442           #'swiper--face-matcher))
 443   (setq ivy--old-re nil))
 444
 445 (defun swiper--face-matcher (regexp candidates)
 446   "Return REGEXP-matching CANDIDATES.
 447 Matched candidates should have `swiper-invocation-face'."
 448   (cl-remove-if-not
 449    (lambda (x)
 450      (and
 451       (string-match regexp x)
 452       (let ((s (match-string 0 x))
 453             (i 0))
 454         (while (and (< i (length s))
 455                     (text-property-any
 456                      i (1+ i)
 457                      'face swiper-invocation-face
 458                      s))
 459           (cl-incf i))
 460         (eq i (length s)))))
 461    candidates))
 462
 463 (defun swiper--ensure-visible ()
 464   "Remove overlays hiding point."
 465   (let ((overlays (overlays-at (1- (point))))
 466         ov expose)
 467     (while (setq ov (pop overlays))
 468       (if (and (invisible-p (overlay-get ov 'invisible))
 469                (setq expose (overlay-get ov 'isearch-open-invisible)))
 470           (funcall expose ov)))))
 471
 472 (defvar swiper--overlays nil
 473   "Store overlays.")
 474
 475 (defun swiper--cleanup ()
 476   "Clean up the overlays."
 477   (while swiper--overlays
 478     (delete-overlay (pop swiper--overlays)))
 479   (save-excursion
 480     (goto-char (point-min))
 481     (isearch-clean-overlays)))
 482
 483 (defun swiper--update-input-ivy ()
 484   "Called when `ivy' input is updated."
 485   (with-ivy-window
 486     (swiper--cleanup)
 487     (when (> (length ivy--current) 0)
 488       (let* ((re (replace-regexp-in-string
 489                   "    " "\t"
 490                   (funcall ivy--regex-function ivy-text)))
 491              (re (if (stringp re) re (caar re)))
 492              (str (get-text-property 0 'display ivy--current))
 493              (num (if (string-match "^[0-9]+" str)
 494                       (string-to-number (match-string 0 str))
 495                     0)))
 496         (unless (eq this-command 'ivy-yank-word)
 497           (when (cl-plusp num)
 498             (unless (if swiper--current-line
 499                         (eq swiper--current-line num)
 500                       (eq (line-number-at-pos) num))
 501               (goto-char (point-min))
 502               (if swiper-use-visual-line
 503                   (line-move (1- num))
 504                 (forward-line (1- num))))
 505             (if (and (equal ivy-text "")
 506                      (>= swiper--opoint (line-beginning-position))
 507                      (<= swiper--opoint (line-end-position)))
 508                 (goto-char swiper--opoint)
 509               (if (eq swiper--current-line num)
 510                   (when swiper--current-match-start
 511                     (goto-char swiper--current-match-start))
 512                 (setq swiper--current-line num))
 513               (when (re-search-forward re (line-end-position) t)
 514                 (setq swiper--current-match-start (match-beginning 0))))
 515             (isearch-range-invisible (line-beginning-position)
 516                                      (line-end-position))
 517             (unless (and (>= (point) (window-start))
 518                          (<= (point) (window-end (ivy-state-window ivy-last) t)))
 519               (recenter))))
 520         (swiper--add-overlays re)))))
 521
 522 (defun swiper--add-overlays (re &optional beg end wnd)
 523   "Add overlays for RE regexp in visible part of the current buffer.
 524 BEG and END, when specified, are the point bounds.
 525 WND, when specified is the window."
 526   (setq wnd (or wnd (ivy-state-window ivy-last)))
 527   (let ((ov (if visual-line-mode
 528                 (make-overlay
 529                  (save-excursion
 530                    (beginning-of-visual-line)
 531                    (point))
 532                  (save-excursion
 533                    (end-of-visual-line)
 534                    (point)))
 535               (make-overlay
 536                (line-beginning-position)
 537                (1+ (line-end-position))))))
 538     (overlay-put ov 'face 'swiper-line-face)
 539     (overlay-put ov 'window wnd)
 540     (push ov swiper--overlays)
 541     (let* ((wh (window-height))
 542            (beg (or beg (save-excursion
 543                           (forward-line (- wh))
 544                           (point))))
 545            (end (or end (save-excursion
 546                           (forward-line wh)
 547                           (point)))))
 548       (when (>= (length re) swiper-min-highlight)
 549         (save-excursion
 550           (goto-char beg)
 551           ;; RE can become an invalid regexp
 552           (while (and (ignore-errors (re-search-forward re end t))
 553                       (> (- (match-end 0) (match-beginning 0)) 0))
 554             (let ((i 0))
 555               (while (<= i ivy--subexps)
 556                 (when (match-beginning i)
 557                   (let ((overlay (make-overlay (match-beginning i)
 558                                                (match-end i)))
 559                         (face
 560                          (cond ((zerop ivy--subexps)
 561                                 (cadr swiper-faces))
 562                                ((zerop i)
 563                                 (car swiper-faces))
 564                                (t
 565                                 (nth (1+ (mod (+ i 2) (1- (length swiper-faces))))
 566                                      swiper-faces)))))
 567                     (push overlay swiper--overlays)
 568                     (overlay-put overlay 'face face)
 569                     (overlay-put overlay 'window wnd)
 570                     (overlay-put overlay 'priority i)))
 571                 (cl-incf i)))))))))
 572
 573 (defun swiper--action (x)
 574   "Goto line X."
 575   (let ((ln (1- (read (or (get-text-property 0 'display x)
 576                           (and (string-match ":\\([0-9]+\\):.*\\'" x)
 577                                (match-string-no-properties 1 x))))))
 578         (re (ivy--regex ivy-text)))
 579     (if (null x)
 580         (user-error "No candidates")
 581       (with-ivy-window
 582         (unless (equal (current-buffer)
 583                        (ivy-state-buffer ivy-last))
 584           (switch-to-buffer (ivy-state-buffer ivy-last)))
 585         (goto-char (point-min))
 586         (funcall (if swiper-use-visual-line
 587                      #'line-move
 588                    #'forward-line)
 589                  ln)
 590         (re-search-forward re (line-end-position) t)
 591         (swiper--ensure-visible)
 592         (when (/= (point) swiper--opoint)
 593           (unless (and transient-mark-mode mark-active)
 594             (when (eq ivy-exit 'done)
 595               (push-mark swiper--opoint t)
 596               (message "Mark saved where search started"))))
 597         (add-to-history
 598          'regexp-search-ring
 599          re
 600          regexp-search-ring-max)))))
 601
 602 ;; (define-key isearch-mode-map (kbd "C-o") 'swiper-from-isearch)
 603 (defun swiper-from-isearch ()
 604   "Invoke `swiper' from isearch."
 605   (interactive)
 606   (let ((query (if isearch-regexp
 607                    isearch-string
 608                  (regexp-quote isearch-string))))
 609     (isearch-exit)
 610     (swiper query)))
 611
 612 (defvar swiper-multi-buffers nil
 613   "Store the current list of buffers.")
 614
 615 (defvar swiper-multi-candidates nil
 616   "Store the list of candidates for `swiper-multi'.")
 617
 618 (defun swiper-multi-prompt ()
 619   (format "Buffers (%s): "
 620           (mapconcat #'identity swiper-multi-buffers ", ")))
 621
 622 (defun swiper-multi ()
 623   "Select one or more buffers.
 624 Run `swiper' for those buffers."
 625   (interactive)
 626   (setq swiper-multi-buffers nil)
 627   (ivy-read (swiper-multi-prompt)
 628             'internal-complete-buffer
 629             :action 'swiper-multi-action-1)
 630   (ivy-read "Swiper: " swiper-multi-candidates
 631             :action 'swiper-multi-action-2
 632             :unwind #'swiper--cleanup
 633             :caller 'swiper-multi))
 634
 635 (defun swiper-all ()
 636   "Run `swiper' for all opened buffers."
 637   (interactive)
 638   (ivy-read "Swiper: " (swiper--multi-candidates
 639                         (cl-remove-if-not
 640                          #'buffer-file-name
 641                          (buffer-list)))
 642             :action 'swiper-multi-action-2
 643             :unwind #'swiper--cleanup
 644             :update-fn (lambda ()
 645                          (swiper-multi-action-2 ivy--current))
 646             :caller 'swiper-multi))
 647
 648 (defun swiper--multi-candidates (buffers)
 649   (let* ((ww (window-width))
 650          (res nil)
 651          (column-2 (apply #'max
 652                           (mapcar
 653                            (lambda (b)
 654                              (length (buffer-name b)))
 655                            buffers)))
 656          (column-1 (- ww 4 column-2 1)))
 657     (dolist (buf buffers)
 658       (with-current-buffer buf
 659         (setq res
 660               (append
 661                (mapcar
 662                 (lambda (s)
 663                   (setq s (concat (ivy--truncate-string s column-1) " "))
 664                   (let ((len (length s)))
 665                     (put-text-property
 666                      (1- len) len 'display
 667                      (concat
 668                       (make-string
 669                        (- ww (string-width s) (length (buffer-name)) 3)
 670                        ?\ )
 671                       (buffer-name))
 672                      s)
 673                     s))
 674                 (swiper--candidates 4))
 675                res))
 676         nil))
 677     res))
 678
 679 (defun swiper-multi-action-1 (x)
 680   (if (member x swiper-multi-buffers)
 681       (progn
 682         (setq swiper-multi-buffers (delete x swiper-multi-buffers)))
 683     (unless (equal x "")
 684       (setq swiper-multi-buffers (append swiper-multi-buffers (list x)))))
 685   (let ((prompt (swiper-multi-prompt)))
 686     (setf (ivy-state-prompt ivy-last) prompt)
 687     (setq ivy--prompt (concat "%-4d " prompt)))
 688   (cond ((memq this-command '(ivy-done
 689                               ivy-alt-done
 690                               ivy-immediate-done))
 691          (setq swiper-multi-candidates
 692                (swiper--multi-candidates
 693                 (mapcar #'get-buffer swiper-multi-buffers))))
 694         ((eq this-command 'ivy-call)
 695          (delete-minibuffer-contents))))
 696
 697 (defun swiper-multi-action-2 (x)
 698   (let ((buf-space (get-text-property (1- (length x)) 'display x)))
 699     (with-ivy-window
 700       (when (string-match "\\` *\\([^ ]+\\)\\'" buf-space)
 701         (switch-to-buffer (match-string 1 buf-space))
 702         (goto-char (point-min))
 703         (forward-line (1- (read (get-text-property 0 'display x))))
 704         (re-search-forward
 705          (ivy--regex ivy-text)
 706          (line-end-position) t)
 707         (unless (eq ivy-exit 'done)
 708           (swiper--cleanup)
 709           (swiper--add-overlays (ivy--regex ivy-text)))))))
 710
 711 (provide 'swiper)
 712
 713 ;;; swiper.el ends here