code.delx.au - gnu-emacs/blob - configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003, 2004,
   8 dnl    2005, 2006, 2007, 2008, 2009, 2010, 2011
   9 dnl    Free Software Foundation, Inc.
  10 dnl
  11 dnl  This file is part of GNU Emacs.
  12 dnl
  13 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  14 dnl  it under the terms of the GNU General Public License as published by
  15 dnl  the Free Software Foundation, either version 3 of the License, or
  16 dnl  (at your option) any later version.
  17 dnl
  18 dnl  GNU Emacs is distributed in the hope that it will be useful,
  19 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 dnl  GNU General Public License for more details.
  22 dnl
  23 dnl  You should have received a copy of the GNU General Public License
  24 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 AC_PREREQ(2.65)
  27 AC_INIT(emacs, 24.0.50)
  28 AC_CONFIG_HEADER(src/config.h:src/config.in)
  29 AC_CONFIG_SRCDIR(src/lisp.h)
  30 AM_INIT_AUTOMAKE
  31
  32 dnl Support for --program-prefix, --program-suffix and
  33 dnl --program-transform-name options
  34 AC_ARG_PROGRAM
  35
  36 dnl It is important that variables on the RHS not be expanded here,
  37 dnl hence the single quotes.  This is per the GNU coding standards, see
  38 dnl (autoconf) Installation Directory Variables
  39 dnl See also epaths.h below.
  40 lispdir='${datadir}/emacs/${version}/lisp'
  41 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  42 '${datadir}/emacs/site-lisp'
  43 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  44 etcdir='${datadir}/emacs/${version}/etc'
  45 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  46 docdir='${datadir}/emacs/${version}/etc'
  47 gamedir='${localstatedir}/games/emacs'
  48
  49 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  50 dnl Create a new --with option that defaults to being disabled.
  51 dnl NAME is the base name of the option.  The shell variable with_NAME
  52 dnl   will be set to either the user's value (if the option is
  53 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  54 dnl   option is not specified).  Note that the shell variable name is
  55 dnl   constructed as autoconf does, by replacing non-alphanumeric
  56 dnl   characters with "_".
  57 dnl HELP-STRING is the help text for the option.
  58 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  59   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  60     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  61 ])dnl
  62
  63 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  64 dnl Create a new --with option that defaults to being enabled.  NAME
  65 dnl   is the base name of the option.  The shell variable with_NAME
  66 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  67 dnl   'yes' (if the option is not specified).  Note that the shell
  68 dnl   variable name is constructed as autoconf does, by replacing
  69 dnl   non-alphanumeric characters with "_".
  70 dnl HELP-STRING is the help text for the option.
  71 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  72   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  73    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  74 ])dnl
  75
  76 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  77 if test "$with_pop" = yes; then
  78    AC_DEFINE(MAIL_USE_POP)
  79 fi
  80 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  81
  82 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  83 if test "$with_kerberos" != no; then
  84    AC_DEFINE(KERBEROS)
  85 fi
  86 AH_TEMPLATE(KERBEROS,
  87             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  88
  89 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  90 if test "${with_kerberos5}" != no; then
  91   if test "${with_kerberos}" = no; then
  92     with_kerberos=yes
  93     AC_DEFINE(KERBEROS)
  94   fi
  95   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  96 fi
  97
  98 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  99 dnl FIXME hesiod support may not be present, so it seems like an error
 100 dnl to define, or at least use, this unconditionally.
 101 if test "$with_hesiod" != no; then
 102   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 103 fi
 104
 105 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 106 if test "$with_mmdf" != no; then
 107    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 108 fi
 109
 110 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 111 if test "$with_mail_unlink" != no; then
 112    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 113 fi
 114
 115 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 116     [string giving default POP mail host])],
 117     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 118
 119 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 120
 121 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 122 if test "$with_sync_input" = yes; then
 123    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 124 fi
 125
 126 dnl FIXME currently it is not the last.
 127 dnl This should be the last --with option, because --with-x is
 128 dnl added later on when we find the path of X, and it's best to
 129 dnl keep them together visually.
 130 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 131  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 132 [         case "${withval}" in
 133             y | ye | yes )      val=gtk ;;
 134             n | no )            val=no  ;;
 135             l | lu | luc | luci | lucid )       val=lucid ;;
 136             a | at | ath | athe | athen | athena )      val=athena ;;
 137             m | mo | mot | moti | motif )       val=motif ;;
 138             g | gt | gtk  )     val=gtk ;;
 139             gtk3  )     val=gtk3 ;;
 140             * )
 141 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 142 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 143 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 144             ;;
 145           esac
 146           with_x_toolkit=$val
 147 ])
 148
 149 dnl _ON results in a '--without' option in the --help output, so
 150 dnl the help text should refer to "don't compile", etc.
 151 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 152 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 153 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 154 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 155 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 156 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 157 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 158 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 159
 160 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 161 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 162 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 163
 164 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 165 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 166 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 167 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 168
 169 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 170 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 171 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 172 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 173 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 174
 175 ## For the times when you want to build Emacs but don't have
 176 ## a suitable makeinfo, and can live without the manuals.
 177 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 178 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 179
 180 ## This is an option because I do not know if all info/man support
 181 ## compressed files, nor how to test if they do so.
 182 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 183 if test $with_compress_info = yes; then
 184    GZIP_INFO=yes
 185 else
 186    GZIP_INFO=
 187 fi
 188 AC_SUBST(GZIP_INFO)
 189
 190 AC_ARG_WITH([pkg-config-prog],dnl
 191 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 192                   [path to pkg-config for finding GTK and librsvg])])
 193 if test "X${with_pkg_config_prog}" != X; then
 194    if test "${with_pkg_config_prog}" != yes; then
 195       PKG_CONFIG="${with_pkg_config_prog}"
 196    fi
 197 fi
 198
 199 CRT_DIR=
 200 AC_ARG_WITH([crt-dir],dnl
 201 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 202 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 203 CRT_DIR="${with_crt_dir}"
 204
 205 AC_ARG_WITH(gameuser,dnl
 206 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 207 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 208   && gameuser="${with_gameuser}"
 209 test "X$gameuser" = X && gameuser=games
 210
 211 AC_ARG_WITH([gnustep-conf],dnl
 212 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 213 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 214   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 215 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 216      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 217
 218 AC_ARG_ENABLE(ns-self-contained,
 219 [AS_HELP_STRING([--disable-ns-self-contained],
 220                 [disable self contained build under NeXTstep])],
 221    EN_NS_SELF_CONTAINED=$enableval,
 222    EN_NS_SELF_CONTAINED=yes)
 223
 224 AC_ARG_ENABLE(asserts,
 225 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 226       USE_XASSERTS=$enableval,
 227       USE_XASSERTS=no)
 228
 229 AC_ARG_ENABLE(maintainer-mode,
 230 [AS_HELP_STRING([--enable-maintainer-mode],
 231                 [enable make rules and dependencies not useful (and sometimes
 232                  confusing) to the casual installer])],
 233       USE_MAINTAINER_MODE=$enableval,
 234       USE_MAINTAINER_MODE=no)
 235 if test $USE_MAINTAINER_MODE = yes; then
 236   MAINT=
 237 else
 238   MAINT=#
 239 fi
 240 AC_SUBST(MAINT)
 241
 242 AC_ARG_ENABLE(locallisppath,
 243 [AS_HELP_STRING([--enable-locallisppath=PATH],
 244                 [directories Emacs should search for lisp files specific
 245                  to this site])],
 246 if test "${enableval}" = "no"; then
 247   locallisppath=
 248 elif test "${enableval}" != "yes"; then
 249   locallisppath=${enableval}
 250 fi)
 251
 252 AC_ARG_ENABLE(checking,
 253 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 254                 [enable expensive run-time checks.  With LIST,
 255                  enable only specific categories of checks.
 256                  Categories are: all,yes,no.
 257                  Flags are: stringbytes, stringoverrun, stringfreelist,
 258                  xmallocoverrun, conslist])],
 259 [ac_checking_flags="${enableval}"],[])
 260 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 261 for check in $ac_checking_flags
 262 do
 263         case $check in
 264         # these set all the flags to specific states
 265         yes)            ac_enable_checking=1 ;;
 266         no)             ac_enable_checking= ;
 267                         ac_gc_check_stringbytes= ;
 268                         ac_gc_check_string_overrun= ;
 269                         ac_gc_check_string_free_list= ;
 270                         ac_xmalloc_overrun= ;
 271                         ac_gc_check_cons_list= ;;
 272         all)            ac_enable_checking=1 ;
 273                         ac_gc_check_stringbytes=1 ;
 274                         ac_gc_check_string_overrun=1 ;
 275                         ac_gc_check_string_free_list=1 ;
 276                         ac_xmalloc_overrun=1 ;
 277                         ac_gc_check_cons_list=1 ;;
 278         # these enable particular checks
 279         stringbytes)    ac_gc_check_stringbytes=1 ;;
 280         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 281         stringfreelist) ac_gc_check_string_free_list=1 ;;
 282         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 283         conslist)       ac_gc_check_cons_list=1 ;;
 284         *)      AC_MSG_ERROR(unknown check category $check) ;;
 285         esac
 286 done
 287 IFS="$ac_save_IFS"
 288
 289 if test x$ac_enable_checking != x ; then
 290   AC_DEFINE(ENABLE_CHECKING, 1,
 291 [Enable expensive run-time checking of data types?])
 292 fi
 293 if test x$ac_gc_check_stringbytes != x ; then
 294   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 295 [Define this temporarily to hunt a bug.  If defined, the size of
 296    strings is redundantly recorded in sdata structures so that it can
 297    be compared to the sizes recorded in Lisp strings.])
 298 fi
 299 if test x$ac_gc_check_stringoverrun != x ; then
 300   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 301 [Define this to check for short string overrun.])
 302 fi
 303 if test x$ac_gc_check_string_free_list != x ; then
 304   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 305 [Define this to check the string free list.])
 306 fi
 307 if test x$ac_xmalloc_overrun != x ; then
 308   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 309 [Define this to check for malloc buffer overrun.])
 310 fi
 311 if test x$ac_gc_check_cons_list != x ; then
 312   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 313 [Define this to check for errors in cons list.])
 314 fi
 315
 316 AC_ARG_ENABLE(use-lisp-union-type,
 317 [AS_HELP_STRING([--enable-use-lisp-union-type],
 318                 [use a union for the Lisp_Object data type.
 319                 This is only useful for development for catching certain types of bugs.])],
 320 if test "${enableval}" != "no"; then
 321    AC_DEFINE(USE_LISP_UNION_TYPE, 1,
 322    [Define this to use a lisp union for the Lisp_Object data type.])
 323 fi)
 324
 325
 326 AC_ARG_ENABLE(profiling,
 327 [AS_HELP_STRING([--enable-profiling],
 328                 [build emacs with profiling support.
 329                  This might not work on all platforms])],
 330 [ac_enable_profiling="${enableval}"],[])
 331 if test x$ac_enable_profiling != x ; then
 332    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 333 else
 334    PROFILING_CFLAGS=
 335 fi
 336 AC_SUBST(PROFILING_CFLAGS)
 337
 338 AC_ARG_ENABLE(autodepend,
 339 [AS_HELP_STRING([--enable-autodepend],
 340                 [automatically generate dependencies to .h-files.
 341                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 342                  found])],
 343 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 344
 345 #### Make srcdir absolute, if it isn't already.  It's important to
 346 #### avoid running the path through pwd unnecessarily, since pwd can
 347 #### give you automounter prefixes, which can go away.  We do all this
 348 #### so Emacs can find its files when run uninstalled.
 349 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 350 unset CDPATH
 351 case "${srcdir}" in
 352   /* ) ;;
 353   . )
 354     ## We may be able to use the $PWD environment variable to make this
 355     ## absolute.  But sometimes PWD is inaccurate.
 356     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 357     ## but that tested only for a well-formed and valid PWD,
 358     ## it did not object when PWD was well-formed and valid but just wrong.
 359     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 360     then
 361       srcdir="$PWD"
 362     else
 363       srcdir="`(cd ${srcdir}; pwd)`"
 364     fi
 365   ;;
 366   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 367 esac
 368
 369 #### Check if the source directory already has a configured system in it.
 370 if test `pwd` != `(cd ${srcdir} && pwd)` \
 371    && test -f "${srcdir}/src/config.h" ; then
 372   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 373    as a build directory right now; it has been configured in its own
 374    right.  To configure in another directory as well, you MUST
 375    use GNU make.  If you do not have GNU make, then you must
 376    now do `make distclean' in ${srcdir},
 377    and then run $0 again.]])
 378 fi
 379
 380 #### Given the configuration name, set machfile and opsysfile to the
 381 #### names of the m/*.h and s/*.h files we should use.
 382
 383 ### Canonicalize the configuration name.
 384
 385 AC_CANONICAL_HOST
 386 canonical=$host
 387 configuration=${host_alias-${build_alias-$host}}
 388
 389 dnl This used to use changequote, but, apart from `changequote is evil'
 390 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 391 dnl the great gob of text.  Thus it's not processed for possible expansion.
 392 dnl Just make sure the brackets remain balanced.
 393 dnl
 394 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 395 dnl indicated by comments.
 396 dnl quotation begins
 397 [
 398
 399 ### If you add support for a new configuration, add code to this
 400 ### switch statement to recognize your configuration name and select
 401 ### the appropriate operating system and machine description files.
 402
 403 ### You would hope that you could choose an m/*.h file pretty much
 404 ### based on the machine portion of the configuration name, and an s/*.h
 405 ### file based on the operating system portion.  However, it turns out
 406 ### that each m/*.h file is pretty manufacturer-specific - for
 407 ### example mips.h is MIPS
 408 ### So we basically have to have a special case for each
 409 ### configuration name.
 410 ###
 411 ### As far as handling version numbers on operating systems is
 412 ### concerned, make sure things will fail in a fixable way.  If
 413 ### /etc/MACHINES doesn't say anything about version numbers, be
 414 ### prepared to handle anything reasonably.  If version numbers
 415 ### matter, be sure /etc/MACHINES says something about it.
 416
 417 machine='' opsys='' unported=no
 418 case "${canonical}" in
 419
 420   ## GNU/Linux ports
 421   *-*-linux-gnu*)
 422     opsys=gnu-linux
 423     case ${canonical} in
 424       alpha*)   machine=alpha ;;
 425       s390-*)   machine=ibms390 ;;
 426       s390x-*)  machine=ibms390x ;;
 427       powerpc*) machine=macppc ;;
 428       sparc*)   machine=sparc ;;
 429       ia64*)    machine=ia64 ;;
 430       m68k*)    machine=m68k ;;
 431       x86_64*)  machine=amdx86-64 ;;
 432     esac
 433   ;;
 434
 435   ## FreeBSD ports
 436   *-*-freebsd* )
 437     opsys=freebsd
 438     case "${canonical}" in
 439       alpha*)           machine=alpha ;;
 440       amd64-*|x86_64-*) machine=amdx86-64 ;;
 441       ia64-*)           machine=ia64 ;;
 442       i[3456]86-*)      machine=intel386 ;;
 443       powerpc-*)        machine=macppc ;;
 444       sparc-*)          machine=sparc ;;
 445       sparc64-*)        machine=sparc ;;
 446     esac
 447   ;;
 448
 449   ## FreeBSD kernel + glibc based userland
 450   *-*-kfreebsd*gnu* )
 451     opsys=gnu-kfreebsd
 452     case "${canonical}" in
 453       alpha*)           machine=alpha ;;
 454       amd64-*|x86_64-*) machine=amdx86-64 ;;
 455       ia64-*)           machine=ia64 ;;
 456       i[3456]86-*)      machine=intel386 ;;
 457       powerpc-*)        machine=macppc ;;
 458       sparc-*)          machine=sparc ;;
 459       sparc64-*)        machine=sparc ;;
 460     esac
 461   ;;
 462
 463   ## NetBSD ports
 464   *-*-netbsd* )
 465     opsys=netbsd
 466     case "${canonical}" in
 467       alpha*)      machine=alpha ;;
 468       x86_64-*)    machine=amdx86-64 ;;
 469       i[3456]86-*) machine=intel386 ;;
 470       m68k-*)      machine=m68k ;;
 471       powerpc-*)   machine=macppc ;;
 472       sparc*-)     machine=sparc ;;
 473       vax-*)       machine=vax ;;
 474     esac
 475   ;;
 476
 477   ## OpenBSD ports
 478   *-*-openbsd* )
 479     opsys=openbsd
 480     case "${canonical}" in
 481       alpha*)    machine=alpha ;;
 482       x86_64-*)  machine=amdx86-64 ;;
 483       i386-*)    machine=intel386 ;;
 484       powerpc-*) machine=macppc ;;
 485       sparc*)    machine=sparc ;;
 486       vax-*)     machine=vax ;;
 487     esac
 488   ;;
 489
 490   ## Apple Darwin / Mac OS X
 491   *-apple-darwin* )
 492     case "${canonical}" in
 493       i[3456]86-* )  machine=intel386 ;;
 494       powerpc-* )    machine=macppc ;;
 495       x86_64-* )     machine=amdx86-64 ;;
 496       * )            unported=yes ;;
 497     esac
 498     opsys=darwin
 499     # Define CPP as follows to make autoconf work correctly.
 500     CPP="${CC-cc} -E -no-cpp-precomp"
 501     # Use fink packages if available.
 502     if test -d /sw/include && test -d /sw/lib; then
 503       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 504       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 505       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 506     fi
 507   ;;
 508
 509   ## HP 9000 series 700 and 800, running HP/UX
 510   hppa*-hp-hpux10.2* )
 511     opsys=hpux10-20
 512   ;;
 513   hppa*-hp-hpux1[1-9]* )
 514     opsys=hpux11
 515     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 516   ;;
 517
 518   ia64*-hp-hpux1[1-9]* )
 519     machine=hp800 opsys=hpux11
 520   ;;
 521
 522   hppa*-*-linux-gnu* )
 523     machine=hp800 opsys=gnu-linux
 524   ;;
 525
 526   ## IBM machines
 527   rs6000-ibm-aix4.[23]* )
 528     machine=ibmrs6000 opsys=aix4-2
 529   ;;
 530   powerpc-ibm-aix4.[23]*  )
 531     machine=ibmrs6000 opsys=aix4-2
 532   ;;
 533   rs6000-ibm-aix[56]* )
 534     machine=ibmrs6000 opsys=aix4-2
 535   ;;
 536   powerpc-ibm-aix[56]*  )
 537     machine=ibmrs6000 opsys=aix4-2
 538   ;;
 539
 540   ## Silicon Graphics machines
 541   ## Iris 4D
 542   mips-sgi-irix6.5 )
 543     machine=iris4d opsys=irix6-5
 544     # Without defining _LANGUAGE_C, things get masked out in the headers
 545     # so that, for instance, grepping for `free' in stdlib.h fails and
 546     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 547     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 548     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 549   ;;
 550
 551   ## Suns
 552   *-sun-solaris* \
 553     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 554     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 555     case "${canonical}" in
 556       i[3456]86-*-* )     machine=intel386 ;;
 557       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 558       sparc* )          machine=sparc ;;
 559       * )               unported=yes ;;
 560     esac
 561     case "${canonical}" in
 562       *-sunos5.6* | *-solaris2.6* )
 563                 opsys=sol2-6
 564                 NON_GNU_CPP=/usr/ccs/lib/cpp
 565                 RANLIB="ar -ts"
 566                 ;;
 567       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 568                 opsys=sol2-6
 569                 emacs_check_sunpro_c=yes
 570                 NON_GNU_CPP=/usr/ccs/lib/cpp
 571                 ;;
 572       *-sunos5* | *-solaris* )
 573                 opsys=sol2-10
 574                 emacs_check_sunpro_c=yes
 575                 NON_GNU_CPP=/usr/ccs/lib/cpp
 576                 ;;
 577     esac
 578     ## Watch out for a compiler that we know will not work.
 579     case "${canonical}" in
 580      *-solaris* | *-sunos5* )
 581                 if [ "x$CC" = x/usr/ucb/cc ]; then
 582                   ## /usr/ucb/cc doesn't work;
 583                   ## we should find some other compiler that does work.
 584                   unset CC
 585                 fi
 586                 ;;
 587       *) ;;
 588     esac
 589   ;;
 590
 591   ## Intel 386 machines where we don't care about the manufacturer.
 592   i[3456]86-*-* )
 593     machine=intel386
 594     case "${canonical}" in
 595       *-cygwin )                opsys=cygwin ;;
 596       *-darwin* )               opsys=darwin
 597                                 CPP="${CC-cc} -E -no-cpp-precomp"
 598                                 ;;
 599       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 600       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 601       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 602       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 603     esac
 604   ;;
 605
 606   * )
 607     unported=yes
 608   ;;
 609 esac
 610
 611 ### If the code above didn't choose an operating system, just choose
 612 ### an operating system based on the configuration name.  You really
 613 ### only want to use this when you have no idea what the right
 614 ### operating system is; if you know what operating systems a machine
 615 ### runs, it's cleaner to make it explicit in the case statement
 616 ### above.
 617 if test x"${opsys}" = x; then
 618   case "${canonical}" in
 619     *-gnu* )                            opsys=gnu ;;
 620     * )
 621       unported=yes
 622     ;;
 623   esac
 624 fi
 625
 626 ]
 627 dnl quotation ends
 628
 629 if test $unported = yes; then
 630   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 631 Check `etc/MACHINES' for recognized configuration names.])
 632 fi
 633
 634 if test -n "$machine"; then
 635   machfile="m/${machine}.h"
 636 else
 637   machfile=
 638 fi
 639 opsysfile="s/${opsys}.h"
 640
 641
 642 #### Choose a compiler.
 643 test -n "$CC" && cc_specified=yes
 644
 645 # Save the value of CFLAGS that the user specified.
 646 SPECIFIED_CFLAGS="$CFLAGS"
 647
 648 dnl Sets GCC=yes if using gcc.
 649 AC_PROG_CC
 650 AM_PROG_CC_C_O
 651
 652 # Initialize gnulib right after verifying that the C compiler works.
 653 gl_EARLY
 654
 655 # On Suns, sometimes $CPP names a directory.
 656 if test -n "$CPP" && test -d "$CPP"; then
 657   CPP=
 658 fi
 659
 660 ## If not using gcc, and on Solaris, and no CPP specified, see if
 661 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 662 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 663  test x"$CPP" = x; then
 664   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 665   AC_CACHE_VAL(emacs_cv_sunpro_c,
 666   [AC_TRY_LINK([],
 667 [#ifndef __SUNPRO_C
 668 fail;
 669 #endif
 670 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 671   AC_MSG_RESULT($emacs_cv_sunpro_c)
 672
 673   if test x"$emacs_cv_sunpro_c" = xyes; then
 674     NON_GNU_CPP="$CC -E -Xs"
 675   fi
 676 fi
 677
 678 #### Some systems specify a CPP to use unless we are using GCC.
 679 #### Now that we know whether we are using GCC, we can decide whether
 680 #### to use that one.
 681 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 682 then
 683   CPP="$NON_GNU_CPP"
 684 fi
 685
 686 #### Some systems specify a CC to use unless we are using GCC.
 687 #### Now that we know whether we are using GCC, we can decide whether
 688 #### to use that one.
 689 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 690   test x$cc_specified != xyes
 691 then
 692   CC="$NON_GNU_CC"
 693 fi
 694
 695 if test x$GCC = xyes; then
 696   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 697 else
 698   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 699 fi
 700
 701 ### Use -Wno-pointer-sign if the compiler supports it
 702 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 703 SAVE_CFLAGS="$CFLAGS"
 704 CFLAGS="$CFLAGS -Wno-pointer-sign"
 705 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 706 if test $has_option = yes; then
 707    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 708 fi
 709 AC_MSG_RESULT($has_option)
 710 CFLAGS="$SAVE_CFLAGS"
 711 unset has_option
 712 unset SAVE_CFLAGS
 713
 714 ### Use -Wdeclaration-after-statement if the compiler supports it
 715 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 716 SAVE_CFLAGS="$CFLAGS"
 717 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 718 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 719 if test $has_option = yes; then
 720    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 721 fi
 722 AC_MSG_RESULT($has_option)
 723 CFLAGS="$SAVE_CFLAGS"
 724 unset has_option
 725 unset SAVE_CFLAGS
 726
 727 ### Use -Wold-style-definition if the compiler supports it
 728 # This can be removed when conversion to standard C is finished.
 729 AC_MSG_CHECKING([whether gcc understands -Wold-style-definition])
 730 SAVE_CFLAGS="$CFLAGS"
 731 CFLAGS="$CFLAGS -Wold-style-definition"
 732 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 733 if test $has_option = yes; then
 734    C_WARNINGS_SWITCH="-Wold-style-definition $C_WARNINGS_SWITCH"
 735 fi
 736 AC_MSG_RESULT($has_option)
 737 CFLAGS="$SAVE_CFLAGS"
 738 unset has_option
 739 unset SAVE_CFLAGS
 740
 741 ### Use -Wimplicit-function-declaration if the compiler supports it
 742 AC_MSG_CHECKING([whether gcc understands -Wimplicit-function-declaration])
 743 SAVE_CFLAGS="$CFLAGS"
 744 CFLAGS="$CFLAGS -Wimplicit-function-declaration"
 745 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 746 if test $has_option = yes; then
 747    C_WARNINGS_SWITCH="-Wimplicit-function-declaration $C_WARNINGS_SWITCH"
 748 fi
 749 AC_MSG_RESULT($has_option)
 750 CFLAGS="$SAVE_CFLAGS"
 751 unset has_option
 752 unset SAVE_CFLAGS
 753
 754 AC_SUBST(C_WARNINGS_SWITCH)
 755
 756
 757 #### Some other nice autoconf tests.
 758
 759 dnl checks for programs
 760 AC_PROG_CPP
 761 AC_PROG_INSTALL
 762 if test "x$RANLIB" = x; then
 763   AC_PROG_RANLIB
 764 fi
 765
 766 ## Although we're running on an amd64 kernel, we're actually compiling for
 767 ## the x86 architecture.  The user should probably have provided an
 768 ## explicit --build to `configure', but if everything else than the kernel
 769 ## is running in i386 mode, we can help them out.
 770 if test "$machine" = "amdx86-64"; then
 771   AC_CHECK_DECL([i386])
 772   if test "$ac_cv_have_decl_i386" = "yes"; then
 773     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 774     machine=intel386
 775     machfile="m/${machine}.h"
 776   fi
 777 fi
 778
 779 AC_PATH_PROG(INSTALL_INFO, install-info)
 780 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 781 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 782 dnl Don't use GZIP, which is used by gzip for additional parameters.
 783 AC_PATH_PROG(GZIP_PROG, gzip)
 784
 785
 786 ## Need makeinfo >= 4.6 (?) to build the manuals.
 787 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 788 dnl By this stage, configure has already checked for egrep and set EGREP,
 789 dnl or exited with an error if no egrep was found.
 790 if test "$MAKEINFO" != "no" && \
 791   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 792    MAKEINFO=no
 793 fi
 794
 795 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 796 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 797 ## therefore in the category of "special tools" not normally required, which
 798 ## configure does not have to check for (eg autoconf itself).
 799 ## In a Bazaar checkout on the other hand, the manuals are not included.
 800 ## So makeinfo is a requirement to build from Bazaar, and configure
 801 ## should test for it as it does for any other build requirement.
 802 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 803 ## with pre-built manuals, from a Bazaar checkout.
 804 HAVE_MAKEINFO=yes
 805
 806 if test "$MAKEINFO" = "no"; then
 807   MAKEINFO=makeinfo
 808   if test "x${with_makeinfo}" = "xno"; then
 809     HAVE_MAKEINFO=no
 810   elif test ! -e $srcdir/info/emacs; then
 811     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 812 source tree does not seem to have pre-built manuals in the `info' directory.
 813 Either install a suitable version of makeinfo, or re-run configure
 814 with the `--without-makeinfo' option to build without the manuals.] )
 815   fi
 816 fi
 817 AC_SUBST(HAVE_MAKEINFO)
 818
 819 dnl Add our options to ac_link now, after it is set up.
 820
 821 if test x$GCC = xyes; then
 822   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 823     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 824 else
 825   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 826     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 827 fi
 828
 829 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 830 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 831 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 832 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 833 dnl if not built to support GNU ld.
 834
 835 late_LDFLAGS=$LDFLAGS
 836 if test x$GCC = xyes; then
 837   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 838 else
 839   LDFLAGS="$LDFLAGS -znocombreloc"
 840 fi
 841
 842 AC_MSG_CHECKING([for -znocombreloc])
 843 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 844   [AC_MSG_RESULT(yes)],
 845   LDFLAGS=$late_LDFLAGS
 846   [AC_MSG_RESULT(no)])
 847
 848
 849 # The value of CPP is a quoted variable reference, so we need to do this
 850 # to get its actual value...
 851 CPP=`eval "echo $CPP"`
 852
 853
 854 dnl Not used by any currently supported platform.
 855 dnl The function dump-emacs will not be defined and temacs will do
 856 dnl (load "loadup") automatically unless told otherwise.
 857 CANNOT_DUMP=no
 858 case "$opsys" in
 859   your-opsys-here)
 860    CANNOT_DUMP=yes
 861    AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 862   ;;
 863 esac
 864 AC_SUBST(CANNOT_DUMP)
 865
 866
 867 UNEXEC_OBJ=unexelf.o
 868 case "$opsys" in
 869   # MSDOS uses unexcoff.o
 870   # MSWindows uses unexw32.o
 871   aix4-2)
 872    UNEXEC_OBJ=unexaix.o
 873    ;;
 874   cygwin)
 875    UNEXEC_OBJ=unexcw.o
 876    ;;
 877   darwin)
 878    UNEXEC_OBJ=unexmacosx.o
 879    ;;
 880   hpux10-20 | hpux11)
 881    UNEXEC_OBJ=unexhp9k800.o
 882    ;;
 883   sol2-10)
 884    # Use the Solaris dldump() function, called from unexsol.c, to dump
 885    # emacs, instead of the generic ELF dump code found in unexelf.c.
 886    # The resulting binary has a complete symbol table, and is better
 887    # for debugging and other observability tools (debuggers, pstack, etc).
 888    #
 889    # If you encounter a problem using dldump(), please consider sending
 890    # a message to the OpenSolaris tools-linking mailing list:
 891    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 892    #
 893    # It is likely that dldump() works with older Solaris too, but this has
 894    # not been tested, so for now this change is for Solaris 10 or newer.
 895    UNEXEC_OBJ=unexsol.o
 896    ;;
 897 esac
 898
 899 LD_SWITCH_SYSTEM=
 900 case "$opsys" in
 901   freebsd)
 902    ## Let `ld' find image libs and similar things in /usr/local/lib.
 903    ## The system compiler, GCC, has apparently been modified to not
 904    ## look there, contrary to what a stock GCC would do.
 905    LD_SWITCH_SYSTEM=-L/usr/local/lib
 906    ;;
 907
 908   gnu-linux)
 909    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 910    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 911    ;;
 912
 913   netbsd)
 914    LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 915    ;;
 916
 917   openbsd)
 918    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 919    ## otherwise Emacs dumps core on elf systems.
 920    LD_SWITCH_SYSTEM="-Z"
 921    ;;
 922 esac
 923 AC_SUBST(LD_SWITCH_SYSTEM)
 924
 925 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 926
 927 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_AUX,
 928 ## which has not been defined yet.  When this was handled with cpp,
 929 ## it was expanded to null when configure sourced the s/*.h file.
 930 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 931 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 932 ## (or somesuch), but because it is supposed to go at the _front_
 933 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 934 ## Compare with the gnu-linux case below, which added to the end
 935 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 936 ## LD_SWITCH_SYSTEM_TEMACS.
 937 case "$opsys" in
 938   netbsd|openbsd)
 939    ## _AUX_RPATH is like _AUX, but uses -rpath instead of -R.
 940    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_AUX_RPATH) $LD_SWITCH_SYSTEM" ;;
 941 esac
 942
 943
 944 C_SWITCH_MACHINE=
 945 if test "$machine" = "alpha"; then
 946   AC_CHECK_DECL([__ELF__])
 947   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 948     ## With ELF, make sure that all common symbols get allocated to in the
 949     ## data section.  Otherwise, the dump of temacs may miss variables in
 950     ## the shared library that have been initialized.  For example, with
 951     ## GNU libc, __malloc_initialized would normally be resolved to the
 952     ## shared library's .bss section, which is fatal.
 953     if test "x$GCC" = "xyes"; then
 954       C_SWITCH_MACHINE="-fno-common"
 955     else
 956       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 957     fi
 958   else
 959     UNEXEC_OBJ=unexalpha.o
 960   fi
 961 fi
 962 AC_SUBST(C_SWITCH_MACHINE)
 963
 964 AC_SUBST(UNEXEC_OBJ)
 965
 966 C_SWITCH_SYSTEM=
 967 ## Some programs in src produce warnings saying certain subprograms
 968 ## are too complex and need a MAXMEM value greater than 2000 for
 969 ## additional optimization.  --nils@exp-math.uni-essen.de
 970 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 971   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 972 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 973 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 974 AC_SUBST(C_SWITCH_SYSTEM)
 975
 976
 977 LIBS_SYSTEM=
 978 case "$opsys" in
 979   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 980   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 981
 982   freebsd) LIBS_SYSTEM="-lutil" ;;
 983
 984   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 985
 986   sol2*) LIBS_SYSTEM="-lsocket -lnsl -lkstat" ;;
 987
 988   ## Motif needs -lgen.
 989   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
 990 esac
 991 AC_SUBST(LIBS_SYSTEM)
 992
 993
 994 ### Make sure subsequent tests use flags consistent with the build flags.
 995
 996 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 997   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 998 else
 999   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1000 fi
1001
1002 dnl For AC_FUNC_GETLOADAVG, at least:
1003 AC_CONFIG_LIBOBJ_DIR(src)
1004
1005 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1006 AC_SYS_LARGEFILE
1007
1008
1009 ## If user specified a crt-dir, use that unconditionally.
1010 if test "X$CRT_DIR" = "X"; then
1011
1012   case "$canonical" in
1013     x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1014     ## On x86-64 and s390x GNU/Linux distributions, the standard library
1015     ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1016     ## For anything else (eg /usr/lib32), it is up the user to specify
1017     ## the location (bug#5655).
1018     ## Test for crtn.o, not just the directory, because sometimes the
1019     ## directory exists but does not have the relevant files (bug#1287).
1020     ## FIXME better to test for binary compatibility somehow.
1021     test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1022     ;;
1023
1024     powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1025   esac
1026
1027   case "$opsys" in
1028     hpux10-20) CRT_DIR=/lib ;;
1029   esac
1030
1031   ## Default is /usr/lib.
1032   test "X$CRT_DIR" = "X" && CRT_DIR=/usr/lib
1033
1034 else
1035
1036   ## Some platforms don't use any of these files, so it is not
1037   ## appropriate to put this test outside the if block.
1038   test -e $CRT_DIR/crtn.o || test -e $CRT_DIR/crt0.o || \
1039     AC_MSG_ERROR([crt*.o not found in specified location.])
1040
1041 fi
1042
1043 AC_SUBST(CRT_DIR)
1044
1045 LIB_MATH=-lm
1046 LIB_STANDARD=
1047 START_FILES=
1048
1049 case $opsys in
1050   cygwin )
1051     LIB_MATH=
1052     START_FILES='pre-crt0.o'
1053     ;;
1054   darwin )
1055     ## Adding -lm confuses the dynamic linker, so omit it.
1056     LIB_MATH=
1057     START_FILES='pre-crt0.o'
1058     ;;
1059   freebsd )
1060     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1061     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1062     ;;
1063   gnu-linux | gnu-kfreebsd )
1064     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1065     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1066     ;;
1067   hpux10-20 | hpux11 )
1068     LIB_STANDARD=-lc
1069     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1070     ;;
1071   netbsd | openbsd )
1072     if test -f $CRT_DIR/crti.o; then
1073         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1074         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1075     else
1076         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1077         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1078     fi
1079     ;;
1080 esac
1081
1082 AC_SUBST(LIB_MATH)
1083 AC_SUBST(START_FILES)
1084
1085 dnl This function definition taken from Gnome 2.0
1086 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1087 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1088 dnl also defines GSTUFF_PKG_ERRORS on error
1089 AC_DEFUN([PKG_CHECK_MODULES], [
1090   succeeded=no
1091
1092   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1093
1094   if test "$PKG_CONFIG" = "no" ; then
1095      ifelse([$4], , [AC_MSG_ERROR([
1096       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1097   else
1098      PKG_CONFIG_MIN_VERSION=0.9.0
1099      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1100         AC_MSG_CHECKING(for $2)
1101
1102         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1103             AC_MSG_RESULT(yes)
1104             succeeded=yes
1105
1106             AC_MSG_CHECKING($1_CFLAGS)
1107             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1108             AC_MSG_RESULT($$1_CFLAGS)
1109
1110             AC_MSG_CHECKING($1_LIBS)
1111             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1112             AC_MSG_RESULT($$1_LIBS)
1113         else
1114             AC_MSG_RESULT(no)
1115             $1_CFLAGS=""
1116             $1_LIBS=""
1117             ## If we have a custom action on failure, don't print errors, but
1118             ## do set a variable so people can do so.
1119             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1120             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1121         fi
1122
1123         AC_SUBST($1_CFLAGS)
1124         AC_SUBST($1_LIBS)
1125      else
1126         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1127         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1128      fi
1129   fi
1130
1131   if test $succeeded = yes; then
1132      ifelse([$3], , :, [$3])
1133   else
1134      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1135   fi
1136 ])
1137
1138
1139 if test "${with_sound}" != "no"; then
1140   # Sound support for GNU/Linux and the free BSDs.
1141   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1142     have_sound_header=yes)
1143   # Emulation library used on NetBSD.
1144   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1145   AC_SUBST(LIBSOUND)
1146
1147   ALSA_REQUIRED=1.0.0
1148   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1149   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1150   if test $HAVE_ALSA = yes; then
1151     SAVE_CFLAGS="$CFLAGS"
1152     SAVE_LDFLAGS="$LDFLAGS"
1153     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1154     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1155     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1156                     emacs_alsa_normal=yes,
1157                     emacs_alsa_normal=no)
1158     if test "$emacs_alsa_normal" != yes; then
1159       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1160                      [snd_lib_error_set_handler (0);],
1161                      emacs_alsa_subdir=yes,
1162                      emacs_alsa_subdir=no)
1163       if test "$emacs_alsa_subdir" != yes; then
1164         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1165       fi
1166       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1167     fi
1168
1169     CFLAGS="$SAVE_CFLAGS"
1170     LDFLAGS="$SAVE_LDFLAGS"
1171     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1172     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1173     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1174   fi
1175
1176   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1177   dnl compiles only on the specified platforms.  For others, it
1178   dnl probably doesn't make sense to try.
1179   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1180      case "$opsys" in
1181        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1182        gnu-linux|freebsd|netbsd)
1183          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1184          ;;
1185      esac
1186   fi
1187
1188   AC_SUBST(CFLAGS_SOUND)
1189 fi
1190
1191 dnl checks for header files
1192 AC_CHECK_HEADERS(sys/select.h sys/time.h unistd.h utime.h \
1193   linux/version.h sys/systeminfo.h limits.h \
1194   stdio_ext.h fcntl.h coff.h pty.h sys/mman.h \
1195   sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1196   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1197
1198 AC_MSG_CHECKING(if personality LINUX32 can be set)
1199 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1200                emacs_cv_personality_linux32=yes,
1201                emacs_cv_personality_linux32=no)
1202 AC_MSG_RESULT($emacs_cv_personality_linux32)
1203
1204 if test $emacs_cv_personality_linux32 = yes; then
1205   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1206             [Define to 1 if personality LINUX32 can be set.])
1207 fi
1208
1209 dnl On Solaris 8 there's a compilation warning for term.h because
1210 dnl it doesn't define `bool'.
1211 AC_CHECK_HEADERS(term.h, , , -)
1212 AC_HEADER_STDC
1213 AC_HEADER_TIME
1214 AC_CHECK_DECLS([sys_siglist])
1215 if test $ac_cv_have_decl_sys_siglist != yes; then
1216   # For Tru64, at least:
1217   AC_CHECK_DECLS([__sys_siglist])
1218   if test $ac_cv_have_decl___sys_siglist = yes; then
1219     AC_DEFINE(sys_siglist, __sys_siglist,
1220               [Define to any substitute for sys_siglist.])
1221   fi
1222 fi
1223 AC_HEADER_SYS_WAIT
1224
1225 dnl Some systems have utime.h but don't declare the struct anyplace.
1226 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1227 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1228 #include <sys/time.h>
1229 #include <time.h>
1230 #else
1231 #ifdef HAVE_SYS_TIME_H
1232 #include <sys/time.h>
1233 #else
1234 #include <time.h>
1235 #endif
1236 #endif
1237 #ifdef HAVE_UTIME_H
1238 #include <utime.h>
1239 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1240   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1241 if test $emacs_cv_struct_utimbuf = yes; then
1242   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1243 fi
1244
1245 dnl checks for typedefs
1246 AC_TYPE_SIGNAL
1247
1248 dnl Check for speed_t typedef.
1249 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1250   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1251     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1252 if test $emacs_cv_speed_t = yes; then
1253   AC_DEFINE(HAVE_SPEED_T, 1,
1254            [Define to 1 if `speed_t' is declared by <termios.h>.])
1255 fi
1256
1257 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1258 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1259 #include <sys/time.h>
1260 #include <time.h>
1261 #else
1262 #ifdef HAVE_SYS_TIME_H
1263 #include <sys/time.h>
1264 #else
1265 #include <time.h>
1266 #endif
1267 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1268   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1269 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1270 if test $emacs_cv_struct_timeval = yes; then
1271   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1272 fi
1273
1274 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1275 AC_TRY_COMPILE([#include <math.h>],
1276 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1277   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1278 HAVE_EXCEPTION=$emacs_cv_struct_exception
1279 if test $emacs_cv_struct_exception != yes; then
1280   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1281 fi
1282
1283 AC_CHECK_HEADERS(sys/socket.h)
1284 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1285 #if HAVE_SYS_SOCKET_H
1286 #include <sys/socket.h>
1287 #endif])
1288
1289 dnl checks for structure members
1290 AC_STRUCT_TM
1291 AC_STRUCT_TIMEZONE
1292 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1293                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1294                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1295                 [#include <time.h>])
1296 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1297                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1298                   struct ifreq.ifr_addr], , ,
1299                  [AC_INCLUDES_DEFAULT
1300 #if HAVE_SYS_SOCKET_H
1301 #include <sys/socket.h>
1302 #endif
1303 #if HAVE_NET_IF_H
1304 #include <net/if.h>
1305 #endif])
1306
1307 dnl checks for compiler characteristics
1308
1309 dnl Testing __STDC__ to determine prototype support isn't good enough.
1310 dnl DEC C, for instance, doesn't define it with default options, and
1311 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1312 dnl and void *.
1313 AC_C_PROTOTYPES
1314 AC_C_VOLATILE
1315 AC_C_CONST
1316 dnl This isn't useful because we can't turn on use of `inline' unless
1317 dnl the compiler groks `extern inline'.
1318 dnl AC_C_INLINE
1319 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1320   [AC_TRY_COMPILE(, [void * foo;],
1321                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1322 if test $emacs_cv_void_star = yes; then
1323   AC_DEFINE(POINTER_TYPE, void)
1324 else
1325   AC_DEFINE(POINTER_TYPE, char)
1326 fi
1327 AH_TEMPLATE(POINTER_TYPE,
1328             [Define as `void' if your compiler accepts `void *'; otherwise
1329              define as `char'.])dnl
1330
1331 dnl Check for endianess
1332 AC_C_BIGENDIAN
1333
1334 AC_CACHE_CHECK([for  __attribute__ ((__aligned__ (expr)))],
1335   [emacs_cv_attribute_aligned],
1336   [AC_COMPILE_IFELSE(
1337      [AC_LANG_PROGRAM(
1338         [[char __attribute__ ((__aligned__ (1 << 3))) c;]],
1339         [[]])],
1340      [emacs_cv_attribute_aligned=yes],
1341      [emacs_cv_attribute_aligned=no])])
1342 if test $emacs_cv_attribute_aligned = yes; then
1343   AC_DEFINE([HAVE_ATTRIBUTE_ALIGNED], 1,
1344     [Define to 1 if GCC-style __attribute__ ((__aligned__ (expr))) works.])
1345 fi
1346
1347 dnl check for Make feature
1348 AC_PROG_MAKE_SET
1349
1350 DEPFLAGS=
1351 MKDEPDIR=":"
1352 deps_frag=deps.mk
1353 dnl check for GNU Make if we have GCC and autodepend is on.
1354 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1355    AC_MSG_CHECKING([whether we are using GNU Make])
1356    HAVE_GNU_MAKE=no
1357    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1358    if test "x$testval" != x; then
1359       HAVE_GNU_MAKE=yes
1360    else
1361       ac_enable_autodepend=no
1362    fi
1363    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1364    if test $HAVE_GNU_MAKE = yes; then
1365       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1366       SAVE_CFLAGS="$CFLAGS"
1367       CFLAGS="$CFLAGS -MMD -MF deps.d"
1368       AC_TRY_COMPILE([], [], , ac_enable_autodepend=no)
1369       CFLAGS="$SAVE_CFLAGS"
1370       test -f deps.d || ac_enable_autodepend=no
1371       rm -rf deps.d
1372       AC_MSG_RESULT([$ac_enable_autodepend])
1373    fi
1374    if test $ac_enable_autodepend = yes; then
1375       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d'
1376       ## In parallel builds, another make might create depdir between
1377       ## the first test and mkdir, so stick another test on the end.
1378       ## Or use mkinstalldirs?  mkdir -p is not portable.
1379       MKDEPDIR='test -d ${DEPDIR} || mkdir ${DEPDIR} || test -d ${DEPDIR}'
1380       deps_frag=autodeps.mk
1381    fi
1382 fi
1383 deps_frag=$srcdir/src/$deps_frag
1384 AC_SUBST(MKDEPDIR)
1385 AC_SUBST(DEPFLAGS)
1386 AC_SUBST_FILE(deps_frag)
1387
1388
1389 dnl checks for operating system services
1390 AC_SYS_LONG_FILE_NAMES
1391
1392 #### Choose a window system.
1393
1394 AC_PATH_X
1395 if test "$no_x" = yes; then
1396   window_system=none
1397 else
1398   window_system=x11
1399 fi
1400
1401 ## Workaround for bug in autoconf <= 2.62.
1402 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1403 ## No need to do anything special for these standard directories.
1404 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1405
1406    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1407
1408 fi
1409
1410 LD_SWITCH_X_SITE_AUX=
1411 LD_SWITCH_X_SITE_AUX_RPATH=
1412 if test "${x_libraries}" != NONE; then
1413   if test -n "${x_libraries}"; then
1414     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1415     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1416     LD_SWITCH_X_SITE_AUX_RPATH=`echo ${LD_SWITCH_X_SITE_AUX} | sed -e 's/-R/-Wl,-rpath,/'`
1417   fi
1418   x_default_search_path=""
1419   x_search_path=${x_libraries}
1420   if test -z "${x_search_path}"; then
1421     x_search_path=/usr/lib
1422   fi
1423   for x_library in `echo ${x_search_path}: | \
1424                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1425     x_search_path="\
1426 ${x_library}/X11/%L/%T/%N%C%S:\
1427 ${x_library}/X11/%l/%T/%N%C%S:\
1428 ${x_library}/X11/%T/%N%C%S:\
1429 ${x_library}/X11/%L/%T/%N%S:\
1430 ${x_library}/X11/%l/%T/%N%S:\
1431 ${x_library}/X11/%T/%N%S"
1432     if test x"${x_default_search_path}" = x; then
1433       x_default_search_path=${x_search_path}
1434     else
1435       x_default_search_path="${x_search_path}:${x_default_search_path}"
1436     fi
1437   done
1438 fi
1439 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1440 AC_SUBST(LD_SWITCH_X_SITE_AUX_RPATH)
1441
1442 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1443   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1444 fi
1445
1446 if test x"${x_includes}" = x; then
1447   bitmapdir=/usr/include/X11/bitmaps
1448 else
1449   # accumulate include directories that have X11 bitmap subdirectories
1450   bmd_acc="dummyval"
1451   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1452     if test -d "${bmd}/X11/bitmaps"; then
1453       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1454     fi
1455     if test -d "${bmd}/bitmaps"; then
1456       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1457     fi
1458   done
1459   if test ${bmd_acc} != "dummyval"; then
1460     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1461   fi
1462 fi
1463
1464 HAVE_NS=no
1465 NS_IMPL_COCOA=no
1466 NS_IMPL_GNUSTEP=no
1467 tmp_CPPFLAGS="$CPPFLAGS"
1468 tmp_CFLAGS="$CFLAGS"
1469 CPPFLAGS="$CPPFLAGS -x objective-c"
1470 CFLAGS="$CFLAGS -x objective-c"
1471 TEMACS_LDFLAGS2="\${LDFLAGS}"
1472 dnl I don't think it's especially important, but src/Makefile.in
1473 dnl (now the only user of ns_appdir) used to go to the trouble of adding a
1474 dnl trailing "/" to it, so now we do it here.
1475 if test "${with_ns}" != no; then
1476   if test "${opsys}" = darwin; then
1477      NS_IMPL_COCOA=yes
1478      ns_appdir=`pwd`/nextstep/Emacs.app
1479      ns_appbindir=${ns_appdir}/Contents/MacOS/
1480      ns_appresdir=${ns_appdir}/Contents/Resources
1481      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1482   elif test -f $GNUSTEP_CONFIG_FILE; then
1483      NS_IMPL_GNUSTEP=yes
1484      ns_appdir=`pwd`/nextstep/Emacs.app
1485      ns_appbindir=${ns_appdir}/
1486      ns_appresdir=${ns_appdir}/Resources
1487      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1488      dnl FIXME sourcing this several times in subshells seems inefficient.
1489      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1490      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1491      dnl I seemed to need these as well with GNUstep-startup 0.25.
1492      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1493      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1494      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1495        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1496      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1497        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1498      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1499      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1500      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1501      LIB_STANDARD=
1502      START_FILES=
1503      TEMACS_LDFLAGS2=
1504   fi
1505   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1506                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1507   files are missing or cannot be compiled.])])
1508   NS_HAVE_NSINTEGER=yes
1509   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1510                                      [NSInteger i;])],
1511                     ns_have_nsinteger=yes,
1512                     ns_have_nsinteger=no)
1513   if test $ns_have_nsinteger = no; then
1514     NS_HAVE_NSINTEGER=no
1515   fi
1516 fi
1517 AC_SUBST(TEMACS_LDFLAGS2)
1518
1519 ns_frag=/dev/null
1520 NS_OBJ=
1521 NS_SUPPORT=
1522 if test "${HAVE_NS}" = yes; then
1523   window_system=nextstep
1524   with_xft=no
1525   # set up packaging dirs
1526   exec_prefix=${ns_appbindir}
1527   libexecdir=${ns_appbindir}/libexec
1528   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1529      prefix=${ns_appresdir}
1530   fi
1531   ns_frag=$srcdir/src/ns.mk
1532   NS_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o fontset.o fringe.o image.o"
1533   NS_SUPPORT="\${lispsource}/emacs-lisp/easymenu.elc \${lispsource}/term/ns-win.elc"
1534 fi
1535 CFLAGS="$tmp_CFLAGS"
1536 CPPFLAGS="$tmp_CPPFLAGS"
1537 AC_SUBST(NS_OBJ)
1538 AC_SUBST(NS_SUPPORT)
1539 AC_SUBST(LIB_STANDARD)
1540 AC_SUBST_FILE(ns_frag)
1541
1542 case "${window_system}" in
1543   x11 )
1544     HAVE_X_WINDOWS=yes
1545     HAVE_X11=yes
1546     case "${with_x_toolkit}" in
1547       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1548       motif ) USE_X_TOOLKIT=MOTIF ;;
1549       gtk ) with_gtk=yes
1550 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1551 dnl USE_X_TOOLKIT is set.
1552             USE_X_TOOLKIT=none ;;
1553       gtk3 ) with_gtk3=yes
1554              USE_X_TOOLKIT=none ;;
1555       no ) USE_X_TOOLKIT=none ;;
1556 dnl If user did not say whether to use a toolkit, make this decision later:
1557 dnl use the toolkit if we have gtk, or X11R5 or newer.
1558       * ) USE_X_TOOLKIT=maybe ;;
1559     esac
1560   ;;
1561   nextstep | none )
1562     HAVE_X_WINDOWS=no
1563     HAVE_X11=no
1564     USE_X_TOOLKIT=none
1565   ;;
1566 esac
1567
1568 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1569    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1570    if test "$HAVE_XSERVER" = true ||
1571       test -n "$DISPLAY" ||
1572       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1573         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1574 were found.  You should install the relevant development files for X
1575 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1576 sure you have development files for image handling, i.e.
1577 tiff, gif, jpeg, png and xpm.
1578 If you are sure you want Emacs compiled without X window support, pass
1579   --without-x
1580 to configure.])
1581    fi
1582 fi
1583
1584 ### If we're using X11, we should use the X menu package.
1585 HAVE_MENUS=no
1586 case ${HAVE_X11} in
1587   yes ) HAVE_MENUS=yes ;;
1588 esac
1589
1590 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1591 # Assume not, until told otherwise.
1592 GNU_MALLOC=yes
1593 doug_lea_malloc=yes
1594 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1595 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1596 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1597                emacs_cv_var___after_morecore_hook,
1598 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1599   emacs_cv_var___after_morecore_hook=yes,
1600   emacs_cv_var___after_morecore_hook=no)])
1601 if test $emacs_cv_var___after_morecore_hook = no; then
1602   doug_lea_malloc=no
1603 fi
1604
1605
1606 dnl See comments in aix4-2.h about maybe using system malloc there.
1607 system_malloc=no
1608 case "$opsys" in
1609   ## darwin ld insists on the use of malloc routines in the System framework.
1610   darwin|sol2-10) system_malloc=yes ;;
1611 esac
1612
1613 if test "${system_malloc}" = "yes"; then
1614   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1615   GNU_MALLOC=no
1616   GNU_MALLOC_reason="
1617     (The GNU allocators don't work with this system configuration.)"
1618   GMALLOC_OBJ=
1619   VMLIMIT_OBJ=
1620 else
1621   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1622   VMLIMIT_OBJ=vm-limit.o
1623 fi
1624 AC_SUBST(GMALLOC_OBJ)
1625 AC_SUBST(VMLIMIT_OBJ)
1626
1627 if test "$doug_lea_malloc" = "yes" ; then
1628   if test "$GNU_MALLOC" = yes ; then
1629     GNU_MALLOC_reason="
1630       (Using Doug Lea's new malloc from the GNU C Library.)"
1631   fi
1632   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1633             [Define to 1 if you are using the GNU C Library.])
1634
1635   ## Use mmap directly for allocating larger buffers.
1636   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1637   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1638   ## Does the AC_FUNC_MMAP test below make this check unecessary?
1639   case "$opsys" in
1640     gnu*) REL_ALLOC=no ;;
1641   esac
1642 fi
1643
1644 if test x"${REL_ALLOC}" = x; then
1645   REL_ALLOC=${GNU_MALLOC}
1646 fi
1647
1648 use_mmap_for_buffers=no
1649 case "$opsys" in
1650   freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1651 esac
1652
1653 AC_FUNC_MMAP
1654 if test $use_mmap_for_buffers = yes; then
1655   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1656   REL_ALLOC=no
1657 fi
1658
1659 LIBS="$LIBS_SYSTEM $LIBS"
1660
1661 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1662 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1663 AC_CHECK_LIB(dnet, dnet_ntoa)
1664 dnl This causes -lresolv to get used in subsequent tests,
1665 dnl which causes failures on some systems such as HPUX 9.
1666 dnl AC_CHECK_LIB(resolv, gethostbyname)
1667
1668 dnl FIXME replace main with a function we actually want from this library.
1669 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1670
1671 AC_CHECK_LIB(pthreads, cma_open)
1672
1673 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1674 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1675 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1676 ## added to LIBS in configure would never contain the pthreads part,
1677 ## but the value used in Makefiles might.  FIXME?
1678 ##
1679 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1680 ## be harmless on older versions of X where it happens to exist.
1681 test "$opsys" = "aix4-2" && \
1682   test $ac_cv_lib_pthreads_cma_open = yes && \
1683   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1684
1685 dnl Check for need for bigtoc support on IBM AIX
1686
1687 case ${host_os} in
1688 aix*)
1689   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1690     case $GCC in
1691     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1692     *) gdb_cv_bigtoc=-bbigtoc ;;
1693     esac
1694
1695     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1696     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1697   ])
1698   ;;
1699 esac
1700
1701 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1702 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1703 # REAL_CPPFLAGS later on.
1704
1705 REAL_CFLAGS="$CFLAGS"
1706 REAL_CPPFLAGS="$CPPFLAGS"
1707
1708 if test "${HAVE_X11}" = "yes"; then
1709   DEFS="$C_SWITCH_X_SITE $DEFS"
1710   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1711   LIBS="-lX11 $LIBS"
1712   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1713   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1714
1715   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1716   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1717   # but it's more convenient here to set LD_RUN_PATH
1718   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1719   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1720     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1721     export LD_RUN_PATH
1722   fi
1723
1724   if test "${opsys}" = "gnu-linux"; then
1725     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1726     AC_TRY_LINK([],
1727      [XOpenDisplay ("foo");],
1728      [xlinux_first_failure=no],
1729      [xlinux_first_failure=yes])
1730     if test "${xlinux_first_failure}" = "yes"; then
1731       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1732       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1733       OLD_CPPFLAGS="$CPPFLAGS"
1734       OLD_LIBS="$LIBS"
1735       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1736       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1737       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1738       LIBS="$LIBS -b i486-linuxaout"
1739       AC_TRY_LINK([],
1740        [XOpenDisplay ("foo");],
1741        [xlinux_second_failure=no],
1742        [xlinux_second_failure=yes])
1743       if test "${xlinux_second_failure}" = "yes"; then
1744         # If we get the same failure with -b, there is no use adding -b.
1745         # So take it out.  This plays safe.
1746         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1747         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1748         CPPFLAGS="$OLD_CPPFLAGS"
1749         LIBS="$OLD_LIBS"
1750         AC_MSG_RESULT(no)
1751       else
1752         AC_MSG_RESULT(yes)
1753       fi
1754     else
1755       AC_MSG_RESULT(no)
1756     fi
1757   fi
1758
1759   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1760   # header files included from there.
1761   AC_MSG_CHECKING(for Xkb)
1762   AC_TRY_LINK([#include <X11/Xlib.h>
1763 #include <X11/XKBlib.h>],
1764         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1765         emacs_xkb=yes, emacs_xkb=no)
1766   AC_MSG_RESULT($emacs_xkb)
1767   if test $emacs_xkb = yes; then
1768     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1769   fi
1770
1771   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1772 XScreenNumberOfScreen XSetWMProtocols)
1773 fi
1774
1775 if test "${window_system}" = "x11"; then
1776   AC_MSG_CHECKING(X11 version 6)
1777   AC_CACHE_VAL(emacs_cv_x11_version_6,
1778   [AC_TRY_LINK([#include <X11/Xlib.h>],
1779 [#if XlibSpecificationRelease < 6
1780 fail;
1781 #endif
1782 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1783   if test $emacs_cv_x11_version_6 = yes; then
1784     AC_MSG_RESULT(6 or newer)
1785     AC_DEFINE(HAVE_X11R6, 1,
1786               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1787     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1788     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1789     ## XIM support.
1790     case "$opsys" in
1791       sol2-*) : ;;
1792       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1793            [Define if you have usable X11R6-style XIM support.])
1794          ;;
1795     esac
1796   else
1797     AC_MSG_RESULT(before 6)
1798   fi
1799 fi
1800
1801
1802 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1803 HAVE_RSVG=no
1804 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1805   if test "${with_rsvg}" != "no"; then
1806     RSVG_REQUIRED=2.11.0
1807     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1808
1809     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1810     AC_SUBST(RSVG_CFLAGS)
1811     AC_SUBST(RSVG_LIBS)
1812
1813     if test $HAVE_RSVG = yes; then
1814       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1815       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1816       LIBS="$RSVG_LIBS $LIBS"
1817     fi
1818   fi
1819 fi
1820
1821 HAVE_IMAGEMAGICK=no
1822 if test "${HAVE_X11}" = "yes"; then
1823   if test "${with_imagemagick}" != "no"; then
1824     IMAGEMAGICK_MODULE="Wand"
1825     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1826     AC_SUBST(IMAGEMAGICK_CFLAGS)
1827     AC_SUBST(IMAGEMAGICK_LIBS)
1828
1829     if test $HAVE_IMAGEMAGICK = yes; then
1830       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1831       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1832       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1833       AC_CHECK_FUNCS(MagickExportImagePixels)
1834     fi
1835   fi
1836 fi
1837
1838
1839 HAVE_GTK=no
1840 if test "${with_gtk3}" = "yes"; then
1841   GLIB_REQUIRED=2.6
1842   GTK_REQUIRED=2.90
1843   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1844
1845   dnl Checks for libraries.
1846   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1847   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1848      AC_MSG_ERROR($GTK_PKG_ERRORS)
1849   fi
1850 fi
1851
1852 if test "$pkg_check_gtk" != "yes"; then
1853   HAVE_GTK=no
1854 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1855   GLIB_REQUIRED=2.6
1856   GTK_REQUIRED=2.6
1857   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1858
1859   dnl Checks for libraries.
1860   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1861   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1862      AC_MSG_ERROR($GTK_PKG_ERRORS)
1863   fi
1864 fi
1865 fi
1866
1867 GTK_OBJ=
1868 if test x"$pkg_check_gtk" = xyes; then
1869
1870   AC_SUBST(GTK_CFLAGS)
1871   AC_SUBST(GTK_LIBS)
1872   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1873   CFLAGS="$CFLAGS $GTK_CFLAGS"
1874   LIBS="$GTK_LIBS $LIBS"
1875   dnl Try to compile a simple GTK program.
1876   GTK_COMPILES=no
1877   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1878   if test "${GTK_COMPILES}" != "yes"; then
1879     if test "$USE_X_TOOLKIT" != "maybe"; then
1880       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1881     fi
1882   else
1883     HAVE_GTK=yes
1884     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1885     GTK_OBJ=gtkutil.o
1886     USE_X_TOOLKIT=none
1887     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1888       :
1889     else
1890       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1891        closing open displays.  This is no problem if you just use
1892        one display, but if you use more than one and close one of them
1893        Emacs may crash.]])
1894       sleep 3
1895     fi
1896   fi
1897
1898 fi
1899 AC_SUBST(GTK_OBJ)
1900
1901
1902 if test "${HAVE_GTK}" = "yes"; then
1903
1904   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1905   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1906   if test "$with_toolkit_scroll_bars" != no; then
1907     with_toolkit_scroll_bars=yes
1908   fi
1909
1910   dnl  Check if we have the old file selection dialog declared and
1911   dnl  in the link library.  In 2.x it may be in the library,
1912   dnl  but not declared if deprecated featured has been selected out.
1913   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1914   HAVE_GTK_FILE_SELECTION=no
1915   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1916                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1917 #include <gtk/gtk.h>])
1918   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1919     AC_CHECK_FUNCS(gtk_file_selection_new)
1920   fi
1921
1922   dnl Check if pthreads are available.  Emacs only needs this when using
1923   dnl gtk_file_chooser under Gnome.
1924     HAVE_GTK_AND_PTHREAD=no
1925     AC_CHECK_HEADERS(pthread.h)
1926     if test "$ac_cv_header_pthread_h"; then
1927       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1928     fi
1929     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1930       case "${canonical}" in
1931         *-hpux*) ;;
1932         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1933       esac
1934       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1935                [Define to 1 if you have GTK and pthread (-lpthread).])
1936     fi
1937
1938   dnl Check for functions introduced in 2.14 and later.
1939   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1940                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1941                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1942                  gtk_orientable_set_orientation)
1943
1944 fi
1945
1946 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1947 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1948 dnl also not configured.
1949 HAVE_DBUS=no
1950 DBUS_OBJ=
1951 if test "${with_dbus}" = "yes"; then
1952    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1953    if test "$HAVE_DBUS" = yes; then
1954      LIBS="$LIBS $DBUS_LIBS"
1955      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1956      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1957      DBUS_OBJ=dbusbind.o
1958    fi
1959 fi
1960 AC_SUBST(DBUS_OBJ)
1961
1962 dnl GConf has been tested under GNU/Linux only.
1963 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1964 HAVE_GCONF=no
1965 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1966    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1967    if test "$HAVE_GCONF" = yes; then
1968       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1969       dnl Newer GConf doesn't link with g_objects, so this is not defined.
1970       AC_CHECK_FUNCS([g_type_init])
1971    fi
1972 fi
1973
1974 dnl SELinux is available for GNU/Linux only.
1975 HAVE_LIBSELINUX=no
1976 LIBSELINUX_LIBS=
1977 if test "${with_selinux}" = "yes"; then
1978    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
1979    if test "$HAVE_LIBSELINUX" = yes; then
1980       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
1981       LIBSELINUX_LIBS=-lselinux
1982    fi
1983 fi
1984 AC_SUBST(LIBSELINUX_LIBS)
1985
1986 HAVE_GNUTLS=no
1987 if test "${with_gnutls}" = "yes" ; then
1988   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.2.4], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
1989   if test "${HAVE_GNUTLS}" = "yes"; then
1990     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
1991   fi
1992 fi
1993 AC_SUBST(LIBGNUTLS_LIBS)
1994 AC_SUBST(LIBGNUTLS_CFLAGS)
1995
1996 dnl Do not put whitespace before the #include statements below.
1997 dnl Older compilers (eg sunos4 cc) choke on it.
1998 HAVE_XAW3D=no
1999 LUCID_LIBW=
2000 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2001   if test "$with_xaw3d" != no; then
2002     AC_MSG_CHECKING(for xaw3d)
2003     AC_CACHE_VAL(emacs_cv_xaw3d,
2004     [AC_TRY_LINK([
2005 #include <X11/Intrinsic.h>
2006 #include <X11/Xaw3d/Simple.h>],
2007       [],
2008       emacs_cv_xaw3d=yes,
2009       emacs_cv_xaw3d=no)])
2010   else
2011     emacs_cv_xaw3d=no
2012   fi
2013   if test $emacs_cv_xaw3d = yes; then
2014     AC_MSG_RESULT([yes; using Lucid toolkit])
2015     USE_X_TOOLKIT=LUCID
2016     HAVE_XAW3D=yes
2017     LUCID_LIBW=-lXaw3d
2018     AC_DEFINE(HAVE_XAW3D, 1,
2019               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2020   else
2021     AC_MSG_RESULT(no)
2022     AC_MSG_CHECKING(for libXaw)
2023     AC_CACHE_VAL(emacs_cv_xaw,
2024     [AC_TRY_LINK([
2025 #include <X11/Intrinsic.h>
2026 #include <X11/Xaw/Simple.h>],
2027       [],
2028       emacs_cv_xaw=yes,
2029       emacs_cv_xaw=no)])
2030     if test $emacs_cv_xaw = yes; then
2031       AC_MSG_RESULT([yes; using Lucid toolkit])
2032       USE_X_TOOLKIT=LUCID
2033       LUCID_LIBW=-lXaw
2034     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2035       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2036     else
2037       AC_MSG_RESULT([no; do not use toolkit by default])
2038       USE_X_TOOLKIT=none
2039     fi
2040   fi
2041 fi
2042
2043 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2044
2045 LIBXTR6=
2046 if test "${USE_X_TOOLKIT}" != "none"; then
2047   AC_MSG_CHECKING(X11 toolkit version)
2048   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2049   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
2050 [#if XtSpecificationRelease < 6
2051 fail;
2052 #endif
2053 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2054   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2055   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2056     AC_MSG_RESULT(6 or newer)
2057     AC_DEFINE(HAVE_X11XTR6, 1,
2058               [Define to 1 if you have the X11R6 or newer version of Xt.])
2059     LIBXTR6="-lSM -lICE"
2060     case "$opsys" in
2061       ## Use libw.a along with X11R6 Xt.
2062       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2063     esac
2064   else
2065     AC_MSG_RESULT(before 6)
2066   fi
2067
2068 dnl If using toolkit, check whether libXmu.a exists.
2069 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2070   OLDLIBS="$LIBS"
2071   if test x$HAVE_X11XTR6 = xyes; then
2072     LIBS="-lXt -lSM -lICE $LIBS"
2073   else
2074     LIBS="-lXt $LIBS"
2075   fi
2076   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2077   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2078 fi
2079 AC_SUBST(LIBXTR6)
2080
2081 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2082 dnl Why not just test for libxmu in the normal way?
2083 LIBXMU=-lXmu
2084 case $opsys in
2085   ## These systems don't supply Xmu.
2086   hpux* | aix4-2 )
2087     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2088     ;;
2089 esac
2090 AC_SUBST(LIBXMU)
2091
2092 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2093 if test "${HAVE_X11}" = "yes"; then
2094   if test "${USE_X_TOOLKIT}" != "none"; then
2095     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2096   fi
2097 fi
2098
2099 LIBXP=
2100 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2101   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2102   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
2103     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2104 int x = 5;
2105 #else
2106 Motif version prior to 2.1.
2107 #endif],
2108     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2109   if test $emacs_cv_motif_version_2_1 = yes; then
2110     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2111   else
2112     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2113     # We put this in CFLAGS temporarily to precede other -I options
2114     # that might be in CFLAGS temporarily.
2115     # We put this in CPPFLAGS where it precedes the other -I options.
2116     OLD_CPPFLAGS=$CPPFLAGS
2117     OLD_CFLAGS=$CFLAGS
2118     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2119     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2120     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
2121       [int x = 5;],
2122       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2123     if test $emacs_cv_lesstif = yes; then
2124       # Make sure this -I option remains in CPPFLAGS after it is set
2125       # back to REAL_CPPFLAGS.
2126       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2127       # have those other -I options anyway.  Ultimately, having this
2128       # directory ultimately in CPPFLAGS will be enough.
2129       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2130       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2131     else
2132       CFLAGS=$OLD_CFLAGS
2133       CPPFLAGS=$OLD_CPPFLAGS
2134     fi
2135   fi
2136 fi
2137
2138 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2139 dnl using Motif or Xaw3d is available, and unless
2140 dnl --with-toolkit-scroll-bars=no was specified.
2141
2142 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2143             [Define to 1 if we should use toolkit scroll bars.])dnl
2144 USE_TOOLKIT_SCROLL_BARS=no
2145 if test "${with_toolkit_scroll_bars}" != "no"; then
2146   if test "${USE_X_TOOLKIT}" != "none"; then
2147     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2148       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2149       HAVE_XAW3D=no
2150       USE_TOOLKIT_SCROLL_BARS=yes
2151     elif test "${HAVE_XAW3D}" = "yes"; then
2152       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2153       USE_TOOLKIT_SCROLL_BARS=yes
2154     fi
2155   elif test "${HAVE_GTK}" = "yes"; then
2156     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2157     USE_TOOLKIT_SCROLL_BARS=yes
2158   elif test "${HAVE_NS}" = "yes"; then
2159     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2160     USE_TOOLKIT_SCROLL_BARS=yes
2161   fi
2162 fi
2163
2164 dnl See if XIM is available.
2165 AC_TRY_COMPILE([
2166           #include <X11/Xlib.h>
2167           #include <X11/Xresource.h>],
2168          [XIMProc  callback;],
2169          [HAVE_XIM=yes
2170          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2171          HAVE_XIM=no)
2172
2173 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2174
2175 if test "${with_xim}" != "no"; then
2176   AC_DEFINE(USE_XIM, 1,
2177             [Define to 1 if we should use XIM, if it is available.])
2178 fi
2179
2180
2181 if test "${HAVE_XIM}" != "no"; then
2182   late_CFLAGS=$CFLAGS
2183   if test "$GCC" = yes; then
2184     CFLAGS="$CFLAGS --pedantic-errors"
2185   fi
2186   AC_TRY_COMPILE([
2187 #include <X11/Xlib.h>
2188 #include <X11/Xresource.h>],
2189 [Display *display;
2190 XrmDatabase db;
2191 char *res_name;
2192 char *res_class;
2193 XIMProc  callback;
2194 XPointer *client_data;
2195 #ifndef __GNUC__
2196 /* If we're not using GCC, it's probably not XFree86, and this is
2197    probably right, but we can't use something like --pedantic-errors.  */
2198 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2199                                            char*, XIMProc, XPointer*);
2200 #endif
2201 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2202    client_data);],
2203     [emacs_cv_arg6_star=yes])
2204   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2205          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2206 either XPointer or XPointer*.])dnl
2207   if test "$emacs_cv_arg6_star" = yes; then
2208     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2209   else
2210     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2211   fi
2212   CFLAGS=$late_CFLAGS
2213 fi
2214
2215 ### Start of font-backend (under any platform) section.
2216 # (nothing here yet -- this is a placeholder)
2217 ### End of font-backend (under any platform) section.
2218
2219 ### Start of font-backend (under X11) section.
2220 if test "${HAVE_X11}" = "yes"; then
2221    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2222
2223    ## Use -lXft if available, unless `--with-xft=no'.
2224    HAVE_XFT=maybe
2225     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2226       with_xft="no";
2227     fi
2228     if test "x${with_xft}" != "xno"; then
2229
2230       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2231       ## Because xftfont.c uses XRenderQueryExtension, we also
2232       ## need to link to -lXrender.
2233       HAVE_XRENDER=no
2234       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2235       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2236         OLD_CPPFLAGS="$CPPFLAGS"
2237         OLD_CFLAGS="$CFLAGS"
2238         OLD_LIBS="$LIBS"
2239         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2240         CFLAGS="$CFLAGS $XFT_CFLAGS"
2241         XFT_LIBS="-lXrender $XFT_LIBS"
2242         LIBS="$XFT_LIBS $LIBS"
2243         AC_CHECK_HEADER(X11/Xft/Xft.h,
2244           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2245
2246         if test "${HAVE_XFT}" = "yes"; then
2247           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2248             AC_SUBST(XFT_LIBS)
2249           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2250         else
2251           CPPFLAGS="$OLD_CPPFLAGS"
2252           CFLAGS="$OLD_CFLAGS"
2253           LIBS="$OLD_LIBS"
2254         fi                        # "${HAVE_XFT}" = "yes"
2255       fi                          # "$HAVE_XFT" != no
2256     fi                            # "x${with_xft}" != "xno"
2257
2258     dnl For the "Does Emacs use" message at the end.
2259     if test "$HAVE_XFT" != "yes"; then
2260        HAVE_XFT=no
2261     fi
2262
2263     ## We used to allow building with FreeType and without Xft.
2264     ## However, the ftx font backend driver is not in good shape.
2265     HAVE_FREETYPE=$HAVE_XFT
2266
2267     HAVE_LIBOTF=no
2268     if test "${HAVE_FREETYPE}" = "yes"; then
2269       AC_DEFINE(HAVE_FREETYPE, 1,
2270                 [Define to 1 if using the freetype and fontconfig libraries.])
2271       if test "${with_libotf}" != "no"; then
2272         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2273                           HAVE_LIBOTF=no)
2274         if test "$HAVE_LIBOTF" = "yes"; then
2275           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2276           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2277                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2278                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2279           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2280             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2281                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2282           fi
2283         fi
2284       fi
2285     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2286     dnl Does the new font backend require it, or can it work without it?
2287     fi
2288
2289     HAVE_M17N_FLT=no
2290     if test "${HAVE_LIBOTF}" = yes; then
2291       if test "${with_m17n_flt}" != "no"; then
2292         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2293         if test "$HAVE_M17N_FLT" = "yes"; then
2294           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2295         fi
2296       fi
2297     fi
2298 else
2299     HAVE_XFT=no
2300     HAVE_FREETYPE=no
2301     HAVE_LIBOTF=no
2302     HAVE_M17N_FLT=no
2303 fi
2304
2305 ### End of font-backend (under X11) section.
2306
2307 AC_SUBST(FREETYPE_CFLAGS)
2308 AC_SUBST(FREETYPE_LIBS)
2309 AC_SUBST(FONTCONFIG_CFLAGS)
2310 AC_SUBST(FONTCONFIG_LIBS)
2311 AC_SUBST(LIBOTF_CFLAGS)
2312 AC_SUBST(LIBOTF_LIBS)
2313 AC_SUBST(M17N_FLT_CFLAGS)
2314 AC_SUBST(M17N_FLT_LIBS)
2315
2316 ### Use -lXpm if available, unless `--with-xpm=no'.
2317 HAVE_XPM=no
2318 LIBXPM=
2319 if test "${HAVE_X11}" = "yes"; then
2320   if test "${with_xpm}" != "no"; then
2321     AC_CHECK_HEADER(X11/xpm.h,
2322       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2323     if test "${HAVE_XPM}" = "yes"; then
2324       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2325       AC_EGREP_CPP(no_return_alloc_pixels,
2326       [#include "X11/xpm.h"
2327 #ifndef XpmReturnAllocPixels
2328 no_return_alloc_pixels
2329 #endif
2330       ], HAVE_XPM=no, HAVE_XPM=yes)
2331
2332       if test "${HAVE_XPM}" = "yes"; then
2333         AC_MSG_RESULT(yes)
2334       else
2335         AC_MSG_RESULT(no)
2336       fi
2337     fi
2338   fi
2339
2340   if test "${HAVE_XPM}" = "yes"; then
2341     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2342     LIBXPM=-lXpm
2343   fi
2344 fi
2345 AC_SUBST(LIBXPM)
2346
2347 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2348 HAVE_JPEG=no
2349 LIBJPEG=
2350 if test "${HAVE_X11}" = "yes"; then
2351   if test "${with_jpeg}" != "no"; then
2352     dnl Checking for jpeglib.h can lose because of a redefinition of
2353     dnl  HAVE_STDLIB_H.
2354     AC_CHECK_HEADER(jerror.h,
2355       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2356   fi
2357
2358   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2359   if test "${HAVE_JPEG}" = "yes"; then
2360     AC_DEFINE(HAVE_JPEG)
2361     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2362         [#include <jpeglib.h>
2363          version=JPEG_LIB_VERSION
2364 ],
2365         [AC_DEFINE(HAVE_JPEG)],
2366         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2367         HAVE_JPEG=no])
2368   fi
2369   if test "${HAVE_JPEG}" = "yes"; then
2370     LIBJPEG=-ljpeg
2371   fi
2372 fi
2373 AC_SUBST(LIBJPEG)
2374
2375 ### Use -lpng if available, unless `--with-png=no'.
2376 HAVE_PNG=no
2377 LIBPNG=
2378 if test "${HAVE_X11}" = "yes"; then
2379   if test "${with_png}" != "no"; then
2380     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2381     # in /usr/include/libpng.
2382     AC_CHECK_HEADERS(png.h libpng/png.h)
2383     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2384       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2385     fi
2386   fi
2387
2388   if test "${HAVE_PNG}" = "yes"; then
2389     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2390     LIBPNG="-lpng -lz -lm"
2391   fi
2392 fi
2393 AC_SUBST(LIBPNG)
2394
2395 ### Use -ltiff if available, unless `--with-tiff=no'.
2396 HAVE_TIFF=no
2397 LIBTIFF=
2398 if test "${HAVE_X11}" = "yes"; then
2399   if test "${with_tiff}" != "no"; then
2400     AC_CHECK_HEADER(tiffio.h,
2401       [tifflibs="-lz -lm"
2402       # At least one tiff package requires the jpeg library.
2403       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2404       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2405   fi
2406
2407   if test "${HAVE_TIFF}" = "yes"; then
2408     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2409     dnl FIXME -lz -lm, as per libpng?
2410     LIBTIFF=-ltiff
2411   fi
2412 fi
2413 AC_SUBST(LIBTIFF)
2414
2415 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2416 HAVE_GIF=no
2417 LIBGIF=
2418 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2419   AC_CHECK_HEADER(gif_lib.h,
2420 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2421 # Earlier versions can crash Emacs.
2422     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2423
2424   if test "$HAVE_GIF" = yes; then
2425     LIBGIF=-lgif
2426   elif test "$HAVE_GIF" = maybe; then
2427 # If gif_lib.h but no libgif, try libungif.
2428     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2429     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2430   fi
2431
2432   if test "${HAVE_GIF}" = "yes"; then
2433     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2434   fi
2435 fi
2436 AC_SUBST(LIBGIF)
2437
2438 dnl Check for required libraries.
2439 if test "${HAVE_X11}" = "yes"; then
2440   MISSING=""
2441   WITH_NO=""
2442   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2443     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2444   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2445     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2446   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2447     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2448   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2449     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2450   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2451     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2452
2453   if test "X${MISSING}" != X; then
2454     AC_MSG_ERROR([The following required libraries were not found:
2455     $MISSING
2456 Maybe some development libraries/packages are missing?
2457 If you don't want to link with them give
2458     $WITH_NO
2459 as options to configure])
2460   fi
2461 fi
2462
2463 ### Use -lgpm if available, unless `--with-gpm=no'.
2464 HAVE_GPM=no
2465 LIBGPM=
2466 MOUSE_SUPPORT=
2467 if test "${with_gpm}" != "no"; then
2468   AC_CHECK_HEADER(gpm.h,
2469     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2470
2471   if test "${HAVE_GPM}" = "yes"; then
2472     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2473     LIBGPM=-lgpm
2474     ## May be reset below.
2475     MOUSE_SUPPORT="\$(GPM_MOUSE_SUPPORT)"
2476   fi
2477 fi
2478 AC_SUBST(LIBGPM)
2479
2480 dnl Check for malloc/malloc.h on darwin
2481 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2482
2483 C_SWITCH_X_SYSTEM=
2484 ### Use NeXTstep API to implement GUI.
2485 if test "${HAVE_NS}" = "yes"; then
2486   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2487   if test "${NS_IMPL_COCOA}" = "yes"; then
2488     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2489     GNU_OBJC_CFLAGS=
2490   fi
2491   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2492     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2493     # See also .m.o rule in Makefile.in */
2494     # FIXME: are all these flags really needed?  Document here why.  */
2495     C_SWITCH_X_SYSTEM="-D_REENTRANT -fPIC -fno-strict-aliasing"
2496     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2497   fi
2498   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2499     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2500   fi
2501   # We also have mouse menus.
2502   HAVE_MENUS=yes
2503   OTHER_FILES=ns-app
2504 fi
2505
2506
2507 ### Use session management (-lSM -lICE) if available
2508 HAVE_X_SM=no
2509 LIBXSM=
2510 if test "${HAVE_X11}" = "yes"; then
2511   AC_CHECK_HEADER(X11/SM/SMlib.h,
2512     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2513
2514   if test "${HAVE_X_SM}" = "yes"; then
2515     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2516     LIBXSM="-lSM -lICE"
2517     case "$LIBS" in
2518       *-lSM*) ;;
2519       *)      LIBS="$LIBXSM $LIBS" ;;
2520     esac
2521   fi
2522 fi
2523 AC_SUBST(LIBXSM)
2524
2525 ### Use libxml (-lxml2) if available
2526 if test "${with_xml2}" != "no"; then
2527   ### I'm not sure what the version number should be, so I just guessed.
2528   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2529   if test "${HAVE_LIBXML2}" = "yes"; then
2530     LIBS="$LIBXML2_LIBS $LIBS"
2531     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2532     if test "${HAVE_LIBXML2}" = "yes"; then
2533       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2534     else
2535       LIBXML2_LIBS=""
2536       LIBXML2_CFLAGS=""
2537     fi
2538   fi
2539 fi
2540 AC_SUBST(LIBXML2_LIBS)
2541 AC_SUBST(LIBXML2_CFLAGS)
2542
2543 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2544 AC_CACHE_CHECK(whether netdb declares h_errno,
2545                emacs_cv_netdb_declares_h_errno,
2546 [AC_TRY_LINK([#include <netdb.h>],
2547   [return h_errno;],
2548   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2549 if test $emacs_cv_netdb_declares_h_errno = yes; then
2550   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2551 fi
2552
2553 AC_FUNC_ALLOCA
2554
2555 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2556 dnl FIXME is there an autoconf test that does the right thing, without
2557 dnl needing to call A_M_E afterwards?
2558 if test x"$ac_cv_func_alloca_works" != xyes; then
2559    AC_MSG_ERROR( [a system implementation of alloca is required] )
2560 fi
2561
2562 # fmod, logb, and frexp are found in -lm on most systems.
2563 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2564 AC_CHECK_LIB(m, sqrt)
2565
2566 # Check for mail-locking functions in a "mail" library.  Probably this should
2567 # have the same check as for liblockfile below.
2568 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2569 if test $have_mail = yes; then
2570   LIBS_MAIL=-lmail
2571   LIBS="$LIBS_MAIL $LIBS"
2572   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2573 else
2574   LIBS_MAIL=
2575 fi
2576 dnl Debian, at least:
2577 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2578 if test $have_lockfile = yes; then
2579    LIBS_MAIL=-llockfile
2580    LIBS="$LIBS_MAIL $LIBS"
2581    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2582 else
2583 # If we have the shared liblockfile, assume we must use it for mail
2584 # locking (e.g. Debian).  If we couldn't link against liblockfile
2585 # (no liblockfile.a installed), ensure that we don't need to.
2586   dnl This works for files generally, not just executables.
2587   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2588   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2589                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2590   if test $ac_cv_prog_liblockfile = yes; then
2591     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2592 This probably means that movemail could lose mail.
2593 There may be a `development' package to install containing liblockfile.])
2594   fi
2595 fi
2596 AC_CHECK_FUNCS(touchlock)
2597 AC_CHECK_HEADERS(maillock.h)
2598 AC_SUBST(LIBS_MAIL)
2599
2600 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2601 ## interlock access to the mail spool.  The alternative is a lock file named
2602 ## /usr/spool/mail/$USER.lock.
2603 mail_lock=no
2604 case "$opsys" in
2605   aix4-2) mail_lock="lockf" ;;
2606
2607   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2608
2609   ## On GNU/Linux systems, both methods are used by various mail programs.
2610   ## I assume most people are using newer mailers that have heard of flock.
2611   ## Change this if you need to.
2612   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2613   ## configure gets the right answers, and that means *NOT* using flock.
2614   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2615   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2616   ## Debian maintainer hasn't provided a clean fix for Emacs.
2617   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2618   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2619   ## correct logic.  -- fx
2620   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2621   ## liblockfile is a Free Software replacement for libmail, used on
2622   ## Debian systems and elsewhere. -rfr.
2623   gnu-*)
2624     mail_lock="flock"
2625     if test $have_mail = yes || test $have_lockfile = yes; then
2626       test $ac_cv_header_maillock_h = yes && mail_lock=no
2627     fi
2628     ;;
2629 esac
2630
2631 BLESSMAIL_TARGET=
2632 case "$mail_lock" in
2633   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2634
2635   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2636
2637   *) BLESSMAIL_TARGET="need-blessmail" ;;
2638 esac
2639 AC_SUBST(BLESSMAIL_TARGET)
2640
2641
2642 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2643 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2644 random lrand48 logb frexp fmod rint cbrt ftime setsid \
2645 strerror fpathconf select euidaccess getpagesize tzset setlocale \
2646 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2647 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm strchr strrchr \
2648 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2649 gai_strerror mkstemp getline getdelim mremap memmove fsync sync \
2650 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2651 cfmakeraw cfsetspeed isnan copysign __executable_start)
2652
2653 dnl Cannot use AC_CHECK_FUNCS
2654 AC_CACHE_CHECK([for __builtin_unwind_init],
2655                emacs_cv_func___builtin_unwind_init,
2656 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2657                 emacs_cv_func___builtin_unwind_init=yes,
2658                 emacs_cv_func___builtin_unwind_init=no)])
2659 if test $emacs_cv_func___builtin_unwind_init = yes; then
2660   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2661             [Define to 1 if you have the `__builtin_unwind_init' function.])
2662 fi
2663
2664 AC_CHECK_HEADERS(sys/un.h)
2665
2666 AC_FUNC_GETLOADAVG
2667
2668 AC_FUNC_FSEEKO
2669
2670 AC_FUNC_GETPGRP
2671
2672 # Configure gnulib.
2673 gl_ASSERT_NO_GNULIB_POSIXCHECK
2674 gl_ASSERT_NO_GNULIB_TESTS
2675 gl_INIT
2676
2677 AC_FUNC_STRFTIME
2678
2679 # UNIX98 PTYs.
2680 AC_CHECK_FUNCS(grantpt)
2681
2682 # PTY-related GNU extensions.
2683 AC_CHECK_FUNCS(getpt)
2684
2685 # Check this now, so that we will NOT find the above functions in ncurses.
2686 # That is because we have not set up to link ncurses in lib-src.
2687 # It's better to believe a function is not available
2688 # than to expect to find it in ncurses.
2689 # Also we need tputs and friends to be able to build at all.
2690 have_tputs_et_al=true
2691 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2692 if test "$have_tputs_et_al" != true; then
2693   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2694 Maybe some development libraries/packages are missing?  Try installing
2695 libncurses-dev(el), libterminfo-dev(el) or similar.])
2696 fi
2697 # Must define this when any termcap library is found.
2698 AC_DEFINE(HAVE_LIBNCURSES, 1,
2699           [Define to 1 if you have the `ncurses' library (-lncurses).])
2700 ## FIXME This was the cpp logic, but I am not sure it is right.
2701 ## The above test has not necessarily found libncurses.
2702 HAVE_LIBNCURSES=yes
2703
2704 ## Use terminfo instead of termcap?
2705 ## Note only system files NOT using terminfo are:
2706 ## freebsd < 40000, ms-w32, msdos, netbsd < 599002500, and
2707 ## darwin|gnu without ncurses.
2708 TERMINFO=no
2709 LIBS_TERMCAP=
2710 case "$opsys" in
2711   ## cygwin: Fewer environment variables to go wrong, more terminal types.
2712   ## hpux10-20: Use the system provided termcap(3) library.
2713   ## openbsd: David Mazieres <dm@reeducation-labor.lcs.mit.edu> says this
2714   ##  is necessary.  Otherwise Emacs dumps core when run -nw.
2715   aix4-2|cygwin|hpux*|irix6-5|openbsd|sol2*|unixware) TERMINFO=yes ;;
2716
2717   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2718   ##  The ncurses library has been moved out of the System framework in
2719   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2720   ##  option to use it.
2721   darwin|gnu*)
2722     ## (HAVE_LIBNCURSES was not always true, but is since 2010-03-18.)
2723     if test "x$HAVE_LIBNCURSES" = "xyes"; then
2724       TERMINFO=yes
2725       LIBS_TERMCAP="-lncurses"
2726     fi
2727     ;;
2728
2729   freebsd)
2730     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2731     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2732     [AC_TRY_LINK([#include <osreldate.h>],
2733 [#if __FreeBSD_version < 400000
2734 fail;
2735 #endif
2736 ], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2737
2738     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2739
2740     if test $emacs_cv_freebsd_terminfo = yes; then
2741       TERMINFO=yes
2742       LIBS_TERMCAP="-lncurses"
2743     else
2744       LIBS_TERMCAP="-ltermcap"
2745     fi
2746     ;;
2747
2748   netbsd)
2749     if test $ac_cv_search_tputs = -lterminfo; then
2750       TERMINFO=yes
2751       LIBS_TERMCAP="-lterminfo"
2752     else
2753       LIBS_TERMCAP="-ltermcap"
2754     fi
2755     ;;
2756
2757 esac
2758
2759 case "$opsys" in
2760   ## hpux: Make sure we get select from libc rather than from libcurses
2761   ##  because libcurses on HPUX 10.10 has a broken version of select.
2762   ##  We used to use -lc -lcurses, but this may be cleaner.
2763   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2764
2765   openbsd) LIBS_TERMCAP="-lncurses" ;;
2766
2767   ## Must use system termcap, if we use any termcap.  It does special things.
2768   sol2*) test "$TERMINFO" != yes && LIBS_TERMCAP="-ltermcap" ;;
2769 esac
2770
2771 TERMCAP_OBJ=tparam.o
2772 if test $TERMINFO = yes; then
2773   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2774
2775   ## Default used to be -ltermcap.  Add a case above if need something else.
2776   test "x$LIBS_TERMCAP" = "x" && LIBS_TERMCAP="-lcurses"
2777
2778   TERMCAP_OBJ=terminfo.o
2779 fi
2780 AC_SUBST(LIBS_TERMCAP)
2781 AC_SUBST(TERMCAP_OBJ)
2782
2783
2784 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2785 resolv=no
2786 AC_TRY_LINK([#include <netinet/in.h>
2787 #include <arpa/nameser.h>
2788 #include <resolv.h>],
2789     [return res_init();],
2790     have_res_init=yes, have_res_init=no)
2791 if test "$have_res_init" = no; then
2792   OLIBS="$LIBS"
2793   LIBS="$LIBS -lresolv"
2794   AC_MSG_CHECKING(for res_init with -lresolv)
2795   AC_TRY_LINK([#include <netinet/in.h>
2796 #include <arpa/nameser.h>
2797 #include <resolv.h>],
2798     [return res_init();],
2799     have_res_init=yes, have_res_init=no)
2800   AC_MSG_RESULT($have_res_init)
2801   if test "$have_res_init" = yes ; then
2802     resolv=yes
2803   fi
2804   LIBS="$OLIBS"
2805 fi
2806
2807 if test "$have_res_init" = yes; then
2808   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2809 fi
2810
2811 # Do we need the Hesiod library to provide the support routines?
2812 LIBHESIOD=
2813 if test "$with_hesiod" != no ; then
2814   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2815   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2816      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2817                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2818   if test "$resolv" = yes ; then
2819     RESOLVLIB=-lresolv
2820   else
2821     RESOLVLIB=
2822   fi
2823   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2824         hesiod=yes, :, $RESOLVLIB)])
2825
2826   if test x"$hesiod" = xyes; then
2827     AC_DEFINE(HAVE_LIBHESIOD, 1,
2828               [Define to 1 if you have the hesiod library (-lhesiod).])
2829     LIBHESIOD=-lhesiod
2830   fi
2831 fi
2832 AC_SUBST(LIBHESIOD)
2833
2834 # Do we need libresolv (due to res_init or Hesiod)?
2835 if test "$resolv" = yes ; then
2836   AC_DEFINE(HAVE_LIBRESOLV, 1,
2837             [Define to 1 if you have the resolv library (-lresolv).])
2838   LIBRESOLV=-lresolv
2839 else
2840   LIBRESOLV=
2841 fi
2842 AC_SUBST(LIBRESOLV)
2843
2844 # These tell us which Kerberos-related libraries to use.
2845 COM_ERRLIB=
2846 CRYPTOLIB=
2847 KRB5LIB=
2848 DESLIB=
2849 KRB4LIB=
2850
2851 if test "${with_kerberos}" != no; then
2852   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2853   if test $have_com_err = yes; then
2854     COM_ERRLIB=-lcom_err
2855     LIBS="$COM_ERRLIB $LIBS"
2856     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2857   fi
2858   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2859   if test $have_crypto = yes; then
2860     CRYPTOLIB=-lcrypto
2861     LIBS="$CRYPTOLIB $LIBS"
2862     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2863   fi
2864   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2865   if test $have_k5crypto = yes; then
2866     CRYPTOLIB=-lk5crypto
2867     LIBS="$CRYPTOLIB $LIBS"
2868     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2869   fi
2870   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2871   if test $have_krb5=yes; then
2872     KRB5LIB=-lkrb5
2873     LIBS="$KRB5LIB $LIBS"
2874     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2875   fi
2876   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2877   if test "${with_kerberos5}" = no; then
2878     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2879     if test $have_des425 = yes; then
2880       DESLIB=-ldes425
2881       LIBS="$DESLIB $LIBS"
2882       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2883     else
2884       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2885       if test $have_des = yes; then
2886         DESLIB=-ldes
2887         LIBS="$DESLIB $LIBS"
2888         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2889       fi
2890     fi
2891     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2892     if test $have_krb4 = yes; then
2893       KRB4LIB=-lkrb4
2894       LIBS="$KRB4LIB $LIBS"
2895       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2896     else
2897       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2898       if test $have_krb = yes; then
2899         KRB4LIB=-lkrb
2900         LIBS="$KRB4LIB $LIBS"
2901         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2902       fi
2903     fi
2904   fi
2905
2906   if test "${with_kerberos5}" != no; then
2907     AC_CHECK_HEADERS(krb5.h,
2908       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2909                         [#include <krb5.h>])])
2910   else
2911     AC_CHECK_HEADERS(des.h,,
2912                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2913                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2914     AC_CHECK_HEADERS(krb.h,,
2915                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2916                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2917   fi
2918   AC_CHECK_HEADERS(com_err.h)
2919 fi
2920
2921 AC_SUBST(COM_ERRLIB)
2922 AC_SUBST(CRYPTOLIB)
2923 AC_SUBST(KRB5LIB)
2924 AC_SUBST(DESLIB)
2925 AC_SUBST(KRB4LIB)
2926
2927 # Solaris requires -lintl if you want strerror (which calls dgettext)
2928 # to return localized messages.
2929 AC_CHECK_LIB(intl, dgettext)
2930
2931 AC_MSG_CHECKING(whether localtime caches TZ)
2932 AC_CACHE_VAL(emacs_cv_localtime_cache,
2933 [if test x$ac_cv_func_tzset = xyes; then
2934 AC_TRY_RUN([#include <time.h>
2935 char TZ_GMT0[] = "TZ=GMT0";
2936 char TZ_PST8[] = "TZ=PST8";
2937 main()
2938 {
2939   time_t now = time ((time_t *) 0);
2940   int hour_GMT0, hour_unset;
2941   if (putenv (TZ_GMT0) != 0)
2942     exit (1);
2943   hour_GMT0 = localtime (&now)->tm_hour;
2944   unsetenv("TZ");
2945   hour_unset = localtime (&now)->tm_hour;
2946   if (putenv (TZ_PST8) != 0)
2947     exit (1);
2948   if (localtime (&now)->tm_hour == hour_GMT0)
2949     exit (1);
2950   unsetenv("TZ");
2951   if (localtime (&now)->tm_hour != hour_unset)
2952     exit (1);
2953   exit (0);
2954 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2955 [# If we have tzset, assume the worst when cross-compiling.
2956 emacs_cv_localtime_cache=yes])
2957 else
2958         # If we lack tzset, report that localtime does not cache TZ,
2959         # since we can't invalidate the cache if we don't have tzset.
2960         emacs_cv_localtime_cache=no
2961 fi])dnl
2962 AC_MSG_RESULT($emacs_cv_localtime_cache)
2963 if test $emacs_cv_localtime_cache = yes; then
2964   AC_DEFINE(LOCALTIME_CACHE, 1,
2965             [Define to 1 if localtime caches TZ.])
2966 fi
2967
2968 if test "x$HAVE_TIMEVAL" = xyes; then
2969   AC_CHECK_FUNCS(gettimeofday)
2970   if test $ac_cv_func_gettimeofday = yes; then
2971     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2972                    emacs_cv_gettimeofday_two_arguments,
2973     [AC_TRY_COMPILE([
2974 #ifdef TIME_WITH_SYS_TIME
2975 #include <sys/time.h>
2976 #include <time.h>
2977 #else
2978 #ifdef HAVE_SYS_TIME_H
2979 #include <sys/time.h>
2980 #else
2981 #include <time.h>
2982 #endif
2983 #endif],
2984       [struct timeval time;
2985        gettimeofday (&time, 0);],
2986       emacs_cv_gettimeofday_two_arguments=yes,
2987       emacs_cv_gettimeofday_two_arguments=no)])
2988     if test $emacs_cv_gettimeofday_two_arguments = no; then
2989       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2990                 [Define to 1 if gettimeofday accepts only one argument.])
2991     fi
2992   fi
2993 fi
2994
2995 ok_so_far=yes
2996 AC_CHECK_FUNC(socket, , ok_so_far=no)
2997 if test $ok_so_far = yes; then
2998   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2999 fi
3000 if test $ok_so_far = yes; then
3001   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3002 fi
3003 if test $ok_so_far = yes; then
3004 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3005   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3006             [Define to 1 if you have inet sockets.])
3007 fi
3008
3009 if test -f /usr/lpp/X11/bin/smt.exp; then
3010   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3011             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3012 fi
3013
3014 AC_MSG_CHECKING(whether system supports dynamic ptys)
3015 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3016   AC_MSG_RESULT(yes)
3017   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3018 else
3019   AC_MSG_RESULT(no)
3020 fi
3021
3022 AC_FUNC_FORK
3023
3024 dnl Adapted from Haible's version.
3025 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3026   [AC_TRY_LINK([#include <langinfo.h>],
3027     [char* cs = nl_langinfo(CODESET);],
3028     emacs_cv_langinfo_codeset=yes,
3029     emacs_cv_langinfo_codeset=no)
3030   ])
3031 if test $emacs_cv_langinfo_codeset = yes; then
3032   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3033     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3034 fi
3035
3036 AC_CHECK_TYPES(size_t)
3037
3038 AC_TYPE_MBSTATE_T
3039
3040 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3041   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
3042                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3043 if test "$emacs_cv_c_restrict_arr" = yes; then
3044   AC_DEFINE(__restrict_arr, __restrict,
3045     [Define to compiler's equivalent of C99 restrict keyword in array
3046      declarations.  Define as empty for no equivalent.])
3047 fi
3048
3049 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3050 dnl how the tty code is related to POSIX and/or other versions of termios.
3051 dnl The following looks like a useful start.
3052 dnl
3053 dnl AC_SYS_POSIX_TERMIOS
3054 dnl if test $ac_cv_sys_posix_termios = yes; then
3055 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3056 dnl                                and macros for terminal control.])
3057 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3058 dnl fi
3059
3060 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
3061
3062 # Set up the CFLAGS for real compilation, so we can substitute it.
3063 CFLAGS="$REAL_CFLAGS"
3064 CPPFLAGS="$REAL_CPPFLAGS"
3065
3066 ## Hack to detect a buggy GCC version.
3067 if test "x$GCC" = xyes \
3068    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3069    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3070    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3071    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3072 fi
3073
3074 #### Find out which version of Emacs this is.
3075 [version=`grep 'const char emacs_version' ${srcdir}/src/emacs.c \
3076          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
3077 if test x"${version}" = x; then
3078   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/src/emacs.c'.])
3079 fi
3080 if test x"${version}" != x"$PACKAGE_VERSION"; then
3081   AC_MSG_WARN([version mismatch between `${srcdir}/configure.in' and `${srcdir}/src/emacs.c'.])
3082 fi
3083
3084 ### Specify what sort of things we'll be editing into Makefile and config.h.
3085 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3086 AC_SUBST(version)
3087 AC_SUBST(configuration)
3088 ## Unused?
3089 AC_SUBST(canonical)
3090 AC_SUBST(srcdir)
3091 AC_SUBST(prefix)
3092 AC_SUBST(exec_prefix)
3093 AC_SUBST(bindir)
3094 AC_SUBST(datadir)
3095 AC_SUBST(sharedstatedir)
3096 AC_SUBST(libexecdir)
3097 AC_SUBST(mandir)
3098 AC_SUBST(infodir)
3099 AC_SUBST(lispdir)
3100 AC_SUBST(locallisppath)
3101 AC_SUBST(lisppath)
3102 AC_SUBST(x_default_search_path)
3103 AC_SUBST(etcdir)
3104 AC_SUBST(archlibdir)
3105 AC_SUBST(docdir)
3106 AC_SUBST(bitmapdir)
3107 AC_SUBST(gamedir)
3108 AC_SUBST(gameuser)
3109 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3110 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3111 ## end of LIBX_BASE, but nothing ever set it.
3112 AC_SUBST(LD_SWITCH_X_SITE)
3113 AC_SUBST(C_SWITCH_X_SITE)
3114 AC_SUBST(C_SWITCH_X_SYSTEM)
3115 AC_SUBST(CFLAGS)
3116 ## Used in lwlib/Makefile.in.
3117 AC_SUBST(X_TOOLKIT_TYPE)
3118 if test -n "${machfile}"; then
3119   M_FILE="\$(srcdir)/${machfile}"
3120 else
3121   M_FILE=
3122 fi
3123 S_FILE="\$(srcdir)/${opsysfile}"
3124 AC_SUBST(M_FILE)
3125 AC_SUBST(S_FILE)
3126 AC_SUBST(GETLOADAVG_LIBS)
3127 AC_SUBST(ns_appdir)
3128 AC_SUBST(ns_appbindir)
3129 AC_SUBST(ns_appresdir)
3130 AC_SUBST(ns_appsrc)
3131 AC_SUBST(GNU_OBJC_CFLAGS)
3132 AC_SUBST(OTHER_FILES)
3133
3134 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3135                    [Define to the canonical Emacs configuration name.])
3136 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3137                    [Define to the options passed to configure.])
3138 if test -n "$machfile"; then
3139   AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3140                      [Define to the used machine dependent file.])
3141 fi
3142 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3143                    [Define to the used os dependent file.])
3144
3145 XMENU_OBJ=
3146 XOBJ=
3147 FONT_OBJ=
3148 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3149   AC_DEFINE(HAVE_X_WINDOWS, 1,
3150             [Define to 1 if you want to use the X window system.])
3151   XMENU_OBJ=xmenu.o
3152   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3153   FONT_OBJ=xfont.o
3154   if test "$HAVE_XFT" = "yes"; then
3155     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3156   elif test "$HAVE_FREETYPE" = "yes"; then
3157     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3158   fi
3159   AC_SUBST(FONT_OBJ)
3160 fi
3161 AC_SUBST(XMENU_OBJ)
3162 AC_SUBST(XOBJ)
3163 AC_SUBST(FONT_OBJ)
3164
3165 WIDGET_OBJ=
3166 MOTIF_LIBW=
3167 if test "${USE_X_TOOLKIT}" != "none" ; then
3168   WIDGET_OBJ=widget.o
3169   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3170   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3171     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3172   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3173     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3174     MOTIF_LIBW=-lXm
3175     case "$opsys" in
3176       gnu-linux)
3177         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3178         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3179         ;;
3180
3181       unixware)
3182         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3183         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3184         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3185         ;;
3186
3187       aix4-2)
3188         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3189         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3190         ;;
3191     esac
3192     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3193   fi
3194 fi
3195 AC_SUBST(WIDGET_OBJ)
3196
3197 TOOLKIT_LIBW=
3198 case "$USE_X_TOOLKIT" in
3199   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3200   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3201   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3202 esac
3203 AC_SUBST(TOOLKIT_LIBW)
3204
3205 if test "$USE_X_TOOLKIT" = "none"; then
3206   LIBXT_OTHER="\$(LIBXSM)"
3207   OLDXMENU_TARGET="really-oldXMenu"
3208 else
3209   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3210   OLDXMENU_TARGET="really-lwlib"
3211 fi
3212 AC_SUBST(LIBXT_OTHER)
3213
3214 ## The X Menu stuff is present in the X10 distribution, but missing
3215 ## from X11.  If we have X10, just use the installed library;
3216 ## otherwise, use our own copy.
3217 if test "${HAVE_X11}" = "yes" ; then
3218   AC_DEFINE(HAVE_X11, 1,
3219             [Define to 1 if you want to use version 11 of X windows.
3220              Otherwise, Emacs expects to use version 10.])
3221
3222   if test "$USE_X_TOOLKIT" = "none"; then
3223     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
3224   else
3225     OLDXMENU="\${lwlibdir}/liblw.a"
3226   fi
3227   LIBXMENU="\$(OLDXMENU)"
3228   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3229   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3230 else
3231   ## For a syntactically valid Makefile; not actually used for anything.
3232   ## See comments in src/Makefile.in.
3233   OLDXMENU=nothing
3234   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3235   if test "${HAVE_X_WINDOWS}" = "yes"; then
3236     LIBXMENU="-lXMenu"
3237   else
3238     LIBXMENU=
3239   fi
3240   LIBX_OTHER=
3241   OLDXMENU_DEPS=
3242 fi
3243
3244 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3245   OLDXMENU_TARGET=
3246   OLDXMENU=nothing
3247   LIBXMENU=
3248   OLDXMENU_DEPS=
3249 fi
3250
3251 AC_SUBST(OLDXMENU_TARGET)
3252 AC_SUBST(OLDXMENU)
3253 AC_SUBST(LIBXMENU)
3254 AC_SUBST(LIBX_OTHER)
3255 AC_SUBST(OLDXMENU_DEPS)
3256
3257 if test "${HAVE_MENUS}" = "yes" ; then
3258   AC_DEFINE(HAVE_MENUS, 1,
3259             [Define to 1 if you have mouse menus.
3260              (This is automatic if you use X, but the option to specify it remains.)
3261              It is also defined with other window systems that support xmenu.c.])
3262 fi
3263
3264 if test "${GNU_MALLOC}" = "yes" ; then
3265   AC_DEFINE(GNU_MALLOC, 1,
3266             [Define to 1 if you want to use the GNU memory allocator.])
3267 fi
3268
3269 RALLOC_OBJ=
3270 if test "${REL_ALLOC}" = "yes" ; then
3271   AC_DEFINE(REL_ALLOC, 1,
3272             [Define REL_ALLOC if you want to use the relocating allocator for
3273              buffer space.])
3274
3275   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3276 fi
3277 AC_SUBST(RALLOC_OBJ)
3278
3279 if test "$opsys" = "cygwin"; then
3280   CYGWIN_OBJ="sheap.o"
3281   ## Cygwin differs because of its unexec().
3282   PRE_ALLOC_OBJ=
3283   POST_ALLOC_OBJ=lastfile.o
3284 else
3285   CYGWIN_OBJ=
3286   PRE_ALLOC_OBJ=lastfile.o
3287   POST_ALLOC_OBJ=
3288 fi
3289 AC_SUBST(CYGWIN_OBJ)
3290 AC_SUBST(PRE_ALLOC_OBJ)
3291 AC_SUBST(POST_ALLOC_OBJ)
3292
3293
3294 case "$opsys" in
3295   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3296
3297   darwin)
3298    ## The -headerpad option tells ld (see man page) to leave room at the
3299    ## end of the header for adding load commands.  Needed for dumping.
3300    ## 0x690 is the total size of 30 segment load commands (at 56
3301    ## each); under Cocoa 31 commands are required.
3302    if test "$HAVE_NS" = "yes"; then
3303      libs_nsgui="-framework AppKit"
3304      headerpad_extra=6C8
3305    else
3306      libs_nsgui=
3307      headerpad_extra=690
3308    fi
3309    LD_SWITCH_SYSTEM_TEMACS="-prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3310
3311    ## This is here because src/Makefile.in did some extra fiddling around
3312    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3313    ##   #ifndef LD_SWITCH_SYSTEM
3314    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3315    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3316    ## not using gcc, darwin system not on an alpha (ie darwin, since
3317    ## darwin + alpha does not occur).
3318    ## Because this was done in src/Makefile.in, the resulting part of
3319    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3320    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3321    ## rather than LD_SWITCH_SYSTEM.
3322    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3323      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3324    ;;
3325
3326   ## LD_SWITCH_X_SITE_AUX is a -R option saying where to find X at run-time.
3327   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at
3328   ## the point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_AUX
3329   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3330   ## had different values in configure (in ac_link) and src/Makefile.in.
3331   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3332   gnu-linux) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_AUX)" ;;
3333
3334   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3335 esac
3336
3337 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3338   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3339 fi
3340
3341 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3342
3343
3344 LD_FIRSTFLAG=
3345 ORDINARY_LINK=
3346 case "$opsys" in
3347   ## gnu: GNU needs its own crt0.
3348   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3349
3350   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3351   ## library search parth, i.e. it won't search /usr/lib for libc and
3352   ## friends.  Using -nostartfiles instead avoids this problem, and
3353   ## will also work on earlier NetBSD releases.
3354   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
3355
3356   ## macpcc: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3357   ##   MkLinux/LinuxPPC needs this.
3358   ## ibms390x only supports opsys = gnu-linux so it can be added here.
3359   gnu-*)
3360     case "$machine" in
3361       macppc|ibms390x) LD_FIRSTFLAG="-nostdlib" ;;
3362     esac
3363     ;;
3364 esac
3365
3366
3367 if test "x$ORDINARY_LINK" = "xyes"; then
3368
3369   LD_FIRSTFLAG=""
3370   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3371
3372 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
3373 ## freebsd, gnu-* not on macppc|ibms390x.
3374 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
3375
3376   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3377   ## places that are difficult to figure out at make time.  Fortunately,
3378   ## these same versions allow you to pass arbitrary flags on to the
3379   ## linker, so there is no reason not to use it as a linker.
3380   ##
3381   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3382   ## searching for libraries in its internal directories, so we have to
3383   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3384   LD_FIRSTFLAG="-nostdlib"
3385 fi
3386
3387 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3388 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
3389
3390 AC_SUBST(LD_FIRSTFLAG)
3391
3392
3393 ## FIXME? The logic here is not precisely the same as that above.
3394 ## There is no check here for a pre-defined LD_FIRSTFLAG.
3395 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3396 LIB_GCC=
3397 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3398
3399   case "$opsys" in
3400     freebsd|netbsd|openbsd) LIB_GCC= ;;
3401
3402     gnu-*)
3403       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3404       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3405       case $host_cpu in
3406       arm*)
3407         LIB_GCC="-lgcc_s"
3408         ;;
3409       *)
3410         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3411         ## immediately undefine it again and redefine it to empty.
3412         ## Was the C_SWITCH_X_SITE part really necessary?
3413 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3414         LIB_GCC=
3415         ;;
3416       esac
3417       ;;
3418
3419     ## Ask GCC where to find libgcc.a.
3420     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3421   esac
3422 fi                              dnl if $GCC
3423 AC_SUBST(LIB_GCC)
3424
3425
3426 TOOLTIP_SUPPORT=
3427 WINDOW_SUPPORT=
3428 ## If we're using X11/GNUstep, define some consequences.
3429 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3430   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3431   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3432   MOUSE_SUPPORT="\$(REAL_MOUSE_SUPPORT)"
3433   TOOLTIP_SUPPORT="\${lispsource}/mouse.elc"
3434
3435   WINDOW_SUPPORT="\$(BASE_WINDOW_SUPPORT)"
3436   test "$HAVE_X_WINDOWS" = "yes" && \
3437     WINDOW_SUPPORT="$WINDOW_SUPPORT \$(X_WINDOW_SUPPORT)"
3438
3439 fi
3440 AC_SUBST(MOUSE_SUPPORT)
3441 AC_SUBST(TOOLTIP_SUPPORT)
3442 AC_SUBST(WINDOW_SUPPORT)
3443
3444
3445 AH_TOP([/* GNU Emacs site configuration template file.
3446    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
3447      2006, 2007, 2008, 2009, 2010, 2011  Free Software Foundation, Inc.
3448
3449 This file is part of GNU Emacs.
3450
3451 GNU Emacs is free software: you can redistribute it and/or modify
3452 it under the terms of the GNU General Public License as published by
3453 the Free Software Foundation, either version 3 of the License, or
3454 (at your option) any later version.
3455
3456 GNU Emacs is distributed in the hope that it will be useful,
3457 but WITHOUT ANY WARRANTY; without even the implied warranty of
3458 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3459 GNU General Public License for more details.
3460
3461 You should have received a copy of the GNU General Public License
3462 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3463
3464
3465 /* No code in Emacs #includes config.h twice, but some bits of code
3466    intended to work with other packages as well (like gmalloc.c)
3467    think they can include it as many times as they like.  */
3468 #ifndef EMACS_CONFIG_H
3469 #define EMACS_CONFIG_H
3470 ])dnl
3471
3472 AH_BOTTOM([
3473 /* Define AMPERSAND_FULL_NAME if you use the convention
3474    that & in the full name stands for the login id.  */
3475 /* Turned on June 1996 supposing nobody will mind it.  */
3476 #define AMPERSAND_FULL_NAME
3477
3478 /* If using GNU, then support inline function declarations.  */
3479 /* Don't try to switch on inline handling as detected by AC_C_INLINE
3480    generally, because even if non-gcc compilers accept `inline', they
3481    may reject `extern inline'.  */
3482 #if defined (__GNUC__)
3483 #define INLINE __inline__
3484 #else
3485 #define INLINE
3486 #endif
3487
3488 /* `subprocesses' should be defined if you want to
3489    have code for asynchronous subprocesses
3490    (as used in M-x compile and M-x shell).
3491    Only MSDOS does not support this (it overrides
3492    this in its config_opsysfile below).  */
3493
3494 #define subprocesses
3495
3496 /* Include the os and machine dependent files.  */
3497 #include config_opsysfile
3498 #ifdef config_machfile
3499 # include config_machfile
3500 #endif
3501
3502 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3503    SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.
3504   (There is probably a better place to do this, but right now the
3505    Cocoa side does this in s/darwin.h and we cannot parallel this
3506    exactly since GNUstep is multi-OS.  */
3507 #if defined HAVE_NS && defined NS_IMPL_GNUSTEP
3508 #  define SYSTEM_PURESIZE_EXTRA 30000
3509 #endif
3510
3511 /* SIGTYPE is the macro we actually use.  */
3512 #ifndef SIGTYPE
3513 #define SIGTYPE RETSIGTYPE
3514 #endif
3515
3516 #ifdef emacs /* Don't do this for lib-src.  */
3517 /* Tell regex.c to use a type compatible with Emacs.  */
3518 #define RE_TRANSLATE_TYPE Lisp_Object
3519 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3520 #ifdef make_number
3521 /* If make_number is a macro, use it.  */
3522 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3523 #else
3524 /* If make_number is a function, avoid it.  */
3525 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3526 #endif
3527 #endif
3528
3529 #define my_strftime nstrftime   /* for strftime.c */
3530
3531 /* These default definitions are good for almost all machines.
3532    The exceptions override them in m/MACHINE.h.  */
3533
3534 #ifndef BITS_PER_CHAR
3535 #define BITS_PER_CHAR 8
3536 #endif
3537
3538 #ifndef BITS_PER_SHORT
3539 #define BITS_PER_SHORT 16
3540 #endif
3541
3542 /* Note that lisp.h uses this in a preprocessor conditional, so it
3543    would not work to use sizeof.  That being so, we do all of them
3544    without sizeof, for uniformity's sake.  */
3545 #ifndef BITS_PER_INT
3546 #define BITS_PER_INT 32
3547 #endif
3548
3549 #ifndef BITS_PER_LONG
3550 #ifdef _LP64
3551 #define BITS_PER_LONG 64
3552 #else
3553 #define BITS_PER_LONG 32
3554 #endif
3555 #endif
3556
3557 /* Define if the compiler supports function prototypes.  It may do so but
3558    not define __STDC__ (e.g. DEC C by default) or may define it as zero.  */
3559 #undef PROTOTYPES
3560
3561 #include <string.h>
3562 #include <stdlib.h>
3563
3564 #ifdef HAVE_ALLOCA_H
3565 # include <alloca.h>
3566 #elif defined __GNUC__
3567 # define alloca __builtin_alloca
3568 #elif defined _AIX
3569 # define alloca __alloca
3570 #else
3571 # include <stddef.h>
3572 # ifdef  __cplusplus
3573 extern "C"
3574 # endif
3575 void *alloca (size_t);
3576 #endif
3577
3578 #ifndef HAVE_SIZE_T
3579 typedef unsigned size_t;
3580 #endif
3581
3582 #ifndef HAVE_STRCHR
3583 #define strchr(a, b) index (a, b)
3584 #endif
3585
3586 #ifndef HAVE_STRRCHR
3587 #define strrchr(a, b) rindex (a, b)
3588 #endif
3589
3590 #if defined __GNUC__ && (__GNUC__ > 2 \
3591                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3592 #define NO_RETURN       __attribute__ ((__noreturn__))
3593 #else
3594 #define NO_RETURN       /* nothing */
3595 #endif
3596
3597 #if __GNUC__ >= 3  /* On GCC 3.0 we might get a warning.  */
3598 #define NO_INLINE __attribute__((noinline))
3599 #else
3600 #define NO_INLINE
3601 #endif
3602
3603 #if (__GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 1))
3604 #define EXTERNALLY_VISIBLE __attribute__((externally_visible))
3605 #else
3606 #define EXTERNALLY_VISIBLE
3607 #endif
3608
3609 /* Some versions of GNU/Linux define noinline in their headers.  */
3610 #ifdef noinline
3611 #undef noinline
3612 #endif
3613
3614 /* These won't be used automatically yet.  We also need to know, at least,
3615    that the stack is continuous.  */
3616 #ifdef __GNUC__
3617 #  ifndef GC_SETJMP_WORKS
3618   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3619 #    define GC_SETJMP_WORKS 1
3620 #  endif
3621 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3622 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3623 #  endif
3624 #endif
3625
3626 #endif /* EMACS_CONFIG_H */
3627
3628 /*
3629 Local Variables:
3630 mode: c
3631 End:
3632 */
3633 ])dnl
3634
3635 #### Report on what we decided to do.
3636 #### Report GTK as a toolkit, even if it doesn't use Xt.
3637 #### It makes printing result more understandable as using GTK sets
3638 #### toolkit_scroll_bars to yes by default.
3639 if test "${HAVE_GTK}" = "yes"; then
3640   USE_X_TOOLKIT=GTK
3641 fi
3642
3643 and_machfile=
3644 if test -n "$machfile"; then
3645   and_machfile=" and \`${machfile}'"
3646 fi
3647
3648 echo "
3649 Configured for \`${canonical}'.
3650
3651   Where should the build process find the source code?    ${srcdir}
3652   What operating system and machine description files should Emacs use?
3653         \`${opsysfile}'${and_machfile}
3654   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3655   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3656   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3657   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3658   What window system should Emacs use?                    ${window_system}
3659   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3660
3661 if test -n "${x_includes}"; then
3662 echo "  Where do we find X Windows header files?                ${x_includes}"
3663 else
3664 echo "  Where do we find X Windows header files?                Standard dirs"
3665 fi
3666 if test -n "${x_libraries}"; then
3667 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3668 else
3669 echo "  Where do we find X Windows libraries?                   Standard dirs"
3670 fi
3671
3672 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3673 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3674 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3675 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3676 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3677 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3678 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3679 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
3680
3681 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3682 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3683 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3684 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3685 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
3686 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
3687
3688 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3689 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3690 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3691 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3692
3693 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3694 echo
3695
3696 if test $USE_XASSERTS = yes; then
3697    echo "  Compiling with asserts turned on."
3698    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3699 fi
3700
3701 echo
3702
3703 if test "$HAVE_NS" = "yes"; then
3704    echo
3705    echo "You must run \"make install\" in order to test the built application.
3706 The installed application will go to nextstep/Emacs.app and can be
3707 run or moved from there."
3708    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3709       echo "The application will be fully self-contained."
3710     else
3711       echo "The lisp resources for the application will be installed under ${prefix}.
3712 You may need to run \"make install\" with sudo.  The application will fail
3713 to run if these resources are not installed."
3714    fi
3715    echo
3716 fi
3717
3718
3719 # Remove any trailing slashes in these variables.
3720 [test "${prefix}" != NONE &&
3721   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3722 test "${exec_prefix}" != NONE &&
3723   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3724
3725 dnl You might wonder (I did) why epaths.h is generated by running make,
3726 dnl rather than just letting configure generate it from epaths.in.
3727 dnl One reason is that the various paths are not fully expanded (see above);
3728 dnl eg gamedir=${prefix}/var/games/emacs.
3729 dnl Secondly, the GNU Coding standards require that one should be able
3730 dnl to run `make prefix=/some/where/else' and override the values set
3731 dnl by configure.  This also explains the `move-if-change' test and
3732 dnl the use of force in the `epaths-force' rule in Makefile.in.
3733 AC_OUTPUT(Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
3734         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3735         doc/lispref/Makefile src/Makefile \
3736         lwlib/Makefile lisp/Makefile leim/Makefile test/automated/Makefile, [
3737
3738 ### Make the necessary directories, if they don't exist.
3739 for dir in etc lisp ; do
3740   test -d ${dir} || mkdir ${dir}
3741 done
3742
3743 echo creating src/epaths.h
3744 ${MAKE-make} epaths-force
3745
3746 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3747   echo creating src/.gdbinit
3748   echo source $srcdir/src/.gdbinit > src/.gdbinit
3749 fi
3750
3751 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPPFLAGS="$CPPFLAGS"])