code.delx.au - gnu-emacs/blob - lisp/gnus/mm-bodies.el

   1 ;;; mm-bodies.el --- Functions for decoding MIME things
   2
   3 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 3, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (require 'mm-util)
  30 (require 'rfc2047)
  31 (require 'mm-encode)
  32
  33 (defvar mm-uu-yenc-decode-function)
  34 (defvar mm-uu-decode-function)
  35 (defvar mm-uu-binhex-decode-function)
  36
  37 ;; 8bit treatment gets any char except: 0x32 - 0x7f, LF, TAB, BEL,
  38 ;; BS, vertical TAB, form feed, and ^_
  39 ;;
  40 ;; Note that CR is *not* included, as that would allow a non-paired CR
  41 ;; in the body contrary to RFC 2822:
  42 ;;
  43 ;;   - CR and LF MUST only occur together as CRLF; they MUST NOT
  44 ;;     appear independently in the body.
  45
  46 (defvar mm-7bit-chars "\x20-\x7f\n\t\x7\x8\xb\xc\x1f")
  47
  48 (defcustom mm-body-charset-encoding-alist
  49   '((iso-2022-jp . 7bit)
  50     (iso-2022-jp-2 . 7bit)
  51     ;; We MUST encode UTF-16 because it can contain \0's which is
  52     ;; known to break servers.
  53     ;; Note: UTF-16 variants are invalid for text parts [RFC 2781],
  54     ;; so this can't happen :-/.
  55     ;; PPS: Yes, it can happen if the user specifies UTF-16 in the MML
  56     ;; markup. - jh.
  57     (utf-16 . base64)
  58     (utf-16be . base64)
  59     (utf-16le . base64))
  60   "Alist of MIME charsets to encodings.
  61 Valid encodings are `7bit', `8bit', `quoted-printable' and `base64'."
  62   :type '(repeat (cons (symbol :tag "charset")
  63                        (choice :tag "encoding"
  64                                (const 7bit)
  65                                (const 8bit)
  66                                (const quoted-printable)
  67                                (const base64))))
  68   :group 'mime)
  69
  70 (defun mm-encode-body (&optional charset)
  71   "Encode a body.
  72 Should be called narrowed to the body that is to be encoded.
  73 If there is more than one non-ASCII MULE charset in the body, then the
  74 list of MULE charsets found is returned.
  75 If CHARSET is non-nil, it is used as the MIME charset to encode the body.
  76 If successful, the MIME charset is returned.
  77 If no encoding was done, nil is returned."
  78   (if (not (mm-multibyte-p))
  79       ;; In the non-Mule case, we search for non-ASCII chars and
  80       ;; return the value of `mail-parse-charset' if any are found.
  81       (or charset
  82           (save-excursion
  83             (goto-char (point-min))
  84             (if (re-search-forward "[^\x0-\x7f]" nil t)
  85                 (or mail-parse-charset
  86                     (message-options-get 'mm-encody-body-charset)
  87                     (message-options-set
  88                      'mm-encody-body-charset
  89                      (mm-read-coding-system "Charset used in the article: ")))
  90               ;; The logic in `mml-generate-mime-1' confirms that it's OK
  91               ;; to return nil here.
  92               nil)))
  93     (save-excursion
  94       (if charset
  95           (progn
  96             (mm-encode-coding-region (point-min) (point-max)
  97                                      (mm-charset-to-coding-system charset))
  98             charset)
  99         (goto-char (point-min))
 100         (let ((charsets (mm-find-mime-charset-region (point-min) (point-max))))
 101           (cond
 102            ;; No encoding.
 103            ((null charsets)
 104             nil)
 105            ;; Too many charsets.
 106            ((> (length charsets) 1)
 107             charsets)
 108            ;; We encode.
 109            (t
 110             (prog1
 111                 (setq charset (car charsets))
 112               (mm-encode-coding-region (point-min) (point-max)
 113                                        (mm-charset-to-coding-system charset))))
 114            ))))))
 115
 116 (defun mm-long-lines-p (length)
 117   "Say whether any of the lines in the buffer is longer than LENGTH."
 118   (save-excursion
 119     (goto-char (point-min))
 120     (end-of-line)
 121     (while (and (not (eobp))
 122                 (not (> (current-column) length)))
 123       (forward-line 1)
 124       (end-of-line))
 125     (and (> (current-column) length)
 126          (current-column))))
 127
 128 (defvar message-posting-charset)
 129
 130 (defun mm-body-encoding (charset &optional encoding)
 131   "Do Content-Transfer-Encoding and return the encoding of the current buffer."
 132   (when (stringp encoding)
 133     (setq encoding (intern (downcase encoding))))
 134   (let ((bits (mm-body-7-or-8))
 135         (longp (mm-long-lines-p 1000)))
 136     (require 'message)
 137     (cond
 138      ((and (not longp)
 139            (not (and mm-use-ultra-safe-encoding
 140                      (or (save-excursion (re-search-forward " $" nil t))
 141                          (save-excursion (re-search-forward "^From " nil t)))))
 142            (eq bits '7bit))
 143       bits)
 144      ((and (not mm-use-ultra-safe-encoding)
 145            (not longp)
 146            (not (cdr (assq charset mm-body-charset-encoding-alist)))
 147            (or (eq t (cdr message-posting-charset))
 148                (memq charset (cdr message-posting-charset))
 149                (eq charset mail-parse-charset)))
 150       bits)
 151      (t
 152       (let ((encoding (or encoding
 153                           (cdr (assq charset mm-body-charset-encoding-alist))
 154                           (mm-qp-or-base64))))
 155         (when mm-use-ultra-safe-encoding
 156           (setq encoding (mm-safer-encoding encoding)))
 157         (mm-encode-content-transfer-encoding encoding "text/plain")
 158         encoding)))))
 159
 160 (defun mm-body-7-or-8 ()
 161   "Say whether the body is 7bit or 8bit."
 162   (if (save-excursion
 163         (goto-char (point-min))
 164         (skip-chars-forward mm-7bit-chars)
 165         (eobp))
 166       '7bit
 167     '8bit))
 168
 169 ;;;
 170 ;;; Functions for decoding
 171 ;;;
 172
 173 (defun mm-decode-content-transfer-encoding (encoding &optional type)
 174   "Decodes buffer encoded with ENCODING, returning success status.
 175 If TYPE is `text/plain' CRLF->LF translation may occur."
 176   (prog1
 177       (condition-case error
 178           (cond
 179            ((eq encoding 'quoted-printable)
 180             (quoted-printable-decode-region (point-min) (point-max))
 181             t)
 182            ((eq encoding 'base64)
 183             (base64-decode-region
 184              (point-min)
 185              ;; Some mailers insert whitespace
 186              ;; junk at the end which
 187              ;; base64-decode-region dislikes.
 188              ;; Also remove possible junk which could
 189              ;; have been added by mailing list software.
 190              (save-excursion
 191                (goto-char (point-min))
 192                (while (re-search-forward "^[\t ]*\r?\n" nil t)
 193                  (delete-region (match-beginning 0) (match-end 0)))
 194                (goto-char (point-max))
 195                (when (re-search-backward "^[A-Za-z0-9+/]+=*[\t ]*$" nil t)
 196                  (forward-line))
 197                (point))))
 198            ((memq encoding '(7bit 8bit binary))
 199             ;; Do nothing.
 200             t)
 201            ((null encoding)
 202             ;; Do nothing.
 203             t)
 204            ((memq encoding '(x-uuencode x-uue))
 205             (require 'mm-uu)
 206             (funcall mm-uu-decode-function (point-min) (point-max))
 207             t)
 208            ((eq encoding 'x-binhex)
 209             (require 'mm-uu)
 210             (funcall mm-uu-binhex-decode-function (point-min) (point-max))
 211             t)
 212            ((eq encoding 'x-yenc)
 213             (require 'mm-uu)
 214             (funcall mm-uu-yenc-decode-function (point-min) (point-max))
 215             )
 216            ((functionp encoding)
 217             (funcall encoding (point-min) (point-max))
 218             t)
 219            (t
 220             (message "Unknown encoding %s; defaulting to 8bit" encoding)))
 221         (error
 222          (message "Error while decoding: %s" error)
 223          nil))
 224     (when (and
 225            type
 226            (memq encoding '(base64 x-uuencode x-uue x-binhex x-yenc))
 227            (string-match "\\`text/" type))
 228       (goto-char (point-min))
 229       (while (search-forward "\r\n" nil t)
 230         (replace-match "\n" t t)))))
 231
 232 (defun mm-decode-body (charset &optional encoding type)
 233   "Decode the current article that has been encoded with ENCODING to CHARSET.
 234 ENCODING is a MIME content transfer encoding.
 235 CHARSET is the MIME charset with which to decode the data after transfer
 236 decoding.  If it is nil, default to `mail-parse-charset'."
 237   (when (stringp charset)
 238     (setq charset (intern (downcase charset))))
 239   (when (or (not charset)
 240             (eq 'gnus-all mail-parse-ignored-charsets)
 241             (memq 'gnus-all mail-parse-ignored-charsets)
 242             (memq charset mail-parse-ignored-charsets))
 243     (setq charset mail-parse-charset))
 244   (save-excursion
 245     (when encoding
 246       (mm-decode-content-transfer-encoding encoding type))
 247     (when (and (featurep 'mule) ;; Fixme: Wrong test for unibyte session.
 248                (not (eq charset 'gnus-decoded)))
 249       (let ((coding-system (mm-charset-to-coding-system
 250                             ;; Allow overwrite using
 251                             ;; `mm-charset-override-alist'.
 252                             charset nil t)))
 253         (if (and (not coding-system)
 254                  (listp mail-parse-ignored-charsets)
 255                  (memq 'gnus-unknown mail-parse-ignored-charsets))
 256             (setq coding-system
 257                   (mm-charset-to-coding-system mail-parse-charset)))
 258         (when (and charset coding-system
 259                    ;; buffer-file-coding-system
 260                    ;;Article buffer is nil coding system
 261                    ;;in XEmacs
 262                    (mm-multibyte-p)
 263                    (or (not (eq coding-system 'ascii))
 264                        (setq coding-system mail-parse-charset)))
 265           (mm-decode-coding-region (point-min) (point-max)
 266                                    coding-system))
 267         (setq buffer-file-coding-system
 268               (if (boundp 'last-coding-system-used)
 269                   (symbol-value 'last-coding-system-used)
 270                 coding-system))))))
 271
 272 (defun mm-decode-string (string charset)
 273   "Decode STRING with CHARSET."
 274   (when (stringp charset)
 275     (setq charset (intern (downcase charset))))
 276   (when (or (not charset)
 277             (eq 'gnus-all mail-parse-ignored-charsets)
 278             (memq 'gnus-all mail-parse-ignored-charsets)
 279             (memq charset mail-parse-ignored-charsets))
 280     (setq charset mail-parse-charset))
 281   (or
 282    (when (featurep 'mule)
 283      (let ((coding-system (mm-charset-to-coding-system
 284                            charset
 285                            ;; Allow overwrite using
 286                            ;; `mm-charset-override-alist'.
 287                            nil t)))
 288        (if (and (not coding-system)
 289                 (listp mail-parse-ignored-charsets)
 290                 (memq 'gnus-unknown mail-parse-ignored-charsets))
 291            (setq coding-system
 292                  (mm-charset-to-coding-system mail-parse-charset)))
 293        (when (and charset coding-system
 294                   (mm-multibyte-p)
 295                   (or (not (eq coding-system 'ascii))
 296                       (setq coding-system mail-parse-charset)))
 297          (mm-decode-coding-string string coding-system))))
 298    string))
 299
 300 (provide 'mm-bodies)
 301
 302 ;;; arch-tag: 41104bb6-4443-4ca9-8d5c-ff87ecf27d8d
 303 ;;; mm-bodies.el ends here