code.delx.au - gnu-emacs/blob - lisp/vc/vc-git.el

   1 ;;; vc-git.el --- VC backend for the git version control system -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2006-2014 Free Software Foundation, Inc.
   4
   5 ;; Author: Alexandre Julliard <julliard@winehq.org>
   6 ;; Keywords: vc tools
   7 ;; Package: vc
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; This file contains a VC backend for the git version control
  27 ;; system.
  28 ;;
  29
  30 ;;; Installation:
  31
  32 ;; To install: put this file on the load-path and add Git to the list
  33 ;; of supported backends in `vc-handled-backends'; the following line,
  34 ;; placed in your init file, will accomplish this:
  35 ;;
  36 ;;     (add-to-list 'vc-handled-backends 'Git)
  37
  38 ;;; Todo:
  39 ;;  - check if more functions could use vc-git-command instead
  40 ;;     of start-process.
  41 ;;  - changelog generation
  42
  43 ;; Implement the rest of the vc interface. See the comment at the
  44 ;; beginning of vc.el. The current status is:
  45 ;; ("??" means: "figure out what to do about it")
  46 ;;
  47 ;; FUNCTION NAME                                   STATUS
  48 ;; BACKEND PROPERTIES
  49 ;; * revision-granularity                          OK
  50 ;; STATE-QUERYING FUNCTIONS
  51 ;; * registered (file)                             OK
  52 ;; * state (file)                                  OK
  53 ;; - dir-status-files (dir files uf)               OK
  54 ;; * working-revision (file)                       OK
  55 ;; - latest-on-branch-p (file)                     NOT NEEDED
  56 ;; * checkout-model (files)                        OK
  57 ;; - mode-line-string (file)                       OK
  58 ;; STATE-CHANGING FUNCTIONS
  59 ;; * create-repo ()                                OK
  60 ;; * register (files &optional rev comment)        OK
  61 ;; - responsible-p (file)                          OK
  62 ;; - receive-file (file rev)                       NOT NEEDED
  63 ;; - unregister (file)                             OK
  64 ;; * checkin (files rev comment)                   OK
  65 ;; * find-revision (file rev buffer)               OK
  66 ;; * checkout (file &optional rev)                 OK
  67 ;; * revert (file &optional contents-done)         OK
  68 ;; - rollback (files)                              COULD BE SUPPORTED
  69 ;; - merge-file (file rev1 rev2)            It would be possible to merge
  70 ;;                                          changes into a single file, but
  71 ;;                                          when committing they wouldn't
  72 ;;                                          be identified as a merge
  73 ;;                                          by git, so it's probably
  74 ;;                                          not a good idea.
  75 ;; - merge-news (file)                      see `merge-file'
  76 ;; - steal-lock (file &optional revision)          NOT NEEDED
  77 ;; HISTORY FUNCTIONS
  78 ;; * print-log (files buffer &optional shortlog start-revision limit)   OK
  79 ;; - log-view-mode ()                              OK
  80 ;; - show-log-entry (revision)                     OK
  81 ;; - comment-history (file)                        ??
  82 ;; - update-changelog (files)                      COULD BE SUPPORTED
  83 ;; * diff (file &optional rev1 rev2 buffer)        OK
  84 ;; - revision-completion-table (files)             OK
  85 ;; - annotate-command (file buf &optional rev)     OK
  86 ;; - annotate-time ()                              OK
  87 ;; - annotate-current-time ()                      NOT NEEDED
  88 ;; - annotate-extract-revision-at-line ()          OK
  89 ;; TAG SYSTEM
  90 ;; - create-tag (dir name branchp)                 OK
  91 ;; - retrieve-tag (dir name update)                OK
  92 ;; MISCELLANEOUS
  93 ;; - make-version-backups-p (file)                 NOT NEEDED
  94 ;; - previous-revision (file rev)                  OK
  95 ;; - next-revision (file rev)                      OK
  96 ;; - check-headers ()                              COULD BE SUPPORTED
  97 ;; - delete-file (file)                            OK
  98 ;; - rename-file (old new)                         OK
  99 ;; - find-file-hook ()                             OK
 100 ;; - conflicted-files                              OK
 101
 102 ;;; Code:
 103
 104 (eval-when-compile
 105   (require 'cl-lib)
 106   (require 'vc)
 107   (require 'vc-dir)
 108   (require 'grep))
 109
 110 (defgroup vc-git nil
 111   "VC Git backend."
 112   :version "24.1"
 113   :group 'vc)
 114
 115 (defcustom vc-git-diff-switches t
 116   "String or list of strings specifying switches for Git diff under VC.
 117 If nil, use the value of `vc-diff-switches'.  If t, use no switches."
 118   :type '(choice (const :tag "Unspecified" nil)
 119                  (const :tag "None" t)
 120                  (string :tag "Argument String")
 121                  (repeat :tag "Argument List" :value ("") string))
 122   :version "23.1"
 123   :group 'vc-git)
 124
 125 (defcustom vc-git-program "git"
 126   "Name of the Git executable (excluding any arguments)."
 127   :version "24.1"
 128   :type 'string
 129   :group 'vc-git)
 130
 131 (defcustom vc-git-root-log-format
 132   '("%d%h..: %an %ad %s"
 133     ;; The first shy group matches the characters drawn by --graph.
 134     ;; We use numbered groups because `log-view-message-re' wants the
 135     ;; revision number to be group 1.
 136     "^\\(?:[*/\\| ]+ \\)?\\(?2: ([^)]+)\\)?\\(?1:[0-9a-z]+\\)..: \
 137 \\(?3:.*?\\)[ \t]+\\(?4:[0-9]\\{4\\}-[0-9]\\{2\\}-[0-9]\\{2\\}\\)"
 138     ((1 'log-view-message-face)
 139      (2 'change-log-list nil lax)
 140      (3 'change-log-name)
 141      (4 'change-log-date)))
 142   "Git log format for `vc-print-root-log'.
 143 This should be a list (FORMAT REGEXP KEYWORDS), where FORMAT is a
 144 format string (which is passed to \"git log\" via the argument
 145 \"--pretty=tformat:FORMAT\"), REGEXP is a regular expression
 146 matching the resulting Git log output, and KEYWORDS is a list of
 147 `font-lock-keywords' for highlighting the Log View buffer."
 148   :type '(list string string (repeat sexp))
 149   :group 'vc-git
 150   :version "24.1")
 151
 152 (defvar vc-git-commits-coding-system 'utf-8
 153   "Default coding system for git commits.")
 154
 155 ;; History of Git commands.
 156 (defvar vc-git-history nil)
 157
 158 ;;; BACKEND PROPERTIES
 159
 160 (defun vc-git-revision-granularity () 'repository)
 161 (defun vc-git-checkout-model (_files) 'implicit)
 162
 163 ;;; STATE-QUERYING FUNCTIONS
 164
 165 ;;;###autoload (defun vc-git-registered (file)
 166 ;;;###autoload   "Return non-nil if FILE is registered with git."
 167 ;;;###autoload   (if (vc-find-root file ".git")       ; Short cut.
 168 ;;;###autoload       (progn
 169 ;;;###autoload         (load "vc-git" nil t)
 170 ;;;###autoload         (vc-git-registered file))))
 171
 172 (defun vc-git-registered (file)
 173   "Check whether FILE is registered with git."
 174   (let ((dir (vc-git-root file)))
 175     (when dir
 176       (with-temp-buffer
 177         (let* (process-file-side-effects
 178                ;; Do not use the `file-name-directory' here: git-ls-files
 179                ;; sometimes fails to return the correct status for relative
 180                ;; path specs.
 181                ;; See also: http://marc.info/?l=git&m=125787684318129&w=2
 182                (name (file-relative-name file dir))
 183                (str (ignore-errors
 184                       (cd dir)
 185                       (vc-git--out-ok "ls-files" "-c" "-z" "--" name)
 186                       ;; If result is empty, use ls-tree to check for deleted
 187                       ;; file.
 188                       (when (eq (point-min) (point-max))
 189                         (vc-git--out-ok "ls-tree" "--name-only" "-z" "HEAD"
 190                                         "--" name))
 191                       (buffer-string))))
 192           (and str
 193                (> (length str) (length name))
 194                (string= (substring str 0 (1+ (length name)))
 195                         (concat name "\0"))))))))
 196
 197 (defun vc-git--state-code (code)
 198   "Convert from a string to a added/deleted/modified state."
 199   (pcase (string-to-char code)
 200     (?M 'edited)
 201     (?A 'added)
 202     (?D 'removed)
 203     (?U 'edited)     ;; FIXME
 204     (?T 'edited)))   ;; FIXME
 205
 206 (defun vc-git-state (file)
 207   "Git-specific version of `vc-state'."
 208   ;; FIXME: This can't set 'ignored or 'conflict yet
 209   ;; The 'ignored state could be detected with `git ls-files -i -o
 210   ;; --exclude-standard` It also can't set 'needs-update or
 211   ;; 'needs-merge. The rough equivalent would be that upstream branch
 212   ;; for current branch is in fast-forward state i.e. current branch
 213   ;; is direct ancestor of corresponding upstream branch, and the file
 214   ;; was modified upstream.  But we can't check that without a network
 215   ;; operation.
 216   ;; This assumes that status is known to be not `unregistered' because
 217   ;; we've been successfully dispatched here from `vc-state', that
 218   ;; means `vc-git-registered' returned t earlier once.  Bug#11757
 219   (let ((diff (vc-git--run-command-string
 220                file "diff-index" "-p" "--raw" "-z" "HEAD" "--")))
 221     (if (and diff
 222              (string-match ":[0-7]\\{6\\} [0-7]\\{6\\} [0-9a-f]\\{40\\} [0-9a-f]\\{40\\} \\([ADMUT]\\)\0[^\0]+\0\\(.*\n.\\)?"
 223                            diff))
 224         (let ((diff-letter (match-string 1 diff)))
 225           (if (not (match-beginning 2))
 226               ;; Empty diff: file contents is the same as the HEAD
 227               ;; revision, but timestamps are different (eg, file
 228               ;; was "touch"ed).  Update timestamp in index:
 229               (prog1 'up-to-date
 230                 (vc-git--call nil "add" "--refresh" "--"
 231                               (file-relative-name file)))
 232             (vc-git--state-code diff-letter)))
 233       (if (vc-git--empty-db-p) 'added 'up-to-date))))
 234
 235 (defun vc-git-working-revision (file)
 236   "Git-specific version of `vc-working-revision'."
 237   (let* (process-file-side-effects
 238          (str (vc-git--run-command-string nil "symbolic-ref" "HEAD")))
 239     (vc-file-setprop file 'vc-git-detached (null str))
 240     (if str
 241         (if (string-match "^\\(refs/heads/\\)?\\(.+\\)$" str)
 242             (match-string 2 str)
 243           str)
 244       (vc-git--rev-parse "HEAD"))))
 245
 246 (defun vc-git-mode-line-string (file)
 247   "Return a string for `vc-mode-line' to put in the mode line for FILE."
 248   (let* ((rev (vc-working-revision file))
 249          (detached (vc-file-getprop file 'vc-git-detached))
 250          (def-ml (vc-default-mode-line-string 'Git file))
 251          (help-echo (get-text-property 0 'help-echo def-ml)))
 252     (propertize (if detached
 253                     (substring def-ml 0 (- 7 (length rev)))
 254                   def-ml)
 255                 'help-echo (concat help-echo "\nCurrent revision: " rev))))
 256
 257 (cl-defstruct (vc-git-extra-fileinfo
 258             (:copier nil)
 259             (:constructor vc-git-create-extra-fileinfo
 260                           (old-perm new-perm &optional rename-state orig-name))
 261             (:conc-name vc-git-extra-fileinfo->))
 262   old-perm new-perm   ;; Permission flags.
 263   rename-state        ;; Rename or copy state.
 264   orig-name)          ;; Original name for renames or copies.
 265
 266 (defun vc-git-escape-file-name (name)
 267   "Escape a file name if necessary."
 268   (if (string-match "[\n\t\"\\]" name)
 269       (concat "\""
 270               (mapconcat (lambda (c)
 271                    (pcase c
 272                      (?\n "\\n")
 273                      (?\t "\\t")
 274                      (?\\ "\\\\")
 275                      (?\" "\\\"")
 276                      (_ (char-to-string c))))
 277                  name "")
 278               "\"")
 279     name))
 280
 281 (defun vc-git-file-type-as-string (old-perm new-perm)
 282   "Return a string describing the file type based on its permissions."
 283   (let* ((old-type (lsh (or old-perm 0) -9))
 284          (new-type (lsh (or new-perm 0) -9))
 285          (str (pcase new-type
 286                 (?\100  ;; File.
 287                  (pcase old-type
 288                    (?\100 nil)
 289                    (?\120 "   (type change symlink -> file)")
 290                    (?\160 "   (type change subproject -> file)")))
 291                  (?\120  ;; Symlink.
 292                   (pcase old-type
 293                     (?\100 "   (type change file -> symlink)")
 294                     (?\160 "   (type change subproject -> symlink)")
 295                     (t "   (symlink)")))
 296                   (?\160  ;; Subproject.
 297                    (pcase old-type
 298                      (?\100 "   (type change file -> subproject)")
 299                      (?\120 "   (type change symlink -> subproject)")
 300                      (t "   (subproject)")))
 301                   (?\110 nil)  ;; Directory (internal, not a real git state).
 302                   (?\000  ;; Deleted or unknown.
 303                    (pcase old-type
 304                      (?\120 "   (symlink)")
 305                      (?\160 "   (subproject)")))
 306                   (_ (format "   (unknown type %o)" new-type)))))
 307     (cond (str (propertize str 'face 'font-lock-comment-face))
 308           ((eq new-type ?\110) "/")
 309           (t ""))))
 310
 311 (defun vc-git-rename-as-string (state extra)
 312   "Return a string describing the copy or rename associated with INFO,
 313 or an empty string if none."
 314   (let ((rename-state (when extra
 315                         (vc-git-extra-fileinfo->rename-state extra))))
 316     (if rename-state
 317         (propertize
 318          (concat "   ("
 319                  (if (eq rename-state 'copy) "copied from "
 320                    (if (eq state 'added) "renamed from "
 321                      "renamed to "))
 322                  (vc-git-escape-file-name
 323                   (vc-git-extra-fileinfo->orig-name extra))
 324                  ")")
 325          'face 'font-lock-comment-face)
 326       "")))
 327
 328 (defun vc-git-permissions-as-string (old-perm new-perm)
 329   "Format a permission change as string."
 330   (propertize
 331    (if (or (not old-perm)
 332            (not new-perm)
 333            (eq 0 (logand ?\111 (logxor old-perm new-perm))))
 334        "  "
 335      (if (eq 0 (logand ?\111 old-perm)) "+x" "-x"))
 336   'face 'font-lock-type-face))
 337
 338 (defun vc-git-dir-printer (info)
 339   "Pretty-printer for the vc-dir-fileinfo structure."
 340   (let* ((isdir (vc-dir-fileinfo->directory info))
 341          (state (if isdir "" (vc-dir-fileinfo->state info)))
 342          (extra (vc-dir-fileinfo->extra info))
 343          (old-perm (when extra (vc-git-extra-fileinfo->old-perm extra)))
 344          (new-perm (when extra (vc-git-extra-fileinfo->new-perm extra))))
 345     (insert
 346      "  "
 347      (propertize (format "%c" (if (vc-dir-fileinfo->marked info) ?* ? ))
 348                  'face 'font-lock-type-face)
 349      "  "
 350      (propertize
 351       (format "%-12s" state)
 352       'face (cond ((eq state 'up-to-date) 'font-lock-builtin-face)
 353                   ((eq state 'missing) 'font-lock-warning-face)
 354                   (t 'font-lock-variable-name-face))
 355       'mouse-face 'highlight)
 356      "  " (vc-git-permissions-as-string old-perm new-perm)
 357      "    "
 358      (propertize (vc-git-escape-file-name (vc-dir-fileinfo->name info))
 359                  'face (if isdir 'font-lock-comment-delimiter-face
 360                          'font-lock-function-name-face)
 361                  'help-echo
 362                  (if isdir
 363                      "Directory\nVC operations can be applied to it\nmouse-3: Pop-up menu"
 364                    "File\nmouse-3: Pop-up menu")
 365                  'keymap vc-dir-filename-mouse-map
 366                  'mouse-face 'highlight)
 367      (vc-git-file-type-as-string old-perm new-perm)
 368      (vc-git-rename-as-string state extra))))
 369
 370 (defun vc-git-after-dir-status-stage (stage files update-function)
 371   "Process sentinel for the various dir-status stages."
 372   (let (next-stage result)
 373     (goto-char (point-min))
 374     (pcase stage
 375       (`update-index
 376        (setq next-stage (if (vc-git--empty-db-p) 'ls-files-added
 377                           (if files 'ls-files-up-to-date 'diff-index))))
 378       (`ls-files-added
 379        (setq next-stage 'ls-files-unknown)
 380        (while (re-search-forward "\\([0-7]\\{6\\}\\) [0-9a-f]\\{40\\} 0\t\\([^\0]+\\)\0" nil t)
 381          (let ((new-perm (string-to-number (match-string 1) 8))
 382                (name (match-string 2)))
 383            (push (list name 'added (vc-git-create-extra-fileinfo 0 new-perm))
 384                  result))))
 385       (`ls-files-up-to-date
 386        (setq next-stage 'diff-index)
 387        (while (re-search-forward "\\([0-7]\\{6\\}\\) [0-9a-f]\\{40\\} 0\t\\([^\0]+\\)\0" nil t)
 388          (let ((perm (string-to-number (match-string 1) 8))
 389                (name (match-string 2)))
 390            (push (list name 'up-to-date
 391                        (vc-git-create-extra-fileinfo perm perm))
 392                  result))))
 393       (`ls-files-unknown
 394        (when files (setq next-stage 'ls-files-ignored))
 395        (while (re-search-forward "\\([^\0]*?\\)\0" nil t 1)
 396          (push (list (match-string 1) 'unregistered
 397                      (vc-git-create-extra-fileinfo 0 0))
 398                result)))
 399       (`ls-files-ignored
 400        (while (re-search-forward "\\([^\0]*?\\)\0" nil t 1)
 401          (push (list (match-string 1) 'ignored
 402                      (vc-git-create-extra-fileinfo 0 0))
 403                result)))
 404       (`diff-index
 405        (setq next-stage 'ls-files-unknown)
 406        (while (re-search-forward
 407                ":\\([0-7]\\{6\\}\\) \\([0-7]\\{6\\}\\) [0-9a-f]\\{40\\} [0-9a-f]\\{40\\} \\(\\([ADMUT]\\)\0\\([^\0]+\\)\\|\\([CR]\\)[0-9]*\0\\([^\0]+\\)\0\\([^\0]+\\)\\)\0"
 408                nil t 1)
 409          (let ((old-perm (string-to-number (match-string 1) 8))
 410                (new-perm (string-to-number (match-string 2) 8))
 411                (state (or (match-string 4) (match-string 6)))
 412                (name (or (match-string 5) (match-string 7)))
 413                (new-name (match-string 8)))
 414            (if new-name  ; Copy or rename.
 415                (if (eq ?C (string-to-char state))
 416                    (push (list new-name 'added
 417                                (vc-git-create-extra-fileinfo old-perm new-perm
 418                                                              'copy name))
 419                          result)
 420                  (push (list name 'removed
 421                              (vc-git-create-extra-fileinfo 0 0
 422                                                            'rename new-name))
 423                        result)
 424                  (push (list new-name 'added
 425                              (vc-git-create-extra-fileinfo old-perm new-perm
 426                                                            'rename name))
 427                        result))
 428              (push (list name (vc-git--state-code state)
 429                          (vc-git-create-extra-fileinfo old-perm new-perm))
 430                    result))))))
 431     (when result
 432       (setq result (nreverse result))
 433       (when files
 434         (dolist (entry result) (setq files (delete (car entry) files)))
 435         (unless files (setq next-stage nil))))
 436     (when (or result (not next-stage))
 437       (funcall update-function result next-stage))
 438     (when next-stage
 439       (vc-git-dir-status-goto-stage next-stage files update-function))))
 440
 441 ;; Follows vc-git-command (or vc-do-async-command), which uses vc-do-command
 442 ;; from vc-dispatcher.
 443 (declare-function vc-exec-after "vc-dispatcher" (code))
 444 ;; Follows vc-exec-after.
 445 (declare-function vc-set-async-update "vc-dispatcher" (process-buffer))
 446
 447 (defun vc-git-dir-status-goto-stage (stage files update-function)
 448   (erase-buffer)
 449   (pcase stage
 450     (`update-index
 451      (if files
 452          (vc-git-command (current-buffer) 'async files "add" "--refresh" "--")
 453        (vc-git-command (current-buffer) 'async nil
 454                        "update-index" "--refresh")))
 455     (`ls-files-added
 456      (vc-git-command (current-buffer) 'async files
 457                      "ls-files" "-z" "-c" "-s" "--"))
 458     (`ls-files-up-to-date
 459      (vc-git-command (current-buffer) 'async files
 460                      "ls-files" "-z" "-c" "-s" "--"))
 461     (`ls-files-unknown
 462      (vc-git-command (current-buffer) 'async files
 463                      "ls-files" "-z" "-o" "--directory"
 464                      "--no-empty-directory" "--exclude-standard" "--"))
 465     (`ls-files-ignored
 466      (vc-git-command (current-buffer) 'async files
 467                      "ls-files" "-z" "-o" "-i" "--directory"
 468                      "--no-empty-directory" "--exclude-standard" "--"))
 469     ;; --relative added in Git 1.5.5.
 470     (`diff-index
 471      (vc-git-command (current-buffer) 'async files
 472                      "diff-index" "--relative" "-z" "-M" "HEAD" "--")))
 473   (vc-run-delayed
 474    (vc-git-after-dir-status-stage stage files update-function)))
 475
 476 (defun vc-git-dir-status-files (_dir files update-function)
 477   "Return a list of (FILE STATE EXTRA) entries for DIR."
 478   ;; Further things that would have to be fixed later:
 479   ;; - how to handle unregistered directories
 480   ;; - how to support vc-dir on a subdir of the project tree
 481   (vc-git-dir-status-goto-stage 'update-index files update-function))
 482
 483 (defvar vc-git-stash-map
 484   (let ((map (make-sparse-keymap)))
 485     ;; Turn off vc-dir marking
 486     (define-key map [mouse-2] 'ignore)
 487
 488     (define-key map [down-mouse-3] 'vc-git-stash-menu)
 489     (define-key map "\C-k" 'vc-git-stash-delete-at-point)
 490     (define-key map "=" 'vc-git-stash-show-at-point)
 491     (define-key map "\C-m" 'vc-git-stash-show-at-point)
 492     (define-key map "A" 'vc-git-stash-apply-at-point)
 493     (define-key map "P" 'vc-git-stash-pop-at-point)
 494     (define-key map "S" 'vc-git-stash-snapshot)
 495     map))
 496
 497 (defvar vc-git-stash-menu-map
 498   (let ((map (make-sparse-keymap "Git Stash")))
 499     (define-key map [de]
 500       '(menu-item "Delete Stash" vc-git-stash-delete-at-point
 501                   :help "Delete the current stash"))
 502     (define-key map [ap]
 503       '(menu-item "Apply Stash" vc-git-stash-apply-at-point
 504                   :help "Apply the current stash and keep it in the stash list"))
 505     (define-key map [po]
 506       '(menu-item "Apply and Remove Stash (Pop)" vc-git-stash-pop-at-point
 507                   :help "Apply the current stash and remove it"))
 508     (define-key map [sh]
 509       '(menu-item "Show Stash" vc-git-stash-show-at-point
 510                   :help "Show the contents of the current stash"))
 511     map))
 512
 513 (defun vc-git-dir-extra-headers (dir)
 514   (let ((str (with-output-to-string
 515                (with-current-buffer standard-output
 516                  (vc-git--out-ok "symbolic-ref" "HEAD"))))
 517         (stash (vc-git-stash-list))
 518         (stash-help-echo "Use M-x vc-git-stash to create stashes.")
 519         branch remote remote-url)
 520     (if (string-match "^\\(refs/heads/\\)?\\(.+\\)$" str)
 521         (progn
 522           (setq branch (match-string 2 str))
 523           (setq remote
 524                 (with-output-to-string
 525                   (with-current-buffer standard-output
 526                     (vc-git--out-ok "config"
 527                                     (concat "branch." branch ".remote")))))
 528           (when (string-match "\\([^\n]+\\)" remote)
 529             (setq remote (match-string 1 remote)))
 530           (when remote
 531             (setq remote-url
 532                   (with-output-to-string
 533                     (with-current-buffer standard-output
 534                       (vc-git--out-ok "config"
 535                                       (concat "remote." remote ".url"))))))
 536           (when (string-match "\\([^\n]+\\)" remote-url)
 537             (setq remote-url (match-string 1 remote-url))))
 538       (setq branch "not (detached HEAD)"))
 539     ;; FIXME: maybe use a different face when nothing is stashed.
 540     (concat
 541      (propertize "Branch     : " 'face 'font-lock-type-face)
 542      (propertize branch
 543                  'face 'font-lock-variable-name-face)
 544      (when remote
 545        (concat
 546         "\n"
 547         (propertize "Remote     : " 'face 'font-lock-type-face)
 548         (propertize remote-url
 549                     'face 'font-lock-variable-name-face)))
 550      "\n"
 551      ;; For now just a heading, key bindings can be added later for various bisect actions
 552      (when (file-exists-p (expand-file-name ".git/BISECT_START" (vc-git-root dir)))
 553        (propertize  "Bisect     : in progress\n" 'face 'font-lock-warning-face))
 554      (when (file-exists-p (expand-file-name ".git/rebase-apply" (vc-git-root dir)))
 555        (propertize  "Rebase     : in progress\n" 'face 'font-lock-warning-face))
 556      (if stash
 557        (concat
 558         (propertize "Stash      :\n" 'face 'font-lock-type-face
 559                     'help-echo stash-help-echo)
 560         (mapconcat
 561          (lambda (x)
 562            (propertize x
 563                        'face 'font-lock-variable-name-face
 564                        'mouse-face 'highlight
 565                        'help-echo "mouse-3: Show stash menu\nRET: Show stash\nA: Apply stash\nP: Apply and remove stash (pop)\nC-k: Delete stash"
 566                        'keymap vc-git-stash-map))
 567          stash "\n"))
 568        (concat
 569         (propertize "Stash      : " 'face 'font-lock-type-face
 570                     'help-echo stash-help-echo)
 571         (propertize "Nothing stashed"
 572                     'help-echo stash-help-echo
 573                     'face 'font-lock-variable-name-face))))))
 574
 575 (defun vc-git-branches ()
 576   "Return the existing branches, as a list of strings.
 577 The car of the list is the current branch."
 578   (with-temp-buffer
 579     (vc-git--call t "branch")
 580     (goto-char (point-min))
 581     (let (current-branch branches)
 582       (while (not (eobp))
 583         (when (looking-at "^\\([ *]\\) \\(.+\\)$")
 584           (if (string-equal (match-string 1) "*")
 585               (setq current-branch (match-string 2))
 586             (push (match-string 2) branches)))
 587         (forward-line 1))
 588       (cons current-branch (nreverse branches)))))
 589
 590 ;;; STATE-CHANGING FUNCTIONS
 591
 592 (defun vc-git-create-repo ()
 593   "Create a new Git repository."
 594   (vc-git-command nil 0 nil "init"))
 595
 596 (defun vc-git-register (files &optional _comment)
 597   "Register FILES into the git version-control system."
 598   (let (flist dlist)
 599     (dolist (crt files)
 600       (if (file-directory-p crt)
 601           (push crt dlist)
 602         (push crt flist)))
 603     (when flist
 604       (vc-git-command nil 0 flist "update-index" "--add" "--"))
 605     (when dlist
 606       (vc-git-command nil 0 dlist "add"))))
 607
 608 (defalias 'vc-git-responsible-p 'vc-git-root)
 609
 610 (defun vc-git-unregister (file)
 611   (vc-git-command nil 0 file "rm" "-f" "--cached" "--"))
 612
 613 (declare-function log-edit-mode "log-edit" ())
 614 (declare-function log-edit-toggle-header "log-edit" (header value))
 615 (declare-function log-edit-extract-headers "log-edit" (headers string))
 616 (declare-function log-edit-set-header "log-edit" (header value &optional toggle))
 617
 618 (defun vc-git-log-edit-toggle-signoff ()
 619   "Toggle whether to add the \"Signed-off-by\" line at the end of
 620 the commit message."
 621   (interactive)
 622   (log-edit-toggle-header "Sign-Off" "yes"))
 623
 624 (defun vc-git-log-edit-toggle-amend ()
 625   "Toggle whether this will amend the previous commit.
 626 If toggling on, also insert its message into the buffer."
 627   (interactive)
 628   (when (log-edit-toggle-header "Amend" "yes")
 629     (goto-char (point-max))
 630     (unless (bolp) (insert "\n"))
 631     (insert (with-output-to-string
 632               (vc-git-command
 633                standard-output 1 nil
 634                "log" "--max-count=1" "--pretty=format:%B" "HEAD")))
 635     (save-excursion
 636       (rfc822-goto-eoh)
 637       (forward-line 1)
 638       (let ((pt (point)))
 639         (and (zerop (forward-line 1))
 640              (looking-at "\n\\|\\'")
 641              (let ((summary (buffer-substring-no-properties pt (1- (point)))))
 642                (skip-chars-forward " \n")
 643                (delete-region pt (point))
 644                (log-edit-set-header "Summary" summary)))))))
 645
 646 (defvar vc-git-log-edit-mode-map
 647   (let ((map (make-sparse-keymap "Git-Log-Edit")))
 648     (define-key map "\C-c\C-s" 'vc-git-log-edit-toggle-signoff)
 649     (define-key map "\C-c\C-e" 'vc-git-log-edit-toggle-amend)
 650     map))
 651
 652 (define-derived-mode vc-git-log-edit-mode log-edit-mode "Log-Edit/git"
 653   "Major mode for editing Git log messages.
 654 It is based on `log-edit-mode', and has Git-specific extensions.")
 655
 656 (defun vc-git-checkin (files comment)
 657   (let* ((file1 (or (car files) default-directory))
 658          (root (vc-git-root file1))
 659          (default-directory (expand-file-name root))
 660          (only (or (cdr files)
 661                    (not (equal root (abbreviate-file-name file1)))))
 662          (coding-system-for-write vc-git-commits-coding-system))
 663     (cl-flet ((boolean-arg-fn
 664                (argument)
 665                (lambda (value) (when (equal value "yes") (list argument)))))
 666       ;; When operating on the whole tree, better pass "-a" than ".", since "."
 667       ;; fails when we're committing a merge.
 668       (apply 'vc-git-command nil 0 (if only files)
 669              (nconc (list "commit" "-m")
 670                     (log-edit-extract-headers
 671                      `(("Author" . "--author")
 672                        ("Date" . "--date")
 673                        ("Amend" . ,(boolean-arg-fn "--amend"))
 674                        ("Sign-Off" . ,(boolean-arg-fn "--signoff")))
 675                      comment)
 676                     (if only (list "--only" "--") '("-a")))))))
 677
 678 (defun vc-git-find-revision (file rev buffer)
 679   (let* (process-file-side-effects
 680          (coding-system-for-read 'binary)
 681          (coding-system-for-write 'binary)
 682          (fullname
 683           (let ((fn (vc-git--run-command-string
 684                      file "ls-files" "-z" "--full-name" "--")))
 685             ;; ls-files does not return anything when looking for a
 686             ;; revision of a file that has been renamed or removed.
 687             (if (string= fn "")
 688                 (file-relative-name file (vc-git-root default-directory))
 689               (substring fn 0 -1)))))
 690     (vc-git-command
 691      buffer 0
 692      nil
 693      "cat-file" "blob" (concat (if rev rev "HEAD") ":" fullname))))
 694
 695 (defun vc-git-find-ignore-file (file)
 696   "Return the root directory of the repository of FILE."
 697   (expand-file-name ".gitignore"
 698                     (vc-git-root file)))
 699
 700 (defun vc-git-checkout (file &optional rev)
 701   (vc-git-command nil 0 file "checkout" (or rev "HEAD")))
 702
 703 (defun vc-git-revert (file &optional contents-done)
 704   "Revert FILE to the version stored in the git repository."
 705   (if contents-done
 706       (vc-git-command nil 0 file "update-index" "--")
 707     (vc-git-command nil 0 file "reset" "-q" "--")
 708     (vc-git-command nil nil file "checkout" "-q" "--")))
 709
 710 (defvar vc-git-error-regexp-alist
 711   '(("^ \\(.+\\) |" 1 nil nil 0))
 712   "Value of `compilation-error-regexp-alist' in *vc-git* buffers.")
 713
 714 ;; To be called via vc-pull from vc.el, which requires vc-dispatcher.
 715 (declare-function vc-compilation-mode "vc-dispatcher" (backend))
 716
 717 (defun vc-git-pull (prompt)
 718   "Pull changes into the current Git branch.
 719 Normally, this runs \"git pull\".  If PROMPT is non-nil, prompt
 720 for the Git command to run."
 721   (let* ((root (vc-git-root default-directory))
 722          (buffer (format "*vc-git : %s*" (expand-file-name root)))
 723          (command "pull")
 724          (git-program vc-git-program)
 725          args)
 726     ;; If necessary, prompt for the exact command.
 727     (when prompt
 728       (setq args (split-string
 729                   (read-shell-command "Git pull command: "
 730                                       (format "%s pull" git-program)
 731                                       'vc-git-history)
 732                   " " t))
 733       (setq git-program (car  args)
 734             command     (cadr args)
 735             args        (cddr args)))
 736     (require 'vc-dispatcher)
 737     (apply 'vc-do-async-command buffer root git-program command args)
 738     (with-current-buffer buffer (vc-run-delayed (vc-compilation-mode 'git)))
 739     (vc-set-async-update buffer)))
 740
 741 (defun vc-git-merge-branch ()
 742   "Merge changes into the current Git branch.
 743 This prompts for a branch to merge from."
 744   (let* ((root (vc-git-root default-directory))
 745          (buffer (format "*vc-git : %s*" (expand-file-name root)))
 746          (branches (cdr (vc-git-branches)))
 747          (merge-source
 748           (completing-read "Merge from branch: "
 749                            (if (or (member "FETCH_HEAD" branches)
 750                                    (not (file-readable-p
 751                                          (expand-file-name ".git/FETCH_HEAD"
 752                                                            root))))
 753                                branches
 754                              (cons "FETCH_HEAD" branches))
 755                            nil t)))
 756     (apply 'vc-do-async-command buffer root vc-git-program "merge"
 757            (list merge-source))
 758     (with-current-buffer buffer (vc-run-delayed (vc-compilation-mode 'git)))
 759     (vc-set-async-update buffer)))
 760
 761 (defun vc-git-conflicted-files (directory)
 762   "Return the list of files with conflicts in DIRECTORY."
 763   (let* ((status
 764           (vc-git--run-command-string directory "status" "--porcelain" "--"))
 765          (lines (when status (split-string status "\n" 'omit-nulls)))
 766          files)
 767     (dolist (line lines files)
 768       (when (string-match "\\([ MADRCU?!][ MADRCU?!]\\) \\(.+\\)\\(?: -> \\(.+\\)\\)?"
 769                           line)
 770         (let ((state (match-string 1 line))
 771               (file (match-string 2 line)))
 772           ;; See git-status(1).
 773           (when (member state '("AU" "UD" "UA" ;; "DD"
 774                                 "DU" "AA" "UU"))
 775             (push (expand-file-name file directory) files)))))))
 776
 777 (defun vc-git-resolve-when-done ()
 778   "Call \"git add\" if the conflict markers have been removed."
 779   (save-excursion
 780     (goto-char (point-min))
 781     (unless (re-search-forward "^<<<<<<< " nil t)
 782       (vc-git-command nil 0 buffer-file-name "add")
 783       ;; Remove the hook so that it is not called multiple times.
 784       (remove-hook 'after-save-hook 'vc-git-resolve-when-done t))))
 785
 786 (defun vc-git-find-file-hook ()
 787   "Activate `smerge-mode' if there is a conflict."
 788   (when (and buffer-file-name
 789              ;; FIXME
 790              ;; 1) the net result is to call git twice per file.
 791              ;; 2) v-g-c-f is documented to take a directory.
 792              ;; http://lists.gnu.org/archive/html/emacs-devel/2014-01/msg01126.html
 793              (vc-git-conflicted-files buffer-file-name)
 794              (save-excursion
 795                (goto-char (point-min))
 796                (re-search-forward "^<<<<<<< " nil 'noerror)))
 797     (vc-file-setprop buffer-file-name 'vc-state 'conflict)
 798     (smerge-start-session)
 799     (add-hook 'after-save-hook 'vc-git-resolve-when-done nil 'local)
 800     (message "There are unresolved conflicts in this file")))
 801
 802 ;;; HISTORY FUNCTIONS
 803
 804 (autoload 'vc-setup-buffer "vc-dispatcher")
 805
 806 (defun vc-git-print-log (files buffer &optional shortlog start-revision limit)
 807   "Print commit log associated with FILES into specified BUFFER.
 808 If SHORTLOG is non-nil, use a short format based on `vc-git-root-log-format'.
 809 \(This requires at least Git version 1.5.6, for the --graph option.)
 810 If START-REVISION is non-nil, it is the newest revision to show.
 811 If LIMIT is non-nil, show no more than this many entries."
 812   (let ((coding-system-for-read vc-git-commits-coding-system))
 813     ;; `vc-do-command' creates the buffer, but we need it before running
 814     ;; the command.
 815     (vc-setup-buffer buffer)
 816     ;; If the buffer exists from a previous invocation it might be
 817     ;; read-only.
 818     (let ((inhibit-read-only t))
 819       (with-current-buffer
 820           buffer
 821         (apply 'vc-git-command buffer
 822                'async files
 823                (append
 824                 '("log" "--no-color")
 825                 (when shortlog
 826                   `("--graph" "--decorate" "--date=short"
 827                     ,(format "--pretty=tformat:%s"
 828                              (car vc-git-root-log-format))
 829                     "--abbrev-commit"))
 830                 (when limit (list "-n" (format "%s" limit)))
 831                 (when start-revision (list start-revision))
 832                 '("--")))))))
 833
 834 (defun vc-git-log-outgoing (buffer remote-location)
 835   (interactive)
 836   (vc-git-command
 837    buffer 0 nil
 838    "log"
 839    "--no-color" "--graph" "--decorate" "--date=short"
 840    (format "--pretty=tformat:%s" (car vc-git-root-log-format))
 841    "--abbrev-commit"
 842    (concat (if (string= remote-location "")
 843                "@{upstream}"
 844              remote-location)
 845            "..HEAD")))
 846
 847 (defun vc-git-log-incoming (buffer remote-location)
 848   (interactive)
 849   (vc-git-command nil 0 nil "fetch")
 850   (vc-git-command
 851    buffer 0 nil
 852    "log"
 853    "--no-color" "--graph" "--decorate" "--date=short"
 854    (format "--pretty=tformat:%s" (car vc-git-root-log-format))
 855    "--abbrev-commit"
 856    (concat "HEAD.." (if (string= remote-location "")
 857                         "@{upstream}"
 858                       remote-location))))
 859
 860 (defvar log-view-message-re)
 861 (defvar log-view-file-re)
 862 (defvar log-view-font-lock-keywords)
 863 (defvar log-view-per-file-logs)
 864 (defvar log-view-expanded-log-entry-function)
 865
 866 (define-derived-mode vc-git-log-view-mode log-view-mode "Git-Log-View"
 867   (require 'add-log) ;; We need the faces add-log.
 868   ;; Don't have file markers, so use impossible regexp.
 869   (set (make-local-variable 'log-view-file-re) "\\`a\\`")
 870   (set (make-local-variable 'log-view-per-file-logs) nil)
 871   (set (make-local-variable 'log-view-message-re)
 872        (if (not (eq vc-log-view-type 'long))
 873            (cadr vc-git-root-log-format)
 874          "^commit *\\([0-9a-z]+\\)"))
 875   ;; Allow expanding short log entries.
 876   (when (eq vc-log-view-type 'short)
 877     (setq truncate-lines t)
 878     (set (make-local-variable 'log-view-expanded-log-entry-function)
 879          'vc-git-expanded-log-entry))
 880   (set (make-local-variable 'log-view-font-lock-keywords)
 881        (if (not (eq vc-log-view-type 'long))
 882            (list (cons (nth 1 vc-git-root-log-format)
 883                        (nth 2 vc-git-root-log-format)))
 884          (append
 885           `((,log-view-message-re (1 'change-log-acknowledgment)))
 886           ;; Handle the case:
 887           ;; user: foo@bar
 888           '(("^Author:[ \t]+\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)"
 889              (1 'change-log-email))
 890             ;; Handle the case:
 891             ;; user: FirstName LastName <foo@bar>
 892             ("^Author:[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
 893              (1 'change-log-name)
 894              (2 'change-log-email))
 895             ("^ +\\(?:\\(?:[Aa]cked\\|[Ss]igned-[Oo]ff\\)-[Bb]y:\\)[ \t]+\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)"
 896              (1 'change-log-name))
 897             ("^ +\\(?:\\(?:[Aa]cked\\|[Ss]igned-[Oo]ff\\)-[Bb]y:\\)[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
 898              (1 'change-log-name)
 899              (2 'change-log-email))
 900             ("^Merge: \\([0-9a-z]+\\) \\([0-9a-z]+\\)"
 901              (1 'change-log-acknowledgment)
 902              (2 'change-log-acknowledgment))
 903             ("^Date:   \\(.+\\)" (1 'change-log-date))
 904             ("^summary:[ \t]+\\(.+\\)" (1 'log-view-message)))))))
 905
 906
 907 (defun vc-git-show-log-entry (revision)
 908   "Move to the log entry for REVISION.
 909 REVISION may have the form BRANCH, BRANCH~N,
 910 or BRANCH^ (where \"^\" can be repeated)."
 911   (goto-char (point-min))
 912   (prog1
 913       (when revision
 914         (search-forward
 915          (format "\ncommit %s" revision) nil t
 916          (cond ((string-match "~\\([0-9]\\)\\'" revision)
 917                 (1+ (string-to-number (match-string 1 revision))))
 918                ((string-match "\\^+\\'" revision)
 919                 (1+ (length (match-string 0 revision))))
 920                (t nil))))
 921     (beginning-of-line)))
 922
 923 (defun vc-git-expanded-log-entry (revision)
 924   (with-temp-buffer
 925     (apply 'vc-git-command t nil nil (list "log" revision "-1"))
 926     (goto-char (point-min))
 927     (unless (eobp)
 928       ;; Indent the expanded log entry.
 929       (indent-region (point-min) (point-max) 2)
 930       (buffer-string))))
 931
 932
 933 (defun vc-git-region-history (file buffer lfrom lto)
 934   (vc-git-command buffer 'async nil "log" "-p" ;"--follow" ;FIXME: not supported?
 935                   (format "-L%d,%d:%s" lfrom lto (file-relative-name file))))
 936
 937 (require 'diff-mode)
 938
 939 (defvar vc-git-region-history-mode-map
 940   (let ((map (make-composed-keymap
 941               nil (make-composed-keymap
 942                    (list diff-mode-map vc-git-log-view-mode-map)))))
 943     map))
 944
 945 (defvar vc-git--log-view-long-font-lock-keywords nil)
 946 (defvar font-lock-keywords)
 947 (defvar vc-git-region-history-font-lock-keywords
 948   `((vc-git-region-history-font-lock)))
 949
 950 (defun vc-git-region-history-font-lock (limit)
 951   (let ((in-diff (save-excursion
 952                    (beginning-of-line)
 953                    (or (looking-at "^\\(?:diff\\|commit\\)\\>")
 954                        (re-search-backward "^\\(?:diff\\|commit\\)\\>" nil t))
 955                    (eq ?d (char-after (match-beginning 0))))))
 956     (while
 957         (let ((end (save-excursion
 958                      (if (re-search-forward "\n\\(diff\\|commit\\)\\>"
 959                                             limit t)
 960                          (match-beginning 1)
 961                        limit))))
 962           (let ((font-lock-keywords (if in-diff diff-font-lock-keywords
 963                                       vc-git--log-view-long-font-lock-keywords)))
 964             (font-lock-fontify-keywords-region (point) end))
 965           (goto-char end)
 966           (prog1 (< (point) limit)
 967             (setq in-diff (eq ?d (char-after))))))
 968     nil))
 969
 970 (define-derived-mode vc-git-region-history-mode
 971     vc-git-log-view-mode "Git-Region-History"
 972   "Major mode to browse Git's \"log -p\" output."
 973   (setq-local vc-git--log-view-long-font-lock-keywords
 974               log-view-font-lock-keywords)
 975   (setq-local font-lock-defaults
 976               (cons 'vc-git-region-history-font-lock-keywords
 977                     (cdr font-lock-defaults))))
 978
 979
 980 (autoload 'vc-switches "vc")
 981
 982 (defun vc-git-diff (files &optional async rev1 rev2 buffer)
 983   "Get a difference report using Git between two revisions of FILES."
 984   (let (process-file-side-effects)
 985     (if vc-git-diff-switches
 986         (apply #'vc-git-command (or buffer "*vc-diff*")
 987                (if async 'async 1)
 988                files
 989                (if (and rev1 rev2) "diff-tree" "diff-index")
 990                "--exit-code"
 991                (append (vc-switches 'git 'diff)
 992                        (list "-p" (or rev1 "HEAD") rev2 "--")))
 993       (vc-git-command (or buffer "*vc-diff*") 1 files
 994                       "difftool" "--exit-code" "--no-prompt" "-x"
 995                       (concat "diff "
 996                               (mapconcat 'identity
 997                                          (vc-switches nil 'diff) " "))
 998                       (or rev1 "HEAD") rev2 "--"))))
 999
1000 (defun vc-git-revision-table (_files)
1001   ;; What about `files'?!?  --Stef
1002   (let (process-file-side-effects
1003         (table (list "HEAD")))
1004     (with-temp-buffer
1005       (vc-git-command t nil nil "for-each-ref" "--format=%(refname)")
1006       (goto-char (point-min))
1007       (while (re-search-forward "^refs/\\(heads\\|tags\\|remotes\\)/\\(.*\\)$"
1008                                 nil t)
1009         (push (match-string 2) table)))
1010     table))
1011
1012 (defun vc-git-revision-completion-table (files)
1013   (letrec ((table (lazy-completion-table
1014                    table (lambda () (vc-git-revision-table files)))))
1015     table))
1016
1017 (defun vc-git-annotate-command (file buf &optional rev)
1018   (let ((name (file-relative-name file)))
1019     (vc-git-command buf 'async nil "blame" "--date=iso" "-C" "-C" rev "--" name)))
1020
1021 (declare-function vc-annotate-convert-time "vc-annotate" (time))
1022
1023 (defun vc-git-annotate-time ()
1024   (and (re-search-forward "[0-9a-f]+[^()]+(.* \\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\) \\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\) \\([-+0-9]+\\) +[0-9]+) " nil t)
1025        (vc-annotate-convert-time
1026         (apply #'encode-time (mapcar (lambda (match)
1027                                        (string-to-number (match-string match)))
1028                                      '(6 5 4 3 2 1 7))))))
1029
1030 (defun vc-git-annotate-extract-revision-at-line ()
1031   (save-excursion
1032     (beginning-of-line)
1033     (when (looking-at "\\([0-9a-f^][0-9a-f]+\\) \\(\\([^(]+\\) \\)?")
1034       (let ((revision (match-string-no-properties 1)))
1035         (if (match-beginning 2)
1036             (let ((fname (match-string-no-properties 3)))
1037               ;; Remove trailing whitespace from the file name.
1038               (when (string-match " +\\'" fname)
1039                 (setq fname (substring fname 0 (match-beginning 0))))
1040               (cons revision
1041                     (expand-file-name fname (vc-git-root default-directory))))
1042           revision)))))
1043
1044 ;;; TAG SYSTEM
1045
1046 (defun vc-git-create-tag (dir name branchp)
1047   (let ((default-directory dir))
1048     (and (vc-git-command nil 0 nil "update-index" "--refresh")
1049          (if branchp
1050              (vc-git-command nil 0 nil "checkout" "-b" name)
1051            (vc-git-command nil 0 nil "tag" name)))))
1052
1053 (defun vc-git-retrieve-tag (dir name _update)
1054   (let ((default-directory dir))
1055     (vc-git-command nil 0 nil "checkout" name)
1056     ;; FIXME: update buffers if `update' is true
1057     ))
1058
1059
1060 ;;; MISCELLANEOUS
1061
1062 (defun vc-git-previous-revision (file rev)
1063   "Git-specific version of `vc-previous-revision'."
1064   (if file
1065       (let* ((fname (file-relative-name file))
1066              (prev-rev (with-temp-buffer
1067                          (and
1068                           (vc-git--out-ok "rev-list" "-2" rev "--" fname)
1069                           (goto-char (point-max))
1070                           (bolp)
1071                           (zerop (forward-line -1))
1072                           (not (bobp))
1073                           (buffer-substring-no-properties
1074                            (point)
1075                            (1- (point-max)))))))
1076         (or (vc-git-symbolic-commit prev-rev) prev-rev))
1077     ;; We used to use "^" here, but that fails on MS-Windows if git is
1078     ;; invoked via a batch file, in which case cmd.exe strips the "^"
1079     ;; because it is a special character for cmd which process-file
1080     ;; does not (and cannot) quote.
1081     (vc-git--rev-parse (concat rev "~1"))))
1082
1083 (defun vc-git--rev-parse (rev)
1084   (with-temp-buffer
1085     (and
1086      (vc-git--out-ok "rev-parse" rev)
1087      (buffer-substring-no-properties (point-min) (+ (point-min) 40)))))
1088
1089 (defun vc-git-next-revision (file rev)
1090   "Git-specific version of `vc-next-revision'."
1091   (let* ((default-directory (file-name-directory
1092                              (expand-file-name file)))
1093          (file (file-name-nondirectory file))
1094          (current-rev
1095           (with-temp-buffer
1096             (and
1097              (vc-git--out-ok "rev-list" "-1" rev "--" file)
1098              (goto-char (point-max))
1099              (bolp)
1100              (zerop (forward-line -1))
1101              (bobp)
1102              (buffer-substring-no-properties
1103               (point)
1104               (1- (point-max))))))
1105          (next-rev
1106           (and current-rev
1107                (with-temp-buffer
1108                  (and
1109                   (vc-git--out-ok "rev-list" "HEAD" "--" file)
1110                   (goto-char (point-min))
1111                   (search-forward current-rev nil t)
1112                   (zerop (forward-line -1))
1113                   (buffer-substring-no-properties
1114                    (point)
1115                    (progn (forward-line 1) (1- (point)))))))))
1116     (or (vc-git-symbolic-commit next-rev) next-rev)))
1117
1118 (defun vc-git-delete-file (file)
1119   (vc-git-command nil 0 file "rm" "-f" "--"))
1120
1121 (defun vc-git-rename-file (old new)
1122   (vc-git-command nil 0 (list old new) "mv" "-f" "--"))
1123
1124 (defvar vc-git-extra-menu-map
1125   (let ((map (make-sparse-keymap)))
1126     (define-key map [git-grep]
1127       '(menu-item "Git grep..." vc-git-grep
1128                   :help "Run the `git grep' command"))
1129     (define-key map [git-sn]
1130       '(menu-item "Stash a Snapshot" vc-git-stash-snapshot
1131                   :help "Stash the current state of the tree and keep the current state"))
1132     (define-key map [git-st]
1133       '(menu-item "Create Stash..." vc-git-stash
1134                   :help "Stash away changes"))
1135     (define-key map [git-ss]
1136       '(menu-item "Show Stash..." vc-git-stash-show
1137                   :help "Show stash contents"))
1138     map))
1139
1140 (defun vc-git-extra-menu () vc-git-extra-menu-map)
1141
1142 (defun vc-git-extra-status-menu () vc-git-extra-menu-map)
1143
1144 (defun vc-git-root (file)
1145   (or (vc-file-getprop file 'git-root)
1146       (vc-file-setprop file 'git-root (vc-find-root file ".git"))))
1147
1148 ;; grep-compute-defaults autoloads grep.
1149 (declare-function grep-read-regexp "grep" ())
1150 (declare-function grep-read-files "grep" (regexp))
1151 (declare-function grep-expand-template "grep"
1152                  (template &optional regexp files dir excl))
1153
1154 ;; Derived from `lgrep'.
1155 (defun vc-git-grep (regexp &optional files dir)
1156   "Run git grep, searching for REGEXP in FILES in directory DIR.
1157 The search is limited to file names matching shell pattern FILES.
1158 FILES may use abbreviations defined in `grep-files-aliases', e.g.
1159 entering `ch' is equivalent to `*.[ch]'.
1160
1161 With \\[universal-argument] prefix, you can edit the constructed shell command line
1162 before it is executed.
1163 With two \\[universal-argument] prefixes, directly edit and run `grep-command'.
1164
1165 Collect output in a buffer.  While git grep runs asynchronously, you
1166 can use \\[next-error] (M-x next-error), or \\<grep-mode-map>\\[compile-goto-error] \
1167 in the grep output buffer,
1168 to go to the lines where grep found matches.
1169
1170 This command shares argument histories with \\[rgrep] and \\[grep]."
1171   (interactive
1172    (progn
1173      (grep-compute-defaults)
1174      (cond
1175       ((equal current-prefix-arg '(16))
1176        (list (read-from-minibuffer "Run: " "git grep"
1177                                    nil nil 'grep-history)
1178              nil))
1179       (t (let* ((regexp (grep-read-regexp))
1180                 (files (grep-read-files regexp))
1181                 (dir (read-directory-name "In directory: "
1182                                           nil default-directory t)))
1183            (list regexp files dir))))))
1184   (require 'grep)
1185   (when (and (stringp regexp) (> (length regexp) 0))
1186     (let ((command regexp))
1187       (if (null files)
1188           (if (string= command "git grep")
1189               (setq command nil))
1190         (setq dir (file-name-as-directory (expand-file-name dir)))
1191         (setq command
1192               (grep-expand-template "git --no-pager grep -n -e <R> -- <F>"
1193                                     regexp files))
1194         (when command
1195           (if (equal current-prefix-arg '(4))
1196               (setq command
1197                     (read-from-minibuffer "Confirm: "
1198                                           command nil nil 'grep-history))
1199             (add-to-history 'grep-history command))))
1200       (when command
1201         (let ((default-directory dir)
1202               (compilation-environment (cons "PAGER=" compilation-environment)))
1203           ;; Setting process-setup-function makes exit-message-function work
1204           ;; even when async processes aren't supported.
1205           (compilation-start command 'grep-mode))
1206         (if (eq next-error-last-buffer (current-buffer))
1207             (setq default-directory dir))))))
1208
1209 ;; Everywhere but here, follows vc-git-command, which uses vc-do-command
1210 ;; from vc-dispatcher.
1211 (autoload 'vc-resynch-buffer "vc-dispatcher")
1212
1213 (defun vc-git-stash (name)
1214   "Create a stash."
1215   (interactive "sStash name: ")
1216   (let ((root (vc-git-root default-directory)))
1217     (when root
1218       (vc-git--call nil "stash" "save" name)
1219       (vc-resynch-buffer root t t))))
1220
1221 (defun vc-git-stash-show (name)
1222   "Show the contents of stash NAME."
1223   (interactive "sStash name: ")
1224   (vc-setup-buffer "*vc-git-stash*")
1225   (vc-git-command "*vc-git-stash*" 'async nil "stash" "show" "-p" name)
1226   (set-buffer "*vc-git-stash*")
1227   (diff-mode)
1228   (setq buffer-read-only t)
1229   (pop-to-buffer (current-buffer)))
1230
1231 (defun vc-git-stash-apply (name)
1232   "Apply stash NAME."
1233   (interactive "sApply stash: ")
1234   (vc-git-command "*vc-git-stash*" 0 nil "stash" "apply" "-q" name)
1235   (vc-resynch-buffer (vc-git-root default-directory) t t))
1236
1237 (defun vc-git-stash-pop (name)
1238   "Pop stash NAME."
1239   (interactive "sPop stash: ")
1240   (vc-git-command "*vc-git-stash*" 0 nil "stash" "pop" "-q" name)
1241   (vc-resynch-buffer (vc-git-root default-directory) t t))
1242
1243 (defun vc-git-stash-snapshot ()
1244   "Create a stash with the current tree state."
1245   (interactive)
1246   (vc-git--call nil "stash" "save"
1247                 (let ((ct (current-time)))
1248                   (concat
1249                    (format-time-string "Snapshot on %Y-%m-%d" ct)
1250                    (format-time-string " at %H:%M" ct))))
1251   (vc-git-command "*vc-git-stash*" 0 nil "stash" "apply" "-q" "stash@{0}")
1252   (vc-resynch-buffer (vc-git-root default-directory) t t))
1253
1254 (defun vc-git-stash-list ()
1255   (delete
1256    ""
1257    (split-string
1258     (replace-regexp-in-string
1259      "^stash@" "             " (vc-git--run-command-string nil "stash" "list"))
1260     "\n")))
1261
1262 (defun vc-git-stash-get-at-point (point)
1263   (save-excursion
1264     (goto-char point)
1265     (beginning-of-line)
1266     (if (looking-at "^ +\\({[0-9]+}\\):")
1267         (match-string 1)
1268       (error "Cannot find stash at point"))))
1269
1270 ;; vc-git-stash-delete-at-point must be called from a vc-dir buffer.
1271 (declare-function vc-dir-refresh "vc-dir" ())
1272
1273 (defun vc-git-stash-delete-at-point ()
1274   (interactive)
1275   (let ((stash (vc-git-stash-get-at-point (point))))
1276     (when (y-or-n-p (format "Remove stash %s ? " stash))
1277       (vc-git--run-command-string nil "stash" "drop" (format "stash@%s" stash))
1278       (vc-dir-refresh))))
1279
1280 (defun vc-git-stash-show-at-point ()
1281   (interactive)
1282   (vc-git-stash-show (format "stash@%s" (vc-git-stash-get-at-point (point)))))
1283
1284 (defun vc-git-stash-apply-at-point ()
1285   (interactive)
1286   (vc-git-stash-apply (format "stash@%s" (vc-git-stash-get-at-point (point)))))
1287
1288 (defun vc-git-stash-pop-at-point ()
1289   (interactive)
1290   (vc-git-stash-pop (format "stash@%s" (vc-git-stash-get-at-point (point)))))
1291
1292 (defun vc-git-stash-menu (e)
1293   (interactive "e")
1294   (vc-dir-at-event e (popup-menu vc-git-stash-menu-map e)))
1295
1296 \f
1297 ;;; Internal commands
1298
1299 (defun vc-git-command (buffer okstatus file-or-list &rest flags)
1300   "A wrapper around `vc-do-command' for use in vc-git.el.
1301 The difference to vc-do-command is that this function always invokes
1302 `vc-git-program'."
1303   (let ((coding-system-for-read vc-git-commits-coding-system)
1304         (coding-system-for-write vc-git-commits-coding-system))
1305     (apply 'vc-do-command (or buffer "*vc*") okstatus vc-git-program
1306            ;; http://debbugs.gnu.org/16897
1307            (unless (and (not (cdr-safe file-or-list))
1308                         (let ((file (or (car-safe file-or-list)
1309                                         file-or-list)))
1310                           (and file
1311                                (eq ?/ (aref file (1- (length file))))
1312                                (equal file (vc-git-root file)))))
1313              file-or-list)
1314            (cons "--no-pager" flags))))
1315
1316 (defun vc-git--empty-db-p ()
1317   "Check if the git db is empty (no commit done yet)."
1318   (let (process-file-side-effects)
1319     (not (eq 0 (vc-git--call nil "rev-parse" "--verify" "HEAD")))))
1320
1321 (defun vc-git--call (buffer command &rest args)
1322   ;; We don't need to care the arguments.  If there is a file name, it
1323   ;; is always a relative one.  This works also for remote
1324   ;; directories.  We enable `inhibit-null-byte-detection', otherwise
1325   ;; Tramp's eol conversion might be confused.
1326   (let ((inhibit-null-byte-detection t)
1327         (coding-system-for-read vc-git-commits-coding-system)
1328         (coding-system-for-write vc-git-commits-coding-system)
1329         (process-environment (cons "PAGER=" process-environment)))
1330     (apply 'process-file vc-git-program nil buffer nil command args)))
1331
1332 (defun vc-git--out-ok (command &rest args)
1333   (zerop (apply 'vc-git--call '(t nil) command args)))
1334
1335 (defun vc-git--run-command-string (file &rest args)
1336   "Run a git command on FILE and return its output as string.
1337 FILE can be nil."
1338   (let* ((ok t)
1339          (str (with-output-to-string
1340                 (with-current-buffer standard-output
1341                   (unless (apply 'vc-git--out-ok
1342                                  (if file
1343                                      (append args (list (file-relative-name
1344                                                          file)))
1345                                    args))
1346                     (setq ok nil))))))
1347     (and ok str)))
1348
1349 (defun vc-git-symbolic-commit (commit)
1350   "Translate COMMIT string into symbolic form.
1351 Returns nil if not possible."
1352   (and commit
1353        (let ((name (with-temp-buffer
1354                      (and
1355                       (vc-git--out-ok "name-rev" "--name-only" commit)
1356                       (goto-char (point-min))
1357                       (= (forward-line 2) 1)
1358                       (bolp)
1359                       (buffer-substring-no-properties (point-min)
1360                                                       (1- (point-max)))))))
1361          (and name (not (string= name "undefined")) name))))
1362
1363 (provide 'vc-git)
1364
1365 ;;; vc-git.el ends here