code.delx.au - gnu-emacs/blob - lisp/emacs-lisp/eieio-opt.el

   1 ;;; eieio-opt.el -- eieio optional functions (debug, printing, speedbar)
   2
   3 ;; Copyright (C) 1996, 1998-2003, 2005, 2008-2014 Free Software
   4 ;; Foundation, Inc.
   5
   6 ;; Author: Eric M. Ludlam <zappo@gnu.org>
   7 ;; Keywords: OO, lisp
   8 ;; Package: eieio
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26 ;;
  27 ;;   This contains support functions to eieio.  These functions contain
  28 ;; some small class browser and class printing functions.
  29 ;;
  30
  31 (require 'eieio)
  32 (require 'find-func)
  33 (require 'speedbar)
  34 (require 'help-mode)
  35
  36 ;;; Code:
  37 ;;;###autoload
  38 (defun eieio-browse (&optional root-class)
  39   "Create an object browser window to show all objects.
  40 If optional ROOT-CLASS, then start with that, otherwise start with
  41 variable `eieio-default-superclass'."
  42   (interactive (if current-prefix-arg
  43                    (list (read (completing-read "Class: "
  44                                                 (eieio-build-class-alist)
  45                                                 nil t)))
  46                  nil))
  47   (if (not root-class) (setq root-class 'eieio-default-superclass))
  48   (eieio--check-type class-p root-class)
  49   (display-buffer (get-buffer-create "*EIEIO OBJECT BROWSE*") t)
  50   (with-current-buffer (get-buffer "*EIEIO OBJECT BROWSE*")
  51     (erase-buffer)
  52     (goto-char 0)
  53     (eieio-browse-tree root-class "" "")
  54     ))
  55
  56 (defun eieio-browse-tree (this-root prefix ch-prefix)
  57   "Recursively draw the children of the given class on the screen.
  58 Argument THIS-ROOT is the local root of the tree.
  59 Argument PREFIX is the character prefix to use.
  60 Argument CH-PREFIX is another character prefix to display."
  61   (eieio--check-type class-p this-root)
  62   (let ((myname (symbol-name this-root))
  63         (chl (eieio--class-children (class-v this-root)))
  64         (fprefix (concat ch-prefix "  +--"))
  65         (mprefix (concat ch-prefix "  |  "))
  66         (lprefix (concat ch-prefix "     ")))
  67     (insert prefix myname "\n")
  68     (while (cdr chl)
  69       (eieio-browse-tree (car chl) fprefix mprefix)
  70       (setq chl (cdr chl)))
  71     (if chl
  72         (eieio-browse-tree (car chl) fprefix lprefix))
  73     ))
  74
  75 ;;; CLASS COMPLETION / DOCUMENTATION
  76
  77 ;;;###autoload
  78 (defun eieio-help-class (class)
  79   "Print help description for CLASS.
  80 If CLASS is actually an object, then also display current values of that object."
  81   ;; Header line
  82   (prin1 class)
  83   (insert " is a"
  84           (if (class-option class :abstract)
  85               "n abstract"
  86             "")
  87           " class")
  88   (let ((location (get class 'class-location)))
  89     (when location
  90       (insert " in `")
  91       (help-insert-xref-button
  92        (file-name-nondirectory location)
  93        'eieio-class-def class location)
  94       (insert "'")))
  95   (insert ".\n")
  96   ;; Parents
  97   (let ((pl (eieio-class-parents class))
  98         cur)
  99     (when pl
 100       (insert " Inherits from ")
 101       (while (setq cur (pop pl))
 102         (insert "`")
 103         (help-insert-xref-button (symbol-name cur)
 104                                  'help-function cur)
 105         (insert (if pl "', " "'")))
 106       (insert ".\n")))
 107   ;; Children
 108   (let ((ch (eieio-class-children class))
 109         cur)
 110     (when ch
 111       (insert " Children ")
 112       (while (setq cur (pop ch))
 113         (insert "`")
 114         (help-insert-xref-button (symbol-name cur)
 115                                  'help-function cur)
 116         (insert (if ch "', " "'")))
 117       (insert ".\n")))
 118   ;; System documentation
 119   (let ((doc (documentation-property class 'variable-documentation)))
 120     (when doc
 121       (insert "\n" doc "\n\n")))
 122   ;; Describe all the slots in this class.
 123   (eieio-help-class-slots class)
 124   ;; Describe all the methods specific to this class.
 125   (let ((methods (eieio-all-generic-functions class))
 126         (type [":STATIC" ":BEFORE" ":PRIMARY" ":AFTER"])
 127         counter doc)
 128     (when methods
 129       (insert (propertize "Specialized Methods:\n\n" 'face 'bold))
 130       (while methods
 131         (setq doc (eieio-method-documentation (car methods) class))
 132         (insert "`")
 133         (help-insert-xref-button (symbol-name (car methods))
 134                                  'help-function (car methods))
 135         (insert "'")
 136         (if (not doc)
 137             (insert "  Undocumented")
 138           (setq counter 0)
 139           (dolist (cur doc)
 140             (when cur
 141               (insert " " (aref type counter) " "
 142                       (prin1-to-string (car cur) (current-buffer))
 143                       "\n"
 144                       (or (cdr cur) "")))
 145             (setq counter (1+ counter))))
 146         (insert "\n\n")
 147         (setq methods (cdr methods))))))
 148
 149 (defun eieio-help-class-slots (class)
 150   "Print help description for the slots in CLASS.
 151 Outputs to the current buffer."
 152   (let* ((cv (class-v class))
 153          (docs   (eieio--class-public-doc cv))
 154          (names  (eieio--class-public-a cv))
 155          (deflt  (eieio--class-public-d cv))
 156          (types  (eieio--class-public-type cv))
 157          (publp (eieio--class-public-printer cv))
 158          (i      0)
 159          (prot   (eieio--class-protection cv))
 160          )
 161     (insert (propertize "Instance Allocated Slots:\n\n"
 162                         'face 'bold))
 163     (while names
 164       (insert
 165        (concat
 166         (when (car prot)
 167           (propertize "Private " 'face 'bold))
 168         (propertize "Slot: " 'face 'bold)
 169         (prin1-to-string (car names))
 170         (unless (eq (aref types i) t)
 171           (concat "    type = "
 172                   (prin1-to-string (aref types i))))
 173         (unless (eq (car deflt) eieio-unbound)
 174           (concat "    default = "
 175                   (prin1-to-string (car deflt))))
 176         (when (car publp)
 177           (concat "    printer = "
 178                   (prin1-to-string (car publp))))
 179         (when (car docs)
 180           (concat "\n  " (car docs) "\n"))
 181         "\n"))
 182       (setq names (cdr names)
 183             docs (cdr docs)
 184             deflt (cdr deflt)
 185             publp (cdr publp)
 186             prot (cdr prot)
 187             i (1+ i)))
 188     (setq docs  (eieio--class-class-allocation-doc cv)
 189           names (eieio--class-class-allocation-a cv)
 190           types (eieio--class-class-allocation-type cv)
 191           i     0
 192           prot  (eieio--class-class-allocation-protection cv))
 193     (when names
 194       (insert (propertize "\nClass Allocated Slots:\n\n" 'face 'bold)))
 195     (while names
 196       (insert
 197        (concat
 198         (when (car prot)
 199           "Private ")
 200         "Slot: "
 201         (prin1-to-string (car names))
 202         (unless (eq (aref types i) t)
 203           (concat "    type = "
 204                   (prin1-to-string (aref types i))))
 205         (condition-case nil
 206             (let ((value (eieio-oref class (car names))))
 207               (concat "   value = "
 208                       (prin1-to-string value)))
 209           (error nil))
 210         (when (car docs)
 211           (concat "\n\n " (car docs) "\n"))
 212         "\n"))
 213       (setq names (cdr names)
 214             docs (cdr docs)
 215             prot (cdr prot)
 216             i (1+ i)))))
 217
 218 (defun eieio-build-class-list (class)
 219   "Return a list of all classes that inherit from CLASS."
 220   (if (class-p class)
 221       (apply #'append
 222              (mapcar
 223               (lambda (c)
 224                 (append (list c) (eieio-build-class-list c)))
 225               (eieio-class-children-fast class)))
 226     (list class)))
 227
 228 (defun eieio-build-class-alist (&optional class instantiable-only buildlist)
 229   "Return an alist of all currently active classes for completion purposes.
 230 Optional argument CLASS is the class to start with.
 231 If INSTANTIABLE-ONLY is non nil, only allow names of classes which
 232 are not abstract, otherwise allow all classes.
 233 Optional argument BUILDLIST is more list to attach and is used internally."
 234   (let* ((cc (or class eieio-default-superclass))
 235          (sublst (eieio--class-children (class-v cc))))
 236     (unless (assoc (symbol-name cc) buildlist)
 237       (when (or (not instantiable-only) (not (class-abstract-p cc)))
 238         (setq buildlist (cons (cons (symbol-name cc) 1) buildlist))))
 239     (while sublst
 240       (setq buildlist (eieio-build-class-alist
 241                        (car sublst) instantiable-only buildlist))
 242       (setq sublst (cdr sublst)))
 243     buildlist))
 244
 245 (defvar eieio-read-class nil
 246   "History of the function `eieio-read-class' prompt.")
 247
 248 (defun eieio-read-class (prompt &optional histvar instantiable-only)
 249   "Return a class chosen by the user using PROMPT.
 250 Optional argument HISTVAR is a variable to use as history.
 251 If INSTANTIABLE-ONLY is non nil, only allow names of classes which
 252 are not abstract."
 253   (intern (completing-read prompt (eieio-build-class-alist nil instantiable-only)
 254                            nil t nil
 255                            (or histvar 'eieio-read-class))))
 256
 257 (defun eieio-read-subclass (prompt class &optional histvar instantiable-only)
 258   "Return a class chosen by the user using PROMPT.
 259 CLASS is the base class, and completion occurs across all subclasses.
 260 Optional argument HISTVAR is a variable to use as history.
 261 If INSTANTIABLE-ONLY is non nil, only allow names of classes which
 262 are not abstract."
 263   (intern (completing-read prompt
 264                            (eieio-build-class-alist class instantiable-only)
 265                            nil t nil
 266                            (or histvar 'eieio-read-class))))
 267
 268 ;;; METHOD COMPLETION / DOC
 269
 270 (define-button-type 'eieio-method-def
 271   :supertype 'help-xref
 272   'help-function (lambda (class method file)
 273                    (eieio-help-find-method-definition class method file))
 274   'help-echo (purecopy "mouse-2, RET: find method's definition"))
 275
 276 (define-button-type 'eieio-class-def
 277   :supertype 'help-xref
 278   'help-function (lambda (class file)
 279                    (eieio-help-find-class-definition class file))
 280   'help-echo (purecopy "mouse-2, RET: find class definition"))
 281
 282 ;;;###autoload
 283 (defun eieio-help-constructor (ctr)
 284   "Describe CTR if it is a class constructor."
 285   (when (class-p ctr)
 286     (erase-buffer)
 287     (let ((location (get ctr 'class-location))
 288           (def (symbol-function ctr)))
 289       (goto-char (point-min))
 290       (prin1 ctr)
 291       (insert (format " is an %s object constructor function"
 292                       (if (autoloadp def)
 293                           "autoloaded"
 294                         "")))
 295       (when (and (autoloadp def)
 296                  (null location))
 297         (setq location
 298               (find-lisp-object-file-name ctr def)))
 299       (when location
 300         (insert " in `")
 301         (help-insert-xref-button
 302          (file-name-nondirectory location)
 303          'eieio-class-def ctr location)
 304         (insert "'"))
 305       (insert ".\nCreates an object of class " (symbol-name ctr) ".")
 306       (goto-char (point-max))
 307       (if (autoloadp def)
 308           (insert "\n\n[Class description not available until class definition is loaded.]\n")
 309         (save-excursion
 310           (insert (propertize "\n\nClass description:\n" 'face 'bold))
 311           (eieio-help-class ctr))
 312         ))))
 313
 314
 315 ;;;###autoload
 316 (defun eieio-help-generic (generic)
 317   "Describe GENERIC if it is a generic function."
 318   (when (and (symbolp generic) (generic-p generic))
 319     (save-excursion
 320       (goto-char (point-min))
 321       (when (re-search-forward " in `.+'.$" nil t)
 322         (replace-match ".")))
 323     (save-excursion
 324       (insert "\n\nThis is a generic function"
 325               (cond
 326                ((and (generic-primary-only-p generic)
 327                      (generic-primary-only-one-p generic))
 328                 " with only one primary method")
 329                ((generic-primary-only-p generic)
 330                 " with only primary methods")
 331                (t ""))
 332               ".\n\n")
 333       (insert (propertize "Implementations:\n\n" 'face 'bold))
 334       (let ((i 4)
 335             (prefix [ ":STATIC" ":BEFORE" ":PRIMARY" ":AFTER" ] ))
 336         ;; Loop over fanciful generics
 337         (while (< i 7)
 338           (let ((gm (aref (get generic 'eieio-method-tree) i)))
 339             (when gm
 340               (insert "Generic "
 341                       (aref prefix (- i 3))
 342                       "\n"
 343                       (or (nth 2 gm) "Undocumented")
 344                       "\n\n")))
 345           (setq i (1+ i)))
 346         (setq i 0)
 347         ;; Loop over defined class-specific methods
 348         (while (< i 4)
 349           (let* ((gm (reverse (aref (get generic 'eieio-method-tree) i)))
 350                  cname location)
 351             (while gm
 352               (setq cname (caar gm))
 353               (insert "`")
 354               (help-insert-xref-button (symbol-name cname)
 355                                        'help-variable cname)
 356               (insert "' " (aref prefix i) " ")
 357               ;; argument list
 358               (let* ((func (cdr (car gm)))
 359                      (arglst (help-function-arglist func)))
 360                 (prin1 arglst (current-buffer)))
 361               (insert "\n"
 362                       (or (documentation (cdr (car gm)))
 363                           "Undocumented"))
 364               ;; Print file location if available
 365               (when (and (setq location (get generic 'method-locations))
 366                          (setq location (assoc cname location)))
 367                 (setq location (cadr location))
 368                 (insert "\n\nDefined in `")
 369                 (help-insert-xref-button
 370                  (file-name-nondirectory location)
 371                  'eieio-method-def cname generic location)
 372                 (insert "'\n"))
 373               (setq gm (cdr gm))
 374               (insert "\n")))
 375           (setq i (1+ i)))))))
 376
 377 (defun eieio-all-generic-functions (&optional class)
 378   "Return a list of all generic functions.
 379 Optional CLASS argument returns only those functions that contain
 380 methods for CLASS."
 381   (let ((l nil) tree (cn (if class (symbol-name class) nil)))
 382     (mapatoms
 383      (lambda (symbol)
 384        (setq tree (get symbol 'eieio-method-obarray))
 385        (if tree
 386            (progn
 387              ;; A symbol might be interned for that class in one of
 388              ;; these three slots in the method-obarray.
 389              (if (or (not class)
 390                      (fboundp (intern-soft cn (aref tree 0)))
 391                      (fboundp (intern-soft cn (aref tree 1)))
 392                      (fboundp (intern-soft cn (aref tree 2))))
 393                  (setq l (cons symbol l)))))))
 394     l))
 395
 396 (defun eieio-method-documentation (generic class)
 397   "Return a list of the specific documentation of GENERIC for CLASS.
 398 If there is not an explicit method for CLASS in GENERIC, or if that
 399 function has no documentation, then return nil."
 400   (let ((tree (get generic 'eieio-method-obarray))
 401         (cn (symbol-name class))
 402         before primary after)
 403     (if (not tree)
 404         nil
 405       ;; A symbol might be interned for that class in one of
 406       ;; these three slots in the method-obarray.
 407       (setq before (intern-soft cn (aref tree 0))
 408             primary (intern-soft cn (aref tree 1))
 409             after (intern-soft cn (aref tree 2)))
 410       (if (not (or (fboundp before)
 411                    (fboundp primary)
 412                    (fboundp after)))
 413           nil
 414         (list (if (fboundp before)
 415                   (cons (help-function-arglist before)
 416                         (documentation before))
 417                 nil)
 418               (if (fboundp primary)
 419                   (cons (help-function-arglist primary)
 420                         (documentation primary))
 421                 nil)
 422               (if (fboundp after)
 423                   (cons (help-function-arglist after)
 424                         (documentation after))
 425                 nil))))))
 426
 427 (defvar eieio-read-generic nil
 428   "History of the `eieio-read-generic' prompt.")
 429
 430 (defun eieio-read-generic-p (fn)
 431   "Function used in function `eieio-read-generic'.
 432 This is because `generic-p' is a macro.
 433 Argument FN is the function to test."
 434   (generic-p fn))
 435
 436 (defun eieio-read-generic (prompt &optional historyvar)
 437   "Read a generic function from the minibuffer with PROMPT.
 438 Optional argument HISTORYVAR is the variable to use as history."
 439   (intern (completing-read prompt obarray 'eieio-read-generic-p
 440                            t nil (or historyvar 'eieio-read-generic))))
 441
 442 ;;; METHOD STATS
 443 ;;
 444 ;; Dump out statistics about all the active methods in a session.
 445 (defun eieio-display-method-list ()
 446   "Display a list of all the methods and what features are used."
 447   (interactive)
 448   (let* ((meth1 (eieio-all-generic-functions))
 449          (meth (sort meth1 (lambda (a b)
 450                              (string< (symbol-name a)
 451                                       (symbol-name b)))))
 452          (buff (get-buffer-create "*EIEIO Method List*"))
 453          (methidx 0)
 454          (standard-output buff)
 455          (slots '(method-static
 456                   method-before
 457                   method-primary
 458                   method-after
 459                   method-generic-before
 460                   method-generic-primary
 461                   method-generic-after))
 462          (slotn '("static"
 463                   "before"
 464                   "primary"
 465                   "after"
 466                   "G bef"
 467                   "G prim"
 468                   "G aft"))
 469          (idxarray (make-vector (length slots) 0))
 470          (primaryonly 0)
 471          (oneprimary 0)
 472          )
 473     (switch-to-buffer-other-window buff)
 474     (erase-buffer)
 475     (dolist (S slotn)
 476       (princ S)
 477       (princ "\t")
 478       )
 479     (princ "Method Name")
 480     (terpri)
 481     (princ "--------------------------------------------------------------------")
 482     (terpri)
 483     (dolist (M meth)
 484       (let ((mtree (get M 'eieio-method-tree))
 485             (P nil) (numP)
 486             (!P nil))
 487         (dolist (S slots)
 488           (let ((num (length (aref mtree (symbol-value S)))))
 489             (aset idxarray (symbol-value S)
 490                   (+ num (aref idxarray (symbol-value S))))
 491             (prin1 num)
 492             (princ "\t")
 493             (when (< 0 num)
 494               (if (eq S 'method-primary)
 495                   (setq P t numP num)
 496                 (setq !P t)))
 497             ))
 498         ;; Is this a primary-only impl method?
 499         (when (and P (not !P))
 500           (setq primaryonly (1+ primaryonly))
 501           (when (= numP 1)
 502             (setq oneprimary (1+ oneprimary))
 503             (princ "*"))
 504           (princ "* ")
 505           )
 506         (prin1 M)
 507         (terpri)
 508         (setq methidx (1+ methidx))
 509         )
 510       )
 511     (princ "--------------------------------------------------------------------")
 512     (terpri)
 513     (dolist (S slots)
 514       (prin1 (aref idxarray (symbol-value S)))
 515       (princ "\t")
 516       )
 517     (prin1 methidx)
 518     (princ " Total symbols")
 519     (terpri)
 520     (dolist (S slotn)
 521       (princ S)
 522       (princ "\t")
 523       )
 524     (terpri)
 525     (terpri)
 526     (princ "Methods Primary Only: ")
 527     (prin1 primaryonly)
 528     (princ "\t")
 529     (princ (format "%d" (* (/ (float primaryonly) (float methidx)) 100)))
 530     (princ "% of total methods")
 531     (terpri)
 532     (princ "Only One Primary Impl: ")
 533     (prin1 oneprimary)
 534     (princ "\t")
 535     (princ (format "%d" (* (/ (float oneprimary) (float primaryonly)) 100)))
 536     (princ "% of total primary methods")
 537     (terpri)
 538     ))
 539
 540 ;;; HELP AUGMENTATION
 541 ;;
 542 (defun eieio-help-find-method-definition (class method file)
 543   (let ((filename (find-library-name file))
 544         location buf)
 545     (when (symbolp class)
 546       (setq class (symbol-name class)))
 547     (when (symbolp method)
 548       (setq method (symbol-name method)))
 549     (when (null filename)
 550       (error "Cannot find library %s" file))
 551     (setq buf (find-file-noselect filename))
 552     (with-current-buffer buf
 553       (goto-char (point-min))
 554       (when
 555           (re-search-forward
 556            ;; Regexp for searching methods.
 557            (concat "(defmethod[ \t\r\n]+" method
 558                    "\\([ \t\r\n]+:[a-zA-Z]+\\)?"
 559                    "[ \t\r\n]+(\\s-*(\\(\\sw\\|\\s_\\)+\\s-+"
 560                    class
 561                    "\\s-*)")
 562            nil t)
 563         (setq location (match-beginning 0))))
 564     (if (null location)
 565         (message "Unable to find location in file")
 566       (pop-to-buffer buf)
 567       (goto-char location)
 568       (recenter)
 569       (beginning-of-line))))
 570
 571 (defun eieio-help-find-class-definition (class file)
 572   (when (symbolp class)
 573     (setq class (symbol-name class)))
 574   (let ((filename (find-library-name file))
 575         location buf)
 576     (when (null filename)
 577       (error "Cannot find library %s" file))
 578     (setq buf (find-file-noselect filename))
 579     (with-current-buffer buf
 580       (goto-char (point-min))
 581       (when
 582           (re-search-forward
 583            ;; Regexp for searching a class.
 584            (concat "(defclass[ \t\r\n]+" class "[ \t\r\n]+")
 585            nil t)
 586         (setq location (match-beginning 0))))
 587     (if (null location)
 588         (message "Unable to find location in file")
 589       (pop-to-buffer buf)
 590       (goto-char location)
 591       (recenter)
 592       (beginning-of-line))))
 593
 594 ;;; SPEEDBAR SUPPORT
 595 ;;
 596
 597 (defvar eieio-class-speedbar-key-map nil
 598   "Keymap used when working with a project in speedbar.")
 599
 600 (defun eieio-class-speedbar-make-map ()
 601   "Make a keymap for EIEIO under speedbar."
 602   (setq eieio-class-speedbar-key-map (speedbar-make-specialized-keymap))
 603
 604   ;; General viewing stuff
 605   (define-key eieio-class-speedbar-key-map "\C-m" 'speedbar-edit-line)
 606   (define-key eieio-class-speedbar-key-map "+" 'speedbar-expand-line)
 607   (define-key eieio-class-speedbar-key-map "-" 'speedbar-contract-line)
 608   )
 609
 610 (if eieio-class-speedbar-key-map
 611     nil
 612   (if (not (featurep 'speedbar))
 613       (add-hook 'speedbar-load-hook (lambda ()
 614                                       (eieio-class-speedbar-make-map)
 615                                       (speedbar-add-expansion-list
 616                                        '("EIEIO"
 617                                          eieio-class-speedbar-menu
 618                                          eieio-class-speedbar-key-map
 619                                          eieio-class-speedbar))))
 620     (eieio-class-speedbar-make-map)
 621     (speedbar-add-expansion-list '("EIEIO"
 622                                    eieio-class-speedbar-menu
 623                                    eieio-class-speedbar-key-map
 624                                    eieio-class-speedbar))))
 625
 626 (defvar eieio-class-speedbar-menu
 627   ()
 628   "Menu part in easymenu format used in speedbar while in `eieio' mode.")
 629
 630 (defun eieio-class-speedbar (dir-or-object depth)
 631   "Create buttons in speedbar that represents the current project.
 632 DIR-OR-OBJECT is the object to expand, or nil, and DEPTH is the
 633 current expansion depth."
 634   (when (eq (point-min) (point-max))
 635     ;; This function is only called once, to start the whole deal.
 636     ;; Create and expand the default object.
 637     (eieio-class-button eieio-default-superclass 0)
 638     (forward-line -1)
 639     (speedbar-expand-line)))
 640
 641 (defun eieio-class-button (class depth)
 642   "Draw a speedbar button at the current point for CLASS at DEPTH."
 643   (eieio--check-type class-p class)
 644   (let ((subclasses (eieio--class-children (class-v class))))
 645     (if subclasses
 646         (speedbar-make-tag-line 'angle ?+
 647                                 'eieio-sb-expand
 648                                 class
 649                                 (symbol-name class)
 650                                 'eieio-describe-class-sb
 651                                 class
 652                                 'speedbar-directory-face
 653                                 depth)
 654       (speedbar-make-tag-line 'angle ?  nil nil
 655                               (symbol-name class)
 656                               'eieio-describe-class-sb
 657                               class
 658                               'speedbar-directory-face
 659                               depth))))
 660
 661 (defun eieio-sb-expand (text class indent)
 662   "For button TEXT, expand CLASS at the current location.
 663 Argument INDENT is the depth of indentation."
 664   (cond ((string-match "+" text)        ;we have to expand this file
 665          (speedbar-change-expand-button-char ?-)
 666          (speedbar-with-writable
 667            (save-excursion
 668              (end-of-line) (forward-char 1)
 669              (let ((subclasses (eieio--class-children (class-v class))))
 670                (while subclasses
 671                  (eieio-class-button (car subclasses) (1+ indent))
 672                  (setq subclasses (cdr subclasses)))))))
 673         ((string-match "-" text)        ;we have to contract this node
 674          (speedbar-change-expand-button-char ?+)
 675          (speedbar-delete-subblock indent))
 676         (t (error "Ooops...  not sure what to do")))
 677   (speedbar-center-buffer-smartly))
 678
 679 (defun eieio-describe-class-sb (text token indent)
 680   "Describe the class TEXT in TOKEN.
 681 INDENT is the current indentation level."
 682   (dframe-with-attached-buffer
 683    (describe-function token))
 684   (dframe-maybee-jump-to-attached-frame))
 685
 686 (provide 'eieio-opt)
 687
 688 ;; Local variables:
 689 ;; generated-autoload-file: "eieio.el"
 690 ;; End:
 691
 692 ;;; eieio-opt.el ends here