code.delx.au - gnu-emacs/blob - configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996 Free Software Foundation, Inc.
   7 dnl
   8 dnl  This file is part of GNU Emacs.
   9 dnl
  10 dnl  GNU Emacs is free software; you can redistribute it and/or modify
  11 dnl  it under the terms of the GNU General Public License as published by
  12 dnl  the Free Software Foundation; either version 2, or (at your option)
  13 dnl  any later version.
  14 dnl
  15 dnl  GNU Emacs is distributed in the hope that it will be useful,
  16 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 dnl  GNU General Public License for more details.
  19 dnl
  20 dnl  You should have received a copy of the GNU General Public License
  21 dnl  along with GNU Emacs; see the file COPYING.  If not, write to the
  22 dnl  Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 dnl  Boston, MA 02111-1307, USA.
  24
  25 AC_PREREQ(2.8)dnl
  26 AC_INIT(src/lisp.h)
  27 AC_CONFIG_HEADER(src/config.h:src/config.in)
  28
  29 lispdir='${datadir}/emacs/${version}/lisp'
  30 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  31 '${datadir}/emacs/site-lisp:${datadir}/emacs/${version}/leim'
  32 lisppath='${locallisppath}:${lispdir}'
  33 etcdir='${datadir}/emacs/${version}/etc'
  34 lockdir='${sharedstatedir}/emacs/lock'
  35 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  36 docdir='${datadir}/emacs/${version}/etc'
  37
  38 AC_ARG_WITH(gcc,
  39 [  --with-gcc              use GCC to compile Emacs])
  40 AC_ARG_WITH(pop,
  41 [  --with-pop              support POP for mail retrieval],
  42 [AC_DEFINE(MAIL_USE_POP)])
  43 AC_ARG_WITH(kerberos,
  44 [  --with-kerberos         support Kerberos-authenticated POP],
  45 [AC_DEFINE(KERBEROS)])
  46 AC_ARG_WITH(hesiod,
  47 [  --with-hesiod           support Hesiod to get the POP server host],
  48 [AC_DEFINE(HESIOD)])
  49 dnl This should be the last --with option, because --with-x is
  50 dnl added later on when we find the path of X, and it's best to
  51 dnl keep them together visually.
  52 AC_ARG_WITH(x-toolkit,
  53 [  --with-x-toolkit=KIT    use an X toolkit (KIT = yes/lucid/athena/motif/no)],
  54 [         case "${withval}" in
  55             y | ye | yes )      val=athena ;;
  56             n | no )            val=no  ;;
  57             l | lu | luc | luci | lucid )       val=lucid ;;
  58             a | at | ath | athe | athen | athena )      val=athena ;;
  59             m | mo | mot | moti | motif )       val=motif ;;
  60 dnl These don't currently work.
  61 dnl         o | op | ope | open | open- | open-l | open-lo \
  62 dnl             | open-loo | open-look )        val=open-look ;;
  63             * )
  64 dnl AC_MSG_ERROR([the \`--with-x-toolkit' option is supposed to have a value
  65 dnl which is \`yes', \`no', \`lucid', \`athena', \`motif' or \`open-look'.])
  66 AC_MSG_ERROR([\`--with-x-toolkit=$withval' is invalid\;
  67 this option's value should be \`yes', \`no', \`lucid', \`athena', or \`motif'.
  68 Currently, \`yes', \`athena' and \`lucid' are synonyms.])
  69             ;;
  70           esac
  71           with_x_toolkit=$val
  72 ])
  73
  74 #### Make srcdir absolute, if it isn't already.  It's important to
  75 #### avoid running the path through pwd unnecessary, since pwd can
  76 #### give you automounter prefixes, which can go away.  We do all this
  77 #### so Emacs can find its files when run uninstalled.
  78 case "${srcdir}" in
  79   /* ) ;;
  80   . )
  81     ## We may be able to use the $PWD environment variable to make this
  82     ## absolute.  But sometimes PWD is inaccurate.
  83     ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
  84     CDPATH=
  85     if test "${PWD}" != "" && test "`(cd ${PWD} ; sh -c pwd)`" = "`pwd`"  ;
  86     then
  87       srcdir="$PWD"
  88     else
  89       srcdir="`(cd ${srcdir}; pwd)`"
  90     fi
  91   ;;
  92   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
  93 esac
  94
  95 #### Check if the source directory already has a configured system in it.
  96 if test `pwd` != `(cd ${srcdir} && pwd)` \
  97    && test -f "${srcdir}/src/config.h" ; then
  98   AC_MSG_WARN([The directory tree \`${srcdir}' is being used
  99    as a build directory right now; it has been configured in its own
 100    right.  To configure in another directory as well, you MUST
 101    use GNU make.  If you do not have GNU make, then you must
 102    now do \`make distclean' in ${srcdir},
 103    and then run $0 again.])
 104
 105 changequote(, )dnl
 106   extrasub='/^VPATH[     ]*=/c\
 107 changequote([, ])dnl
 108 vpath %.c $(srcdir)\
 109 vpath %.h $(srcdir)\
 110 vpath %.y $(srcdir)\
 111 vpath %.l $(srcdir)\
 112 vpath %.s $(srcdir)\
 113 vpath %.in $(srcdir)\
 114 vpath %.texi $(srcdir)'
 115 fi
 116
 117 #### Given the configuration name, set machfile and opsysfile to the
 118 #### names of the m/*.h and s/*.h files we should use.
 119
 120 ### Canonicalize the configuration name.
 121
 122 AC_CANONICAL_HOST
 123 canonical=$host
 124 configuration=$host_alias
 125
 126 changequote(, )dnl
 127
 128 ### If you add support for a new configuration, add code to this
 129 ### switch statement to recognize your configuration name and select
 130 ### the appropriate operating system and machine description files.
 131
 132 ### You would hope that you could choose an m/*.h file pretty much
 133 ### based on the machine portion of the configuration name, and an s-
 134 ### file based on the operating system portion.  However, it turns out
 135 ### that each m/*.h file is pretty manufacturer-specific - for
 136 ### example, apollo.h, hp9000s300.h, mega68k, news.h, and tad68k are
 137 ### all 68000 machines; mips.h, pmax.h, and news-risc are all MIPS
 138 ### machines.  So we basically have to have a special case for each
 139 ### configuration name.
 140 ###
 141 ### As far as handling version numbers on operating systems is
 142 ### concerned, make sure things will fail in a fixable way.  If
 143 ### /etc/MACHINES doesn't say anything about version numbers, be
 144 ### prepared to handle anything reasonably.  If version numbers
 145 ### matter, be sure /etc/MACHINES says something about it.
 146 ###
 147 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 148 ### "System V Release 4"; he writes, "The old convention encouraged
 149 ### confusion between `system' and `release' levels'."
 150
 151 machine='' opsys='' unported=no
 152 case "${canonical}" in
 153
 154   ## NetBSD ports
 155   *-*-netbsd* )
 156     opsys=netbsd
 157     case "${canonical}" in
 158       alpha-*-netbsd*)  machine=alpha ;;
 159       i[3456]86-*-netbsd*) machine=intel386 ;;
 160       m68k-*-netbsd*)
 161                         # This is somewhat bogus.
 162                         machine=hp9000s300 ;;
 163       mips-*-netbsd*)   machine=pmax ;;
 164       ns32k-*-netbsd*)  machine=ns32000 ;;
 165       sparc-*-netbsd*)  machine=sparc ;;
 166       vax-*-netbsd*)    machine=vax ;;
 167     esac
 168   ;;
 169
 170   ## Acorn RISCiX:
 171   arm-acorn-riscix1.1* )
 172     machine=acorn opsys=riscix1-1
 173   ;;
 174   arm-acorn-riscix1.2* | arm-acorn-riscix )
 175     ## This name is riscix12 instead of riscix1.2
 176     ## to avoid a file name conflict on MSDOS.
 177     machine=acorn opsys=riscix12
 178   ;;
 179
 180   ## BSDI ports
 181   *-*-bsdi* )
 182     opsys=bsdi
 183     case "${canonical}" in
 184       i[345]86-*-bsdi*) machine=intel386 ;;
 185       sparc-*-bsdi*)  machine=sparc ;;
 186       powerpc-*-bsdi*)  machine=powerpc ;;
 187     esac
 188     case "${canonical}" in
 189       *-*-bsd386* | *-*-bsdi1* )        opsys=bsd386 ;;
 190       *-*-bsdi2.0* )            opsys=bsdos2 ;;
 191       *-*-bsdi2* )              opsys=bsdos2-1 ;;
 192       *-*-bsdi3* )              opsys=bsdos3 ;;
 193     esac
 194   ;;
 195
 196   ## Alliant machines
 197   ## Strictly speaking, we need the version of the alliant operating
 198   ## system to choose the right machine file, but currently the
 199   ## configuration name doesn't tell us enough to choose the right
 200   ## one; we need to give alliants their own operating system name to
 201   ## do this right.  When someone cares, they can help us.
 202   fx80-alliant-* )
 203     machine=alliant4 opsys=bsd4-2
 204   ;;
 205   i860-alliant-* )
 206     machine=alliant-2800 opsys=bsd4-3
 207   ;;
 208
 209   ## Alpha (DEC) machines.
 210   alpha-dec-osf* )
 211     machine=alpha opsys=osf1
 212     # This is needed to find X11R6.1 libraries for certain tests.
 213     NON_GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
 214     GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
 215   ;;
 216
 217   alpha-*-linux-gnu* )
 218     machine=alpha opsys=gnu-linux
 219   ;;
 220
 221   ## Altos 3068
 222   m68*-altos-sysv* )
 223     machine=altos opsys=usg5-2
 224   ;;
 225
 226   ## Amdahl UTS
 227   580-amdahl-sysv* )
 228     machine=amdahl opsys=usg5-2-2
 229   ;;
 230
 231   ## Apollo, Domain/OS
 232   m68*-apollo-* )
 233     machine=apollo opsys=bsd4-3
 234   ;;
 235
 236   ## AT&T 3b2, 3b5, 3b15, 3b20
 237   we32k-att-sysv* )
 238     machine=att3b opsys=usg5-2-2
 239   ;;
 240
 241   ## AT&T 3b1 - The Mighty Unix PC!
 242   m68*-att-sysv* )
 243     machine=7300 opsys=usg5-2-2
 244   ;;
 245
 246   ## Bull dpx20
 247   rs6000-bull-bosx* )
 248     machine=ibmrs6000 opsys=aix3-2
 249   ;;
 250
 251   ## Bull dpx2
 252   m68*-bull-sysv3* )
 253     machine=dpx2 opsys=usg5-3
 254   ;;
 255
 256   ## Bull sps7
 257   m68*-bull-sysv2* )
 258     machine=sps7 opsys=usg5-2
 259   ;;
 260
 261   ## CCI 5/32, 6/32 -- see "Tahoe".
 262
 263   ## Celerity
 264   ## I don't know what configuration name to use for this; config.sub
 265   ## doesn't seem to know anything about it.  Hey, Celerity users, get
 266   ## in touch with us!
 267   celerity-celerity-bsd* )
 268     machine=celerity opsys=bsd4-2
 269   ;;
 270
 271   ## Clipper
 272   ## What operating systems does this chip run that Emacs has been
 273   ## tested on?
 274   clipper-* )
 275     machine=clipper
 276     ## We'll use the catch-all code at the bottom to guess the
 277     ## operating system.
 278   ;;
 279
 280   ## Convex
 281   *-convex-bsd* | *-convex-convexos* )
 282     machine=convex opsys=bsd4-3
 283     ## Prevents spurious white space in makefiles - d.m.cooke@larc.nasa.gov
 284     NON_GNU_CPP="cc -E -P"
 285   ;;
 286
 287   ## Cubix QBx/386
 288   i[3456]86-cubix-sysv* )
 289     machine=intel386 opsys=usg5-3
 290   ;;
 291
 292   ## Cydra 5
 293   cydra*-cydrome-sysv* )
 294     machine=cydra5 opsys=usg5-3
 295   ;;
 296
 297   ## Data General AViiON Machines
 298   ## DG changed naming conventions with the release of 5.4.4.10, they
 299   ## dropped the initial 5.4 but left the intervening R.  Because of the
 300   ## R this shouldn't conflict with older versions of the OS (which I
 301   ## think were named like dgux4.*).
 302   m88k-dg-dguxR4.* | m88k-dg-dgux4* )
 303     machine=aviion opsys=dgux4
 304   ;;
 305   m88k-dg-dgux5.4R3* | m88k-dg-dgux5.4.3* )
 306     ## This name is dgux5-4-3 instead of dgux5-4r3
 307     ## to avoid a file name conflict on MSDOS.
 308     machine=aviion opsys=dgux5-4-3
 309   ;;
 310   m88k-dg-dgux5.4R2* | m88k-dg-dgux5.4.2* )
 311     machine=aviion opsys=dgux5-4r2
 312   ;;
 313   m88k-dg-dgux* )
 314     machine=aviion opsys=dgux
 315   ;;
 316
 317   ## DECstations
 318   mips-dec-ultrix[0-3].* | mips-dec-ultrix4.0* | mips-dec-bsd4.2* )
 319     machine=pmax opsys=bsd4-2
 320   ;;
 321   mips-dec-ultrix4.[12]* | mips-dec-bsd* )
 322     machine=pmax opsys=bsd4-3
 323   ;;
 324   mips-dec-ultrix* )
 325     machine=pmax opsys=ultrix4-3
 326   ;;
 327   mips-dec-osf* )
 328     machine=pmax opsys=osf1
 329   ;;
 330   mips-dec-mach_bsd4.3* )
 331     machine=pmax opsys=mach-bsd4-3
 332   ;;
 333
 334   ## Motorola Delta machines
 335   m68k-motorola-sysv* | m68000-motorola-sysv* )
 336     machine=delta opsys=usg5-3
 337     if test -z "`type gnucc | grep 'not found'`"
 338     then
 339       if test -s /etc/167config
 340       then CC="gnucc -m68040"
 341       else CC="gnucc -m68881"
 342       fi
 343     else
 344       if test -z "`type gcc | grep 'not found'`"
 345       then CC=gcc
 346       else CC=cc
 347       fi
 348     fi
 349   ;;
 350   m88k-motorola-sysv4* )
 351     # jbotte@bnr.ca says that UNIX_System_V <hostName> 4.0 R40V4.3 m88k mc88110
 352     # needs POSIX_SIGNALS and therefore needs usg5-4-2.
 353     # I hope there are not other 4.0 versions for this machine
 354     # which really need usg5-4 instead.
 355     machine=delta88k opsys=usg5-4-2
 356   ;;
 357   m88k-motorola-sysv* | m88k-motorola-m88kbcs* )
 358     machine=delta88k opsys=usg5-3
 359   ;;
 360
 361   ## Dual machines
 362   m68*-dual-sysv* )
 363     machine=dual opsys=usg5-2
 364   ;;
 365   m68*-dual-uniplus* )
 366     machine=dual opsys=unipl5-2
 367   ;;
 368
 369   ## Elxsi 6400
 370   elxsi-elxsi-sysv* )
 371     machine=elxsi opsys=usg5-2
 372   ;;
 373
 374   ## Encore machines
 375   ns16k-encore-bsd* )
 376     machine=ns16000 opsys=umax
 377   ;;
 378
 379   ## The GEC 93 - apparently, this port isn't really finished yet.
 380
 381   ## Gould Power Node and NP1
 382   pn-gould-bsd4.2* )
 383     machine=gould opsys=bsd4-2
 384   ;;
 385   pn-gould-bsd4.3* )
 386     machine=gould opsys=bsd4-3
 387   ;;
 388   np1-gould-bsd* )
 389     machine=gould-np1 opsys=bsd4-3
 390   ;;
 391
 392   ## Harris Night Hawk machines running CX/UX (a 5000 looks just like a 4000
 393   ## as far as Emacs is concerned).
 394   m88k-harris-cxux* )
 395     # Build needs to be different on 7.0 and later releases
 396     case "`uname -r`" in
 397        [56].[0-9] ) machine=nh4000 opsys=cxux ;;
 398        [7].[0-9] ) machine=nh4000 opsys=cxux7 ;;
 399     esac
 400     NON_GNU_CPP="/lib/cpp"
 401   ;;
 402   ## Harris ecx or gcx running CX/UX (Series 1200, Series 3000)
 403   m68k-harris-cxux* )
 404     machine=nh3000 opsys=cxux
 405   ;;
 406   ## Harris power pc NightHawk running Power UNIX (Series 6000)
 407   powerpc-harris-powerunix )
 408     machine=nh6000 opsys=powerunix
 409     NON_GNU_CPP="cc -Xo -E -P"
 410   ;;
 411   ## SR2001/SR2201 running HI-UX/MPP
 412   hppa1.1-hitachi-hiuxmpp* )
 413     machine=sr2k opsys=hiuxmpp
 414   ;;
 415   ## Honeywell XPS100
 416   xps*-honeywell-sysv* )
 417     machine=xps100 opsys=usg5-2
 418   ;;
 419
 420   ## HP 9000 series 200 or 300
 421   m68*-hp-bsd* )
 422     machine=hp9000s300 opsys=bsd4-3
 423   ;;
 424   ## HP/UX 7, 8, 9, and 10 are supported on these machines.
 425   m68*-hp-hpux* )
 426     case "`uname -r`" in
 427       ## Someone's system reports A.B8.05 for this.
 428       ## I wonder what other possibilities there are.
 429       *.B8.* ) machine=hp9000s300 opsys=hpux8 ;;
 430       *.08.* ) machine=hp9000s300 opsys=hpux8 ;;
 431       *.09.* ) machine=hp9000s300 opsys=hpux9 ;;
 432       *.10.* ) machine=hp9000s300 opsys=hpux9shr ;;
 433       *) machine=hp9000s300 opsys=hpux ;;
 434     esac
 435   ;;
 436
 437   ## HP 9000 series 700 and 800, running HP/UX
 438   hppa*-hp-hpux7* )
 439     machine=hp800 opsys=hpux
 440   ;;
 441   hppa*-hp-hpux8* )
 442     machine=hp800 opsys=hpux8
 443   ;;
 444   hppa*-hp-hpux9shr* )
 445     machine=hp800 opsys=hpux9shr
 446   ;;
 447   hppa*-hp-hpux9* )
 448     machine=hp800 opsys=hpux9
 449   ;;
 450   hppa*-hp-hpux10* )
 451     machine=hp800 opsys=hpux10
 452   ;;
 453
 454   ## HP 9000 series 700 and 800, running HP/UX
 455   hppa*-hp-hpux* )
 456     ## Cross-compilation?  Nah!
 457     case "`uname -r`" in
 458       ## Someone's system reports A.B8.05 for this.
 459       ## I wonder what other possibilities there are.
 460       *.B8.* ) machine=hp800 opsys=hpux8 ;;
 461       *.08.* ) machine=hp800 opsys=hpux8 ;;
 462       *.09.* ) machine=hp800 opsys=hpux9 ;;
 463       *) machine=hp800 opsys=hpux ;;
 464     esac
 465   ;;
 466   hppa*-*-nextstep* )
 467     machine=hp800 opsys=nextstep
 468   ;;
 469
 470   ## Orion machines
 471   orion-orion-bsd* )
 472     machine=orion opsys=bsd4-2
 473   ;;
 474   clipper-orion-bsd* )
 475     machine=orion105 opsys=bsd4-2
 476   ;;
 477
 478   ## IBM machines
 479   i[3456]86-ibm-aix1.1* )
 480     machine=ibmps2-aix opsys=usg5-2-2
 481   ;;
 482   i[3456]86-ibm-aix1.[23]* | i[3456]86-ibm-aix* )
 483     machine=ibmps2-aix opsys=usg5-3
 484   ;;
 485   i370-ibm-aix*)
 486     machine=ibm370aix opsys=usg5-3
 487   ;;
 488   rs6000-ibm-aix3.1* | powerpc-ibm-aix3.1*  )
 489     machine=ibmrs6000 opsys=aix3-1
 490   ;;
 491   rs6000-ibm-aix3.2.5 | powerpc-ibm-aix3.2.5 )
 492     machine=ibmrs6000 opsys=aix3-2-5
 493   ;;
 494   rs6000-ibm-aix4.1* | powerpc-ibm-aix4.1*  )
 495     machine=ibmrs6000 opsys=aix4-1
 496   ;;
 497   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 498     machine=ibmrs6000 opsys=aix4-2
 499   ;;
 500   rs6000-ibm-aix4.0* | powerpc-ibm-aix4.0*  )
 501     machine=ibmrs6000 opsys=aix4
 502   ;;
 503   rs6000-ibm-aix4* | powerpc-ibm-aix4*  )
 504     machine=ibmrs6000 opsys=aix4-1
 505   ;;
 506   rs6000-ibm-aix* | powerpc-ibm-aix* )
 507     machine=ibmrs6000 opsys=aix3-2
 508   ;;
 509   romp-ibm-bsd4.3* )
 510     machine=ibmrt opsys=bsd4-3
 511   ;;
 512   romp-ibm-bsd4.2* )
 513     machine=ibmrt opsys=bsd4-2
 514   ;;
 515   romp-ibm-aos4.3* )
 516     machine=ibmrt opsys=bsd4-3
 517   ;;
 518   romp-ibm-aos4.2* )
 519     machine=ibmrt opsys=bsd4-2
 520   ;;
 521   romp-ibm-aos* )
 522     machine=ibmrt opsys=bsd4-3
 523   ;;
 524   romp-ibm-bsd* )
 525     machine=ibmrt opsys=bsd4-3
 526   ;;
 527   romp-ibm-aix* )
 528     machine=ibmrt-aix opsys=usg5-2-2
 529   ;;
 530
 531   ## Integrated Solutions `Optimum V'
 532   m68*-isi-bsd4.2* )
 533     machine=isi-ov opsys=bsd4-2
 534   ;;
 535   m68*-isi-bsd4.3* )
 536     machine=isi-ov opsys=bsd4-3
 537   ;;
 538
 539   ## Intel 386 machines where we do care about the manufacturer
 540   i[3456]86-intsys-sysv* )
 541     machine=is386 opsys=usg5-2-2
 542   ;;
 543
 544   ## Prime EXL
 545   i[3456]86-prime-sysv* )
 546     machine=i386 opsys=usg5-3
 547   ;;
 548
 549   ## Sequent Symmetry running Dynix
 550   i[3456]86-sequent-bsd* )
 551     machine=symmetry opsys=bsd4-3
 552   ;;
 553
 554   ## Sequent Symmetry running ptx 4, which is a modified SVR4.
 555   i[3456]86-sequent-ptx4* | i[3456]86-sequent-sysv4* )
 556     machine=sequent-ptx opsys=ptx4
 557     NON_GNU_CPP=/lib/cpp
 558   ;;
 559
 560   ## Sequent Symmetry running DYNIX/ptx
 561   ## Use the old cpp rather than the newer ANSI one.
 562   i[3456]86-sequent-ptx* )
 563     machine=sequent-ptx opsys=ptx
 564     NON_GNU_CPP="/lib/cpp"
 565   ;;
 566
 567   ## ncr machine running svr4.3.
 568   i[3456]86-ncr-sysv4.3 )
 569     machine=ncr386 opsys=usg5-4-3
 570   ;;
 571
 572   ## Unspecified sysv on an ncr machine defaults to svr4.2.
 573   ## (Plain usg5-4 doesn't turn on POSIX signals, which we need.)
 574   i[3456]86-ncr-sysv* )
 575     machine=ncr386 opsys=usg5-4-2
 576   ;;
 577
 578   ## Intel Paragon OSF/1
 579   i860-intel-osf1* )
 580     machine=paragon opsys=osf1 NON_GNU_CPP=/usr/mach/lib/cpp
 581   ;;
 582
 583   ## Intel 860
 584   i860-*-sysv4* )
 585     machine=i860 opsys=usg5-4
 586     NON_GNU_CC="/bin/cc" # Ie, not the one in /usr/ucb/cc.
 587     NON_GNU_CPP="/usr/ccs/lib/cpp" # cc -E tokenizes macro expansion.
 588   ;;
 589
 590   ## Masscomp machines
 591   m68*-masscomp-rtu* )
 592     machine=masscomp opsys=rtu
 593   ;;
 594
 595   ## Megatest machines
 596   m68*-megatest-bsd* )
 597     machine=mega68 opsys=bsd4-2
 598   ;;
 599
 600   ## Workstations sold by MIPS
 601   ## This is not necessarily all workstations using the MIPS processor -
 602   ## Irises are produced by SGI, and DECstations by DEC.
 603
 604   ## etc/MACHINES lists mips.h and mips4.h as possible machine files,
 605   ## and usg5-2-2 and bsd4-3 as possible OS files.  The only guidance
 606   ## it gives for choosing between the alternatives seems to be "Use
 607   ## -machine=mips4 for RISCOS version 4; use -opsystem=bsd4-3 with
 608   ## the BSD world."  I'll assume that these are instructions for
 609   ## handling two odd situations, and that every other situation
 610   ## should use mips.h and usg5-2-2, they being listed first.
 611   mips-mips-usg* )
 612     machine=mips4
 613     ## Fall through to the general code at the bottom to decide on the OS.
 614   ;;
 615   mips-mips-riscos4* )
 616     machine=mips4 opsys=bsd4-3
 617     NON_GNU_CC="cc -systype bsd43"
 618     NON_GNU_CPP="cc -systype bsd43 -E"
 619   ;;
 620   mips-mips-riscos5* )
 621     machine=mips4 opsys=riscos5
 622     NON_GNU_CC="cc -systype bsd43"
 623     NON_GNU_CPP="cc -systype bsd43 -E"
 624   ;;
 625   mips-mips-bsd* )
 626     machine=mips opsys=bsd4-3
 627   ;;
 628   mips-mips-* )
 629     machine=mips opsys=usg5-2-2
 630   ;;
 631
 632   ## NeXT
 633   m68*-next-* | m68k-*-nextstep* )
 634     machine=m68k opsys=nextstep
 635   ;;
 636
 637   ## The complete machine from National Semiconductor
 638   ns32k-ns-genix* )
 639     machine=ns32000 opsys=usg5-2
 640   ;;
 641
 642   ## NCR machines
 643   m68*-ncr-sysv2* | m68*-ncr-sysvr2* )
 644     machine=tower32 opsys=usg5-2-2
 645   ;;
 646   m68*-ncr-sysv3* | m68*-ncr-sysvr3* )
 647     machine=tower32v3 opsys=usg5-3
 648   ;;
 649
 650   ## Nixdorf Targon 31
 651   m68*-nixdorf-sysv* )
 652     machine=targon31 opsys=usg5-2-2
 653   ;;
 654
 655   ## Nu (TI or LMI)
 656   m68*-nu-sysv* )
 657     machine=nu opsys=usg5-2
 658   ;;
 659
 660   ## Plexus
 661   m68*-plexus-sysv* )
 662     machine=plexus opsys=usg5-2
 663   ;;
 664
 665   ## PowerPC reference platform
 666   powerpcle-*-solaris2* )
 667     machine=prep
 668     opsys=sol2-5
 669   ;;
 670
 671   ## Pyramid machines
 672   ## I don't really have any idea what sort of processor the Pyramid has,
 673   ## so I'm assuming it is its own architecture.
 674   pyramid-pyramid-bsd* )
 675     machine=pyramid opsys=bsd4-2
 676   ;;
 677
 678   ## Sequent Balance
 679   ns32k-sequent-bsd4.2* )
 680     machine=sequent opsys=bsd4-2
 681   ;;
 682   ns32k-sequent-bsd4.3* )
 683     machine=sequent opsys=bsd4-3
 684   ;;
 685
 686   ## Siemens Nixdorf
 687   mips-siemens-sysv* | mips-sni-sysv*)
 688     machine=mips-siemens opsys=usg5-4
 689     NON_GNU_CC=/usr/ccs/bin/cc
 690     NON_GNU_CPP=/usr/ccs/lib/cpp
 691   ;;
 692
 693   ## Silicon Graphics machines
 694   ## Iris 2500 and Iris 2500 Turbo (aka the Iris 3030)
 695   m68*-sgi-iris3.5* )
 696     machine=irist opsys=iris3-5
 697   ;;
 698   m68*-sgi-iris3.6* | m68*-sgi-iris*)
 699     machine=irist opsys=iris3-6
 700   ;;
 701   ## Iris 4D
 702   mips-sgi-irix3* )
 703     machine=iris4d opsys=irix3-3
 704   ;;
 705   mips-sgi-irix4* )
 706     machine=iris4d opsys=irix4-0
 707   ;;
 708   mips-sgi-irix6* )
 709     machine=iris4d opsys=irix6-0
 710     NON_GNU_CPP=/lib/cpp
 711     NON_GCC_TEST_OPTIONS=-32
 712   ;;
 713   mips-sgi-irix5.[01]* )
 714     machine=iris4d opsys=irix5-0
 715   ;;
 716   mips-sgi-irix5* | mips-sgi-irix* )
 717     machine=iris4d opsys=irix5-2
 718   ;;
 719
 720   ## SONY machines
 721   m68*-sony-bsd4.2* )
 722     machine=news opsys=bsd4-2
 723   ;;
 724   m68*-sony-bsd4.3* )
 725     machine=news opsys=bsd4-3
 726   ;;
 727   m68*-sony-newsos3* | m68*-sony-news3*)
 728     machine=news opsys=bsd4-3
 729   ;;
 730   mips-sony-bsd* | mips-sony-newsos4* | mips-sony-news4*)
 731     machine=news-risc opsys=bsd4-3
 732   ;;
 733   mips-sony-newsos6* )
 734     machine=news-r6 opsys=newsos6
 735   ;;
 736   mips-sony-news* )
 737     machine=news-risc opsys=newsos5
 738   ;;
 739
 740   ## Stride
 741   m68*-stride-sysv* )
 742     machine=stride opsys=usg5-2
 743   ;;
 744
 745   ## Suns
 746   sparc-*-linux-gnu* )
 747     machine=sparc opsys=gnu-linux
 748   ;;
 749
 750   *-sun-sunos* | *-sun-bsd* | *-sun-solaris* \
 751     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* | powerpc*-*-solaris2* \
 752     | rs6000-*-solaris2*)
 753     case "${canonical}" in
 754       m68*-sunos1* )    machine=sun1 ;;
 755       m68*-sunos2* )    machine=sun2 ;;
 756       m68* )            machine=sun3 ;;
 757       i[3456]86-sun-sunos[34]* )        machine=sun386 ;;
 758       i[3456]86-*-* )     machine=intel386 ;;
 759       powerpcle* )      machine=powerpcle ;;
 760       powerpc* | rs6000* )  machine=ibmrs6000 ;;
 761       sparc* )          machine=sparc ;;
 762       * )               unported=yes ;;
 763     esac
 764     case "${canonical}" in
 765       ## The Sun386 didn't get past 4.0.
 766       i[3456]86-*-sunos4          ) opsys=sunos4-0 ;;
 767       *-sunos4.0*         ) opsys=sunos4-0 ;;
 768       *-sunos4.1.[3-9]*noshare )
 769                 ## This name is sunos413 instead of sunos4-1-3
 770                 ## to avoid a file name conflict on MSDOS.
 771                 opsys=sunos413
 772                 NON_GNU_CPP=/usr/lib/cpp
 773                 NON_GCC_TEST_OPTIONS=-Bstatic
 774                 GCC_TEST_OPTIONS=-static
 775                 ;;
 776       *-sunos4.1.[3-9]* | *-sunos4shr*)
 777                 opsys=sunos4shr
 778                 NON_GNU_CPP=/usr/lib/cpp
 779                 ;;
 780       *-sunos4* | *-sunos )
 781                 opsys=sunos4-1
 782                 NON_GCC_TEST_OPTIONS=-Bstatic
 783                 GCC_TEST_OPTIONS=-static
 784                 ;;
 785       *-sunos5.3* | *-solaris2.3* )
 786                 opsys=sol2-3
 787                 NON_GNU_CPP=/usr/ccs/lib/cpp
 788                 ;;
 789       *-sunos5.4* | *-solaris2.4* )
 790                 opsys=sol2-4
 791                 NON_GNU_CPP=/usr/ccs/lib/cpp
 792                 RANLIB="ar -ts"
 793                 ;;
 794       *-sunos5.5* | *-solaris2.5* )
 795                 opsys=sol2-5
 796                 NON_GNU_CPP=/usr/ccs/lib/cpp
 797                 RANLIB="ar -ts"
 798                 ;;
 799       *-sunos5* | *-solaris* )
 800                 opsys=sol2-4
 801                 NON_GNU_CPP=/usr/ccs/lib/cpp
 802                 ;;
 803       *                   ) opsys=bsd4-2   ;;
 804     esac
 805     ## Watch out for a compiler that we know will not work.
 806     case "${canonical}" in
 807      *-solaris* | *-sunos5* )
 808                 if [ "x$CC" = x/usr/ucb/cc ]; then
 809                   ## /usr/ucb/cc doesn't work;
 810                   ## we should find some other compiler that does work.
 811                   unset CC
 812                 fi
 813                 ;;
 814       *) ;;
 815     esac
 816   ;;
 817   sparc-*-nextstep* )
 818     machine=sparc opsys=nextstep
 819   ;;
 820
 821   ## Tadpole 68k
 822   m68*-tadpole-sysv* )
 823     machine=tad68k opsys=usg5-3
 824   ;;
 825
 826   ## Tahoe machines
 827   tahoe-tahoe-bsd4.2* )
 828     machine=tahoe opsys=bsd4-2
 829   ;;
 830   tahoe-tahoe-bsd4.3* )
 831     machine=tahoe opsys=bsd4-3
 832   ;;
 833
 834   ## Tandem Integrity S2
 835   mips-tandem-sysv* )
 836     machine=tandem-s2 opsys=usg5-3
 837   ;;
 838
 839   ## Tektronix XD88
 840   m88k-tektronix-sysv3* )
 841   machine=tekxd88 opsys=usg5-3
 842   ;;
 843
 844   ## Tektronix 16000 box (6130?)
 845   ns16k-tektronix-bsd* )
 846     machine=ns16000 opsys=bsd4-2
 847   ;;
 848   ## Tektronix 4300
 849   ## src/m/tek4300.h hints that this is a m68k machine.
 850   m68*-tektronix-bsd* )
 851     machine=tek4300 opsys=bsd4-3
 852   ;;
 853
 854   ## Titan P2 or P3
 855   ## We seem to have lost the machine-description file titan.h!
 856   titan-titan-sysv* )
 857     machine=titan opsys=usg5-3
 858   ;;
 859
 860   ## Ustation E30 (SS5E)
 861   m68*-unisys-uniplus* )
 862     machine=ustation opsystem=unipl5-2
 863   ;;
 864
 865   ## Vaxen.
 866   vax-dec-* )
 867     machine=vax
 868     case "${canonical}" in
 869       *-bsd4.1* )                                       opsys=bsd4-1 ;;
 870       *-bsd4.2* | *-ultrix[0-3].* | *-ultrix4.0* )      opsys=bsd4-2 ;;
 871       *-bsd4.3* | *-ultrix* )                           opsys=bsd4-3 ;;
 872       *-sysv[01]* | *-sysvr[01]* )                      opsys=usg5-0 ;;
 873       *-sysv2* | *-sysvr2* )                            opsys=usg5-2 ;;
 874       *-vms* )                                          opsys=vms ;;
 875       * )                                               unported=yes
 876     esac
 877   ;;
 878
 879   ## Whitechapel MG1
 880   ns16k-whitechapel-* )
 881     machine=mg1
 882     ## We don't know what sort of OS runs on these; we'll let the
 883     ## operating system guessing code below try.
 884   ;;
 885
 886   ## Wicat
 887   m68*-wicat-sysv* )
 888     machine=wicat opsys=usg5-2
 889   ;;
 890
 891   ## Intel 386 machines where we don't care about the manufacturer
 892   i[3456]86-*-* )
 893     machine=intel386
 894     case "${canonical}" in
 895       *-isc1.* | *-isc2.[01]* ) opsys=386-ix ;;
 896       *-isc2.2* )               opsys=isc2-2 ;;
 897       *-isc4.0* )               opsys=isc4-0 ;;
 898       *-isc4.* )                opsys=isc4-1
 899                                 GCC_TEST_OPTIONS=-posix
 900                                 NON_GCC_TEST_OPTIONS=-Xp
 901                                 ;;
 902       *-isc* )                  opsys=isc3-0 ;;
 903       *-esix5* )                opsys=esix5r4; NON_GNU_CPP=/usr/lib/cpp ;;
 904       *-esix* )                 opsys=esix ;;
 905       *-xenix* )                opsys=xenix ;;
 906       *-linux-gnu* )            opsys=gnu-linux ;;
 907       *-sco3.2v4* )             opsys=sco4 ; NON_GNU_CPP=/lib/cpp  ;;
 908       *-sco3.2v5* )             opsys=sco5
 909                                 NON_GNU_CPP=/lib/cpp
 910                                 # Prevent -belf from being passed to $CPP.
 911                                 # /lib/cpp does not accept it.
 912                                 OVERRIDE_CPPFLAGS=" "
 913                                 ;;
 914       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 915       *-386bsd* )               opsys=386bsd ;;
 916       *-freebsd* )              opsys=freebsd ;;
 917       *-nextstep* )             opsys=nextstep ;;
 918       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 919     esac
 920   ;;
 921
 922   ## m68k Linux-based GNU system
 923   m68k-*-linux-gnu* )
 924     machine=m68k opsys=gnu-linux
 925   ;;
 926
 927   ## Mips Linux-based GNU system
 928   mips-*-linux-gnu* )
 929     machine=mips opsys=gnu-linux
 930   ;;
 931
 932   * )
 933     unported=yes
 934   ;;
 935 esac
 936
 937 ### If the code above didn't choose an operating system, just choose
 938 ### an operating system based on the configuration name.  You really
 939 ### only want to use this when you have no idea what the right
 940 ### operating system is; if you know what operating systems a machine
 941 ### runs, it's cleaner to make it explicit in the case statement
 942 ### above.
 943 if test x"${opsys}" = x; then
 944   case "${canonical}" in
 945     *-gnu* )                            opsys=gnu ;;
 946     *-bsd4.[01] )                       opsys=bsd4-1 ;;
 947     *-bsd4.2 )                          opsys=bsd4-2 ;;
 948     *-bsd4.3 )                          opsys=bsd4-3 ;;
 949     *-sysv0 | *-sysvr0 )                opsys=usg5-0 ;;
 950     *-sysv2 | *-sysvr2 )                opsys=usg5-2 ;;
 951     *-sysv2.2 | *-sysvr2.2 )            opsys=usg5-2-2 ;;
 952     *-sysv3* | *-sysvr3* )              opsys=usg5-3 ;;
 953     *-sysv4.2uw* )                      opsys=unixware ;;
 954     *-sysv4.1* | *-sysvr4.1* )
 955         NON_GNU_CPP=/usr/lib/cpp
 956         opsys=usg5-4 ;;
 957     *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
 958         if [ x$NON_GNU_CPP = x ]; then
 959           if [ -f /usr/ccs/lib/cpp ]; then
 960             NON_GNU_CPP=/usr/ccs/lib/cpp
 961           else
 962             NON_GNU_CPP=/lib/cpp
 963           fi
 964         fi
 965         opsys=usg5-4-2 ;;
 966     *-sysv4* | *-sysvr4* )              opsys=usg5-4 ;;
 967     * )
 968       unported=yes
 969     ;;
 970   esac
 971 fi
 972
 973 if test "x$RANLIB" = x; then
 974   RANLIB=ranlib
 975 fi
 976
 977 changequote([, ])dnl
 978
 979 if test $unported = yes; then
 980   AC_MSG_ERROR([Emacs hasn't been ported to \`${canonical}' systems.
 981 Check \`etc/MACHINES' for recognized configuration names.])
 982 fi
 983
 984 machfile="m/${machine}.h"
 985 opsysfile="s/${opsys}.h"
 986
 987
 988 #### Choose a compiler.
 989 test -n "$CC" && cc_specified=yes
 990
 991 # Save the value of CFLAGS that the user specified.
 992 SPECIFIED_CFLAGS="$CFLAGS"
 993
 994 case ${with_gcc} in
 995   "yes" ) CC="gcc" GCC=yes ;;
 996   "no"  ) : ${CC=cc} ;;
 997   * ) AC_PROG_CC
 998 esac
 999
1000 # On Suns, sometimes $CPP names a directory.
1001 if test -n "$CPP" && test -d "$CPP"; then
1002   CPP=
1003 fi
1004
1005 #### Some systems specify a CPP to use unless we are using GCC.
1006 #### Now that we know whether we are using GCC, we can decide whether
1007 #### to use that one.
1008 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
1009 then
1010   CPP="$NON_GNU_CPP"
1011 fi
1012
1013 #### Some systems specify a CC to use unless we are using GCC.
1014 #### Now that we know whether we are using GCC, we can decide whether
1015 #### to use that one.
1016 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
1017   test x$cc_specified != xyes
1018 then
1019   CC="$NON_GNU_CC"
1020 fi
1021
1022 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
1023 then
1024   CC="$CC $GCC_TEST_OPTIONS"
1025 fi
1026
1027 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
1028 then
1029   CC="$CC $NON_GCC_TEST_OPTIONS"
1030 fi
1031
1032 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
1033 then
1034   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1035 fi
1036
1037 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
1038 then
1039   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1040 fi
1041
1042 #### Some other nice autoconf tests.  If you add a test here which
1043 #### should make an entry in src/config.h, don't forget to add an
1044 #### #undef clause to src/config.h.in for autoconf to modify.
1045
1046 dnl checks for programs
1047 AC_PROG_LN_S
1048 AC_PROG_CPP
1049 AC_PROG_INSTALL
1050 AC_PROG_YACC
1051
1052 dnl checks for Unix variants
1053 AC_AIX
1054
1055 dnl checks for header files
1056 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h linux/version.h sys/systeminfo.h termios.h limits.h)
1057 AC_HEADER_STDC
1058 AC_HEADER_TIME
1059 AC_DECL_SYS_SIGLIST
1060
1061 dnl Some systems have utime.h but don't declare the struct anyplace.
1062 AC_MSG_CHECKING(for struct utimbuf)
1063 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1064 #include <sys/time.h>
1065 #include <time.h>
1066 #else
1067 #ifdef HAVE_SYS_TIME_H
1068 #include <sys/time.h>
1069 #else
1070 #include <time.h>
1071 #endif
1072 #endif
1073 #ifdef HAVE_UTIME_H
1074 #include <utime.h>
1075 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1076   [AC_MSG_RESULT(yes)
1077    AC_DEFINE(HAVE_STRUCT_UTIMBUF)],
1078   AC_MSG_RESULT(no))
1079
1080 dnl checks for typedefs
1081 AC_TYPE_SIGNAL
1082
1083 AC_MSG_CHECKING(for struct timeval)
1084 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1085 #include <sys/time.h>
1086 #include <time.h>
1087 #else
1088 #ifdef HAVE_SYS_TIME_H
1089 #include <sys/time.h>
1090 #else
1091 #include <time.h>
1092 #endif
1093 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1094   [AC_MSG_RESULT(yes)
1095    HAVE_TIMEVAL=yes
1096    AC_DEFINE(HAVE_TIMEVAL)],
1097   [AC_MSG_RESULT(no)
1098    HAVE_TIMEVAL=no])
1099
1100 dnl checks for structure members
1101 AC_STRUCT_TM
1102 AC_STRUCT_TIMEZONE
1103
1104 dnl checks for compiler characteristics
1105 AC_C_CONST
1106
1107 dnl check for Make feature
1108 AC_PROG_MAKE_SET
1109
1110 dnl checks for operating system services
1111 AC_SYS_LONG_FILE_NAMES
1112
1113 #### Choose a window system.
1114
1115 AC_PATH_X
1116 if test "$no_x" = yes; then
1117   window_system=none
1118 else
1119   window_system=x11
1120 fi
1121
1122 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1123   LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1124   LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1125 fi
1126 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1127   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1128 fi
1129
1130 if test x"${x_includes}" = x; then
1131   bitmapdir=/usr/include/X11/bitmaps
1132 else
1133   # accumulate include directories that have X11 bitmap subdirectories
1134   bmd_acc="dummyval"
1135   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1136     if test -d "${bmd}/X11/bitmaps"; then
1137       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1138     elif test -d "${bmd}/bitmaps"; then
1139       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1140     fi
1141   done
1142   if test ${bmd_acc} != "dummyval"; then
1143     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1144   fi
1145 fi
1146
1147 case "${window_system}" in
1148   x11 )
1149     HAVE_X_WINDOWS=yes
1150     HAVE_X11=yes
1151     case "${with_x_toolkit}" in
1152       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1153       motif ) USE_X_TOOLKIT=MOTIF ;;
1154 dnl      open-look ) USE_X_TOOLKIT=OPEN_LOOK ;;
1155       no ) USE_X_TOOLKIT=none ;;
1156 dnl If user did not say whether to use a toolkit,
1157 dnl make this decision later: use the toolkit if we have X11R5 or newer.
1158       * ) USE_X_TOOLKIT=maybe ;;
1159     esac
1160   ;;
1161   none )
1162     HAVE_X_WINDOWS=no
1163     HAVE_X11=no
1164     USE_X_TOOLKIT=none
1165   ;;
1166 esac
1167
1168 ### If we're using X11, we should use the X menu package.
1169 HAVE_MENUS=no
1170 case ${HAVE_X11} in
1171   yes ) HAVE_MENUS=yes ;;
1172 esac
1173
1174 if test "${opsys}" = "hpux9"; then
1175   case "${x_libraries}" in
1176     *X11R4* )
1177       opsysfile="s/hpux9-x11r4.h"
1178       ;;
1179   esac
1180 fi
1181
1182 if test "${opsys}" = "hpux9shr"; then
1183   case "${x_libraries}" in
1184     *X11R4* )
1185       opsysfile="s/hpux9shxr4.h"
1186       ;;
1187   esac
1188 fi
1189
1190 #### Extract some information from the operating system and machine files.
1191
1192 AC_CHECKING([the machine- and system-dependent files to find out
1193  - which libraries the lib-src programs will want, and
1194  - whether the GNU malloc routines are usable])
1195
1196 ### First figure out CFLAGS (which we use for running the compiler here)
1197 ### and REAL_CFLAGS (which we use for real compilation).
1198 ### The two are the same except on a few systems, where they are made
1199 ### different to work around various lossages.  For example,
1200 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
1201 ### as implying static linking.
1202
1203 ### If the CFLAGS env var is specified, we use that value
1204 ### instead of the default.
1205
1206 ### It's not important that this name contain the PID; you can't run
1207 ### two configures in the same directory and have anything work
1208 ### anyway.
1209 tempcname="conftest.c"
1210
1211 echo '
1212 #include "'${srcdir}'/src/'${opsysfile}'"
1213 #include "'${srcdir}'/src/'${machfile}'"
1214 #ifndef LIBS_MACHINE
1215 #define LIBS_MACHINE
1216 #endif
1217 #ifndef LIBS_SYSTEM
1218 #define LIBS_SYSTEM
1219 #endif
1220 #ifndef C_SWITCH_SYSTEM
1221 #define C_SWITCH_SYSTEM
1222 #endif
1223 #ifndef C_SWITCH_MACHINE
1224 #define C_SWITCH_MACHINE
1225 #endif
1226 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
1227 configure___ c_switch_system=C_SWITCH_SYSTEM
1228 configure___ c_switch_machine=C_SWITCH_MACHINE
1229
1230 #ifndef LIB_X11_LIB
1231 #define LIB_X11_LIB -lX11
1232 #endif
1233
1234 #ifndef LIBX11_MACHINE
1235 #define LIBX11_MACHINE
1236 #endif
1237
1238 #ifndef LIBX11_SYSTEM
1239 #define LIBX11_SYSTEM
1240 #endif
1241 configure___ LIBX=LIB_X11_LIB LIBX11_MACHINE LIBX11_SYSTEM
1242
1243 #ifdef UNEXEC
1244 configure___ unexec=UNEXEC
1245 #else
1246 configure___ unexec=unexec.o
1247 #endif
1248
1249 #ifdef SYSTEM_MALLOC
1250 configure___ system_malloc=yes
1251 #else
1252 configure___ system_malloc=no
1253 #endif
1254
1255 #ifndef C_DEBUG_SWITCH
1256 #define C_DEBUG_SWITCH -g
1257 #endif
1258
1259 #ifndef C_OPTIMIZE_SWITCH
1260 #define C_OPTIMIZE_SWITCH -O
1261 #endif
1262
1263 #ifndef LD_SWITCH_MACHINE
1264 #define LD_SWITCH_MACHINE
1265 #endif
1266
1267 #ifndef LD_SWITCH_SYSTEM
1268 #define LD_SWITCH_SYSTEM
1269 #endif
1270
1271 #ifndef LD_SWITCH_X_SITE_AUX
1272 #define LD_SWITCH_X_SITE_AUX
1273 #endif
1274
1275 configure___ ld_switch_system=LD_SWITCH_SYSTEM
1276 configure___ ld_switch_machine=LD_SWITCH_MACHINE
1277
1278 #ifdef THIS_IS_CONFIGURE
1279
1280 /* Get the CFLAGS for tests in configure.  */
1281 #ifdef __GNUC__
1282 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1283 #else
1284 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1285 #endif
1286
1287 #else /* not THIS_IS_CONFIGURE */
1288
1289 /* Get the CFLAGS for real compilation.  */
1290 #ifdef __GNUC__
1291 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1292 #else
1293 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1294 #endif
1295
1296 #endif /* not THIS_IS_CONFIGURE */
1297 ' > ${tempcname}
1298
1299 # The value of CPP is a quoted variable reference, so we need to do this
1300 # to get its actual value...
1301 CPP=`eval "echo $CPP"`
1302 changequote(, )dnl
1303 eval `${CPP} -Isrc ${tempcname} \
1304        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1305 if test "x$SPECIFIED_CFLAGS" = x; then
1306   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
1307          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1308 else
1309   REAL_CFLAGS="$CFLAGS"
1310 fi
1311 changequote([, ])dnl
1312 rm ${tempcname}
1313
1314 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
1315
1316 ### Compute the unexec source name from the object name.
1317 UNEXEC_SRC="`echo ${unexec} | sed 's/\.o/.c/'`"
1318
1319 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1320 # Assume not, until told otherwise.
1321 GNU_MALLOC=yes
1322 doug_lea_malloc=yes
1323 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1324 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1325 AC_MSG_CHECKING(whether __after_morecore_hook exists)
1326 AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1327   [AC_MSG_RESULT(yes)],
1328   [AC_MSG_RESULT(no)
1329    doug_lea_malloc=no])
1330 if test "${system_malloc}" = "yes"; then
1331   GNU_MALLOC=no
1332   GNU_MALLOC_reason="
1333     (The GNU allocators don't work with this system configuration.)"
1334 fi
1335 if test "$doug_lea_malloc" = "yes" ; then
1336   if test "$GNU_MALLOC" = yes ; then
1337     GNU_MALLOC_reason="
1338       (Using Doug Lea's new malloc from the GNU C Library.)"
1339   fi
1340   AC_DEFINE(DOUG_LEA_MALLOC)
1341 fi
1342
1343 if test x"${REL_ALLOC}" = x; then
1344   REL_ALLOC=${GNU_MALLOC}
1345 fi
1346
1347 LISP_FLOAT_TYPE=yes
1348
1349
1350 #### Add the libraries to LIBS and check for some functions.
1351
1352 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1353   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1354 else
1355   CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
1356 fi
1357
1358 LIBS="$libsrc_libs $LIBS"
1359
1360 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1361 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1362 AC_CHECK_LIB(dnet, dnet_ntoa)
1363 dnl This causes -lresolv to get used in subsequent tests,
1364 dnl which causes failures on some systems such as HPUX 9.
1365 dnl AC_CHECK_LIB(resolv, gethostbyname)
1366
1367 dnl FIXME replace main with a function we actually want from this library.
1368 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1369
1370 AC_CHECK_LIB(pthreads, cma_open)
1371
1372 AC_MSG_CHECKING(for XFree86)
1373 if test -d /usr/X386/include; then
1374   HAVE_XFREE386=yes
1375   : ${C_SWITCH_X_SITE="-I/usr/X386/include"}
1376 else
1377   HAVE_XFREE386=no
1378 fi
1379 AC_MSG_RESULT($HAVE_XFREE386)
1380
1381 # Change CFLAGS temporarily so that C_SWITCH_X_SITE gets used
1382 # for the tests that follow.  We set it back to REAL_CFLAGS later on.
1383
1384 if test "${HAVE_X11}" = "yes"; then
1385   DEFS="$C_SWITCH_X_SITE $DEFS"
1386   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1387   LIBS="$LIBX $LIBS"
1388   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1389
1390   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1391   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1392   # but it's more convenient here to set LD_RUN_PATH
1393   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1394   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1395     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1396     export LD_RUN_PATH
1397   fi
1398
1399   if test "${opsys}" = "gnu-linux"; then
1400     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1401     AC_TRY_LINK([],
1402      [XOpenDisplay ("foo");],
1403      [xlinux_first_failure=no],
1404      [xlinux_first_failure=yes])
1405     if test "${xlinux_first_failure}" = "yes"; then
1406       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1407       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1408       OLD_CPPFLAGS="$CPPFLAGS"
1409       OLD_LIBS="$LIBS"
1410       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1411       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1412       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1413       LIBS="$LIBS -b i486-linuxaout"
1414       AC_TRY_LINK([],
1415        [XOpenDisplay ("foo");],
1416        [xlinux_second_failure=no],
1417        [xlinux_second_failure=yes])
1418       if test "${xlinux_second_failure}" = "yes"; then
1419         # If we get the same failure with -b, there is no use adding -b.
1420         # So take it out.  This plays safe.
1421         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1422         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1423         CPPFLAGS="$OLD_CPPFLAGS"
1424         LIBS="$OLD_LIBS"
1425         AC_MSG_RESULT(no)
1426       else
1427         AC_MSG_RESULT(yes)
1428       fi
1429     else
1430       AC_MSG_RESULT(no)
1431     fi
1432   fi
1433
1434   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1435 XScreenNumberOfScreen XSetWMProtocols)
1436 fi
1437
1438 if test "${window_system}" = "x11"; then
1439   AC_MSG_CHECKING(X11 version 6)
1440   AC_TRY_LINK([#include <X11/Xlib.h>],
1441 [#if XlibSpecificationRelease < 6
1442 fail;
1443 #endif
1444 ], [AC_MSG_RESULT(6 or newer)
1445     AC_DEFINE(HAVE_X11R6)],
1446    [AC_MSG_RESULT(before 6)])
1447 fi
1448
1449 if test "${window_system}" = "x11"; then
1450   AC_MSG_CHECKING(X11 version 5)
1451   AC_TRY_LINK([#include <X11/Xlib.h>],
1452 [#if XlibSpecificationRelease < 5
1453 fail;
1454 #endif
1455 ], [AC_MSG_RESULT(5 or newer)
1456     HAVE_X11R5=yes
1457     AC_DEFINE(HAVE_X11R5)],
1458    [
1459     HAVE_X11R5=no
1460     AC_MSG_RESULT(before 5)])
1461 fi
1462
1463 dnl Do not put whitespace before the #include statements below.
1464 dnl Older compilers (eg sunos4 cc) choke on it.
1465 if test x"${USE_X_TOOLKIT}" = xmaybe; then
1466   if test x"${HAVE_X11R5}" = xyes; then
1467     AC_MSG_CHECKING(X11 version 5 with Xaw)
1468     AC_TRY_LINK([
1469 #include <X11/Intrinsic.h>
1470 #include <X11/Xaw/Simple.h>],
1471       [],
1472       [AC_MSG_RESULT(5 or newer, with Xaw; use toolkit by default)
1473        USE_X_TOOLKIT=LUCID],
1474       [AC_MSG_RESULT(before 5 or no Xaw; do not use toolkit by default)
1475        USE_X_TOOLKIT=none])
1476   else
1477     USE_X_TOOLKIT=none
1478   fi
1479 fi
1480
1481 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1482
1483 if test "${USE_X_TOOLKIT}" != "none"; then
1484   AC_MSG_CHECKING(X11 toolkit version)
1485   AC_TRY_LINK([#include <X11/Intrinsic.h>],
1486 [#if XtSpecificationRelease < 6
1487 fail;
1488 #endif
1489 ], [AC_MSG_RESULT(6 or newer)
1490     HAVE_X11XTR6=yes
1491     AC_DEFINE(HAVE_X11XTR6)],
1492    [AC_MSG_RESULT(before 6)
1493     HAVE_X11XTR6=no])
1494
1495 dnl If using toolkit, check whether libXmu.a exists.
1496 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1497   OLDLIBS="$LIBS"
1498   if test x$HAVE_X11XTR6 = xyes; then
1499     LIBS="-lXt -lSM -lICE $LIBS"
1500   else
1501     LIBS="-lXt $LIBS"
1502   fi
1503   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1504   LIBS="$OLDLIBS"
1505 fi
1506
1507 # If netdb.h doesn't declare h_errno, we must declare it by hand.
1508 AC_MSG_CHECKING(whether netdb declares h_errno)
1509 AC_TRY_LINK([#include <netdb.h>],
1510   [return h_errno;],
1511   [AC_MSG_RESULT(yes)
1512    AC_DEFINE(HAVE_H_ERRNO)],
1513   [AC_MSG_RESULT(no)])
1514
1515 AC_FUNC_ALLOCA
1516
1517 # fmod, logb, and frexp are found in -lm on most systems.
1518 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
1519 AC_CHECK_LIB(m, sqrt)
1520
1521 # Check for mail-locking functions in a "mail" library
1522 AC_CHECK_LIB(mail, maillock,
1523              AC_DEFINE(HAVE_LIBMAIL)
1524              AC_CHECK_FUNCS(touchlock)
1525              AC_CHECK_HEADERS(maillock.h))
1526
1527 AC_CHECK_FUNCS(gettimeofday gethostname getdomainname dup2 \
1528 rename closedir mkdir rmdir sysinfo \
1529 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime res_init setsid \
1530 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
1531 utimes setrlimit setpgid getcwd shutdown)
1532
1533 # Check this now, so that we will NOT find the above functions in ncurses.
1534 # That is because we have not set up to link ncurses in lib-src.
1535 # It's better to believe a function is not available
1536 # than to expect to find it in ncurses.
1537 AC_CHECK_LIB(ncurses, tparm)
1538
1539 # These tell us which Kerberos-related libraries to use.
1540 if test "${with_kerberos+set}" = set; then
1541   AC_CHECK_LIB(krb, krb_get_cred)
1542   AC_CHECK_LIB(des, des_cbc_encrypt)
1543   AC_CHECK_LIB(com_err, com_err)
1544 fi
1545
1546 AC_MSG_CHECKING(whether localtime caches TZ)
1547 AC_CACHE_VAL(emacs_cv_localtime_cache,
1548 [if test x$ac_cv_func_tzset = xyes; then
1549 AC_TRY_RUN([#include <time.h>
1550 #if STDC_HEADERS
1551 # include <stdlib.h>
1552 #endif
1553 extern char **environ;
1554 unset_TZ ()
1555 {
1556   char **from, **to;
1557   for (to = from = environ; (*to = *from); from++)
1558     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
1559       to++;
1560 }
1561 char TZ_GMT0[] = "TZ=GMT0";
1562 char TZ_PST8[] = "TZ=PST8";
1563 main()
1564 {
1565   time_t now = time ((time_t *) 0);
1566   int hour_GMT0, hour_unset;
1567   if (putenv (TZ_GMT0) != 0)
1568     exit (1);
1569   hour_GMT0 = localtime (&now)->tm_hour;
1570   unset_TZ ();
1571   hour_unset = localtime (&now)->tm_hour;
1572   if (putenv (TZ_PST8) != 0)
1573     exit (1);
1574   if (localtime (&now)->tm_hour == hour_GMT0)
1575     exit (1);
1576   unset_TZ ();
1577   if (localtime (&now)->tm_hour != hour_unset)
1578     exit (1);
1579   exit (0);
1580 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
1581 [# If we have tzset, assume the worst when cross-compiling.
1582 emacs_cv_localtime_cache=yes])
1583 else
1584         # If we lack tzset, report that localtime does not cache TZ,
1585         # since we can't invalidate the cache if we don't have tzset.
1586         emacs_cv_localtime_cache=no
1587 fi])dnl
1588 AC_MSG_RESULT($emacs_cv_localtime_cache)
1589 if test $emacs_cv_localtime_cache = yes; then
1590   AC_DEFINE(LOCALTIME_CACHE)
1591 fi
1592
1593 if test "x$HAVE_TIMEVAL" = xyes; then
1594 AC_MSG_CHECKING(whether gettimeofday can't accept two arguments)
1595 AC_TRY_LINK([
1596 #ifdef TIME_WITH_SYS_TIME
1597 #include <sys/time.h>
1598 #include <time.h>
1599 #else
1600 #ifdef HAVE_SYS_TIME_H
1601 #include <sys/time.h>
1602 #else
1603 #include <time.h>
1604 #endif
1605 #endif
1606   ],
1607   [
1608   struct timeval time;
1609   struct timezone dummy;
1610   gettimeofday (&time, &dummy);
1611 ],
1612   [AC_MSG_RESULT(no)],
1613   [AC_MSG_RESULT(yes)
1614    AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT)])
1615 fi
1616
1617 ok_so_far=yes
1618 AC_CHECK_FUNC(socket, , ok_so_far=no)
1619 if test $ok_so_far = yes; then
1620   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
1621 fi
1622 if test $ok_so_far = yes; then
1623   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
1624 fi
1625 if test $ok_so_far = yes; then
1626   AC_DEFINE(HAVE_INET_SOCKETS)
1627 fi
1628
1629 if test -f /usr/lpp/X11/bin/smt.exp; then
1630   AC_DEFINE(HAVE_AIX_SMT_EXP)
1631 fi
1632
1633 # Set up the CFLAGS for real compilation, so we can substitute it.
1634 CFLAGS="$REAL_CFLAGS"
1635
1636 changequote(, )dnl
1637 #### Find out which version of Emacs this is.
1638 version=`grep 'defconst[         ]*emacs-version' ${srcdir}/lisp/version.el \
1639          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`
1640 changequote([, ])dnl
1641 if test x"${version}" = x; then
1642   AC_MSG_ERROR(can't find current emacs version in \`${srcdir}/lisp/version.el'.)
1643 fi
1644
1645 ### Specify what sort of things we'll be editing into Makefile and config.h.
1646 ### Use configuration here uncanonicalized to avoid exceeding size limits.
1647 AC_SUBST(version)
1648 AC_SUBST(configuration)
1649 AC_SUBST(canonical)
1650 AC_SUBST(srcdir)
1651 AC_SUBST(prefix)
1652 AC_SUBST(exec_prefix)
1653 AC_SUBST(bindir)
1654 AC_SUBST(datadir)
1655 AC_SUBST(sharedstatedir)
1656 AC_SUBST(libexecdir)
1657 AC_SUBST(mandir)
1658 AC_SUBST(infodir)
1659 AC_SUBST(lispdir)
1660 AC_SUBST(locallisppath)
1661 AC_SUBST(lisppath)
1662 AC_SUBST(etcdir)
1663 AC_SUBST(lockdir)
1664 AC_SUBST(archlibdir)
1665 AC_SUBST(docdir)
1666 AC_SUBST(bitmapdir)
1667 AC_SUBST(c_switch_system)
1668 AC_SUBST(c_switch_machine)
1669 AC_SUBST(LD_SWITCH_X_SITE)
1670 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1671 AC_SUBST(C_SWITCH_X_SITE)
1672 AC_SUBST(CFLAGS)
1673 AC_SUBST(X_TOOLKIT_TYPE)
1674 AC_SUBST(machfile)
1675 AC_SUBST(opsysfile)
1676 AC_SUBST(RANLIB)
1677
1678 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}")
1679 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}")
1680 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}")
1681 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}")
1682 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE})
1683 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX})
1684 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE})
1685 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC})
1686
1687 if test "${HAVE_X_WINDOWS}" = "yes" ; then
1688   AC_DEFINE(HAVE_X_WINDOWS)
1689 fi
1690 if test "${USE_X_TOOLKIT}" != "none" ; then
1691   AC_DEFINE(USE_X_TOOLKIT)
1692 fi
1693 if test "${HAVE_X11}" = "yes" ; then
1694   AC_DEFINE(HAVE_X11)
1695 fi
1696 if test "${HAVE_XFREE386}" = "yes" ; then
1697   AC_DEFINE(HAVE_XFREE386)
1698 fi
1699 if test "${HAVE_MENUS}" = "yes" ; then
1700   AC_DEFINE(HAVE_MENUS)
1701 fi
1702 if test "${GNU_MALLOC}" = "yes" ; then
1703   AC_DEFINE(GNU_MALLOC)
1704 fi
1705 if test "${REL_ALLOC}" = "yes" ; then
1706   AC_DEFINE(REL_ALLOC)
1707 fi
1708 if test "${LISP_FLOAT_TYPE}" = "yes" ; then
1709   AC_DEFINE(LISP_FLOAT_TYPE)
1710 fi
1711
1712 #### Report on what we decided to do.
1713 echo "
1714 Configured for \`${canonical}'.
1715
1716   Where should the build process find the source code?    ${srcdir}
1717   What operating system and machine description files should Emacs use?
1718         \`${opsysfile}' and \`${machfile}'
1719   What compiler should emacs be built with?               ${CC} ${CFLAGS}
1720   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
1721   Should Emacs use the relocating allocator for buffers?  ${REL_ALLOC}
1722   What window system should Emacs use?                    ${window_system}
1723   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
1724
1725 if test -n "${x_includes}"; then
1726 echo "  Where do we find X Windows header files?                ${x_includes}"
1727 else
1728 echo "  Where do we find X Windows header files?                Standard dirs"
1729 fi
1730 if test -n "${x_libraries}"; then
1731 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
1732 else
1733 echo "  Where do we find X Windows libraries?                   Standard dirs"
1734 fi
1735
1736 echo
1737
1738 # Remove any trailing slashes in these variables.
1739 changequote(, )dnl
1740 test "${prefix}" != NONE &&
1741   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
1742 test "${exec_prefix}" != NONE &&
1743   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`
1744 changequote([, ])dnl
1745
1746 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
1747         man/Makefile lwlib/Makefile src/Makefile.c:src/Makefile.in \
1748         leim/Makefile, [
1749
1750 ### Make the necessary directories, if they don't exist.
1751 for dir in cpp etc lisp ; do
1752   test -d ${dir} || mkdir ${dir}
1753 done
1754
1755 # Build src/Makefile from ${srcdir}/src/Makefile.c
1756 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
1757 # This must be done after src/config.h is built, since we rely on that file.
1758
1759 changequote(, )dnl The horror, the horror.
1760 # Now get this: Some word that is part of the ${srcdir} directory name
1761 # or the ${configuration} value might, just might, happen to be an
1762 # identifier like `sun4' or `i386' or something, and be predefined by
1763 # the C preprocessor to some helpful value like 1, or maybe the empty
1764 # string.  Needless to say consequent macro substitutions are less
1765 # than conducive to the makefile finding the correct directory.
1766 undefs="`echo $top_srcdir $configuration $canonical |
1767 sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
1768     -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g' \
1769 `"
1770 changequote([, ])dnl
1771
1772 echo creating src/paths.h
1773 make paths-force
1774
1775 echo creating lib-src/Makefile
1776 ( cd lib-src
1777   rm -f junk.c junk1.c junk2.c
1778   sed -e '/start of cpp stuff/q' \
1779       < Makefile.c > junk1.c
1780   sed -e '1,/start of cpp stuff/d'\
1781       -e 's@/\*\*/#\(.*\)$@/* \1 */@' \
1782       < Makefile.c > junk.c
1783   $CPP $undefs -I. -I$top_srcdir/src $CPPFLAGS junk.c | \
1784       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
1785   cat junk1.c junk2.c > Makefile.new
1786   rm -f junk.c junk1.c junk2.c
1787   chmod 444 Makefile.new
1788   mv -f Makefile.new Makefile
1789 )
1790
1791 echo creating src/Makefile
1792 ( cd src
1793   rm -f junk.c junk1.c junk2.c
1794   sed -e '/start of cpp stuff/q' \
1795       < Makefile.c > junk1.c
1796   sed -e '1,/start of cpp stuff/d'\
1797       -e 's@/\*\*/#\(.*\)$@/* \1 */@' \
1798       < Makefile.c > junk.c
1799   $CPP $undefs -I. -I$top_srcdir/src $CPPFLAGS junk.c | \
1800       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
1801   cat junk1.c junk2.c > Makefile.new
1802   rm -f junk.c junk1.c junk2.c
1803   chmod 444 Makefile.new
1804   mv -f Makefile.new Makefile
1805 )
1806
1807 if test ! -f src/.gdbinit && test -f $top_srcdir/src/.gdbinit; then
1808   echo creating src/.gdbinit
1809   echo source $top_srcdir/src/.gdbinit > src/.gdbinit
1810 fi
1811
1812 # This is how we know whether to re-run configure in certain cases.
1813 touch src/config.stamp
1814
1815 ], [CPP="$CPP" CPPFLAGS="$CPPFLAGS"])