code.delx.au - gnu-emacs/blob - lisp/autorevert.el

   1 ;;; autorevert --- revert buffers when files on disk change
   2
   3 ;; Copyright (C) 1997, 1998 Free Software Foundation, Inc.
   4
   5 ;; Author: Anders Lindgren <andersl@csd.uu.se>
   6 ;; Keywords: convenience
   7 ;; Created: 1 Jun 1997
   8 ;; Date: 3 Jul 1997
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Introduction:
  30 ;;
  31 ;; Whenever a file that Emacs is editing has been changed by another
  32 ;; program the user normally has to execute the command `revert-buffer'
  33 ;; to load the new content of the file into Emacs.
  34 ;;
  35 ;; This package contains two minor modes: Global Auto-Revert Mode and
  36 ;; Auto-Revert Mode.  Both modes automatically revert buffers
  37 ;; whenever the corresponding files have been changed on disk.
  38 ;;
  39 ;; Auto-Revert Mode can be activated for individual buffers.
  40 ;; Global Auto-Revert Mode applies to all file buffers.
  41 ;;
  42 ;; Both modes operate by checking the time stamp of all files at
  43 ;; intervals of `auto-revert-interval'.  The default is every five
  44 ;; seconds.  The check is aborted whenever the user actually uses
  45 ;; Emacs.  You should never even notice that this package is active
  46 ;; (except that your buffers will be reverted, of course).
  47
  48 ;; Usage:
  49 ;;
  50 ;; Go to the appropriate buffer and press:
  51 ;;   M-x auto-revert-mode RET
  52 ;;
  53 ;; To activate Global Auto-Revert Mode, press:
  54 ;;   M-x global-auto-revert-mode RET
  55 ;;
  56 ;; To activate Global Auto-Revert Mode every time Emacs is started
  57 ;; customise the option `global-auto-revert-mode' or the following
  58 ;; line could be added to your ~/.emacs:
  59 ;;   (global-auto-revert-mode 1)
  60 ;;
  61 ;; The function `turn-on-auto-revert-mode' could be added to any major
  62 ;; mode hook to activate Auto-Revert Mode for all buffers in that
  63 ;; mode.  For example, the following line will activate Auto-Revert
  64 ;; Mode in all C mode buffers:
  65 ;;
  66 ;; (add-hook 'c-mode-hook 'turn-on-auto-revert-mode)
  67
  68 ;;; Code:
  69
  70 ;; Dependencies:
  71
  72 (require 'timer)
  73 (eval-when-compile (require 'cl))
  74
  75
  76 ;; Custom Group:
  77 ;;
  78 ;; The two modes will be placed next to Auto Save Mode under the
  79 ;; Files group under Emacs.
  80
  81 (defgroup auto-revert nil
  82   "Revert individual buffers when files on disk change.
  83
  84 Auto-Revert Mode can be activated for individual buffer.
  85 Global Auto-Revert Mode applies to all buffers."
  86   :group 'files
  87   :group 'convenience)
  88
  89
  90 ;; Variables:
  91
  92 ;; Autoload for the benefit of `make-mode-line-mouse-sensitive'.
  93 ;;;###autoload
  94 (defvar auto-revert-mode nil
  95   "*Non-nil when Auto-Revert Mode is active.
  96
  97 Never set this variable directly, use the command `auto-revert-mode'
  98 instead.")
  99
 100 (defcustom global-auto-revert-mode nil
 101   "When on, buffers are automatically reverted when files on disk change.
 102
 103 Set this variable using \\[customize] only.  Otherwise, use the
 104 command `global-auto-revert-mode'."
 105   :group 'auto-revert
 106   :initialize 'custom-initialize-default
 107   :set '(lambda (symbol value)
 108           (global-auto-revert-mode (or value 0)))
 109   :type 'boolean
 110   :require 'autorevert)
 111
 112 (defcustom auto-revert-interval 5
 113   "Time, in seconds, between Auto-Revert Mode file checks."
 114   :group 'auto-revert
 115   :type 'integer)
 116
 117 (defcustom auto-revert-stop-on-user-input t
 118   "When non-nil Auto-Revert Mode stops checking files on user input."
 119   :group 'auto-revert
 120   :type 'boolean)
 121
 122 (defcustom auto-revert-verbose t
 123   "When nil, Auto-Revert Mode will not generate any messages.
 124
 125 Currently, messages are generated when the mode is activated or
 126 deactivated, and whenever a file is reverted."
 127   :group 'auto-revert
 128   :type 'boolean)
 129
 130 (defcustom auto-revert-mode-text " ARev"
 131   "String to display in the mode line when Auto-Revert Mode is active.
 132
 133 \(When the string is not empty, make sure that it has a leading space.)"
 134   :tag "Auto Revert Mode Text"          ; To separate it from `global-...'
 135   :group 'auto-revert
 136   :type 'string)
 137
 138 (defcustom auto-revert-mode-hook nil
 139   "Functions to run when Auto-Revert Mode is activated."
 140   :tag "Auto Revert Mode Hook"          ; To separate it from `global-...'
 141   :group 'auto-revert
 142   :type 'hook)
 143
 144 (defcustom global-auto-revert-mode-text ""
 145   "String to display when Global Auto-Revert Mode is active.
 146
 147 The default is nothing since when this mode is active this text doesn't
 148 vary over time, or between buffers.  Hence mode line text
 149 would only waste precious space."
 150   :group 'auto-revert
 151   :type 'string)
 152
 153 (defcustom global-auto-revert-mode-hook nil
 154   "Hook called when Global Auto-Revert Mode is activated."
 155   :group 'auto-revert
 156   :type 'hook)
 157
 158 (defcustom global-auto-revert-non-file-buffers nil
 159   "*When nil only file buffers are reverted by Global Auto-Revert Mode.
 160
 161 When non-nil, both file buffers and buffers with a custom
 162 `revert-buffer-function' are reverted by Global Auto-Revert Mode."
 163   :group 'auto-revert
 164   :type 'boolean)
 165
 166 (defcustom global-auto-revert-non-file-buffers nil
 167   "When nil only file buffers are reverted by Global Auto-Revert Mode.
 168
 169 When non-nil, both file buffers and buffers with a custom
 170 `revert-buffer-function' are reverted by Global Auto-Revert Mode.
 171
 172 Use this option with care since it could lead to excessive reverts."
 173   :group 'auto-revert
 174   :type 'boolean)
 175
 176 (defcustom global-auto-revert-ignore-modes '()
 177   "List of major modes Global Auto-Revert Mode should not check."
 178   :group 'auto-revert
 179   :type '(repeat sexp))
 180
 181 (defcustom auto-revert-load-hook nil
 182   "Functions to run when Auto-Revert Mode is first loaded."
 183   :tag "Load Hook"
 184   :group 'auto-revert
 185   :type 'hook)
 186
 187 (defvar global-auto-revert-ignore-buffer nil
 188   "*When non-nil, Global Auto-Revert Mode will not revert this buffer.
 189
 190 This variable becomes buffer local when set in any fashion.")
 191 (make-variable-buffer-local 'global-auto-revert-ignore-buffer)
 192
 193
 194 ;; Internal variables:
 195
 196 (defvar auto-revert-buffer-list '()
 197   "List of buffers in Auto-Revert Mode.
 198
 199 Note that only Auto-Revert Mode, never Global Auto-Revert Mode, adds
 200 buffers to this list.
 201
 202 The timer function `auto-revert-buffers' is responsible for purging
 203 the list of old buffers.")
 204
 205 (defvar auto-revert-timer nil
 206   "Timer used by Auto-Revert Mode.")
 207
 208 (defvar auto-revert-remaining-buffers '()
 209   "Buffers not checked when user input stopped execution.")
 210
 211
 212 ;; Functions:
 213
 214 ;;;###autoload
 215 (defun auto-revert-mode (&optional arg)
 216   "Toggle reverting buffer when file on disk changes.
 217
 218 With arg, turn Auto Revert mode on if and only if arg is positive.
 219 This is a minor mode that affects only the current buffer.
 220 Use `global-auto-revert-mode' to automatically revert all buffers."
 221   (interactive "P")
 222   (make-local-variable 'auto-revert-mode)
 223   (setq auto-revert-mode
 224         (if (null arg)
 225             (not auto-revert-mode)
 226           (> (prefix-numeric-value arg) 0)))
 227   (if (and auto-revert-verbose
 228            (interactive-p))
 229       (message "Auto-Revert Mode is now %s."
 230                (if auto-revert-mode "on" "off")))
 231   (if auto-revert-mode
 232       (if (not (memq (current-buffer) auto-revert-buffer-list))
 233           (push (current-buffer) auto-revert-buffer-list))
 234     (setq auto-revert-buffer-list
 235           (delq (current-buffer) auto-revert-buffer-list)))
 236   (auto-revert-set-timer)
 237   (when auto-revert-mode
 238     (auto-revert-buffers)
 239     (run-hooks 'auto-revert-mode-hook)))
 240
 241
 242 ;;;###autoload
 243 (defun turn-on-auto-revert-mode ()
 244   "Turn on Auto-Revert Mode.
 245
 246 This function is designed to be added to hooks, for example:
 247   (add-hook 'c-mode-hook 'turn-on-auto-revert-mode)"
 248   (auto-revert-mode 1))
 249
 250
 251 ;;;###autoload
 252 (defun global-auto-revert-mode (&optional arg)
 253   "Revert any buffer when file on disk change.
 254
 255 With arg, turn Auto Revert mode on globally if and only if arg is positive.
 256 This is a minor mode that affects all buffers.
 257 Use `auto-revert-mode' to revert a particular buffer."
 258   (interactive "P")
 259   (setq global-auto-revert-mode
 260         (if (null arg)
 261             (not global-auto-revert-mode)
 262           (> (prefix-numeric-value arg) 0)))
 263   (if (and auto-revert-verbose
 264            (interactive-p))
 265       (message "Global Auto-Revert Mode is now %s."
 266                (if global-auto-revert-mode "on" "off")))
 267   (auto-revert-set-timer)
 268   (when global-auto-revert-mode
 269     (auto-revert-buffers)
 270     (run-hooks 'global-auto-revert-mode-hook)))
 271
 272
 273 (defun auto-revert-set-timer ()
 274   "Restart or cancel the timer."
 275   (if (timerp auto-revert-timer)
 276       (cancel-timer auto-revert-timer))
 277   (if (or global-auto-revert-mode auto-revert-buffer-list)
 278       (setq auto-revert-timer (run-with-timer auto-revert-interval
 279                                               auto-revert-interval
 280                                               'auto-revert-buffers))
 281     (setq auto-revert-timer nil)))
 282
 283
 284 (defun auto-revert-buffers ()
 285   "Revert buffers as specified by Auto-Revert and Global Auto-Revert Mode.
 286
 287 Should `global-auto-revert-mode' be active all file buffers are checked.
 288
 289 Should `auto-revert-mode' be active in some buffers, those buffers
 290 are checked.
 291
 292 Non-file buffers that have a custom `revert-buffer-function' are
 293 reverted either when Auto-Revert Mode is active in that buffer, or
 294 when the variable `global-auto-revert-non-file-buffers' is non-nil
 295 and Global Auto-Revert Mode is active.
 296
 297 This function stops whenever there is user input.  The buffers not
 298 checked are stored in the variable `auto-revert-remaining-buffers'.
 299
 300 To avoid starvation, the buffers in `auto-revert-remaining-buffers'
 301 are checked first the next time this function is called.
 302
 303 This function is also responsible for removing buffers no longer in
 304 Auto-Revert mode from `auto-revert-buffer-list', and for canceling
 305 the timer when no buffers need to be checked."
 306   (let ((bufs (if global-auto-revert-mode
 307                   (buffer-list)
 308                 auto-revert-buffer-list))
 309         (remaining '())
 310         (new '()))
 311     ;; Partition `bufs' into two halves depending on whether or not
 312     ;; the buffers are in `auto-revert-remaining-buffers'.  The two
 313     ;; halves are then re-joined with the "remaining" buffers at the
 314     ;; head of the list.
 315     (dolist (buf auto-revert-remaining-buffers)
 316       (if (memq buf bufs)
 317           (push buf remaining)))
 318     (dolist (buf bufs)
 319       (if (not (memq buf remaining))
 320           (push buf new)))
 321     (setq bufs (nreverse (nconc new remaining)))
 322     (while (and bufs
 323                 (not (and auto-revert-stop-on-user-input
 324                           (input-pending-p))))
 325       (let ((buf (car bufs)))
 326         (if (buffer-name buf)           ; Buffer still alive?
 327             (save-excursion
 328               (set-buffer buf)
 329               ;; Test if someone has turned off Auto-Revert Mode in a
 330               ;; non-standard way, for example by changing major mode.
 331               (if (and (not auto-revert-mode)
 332                        (memq buf auto-revert-buffer-list))
 333                   (setq auto-revert-buffer-list
 334                         (delq buf auto-revert-buffer-list)))
 335               (when (and
 336                      (or auto-revert-mode
 337                          (and
 338                           global-auto-revert-mode
 339                           (not global-auto-revert-ignore-buffer)
 340                           (not (memq major-mode
 341                                      global-auto-revert-ignore-modes))))
 342                      (not (buffer-modified-p))
 343                      (if (buffer-file-name)
 344                          (and (file-readable-p (buffer-file-name))
 345                               (not (verify-visited-file-modtime buf)))
 346                        (and revert-buffer-function
 347                             (or (and global-auto-revert-mode
 348                                      global-auto-revert-non-file-buffers)
 349                                 auto-revert-mode))))
 350                 (if auto-revert-verbose
 351                     (message "Reverting buffer `%s'." buf))
 352                 (revert-buffer t t)))
 353           ;; Remove dead buffer from `auto-revert-buffer-list'.
 354           (setq auto-revert-buffer-list
 355                 (delq buf auto-revert-buffer-list))))
 356       (setq bufs (cdr bufs)))
 357     (setq auto-revert-remaining-buffers bufs)
 358     ;; Check if we should cancel the timer.
 359     (when (and (not global-auto-revert-mode)
 360                (null auto-revert-buffer-list))
 361       (cancel-timer auto-revert-timer)
 362       (setq auto-revert-timer nil))))
 363
 364
 365 ;; The end:
 366
 367 (unless (assq 'auto-revert-mode minor-mode-alist)
 368   (push '(auto-revert-mode auto-revert-mode-text)
 369         minor-mode-alist))
 370 (unless (assq 'global-auto-revert-mode minor-mode-alist)
 371   (push '(global-auto-revert-mode global-auto-revert-mode-text)
 372         minor-mode-alist))
 373
 374 (provide 'autorevert)
 375
 376 (run-hooks 'auto-revert-load-hook)
 377
 378 ;; This makes it possible to set Global Auto-Revert Mode from
 379 ;; Customize.
 380 (if global-auto-revert-mode
 381     (global-auto-revert-mode 1))
 382
 383 ;; autorevert.el ends here.