code.delx.au - gnu-emacs/blob - lisp/mail/smtpmail.el

   1 ;;; smtpmail.el --- simple SMTP protocol (RFC 821) for sending mail
   2
   3 ;; Copyright (C) 1995, 1996, 2001, 2002, 2003, 2004
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Author: Tomoji Kagatani <kagatani@rbc.ncl.omron.co.jp>
   7 ;; Maintainer: Simon Josefsson <simon@josefsson.org>
   8 ;; w32 Maintainer: Brian D. Carlstrom <bdc@ai.mit.edu>
   9 ;; ESMTP support: Simon Leinen <simon@switch.ch>
  10 ;; Hacked by Mike Taylor, 11th October 1999 to add support for
  11 ;; automatically appending a domain to RCPT TO: addresses.
  12 ;; AUTH=LOGIN support: Stephen Cranefield <scranefield@infoscience.otago.ac.nz>
  13 ;; Keywords: mail
  14
  15 ;; This file is part of GNU Emacs.
  16
  17 ;; GNU Emacs is free software; you can redistribute it and/or modify
  18 ;; it under the terms of the GNU General Public License as published by
  19 ;; the Free Software Foundation; either version 2, or (at your option)
  20 ;; any later version.
  21
  22 ;; GNU Emacs is distributed in the hope that it will be useful,
  23 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  24 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  25 ;; GNU General Public License for more details.
  26
  27 ;; You should have received a copy of the GNU General Public License
  28 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  29 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  30 ;; Boston, MA 02111-1307, USA.
  31
  32 ;;; Commentary:
  33
  34 ;; Send Mail to smtp host from smtpmail temp buffer.
  35
  36 ;; Please add these lines in your .emacs(_emacs) or use customize.
  37 ;;
  38 ;;(setq send-mail-function 'smtpmail-send-it) ; if you use `mail'
  39 ;;(setq message-send-mail-function 'smtpmail-send-it) ; if you use message/Gnus
  40 ;;(setq smtpmail-default-smtp-server "YOUR SMTP HOST")
  41 ;;(setq smtpmail-local-domain "YOUR DOMAIN NAME")
  42 ;;(setq smtpmail-sendto-domain "YOUR DOMAIN NAME")
  43 ;;(setq smtpmail-debug-info t) ; only to debug problems
  44 ;;(setq smtpmail-auth-credentials  ; or use ~/.authinfo
  45 ;;      '(("YOUR SMTP HOST" 25 "username" "password")))
  46 ;;(setq smtpmail-starttls-credentials
  47 ;;      '(("YOUR SMTP HOST" 25 "~/.my_smtp_tls.key" "~/.my_smtp_tls.cert")))
  48 ;; Where the 25 equals the value of `smtpmail-smtp-service', it can be an
  49 ;; integer or a string, just as long as they match (eq).
  50
  51 ;; To queue mail, set smtpmail-queue-mail to t and use
  52 ;; smtpmail-send-queued-mail to send.
  53
  54 ;; Modified by Stephen Cranefield <scranefield@infoscience.otago.ac.nz>,
  55 ;; 22/6/99, to support SMTP Authentication by the AUTH=LOGIN mechanism.
  56 ;; See http://help.netscape.com/products/server/messaging/3x/info/smtpauth.html
  57 ;; Rewritten by Simon Josefsson to use same credential variable as AUTH
  58 ;; support below.
  59
  60 ;; Modified by Simon Josefsson <jas@pdc.kth.se>, 22/2/99, to support SMTP
  61 ;; Authentication by the AUTH mechanism.
  62 ;; See http://www.ietf.org/rfc/rfc2554.txt
  63
  64 ;; Modified by Simon Josefsson <simon@josefsson.org>, 2000-10-07, to support
  65 ;; STARTTLS.  Requires external program
  66 ;; ftp://ftp.opaopa.org/pub/elisp/starttls-*.tar.gz.
  67 ;; See http://www.ietf.org/rfc/rfc2246.txt, http://www.ietf.org/rfc/rfc2487.txt
  68
  69 ;;; Code:
  70
  71 (require 'sendmail)
  72 (autoload 'starttls-open-stream "starttls")
  73 (autoload 'starttls-negotiate "starttls")
  74 (autoload 'mail-strip-quoted-names "mail-utils")
  75 (autoload 'message-make-date "message")
  76 (autoload 'message-make-message-id "message")
  77 (autoload 'rfc2104-hash "rfc2104")
  78 (autoload 'netrc-parse "netrc")
  79 (autoload 'netrc-machine "netrc")
  80 (autoload 'netrc-get "netrc")
  81
  82 ;;;
  83 (defgroup smtpmail nil
  84   "SMTP protocol for sending mail."
  85   :group 'mail)
  86
  87
  88 (defcustom smtpmail-default-smtp-server nil
  89   "*Specify default SMTP server.
  90 This only has effect if you specify it before loading the smtpmail library."
  91   :type '(choice (const nil) string)
  92   :group 'smtpmail)
  93
  94 (defcustom smtpmail-smtp-server
  95   (or (getenv "SMTPSERVER") smtpmail-default-smtp-server)
  96   "*The name of the host running SMTP server."
  97   :type '(choice (const nil) string)
  98   :group 'smtpmail)
  99
 100 (defcustom smtpmail-smtp-service 25
 101   "*SMTP service port number.
 102 The default value would be \"smtp\" or 25 ."
 103   :type '(choice (integer :tag "Port") (string :tag "Service"))
 104   :group 'smtpmail)
 105
 106 (defcustom smtpmail-local-domain nil
 107   "*Local domain name without a host name.
 108 If the function (system-name) returns the full internet address,
 109 don't define this value."
 110   :type '(choice (const nil) string)
 111   :group 'smtpmail)
 112
 113 (defcustom smtpmail-sendto-domain nil
 114   "*Local domain name without a host name.
 115 This is appended (with an @-sign) to any specified recipients which do
 116 not include an @-sign, so that each RCPT TO address is fully qualified.
 117 \(Some configurations of sendmail require this.)
 118
 119 Don't bother to set this unless you have get an error like:
 120         Sending failed; SMTP protocol error
 121 when sending mail, and the *trace of SMTP session to <somewhere>*
 122 buffer includes an exchange like:
 123         RCPT TO: <someone>
 124         501 <someone>: recipient address must contain a domain
 125 "
 126   :type '(choice (const nil) string)
 127   :group 'smtpmail)
 128
 129 (defcustom smtpmail-debug-info nil
 130   "Whether to print info in buffer *trace of SMTP session to <somewhere>*.
 131 See also `smtpmail-debug-verb' which determines if the SMTP protocol should
 132 be verbose as well."
 133   :type 'boolean
 134   :group 'smtpmail)
 135
 136 (defcustom smtpmail-debug-verb nil
 137   "Whether this library sends the SMTP VERB command or not.
 138 The commands enables verbose information from the SMTP server."
 139   :type 'boolean
 140   :group 'smtpmail)
 141
 142 (defcustom smtpmail-code-conv-from nil ;; *junet*
 143   "*smtpmail code convert from this code to *internal*..for tiny-mime.."
 144   :type 'boolean
 145   :group 'smtpmail)
 146
 147 (defcustom smtpmail-queue-mail nil
 148   "*Specify if mail is queued (if t) or sent immediately (if nil).
 149 If queued, it is stored in the directory `smtpmail-queue-dir'
 150 and sent with `smtpmail-send-queued-mail'."
 151   :type 'boolean
 152   :group 'smtpmail)
 153
 154 (defcustom smtpmail-queue-dir "~/Mail/queued-mail/"
 155   "*Directory where `smtpmail.el' stores queued mail."
 156   :type 'directory
 157   :group 'smtpmail)
 158
 159 (defcustom smtpmail-auth-credentials "~/.authinfo"
 160   "Specify username and password for servers, directly or via .netrc file.
 161 This variable can either be a filename pointing to a file in netrc(5)
 162 format, or list of four-element lists that contain, in order,
 163 `servername' (a string), `port' (an integer), `user' (a string) and
 164 `password' (a string, or nil to query the user when needed).  If you
 165 need to enter a `realm' too, add it to the user string, so that it
 166 looks like `user@realm'."
 167   :type '(choice file
 168                  (repeat (list (string  :tag "Server")
 169                        (integer :tag "Port")
 170                        (string  :tag "Username")
 171                        (choice (const :tag "Query when needed" nil)
 172                                        (string  :tag "Password")))))
 173   :version "22.1"
 174   :group 'smtpmail)
 175
 176 (defcustom smtpmail-starttls-credentials '(("" 25 "" ""))
 177   "Specify STARTTLS keys and certificates for servers.
 178 This is a list of four-element list with `servername' (a string),
 179 `port' (an integer), `key' (a filename) and `certificate' (a filename)."
 180   :type '(repeat (list (string  :tag "Server")
 181                        (integer :tag "Port")
 182                        (file    :tag "Key")
 183                        (file    :tag "Certificate")))
 184   :version "21.1"
 185   :group 'smtpmail)
 186
 187 (defcustom smtpmail-warn-about-unknown-extensions nil
 188   "*If set, print warnings about unknown SMTP extensions.
 189 This is mainly useful for development purposes, to learn about
 190 new SMTP extensions that might be useful to support."
 191   :type 'boolean
 192   :version "21.1"
 193   :group 'smtpmail)
 194
 195 (defvar smtpmail-queue-index-file "index"
 196   "File name of queued mail index,
 197 This is relative to `smtpmail-queue-dir'.")
 198
 199 (defvar smtpmail-address-buffer)
 200 (defvar smtpmail-recipient-address-list)
 201
 202 (defvar smtpmail-queue-counter 0)
 203
 204 ;; Buffer-local variable.
 205 (defvar smtpmail-read-point)
 206
 207 (defvar smtpmail-queue-index (concat smtpmail-queue-dir
 208                                      smtpmail-queue-index-file))
 209
 210 (defconst smtpmail-auth-supported '(cram-md5 login)
 211   "List of supported SMTP AUTH mechanisms.")
 212
 213 ;;;
 214 ;;;
 215 ;;;
 216
 217 (defvar smtpmail-mail-address nil
 218   "Value to use for envelope-from address for mail from ambient buffer.")
 219
 220 ;;;###autoload
 221 (defun smtpmail-send-it ()
 222   (let ((errbuf (if mail-interactive
 223                     (generate-new-buffer " smtpmail errors")
 224                   0))
 225         (tembuf (generate-new-buffer " smtpmail temp"))
 226         (case-fold-search nil)
 227         delimline
 228         (mailbuf (current-buffer))
 229         ;; Examine this variable now, so that
 230         ;; local binding in the mail buffer will take effect.
 231         (smtpmail-mail-address
 232          (or (and mail-specify-envelope-from (mail-envelope-from))
 233              user-mail-address))
 234         (smtpmail-code-conv-from
 235          (if enable-multibyte-characters
 236              (let ((sendmail-coding-system smtpmail-code-conv-from))
 237                (select-message-coding-system)))))
 238     (unwind-protect
 239         (save-excursion
 240           (set-buffer tembuf)
 241           (erase-buffer)
 242           (insert-buffer-substring mailbuf)
 243           (goto-char (point-max))
 244           ;; require one newline at the end.
 245           (or (= (preceding-char) ?\n)
 246               (insert ?\n))
 247           ;; Change header-delimiter to be what sendmail expects.
 248           (mail-sendmail-undelimit-header)
 249           (setq delimline (point-marker))
 250 ;;        (sendmail-synch-aliases)
 251           (if mail-aliases
 252               (expand-mail-aliases (point-min) delimline))
 253           (goto-char (point-min))
 254           ;; ignore any blank lines in the header
 255           (while (and (re-search-forward "\n\n\n*" delimline t)
 256                       (< (point) delimline))
 257             (replace-match "\n"))
 258           (let ((case-fold-search t))
 259             ;; We used to process Resent-... headers here,
 260             ;; but it was not done properly, and the job
 261             ;; is done correctly in smtpmail-deduce-address-list.
 262             ;; Don't send out a blank subject line
 263             (goto-char (point-min))
 264             (if (re-search-forward "^Subject:\\([ \t]*\n\\)+\\b" delimline t)
 265                 (replace-match "")
 266               ;; This one matches a Subject just before the header delimiter.
 267               (if (and (re-search-forward "^Subject:\\([ \t]*\n\\)+" delimline t)
 268                        (= (match-end 0) delimline))
 269                   (replace-match "")))
 270             ;; Put the "From:" field in unless for some odd reason
 271             ;; they put one in themselves.
 272             (goto-char (point-min))
 273             (if (not (re-search-forward "^From:" delimline t))
 274                 (let* ((login smtpmail-mail-address)
 275                        (fullname (user-full-name)))
 276                   (cond ((eq mail-from-style 'angles)
 277                          (insert "From: " fullname)
 278                          (let ((fullname-start (+ (point-min) 6))
 279                                (fullname-end (point-marker)))
 280                            (goto-char fullname-start)
 281                            ;; Look for a character that cannot appear unquoted
 282                            ;; according to RFC 822.
 283                            (if (re-search-forward "[^- !#-'*+/-9=?A-Z^-~]"
 284                                                   fullname-end 1)
 285                                (progn
 286                                  ;; Quote fullname, escaping specials.
 287                                  (goto-char fullname-start)
 288                                  (insert "\"")
 289                                  (while (re-search-forward "[\"\\]"
 290                                                            fullname-end 1)
 291                                    (replace-match "\\\\\\&" t))
 292                                  (insert "\""))))
 293                          (insert " <" login ">\n"))
 294                         ((eq mail-from-style 'parens)
 295                          (insert "From: " login " (")
 296                          (let ((fullname-start (point)))
 297                            (insert fullname)
 298                            (let ((fullname-end (point-marker)))
 299                              (goto-char fullname-start)
 300                              ;; RFC 822 says \ and nonmatching parentheses
 301                              ;; must be escaped in comments.
 302                              ;; Escape every instance of ()\ ...
 303                              (while (re-search-forward "[()\\]" fullname-end 1)
 304                                (replace-match "\\\\\\&" t))
 305                              ;; ... then undo escaping of matching parentheses,
 306                              ;; including matching nested parentheses.
 307                              (goto-char fullname-start)
 308                              (while (re-search-forward
 309                                      "\\(\\=\\|[^\\]\\(\\\\\\\\\\)*\\)\\\\(\\(\\([^\\]\\|\\\\\\\\\\)*\\)\\\\)"
 310                                      fullname-end 1)
 311                                (replace-match "\\1(\\3)" t)
 312                                (goto-char fullname-start))))
 313                          (insert ")\n"))
 314                         ((null mail-from-style)
 315                          (insert "From: " login "\n")))))
 316             ;; Insert a `Message-Id:' field if there isn't one yet.
 317             (goto-char (point-min))
 318             (unless (re-search-forward "^Message-Id:" delimline t)
 319               (insert "Message-Id: " (message-make-message-id) "\n"))
 320             ;; Insert a `Date:' field if there isn't one yet.
 321             (goto-char (point-min))
 322             (unless (re-search-forward "^Date:" delimline t)
 323               (insert "Date: " (message-make-date) "\n"))
 324             ;; Insert an extra newline if we need it to work around
 325             ;; Sun's bug that swallows newlines.
 326             (goto-char (1+ delimline))
 327             (if (eval mail-mailer-swallows-blank-line)
 328                 (newline))
 329             ;; Find and handle any FCC fields.
 330             (goto-char (point-min))
 331             (if (re-search-forward "^FCC:" delimline t)
 332                 (mail-do-fcc delimline))
 333             (if mail-interactive
 334                 (with-current-buffer errbuf
 335                   (erase-buffer))))
 336           ;;
 337           ;;
 338           ;;
 339           (setq smtpmail-address-buffer (generate-new-buffer "*smtp-mail*"))
 340           (setq smtpmail-recipient-address-list
 341                     (smtpmail-deduce-address-list tembuf (point-min) delimline))
 342           (kill-buffer smtpmail-address-buffer)
 343
 344           (smtpmail-do-bcc delimline)
 345           ; Send or queue
 346           (if (not smtpmail-queue-mail)
 347               (if (not (null smtpmail-recipient-address-list))
 348                   (if (not (smtpmail-via-smtp
 349                             smtpmail-recipient-address-list tembuf))
 350                       (error "Sending failed; SMTP protocol error"))
 351                 (error "Sending failed; no recipients"))
 352             (let* ((file-data
 353                     (expand-file-name
 354                      (format "%s_%i"
 355                              (format-time-string "%Y-%m-%d_%H:%M:%S")
 356                              (setq smtpmail-queue-counter
 357                                    (1+ smtpmail-queue-counter)))
 358                      smtpmail-queue-dir))
 359                    (file-data (convert-standard-filename file-data))
 360                    (file-elisp (concat file-data ".el"))
 361                    (buffer-data (create-file-buffer file-data))
 362                    (buffer-elisp (create-file-buffer file-elisp))
 363                    (buffer-scratch "*queue-mail*"))
 364               (unless (file-exists-p smtpmail-queue-dir)
 365                 (make-directory smtpmail-queue-dir t))
 366               (with-current-buffer buffer-data
 367                 (erase-buffer)
 368                 (insert-buffer tembuf)
 369                 (write-file file-data)
 370                 (set-buffer buffer-elisp)
 371                 (erase-buffer)
 372                 (insert (concat
 373                          "(setq smtpmail-recipient-address-list '"
 374                          (prin1-to-string smtpmail-recipient-address-list)
 375                          ")\n"))
 376                 (write-file file-elisp)
 377                 (set-buffer (generate-new-buffer buffer-scratch))
 378                 (insert (concat file-data "\n"))
 379                 (append-to-file (point-min)
 380                                 (point-max)
 381                                 smtpmail-queue-index)
 382                 )
 383               (kill-buffer buffer-scratch)
 384               (kill-buffer buffer-data)
 385               (kill-buffer buffer-elisp))))
 386       (kill-buffer tembuf)
 387       (if (bufferp errbuf)
 388           (kill-buffer errbuf)))))
 389
 390 ;;;###autoload
 391 (defun smtpmail-send-queued-mail ()
 392   "Send mail that was queued as a result of setting `smtpmail-queue-mail'."
 393   (interactive)
 394   (with-temp-buffer
 395     ;;; Get index, get first mail, send it, update index, get second
 396     ;;; mail, send it, etc...
 397     (let ((file-msg ""))
 398       (insert-file-contents smtpmail-queue-index)
 399       (beginning-of-buffer)
 400       (while (not (eobp))
 401         (setq file-msg (buffer-substring (point) (line-end-position)))
 402         (load file-msg)
 403         ;; Insert the message literally: it is already encoded as per
 404         ;; the MIME headers, and code conversions might guess the
 405         ;; encoding wrongly.
 406         (with-temp-buffer
 407           (let ((coding-system-for-read 'no-conversion))
 408             (insert-file-contents file-msg))
 409           (let ((smtpmail-mail-address
 410                  (or (and mail-specify-envelope-from (mail-envelope-from))
 411                      user-mail-address)))
 412             (if (not (null smtpmail-recipient-address-list))
 413                 (if (not (smtpmail-via-smtp smtpmail-recipient-address-list
 414                                             (current-buffer)))
 415                     (error "Sending failed; SMTP protocol error"))
 416               (error "Sending failed; no recipients"))))
 417         (delete-file file-msg)
 418         (delete-file (concat file-msg ".el"))
 419         (delete-region (point-at-bol) (point-at-bol 2)))
 420       (write-region (point-min) (point-max) smtpmail-queue-index))))
 421
 422 ;(defun smtpmail-via-smtp (host,port,sender,destination,smtpmail-text-buffer)
 423
 424 (defun smtpmail-fqdn ()
 425   (if smtpmail-local-domain
 426       (concat (system-name) "." smtpmail-local-domain)
 427     (system-name)))
 428
 429 (defsubst smtpmail-cred-server (cred)
 430   (nth 0 cred))
 431
 432 (defsubst smtpmail-cred-port (cred)
 433   (nth 1 cred))
 434
 435 (defsubst smtpmail-cred-key (cred)
 436   (nth 2 cred))
 437
 438 (defsubst smtpmail-cred-user (cred)
 439   (nth 2 cred))
 440
 441 (defsubst smtpmail-cred-cert (cred)
 442   (nth 3 cred))
 443
 444 (defsubst smtpmail-cred-passwd (cred)
 445   (nth 3 cred))
 446
 447 (defun smtpmail-find-credentials (cred server port)
 448   (catch 'done
 449     (let ((l cred) el)
 450       (while (setq el (pop l))
 451         (when (and (equal server (smtpmail-cred-server el))
 452                    (equal port (smtpmail-cred-port el)))
 453           (throw 'done el))))))
 454
 455 (defun smtpmail-maybe-append-domain (recipient)
 456   (if (or (not smtpmail-sendto-domain)
 457           (string-match "@" recipient))
 458       recipient
 459     (concat recipient "@" smtpmail-sendto-domain)))
 460
 461 (defun smtpmail-intersection (list1 list2)
 462   (let ((result nil))
 463     (dolist (el2 list2)
 464       (when (memq el2 list1)
 465         (push el2 result)))
 466     (nreverse result)))
 467
 468 (defun smtpmail-open-stream (process-buffer host port)
 469   (let ((cred (smtpmail-find-credentials
 470                smtpmail-starttls-credentials host port)))
 471     (if (null (and cred (condition-case ()
 472                             (progn
 473                               (require 'starttls)
 474                               (call-process (if starttls-use-gnutls
 475                                                 starttls-gnutls-program
 476                                               starttls-program)))
 477                           (error nil))))
 478         ;; The normal case.
 479         (open-network-stream "SMTP" process-buffer host port)
 480       (let* ((cred-key (smtpmail-cred-key cred))
 481              (cred-cert (smtpmail-cred-cert cred))
 482              (starttls-extra-args
 483               (append
 484                starttls-extra-args
 485                (when (and (stringp cred-key) (stringp cred-cert)
 486                           (file-regular-p
 487                            (setq cred-key (expand-file-name cred-key)))
 488                           (file-regular-p
 489                            (setq cred-cert (expand-file-name cred-cert))))
 490                  (list "--key-file" cred-key "--cert-file" cred-cert))))
 491              (starttls-extra-arguments
 492               (append
 493                starttls-extra-arguments
 494                (when (and (stringp cred-key) (stringp cred-cert)
 495                           (file-regular-p
 496                            (setq cred-key (expand-file-name cred-key)))
 497                           (file-regular-p
 498                            (setq cred-cert (expand-file-name cred-cert))))
 499                  (list "--x509keyfile" cred-key "--x509certfile" cred-cert)))))
 500         (starttls-open-stream "SMTP" process-buffer host port)))))
 501
 502 (defun smtpmail-try-auth-methods (process supported-extensions host port)
 503   (let* ((mechs (cdr-safe (assoc 'auth supported-extensions)))
 504          (mech (car (smtpmail-intersection smtpmail-auth-supported mechs)))
 505          (cred (if (stringp smtpmail-auth-credentials)
 506                    (let* ((netrc (netrc-parse smtpmail-auth-credentials))
 507                           (port-name (format "%s" (or port "smtp")))
 508                           (hostentry (netrc-machine netrc host port-name
 509                                                     port-name)))
 510                      (when hostentry
 511                        (list host port
 512                              (netrc-get hostentry "login")
 513                              (netrc-get hostentry "password"))))
 514                  (smtpmail-find-credentials
 515                   smtpmail-auth-credentials host port)))
 516          (passwd (when cred
 517                    (or (smtpmail-cred-passwd cred)
 518                        (read-passwd
 519                         (format "SMTP password for %s:%s: "
 520                                 (smtpmail-cred-server cred)
 521                                 (smtpmail-cred-port cred))))))
 522          ret)
 523     (when (and cred mech)
 524       (cond
 525        ((eq mech 'cram-md5)
 526         (smtpmail-send-command process (upcase (format "AUTH %s" mech)))
 527         (if (or (null (car (setq ret (smtpmail-read-response process))))
 528                 (not (integerp (car ret)))
 529                 (>= (car ret) 400))
 530             (throw 'done nil))
 531         (when (eq (car ret) 334)
 532           (let* ((challenge (substring (cadr ret) 4))
 533                  (decoded (base64-decode-string challenge))
 534                  (hash (rfc2104-hash 'md5 64 16 passwd decoded))
 535                  (response (concat (smtpmail-cred-user cred) " " hash))
 536                  (encoded (base64-encode-string response)))
 537             (smtpmail-send-command process (format "%s" encoded))
 538             (if (or (null (car (setq ret (smtpmail-read-response process))))
 539                     (not (integerp (car ret)))
 540                     (>= (car ret) 400))
 541                 (throw 'done nil)))))
 542        ((eq mech 'login)
 543         (smtpmail-send-command process "AUTH LOGIN")
 544         (if (or (null (car (setq ret (smtpmail-read-response process))))
 545                 (not (integerp (car ret)))
 546                 (>= (car ret) 400))
 547             (throw 'done nil))
 548         (smtpmail-send-command
 549          process (base64-encode-string (smtpmail-cred-user cred)))
 550         (if (or (null (car (setq ret (smtpmail-read-response process))))
 551                 (not (integerp (car ret)))
 552                 (>= (car ret) 400))
 553             (throw 'done nil))
 554         (smtpmail-send-command process (base64-encode-string passwd))
 555         (if (or (null (car (setq ret (smtpmail-read-response process))))
 556                 (not (integerp (car ret)))
 557                 (>= (car ret) 400))
 558             (throw 'done nil)))
 559        (t
 560         (error "Mechanism %s not implemented" mech)))
 561       ;; Remember the password.
 562       (when (and (not (stringp smtpmail-auth-credentials))
 563                  (null (smtpmail-cred-passwd cred)))
 564         (setcar (cdr (cdr (cdr cred))) passwd)))))
 565
 566 (defun smtpmail-via-smtp (recipient smtpmail-text-buffer)
 567   (let ((process nil)
 568         (host (or smtpmail-smtp-server
 569                   (error "`smtpmail-smtp-server' not defined")))
 570         (port smtpmail-smtp-service)
 571         ;; smtpmail-mail-address should be set to the appropriate
 572         ;; buffer-local value by the caller, but in case not:
 573         (envelope-from (or smtpmail-mail-address
 574                            (and mail-specify-envelope-from
 575                                 (mail-envelope-from))
 576                            user-mail-address))
 577         response-code
 578         greeting
 579         process-buffer
 580         (supported-extensions '()))
 581     (unwind-protect
 582         (catch 'done
 583           ;; get or create the trace buffer
 584           (setq process-buffer
 585                 (get-buffer-create (format "*trace of SMTP session to %s*" host)))
 586
 587           ;; clear the trace buffer of old output
 588           (with-current-buffer process-buffer
 589             (erase-buffer))
 590
 591           ;; open the connection to the server
 592           (setq process (smtpmail-open-stream process-buffer host port))
 593           (and (null process) (throw 'done nil))
 594
 595           ;; set the send-filter
 596           (set-process-filter process 'smtpmail-process-filter)
 597
 598           (with-current-buffer process-buffer
 599             (set-buffer-process-coding-system 'raw-text-unix 'raw-text-unix)
 600             (make-local-variable 'smtpmail-read-point)
 601             (setq smtpmail-read-point (point-min))
 602
 603
 604             (if (or (null (car (setq greeting (smtpmail-read-response process))))
 605                     (not (integerp (car greeting)))
 606                     (>= (car greeting) 400))
 607                 (throw 'done nil)
 608               )
 609
 610             (let ((do-ehlo t)
 611                   (do-starttls t))
 612               (while do-ehlo
 613             ;; EHLO
 614             (smtpmail-send-command process (format "EHLO %s" (smtpmail-fqdn)))
 615
 616             (if (or (null (car (setq response-code
 617                                      (smtpmail-read-response process))))
 618                     (not (integerp (car response-code)))
 619                     (>= (car response-code) 400))
 620                 (progn
 621                   ;; HELO
 622                   (smtpmail-send-command
 623                    process (format "HELO %s" (smtpmail-fqdn)))
 624
 625                   (if (or (null (car (setq response-code
 626                                            (smtpmail-read-response process))))
 627                           (not (integerp (car response-code)))
 628                           (>= (car response-code) 400))
 629                       (throw 'done nil)))
 630               (dolist (line (cdr (cdr response-code)))
 631                 (let ((name (mapcar (lambda (s) (intern (downcase s)))
 632                                     (split-string (substring line 4) "[ ]"))))
 633                   (and (eq (length name) 1)
 634                        (setq name (car name)))
 635                     (and name
 636                        (cond ((memq (if (consp name) (car name) name)
 637                                     '(verb xvrb 8bitmime onex xone
 638                                                   expn size dsn etrn
 639                                       enhancedstatuscodes
 640                                       help xusr
 641                                       auth=login auth starttls))
 642                                 (setq supported-extensions
 643                                       (cons name supported-extensions)))
 644                                (smtpmail-warn-about-unknown-extensions
 645                               (message "Unknown extension %s" name)))))))
 646
 647             (if (and do-starttls
 648                      (smtpmail-find-credentials smtpmail-starttls-credentials host port)
 649                      (member 'starttls supported-extensions)
 650                      (numberp (process-id process)))
 651                 (progn
 652                   (smtpmail-send-command process (format "STARTTLS"))
 653                   (if (or (null (car (setq response-code (smtpmail-read-response process))))
 654                           (not (integerp (car response-code)))
 655                           (>= (car response-code) 400))
 656                       (throw 'done nil))
 657                   (starttls-negotiate process)
 658                   (setq do-starttls nil))
 659               (setq do-ehlo nil))))
 660
 661             (smtpmail-try-auth-methods process supported-extensions host port)
 662
 663             (if (or (member 'onex supported-extensions)
 664                     (member 'xone supported-extensions))
 665                 (progn
 666                   (smtpmail-send-command process (format "ONEX"))
 667                   (if (or (null (car (setq response-code (smtpmail-read-response process))))
 668                           (not (integerp (car response-code)))
 669                           (>= (car response-code) 400))
 670                       (throw 'done nil))))
 671
 672             (if (and smtpmail-debug-verb
 673                      (or (member 'verb supported-extensions)
 674                          (member 'xvrb supported-extensions)))
 675                 (progn
 676                   (smtpmail-send-command process (format "VERB"))
 677                   (if (or (null (car (setq response-code (smtpmail-read-response process))))
 678                           (not (integerp (car response-code)))
 679                           (>= (car response-code) 400))
 680                       (throw 'done nil))))
 681
 682             (if (member 'xusr supported-extensions)
 683                 (progn
 684                   (smtpmail-send-command process (format "XUSR"))
 685                   (if (or (null (car (setq response-code (smtpmail-read-response process))))
 686                           (not (integerp (car response-code)))
 687                           (>= (car response-code) 400))
 688                       (throw 'done nil))))
 689
 690             ;; MAIL FROM:<sender>
 691             (let ((size-part
 692                    (if (or (member 'size supported-extensions)
 693                            (assoc 'size supported-extensions))
 694                        (format " SIZE=%d"
 695                                (with-current-buffer smtpmail-text-buffer
 696                                  ;; size estimate:
 697                                  (+ (- (point-max) (point-min))
 698                                     ;; Add one byte for each change-of-line
 699                                     ;; because of CR-LF representation:
 700                                     (count-lines (point-min) (point-max)))))
 701                      ""))
 702                   (body-part
 703                    (if (member '8bitmime supported-extensions)
 704                        ;; FIXME:
 705                        ;; Code should be added here that transforms
 706                        ;; the contents of the message buffer into
 707                        ;; something the receiving SMTP can handle.
 708                        ;; For a receiver that supports 8BITMIME, this
 709                        ;; may mean converting BINARY to BASE64, or
 710                        ;; adding Content-Transfer-Encoding and the
 711                        ;; other MIME headers.  The code should also
 712                        ;; return an indication of what encoding the
 713                        ;; message buffer is now, i.e. ASCII or
 714                        ;; 8BITMIME.
 715                        (if nil
 716                            " BODY=8BITMIME"
 717                          "")
 718                      "")))
 719 ;             (smtpmail-send-command process (format "MAIL FROM:%s@%s" (user-login-name) (smtpmail-fqdn)))
 720               (smtpmail-send-command process (format "MAIL FROM:<%s>%s%s"
 721                                                      envelope-from
 722                                                      size-part
 723                                                      body-part))
 724
 725               (if (or (null (car (setq response-code (smtpmail-read-response process))))
 726                       (not (integerp (car response-code)))
 727                       (>= (car response-code) 400))
 728                   (throw 'done nil)
 729                 ))
 730
 731             ;; RCPT TO:<recipient>
 732             (let ((n 0))
 733               (while (not (null (nth n recipient)))
 734                 (smtpmail-send-command process (format "RCPT TO:<%s>" (smtpmail-maybe-append-domain (nth n recipient))))
 735                 (setq n (1+ n))
 736
 737                 (setq response-code (smtpmail-read-response process))
 738                 (if (or (null (car response-code))
 739                         (not (integerp (car response-code)))
 740                         (>= (car response-code) 400))
 741                     (throw 'done nil)
 742                   )
 743                 ))
 744
 745             ;; DATA
 746             (smtpmail-send-command process "DATA")
 747
 748             (if (or (null (car (setq response-code (smtpmail-read-response process))))
 749                     (not (integerp (car response-code)))
 750                     (>= (car response-code) 400))
 751                 (throw 'done nil)
 752               )
 753
 754             ;; Mail contents
 755             (smtpmail-send-data process smtpmail-text-buffer)
 756
 757             ;;DATA end "."
 758             (smtpmail-send-command process ".")
 759
 760             (if (or (null (car (setq response-code (smtpmail-read-response process))))
 761                     (not (integerp (car response-code)))
 762                     (>= (car response-code) 400))
 763                 (throw 'done nil)
 764               )
 765
 766             ;;QUIT
 767 ;           (smtpmail-send-command process "QUIT")
 768 ;           (and (null (car (smtpmail-read-response process)))
 769 ;                (throw 'done nil))
 770             t ))
 771       (if process
 772           (with-current-buffer (process-buffer process)
 773             (smtpmail-send-command process "QUIT")
 774             (smtpmail-read-response process)
 775
 776 ;           (if (or (null (car (setq response-code (smtpmail-read-response process))))
 777 ;                   (not (integerp (car response-code)))
 778 ;                   (>= (car response-code) 400))
 779 ;               (throw 'done nil)
 780 ;             )
 781             (delete-process process)
 782             (unless smtpmail-debug-info
 783               (kill-buffer process-buffer)))))))
 784
 785
 786 (defun smtpmail-process-filter (process output)
 787   (with-current-buffer (process-buffer process)
 788     (goto-char (point-max))
 789     (insert output)))
 790
 791 (defun smtpmail-read-response (process)
 792   (let ((case-fold-search nil)
 793         (response-strings nil)
 794         (response-continue t)
 795         (return-value '(nil ()))
 796         match-end)
 797     (catch 'done
 798       (while response-continue
 799         (goto-char smtpmail-read-point)
 800         (while (not (search-forward "\r\n" nil t))
 801           (unless (memq (process-status process) '(open run))
 802             (throw 'done nil))
 803           (accept-process-output process)
 804           (goto-char smtpmail-read-point))
 805
 806         (setq match-end (point))
 807         (setq response-strings
 808               (cons (buffer-substring smtpmail-read-point (- match-end 2))
 809                     response-strings))
 810
 811         (goto-char smtpmail-read-point)
 812         (if (looking-at "[0-9]+ ")
 813             (let ((begin (match-beginning 0))
 814                   (end (match-end 0)))
 815               (if smtpmail-debug-info
 816                   (message "%s" (car response-strings)))
 817
 818               (setq smtpmail-read-point match-end)
 819
 820               ;; ignore lines that start with "0"
 821               (if (looking-at "0[0-9]+ ")
 822                   nil
 823                 (setq response-continue nil)
 824                 (setq return-value
 825                       (cons (string-to-number
 826                              (buffer-substring begin end))
 827                             (nreverse response-strings)))))
 828
 829           (if (looking-at "[0-9]+-")
 830               (progn (if smtpmail-debug-info
 831                          (message "%s" (car response-strings)))
 832                      (setq smtpmail-read-point match-end)
 833                      (setq response-continue t))
 834             (progn
 835               (setq smtpmail-read-point match-end)
 836               (setq response-continue nil)
 837               (setq return-value
 838                     (cons nil (nreverse response-strings)))))))
 839       (setq smtpmail-read-point match-end))
 840     return-value))
 841
 842
 843 (defun smtpmail-send-command (process command)
 844   (goto-char (point-max))
 845   (if (= (aref command 0) ?P)
 846       (insert "PASS <omitted>\r\n")
 847     (insert command "\r\n"))
 848   (setq smtpmail-read-point (point))
 849   (process-send-string process command)
 850   (process-send-string process "\r\n"))
 851
 852 (defun smtpmail-send-data-1 (process data)
 853   (goto-char (point-max))
 854
 855   (if (and (multibyte-string-p data)
 856            smtpmail-code-conv-from)
 857       (setq data (string-as-multibyte
 858                   (encode-coding-string data smtpmail-code-conv-from))))
 859
 860   (if smtpmail-debug-info
 861       (insert data "\r\n"))
 862
 863   (setq smtpmail-read-point (point))
 864   ;; Escape "." at start of a line
 865   (if (eq (string-to-char data) ?.)
 866       (process-send-string process "."))
 867   (process-send-string process data)
 868   (process-send-string process "\r\n")
 869   )
 870
 871 (defun smtpmail-send-data (process buffer)
 872   (let ((data-continue t) sending-data)
 873     (with-current-buffer buffer
 874       (goto-char (point-min)))
 875     (while data-continue
 876       (with-current-buffer buffer
 877         (setq sending-data (buffer-substring (point-at-bol) (point-at-eol)))
 878         (end-of-line 2)
 879         (setq data-continue (not (eobp))))
 880       (smtpmail-send-data-1 process sending-data))))
 881
 882 (defun smtpmail-deduce-address-list (smtpmail-text-buffer header-start header-end)
 883   "Get address list suitable for smtp RCPT TO: <address>."
 884   (unwind-protect
 885       (with-current-buffer smtpmail-address-buffer
 886         (erase-buffer)
 887         (let
 888             ((case-fold-search t)
 889              (simple-address-list "")
 890              this-line
 891              this-line-end
 892              addr-regexp)
 893           (insert-buffer-substring smtpmail-text-buffer header-start header-end)
 894           (goto-char (point-min))
 895           ;; RESENT-* fields should stop processing of regular fields.
 896           (save-excursion
 897             (setq addr-regexp
 898                   (if (re-search-forward "^Resent-\\(to\\|cc\\|bcc\\):"
 899                                          header-end t)
 900                       "^Resent-\\(to\\|cc\\|bcc\\):"
 901                     "^\\(To:\\|Cc:\\|Bcc:\\)")))
 902
 903           (while (re-search-forward addr-regexp header-end t)
 904             (replace-match "")
 905             (setq this-line (match-beginning 0))
 906             (forward-line 1)
 907             ;; get any continuation lines
 908             (while (and (looking-at "^[ \t]+") (< (point) header-end))
 909               (forward-line 1))
 910             (setq this-line-end (point-marker))
 911             (setq simple-address-list
 912                   (concat simple-address-list " "
 913                           (mail-strip-quoted-names (buffer-substring this-line this-line-end))))
 914             )
 915           (erase-buffer)
 916           (insert " " simple-address-list "\n")
 917           (subst-char-in-region (point-min) (point-max) 10 ?  t);; newline --> blank
 918           (subst-char-in-region (point-min) (point-max) ?, ?  t);; comma   --> blank
 919           (subst-char-in-region (point-min) (point-max)  9 ?  t);; tab     --> blank
 920
 921           (goto-char (point-min))
 922           ;; tidyness in case hook is not robust when it looks at this
 923           (while (re-search-forward "[ \t]+" header-end t) (replace-match " "))
 924
 925           (goto-char (point-min))
 926           (let (recipient-address-list)
 927             (while (re-search-forward " \\([^ ]+\\) " (point-max) t)
 928               (backward-char 1)
 929               (setq recipient-address-list (cons (buffer-substring (match-beginning 1) (match-end 1))
 930                                                  recipient-address-list))
 931               )
 932             (setq smtpmail-recipient-address-list recipient-address-list))
 933
 934           )
 935         )
 936     )
 937   )
 938
 939
 940 (defun smtpmail-do-bcc (header-end)
 941   "Delete [Resent-]BCC: and their continuation lines from the header area.
 942 There may be multiple BCC: lines, and each may have arbitrarily
 943 many continuation lines."
 944   (let ((case-fold-search t))
 945     (save-excursion
 946       (goto-char (point-min))
 947       ;; iterate over all BCC: lines
 948       (while (re-search-forward "^\\(RESENT-\\)?BCC:" header-end t)
 949         (delete-region (match-beginning 0)
 950                        (progn (forward-line 1) (point)))
 951         ;; get rid of any continuation lines
 952         (while (and (looking-at "^[ \t].*\n") (< (point) header-end))
 953           (replace-match ""))))))
 954
 955
 956 (provide 'smtpmail)
 957
 958 ;;; arch-tag: a76992df-6d71-43b7-9e72-4bacc6c05466
 959 ;;; smtpmail.el ends here