code.delx.au - gnu-emacs/blob - lisp/replace.el

   1 ;;; replace.el --- replace commands for Emacs
   2
   3 ;; Copyright (C) 1985, 1986, 1987, 1992, 1994, 1996, 1997, 2000, 2001, 2002,
   4 ;;   2003, 2004, 2005  Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This package supplies the string and regular-expression replace functions
  28 ;; documented in the Emacs user's manual.
  29
  30 ;;; Code:
  31
  32 (defcustom case-replace t
  33   "*Non-nil means `query-replace' should preserve case in replacements."
  34   :type 'boolean
  35   :group 'matching)
  36
  37 (defvar query-replace-history nil)
  38
  39 (defvar query-replace-interactive nil
  40   "Non-nil means `query-replace' uses the last search string.
  41 That becomes the \"string to replace\".")
  42
  43 (defcustom query-replace-from-history-variable 'query-replace-history
  44   "History list to use for the FROM argument of `query-replace' commands.
  45 The value of this variable should be a symbol; that symbol
  46 is used as a variable to hold a history list for the strings
  47 or patterns to be replaced."
  48   :group 'matching
  49   :type 'symbol
  50   :version "20.3")
  51
  52 (defcustom query-replace-to-history-variable 'query-replace-history
  53   "History list to use for the TO argument of `query-replace' commands.
  54 The value of this variable should be a symbol; that symbol
  55 is used as a variable to hold a history list for replacement
  56 strings or patterns."
  57   :group 'matching
  58   :type 'symbol
  59   :version "20.3")
  60
  61 (defcustom query-replace-skip-read-only nil
  62   "*Non-nil means `query-replace' and friends ignore read-only matches."
  63   :type 'boolean
  64   :group 'matching
  65   :version "22.1")
  66
  67 (defcustom query-replace-highlight t
  68   "*Non-nil means to highlight matches during query replacement."
  69   :type 'boolean
  70   :group 'matching)
  71
  72 (defcustom query-replace-lazy-highlight t
  73   "*Controls the lazy-highlighting during query replacements.
  74 When non-nil, all text in the buffer matching the current match
  75 is highlighted lazily using isearch lazy highlighting (see
  76 `lazy-highlight-initial-delay' and `lazy-highlight-interval')."
  77   :type 'boolean
  78   :group 'lazy-highlight
  79   :group 'matching
  80   :version "22.1")
  81
  82 (defface query-replace
  83   '((t (:inherit isearch)))
  84   "Face for highlighting query replacement matches."
  85   :group 'matching
  86   :version "22.1")
  87
  88 (defun query-replace-descr (string)
  89   (mapconcat 'isearch-text-char-description string ""))
  90
  91 (defun query-replace-read-from (string regexp-flag)
  92   "Query and return the `from' argument of a query-replace operation.
  93 The return value can also be a pair (FROM . TO) indicating that the user
  94 wants to replace FROM with TO."
  95   (if query-replace-interactive
  96       (car (if regexp-flag regexp-search-ring search-ring))
  97     (let* ((lastfrom (car (symbol-value query-replace-from-history-variable)))
  98            (lastto (car (symbol-value query-replace-to-history-variable)))
  99            (from
 100             ;; The save-excursion here is in case the user marks and copies
 101             ;; a region in order to specify the minibuffer input.
 102             ;; That should not clobber the region for the query-replace itself.
 103             (save-excursion
 104               (when (equal lastfrom lastto)
 105                 ;; Typically, this is because the two histlists are shared.
 106                 (setq lastfrom (cadr (symbol-value
 107                                       query-replace-from-history-variable))))
 108               (read-from-minibuffer
 109                (if (and lastto lastfrom)
 110                    (format "%s (default %s -> %s): " string
 111                            (query-replace-descr lastfrom)
 112                            (query-replace-descr lastto))
 113                  (format "%s: " string))
 114                nil nil nil
 115                query-replace-from-history-variable
 116                nil t t))))
 117       (if (and (zerop (length from)) lastto lastfrom)
 118           (progn
 119             (set query-replace-from-history-variable
 120                  (cdr (symbol-value query-replace-from-history-variable)))
 121             (cons lastfrom
 122                   (query-replace-compile-replacement lastto regexp-flag)))
 123         ;; Warn if user types \n or \t, but don't reject the input.
 124         (and regexp-flag
 125              (string-match "\\(\\`\\|[^\\]\\)\\(\\\\\\\\\\)*\\(\\\\[nt]\\)" from)
 126              (let ((match (match-string 3 from)))
 127                (cond
 128                 ((string= match "\\n")
 129                  (message "Note: `\\n' here doesn't match a newline; to do that, type C-q C-j instead"))
 130                 ((string= match "\\t")
 131                  (message "Note: `\\t' here doesn't match a tab; to do that, just type TAB")))
 132                (sit-for 2)))
 133         from))))
 134
 135 (defun query-replace-compile-replacement (to regexp-flag)
 136   "Maybe convert a regexp replacement TO to Lisp.
 137 Returns a list suitable for `perform-replace' if necessary,
 138 the original string if not."
 139   (if (and regexp-flag
 140            (string-match "\\(\\`\\|[^\\]\\)\\(\\\\\\\\\\)*\\\\[,#]" to))
 141       (let (pos list char)
 142         (while
 143             (progn
 144               (setq pos (match-end 0))
 145               (push (substring to 0 (- pos 2)) list)
 146               (setq char (aref to (1- pos))
 147                     to (substring to pos))
 148               (cond ((eq char ?\#)
 149                      (push '(number-to-string replace-count) list))
 150                     ((eq char ?\,)
 151                      (setq pos (read-from-string to))
 152                      (push `(replace-quote ,(car pos)) list)
 153                      (let ((end
 154                             ;; Swallow a space after a symbol
 155                             ;; if there is a space.
 156                             (if (and (or (symbolp (car pos))
 157                                          ;; Swallow a space after 'foo
 158                                          ;; but not after (quote foo).
 159                                          (and (eq (car-safe (car pos)) 'quote)
 160                                               (not (= ?\( (aref to 0)))))
 161                                      (eq (string-match " " to (cdr pos))
 162                                          (cdr pos)))
 163                                 (1+ (cdr pos))
 164                               (cdr pos))))
 165                        (setq to (substring to end)))))
 166               (string-match "\\(\\`\\|[^\\]\\)\\(\\\\\\\\\\)*\\\\[,#]" to)))
 167         (setq to (nreverse (delete "" (cons to list))))
 168         (replace-match-string-symbols to)
 169         (cons 'replace-eval-replacement
 170               (if (cdr to)
 171                   (cons 'concat to)
 172                 (car to))))
 173     to))
 174
 175
 176 (defun query-replace-read-to (from string regexp-flag)
 177   "Query and return the `to' argument of a query-replace operation."
 178   (query-replace-compile-replacement
 179    (save-excursion
 180      (read-from-minibuffer
 181       (format "%s %s with: " string (query-replace-descr from))
 182       nil nil nil
 183       query-replace-to-history-variable from t t))
 184    regexp-flag))
 185
 186 (defun query-replace-read-args (string regexp-flag &optional noerror)
 187   (unless noerror
 188     (barf-if-buffer-read-only))
 189   (let* ((from (query-replace-read-from string regexp-flag))
 190          (to (if (consp from) (prog1 (cdr from) (setq from (car from)))
 191                (query-replace-read-to from string regexp-flag))))
 192     (list from to current-prefix-arg)))
 193
 194 (defun query-replace (from-string to-string &optional delimited start end)
 195   "Replace some occurrences of FROM-STRING with TO-STRING.
 196 As each match is found, the user must type a character saying
 197 what to do with it.  For directions, type \\[help-command] at that time.
 198
 199 In Transient Mark mode, if the mark is active, operate on the contents
 200 of the region.  Otherwise, operate from point to the end of the buffer.
 201
 202 If `query-replace-interactive' is non-nil, the last incremental search
 203 string is used as FROM-STRING--you don't have to specify it with the
 204 minibuffer.
 205
 206 Matching is independent of case if `case-fold-search' is non-nil and
 207 FROM-STRING has no uppercase letters.  Replacement transfers the case
 208 pattern of the old text to the new text, if `case-replace' and
 209 `case-fold-search' are non-nil and FROM-STRING has no uppercase
 210 letters.  \(Transferring the case pattern means that if the old text
 211 matched is all caps, or capitalized, then its replacement is upcased
 212 or capitalized.)
 213
 214 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 215 only matches surrounded by word boundaries.
 216 Fourth and fifth arg START and END specify the region to operate on.
 217
 218 To customize possible responses, change the \"bindings\" in `query-replace-map'."
 219   (interactive (let ((common
 220                       (query-replace-read-args
 221                        (if (and transient-mark-mode mark-active)
 222                          "Query replace in region"
 223                          "Query replace")
 224                          nil)))
 225                  (list (nth 0 common) (nth 1 common) (nth 2 common)
 226                        ;; These are done separately here
 227                        ;; so that command-history will record these expressions
 228                        ;; rather than the values they had this time.
 229                        (if (and transient-mark-mode mark-active)
 230                            (region-beginning))
 231                        (if (and transient-mark-mode mark-active)
 232                            (region-end)))))
 233   (perform-replace from-string to-string t nil delimited nil nil start end))
 234
 235 (define-key esc-map "%" 'query-replace)
 236
 237 (defun query-replace-regexp (regexp to-string &optional delimited start end)
 238   "Replace some things after point matching REGEXP with TO-STRING.
 239 As each match is found, the user must type a character saying
 240 what to do with it.  For directions, type \\[help-command] at that time.
 241
 242 In Transient Mark mode, if the mark is active, operate on the contents
 243 of the region.  Otherwise, operate from point to the end of the buffer.
 244
 245 If `query-replace-interactive' is non-nil, the last incremental search
 246 regexp is used as REGEXP--you don't have to specify it with the
 247 minibuffer.
 248
 249 Matching is independent of case if `case-fold-search' is non-nil and
 250 REGEXP has no uppercase letters.  Replacement transfers the case
 251 pattern of the old text to the new text, if `case-replace' and
 252 `case-fold-search' are non-nil and REGEXP has no uppercase letters.
 253 \(Transferring the case pattern means that if the old text matched is
 254 all caps, or capitalized, then its replacement is upcased or
 255 capitalized.)
 256
 257 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 258 only matches surrounded by word boundaries.
 259 Fourth and fifth arg START and END specify the region to operate on.
 260
 261 In TO-STRING, `\\&' stands for whatever matched the whole of REGEXP,
 262 and `\\=\\N' (where N is a digit) stands for
 263 whatever what matched the Nth `\\(...\\)' in REGEXP.
 264 `\\?' lets you edit the replacement text in the minibuffer
 265 at the given position for each replacement.
 266
 267 In interactive calls, the replacement text can contain `\\,'
 268 followed by a Lisp expression.  Each
 269 replacement evaluates that expression to compute the replacement
 270 string.  Inside of that expression, `\\&' is a string denoting the
 271 whole match as a string, `\\N' for a partial match, `\\#&' and `\\#N'
 272 for the whole or a partial match converted to a number with
 273 `string-to-number', and `\\#' itself for the number of replacements
 274 done so far (starting with zero).
 275
 276 If the replacement expression is a symbol, write a space after it
 277 to terminate it.  One space there, if any, will be discarded.
 278
 279 When using those Lisp features interactively in the replacement
 280 text, TO-STRING is actually made a list instead of a string.
 281 Use \\[repeat-complex-command] after this command for details."
 282   (interactive
 283    (let ((common
 284           (query-replace-read-args
 285            (if (and transient-mark-mode mark-active)
 286                "Query replace regexp in region"
 287              "Query replace regexp")
 288            t)))
 289      (list (nth 0 common) (nth 1 common) (nth 2 common)
 290            ;; These are done separately here
 291            ;; so that command-history will record these expressions
 292            ;; rather than the values they had this time.
 293            (if (and transient-mark-mode mark-active)
 294                (region-beginning))
 295            (if (and transient-mark-mode mark-active)
 296                (region-end)))))
 297   (perform-replace regexp to-string t t delimited nil nil start end))
 298
 299 (define-key esc-map [?\C-%] 'query-replace-regexp)
 300
 301 (defun query-replace-regexp-eval (regexp to-expr &optional delimited start end)
 302   "Replace some things after point matching REGEXP with the result of TO-EXPR.
 303 As each match is found, the user must type a character saying
 304 what to do with it.  For directions, type \\[help-command] at that time.
 305
 306 TO-EXPR is a Lisp expression evaluated to compute each replacement.  It may
 307 reference `replace-count' to get the number of replacements already made.
 308 If the result of TO-EXPR is not a string, it is converted to one using
 309 `prin1-to-string' with the NOESCAPE argument (which see).
 310
 311 For convenience, when entering TO-EXPR interactively, you can use `\\&' or
 312 `\\0' to stand for whatever matched the whole of REGEXP, and `\\N' (where
 313 N is a digit) to stand for whatever matched the Nth `\\(...\\)' in REGEXP.
 314 Use `\\#&' or `\\#N' if you want a number instead of a string.
 315 In interactive use, `\\#' in itself stands for `replace-count'.
 316
 317 In Transient Mark mode, if the mark is active, operate on the contents
 318 of the region.  Otherwise, operate from point to the end of the buffer.
 319
 320 If `query-replace-interactive' is non-nil, the last incremental search
 321 regexp is used as REGEXP--you don't have to specify it with the
 322 minibuffer.
 323
 324 Preserves case in each replacement if `case-replace' and `case-fold-search'
 325 are non-nil and REGEXP has no uppercase letters.
 326
 327 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 328 only matches that are surrounded by word boundaries.
 329 Fourth and fifth arg START and END specify the region to operate on."
 330   (interactive
 331    (progn
 332    (barf-if-buffer-read-only)
 333    (let* ((from
 334            ;; Let-bind the history var to disable the "foo -> bar" default.
 335            ;; Maybe we shouldn't disable this default, but for now I'll
 336            ;; leave it off.  --Stef
 337            (let ((query-replace-to-history-variable nil))
 338              (query-replace-read-from "Query replace regexp" t)))
 339           (to (list (read-from-minibuffer
 340                      (format "Query replace regexp %s with eval: "
 341                              (query-replace-descr from))
 342                      nil nil t query-replace-to-history-variable from t))))
 343      ;; We make TO a list because replace-match-string-symbols requires one,
 344      ;; and the user might enter a single token.
 345      (replace-match-string-symbols to)
 346      (list from (car to) current-prefix-arg
 347            (if (and transient-mark-mode mark-active)
 348                (region-beginning))
 349            (if (and transient-mark-mode mark-active)
 350                (region-end))))))
 351   (perform-replace regexp (cons 'replace-eval-replacement to-expr)
 352                    t 'literal delimited nil nil start end))
 353
 354 (defun map-query-replace-regexp (regexp to-strings &optional n start end)
 355   "Replace some matches for REGEXP with various strings, in rotation.
 356 The second argument TO-STRINGS contains the replacement strings,
 357 separated by spaces.  Third arg DELIMITED (prefix arg if interactive),
 358 if non-nil, means replace only matches surrounded by word boundaries.
 359 This command works like `query-replace-regexp' except that each
 360 successive replacement uses the next successive replacement string,
 361 wrapping around from the last such string to the first.
 362
 363 In Transient Mark mode, if the mark is active, operate on the contents
 364 of the region.  Otherwise, operate from point to the end of the buffer.
 365
 366 Non-interactively, TO-STRINGS may be a list of replacement strings.
 367
 368 If `query-replace-interactive' is non-nil, the last incremental search
 369 regexp is used as REGEXP--you don't have to specify it with the minibuffer.
 370
 371 A prefix argument N says to use each replacement string N times
 372 before rotating to the next.
 373 Fourth and fifth arg START and END specify the region to operate on."
 374   (interactive
 375    (let* ((from (if query-replace-interactive
 376                     (car regexp-search-ring)
 377                   (read-from-minibuffer "Map query replace (regexp): "
 378                                         nil nil nil
 379                                         'query-replace-history nil t)))
 380           (to (read-from-minibuffer
 381                (format "Query replace %s with (space-separated strings): "
 382                        (query-replace-descr from))
 383                nil nil nil
 384                'query-replace-history from t)))
 385      (list from to
 386            (and current-prefix-arg
 387                 (prefix-numeric-value current-prefix-arg))
 388            (if (and transient-mark-mode mark-active)
 389                (region-beginning))
 390            (if (and transient-mark-mode mark-active)
 391                (region-end)))))
 392   (let (replacements)
 393     (if (listp to-strings)
 394         (setq replacements to-strings)
 395       (while (/= (length to-strings) 0)
 396         (if (string-match " " to-strings)
 397             (setq replacements
 398                   (append replacements
 399                           (list (substring to-strings 0
 400                                            (string-match " " to-strings))))
 401                   to-strings (substring to-strings
 402                                        (1+ (string-match " " to-strings))))
 403           (setq replacements (append replacements (list to-strings))
 404                 to-strings ""))))
 405     (perform-replace regexp replacements t t nil n nil start end)))
 406
 407 (defun replace-string (from-string to-string &optional delimited start end)
 408   "Replace occurrences of FROM-STRING with TO-STRING.
 409 Preserve case in each match if `case-replace' and `case-fold-search'
 410 are non-nil and FROM-STRING has no uppercase letters.
 411 \(Preserving case means that if the string matched is all caps, or capitalized,
 412 then its replacement is upcased or capitalized.)
 413
 414 In Transient Mark mode, if the mark is active, operate on the contents
 415 of the region.  Otherwise, operate from point to the end of the buffer.
 416
 417 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 418 only matches surrounded by word boundaries.
 419 Fourth and fifth arg START and END specify the region to operate on.
 420
 421 If `query-replace-interactive' is non-nil, the last incremental search
 422 string is used as FROM-STRING--you don't have to specify it with the
 423 minibuffer.
 424
 425 This function is usually the wrong thing to use in a Lisp program.
 426 What you probably want is a loop like this:
 427   (while (search-forward FROM-STRING nil t)
 428     (replace-match TO-STRING nil t))
 429 which will run faster and will not set the mark or print anything.
 430 \(You may need a more complex loop if FROM-STRING can match the null string
 431 and TO-STRING is also null.)"
 432   (interactive
 433    (let ((common
 434           (query-replace-read-args
 435            (if (and transient-mark-mode mark-active)
 436                "Replace string in region"
 437              "Replace string")
 438            nil)))
 439      (list (nth 0 common) (nth 1 common) (nth 2 common)
 440            (if (and transient-mark-mode mark-active)
 441                (region-beginning))
 442            (if (and transient-mark-mode mark-active)
 443                (region-end)))))
 444   (perform-replace from-string to-string nil nil delimited nil nil start end))
 445
 446 (defun replace-regexp (regexp to-string &optional delimited start end)
 447   "Replace things after point matching REGEXP with TO-STRING.
 448 Preserve case in each match if `case-replace' and `case-fold-search'
 449 are non-nil and REGEXP has no uppercase letters.
 450
 451 In Transient Mark mode, if the mark is active, operate on the contents
 452 of the region.  Otherwise, operate from point to the end of the buffer.
 453
 454 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 455 only matches surrounded by word boundaries.
 456 Fourth and fifth arg START and END specify the region to operate on.
 457
 458 In TO-STRING, `\\&' stands for whatever matched the whole of REGEXP,
 459 and `\\=\\N' (where N is a digit) stands for
 460 whatever what matched the Nth `\\(...\\)' in REGEXP.
 461 `\\?' lets you edit the replacement text in the minibuffer
 462 at the given position for each replacement.
 463
 464 In interactive calls, the replacement text may contain `\\,'
 465 followed by a Lisp expression used as part of the replacement
 466 text.  Inside of that expression, `\\&' is a string denoting the
 467 whole match, `\\N' a partial matches, `\\#&' and `\\#N' the
 468 respective numeric values from `string-to-number', and `\\#'
 469 itself for `replace-count', the number of replacements occured so
 470 far.
 471
 472 If your Lisp expression is an identifier and the next letter in
 473 the replacement string would be interpreted as part of it, you
 474 can wrap it with an expression like `\\,(or \\#)'.  Incidentally,
 475 for this particular case you may also enter `\\#' in the
 476 replacement text directly.
 477
 478 When using those Lisp features interactively in the replacement
 479 text, TO-STRING is actually made a list instead of a string.
 480 Use \\[repeat-complex-command] after this command for details.
 481
 482 If `query-replace-interactive' is non-nil, the last incremental search
 483 regexp is used as REGEXP--you don't have to specify it with the minibuffer.
 484
 485 This function is usually the wrong thing to use in a Lisp program.
 486 What you probably want is a loop like this:
 487   (while (re-search-forward REGEXP nil t)
 488     (replace-match TO-STRING nil nil))
 489 which will run faster and will not set the mark or print anything."
 490   (interactive
 491    (let ((common
 492           (query-replace-read-args
 493            (if (and transient-mark-mode mark-active)
 494                "Replace regexp in region"
 495              "Replace regexp")
 496            t)))
 497      (list (nth 0 common) (nth 1 common) (nth 2 common)
 498            (if (and transient-mark-mode mark-active)
 499                (region-beginning))
 500            (if (and transient-mark-mode mark-active)
 501                (region-end)))))
 502   (perform-replace regexp to-string nil t delimited nil nil start end))
 503
 504 \f
 505 (defvar regexp-history nil
 506   "History list for some commands that read regular expressions.")
 507
 508
 509 (defalias 'delete-non-matching-lines 'keep-lines)
 510 (defalias 'delete-matching-lines 'flush-lines)
 511 (defalias 'count-matches 'how-many)
 512
 513
 514 (defun keep-lines-read-args (prompt)
 515   "Read arguments for `keep-lines' and friends.
 516 Prompt for a regexp with PROMPT.
 517 Value is a list, (REGEXP)."
 518   (list (read-from-minibuffer prompt nil nil nil
 519                               'regexp-history nil t)
 520         nil nil t))
 521
 522 (defun keep-lines (regexp &optional rstart rend interactive)
 523   "Delete all lines except those containing matches for REGEXP.
 524 A match split across lines preserves all the lines it lies in.
 525 When called from Lisp (and usually interactively as well, see below)
 526 applies to all lines starting after point.
 527
 528 If REGEXP contains upper case characters (excluding those preceded by `\\'),
 529 the matching is case-sensitive.
 530
 531 Second and third arg RSTART and REND specify the region to operate on.
 532 This command operates on (the accessible part of) all lines whose
 533 accessible part is entirely contained in the region determined by RSTART
 534 and REND.  (A newline ending a line counts as part of that line.)
 535
 536 Interactively, in Transient Mark mode when the mark is active, operate
 537 on all lines whose accessible part is entirely contained in the region.
 538 Otherwise, the command applies to all lines starting after point.
 539 When calling this function from Lisp, you can pretend that it was
 540 called interactively by passing a non-nil INTERACTIVE argument.
 541
 542 This function starts looking for the next match from the end of
 543 the previous match.  Hence, it ignores matches that overlap
 544 a previously found match."
 545
 546   (interactive
 547    (progn
 548      (barf-if-buffer-read-only)
 549      (keep-lines-read-args "Keep lines (containing match for regexp): ")))
 550   (if rstart
 551       (progn
 552         (goto-char (min rstart rend))
 553         (setq rend
 554               (progn
 555                 (save-excursion
 556                   (goto-char (max rstart rend))
 557                   (unless (or (bolp) (eobp))
 558                     (forward-line 0))
 559                   (point-marker)))))
 560     (if (and interactive transient-mark-mode mark-active)
 561         (setq rstart (region-beginning)
 562               rend (progn
 563                      (goto-char (region-end))
 564                      (unless (or (bolp) (eobp))
 565                        (forward-line 0))
 566                      (point-marker)))
 567       (setq rstart (point)
 568             rend (point-max-marker)))
 569     (goto-char rstart))
 570   (save-excursion
 571     (or (bolp) (forward-line 1))
 572     (let ((start (point))
 573           (case-fold-search  (and case-fold-search
 574                                   (isearch-no-upper-case-p regexp t))))
 575       (while (< (point) rend)
 576         ;; Start is first char not preserved by previous match.
 577         (if (not (re-search-forward regexp rend 'move))
 578             (delete-region start rend)
 579           (let ((end (save-excursion (goto-char (match-beginning 0))
 580                                      (forward-line 0)
 581                                      (point))))
 582             ;; Now end is first char preserved by the new match.
 583             (if (< start end)
 584                 (delete-region start end))))
 585
 586         (setq start (save-excursion (forward-line 1) (point)))
 587         ;; If the match was empty, avoid matching again at same place.
 588         (and (< (point) rend)
 589              (= (match-beginning 0) (match-end 0))
 590              (forward-char 1)))))
 591   (set-marker rend nil)
 592   nil)
 593
 594
 595 (defun flush-lines (regexp &optional rstart rend interactive)
 596  "Delete lines containing matches for REGEXP.
 597 When called from Lisp (and usually when called interactively as
 598 well, see below), applies to the part of the buffer after point.
 599 The line point is in is deleted if and only if it contains a
 600 match for regexp starting after point.
 601
 602 If REGEXP contains upper case characters (excluding those preceded by `\\'),
 603 the matching is case-sensitive.
 604
 605 Second and third arg RSTART and REND specify the region to operate on.
 606 Lines partially contained in this region are deleted if and only if
 607 they contain a match entirely contained in it.
 608
 609 Interactively, in Transient Mark mode when the mark is active, operate
 610 on the contents of the region.  Otherwise, operate from point to the
 611 end of (the accessible portion of) the buffer.  When calling this function
 612 from Lisp, you can pretend that it was called interactively by passing
 613 a non-nil INTERACTIVE argument.
 614
 615 If a match is split across lines, all the lines it lies in are deleted.
 616 They are deleted _before_ looking for the next match.  Hence, a match
 617 starting on the same line at which another match ended is ignored."
 618
 619   (interactive
 620    (progn
 621      (barf-if-buffer-read-only)
 622      (keep-lines-read-args "Flush lines (containing match for regexp): ")))
 623   (if rstart
 624       (progn
 625         (goto-char (min rstart rend))
 626         (setq rend (copy-marker (max rstart rend))))
 627     (if (and interactive transient-mark-mode mark-active)
 628         (setq rstart (region-beginning)
 629               rend (copy-marker (region-end)))
 630       (setq rstart (point)
 631             rend (point-max-marker)))
 632     (goto-char rstart))
 633   (let ((case-fold-search (and case-fold-search
 634                                (isearch-no-upper-case-p regexp t))))
 635     (save-excursion
 636       (while (and (< (point) rend)
 637                   (re-search-forward regexp rend t))
 638         (delete-region (save-excursion (goto-char (match-beginning 0))
 639                                        (forward-line 0)
 640                                        (point))
 641                        (progn (forward-line 1) (point))))))
 642   (set-marker rend nil)
 643   nil)
 644
 645
 646 (defun how-many (regexp &optional rstart rend interactive)
 647   "Print and return number of matches for REGEXP following point.
 648 When called from Lisp and INTERACTIVE is omitted or nil, just return
 649 the number, do not print it; if INTERACTIVE is t, the function behaves
 650 in all respects has if it had been called interactively.
 651
 652 If REGEXP contains upper case characters (excluding those preceded by `\\'),
 653 the matching is case-sensitive.
 654
 655 Second and third arg RSTART and REND specify the region to operate on.
 656
 657 Interactively, in Transient Mark mode when the mark is active, operate
 658 on the contents of the region.  Otherwise, operate from point to the
 659 end of (the accessible portion of) the buffer.
 660
 661 This function starts looking for the next match from the end of
 662 the previous match.  Hence, it ignores matches that overlap
 663 a previously found match."
 664
 665   (interactive
 666    (keep-lines-read-args "How many matches for (regexp): "))
 667   (save-excursion
 668     (if rstart
 669         (progn
 670           (goto-char (min rstart rend))
 671           (setq rend (max rstart rend)))
 672       (if (and interactive transient-mark-mode mark-active)
 673           (setq rstart (region-beginning)
 674                 rend (region-end))
 675         (setq rstart (point)
 676               rend (point-max)))
 677       (goto-char rstart))
 678     (let ((count 0)
 679           opoint
 680           (case-fold-search (and case-fold-search
 681                                  (isearch-no-upper-case-p regexp t))))
 682       (while (and (< (point) rend)
 683                   (progn (setq opoint (point))
 684                          (re-search-forward regexp rend t)))
 685         (if (= opoint (point))
 686             (forward-char 1)
 687           (setq count (1+ count))))
 688       (when interactive (message "%d occurrence%s"
 689                                  count
 690                                  (if (= count 1) "" "s")))
 691       count)))
 692
 693 \f
 694 (defvar occur-mode-map
 695   (let ((map (make-sparse-keymap)))
 696     (define-key map [mouse-2] 'occur-mode-mouse-goto)
 697     (define-key map "\C-c\C-c" 'occur-mode-goto-occurrence)
 698     (define-key map "\C-m" 'occur-mode-goto-occurrence)
 699     (define-key map "o" 'occur-mode-goto-occurrence-other-window)
 700     (define-key map "\C-o" 'occur-mode-display-occurrence)
 701     (define-key map "\M-n" 'occur-next)
 702     (define-key map "\M-p" 'occur-prev)
 703     (define-key map "r" 'occur-rename-buffer)
 704     (define-key map "c" 'clone-buffer)
 705     (define-key map "g" 'revert-buffer)
 706     (define-key map "q" 'quit-window)
 707     (define-key map "z" 'kill-this-buffer)
 708     (define-key map "\C-c\C-f" 'next-error-follow-minor-mode)
 709     map)
 710   "Keymap for `occur-mode'.")
 711
 712 (defvar occur-revert-arguments nil
 713   "Arguments to pass to `occur-1' to revert an Occur mode buffer.
 714 See `occur-revert-function'.")
 715
 716 (defcustom occur-mode-hook '(turn-on-font-lock)
 717   "Hook run when entering Occur mode."
 718   :type 'hook
 719   :group 'matching)
 720
 721 (defcustom occur-hook nil
 722   "Hook run by Occur when there are any matches."
 723   :type 'hook
 724   :group 'matching)
 725
 726 (put 'occur-mode 'mode-class 'special)
 727 (defun occur-mode ()
 728   "Major mode for output from \\[occur].
 729 \\<occur-mode-map>Move point to one of the items in this buffer, then use
 730 \\[occur-mode-goto-occurrence] to go to the occurrence that the item refers to.
 731 Alternatively, click \\[occur-mode-mouse-goto] on an item to go to it.
 732
 733 \\{occur-mode-map}"
 734   (interactive)
 735   (kill-all-local-variables)
 736   (use-local-map occur-mode-map)
 737   (setq major-mode 'occur-mode)
 738   (setq mode-name "Occur")
 739   (set (make-local-variable 'revert-buffer-function) 'occur-revert-function)
 740   (make-local-variable 'occur-revert-arguments)
 741   (add-hook 'change-major-mode-hook 'font-lock-defontify nil t)
 742   (setq next-error-function 'occur-next-error)
 743   (run-mode-hooks 'occur-mode-hook))
 744
 745 (defun occur-revert-function (ignore1 ignore2)
 746   "Handle `revert-buffer' for Occur mode buffers."
 747   (apply 'occur-1 (append occur-revert-arguments (list (buffer-name)))))
 748
 749 (defun occur-mode-mouse-goto (event)
 750   "In Occur mode, go to the occurrence whose line you click on."
 751   (interactive "e")
 752   (let (pos)
 753     (save-excursion
 754       (set-buffer (window-buffer (posn-window (event-end event))))
 755       (save-excursion
 756         (goto-char (posn-point (event-end event)))
 757         (setq pos (occur-mode-find-occurrence))))
 758     (pop-to-buffer (marker-buffer pos))
 759     (goto-char pos)))
 760
 761 (defun occur-mode-find-occurrence ()
 762   (let ((pos (get-text-property (point) 'occur-target)))
 763     (unless pos
 764       (error "No occurrence on this line"))
 765     (unless (buffer-live-p (marker-buffer pos))
 766       (error "Buffer for this occurrence was killed"))
 767     pos))
 768
 769 (defun occur-mode-goto-occurrence ()
 770   "Go to the occurrence the current line describes."
 771   (interactive)
 772   (let ((pos (occur-mode-find-occurrence)))
 773     (pop-to-buffer (marker-buffer pos))
 774     (goto-char pos)))
 775
 776 (defun occur-mode-goto-occurrence-other-window ()
 777   "Go to the occurrence the current line describes, in another window."
 778   (interactive)
 779   (let ((pos (occur-mode-find-occurrence)))
 780     (switch-to-buffer-other-window (marker-buffer pos))
 781     (goto-char pos)))
 782
 783 (defun occur-mode-display-occurrence ()
 784   "Display in another window the occurrence the current line describes."
 785   (interactive)
 786   (let ((pos (occur-mode-find-occurrence))
 787         window
 788         ;; Bind these to ensure `display-buffer' puts it in another window.
 789         same-window-buffer-names
 790         same-window-regexps)
 791     (setq window (display-buffer (marker-buffer pos)))
 792     ;; This is the way to set point in the proper window.
 793     (save-selected-window
 794       (select-window window)
 795       (goto-char pos))))
 796
 797 (defun occur-find-match (n search message)
 798   (if (not n) (setq n 1))
 799   (let ((r))
 800     (while (> n 0)
 801       (setq r (funcall search (point) 'occur-match))
 802       (and r
 803            (get-text-property r 'occur-match)
 804            (setq r (funcall search r 'occur-match)))
 805       (if r
 806           (goto-char r)
 807         (error message))
 808       (setq n (1- n)))))
 809
 810 (defun occur-next (&optional n)
 811   "Move to the Nth (default 1) next match in an Occur mode buffer."
 812   (interactive "p")
 813   (occur-find-match n #'next-single-property-change "No more matches"))
 814
 815 (defun occur-prev (&optional n)
 816   "Move to the Nth (default 1) previous match in an Occur mode buffer."
 817   (interactive "p")
 818   (occur-find-match n #'previous-single-property-change "No earlier matches"))
 819
 820 (defun occur-next-error (&optional argp reset)
 821   "Move to the Nth (default 1) next match in an Occur mode buffer.
 822 Compatibility function for \\[next-error] invocations."
 823   (interactive "p")
 824   ;; we need to run occur-find-match from within the Occur buffer
 825   (with-current-buffer
 826       ;; Choose the buffer and make it current.
 827       (if (next-error-buffer-p (current-buffer))
 828           (current-buffer)
 829         (next-error-find-buffer nil nil
 830                                 (lambda ()
 831                                   (eq major-mode 'occur-mode))))
 832
 833     (goto-char (cond (reset (point-min))
 834                      ((< argp 0) (line-beginning-position))
 835                      ((line-end-position))))
 836     (occur-find-match
 837      (abs argp)
 838      (if (> 0 argp)
 839          #'previous-single-property-change
 840        #'next-single-property-change)
 841      "No more matches")
 842     ;; In case the *Occur* buffer is visible in a nonselected window.
 843     (set-window-point (get-buffer-window (current-buffer)) (point))
 844     (occur-mode-goto-occurrence)))
 845 \f
 846 (defface match
 847   '((((class color) (min-colors 88) (background light))
 848      :background "Tan")
 849     (((class color) (min-colors 88) (background dark))
 850      :background "RoyalBlue4")
 851     (((class color) (min-colors 8))
 852      :background "blue" :foreground "white")
 853     (((type tty) (class mono))
 854      :inverse-video t)
 855     (t :background "gray"))
 856   "Face used to highlight matches permanently."
 857   :group 'matching
 858   :version "22.1")
 859
 860 (defcustom list-matching-lines-default-context-lines 0
 861   "*Default number of context lines included around `list-matching-lines' matches.
 862 A negative number means to include that many lines before the match.
 863 A positive number means to include that many lines both before and after."
 864   :type 'integer
 865   :group 'matching)
 866
 867 (defalias 'list-matching-lines 'occur)
 868
 869 (defcustom list-matching-lines-face 'match
 870   "*Face used by \\[list-matching-lines] to show the text that matches.
 871 If the value is nil, don't highlight the matching portions specially."
 872   :type 'face
 873   :group 'matching)
 874
 875 (defcustom list-matching-lines-buffer-name-face 'underline
 876   "*Face used by \\[list-matching-lines] to show the names of buffers.
 877 If the value is nil, don't highlight the buffer names specially."
 878   :type 'face
 879   :group 'matching)
 880
 881 (defun occur-accumulate-lines (count &optional keep-props)
 882   (save-excursion
 883     (let ((forwardp (> count 0))
 884           result beg end)
 885       (while (not (or (zerop count)
 886                       (if forwardp
 887                           (eobp)
 888                         (bobp))))
 889         (setq count (+ count (if forwardp -1 1)))
 890         (setq beg (line-beginning-position)
 891               end (line-end-position))
 892         (if (and keep-props (if (boundp 'jit-lock-mode) jit-lock-mode)
 893                  (text-property-not-all beg end 'fontified t))
 894             (if (fboundp 'jit-lock-fontify-now)
 895                 (jit-lock-fontify-now beg end)))
 896         (push
 897          (funcall (if keep-props
 898                       #'buffer-substring
 899                     #'buffer-substring-no-properties)
 900                   beg end)
 901          result)
 902         (forward-line (if forwardp 1 -1)))
 903       (nreverse result))))
 904
 905 (defun occur-read-primary-args ()
 906   (list (let* ((default (car regexp-history))
 907                (input
 908                 (read-from-minibuffer
 909                  (if default
 910                      (format "List lines matching regexp (default `%s'): "
 911                              (query-replace-descr default))
 912                    "List lines matching regexp: ")
 913                  nil
 914                  nil
 915                  nil
 916                  'regexp-history
 917                  default)))
 918           (if (equal input "")
 919               default
 920             input))
 921         (when current-prefix-arg
 922           (prefix-numeric-value current-prefix-arg))))
 923
 924 (defun occur-rename-buffer (&optional unique-p)
 925   "Rename the current *Occur* buffer to *Occur: original-buffer-name*.
 926 Here `original-buffer-name' is the buffer name were occur was originally run.
 927 When given the prefix argument, the renaming will not clobber the existing
 928 buffer(s) of that name, but use `generate-new-buffer-name' instead.
 929 You can add this to `occur-mode-hook' if you always want a separate *Occur*
 930 buffer for each buffer where you invoke `occur'."
 931   (interactive "P")
 932   (with-current-buffer
 933       (if (eq major-mode 'occur-mode) (current-buffer) (get-buffer "*Occur*"))
 934     (rename-buffer (concat "*Occur: "
 935                            (mapconcat #'buffer-name
 936                                       (car (cddr occur-revert-arguments)) "/")
 937                            "*")
 938                    unique-p)))
 939
 940 (defun occur (regexp &optional nlines)
 941   "Show all lines in the current buffer containing a match for REGEXP.
 942 This function can not handle matches that span more than one line.
 943
 944 Each line is displayed with NLINES lines before and after, or -NLINES
 945 before if NLINES is negative.
 946 NLINES defaults to `list-matching-lines-default-context-lines'.
 947 Interactively it is the prefix arg.
 948
 949 The lines are shown in a buffer named `*Occur*'.
 950 It serves as a menu to find any of the occurrences in this buffer.
 951 \\<occur-mode-map>\\[describe-mode] in that buffer will explain how.
 952
 953 If REGEXP contains upper case characters (excluding those preceded by `\\'),
 954 the matching is case-sensitive."
 955   (interactive (occur-read-primary-args))
 956   (occur-1 regexp nlines (list (current-buffer))))
 957
 958 (defun multi-occur (bufs regexp &optional nlines)
 959   "Show all lines in buffers BUFS containing a match for REGEXP.
 960 This function acts on multiple buffers; otherwise, it is exactly like
 961 `occur'."
 962   (interactive
 963    (cons
 964     (let* ((bufs (list (read-buffer "First buffer to search: "
 965                                     (current-buffer) t)))
 966            (buf nil)
 967            (ido-ignore-item-temp-list bufs))
 968       (while (not (string-equal
 969                    (setq buf (read-buffer
 970                               (if (eq read-buffer-function 'ido-read-buffer)
 971                                   "Next buffer to search (C-j to end): "
 972                                 "Next buffer to search (RET to end): ")
 973                               nil t))
 974                    ""))
 975         (add-to-list 'bufs buf)
 976         (setq ido-ignore-item-temp-list bufs))
 977       (nreverse (mapcar #'get-buffer bufs)))
 978     (occur-read-primary-args)))
 979   (occur-1 regexp nlines bufs))
 980
 981 (defun multi-occur-by-filename-regexp (bufregexp regexp &optional nlines)
 982   "Show all lines matching REGEXP in buffers named by BUFREGEXP.
 983 See also `multi-occur'."
 984   (interactive
 985    (cons
 986     (let* ((default (car regexp-history))
 987            (input
 988             (read-from-minibuffer
 989              "List lines in buffers whose filename matches regexp: "
 990              nil
 991              nil
 992              nil
 993              'regexp-history)))
 994       (if (equal input "")
 995           default
 996         input))
 997     (occur-read-primary-args)))
 998   (when bufregexp
 999     (occur-1 regexp nlines
1000              (delq nil
1001                    (mapcar (lambda (buf)
1002                              (when (and (buffer-file-name buf)
1003                                         (string-match bufregexp
1004                                                       (buffer-file-name buf)))
1005                                buf))
1006                            (buffer-list))))))
1007
1008 (defun occur-1 (regexp nlines bufs &optional buf-name)
1009   (unless buf-name
1010     (setq buf-name "*Occur*"))
1011   (let (occur-buf
1012         (active-bufs (delq nil (mapcar #'(lambda (buf)
1013                                            (when (buffer-live-p buf) buf))
1014                                        bufs))))
1015     ;; Handle the case where one of the buffers we're searching is the
1016     ;; output buffer.  Just rename it.
1017     (when (member buf-name (mapcar 'buffer-name active-bufs))
1018       (with-current-buffer (get-buffer buf-name)
1019         (rename-uniquely)))
1020
1021     ;; Now find or create the output buffer.
1022     ;; If we just renamed that buffer, we will make a new one here.
1023     (setq occur-buf (get-buffer-create buf-name))
1024
1025     (with-current-buffer occur-buf
1026       (occur-mode)
1027       (let ((inhibit-read-only t))
1028         (erase-buffer)
1029         (let ((count (occur-engine
1030                       regexp active-bufs occur-buf
1031                       (or nlines list-matching-lines-default-context-lines)
1032                       (and case-fold-search
1033                            (isearch-no-upper-case-p regexp t))
1034                       list-matching-lines-buffer-name-face
1035                       nil list-matching-lines-face t)))
1036           (let* ((bufcount (length active-bufs))
1037                  (diff (- (length bufs) bufcount)))
1038             (message "Searched %d buffer%s%s; %s match%s for `%s'"
1039                      bufcount (if (= bufcount 1) "" "s")
1040                      (if (zerop diff) "" (format " (%d killed)" diff))
1041                      (if (zerop count) "no" (format "%d" count))
1042                      (if (= count 1) "" "es")
1043                      regexp))
1044           (setq occur-revert-arguments (list regexp nlines bufs))
1045           (if (= count 0)
1046               (kill-buffer occur-buf)
1047             (display-buffer occur-buf)
1048             (setq next-error-last-buffer occur-buf)
1049             (setq buffer-read-only t)
1050             (set-buffer-modified-p nil)
1051             (run-hooks 'occur-hook)))))))
1052
1053 (defun occur-engine-add-prefix (lines)
1054   (mapcar
1055    #'(lambda (line)
1056        (concat "       :" line "\n"))
1057    lines))
1058
1059 (defun occur-engine (regexp buffers out-buf nlines case-fold-search
1060                             title-face prefix-face match-face keep-props)
1061   (with-current-buffer out-buf
1062     (let ((globalcount 0)
1063           (coding nil))
1064       ;; Map over all the buffers
1065       (dolist (buf buffers)
1066         (when (buffer-live-p buf)
1067           (let ((matches 0)     ;; count of matched lines
1068                 (lines 1)       ;; line count
1069                 (matchbeg 0)
1070                 (origpt nil)
1071                 (begpt nil)
1072                 (endpt nil)
1073                 (marker nil)
1074                 (curstring "")
1075                 (headerpt (with-current-buffer out-buf (point))))
1076             (save-excursion
1077               (set-buffer buf)
1078               (or coding
1079                   ;; Set CODING only if the current buffer locally
1080                   ;; binds buffer-file-coding-system.
1081                   (not (local-variable-p 'buffer-file-coding-system))
1082                   (setq coding buffer-file-coding-system))
1083               (save-excursion
1084                 (goto-char (point-min)) ;; begin searching in the buffer
1085                 (while (not (eobp))
1086                   (setq origpt (point))
1087                   (when (setq endpt (re-search-forward regexp nil t))
1088                     (setq matches (1+ matches)) ;; increment match count
1089                     (setq matchbeg (match-beginning 0))
1090                     (setq lines (+ lines (1- (count-lines origpt endpt))))
1091                     (save-excursion
1092                       (goto-char matchbeg)
1093                       (setq begpt (line-beginning-position)
1094                             endpt (line-end-position)))
1095                     (setq marker (make-marker))
1096                     (set-marker marker matchbeg)
1097                     (if (and keep-props
1098                              (if (boundp 'jit-lock-mode) jit-lock-mode)
1099                              (text-property-not-all begpt endpt 'fontified t))
1100                         (if (fboundp 'jit-lock-fontify-now)
1101                             (jit-lock-fontify-now begpt endpt)))
1102                     (setq curstring (buffer-substring begpt endpt))
1103                     ;; Depropertize the string, and maybe
1104                     ;; highlight the matches
1105                     (let ((len (length curstring))
1106                           (start 0))
1107                       (unless keep-props
1108                         (set-text-properties 0 len nil curstring))
1109                       (while (and (< start len)
1110                                   (string-match regexp curstring start))
1111                         (add-text-properties
1112                          (match-beginning 0) (match-end 0)
1113                          (append
1114                           `(occur-match t)
1115                           (when match-face
1116                             ;; Use `face' rather than `font-lock-face' here
1117                             ;; so as to override faces copied from the buffer.
1118                             `(face ,match-face)))
1119                          curstring)
1120                         (setq start (match-end 0))))
1121                     ;; Generate the string to insert for this match
1122                     (let* ((out-line
1123                             (concat
1124                              ;; Using 7 digits aligns tabs properly.
1125                              (apply #'propertize (format "%7d:" lines)
1126                                     (append
1127                                      (when prefix-face
1128                                        `(font-lock-face prefix-face))
1129                                      '(occur-prefix t)))
1130                              ;; We don't put `mouse-face' on the newline,
1131                              ;; because that loses.  And don't put it
1132                              ;; on context lines to reduce flicker.
1133                              (propertize curstring 'mouse-face 'highlight)
1134                              "\n"))
1135                            (data
1136                             (if (= nlines 0)
1137                                 ;; The simple display style
1138                                 out-line
1139                               ;; The complex multi-line display
1140                               ;; style.  Generate a list of lines,
1141                               ;; concatenate them all together.
1142                               (apply #'concat
1143                                      (nconc
1144                                       (occur-engine-add-prefix (nreverse (cdr (occur-accumulate-lines (- (1+ (abs nlines))) keep-props))))
1145                                       (list out-line)
1146                                       (if (> nlines 0)
1147                                           (occur-engine-add-prefix
1148                                            (cdr (occur-accumulate-lines (1+ nlines) keep-props)))))))))
1149                       ;; Actually insert the match display data
1150                       (with-current-buffer out-buf
1151                         (let ((beg (point))
1152                               (end (progn (insert data) (point))))
1153                           (unless (= nlines 0)
1154                             (insert "-------\n"))
1155                           (add-text-properties
1156                            beg end
1157                            `(occur-target ,marker help-echo "mouse-2: go to this occurrence")))))
1158                     (goto-char endpt))
1159                   (if endpt
1160                       (progn
1161                         (setq lines (1+ lines))
1162                         ;; On to the next match...
1163                         (forward-line 1))
1164                     (goto-char (point-max))))))
1165             (when (not (zerop matches)) ;; is the count zero?
1166               (setq globalcount (+ globalcount matches))
1167               (with-current-buffer out-buf
1168                 (goto-char headerpt)
1169                 (let ((beg (point))
1170                       end)
1171                   (insert (format "%d match%s for \"%s\" in buffer: %s\n"
1172                                   matches (if (= matches 1) "" "es")
1173                                   regexp (buffer-name buf)))
1174                   (setq end (point))
1175                   (add-text-properties beg end
1176                                        (append
1177                                         (when title-face
1178                                           `(font-lock-face ,title-face))
1179                                         `(occur-title ,buf))))
1180                 (goto-char (point-min)))))))
1181       (if coding
1182           ;; CODING is buffer-file-coding-system of the first buffer
1183           ;; that locally binds it.  Let's use it also for the output
1184           ;; buffer.
1185           (set-buffer-file-coding-system coding))
1186       ;; Return the number of matches
1187       globalcount)))
1188
1189 \f
1190 ;; It would be nice to use \\[...], but there is no reasonable way
1191 ;; to make that display both SPC and Y.
1192 (defconst query-replace-help
1193   "Type Space or `y' to replace one match, Delete or `n' to skip to next,
1194 RET or `q' to exit, Period to replace one match and exit,
1195 Comma to replace but not move point immediately,
1196 C-r to enter recursive edit (\\[exit-recursive-edit] to get out again),
1197 C-w to delete match and recursive edit,
1198 C-l to clear the screen, redisplay, and offer same replacement again,
1199 ! to replace all remaining matches with no more questions,
1200 ^ to move point back to previous match,
1201 E to edit the replacement string"
1202   "Help message while in `query-replace'.")
1203
1204 (defvar query-replace-map (make-sparse-keymap)
1205   "Keymap that defines the responses to questions in `query-replace'.
1206 The \"bindings\" in this map are not commands; they are answers.
1207 The valid answers include `act', `skip', `act-and-show',
1208 `exit', `act-and-exit', `edit', `delete-and-edit', `recenter',
1209 `automatic', `backup', `exit-prefix', and `help'.")
1210
1211 (define-key query-replace-map " " 'act)
1212 (define-key query-replace-map "\d" 'skip)
1213 (define-key query-replace-map [delete] 'skip)
1214 (define-key query-replace-map [backspace] 'skip)
1215 (define-key query-replace-map "y" 'act)
1216 (define-key query-replace-map "n" 'skip)
1217 (define-key query-replace-map "Y" 'act)
1218 (define-key query-replace-map "N" 'skip)
1219 (define-key query-replace-map "e" 'edit-replacement)
1220 (define-key query-replace-map "E" 'edit-replacement)
1221 (define-key query-replace-map "," 'act-and-show)
1222 (define-key query-replace-map "q" 'exit)
1223 (define-key query-replace-map "\r" 'exit)
1224 (define-key query-replace-map [return] 'exit)
1225 (define-key query-replace-map "." 'act-and-exit)
1226 (define-key query-replace-map "\C-r" 'edit)
1227 (define-key query-replace-map "\C-w" 'delete-and-edit)
1228 (define-key query-replace-map "\C-l" 'recenter)
1229 (define-key query-replace-map "!" 'automatic)
1230 (define-key query-replace-map "^" 'backup)
1231 (define-key query-replace-map "\C-h" 'help)
1232 (define-key query-replace-map [f1] 'help)
1233 (define-key query-replace-map [help] 'help)
1234 (define-key query-replace-map "?" 'help)
1235 (define-key query-replace-map "\C-g" 'quit)
1236 (define-key query-replace-map "\C-]" 'quit)
1237 (define-key query-replace-map "\e" 'exit-prefix)
1238 (define-key query-replace-map [escape] 'exit-prefix)
1239
1240 (defun replace-match-string-symbols (n)
1241   "Process a list (and any sub-lists), expanding certain symbols.
1242 Symbol  Expands To
1243 N     (match-string N)           (where N is a string of digits)
1244 #N    (string-to-number (match-string N))
1245 &     (match-string 0)
1246 #&    (string-to-number (match-string 0))
1247 #     replace-count
1248
1249 Note that these symbols must be preceeded by a backslash in order to
1250 type them."
1251   (while n
1252     (cond
1253      ((consp (car n))
1254       (replace-match-string-symbols (car n))) ;Process sub-list
1255      ((symbolp (car n))
1256       (let ((name (symbol-name (car n))))
1257         (cond
1258          ((string-match "^[0-9]+$" name)
1259           (setcar n (list 'match-string (string-to-number name))))
1260          ((string-match "^#[0-9]+$" name)
1261           (setcar n (list 'string-to-number
1262                           (list 'match-string
1263                                 (string-to-number (substring name 1))))))
1264          ((string= "&" name)
1265           (setcar n '(match-string 0)))
1266          ((string= "#&" name)
1267           (setcar n '(string-to-number (match-string 0))))
1268          ((string= "#" name)
1269           (setcar n 'replace-count))))))
1270     (setq n (cdr n))))
1271
1272 (defun replace-eval-replacement (expression replace-count)
1273   (let ((replacement (eval expression)))
1274     (if (stringp replacement)
1275         replacement
1276       (prin1-to-string replacement t))))
1277
1278 (defun replace-quote (replacement)
1279   "Quote a replacement string.
1280 This just doubles all backslashes in REPLACEMENT and
1281 returns the resulting string.  If REPLACEMENT is not
1282 a string, it is first passed through `prin1-to-string'
1283 with the `noescape' argument set.
1284
1285 `match-data' is preserved across the call."
1286   (save-match-data
1287     (replace-regexp-in-string "\\\\" "\\\\"
1288                               (if (stringp replacement)
1289                                   replacement
1290                                 (prin1-to-string replacement t))
1291                               t t)))
1292
1293 (defun replace-loop-through-replacements (data replace-count)
1294   ;; DATA is a vector contaning the following values:
1295   ;;   0 next-rotate-count
1296   ;;   1 repeat-count
1297   ;;   2 next-replacement
1298   ;;   3 replacements
1299   (if (= (aref data 0) replace-count)
1300       (progn
1301         (aset data 0 (+ replace-count (aref data 1)))
1302         (let ((next (cdr (aref data 2))))
1303           (aset data 2 (if (consp next) next (aref data 3))))))
1304   (car (aref data 2)))
1305
1306 (defun replace-match-data (integers reuse &optional new)
1307   "Like `match-data', but markers in REUSE get invalidated.
1308 If NEW is non-NIL, it is set and returned instead of fresh data,
1309 but coerced to the correct value of INTEGERS."
1310   (or (and new
1311            (progn
1312              (set-match-data new)
1313              (and (eq new reuse)
1314                   (eq (null integers) (markerp (car reuse)))
1315                   new)))
1316       (match-data integers reuse t)))
1317
1318 (defun replace-match-maybe-edit (newtext fixedcase literal noedit match-data)
1319   "Make a replacement with `replace-match', editing `\\?'.
1320 NEWTEXT, FIXEDCASE, LITERAL are just passed on.  If NOEDIT is true, no
1321 check for `\\?' is made to save time.  MATCH-DATA is used for the
1322 replacement.  In case editing is done, it is changed to use markers.
1323
1324 The return value is non-NIL if there has been no `\\?' or NOEDIT was
1325 passed in.  If LITERAL is set, no checking is done, anyway."
1326   (unless (or literal noedit)
1327     (setq noedit t)
1328     (while (string-match "\\(\\`\\|[^\\]\\)\\(\\\\\\\\\\)*\\(\\\\\\?\\)"
1329                          newtext)
1330       (setq newtext
1331             (read-string "Edit replacement string: "
1332                          (prog1
1333                              (cons
1334                               (replace-match "" t t newtext 3)
1335                               (1+ (match-beginning 3)))
1336                            (setq match-data
1337                                  (replace-match-data
1338                                   nil match-data match-data))))
1339             noedit nil)))
1340   (set-match-data match-data)
1341   (replace-match newtext fixedcase literal)
1342   noedit)
1343
1344 (defun perform-replace (from-string replacements
1345                         query-flag regexp-flag delimited-flag
1346                         &optional repeat-count map start end)
1347   "Subroutine of `query-replace'.  Its complexity handles interactive queries.
1348 Don't use this in your own program unless you want to query and set the mark
1349 just as `query-replace' does.  Instead, write a simple loop like this:
1350
1351   (while (re-search-forward \"foo[ \\t]+bar\" nil t)
1352     (replace-match \"foobar\" nil nil))
1353
1354 which will run faster and probably do exactly what you want.  Please
1355 see the documentation of `replace-match' to find out how to simulate
1356 `case-replace'.
1357
1358 This function returns nil if and only if there were no matches to
1359 make, or the user didn't cancel the call."
1360   (or map (setq map query-replace-map))
1361   (and query-flag minibuffer-auto-raise
1362        (raise-frame (window-frame (minibuffer-window))))
1363   (let ((nocasify (not (and case-fold-search case-replace
1364                             (string-equal from-string
1365                                           (downcase from-string)))))
1366         (case-fold-search (and case-fold-search
1367                                (string-equal from-string
1368                                              (downcase from-string))))
1369         (literal (or (not regexp-flag) (eq regexp-flag 'literal)))
1370         (search-function (if regexp-flag 're-search-forward 'search-forward))
1371         (search-string from-string)
1372         (real-match-data nil)           ; the match data for the current match
1373         (next-replacement nil)
1374         (noedit nil)
1375         (keep-going t)
1376         (stack nil)
1377         (replace-count 0)
1378         (nonempty-match nil)
1379
1380         ;; If non-nil, it is marker saying where in the buffer to stop.
1381         (limit nil)
1382
1383         ;; Data for the next match.  If a cons, it has the same format as
1384         ;; (match-data); otherwise it is t if a match is possible at point.
1385         (match-again t)
1386
1387         (message
1388          (if query-flag
1389              (substitute-command-keys
1390               "Query replacing %s with %s: (\\<query-replace-map>\\[help] for help) "))))
1391
1392     ;; If region is active, in Transient Mark mode, operate on region.
1393     (when start
1394       (setq limit (copy-marker (max start end)))
1395       (goto-char (min start end))
1396       (deactivate-mark))
1397
1398     ;; REPLACEMENTS is either a string, a list of strings, or a cons cell
1399     ;; containing a function and its first argument.  The function is
1400     ;; called to generate each replacement like this:
1401     ;;   (funcall (car replacements) (cdr replacements) replace-count)
1402     ;; It must return a string.
1403     (cond
1404      ((stringp replacements)
1405       (setq next-replacement replacements
1406             replacements     nil))
1407      ((stringp (car replacements)) ; If it isn't a string, it must be a cons
1408       (or repeat-count (setq repeat-count 1))
1409       (setq replacements (cons 'replace-loop-through-replacements
1410                                (vector repeat-count repeat-count
1411                                        replacements replacements)))))
1412
1413     (if delimited-flag
1414         (setq search-function 're-search-forward
1415               search-string (concat "\\b"
1416                                     (if regexp-flag from-string
1417                                       (regexp-quote from-string))
1418                                     "\\b")))
1419     (when query-replace-lazy-highlight
1420       (setq isearch-lazy-highlight-last-string nil))
1421
1422     (push-mark)
1423     (undo-boundary)
1424     (unwind-protect
1425         ;; Loop finding occurrences that perhaps should be replaced.
1426         (while (and keep-going
1427                     (not (or (eobp) (and limit (>= (point) limit))))
1428                     ;; Use the next match if it is already known;
1429                     ;; otherwise, search for a match after moving forward
1430                     ;; one char if progress is required.
1431                     (setq real-match-data
1432                           (if (consp match-again)
1433                               (progn (goto-char (nth 1 match-again))
1434                                      (replace-match-data t
1435                                       real-match-data
1436                                       match-again))
1437                             (and (or match-again
1438                                      ;; MATCH-AGAIN non-nil means we
1439                                      ;; accept an adjacent match.  If
1440                                      ;; we don't, move one char to the
1441                                      ;; right.  This takes us a
1442                                      ;; character too far at the end,
1443                                      ;; but this is undone after the
1444                                      ;; while-loop.
1445                                      (progn
1446                                        (forward-char 1)
1447                                        (not (or (eobp)
1448                                                 (and limit (>= (point) limit))))))
1449                                  (funcall search-function search-string limit t)
1450                                  ;; For speed, use only integers and
1451                                  ;; reuse the list used last time.
1452                                  (replace-match-data t real-match-data)))))
1453           ;; Optionally ignore matches that have a read-only property.
1454           (unless (and query-replace-skip-read-only
1455                        (text-property-not-all
1456                         (match-beginning 0) (match-end 0)
1457                         'read-only nil))
1458
1459             ;; Record whether the match is nonempty, to avoid an infinite loop
1460             ;; repeatedly matching the same empty string.
1461             (setq nonempty-match
1462                   (/= (nth 0 real-match-data) (nth 1 real-match-data)))
1463
1464             ;; If the match is empty, record that the next one can't be
1465             ;; adjacent.
1466
1467             ;; Otherwise, if matching a regular expression, do the next
1468             ;; match now, since the replacement for this match may
1469             ;; affect whether the next match is adjacent to this one.
1470             ;; If that match is empty, don't use it.
1471             (setq match-again
1472                   (and nonempty-match
1473                        (or (not regexp-flag)
1474                            (and (looking-at search-string)
1475                                 (let ((match (match-data)))
1476                                   (and (/= (nth 0 match) (nth 1 match))
1477                                        match))))))
1478
1479             ;; Calculate the replacement string, if necessary.
1480             (when replacements
1481               (set-match-data real-match-data)
1482               (setq next-replacement
1483                     (funcall (car replacements) (cdr replacements)
1484                              replace-count)
1485                     noedit nil))
1486             (if (not query-flag)
1487                 (let ((inhibit-read-only
1488                        query-replace-skip-read-only))
1489                   (unless (or literal noedit)
1490                     (replace-highlight
1491                      (nth 0 real-match-data) (nth 1 real-match-data)
1492                      start end search-string
1493                      (or delimited-flag regexp-flag) case-fold-search))
1494                   (setq noedit
1495                         (replace-match-maybe-edit
1496                          next-replacement nocasify literal
1497                          noedit real-match-data)
1498                         replace-count (1+ replace-count)))
1499               (undo-boundary)
1500               (let (done replaced key def)
1501                 ;; Loop reading commands until one of them sets done,
1502                 ;; which means it has finished handling this
1503                 ;; occurrence.  Any command that sets `done' should
1504                 ;; leave behind proper match data for the stack.
1505                 ;; Commands not setting `done' need to adjust
1506                 ;; `real-match-data'.
1507                 (while (not done)
1508                   (set-match-data real-match-data)
1509                   (replace-highlight
1510                    (match-beginning 0) (match-end 0)
1511                    start end search-string
1512                    (or delimited-flag regexp-flag) case-fold-search)
1513                   ;; Bind message-log-max so we don't fill up the message log
1514                   ;; with a bunch of identical messages.
1515                   (let ((message-log-max nil))
1516                     (message message
1517                              (query-replace-descr from-string)
1518                              (query-replace-descr next-replacement)))
1519                   (setq key (read-event))
1520                   ;; Necessary in case something happens during read-event
1521                   ;; that clobbers the match data.
1522                   (set-match-data real-match-data)
1523                   (setq key (vector key))
1524                   (setq def (lookup-key map key))
1525                   ;; Restore the match data while we process the command.
1526                   (cond ((eq def 'help)
1527                          (with-output-to-temp-buffer "*Help*"
1528                            (princ
1529                             (concat "Query replacing "
1530                                     (if regexp-flag "regexp " "")
1531                                     from-string " with "
1532                                     next-replacement ".\n\n"
1533                                     (substitute-command-keys
1534                                      query-replace-help)))
1535                            (with-current-buffer standard-output
1536                              (help-mode))))
1537                         ((eq def 'exit)
1538                          (setq keep-going nil)
1539                          (setq done t))
1540                         ((eq def 'backup)
1541                          (if stack
1542                              (let ((elt (pop stack)))
1543                                (goto-char (nth 0 elt))
1544                                (setq replaced (nth 1 elt)
1545                                      real-match-data
1546                                      (replace-match-data
1547                                       t real-match-data
1548                                       (nth 2 elt))))
1549                            (message "No previous match")
1550                            (ding 'no-terminate)
1551                            (sit-for 1)))
1552                         ((eq def 'act)
1553                          (or replaced
1554                              (setq noedit
1555                                    (replace-match-maybe-edit
1556                                     next-replacement nocasify literal
1557                                     noedit real-match-data)
1558                                    replace-count (1+ replace-count)))
1559                          (setq done t replaced t))
1560                         ((eq def 'act-and-exit)
1561                          (or replaced
1562                              (setq noedit
1563                                    (replace-match-maybe-edit
1564                                     next-replacement nocasify literal
1565                                     noedit real-match-data)
1566                                    replace-count (1+ replace-count)))
1567                          (setq keep-going nil)
1568                          (setq done t replaced t))
1569                         ((eq def 'act-and-show)
1570                          (if (not replaced)
1571                              (setq noedit
1572                                    (replace-match-maybe-edit
1573                                     next-replacement nocasify literal
1574                                     noedit real-match-data)
1575                                    replace-count (1+ replace-count)
1576                                    real-match-data (replace-match-data
1577                                                     t real-match-data)
1578                                    replaced t)))
1579                         ((eq def 'automatic)
1580                          (or replaced
1581                              (setq noedit
1582                                    (replace-match-maybe-edit
1583                                     next-replacement nocasify literal
1584                                     noedit real-match-data)
1585                                    replace-count (1+ replace-count)))
1586                          (setq done t query-flag nil replaced t))
1587                         ((eq def 'skip)
1588                          (setq done t))
1589                         ((eq def 'recenter)
1590                          (recenter nil))
1591                         ((eq def 'edit)
1592                          (let ((opos (point-marker)))
1593                            (setq real-match-data (replace-match-data
1594                                                   nil real-match-data
1595                                                   real-match-data))
1596                            (goto-char (match-beginning 0))
1597                            (save-excursion
1598                              (save-window-excursion
1599                                (recursive-edit)))
1600                            (goto-char opos)
1601                            (set-marker opos nil))
1602                          ;; Before we make the replacement,
1603                          ;; decide whether the search string
1604                          ;; can match again just after this match.
1605                          (if (and regexp-flag nonempty-match)
1606                              (setq match-again (and (looking-at search-string)
1607                                                     (match-data)))))
1608                         ;; Edit replacement.
1609                         ((eq def 'edit-replacement)
1610                          (setq real-match-data (replace-match-data
1611                                                 nil real-match-data
1612                                                 real-match-data)
1613                                next-replacement
1614                                (read-string "Edit replacement string: "
1615                                             next-replacement)
1616                                noedit nil)
1617                          (if replaced
1618                              (set-match-data real-match-data)
1619                            (setq noedit
1620                                  (replace-match-maybe-edit
1621                                   next-replacement nocasify literal noedit
1622                                   real-match-data)
1623                                  replaced t))
1624                          (setq done t))
1625
1626                         ((eq def 'delete-and-edit)
1627                          (replace-match "" t t)
1628                          (setq real-match-data (replace-match-data
1629                                                 nil real-match-data))
1630                          (replace-dehighlight)
1631                          (save-excursion (recursive-edit))
1632                          (setq replaced t))
1633                         ;; Note: we do not need to treat `exit-prefix'
1634                         ;; specially here, since we reread
1635                         ;; any unrecognized character.
1636                         (t
1637                          (setq this-command 'mode-exited)
1638                          (setq keep-going nil)
1639                          (setq unread-command-events
1640                                (append (listify-key-sequence key)
1641                                        unread-command-events))
1642                          (setq done t)))
1643                   (when query-replace-lazy-highlight
1644                     ;; Force lazy rehighlighting only after replacements
1645                     (if (not (memq def '(skip backup)))
1646                         (setq isearch-lazy-highlight-last-string nil))))
1647                 ;; Record previous position for ^ when we move on.
1648                 ;; Change markers to numbers in the match data
1649                 ;; since lots of markers slow down editing.
1650                 (push (list (point) replaced
1651 ;;;  If the replacement has already happened, all we need is the
1652 ;;;  current match start and end.  We could get this with a trivial
1653 ;;;  match like
1654 ;;;  (save-excursion (goto-char (match-beginning 0))
1655 ;;;                  (search-forward (match-string 0))
1656 ;;;                  (match-data t))
1657 ;;;  if we really wanted to avoid manually constructing match data.
1658 ;;;  Adding current-buffer is necessary so that match-data calls can
1659 ;;;  return markers which are appropriate for editing.
1660                             (if replaced
1661                                 (list
1662                                  (match-beginning 0)
1663                                  (match-end 0)
1664                                  (current-buffer))
1665                               (match-data t)))
1666                       stack)))))
1667
1668       ;; The code preventing adjacent regexp matches in the condition
1669       ;; of the while-loop above will haven taken us one character
1670       ;; beyond the last replacement.  Undo that.
1671       (when (and regexp-flag (not match-again) (> replace-count 0))
1672         (backward-char 1))
1673
1674       (replace-dehighlight))
1675     (or unread-command-events
1676         (message "Replaced %d occurrence%s"
1677                  replace-count
1678                  (if (= replace-count 1) "" "s")))
1679     (and keep-going stack)))
1680
1681 (defvar replace-overlay nil)
1682
1683 (defun replace-highlight (match-beg match-end range-beg range-end
1684                           string regexp case-fold)
1685   (if query-replace-highlight
1686       (if replace-overlay
1687           (move-overlay replace-overlay match-beg match-end (current-buffer))
1688         (setq replace-overlay (make-overlay match-beg match-end))
1689         (overlay-put replace-overlay 'priority 1) ;higher than lazy overlays
1690         (overlay-put replace-overlay 'face 'query-replace)))
1691   (if query-replace-lazy-highlight
1692       (let ((isearch-string string)
1693             (isearch-regexp regexp)
1694             (isearch-case-fold-search case-fold))
1695         (isearch-lazy-highlight-new-loop range-beg range-end))))
1696
1697 (defun replace-dehighlight ()
1698   (when replace-overlay
1699     (delete-overlay replace-overlay))
1700   (when query-replace-lazy-highlight
1701     (lazy-highlight-cleanup lazy-highlight-cleanup)
1702     (setq isearch-lazy-highlight-last-string nil)))
1703
1704 ;; arch-tag: 16b4cd61-fd40-497b-b86f-b667c4cf88e4
1705 ;;; replace.el ends here