code.delx.au - gnu-emacs/blob - lisp/net/rcompile.el

   1 ;;; rcompile.el --- run a compilation on a remote machine
   2
   3 ;; Copyright (C) 1993, 1994, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Albert    <alon@milcse.rtsg.mot.com>
   7 ;; Maintainer: FSF
   8 ;; Created: 1993 Oct 6
   9 ;; Keywords: tools, processes
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 3, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  26 ;; Boston, MA 02110-1301, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; This package is for running a remote compilation and using emacs to parse
  31 ;; the error messages. It works by rsh'ing the compilation to a remote host
  32 ;; and parsing the output. If the file visited at the time remote-compile was
  33 ;; called was loaded remotely (ange-ftp), the host and user name are obtained
  34 ;; by the calling ange-ftp-ftp-name on the current directory. In this case the
  35 ;; next-error command will also ange-ftp the files over. This is achieved
  36 ;; automatically because the compilation-parse-errors function uses
  37 ;; default-directory to build its file names. If however the file visited was
  38 ;; loaded locally, remote-compile prompts for a host and user and assumes the
  39 ;; files mounted locally (otherwise, how was the visited file loaded).
  40
  41 ;; See the user defined variables section for more info.
  42
  43 ;; I was contemplating redefining "compile" to "remote-compile" automatically
  44 ;; if the file visited was ange-ftp'ed but decided against it for now. If you
  45 ;; feel this is a good idea, let me know and I'll consider it again.
  46
  47 ;; Installation:
  48
  49 ;; To use rcompile, you also need to give yourself permission to connect to
  50 ;; the remote host.  You do this by putting lines like:
  51
  52 ;; monopoly alon
  53 ;; vme33
  54 ;;
  55 ;; in a file named .rhosts in the home directory (of the remote machine).
  56 ;; Be careful what you put in this file. A line like:
  57 ;;
  58 ;; +
  59 ;;
  60 ;; Will allow anyone access to your account without a password. I suggest you
  61 ;; read the rhosts(5) manual page before you edit this file (if you are not
  62 ;; familiar with it already)
  63 \f
  64 ;;; Code:
  65
  66 (provide 'rcompile)
  67 (require 'compile)
  68 ;;; The following should not be needed.
  69 ;;; (eval-when-compile (require 'ange-ftp))
  70
  71 ;;;; user defined variables
  72
  73 (defgroup remote-compile nil
  74   "Run a compilation on a remote machine."
  75   :group 'processes
  76   :group 'tools)
  77
  78
  79 (defcustom remote-compile-host nil
  80   "*Host for remote compilations."
  81   :type '(choice string (const nil))
  82   :group 'remote-compile)
  83
  84 (defcustom remote-compile-user nil
  85   "User for remote compilations.
  86 nil means use the value returned by \\[user-login-name]."
  87   :type '(choice string (const nil))
  88   :group 'remote-compile)
  89
  90 (defcustom remote-compile-run-before nil
  91   "*Command to run before compilation.
  92 This can be used for setting up environment variables,
  93 since rsh does not invoke the shell as a login shell and files like .login
  94 \(tcsh\) and .bash_profile \(bash\) are not run.
  95 nil means run no commands."
  96   :type '(choice string (const nil))
  97   :group 'remote-compile)
  98
  99 (defcustom remote-compile-prompt-for-host nil
 100   "*Non-nil means prompt for host if not available from filename."
 101   :type 'boolean
 102   :group 'remote-compile)
 103
 104 (defcustom remote-compile-prompt-for-user nil
 105   "*Non-nil means prompt for user if not available from filename."
 106   :type 'boolean
 107   :group 'remote-compile)
 108
 109 ;;;; internal variables
 110
 111 ;; History of remote compile hosts and users
 112 (defvar remote-compile-host-history nil)
 113 (defvar remote-compile-user-history nil)
 114
 115 \f
 116 ;;;; entry point
 117
 118 ;; We use the Tramp internal function`tramp-make-tramp-file-name'.
 119 ;; Better would be, if there are functions to provide user, host and
 120 ;; localname of a remote filename, independent of Tramp's implementation.
 121 ;; The function calls are wrapped by `funcall' in order to pacify the byte
 122 ;; compiler.  ange-ftp check removed, because it is handled also by Tramp.
 123 ;;;###autoload
 124 (defun remote-compile (host user command)
 125   "Compile the current buffer's directory on HOST.  Log in as USER.
 126 See \\[compile]."
 127   (interactive
 128    (let (host user command prompt l l-host l-user)
 129      (setq prompt (if (stringp remote-compile-host)
 130                       (format "Compile on host (default %s): "
 131                               remote-compile-host)
 132                     "Compile on host: ")
 133            host (if (or remote-compile-prompt-for-host
 134                         (null remote-compile-host))
 135                     (read-from-minibuffer prompt
 136                                           "" nil nil
 137                                           'remote-compile-host-history)
 138                   remote-compile-host)
 139            user (if remote-compile-prompt-for-user
 140                     (read-from-minibuffer (format
 141                                            "Compile by user (default %s): "
 142                                            (or remote-compile-user
 143                                                (user-login-name)))
 144                                           "" nil nil
 145                                           'remote-compile-user-history)
 146                   remote-compile-user))
 147      (setq command (read-from-minibuffer "Compile command: "
 148                                          compile-command nil nil
 149                                          '(compile-history . 1)))
 150      (list (if (string= host "") remote-compile-host host)
 151            (if (string= user "") remote-compile-user user)
 152            command)))
 153   (setq compile-command command)
 154   (cond (user
 155          (setq remote-compile-user user))
 156         ((null remote-compile-user)
 157          (setq remote-compile-user (user-login-name))))
 158   (let* (localname ;; Pacify byte-compiler.
 159          (compile-command
 160           (format "%s %s -l %s \"(%scd %s; %s)\""
 161                   remote-shell-program
 162                   host
 163                   remote-compile-user
 164                   (if remote-compile-run-before
 165                       (concat remote-compile-run-before "; ")
 166                     "")
 167                   ""
 168                   compile-command)))
 169     (setq remote-compile-host host)
 170     (save-some-buffers nil nil)
 171     (compilation-start compile-command)
 172     ;; Set comint-file-name-prefix in the compilation buffer so
 173     ;; compilation-parse-errors will find referenced files by Tramp.
 174     (with-current-buffer compilation-last-buffer
 175       (when (fboundp 'tramp-make-tramp-file-name)
 176         (set (make-local-variable 'comint-file-name-prefix)
 177              (tramp-make-tramp-file-name
 178               nil ;; method.
 179               remote-compile-user
 180               remote-compile-host
 181               ""))))))
 182
 183 ;; arch-tag: 2866a132-ece4-4ce9-9f91-ec147f803f73
 184 ;;; rcompile.el ends here