code.delx.au - gnu-emacs/blob - configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003,
   7 dnl    2004, 2005, 2006, 2007  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software; you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation; either version 3, or (at your option)
  14 dnl  any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs; see the file COPYING.  If not, write to the
  23 dnl  Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 dnl  Boston, MA 02110-1301, USA.
  25
  26 AC_PREREQ(2.61)dnl
  27 AC_INIT(src/lisp.h)
  28 AC_CONFIG_HEADER(src/config.h:src/config.in)
  29
  30 dnl Support for --program-prefix, --program-suffix and
  31 dnl --program-transform-name options
  32 AC_ARG_PROGRAM
  33
  34 lispdir='${datadir}/emacs/${version}/lisp'
  35 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  36 '${datadir}/emacs/site-lisp'
  37 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  38 etcdir='${datadir}/emacs/${version}/etc'
  39 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  40 docdir='${datadir}/emacs/${version}/etc'
  41 gamedir='${localstatedir}/games/emacs'
  42
  43 gameuser=games
  44
  45 AC_ARG_WITH(gcc,
  46 [  --without-gcc           don't use GCC to compile Emacs if GCC is found])
  47 AC_ARG_WITH(pop,
  48 [  --without-pop           don't support POP mail retrieval with movemail],
  49 [if test "$withval" = yes; then
  50    AC_DEFINE(MAIL_USE_POP)
  51 else :
  52 fi],
  53 AC_DEFINE(MAIL_USE_POP))
  54 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  55 AC_ARG_WITH(kerberos,
  56 [  --with-kerberos         support Kerberos-authenticated POP],
  57 [if test "$withval" = yes; then
  58    AC_DEFINE(KERBEROS)
  59 fi])
  60 AH_TEMPLATE(KERBEROS,
  61             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  62 AC_ARG_WITH(kerberos5,
  63 [  --with-kerberos5        support Kerberos version 5 authenticated POP],
  64 [if test "${with_kerberos5+set}" = set; then
  65   if test "${with_kerberos+set}" != set; then
  66     with_kerberos=yes
  67     AC_DEFINE(KERBEROS)
  68   fi
  69   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  70 fi])
  71 AC_ARG_WITH(hesiod,
  72 [  --with-hesiod           support Hesiod to get the POP server host],
  73 [if test "$withval" = yes; then
  74   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
  75 fi])
  76
  77 AC_ARG_WITH(sound,
  78 [  --without-sound         don't compile with sound support])
  79
  80 dnl This should be the last --with option, because --with-x is
  81 dnl added later on when we find the path of X, and it's best to
  82 dnl keep them together visually.
  83 AC_ARG_WITH(x-toolkit,
  84 [  --with-x-toolkit=KIT    use an X toolkit
  85                               (KIT = yes/lucid/athena/motif/gtk/no)],
  86 [         case "${withval}" in
  87             y | ye | yes )      val=gtk ;;
  88             n | no )            val=no  ;;
  89             l | lu | luc | luci | lucid )       val=lucid ;;
  90             a | at | ath | athe | athen | athena )      val=athena ;;
  91             m | mo | mot | moti | motif )       val=motif ;;
  92             g | gt | gtk  )     val=gtk ;;
  93             * )
  94 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
  95 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
  96 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
  97             ;;
  98           esac
  99           with_x_toolkit=$val
 100 ])
 101 AC_ARG_WITH(xpm,
 102 [  --with-xpm              use -lXpm for displaying XPM images])
 103 AC_ARG_WITH(jpeg,
 104 [  --with-jpeg             use -ljpeg for displaying JPEG images])
 105 AC_ARG_WITH(tiff,
 106 [  --with-tiff             use -ltiff for displaying TIFF images])
 107 AC_ARG_WITH(gif,
 108 [  --with-gif              use -lgif (or -lungif) for displaying GIF images])
 109 AC_ARG_WITH(png,
 110 [  --with-png              use -lpng for displaying PNG images])
 111 AC_ARG_WITH(gpm,
 112 [  --with-gpm              use -lgpm for mouse support on a GNU/Linux console])
 113 AC_ARG_WITH(rsvg,
 114 [  --with-rsvg             use -lrsvg-2 for displaying SVG images])
 115 AC_ARG_WITH(gtk,
 116 [  --with-gtk              use GTK (same as --with-x-toolkit=gtk)])
 117 AC_ARG_WITH(pkg-config-prog,
 118 [  --with-pkg-config-prog  Path to pkg-config to use for finding GTK and librsvg])
 119 AC_ARG_WITH(toolkit-scroll-bars,
 120 [  --without-toolkit-scroll-bars
 121                           don't use Motif or Xaw3d scroll bars])
 122 AC_ARG_WITH(xaw3d,
 123 [  --without-xaw3d         don't use Xaw3d])
 124 AC_ARG_WITH(xim,
 125 [  --without-xim           don't use X11 XIM])
 126 AC_ARG_WITH(carbon,
 127 [  --without-carbon        don't use Carbon GUI on Mac OS X])
 128 AC_ARG_ENABLE(carbon-app,
 129 [[  --enable-carbon-app[=DIR]  [DIR=/Application]
 130                           specify install directory for Emacs.app on Mac OS X]],
 131 [ carbon_appdir_x=${enableval}])
 132
 133 AC_ARG_ENABLE(asserts,
 134 [  --enable-asserts        compile code with asserts enabled],
 135       USE_XASSERTS=$enableval,
 136       USE_XASSERTS=no)
 137
 138 AC_ARG_ENABLE(maintainer-mode,
 139 [  --enable-maintainer-mode enable make rules and dependencies not useful
 140                           (and sometimes confusing) to the casual installer],
 141       USE_MAINTAINER_MODE=$enableval,
 142       USE_MAINTAINER_MODE=no)
 143 if test $USE_MAINTAINER_MODE = yes; then
 144   MAINT=
 145 else
 146   MAINT=#
 147 fi
 148 AC_SUBST(MAINT)
 149
 150 AC_ARG_ENABLE(locallisppath,
 151 [  --enable-locallisppath=PATH
 152                           directories Emacs should search for lisp files
 153                           specific to this site],
 154 if test "${enableval}" = "no"; then
 155   locallisppath=
 156 elif test "${enableval}" != "yes"; then
 157   locallisppath=${enableval}
 158 fi)
 159
 160 #### Make srcdir absolute, if it isn't already.  It's important to
 161 #### avoid running the path through pwd unnecessarily, since pwd can
 162 #### give you automounter prefixes, which can go away.  We do all this
 163 #### so Emacs can find its files when run uninstalled.
 164 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 165 unset CDPATH
 166 case "${srcdir}" in
 167   /* ) ;;
 168   . )
 169     ## We may be able to use the $PWD environment variable to make this
 170     ## absolute.  But sometimes PWD is inaccurate.
 171     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 172     ## but that tested only for a well-formed and valid PWD,
 173     ## it did not object when PWD was well-formed and valid but just wrong.
 174     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 175     then
 176       srcdir="$PWD"
 177     else
 178       srcdir="`(cd ${srcdir}; pwd)`"
 179     fi
 180   ;;
 181   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 182 esac
 183
 184 #### Check if the source directory already has a configured system in it.
 185 if test `pwd` != `(cd ${srcdir} && pwd)` \
 186    && test -f "${srcdir}/src/config.h" ; then
 187   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 188    as a build directory right now; it has been configured in its own
 189    right.  To configure in another directory as well, you MUST
 190    use GNU make.  If you do not have GNU make, then you must
 191    now do `make distclean' in ${srcdir},
 192    and then run $0 again.]])
 193 fi
 194
 195 #### Given the configuration name, set machfile and opsysfile to the
 196 #### names of the m/*.h and s/*.h files we should use.
 197
 198 ### Canonicalize the configuration name.
 199
 200 AC_CANONICAL_HOST
 201 canonical=$host
 202 configuration=${host_alias-${build_alias-$host}}
 203
 204 dnl This used to use changequote, but, apart from `changequote is evil'
 205 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 206 dnl the great gob of text.  Thus it's not processed for possible expansion.
 207 dnl Just make sure the brackets remain balanced.
 208 dnl
 209 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 210 dnl indicated by comments.
 211 dnl quotation begins
 212 [
 213
 214 ### If you add support for a new configuration, add code to this
 215 ### switch statement to recognize your configuration name and select
 216 ### the appropriate operating system and machine description files.
 217
 218 ### You would hope that you could choose an m/*.h file pretty much
 219 ### based on the machine portion of the configuration name, and an s-
 220 ### file based on the operating system portion.  However, it turns out
 221 ### that each m/*.h file is pretty manufacturer-specific - for
 222 ### example, apollo.h, hp9000s300.h, mega68k, news.h, and tad68k are
 223 ### all 68000 machines; mips.h, pmax.h, and news-risc are all MIPS
 224 ### machines.  So we basically have to have a special case for each
 225 ### configuration name.
 226 ###
 227 ### As far as handling version numbers on operating systems is
 228 ### concerned, make sure things will fail in a fixable way.  If
 229 ### /etc/MACHINES doesn't say anything about version numbers, be
 230 ### prepared to handle anything reasonably.  If version numbers
 231 ### matter, be sure /etc/MACHINES says something about it.
 232 ###
 233 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 234 ### "System V Release 4"; he writes, "The old convention encouraged
 235 ### confusion between `system' and `release' levels'."
 236
 237 machine='' opsys='' unported=no
 238 case "${canonical}" in
 239
 240   ## FreeBSD ports
 241   *-*-freebsd* )
 242     opsys=freebsd
 243     case "${canonical}" in
 244       alpha*-*-freebsd*)        machine=alpha ;;
 245       ia64-*-freebsd*)          machine=ia64 ;;
 246       sparc64-*-freebsd*)       machine=sparc ;;
 247       powerpc-*-freebsd*)       machine=macppc ;;
 248       i[3456]86-*-freebsd*)     machine=intel386 ;;
 249       amd64-*-freebsd*|x86_64-*-freebsd*) machine=amdx86-64 ;;
 250     esac
 251   ;;
 252
 253   ## NetBSD ports
 254   *-*-netbsd* )
 255     opsys=netbsd
 256     if test -f /usr/lib/crti.o; then]
 257 dnl The close and open brackets here are because this section is quoted --
 258 dnl see the `changequote' comment above.
 259       AC_DEFINE(HAVE_CRTIN, [], [Define to 1 if you have /usr/lib/crti.o.])
 260 [   fi
 261
 262     case "${canonical}" in
 263       alpha*-*-netbsd*) machine=alpha ;;
 264       i[3456]86-*-netbsd*) machine=intel386 ;;
 265       m68k-*-netbsd*)
 266                         # This is somewhat bogus.
 267                         machine=hp9000s300 ;;
 268       mips-*-netbsd*)   machine=pmax ;;
 269       mipsel-*-netbsd*) machine=pmax ;;
 270       mipseb-*-netbsd*) machine=pmax ;;
 271       ns32k-*-netbsd*)  machine=ns32000 ;;
 272       powerpc-*-netbsd*) machine=macppc ;;
 273       sparc*-*-netbsd*) machine=sparc ;;
 274       vax-*-netbsd*)    machine=vax ;;
 275       arm-*-netbsd*)    machine=arm ;;
 276       x86_64-*-netbsd*) machine=amdx86-64 ;;
 277       hppa-*-netbsd*)   machine=hp800 ;;
 278       shle-*-netbsd*)   machine=sh3el ;;
 279     esac
 280   ;;
 281
 282   ## OpenBSD ports
 283   *-*-openbsd* )
 284     opsys=openbsd
 285     case "${canonical}" in
 286       alpha*-*-openbsd*)        machine=alpha ;;
 287       arm-*-openbsd*)          machine=arm ;;
 288       hppa-*-openbsd*)         machine=hp9000s300 ;;
 289       i386-*-openbsd*)         machine=intel386 ;;
 290       m68k-*-openbsd*)         machine=hp9000s300 ;;
 291       m88k-*-openbsd*)         machine=aviion ;;
 292       mips64-*-openbsd*)       machine=mips64 ;;
 293       powerpc-*-openbsd*)      machine=macppc ;;
 294       sh-*-openbsd*)           machine=sh3el ;;
 295       sparc*-*-openbsd*)       machine=sparc ;;
 296       vax-*-openbsd*)          machine=vax ;;
 297       x86_64-*-openbsd*)       machine=amdx86-64 ;;
 298     esac
 299   ;;
 300
 301   ## LynxOS ports
 302   *-*-lynxos* )
 303     opsys=lynxos
 304     case "${canonical}" in
 305       i[3456]86-*-lynxos*) machine=intel386 ;;
 306       powerpc-*-lynxos*) machine=powerpc ;;
 307     esac
 308   ;;
 309
 310   ## Acorn RISCiX:
 311   arm-acorn-riscix1.1* )
 312     machine=acorn opsys=riscix1-1
 313   ;;
 314   arm-acorn-riscix1.2* | arm-acorn-riscix )
 315     ## This name is riscix12 instead of riscix1.2
 316     ## to avoid a file name conflict on MSDOS.
 317     machine=acorn opsys=riscix12
 318   ;;
 319
 320   ## BSDI ports
 321   *-*-bsdi* )
 322     opsys=bsdi
 323     case "${canonical}" in
 324       i[345]86-*-bsdi*) machine=intel386 ;;
 325       sparc-*-bsdi*)  machine=sparc ;;
 326       powerpc-*-bsdi*)  machine=macppc ;;
 327     esac
 328     case "${canonical}" in
 329       *-*-bsd386* | *-*-bsdi1* )        opsys=bsd386 ;;
 330       *-*-bsdi2.0* )            opsys=bsdos2 ;;
 331       *-*-bsdi2* )              opsys=bsdos2-1 ;;
 332       *-*-bsdi3* )              opsys=bsdos3 ;;
 333       *-*-bsdi[45]* )           opsys=bsdos4 ;;
 334     esac
 335   ;;
 336
 337   ## Alliant machines
 338   ## Strictly speaking, we need the version of the alliant operating
 339   ## system to choose the right machine file, but currently the
 340   ## configuration name doesn't tell us enough to choose the right
 341   ## one; we need to give alliants their own operating system name to
 342   ## do this right.  When someone cares, they can help us.
 343   fx80-alliant-* )
 344     machine=alliant4 opsys=bsd4-2
 345   ;;
 346   i860-alliant-* )
 347     machine=alliant-2800 opsys=bsd4-3
 348   ;;
 349
 350   ## Alpha (DEC) machines.
 351   alpha*-dec-osf* )
 352     machine=alpha opsys=osf1
 353     # This is needed to find X11R6.1 libraries for certain tests.
 354     NON_GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
 355     GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
 356     # NON_GNU_CPP is necessary on 5.0 to avoid mangling src/Makefile
 357     # due to non-traditional preprocessing with the current compiler
 358     # defaults.  OSF 4 can also have that compiler version, and there
 359     # seems always to have been a usable /usr/bin/cpp.
 360     NON_GNU_CPP=/usr/bin/cpp
 361     case "${canonical}" in
 362     alpha*-dec-osf[5-9]*)
 363       opsys=osf5-0 ;;
 364     esac
 365   ;;
 366
 367   alpha*-*-linux-gnu* )
 368     machine=alpha opsys=gnu-linux
 369   ;;
 370
 371   arm*-*-linux-gnu* )
 372     machine=arm opsys=gnu-linux
 373   ;;
 374
 375   ## Altos 3068
 376   m68*-altos-sysv* )
 377     machine=altos opsys=usg5-2
 378   ;;
 379
 380   ## Amdahl UTS
 381   580-amdahl-sysv* )
 382     machine=amdahl opsys=usg5-2-2
 383   ;;
 384
 385   ## Apollo, Domain/OS
 386   m68*-apollo-* )
 387     machine=apollo opsys=bsd4-3
 388   ;;
 389
 390   ## Apple Darwin / Mac OS X
 391   *-apple-darwin* )
 392     case "${canonical}" in
 393       i[3456]86-* )  machine=intel386 ;;
 394       powerpc-* )    machine=powermac ;;
 395       * )            unported=yes ;;
 396     esac
 397     opsys=darwin
 398     # Define CPP as follows to make autoconf work correctly.
 399     CPP="${CC-cc} -E -no-cpp-precomp"
 400     # Use fink packages if available.
 401     if test -d /sw/include && test -d /sw/lib; then
 402       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 403       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 404       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 405     fi
 406   ;;
 407
 408   ## AT&T 3b2, 3b5, 3b15, 3b20
 409   we32k-att-sysv* )
 410     machine=att3b opsys=usg5-2-2
 411   ;;
 412
 413   ## AT&T 3b1 - The Mighty Unix PC!
 414   m68*-att-sysv* )
 415     machine=7300 opsys=usg5-2-2
 416   ;;
 417
 418   ## Bull dpx20
 419   rs6000-bull-bosx* )
 420     machine=ibmrs6000 opsys=aix3-2
 421   ;;
 422
 423   ## Bull dpx2
 424   m68*-bull-sysv3* )
 425     machine=dpx2 opsys=usg5-3
 426   ;;
 427
 428   ## Bull sps7
 429   m68*-bull-sysv2* )
 430     machine=sps7 opsys=usg5-2
 431   ;;
 432
 433   ## CCI 5/32, 6/32 -- see "Tahoe".
 434
 435   ## Celerity
 436   ## I don't know what configuration name to use for this; config.sub
 437   ## doesn't seem to know anything about it.  Hey, Celerity users, get
 438   ## in touch with us!
 439   celerity-celerity-bsd* )
 440     machine=celerity opsys=bsd4-2
 441   ;;
 442
 443   ## Clipper
 444   ## What operating systems does this chip run that Emacs has been
 445   ## tested on?
 446   clipper-* )
 447     machine=clipper
 448     ## We'll use the catch-all code at the bottom to guess the
 449     ## operating system.
 450   ;;
 451
 452   ## Compaq Nonstop
 453   mips-compaq-nonstopux* )
 454     machine=nonstopux opsys=nonstopux
 455     ;;
 456
 457   ## Convex
 458   *-convex-bsd* | *-convex-convexos* )
 459     machine=convex opsys=bsd4-3
 460     ## Prevents spurious white space in makefiles - d.m.cooke@larc.nasa.gov
 461     NON_GNU_CPP="cc -E -P"
 462   ;;
 463
 464   ## Cubix QBx/386
 465   i[3456]86-cubix-sysv* )
 466     machine=intel386 opsys=usg5-3
 467   ;;
 468
 469   ## Cydra 5
 470   cydra*-cydrome-sysv* )
 471     machine=cydra5 opsys=usg5-3
 472   ;;
 473
 474   ## Data General AViiON Machines
 475   ## DG changed naming conventions with the release of 5.4.4.10, they
 476   ## dropped the initial 5.4 but left the intervening R.  Because of the
 477   ## R this shouldn't conflict with older versions of the OS (which I
 478   ## think were named like dgux4.*). In addition, DG new AViiONs series
 479   ## uses either Motorola M88k or Intel Pentium CPUs.
 480   m88k-dg-dguxR4.* | m88k-dg-dgux4* )
 481     machine=aviion opsys=dgux4
 482   ;;
 483   m88k-dg-dgux5.4R3* | m88k-dg-dgux5.4.3* )
 484     ## This name is dgux5-4-3 instead of dgux5-4r3
 485     ## to avoid a file name conflict on MSDOS.
 486     machine=aviion opsys=dgux5-4-3
 487   ;;
 488   m88k-dg-dgux5.4R2* | m88k-dg-dgux5.4.2* )
 489     machine=aviion opsys=dgux5-4r2
 490   ;;
 491   m88k-dg-dgux* )
 492     machine=aviion opsys=dgux
 493   ;;
 494
 495   ## Data General AViiON Intel (x86) Machines
 496   ## Exists from 5.4.3 (current i586-dg-dguxR4.11)
 497   ## Ehud Karni, 1998-may-30, ehud@unix.simonwiesel.co.il
 498   i[345]86-dg-dguxR4* )
 499     machine=aviion-intel opsys=dgux4
 500   ;;
 501
 502   ## DECstations
 503   mips-dec-ultrix[0-3].* | mips-dec-ultrix4.0* | mips-dec-bsd4.2* )
 504     machine=pmax opsys=bsd4-2
 505   ;;
 506   mips-dec-ultrix4.[12]* | mips-dec-bsd* )
 507     machine=pmax opsys=bsd4-3
 508   ;;
 509   mips-dec-ultrix* )
 510     machine=pmax opsys=ultrix4-3
 511   ;;
 512   mips-dec-osf* )
 513     machine=pmax opsys=osf1
 514   ;;
 515   mips-dec-mach_bsd4.3* )
 516     machine=pmax opsys=mach-bsd4-3
 517   ;;
 518
 519   ## Motorola Delta machines
 520   m68k-motorola-sysv* | m68000-motorola-sysv* )
 521     machine=delta opsys=usg5-3
 522     if test -z "`type gnucc | grep 'not found'`"
 523     then
 524       if test -s /etc/167config
 525       then CC="gnucc -m68040"
 526       else CC="gnucc -m68881"
 527       fi
 528     else
 529       if test -z "`type gcc | grep 'not found'`"
 530       then CC=gcc
 531       else CC=cc
 532       fi
 533     fi
 534   ;;
 535   m88k-motorola-sysv4* )
 536     # jbotte@bnr.ca says that UNIX_System_V <hostName> 4.0 R40V4.3 m88k mc88110
 537     # needs POSIX_SIGNALS and therefore needs usg5-4-2.
 538     # I hope there are not other 4.0 versions for this machine
 539     # which really need usg5-4 instead.
 540     machine=delta88k opsys=usg5-4-2
 541   ;;
 542   m88k-motorola-sysv* | m88k-motorola-m88kbcs* )
 543     machine=delta88k opsys=usg5-3
 544   ;;
 545
 546   ## Dual machines
 547   m68*-dual-sysv* )
 548     machine=dual opsys=usg5-2
 549   ;;
 550   m68*-dual-uniplus* )
 551     machine=dual opsys=unipl5-2
 552   ;;
 553
 554   ## Elxsi 6400
 555   elxsi-elxsi-sysv* )
 556     machine=elxsi opsys=usg5-2
 557   ;;
 558
 559   ## Encore machines
 560   ns16k-encore-bsd* )
 561     machine=ns16000 opsys=umax
 562   ;;
 563
 564   ## The GEC 63 - apparently, this port isn't really finished yet.
 565   #  I'm sure we finished off the last of the machines, though.  -- fx
 566
 567   ## Gould Power Node and NP1
 568   pn-gould-bsd4.2* )
 569     machine=gould opsys=bsd4-2
 570   ;;
 571   pn-gould-bsd4.3* )
 572     machine=gould opsys=bsd4-3
 573   ;;
 574   np1-gould-bsd* )
 575     machine=gould-np1 opsys=bsd4-3
 576   ;;
 577
 578   ## Harris Night Hawk machines running CX/UX (a 5000 looks just like a 4000
 579   ## as far as Emacs is concerned).
 580   m88k-harris-cxux* )
 581     # Build needs to be different on 7.0 and later releases
 582     case "`uname -r`" in
 583        [56].[0-9] ) machine=nh4000 opsys=cxux ;;
 584        [7].[0-9] ) machine=nh4000 opsys=cxux7 ;;
 585     esac
 586     NON_GNU_CPP="/lib/cpp"
 587   ;;
 588   ## Harris ecx or gcx running CX/UX (Series 1200, Series 3000)
 589   m68k-harris-cxux* )
 590     machine=nh3000 opsys=cxux
 591   ;;
 592   ## Harris power pc NightHawk running Power UNIX (Series 6000)
 593   powerpc-harris-powerunix )
 594     machine=nh6000 opsys=powerunix
 595     NON_GNU_CPP="cc -Xo -E -P"
 596   ;;
 597   ## SR2001/SR2201 running HI-UX/MPP
 598   hppa1.1-hitachi-hiuxmpp* )
 599     machine=sr2k opsys=hiuxmpp
 600   ;;
 601   hppa1.1-hitachi-hiuxwe2* )
 602     machine=sr2k opsys=hiuxwe2
 603   ;;
 604   ## Honeywell XPS100
 605   xps*-honeywell-sysv* )
 606     machine=xps100 opsys=usg5-2
 607   ;;
 608
 609   ## HP 9000 series 200 or 300
 610   m68*-hp-bsd* )
 611     machine=hp9000s300 opsys=bsd4-3
 612   ;;
 613   ## HP/UX 7, 8, 9, and 10 are supported on these machines.
 614   m68*-hp-hpux* )
 615     case "`uname -r`" in
 616       ## Someone's system reports A.B8.05 for this.
 617       ## I wonder what other possibilities there are.
 618       *.B8.* ) machine=hp9000s300 opsys=hpux8 ;;
 619       *.08.* ) machine=hp9000s300 opsys=hpux8 ;;
 620       *.09.* ) machine=hp9000s300 opsys=hpux9 ;;
 621       *.1[0-9].* ) machine=hp9000s300 opsys=hpux9shr ;;
 622       *) machine=hp9000s300 opsys=hpux ;;
 623     esac
 624   ;;
 625
 626   ## HP 9000 series 700 and 800, running HP/UX
 627   hppa*-hp-hpux7* )
 628     machine=hp800 opsys=hpux
 629   ;;
 630   hppa*-hp-hpux8* )
 631     machine=hp800 opsys=hpux8
 632   ;;
 633   hppa*-hp-hpux9shr* )
 634     machine=hp800 opsys=hpux9shr
 635   ;;
 636   hppa*-hp-hpux9* )
 637     machine=hp800 opsys=hpux9
 638   ;;
 639   hppa*-hp-hpux10.2* )
 640     machine=hp800 opsys=hpux10-20
 641   ;;
 642   hppa*-hp-hpux10* )
 643     machine=hp800 opsys=hpux10
 644   ;;
 645   hppa*-hp-hpux1[1-9]* )
 646     machine=hp800 opsys=hpux11
 647     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 648   ;;
 649
 650   hppa*-*-linux-gnu* )
 651     machine=hp800 opsys=gnu-linux
 652   ;;
 653
 654   ## HP 9000 series 700 and 800, running HP/UX
 655   hppa*-hp-hpux* )
 656     ## Cross-compilation?  Nah!
 657     case "`uname -r`" in
 658       ## Someone's system reports A.B8.05 for this.
 659       ## I wonder what other possibilities there are.
 660       *.B8.* ) machine=hp800 opsys=hpux8 ;;
 661       *.08.* ) machine=hp800 opsys=hpux8 ;;
 662       *.09.* ) machine=hp800 opsys=hpux9 ;;
 663       *) machine=hp800 opsys=hpux10 ;;
 664     esac
 665   ;;
 666   hppa*-*-nextstep* )
 667     machine=hp800 opsys=nextstep
 668   ;;
 669
 670   ## Orion machines
 671   orion-orion-bsd* )
 672     machine=orion opsys=bsd4-2
 673   ;;
 674   clipper-orion-bsd* )
 675     machine=orion105 opsys=bsd4-2
 676   ;;
 677
 678   ## IBM machines
 679   i[3456]86-ibm-aix1.1* )
 680     machine=ibmps2-aix opsys=usg5-2-2
 681   ;;
 682   i[3456]86-ibm-aix1.[23]* | i[3456]86-ibm-aix* )
 683     machine=ibmps2-aix opsys=usg5-3
 684   ;;
 685   i370-ibm-aix*)
 686     machine=ibm370aix opsys=usg5-3
 687   ;;
 688   s390-*-linux-gnu* )
 689     machine=ibms390 opsys=gnu-linux
 690   ;;
 691   s390x-*-linux-gnu* )
 692     machine=ibms390x opsys=gnu-linux
 693   ;;
 694   rs6000-ibm-aix3.1* | powerpc-ibm-aix3.1*  )
 695     machine=ibmrs6000 opsys=aix3-1
 696   ;;
 697   rs6000-ibm-aix3.2.5 | powerpc-ibm-aix3.2.5 )
 698     machine=ibmrs6000 opsys=aix3-2-5
 699   ;;
 700   rs6000-ibm-aix4.1* | powerpc-ibm-aix4.1*  )
 701     machine=ibmrs6000 opsys=aix4-1
 702   ;;
 703   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 704     machine=ibmrs6000 opsys=aix4-2
 705   ;;
 706   rs6000-ibm-aix4.3* | powerpc-ibm-aix4.3*  )
 707     machine=ibmrs6000 opsys=aix4-2
 708   ;;
 709   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 710     machine=ibmrs6000 opsys=aix4-2
 711   ;;
 712   rs6000-ibm-aix4.0* | powerpc-ibm-aix4.0*  )
 713     machine=ibmrs6000 opsys=aix4
 714   ;;
 715   rs6000-ibm-aix4* | powerpc-ibm-aix4*  )
 716     machine=ibmrs6000 opsys=aix4-1
 717   ;;
 718   rs6000-ibm-aix* | powerpc-ibm-aix* )
 719     machine=ibmrs6000 opsys=aix3-2
 720   ;;
 721   romp-ibm-bsd4.3* )
 722     machine=ibmrt opsys=bsd4-3
 723   ;;
 724   romp-ibm-bsd4.2* )
 725     machine=ibmrt opsys=bsd4-2
 726   ;;
 727   romp-ibm-aos4.3* )
 728     machine=ibmrt opsys=bsd4-3
 729   ;;
 730   romp-ibm-aos4.2* )
 731     machine=ibmrt opsys=bsd4-2
 732   ;;
 733   romp-ibm-aos* )
 734     machine=ibmrt opsys=bsd4-3
 735   ;;
 736   romp-ibm-bsd* )
 737     machine=ibmrt opsys=bsd4-3
 738   ;;
 739   romp-ibm-aix* )
 740     machine=ibmrt-aix opsys=usg5-2-2
 741   ;;
 742
 743   ## Integrated Solutions `Optimum V'
 744   m68*-isi-bsd4.2* )
 745     machine=isi-ov opsys=bsd4-2
 746   ;;
 747   m68*-isi-bsd4.3* )
 748     machine=isi-ov opsys=bsd4-3
 749   ;;
 750
 751   ## Intel 386 machines where we do care about the manufacturer
 752   i[3456]86-intsys-sysv* )
 753     machine=is386 opsys=usg5-2-2
 754   ;;
 755
 756   ## Prime EXL
 757   i[3456]86-prime-sysv* )
 758     machine=i386 opsys=usg5-3
 759   ;;
 760
 761   ## Sequent Symmetry running Dynix
 762   i[3456]86-sequent-bsd* )
 763     machine=symmetry opsys=bsd4-3
 764   ;;
 765
 766   ## Sequent Symmetry running ptx 4, which is a modified SVR4.
 767   i[3456]86-sequent-ptx4* | i[3456]86-sequent-sysv4* )
 768     machine=sequent-ptx opsys=ptx4
 769     NON_GNU_CPP=/lib/cpp
 770   ;;
 771
 772   ## Sequent Symmetry running DYNIX/ptx
 773   ## Use the old cpp rather than the newer ANSI one.
 774   i[3456]86-sequent-ptx* )
 775     machine=sequent-ptx opsys=ptx
 776     NON_GNU_CPP="/lib/cpp"
 777   ;;
 778
 779   ## ncr machine running svr4.3.
 780   i[3456]86-ncr-sysv4.3 )
 781     machine=ncr386 opsys=usg5-4-3
 782   ;;
 783
 784   ## Unspecified sysv on an ncr machine defaults to svr4.2.
 785   ## (Plain usg5-4 doesn't turn on POSIX signals, which we need.)
 786   i[3456]86-ncr-sysv* )
 787     machine=ncr386 opsys=usg5-4-2
 788   ;;
 789
 790   ## Intel Paragon OSF/1
 791   i860-intel-osf1* )
 792     machine=paragon opsys=osf1 NON_GNU_CPP=/usr/mach/lib/cpp
 793   ;;
 794
 795   ## Intel 860
 796   i860-*-sysv4* )
 797     machine=i860 opsys=usg5-4
 798     NON_GNU_CC="/bin/cc" # Ie, not the one in /usr/ucb/cc.
 799     NON_GNU_CPP="/usr/ccs/lib/cpp" # cc -E tokenizes macro expansion.
 800   ;;
 801
 802   ## Macintosh PowerPC
 803   powerpc*-*-linux-gnu* )
 804     machine=macppc opsys=gnu-linux
 805   ;;
 806
 807   ## Masscomp machines
 808   m68*-masscomp-rtu* )
 809     machine=masscomp opsys=rtu
 810   ;;
 811
 812   ## Megatest machines
 813   m68*-megatest-bsd* )
 814     machine=mega68 opsys=bsd4-2
 815   ;;
 816
 817   ## Workstations sold by MIPS
 818   ## This is not necessarily all workstations using the MIPS processor -
 819   ## Irises are produced by SGI, and DECstations by DEC.
 820
 821   ## etc/MACHINES lists mips.h and mips4.h as possible machine files,
 822   ## and usg5-2-2 and bsd4-3 as possible OS files.  The only guidance
 823   ## it gives for choosing between the alternatives seems to be "Use
 824   ## -machine=mips4 for RISCOS version 4; use -opsystem=bsd4-3 with
 825   ## the BSD world."  I'll assume that these are instructions for
 826   ## handling two odd situations, and that every other situation
 827   ## should use mips.h and usg5-2-2, they being listed first.
 828   mips-mips-usg* )
 829     machine=mips4
 830     ## Fall through to the general code at the bottom to decide on the OS.
 831   ;;
 832   mips-mips-riscos4* )
 833     machine=mips4 opsys=bsd4-3
 834     NON_GNU_CC="cc -systype bsd43"
 835     NON_GNU_CPP="cc -systype bsd43 -E"
 836   ;;
 837   mips-mips-riscos5* )
 838     machine=mips4 opsys=riscos5
 839     NON_GNU_CC="cc -systype bsd43"
 840     NON_GNU_CPP="cc -systype bsd43 -E"
 841   ;;
 842   mips-mips-bsd* )
 843     machine=mips opsys=bsd4-3
 844   ;;
 845   mips-mips-* )
 846     machine=mips opsys=usg5-2-2
 847   ;;
 848
 849   ## NeXT
 850   m68*-next-* | m68k-*-nextstep* )
 851     machine=m68k opsys=nextstep
 852   ;;
 853
 854   ## The complete machine from National Semiconductor
 855   ns32k-ns-genix* )
 856     machine=ns32000 opsys=usg5-2
 857   ;;
 858
 859   ## NCR machines
 860   m68*-ncr-sysv2* | m68*-ncr-sysvr2* )
 861     machine=tower32 opsys=usg5-2-2
 862   ;;
 863   m68*-ncr-sysv3* | m68*-ncr-sysvr3* )
 864     machine=tower32v3 opsys=usg5-3
 865   ;;
 866
 867   ## NEC EWS4800
 868   mips-nec-sysv4*)
 869   machine=ews4800 opsys=ux4800
 870   ;;
 871
 872   ## Nixdorf Targon 31
 873   m68*-nixdorf-sysv* )
 874     machine=targon31 opsys=usg5-2-2
 875   ;;
 876
 877   ## Nu (TI or LMI)
 878   m68*-nu-sysv* )
 879     machine=nu opsys=usg5-2
 880   ;;
 881
 882   ## Plexus
 883   m68*-plexus-sysv* )
 884     machine=plexus opsys=usg5-2
 885   ;;
 886
 887   ## Pyramid machines
 888   ## I don't really have any idea what sort of processor the Pyramid has,
 889   ## so I'm assuming it is its own architecture.
 890   pyramid-pyramid-bsd* )
 891     machine=pyramid opsys=bsd4-2
 892   ;;
 893
 894   ## Sequent Balance
 895   ns32k-sequent-bsd4.2* )
 896     machine=sequent opsys=bsd4-2
 897   ;;
 898   ns32k-sequent-bsd4.3* )
 899     machine=sequent opsys=bsd4-3
 900   ;;
 901
 902   ## Siemens Nixdorf
 903   mips-siemens-sysv* | mips-sni-sysv*)
 904     machine=mips-siemens opsys=usg5-4
 905     NON_GNU_CC=/usr/ccs/bin/cc
 906     NON_GNU_CPP=/usr/ccs/lib/cpp
 907   ;;
 908
 909   ## Silicon Graphics machines
 910   ## Iris 2500 and Iris 2500 Turbo (aka the Iris 3030)
 911   m68*-sgi-iris3.5* )
 912     machine=irist opsys=iris3-5
 913   ;;
 914   m68*-sgi-iris3.6* | m68*-sgi-iris*)
 915     machine=irist opsys=iris3-6
 916   ;;
 917   ## Iris 4D
 918   mips-sgi-irix3* )
 919     machine=iris4d opsys=irix3-3
 920   ;;
 921   mips-sgi-irix4* )
 922     machine=iris4d opsys=irix4-0
 923   ;;
 924   mips-sgi-irix6.5 )
 925     machine=iris4d opsys=irix6-5
 926     # Without defining _LANGUAGE_C, things get masked out in the headers
 927     # so that, for instance, grepping for `free' in stdlib.h fails and
 928     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 929     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 930     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 931   ;;
 932   mips-sgi-irix6* )
 933     machine=iris4d opsys=irix6-0
 934     # It's not clear whether -D_LANGUAGE_C is necessary as it is for 6.5,
 935     # but presumably it does no harm.
 936     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 937     # -32 probably isn't necessary in later v.6s -- anyone know which?
 938     NON_GCC_TEST_OPTIONS=-32
 939   ;;
 940   mips-sgi-irix5.[01]* )
 941     machine=iris4d opsys=irix5-0
 942   ;;
 943   mips-sgi-irix5* | mips-sgi-irix* )
 944     machine=iris4d opsys=irix5-2
 945   ;;
 946
 947   ## SONY machines
 948   m68*-sony-bsd4.2* )
 949     machine=news opsys=bsd4-2
 950   ;;
 951   m68*-sony-bsd4.3* )
 952     machine=news opsys=bsd4-3
 953   ;;
 954   m68*-sony-newsos3* | m68*-sony-news3*)
 955     machine=news opsys=bsd4-3
 956   ;;
 957   mips-sony-bsd* | mips-sony-newsos4* | mips-sony-news4*)
 958     machine=news-risc opsys=bsd4-3
 959   ;;
 960   mips-sony-newsos6* )
 961     machine=news-r6 opsys=newsos6
 962   ;;
 963   mips-sony-news* )
 964     machine=news-risc opsys=newsos5
 965   ;;
 966
 967   ## Stride
 968   m68*-stride-sysv* )
 969     machine=stride opsys=usg5-2
 970   ;;
 971
 972   ## Suns
 973   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 974     machine=sparc opsys=gnu-linux
 975   ;;
 976
 977   *-auspex-sunos* | *-sun-sunos* | *-sun-bsd* | *-sun-solaris* \
 978     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* | powerpc*-*-solaris2* \
 979     | rs6000-*-solaris2*)
 980     case "${canonical}" in
 981       m68*-sunos1* )    machine=sun1 ;;
 982       m68*-sunos2* )    machine=sun2 ;;
 983       m68* )            machine=sun3 ;;
 984       i[3456]86-sun-sunos[34]* )        machine=sun386 ;;
 985       i[3456]86-*-* )     machine=intel386 ;;
 986       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 987       powerpcle* )      machine=powerpcle ;;
 988       powerpc* | rs6000* )  machine=ibmrs6000 ;;
 989       sparc* )          machine=sparc ;;
 990       * )               unported=yes ;;
 991     esac
 992     case "${canonical}" in
 993       ## The Sun386 didn't get past 4.0.
 994       i[3456]86-*-sunos4          ) opsys=sunos4-0 ;;
 995       *-sunos4.0*         ) opsys=sunos4-0 ;;
 996       *-sunos4.1.[3-9]*noshare )
 997                 ## This name is sunos413 instead of sunos4-1-3
 998                 ## to avoid a file name conflict on MSDOS.
 999                 opsys=sunos413
1000                 NON_GNU_CPP=/usr/lib/cpp
1001                 NON_GCC_TEST_OPTIONS=-Bstatic
1002                 GCC_TEST_OPTIONS=-static
1003                 ;;
1004       *-sunos4.1.[3-9]* | *-sunos4shr*)
1005                 opsys=sunos4shr
1006                 NON_GNU_CPP=/usr/lib/cpp
1007                 ;;
1008       *-sunos4* | *-sunos )
1009                 opsys=sunos4-1
1010                 NON_GCC_TEST_OPTIONS=-Bstatic
1011                 GCC_TEST_OPTIONS=-static
1012                 ;;
1013       *-sunos5.3* | *-solaris2.3* )
1014                 opsys=sol2-3
1015                 NON_GNU_CPP=/usr/ccs/lib/cpp
1016                 ;;
1017       *-sunos5.4* | *-solaris2.4* )
1018                 opsys=sol2-4
1019                 NON_GNU_CPP=/usr/ccs/lib/cpp
1020                 RANLIB="ar -ts"
1021                 ;;
1022       *-sunos5.5* | *-solaris2.5* )
1023                 opsys=sol2-5
1024                 NON_GNU_CPP=/usr/ccs/lib/cpp
1025                 RANLIB="ar -ts"
1026                 ;;
1027       *-sunos5.6* | *-solaris2.6* )
1028                 opsys=sol2-6
1029                 NON_GNU_CPP=/usr/ccs/lib/cpp
1030                 RANLIB="ar -ts"
1031                 ;;
1032       *-sunos5* | *-solaris* )
1033                 opsys=sol2-6
1034                 emacs_check_sunpro_c=yes
1035                 NON_GNU_CPP=/usr/ccs/lib/cpp
1036                 ;;
1037       *                   ) opsys=bsd4-2   ;;
1038     esac
1039     ## Watch out for a compiler that we know will not work.
1040     case "${canonical}" in
1041      *-solaris* | *-sunos5* )
1042                 if [ "x$CC" = x/usr/ucb/cc ]; then
1043                   ## /usr/ucb/cc doesn't work;
1044                   ## we should find some other compiler that does work.
1045                   unset CC
1046                 fi
1047                 ;;
1048       *) ;;
1049     esac
1050   ;;
1051   sparc-*-nextstep* )
1052     machine=sparc opsys=nextstep
1053   ;;
1054
1055   ## Tadpole 68k
1056   m68*-tadpole-sysv* )
1057     machine=tad68k opsys=usg5-3
1058   ;;
1059
1060   ## Tahoe machines
1061   tahoe-tahoe-bsd4.2* )
1062     machine=tahoe opsys=bsd4-2
1063   ;;
1064   tahoe-tahoe-bsd4.3* )
1065     machine=tahoe opsys=bsd4-3
1066   ;;
1067
1068   ## Tandem Integrity S2
1069   mips-tandem-sysv* )
1070     machine=tandem-s2 opsys=usg5-3
1071   ;;
1072
1073   ## Tektronix XD88
1074   m88k-tektronix-sysv3* )
1075   machine=tekxd88 opsys=usg5-3
1076   ;;
1077
1078   ## Tektronix 16000 box (6130?)
1079   ns16k-tektronix-bsd* )
1080     machine=ns16000 opsys=bsd4-2
1081   ;;
1082   ## Tektronix 4300
1083   ## src/m/tek4300.h hints that this is a m68k machine.
1084   m68*-tektronix-bsd* )
1085     machine=tek4300 opsys=bsd4-3
1086   ;;
1087
1088   ## Titan P2 or P3
1089   ## We seem to have lost the machine-description file titan.h!
1090   titan-titan-sysv* )
1091     machine=titan opsys=usg5-3
1092   ;;
1093
1094   ## Ustation E30 (SS5E)
1095   m68*-unisys-uniplus* )
1096     machine=ustation opsystem=unipl5-2
1097   ;;
1098
1099   ## Vaxen.
1100   vax-dec-* )
1101     machine=vax
1102     case "${canonical}" in
1103       *-bsd4.1* )                                       opsys=bsd4-1 ;;
1104       *-bsd4.2* | *-ultrix[0-3].* | *-ultrix4.0* )      opsys=bsd4-2 ;;
1105       *-bsd4.3* | *-ultrix* )                           opsys=bsd4-3 ;;
1106       *-sysv[01]* | *-sysvr[01]* )                      opsys=usg5-0 ;;
1107       *-sysv2* | *-sysvr2* )                            opsys=usg5-2 ;;
1108       *-vms* )                                          opsys=vms ;;
1109       * )                                               unported=yes
1110     esac
1111   ;;
1112
1113   ## Whitechapel MG1
1114   ns16k-whitechapel-* )
1115     machine=mg1
1116     ## We don't know what sort of OS runs on these; we'll let the
1117     ## operating system guessing code below try.
1118   ;;
1119
1120   ## Wicat
1121   m68*-wicat-sysv* )
1122     machine=wicat opsys=usg5-2
1123   ;;
1124
1125   ## IA-64
1126   ia64*-*-linux* )
1127     machine=ia64 opsys=gnu-linux
1128   ;;
1129
1130   ## Intel 386 machines where we don't care about the manufacturer
1131   i[3456]86-*-* )
1132     machine=intel386
1133     case "${canonical}" in
1134       *-cygwin )                opsys=cygwin ;;
1135       *-darwin* )               opsys=darwin
1136                                 CPP="${CC-cc} -E -no-cpp-precomp"
1137                                 ;;
1138       *-isc1.* | *-isc2.[01]* ) opsys=386-ix ;;
1139       *-isc2.2* )               opsys=isc2-2 ;;
1140       *-isc4.0* )               opsys=isc4-0 ;;
1141       *-isc4.* )                opsys=isc4-1
1142                                 GCC_TEST_OPTIONS=-posix
1143                                 NON_GCC_TEST_OPTIONS=-Xp
1144                                 ;;
1145       *-isc* )                  opsys=isc3-0 ;;
1146       *-esix5* )                opsys=esix5r4; NON_GNU_CPP=/usr/lib/cpp ;;
1147       *-esix* )                 opsys=esix ;;
1148       *-xenix* )                opsys=xenix ;;
1149       *-linux-gnu* )            opsys=gnu-linux ;;
1150       *-sco3.2v4* )             opsys=sco4 ; NON_GNU_CPP=/lib/cpp  ;;
1151       *-sco3.2v5* )             opsys=sco5
1152                                 NON_GNU_CPP=/lib/cpp
1153                                 # Prevent -belf from being passed to $CPP.
1154                                 # /lib/cpp does not accept it.
1155                                 OVERRIDE_CPPFLAGS=" "
1156                                 ;;
1157       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
1158       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
1159       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
1160       *-386bsd* )               opsys=386bsd ;;
1161       *-nextstep* )             opsys=nextstep ;;
1162       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
1163     esac
1164   ;;
1165
1166   ## m68k Linux-based GNU system
1167   m68k-*-linux-gnu* )
1168     machine=m68k opsys=gnu-linux
1169   ;;
1170
1171   ## Mips Linux-based GNU system
1172   mips-*-linux-gnu* | mipsel-*-linux-gnu* )
1173     machine=mips opsys=gnu-linux
1174   ;;
1175
1176   ## UXP/DS
1177   sparc-fujitsu-sysv4* )
1178     machine=sparc opsys=uxpds
1179     NON_GNU_CPP=/usr/ccs/lib/cpp
1180     RANLIB="ar -ts"
1181   ;;
1182
1183   ## UXP/V
1184   f301-fujitsu-uxpv4.1)
1185     machine=f301 opsys=uxpv
1186   ;;
1187
1188   ## AMD x86-64 Linux-based GNU system
1189   x86_64-*-linux-gnu* )
1190     machine=amdx86-64 opsys=gnu-linux
1191   ;;
1192
1193   ## Tensilica Xtensa Linux-based GNU system
1194   xtensa-*-linux-gnu* )
1195     machine=xtensa opsys=gnu-linux
1196     ;;
1197
1198   * )
1199     unported=yes
1200   ;;
1201 esac
1202
1203 ### If the code above didn't choose an operating system, just choose
1204 ### an operating system based on the configuration name.  You really
1205 ### only want to use this when you have no idea what the right
1206 ### operating system is; if you know what operating systems a machine
1207 ### runs, it's cleaner to make it explicit in the case statement
1208 ### above.
1209 if test x"${opsys}" = x; then
1210   case "${canonical}" in
1211     *-gnu* )                            opsys=gnu ;;
1212     *-bsd4.[01] )                       opsys=bsd4-1 ;;
1213     *-bsd4.2 )                          opsys=bsd4-2 ;;
1214     *-bsd4.3 )                          opsys=bsd4-3 ;;
1215     *-sysv0 | *-sysvr0 )                opsys=usg5-0 ;;
1216     *-sysv2 | *-sysvr2 )                opsys=usg5-2 ;;
1217     *-sysv2.2 | *-sysvr2.2 )            opsys=usg5-2-2 ;;
1218     *-sysv3* | *-sysvr3* )              opsys=usg5-3 ;;
1219     *-sysv4.2uw* )                      opsys=unixware ;;
1220     *-sysv5uw* )                        opsys=unixware ;;
1221     *-sysv5OpenUNIX* )                  opsys=unixware ;;
1222     *-sysv4.1* | *-sysvr4.1* )
1223         NON_GNU_CPP=/usr/lib/cpp
1224         opsys=usg5-4 ;;
1225     *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
1226         if [ x$NON_GNU_CPP = x ]; then
1227           if [ -f /usr/ccs/lib/cpp ]; then
1228             NON_GNU_CPP=/usr/ccs/lib/cpp
1229           else
1230             NON_GNU_CPP=/lib/cpp
1231           fi
1232         fi
1233         opsys=usg5-4-2 ;;
1234     *-sysv4* | *-sysvr4* )              opsys=usg5-4 ;;
1235     * )
1236       unported=yes
1237     ;;
1238   esac
1239 fi
1240
1241 ]
1242 dnl quotation ends
1243
1244 if test $unported = yes; then
1245   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
1246 Check `etc/MACHINES' for recognized configuration names.])
1247 fi
1248
1249 machfile="m/${machine}.h"
1250 opsysfile="s/${opsys}.h"
1251
1252
1253 #### Choose a compiler.
1254 test -n "$CC" && cc_specified=yes
1255
1256 # Save the value of CFLAGS that the user specified.
1257 SPECIFIED_CFLAGS="$CFLAGS"
1258
1259 case ${with_gcc} in
1260   "yes" ) CC="gcc" GCC=yes ;;
1261   "no"  ) : ${CC=cc} ;;
1262   * )
1263 esac
1264 AC_PROG_CC
1265
1266 # On Suns, sometimes $CPP names a directory.
1267 if test -n "$CPP" && test -d "$CPP"; then
1268   CPP=
1269 fi
1270
1271 ## If not using gcc, and on Solaris, and no CPP specified, see if
1272 ## using a Sun compiler, which needs -Xs to prevent whitespace.
1273 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
1274  test x"$CPP" = x; then
1275   AC_MSG_CHECKING([whether we are using a Sun C compiler])
1276   AC_CACHE_VAL(emacs_cv_sunpro_c,
1277   [AC_TRY_LINK([],
1278 [#ifndef __SUNPRO_C
1279 fail;
1280 #endif
1281 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
1282   AC_MSG_RESULT($emacs_cv_sunpro_c)
1283
1284   if test x"$emacs_cv_sunpro_c" = xyes; then
1285     NON_GNU_CPP="$CC -E -Xs"
1286   fi
1287 fi
1288
1289 #### Some systems specify a CPP to use unless we are using GCC.
1290 #### Now that we know whether we are using GCC, we can decide whether
1291 #### to use that one.
1292 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
1293 then
1294   CPP="$NON_GNU_CPP"
1295 fi
1296
1297 #### Some systems specify a CC to use unless we are using GCC.
1298 #### Now that we know whether we are using GCC, we can decide whether
1299 #### to use that one.
1300 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
1301   test x$cc_specified != xyes
1302 then
1303   CC="$NON_GNU_CC"
1304 fi
1305
1306 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
1307 then
1308   CC="$CC $GCC_TEST_OPTIONS"
1309 fi
1310
1311 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
1312 then
1313   CC="$CC $NON_GCC_TEST_OPTIONS"
1314 fi
1315
1316 dnl checks for Unix variants
1317 AC_AIX
1318 AC_GNU_SOURCE
1319
1320 ### Use -Wno-pointer-sign if the compiler supports it
1321 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
1322 SAVE_CFLAGS="$CFLAGS"
1323 CFLAGS="$CFLAGS -Wno-pointer-sign"
1324 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
1325 if test $has_option = yes; then
1326    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
1327 fi
1328 AC_MSG_RESULT($has_option)
1329 CFLAGS="$SAVE_CFLAGS"
1330 unset has_option
1331 unset SAVE_CFLAGS
1332
1333 #### Some other nice autoconf tests.
1334
1335 dnl checks for programs
1336 AC_PROG_LN_S
1337 AC_PROG_CPP
1338 AC_PROG_INSTALL
1339 if test "x$RANLIB" = x; then
1340   AC_PROG_RANLIB
1341 fi
1342 AC_PATH_PROG(INSTALL_INFO, install-info)
1343 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
1344 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
1345 dnl Don't use GZIP, which is used by gzip for additional parameters.
1346 AC_PATH_PROG(GZIP_PROG, gzip)
1347
1348
1349 ## Need makeinfo >= 4.6 (?) to build the manuals.
1350 AC_PATH_PROG(MAKEINFO, makeinfo, no)
1351 dnl By this stage, configure has already checked for egrep and set EGREP,
1352 dnl or exited with an error if no egrep was found.
1353 if test "$MAKEINFO" != "no" && \
1354   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[5-9]]|4\.[[6-9]])'`" = x; then
1355    MAKEINFO=no
1356 fi
1357
1358 if test "$MAKEINFO" = "no"; then
1359   AC_MSG_ERROR( [makeinfo >= 4.6 is required] )
1360 fi
1361
1362
1363 dnl Add our options to ac_link now, after it is set up.
1364
1365 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
1366 then
1367   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1368 fi
1369
1370 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
1371 then
1372   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1373 fi
1374
1375 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
1376 dnl If we can link with the flag, it shouldn't do any harm anyhow.
1377 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
1378 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
1379 dnl if not built to support GNU ld.
1380
1381 late_LDFLAGS=$LDFLAGS
1382 if test "$GCC" = yes; then
1383   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
1384 else
1385   LDFLAGS="$LDFLAGS -znocombreloc"
1386 fi
1387
1388 AC_MSG_CHECKING([for -znocombreloc])
1389 AC_LINK_IFELSE([main(){return 0;}],
1390   [AC_MSG_RESULT(yes)],
1391   LDFLAGS=$late_LDFLAGS
1392   [AC_MSG_RESULT(no)])
1393
1394 #### Extract some information from the operating system and machine files.
1395
1396 AC_CHECKING([the machine- and system-dependent files to find out
1397  - which libraries the lib-src programs will want, and
1398  - whether the GNU malloc routines are usable])
1399
1400 ### First figure out CFLAGS (which we use for running the compiler here)
1401 ### and REAL_CFLAGS (which we use for real compilation).
1402 ### The two are the same except on a few systems, where they are made
1403 ### different to work around various lossages.  For example,
1404 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
1405 ### as implying static linking.
1406
1407 ### If the CFLAGS env var is specified, we use that value
1408 ### instead of the default.
1409
1410 ### It's not important that this name contain the PID; you can't run
1411 ### two configures in the same directory and have anything work
1412 ### anyway.
1413 tempcname="conftest.c"
1414
1415 echo '
1416 #include "'${srcdir}'/src/'${opsysfile}'"
1417 #include "'${srcdir}'/src/'${machfile}'"
1418 #ifndef LIBS_MACHINE
1419 #define LIBS_MACHINE
1420 #endif
1421 #ifndef LIBS_SYSTEM
1422 #define LIBS_SYSTEM
1423 #endif
1424 #ifndef C_SWITCH_SYSTEM
1425 #define C_SWITCH_SYSTEM
1426 #endif
1427 #ifndef C_SWITCH_MACHINE
1428 #define C_SWITCH_MACHINE
1429 #endif
1430 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
1431 configure___ c_switch_system=C_SWITCH_SYSTEM
1432 configure___ c_switch_machine=C_SWITCH_MACHINE
1433
1434 #ifndef LIB_X11_LIB
1435 #define LIB_X11_LIB -lX11
1436 #endif
1437
1438 #ifndef LIBX11_MACHINE
1439 #define LIBX11_MACHINE
1440 #endif
1441
1442 #ifndef LIBX11_SYSTEM
1443 #define LIBX11_SYSTEM
1444 #endif
1445 configure___ LIBX=LIB_X11_LIB LIBX11_MACHINE LIBX11_SYSTEM
1446
1447 #ifdef UNEXEC
1448 configure___ unexec=UNEXEC
1449 #else
1450 configure___ unexec=unexec.o
1451 #endif
1452
1453 #ifdef SYSTEM_MALLOC
1454 configure___ system_malloc=yes
1455 #else
1456 configure___ system_malloc=no
1457 #endif
1458
1459 #ifdef USE_MMAP_FOR_BUFFERS
1460 configure___ use_mmap_for_buffers=yes
1461 #else
1462 configure___ use_mmap_for_buffers=no
1463 #endif
1464
1465 #ifndef C_DEBUG_SWITCH
1466 #define C_DEBUG_SWITCH -g
1467 #endif
1468
1469 #ifndef C_OPTIMIZE_SWITCH
1470 #ifdef __GNUC__
1471 #define C_OPTIMIZE_SWITCH -O2
1472 #else
1473 #define C_OPTIMIZE_SWITCH -O
1474 #endif
1475 #endif
1476
1477 #ifndef C_WARNINGS_SWITCH
1478 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
1479 #endif
1480
1481 #ifndef LD_SWITCH_MACHINE
1482 #define LD_SWITCH_MACHINE
1483 #endif
1484
1485 #ifndef LD_SWITCH_SYSTEM
1486 #define LD_SWITCH_SYSTEM
1487 #endif
1488
1489 #ifndef LD_SWITCH_X_SITE_AUX
1490 #define LD_SWITCH_X_SITE_AUX
1491 #endif
1492
1493 configure___ ld_switch_system=LD_SWITCH_SYSTEM
1494 configure___ ld_switch_machine=LD_SWITCH_MACHINE
1495
1496 #ifdef THIS_IS_CONFIGURE
1497
1498 /* Get the CFLAGS for tests in configure.  */
1499 #ifdef __GNUC__
1500 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1501 #else
1502 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1503 #endif
1504
1505 #else /* not THIS_IS_CONFIGURE */
1506
1507 /* Get the CFLAGS for real compilation.  */
1508 #ifdef __GNUC__
1509 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH '${SPECIFIED_CFLAGS}'
1510 #else
1511 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1512 #endif
1513
1514 #endif /* not THIS_IS_CONFIGURE */
1515 ' > ${tempcname}
1516
1517 # The value of CPP is a quoted variable reference, so we need to do this
1518 # to get its actual value...
1519 CPP=`eval "echo $CPP"`
1520 [eval `${CPP} -Isrc ${tempcname} \
1521        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1522 if test "x$SPECIFIED_CFLAGS" = x; then
1523   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
1524          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1525 else
1526   REAL_CFLAGS="$CFLAGS"
1527 fi]
1528 rm ${tempcname}
1529
1530 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
1531
1532 ### Make sure subsequent tests use flags consistent with the build flags.
1533
1534 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1535   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1536 else
1537   CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
1538 fi
1539
1540 dnl For AC_FUNC_GETLOADAVG, at least:
1541 AC_CONFIG_LIBOBJ_DIR(src)
1542
1543 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1544 AC_SYS_LARGEFILE
1545
1546
1547 ### The standard library on x86-64 GNU/Linux distributions can
1548 ### be located in either /usr/lib64 or /usr/lib.
1549 case "${canonical}" in
1550   x86_64-*-linux-gnu* )
1551     if test -d /usr/lib64; then
1552       AC_DEFINE(HAVE_X86_64_LIB64_DIR, 1,
1553         [Define to 1 if the file /usr/lib64 exists.])
1554 fi
1555 esac
1556
1557 dnl This function defintion taken from Gnome 2.0
1558 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1559 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1560 dnl also defines GSTUFF_PKG_ERRORS on error
1561 AC_DEFUN([PKG_CHECK_MODULES], [
1562   succeeded=no
1563
1564   if test -z "$PKG_CONFIG"; then
1565     AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1566   fi
1567
1568   if test "$PKG_CONFIG" = "no" ; then
1569      ifelse([$4], , [AC_MSG_ERROR([
1570       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1571   else
1572      PKG_CONFIG_MIN_VERSION=0.9.0
1573      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1574         AC_MSG_CHECKING(for $2)
1575
1576         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1577             AC_MSG_RESULT(yes)
1578             succeeded=yes
1579
1580             AC_MSG_CHECKING($1_CFLAGS)
1581             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1582             AC_MSG_RESULT($$1_CFLAGS)
1583
1584             AC_MSG_CHECKING($1_LIBS)
1585             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1586             AC_MSG_RESULT($$1_LIBS)
1587         else
1588             AC_MSG_RESULT(no)
1589             $1_CFLAGS=""
1590             $1_LIBS=""
1591             ## If we have a custom action on failure, don't print errors, but
1592             ## do set a variable so people can do so.
1593             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1594             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1595         fi
1596
1597         AC_SUBST($1_CFLAGS)
1598         AC_SUBST($1_LIBS)
1599      else
1600         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1601         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1602      fi
1603   fi
1604
1605   if test $succeeded = yes; then
1606      ifelse([$3], , :, [$3])
1607   else
1608      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1609   fi
1610 ])
1611
1612
1613 if test "${with_sound}" != "no"; then
1614   # Sound support for GNU/Linux and the free BSDs.
1615   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1616   # Emulation library used on NetBSD.
1617   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1618   AC_SUBST(LIBSOUND)
1619
1620   ALSA_REQUIRED=1.0.0
1621   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1622   dnl Check if --with-pkg-config-prog has been given.
1623   if test "X${with_pkg_config_prog}" != X; then
1624     PKG_CONFIG="${with_pkg_config_prog}"
1625   fi
1626   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1627   if test $HAVE_ALSA = yes; then
1628     SAVE_CFLAGS="$CFLAGS"
1629     SAVE_LDFLAGS="$LDFLAGS"
1630     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1631     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1632     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1633                     emacs_alsa_normal=yes,
1634                     emacs_alsa_normal=no)
1635     if test "$emacs_alsa_normal" != yes; then
1636       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1637                      [snd_lib_error_set_handler (0);],
1638                      emacs_alsa_subdir=yes,
1639                      emacs_alsa_subdir=no)
1640       if test "$emacs_alsa_subdir" != yes; then
1641         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1642       fi
1643       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1644     fi
1645
1646     CFLAGS="$SAVE_CFLAGS"
1647     LDFLAGS="$SAVE_LDFLAGS"
1648     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1649     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1650     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1651   fi
1652   AC_SUBST(CFLAGS_SOUND)
1653 fi
1654
1655 dnl checks for header files
1656 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1657   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1658   termcap.h stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1659   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1660   sys/utsname.h pwd.h)
1661
1662 AC_MSG_CHECKING(if personality LINUX32 can be set)
1663 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1664                emacs_cv_personality_linux32=yes,
1665                emacs_cv_personality_linux32=no)
1666 AC_MSG_RESULT($emacs_cv_personality_linux32)
1667
1668 if test $emacs_cv_personality_linux32 = yes; then
1669   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1670             [Define to 1 if personality LINUX32 can be set.])
1671 fi
1672
1673 dnl On Solaris 8 there's a compilation warning for term.h because
1674 dnl it doesn't define `bool'.
1675 AC_CHECK_HEADERS(term.h, , , -)
1676 AC_HEADER_STDC
1677 AC_HEADER_TIME
1678 AC_CHECK_DECLS([sys_siglist])
1679 if test $ac_cv_have_decl_sys_siglist != yes; then
1680   # For Tru64, at least:
1681   AC_CHECK_DECLS([__sys_siglist])
1682   if test $ac_cv_have_decl___sys_siglist = yes; then
1683     AC_DEFINE(sys_siglist, __sys_siglist,
1684               [Define to any substitute for sys_siglist.])
1685   fi
1686 fi
1687 AC_HEADER_SYS_WAIT
1688
1689 dnl Some systems have utime.h but don't declare the struct anyplace.
1690 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1691 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1692 #include <sys/time.h>
1693 #include <time.h>
1694 #else
1695 #ifdef HAVE_SYS_TIME_H
1696 #include <sys/time.h>
1697 #else
1698 #include <time.h>
1699 #endif
1700 #endif
1701 #ifdef HAVE_UTIME_H
1702 #include <utime.h>
1703 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1704   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1705 if test $emacs_cv_struct_utimbuf = yes; then
1706   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1707 fi
1708
1709 dnl checks for typedefs
1710 AC_TYPE_SIGNAL
1711
1712 dnl Check for speed_t typedef.
1713 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1714   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1715     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1716 if test $emacs_cv_speed_t = yes; then
1717   AC_DEFINE(HAVE_SPEED_T, 1,
1718            [Define to 1 if `speed_t' is declared by <termios.h>.])
1719 fi
1720
1721 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1722 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1723 #include <sys/time.h>
1724 #include <time.h>
1725 #else
1726 #ifdef HAVE_SYS_TIME_H
1727 #include <sys/time.h>
1728 #else
1729 #include <time.h>
1730 #endif
1731 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1732   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1733 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1734 if test $emacs_cv_struct_timeval = yes; then
1735   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1736 fi
1737
1738 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1739 AC_TRY_COMPILE([#include <math.h>],
1740 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1741   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1742 HAVE_EXCEPTION=$emacs_cv_struct_exception
1743 if test $emacs_cv_struct_exception != yes; then
1744   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1745 fi
1746
1747 AC_CHECK_HEADERS(sys/socket.h)
1748 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1749 #if HAVE_SYS_SOCKET_H
1750 #include <sys/socket.h>
1751 #endif])
1752
1753 dnl checks for structure members
1754 AC_STRUCT_TM
1755 AC_STRUCT_TIMEZONE
1756 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1757                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1758                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1759                 [#include <time.h>])
1760 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1761                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1762                   struct ifreq.ifr_addr], , ,
1763                  [AC_INCLUDES_DEFAULT
1764 #if HAVE_SYS_SOCKET_H
1765 #include <sys/socket.h>
1766 #endif
1767 #if HAVE_NET_IF_H
1768 #include <net/if.h>
1769 #endif])
1770
1771 dnl checks for compiler characteristics
1772
1773 dnl Testing __STDC__ to determine prototype support isn't good enough.
1774 dnl DEC C, for instance, doesn't define it with default options, and
1775 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1776 dnl and void *.
1777 AC_C_PROTOTYPES
1778 AC_C_VOLATILE
1779 AC_C_CONST
1780 dnl This isn't useful because we can't turn on use of `inline' unless
1781 dnl the compiler groks `extern inline'.
1782 dnl AC_C_INLINE
1783 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1784   [AC_TRY_COMPILE(, [void * foo;],
1785                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1786 if test $emacs_cv_void_star = yes; then
1787   AC_DEFINE(POINTER_TYPE, void)
1788 else
1789   AC_DEFINE(POINTER_TYPE, char)
1790 fi
1791 AH_TEMPLATE(POINTER_TYPE,
1792             [Define as `void' if your compiler accepts `void *'; otherwise
1793              define as `char'.])dnl
1794
1795
1796
1797 dnl This could be used for targets which can have both byte sexes.
1798 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1799 dnl AC_C_BIGENDIAN
1800
1801 dnl check for Make feature
1802 AC_PROG_MAKE_SET
1803
1804 dnl checks for operating system services
1805 AC_SYS_LONG_FILE_NAMES
1806
1807 #### Choose a window system.
1808
1809 AC_PATH_X
1810 if test "$no_x" = yes; then
1811   window_system=none
1812 else
1813   window_system=x11
1814 fi
1815
1816 if test "${x_libraries}" != NONE; then
1817   if test -n "${x_libraries}"; then
1818     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1819     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1820   fi
1821   x_default_search_path=""
1822   x_search_path=${x_libraries}
1823   if test -z "${x_search_path}"; then
1824     x_search_path=/usr/lib
1825   fi
1826   for x_library in `echo ${x_search_path}: | \
1827                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1828     x_search_path="\
1829 ${x_library}/X11/%L/%T/%N%C%S:\
1830 ${x_library}/X11/%l/%T/%N%C%S:\
1831 ${x_library}/X11/%T/%N%C%S:\
1832 ${x_library}/X11/%L/%T/%N%S:\
1833 ${x_library}/X11/%l/%T/%N%S:\
1834 ${x_library}/X11/%T/%N%S"
1835     if test x"${x_default_search_path}" = x; then
1836       x_default_search_path=${x_search_path}
1837     else
1838       x_default_search_path="${x_search_path}:${x_default_search_path}"
1839     fi
1840   done
1841 fi
1842 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1843   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1844 fi
1845
1846 if test x"${x_includes}" = x; then
1847   bitmapdir=/usr/include/X11/bitmaps
1848 else
1849   # accumulate include directories that have X11 bitmap subdirectories
1850   bmd_acc="dummyval"
1851   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1852     if test -d "${bmd}/X11/bitmaps"; then
1853       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1854     fi
1855     if test -d "${bmd}/bitmaps"; then
1856       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1857     fi
1858   done
1859   if test ${bmd_acc} != "dummyval"; then
1860     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1861   fi
1862 fi
1863
1864 HAVE_CARBON=no
1865 if test "${with_carbon}" != no; then
1866   AC_CHECK_HEADER(Carbon/Carbon.h, HAVE_CARBON=yes)
1867 fi
1868 if test "${window_system}" = x11 && test "${HAVE_CARBON}" = yes; then
1869   if test "${with_carbon+set}" != set \
1870      && test "${carbon_appdir_x+set}" != set; then
1871     for var in with_x with_x_toolkit with_gtk with_xim \
1872                with_xpm with_jpeg with_tiff with_gif with_png; do
1873       if eval test \"\${$var+set}\" = set; then
1874         HAVE_CARBON=no
1875         break
1876       fi
1877     done
1878   fi
1879 fi
1880 if test "${HAVE_CARBON}" = yes; then
1881   window_system=mac
1882 fi
1883
1884 case "${window_system}" in
1885   x11 )
1886     HAVE_X_WINDOWS=yes
1887     HAVE_X11=yes
1888     case "${with_x_toolkit}" in
1889       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1890       motif ) USE_X_TOOLKIT=MOTIF ;;
1891       gtk ) with_gtk=yes
1892 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1893 dnl USE_X_TOOLKIT is set.
1894             USE_X_TOOLKIT=none ;;
1895       no ) USE_X_TOOLKIT=none ;;
1896 dnl If user did not say whether to use a toolkit, make this decision later:
1897 dnl use the toolkit if we have gtk, or X11R5 or newer.
1898       * )
1899           if test x"$with_gtk" = xyes; then
1900              USE_X_TOOLKIT=none
1901           else
1902              USE_X_TOOLKIT=maybe
1903           fi
1904           ;;
1905     esac
1906   ;;
1907   mac | none )
1908     HAVE_X_WINDOWS=no
1909     HAVE_X11=no
1910     USE_X_TOOLKIT=none
1911   ;;
1912 esac
1913
1914 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1915    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1916    if test "$HAVE_XSERVER" = true ||
1917       test -n "$DISPLAY" ||
1918       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1919         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1920 were found.  You should install the relevant development files for X
1921 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1922 sure you have development files for image handling, i.e.
1923 tiff, gif, jpeg, png and xpm.
1924 If you are sure you want Emacs compiled without X window support, pass
1925   --without-x
1926 to configure.])
1927    fi
1928 fi
1929
1930 ### If we're using X11, we should use the X menu package.
1931 HAVE_MENUS=no
1932 case ${HAVE_X11} in
1933   yes ) HAVE_MENUS=yes ;;
1934 esac
1935
1936 if test "${opsys}" = "hpux9"; then
1937   case "${x_libraries}" in
1938     *X11R4* )
1939       opsysfile="s/hpux9-x11r4.h"
1940       ;;
1941   esac
1942 fi
1943
1944 if test "${opsys}" = "hpux9shr"; then
1945   case "${x_libraries}" in
1946     *X11R4* )
1947       opsysfile="s/hpux9shxr4.h"
1948       ;;
1949   esac
1950 fi
1951
1952 ### Compute the unexec source name from the object name.
1953 UNEXEC_SRC="`echo ${unexec} | sed 's/\.o/.c/'`"
1954
1955 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1956 # Assume not, until told otherwise.
1957 GNU_MALLOC=yes
1958 doug_lea_malloc=yes
1959 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1960 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1961 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1962                emacs_cv_var___after_morecore_hook,
1963 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1964   emacs_cv_var___after_morecore_hook=yes,
1965   emacs_cv_var___after_morecore_hook=no)])
1966 if test $emacs_cv_var___after_morecore_hook = no; then
1967   doug_lea_malloc=no
1968 fi
1969 if test "${system_malloc}" = "yes"; then
1970   GNU_MALLOC=no
1971   GNU_MALLOC_reason="
1972     (The GNU allocators don't work with this system configuration.)"
1973 fi
1974 if test "$doug_lea_malloc" = "yes" ; then
1975   if test "$GNU_MALLOC" = yes ; then
1976     GNU_MALLOC_reason="
1977       (Using Doug Lea's new malloc from the GNU C Library.)"
1978   fi
1979   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1980             [Define to 1 if you are using the GNU C Library.])
1981 fi
1982
1983 if test x"${REL_ALLOC}" = x; then
1984   REL_ALLOC=${GNU_MALLOC}
1985 fi
1986
1987 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1988 dnl the system configuration file (s/*.h) to turn the use of mmap
1989 dnl in the relocating allocator on.
1990
1991 AC_FUNC_MMAP
1992 if test $use_mmap_for_buffers = yes; then
1993   REL_ALLOC=no
1994 fi
1995
1996 LIBS="$libsrc_libs $LIBS"
1997
1998 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1999 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
2000 AC_CHECK_LIB(dnet, dnet_ntoa)
2001 dnl This causes -lresolv to get used in subsequent tests,
2002 dnl which causes failures on some systems such as HPUX 9.
2003 dnl AC_CHECK_LIB(resolv, gethostbyname)
2004
2005 dnl FIXME replace main with a function we actually want from this library.
2006 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
2007
2008 AC_CHECK_LIB(pthreads, cma_open)
2009
2010 AC_MSG_CHECKING(for XFree86 in /usr/X386)
2011 if test -d /usr/X386/include; then
2012   HAVE_XFREE386=yes
2013   : ${C_SWITCH_X_SITE="-I/usr/X386/include"}
2014 else
2015   HAVE_XFREE386=no
2016 fi
2017 AC_MSG_RESULT($HAVE_XFREE386)
2018
2019 dnl Check for need for bigtoc support on IBM AIX
2020
2021 case ${host_os} in
2022 aix*)
2023   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
2024     case $GCC in
2025     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
2026     *) gdb_cv_bigtoc=-bbigtoc ;;
2027     esac
2028
2029     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
2030     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
2031   ])
2032   ;;
2033 esac
2034
2035 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
2036 # used for the tests that follow.  We set them back to REAL_CFLAGS and
2037 # REAL_CPPFLAGS later on.
2038
2039 REAL_CPPFLAGS="$CPPFLAGS"
2040
2041 if test "${HAVE_X11}" = "yes"; then
2042   DEFS="$C_SWITCH_X_SITE $DEFS"
2043   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
2044   LIBS="$LIBX $LIBS"
2045   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
2046   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
2047
2048   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
2049   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
2050   # but it's more convenient here to set LD_RUN_PATH
2051   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
2052   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
2053     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
2054     export LD_RUN_PATH
2055   fi
2056
2057   if test "${opsys}" = "gnu-linux"; then
2058     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
2059     AC_TRY_LINK([],
2060      [XOpenDisplay ("foo");],
2061      [xlinux_first_failure=no],
2062      [xlinux_first_failure=yes])
2063     if test "${xlinux_first_failure}" = "yes"; then
2064       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
2065       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
2066       OLD_CPPFLAGS="$CPPFLAGS"
2067       OLD_LIBS="$LIBS"
2068       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
2069       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
2070       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
2071       LIBS="$LIBS -b i486-linuxaout"
2072       AC_TRY_LINK([],
2073        [XOpenDisplay ("foo");],
2074        [xlinux_second_failure=no],
2075        [xlinux_second_failure=yes])
2076       if test "${xlinux_second_failure}" = "yes"; then
2077         # If we get the same failure with -b, there is no use adding -b.
2078         # So take it out.  This plays safe.
2079         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
2080         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
2081         CPPFLAGS="$OLD_CPPFLAGS"
2082         LIBS="$OLD_LIBS"
2083         AC_MSG_RESULT(no)
2084       else
2085         AC_MSG_RESULT(yes)
2086       fi
2087     else
2088       AC_MSG_RESULT(no)
2089     fi
2090   fi
2091
2092   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
2093   # header files included from there.
2094   AC_MSG_CHECKING(for Xkb)
2095   AC_TRY_LINK([#include <X11/Xlib.h>
2096 #include <X11/XKBlib.h>],
2097         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
2098         emacs_xkb=yes, emacs_xkb=no)
2099   AC_MSG_RESULT($emacs_xkb)
2100   if test $emacs_xkb = yes; then
2101     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
2102   fi
2103
2104   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
2105 XScreenNumberOfScreen XSetWMProtocols)
2106 fi
2107
2108 if test "${window_system}" = "x11"; then
2109   AC_MSG_CHECKING(X11 version 6)
2110   AC_CACHE_VAL(emacs_cv_x11_version_6,
2111   [AC_TRY_LINK([#include <X11/Xlib.h>],
2112 [#if XlibSpecificationRelease < 6
2113 fail;
2114 #endif
2115 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
2116   if test $emacs_cv_x11_version_6 = yes; then
2117     AC_MSG_RESULT(6 or newer)
2118     AC_DEFINE(HAVE_X11R6, 1,
2119               [Define to 1 if you have the X11R6 or newer version of Xlib.])
2120   else
2121     AC_MSG_RESULT(before 6)
2122   fi
2123 fi
2124
2125 if test "${window_system}" = "x11"; then
2126   AC_MSG_CHECKING(X11 version 5)
2127   AC_CACHE_VAL(emacs_cv_x11_version_5,
2128   [AC_TRY_LINK([#include <X11/Xlib.h>],
2129 [#if XlibSpecificationRelease < 5
2130 fail;
2131 #endif
2132 ], emacs_cv_x11_version_5=yes, emacs_cv_x11_version_5=no)])
2133   if test $emacs_cv_x11_version_5 = yes; then
2134     AC_MSG_RESULT(5 or newer)
2135     HAVE_X11R5=yes
2136     AC_DEFINE(HAVE_X11R5, 1,
2137               [Define to 1 if you have the X11R5 or newer version of Xlib.])
2138   else
2139     HAVE_X11R5=no
2140     AC_MSG_RESULT(before 5)
2141   fi
2142 fi
2143
2144 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
2145 HAVE_RSVG=no
2146 if test "${HAVE_X11}" = "yes" || test "${HAVE_CARBON}" = "yes"; then
2147   if test "${with_rsvg}" != "no"; then
2148     dnl Check if `--with-pkg-config-prog' has been given.
2149     if test "X${with_pkg_config_prog}" != X; then
2150       PKG_CONFIG="${with_pkg_config_prog}"
2151     fi
2152
2153     RSVG_REQUIRED=2.0.0
2154     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
2155
2156     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
2157     AC_SUBST(RSVG_CFLAGS)
2158     AC_SUBST(RSVG_LIBS)
2159
2160     if test ".${RSVG_CFLAGS}" != "."; then
2161       HAVE_RSVG=yes
2162       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
2163       CFLAGS="$CFLAGS $RSVG_CFLAGS"
2164       LIBS="$RSVG_LIBS $LIBS"
2165     fi
2166   fi
2167 fi
2168
2169
2170 HAVE_GTK=no
2171 if test "${with_gtk}" = "yes" && test "$USE_X_TOOLKIT" = "gtk"; then
2172   USE_X_TOOLKIT=none
2173 fi
2174 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "gtk" || \
2175  test "$USE_X_TOOLKIT" = "maybe"; then
2176   if test "$USE_X_TOOLKIT" != "none" && test "$USE_X_TOOLKIT" != "maybe"; then
2177     AC_MSG_ERROR([Conflicting options, --with-gtk is incompatible with --with-x-toolkit=${with_x_toolkit}]);
2178   fi
2179   GLIB_REQUIRED=2.4
2180   GTK_REQUIRED=2.4
2181   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2182
2183   dnl Check if --with-pkg-config-prog has been given.
2184   if test "X${with_pkg_config_prog}" != X; then
2185     PKG_CONFIG="${with_pkg_config_prog}"
2186   fi
2187   dnl Checks for libraries.
2188   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
2189   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
2190      AC_MSG_ERROR($GTK_PKG_ERRORS)
2191   fi
2192 fi
2193
2194
2195 if test x"$pkg_check_gtk" = xyes; then
2196
2197   AC_SUBST(GTK_CFLAGS)
2198   AC_SUBST(GTK_LIBS)
2199   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
2200   CFLAGS="$CFLAGS $GTK_CFLAGS"
2201   LIBS="$GTK_LIBS $LIBS"
2202   dnl Try to compile a simple GTK program.
2203   GTK_COMPILES=no
2204   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
2205   if test "${GTK_COMPILES}" != "yes"; then
2206     if test "$USE_X_TOOLKIT" != "maybe"; then
2207       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
2208     fi
2209   else
2210     HAVE_GTK=yes
2211     AC_DEFINE(HAVE_GTK, 1, [Define to 1 if using GTK.])
2212     USE_X_TOOLKIT=none
2213   fi
2214
2215 fi
2216
2217
2218 if test "${HAVE_GTK}" = "yes"; then
2219
2220   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2221   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
2222   if test "$with_toolkit_scroll_bars" != no; then
2223     with_toolkit_scroll_bars=yes
2224   fi
2225
2226   dnl  Check if we can use multiple displays with this GTK version.
2227   dnl  If gdk_display_open exists, assume all others are there also.
2228   HAVE_GTK_MULTIDISPLAY=no
2229   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
2230   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
2231     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
2232               [Define to 1 if GTK can handle more than one display.])
2233   fi
2234
2235   dnl  Check if we have the old file selection dialog.
2236   dnl  If gdk_display_open exists, assume all others are there also.
2237   HAVE_GTK_FILE_SELECTION=no
2238   AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes)
2239
2240   dnl  Check if we have the new file chooser dialog
2241   dnl  If gdk_display_open exists, assume all others are there also.
2242   HAVE_GTK_FILE_CHOOSER=no
2243   AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes)
2244
2245   if test "$HAVE_GTK_FILE_SELECTION" = yes \
2246      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
2247     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
2248               [Define to 1 if GTK has both file selection and chooser dialog.])
2249   fi
2250
2251   dnl Check if pthreads are available.  Emacs only needs this when using
2252   dnl gtk_file_chooser under Gnome.
2253   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
2254     HAVE_GTK_AND_PTHREAD=no
2255     AC_CHECK_HEADERS(pthread.h)
2256     if test "$ac_cv_header_pthread_h"; then
2257       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
2258     fi
2259     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
2260       GTK_LIBS="$GTK_LIBS -lpthread"
2261       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
2262                [Define to 1 if you have GTK and pthread (-lpthread).])
2263     fi
2264   fi
2265 fi
2266
2267 ### Link with -lXft if available to work around a bug.
2268 HAVE_XFT=maybe
2269 if test "${HAVE_GTK}" = "yes"; then
2270   dnl Check if --with-pkg-config-prog has been given.
2271   if test "X${with_pkg_config_prog}" != X; then
2272     PKG_CONFIG="${with_pkg_config_prog}"
2273   fi
2274
2275   PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2276   if test "$HAVE_XFT" != no; then
2277     OLD_CFLAGS="$CPPFLAGS"
2278     OLD_CPPFLAGS="$CFLAGS"
2279     OLD_LIBS="$LIBS"
2280     CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2281     CFLAGS="$CFLAGS $XFT_CFLAGS"
2282     LIBS="$XFT_LIBS $LIBS"
2283     AC_CHECK_HEADER(X11/Xft/Xft.h,
2284       [AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS)])
2285
2286     if test "${HAVE_XFT}" = "yes"; then
2287       AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2288       AC_SUBST(XFT_LIBS)
2289       C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2290     else
2291       CFLAGS="$OLD_CPPFLAGS"
2292       CFLAGS="$OLD_CFLAGS"
2293       LIBS="$OLD_LIBS"
2294     fi
2295   fi
2296 fi
2297
2298 dnl Do not put whitespace before the #include statements below.
2299 dnl Older compilers (eg sunos4 cc) choke on it.
2300 HAVE_XAW3D=no
2301 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2302   if test x"${HAVE_X11R5}" != xyes; then
2303     USE_X_TOOLKIT=none
2304   else
2305     if test "$with_xaw3d" != no; then
2306       AC_MSG_CHECKING(for xaw3d)
2307       AC_CACHE_VAL(emacs_cv_xaw3d,
2308       [AC_TRY_LINK([
2309 #include <X11/Intrinsic.h>
2310 #include <X11/Xaw3d/Simple.h>],
2311         [],
2312         emacs_cv_xaw3d=yes,
2313         emacs_cv_xaw3d=no)])
2314     else
2315       emacs_cv_xaw3d=no
2316     fi
2317     if test $emacs_cv_xaw3d = yes; then
2318       AC_MSG_RESULT([yes; using Lucid toolkit])
2319       USE_X_TOOLKIT=LUCID
2320       HAVE_XAW3D=yes
2321       AC_DEFINE(HAVE_XAW3D, 1,
2322                 [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2323     else
2324       AC_MSG_RESULT(no)
2325       AC_MSG_CHECKING(for libXaw)
2326       AC_CACHE_VAL(emacs_cv_xaw,
2327       [AC_TRY_LINK([
2328 #include <X11/Intrinsic.h>
2329 #include <X11/Xaw/Simple.h>],
2330         [],
2331         emacs_cv_xaw=yes,
2332         emacs_cv_xaw=no)])
2333       if test $emacs_cv_xaw = yes; then
2334         AC_MSG_RESULT([yes; using Lucid toolkit])
2335         USE_X_TOOLKIT=LUCID
2336       elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2337         AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2338       else
2339         AC_MSG_RESULT([no; do not use toolkit by default])
2340         USE_X_TOOLKIT=none
2341       fi
2342     fi
2343   fi
2344 fi
2345
2346 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2347
2348 if test "${USE_X_TOOLKIT}" != "none"; then
2349   AC_MSG_CHECKING(X11 toolkit version)
2350   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2351   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
2352 [#if XtSpecificationRelease < 6
2353 fail;
2354 #endif
2355 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2356   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2357   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2358     AC_MSG_RESULT(6 or newer)
2359     AC_DEFINE(HAVE_X11XTR6, 1,
2360               [Define to 1 if you have the X11R6 or newer version of Xt.])
2361   else
2362     AC_MSG_RESULT(before 6)
2363   fi
2364
2365 dnl If using toolkit, check whether libXmu.a exists.
2366 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2367   OLDLIBS="$LIBS"
2368   if test x$HAVE_X11XTR6 = xyes; then
2369     LIBS="-lXt -lSM -lICE $LIBS"
2370   else
2371     LIBS="-lXt $LIBS"
2372   fi
2373   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2374   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2375 fi
2376
2377 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2378 if test "${HAVE_X11}" = "yes"; then
2379   if test "${USE_X_TOOLKIT}" != "none"; then
2380     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2381   fi
2382 fi
2383
2384 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2385   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2386   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
2387     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2388 int x = 5;
2389 #else
2390 Motif version prior to 2.1.
2391 #endif],
2392     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2393   HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
2394   if test $emacs_cv_motif_version_2_1 = yes; then
2395     HAVE_LIBXP=no
2396     AC_DEFINE(HAVE_MOTIF_2_1, 1,
2397               [Define to 1 if you have Motif 2.1 or newer.])
2398     AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
2399     if test ${HAVE_LIBXP} = yes; then
2400       AC_DEFINE(HAVE_LIBXP, 1,
2401                 [Define to 1 if you have the Xp library (-lXp).])
2402     fi
2403   else
2404     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2405     # We put this in CFLAGS temporarily to precede other -I options
2406     # that might be in CFLAGS temporarily.
2407     # We put this in CPPFLAGS where it precedes the other -I options.
2408     OLD_CPPFLAGS=$CPPFLAGS
2409     OLD_CFLAGS=$CFLAGS
2410     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2411     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2412     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
2413       [int x = 5;],
2414       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2415     if test $emacs_cv_lesstif = yes; then
2416       # Make sure this -I option remains in CPPFLAGS after it is set
2417       # back to REAL_CPPFLAGS.
2418       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2419       # have those other -I options anyway.  Ultimately, having this
2420       # directory ultimately in CPPFLAGS will be enough.
2421       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2422       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2423     else
2424       CFLAGS=$OLD_CFLAGS
2425       CPPFLAGS=$OLD_CPPFLAGS
2426     fi
2427   fi
2428 fi
2429
2430 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2431 dnl using Motif or Xaw3d is available, and unless
2432 dnl --with-toolkit-scroll-bars=no was specified.
2433
2434 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2435             [Define to 1 if we should use toolkit scroll bars.])dnl
2436 USE_TOOLKIT_SCROLL_BARS=no
2437 if test "${with_toolkit_scroll_bars}" != "no"; then
2438   if test "${USE_X_TOOLKIT}" != "none"; then
2439     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2440       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2441       HAVE_XAW3D=no
2442       USE_TOOLKIT_SCROLL_BARS=yes
2443     elif test "${HAVE_XAW3D}" = "yes"; then
2444       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2445       USE_TOOLKIT_SCROLL_BARS=yes
2446     fi
2447   elif test "${HAVE_GTK}" = "yes"; then
2448     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2449     USE_TOOLKIT_SCROLL_BARS=yes
2450   elif test "${HAVE_CARBON}" = "yes"; then
2451     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2452     USE_TOOLKIT_SCROLL_BARS=yes
2453   fi
2454 fi
2455
2456 dnl See if XIM is available.
2457 AC_TRY_COMPILE([
2458           #include <X11/Xlib.h>
2459           #include <X11/Xresource.h>],
2460          [XIMProc  callback;],
2461          [HAVE_XIM=yes
2462          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2463          HAVE_XIM=no)
2464
2465 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2466
2467 if test "${with_xim}" != "no"; then
2468   AC_DEFINE(USE_XIM, 1,
2469             [Define to 1 if we should use XIM, if it is available.])
2470 fi
2471
2472
2473 if test "${HAVE_XIM}" != "no"; then
2474   late_CFLAGS=$CFLAGS
2475   if test "$GCC" = yes; then
2476     CFLAGS="$CFLAGS --pedantic-errors"
2477   fi
2478   AC_TRY_COMPILE([
2479 #include <X11/Xlib.h>
2480 #include <X11/Xresource.h>],
2481 [Display *display;
2482 XrmDatabase db;
2483 char *res_name;
2484 char *res_class;
2485 XIMProc  callback;
2486 XPointer *client_data;
2487 #ifndef __GNUC__
2488 /* If we're not using GCC, it's probably not XFree86, and this is
2489    probably right, but we can't use something like --pedantic-errors.  */
2490 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2491                                            char*, XIMProc, XPointer*);
2492 #endif
2493 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2494    client_data);],
2495     [emacs_cv_arg6_star=yes])
2496   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2497          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2498 either XPointer or XPointer*.])dnl
2499   if test "$emacs_cv_arg6_star" = yes; then
2500     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2501   else
2502     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2503   fi
2504   CFLAGS=$late_CFLAGS
2505 fi
2506
2507 ### Use -lXpm if available, unless `--with-xpm=no'.
2508 HAVE_XPM=no
2509 if test "${HAVE_X11}" = "yes"; then
2510   if test "${with_xpm}" != "no"; then
2511     AC_CHECK_HEADER(X11/xpm.h,
2512       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2513     if test "${HAVE_XPM}" = "yes"; then
2514       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2515       AC_EGREP_CPP(no_return_alloc_pixels,
2516       [#include "X11/xpm.h"
2517 #ifndef XpmReturnAllocPixels
2518 no_return_alloc_pixels
2519 #endif
2520       ], HAVE_XPM=no, HAVE_XPM=yes)
2521
2522       if test "${HAVE_XPM}" = "yes"; then
2523         AC_MSG_RESULT(yes)
2524       else
2525         AC_MSG_RESULT(no)
2526       fi
2527     fi
2528   fi
2529
2530   if test "${HAVE_XPM}" = "yes"; then
2531     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2532   fi
2533 fi
2534
2535 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2536 HAVE_JPEG=no
2537 if test "${HAVE_X11}" = "yes"; then
2538   if test "${with_jpeg}" != "no"; then
2539     dnl Checking for jpeglib.h can lose because of a redefinition of
2540     dnl  HAVE_STDLIB_H.
2541     AC_CHECK_HEADER(jerror.h,
2542       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2543   fi
2544
2545   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2546   if test "${HAVE_JPEG}" = "yes"; then
2547     AC_DEFINE(HAVE_JPEG)
2548     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2549         [#include <jpeglib.h>
2550          version=JPEG_LIB_VERSION
2551 ],
2552         [AC_DEFINE(HAVE_JPEG)],
2553         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2554         HAVE_JPEG=no])
2555   fi
2556 fi
2557
2558 ### Use -lpng if available, unless `--with-png=no'.
2559 HAVE_PNG=no
2560 if test "${HAVE_X11}" = "yes"; then
2561   if test "${with_png}" != "no"; then
2562     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2563     # in /usr/include/libpng.
2564     AC_CHECK_HEADERS(png.h libpng/png.h)
2565     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2566       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2567     fi
2568   fi
2569
2570   if test "${HAVE_PNG}" = "yes"; then
2571     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2572   fi
2573 fi
2574
2575 ### Use -ltiff if available, unless `--with-tiff=no'.
2576 HAVE_TIFF=no
2577 if test "${HAVE_X11}" = "yes"; then
2578   if test "${with_tiff}" != "no"; then
2579     AC_CHECK_HEADER(tiffio.h,
2580       [tifflibs="-lz -lm"
2581       # At least one tiff package requires the jpeg library.
2582       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2583       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2584   fi
2585
2586   if test "${HAVE_TIFF}" = "yes"; then
2587     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2588   fi
2589 fi
2590
2591 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2592 HAVE_GIF=no
2593 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2594   AC_CHECK_HEADER(gif_lib.h,
2595 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2596 # Earlier versions can crash Emacs.
2597     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, try_libungif=yes)])
2598
2599   if test "$HAVE_GIF" = yes; then
2600       ac_gif_lib_name="-lgif"
2601   fi
2602
2603 # If gif_lib.h but no libgif, try libungif.
2604   if test x"$try_libungif" = xyes; then
2605     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes)
2606
2607     if test "$HAVE_GIF" = yes; then
2608       AC_DEFINE(LIBGIF, -lungif, [Compiler option to link with the gif library (if not -lgif).])
2609       ac_gif_lib_name="-lungif"
2610     fi
2611   fi
2612
2613   if test "${HAVE_GIF}" = "yes"; then
2614     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif library (default -lgif; otherwise specify with LIBGIF).])
2615   fi
2616 fi
2617
2618 dnl Check for required libraries.
2619 if test "${HAVE_X11}" = "yes"; then
2620   MISSING=""
2621   WITH_NO=""
2622   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2623     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2624   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2625     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2626   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2627     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2628   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2629     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2630   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2631     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2632
2633   if test "X${MISSING}" != X; then
2634     AC_MSG_ERROR([The following required libraries were not found:
2635     $MISSING
2636 Maybe some development libraries/packages are missing?
2637 If you don't want to link with them give
2638     $WITH_NO
2639 as options to configure])
2640   fi
2641 fi
2642
2643 ### Use -lgpm if available, unless `--with-gpm=no'.
2644 HAVE_GPM=no
2645 if test "${with_gpm}" != "no"; then
2646   AC_CHECK_HEADER(gpm.h,
2647     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2648 fi
2649
2650 if test "${HAVE_GPM}" = "yes"; then
2651   AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2652 fi
2653
2654 dnl Check for malloc/malloc.h on darwin
2655 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2656
2657 ### Use Mac OS X Carbon API to implement GUI.
2658 if test "${HAVE_CARBON}" = "yes"; then
2659   AC_DEFINE(HAVE_CARBON, 1, [Define to 1 if you are using the Carbon API on Mac OS X.])
2660   ## Specify the install directory
2661   carbon_appdir=
2662   if test "${carbon_appdir_x}" != ""; then
2663     case ${carbon_appdir_x} in
2664       y | ye | yes)  carbon_appdir=/Applications ;;
2665       * ) carbon_appdir=${carbon_appdir_x} ;;
2666     esac
2667   fi
2668   # We also have mouse menus.
2669   HAVE_MENUS=yes
2670 fi
2671
2672 ### Use session management (-lSM -lICE) if available
2673 HAVE_X_SM=no
2674 if test "${HAVE_X11}" = "yes"; then
2675   AC_CHECK_HEADER(X11/SM/SMlib.h,
2676     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2677
2678   if test "${HAVE_X_SM}" = "yes"; then
2679     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2680     case "$LIBS" in
2681       *-lSM*) ;;
2682       *)      LIBS="-lSM -lICE $LIBS" ;;
2683     esac
2684   fi
2685 fi
2686
2687 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2688 AC_CACHE_CHECK(whether netdb declares h_errno,
2689                emacs_cv_netdb_declares_h_errno,
2690 [AC_TRY_LINK([#include <netdb.h>],
2691   [return h_errno;],
2692   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2693 if test $emacs_cv_netdb_declares_h_errno = yes; then
2694   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2695 fi
2696
2697 AC_FUNC_ALLOCA
2698
2699 # fmod, logb, and frexp are found in -lm on most systems.
2700 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2701 AC_CHECK_LIB(m, sqrt)
2702
2703 # Check for mail-locking functions in a "mail" library.  Probably this should
2704 # have the same check as for liblockfile below.
2705 AC_CHECK_LIB(mail, maillock)
2706 dnl Debian, at least:
2707 AC_CHECK_LIB(lockfile, maillock)
2708 # If we have the shared liblockfile, assume we must use it for mail
2709 # locking (e.g. Debian).  If we couldn't link against liblockfile
2710 # (no liblockfile.a installed), ensure that we don't need to.
2711 if test "$ac_cv_lib_lockfile_maillock" = no; then
2712   dnl This works for files generally, not just executables.
2713   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2714   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2715                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2716   if test $ac_cv_prog_liblockfile = yes; then
2717     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2718 This probably means that movemail could lose mail.
2719 There may be a `development' package to install containing liblockfile.])
2720   else :
2721   fi
2722 fi
2723 AC_CHECK_FUNCS(touchlock)
2724 AC_CHECK_HEADERS(maillock.h)
2725
2726 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2727 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2728 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime res_init setsid \
2729 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2730 utimes setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2731 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2732 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2733 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2734 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign)
2735
2736 AC_CHECK_HEADERS(sys/un.h)
2737
2738 AC_FUNC_MKTIME
2739 if test "$ac_cv_func_working_mktime" = no; then
2740   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2741 fi
2742
2743 AC_FUNC_GETLOADAVG
2744
2745 AC_FUNC_FSEEKO
2746
2747 # Configure getopt.
2748 m4_include([m4/getopt.m4])
2749 gl_GETOPT_IFELSE([
2750   gl_GETOPT_SUBSTITUTE_HEADER
2751   gl_PREREQ_GETOPT
2752   GETOPTOBJS='getopt.o getopt1.o'
2753 ])
2754 AC_SUBST(GETOPTOBJS)
2755
2756 AC_FUNC_GETPGRP
2757
2758 AC_FUNC_STRFTIME
2759
2760 # UNIX98 PTYs.
2761 AC_CHECK_FUNCS(grantpt)
2762
2763 # PTY-related GNU extensions.
2764 AC_CHECK_FUNCS(getpt)
2765
2766 # Check this now, so that we will NOT find the above functions in ncurses.
2767 # That is because we have not set up to link ncurses in lib-src.
2768 # It's better to believe a function is not available
2769 # than to expect to find it in ncurses.
2770 AC_CHECK_LIB(ncurses, tparm)
2771
2772 # Do we need the Hesiod library to provide the support routines?
2773 if test "$with_hesiod" = yes ; then
2774   # Don't set $LIBS here -- see comments above.
2775   resolv=no
2776   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2777      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2778                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2779   if test "$resolv" = yes ; then
2780     RESOLVLIB=-lresolv
2781     AC_DEFINE(HAVE_LIBRESOLV, 1,
2782               [Define to 1 if you have the resolv library (-lresolv).])
2783   else
2784     RESOLVLIB=
2785   fi
2786   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2787         [AC_DEFINE(HAVE_LIBHESIOD, 1,
2788                   [Define to 1 if you have the hesiod library (-lhesiod).])],
2789         :, $RESOLVLIB)])
2790 fi
2791
2792 # These tell us which Kerberos-related libraries to use.
2793 if test "${with_kerberos+set}" = set; then
2794   AC_CHECK_LIB(com_err, com_err)
2795   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
2796   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
2797   AC_CHECK_LIB(krb5, krb5_init_context)
2798   if test "${with_kerberos5+set}" != set; then
2799     AC_CHECK_LIB(des425, des_cbc_encrypt,,
2800                  [AC_CHECK_LIB(des, des_cbc_encrypt)])
2801     AC_CHECK_LIB(krb4, krb_get_cred,,
2802                  [AC_CHECK_LIB(krb, krb_get_cred)])
2803   fi
2804
2805   if test "${with_kerberos5+set}" = set; then
2806     AC_CHECK_HEADERS(krb5.h)
2807   else
2808     AC_CHECK_HEADERS(des.h,,
2809                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2810                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2811     AC_CHECK_HEADERS(krb.h,,
2812                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2813                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2814   fi
2815   AC_CHECK_HEADERS(com_err.h)
2816 fi
2817
2818 # Solaris requires -lintl if you want strerror (which calls dgettext)
2819 # to return localized messages.
2820 AC_CHECK_LIB(intl, dgettext)
2821
2822 AC_MSG_CHECKING(whether localtime caches TZ)
2823 AC_CACHE_VAL(emacs_cv_localtime_cache,
2824 [if test x$ac_cv_func_tzset = xyes; then
2825 AC_TRY_RUN([#include <time.h>
2826 extern char **environ;
2827 unset_TZ ()
2828 {
2829   char **from, **to;
2830   for (to = from = environ; (*to = *from); from++)
2831     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2832       to++;
2833 }
2834 char TZ_GMT0[] = "TZ=GMT0";
2835 char TZ_PST8[] = "TZ=PST8";
2836 main()
2837 {
2838   time_t now = time ((time_t *) 0);
2839   int hour_GMT0, hour_unset;
2840   if (putenv (TZ_GMT0) != 0)
2841     exit (1);
2842   hour_GMT0 = localtime (&now)->tm_hour;
2843   unset_TZ ();
2844   hour_unset = localtime (&now)->tm_hour;
2845   if (putenv (TZ_PST8) != 0)
2846     exit (1);
2847   if (localtime (&now)->tm_hour == hour_GMT0)
2848     exit (1);
2849   unset_TZ ();
2850   if (localtime (&now)->tm_hour != hour_unset)
2851     exit (1);
2852   exit (0);
2853 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2854 [# If we have tzset, assume the worst when cross-compiling.
2855 emacs_cv_localtime_cache=yes])
2856 else
2857         # If we lack tzset, report that localtime does not cache TZ,
2858         # since we can't invalidate the cache if we don't have tzset.
2859         emacs_cv_localtime_cache=no
2860 fi])dnl
2861 AC_MSG_RESULT($emacs_cv_localtime_cache)
2862 if test $emacs_cv_localtime_cache = yes; then
2863   AC_DEFINE(LOCALTIME_CACHE, 1,
2864             [Define to 1 if localtime caches TZ.])
2865 fi
2866
2867 if test "x$HAVE_TIMEVAL" = xyes; then
2868   AC_CHECK_FUNCS(gettimeofday)
2869   if test $ac_cv_func_gettimeofday = yes; then
2870     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2871                    emacs_cv_gettimeofday_two_arguments,
2872     [AC_TRY_COMPILE([
2873 #ifdef TIME_WITH_SYS_TIME
2874 #include <sys/time.h>
2875 #include <time.h>
2876 #else
2877 #ifdef HAVE_SYS_TIME_H
2878 #include <sys/time.h>
2879 #else
2880 #include <time.h>
2881 #endif
2882 #endif],
2883       [struct timeval time;
2884        gettimeofday (&time, 0);],
2885       emacs_cv_gettimeofday_two_arguments=yes,
2886       emacs_cv_gettimeofday_two_arguments=no)])
2887     if test $emacs_cv_gettimeofday_two_arguments = no; then
2888       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2889                 [Define to 1 if gettimeofday accepts only one argument.])
2890     fi
2891   fi
2892 fi
2893
2894 ok_so_far=yes
2895 AC_CHECK_FUNC(socket, , ok_so_far=no)
2896 if test $ok_so_far = yes; then
2897   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2898 fi
2899 if test $ok_so_far = yes; then
2900   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2901 fi
2902 if test $ok_so_far = yes; then
2903 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2904   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2905             [Define to 1 if you have inet sockets.])
2906 fi
2907
2908 AC_CHECK_HEADERS(sys/ioctl.h)
2909
2910 if test -f /usr/lpp/X11/bin/smt.exp; then
2911   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2912             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2913 fi
2914
2915 AC_MSG_CHECKING(whether system supports dynamic ptys)
2916 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2917   AC_MSG_RESULT(yes)
2918   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2919 else
2920   AC_MSG_RESULT(no)
2921 fi
2922
2923 AC_FUNC_FORK
2924
2925 dnl Adapted from Haible's version.
2926 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2927   [AC_TRY_LINK([#include <langinfo.h>],
2928     [char* cs = nl_langinfo(CODESET);],
2929     emacs_cv_langinfo_codeset=yes,
2930     emacs_cv_langinfo_codeset=no)
2931   ])
2932 if test $emacs_cv_langinfo_codeset = yes; then
2933   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2934     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2935 fi
2936
2937 AC_CHECK_TYPES(size_t)
2938
2939 AC_TYPE_MBSTATE_T
2940
2941 dnl Restrict could probably be used effectively other than in regex.c.
2942 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2943   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2944                   emacs_cv_c_restrict=yes,
2945                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2946                                   emacs_cv_c_restrict=__restrict,
2947                                   emacs_cv_c_restrict=no)])])
2948 case "$emacs_cv_c_restrict" in
2949   yes) emacs_restrict=restrict;;
2950   no) emacs_restrict="";;
2951   *) emacs_restrict="$emacs_cv_c_restrict";;
2952 esac
2953 if test "$emacs_restrict" != __restrict; then
2954   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2955     [Define to compiler's equivalent of C99 restrict keyword.
2956      Don't define if equivalent is `__restrict'.])
2957 fi
2958
2959 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2960   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2961                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2962 if test "$emacs_cv_c_restrict_arr" = yes; then
2963   AC_DEFINE(__restrict_arr, __restrict,
2964     [Define to compiler's equivalent of C99 restrict keyword in array
2965      declarations.  Define as empty for no equivalent.])
2966 fi
2967
2968 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2969 dnl how the tty code is related to POSIX and/or other versions of termios.
2970 dnl The following looks like a useful start.
2971 dnl
2972 dnl AC_SYS_POSIX_TERMIOS
2973 dnl if test $ac_cv_sys_posix_termios = yes; then
2974 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2975 dnl                                and macros for terminal control.])
2976 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2977 dnl fi
2978
2979 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
2980
2981 # Set up the CFLAGS for real compilation, so we can substitute it.
2982 CFLAGS="$REAL_CFLAGS"
2983 CPPFLAGS="$REAL_CPPFLAGS"
2984
2985 #### Find out which version of Emacs this is.
2986 [version=`grep 'defconst[        ]*emacs-version' ${srcdir}/lisp/version.el \
2987          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2988 if test x"${version}" = x; then
2989   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2990 fi
2991
2992 ### Specify what sort of things we'll be editing into Makefile and config.h.
2993 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2994 AC_SUBST(version)
2995 AC_SUBST(configuration)
2996 AC_SUBST(canonical)
2997 AC_SUBST(srcdir)
2998 AC_SUBST(prefix)
2999 AC_SUBST(exec_prefix)
3000 AC_SUBST(bindir)
3001 AC_SUBST(datadir)
3002 AC_SUBST(sharedstatedir)
3003 AC_SUBST(libexecdir)
3004 AC_SUBST(mandir)
3005 AC_SUBST(infodir)
3006 AC_SUBST(lispdir)
3007 AC_SUBST(locallisppath)
3008 AC_SUBST(lisppath)
3009 AC_SUBST(x_default_search_path)
3010 AC_SUBST(etcdir)
3011 AC_SUBST(archlibdir)
3012 AC_SUBST(docdir)
3013 AC_SUBST(bitmapdir)
3014 AC_SUBST(gamedir)
3015 AC_SUBST(gameuser)
3016 AC_SUBST(c_switch_system)
3017 AC_SUBST(c_switch_machine)
3018 AC_SUBST(LD_SWITCH_X_SITE)
3019 AC_SUBST(LD_SWITCH_X_SITE_AUX)
3020 AC_SUBST(C_SWITCH_X_SITE)
3021 AC_SUBST(CFLAGS)
3022 AC_SUBST(X_TOOLKIT_TYPE)
3023 AC_SUBST(machfile)
3024 AC_SUBST(opsysfile)
3025 AC_SUBST(GETLOADAVG_LIBS)
3026 AC_SUBST(carbon_appdir)
3027
3028 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3029                    [Define to the canonical Emacs configuration name.])
3030 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3031                    [Define to the options passed to configure.])
3032 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3033                    [Define to the used machine dependent file.])
3034 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3035                    [Define to the used os dependent file.])
3036 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
3037 [Define LD_SWITCH_X_SITE to contain any special flags your loader
3038  may need to deal with X Windows.  For instance, if you've defined
3039  HAVE_X_WINDOWS above and your X libraries aren't in a place that
3040  your loader can find on its own, you might want to add "-L/..." or
3041  something similar.])
3042 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
3043                    [Define LD_SWITCH_X_SITE_AUX with an -R option
3044                     in case it's needed (for Solaris, for example).])
3045 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE},
3046 [Define C_SWITCH_X_SITE to contain any special flags your compiler
3047  may need to deal with X Windows.  For instance, if you've defined
3048  HAVE_X_WINDOWS above and your X include files aren't in a place
3049  that your compiler can find on its own, you might want to add
3050  "-I/..." or something similar.])
3051 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC},
3052                    [Define to the unexec source file name.])
3053
3054 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3055   AC_DEFINE(HAVE_X_WINDOWS, 1,
3056             [Define to 1 if you want to use the X window system.])
3057 fi
3058 if test "${USE_X_TOOLKIT}" != "none" ; then
3059   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3060 fi
3061 if test "${HAVE_X11}" = "yes" ; then
3062   AC_DEFINE(HAVE_X11, 1,
3063             [Define to 1 if you want to use version 11 of X windows.
3064              Otherwise, Emacs expects to use version 10.])
3065 fi
3066 if test "${HAVE_XFREE386}" = "yes" ; then
3067   AC_DEFINE(HAVE_XFREE386, 1, [Define to 1 if you're using XFree386.])
3068 fi
3069 if test "${HAVE_MENUS}" = "yes" ; then
3070   AC_DEFINE(HAVE_MENUS, 1,
3071             [Define to 1 if you have mouse menus.
3072              (This is automatic if you use X, but the option to specify it remains.)
3073              It is also defined with other window systems that support xmenu.c.])
3074 fi
3075 if test "${GNU_MALLOC}" = "yes" ; then
3076   AC_DEFINE(GNU_MALLOC, 1,
3077             [Define to 1 if you want to use the GNU memory allocator.])
3078 fi
3079 if test "${REL_ALLOC}" = "yes" ; then
3080   AC_DEFINE(REL_ALLOC, 1,
3081             [Define REL_ALLOC if you want to use the relocating allocator for
3082              buffer space.])
3083 fi
3084
3085
3086 AH_TOP([/* GNU Emacs site configuration template file.
3087    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005, 2006, 2007
3088              Free Software Foundation, Inc.
3089
3090 This file is part of GNU Emacs.
3091
3092 GNU Emacs is free software; you can redistribute it and/or modify
3093 it under the terms of the GNU General Public License as published by
3094 the Free Software Foundation; either version 3, or (at your option)
3095 any later version.
3096
3097 GNU Emacs is distributed in the hope that it will be useful,
3098 but WITHOUT ANY WARRANTY; without even the implied warranty of
3099 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3100 GNU General Public License for more details.
3101
3102 You should have received a copy of the GNU General Public License
3103 along with GNU Emacs; see the file COPYING.  If not, write to the
3104 Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
3105 Boston, MA 02110-1301, USA.  */
3106
3107
3108 /* No code in Emacs #includes config.h twice, but some bits of code
3109    intended to work with other packages as well (like gmalloc.c)
3110    think they can include it as many times as they like.  */
3111 #ifndef EMACS_CONFIG_H
3112 #define EMACS_CONFIG_H
3113 ])dnl
3114
3115 AH_BOTTOM([
3116 /* If we're using any sort of window system, define some consequences.  */
3117 #ifdef HAVE_X_WINDOWS
3118 #define HAVE_WINDOW_SYSTEM
3119 #define MULTI_KBOARD
3120 #define HAVE_MOUSE
3121 #endif
3122
3123 /* Multi-tty support relies on MULTI_KBOARD.  It seems safe to turn it
3124    on unconditionally.  Note that src/s/darwin.h disables this at
3125    present.  */
3126 #ifndef MULTI_KBOARD
3127 #define MULTI_KBOARD
3128 #endif
3129
3130 /* If we're using the Carbon API on Mac OS X, define a few more
3131    variables as well.  */
3132 #ifdef HAVE_CARBON
3133 #define HAVE_WINDOW_SYSTEM
3134 #define HAVE_MOUSE
3135 #endif
3136
3137 /* Define USER_FULL_NAME to return a string
3138    that is the user's full name.
3139    It can assume that the variable `pw'
3140    points to the password file entry for this user.
3141
3142    At some sites, the pw_gecos field contains
3143    the user's full name.  If neither this nor any other
3144    field contains the right thing, use pw_name,
3145    giving the user's login name, since that is better than nothing.  */
3146 #define USER_FULL_NAME pw->pw_gecos
3147
3148 /* Define AMPERSAND_FULL_NAME if you use the convention
3149    that & in the full name stands for the login id.  */
3150 /* Turned on June 1996 supposing nobody will mind it.  */
3151 #define AMPERSAND_FULL_NAME
3152
3153 /* We have blockinput.h.  */
3154 #define DO_BLOCK_INPUT
3155
3156 /* Define HAVE_SOUND if we have sound support.  We know it works
3157    and compiles only on the specified platforms.   For others,
3158    it probably doesn't make sense to try.  */
3159
3160 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
3161 #ifdef HAVE_MACHINE_SOUNDCARD_H
3162 #define HAVE_SOUND 1
3163 #endif
3164 #ifdef HAVE_SYS_SOUNDCARD_H
3165 #define HAVE_SOUND 1
3166 #endif
3167 #ifdef HAVE_SOUNDCARD_H
3168 #define HAVE_SOUND 1
3169 #endif
3170 #ifdef HAVE_ALSA
3171 #define HAVE_SOUND 1
3172 #endif
3173 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
3174
3175 /* If using GNU, then support inline function declarations. */
3176 /* Don't try to switch on inline handling as detected by AC_C_INLINE
3177    generally, because even if non-gcc compilers accept `inline', they
3178    may reject `extern inline'.  */
3179 #if defined (__GNUC__) && defined (OPTIMIZE)
3180 #define INLINE __inline__
3181 #else
3182 #define INLINE
3183 #endif
3184
3185 /* Include the os and machine dependent files.  */
3186 #include config_opsysfile
3187 #include config_machfile
3188
3189 /* Load in the conversion definitions if this system
3190    needs them and the source file being compiled has not
3191    said to inhibit this.  There should be no need for you
3192    to alter these lines.  */
3193
3194 #ifdef SHORTNAMES
3195 #ifndef NO_SHORTNAMES
3196 #include "../shortnames/remap.h"
3197 #endif /* not NO_SHORTNAMES */
3198 #endif /* SHORTNAMES */
3199
3200 /* If no remapping takes place, static variables cannot be dumped as
3201    pure, so don't worry about the `static' keyword. */
3202 #ifdef NO_REMAP
3203 #undef static
3204 #endif
3205
3206 /* Define `subprocesses' should be defined if you want to
3207    have code for asynchronous subprocesses
3208    (as used in M-x compile and M-x shell).
3209    These do not work for some USG systems yet;
3210    for the ones where they work, the s/SYSTEM.h file defines this flag.  */
3211
3212 #ifndef VMS
3213 #ifndef USG
3214 /* #define subprocesses */
3215 #endif
3216 #endif
3217
3218 /* SIGTYPE is the macro we actually use.  */
3219 #ifndef SIGTYPE
3220 #define SIGTYPE RETSIGTYPE
3221 #endif
3222
3223 #ifdef emacs /* Don't do this for lib-src.  */
3224 /* Tell regex.c to use a type compatible with Emacs.  */
3225 #define RE_TRANSLATE_TYPE Lisp_Object
3226 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3227 #ifdef make_number
3228 /* If make_number is a macro, use it.  */
3229 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3230 #else
3231 /* If make_number is a function, avoid it.  */
3232 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3233 #endif
3234 #endif
3235
3236 /* Avoid link-time collision with system mktime if we will use our own.  */
3237 #if ! HAVE_MKTIME || BROKEN_MKTIME
3238 #define mktime emacs_mktime
3239 #endif
3240
3241 #define my_strftime nstrftime   /* for strftime.c */
3242
3243 /* The rest of the code currently tests the CPP symbol BSTRING.
3244    Override any claims made by the system-description files.
3245    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
3246 #undef BSTRING
3247 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
3248 #define BSTRING
3249 #endif
3250
3251 /* Some of the files of Emacs which are intended for use with other
3252    programs assume that if you have a config.h file, you must declare
3253    the type of getenv.
3254
3255    This declaration shouldn't appear when alloca.s or Makefile.in
3256    includes config.h.  */
3257 #ifndef NOT_C_CODE
3258 extern char *getenv ();
3259 #endif
3260
3261 /* These default definitions are good for almost all machines.
3262    The exceptions override them in m/MACHINE.h.  */
3263
3264 #ifndef BITS_PER_CHAR
3265 #define BITS_PER_CHAR 8
3266 #endif
3267
3268 #ifndef BITS_PER_SHORT
3269 #define BITS_PER_SHORT 16
3270 #endif
3271
3272 /* Note that lisp.h uses this in a preprocessor conditional, so it
3273    would not work to use sizeof.  That being so, we do all of them
3274    without sizeof, for uniformity's sake.  */
3275 #ifndef BITS_PER_INT
3276 #define BITS_PER_INT 32
3277 #endif
3278
3279 #ifndef BITS_PER_LONG
3280 #ifdef _LP64
3281 #define BITS_PER_LONG 64
3282 #else
3283 #define BITS_PER_LONG 32
3284 #endif
3285 #endif
3286
3287 /* Define if the compiler supports function prototypes.  It may do so
3288    but not define __STDC__ (e.g. DEC C by default) or may define it as
3289    zero.  */
3290 #undef PROTOTYPES
3291 /* For mktime.c:  */
3292 #ifndef __P
3293 # if defined PROTOTYPES
3294 #  define __P(args) args
3295 # else
3296 #  define __P(args) ()
3297 # endif  /* GCC.  */
3298 #endif /* __P */
3299
3300 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
3301 #ifndef NOT_C_CODE
3302 #ifdef HAVE_STRING_H
3303 #include "string.h"
3304 #endif
3305 #ifdef HAVE_STRINGS_H
3306 #include "strings.h"  /* May be needed for bcopy & al. */
3307 #endif
3308 #ifdef HAVE_STDLIB_H
3309 #include <stdlib.h>
3310 #endif
3311 #ifndef __GNUC__
3312 # ifdef HAVE_ALLOCA_H
3313 #  include <alloca.h>
3314 # else /* AIX files deal with #pragma.  */
3315 #  ifndef alloca /* predefined by HP cc +Olibcalls */
3316 char *alloca ();
3317 #  endif
3318 # endif /* HAVE_ALLOCA_H */
3319 #endif /* __GNUC__ */
3320 #ifndef HAVE_SIZE_T
3321 typedef unsigned size_t;
3322 #endif
3323 #endif /* NOT_C_CODE */
3324
3325 /* Define HAVE_X_I18N if we have usable i18n support.  */
3326
3327 #ifdef HAVE_X11R6
3328 #define HAVE_X_I18N
3329 #elif defined HAVE_X11R5 && !defined X11R5_INHIBIT_I18N
3330 #define HAVE_X_I18N
3331 #endif
3332
3333 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
3334
3335 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
3336 #define HAVE_X11R6_XIM
3337 #endif
3338
3339 /* Should we enable expensive run-time checking of data types?  */
3340 #undef ENABLE_CHECKING
3341
3342 #if defined __GNUC__ && (__GNUC__ > 2 \
3343                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3344 #define NO_RETURN       __attribute__ ((__noreturn__))
3345 #else
3346 #define NO_RETURN       /* nothing */
3347 #endif
3348
3349 /* These won't be used automatically yet.  We also need to know, at least,
3350    that the stack is continuous.  */
3351 #ifdef __GNUC__
3352 #  ifndef GC_SETJMP_WORKS
3353   /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
3354      see NON_SAVING_SETJMP in the target descriptions.  */
3355   /* Exceptions (see NON_SAVING_SETJMP in target description) are ns32k,
3356      SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
3357      Fixme: Deal with ns32k, SVR3.  */
3358 #    define GC_SETJMP_WORKS 1
3359 #  endif
3360 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3361 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3362 #  endif
3363 #endif
3364
3365 #ifndef HAVE_BCOPY
3366 #define bcopy(a,b,s) memcpy (b,a,s)
3367 #endif
3368 #ifndef HAVE_BZERO
3369 #define bzero(a,s) memset (a,0,s)
3370 #endif
3371 #ifndef HAVE_BCMP
3372 #define BCMP memcmp
3373 #endif
3374
3375 #endif /* EMACS_CONFIG_H */
3376
3377 /*
3378 Local Variables:
3379 mode: c
3380 End:
3381 */
3382 ])dnl
3383
3384 #### Report on what we decided to do.
3385 #### Report GTK as a toolkit, even if it doesn't use Xt.
3386 #### It makes printing result more understandable as using GTK sets
3387 #### toolkit_scroll_bars to yes by default.
3388 if test "${HAVE_GTK}" = "yes"; then
3389   USE_X_TOOLKIT=GTK
3390 fi
3391
3392 echo "
3393 Configured for \`${canonical}'.
3394
3395   Where should the build process find the source code?    ${srcdir}
3396   What operating system and machine description files should Emacs use?
3397         \`${opsysfile}' and \`${machfile}'
3398   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3399   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3400   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3401   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3402   What window system should Emacs use?                    ${window_system}
3403   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3404
3405 if test -n "${x_includes}"; then
3406 echo "  Where do we find X Windows header files?                ${x_includes}"
3407 else
3408 echo "  Where do we find X Windows header files?                Standard dirs"
3409 fi
3410 if test -n "${x_libraries}"; then
3411 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3412 else
3413 echo "  Where do we find X Windows libraries?                   Standard dirs"
3414 fi
3415
3416 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3417 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3418 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3419 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3420 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $ac_gif_lib_name"
3421 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3422 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3423 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3424 echo "  Does Emacs use X toolkit scroll bars?                   ${USE_TOOLKIT_SCROLL_BARS}"
3425 echo
3426
3427 if test $USE_XASSERTS = yes; then
3428    echo "  Compiling with asserts turned on."
3429    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3430    echo
3431 fi
3432
3433 if test "$USE_X_TOOLKIT" = GTK; then
3434   case "$canonical" in
3435   *cygwin*)
3436     echo "There are known problems with Emacs and Gtk+ on cygwin, so you
3437   will probably get a crash on startup.  If this happens, please use another
3438   toolkit for Emacs.  See etc/PROBLEMS for more information."
3439   ;;
3440   esac
3441 fi
3442
3443
3444
3445 # Remove any trailing slashes in these variables.
3446 [test "${prefix}" != NONE &&
3447   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3448 test "${exec_prefix}" != NONE &&
3449   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3450
3451 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
3452 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
3453 ## from Makefile.c can correctly provide the arg `-traditional' to the
3454 ## C preprocessor.
3455
3456 AC_EGREP_CPP(yes..yes,
3457         [yes..yes],
3458         CPP_NEED_TRADITIONAL=no,
3459         CPP_NEED_TRADITIONAL=yes)
3460
3461 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
3462         man/Makefile lwlib/Makefile src/Makefile.c:src/Makefile.in \
3463         lisp/Makefile lispref/Makefile lispintro/Makefile leim/Makefile, [
3464
3465 ### Make the necessary directories, if they don't exist.
3466 for dir in etc lisp ; do
3467   test -d ${dir} || mkdir ${dir}
3468 done
3469
3470 # Build src/Makefile from ${srcdir}/src/Makefile.c
3471 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
3472 # This must be done after src/config.h is built, since we rely on that file.
3473
3474 # Now get this: Some word that is part of the ${srcdir} directory name
3475 # or the ${configuration} value might, just might, happen to be an
3476 # identifier like `sun4' or `i386' or something, and be predefined by
3477 # the C preprocessor to some helpful value like 1, or maybe the empty
3478 # string.  Needless to say consequent macro substitutions are less
3479 # than conducive to the makefile finding the correct directory.
3480 [undefs="`echo $top_srcdir $configuration $canonical |
3481 sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
3482     -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g' \
3483 `"]
3484
3485 echo creating src/epaths.h
3486 ${MAKE-make} epaths-force
3487
3488 # As of 2000-11-19, newest development versions of GNU cpp preprocess
3489 # `..' to `. .'  unless invoked with -traditional
3490
3491 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
3492   CPPFLAGS="$CPPFLAGS -traditional"
3493 fi
3494
3495 echo creating lib-src/Makefile
3496 ( cd lib-src
3497   rm -f junk.c junk1.c junk2.c
3498   sed -e '/start of cpp stuff/q' \
3499       < Makefile.c > junk1.c
3500   sed -e '1,/start of cpp stuff/d'\
3501       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3502       < Makefile.c > junk.c
3503   $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3504       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3505   cat junk1.c junk2.c > Makefile.new
3506   rm -f junk.c junk1.c junk2.c
3507   chmod 444 Makefile.new
3508   mv -f Makefile.new Makefile
3509 )
3510
3511 echo creating src/Makefile
3512 ( cd src
3513   rm -f junk.c junk1.c junk2.c
3514   sed -e '/start of cpp stuff/q' \
3515       < Makefile.c > junk1.c
3516   sed -e '1,/start of cpp stuff/d'\
3517       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3518       < Makefile.c > junk.c
3519   $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3520       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3521   cat junk1.c junk2.c > Makefile.new
3522   rm -f junk.c junk1.c junk2.c
3523   chmod 444 Makefile.new
3524   mv -f Makefile.new Makefile
3525 )
3526
3527 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3528   echo creating src/.gdbinit
3529   echo source $srcdir/src/.gdbinit > src/.gdbinit
3530 fi
3531
3532 # This is how we know whether to re-run configure in certain cases.
3533 touch src/config.stamp
3534
3535 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS"])
3536
3537 m4_if(dnl       Do not change this comment
3538    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3539 )dnl