code.delx.au - gnu-emacs/blob - lisp/textmodes/nroff-mode.el

   1 ;;; nroff-mode.el --- GNU Emacs major mode for editing nroff source
   2
   3 ;; Copyright (C) 1985, 1986, 1994 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: wp
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  22 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; This package is a major mode for editing nroff source code.  It knows
  27 ;; about various nroff constructs, ms, mm, and me macros, and will fill
  28 ;; and indent paragraphs properly in their presence.  It also includes
  29 ;; a command to count text lines (excluding nroff constructs), a command
  30 ;; to center a line, and movement commands that know how to skip macros.
  31
  32 ;;; Code:
  33
  34 (defvar nroff-mode-abbrev-table nil
  35   "Abbrev table used while in nroff mode.")
  36 (define-abbrev-table 'nroff-mode-abbrev-table ())
  37
  38 (defvar nroff-mode-map nil
  39      "Major mode keymap for nroff mode.")
  40 (if (not nroff-mode-map)
  41     (progn
  42       (setq nroff-mode-map (make-sparse-keymap))
  43       (define-key nroff-mode-map "\t"  'tab-to-tab-stop)
  44       (define-key nroff-mode-map "\es" 'center-line)
  45       (define-key nroff-mode-map "\e?" 'count-text-lines)
  46       (define-key nroff-mode-map "\n"  'electric-nroff-newline)
  47       (define-key nroff-mode-map "\en" 'forward-text-line)
  48       (define-key nroff-mode-map "\ep" 'backward-text-line)))
  49
  50 ;;;###autoload
  51 (defun nroff-mode ()
  52   "Major mode for editing text intended for nroff to format.
  53 \\{nroff-mode-map}
  54 Turning on Nroff mode runs `text-mode-hook', then `nroff-mode-hook'.
  55 Also, try `nroff-electric-mode', for automatically inserting
  56 closing requests for requests that are used in matched pairs."
  57   (interactive)
  58   (kill-all-local-variables)
  59   (use-local-map nroff-mode-map)
  60   (setq mode-name "Nroff")
  61   (setq major-mode 'nroff-mode)
  62   (set-syntax-table text-mode-syntax-table)
  63   (setq local-abbrev-table nroff-mode-abbrev-table)
  64   (make-local-variable 'nroff-electric-mode)
  65   (setq nroff-electric-mode nil)
  66   (make-local-variable 'outline-regexp)
  67   (setq outline-regexp "\\.H[ ]+[1-7]+ ")
  68   (make-local-variable 'outline-level)
  69   (setq outline-level 'nroff-outline-level)
  70   ;; now define a bunch of variables for use by commands in this mode
  71   (make-local-variable 'page-delimiter)
  72   (setq page-delimiter "^\\.\\(bp\\|SK\\|OP\\)")
  73   (make-local-variable 'paragraph-start)
  74   (setq paragraph-start (concat "^[.']\\|" paragraph-start))
  75   (make-local-variable 'paragraph-separate)
  76   (setq paragraph-separate (concat "^[.']\\|" paragraph-separate))
  77   ;; comment syntax added by mit-erl!gildea 18 Apr 86
  78   (make-local-variable 'comment-start)
  79   (setq comment-start "\\\" ")
  80   (make-local-variable 'comment-start-skip)
  81   (setq comment-start-skip "\\\\\"[ \t]*")
  82   (make-local-variable 'comment-column)
  83   (setq comment-column 24)
  84   (make-local-variable 'comment-indent-function)
  85   (setq comment-indent-function 'nroff-comment-indent)
  86   (run-hooks 'text-mode-hook 'nroff-mode-hook))
  87
  88 (defun nroff-outline-level ()
  89   (save-excursion
  90     (looking-at outline-regexp)
  91     (skip-chars-forward ".H ")
  92     (string-to-int (buffer-substring (point) (+ 1 (point))))))
  93
  94 ;;; Compute how much to indent a comment in nroff/troff source.
  95 ;;; By mit-erl!gildea April 86
  96 (defun nroff-comment-indent ()
  97   "Compute indent for an nroff/troff comment.
  98 Puts a full-stop before comments on a line by themselves."
  99   (let ((pt (point)))
 100     (unwind-protect
 101         (progn
 102           (skip-chars-backward " \t")
 103           (if (bolp)
 104               (progn
 105                 (setq pt (1+ pt))
 106                 (insert ?.)
 107                 1)
 108             (if (save-excursion
 109                   (backward-char 1)
 110                   (looking-at "^[.']"))
 111                 1
 112               (max comment-column
 113                    (* 8 (/ (+ (current-column)
 114                               9) 8)))))) ; add 9 to ensure at least two blanks
 115       (goto-char pt))))
 116
 117 (defun count-text-lines (start end &optional print)
 118   "Count lines in region, except for nroff request lines.
 119 All lines not starting with a period are counted up.
 120 Interactively, print result in echo area.
 121 Noninteractively, return number of non-request lines from START to END."
 122   (interactive "r\np")
 123   (if print
 124       (message "Region has %d text lines" (count-text-lines start end))
 125     (save-excursion
 126       (save-restriction
 127         (narrow-to-region start end)
 128         (goto-char (point-min))
 129         (- (buffer-size) (forward-text-line (buffer-size)))))))
 130
 131 (defun forward-text-line (&optional cnt)
 132   "Go forward one nroff text line, skipping lines of nroff requests.
 133 An argument is a repeat count; if negative, move backward."
 134   (interactive "p")
 135   (if (not cnt) (setq cnt 1))
 136   (while (and (> cnt 0) (not (eobp)))
 137     (forward-line 1)
 138     (while (and (not (eobp)) (looking-at "[.']."))
 139       (forward-line 1))
 140     (setq cnt (- cnt 1)))
 141   (while (and (< cnt 0) (not (bobp)))
 142     (forward-line -1)
 143     (while (and (not (bobp))
 144                 (looking-at "[.']."))
 145       (forward-line -1))
 146     (setq cnt (+ cnt 1)))
 147   cnt)
 148
 149 (defun backward-text-line (&optional cnt)
 150   "Go backward one nroff text line, skipping lines of nroff requests.
 151 An argument is a repeat count; negative means move forward."
 152   (interactive "p")
 153   (forward-text-line (- cnt)))
 154
 155 (defconst nroff-brace-table
 156   '((".(b" . ".)b")
 157     (".(l" . ".)l")
 158     (".(q" . ".)q")
 159     (".(c" . ".)c")
 160     (".(x" . ".)x")
 161     (".(z" . ".)z")
 162     (".(d" . ".)d")
 163     (".(f" . ".)f")
 164     (".LG" . ".NL")
 165     (".SM" . ".NL")
 166     (".LD" . ".DE")
 167     (".CD" . ".DE")
 168     (".BD" . ".DE")
 169     (".DS" . ".DE")
 170     (".DF" . ".DE")
 171     (".FS" . ".FE")
 172     (".KS" . ".KE")
 173     (".KF" . ".KE")
 174     (".LB" . ".LE")
 175     (".AL" . ".LE")
 176     (".BL" . ".LE")
 177     (".DL" . ".LE")
 178     (".ML" . ".LE")
 179     (".RL" . ".LE")
 180     (".VL" . ".LE")
 181     (".RS" . ".RE")
 182     (".TS" . ".TE")
 183     (".EQ" . ".EN")
 184     (".PS" . ".PE")
 185     (".BS" . ".BE")
 186     (".G1" . ".G2")                     ; grap
 187     (".na" . ".ad b")
 188     (".nf" . ".fi")
 189     (".de" . "..")))
 190
 191 (defun electric-nroff-newline (arg)
 192   "Insert newline for nroff mode; special if electric-nroff mode.
 193 In `electric-nroff-mode', if ending a line containing an nroff opening request,
 194 automatically inserts the matching closing request after point."
 195   (interactive "P")
 196   (let ((completion (save-excursion
 197                       (beginning-of-line)
 198                       (and (null arg)
 199                            nroff-electric-mode
 200                            (<= (point) (- (point-max) 3))
 201                            (cdr (assoc (buffer-substring (point)
 202                                                          (+ 3 (point)))
 203                                        nroff-brace-table)))))
 204         (needs-nl (not (looking-at "[ \t]*$"))))
 205     (if (null completion)
 206         (newline (prefix-numeric-value arg))
 207       (save-excursion
 208         (insert "\n\n" completion)
 209         (if needs-nl (insert "\n")))
 210       (forward-char 1))))
 211
 212 (defun electric-nroff-mode (&optional arg)
 213   "Toggle `nroff-electric-newline' minor mode.
 214 `nroff-electric-newline' forces Emacs to check for an nroff request at the
 215 beginning of the line, and insert the matching closing request if necessary.
 216 This command toggles that mode (off->on, on->off), with an argument,
 217 turns it on iff arg is positive, otherwise off."
 218   (interactive "P")
 219   (or (eq major-mode 'nroff-mode) (error "Must be in nroff mode"))
 220   (or (assq 'nroff-electric-mode minor-mode-alist)
 221       (setq minor-mode-alist (append minor-mode-alist
 222                                      (list '(nroff-electric-mode
 223                                              " Electric")))))
 224   (setq nroff-electric-mode
 225         (cond ((null arg) (null nroff-electric-mode))
 226               (t (> (prefix-numeric-value arg) 0)))))
 227
 228 ;;; nroff-mode.el ends here