code.delx.au - gnu-emacs/blob - lisp/net/goto-addr.el

   1 ;;; goto-addr.el --- click to browse URL or to send to e-mail address
   2
   3 ;; Copyright (C) 1995, 2000, 2001 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Ding <ericding@alum.mit.edu>
   6 ;; Maintainer: FSF
   7 ;; Created: 15 Aug 1995
   8 ;; Keywords: mh-e, www, mouse, mail
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; This package allows you to click or hit a key sequence while on a
  30 ;; URL or e-mail address, and either load the URL into a browser of
  31 ;; your choice using the browse-url package, or if it's an e-mail
  32 ;; address, to send an e-mail to that address.  By default, we bind to
  33 ;; the [mouse-2] and the [C-c return] key sequences.
  34
  35 ;; INSTALLATION
  36 ;;
  37 ;; To use goto-address in a particular mode (for example, while
  38 ;; reading mail in mh-e), add something like this in your .emacs file:
  39 ;;
  40 ;; (add-hook 'mh-show-mode-hook 'goto-address)
  41 ;;
  42 ;; The mouse click method is bound to [mouse-2] on highlighted URLs or
  43 ;; e-mail addresses only; it functions normally everywhere else.  To bind
  44 ;; another mouse click to the function, add the following to your .emacs
  45 ;; (for example):
  46 ;;
  47 ;; (setq goto-address-highlight-keymap
  48 ;;   (let ((m (make-sparse-keymap)))
  49 ;;     (define-key m [S-mouse-2] 'goto-address-at-mouse)
  50 ;;     m))
  51 ;;
  52
  53 ;; Known bugs/features:
  54 ;; * goto-address-mail-regexp only catches foo@bar.org style addressing,
  55 ;;   not stuff like X.400 addresses, etc.
  56 ;; * regexp also catches Message-Id line, since it is in the format of
  57 ;;   an Internet e-mail address (like Compuserve addresses)
  58 ;; * If the buffer is fontified after goto-address-fontify is run
  59 ;;   (say, using font-lock-fontify-buffer), then font-lock faces will
  60 ;;   override goto-address faces.
  61
  62 ;;; Code:
  63
  64 (require 'thingatpt)
  65 (autoload 'browse-url-url-at-point "browse-url")
  66
  67 ;; XEmacs needs the following definitions.
  68 (unless (fboundp 'overlays-in)
  69   (require 'overlay))
  70 (unless (fboundp 'line-beginning-position)
  71   (defalias 'line-beginning-position 'point-at-bol))
  72 (unless (fboundp 'line-end-position)
  73   (defalias 'line-end-position 'point-at-eol))
  74 (unless (fboundp 'match-string-no-properties)
  75   (defalias 'match-string-no-properties 'match-string))
  76
  77 (defgroup goto-address nil
  78   "Click to browse URL or to send to e-mail address."
  79   :group 'mouse
  80   :group 'hypermedia)
  81
  82
  83 ;; I don't expect users to want fontify'ing without highlighting.
  84 (defcustom goto-address-fontify-p t
  85   "*Non-nil means URLs and e-mail addresses in buffer are fontified.
  86 But only if `goto-address-highlight-p' is also non-nil."
  87   :type 'boolean
  88   :group 'goto-address)
  89
  90 (defcustom goto-address-highlight-p t
  91   "*Non-nil means URLs and e-mail addresses in buffer are highlighted."
  92   :type 'boolean
  93   :group 'goto-address)
  94
  95 (defcustom goto-address-fontify-maximum-size 30000
  96   "*Maximum size of file in which to fontify and/or highlight URLs.
  97 A value of t means there is no limit--fontify regardless of the size."
  98   :type '(choice (integer :tag "Maximum size") (const :tag "No limit" t))
  99   :group 'goto-address)
 100
 101 (defvar goto-address-mail-regexp
 102   ;; Actually pretty much any char could appear in the username part.  -stef
 103   "[-a-zA-Z0-9=._+]+@\\([-a-zA-z0-9_]+\\.\\)+[a-zA-Z0-9]+"
 104   "A regular expression probably matching an e-mail address.")
 105
 106 (defvar goto-address-url-regexp
 107   (concat "\\<\\("
 108           (mapconcat 'identity
 109                      (delete "mailto:" (copy-sequence thing-at-point-uri-schemes))
 110                      "\\|")
 111           "\\)"
 112           thing-at-point-url-path-regexp)
 113   ;; (concat "\\b\\(s?https?\\|ftp\\|file\\|gopher\\|news\\|"
 114   ;;      "telnet\\|wais\\):\\(//[-a-zA-Z0-9_.]+:"
 115   ;;      "[0-9]*\\)?[-a-zA-Z0-9_=?#$@~`%&*+|\\/.,]*"
 116   ;;      "[-a-zA-Z0-9_=#$@~`%&*+|\\/]")
 117   "A regular expression probably matching a URL.")
 118
 119 (defvar goto-address-highlight-keymap
 120   (let ((m (make-sparse-keymap)))
 121     (if (featurep 'xemacs)
 122         (define-key m (kbd "<button2>") 'goto-address-at-mouse)
 123       (define-key m (kbd "<mouse-2>") 'goto-address-at-mouse))
 124     (define-key m (kbd "C-c RET") 'goto-address-at-point)
 125     m)
 126   "keymap to hold goto-addr's mouse key defs under highlighted URLs.")
 127
 128 (defcustom goto-address-url-face 'bold
 129   "Face to use for URLs."
 130   :type 'face
 131   :group 'goto-address)
 132
 133 (defcustom goto-address-url-mouse-face 'highlight
 134   "Face to use for URLs when the mouse is on them."
 135   :type 'face
 136   :group 'goto-address)
 137
 138 (defcustom goto-address-mail-face 'italic
 139   "Face to use for e-mail addresses."
 140   :type 'face
 141   :group 'goto-address)
 142
 143 (defcustom goto-address-mail-mouse-face 'secondary-selection
 144   "Face to use for e-mail addresses when the mouse is on them."
 145   :type 'face
 146   :group 'goto-address)
 147
 148 (defun goto-address-fontify ()
 149   "Fontify the URLs and e-mail addresses in the current buffer.
 150 This function implements `goto-address-highlight-p'
 151 and `goto-address-fontify-p'."
 152   ;; Clean up from any previous go.
 153   (dolist (overlay (overlays-in (point-min) (point-max)))
 154     (if (overlay-get overlay 'goto-address)
 155         (delete-overlay overlay)))
 156   (save-excursion
 157     (let ((inhibit-point-motion-hooks t))
 158       (goto-char (point-min))
 159       (if (or (eq t goto-address-fontify-maximum-size)
 160               (< (- (point-max) (point)) goto-address-fontify-maximum-size))
 161           (progn
 162             (while (re-search-forward goto-address-url-regexp nil t)
 163               (let* ((s (match-beginning 0))
 164                      (e (match-end 0))
 165                      (this-overlay (make-overlay s e)))
 166                 (and goto-address-fontify-p
 167                      (overlay-put this-overlay 'face goto-address-url-face))
 168                 (overlay-put this-overlay
 169                              'mouse-face goto-address-url-mouse-face)
 170                 (overlay-put this-overlay
 171                              'help-echo "mouse-2, C-c RET: follow URL")
 172                 (overlay-put this-overlay
 173                              'keymap goto-address-highlight-keymap)
 174                 (overlay-put this-overlay 'goto-address t)))
 175             (goto-char (point-min))
 176             (while (re-search-forward goto-address-mail-regexp nil t)
 177               (let* ((s (match-beginning 0))
 178                      (e (match-end 0))
 179                      (this-overlay (make-overlay s e)))
 180                 (and goto-address-fontify-p
 181                      (overlay-put this-overlay 'face goto-address-mail-face))
 182                 (overlay-put this-overlay 'mouse-face
 183                              goto-address-mail-mouse-face)
 184                 (overlay-put this-overlay
 185                              'help-echo "mouse-2, C-c RET: mail this address")
 186                 (overlay-put this-overlay
 187                              'keymap goto-address-highlight-keymap)
 188                 (overlay-put this-overlay 'goto-address t))))))))
 189
 190 ;; code to find and goto addresses; much of this has been blatantly
 191 ;; snarfed from browse-url.el
 192
 193 ;;;###autoload
 194 (defun goto-address-at-mouse (event)
 195   "Send to the e-mail address or load the URL clicked with the mouse.
 196 Send mail to address at position of mouse click.  See documentation for
 197 `goto-address-find-address-at-point'.  If no address is found
 198 there, then load the URL at or before the position of the mouse click."
 199   (interactive "e")
 200   (save-excursion
 201     (mouse-set-point event)
 202     (goto-address-at-point)))
 203
 204 ;;;###autoload
 205 (defun goto-address-at-point ()
 206   "Send to the e-mail address or load the URL at point.
 207 Send mail to address at point.  See documentation for
 208 `goto-address-find-address-at-point'.  If no address is found
 209 there, then load the URL at or before point."
 210   (interactive)
 211   (save-excursion
 212     (let ((address (save-excursion (goto-address-find-address-at-point))))
 213       (if (and address
 214                (save-excursion
 215                  (goto-char (previous-single-char-property-change
 216                              (point) 'goto-address nil
 217                              (line-beginning-position)))
 218                  (not (looking-at goto-address-url-regexp))))
 219           (compose-mail address)
 220         (let ((url (browse-url-url-at-point)))
 221           (if url
 222               (browse-url url)
 223             (error "No e-mail address or URL found")))))))
 224
 225 (defun goto-address-find-address-at-point ()
 226   "Find e-mail address around or before point.
 227 Then search backwards to beginning of line for the start of an e-mail
 228 address.  If no e-mail address found, return nil."
 229   (re-search-backward "[^-_A-z0-9.@]" (line-beginning-position) 'lim)
 230   (if (or (looking-at goto-address-mail-regexp) ; already at start
 231           (and (re-search-forward goto-address-mail-regexp
 232                                   (line-end-position) 'lim)
 233                (goto-char (match-beginning 0))))
 234       (match-string-no-properties 0)))
 235
 236 ;;;###autoload
 237 (defun goto-address ()
 238   "Sets up goto-address functionality in the current buffer.
 239 Allows user to use mouse/keyboard command to click to go to a URL
 240 or to send e-mail.
 241 By default, goto-address binds to mouse-2 and C-c RET.
 242
 243 Also fontifies the buffer appropriately (see `goto-address-fontify-p' and
 244 `goto-address-highlight-p' for more information)."
 245   (interactive)
 246   (if goto-address-highlight-p
 247       (goto-address-fontify)))
 248
 249 (provide 'goto-addr)
 250
 251 ;;; arch-tag: ca47c505-5661-425d-a471-62bc6e75cf0a
 252 ;;; goto-addr.el ends here