code.delx.au - gnu-emacs/blob - configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2011  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.0.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28 AM_INIT_AUTOMAKE
  29
  30 dnl Support for --program-prefix, --program-suffix and
  31 dnl --program-transform-name options
  32 AC_ARG_PROGRAM
  33
  34 dnl It is important that variables on the RHS not be expanded here,
  35 dnl hence the single quotes.  This is per the GNU coding standards, see
  36 dnl (autoconf) Installation Directory Variables
  37 dnl See also epaths.h below.
  38 lispdir='${datadir}/emacs/${version}/lisp'
  39 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  40 '${datadir}/emacs/site-lisp'
  41 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  42 etcdir='${datadir}/emacs/${version}/etc'
  43 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  44 docdir='${datadir}/emacs/${version}/etc'
  45 gamedir='${localstatedir}/games/emacs'
  46
  47 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  48 dnl Create a new --with option that defaults to being disabled.
  49 dnl NAME is the base name of the option.  The shell variable with_NAME
  50 dnl   will be set to either the user's value (if the option is
  51 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  52 dnl   option is not specified).  Note that the shell variable name is
  53 dnl   constructed as autoconf does, by replacing non-alphanumeric
  54 dnl   characters with "_".
  55 dnl HELP-STRING is the help text for the option.
  56 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  57   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  58     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  59 ])dnl
  60
  61 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  62 dnl Create a new --with option that defaults to being enabled.  NAME
  63 dnl   is the base name of the option.  The shell variable with_NAME
  64 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  65 dnl   'yes' (if the option is not specified).  Note that the shell
  66 dnl   variable name is constructed as autoconf does, by replacing
  67 dnl   non-alphanumeric characters with "_".
  68 dnl HELP-STRING is the help text for the option.
  69 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  70   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  71    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  72 ])dnl
  73
  74 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  75 if test "$with_pop" = yes; then
  76    AC_DEFINE(MAIL_USE_POP)
  77 fi
  78 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  79
  80 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  81 if test "$with_kerberos" != no; then
  82    AC_DEFINE(KERBEROS)
  83 fi
  84 AH_TEMPLATE(KERBEROS,
  85             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  86
  87 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  88 if test "${with_kerberos5}" != no; then
  89   if test "${with_kerberos}" = no; then
  90     with_kerberos=yes
  91     AC_DEFINE(KERBEROS)
  92   fi
  93   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  94 fi
  95
  96 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  97 dnl FIXME hesiod support may not be present, so it seems like an error
  98 dnl to define, or at least use, this unconditionally.
  99 if test "$with_hesiod" != no; then
 100   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 101 fi
 102
 103 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 104 if test "$with_mmdf" != no; then
 105    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 106 fi
 107
 108 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 109 if test "$with_mail_unlink" != no; then
 110    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 111 fi
 112
 113 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 114     [string giving default POP mail host])],
 115     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 116
 117 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 118
 119 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 120 if test "$with_sync_input" = yes; then
 121    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 122 fi
 123
 124 dnl FIXME currently it is not the last.
 125 dnl This should be the last --with option, because --with-x is
 126 dnl added later on when we find the path of X, and it's best to
 127 dnl keep them together visually.
 128 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 129  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 130 [         case "${withval}" in
 131             y | ye | yes )      val=gtk ;;
 132             n | no )            val=no  ;;
 133             l | lu | luc | luci | lucid )       val=lucid ;;
 134             a | at | ath | athe | athen | athena )      val=athena ;;
 135             m | mo | mot | moti | motif )       val=motif ;;
 136             g | gt | gtk  )     val=gtk ;;
 137             gtk3  )     val=gtk3 ;;
 138             * )
 139 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 140 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 141 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 142             ;;
 143           esac
 144           with_x_toolkit=$val
 145 ])
 146
 147 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 148 if test "$with_wide_int" = yes; then
 149   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 150 fi
 151
 152 dnl _ON results in a '--without' option in the --help output, so
 153 dnl the help text should refer to "don't compile", etc.
 154 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 155 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 156 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 157 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 158 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 159 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 160 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 161 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 162
 163 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 164 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 165 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 166
 167 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 168 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 169 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 170 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 171
 172 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 173 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 174 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 175 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 176 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 177 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 178
 179 OPTION_DEFAULT_OFF([xwidgets],[enable use of some gtk widgets it Emacs buffers])
 180
 181 ## For the times when you want to build Emacs but don't have
 182 ## a suitable makeinfo, and can live without the manuals.
 183 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 184 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 185
 186 ## This is an option because I do not know if all info/man support
 187 ## compressed files, nor how to test if they do so.
 188 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 189 if test $with_compress_info = yes; then
 190    GZIP_INFO=yes
 191 else
 192    GZIP_INFO=
 193 fi
 194 AC_SUBST(GZIP_INFO)
 195
 196 AC_ARG_WITH([pkg-config-prog],dnl
 197 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 198                   [path to pkg-config for finding GTK and librsvg])])
 199 if test "X${with_pkg_config_prog}" != X; then
 200    if test "${with_pkg_config_prog}" != yes; then
 201       PKG_CONFIG="${with_pkg_config_prog}"
 202    fi
 203 fi
 204
 205 CRT_DIR=
 206 AC_ARG_WITH([crt-dir],dnl
 207 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 208 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 209 CRT_DIR="${with_crt_dir}"
 210
 211 AC_ARG_WITH(gameuser,dnl
 212 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 213 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 214   && gameuser="${with_gameuser}"
 215 test "X$gameuser" = X && gameuser=games
 216
 217 AC_ARG_WITH([gnustep-conf],dnl
 218 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 219 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 220   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 221 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 222      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 223
 224 AC_ARG_ENABLE(ns-self-contained,
 225 [AS_HELP_STRING([--disable-ns-self-contained],
 226                 [disable self contained build under NeXTstep])],
 227    EN_NS_SELF_CONTAINED=$enableval,
 228    EN_NS_SELF_CONTAINED=yes)
 229
 230 AC_ARG_ENABLE(asserts,
 231 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 232       USE_XASSERTS=$enableval,
 233       USE_XASSERTS=no)
 234
 235 AC_ARG_ENABLE(maintainer-mode,
 236 [AS_HELP_STRING([--disable-maintainer-mode],
 237                 [disable make rules and dependencies not useful (and sometimes
 238                  confusing) to the casual installer])],
 239       USE_MAINTAINER_MODE=$enableval,
 240       USE_MAINTAINER_MODE=yes)
 241 if test $USE_MAINTAINER_MODE = yes; then
 242   MAINT=
 243 else
 244   MAINT=#
 245 fi
 246 AC_SUBST(MAINT)
 247
 248 AC_ARG_ENABLE(locallisppath,
 249 [AS_HELP_STRING([--enable-locallisppath=PATH],
 250                 [directories Emacs should search for lisp files specific
 251                  to this site])],
 252 if test "${enableval}" = "no"; then
 253   locallisppath=
 254 elif test "${enableval}" != "yes"; then
 255   locallisppath=${enableval}
 256 fi)
 257
 258 AC_ARG_ENABLE(checking,
 259 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 260                 [enable expensive run-time checks.  With LIST,
 261                  enable only specific categories of checks.
 262                  Categories are: all,yes,no.
 263                  Flags are: stringbytes, stringoverrun, stringfreelist,
 264                  xmallocoverrun, conslist])],
 265 [ac_checking_flags="${enableval}"],[])
 266 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 267 for check in $ac_checking_flags
 268 do
 269         case $check in
 270         # these set all the flags to specific states
 271         yes)            ac_enable_checking=1 ;;
 272         no)             ac_enable_checking= ;
 273                         ac_gc_check_stringbytes= ;
 274                         ac_gc_check_string_overrun= ;
 275                         ac_gc_check_string_free_list= ;
 276                         ac_xmalloc_overrun= ;
 277                         ac_gc_check_cons_list= ;;
 278         all)            ac_enable_checking=1 ;
 279                         ac_gc_check_stringbytes=1 ;
 280                         ac_gc_check_string_overrun=1 ;
 281                         ac_gc_check_string_free_list=1 ;
 282                         ac_xmalloc_overrun=1 ;
 283                         ac_gc_check_cons_list=1 ;;
 284         # these enable particular checks
 285         stringbytes)    ac_gc_check_stringbytes=1 ;;
 286         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 287         stringfreelist) ac_gc_check_string_free_list=1 ;;
 288         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 289         conslist)       ac_gc_check_cons_list=1 ;;
 290         *)      AC_MSG_ERROR(unknown check category $check) ;;
 291         esac
 292 done
 293 IFS="$ac_save_IFS"
 294
 295 if test x$ac_enable_checking != x ; then
 296   AC_DEFINE(ENABLE_CHECKING, 1,
 297 [Enable expensive run-time checking of data types?])
 298 fi
 299 if test x$ac_gc_check_stringbytes != x ; then
 300   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 301 [Define this temporarily to hunt a bug.  If defined, the size of
 302    strings is redundantly recorded in sdata structures so that it can
 303    be compared to the sizes recorded in Lisp strings.])
 304 fi
 305 if test x$ac_gc_check_string_overrun != x ; then
 306   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 307 [Define this to check for short string overrun.])
 308 fi
 309 if test x$ac_gc_check_string_free_list != x ; then
 310   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 311 [Define this to check the string free list.])
 312 fi
 313 if test x$ac_xmalloc_overrun != x ; then
 314   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 315 [Define this to check for malloc buffer overrun.])
 316 fi
 317 if test x$ac_gc_check_cons_list != x ; then
 318   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 319 [Define this to check for errors in cons list.])
 320 fi
 321
 322 AC_ARG_ENABLE(use-lisp-union-type,
 323 [AS_HELP_STRING([--enable-use-lisp-union-type],
 324                 [use a union for the Lisp_Object data type.
 325                 This is only useful for development for catching certain types of bugs.])],
 326 if test "${enableval}" != "no"; then
 327    AC_DEFINE(USE_LISP_UNION_TYPE, 1,
 328    [Define this to use a lisp union for the Lisp_Object data type.])
 329 fi)
 330
 331
 332 AC_ARG_ENABLE(profiling,
 333 [AS_HELP_STRING([--enable-profiling],
 334                 [build emacs with profiling support.
 335                  This might not work on all platforms])],
 336 [ac_enable_profiling="${enableval}"],[])
 337 if test x$ac_enable_profiling != x ; then
 338    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 339 else
 340    PROFILING_CFLAGS=
 341 fi
 342 AC_SUBST(PROFILING_CFLAGS)
 343
 344 AC_ARG_ENABLE(autodepend,
 345 [AS_HELP_STRING([--enable-autodepend],
 346                 [automatically generate dependencies to .h-files.
 347                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 348                  found])],
 349 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 350
 351 #### Make srcdir absolute, if it isn't already.  It's important to
 352 #### avoid running the path through pwd unnecessarily, since pwd can
 353 #### give you automounter prefixes, which can go away.  We do all this
 354 #### so Emacs can find its files when run uninstalled.
 355 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 356 unset CDPATH
 357 case "${srcdir}" in
 358   /* ) ;;
 359   . )
 360     ## We may be able to use the $PWD environment variable to make this
 361     ## absolute.  But sometimes PWD is inaccurate.
 362     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 363     ## but that tested only for a well-formed and valid PWD,
 364     ## it did not object when PWD was well-formed and valid but just wrong.
 365     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 366     then
 367       srcdir="$PWD"
 368     else
 369       srcdir="`(cd ${srcdir}; pwd)`"
 370     fi
 371   ;;
 372   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 373 esac
 374
 375 #### Given the configuration name, set machfile and opsysfile to the
 376 #### names of the m/*.h and s/*.h files we should use.
 377
 378 ### Canonicalize the configuration name.
 379
 380 AC_CANONICAL_HOST
 381 canonical=$host
 382 configuration=${host_alias-${build_alias-$host}}
 383
 384 dnl This used to use changequote, but, apart from `changequote is evil'
 385 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 386 dnl the great gob of text.  Thus it's not processed for possible expansion.
 387 dnl Just make sure the brackets remain balanced.
 388 dnl
 389 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 390 dnl indicated by comments.
 391 dnl quotation begins
 392 [
 393
 394 ### If you add support for a new configuration, add code to this
 395 ### switch statement to recognize your configuration name and select
 396 ### the appropriate operating system and machine description files.
 397
 398 ### You would hope that you could choose an m/*.h file pretty much
 399 ### based on the machine portion of the configuration name, and an s/*.h
 400 ### file based on the operating system portion.  However, it turns out
 401 ### that each m/*.h file is pretty manufacturer-specific - for
 402 ### example mips.h is MIPS
 403 ### So we basically have to have a special case for each
 404 ### configuration name.
 405 ###
 406 ### As far as handling version numbers on operating systems is
 407 ### concerned, make sure things will fail in a fixable way.  If
 408 ### /etc/MACHINES doesn't say anything about version numbers, be
 409 ### prepared to handle anything reasonably.  If version numbers
 410 ### matter, be sure /etc/MACHINES says something about it.
 411
 412 machine='' opsys='' unported=no
 413 case "${canonical}" in
 414
 415   ## GNU/Linux ports
 416   *-*-linux-gnu*)
 417     opsys=gnu-linux
 418     case ${canonical} in
 419       alpha*)   machine=alpha ;;
 420       s390-*)   machine=ibms390 ;;
 421       s390x-*)  machine=ibms390x ;;
 422       powerpc*) machine=macppc ;;
 423       sparc*)   machine=sparc ;;
 424       ia64*)    machine=ia64 ;;
 425       m68k*)    machine=m68k ;;
 426       x86_64*)  machine=amdx86-64 ;;
 427     esac
 428   ;;
 429
 430   ## FreeBSD ports
 431   *-*-freebsd* )
 432     opsys=freebsd
 433     case "${canonical}" in
 434       alpha*)           machine=alpha ;;
 435       amd64-*|x86_64-*) machine=amdx86-64 ;;
 436       ia64-*)           machine=ia64 ;;
 437       i[3456]86-*)      machine=intel386 ;;
 438       powerpc-*)        machine=macppc ;;
 439       sparc-*)          machine=sparc ;;
 440       sparc64-*)        machine=sparc ;;
 441     esac
 442   ;;
 443
 444   ## FreeBSD kernel + glibc based userland
 445   *-*-kfreebsd*gnu* )
 446     opsys=gnu-kfreebsd
 447     case "${canonical}" in
 448       alpha*)           machine=alpha ;;
 449       amd64-*|x86_64-*) machine=amdx86-64 ;;
 450       ia64-*)           machine=ia64 ;;
 451       i[3456]86-*)      machine=intel386 ;;
 452       powerpc-*)        machine=macppc ;;
 453       sparc-*)          machine=sparc ;;
 454       sparc64-*)        machine=sparc ;;
 455     esac
 456   ;;
 457
 458   ## NetBSD ports
 459   *-*-netbsd* )
 460     opsys=netbsd
 461     case "${canonical}" in
 462       alpha*)      machine=alpha ;;
 463       x86_64-*)    machine=amdx86-64 ;;
 464       i[3456]86-*) machine=intel386 ;;
 465       m68k-*)      machine=m68k ;;
 466       powerpc-*)   machine=macppc ;;
 467       sparc*-)     machine=sparc ;;
 468       vax-*)       machine=vax ;;
 469     esac
 470   ;;
 471
 472   ## OpenBSD ports
 473   *-*-openbsd* )
 474     opsys=openbsd
 475     case "${canonical}" in
 476       alpha*)    machine=alpha ;;
 477       x86_64-*)  machine=amdx86-64 ;;
 478       i386-*)    machine=intel386 ;;
 479       powerpc-*) machine=macppc ;;
 480       sparc*)    machine=sparc ;;
 481       vax-*)     machine=vax ;;
 482     esac
 483   ;;
 484
 485   ## Apple Darwin / Mac OS X
 486   *-apple-darwin* )
 487     case "${canonical}" in
 488       i[3456]86-* )  machine=intel386 ;;
 489       powerpc-* )    machine=macppc ;;
 490       x86_64-* )     machine=amdx86-64 ;;
 491       * )            unported=yes ;;
 492     esac
 493     opsys=darwin
 494     # Define CPP as follows to make autoconf work correctly.
 495     CPP="${CC-cc} -E -no-cpp-precomp"
 496     # Use fink packages if available.
 497     if test -d /sw/include && test -d /sw/lib; then
 498       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 499       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 500       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 501     fi
 502   ;;
 503
 504   ## HP 9000 series 700 and 800, running HP/UX
 505   hppa*-hp-hpux10.2* )
 506     opsys=hpux10-20
 507   ;;
 508   hppa*-hp-hpux1[1-9]* )
 509     opsys=hpux11
 510     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 511   ;;
 512
 513   ia64*-hp-hpux1[1-9]* )
 514     machine=hp800 opsys=hpux11
 515     ## FIXME.  Peter O'Gorman reports that dumping using unexelf.o doesn't
 516     ## work either: http://debbugs.gnu.org/cgi/bugreport.cgi?bug=6811
 517     CANNOT_DUMP=yes
 518   ;;
 519
 520   hppa*-*-linux-gnu* )
 521     machine=hp800 opsys=gnu-linux
 522   ;;
 523
 524   ## IBM machines
 525   rs6000-ibm-aix4.[23]* )
 526     machine=ibmrs6000 opsys=aix4-2
 527   ;;
 528   powerpc-ibm-aix4.[23]*  )
 529     machine=ibmrs6000 opsys=aix4-2
 530   ;;
 531   rs6000-ibm-aix[56]* )
 532     machine=ibmrs6000 opsys=aix4-2
 533   ;;
 534   powerpc-ibm-aix[56]*  )
 535     machine=ibmrs6000 opsys=aix4-2
 536   ;;
 537
 538   ## Silicon Graphics machines
 539   ## Iris 4D
 540   mips-sgi-irix6.5 )
 541     opsys=irix6-5
 542     # Without defining _LANGUAGE_C, things get masked out in the headers
 543     # so that, for instance, grepping for `free' in stdlib.h fails and
 544     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 545     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 546     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 547   ;;
 548
 549   ## Suns
 550   *-sun-solaris* \
 551     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 552     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 553     case "${canonical}" in
 554       i[3456]86-*-* )     machine=intel386 ;;
 555       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 556       sparc* )          machine=sparc ;;
 557       * )               unported=yes ;;
 558     esac
 559     case "${canonical}" in
 560       *-sunos5.6* | *-solaris2.6* )
 561                 opsys=sol2-6
 562                 NON_GNU_CPP=/usr/ccs/lib/cpp
 563                 RANLIB="ar -ts"
 564                 ;;
 565       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 566                 opsys=sol2-6
 567                 emacs_check_sunpro_c=yes
 568                 NON_GNU_CPP=/usr/ccs/lib/cpp
 569                 ;;
 570       *-sunos5* | *-solaris* )
 571                 opsys=sol2-10
 572                 emacs_check_sunpro_c=yes
 573                 NON_GNU_CPP=/usr/ccs/lib/cpp
 574                 ;;
 575     esac
 576     ## Watch out for a compiler that we know will not work.
 577     case "${canonical}" in
 578      *-solaris* | *-sunos5* )
 579                 if [ "x$CC" = x/usr/ucb/cc ]; then
 580                   ## /usr/ucb/cc doesn't work;
 581                   ## we should find some other compiler that does work.
 582                   unset CC
 583                 fi
 584                 ;;
 585       *) ;;
 586     esac
 587   ;;
 588
 589   ## Intel 386 machines where we don't care about the manufacturer.
 590   i[3456]86-*-* )
 591     machine=intel386
 592     case "${canonical}" in
 593       *-cygwin )                opsys=cygwin ;;
 594       *-darwin* )               opsys=darwin
 595                                 CPP="${CC-cc} -E -no-cpp-precomp"
 596                                 ;;
 597       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 598       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 599       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 600       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 601     esac
 602   ;;
 603
 604   * )
 605     unported=yes
 606   ;;
 607 esac
 608
 609 ### If the code above didn't choose an operating system, just choose
 610 ### an operating system based on the configuration name.  You really
 611 ### only want to use this when you have no idea what the right
 612 ### operating system is; if you know what operating systems a machine
 613 ### runs, it's cleaner to make it explicit in the case statement
 614 ### above.
 615 if test x"${opsys}" = x; then
 616   case "${canonical}" in
 617     *-gnu* )                            opsys=gnu ;;
 618     * )
 619       unported=yes
 620     ;;
 621   esac
 622 fi
 623
 624 ]
 625 dnl quotation ends
 626
 627 if test $unported = yes; then
 628   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 629 Check `etc/MACHINES' for recognized configuration names.])
 630 fi
 631
 632 if test -n "$machine"; then
 633   machfile="m/${machine}.h"
 634 else
 635   machfile=
 636 fi
 637 opsysfile="s/${opsys}.h"
 638
 639
 640 #### Choose a compiler.
 641 test -n "$CC" && cc_specified=yes
 642
 643 # Save the value of CFLAGS that the user specified.
 644 SPECIFIED_CFLAGS="$CFLAGS"
 645
 646 dnl Sets GCC=yes if using gcc.
 647 AC_PROG_CC
 648 AM_PROG_CC_C_O
 649
 650 # Initialize gnulib right after verifying that the C compiler works.
 651 gl_EARLY
 652
 653 # On Suns, sometimes $CPP names a directory.
 654 if test -n "$CPP" && test -d "$CPP"; then
 655   CPP=
 656 fi
 657
 658 ## If not using gcc, and on Solaris, and no CPP specified, see if
 659 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 660 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 661  test x"$CPP" = x; then
 662   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 663   AC_CACHE_VAL(emacs_cv_sunpro_c,
 664   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
 665 [[#ifndef __SUNPRO_C
 666 fail;
 667 #endif
 668 ]])], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 669   AC_MSG_RESULT($emacs_cv_sunpro_c)
 670
 671   if test x"$emacs_cv_sunpro_c" = xyes; then
 672     NON_GNU_CPP="$CC -E -Xs"
 673   fi
 674 fi
 675
 676 #### Some systems specify a CPP to use unless we are using GCC.
 677 #### Now that we know whether we are using GCC, we can decide whether
 678 #### to use that one.
 679 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 680 then
 681   CPP="$NON_GNU_CPP"
 682 fi
 683
 684 #### Some systems specify a CC to use unless we are using GCC.
 685 #### Now that we know whether we are using GCC, we can decide whether
 686 #### to use that one.
 687 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 688   test x$cc_specified != xyes
 689 then
 690   CC="$NON_GNU_CC"
 691 fi
 692
 693 if test x$GCC = xyes; then
 694   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 695 else
 696   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 697 fi
 698
 699 ### Use -Wdeclaration-after-statement if the compiler supports it
 700 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 701 SAVE_CFLAGS="$CFLAGS"
 702 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 703 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], has_option=yes, has_option=no)
 704 if test $has_option = yes; then
 705    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 706 fi
 707 AC_MSG_RESULT($has_option)
 708 CFLAGS="$SAVE_CFLAGS"
 709 unset has_option
 710 unset SAVE_CFLAGS
 711
 712 ### Use -Wold-style-definition if the compiler supports it
 713 # This can be removed when conversion to standard C is finished.
 714 AC_MSG_CHECKING([whether gcc understands -Wold-style-definition])
 715 SAVE_CFLAGS="$CFLAGS"
 716 CFLAGS="$CFLAGS -Wold-style-definition"
 717 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], has_option=yes, has_option=no)
 718 if test $has_option = yes; then
 719    C_WARNINGS_SWITCH="-Wold-style-definition $C_WARNINGS_SWITCH"
 720 fi
 721 AC_MSG_RESULT($has_option)
 722 CFLAGS="$SAVE_CFLAGS"
 723 unset has_option
 724 unset SAVE_CFLAGS
 725
 726 ### Use -Wimplicit-function-declaration if the compiler supports it
 727 AC_MSG_CHECKING([whether gcc understands -Wimplicit-function-declaration])
 728 SAVE_CFLAGS="$CFLAGS"
 729 CFLAGS="$CFLAGS -Wimplicit-function-declaration"
 730 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], has_option=yes, has_option=no)
 731 if test $has_option = yes; then
 732    C_WARNINGS_SWITCH="-Wimplicit-function-declaration $C_WARNINGS_SWITCH"
 733 fi
 734 AC_MSG_RESULT($has_option)
 735 CFLAGS="$SAVE_CFLAGS"
 736 unset has_option
 737 unset SAVE_CFLAGS
 738
 739 AC_SUBST(C_WARNINGS_SWITCH)
 740
 741
 742 #### Some other nice autoconf tests.
 743
 744 dnl checks for programs
 745 AC_PROG_CPP
 746 AC_PROG_INSTALL
 747 if test "x$RANLIB" = x; then
 748   AC_PROG_RANLIB
 749 fi
 750
 751 ## Although we're running on an amd64 kernel, we're actually compiling for
 752 ## the x86 architecture.  The user should probably have provided an
 753 ## explicit --build to `configure', but if everything else than the kernel
 754 ## is running in i386 mode, we can help them out.
 755 if test "$machine" = "amdx86-64"; then
 756   AC_CHECK_DECL([i386])
 757   if test "$ac_cv_have_decl_i386" = "yes"; then
 758     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 759     machine=intel386
 760     machfile="m/${machine}.h"
 761   fi
 762 fi
 763
 764 AC_PATH_PROG(INSTALL_INFO, install-info)
 765 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 766 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 767 dnl Don't use GZIP, which is used by gzip for additional parameters.
 768 AC_PATH_PROG(GZIP_PROG, gzip)
 769
 770
 771 ## Need makeinfo >= 4.6 (?) to build the manuals.
 772 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 773 dnl By this stage, configure has already checked for egrep and set EGREP,
 774 dnl or exited with an error if no egrep was found.
 775 if test "$MAKEINFO" != "no" && \
 776   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 777    MAKEINFO=no
 778 fi
 779
 780 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 781 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 782 ## therefore in the category of "special tools" not normally required, which
 783 ## configure does not have to check for (eg autoconf itself).
 784 ## In a Bazaar checkout on the other hand, the manuals are not included.
 785 ## So makeinfo is a requirement to build from Bazaar, and configure
 786 ## should test for it as it does for any other build requirement.
 787 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 788 ## with pre-built manuals, from a Bazaar checkout.
 789 HAVE_MAKEINFO=yes
 790
 791 if test "$MAKEINFO" = "no"; then
 792   MAKEINFO=makeinfo
 793   if test "x${with_makeinfo}" = "xno"; then
 794     HAVE_MAKEINFO=no
 795   elif test ! -e $srcdir/info/emacs; then
 796     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 797 source tree does not seem to have pre-built manuals in the `info' directory.
 798 Either install a suitable version of makeinfo, or re-run configure
 799 with the `--without-makeinfo' option to build without the manuals.] )
 800   fi
 801 fi
 802 AC_SUBST(HAVE_MAKEINFO)
 803
 804 dnl Add our options to ac_link now, after it is set up.
 805
 806 if test x$GCC = xyes; then
 807   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 808     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 809 else
 810   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 811     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 812 fi
 813
 814 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 815 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 816 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 817 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 818 dnl if not built to support GNU ld.
 819
 820 late_LDFLAGS=$LDFLAGS
 821 if test x$GCC = xyes; then
 822   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 823 else
 824   LDFLAGS="$LDFLAGS -znocombreloc"
 825 fi
 826
 827 AC_MSG_CHECKING([for -znocombreloc])
 828 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 829   [AC_MSG_RESULT(yes)],
 830   LDFLAGS=$late_LDFLAGS
 831   [AC_MSG_RESULT(no)])
 832
 833
 834 # The value of CPP is a quoted variable reference, so we need to do this
 835 # to get its actual value...
 836 CPP=`eval "echo $CPP"`
 837
 838
 839 dnl The function dump-emacs will not be defined and temacs will do
 840 dnl (load "loadup") automatically unless told otherwise.
 841 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 842 case "$opsys" in
 843   your-opsys-here) CANNOT_DUMP=yes ;;
 844 esac
 845
 846 test "$CANNOT_DUMP" = "yes" && \
 847   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 848
 849 AC_SUBST(CANNOT_DUMP)
 850
 851
 852 UNEXEC_OBJ=unexelf.o
 853 case "$opsys" in
 854   # MSDOS uses unexcoff.o
 855   # MSWindows uses unexw32.o
 856   aix4-2)
 857    UNEXEC_OBJ=unexaix.o
 858    ;;
 859   cygwin)
 860    UNEXEC_OBJ=unexcw.o
 861    ;;
 862   darwin)
 863    UNEXEC_OBJ=unexmacosx.o
 864    ;;
 865   hpux10-20 | hpux11)
 866    UNEXEC_OBJ=unexhp9k800.o
 867    ;;
 868   sol2-10)
 869    # Use the Solaris dldump() function, called from unexsol.c, to dump
 870    # emacs, instead of the generic ELF dump code found in unexelf.c.
 871    # The resulting binary has a complete symbol table, and is better
 872    # for debugging and other observability tools (debuggers, pstack, etc).
 873    #
 874    # If you encounter a problem using dldump(), please consider sending
 875    # a message to the OpenSolaris tools-linking mailing list:
 876    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 877    #
 878    # It is likely that dldump() works with older Solaris too, but this has
 879    # not been tested, so for now this change is for Solaris 10 or newer.
 880    UNEXEC_OBJ=unexsol.o
 881    ;;
 882 esac
 883
 884 LD_SWITCH_SYSTEM=
 885 case "$opsys" in
 886   freebsd)
 887    ## Let `ld' find image libs and similar things in /usr/local/lib.
 888    ## The system compiler, GCC, has apparently been modified to not
 889    ## look there, contrary to what a stock GCC would do.
 890    LD_SWITCH_SYSTEM=-L/usr/local/lib
 891    ;;
 892
 893   gnu-linux)
 894    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 895    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 896    ;;
 897
 898   netbsd)
 899    LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 900    ;;
 901
 902   openbsd)
 903    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 904    ## otherwise Emacs dumps core on elf systems.
 905    LD_SWITCH_SYSTEM="-Z"
 906    ;;
 907 esac
 908 AC_SUBST(LD_SWITCH_SYSTEM)
 909
 910 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 911
 912 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_AUX,
 913 ## which has not been defined yet.  When this was handled with cpp,
 914 ## it was expanded to null when configure sourced the s/*.h file.
 915 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 916 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 917 ## (or somesuch), but because it is supposed to go at the _front_
 918 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 919 ## Compare with the gnu-linux case below, which added to the end
 920 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 921 ## LD_SWITCH_SYSTEM_TEMACS.
 922 case "$opsys" in
 923   netbsd|openbsd)
 924    ## _AUX_RPATH is like _AUX, but uses -rpath instead of -R.
 925    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_AUX_RPATH) $LD_SWITCH_SYSTEM" ;;
 926 esac
 927
 928
 929 C_SWITCH_MACHINE=
 930 if test "$machine" = "alpha"; then
 931   AC_CHECK_DECL([__ELF__])
 932   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 933     ## With ELF, make sure that all common symbols get allocated to in the
 934     ## data section.  Otherwise, the dump of temacs may miss variables in
 935     ## the shared library that have been initialized.  For example, with
 936     ## GNU libc, __malloc_initialized would normally be resolved to the
 937     ## shared library's .bss section, which is fatal.
 938     if test "x$GCC" = "xyes"; then
 939       C_SWITCH_MACHINE="-fno-common"
 940     else
 941       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 942     fi
 943   else
 944     UNEXEC_OBJ=unexalpha.o
 945   fi
 946 fi
 947 AC_SUBST(C_SWITCH_MACHINE)
 948
 949 AC_SUBST(UNEXEC_OBJ)
 950
 951 C_SWITCH_SYSTEM=
 952 ## Some programs in src produce warnings saying certain subprograms
 953 ## are too complex and need a MAXMEM value greater than 2000 for
 954 ## additional optimization.  --nils@exp-math.uni-essen.de
 955 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 956   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 957 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 958 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 959 AC_SUBST(C_SWITCH_SYSTEM)
 960
 961
 962 LIBS_SYSTEM=
 963 case "$opsys" in
 964   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 965   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 966
 967   freebsd) LIBS_SYSTEM="-lutil" ;;
 968
 969   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 970
 971   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
 972
 973   ## Motif needs -lgen.
 974   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
 975 esac
 976 AC_SUBST(LIBS_SYSTEM)
 977
 978
 979 ### Make sure subsequent tests use flags consistent with the build flags.
 980
 981 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 982   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 983 else
 984   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
 985 fi
 986
 987 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
 988 AC_DEFUN([AC_TYPE_SIZE_T])
 989 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
 990 AC_DEFUN([AC_TYPE_UID_T])
 991
 992 dnl Do this early because it can frob feature test macros for Unix-98 &c.
 993 AC_SYS_LARGEFILE
 994
 995
 996 LIB_MATH=-lm
 997 LIB_STANDARD=
 998 START_FILES=
 999
1000 case $opsys in
1001   cygwin )
1002     LIB_MATH=
1003     START_FILES='pre-crt0.o'
1004     ;;
1005   darwin )
1006     ## Adding -lm confuses the dynamic linker, so omit it.
1007     LIB_MATH=
1008     START_FILES='pre-crt0.o'
1009     ;;
1010   freebsd )
1011     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1012     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1013     ;;
1014   gnu-linux | gnu-kfreebsd )
1015     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1016     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1017     ;;
1018   hpux10-20 | hpux11 )
1019     LIB_STANDARD=-lc
1020     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1021     ;;
1022   netbsd | openbsd )
1023     if test -f $CRT_DIR/crti.o; then
1024         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1025         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1026     else
1027         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1028         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1029     fi
1030     ;;
1031 esac
1032
1033 AC_SUBST(LIB_MATH)
1034 AC_SUBST(START_FILES)
1035
1036 dnl Not all platforms use crtn.o files.  Check if the current one does.
1037 crt_files=
1038
1039 for file in x $LIB_STANDARD $START_FILES; do
1040   case "$file" in
1041     *CRT_DIR*) crt_files="$crt_files `echo $file | sed -e 's|.*/||'`" ;;
1042   esac
1043 done
1044
1045 if test "x$crt_files" != x; then
1046
1047   ## If user specified a crt-dir, use that unconditionally.
1048   crt_gcc=no
1049
1050   if test "X$CRT_DIR" = "X"; then
1051
1052     CRT_DIR=/usr/lib            # default
1053
1054     case "$canonical" in
1055       x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1056       ## On x86-64 and s390x GNU/Linux distributions, the standard library
1057       ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1058       ## For anything else (eg /usr/lib32), it is up the user to specify
1059       ## the location (bug#5655).
1060       ## Test for crtn.o, not just the directory, because sometimes the
1061       ## directory exists but does not have the relevant files (bug#1287).
1062       ## FIXME better to test for binary compatibility somehow.
1063       test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1064       ;;
1065
1066       powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1067     esac
1068
1069     case "$opsys" in
1070       hpux10-20) CRT_DIR=/lib ;;
1071     esac
1072
1073     test "x${GCC}" = xyes && crt_gcc=yes
1074
1075   fi                            # CRT_DIR = ""
1076
1077   crt_missing=
1078
1079   for file in $crt_files; do
1080
1081     ## If we're using gcc, try to determine it automatically by asking
1082     ## gcc.  [If this doesn't work, CRT_DIR will remain at the
1083     ## system-dependent default from above.]
1084     if test $crt_gcc = yes && test ! -e $CRT_DIR/$file; then
1085
1086        crt_file=`$CC --print-file-name=$file 2>/dev/null`
1087        case "$crt_file" in
1088          */*)
1089            CRT_DIR=`AS_DIRNAME(["$crt_file"])`
1090            ;;
1091        esac
1092     fi
1093
1094     dnl We expect all the files to be in a single directory, so after the
1095     dnl first there is no point asking gcc.
1096     crt_gcc=no
1097
1098     test -e $CRT_DIR/$file || crt_missing="$crt_missing $file"
1099   done                          # $crt_files
1100
1101   test "x$crt_missing" = x || \
1102     AC_MSG_ERROR([Required file(s) not found:$crt_missing
1103 Try using the --with-crt-dir option.])
1104
1105 fi                              # crt_files != ""
1106
1107 AC_SUBST(CRT_DIR)
1108
1109
1110 dnl This function definition taken from Gnome 2.0
1111 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1112 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1113 dnl also defines GSTUFF_PKG_ERRORS on error
1114 AC_DEFUN([PKG_CHECK_MODULES], [
1115   succeeded=no
1116
1117   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1118
1119   if test "$PKG_CONFIG" = "no" ; then
1120      ifelse([$4], , [AC_MSG_ERROR([
1121       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1122   else
1123      PKG_CONFIG_MIN_VERSION=0.9.0
1124      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1125         AC_MSG_CHECKING(for $2)
1126
1127         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1128             AC_MSG_RESULT(yes)
1129             succeeded=yes
1130
1131             AC_MSG_CHECKING($1_CFLAGS)
1132             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1133             AC_MSG_RESULT($$1_CFLAGS)
1134
1135             AC_MSG_CHECKING($1_LIBS)
1136             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1137             AC_MSG_RESULT($$1_LIBS)
1138         else
1139             AC_MSG_RESULT(no)
1140             $1_CFLAGS=""
1141             $1_LIBS=""
1142             ## If we have a custom action on failure, don't print errors, but
1143             ## do set a variable so people can do so.
1144             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1145             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1146         fi
1147
1148         AC_SUBST($1_CFLAGS)
1149         AC_SUBST($1_LIBS)
1150      else
1151         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1152         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1153      fi
1154   fi
1155
1156   if test $succeeded = yes; then
1157      ifelse([$3], , :, [$3])
1158   else
1159      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1160   fi
1161 ])
1162
1163
1164 if test "${with_sound}" != "no"; then
1165   # Sound support for GNU/Linux and the free BSDs.
1166   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1167     have_sound_header=yes)
1168   # Emulation library used on NetBSD.
1169   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1170   AC_SUBST(LIBSOUND)
1171
1172   ALSA_REQUIRED=1.0.0
1173   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1174   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1175   if test $HAVE_ALSA = yes; then
1176     SAVE_CFLAGS="$CFLAGS"
1177     SAVE_LDFLAGS="$LDFLAGS"
1178     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1179     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1180     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1181                     emacs_alsa_normal=yes,
1182                     emacs_alsa_normal=no)
1183     if test "$emacs_alsa_normal" != yes; then
1184       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1185                      [[snd_lib_error_set_handler (0);]])],
1186                      emacs_alsa_subdir=yes,
1187                      emacs_alsa_subdir=no)
1188       if test "$emacs_alsa_subdir" != yes; then
1189         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1190       fi
1191       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1192     fi
1193
1194     CFLAGS="$SAVE_CFLAGS"
1195     LDFLAGS="$SAVE_LDFLAGS"
1196     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1197     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1198     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1199   fi
1200
1201   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1202   dnl compiles only on the specified platforms.  For others, it
1203   dnl probably doesn't make sense to try.
1204   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1205      case "$opsys" in
1206        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1207        gnu-linux|freebsd|netbsd)
1208          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1209          ;;
1210      esac
1211   fi
1212
1213   AC_SUBST(CFLAGS_SOUND)
1214 fi
1215
1216 dnl checks for header files
1217 AC_CHECK_HEADERS(sys/select.h sys/time.h unistd.h utime.h \
1218   linux/version.h sys/systeminfo.h limits.h \
1219   stdio_ext.h fcntl.h coff.h pty.h sys/mman.h \
1220   sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1221   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1222
1223 AC_MSG_CHECKING(if personality LINUX32 can be set)
1224 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1225                emacs_cv_personality_linux32=yes,
1226                emacs_cv_personality_linux32=no)
1227 AC_MSG_RESULT($emacs_cv_personality_linux32)
1228
1229 if test $emacs_cv_personality_linux32 = yes; then
1230   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1231             [Define to 1 if personality LINUX32 can be set.])
1232 fi
1233
1234 dnl On Solaris 8 there's a compilation warning for term.h because
1235 dnl it doesn't define `bool'.
1236 AC_CHECK_HEADERS(term.h, , , -)
1237 AC_HEADER_STDC
1238 AC_HEADER_TIME
1239 AC_CHECK_DECLS([sys_siglist])
1240 if test $ac_cv_have_decl_sys_siglist != yes; then
1241   # For Tru64, at least:
1242   AC_CHECK_DECLS([__sys_siglist])
1243   if test $ac_cv_have_decl___sys_siglist = yes; then
1244     AC_DEFINE(sys_siglist, __sys_siglist,
1245               [Define to any substitute for sys_siglist.])
1246   fi
1247 fi
1248 AC_HEADER_SYS_WAIT
1249
1250 dnl Some systems have utime.h but don't declare the struct anyplace.
1251 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1252 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
1253 #include <sys/time.h>
1254 #include <time.h>
1255 #else
1256 #ifdef HAVE_SYS_TIME_H
1257 #include <sys/time.h>
1258 #else
1259 #include <time.h>
1260 #endif
1261 #endif
1262 #ifdef HAVE_UTIME_H
1263 #include <utime.h>
1264 #endif]], [[static struct utimbuf x; x.actime = x.modtime;]])],
1265   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1266 if test $emacs_cv_struct_utimbuf = yes; then
1267   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1268 fi
1269
1270 dnl Check for speed_t typedef.
1271 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1272   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <termios.h>]], [[speed_t x = 1;]])],
1273     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1274 if test $emacs_cv_speed_t = yes; then
1275   AC_DEFINE(HAVE_SPEED_T, 1,
1276            [Define to 1 if `speed_t' is declared by <termios.h>.])
1277 fi
1278
1279 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1280 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
1281 #include <sys/time.h>
1282 #include <time.h>
1283 #else
1284 #ifdef HAVE_SYS_TIME_H
1285 #include <sys/time.h>
1286 #else
1287 #include <time.h>
1288 #endif
1289 #endif]], [[static struct timeval x; x.tv_sec = x.tv_usec;]])],
1290   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1291 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1292 if test $emacs_cv_struct_timeval = yes; then
1293   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1294 fi
1295
1296 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1297 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]],
1298 [[static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;]])],
1299   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1300 HAVE_EXCEPTION=$emacs_cv_struct_exception
1301 if test $emacs_cv_struct_exception != yes; then
1302   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1303 fi
1304
1305 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1306 #if HAVE_SYS_SOCKET_H
1307 #include <sys/socket.h>
1308 #endif])
1309
1310 dnl checks for structure members
1311 AC_STRUCT_TM
1312 AC_STRUCT_TIMEZONE
1313 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1314                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1315                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1316                 [#include <time.h>])
1317 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1318                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1319                   struct ifreq.ifr_addr], , ,
1320                  [AC_INCLUDES_DEFAULT
1321 #if HAVE_SYS_SOCKET_H
1322 #include <sys/socket.h>
1323 #endif
1324 #if HAVE_NET_IF_H
1325 #include <net/if.h>
1326 #endif])
1327
1328 dnl checks for compiler characteristics
1329
1330 dnl Testing __STDC__ to determine prototype support isn't good enough.
1331 dnl DEC C, for instance, doesn't define it with default options, and
1332 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1333 dnl and void *.
1334 AC_C_PROTOTYPES
1335 AC_C_VOLATILE
1336 AC_C_CONST
1337 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1338   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [[void * foo;]])],
1339                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1340 if test $emacs_cv_void_star = yes; then
1341   AC_DEFINE(POINTER_TYPE, void)
1342 else
1343   AC_DEFINE(POINTER_TYPE, char)
1344 fi
1345 AH_TEMPLATE(POINTER_TYPE,
1346             [Define as `void' if your compiler accepts `void *'; otherwise
1347              define as `char'.])dnl
1348
1349 dnl Check for endianess
1350 AC_C_BIGENDIAN
1351
1352 AC_CACHE_CHECK([for  __attribute__ ((__aligned__ (expr)))],
1353   [emacs_cv_attribute_aligned],
1354   [AC_COMPILE_IFELSE(
1355      [AC_LANG_PROGRAM(
1356         [[char __attribute__ ((__aligned__ (1 << 3))) c;]],
1357         [[]])],
1358      [emacs_cv_attribute_aligned=yes],
1359      [emacs_cv_attribute_aligned=no])])
1360 if test $emacs_cv_attribute_aligned = yes; then
1361   AC_DEFINE([HAVE_ATTRIBUTE_ALIGNED], 1,
1362     [Define to 1 if GCC-style __attribute__ ((__aligned__ (expr))) works.])
1363 fi
1364
1365 dnl check for Make feature
1366 AC_PROG_MAKE_SET
1367
1368 DEPFLAGS=
1369 MKDEPDIR=":"
1370 deps_frag=deps.mk
1371 dnl check for GNU Make if we have GCC and autodepend is on.
1372 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1373    AC_MSG_CHECKING([whether we are using GNU Make])
1374    HAVE_GNU_MAKE=no
1375    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1376    if test "x$testval" != x; then
1377       HAVE_GNU_MAKE=yes
1378    else
1379       ac_enable_autodepend=no
1380    fi
1381    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1382    if test $HAVE_GNU_MAKE = yes; then
1383       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1384       SAVE_CFLAGS="$CFLAGS"
1385       CFLAGS="$CFLAGS -MMD -MF deps.d"
1386       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1387       CFLAGS="$SAVE_CFLAGS"
1388       test -f deps.d || ac_enable_autodepend=no
1389       rm -rf deps.d
1390       AC_MSG_RESULT([$ac_enable_autodepend])
1391    fi
1392    if test $ac_enable_autodepend = yes; then
1393       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d'
1394       ## In parallel builds, another make might create depdir between
1395       ## the first test and mkdir, so stick another test on the end.
1396       ## Or use install-sh -d?  mkdir -p is not portable.
1397       MKDEPDIR='test -d ${DEPDIR} || mkdir ${DEPDIR} || test -d ${DEPDIR}'
1398       deps_frag=autodeps.mk
1399    fi
1400 fi
1401 deps_frag=$srcdir/src/$deps_frag
1402 AC_SUBST(MKDEPDIR)
1403 AC_SUBST(DEPFLAGS)
1404 AC_SUBST_FILE(deps_frag)
1405
1406
1407 lisp_frag=$srcdir/src/lisp.mk
1408 AC_SUBST_FILE(lisp_frag)
1409
1410
1411 dnl checks for operating system services
1412 AC_SYS_LONG_FILE_NAMES
1413
1414 #### Choose a window system.
1415
1416 AC_PATH_X
1417 if test "$no_x" = yes; then
1418   window_system=none
1419 else
1420   window_system=x11
1421 fi
1422
1423 ## Workaround for bug in autoconf <= 2.62.
1424 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1425 ## No need to do anything special for these standard directories.
1426 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1427
1428    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1429
1430 fi
1431
1432 LD_SWITCH_X_SITE_AUX=
1433 LD_SWITCH_X_SITE_AUX_RPATH=
1434 if test "${x_libraries}" != NONE; then
1435   if test -n "${x_libraries}"; then
1436     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1437     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1438     LD_SWITCH_X_SITE_AUX_RPATH=`echo ${LD_SWITCH_X_SITE_AUX} | sed -e 's/-R/-Wl,-rpath,/'`
1439   fi
1440   x_default_search_path=""
1441   x_search_path=${x_libraries}
1442   if test -z "${x_search_path}"; then
1443     x_search_path=/usr/lib
1444   fi
1445   for x_library in `echo ${x_search_path}: | \
1446                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1447     x_search_path="\
1448 ${x_library}/X11/%L/%T/%N%C%S:\
1449 ${x_library}/X11/%l/%T/%N%C%S:\
1450 ${x_library}/X11/%T/%N%C%S:\
1451 ${x_library}/X11/%L/%T/%N%S:\
1452 ${x_library}/X11/%l/%T/%N%S:\
1453 ${x_library}/X11/%T/%N%S"
1454     if test x"${x_default_search_path}" = x; then
1455       x_default_search_path=${x_search_path}
1456     else
1457       x_default_search_path="${x_search_path}:${x_default_search_path}"
1458     fi
1459   done
1460 fi
1461 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1462 AC_SUBST(LD_SWITCH_X_SITE_AUX_RPATH)
1463
1464 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1465   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1466 fi
1467
1468 if test x"${x_includes}" = x; then
1469   bitmapdir=/usr/include/X11/bitmaps
1470 else
1471   # accumulate include directories that have X11 bitmap subdirectories
1472   bmd_acc="dummyval"
1473   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1474     if test -d "${bmd}/X11/bitmaps"; then
1475       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1476     fi
1477     if test -d "${bmd}/bitmaps"; then
1478       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1479     fi
1480   done
1481   if test ${bmd_acc} != "dummyval"; then
1482     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1483   fi
1484 fi
1485
1486 HAVE_NS=no
1487 NS_IMPL_COCOA=no
1488 NS_IMPL_GNUSTEP=no
1489 tmp_CPPFLAGS="$CPPFLAGS"
1490 tmp_CFLAGS="$CFLAGS"
1491 CPPFLAGS="$CPPFLAGS -x objective-c"
1492 CFLAGS="$CFLAGS -x objective-c"
1493 TEMACS_LDFLAGS2="\${LDFLAGS}"
1494 dnl I don't think it's especially important, but src/Makefile.in
1495 dnl (now the only user of ns_appdir) used to go to the trouble of adding a
1496 dnl trailing "/" to it, so now we do it here.
1497 if test "${with_ns}" != no; then
1498   if test "${opsys}" = darwin; then
1499      NS_IMPL_COCOA=yes
1500      ns_appdir=`pwd`/nextstep/Emacs.app
1501      ns_appbindir=${ns_appdir}/Contents/MacOS/
1502      ns_appresdir=${ns_appdir}/Contents/Resources
1503      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1504   elif test -f $GNUSTEP_CONFIG_FILE; then
1505      NS_IMPL_GNUSTEP=yes
1506      ns_appdir=`pwd`/nextstep/Emacs.app
1507      ns_appbindir=${ns_appdir}/
1508      ns_appresdir=${ns_appdir}/Resources
1509      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1510      dnl FIXME sourcing this several times in subshells seems inefficient.
1511      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1512      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1513      dnl I seemed to need these as well with GNUstep-startup 0.25.
1514      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1515      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1516      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1517        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1518      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1519        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1520      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1521      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1522      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1523      LIB_STANDARD=
1524      START_FILES=
1525      TEMACS_LDFLAGS2=
1526   fi
1527   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1528                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1529   files are missing or cannot be compiled.])])
1530   NS_HAVE_NSINTEGER=yes
1531   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1532                                      [NSInteger i;])],
1533                     ns_have_nsinteger=yes,
1534                     ns_have_nsinteger=no)
1535   if test $ns_have_nsinteger = no; then
1536     NS_HAVE_NSINTEGER=no
1537   fi
1538 fi
1539 AC_SUBST(TEMACS_LDFLAGS2)
1540
1541 ns_frag=/dev/null
1542 NS_OBJ=
1543 NS_OBJC_OBJ=
1544 if test "${HAVE_NS}" = yes; then
1545   window_system=nextstep
1546   with_xft=no
1547   # set up packaging dirs
1548   exec_prefix=${ns_appbindir}
1549   libexecdir=${ns_appbindir}/libexec
1550   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1551      prefix=${ns_appresdir}
1552   fi
1553   ns_frag=$srcdir/src/ns.mk
1554   NS_OBJ="fontset.o fringe.o image.o"
1555   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o"
1556 fi
1557 CFLAGS="$tmp_CFLAGS"
1558 CPPFLAGS="$tmp_CPPFLAGS"
1559 AC_SUBST(NS_OBJ)
1560 AC_SUBST(NS_OBJC_OBJ)
1561 AC_SUBST(LIB_STANDARD)
1562 AC_SUBST_FILE(ns_frag)
1563
1564 case "${window_system}" in
1565   x11 )
1566     HAVE_X_WINDOWS=yes
1567     HAVE_X11=yes
1568     case "${with_x_toolkit}" in
1569       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1570       motif ) USE_X_TOOLKIT=MOTIF ;;
1571       gtk ) with_gtk=yes
1572 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1573 dnl USE_X_TOOLKIT is set.
1574             USE_X_TOOLKIT=none ;;
1575       gtk3 ) with_gtk3=yes
1576              USE_X_TOOLKIT=none ;;
1577       no ) USE_X_TOOLKIT=none ;;
1578 dnl If user did not say whether to use a toolkit, make this decision later:
1579 dnl use the toolkit if we have gtk, or X11R5 or newer.
1580       * ) USE_X_TOOLKIT=maybe ;;
1581     esac
1582   ;;
1583   nextstep | none )
1584     HAVE_X_WINDOWS=no
1585     HAVE_X11=no
1586     USE_X_TOOLKIT=none
1587   ;;
1588 esac
1589
1590 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1591    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1592    if test "$HAVE_XSERVER" = true ||
1593       test -n "$DISPLAY" ||
1594       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1595         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1596 were found.  You should install the relevant development files for X
1597 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1598 sure you have development files for image handling, i.e.
1599 tiff, gif, jpeg, png and xpm.
1600 If you are sure you want Emacs compiled without X window support, pass
1601   --without-x
1602 to configure.])
1603    fi
1604 fi
1605
1606 ### If we're using X11, we should use the X menu package.
1607 HAVE_MENUS=no
1608 case ${HAVE_X11} in
1609   yes ) HAVE_MENUS=yes ;;
1610 esac
1611
1612 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1613 # Assume not, until told otherwise.
1614 GNU_MALLOC=yes
1615 doug_lea_malloc=yes
1616 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1617 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1618 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1619                emacs_cv_var___after_morecore_hook,
1620 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[extern void (* __after_morecore_hook)();]],[[__after_morecore_hook = 0]])],
1621   emacs_cv_var___after_morecore_hook=yes,
1622   emacs_cv_var___after_morecore_hook=no)])
1623 if test $emacs_cv_var___after_morecore_hook = no; then
1624   doug_lea_malloc=no
1625 fi
1626
1627
1628 dnl See comments in aix4-2.h about maybe using system malloc there.
1629 system_malloc=no
1630 case "$opsys" in
1631   ## darwin ld insists on the use of malloc routines in the System framework.
1632   darwin|sol2-10) system_malloc=yes ;;
1633 esac
1634
1635 if test "${system_malloc}" = "yes"; then
1636   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1637   GNU_MALLOC=no
1638   GNU_MALLOC_reason="
1639     (The GNU allocators don't work with this system configuration.)"
1640   GMALLOC_OBJ=
1641   VMLIMIT_OBJ=
1642 else
1643   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1644   VMLIMIT_OBJ=vm-limit.o
1645 fi
1646 AC_SUBST(GMALLOC_OBJ)
1647 AC_SUBST(VMLIMIT_OBJ)
1648
1649 if test "$doug_lea_malloc" = "yes" ; then
1650   if test "$GNU_MALLOC" = yes ; then
1651     GNU_MALLOC_reason="
1652       (Using Doug Lea's new malloc from the GNU C Library.)"
1653   fi
1654   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1655             [Define to 1 if you are using the GNU C Library.])
1656
1657   ## Use mmap directly for allocating larger buffers.
1658   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1659   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1660   ## Does the AC_FUNC_MMAP test below make this check unecessary?
1661   case "$opsys" in
1662     gnu*) REL_ALLOC=no ;;
1663   esac
1664 fi
1665
1666 if test x"${REL_ALLOC}" = x; then
1667   REL_ALLOC=${GNU_MALLOC}
1668 fi
1669
1670 use_mmap_for_buffers=no
1671 case "$opsys" in
1672   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1673 esac
1674
1675 AC_FUNC_MMAP
1676 if test $use_mmap_for_buffers = yes; then
1677   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1678   REL_ALLOC=no
1679 fi
1680
1681 LIBS="$LIBS_SYSTEM $LIBS"
1682
1683 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1684 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1685 AC_CHECK_LIB(dnet, dnet_ntoa)
1686 dnl This causes -lresolv to get used in subsequent tests,
1687 dnl which causes failures on some systems such as HPUX 9.
1688 dnl AC_CHECK_LIB(resolv, gethostbyname)
1689
1690 dnl FIXME replace main with a function we actually want from this library.
1691 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1692
1693 AC_CHECK_LIB(pthreads, cma_open)
1694
1695 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1696 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1697 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1698 ## added to LIBS in configure would never contain the pthreads part,
1699 ## but the value used in Makefiles might.  FIXME?
1700 ##
1701 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1702 ## be harmless on older versions of X where it happens to exist.
1703 test "$opsys" = "aix4-2" && \
1704   test $ac_cv_lib_pthreads_cma_open = yes && \
1705   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1706
1707 dnl Check for need for bigtoc support on IBM AIX
1708
1709 case ${host_os} in
1710 aix*)
1711   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1712     case $GCC in
1713     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1714     *) gdb_cv_bigtoc=-bbigtoc ;;
1715     esac
1716
1717     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1718     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
1719   ])
1720   ;;
1721 esac
1722
1723 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1724 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1725 # REAL_CPPFLAGS later on.
1726
1727 REAL_CFLAGS="$CFLAGS"
1728 REAL_CPPFLAGS="$CPPFLAGS"
1729
1730 if test "${HAVE_X11}" = "yes"; then
1731   DEFS="$C_SWITCH_X_SITE $DEFS"
1732   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1733   LIBS="-lX11 $LIBS"
1734   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1735   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1736
1737   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1738   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1739   # but it's more convenient here to set LD_RUN_PATH
1740   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1741   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1742     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1743     export LD_RUN_PATH
1744   fi
1745
1746   if test "${opsys}" = "gnu-linux"; then
1747     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1748     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1749      [[XOpenDisplay ("foo");]])],
1750      [xlinux_first_failure=no],
1751      [xlinux_first_failure=yes])
1752     if test "${xlinux_first_failure}" = "yes"; then
1753       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1754       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1755       OLD_CPPFLAGS="$CPPFLAGS"
1756       OLD_LIBS="$LIBS"
1757       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1758       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1759       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1760       LIBS="$LIBS -b i486-linuxaout"
1761       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1762        [[XOpenDisplay ("foo");]])],
1763        [xlinux_second_failure=no],
1764        [xlinux_second_failure=yes])
1765       if test "${xlinux_second_failure}" = "yes"; then
1766         # If we get the same failure with -b, there is no use adding -b.
1767         # So take it out.  This plays safe.
1768         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1769         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1770         CPPFLAGS="$OLD_CPPFLAGS"
1771         LIBS="$OLD_LIBS"
1772         AC_MSG_RESULT(no)
1773       else
1774         AC_MSG_RESULT(yes)
1775       fi
1776     else
1777       AC_MSG_RESULT(no)
1778     fi
1779   fi
1780
1781   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1782   # header files included from there.
1783   AC_MSG_CHECKING(for Xkb)
1784   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1785 #include <X11/XKBlib.h>]],
1786         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
1787         emacs_xkb=yes, emacs_xkb=no)
1788   AC_MSG_RESULT($emacs_xkb)
1789   if test $emacs_xkb = yes; then
1790     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1791   fi
1792
1793   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1794 XScreenNumberOfScreen XSetWMProtocols)
1795 fi
1796
1797 if test "${window_system}" = "x11"; then
1798   AC_MSG_CHECKING(X11 version 6)
1799   AC_CACHE_VAL(emacs_cv_x11_version_6,
1800   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
1801 [[#if XlibSpecificationRelease < 6
1802 fail;
1803 #endif
1804 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1805   if test $emacs_cv_x11_version_6 = yes; then
1806     AC_MSG_RESULT(6 or newer)
1807     AC_DEFINE(HAVE_X11R6, 1,
1808               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1809     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1810     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1811     ## XIM support.
1812     case "$opsys" in
1813       sol2-*) : ;;
1814       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1815            [Define if you have usable X11R6-style XIM support.])
1816          ;;
1817     esac
1818   else
1819     AC_MSG_RESULT(before 6)
1820   fi
1821 fi
1822
1823
1824 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1825 HAVE_RSVG=no
1826 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1827   if test "${with_rsvg}" != "no"; then
1828     RSVG_REQUIRED=2.11.0
1829     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1830
1831     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1832     AC_SUBST(RSVG_CFLAGS)
1833     AC_SUBST(RSVG_LIBS)
1834
1835     if test $HAVE_RSVG = yes; then
1836       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1837       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1838       LIBS="$RSVG_LIBS $LIBS"
1839     fi
1840   fi
1841 fi
1842
1843 HAVE_IMAGEMAGICK=no
1844 if test "${HAVE_X11}" = "yes"; then
1845   if test "${with_imagemagick}" != "no"; then
1846     ## 6.2.8 is the earliest version known to work, but earlier versions
1847     ## might work - let us know if you find one.
1848     ## 6.0.7 does not work.  See bug#7955.
1849     IMAGEMAGICK_MODULE="Wand >= 6.2.8"
1850     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1851     AC_SUBST(IMAGEMAGICK_CFLAGS)
1852     AC_SUBST(IMAGEMAGICK_LIBS)
1853
1854     if test $HAVE_IMAGEMAGICK = yes; then
1855       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1856       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1857       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1858       AC_CHECK_FUNCS(MagickExportImagePixels)
1859     fi
1860   fi
1861 fi
1862
1863
1864 HAVE_GTK=no
1865 GTK_OBJ=
1866 if test "${with_gtk3}" = "yes"; then
1867   GLIB_REQUIRED=2.28
1868   GTK_REQUIRED=3.0
1869   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1870
1871   dnl Checks for libraries.
1872   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1873   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1874      AC_MSG_ERROR($GTK_PKG_ERRORS)
1875   fi
1876   AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
1877   GTK_OBJ=emacsgtkfixed.o
1878 fi
1879
1880 if test "$pkg_check_gtk" != "yes"; then
1881   HAVE_GTK=no
1882 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1883   GLIB_REQUIRED=2.6
1884   GTK_REQUIRED=2.6
1885   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1886
1887   dnl Checks for libraries.
1888   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1889   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1890      AC_MSG_ERROR($GTK_PKG_ERRORS)
1891   fi
1892 fi
1893 fi
1894
1895 if test x"$pkg_check_gtk" = xyes; then
1896
1897   AC_SUBST(GTK_CFLAGS)
1898   AC_SUBST(GTK_LIBS)
1899   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1900   CFLAGS="$CFLAGS $GTK_CFLAGS"
1901   LIBS="$GTK_LIBS $LIBS"
1902   dnl Try to compile a simple GTK program.
1903   GTK_COMPILES=no
1904   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1905   if test "${GTK_COMPILES}" != "yes"; then
1906     if test "$USE_X_TOOLKIT" != "maybe"; then
1907       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1908     fi
1909   else
1910     HAVE_GTK=yes
1911     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1912     GTK_OBJ="gtkutil.o $GTK_OBJ"
1913     USE_X_TOOLKIT=none
1914     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1915       :
1916     else
1917       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1918        closing open displays.  This is no problem if you just use
1919        one display, but if you use more than one and close one of them
1920        Emacs may crash.]])
1921       sleep 3
1922     fi
1923   fi
1924
1925 fi
1926 AC_SUBST(GTK_OBJ)
1927
1928
1929 if test "${HAVE_GTK}" = "yes"; then
1930
1931   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1932   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1933   if test "$with_toolkit_scroll_bars" != no; then
1934     with_toolkit_scroll_bars=yes
1935   fi
1936
1937   dnl  Check if we have the old file selection dialog declared and
1938   dnl  in the link library.  In 2.x it may be in the library,
1939   dnl  but not declared if deprecated featured has been selected out.
1940   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1941   HAVE_GTK_FILE_SELECTION=no
1942   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1943                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1944 #include <gtk/gtk.h>])
1945   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1946     AC_CHECK_FUNCS(gtk_file_selection_new)
1947   fi
1948
1949   dnl Check if pthreads are available.  Emacs only needs this when using
1950   dnl gtk_file_chooser under Gnome.
1951     HAVE_GTK_AND_PTHREAD=no
1952     AC_CHECK_HEADERS(pthread.h)
1953     if test "$ac_cv_header_pthread_h"; then
1954       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1955     fi
1956     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1957       case "${canonical}" in
1958         *-hpux*) ;;
1959         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1960       esac
1961       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1962                [Define to 1 if you have GTK and pthread (-lpthread).])
1963     fi
1964
1965   dnl Check for functions introduced in 2.14 and later.
1966   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1967                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1968                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1969                  gtk_orientable_set_orientation)
1970
1971 fi
1972
1973
1974 HAVE_XWIDGETS=no
1975 HAVE_WEBKIT=no
1976 HAVE_GOOCANVAS=no
1977 HAVE_CLUTTER=no
1978 if test "${with_xwidgets}" != "no"; then
1979    echo "xwidgets enabled, checking webkit, and others"
1980    HAVE_XWIDGETS=yes
1981    AC_DEFINE(HAVE_XWIDGETS, 1, [Define to 1 if you have xwidgets support.])
1982 #xwidgets
1983 #TODO
1984 # - enable only if gtk/gtk3 enabled
1985 # - webkit, goocanvas, clutter
1986 # - only webkit_osr is good so remove plain webkit laterish
1987
1988 #webkit version for gtk3.
1989   WEBKIT_REQUIRED=1.4.0
1990   WEBKIT_MODULES="webkitgtk-3.0 >= $WEBKIT_REQUIRED"
1991
1992   if test "${with_gtk3}" = "yes"; then
1993     PKG_CHECK_MODULES(WEBKIT, $WEBKIT_MODULES, HAVE_WEBKIT=yes, HAVE_WEBKIT=no)
1994     if test $HAVE_WEBKIT = yes; then
1995         AC_DEFINE(HAVE_WEBKIT_OSR, 1, [Define to 1 if you have webkit_osr support.])
1996     fi
1997   fi
1998
1999   CLUTTER_REQUIRED=1.0.0
2000   CLUTTER_MODULES="clutter-gtk-1.0 >= $CLUTTER_REQUIRED"
2001
2002   PKG_CHECK_MODULES(CLUTTER, $CLUTTER_MODULES, HAVE_CLUTTER=yes, HAVE_CLUTTER=no)
2003   if test $HAVE_CLUTTER = yes; then
2004      AC_DEFINE(HAVE_CLUTTER, 1, [Define to 1 if you have clutter support.])
2005   fi
2006
2007 #TODO
2008   GOOCANVAS_REQUIRED=1.4.0
2009   GOOCANVAS_MODULES="goocanvasgtk-3.0 >= $GOOCANVAS_REQUIRED"
2010
2011   PKG_CHECK_MODULES(GOOCANVAS, $GOOCANVAS_MODULES, HAVE_GOOCANVAS=yes, HAVE_GOOCANVAS=no)
2012   if test $HAVE_GOOCANVAS = yes; then
2013      AC_DEFINE(HAVE_GOOCANVAS, 1, [Define to 1 if you have goocanvas support.])
2014   fi
2015
2016 fi
2017
2018
2019 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2020 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
2021 dnl also not configured.
2022 HAVE_DBUS=no
2023 DBUS_OBJ=
2024 if test "${with_dbus}" = "yes"; then
2025    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
2026    if test "$HAVE_DBUS" = yes; then
2027      LIBS="$LIBS $DBUS_LIBS"
2028      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2029      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
2030      DBUS_OBJ=dbusbind.o
2031    fi
2032 fi
2033 AC_SUBST(DBUS_OBJ)
2034
2035 dnl GSettings has been tested under GNU/Linux only.
2036 HAVE_GSETTINGS=no
2037 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2038    PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
2039    if test "$HAVE_GSETTINGS" = "yes"; then
2040       AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2041       SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2042       SETTINGS_LIBS="$GSETTINGS_LIBS"
2043    fi
2044 fi
2045
2046 dnl GConf has been tested under GNU/Linux only.
2047 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2048 HAVE_GCONF=no
2049 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2050    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
2051    if test "$HAVE_GCONF" = yes; then
2052       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2053       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2054       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2055       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2056    fi
2057 fi
2058
2059 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2060     SAVE_CFLAGS="$CFLAGS"
2061     SAVE_LDFLAGS="$LDFLAGS"
2062     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2063     LDFLAGS="$SETTINGS_LIBS $LDFLAGS"
2064     AC_CHECK_FUNCS([g_type_init])
2065     CFLAGS="$SAVE_CFLAGS"
2066     LDFLAGS="$SAVE_LDFLAGS"
2067 fi
2068 AC_SUBST(SETTINGS_CFLAGS)
2069 AC_SUBST(SETTINGS_LIBS)
2070
2071
2072 dnl SELinux is available for GNU/Linux only.
2073 HAVE_LIBSELINUX=no
2074 LIBSELINUX_LIBS=
2075 if test "${with_selinux}" = "yes"; then
2076    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2077    if test "$HAVE_LIBSELINUX" = yes; then
2078       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2079       LIBSELINUX_LIBS=-lselinux
2080    fi
2081 fi
2082 AC_SUBST(LIBSELINUX_LIBS)
2083
2084 HAVE_GNUTLS=no
2085 HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=no
2086 if test "${with_gnutls}" = "yes" ; then
2087   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.0], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2088   if test "${HAVE_GNUTLS}" = "yes"; then
2089     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2090   fi
2091
2092   CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
2093   LIBS="$LIBGNUTLS_LIBS $LIBS"
2094   AC_CHECK_FUNCS(gnutls_certificate_set_verify_function, HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=yes)
2095
2096   if test "${HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY}" = "yes"; then
2097     AC_DEFINE(HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY, 1, [Define if using GnuTLS certificate verification callbacks.])
2098   fi
2099 fi
2100
2101 AC_SUBST(LIBGNUTLS_LIBS)
2102 AC_SUBST(LIBGNUTLS_CFLAGS)
2103
2104 dnl Do not put whitespace before the #include statements below.
2105 dnl Older compilers (eg sunos4 cc) choke on it.
2106 HAVE_XAW3D=no
2107 LUCID_LIBW=
2108 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2109   if test "$with_xaw3d" != no; then
2110     AC_MSG_CHECKING(for xaw3d)
2111     AC_CACHE_VAL(emacs_cv_xaw3d,
2112     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2113 #include <X11/Intrinsic.h>
2114 #include <X11/Xaw3d/Simple.h>]],
2115       [[]])],
2116       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2117                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2118       emacs_cv_xaw3d=no)])
2119   else
2120     emacs_cv_xaw3d=no
2121   fi
2122   if test $emacs_cv_xaw3d = yes; then
2123     AC_MSG_RESULT([yes; using Lucid toolkit])
2124     USE_X_TOOLKIT=LUCID
2125     HAVE_XAW3D=yes
2126     LUCID_LIBW=-lXaw3d
2127     AC_DEFINE(HAVE_XAW3D, 1,
2128               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2129   else
2130     AC_MSG_RESULT(no)
2131     AC_MSG_CHECKING(for libXaw)
2132     AC_CACHE_VAL(emacs_cv_xaw,
2133     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2134 #include <X11/Intrinsic.h>
2135 #include <X11/Xaw/Simple.h>]],
2136       [[]])],
2137       emacs_cv_xaw=yes,
2138       emacs_cv_xaw=no)])
2139     if test $emacs_cv_xaw = yes; then
2140       AC_MSG_RESULT([yes; using Lucid toolkit])
2141       USE_X_TOOLKIT=LUCID
2142       LUCID_LIBW=-lXaw
2143     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2144       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2145     else
2146       AC_MSG_ERROR([No X toolkit could be found.
2147 If you are sure you want Emacs compiled without an X toolkit, pass
2148   --with-x-toolkit=no
2149 to configure.  Otherwise, install the development libraries for the toolkit
2150 that you want to use (e.g. Gtk+) and re-run configure.])
2151     fi
2152   fi
2153 fi
2154
2155 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2156
2157 LIBXTR6=
2158 if test "${USE_X_TOOLKIT}" != "none"; then
2159   AC_MSG_CHECKING(X11 toolkit version)
2160   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2161   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2162 [[#if XtSpecificationRelease < 6
2163 fail;
2164 #endif
2165 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2166   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2167   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2168     AC_MSG_RESULT(6 or newer)
2169     AC_DEFINE(HAVE_X11XTR6, 1,
2170               [Define to 1 if you have the X11R6 or newer version of Xt.])
2171     LIBXTR6="-lSM -lICE"
2172     case "$opsys" in
2173       ## Use libw.a along with X11R6 Xt.
2174       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2175     esac
2176   else
2177     AC_MSG_RESULT(before 6)
2178   fi
2179
2180 dnl If using toolkit, check whether libXmu.a exists.
2181 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2182   OLDLIBS="$LIBS"
2183   if test x$HAVE_X11XTR6 = xyes; then
2184     LIBS="-lXt -lSM -lICE $LIBS"
2185   else
2186     LIBS="-lXt $LIBS"
2187   fi
2188   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2189   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2190 fi
2191 AC_SUBST(LIBXTR6)
2192
2193 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2194 dnl Why not just test for libxmu in the normal way?
2195 LIBXMU=-lXmu
2196 case $opsys in
2197   ## These systems don't supply Xmu.
2198   hpux* | aix4-2 )
2199     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2200     ;;
2201 esac
2202 AC_SUBST(LIBXMU)
2203
2204 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2205 if test "${HAVE_X11}" = "yes"; then
2206   if test "${USE_X_TOOLKIT}" != "none"; then
2207     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2208   fi
2209 fi
2210
2211 LIBXP=
2212 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2213   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2214   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2215     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2216 int x = 5;
2217 #else
2218 Motif version prior to 2.1.
2219 #endif]])],
2220     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2221   if test $emacs_cv_motif_version_2_1 = yes; then
2222     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2223   else
2224     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2225     # We put this in CFLAGS temporarily to precede other -I options
2226     # that might be in CFLAGS temporarily.
2227     # We put this in CPPFLAGS where it precedes the other -I options.
2228     OLD_CPPFLAGS=$CPPFLAGS
2229     OLD_CFLAGS=$CFLAGS
2230     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2231     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2232     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2233       [[int x = 5;]])],
2234       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2235     if test $emacs_cv_lesstif = yes; then
2236       # Make sure this -I option remains in CPPFLAGS after it is set
2237       # back to REAL_CPPFLAGS.
2238       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2239       # have those other -I options anyway.  Ultimately, having this
2240       # directory ultimately in CPPFLAGS will be enough.
2241       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2242       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2243     else
2244       CFLAGS=$OLD_CFLAGS
2245       CPPFLAGS=$OLD_CPPFLAGS
2246     fi
2247   fi
2248 fi
2249
2250 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2251 dnl using Motif or Xaw3d is available, and unless
2252 dnl --with-toolkit-scroll-bars=no was specified.
2253
2254 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2255             [Define to 1 if we should use toolkit scroll bars.])dnl
2256 USE_TOOLKIT_SCROLL_BARS=no
2257 if test "${with_toolkit_scroll_bars}" != "no"; then
2258   if test "${USE_X_TOOLKIT}" != "none"; then
2259     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2260       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2261       HAVE_XAW3D=no
2262       USE_TOOLKIT_SCROLL_BARS=yes
2263     elif test "${HAVE_XAW3D}" = "yes"; then
2264       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2265       USE_TOOLKIT_SCROLL_BARS=yes
2266     fi
2267   elif test "${HAVE_GTK}" = "yes"; then
2268     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2269     USE_TOOLKIT_SCROLL_BARS=yes
2270   elif test "${HAVE_NS}" = "yes"; then
2271     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2272     USE_TOOLKIT_SCROLL_BARS=yes
2273   fi
2274 fi
2275
2276 dnl See if XIM is available.
2277 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2278           #include <X11/Xlib.h>
2279           #include <X11/Xresource.h>]],
2280          [[XIMProc  callback;]])],
2281          [HAVE_XIM=yes
2282          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2283          HAVE_XIM=no)
2284
2285 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2286
2287 if test "${with_xim}" != "no"; then
2288   AC_DEFINE(USE_XIM, 1,
2289             [Define to 1 if we should use XIM, if it is available.])
2290 fi
2291
2292
2293 if test "${HAVE_XIM}" != "no"; then
2294   late_CFLAGS=$CFLAGS
2295   if test "$GCC" = yes; then
2296     CFLAGS="$CFLAGS --pedantic-errors"
2297   fi
2298   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2299 #include <X11/Xlib.h>
2300 #include <X11/Xresource.h>]],
2301 [[Display *display;
2302 XrmDatabase db;
2303 char *res_name;
2304 char *res_class;
2305 XIMProc  callback;
2306 XPointer *client_data;
2307 #ifndef __GNUC__
2308 /* If we're not using GCC, it's probably not XFree86, and this is
2309    probably right, but we can't use something like --pedantic-errors.  */
2310 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2311                                            char*, XIMProc, XPointer*);
2312 #endif
2313 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2314    client_data);]])],
2315     [emacs_cv_arg6_star=yes])
2316   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2317          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2318 either XPointer or XPointer*.])dnl
2319   if test "$emacs_cv_arg6_star" = yes; then
2320     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2321   else
2322     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2323   fi
2324   CFLAGS=$late_CFLAGS
2325 fi
2326
2327 ### Start of font-backend (under any platform) section.
2328 # (nothing here yet -- this is a placeholder)
2329 ### End of font-backend (under any platform) section.
2330
2331 ### Start of font-backend (under X11) section.
2332 if test "${HAVE_X11}" = "yes"; then
2333    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2334
2335    ## Use -lXft if available, unless `--with-xft=no'.
2336    HAVE_XFT=maybe
2337     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2338       with_xft="no";
2339     fi
2340     if test "x${with_xft}" != "xno"; then
2341
2342       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2343       ## Because xftfont.c uses XRenderQueryExtension, we also
2344       ## need to link to -lXrender.
2345       HAVE_XRENDER=no
2346       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2347       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2348         OLD_CPPFLAGS="$CPPFLAGS"
2349         OLD_CFLAGS="$CFLAGS"
2350         OLD_LIBS="$LIBS"
2351         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2352         CFLAGS="$CFLAGS $XFT_CFLAGS"
2353         XFT_LIBS="-lXrender $XFT_LIBS"
2354         LIBS="$XFT_LIBS $LIBS"
2355         AC_CHECK_HEADER(X11/Xft/Xft.h,
2356           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2357
2358         if test "${HAVE_XFT}" = "yes"; then
2359           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2360             AC_SUBST(XFT_LIBS)
2361           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2362         else
2363           CPPFLAGS="$OLD_CPPFLAGS"
2364           CFLAGS="$OLD_CFLAGS"
2365           LIBS="$OLD_LIBS"
2366         fi                        # "${HAVE_XFT}" = "yes"
2367       fi                          # "$HAVE_XFT" != no
2368     fi                            # "x${with_xft}" != "xno"
2369
2370     ## We used to allow building with FreeType and without Xft.
2371     ## However, the ftx font backend driver is not in good shape.
2372     if test "$HAVE_XFT" != "yes"; then
2373        dnl For the "Does Emacs use" message at the end.
2374        HAVE_XFT=no
2375        HAVE_FREETYPE=no
2376     else
2377        dnl Strict linkers fail with
2378        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2379        dnl if -lfreetype is not specified.
2380        dnl The following is needed to set FREETYPE_LIBS.
2381        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2382                          HAVE_FREETYPE=no)
2383
2384        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2385     fi
2386
2387     HAVE_LIBOTF=no
2388     if test "${HAVE_FREETYPE}" = "yes"; then
2389       AC_DEFINE(HAVE_FREETYPE, 1,
2390                 [Define to 1 if using the freetype and fontconfig libraries.])
2391       if test "${with_libotf}" != "no"; then
2392         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2393                           HAVE_LIBOTF=no)
2394         if test "$HAVE_LIBOTF" = "yes"; then
2395           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2396           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2397                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2398                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2399           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2400             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2401                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2402           fi
2403         fi
2404       fi
2405     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2406     dnl Does the new font backend require it, or can it work without it?
2407     fi
2408
2409     HAVE_M17N_FLT=no
2410     if test "${HAVE_LIBOTF}" = yes; then
2411       if test "${with_m17n_flt}" != "no"; then
2412         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2413         if test "$HAVE_M17N_FLT" = "yes"; then
2414           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2415         fi
2416       fi
2417     fi
2418 else
2419     HAVE_XFT=no
2420     HAVE_FREETYPE=no
2421     HAVE_LIBOTF=no
2422     HAVE_M17N_FLT=no
2423 fi
2424
2425 ### End of font-backend (under X11) section.
2426
2427 AC_SUBST(FREETYPE_CFLAGS)
2428 AC_SUBST(FREETYPE_LIBS)
2429 AC_SUBST(FONTCONFIG_CFLAGS)
2430 AC_SUBST(FONTCONFIG_LIBS)
2431 AC_SUBST(LIBOTF_CFLAGS)
2432 AC_SUBST(LIBOTF_LIBS)
2433 AC_SUBST(M17N_FLT_CFLAGS)
2434 AC_SUBST(M17N_FLT_LIBS)
2435
2436 ### Use -lXpm if available, unless `--with-xpm=no'.
2437 HAVE_XPM=no
2438 LIBXPM=
2439 if test "${HAVE_X11}" = "yes"; then
2440   if test "${with_xpm}" != "no"; then
2441     AC_CHECK_HEADER(X11/xpm.h,
2442       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2443     if test "${HAVE_XPM}" = "yes"; then
2444       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2445       AC_EGREP_CPP(no_return_alloc_pixels,
2446       [#include "X11/xpm.h"
2447 #ifndef XpmReturnAllocPixels
2448 no_return_alloc_pixels
2449 #endif
2450       ], HAVE_XPM=no, HAVE_XPM=yes)
2451
2452       if test "${HAVE_XPM}" = "yes"; then
2453         AC_MSG_RESULT(yes)
2454       else
2455         AC_MSG_RESULT(no)
2456       fi
2457     fi
2458   fi
2459
2460   if test "${HAVE_XPM}" = "yes"; then
2461     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2462     LIBXPM=-lXpm
2463   fi
2464 fi
2465 AC_SUBST(LIBXPM)
2466
2467 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2468 HAVE_JPEG=no
2469 LIBJPEG=
2470 if test "${HAVE_X11}" = "yes"; then
2471   if test "${with_jpeg}" != "no"; then
2472     dnl Checking for jpeglib.h can lose because of a redefinition of
2473     dnl  HAVE_STDLIB_H.
2474     AC_CHECK_HEADER(jerror.h,
2475       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2476   fi
2477
2478   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2479   if test "${HAVE_JPEG}" = "yes"; then
2480     AC_DEFINE(HAVE_JPEG)
2481     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2482         [#include <jpeglib.h>
2483          version=JPEG_LIB_VERSION
2484 ],
2485         [AC_DEFINE(HAVE_JPEG)],
2486         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2487         HAVE_JPEG=no])
2488   fi
2489   if test "${HAVE_JPEG}" = "yes"; then
2490     LIBJPEG=-ljpeg
2491   fi
2492 fi
2493 AC_SUBST(LIBJPEG)
2494
2495 ### Use -lpng if available, unless `--with-png=no'.
2496 HAVE_PNG=no
2497 LIBPNG=
2498 if test "${HAVE_X11}" = "yes"; then
2499   if test "${with_png}" != "no"; then
2500     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2501     # in /usr/include/libpng.
2502     AC_CHECK_HEADERS(png.h libpng/png.h)
2503     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2504       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2505     fi
2506   fi
2507
2508   if test "${HAVE_PNG}" = "yes"; then
2509     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2510     LIBPNG="-lpng -lz -lm"
2511   fi
2512 fi
2513 AC_SUBST(LIBPNG)
2514
2515 ### Use -ltiff if available, unless `--with-tiff=no'.
2516 HAVE_TIFF=no
2517 LIBTIFF=
2518 if test "${HAVE_X11}" = "yes"; then
2519   if test "${with_tiff}" != "no"; then
2520     AC_CHECK_HEADER(tiffio.h,
2521       [tifflibs="-lz -lm"
2522       # At least one tiff package requires the jpeg library.
2523       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2524       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2525   fi
2526
2527   if test "${HAVE_TIFF}" = "yes"; then
2528     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2529     dnl FIXME -lz -lm, as per libpng?
2530     LIBTIFF=-ltiff
2531   fi
2532 fi
2533 AC_SUBST(LIBTIFF)
2534
2535 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2536 HAVE_GIF=no
2537 LIBGIF=
2538 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2539   AC_CHECK_HEADER(gif_lib.h,
2540 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2541 # Earlier versions can crash Emacs.
2542     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2543
2544   if test "$HAVE_GIF" = yes; then
2545     LIBGIF=-lgif
2546   elif test "$HAVE_GIF" = maybe; then
2547 # If gif_lib.h but no libgif, try libungif.
2548     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2549     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2550   fi
2551
2552   if test "${HAVE_GIF}" = "yes"; then
2553     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2554   fi
2555 fi
2556 AC_SUBST(LIBGIF)
2557
2558 dnl Check for required libraries.
2559 if test "${HAVE_X11}" = "yes"; then
2560   MISSING=""
2561   WITH_NO=""
2562   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2563     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2564   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2565     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2566   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2567     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2568   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2569     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2570   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2571     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2572
2573   if test "X${MISSING}" != X; then
2574     AC_MSG_ERROR([The following required libraries were not found:
2575     $MISSING
2576 Maybe some development libraries/packages are missing?
2577 If you don't want to link with them give
2578     $WITH_NO
2579 as options to configure])
2580   fi
2581 fi
2582
2583 ### Use -lgpm if available, unless `--with-gpm=no'.
2584 HAVE_GPM=no
2585 LIBGPM=
2586 if test "${with_gpm}" != "no"; then
2587   AC_CHECK_HEADER(gpm.h,
2588     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2589
2590   if test "${HAVE_GPM}" = "yes"; then
2591     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2592     LIBGPM=-lgpm
2593   fi
2594 fi
2595 AC_SUBST(LIBGPM)
2596
2597 dnl Check for malloc/malloc.h on darwin
2598 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2599
2600 C_SWITCH_X_SYSTEM=
2601 ### Use NeXTstep API to implement GUI.
2602 if test "${HAVE_NS}" = "yes"; then
2603   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2604   if test "${NS_IMPL_COCOA}" = "yes"; then
2605     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2606     GNU_OBJC_CFLAGS=
2607   fi
2608   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2609     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2610     # See also .m.o rule in Makefile.in */
2611     # FIXME: are all these flags really needed?  Document here why.  */
2612     C_SWITCH_X_SYSTEM="-D_REENTRANT -fPIC -fno-strict-aliasing"
2613     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2614   fi
2615   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2616     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2617   fi
2618   # We also have mouse menus.
2619   HAVE_MENUS=yes
2620   OTHER_FILES=ns-app
2621 fi
2622
2623
2624 ### Use session management (-lSM -lICE) if available
2625 HAVE_X_SM=no
2626 LIBXSM=
2627 if test "${HAVE_X11}" = "yes"; then
2628   AC_CHECK_HEADER(X11/SM/SMlib.h,
2629     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2630
2631   if test "${HAVE_X_SM}" = "yes"; then
2632     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2633     LIBXSM="-lSM -lICE"
2634     case "$LIBS" in
2635       *-lSM*) ;;
2636       *)      LIBS="$LIBXSM $LIBS" ;;
2637     esac
2638   fi
2639 fi
2640 AC_SUBST(LIBXSM)
2641
2642 ### Use libxml (-lxml2) if available
2643 if test "${with_xml2}" != "no"; then
2644   ### I'm not sure what the version number should be, so I just guessed.
2645   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2646   if test "${HAVE_LIBXML2}" = "yes"; then
2647     LIBS="$LIBXML2_LIBS $LIBS"
2648     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2649     if test "${HAVE_LIBXML2}" = "yes"; then
2650       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2651     else
2652       LIBXML2_LIBS=""
2653       LIBXML2_CFLAGS=""
2654     fi
2655   fi
2656 fi
2657 AC_SUBST(LIBXML2_LIBS)
2658 AC_SUBST(LIBXML2_CFLAGS)
2659
2660 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2661 AC_CACHE_CHECK(whether netdb declares h_errno,
2662                emacs_cv_netdb_declares_h_errno,
2663 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
2664   [[return h_errno;]])],
2665   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2666 if test $emacs_cv_netdb_declares_h_errno = yes; then
2667   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2668 fi
2669
2670 # fmod, logb, and frexp are found in -lm on most systems.
2671 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2672 AC_CHECK_LIB(m, sqrt)
2673
2674 # Check for mail-locking functions in a "mail" library.  Probably this should
2675 # have the same check as for liblockfile below.
2676 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2677 if test $have_mail = yes; then
2678   LIBS_MAIL=-lmail
2679   LIBS="$LIBS_MAIL $LIBS"
2680   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2681 else
2682   LIBS_MAIL=
2683 fi
2684 dnl Debian, at least:
2685 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2686 if test $have_lockfile = yes; then
2687    LIBS_MAIL=-llockfile
2688    LIBS="$LIBS_MAIL $LIBS"
2689    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2690 else
2691 # If we have the shared liblockfile, assume we must use it for mail
2692 # locking (e.g. Debian).  If we couldn't link against liblockfile
2693 # (no liblockfile.a installed), ensure that we don't need to.
2694   dnl This works for files generally, not just executables.
2695   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2696   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2697                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2698   if test $ac_cv_prog_liblockfile = yes; then
2699     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2700 This probably means that movemail could lose mail.
2701 There may be a `development' package to install containing liblockfile.])
2702   fi
2703 fi
2704 AC_CHECK_FUNCS(touchlock)
2705 AC_CHECK_HEADERS(maillock.h)
2706 AC_SUBST(LIBS_MAIL)
2707
2708 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2709 ## interlock access to the mail spool.  The alternative is a lock file named
2710 ## /usr/spool/mail/$USER.lock.
2711 mail_lock=no
2712 case "$opsys" in
2713   aix4-2) mail_lock="lockf" ;;
2714
2715   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2716
2717   ## On GNU/Linux systems, both methods are used by various mail programs.
2718   ## I assume most people are using newer mailers that have heard of flock.
2719   ## Change this if you need to.
2720   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2721   ## configure gets the right answers, and that means *NOT* using flock.
2722   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2723   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2724   ## Debian maintainer hasn't provided a clean fix for Emacs.
2725   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2726   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2727   ## correct logic.  -- fx
2728   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2729   ## liblockfile is a Free Software replacement for libmail, used on
2730   ## Debian systems and elsewhere. -rfr.
2731   gnu-*)
2732     mail_lock="flock"
2733     if test $have_mail = yes || test $have_lockfile = yes; then
2734       test $ac_cv_header_maillock_h = yes && mail_lock=no
2735     fi
2736     ;;
2737 esac
2738
2739 BLESSMAIL_TARGET=
2740 case "$mail_lock" in
2741   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2742
2743   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2744
2745   *) BLESSMAIL_TARGET="need-blessmail" ;;
2746 esac
2747 AC_SUBST(BLESSMAIL_TARGET)
2748
2749
2750 AC_CHECK_FUNCS(gethostname getdomainname \
2751 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2752 random lrand48 logb frexp fmod rint cbrt ftime setsid \
2753 strerror fpathconf select euidaccess getpagesize tzset setlocale \
2754 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2755 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm strchr strrchr \
2756 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2757 gai_strerror mkstemp getline getdelim mremap memmove fsync sync \
2758 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2759 cfmakeraw cfsetspeed isnan copysign __executable_start)
2760
2761 dnl Cannot use AC_CHECK_FUNCS
2762 AC_CACHE_CHECK([for __builtin_unwind_init],
2763                emacs_cv_func___builtin_unwind_init,
2764 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2765                 emacs_cv_func___builtin_unwind_init=yes,
2766                 emacs_cv_func___builtin_unwind_init=no)])
2767 if test $emacs_cv_func___builtin_unwind_init = yes; then
2768   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2769             [Define to 1 if you have the `__builtin_unwind_init' function.])
2770 fi
2771
2772 AC_CHECK_HEADERS(sys/un.h)
2773
2774 AC_FUNC_FSEEKO
2775
2776 AC_FUNC_GETPGRP
2777
2778 # UNIX98 PTYs.
2779 AC_CHECK_FUNCS(grantpt)
2780
2781 # PTY-related GNU extensions.
2782 AC_CHECK_FUNCS(getpt)
2783
2784 # Check this now, so that we will NOT find the above functions in ncurses.
2785 # That is because we have not set up to link ncurses in lib-src.
2786 # It's better to believe a function is not available
2787 # than to expect to find it in ncurses.
2788 # Also we need tputs and friends to be able to build at all.
2789 have_tputs_et_al=true
2790 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2791 if test "$have_tputs_et_al" != true; then
2792   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2793 Maybe some development libraries/packages are missing?  Try installing
2794 libncurses-dev(el), libterminfo-dev(el) or similar.])
2795 fi
2796 # Must define this when any termcap library is found.
2797 AC_DEFINE(HAVE_LIBNCURSES, 1,
2798           [Define to 1 if you have the `ncurses' library (-lncurses).])
2799 ## FIXME This was the cpp logic, but I am not sure it is right.
2800 ## The above test has not necessarily found libncurses.
2801 HAVE_LIBNCURSES=yes
2802
2803 ## Use terminfo instead of termcap?
2804 ## Note only system files NOT using terminfo are:
2805 ## freebsd < 40000, ms-w32, msdos, netbsd < 599002500, and
2806 ## darwin|gnu without ncurses.
2807 TERMINFO=no
2808 LIBS_TERMCAP=
2809 case "$opsys" in
2810   ## cygwin: Fewer environment variables to go wrong, more terminal types.
2811   ## hpux10-20: Use the system provided termcap(3) library.
2812   ## openbsd: David Mazieres <dm@reeducation-labor.lcs.mit.edu> says this
2813   ##  is necessary.  Otherwise Emacs dumps core when run -nw.
2814   aix4-2|cygwin|hpux*|irix6-5|openbsd|sol2*|unixware) TERMINFO=yes ;;
2815
2816   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2817   ##  The ncurses library has been moved out of the System framework in
2818   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2819   ##  option to use it.
2820   darwin|gnu*)
2821     ## (HAVE_LIBNCURSES was not always true, but is since 2010-03-18.)
2822     if test "x$HAVE_LIBNCURSES" = "xyes"; then
2823       TERMINFO=yes
2824       LIBS_TERMCAP="-lncurses"
2825     fi
2826     ;;
2827
2828   freebsd)
2829     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2830     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2831     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
2832 [[#if __FreeBSD_version < 400000
2833 fail;
2834 #endif
2835 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2836
2837     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2838
2839     if test $emacs_cv_freebsd_terminfo = yes; then
2840       TERMINFO=yes
2841       LIBS_TERMCAP="-lncurses"
2842     else
2843       LIBS_TERMCAP="-ltermcap"
2844     fi
2845     ;;
2846
2847   netbsd)
2848     if test $ac_cv_search_tputs = -lterminfo; then
2849       TERMINFO=yes
2850       LIBS_TERMCAP="-lterminfo"
2851     else
2852       LIBS_TERMCAP="-ltermcap"
2853     fi
2854     ;;
2855
2856 esac
2857
2858 case "$opsys" in
2859   ## hpux: Make sure we get select from libc rather than from libcurses
2860   ##  because libcurses on HPUX 10.10 has a broken version of select.
2861   ##  We used to use -lc -lcurses, but this may be cleaner.
2862   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2863
2864   openbsd) LIBS_TERMCAP="-lncurses" ;;
2865
2866   ## Must use system termcap, if we use any termcap.  It does special things.
2867   sol2*) test "$TERMINFO" != yes && LIBS_TERMCAP="-ltermcap" ;;
2868 esac
2869
2870 TERMCAP_OBJ=tparam.o
2871 if test $TERMINFO = yes; then
2872   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2873
2874   ## Default used to be -ltermcap.  Add a case above if need something else.
2875   test "x$LIBS_TERMCAP" = "x" && LIBS_TERMCAP="-lcurses"
2876
2877   TERMCAP_OBJ=terminfo.o
2878 fi
2879 AC_SUBST(LIBS_TERMCAP)
2880 AC_SUBST(TERMCAP_OBJ)
2881
2882
2883 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2884 resolv=no
2885 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2886 #include <arpa/nameser.h>
2887 #include <resolv.h>]],
2888     [[return res_init();]])],
2889     have_res_init=yes, have_res_init=no)
2890 if test "$have_res_init" = no; then
2891   OLIBS="$LIBS"
2892   LIBS="$LIBS -lresolv"
2893   AC_MSG_CHECKING(for res_init with -lresolv)
2894   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2895 #include <arpa/nameser.h>
2896 #include <resolv.h>]],
2897     [[return res_init();]])],
2898     have_res_init=yes, have_res_init=no)
2899   AC_MSG_RESULT($have_res_init)
2900   if test "$have_res_init" = yes ; then
2901     resolv=yes
2902   fi
2903   LIBS="$OLIBS"
2904 fi
2905
2906 if test "$have_res_init" = yes; then
2907   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2908 fi
2909
2910 # Do we need the Hesiod library to provide the support routines?
2911 LIBHESIOD=
2912 if test "$with_hesiod" != no ; then
2913   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2914   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2915      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2916                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2917   if test "$resolv" = yes ; then
2918     RESOLVLIB=-lresolv
2919   else
2920     RESOLVLIB=
2921   fi
2922   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2923         hesiod=yes, :, $RESOLVLIB)])
2924
2925   if test x"$hesiod" = xyes; then
2926     AC_DEFINE(HAVE_LIBHESIOD, 1,
2927               [Define to 1 if you have the hesiod library (-lhesiod).])
2928     LIBHESIOD=-lhesiod
2929   fi
2930 fi
2931 AC_SUBST(LIBHESIOD)
2932
2933 # Do we need libresolv (due to res_init or Hesiod)?
2934 if test "$resolv" = yes ; then
2935   AC_DEFINE(HAVE_LIBRESOLV, 1,
2936             [Define to 1 if you have the resolv library (-lresolv).])
2937   LIBRESOLV=-lresolv
2938 else
2939   LIBRESOLV=
2940 fi
2941 AC_SUBST(LIBRESOLV)
2942
2943 # These tell us which Kerberos-related libraries to use.
2944 COM_ERRLIB=
2945 CRYPTOLIB=
2946 KRB5LIB=
2947 DESLIB=
2948 KRB4LIB=
2949
2950 if test "${with_kerberos}" != no; then
2951   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2952   if test $have_com_err = yes; then
2953     COM_ERRLIB=-lcom_err
2954     LIBS="$COM_ERRLIB $LIBS"
2955     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2956   fi
2957   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2958   if test $have_crypto = yes; then
2959     CRYPTOLIB=-lcrypto
2960     LIBS="$CRYPTOLIB $LIBS"
2961     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2962   fi
2963   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2964   if test $have_k5crypto = yes; then
2965     CRYPTOLIB=-lk5crypto
2966     LIBS="$CRYPTOLIB $LIBS"
2967     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2968   fi
2969   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2970   if test $have_krb5=yes; then
2971     KRB5LIB=-lkrb5
2972     LIBS="$KRB5LIB $LIBS"
2973     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2974   fi
2975   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2976   if test "${with_kerberos5}" = no; then
2977     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2978     if test $have_des425 = yes; then
2979       DESLIB=-ldes425
2980       LIBS="$DESLIB $LIBS"
2981       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2982     else
2983       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2984       if test $have_des = yes; then
2985         DESLIB=-ldes
2986         LIBS="$DESLIB $LIBS"
2987         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2988       fi
2989     fi
2990     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2991     if test $have_krb4 = yes; then
2992       KRB4LIB=-lkrb4
2993       LIBS="$KRB4LIB $LIBS"
2994       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2995     else
2996       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2997       if test $have_krb = yes; then
2998         KRB4LIB=-lkrb
2999         LIBS="$KRB4LIB $LIBS"
3000         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
3001       fi
3002     fi
3003   fi
3004
3005   if test "${with_kerberos5}" != no; then
3006     AC_CHECK_HEADERS(krb5.h,
3007       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
3008                         [#include <krb5.h>])])
3009   else
3010     AC_CHECK_HEADERS(des.h,,
3011                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
3012                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
3013     AC_CHECK_HEADERS(krb.h,,
3014                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
3015                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
3016   fi
3017   AC_CHECK_HEADERS(com_err.h)
3018 fi
3019
3020 AC_SUBST(COM_ERRLIB)
3021 AC_SUBST(CRYPTOLIB)
3022 AC_SUBST(KRB5LIB)
3023 AC_SUBST(DESLIB)
3024 AC_SUBST(KRB4LIB)
3025
3026 # Solaris requires -lintl if you want strerror (which calls dgettext)
3027 # to return localized messages.
3028 AC_CHECK_LIB(intl, dgettext)
3029
3030 AC_MSG_CHECKING(whether localtime caches TZ)
3031 AC_CACHE_VAL(emacs_cv_localtime_cache,
3032 [if test x$ac_cv_func_tzset = xyes; then
3033 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
3034 char TZ_GMT0[] = "TZ=GMT0";
3035 char TZ_PST8[] = "TZ=PST8";
3036 main()
3037 {
3038   time_t now = time ((time_t *) 0);
3039   int hour_GMT0, hour_unset;
3040   if (putenv (TZ_GMT0) != 0)
3041     exit (1);
3042   hour_GMT0 = localtime (&now)->tm_hour;
3043   unsetenv("TZ");
3044   hour_unset = localtime (&now)->tm_hour;
3045   if (putenv (TZ_PST8) != 0)
3046     exit (1);
3047   if (localtime (&now)->tm_hour == hour_GMT0)
3048     exit (1);
3049   unsetenv("TZ");
3050   if (localtime (&now)->tm_hour != hour_unset)
3051     exit (1);
3052   exit (0);
3053 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3054 [# If we have tzset, assume the worst when cross-compiling.
3055 emacs_cv_localtime_cache=yes])
3056 else
3057         # If we lack tzset, report that localtime does not cache TZ,
3058         # since we can't invalidate the cache if we don't have tzset.
3059         emacs_cv_localtime_cache=no
3060 fi])dnl
3061 AC_MSG_RESULT($emacs_cv_localtime_cache)
3062 if test $emacs_cv_localtime_cache = yes; then
3063   AC_DEFINE(LOCALTIME_CACHE, 1,
3064             [Define to 1 if localtime caches TZ.])
3065 fi
3066
3067 if test "x$HAVE_TIMEVAL" = xyes; then
3068   AC_CHECK_FUNCS(gettimeofday)
3069   if test $ac_cv_func_gettimeofday = yes; then
3070     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
3071                    emacs_cv_gettimeofday_two_arguments,
3072     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3073 #ifdef TIME_WITH_SYS_TIME
3074 #include <sys/time.h>
3075 #include <time.h>
3076 #else
3077 #ifdef HAVE_SYS_TIME_H
3078 #include <sys/time.h>
3079 #else
3080 #include <time.h>
3081 #endif
3082 #endif]],
3083       [[struct timeval time;
3084        gettimeofday (&time, 0);]])],
3085       emacs_cv_gettimeofday_two_arguments=yes,
3086       emacs_cv_gettimeofday_two_arguments=no)])
3087     if test $emacs_cv_gettimeofday_two_arguments = no; then
3088       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
3089                 [Define to 1 if gettimeofday accepts only one argument.])
3090     fi
3091   fi
3092 fi
3093
3094 ok_so_far=yes
3095 AC_CHECK_FUNC(socket, , ok_so_far=no)
3096 if test $ok_so_far = yes; then
3097   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3098 fi
3099 if test $ok_so_far = yes; then
3100   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3101 fi
3102 if test $ok_so_far = yes; then
3103 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3104   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3105             [Define to 1 if you have inet sockets.])
3106 fi
3107
3108 if test -f /usr/lpp/X11/bin/smt.exp; then
3109   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3110             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3111 fi
3112
3113 AC_MSG_CHECKING(whether system supports dynamic ptys)
3114 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3115   AC_MSG_RESULT(yes)
3116   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3117 else
3118   AC_MSG_RESULT(no)
3119 fi
3120
3121 AC_FUNC_FORK
3122
3123 dnl Adapted from Haible's version.
3124 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3125   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3126     [[char* cs = nl_langinfo(CODESET);]])],
3127     emacs_cv_langinfo_codeset=yes,
3128     emacs_cv_langinfo_codeset=no)
3129   ])
3130 if test $emacs_cv_langinfo_codeset = yes; then
3131   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3132     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3133 fi
3134
3135 AC_TYPE_MBSTATE_T
3136
3137 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3138   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3139                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3140 if test "$emacs_cv_c_restrict_arr" = yes; then
3141   AC_DEFINE(__restrict_arr, __restrict,
3142     [Define to compiler's equivalent of C99 restrict keyword in array
3143      declarations.  Define as empty for no equivalent.])
3144 fi
3145
3146 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3147 dnl how the tty code is related to POSIX and/or other versions of termios.
3148 dnl The following looks like a useful start.
3149 dnl
3150 dnl AC_SYS_POSIX_TERMIOS
3151 dnl if test $ac_cv_sys_posix_termios = yes; then
3152 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3153 dnl                                and macros for terminal control.])
3154 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3155 dnl fi
3156
3157 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
3158
3159 # Set up the CFLAGS for real compilation, so we can substitute it.
3160 CFLAGS="$REAL_CFLAGS"
3161 CPPFLAGS="$REAL_CPPFLAGS"
3162
3163 ## Hack to detect a buggy GCC version.
3164 if test "x$GCC" = xyes \
3165    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3166    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3167    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3168    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3169 fi
3170
3171 version=$PACKAGE_VERSION
3172
3173 ### Specify what sort of things we'll be editing into Makefile and config.h.
3174 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3175 AC_SUBST(version)
3176 AC_SUBST(configuration)
3177 ## Unused?
3178 AC_SUBST(canonical)
3179 AC_SUBST(srcdir)
3180 AC_SUBST(prefix)
3181 AC_SUBST(exec_prefix)
3182 AC_SUBST(bindir)
3183 AC_SUBST(datadir)
3184 AC_SUBST(sharedstatedir)
3185 AC_SUBST(libexecdir)
3186 AC_SUBST(mandir)
3187 AC_SUBST(infodir)
3188 AC_SUBST(lispdir)
3189 AC_SUBST(locallisppath)
3190 AC_SUBST(lisppath)
3191 AC_SUBST(x_default_search_path)
3192 AC_SUBST(etcdir)
3193 AC_SUBST(archlibdir)
3194 AC_SUBST(docdir)
3195 AC_SUBST(bitmapdir)
3196 AC_SUBST(gamedir)
3197 AC_SUBST(gameuser)
3198 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3199 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3200 ## end of LIBX_BASE, but nothing ever set it.
3201 AC_SUBST(LD_SWITCH_X_SITE)
3202 AC_SUBST(C_SWITCH_X_SITE)
3203 AC_SUBST(C_SWITCH_X_SYSTEM)
3204 AC_SUBST(CFLAGS)
3205 ## Used in lwlib/Makefile.in.
3206 AC_SUBST(X_TOOLKIT_TYPE)
3207 if test -n "${machfile}"; then
3208   M_FILE="\$(srcdir)/${machfile}"
3209 else
3210   M_FILE=
3211 fi
3212 S_FILE="\$(srcdir)/${opsysfile}"
3213 AC_SUBST(M_FILE)
3214 AC_SUBST(S_FILE)
3215 AC_SUBST(ns_appdir)
3216 AC_SUBST(ns_appbindir)
3217 AC_SUBST(ns_appresdir)
3218 AC_SUBST(ns_appsrc)
3219 AC_SUBST(GNU_OBJC_CFLAGS)
3220 AC_SUBST(OTHER_FILES)
3221
3222 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3223                    [Define to the canonical Emacs configuration name.])
3224 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3225                    [Define to the options passed to configure.])
3226 if test -n "$machfile"; then
3227   AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3228                      [Define to the used machine dependent file.])
3229 fi
3230 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3231                    [Define to the used os dependent file.])
3232
3233 XMENU_OBJ=
3234 XOBJ=
3235 FONT_OBJ=
3236 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3237   AC_DEFINE(HAVE_X_WINDOWS, 1,
3238             [Define to 1 if you want to use the X window system.])
3239   XMENU_OBJ=xmenu.o
3240   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3241   FONT_OBJ=xfont.o
3242   if test "$HAVE_XFT" = "yes"; then
3243     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3244   elif test "$HAVE_FREETYPE" = "yes"; then
3245     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3246   fi
3247   AC_SUBST(FONT_OBJ)
3248 fi
3249 AC_SUBST(XMENU_OBJ)
3250 AC_SUBST(XOBJ)
3251 AC_SUBST(FONT_OBJ)
3252
3253 WIDGET_OBJ=
3254 MOTIF_LIBW=
3255 if test "${USE_X_TOOLKIT}" != "none" ; then
3256   WIDGET_OBJ=widget.o
3257   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3258   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3259     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3260   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3261     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3262     MOTIF_LIBW=-lXm
3263     case "$opsys" in
3264       gnu-linux)
3265         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3266         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3267         ;;
3268
3269       unixware)
3270         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3271         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3272         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3273         ;;
3274
3275       aix4-2)
3276         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3277         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3278         ;;
3279     esac
3280     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3281   fi
3282 fi
3283 AC_SUBST(WIDGET_OBJ)
3284
3285 TOOLKIT_LIBW=
3286 case "$USE_X_TOOLKIT" in
3287   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3288   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3289   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS -lXcomposite" ;;
3290 esac
3291 AC_SUBST(TOOLKIT_LIBW)
3292
3293 if test "$USE_X_TOOLKIT" = "none"; then
3294   LIBXT_OTHER="\$(LIBXSM)"
3295   OLDXMENU_TARGET="really-oldXMenu"
3296 else
3297   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3298   OLDXMENU_TARGET="really-lwlib"
3299 fi
3300 AC_SUBST(LIBXT_OTHER)
3301
3302 ## The X Menu stuff is present in the X10 distribution, but missing
3303 ## from X11.  If we have X10, just use the installed library;
3304 ## otherwise, use our own copy.
3305 if test "${HAVE_X11}" = "yes" ; then
3306   AC_DEFINE(HAVE_X11, 1,
3307             [Define to 1 if you want to use version 11 of X windows.
3308              Otherwise, Emacs expects to use version 10.])
3309
3310   if test "$USE_X_TOOLKIT" = "none"; then
3311     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
3312   else
3313     OLDXMENU="\${lwlibdir}/liblw.a"
3314   fi
3315   LIBXMENU="\$(OLDXMENU)"
3316   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3317   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3318 else
3319   ## For a syntactically valid Makefile; not actually used for anything.
3320   ## See comments in src/Makefile.in.
3321   OLDXMENU=nothing
3322   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3323   if test "${HAVE_X_WINDOWS}" = "yes"; then
3324     LIBXMENU="-lXMenu"
3325   else
3326     LIBXMENU=
3327   fi
3328   LIBX_OTHER=
3329   OLDXMENU_DEPS=
3330 fi
3331
3332 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3333   OLDXMENU_TARGET=
3334   OLDXMENU=nothing
3335   LIBXMENU=
3336   OLDXMENU_DEPS=
3337 fi
3338
3339 AC_SUBST(OLDXMENU_TARGET)
3340 AC_SUBST(OLDXMENU)
3341 AC_SUBST(LIBXMENU)
3342 AC_SUBST(LIBX_OTHER)
3343 AC_SUBST(OLDXMENU_DEPS)
3344
3345 if test "${HAVE_MENUS}" = "yes" ; then
3346   AC_DEFINE(HAVE_MENUS, 1,
3347             [Define to 1 if you have mouse menus.
3348              (This is automatic if you use X, but the option to specify it remains.)
3349              It is also defined with other window systems that support xmenu.c.])
3350 fi
3351
3352 if test "${GNU_MALLOC}" = "yes" ; then
3353   AC_DEFINE(GNU_MALLOC, 1,
3354             [Define to 1 if you want to use the GNU memory allocator.])
3355 fi
3356
3357 RALLOC_OBJ=
3358 if test "${REL_ALLOC}" = "yes" ; then
3359   AC_DEFINE(REL_ALLOC, 1,
3360             [Define REL_ALLOC if you want to use the relocating allocator for
3361              buffer space.])
3362
3363   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3364 fi
3365 AC_SUBST(RALLOC_OBJ)
3366
3367 if test "$opsys" = "cygwin"; then
3368   CYGWIN_OBJ="sheap.o"
3369   ## Cygwin differs because of its unexec().
3370   PRE_ALLOC_OBJ=
3371   POST_ALLOC_OBJ=lastfile.o
3372 else
3373   CYGWIN_OBJ=
3374   PRE_ALLOC_OBJ=lastfile.o
3375   POST_ALLOC_OBJ=
3376 fi
3377 AC_SUBST(CYGWIN_OBJ)
3378 AC_SUBST(PRE_ALLOC_OBJ)
3379 AC_SUBST(POST_ALLOC_OBJ)
3380
3381 # Configure gnulib here, now that we know LIBS.
3382 gl_ASSERT_NO_GNULIB_POSIXCHECK
3383 gl_ASSERT_NO_GNULIB_TESTS
3384 gl_INIT
3385
3386 case "$opsys" in
3387   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3388
3389   darwin)
3390    ## The -headerpad option tells ld (see man page) to leave room at the
3391    ## end of the header for adding load commands.  Needed for dumping.
3392    ## 0x690 is the total size of 30 segment load commands (at 56
3393    ## each); under Cocoa 31 commands are required.
3394    if test "$HAVE_NS" = "yes"; then
3395      libs_nsgui="-framework AppKit"
3396      headerpad_extra=6C8
3397    else
3398      libs_nsgui=
3399      headerpad_extra=690
3400    fi
3401    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3402
3403    ## This is here because src/Makefile.in did some extra fiddling around
3404    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3405    ##   #ifndef LD_SWITCH_SYSTEM
3406    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3407    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3408    ## not using gcc, darwin system not on an alpha (ie darwin, since
3409    ## darwin + alpha does not occur).
3410    ## Because this was done in src/Makefile.in, the resulting part of
3411    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3412    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3413    ## rather than LD_SWITCH_SYSTEM.
3414    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3415      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3416    ;;
3417
3418   ## LD_SWITCH_X_SITE_AUX is a -R option saying where to find X at run-time.
3419   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at
3420   ## the point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_AUX
3421   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3422   ## had different values in configure (in ac_link) and src/Makefile.in.
3423   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3424   gnu-linux) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_AUX)" ;;
3425
3426   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3427 esac
3428
3429 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3430   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3431 fi
3432
3433 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3434
3435
3436 LD_FIRSTFLAG=
3437 ORDINARY_LINK=
3438 case "$opsys" in
3439   ## gnu: GNU needs its own crt0.
3440   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3441
3442   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3443   ## library search parth, i.e. it won't search /usr/lib for libc and
3444   ## friends.  Using -nostartfiles instead avoids this problem, and
3445   ## will also work on earlier NetBSD releases.
3446   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
3447
3448   ## macpcc: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3449   ##   MkLinux/LinuxPPC needs this.
3450   ## ibms390x only supports opsys = gnu-linux so it can be added here.
3451   gnu-*)
3452     case "$machine" in
3453       macppc|ibms390x) LD_FIRSTFLAG="-nostdlib" ;;
3454     esac
3455     ;;
3456 esac
3457
3458
3459 if test "x$ORDINARY_LINK" = "xyes"; then
3460
3461   LD_FIRSTFLAG=""
3462   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3463
3464 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
3465 ## freebsd, gnu-* not on macppc|ibms390x.
3466 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
3467
3468   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3469   ## places that are difficult to figure out at make time.  Fortunately,
3470   ## these same versions allow you to pass arbitrary flags on to the
3471   ## linker, so there is no reason not to use it as a linker.
3472   ##
3473   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3474   ## searching for libraries in its internal directories, so we have to
3475   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3476   LD_FIRSTFLAG="-nostdlib"
3477 fi
3478
3479 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3480 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
3481
3482 AC_SUBST(LD_FIRSTFLAG)
3483
3484
3485 ## FIXME? The logic here is not precisely the same as that above.
3486 ## There is no check here for a pre-defined LD_FIRSTFLAG.
3487 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3488 LIB_GCC=
3489 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3490
3491   case "$opsys" in
3492     freebsd|netbsd|openbsd) LIB_GCC= ;;
3493
3494     gnu-*)
3495       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3496       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3497       case $host_cpu in
3498       arm*)
3499         LIB_GCC="-lgcc_s"
3500         ;;
3501       *)
3502         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3503         ## immediately undefine it again and redefine it to empty.
3504         ## Was the C_SWITCH_X_SITE part really necessary?
3505 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3506         LIB_GCC=
3507         ;;
3508       esac
3509       ;;
3510
3511     ## Ask GCC where to find libgcc.a.
3512     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3513   esac
3514 fi                              dnl if $GCC
3515 AC_SUBST(LIB_GCC)
3516
3517
3518 ## If we're using X11/GNUstep, define some consequences.
3519 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3520   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3521   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3522 fi
3523
3524
3525 AH_TOP([/* GNU Emacs site configuration template file.
3526
3527 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2011
3528   Free Software Foundation, Inc.
3529
3530 This file is part of GNU Emacs.
3531
3532 GNU Emacs is free software: you can redistribute it and/or modify
3533 it under the terms of the GNU General Public License as published by
3534 the Free Software Foundation, either version 3 of the License, or
3535 (at your option) any later version.
3536
3537 GNU Emacs is distributed in the hope that it will be useful,
3538 but WITHOUT ANY WARRANTY; without even the implied warranty of
3539 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3540 GNU General Public License for more details.
3541
3542 You should have received a copy of the GNU General Public License
3543 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3544
3545
3546 /* No code in Emacs #includes config.h twice, but some bits of code
3547    intended to work with other packages as well (like gmalloc.c)
3548    think they can include it as many times as they like.  */
3549 #ifndef EMACS_CONFIG_H
3550 #define EMACS_CONFIG_H
3551 ])dnl
3552
3553 AH_BOTTOM([
3554 /* On AIX 3 this must be included before any other include file.  */
3555 #include <alloca.h>
3556 #if ! HAVE_ALLOCA
3557 # error "alloca not available on this machine"
3558 #endif
3559
3560 /* Define AMPERSAND_FULL_NAME if you use the convention
3561    that & in the full name stands for the login id.  */
3562 /* Turned on June 1996 supposing nobody will mind it.  */
3563 #define AMPERSAND_FULL_NAME
3564
3565 /* `subprocesses' should be defined if you want to
3566    have code for asynchronous subprocesses
3567    (as used in M-x compile and M-x shell).
3568    Only MSDOS does not support this (it overrides
3569    this in its config_opsysfile below).  */
3570
3571 #define subprocesses
3572
3573 /* Include the os and machine dependent files.  */
3574 #include config_opsysfile
3575 #ifdef config_machfile
3576 # include config_machfile
3577 #endif
3578
3579 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3580    SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.
3581   (There is probably a better place to do this, but right now the
3582    Cocoa side does this in s/darwin.h and we cannot parallel this
3583    exactly since GNUstep is multi-OS.  */
3584 #if defined HAVE_NS && defined NS_IMPL_GNUSTEP
3585 #  define SYSTEM_PURESIZE_EXTRA 30000
3586 #endif
3587
3588 #ifdef emacs /* Don't do this for lib-src.  */
3589 /* Tell regex.c to use a type compatible with Emacs.  */
3590 #define RE_TRANSLATE_TYPE Lisp_Object
3591 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3592 #ifdef make_number
3593 /* If make_number is a macro, use it.  */
3594 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3595 #else
3596 /* If make_number is a function, avoid it.  */
3597 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3598 #endif
3599 #endif
3600
3601 /* These default definitions are good for almost all machines.
3602    Any exceptions should override them in m/MACHINE.h.
3603    They must be usable in preprocessor conditionals.  */
3604
3605 #ifndef BITS_PER_CHAR
3606 #define BITS_PER_CHAR 8
3607 #endif
3608
3609 #ifndef BITS_PER_SHORT
3610 #define BITS_PER_SHORT 16
3611 #endif
3612
3613 #ifndef BITS_PER_INT
3614 #define BITS_PER_INT 32
3615 #endif
3616
3617 #ifndef BITS_PER_LONG
3618 #ifdef _LP64
3619 #define BITS_PER_LONG 64
3620 #else
3621 #define BITS_PER_LONG 32
3622 #endif
3623 #endif
3624
3625 #if !defined BITS_PER_LONG_LONG && HAVE_LONG_LONG_INT
3626 #define BITS_PER_LONG_LONG 64
3627 #endif
3628
3629 /* Define if the compiler supports function prototypes.  It may do so but
3630    not define __STDC__ (e.g. DEC C by default) or may define it as zero.  */
3631 #undef PROTOTYPES
3632
3633 #include <string.h>
3634 #include <stdlib.h>
3635
3636 #ifndef HAVE_STRCHR
3637 #define strchr(a, b) index (a, b)
3638 #endif
3639
3640 #ifndef HAVE_STRRCHR
3641 #define strrchr(a, b) rindex (a, b)
3642 #endif
3643
3644 #if defined __GNUC__ && (__GNUC__ > 2 \
3645                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3646 #define NO_RETURN       __attribute__ ((__noreturn__))
3647 #else
3648 #define NO_RETURN       /* nothing */
3649 #endif
3650
3651 #if __GNUC__ >= 3  /* On GCC 3.0 we might get a warning.  */
3652 #define NO_INLINE __attribute__((noinline))
3653 #else
3654 #define NO_INLINE
3655 #endif
3656
3657 #if (__GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 1))
3658 #define EXTERNALLY_VISIBLE __attribute__((externally_visible))
3659 #else
3660 #define EXTERNALLY_VISIBLE
3661 #endif
3662
3663 #if __GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 7)
3664 # define ATTRIBUTE_FORMAT(spec) __attribute__ ((__format__ spec))
3665 #else
3666 # define ATTRIBUTE_FORMAT(spec) /* empty */
3667 #endif
3668
3669 #if __GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 4)
3670 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3671    ATTRIBUTE_FORMAT ((__gnu_printf__, formatstring_parameter, first_argument))
3672 #else
3673 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3674    ATTRIBUTE_FORMAT ((__printf__, formatstring_parameter, first_argument))
3675 #endif
3676
3677 /* Some versions of GNU/Linux define noinline in their headers.  */
3678 #ifdef noinline
3679 #undef noinline
3680 #endif
3681
3682 /* These won't be used automatically yet.  We also need to know, at least,
3683    that the stack is continuous.  */
3684 #ifdef __GNUC__
3685 #  ifndef GC_SETJMP_WORKS
3686   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3687 #    define GC_SETJMP_WORKS 1
3688 #  endif
3689 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3690 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3691 #  endif
3692 #endif
3693
3694 #endif /* EMACS_CONFIG_H */
3695
3696 /*
3697 Local Variables:
3698 mode: c
3699 End:
3700 */
3701 ])dnl
3702
3703 #### Report on what we decided to do.
3704 #### Report GTK as a toolkit, even if it doesn't use Xt.
3705 #### It makes printing result more understandable as using GTK sets
3706 #### toolkit_scroll_bars to yes by default.
3707 if test "${HAVE_GTK}" = "yes"; then
3708   USE_X_TOOLKIT=GTK
3709 fi
3710
3711 and_machfile=
3712 if test -n "$machfile"; then
3713   and_machfile=" and \`${machfile}'"
3714 fi
3715
3716 echo "
3717 Configured for \`${canonical}'.
3718
3719   Where should the build process find the source code?    ${srcdir}
3720   What operating system and machine description files should Emacs use?
3721         \`${opsysfile}'${and_machfile}
3722   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3723   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3724   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3725   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3726   What window system should Emacs use?                    ${window_system}
3727   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3728
3729 if test -n "${x_includes}"; then
3730 echo "  Where do we find X Windows header files?                ${x_includes}"
3731 else
3732 echo "  Where do we find X Windows header files?                Standard dirs"
3733 fi
3734 if test -n "${x_libraries}"; then
3735 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3736 else
3737 echo "  Where do we find X Windows libraries?                   Standard dirs"
3738 fi
3739
3740 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3741 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3742 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3743 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3744 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3745 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3746 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3747 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
3748
3749 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3750 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3751 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3752 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
3753 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3754 echo "  Does Emacs use -lgnutls (2.6.x or higher)?              ${HAVE_GNUTLS}"
3755 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
3756
3757 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3758 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3759 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3760 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3761
3762 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3763
3764 echo "  Does Emacs support Xwidgets?                            ${HAVE_XWIDGETS}"
3765 echo "       Does xwidgets support webkit(requires gtk3)?       ${HAVE_WEBKIT}"
3766 echo "       Does xwidgets support clutter(demo code)?          ${HAVE_CLUTTER}"
3767 echo "       Does xwidgets support goocanvas(demo code)?        ${HAVE_GOOCANVAS}"
3768 echo
3769
3770 if test $USE_XASSERTS = yes; then
3771    echo "  Compiling with asserts turned on."
3772    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3773 fi
3774
3775 echo
3776
3777 if test "$HAVE_NS" = "yes"; then
3778    echo
3779    echo "You must run \"make install\" in order to test the built application.
3780 The installed application will go to nextstep/Emacs.app and can be
3781 run or moved from there."
3782    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3783       echo "The application will be fully self-contained."
3784     else
3785       echo "The lisp resources for the application will be installed under ${prefix}.
3786 You may need to run \"make install\" with sudo.  The application will fail
3787 to run if these resources are not installed."
3788    fi
3789    echo
3790 fi
3791
3792
3793 # Remove any trailing slashes in these variables.
3794 [test "${prefix}" != NONE &&
3795   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3796 test "${exec_prefix}" != NONE &&
3797   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3798
3799 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
3800 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
3801 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
3802 dnl (else you get "no `Makefile.am' found for any configure output").
3803 dnl This will work, but you get a config.status that is not quite right
3804 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
3805 dnl That doesn't have any obvious consequences for Emacs, but on the whole
3806 dnl it seems better to just live with the duplication.
3807 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile"
3808
3809 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
3810        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3811        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
3812        leim/Makefile])
3813
3814 dnl test/ is not present in release tarfiles.
3815 opt_makefile=test/automated/Makefile
3816
3817 if test -f $srcdir/${opt_makefile}.in; then
3818   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
3819   dnl Again, it's best not to use a variable.  Though you can add
3820   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
3821   AC_CONFIG_FILES([test/automated/Makefile])
3822 fi
3823
3824 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
3825
3826 AC_SUBST(SUBDIR_MAKEFILES_IN)
3827
3828 dnl Make the necessary directories, if they don't exist.
3829 AC_CONFIG_COMMANDS([mkdirs], [
3830 for dir in etc lisp ; do
3831   test -d ${dir} || mkdir ${dir}
3832 done
3833 ])
3834
3835 dnl You might wonder (I did) why epaths.h is generated by running make,
3836 dnl rather than just letting configure generate it from epaths.in.
3837 dnl One reason is that the various paths are not fully expanded (see above);
3838 dnl eg gamedir=${prefix}/var/games/emacs.
3839 dnl Secondly, the GNU Coding standards require that one should be able
3840 dnl to run `make prefix=/some/where/else' and override the values set
3841 dnl by configure.  This also explains the `move-if-change' test and
3842 dnl the use of force in the `epaths-force' rule in Makefile.in.
3843 AC_CONFIG_COMMANDS([epaths], [
3844 echo creating src/epaths.h
3845 ${MAKE-make} epaths-force
3846 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPPFLAGS="$CPPFLAGS"])
3847
3848 AC_CONFIG_COMMANDS([gdbinit], [
3849 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3850   echo creating src/.gdbinit
3851   echo source $srcdir/src/.gdbinit > src/.gdbinit
3852 fi
3853 ])
3854
3855 AC_OUTPUT
3856
3857 dnl configure.in ends here