code.delx.au - gnu-emacs/blob - lisp/calendar/lunar.el

   1 ;;; lunar.el --- calendar functions for phases of the moon.
   2
   3 ;; Copyright (C) 1992 Free Software Foundation, Inc.
   4
   5 ;; Author: Edward M. Reingold <reingold@cs.uiuc.edu>
   6 ;; Keywords: calendar
   7 ;; Human-Keywords: moon, lunar phases, calendar, diary
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is distributed in the hope that it will be useful,
  12 ;; but WITHOUT ANY WARRANTY.  No author or distributor
  13 ;; accepts responsibility to anyone for the consequences of using it
  14 ;; or for whether it serves any particular purpose or works at all,
  15 ;; unless he says so in writing.  Refer to the GNU Emacs General Public
  16 ;; License for full details.
  17
  18 ;; Everyone is granted permission to copy, modify and redistribute
  19 ;; GNU Emacs, but only under the conditions described in the
  20 ;; GNU Emacs General Public License.   A copy of this license is
  21 ;; supposed to have been given to you along with GNU Emacs so you
  22 ;; can know your rights and responsibilities.  It should be in a
  23 ;; file named COPYING.  Among other things, the copyright notice
  24 ;; and this notice must be preserved on all copies.
  25
  26 ;;; Commentary:
  27
  28 ;; This collection of functions implements lunar phases for calendar.el and
  29 ;; diary.el.
  30
  31 ;; Based on ``Astronomical Formulae for Calculators,'' 3rd ed., by Jean Meeus,
  32 ;; Willmann-Bell, Inc., 1985.
  33 ;;
  34 ;; WARNING: The calculations will be accurate only to within a few minutes.
  35
  36 ;; The author would be delighted to have an astronomically more sophisticated
  37 ;; person rewrite the code for the lunar calculations in this file!
  38
  39 ;; Comments, corrections, and improvements should be sent to
  40 ;;  Edward M. Reingold               Department of Computer Science
  41 ;;  (217) 333-6733                   University of Illinois at Urbana-Champaign
  42 ;;  reingold@cs.uiuc.edu             1304 West Springfield Avenue
  43 ;;                                   Urbana, Illinois 61801
  44
  45 ;;; Code:
  46
  47 (if (fboundp 'atan)
  48     (require 'lisp-float-type)
  49   (error "Lunar calculations impossible since floating point is unavailable."))
  50
  51 (require 'solar)
  52
  53 (defun lunar-phase-list (month year)
  54   "List of lunar phases for three months starting with Gregorian MONTH, YEAR."
  55   (let ((end-month month)
  56         (end-year year)
  57         (start-month month)
  58         (start-year year))
  59     (increment-calendar-month end-month end-year 3)
  60     (increment-calendar-month start-month start-year -1)
  61     (let* ((end-date (list (list end-month 1 end-year)))
  62            (start-date (list (list start-month
  63                                    (calendar-last-day-of-month
  64                                     start-month start-year)
  65                                    start-year)))
  66            (index (* 4
  67                      (truncate
  68                       (* 12.3685
  69                          (+ year
  70                             ( / (calendar-day-number (list month 1 year))
  71                                 366.0)
  72                             -1900)))))
  73            (new-moon (lunar-phase index))
  74            (list))
  75       (while (calendar-date-compare new-moon end-date)
  76         (if (calendar-date-compare start-date new-moon)
  77             (setq list (append list (list new-moon))))
  78         (setq index (1+ index))
  79         (setq new-moon (lunar-phase index)))
  80       list)))
  81
  82 (defun lunar-phase (index)
  83   "Local date and time of lunar phase INDEX.
  84 Integer below INDEX/4 gives the lunation number, counting from Jan 1, 1900;
  85 remainder mod 4 gives the phase: 0 new moon, 1 first quarter, 2 full moon,
  86 3 last quarter."
  87   (let* ((phase (% index 4))
  88          (index (/ index 4.0))
  89          (time (/ index 1236.85))
  90          (date (+ (calendar-absolute-from-gregorian '(1 0.5 1900))
  91                   0.75933
  92                   (* 29.53058868 index)
  93                   (* 0.0001178 time time)
  94                   (* -0.000000155 time time time)
  95                   (* 0.00033
  96                      (solar-sin-degrees (+ 166.56
  97                                            (* 132.87 time)
  98                                            (* -0.009173 time time))))))
  99          (sun-anomaly (solar-mod
 100                        (+ 359.2242
 101                           (* 29.105356 index)
 102                           (* -0.0000333 time time)
 103                           (* -0.00000347 time time time))
 104                        360.0))
 105          (moon-anomaly (solar-mod
 106                         (+ 306.0253
 107                            (* 385.81691806 index)
 108                            (* 0.0107306 time time)
 109                            (* 0.00001236 time time time))
 110                         360.0))
 111          (moon-lat (solar-mod
 112                     (+ 21.2964
 113                        (* 390.67050646 index)
 114                        (* -0.0016528 time time)
 115                        (* -0.00000239 time time time))
 116                     360.0))
 117          (adjustment
 118           (if (memq phase '(0 2))
 119               (+ (* (- 0.1734 (* 0.000393 time))
 120                     (solar-sin-degrees sun-anomaly))
 121                  (* 0.0021 (solar-sin-degrees (* 2 sun-anomaly)))
 122                  (* -0.4068 (solar-sin-degrees moon-anomaly))
 123                  (* 0.0161 (solar-sin-degrees (* 2 moon-anomaly)))
 124                  (* -0.0004 (solar-sin-degrees (* 3 moon-anomaly)))
 125                  (* 0.0104 (solar-sin-degrees (* 2 moon-lat)))
 126                  (* -0.0051 (solar-sin-degrees (+ sun-anomaly moon-anomaly)))
 127                  (* -0.0074 (solar-sin-degrees (- sun-anomaly moon-anomaly)))
 128                  (* 0.0004 (solar-sin-degrees (+ (* 2 moon-lat) sun-anomaly)))
 129                  (* -0.0004 (solar-sin-degrees (- (* 2 moon-lat) sun-anomaly)))
 130                  (* -0.0006 (solar-sin-degrees
 131                              (+ (* 2 moon-lat) moon-anomaly)))
 132                  (* 0.0010 (solar-sin-degrees (- (* 2 moon-lat) moon-anomaly)))
 133                  (* 0.0005 (solar-sin-degrees
 134                             (+ (* 2 moon-anomaly) sun-anomaly))))
 135             (+ (* (- 0.1721 (* 0.0004 time))
 136                   (solar-sin-degrees sun-anomaly))
 137                (* 0.0021 (solar-sin-degrees (* 2 sun-anomaly)))
 138                (* -0.6280 (solar-sin-degrees moon-anomaly))
 139                (* 0.0089 (solar-sin-degrees (* 2 moon-anomaly)))
 140                (* -0.0004 (solar-sin-degrees (* 3 moon-anomaly)))
 141                (* 0.0079 (solar-sin-degrees (* 2 moon-lat)))
 142                (* -0.0119 (solar-sin-degrees (+ sun-anomaly moon-anomaly)))
 143                (* -0.0047 (solar-sin-degrees (- sun-anomaly moon-anomaly)))
 144                (* 0.0003 (solar-sin-degrees (+ (* 2 moon-lat) sun-anomaly)))
 145                (* -0.0004 (solar-sin-degrees (- (* 2 moon-lat) sun-anomaly)))
 146                (* -0.0006 (solar-sin-degrees (+ (* 2 moon-lat) moon-anomaly)))
 147                (* 0.0021 (solar-sin-degrees (- (* 2 moon-lat) moon-anomaly)))
 148                (* 0.0003 (solar-sin-degrees
 149                           (+ (* 2 moon-anomaly) sun-anomaly)))
 150                (* 0.0004 (solar-sin-degrees
 151                           (- sun-anomaly (* 2 moon-anomaly))))
 152                (* -0.0003 (solar-sin-degrees
 153                           (+ (* 2 sun-anomaly) moon-anomaly))))))
 154          (adj (+ 0.0028
 155                  (* -0.0004 (solar-cosine-degrees
 156                              sun-anomaly))
 157                  (* 0.0003 (solar-cosine-degrees
 158                             moon-anomaly))))
 159          (adjustment (cond ((= phase 1) (+ adjustment adj))
 160                            ((= phase 2) (- adjustment adj))
 161                            (t adjustment)))
 162          (date (+ date adjustment))
 163          (calendar-standard-time-zone-name
 164           (if calendar-time-zone calendar-standard-time-zone-name "UT"))
 165          (calendar-daylight-savings-starts
 166           (if calendar-time-zone calendar-daylight-savings-starts))
 167          (calendar-daylight-savings-ends
 168           (if calendar-time-zone calendar-daylight-savings-ends))
 169          (calendar-time-zone (if calendar-time-zone calendar-time-zone 0))
 170          (year (extract-calendar-year
 171                 (calendar-gregorian-from-absolute (truncate date))))
 172          (dst (and calendar-daylight-savings-starts
 173                    calendar-daylight-savings-ends
 174                    (<= (calendar-absolute-from-gregorian
 175                         (eval calendar-daylight-savings-starts))
 176                        date)
 177                    (< date
 178                       (calendar-absolute-from-gregorian
 179                        (eval calendar-daylight-savings-ends)))))
 180          (date (+ date
 181                   (/ (+ (if dst 60 0) calendar-time-zone) 60.0 24.0)
 182                   (- (/ (solar-ephemeris-correction year) 60.0 24.0))))
 183          (time (* 24 (- date (truncate date))))
 184          (date (calendar-gregorian-from-absolute (truncate date)))
 185          (time-zone calendar-time-zone)
 186          (time-zone (if dst
 187                         calendar-daylight-time-zone-name
 188                         calendar-standard-time-zone-name))
 189          (24-hours (truncate time))
 190          (12-hours (format "%d" (if (> 24-hours 12)
 191                                     (- 24-hours 12)
 192                                   (if (= 24-hours 0) 12 24-hours))))
 193          (am-pm (if (>= 24-hours 12) "pm" "am"))
 194          (minutes (format "%02d" (round (* 60 (- time 24-hours)))))
 195          (24-hours (format "%02d" 24-hours))
 196          (time (mapconcat 'eval calendar-time-display-form "")))
 197     (list date time phase)))
 198
 199 (defun lunar-phase-name (phase)
 200   "Name of lunar PHASE.
 201 0 = new moon, 1 = first quarter, 2 = full moon, 3 = last quarter."
 202   (cond ((= 0 phase) "New Moon")
 203         ((= 1 phase) "First Quarter Moon")
 204         ((= 2 phase) "Full Moon")
 205         ((= 3 phase) "Last Quarter Moon")))
 206
 207 (defun calendar-phases-of-moon ()
 208   "Create a buffer with the lunar phases for the current calendar window."
 209   (interactive)
 210   (message "Computing phases of the moon...")
 211   (let ((m1 displayed-month)
 212         (y1 displayed-year)
 213         (m2 displayed-month)
 214         (y2 displayed-year)
 215         (lunar-phases-buffer "*Phases of Moon*"))
 216     (increment-calendar-month m1 y1 -1)
 217     (increment-calendar-month m2 y2 1)
 218     (set-buffer (get-buffer-create lunar-phases-buffer))
 219     (setq buffer-read-only nil)
 220     (calendar-set-mode-line
 221           (format "Phases of the moon from %s, %d to %s, %d%%-"
 222                   (calendar-month-name m1) y1 (calendar-month-name m2) y2))
 223     (erase-buffer)
 224     (insert
 225      (mapconcat
 226       '(lambda (x)
 227          (let ((date (car x))
 228                (time (car (cdr x)))
 229                (phase (car (cdr (cdr x)))))
 230            (concat (calendar-date-string date)
 231                    ": "
 232                    (lunar-phase-name phase)
 233                    " "
 234                    time)))
 235       (lunar-phase-list m1 y1) "\n"))
 236     (goto-char (point-min))
 237     (set-buffer-modified-p nil)
 238     (setq buffer-read-only t)
 239     (display-buffer lunar-phases-buffer)
 240     (message "Computing phases of the moon...done")))
 241
 242 ;;;###autoload
 243 (defun phases-of-moon (&optional arg)
 244   "Display the quarters of the moon for last month, this month, and next month.
 245 If called with an optional prefix argument, prompts for month and year.
 246
 247 This function is suitable for execution in a .emacs file."
 248   (interactive "P")
 249   (save-excursion
 250     (let* ((completion-ignore-case t)
 251            (date (calendar-current-date))
 252            (displayed-month
 253             (if arg
 254                 (cdr (assoc
 255                       (capitalize
 256                        (completing-read
 257                         "Month name: "
 258                         (mapcar 'list (append calendar-month-name-array nil))
 259                         nil t))
 260                       (calendar-make-alist calendar-month-name-array)))
 261               (extract-calendar-month date)))
 262            (displayed-year
 263             (if arg
 264                 (calendar-read
 265                  "Year (>0): "
 266                  '(lambda (x) (> x 0))
 267                  (int-to-string
 268                   (extract-calendar-year (calendar-current-date))))
 269               (extract-calendar-year date))))
 270       (calendar-phases-of-moon))))
 271
 272 (defun diary-phases-of-moon ()
 273   "Moon phases diary entry."
 274   (let* ((index (* 4
 275                    (truncate
 276                     (* 12.3685
 277                        (+ (extract-calendar-year date)
 278                           ( / (calendar-day-number date)
 279                               366.0)
 280                           -1900)))))
 281          (phase (lunar-phase index)))
 282     (while (calendar-date-compare phase (list date))
 283       (setq index (1+ index))
 284       (setq phase (lunar-phase index)))
 285     (if (calendar-date-equal (car phase) date)
 286         (concat (lunar-phase-name (car (cdr (cdr phase)))) " "
 287                 (car (cdr phase))))))
 288
 289 (provide 'lunar)
 290
 291 ;;; lunar.el ends here