code.delx.au - gnu-emacs/blob - lisp/skeleton.el

   1 ;;; skeleton.el --- Lisp language extension for writing statement skeletons
   2
   3 ;; Copyright (C) 1993, 1994, 1995, 1996 by Free Software Foundation, Inc.
   4
   5 ;; Author: Daniel.Pfeiffer@Informatik.START.dbp.de, fax (+49 69) 7588-2389
   6 ;; Maintainer: FSF
   7 ;; Keywords: extensions, abbrev, languages, tools
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; A very concise language extension for writing structured statement
  29 ;; skeleton insertion commands for programming language modes.  This
  30 ;; originated in shell-script mode and was applied to ada-mode's
  31 ;; commands which shrunk to one third.  And these commands are now
  32 ;; user configurable.
  33
  34 ;;; Code:
  35
  36 ;; page 1:      statement skeleton language definition & interpreter
  37 ;; page 2:      paired insertion
  38 ;; page 3:      mirror-mode, an example for setting up paired insertion
  39
  40
  41 (defvar skeleton-transformation nil
  42   "*If non-nil, function applied to literal strings before they are inserted.
  43 It should take strings and characters and return them transformed, or nil
  44 which means no transformation.
  45 Typical examples might be `upcase' or `capitalize'.")
  46
  47 ; this should be a fourth argument to defvar
  48 (put 'skeleton-transformation 'variable-interactive
  49      "aTransformation function: ")
  50
  51
  52 (defvar skeleton-autowrap t
  53   "Controls wrapping behaviour of functions created with `define-skeleton'.
  54 When the region is visible (due to `transient-mark-mode' or marking a region
  55 with the mouse) and this is non-`nil' and the function was called without an
  56 explicit ARG, then the ARG defaults to -1, i.e. wrapping around the visible
  57 region.
  58
  59 We will probably delete this variable in a future Emacs version
  60 unless we get a substantial number of complaints about the auto-wrap
  61 feature.")
  62
  63 (defvar skeleton-end-hook
  64   (lambda ()
  65     (or (eolp) (newline-and-indent)))
  66   "Hook called at end of skeleton but before going to point of interest.
  67 By default this moves out anything following to next line.
  68 The variables `v1' and `v2' are still set when calling this.")
  69
  70
  71 ;;;###autoload
  72 (defvar skeleton-filter 'identity
  73   "Function for transforming a skeleton proxy's aliases' variable value.")
  74
  75 (defvar skeleton-untabify t
  76   "When non-`nil' untabifies when deleting backwards with element -ARG.")
  77
  78 (defvar skeleton-newline-indent-rigidly nil
  79   "When non-`nil', indent rigidly under current line for element `\\n'.
  80 Else use mode's `indent-line-function'.")
  81
  82 (defvar skeleton-further-elements ()
  83   "A buffer-local varlist (see `let') of mode specific skeleton elements.
  84 These variables are bound while interpreting a skeleton.  Their value may
  85 in turn be any valid skeleton element if they are themselves to be used as
  86 skeleton elements.")
  87 (make-variable-buffer-local 'skeleton-further-elements)
  88
  89
  90 (defvar skeleton-subprompt
  91   (substitute-command-keys
  92    "RET, \\<minibuffer-local-map>\\[abort-recursive-edit] or \\[help-command]")
  93   "*Replacement for %s in prompts of recursive subskeletons.")
  94
  95
  96 (defvar skeleton-abbrev-cleanup nil
  97   "Variable used to delete the character that led to abbrev expansion.")
  98
  99
 100 (defvar skeleton-debug nil
 101   "*If non-nil `define-skeleton' will override previous definition.")
 102
 103 (defvar skeleton-positions nil
 104   "List of positions marked with @, after skeleton insertion.
 105 The list describes the most recent skeleton insertion, and its elements
 106 are integer buffer positions in the reverse order of the insertion order.")
 107
 108 ;; reduce the number of compiler warnings
 109 (defvar skeleton)
 110 (defvar skeleton-modified)
 111 (defvar skeleton-point)
 112 (defvar skeleton-regions)
 113
 114 ;;;###autoload
 115 (defmacro define-skeleton (command documentation &rest skeleton)
 116   "Define a user-configurable COMMAND that enters a statement skeleton.
 117 DOCUMENTATION is that of the command, while the variable of the same name,
 118 which contains the skeleton, has a documentation to that effect.
 119 INTERACTOR and ELEMENT ... are as defined under `skeleton-insert'."
 120   (if skeleton-debug
 121       (set command skeleton))
 122   `(progn
 123      (defun ,command (&optional str arg)
 124        ,(concat documentation
 125                 (if (string-match "\n\\>" documentation)
 126                     "" "\n")
 127                 "\n"
 128   "This is a skeleton command (see `skeleton-insert').
 129 Normally the skeleton text is inserted at point, with nothing \"inside\".
 130 If there is a highlighted region, the skeleton text is wrapped
 131 around the region text.
 132
 133 A prefix argument ARG says to wrap the skeleton around the next ARG words.
 134 A prefix argument of zero says to wrap around zero words---that is, nothing.
 135 This is a way of overiding the use of a highlighted region.")
 136        (interactive "*P\nP")
 137        (skeleton-proxy-new ',skeleton str arg))))
 138
 139 ;;;###autoload
 140 (defun skeleton-proxy-new (skeleton &optional str arg)
 141   "Insert skeleton defined by variable of same name (see `skeleton-insert').
 142 Prefix ARG allows wrapping around words or regions (see `skeleton-insert').
 143 If no ARG was given, but the region is visible, ARG defaults to -1 depending
 144 on `skeleton-autowrap'.  An ARG of  M-0  will prevent this just for once.
 145 This command can also be an abbrev expansion (3rd and 4th columns in
 146 \\[edit-abbrevs]  buffer: \"\"  command-name).
 147
 148 When called as a function, optional first argument STR may also be a string
 149 which will be the value of `str' whereas the skeleton's interactor is then
 150 ignored."
 151   (interactive "*P\nP")
 152   (setq skeleton (funcall skeleton-filter skeleton))
 153   (if (not skeleton)
 154       (if (memq this-command '(self-insert-command
 155                                skeleton-pair-insert-maybe
 156                                expand-abbrev))
 157           (setq buffer-undo-list (primitive-undo 1 buffer-undo-list)))
 158     (skeleton-insert skeleton
 159                      (if (setq skeleton-abbrev-cleanup
 160                                (or (eq this-command 'self-insert-command)
 161                                    (eq this-command
 162                                        'skeleton-pair-insert-maybe)))
 163                          ()
 164                        ;; Pretend  C-x a e  passed its prefix arg to us
 165                        (if (or arg current-prefix-arg)
 166                            (prefix-numeric-value (or arg
 167                                                      current-prefix-arg))
 168                          (and skeleton-autowrap
 169                               (or (eq last-command 'mouse-drag-region)
 170                                   (and transient-mark-mode mark-active))
 171                               -1)))
 172                      (if (stringp str)
 173                          str))
 174     (and skeleton-abbrev-cleanup
 175          (setq skeleton-abbrev-cleanup (point))
 176          (add-hook 'post-command-hook 'skeleton-abbrev-cleanup nil t))))
 177
 178 ;; This command isn't meant to be called, only its aliases with meaningful
 179 ;; names are.
 180 ;;;###autoload
 181 (defun skeleton-proxy (&optional str arg)
 182   "Insert skeleton defined by variable of same name (see `skeleton-insert').
 183 Prefix ARG allows wrapping around words or regions (see `skeleton-insert').
 184 If no ARG was given, but the region is visible, ARG defaults to -1 depending
 185 on `skeleton-autowrap'.  An ARG of  M-0  will prevent this just for once.
 186 This command can also be an abbrev expansion (3rd and 4th columns in
 187 \\[edit-abbrevs]  buffer: \"\"  command-name).
 188
 189 When called as a function, optional first argument STR may also be a string
 190 which will be the value of `str' whereas the skeleton's interactor is then
 191 ignored."
 192   (interactive "*P\nP")
 193   (let ((function (nth 1 (backtrace-frame 1))))
 194     (if (eq function 'nth)              ; uncompiled Lisp function
 195         (setq function (nth 1 (backtrace-frame 5)))
 196       (if (eq function 'byte-code)      ; tracing byte-compiled function
 197           (setq function (nth 1 (backtrace-frame 2)))))
 198     (if (not (setq function (funcall skeleton-filter (symbol-value function))))
 199         (if (memq this-command '(self-insert-command
 200                                  skeleton-pair-insert-maybe
 201                                  expand-abbrev))
 202             (setq buffer-undo-list (primitive-undo 1 buffer-undo-list)))
 203       (skeleton-insert function
 204                        (if (setq skeleton-abbrev-cleanup
 205                                  (or (eq this-command 'self-insert-command)
 206                                      (eq this-command
 207                                          'skeleton-pair-insert-maybe)))
 208                            ()
 209                          ;; Pretend  C-x a e  passed its prefix arg to us
 210                          (if (or arg current-prefix-arg)
 211                              (prefix-numeric-value (or arg
 212                                                        current-prefix-arg))
 213                            (and skeleton-autowrap
 214                                 (or (eq last-command 'mouse-drag-region)
 215                                     (and transient-mark-mode mark-active))
 216                                 -1)))
 217                        (if (stringp str)
 218                            str))
 219       (and skeleton-abbrev-cleanup
 220            (setq skeleton-abbrev-cleanup (point))
 221            (add-hook 'post-command-hook 'skeleton-abbrev-cleanup nil t)))))
 222
 223
 224 (defun skeleton-abbrev-cleanup (&rest list)
 225   "Value for `post-command-hook' to remove char that expanded abbrev."
 226   (if (integerp skeleton-abbrev-cleanup)
 227       (progn
 228         (delete-region skeleton-abbrev-cleanup (point))
 229         (setq skeleton-abbrev-cleanup)
 230         (remove-hook 'post-command-hook 'skeleton-abbrev-cleanup t))))
 231
 232
 233 ;;;###autoload
 234 (defun skeleton-insert (skeleton &optional regions str)
 235   "Insert the complex statement skeleton SKELETON describes very concisely.
 236
 237 With optional second argument REGIONS, wrap first interesting point
 238 \(`_') in skeleton around next REGIONS words, if REGIONS is positive.
 239 If REGIONS is negative, wrap REGIONS preceding interregions into first
 240 REGIONS interesting positions \(successive `_'s) in skeleton.
 241
 242 An interregion is the stretch of text between two contiguous marked
 243 points.  If you marked A B C [] (where [] is the cursor) in
 244 alphabetical order, the 3 interregions are simply the last 3 regions.
 245 But if you marked B A [] C, the interregions are B-A, A-[], []-C.
 246
 247 The optional third argument STR, if specified, is the value for the
 248 variable `str' within the skeleton.  When this is non-nil, the
 249 interactor gets ignored, and this should be a valid skeleton element.
 250
 251 SKELETON is made up as (INTERACTOR ELEMENT ...).  INTERACTOR may be nil if
 252 not needed, a prompt-string or an expression for complex read functions.
 253
 254 If ELEMENT is a string or a character it gets inserted (see also
 255 `skeleton-transformation').  Other possibilities are:
 256
 257         \\n     go to next line and indent according to mode
 258         _       interesting point, interregion here, point after termination
 259         >       indent line (or interregion if > _) according to major mode
 260         @       add position to `skeleton-positions'
 261         &       do next ELEMENT if previous moved point
 262         |       do next ELEMENT if previous didn't move point
 263         -num    delete num preceding characters (see `skeleton-untabify')
 264         resume: skipped, continue here if quit is signaled
 265         nil     skipped
 266
 267 Further elements can be defined via `skeleton-further-elements'.  ELEMENT may
 268 itself be a SKELETON with an INTERACTOR.  The user is prompted repeatedly for
 269 different inputs.  The SKELETON is processed as often as the user enters a
 270 non-empty string.  \\[keyboard-quit] terminates skeleton insertion, but
 271 continues after `resume:' and positions at `_' if any.  If INTERACTOR in such
 272 a subskeleton is a prompt-string which contains a \".. %s ..\" it is
 273 formatted with `skeleton-subprompt'.  Such an INTERACTOR may also be a list of
 274 strings with the subskeleton being repeated once for each string.
 275
 276 Quoted Lisp expressions are evaluated for their side-effects.
 277 Other Lisp expressions are evaluated and the value treated as above.
 278 Note that expressions may not return `t' since this implies an
 279 endless loop.  Modes can define other symbols by locally setting them
 280 to any valid skeleton element.  The following local variables are
 281 available:
 282
 283         str     first time: read a string according to INTERACTOR
 284                 then: insert previously read string once more
 285         help    help-form during interaction with the user or `nil'
 286         input   initial input (string or cons with index) while reading str
 287         v1, v2  local variables for memorizing anything you want
 288
 289 When done with skeleton, but before going back to `_'-point call
 290 `skeleton-end-hook' if that is non-`nil'."
 291   (let ((skeleton-regions regions))
 292     (and skeleton-regions
 293          (setq skeleton-regions
 294                (if (> skeleton-regions 0)
 295                    (list (point-marker)
 296                          (save-excursion (forward-word skeleton-regions)
 297                                          (point-marker)))
 298                  (setq skeleton-regions (- skeleton-regions))
 299                  ;; copy skeleton-regions - 1 elements from `mark-ring'
 300                  (let ((l1 (cons (mark-marker) mark-ring))
 301                        (l2 (list (point-marker))))
 302                    (while (and l1 (> skeleton-regions 0))
 303                      (setq l2 (cons (car l1) l2)
 304                            skeleton-regions (1- skeleton-regions)
 305                            l1 (cdr l1)))
 306                    (sort l2 '<))))
 307          (goto-char (car skeleton-regions))
 308          (setq skeleton-regions (cdr skeleton-regions)))
 309     (let ((beg (point))
 310           skeleton-modified skeleton-point resume: help input v1 v2)
 311       (setq skeleton-positions nil)
 312       (unwind-protect
 313           (eval `(let ,skeleton-further-elements
 314                    (skeleton-internal-list skeleton str)))
 315         (run-hooks 'skeleton-end-hook)
 316         (sit-for 0)
 317         (or (pos-visible-in-window-p beg)
 318             (progn
 319               (goto-char beg)
 320               (recenter 0)))
 321         (if skeleton-point
 322             (goto-char skeleton-point))))))
 323
 324 (defun skeleton-read (prompt &optional initial-input recursive)
 325   "Function for reading a string from the minibuffer within skeletons.
 326 PROMPT may contain a `%s' which will be replaced by `skeleton-subprompt'.
 327 If non-`nil' second arg INITIAL-INPUT or variable `input' is a string or
 328 cons with index to insert before reading.  If third arg RECURSIVE is non-`nil'
 329 i.e. we are handling the iterator of a subskeleton, returns empty string if
 330 user didn't modify input.
 331 While reading, the value of `minibuffer-help-form' is variable `help' if that
 332 is non-nil or a default string."
 333   (let ((minibuffer-help-form (or (if (boundp 'help) (symbol-value 'help))
 334                                   (if recursive "\
 335 As long as you provide input you will insert another subskeleton.
 336
 337 If you enter the empty string, the loop inserting subskeletons is
 338 left, and the current one is removed as far as it has been entered.
 339
 340 If you quit, the current subskeleton is removed as far as it has been
 341 entered.  No more of the skeleton will be inserted, except maybe for a
 342 syntactically necessary termination."
 343                                     "\
 344 You are inserting a skeleton.  Standard text gets inserted into the buffer
 345 automatically, and you are prompted to fill in the variable parts.")))
 346         (eolp (eolp)))
 347     ;; since Emacs doesn't show main window's cursor, do something noticeable
 348     (or eolp
 349         (open-line 1))
 350     (unwind-protect
 351         (setq prompt (if (stringp prompt)
 352                          (read-string (format prompt skeleton-subprompt)
 353                                       (setq initial-input
 354                                             (or initial-input
 355                                                 (symbol-value 'input))))
 356                        (eval prompt)))
 357       (or eolp
 358           (delete-char 1))))
 359   (if (and recursive
 360            (or (null prompt)
 361                (string= prompt "")
 362                (equal prompt initial-input)
 363                (equal prompt (car-safe initial-input))))
 364       (signal 'quit t)
 365     prompt))
 366
 367 (defun skeleton-internal-list (skeleton &optional str recursive)
 368   (let* ((start (save-excursion (beginning-of-line) (point)))
 369          (column (current-column))
 370          (line (buffer-substring start
 371                                  (save-excursion (end-of-line) (point))))
 372          opoint)
 373     (or str
 374         (setq str `(setq str (skeleton-read ',(car skeleton) nil ,recursive))))
 375     (while (setq skeleton-modified (eq opoint (point))
 376                  opoint (point)
 377                  skeleton (cdr skeleton))
 378       (condition-case quit
 379           (skeleton-internal-1 (car skeleton))
 380         (quit
 381          (if (eq (cdr quit) 'recursive)
 382              (setq recursive 'quit
 383                    skeleton (memq 'resume: skeleton))
 384            ;; remove the subskeleton as far as it has been shown
 385            ;; the subskeleton shouldn't have deleted outside current line
 386            (end-of-line)
 387            (delete-region start (point))
 388            (insert line)
 389            (move-to-column column)
 390            (if (cdr quit)
 391                (setq skeleton ()
 392                      recursive nil)
 393              (signal 'quit 'recursive)))))))
 394   ;; maybe continue loop or go on to next outer resume: section
 395   (if (eq recursive 'quit)
 396       (signal 'quit 'recursive)
 397     recursive))
 398
 399
 400 (defun skeleton-internal-1 (element &optional literal)
 401   (cond ((char-or-string-p element)
 402          (if (and (integerp element)    ; -num
 403                   (< element 0))
 404              (if skeleton-untabify
 405                  (backward-delete-char-untabify (- element))
 406                (delete-backward-char (- element)))
 407            (insert-before-markers (if (and skeleton-transformation
 408                                            (not literal))
 409                                       (funcall skeleton-transformation element)
 410                                     element))))
 411         ((eq element '\n)               ; actually (eq '\n 'n)
 412          (if (and skeleton-regions
 413                   (eq (nth 1 skeleton) '_))
 414              (progn
 415                (or (eolp)
 416                    (newline))
 417                (indent-region (point) (car skeleton-regions) nil))
 418            (if skeleton-newline-indent-rigidly
 419                (indent-to (prog1 (current-indentation)
 420                             (newline)))
 421              (newline)
 422              (indent-according-to-mode))))
 423         ((eq element '>)
 424          (if (and skeleton-regions
 425                   (eq (nth 1 skeleton) '_))
 426              (indent-region (point) (car skeleton-regions) nil)
 427            (indent-according-to-mode)))
 428         ((eq element '_)
 429          (if skeleton-regions
 430              (progn
 431                (goto-char (car skeleton-regions))
 432                (setq skeleton-regions (cdr skeleton-regions))
 433                (and (<= (current-column) (current-indentation))
 434                     (eq (nth 1 skeleton) '\n)
 435                     (end-of-line 0)))
 436            (or skeleton-point
 437                (setq skeleton-point (point)))))
 438         ((eq element '&)
 439          (if skeleton-modified
 440              (setq skeleton (cdr skeleton))))
 441         ((eq element '|)
 442          (or skeleton-modified
 443              (setq skeleton (cdr skeleton))))
 444         ((eq element '@)
 445          (setq skeleton-positions (cons (point) skeleton-positions)))
 446         ((eq 'quote (car-safe element))
 447          (eval (nth 1 element)))
 448         ((or (stringp (car-safe element))
 449              (consp (car-safe element)))
 450          (if (symbolp (car-safe (car element)))
 451              (while (skeleton-internal-list element nil t))
 452            (setq literal (car element))
 453            (while literal
 454              (skeleton-internal-list element (car literal))
 455              (setq literal (cdr literal)))))
 456         ((null element))
 457         ((skeleton-internal-1 (eval element) t))))
 458
 459
 460 ;; Maybe belongs into simple.el or elsewhere
 461 ;; ;###autoload
 462 ;;; (define-skeleton local-variables-section
 463 ;;  "Insert a local variables section.  Use current comment syntax if any."
 464 ;;  (completing-read "Mode: " obarray
 465 ;;                 (lambda (symbol)
 466 ;;                   (if (commandp symbol)
 467 ;;                       (string-match "-mode$" (symbol-name symbol))))
 468 ;;                 t)
 469 ;;  '(save-excursion
 470 ;;     (if (re-search-forward page-delimiter nil t)
 471 ;;       (error "Not on last page.")))
 472 ;;  comment-start "Local Variables:" comment-end \n
 473 ;;  comment-start "mode: " str
 474 ;;  & -5 | '(kill-line 0) & -1 | comment-end \n
 475 ;;  ( (completing-read (format "Variable, %s: " skeleton-subprompt)
 476 ;;                   obarray
 477 ;;                   (lambda (symbol)
 478 ;;                     (or (eq symbol 'eval)
 479 ;;                         (user-variable-p symbol)))
 480 ;;                   t)
 481 ;;    comment-start str ": "
 482 ;;    (read-from-minibuffer "Expression: " nil read-expression-map nil
 483 ;;                        'read-expression-history) | _
 484 ;;    comment-end \n)
 485 ;;  resume:
 486 ;;  comment-start "End:" comment-end \n)
 487 \f
 488 ;; Variables and command for automatically inserting pairs like () or "".
 489
 490 (defvar skeleton-pair nil
 491   "*If this is nil pairing is turned off, no matter what else is set.
 492 Otherwise modes with `skeleton-pair-insert-maybe' on some keys
 493 will attempt to insert pairs of matching characters.")
 494
 495
 496 (defvar skeleton-pair-on-word nil
 497   "*If this is nil, paired insertion is inhibited before or inside a word.")
 498
 499
 500 (defvar skeleton-pair-filter (lambda ())
 501   "Attempt paired insertion if this function returns nil, before inserting.
 502 This allows for context-sensitive checking whether pairing is appropriate.")
 503
 504
 505 (defvar skeleton-pair-alist ()
 506   "An override alist of pairing partners matched against `last-command-char'.
 507 Each alist element, which looks like (ELEMENT ...), is passed to
 508 `skeleton-insert' with no interactor.  Variable `str' does nothing.
 509
 510 Elements might be (?` ?` _ \"''\"), (?\\( ?  _ \" )\") or (?{ \\n > _ \\n ?} >).")
 511
 512
 513 ;;;###autoload
 514 (defun skeleton-pair-insert-maybe (arg)
 515   "Insert the character you type ARG times.
 516
 517 With no ARG, if `skeleton-pair' is non-nil, pairing can occur.  If the region
 518 is visible the pair is wrapped around it depending on `skeleton-autowrap'.
 519 Else, if `skeleton-pair-on-word' is non-nil or we are not before or inside a
 520 word, and if `skeleton-pair-filter' returns nil, pairing is performed.
 521
 522 If a match is found in `skeleton-pair-alist', that is inserted, else
 523 the defaults are used.  These are (), [], {}, <> and `' for the
 524 symmetrical ones, and the same character twice for the others."
 525   (interactive "*P")
 526   (let ((mark (and skeleton-autowrap
 527                    (or (eq last-command 'mouse-drag-region)
 528                        (and transient-mark-mode mark-active))))
 529         (skeleton-end-hook))
 530     (if (or arg
 531             (not skeleton-pair)
 532             (and (not mark)
 533                  (or overwrite-mode
 534                      (if (not skeleton-pair-on-word) (looking-at "\\w"))
 535                      (funcall skeleton-pair-filter))))
 536         (self-insert-command (prefix-numeric-value arg))
 537       (setq last-command-char (logand last-command-char 255))
 538       (or skeleton-abbrev-cleanup
 539           (skeleton-insert
 540            (cons nil (or (assq last-command-char skeleton-pair-alist)
 541                          (assq last-command-char '((?( _ ?))
 542                                                    (?[ _ ?])
 543                                                    (?{ _ ?})
 544                                                    (?< _ ?>)
 545                                                    (?` _ ?')))
 546                          `(,last-command-char _ ,last-command-char)))
 547            (if mark -1))))))
 548
 549 \f
 550 ;; A more serious example can be found in sh-script.el
 551 ;;; (defun mirror-mode ()
 552 ;;  "This major mode is an amusing little example of paired insertion.
 553 ;;All printable characters do a paired self insert, while the other commands
 554 ;;work normally."
 555 ;;  (interactive)
 556 ;;  (kill-all-local-variables)
 557 ;;  (make-local-variable 'skeleton-pair)
 558 ;;  (make-local-variable 'skeleton-pair-on-word)
 559 ;;  (make-local-variable 'skeleton-pair-filter)
 560 ;;  (make-local-variable 'skeleton-pair-alist)
 561 ;;  (setq major-mode 'mirror-mode
 562 ;;      mode-name "Mirror"
 563 ;;      skeleton-pair-on-word t
 564 ;;      ;; in the middle column insert one or none if odd window-width
 565 ;;      skeleton-pair-filter (lambda ()
 566 ;;                             (if (>= (current-column)
 567 ;;                                     (/ (window-width) 2))
 568 ;;                                 ;; insert both on next line
 569 ;;                                 (next-line 1)
 570 ;;                               ;; insert one or both?
 571 ;;                               (= (* 2 (1+ (current-column)))
 572 ;;                                  (window-width))))
 573 ;;      ;; mirror these the other way round as well
 574 ;;      skeleton-pair-alist '((?) _ ?()
 575 ;;                            (?] _ ?[)
 576 ;;                            (?} _ ?{)
 577 ;;                            (?> _ ?<)
 578 ;;                            (?/ _ ?\\)
 579 ;;                            (?\\ _ ?/)
 580 ;;                            (?` ?` _ "''")
 581 ;;                            (?' ?' _ "``"))
 582 ;;      ;; in this mode we exceptionally ignore the user, else it's no fun
 583 ;;      skeleton-pair t)
 584 ;;  (let ((map (make-vector 256 'skeleton-pair-insert-maybe))
 585 ;;      (i 0))
 586 ;;    (use-local-map `(keymap ,map))
 587 ;;    (while (< i ? )
 588 ;;      (aset map i nil)
 589 ;;      (aset map (+ i 128) nil)
 590 ;;      (setq i (1+ i))))
 591 ;;  (run-hooks 'mirror-mode-hook))
 592
 593 (provide 'skeleton)
 594
 595 ;; skeleton.el ends here