code.delx.au - gnu-emacs-elpa/blob - counsel.el

   1 ;;; counsel.el --- Various completion functions using Ivy -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2015  Free Software Foundation, Inc.
   4
   5 ;; Author: Oleh Krehel <ohwoeowho@gmail.com>
   6 ;; URL: https://github.com/abo-abo/swiper
   7 ;; Package-Requires: ((emacs "24.1") (swiper "0.4.0"))
   8 ;; Keywords: completion, matching
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; This file is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 3, or (at your option)
  15 ;; any later version.
  16
  17 ;; This program is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; For a full copy of the GNU General Public License
  23 ;; see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26 ;;
  27 ;; Just call one of the interactive functions in this file to complete
  28 ;; the corresponding thing using `ivy'.
  29 ;;
  30 ;; Currently available: Elisp symbols, Clojure symbols, Git files.
  31
  32 ;;; Code:
  33
  34 (require 'swiper)
  35 (require 'etags)
  36
  37 ;;* Utility
  38 (defun counsel-more-chars (n)
  39   "Return two fake candidates prompting for at least N input."
  40   (list ""
  41         (format "%d chars more" (- n (length ivy-text)))))
  42
  43 (defun counsel-unquote-regex-parens (str)
  44   (replace-regexp-in-string
  45    "\\\\)" ")"
  46    (replace-regexp-in-string
  47     "\\\\(" "("
  48     str)))
  49
  50 (defun counsel-directory-parent (dir)
  51   "Return the directory parent of directory DIR."
  52   (concat (file-name-nondirectory
  53            (directory-file-name dir)) "/"))
  54
  55 (defun counsel-string-compose (prefix str)
  56   "Make PREFIX the display prefix of STR though text properties."
  57   (let ((str (copy-sequence str)))
  58     (put-text-property
  59      0 1 'display
  60      (concat prefix (substring str 0 1))
  61      str)
  62     str))
  63
  64 ;;* Async Utility
  65 (defvar counsel--async-time nil
  66   "Store the time when a new process was started.
  67 Or the time of the last minibuffer update.")
  68
  69 (defvar counsel-async-split-string-re "\n"
  70   "Store the regexp for splitting shell command output.")
  71
  72 (defun counsel--async-command (cmd &optional process-sentinel process-filter)
  73   (let* ((counsel--process " *counsel*")
  74          (proc (get-process counsel--process))
  75          (buff (get-buffer counsel--process)))
  76     (when proc
  77       (delete-process proc))
  78     (when buff
  79       (kill-buffer buff))
  80     (setq proc (start-process-shell-command
  81                 counsel--process
  82                 counsel--process
  83                 cmd))
  84     (setq counsel--async-time (current-time))
  85     (set-process-sentinel proc (or process-sentinel #'counsel--async-sentinel))
  86     (set-process-filter proc (or process-filter #'counsel--async-filter))))
  87
  88 (defun counsel--async-sentinel (process event)
  89   (if (string= event "finished\n")
  90       (progn
  91         (with-current-buffer (process-buffer process)
  92           (ivy--set-candidates
  93            (ivy--sort-maybe
  94             (split-string
  95              (buffer-string)
  96              counsel-async-split-string-re
  97              t)))
  98           (if (null ivy--old-cands)
  99               (setq ivy--index
 100                     (or (ivy--preselect-index
 101                          (ivy-state-preselect ivy-last)
 102                          ivy--all-candidates)
 103                         0))
 104             (let ((re (funcall ivy--regex-function ivy-text)))
 105               (unless (stringp re)
 106                 (setq re (caar re)))
 107               (ivy--recompute-index
 108                ivy-text re ivy--all-candidates)))
 109           (setq ivy--old-cands ivy--all-candidates))
 110         (if (null ivy--all-candidates)
 111             (ivy--insert-minibuffer "")
 112           (ivy--exhibit)))
 113     (if (string-match "exited abnormally with code \\([0-9]+\\)\n" event)
 114         (progn
 115           (setq ivy--all-candidates (list (format "error code %s" (match-string 1 event))))
 116           (setq ivy--old-cands ivy--all-candidates)
 117           (ivy--exhibit)))))
 118
 119 (defun counsel--async-filter (process str)
 120   "Receive from PROCESS the output STR.
 121 Update the minibuffer with the amount of lines collected every
 122 0.5 seconds since the last update."
 123   (with-current-buffer (process-buffer process)
 124     (insert str))
 125   (let (size)
 126     (when (time-less-p
 127            ;; 0.5s
 128            '(0 0 500000 0)
 129            (time-since counsel--async-time))
 130       (with-current-buffer (process-buffer process)
 131         (goto-char (point-min))
 132         (setq size (- (buffer-size) (forward-line (buffer-size))))
 133         (ivy--set-candidates
 134          (split-string
 135           (buffer-string)
 136           counsel-async-split-string-re
 137           t)))
 138       (let ((ivy--prompt (format
 139                           (concat "%d++ " (ivy-state-prompt ivy-last))
 140                           size)))
 141         (ivy--insert-minibuffer
 142          (ivy--format ivy--all-candidates)))
 143       (setq counsel--async-time (current-time)))))
 144
 145 (defun counsel-delete-process ()
 146   (let ((process (get-process " *counsel*")))
 147     (when process
 148       (delete-process process))))
 149
 150 ;;* Completion at point
 151 ;;** `counsel-el'
 152 ;;;###autoload
 153 (defun counsel-el ()
 154   "Elisp completion at point."
 155   (interactive)
 156   (let* ((bnd (unless (and (looking-at ")")
 157                            (eq (char-before) ?\())
 158                 (bounds-of-thing-at-point
 159                  'symbol)))
 160          (str (if bnd
 161                   (buffer-substring-no-properties
 162                    (car bnd)
 163                    (cdr bnd))
 164                 ""))
 165          (ivy-height 7)
 166          (funp (eq (char-before (car bnd)) ?\())
 167          symbol-names)
 168     (if bnd
 169         (progn
 170           (setq ivy-completion-beg
 171                 (move-marker (make-marker) (car bnd)))
 172           (setq ivy-completion-end
 173                 (move-marker (make-marker) (cdr bnd))))
 174       (setq ivy-completion-beg nil)
 175       (setq ivy-completion-end nil))
 176     (if (string= str "")
 177         (mapatoms
 178          (lambda (x)
 179            (when (symbolp x)
 180              (push (symbol-name x) symbol-names))))
 181       (setq symbol-names
 182             (all-completions str obarray
 183                              (and funp
 184                                   (lambda (x)
 185                                     (or (functionp x)
 186                                         (macrop x)
 187                                         (special-form-p x)))))))
 188     (ivy-read "Symbol name: " symbol-names
 189               :predicate (and funp #'functionp)
 190               :initial-input str
 191               :action #'ivy-completion-in-region-action)))
 192
 193 ;;** `counsel-cl'
 194 (declare-function slime-symbol-start-pos "ext:slime")
 195 (declare-function slime-symbol-end-pos "ext:slime")
 196 (declare-function slime-contextual-completions "ext:slime-c-p-c")
 197
 198 ;;;###autoload
 199 (defun counsel-cl ()
 200   "Common Lisp completion at point."
 201   (interactive)
 202   (setq ivy-completion-beg (slime-symbol-start-pos))
 203   (setq ivy-completion-end (slime-symbol-end-pos))
 204   (ivy-read "Symbol name: "
 205             (car (slime-contextual-completions
 206                   ivy-completion-beg
 207                   ivy-completion-end))
 208             :action #'ivy-completion-in-region-action))
 209
 210 ;;** `counsel-jedi'
 211 (declare-function deferred:sync! "ext:deferred")
 212 (declare-function jedi:complete-request "ext:jedi-core")
 213 (declare-function jedi:ac-direct-matches "ext:jedi")
 214
 215 (defun counsel-jedi ()
 216   "Python completion at point."
 217   (interactive)
 218   (let ((bnd (bounds-of-thing-at-point 'symbol)))
 219     (if bnd
 220         (progn
 221           (setq ivy-completion-beg (car bnd))
 222           (setq ivy-completion-end (cdr bnd)))
 223       (setq ivy-completion-beg nil)
 224       (setq ivy-completion-end nil)))
 225   (deferred:sync!
 226       (jedi:complete-request))
 227   (ivy-read "Symbol name: " (jedi:ac-direct-matches)
 228             :action #'counsel--py-action))
 229
 230 (defun counsel--py-action (symbol)
 231   "Insert SYMBOL, erasing the previous one."
 232   (when (stringp symbol)
 233     (with-ivy-window
 234       (when ivy-completion-beg
 235         (delete-region
 236          ivy-completion-beg
 237          ivy-completion-end))
 238       (setq ivy-completion-beg
 239             (move-marker (make-marker) (point)))
 240       (insert symbol)
 241       (setq ivy-completion-end
 242             (move-marker (make-marker) (point)))
 243       (when (equal (get-text-property 0 'symbol symbol) "f")
 244         (insert "()")
 245         (setq ivy-completion-end
 246               (move-marker (make-marker) (point)))
 247         (backward-char 1)))))
 248
 249 ;;** `counsel-clj'
 250 (declare-function cider-sync-request:complete "ext:cider-client")
 251 (defun counsel--generic (completion-fn)
 252   "Complete thing at point with COMPLETION-FN."
 253   (let* ((bnd (or (bounds-of-thing-at-point 'symbol)
 254                   (cons (point) (point))))
 255          (str (buffer-substring-no-properties
 256                (car bnd) (cdr bnd)))
 257          (candidates (funcall completion-fn str))
 258          (ivy-height 7)
 259          (res (ivy-read (format "pattern (%s): " str)
 260                         candidates)))
 261     (when (stringp res)
 262       (when bnd
 263         (delete-region (car bnd) (cdr bnd)))
 264       (insert res))))
 265
 266 ;;;###autoload
 267 (defun counsel-clj ()
 268   "Clojure completion at point."
 269   (interactive)
 270   (counsel--generic
 271    (lambda (str)
 272      (mapcar
 273       #'cl-caddr
 274       (cider-sync-request:complete str ":same")))))
 275
 276 ;;** `counsel-unicode-char'
 277 (defvar counsel-unicode-char-history nil
 278   "History for `counsel-unicode-char'.")
 279
 280 ;;;###autoload
 281 (defun counsel-unicode-char ()
 282   "Insert a Unicode character at point."
 283   (interactive)
 284   (let ((minibuffer-allow-text-properties t))
 285     (setq ivy-completion-beg (point))
 286     (setq ivy-completion-end (point))
 287     (ivy-read "Unicode name: "
 288               (mapcar (lambda (x)
 289                         (propertize
 290                          (format "% -6X% -60s%c" (cdr x) (car x) (cdr x))
 291                          'result (cdr x)))
 292                       (ucs-names))
 293               :action (lambda (char)
 294                         (with-ivy-window
 295                           (delete-region ivy-completion-beg ivy-completion-end)
 296                           (setq ivy-completion-beg (point))
 297                           (insert-char (get-text-property 0 'result char))
 298                           (setq ivy-completion-end (point))))
 299               :history 'counsel-unicode-char-history)))
 300
 301 ;;* Elisp symbols
 302 ;;** `counsel-describe-variable'
 303 (defvar counsel-describe-map
 304   (let ((map (make-sparse-keymap)))
 305     (define-key map (kbd "C-.") #'counsel-find-symbol)
 306     (define-key map (kbd "C-,") #'counsel--info-lookup-symbol)
 307     map))
 308
 309 (ivy-set-actions
 310  'counsel-describe-variable
 311  '(("i" counsel-info-lookup-symbol "info")
 312    ("d" counsel--find-symbol "definition")))
 313
 314 (defvar counsel-describe-symbol-history nil
 315   "History for `counsel-describe-variable' and `counsel-describe-function'.")
 316
 317 (defun counsel-find-symbol ()
 318   "Jump to the definition of the current symbol."
 319   (interactive)
 320   (ivy-exit-with-action #'counsel--find-symbol))
 321
 322 (defun counsel--info-lookup-symbol ()
 323   "Lookup the current symbol in the info docs."
 324   (interactive)
 325   (ivy-exit-with-action #'counsel-info-lookup-symbol))
 326
 327 (defun counsel--find-symbol (x)
 328   "Find symbol definition that corresponds to string X."
 329   (with-ivy-window
 330     (with-no-warnings
 331       (ring-insert find-tag-marker-ring (point-marker)))
 332     (let ((full-name (get-text-property 0 'full-name x)))
 333       (if full-name
 334           (find-library full-name)
 335         (let ((sym (read x)))
 336           (cond ((and (eq (ivy-state-caller ivy-last)
 337                           'counsel-describe-variable)
 338                       (boundp sym))
 339                  (find-variable sym))
 340                 ((fboundp sym)
 341                  (find-function sym))
 342                 ((boundp sym)
 343                  (find-variable sym))
 344                 ((or (featurep sym)
 345                      (locate-library
 346                       (prin1-to-string sym)))
 347                  (find-library
 348                   (prin1-to-string sym)))
 349                 (t
 350                  (error "Couldn't fild definition of %s"
 351                         sym))))))))
 352
 353 (define-obsolete-function-alias 'counsel-symbol-at-point
 354     'ivy-thing-at-point "0.7.0")
 355
 356 (defun counsel-variable-list ()
 357   "Return the list of all currently bound variables."
 358   (let (cands)
 359     (mapatoms
 360      (lambda (vv)
 361        (when (or (get vv 'variable-documentation)
 362                  (and (boundp vv) (not (keywordp vv))))
 363          (push (symbol-name vv) cands))))
 364     cands))
 365
 366 ;;;###autoload
 367 (defun counsel-describe-variable ()
 368   "Forward to `describe-variable'."
 369   (interactive)
 370   (let ((enable-recursive-minibuffers t))
 371     (ivy-read
 372      "Describe variable: "
 373      (counsel-variable-list)
 374      :keymap counsel-describe-map
 375      :preselect (ivy-thing-at-point)
 376      :history 'counsel-describe-symbol-history
 377      :require-match t
 378      :sort t
 379      :action (lambda (x)
 380                (describe-variable
 381                 (intern x)))
 382      :caller 'counsel-describe-variable)))
 383
 384 ;;** `counsel-describe-function'
 385 (ivy-set-actions
 386  'counsel-describe-function
 387  '(("i" counsel-info-lookup-symbol "info")
 388    ("d" counsel--find-symbol "definition")))
 389
 390 ;;;###autoload
 391 (defun counsel-describe-function ()
 392   "Forward to `describe-function'."
 393   (interactive)
 394   (let ((enable-recursive-minibuffers t))
 395     (ivy-read "Describe function: "
 396               (let (cands)
 397                 (mapatoms
 398                  (lambda (x)
 399                    (when (fboundp x)
 400                      (push (symbol-name x) cands))))
 401                 cands)
 402               :keymap counsel-describe-map
 403               :preselect (ivy-thing-at-point)
 404               :history 'counsel-describe-symbol-history
 405               :require-match t
 406               :sort t
 407               :action (lambda (x)
 408                         (describe-function
 409                          (intern x)))
 410               :caller 'counsel-describe-function)))
 411
 412 ;;** `counsel-info-lookup-symbol'
 413 (defvar info-lookup-mode)
 414 (declare-function info-lookup->completions "info-look")
 415 (declare-function info-lookup->mode-value "info-look")
 416 (declare-function info-lookup-select-mode "info-look")
 417 (declare-function info-lookup-change-mode "info-look")
 418 (declare-function info-lookup "info-look")
 419
 420 ;;;###autoload
 421 (defun counsel-info-lookup-symbol (symbol &optional mode)
 422   "Forward to (`info-describe-symbol' SYMBOL MODE) with ivy completion."
 423   (interactive
 424    (progn
 425      (require 'info-look)
 426      (let* ((topic 'symbol)
 427             (mode (cond (current-prefix-arg
 428                          (info-lookup-change-mode topic))
 429                         ((info-lookup->mode-value
 430                           topic (info-lookup-select-mode))
 431                          info-lookup-mode)
 432                         ((info-lookup-change-mode topic))))
 433             (completions (info-lookup->completions topic mode))
 434             (enable-recursive-minibuffers t)
 435             (value (ivy-read
 436                     "Describe symbol: "
 437                     (mapcar #'car completions)
 438                     :sort t)))
 439        (list value info-lookup-mode))))
 440   (require 'info-look)
 441   (info-lookup 'symbol symbol mode))
 442
 443 ;;** `counsel-M-x'
 444 (ivy-set-actions
 445  'counsel-M-x
 446  '(("d" counsel--find-symbol "definition")))
 447
 448 (ivy-set-display-transformer
 449  'counsel-M-x
 450  'counsel-M-x-transformer)
 451
 452 (defun counsel-M-x-transformer (cmd)
 453   "Return CMD appended with the corresponding binding in the current window."
 454   (let ((binding (substitute-command-keys (format "\\[%s]" cmd))))
 455     (setq binding (replace-regexp-in-string "C-x 6" "<f2>" binding))
 456     (if (string-match "^M-x" binding)
 457         cmd
 458       (format "%s (%s)"
 459               cmd (propertize binding 'face 'font-lock-keyword-face)))))
 460
 461 (defvar smex-initialized-p)
 462 (defvar smex-ido-cache)
 463 (declare-function smex-initialize "ext:smex")
 464 (declare-function smex-detect-new-commands "ext:smex")
 465 (declare-function smex-update "ext:smex")
 466 (declare-function smex-rank "ext:smex")
 467
 468 (defun counsel--M-x-prompt ()
 469   "M-x plus the string representation of `current-prefix-arg'."
 470   (if (not current-prefix-arg)
 471       "M-x "
 472     (concat
 473      (if (eq current-prefix-arg '-)
 474          "- "
 475        (if (integerp current-prefix-arg)
 476            (format "%d " current-prefix-arg)
 477          (if (= (car current-prefix-arg) 4)
 478              "C-u "
 479            (format "%d " (car current-prefix-arg)))))
 480      "M-x ")))
 481
 482 ;;;###autoload
 483 (defun counsel-M-x (&optional initial-input)
 484   "Ivy version of `execute-extended-command'.
 485 Optional INITIAL-INPUT is the initial input in the minibuffer."
 486   (interactive)
 487   (unless initial-input
 488     (setq initial-input (cdr (assoc this-command
 489                                     ivy-initial-inputs-alist))))
 490   (let* ((cands obarray)
 491          (pred 'commandp)
 492          (sort t))
 493     (when (require 'smex nil 'noerror)
 494       (unless smex-initialized-p
 495         (smex-initialize))
 496       (smex-detect-new-commands)
 497       (smex-update)
 498       (setq cands smex-ido-cache)
 499       (setq pred nil)
 500       (setq sort nil))
 501     (ivy-read (counsel--M-x-prompt) cands
 502               :predicate pred
 503               :require-match t
 504               :history 'extended-command-history
 505               :action
 506               (lambda (cmd)
 507                 (when (featurep 'smex)
 508                   (smex-rank (intern cmd)))
 509                 (let ((prefix-arg current-prefix-arg)
 510                       (this-command (intern cmd)))
 511                   (command-execute (intern cmd) 'record)))
 512               :sort sort
 513               :keymap counsel-describe-map
 514               :initial-input initial-input
 515               :caller 'counsel-M-x)))
 516
 517 ;;** `counsel-load-library'
 518 ;;;###autoload
 519 (defun counsel-load-library ()
 520   "Load a selected the Emacs Lisp library.
 521 The libraries are offered from `load-path'."
 522   (interactive)
 523   (let ((dirs load-path)
 524         (suffix (concat (regexp-opt '(".el" ".el.gz") t) "\\'"))
 525         (cands (make-hash-table :test #'equal))
 526         short-name
 527         old-val
 528         dir-parent
 529         res)
 530     (dolist (dir dirs)
 531       (when (file-directory-p dir)
 532         (dolist (file (file-name-all-completions "" dir))
 533           (when (string-match suffix file)
 534             (unless (string-match "pkg.elc?$" file)
 535               (setq short-name (substring file 0 (match-beginning 0)))
 536               (if (setq old-val (gethash short-name cands))
 537                   (progn
 538                     ;; assume going up directory once will resolve name clash
 539                     (setq dir-parent (counsel-directory-parent (cdr old-val)))
 540                     (puthash short-name
 541                              (cons
 542                               (counsel-string-compose dir-parent (car old-val))
 543                               (cdr old-val))
 544                              cands)
 545                     (setq dir-parent (counsel-directory-parent dir))
 546                     (puthash (concat dir-parent short-name)
 547                              (cons
 548                               (propertize
 549                                (counsel-string-compose
 550                                 dir-parent short-name)
 551                                'full-name (expand-file-name file dir))
 552                               dir)
 553                              cands))
 554                 (puthash short-name
 555                          (cons (propertize
 556                                 short-name
 557                                 'full-name (expand-file-name file dir))
 558                                dir) cands)))))))
 559     (maphash (lambda (_k v) (push (car v) res)) cands)
 560     (ivy-read "Load library: " (nreverse res)
 561               :action (lambda (x)
 562                         (load-library
 563                          (get-text-property 0 'full-name x)))
 564               :keymap counsel-describe-map)))
 565
 566 ;;** `counsel-load-theme'
 567 (declare-function powerline-reset "ext:powerline")
 568
 569 (defun counsel-load-theme-action (x)
 570   "Disable current themes and load theme X."
 571   (condition-case nil
 572       (progn
 573         (mapc #'disable-theme custom-enabled-themes)
 574         (load-theme (intern x))
 575         (when (fboundp 'powerline-reset)
 576           (powerline-reset)))
 577     (error "Problem loading theme %s" x)))
 578
 579 ;;;###autoload
 580 (defun counsel-load-theme ()
 581   "Forward to `load-theme'.
 582 Usable with `ivy-resume', `ivy-next-line-and-call' and
 583 `ivy-previous-line-and-call'."
 584   (interactive)
 585   (ivy-read "Load custom theme: "
 586             (mapcar 'symbol-name
 587                     (custom-available-themes))
 588             :action #'counsel-load-theme-action
 589             :caller 'counsel-load-theme))
 590
 591 ;;** `counsel-descbinds'
 592 (ivy-set-actions
 593  'counsel-descbinds
 594  '(("d" counsel-descbinds-action-find "definition")
 595    ("i" counsel-descbinds-action-info "info")))
 596
 597 (defvar counsel-descbinds-history nil
 598   "History for `counsel-descbinds'.")
 599
 600 (defun counsel--descbinds-cands ()
 601   (let ((buffer (current-buffer))
 602         (re-exclude (regexp-opt
 603                      '("<vertical-line>" "<bottom-divider>" "<right-divider>"
 604                        "<mode-line>" "<C-down-mouse-2>" "<left-fringe>"
 605                        "<right-fringe>" "<header-line>"
 606                        "<vertical-scroll-bar>" "<horizontal-scroll-bar>")))
 607         res)
 608     (with-temp-buffer
 609       (let ((indent-tabs-mode t))
 610         (describe-buffer-bindings buffer))
 611       (goto-char (point-min))
 612       ;; Skip the "Key translations" section
 613       (re-search-forward "\f")
 614       (forward-char 1)
 615       (while (not (eobp))
 616         (when (looking-at "^\\([^\t\n]+\\)\t+\\(.*\\)$")
 617           (let ((key (match-string 1))
 618                 (fun (match-string 2))
 619                 cmd)
 620             (unless (or (member fun '("??" "self-insert-command"))
 621                         (string-match re-exclude key)
 622                         (not (or (commandp (setq cmd (intern-soft fun)))
 623                                  (member fun '("Prefix Command")))))
 624               (push
 625                (cons (format
 626                       "%-15s %s"
 627                       (propertize key 'face 'font-lock-builtin-face)
 628                       fun)
 629                      (cons key cmd))
 630                res))))
 631         (forward-line 1)))
 632     (nreverse res)))
 633
 634 (defun counsel-descbinds-action-describe (x)
 635   (let ((cmd (cdr x)))
 636     (describe-function cmd)))
 637
 638 (defun counsel-descbinds-action-find (x)
 639   (let ((cmd (cdr x)))
 640     (counsel--find-symbol (symbol-name cmd))))
 641
 642 (defun counsel-descbinds-action-info (x)
 643   (let ((cmd (cdr x)))
 644     (counsel-info-lookup-symbol (symbol-name cmd))))
 645
 646 ;;;###autoload
 647 (defun counsel-descbinds ()
 648   "Show a list of all defined keys, and their definitions.
 649 Describe the selected candidate."
 650   (interactive)
 651   (ivy-read "Bindings: " (counsel--descbinds-cands)
 652             :action #'counsel-descbinds-action-describe
 653             :history 'counsel-descbinds-history
 654             :caller 'counsel-descbinds))
 655 ;;* Git
 656 ;;** `counsel-git'
 657 (defvar counsel--git-dir nil
 658   "Store the base git directory.")
 659
 660 ;;;###autoload
 661 (defun counsel-git ()
 662   "Find file in the current Git repository."
 663   (interactive)
 664   (setq counsel--git-dir (expand-file-name
 665                           (locate-dominating-file
 666                            default-directory ".git")))
 667   (let* ((default-directory counsel--git-dir)
 668          (cands (split-string
 669                  (shell-command-to-string
 670                   "git ls-files --full-name --")
 671                  "\n"
 672                  t)))
 673     (ivy-read "Find file: " cands
 674               :action #'counsel-git-action)))
 675
 676 (defun counsel-git-action (x)
 677   (with-ivy-window
 678     (let ((default-directory counsel--git-dir))
 679       (find-file x))))
 680
 681 ;;** `counsel-git-grep'
 682 (defvar counsel-git-grep-map
 683   (let ((map (make-sparse-keymap)))
 684     (define-key map (kbd "C-l") 'counsel-git-grep-recenter)
 685     (define-key map (kbd "M-q") 'counsel-git-grep-query-replace)
 686     map))
 687
 688 (ivy-set-occur 'counsel-git-grep 'counsel-git-grep-occur)
 689
 690 (defvar counsel-git-grep-cmd "git --no-pager grep --full-name -n --no-color -i -e %S"
 691   "Store the command for `counsel-git-grep'.")
 692
 693 (defvar counsel--git-grep-dir nil
 694   "Store the base git directory.")
 695
 696 (defvar counsel--git-grep-count nil
 697   "Store the line count in current repository.")
 698
 699 (defvar counsel-git-grep-history nil
 700   "History for `counsel-git-grep'.")
 701
 702 (defvar counsel-git-grep-cmd-history
 703   '("git --no-pager grep --full-name -n --no-color -i -e %S")
 704   "History for `counsel-git-grep' shell commands.")
 705
 706 (defun counsel-git-grep-function (string &optional _pred &rest _unused)
 707   "Grep in the current git repository for STRING."
 708   (if (and (> counsel--git-grep-count 20000)
 709            (< (length string) 3))
 710       (counsel-more-chars 3)
 711     (let* ((default-directory counsel--git-grep-dir)
 712            (cmd (format counsel-git-grep-cmd
 713                         (setq ivy--old-re (ivy--regex string t)))))
 714       (if (<= counsel--git-grep-count 20000)
 715           (split-string (shell-command-to-string cmd) "\n" t)
 716         (counsel--gg-candidates (ivy--regex string))
 717         nil))))
 718
 719 (defun counsel-git-grep-action (x)
 720   (when (string-match "\\`\\(.*?\\):\\([0-9]+\\):\\(.*\\)\\'" x)
 721     (with-ivy-window
 722       (let ((file-name (match-string-no-properties 1 x))
 723             (line-number (match-string-no-properties 2 x)))
 724         (find-file (expand-file-name file-name counsel--git-grep-dir))
 725         (goto-char (point-min))
 726         (forward-line (1- (string-to-number line-number)))
 727         (re-search-forward (ivy--regex ivy-text t) (line-end-position) t)
 728         (unless (eq ivy-exit 'done)
 729           (swiper--cleanup)
 730           (swiper--add-overlays (ivy--regex ivy-text)))))))
 731
 732 (defun counsel-git-grep-matcher (regexp candidates)
 733   (or (and (equal regexp ivy--old-re)
 734            ivy--old-cands)
 735       (prog1
 736           (setq ivy--old-cands
 737                 (cl-remove-if-not
 738                  (lambda (x)
 739                    (ignore-errors
 740                      (when (string-match "^[^:]+:[^:]+:" x)
 741                        (setq x (substring x (match-end 0)))
 742                        (if (stringp regexp)
 743                            (string-match regexp x)
 744                          (let ((res t))
 745                            (dolist (re regexp)
 746                              (setq res
 747                                    (and res
 748                                         (ignore-errors
 749                                           (if (cdr re)
 750                                               (string-match (car re) x)
 751                                             (not (string-match (car re) x)))))))
 752                            res)))))
 753                  candidates))
 754         (setq ivy--old-re regexp))))
 755
 756 ;;;###autoload
 757 (defun counsel-git-grep (&optional cmd initial-input)
 758   "Grep for a string in the current git repository.
 759 When CMD is a string, use it as a \"git grep\" command.
 760 When CMD is non-nil, prompt for a specific \"git grep\" command.
 761 INITIAL-INPUT can be given as the initial minibuffer input."
 762   (interactive "P")
 763   (cond
 764     ((stringp cmd)
 765      (setq counsel-git-grep-cmd cmd))
 766     (cmd
 767      (setq counsel-git-grep-cmd
 768            (ivy-read "cmd: " counsel-git-grep-cmd-history
 769                      :history 'counsel-git-grep-cmd-history))
 770      (setq counsel-git-grep-cmd-history
 771            (delete-dups counsel-git-grep-cmd-history)))
 772     (t
 773      (setq counsel-git-grep-cmd "git --no-pager grep --full-name -n --no-color -i -e %S")))
 774   (setq counsel--git-grep-dir
 775         (locate-dominating-file default-directory ".git"))
 776   (if (null counsel--git-grep-dir)
 777       (error "Not in a git repository")
 778     (setq counsel--git-grep-count (counsel--gg-count "" t))
 779     (ivy-read "git grep: " 'counsel-git-grep-function
 780               :initial-input initial-input
 781               :matcher #'counsel-git-grep-matcher
 782               :dynamic-collection (> counsel--git-grep-count 20000)
 783               :keymap counsel-git-grep-map
 784               :action #'counsel-git-grep-action
 785               :unwind #'swiper--cleanup
 786               :history 'counsel-git-grep-history
 787               :caller 'counsel-git-grep)))
 788
 789 (defvar counsel-gg-state nil
 790   "The current state of candidates / count sync.")
 791
 792 (defun counsel--gg-candidates (regex)
 793   "Return git grep candidates for REGEX."
 794   (setq counsel-gg-state -2)
 795   (counsel--gg-count regex)
 796   (let* ((default-directory counsel--git-grep-dir)
 797          (counsel-gg-process " *counsel-gg*")
 798          (proc (get-process counsel-gg-process))
 799          (buff (get-buffer counsel-gg-process)))
 800     (when proc
 801       (delete-process proc))
 802     (when buff
 803       (kill-buffer buff))
 804     (setq proc (start-process-shell-command
 805                 counsel-gg-process
 806                 counsel-gg-process
 807                 (concat
 808                  (format counsel-git-grep-cmd regex)
 809                  " | head -n 200")))
 810     (set-process-sentinel
 811      proc
 812      #'counsel--gg-sentinel)))
 813
 814 (defun counsel--gg-sentinel (process event)
 815   (if (string= event "finished\n")
 816       (progn
 817         (with-current-buffer (process-buffer process)
 818           (setq ivy--all-candidates
 819                 (or (split-string (buffer-string) "\n" t)
 820                     '("")))
 821           (setq ivy--old-cands ivy--all-candidates))
 822         (when (= 0 (cl-incf counsel-gg-state))
 823           (ivy--exhibit)))
 824     (if (string= event "exited abnormally with code 1\n")
 825         (progn
 826           (setq ivy--all-candidates '("Error"))
 827           (setq ivy--old-cands ivy--all-candidates)
 828           (ivy--exhibit)))))
 829
 830 (defun counsel--gg-count (regex &optional no-async)
 831   "Quickly and asynchronously count the amount of git grep REGEX matches.
 832 When NO-ASYNC is non-nil, do it synchronously."
 833   (let ((default-directory counsel--git-grep-dir)
 834         (cmd
 835          (concat
 836           (format
 837            (replace-regexp-in-string
 838             "--full-name" "-c"
 839             counsel-git-grep-cmd)
 840            ;; "git grep -i -c '%s'"
 841            (replace-regexp-in-string
 842             "-" "\\\\-"
 843             (replace-regexp-in-string "'" "''" regex)))
 844           " | sed 's/.*:\\(.*\\)/\\1/g' | awk '{s+=$1} END {print s}'"))
 845         (counsel-ggc-process " *counsel-gg-count*"))
 846     (if no-async
 847         (string-to-number (shell-command-to-string cmd))
 848       (let ((proc (get-process counsel-ggc-process))
 849             (buff (get-buffer counsel-ggc-process)))
 850         (when proc
 851           (delete-process proc))
 852         (when buff
 853           (kill-buffer buff))
 854         (setq proc (start-process-shell-command
 855                     counsel-ggc-process
 856                     counsel-ggc-process
 857                     cmd))
 858         (set-process-sentinel
 859          proc
 860          #'(lambda (process event)
 861              (when (string= event "finished\n")
 862                (with-current-buffer (process-buffer process)
 863                  (setq ivy--full-length (string-to-number (buffer-string))))
 864                (when (= 0 (cl-incf counsel-gg-state))
 865                  (ivy--exhibit)))))))))
 866
 867 (defun counsel-git-grep-occur ()
 868   "Generate a custom occur buffer for `counsel-git-grep'."
 869   (ivy-occur-grep-mode)
 870   (setq default-directory counsel--git-grep-dir)
 871   (let ((cands (split-string
 872                 (shell-command-to-string
 873                  (format counsel-git-grep-cmd
 874                          (if (stringp ivy--old-re)
 875                              ivy--old-re
 876                            (caar ivy--old-re))))
 877                 "\n"
 878                 t)))
 879     ;; Need precise number of header lines for `wgrep' to work.
 880     (insert (format "-*- mode:grep; default-directory: %S -*-\n\n\n"
 881                     default-directory))
 882     (insert (format "%d candidates:\n" (length cands)))
 883     (ivy--occur-insert-lines
 884      (mapcar
 885       (lambda (cand) (concat "./" cand))
 886       cands))))
 887
 888 (defun counsel-git-grep-query-replace ()
 889   "Start `query-replace' with string to replace from last search string."
 890   (interactive)
 891   (if (null (window-minibuffer-p))
 892       (user-error
 893        "Should only be called in the minibuffer through `counsel-git-grep-map'")
 894     (let* ((enable-recursive-minibuffers t)
 895            (from (ivy--regex ivy-text))
 896            (to (query-replace-read-to from "Query replace" t)))
 897       (ivy-exit-with-action
 898        (lambda (_)
 899          (let (done-buffers)
 900            (dolist (cand ivy--old-cands)
 901              (when (string-match "\\`\\(.*?\\):\\([0-9]+\\):\\(.*\\)\\'" cand)
 902                (with-ivy-window
 903                  (let ((file-name (match-string-no-properties 1 cand)))
 904                    (setq file-name (expand-file-name file-name counsel--git-grep-dir))
 905                    (unless (member file-name done-buffers)
 906                      (push file-name done-buffers)
 907                      (find-file file-name)
 908                      (goto-char (point-min)))
 909                    (perform-replace from to t t nil)))))))))))
 910
 911 (defun counsel-git-grep-recenter ()
 912   (interactive)
 913   (with-ivy-window
 914     (counsel-git-grep-action ivy--current)
 915     (recenter-top-bottom)))
 916
 917 ;;** `counsel-git-stash'
 918 (defun counsel-git-stash-kill-action (x)
 919   (when (string-match "\\([^:]+\\):" x)
 920     (kill-new (message (format "git stash apply %s" (match-string 1 x))))))
 921
 922 ;;;###autoload
 923 (defun counsel-git-stash ()
 924   "Search through all available git stashes."
 925   (interactive)
 926   (let ((dir (locate-dominating-file default-directory ".git")))
 927     (if (null dir)
 928         (error "Not in a git repository")
 929       (let ((cands (split-string (shell-command-to-string
 930                                   "IFS=$'\n'
 931 for i in `git stash list --format=\"%gd\"`; do
 932     git stash show -p $i | grep -H --label=\"$i\" \"$1\"
 933 done") "\n" t)))
 934         (ivy-read "git stash: " cands
 935                   :action 'counsel-git-stash-kill-action
 936                   :caller 'counsel-git-stash)))))
 937 ;;* File
 938 ;;** `counsel-find-file'
 939 (defvar counsel-find-file-map
 940   (let ((map (make-sparse-keymap)))
 941     (define-key map (kbd "C-DEL") 'counsel-up-directory)
 942     (define-key map (kbd "C-<backspace>") 'counsel-up-directory)
 943     map))
 944
 945 (add-to-list 'ivy-ffap-url-functions 'counsel-github-url-p)
 946 (add-to-list 'ivy-ffap-url-functions 'counsel-emacs-url-p)
 947
 948 (defcustom counsel-find-file-at-point nil
 949   "When non-nil, add file-at-point to the list of candidates."
 950   :type 'boolean
 951   :group 'ivy)
 952
 953 (defcustom counsel-find-file-ignore-regexp nil
 954   "A regexp of files to ignore while in `counsel-find-file'.
 955 These files are un-ignored if `ivy-text' matches them.
 956 The common way to show all files is to start `ivy-text' with a dot.
 957 Possible value: \"\\(?:\\`[#.]\\)\\|\\(?:[#~]\\'\\)\"."
 958   :group 'ivy
 959   :type '(choice
 960           (const :tag "None" nil)
 961           (regexp :tag "Regex")))
 962
 963 (defun counsel--find-file-matcher (regexp candidates)
 964   "Return REGEXP-matching CANDIDATES.
 965 Skip some dotfiles unless `ivy-text' requires them."
 966   (let ((res (ivy--re-filter regexp candidates)))
 967     (if (or (null ivy-use-ignore)
 968             (null counsel-find-file-ignore-regexp)
 969             (string-match counsel-find-file-ignore-regexp ivy-text))
 970         res
 971       (or (cl-remove-if
 972            (lambda (x)
 973              (string-match counsel-find-file-ignore-regexp x))
 974            res)
 975           res))))
 976
 977 (declare-function ffap-guesser "ffap")
 978
 979 ;;;###autoload
 980 (defun counsel-find-file (&optional initial-input)
 981   "Forward to `find-file'.
 982 When INITIAL-INPUT is non-nil, use it in the minibuffer during completion."
 983   (interactive)
 984   (ivy-read "Find file: " 'read-file-name-internal
 985             :matcher #'counsel--find-file-matcher
 986             :initial-input initial-input
 987             :action
 988             (lambda (x)
 989               (with-ivy-window
 990                 (find-file (expand-file-name x ivy--directory))))
 991             :preselect (when counsel-find-file-at-point
 992                          (require 'ffap)
 993                          (ffap-guesser))
 994             :require-match 'confirm-after-completion
 995             :history 'file-name-history
 996             :keymap counsel-find-file-map))
 997
 998 (defun counsel-up-directory ()
 999   "Go to the parent directory preselecting the current one."
1000   (interactive)
1001   (let ((dir-file-name
1002          (directory-file-name (expand-file-name ivy--directory))))
1003     (ivy--cd (file-name-directory dir-file-name))
1004     (setf (ivy-state-preselect ivy-last)
1005           (file-name-as-directory (file-name-nondirectory dir-file-name)))))
1006
1007 (defun counsel-at-git-issue-p ()
1008   "Whe point is at an issue in a Git-versioned file, return the issue string."
1009   (and (looking-at "#[0-9]+")
1010        (or
1011         (eq (vc-backend (buffer-file-name)) 'Git)
1012         (memq major-mode '(magit-commit-mode)))
1013        (match-string-no-properties 0)))
1014
1015 (defun counsel-github-url-p ()
1016   "Return a Github issue URL at point."
1017   (let ((url (counsel-at-git-issue-p)))
1018     (when url
1019       (let ((origin (shell-command-to-string
1020                      "git remote get-url origin"))
1021             user repo)
1022         (cond ((string-match "\\`git@github.com:\\([^/]+\\)/\\(.*\\)\\.git$"
1023                              origin)
1024                (setq user (match-string 1 origin))
1025                (setq repo (match-string 2 origin)))
1026               ((string-match "\\`https://github.com/\\([^/]+\\)/\\(.*\\)$"
1027                              origin)
1028                (setq user (match-string 1 origin))
1029                (setq repo (match-string 2 origin))))
1030         (when user
1031           (setq url (format "https://github.com/%s/%s/issues/%s"
1032                             user repo (substring url 1))))))))
1033
1034 (defun counsel-emacs-url-p ()
1035   "Return a Debbugs issue URL at point."
1036   (let ((url (counsel-at-git-issue-p)))
1037     (when url
1038       (let ((origin (shell-command-to-string
1039                      "git remote get-url origin")))
1040         (when (string-match "git.sv.gnu.org:/srv/git/emacs.git" origin)
1041           (format "http://debbugs.gnu.org/cgi/bugreport.cgi?bug=%s"
1042                   (substring url 1)))))))
1043
1044 ;;** `counsel-locate'
1045 (defcustom counsel-locate-options nil
1046   "Command line options for `locate`."
1047   :group 'ivy
1048   :type '(repeat string))
1049
1050 (make-obsolete-variable 'counsel-locate-options 'counsel-locate-cmd "0.7.0")
1051
1052 (defcustom counsel-locate-cmd (if (eq system-type 'darwin)
1053                                   'counsel-locate-cmd-noregex
1054                                 'counsel-locate-cmd-default)
1055   "The function for producing a locate command string from the input.
1056
1057 The function takes a string - the current input, and returns a
1058 string - the full shell command to run."
1059   :group 'ivy
1060   :type '(choice
1061           (const :tag "Default" counsel-locate-cmd-default)
1062           (const :tag "No regex" counsel-locate-cmd-noregex)
1063           (const :tag "mdfind" counsel-locate-cmd-mdfind)))
1064
1065 (ivy-set-actions
1066  'counsel-locate
1067  '(("x" counsel-locate-action-extern "xdg-open")
1068    ("d" counsel-locate-action-dired "dired")))
1069
1070 (defvar counsel-locate-history nil
1071   "History for `counsel-locate'.")
1072
1073 (defun counsel-locate-action-extern (x)
1074   "Use xdg-open shell command on X."
1075   (call-process shell-file-name nil
1076                 nil nil
1077                 shell-command-switch
1078                 (format "%s %s"
1079                         (if (eq system-type 'darwin)
1080                             "open"
1081                           "xdg-open")
1082                         (shell-quote-argument x))))
1083
1084 (declare-function dired-jump "dired-x")
1085
1086 (defun counsel-locate-action-dired (x)
1087   "Use `dired-jump' on X."
1088   (dired-jump nil x))
1089
1090 (defun counsel-locate-cmd-default (input)
1091   "Return a shell command based on INPUT."
1092   (format "locate -i --regex '%s'"
1093           (counsel-unquote-regex-parens
1094            (ivy--regex input))))
1095
1096 (defun counsel-locate-cmd-noregex (input)
1097   "Return a shell command based on INPUT."
1098   (format "locate -i '%s'" input))
1099
1100 (defun counsel-locate-cmd-mdfind (input)
1101   "Return a shell command based on INPUT."
1102   (format "mdfind -name '%s'" input))
1103
1104 (defun counsel-locate-function (input)
1105   (if (< (length input) 3)
1106       (counsel-more-chars 3)
1107     (counsel--async-command
1108      (funcall counsel-locate-cmd input))
1109     '("" "working...")))
1110
1111 ;;;###autoload
1112 (defun counsel-locate (&optional initial-input)
1113   "Call the \"locate\" shell command.
1114 INITIAL-INPUT can be given as the initial minibuffer input."
1115   (interactive)
1116   (ivy-read "Locate: " #'counsel-locate-function
1117             :initial-input initial-input
1118             :dynamic-collection t
1119             :history 'counsel-locate-history
1120             :action (lambda (file)
1121                       (with-ivy-window
1122                         (when file
1123                           (find-file file))))
1124             :unwind #'counsel-delete-process
1125             :caller 'counsel-locate))
1126
1127 ;;* Grep
1128 ;;** `counsel-ag'
1129 (defcustom counsel-ag-base-command "ag --vimgrep %S"
1130   "Format string to use in `cousel-ag-function' to construct the
1131 command. %S will be replaced by the regex string. The default is
1132 \"ag --vimgrep %S\"."
1133   :type 'stringp
1134   :group 'ivy)
1135
1136 (defun counsel-ag-function (string)
1137   "Grep in the current directory for STRING."
1138   (if (< (length string) 3)
1139       (counsel-more-chars 3)
1140     (let ((default-directory counsel--git-grep-dir)
1141           (regex (counsel-unquote-regex-parens
1142                   (setq ivy--old-re
1143                         (ivy--regex string)))))
1144       (counsel--async-command
1145        (format counsel-ag-base-command regex))
1146       nil)))
1147
1148 ;;;###autoload
1149 (defun counsel-ag (&optional initial-input initial-directory)
1150   "Grep for a string in the current directory using ag.
1151 INITIAL-INPUT can be given as the initial minibuffer input."
1152   (interactive)
1153   (setq counsel--git-grep-dir (or initial-directory default-directory))
1154   (ivy-read "ag: " 'counsel-ag-function
1155             :initial-input initial-input
1156             :dynamic-collection t
1157             :history 'counsel-git-grep-history
1158             :action #'counsel-git-grep-action
1159             :unwind (lambda ()
1160                       (counsel-delete-process)
1161                       (swiper--cleanup))
1162             :caller 'counsel-ag))
1163
1164 ;;** `counsel-grep'
1165 (defun counsel-grep-function (string)
1166   "Grep in the current directory for STRING."
1167   (if (< (length string) 3)
1168       (counsel-more-chars 3)
1169     (let ((regex (counsel-unquote-regex-parens
1170                   (setq ivy--old-re
1171                         (ivy--regex string)))))
1172       (counsel--async-command
1173        (format "grep -nP --ignore-case '%s' %s" regex counsel--git-grep-dir))
1174       nil)))
1175
1176 (defun counsel-grep-action (x)
1177   (when (string-match "\\`\\([0-9]+\\):\\(.*\\)\\'" x)
1178     (with-ivy-window
1179       (let ((file-name counsel--git-grep-dir)
1180             (line-number (match-string-no-properties 1 x)))
1181         (find-file file-name)
1182         (goto-char (point-min))
1183         (forward-line (1- (string-to-number line-number)))
1184         (re-search-forward (ivy--regex ivy-text t) (line-end-position) t)
1185         (unless (eq ivy-exit 'done)
1186           (swiper--cleanup)
1187           (swiper--add-overlays (ivy--regex ivy-text)))))))
1188
1189 ;;;###autoload
1190 (defun counsel-grep ()
1191   "Grep for a string in the current file."
1192   (interactive)
1193   (setq counsel--git-grep-dir (buffer-file-name))
1194   (ivy-read "grep: " 'counsel-grep-function
1195             :dynamic-collection t
1196             :preselect (format "%d:%s"
1197                                (line-number-at-pos)
1198                                (buffer-substring-no-properties
1199                                 (line-beginning-position)
1200                                 (line-end-position)))
1201             :history 'counsel-git-grep-history
1202             :update-fn (lambda ()
1203                          (counsel-grep-action ivy--current))
1204             :action #'counsel-grep-action
1205             :unwind (lambda ()
1206                       (counsel-delete-process)
1207                       (swiper--cleanup))
1208             :caller 'counsel-grep))
1209 ;;** `counsel-recoll'
1210 (defun counsel-recoll-function (string)
1211   "Grep in the current directory for STRING."
1212   (if (< (length string) 3)
1213       (counsel-more-chars 3)
1214     (counsel--async-command
1215      (format "recoll -t -b '%s'" string))
1216     nil))
1217
1218 ;; This command uses the recollq command line tool that comes together
1219 ;; with the recoll (the document indexing database) source:
1220 ;;     http://www.lesbonscomptes.com/recoll/download.html
1221 ;; You need to build it yourself (together with recoll):
1222 ;;     cd ./query && make && sudo cp recollq /usr/local/bin
1223 ;; You can try the GUI version of recoll with:
1224 ;;     sudo apt-get install recoll
1225 ;; Unfortunately, that does not install recollq.
1226 (defun counsel-recoll (&optional initial-input)
1227   "Search for a string in the recoll database.
1228 You'll be given a list of files that match.
1229 Selecting a file will launch `swiper' for that file.
1230 INITIAL-INPUT can be given as the initial minibuffer input."
1231   (interactive)
1232   (ivy-read "recoll: " 'counsel-recoll-function
1233             :initial-input initial-input
1234             :dynamic-collection t
1235             :history 'counsel-git-grep-history
1236             :action (lambda (x)
1237                       (when (string-match "file://\\(.*\\)\\'" x)
1238                         (let ((file-name (match-string 1 x)))
1239                           (find-file file-name)
1240                           (unless (string-match "pdf$" x)
1241                             (swiper ivy-text)))))
1242             :unwind #'counsel-delete-process
1243             :caller 'counsel-recoll))
1244 ;;* Misc Emacs
1245 ;;** `counsel-org-tag'
1246 (defvar counsel-org-tags nil
1247   "Store the current list of tags.")
1248
1249 (defvar org-outline-regexp)
1250 (defvar org-indent-mode)
1251 (defvar org-indent-indentation-per-level)
1252 (defvar org-tags-column)
1253 (declare-function org-get-tags-string "org")
1254 (declare-function org-move-to-column "org-compat")
1255
1256 (defun counsel-org-change-tags (tags)
1257   (let ((current (org-get-tags-string))
1258         (col (current-column))
1259         level)
1260     ;; Insert new tags at the correct column
1261     (beginning-of-line 1)
1262     (setq level (or (and (looking-at org-outline-regexp)
1263                          (- (match-end 0) (point) 1))
1264                     1))
1265     (cond
1266       ((and (equal current "") (equal tags "")))
1267       ((re-search-forward
1268         (concat "\\([ \t]*" (regexp-quote current) "\\)[ \t]*$")
1269         (point-at-eol) t)
1270        (if (equal tags "")
1271            (delete-region
1272             (match-beginning 0)
1273             (match-end 0))
1274          (goto-char (match-beginning 0))
1275          (let* ((c0 (current-column))
1276                 ;; compute offset for the case of org-indent-mode active
1277                 (di (if (bound-and-true-p org-indent-mode)
1278                         (* (1- org-indent-indentation-per-level) (1- level))
1279                       0))
1280                 (p0 (if (equal (char-before) ?*) (1+ (point)) (point)))
1281                 (tc (+ org-tags-column (if (> org-tags-column 0) (- di) di)))
1282                 (c1 (max (1+ c0) (if (> tc 0) tc (- (- tc) (string-width tags)))))
1283                 (rpl (concat (make-string (max 0 (- c1 c0)) ?\ ) tags)))
1284            (replace-match rpl t t)
1285            (and c0 indent-tabs-mode (tabify p0 (point)))
1286            tags)))
1287       (t (error "Tags alignment failed")))
1288     (org-move-to-column col)))
1289
1290 (defun counsel-org--set-tags ()
1291   (counsel-org-change-tags
1292    (if counsel-org-tags
1293        (format ":%s:"
1294                (mapconcat #'identity counsel-org-tags ":"))
1295      "")))
1296
1297 (defvar org-agenda-bulk-marked-entries)
1298
1299 (declare-function org-get-at-bol "org")
1300 (declare-function org-agenda-error "org-agenda")
1301
1302 (defun counsel-org-tag-action (x)
1303   (if (member x counsel-org-tags)
1304       (progn
1305         (setq counsel-org-tags (delete x counsel-org-tags)))
1306     (unless (equal x "")
1307       (setq counsel-org-tags (append counsel-org-tags (list x)))
1308       (unless (member x ivy--all-candidates)
1309         (setq ivy--all-candidates (append ivy--all-candidates (list x))))))
1310   (let ((prompt (counsel-org-tag-prompt)))
1311     (setf (ivy-state-prompt ivy-last) prompt)
1312     (setq ivy--prompt (concat "%-4d " prompt)))
1313   (cond ((memq this-command '(ivy-done
1314                               ivy-alt-done
1315                               ivy-immediate-done))
1316          (if (eq major-mode 'org-agenda-mode)
1317              (if (null org-agenda-bulk-marked-entries)
1318                  (let ((hdmarker (or (org-get-at-bol 'org-hd-marker)
1319                                      (org-agenda-error))))
1320                    (with-current-buffer (marker-buffer hdmarker)
1321                      (goto-char hdmarker)
1322                      (counsel-org--set-tags)))
1323                (let ((add-tags (copy-sequence counsel-org-tags)))
1324                  (dolist (m org-agenda-bulk-marked-entries)
1325                    (with-current-buffer (marker-buffer m)
1326                      (save-excursion
1327                        (goto-char m)
1328                        (setq counsel-org-tags
1329                              (delete-dups
1330                               (append (split-string (org-get-tags-string) ":" t)
1331                                       add-tags)))
1332                        (counsel-org--set-tags))))))
1333            (counsel-org--set-tags)))
1334         ((eq this-command 'ivy-call)
1335          (delete-minibuffer-contents))))
1336
1337 (defun counsel-org-tag-prompt ()
1338   (format "Tags (%s): "
1339           (mapconcat #'identity counsel-org-tags ", ")))
1340
1341 (defvar org-setting-tags)
1342 (defvar org-last-tags-completion-table)
1343 (defvar org-tag-persistent-alist)
1344 (defvar org-tag-alist)
1345 (defvar org-complete-tags-always-offer-all-agenda-tags)
1346
1347 (declare-function org-at-heading-p "org")
1348 (declare-function org-back-to-heading "org")
1349 (declare-function org-get-buffer-tags "org")
1350 (declare-function org-global-tags-completion-table "org")
1351 (declare-function org-agenda-files "org")
1352 (declare-function org-agenda-set-tags "org-agenda")
1353
1354 ;;;###autoload
1355 (defun counsel-org-tag ()
1356   "Add or remove tags in org-mode."
1357   (interactive)
1358   (save-excursion
1359     (if (eq major-mode 'org-agenda-mode)
1360         (if org-agenda-bulk-marked-entries
1361             (setq counsel-org-tags nil)
1362           (let ((hdmarker (or (org-get-at-bol 'org-hd-marker)
1363                               (org-agenda-error))))
1364             (with-current-buffer (marker-buffer hdmarker)
1365               (goto-char hdmarker)
1366               (setq counsel-org-tags
1367                     (split-string (org-get-tags-string) ":" t)))))
1368       (unless (org-at-heading-p)
1369         (org-back-to-heading t))
1370       (setq counsel-org-tags (split-string (org-get-tags-string) ":" t)))
1371     (let ((org-setting-tags t)
1372           (org-last-tags-completion-table
1373            (append org-tag-persistent-alist
1374                    (or org-tag-alist (org-get-buffer-tags))
1375                    (and
1376                     (or org-complete-tags-always-offer-all-agenda-tags
1377                         (eq major-mode 'org-agenda-mode))
1378                     (org-global-tags-completion-table
1379                      (org-agenda-files))))))
1380       (ivy-read (counsel-org-tag-prompt)
1381                 (lambda (str &rest _unused)
1382                   (delete-dups
1383                    (all-completions str 'org-tags-completion-function)))
1384                 :history 'org-tags-history
1385                 :action 'counsel-org-tag-action
1386                 :caller 'counsel-org-tag))))
1387
1388 ;;;###autoload
1389 (defun counsel-org-tag-agenda ()
1390   "Set tags for the current agenda item."
1391   (interactive)
1392   (let ((store (symbol-function 'org-set-tags)))
1393     (unwind-protect
1394          (progn
1395            (fset 'org-set-tags
1396                  (symbol-function 'counsel-org-tag))
1397            (org-agenda-set-tags nil nil))
1398       (fset 'org-set-tags store))))
1399
1400 ;;** `counsel-tmm'
1401 (defvar tmm-km-list nil)
1402 (declare-function tmm-get-keymap "tmm")
1403 (declare-function tmm--completion-table "tmm")
1404 (declare-function tmm-get-keybind "tmm")
1405
1406 (defun counsel-tmm-prompt (menu)
1407   "Select and call an item from the MENU keymap."
1408   (let (out
1409         choice
1410         chosen-string)
1411     (setq tmm-km-list nil)
1412     (map-keymap (lambda (k v) (tmm-get-keymap (cons k v))) menu)
1413     (setq tmm-km-list (nreverse tmm-km-list))
1414     (setq out (ivy-read "Menu bar: " (tmm--completion-table tmm-km-list)
1415                         :require-match t
1416                         :sort nil))
1417     (setq choice (cdr (assoc out tmm-km-list)))
1418     (setq chosen-string (car choice))
1419     (setq choice (cdr choice))
1420     (cond ((keymapp choice)
1421            (counsel-tmm-prompt choice))
1422           ((and choice chosen-string)
1423            (setq last-command-event chosen-string)
1424            (call-interactively choice)))))
1425
1426 (defvar tmm-table-undef)
1427
1428 ;;;###autoload
1429 (defun counsel-tmm ()
1430   "Text-mode emulation of looking and choosing from a menubar."
1431   (interactive)
1432   (require 'tmm)
1433   (run-hooks 'menu-bar-update-hook)
1434   (setq tmm-table-undef nil)
1435   (counsel-tmm-prompt (tmm-get-keybind [menu-bar])))
1436
1437 ;;** `counsel-yank-pop'
1438 (defcustom counsel-yank-pop-truncate-radius 2
1439   "When non-nil, truncate the display of long strings."
1440   :type 'integer
1441   :group 'ivy)
1442
1443 (defun counsel--yank-pop-truncate (str)
1444   (condition-case nil
1445       (let* ((lines (split-string str "\n" t))
1446              (n (length lines))
1447              (first-match (cl-position-if
1448                            (lambda (s) (string-match ivy--old-re s))
1449                            lines))
1450              (beg (max 0 (- first-match
1451                             counsel-yank-pop-truncate-radius)))
1452              (end (min n (+ first-match
1453                             counsel-yank-pop-truncate-radius
1454                             1)))
1455              (seq (cl-subseq lines beg end)))
1456         (if (null first-match)
1457             (error "Could not match %s" str)
1458           (when (> beg 0)
1459             (setcar seq (concat "[...] " (car seq))))
1460           (when (< end n)
1461             (setcar (last seq)
1462                     (concat (car (last seq)) " [...]")))
1463           (mapconcat #'identity seq "\n")))
1464     (error str)))
1465
1466 (defun counsel--yank-pop-format-function (cand-pairs)
1467   (ivy--format-function-generic
1468    (lambda (str)
1469      (mapconcat
1470       (lambda (s)
1471         (ivy--add-face s 'ivy-current-match))
1472       (split-string
1473        (counsel--yank-pop-truncate str) "\n" t)
1474       "\n"))
1475    (lambda (str)
1476      (counsel--yank-pop-truncate str))
1477    cand-pairs
1478    "\n"))
1479
1480 (defun counsel-yank-pop-action (s)
1481   "Insert S into the buffer, overwriting the previous yank."
1482   (with-ivy-window
1483     (delete-region ivy-completion-beg
1484                    ivy-completion-end)
1485     (insert (substring-no-properties s))
1486     (setq ivy-completion-end (point))))
1487
1488 ;;;###autoload
1489 (defun counsel-yank-pop ()
1490   "Ivy replacement for `yank-pop'."
1491   (interactive)
1492   (if (eq last-command 'yank)
1493       (progn
1494         (setq ivy-completion-end (point))
1495         (setq ivy-completion-beg
1496               (save-excursion
1497                 (search-backward (car kill-ring))
1498                 (point))))
1499     (setq ivy-completion-beg (point))
1500     (setq ivy-completion-end (point)))
1501   (let ((candidates (cl-remove-if
1502                      (lambda (s)
1503                        (or (< (length s) 3)
1504                            (string-match "\\`[\n[:blank:]]+\\'" s)))
1505                      (delete-dups kill-ring))))
1506     (let ((ivy-format-function #'counsel--yank-pop-format-function)
1507           (ivy-height 5))
1508       (ivy-read "kill-ring: " candidates
1509                 :action 'counsel-yank-pop-action
1510                 :caller 'counsel-yank-pop))))
1511
1512 ;;** `counsel-imenu'
1513 (defvar imenu-auto-rescan)
1514 (declare-function imenu--subalist-p "imenu")
1515 (declare-function imenu--make-index-alist "imenu")
1516
1517 (defun counsel-imenu-get-candidates-from (alist &optional prefix)
1518   "Create a list of (key . value) from ALIST.
1519 PREFIX is used to create the key."
1520   (cl-mapcan (lambda (elm)
1521                (if (imenu--subalist-p elm)
1522                    (counsel-imenu-get-candidates-from
1523                     (cl-loop for (e . v) in (cdr elm) collect
1524                          (cons e (if (integerp v) (copy-marker v) v)))
1525                     ;; pass the prefix to next recursive call
1526                     (concat prefix (if prefix ".") (car elm)))
1527                  (let ((key (concat prefix (if prefix ".") (car elm))))
1528                    (list (cons key
1529                                ;; create a imenu candidate here
1530                                (cons key (if (overlayp (cdr elm))
1531                                              (overlay-start (cdr elm))
1532                                            (cdr elm))))))))
1533              alist))
1534
1535 ;;;###autoload
1536 (defun counsel-imenu ()
1537   "Jump to a buffer position indexed by imenu."
1538   (interactive)
1539   (unless (featurep 'imenu)
1540     (require 'imenu nil t))
1541   (let* ((imenu-auto-rescan t)
1542          (items (imenu--make-index-alist t))
1543          (items (delete (assoc "*Rescan*" items) items)))
1544     (ivy-read "imenu items:" (counsel-imenu-get-candidates-from items)
1545               :preselect (thing-at-point 'symbol)
1546               :require-match t
1547               :action (lambda (candidate)
1548                         (with-ivy-window
1549                           ;; In org-mode, (imenu candidate) will expand child node
1550                           ;; after jump to the candidate position
1551                           (imenu candidate)))
1552               :caller 'counsel-imenu)))
1553
1554 ;;** `counsel-list-processes'
1555 (defun counsel-list-processes-action-delete (x)
1556   (delete-process x)
1557   (setf (ivy-state-collection ivy-last)
1558         (setq ivy--all-candidates
1559               (delete x ivy--all-candidates))))
1560
1561 (defun counsel-list-processes-action-switch (x)
1562   (let* ((proc (get-process x))
1563          (buf (and proc (process-buffer proc))))
1564     (if buf
1565         (switch-to-buffer x)
1566       (message "Process %s doesn't have a buffer" x))))
1567
1568 ;;;###autoload
1569 (defun counsel-list-processes ()
1570   "Offer completion for `process-list'
1571 The default action deletes the selected process.
1572 An extra action allows to switch to the process buffer."
1573   (interactive)
1574   (list-processes--refresh)
1575   (ivy-read "Process: " (mapcar #'process-name (process-list))
1576             :require-match t
1577             :action
1578             '(1
1579               ("o" counsel-list-processes-action-delete "kill")
1580               ("s" counsel-list-processes-action-switch "switch"))
1581             :caller 'counsel-list-processes))
1582
1583 ;;* Misc OS
1584 ;;** `counsel-rhythmbox'
1585 (defvar rhythmbox-library)
1586 (declare-function rhythmbox-load-library "ext:helm-rhythmbox")
1587 (declare-function dbus-call-method "dbus")
1588 (declare-function dbus-get-property "dbus")
1589 (declare-function rhythmbox-song-uri "ext:helm-rhythmbox")
1590 (declare-function helm-rhythmbox-candidates "ext:helm-rhythmbox")
1591
1592 (defun counsel-rhythmbox-enqueue-song (song)
1593   "Let Rhythmbox enqueue SONG."
1594   (let ((service "org.gnome.Rhythmbox3")
1595         (path "/org/gnome/Rhythmbox3/PlayQueue")
1596         (interface "org.gnome.Rhythmbox3.PlayQueue"))
1597     (dbus-call-method :session service path interface
1598                       "AddToQueue" (rhythmbox-song-uri song))))
1599
1600 (defvar counsel-rhythmbox-history nil
1601   "History for `counsel-rhythmbox'.")
1602
1603 (defun counsel-rhythmbox-current-song ()
1604   "Return the currently playing song title."
1605   (ignore-errors
1606     (let* ((entry (dbus-get-property
1607                    :session
1608                    "org.mpris.MediaPlayer2.rhythmbox"
1609                    "/org/mpris/MediaPlayer2"
1610                    "org.mpris.MediaPlayer2.Player"
1611                    "Metadata"))
1612            (artist (caar (cadr (assoc "xesam:artist" entry))))
1613            (album (cl-caadr (assoc "xesam:album" entry)))
1614            (title (cl-caadr (assoc "xesam:title" entry))))
1615       (format "%s - %s - %s" artist album title))))
1616
1617 ;;;###autoload
1618 (defun counsel-rhythmbox ()
1619   "Choose a song from the Rhythmbox library to play or enqueue."
1620   (interactive)
1621   (unless (require 'helm-rhythmbox nil t)
1622     (error "Please install `helm-rhythmbox'"))
1623   (unless rhythmbox-library
1624     (rhythmbox-load-library)
1625     (while (null rhythmbox-library)
1626       (sit-for 0.1)))
1627   (ivy-read "Rhythmbox: "
1628             (helm-rhythmbox-candidates)
1629             :history 'counsel-rhythmbox-history
1630             :preselect (counsel-rhythmbox-current-song)
1631             :action
1632             '(1
1633               ("p" helm-rhythmbox-play-song "Play song")
1634               ("e" counsel-rhythmbox-enqueue-song "Enqueue song"))
1635             :caller 'counsel-rhythmbox))
1636
1637 (provide 'counsel)
1638
1639 ;;; counsel.el ends here