code.delx.au - gnu-emacs/blob - configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2012 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.1.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28 AC_CONFIG_AUX_DIR(build-aux)
  29 AM_INIT_AUTOMAKE
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 dnl It is important that variables on the RHS not be expanded here,
  36 dnl hence the single quotes.  This is per the GNU coding standards, see
  37 dnl (autoconf) Installation Directory Variables
  38 dnl See also epaths.h below.
  39 lispdir='${datadir}/emacs/${version}/lisp'
  40 leimdir='${datadir}/emacs/${version}/leim'
  41 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  42 '${datadir}/emacs/site-lisp'
  43 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  44 etcdir='${datadir}/emacs/${version}/etc'
  45 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  46 docdir='${datadir}/emacs/${version}/etc'
  47 gamedir='${localstatedir}/games/emacs'
  48
  49 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  50 dnl Create a new --with option that defaults to being disabled.
  51 dnl NAME is the base name of the option.  The shell variable with_NAME
  52 dnl   will be set to either the user's value (if the option is
  53 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  54 dnl   option is not specified).  Note that the shell variable name is
  55 dnl   constructed as autoconf does, by replacing non-alphanumeric
  56 dnl   characters with "_".
  57 dnl HELP-STRING is the help text for the option.
  58 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  59   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  60     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  61 ])dnl
  62
  63 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  64 dnl Create a new --with option that defaults to being enabled.  NAME
  65 dnl   is the base name of the option.  The shell variable with_NAME
  66 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  67 dnl   'yes' (if the option is not specified).  Note that the shell
  68 dnl   variable name is constructed as autoconf does, by replacing
  69 dnl   non-alphanumeric characters with "_".
  70 dnl HELP-STRING is the help text for the option.
  71 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  72   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  73    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  74 ])dnl
  75
  76 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  77 if test "$with_pop" = yes; then
  78    AC_DEFINE(MAIL_USE_POP)
  79 fi
  80 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  81
  82 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  83 if test "$with_kerberos" != no; then
  84    AC_DEFINE(KERBEROS)
  85 fi
  86 AH_TEMPLATE(KERBEROS,
  87             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  88
  89 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  90 if test "${with_kerberos5}" != no; then
  91   if test "${with_kerberos}" = no; then
  92     with_kerberos=yes
  93     AC_DEFINE(KERBEROS)
  94   fi
  95   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  96 fi
  97
  98 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  99 dnl FIXME hesiod support may not be present, so it seems like an error
 100 dnl to define, or at least use, this unconditionally.
 101 if test "$with_hesiod" != no; then
 102   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 103 fi
 104
 105 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 106 if test "$with_mmdf" != no; then
 107    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 108 fi
 109
 110 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 111 if test "$with_mail_unlink" != no; then
 112    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 113 fi
 114
 115 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 116     [string giving default POP mail host])],
 117     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 118
 119 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 120
 121 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 122 if test "$with_sync_input" = yes; then
 123    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 124 fi
 125
 126 dnl FIXME currently it is not the last.
 127 dnl This should be the last --with option, because --with-x is
 128 dnl added later on when we find the path of X, and it's best to
 129 dnl keep them together visually.
 130 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 131  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 132 [         case "${withval}" in
 133             y | ye | yes )      val=gtk ;;
 134             n | no )            val=no  ;;
 135             l | lu | luc | luci | lucid )       val=lucid ;;
 136             a | at | ath | athe | athen | athena )      val=athena ;;
 137             m | mo | mot | moti | motif )       val=motif ;;
 138             g | gt | gtk  )     val=gtk ;;
 139             gtk3  )     val=gtk3 ;;
 140             * )
 141 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 142 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 143 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 144             ;;
 145           esac
 146           with_x_toolkit=$val
 147 ])
 148
 149 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 150 if test "$with_wide_int" = yes; then
 151   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 152 fi
 153
 154 dnl _ON results in a '--without' option in the --help output, so
 155 dnl the help text should refer to "don't compile", etc.
 156 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 157 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 158 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 159 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 160 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 161 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 162 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 163 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 164
 165 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 166 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 167 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 168
 169 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 170 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 171 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 172 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 173
 174 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 175 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 176 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 177 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 178 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 179 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 180
 181 ## For the times when you want to build Emacs but don't have
 182 ## a suitable makeinfo, and can live without the manuals.
 183 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 184 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 185
 186 ## Makefile.in needs the cache file name.
 187 AC_SUBST(cache_file)
 188
 189 ## This is an option because I do not know if all info/man support
 190 ## compressed files, nor how to test if they do so.
 191 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 192 if test $with_compress_info = yes; then
 193    GZIP_INFO=yes
 194 else
 195    GZIP_INFO=
 196 fi
 197 AC_SUBST(GZIP_INFO)
 198
 199 AC_ARG_WITH([pkg-config-prog],dnl
 200 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 201                   [path to pkg-config for finding GTK and librsvg])])
 202 if test "X${with_pkg_config_prog}" != X; then
 203    if test "${with_pkg_config_prog}" != yes; then
 204       PKG_CONFIG="${with_pkg_config_prog}"
 205    fi
 206 fi
 207
 208 CRT_DIR=
 209 AC_ARG_WITH([crt-dir],dnl
 210 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 211 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 212 CRT_DIR="${with_crt_dir}"
 213
 214 AC_ARG_WITH(gameuser,dnl
 215 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 216 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 217   && gameuser="${with_gameuser}"
 218 test "X$gameuser" = X && gameuser=games
 219
 220 AC_ARG_WITH([gnustep-conf],dnl
 221 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 222 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 223   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 224 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 225      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 226
 227 AC_ARG_ENABLE(ns-self-contained,
 228 [AS_HELP_STRING([--disable-ns-self-contained],
 229                 [disable self contained build under NeXTstep])],
 230    EN_NS_SELF_CONTAINED=$enableval,
 231    EN_NS_SELF_CONTAINED=yes)
 232
 233 AC_ARG_ENABLE(asserts,
 234 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 235       USE_XASSERTS=$enableval,
 236       USE_XASSERTS=no)
 237
 238 AC_ARG_ENABLE(maintainer-mode,
 239 [AS_HELP_STRING([--disable-maintainer-mode],
 240                 [disable make rules and dependencies not useful (and sometimes
 241                  confusing) to the casual installer])],
 242       USE_MAINTAINER_MODE=$enableval,
 243       USE_MAINTAINER_MODE=yes)
 244 if test $USE_MAINTAINER_MODE = yes; then
 245   MAINT=
 246 else
 247   MAINT=#
 248 fi
 249 AC_SUBST(MAINT)
 250
 251 AC_ARG_ENABLE(locallisppath,
 252 [AS_HELP_STRING([--enable-locallisppath=PATH],
 253                 [directories Emacs should search for lisp files specific
 254                  to this site])],
 255 if test "${enableval}" = "no"; then
 256   locallisppath=
 257 elif test "${enableval}" != "yes"; then
 258   locallisppath=${enableval}
 259 fi)
 260
 261 AC_ARG_ENABLE(checking,
 262 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 263                 [enable expensive run-time checks.  With LIST,
 264                  enable only specific categories of checks.
 265                  Categories are: all,yes,no.
 266                  Flags are: stringbytes, stringoverrun, stringfreelist,
 267                  xmallocoverrun, conslist])],
 268 [ac_checking_flags="${enableval}"],[])
 269 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 270 for check in $ac_checking_flags
 271 do
 272         case $check in
 273         # these set all the flags to specific states
 274         yes)            ac_enable_checking=1 ;;
 275         no)             ac_enable_checking= ;
 276                         ac_gc_check_stringbytes= ;
 277                         ac_gc_check_string_overrun= ;
 278                         ac_gc_check_string_free_list= ;
 279                         ac_xmalloc_overrun= ;
 280                         ac_gc_check_cons_list= ;;
 281         all)            ac_enable_checking=1 ;
 282                         ac_gc_check_stringbytes=1 ;
 283                         ac_gc_check_string_overrun=1 ;
 284                         ac_gc_check_string_free_list=1 ;
 285                         ac_xmalloc_overrun=1 ;
 286                         ac_gc_check_cons_list=1 ;;
 287         # these enable particular checks
 288         stringbytes)    ac_gc_check_stringbytes=1 ;;
 289         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 290         stringfreelist) ac_gc_check_string_free_list=1 ;;
 291         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 292         conslist)       ac_gc_check_cons_list=1 ;;
 293         *)      AC_MSG_ERROR(unknown check category $check) ;;
 294         esac
 295 done
 296 IFS="$ac_save_IFS"
 297
 298 if test x$ac_enable_checking != x ; then
 299   AC_DEFINE(ENABLE_CHECKING, 1,
 300 [Enable expensive run-time checking of data types?])
 301 fi
 302 if test x$ac_gc_check_stringbytes != x ; then
 303   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 304 [Define this temporarily to hunt a bug.  If defined, the size of
 305    strings is redundantly recorded in sdata structures so that it can
 306    be compared to the sizes recorded in Lisp strings.])
 307 fi
 308 if test x$ac_gc_check_string_overrun != x ; then
 309   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 310 [Define this to check for short string overrun.])
 311 fi
 312 if test x$ac_gc_check_string_free_list != x ; then
 313   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 314 [Define this to check the string free list.])
 315 fi
 316 if test x$ac_xmalloc_overrun != x ; then
 317   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 318 [Define this to check for malloc buffer overrun.])
 319 fi
 320 if test x$ac_gc_check_cons_list != x ; then
 321   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 322 [Define this to check for errors in cons list.])
 323 fi
 324
 325 AC_ARG_ENABLE(use-lisp-union-type,
 326 [AS_HELP_STRING([--enable-use-lisp-union-type],
 327                 [use a union for the Lisp_Object data type.
 328                 This is only useful for development for catching certain types of bugs.])],
 329 if test "${enableval}" != "no"; then
 330    AC_DEFINE(USE_LISP_UNION_TYPE, 1,
 331    [Define this to use a lisp union for the Lisp_Object data type.])
 332 fi)
 333
 334
 335 AC_ARG_ENABLE(profiling,
 336 [AS_HELP_STRING([--enable-profiling],
 337                 [build emacs with profiling support.
 338                  This might not work on all platforms])],
 339 [ac_enable_profiling="${enableval}"],[])
 340 if test x$ac_enable_profiling != x ; then
 341    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 342 else
 343    PROFILING_CFLAGS=
 344 fi
 345 AC_SUBST(PROFILING_CFLAGS)
 346
 347 AC_ARG_ENABLE(autodepend,
 348 [AS_HELP_STRING([--enable-autodepend],
 349                 [automatically generate dependencies to .h-files.
 350                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 351                  found])],
 352 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 353
 354 #### Make srcdir absolute, if it isn't already.  It's important to
 355 #### avoid running the path through pwd unnecessarily, since pwd can
 356 #### give you automounter prefixes, which can go away.  We do all this
 357 #### so Emacs can find its files when run uninstalled.
 358 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 359 unset CDPATH
 360 case "${srcdir}" in
 361   /* ) ;;
 362   . )
 363     ## We may be able to use the $PWD environment variable to make this
 364     ## absolute.  But sometimes PWD is inaccurate.
 365     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 366     ## but that tested only for a well-formed and valid PWD,
 367     ## it did not object when PWD was well-formed and valid but just wrong.
 368     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 369     then
 370       srcdir="$PWD"
 371     else
 372       srcdir="`(cd ${srcdir}; pwd)`"
 373     fi
 374   ;;
 375   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 376 esac
 377
 378 #### Given the configuration name, set opsysfile to the
 379 #### name of s/*.h file we should use.
 380
 381 ### Canonicalize the configuration name.
 382
 383 AC_CANONICAL_HOST
 384 canonical=$host
 385 configuration=${host_alias-${build_alias-$host}}
 386
 387 dnl This used to use changequote, but, apart from `changequote is evil'
 388 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 389 dnl the great gob of text.  Thus it's not processed for possible expansion.
 390 dnl Just make sure the brackets remain balanced.
 391 dnl
 392 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 393 dnl indicated by comments.
 394 dnl quotation begins
 395 [
 396
 397 ### If you add support for a new configuration, add code to this
 398 ### switch statement to recognize your configuration name and select
 399 ### the appropriate operating system file.
 400
 401 ### You would hope that you could choose an s/*.h
 402 ### file based on the operating system portion.  However, it turns out
 403 ### that each s/*.h file is pretty manufacturer-specific.
 404 ### So we basically have to have a special case for each
 405 ### configuration name.
 406 ###
 407 ### As far as handling version numbers on operating systems is
 408 ### concerned, make sure things will fail in a fixable way.  If
 409 ### /etc/MACHINES doesn't say anything about version numbers, be
 410 ### prepared to handle anything reasonably.  If version numbers
 411 ### matter, be sure /etc/MACHINES says something about it.
 412
 413 opsys='' unported=no
 414 case "${canonical}" in
 415
 416   ## GNU/Linux and similar ports
 417   *-*-linux* )
 418     opsys=gnu-linux
 419   ;;
 420
 421   ## FreeBSD ports
 422   *-*-freebsd* )
 423     opsys=freebsd
 424   ;;
 425
 426   ## FreeBSD kernel + glibc based userland
 427   *-*-kfreebsd*gnu* )
 428     opsys=gnu-kfreebsd
 429   ;;
 430
 431   ## NetBSD ports
 432   *-*-netbsd* )
 433     opsys=netbsd
 434   ;;
 435
 436   ## OpenBSD ports
 437   *-*-openbsd* )
 438     opsys=openbsd
 439   ;;
 440
 441   ## Apple Darwin / Mac OS X
 442   *-apple-darwin* )
 443     case "${canonical}" in
 444       i[3456]86-* )  ;;
 445       powerpc-* )    ;;
 446       x86_64-* )     ;;
 447       * )            unported=yes ;;
 448     esac
 449     opsys=darwin
 450     ## Use fink packages if available.
 451     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 452 ##    if test -d /sw/include && test -d /sw/lib; then
 453 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 454 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 455 ##    fi
 456   ;;
 457
 458   ## HP 9000 series 700 and 800, running HP/UX
 459   hppa*-hp-hpux10.2* )
 460     opsys=hpux10-20
 461   ;;
 462   hppa*-hp-hpux1[1-9]* )
 463     opsys=hpux11
 464     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 465   ;;
 466
 467   ## IBM machines
 468   rs6000-ibm-aix4.[23]* )
 469     opsys=aix4-2
 470   ;;
 471   powerpc-ibm-aix4.[23]*  )
 472     opsys=aix4-2
 473   ;;
 474   rs6000-ibm-aix[56]* )
 475     opsys=aix4-2
 476   ;;
 477   powerpc-ibm-aix[56]*  )
 478     opsys=aix4-2
 479   ;;
 480
 481   ## Silicon Graphics machines
 482   ## Iris 4D
 483   mips-sgi-irix6.5 )
 484     opsys=irix6-5
 485     # Without defining _LANGUAGE_C, things get masked out in the headers
 486     # so that, for instance, grepping for `free' in stdlib.h fails and
 487     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 488     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 489   ;;
 490
 491   ## Suns
 492   *-sun-solaris* \
 493     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 494     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 495     case "${canonical}" in
 496       i[3456]86-*-* )   ;;
 497       amd64-*-*|x86_64-*-*) ;;
 498       sparc* )          ;;
 499       * )               unported=yes ;;
 500     esac
 501     case "${canonical}" in
 502       *-sunos5.6* | *-solaris2.6* )
 503                 opsys=sol2-6
 504                 RANLIB="ar -ts"
 505                 ;;
 506       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 507                 opsys=sol2-6
 508                 emacs_check_sunpro_c=yes
 509                 ;;
 510       *-sunos5* | *-solaris* )
 511                 opsys=sol2-10
 512                 emacs_check_sunpro_c=yes
 513                 ;;
 514     esac
 515     ## Watch out for a compiler that we know will not work.
 516     case "${canonical}" in
 517      *-solaris* | *-sunos5* )
 518                 if [ "x$CC" = x/usr/ucb/cc ]; then
 519                   ## /usr/ucb/cc doesn't work;
 520                   ## we should find some other compiler that does work.
 521                   unset CC
 522                 fi
 523                 ;;
 524       *) ;;
 525     esac
 526   ;;
 527
 528   ## Intel 386 machines where we don't care about the manufacturer.
 529   i[3456]86-*-* )
 530     case "${canonical}" in
 531       *-cygwin )                opsys=cygwin ;;
 532       *-darwin* )               opsys=darwin ;;
 533       *-sysv4.2uw* )            opsys=unixware ;;
 534       *-sysv5uw* )              opsys=unixware ;;
 535       *-sysv5OpenUNIX* )        opsys=unixware ;;
 536       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 537     esac
 538   ;;
 539
 540   * )
 541     unported=yes
 542   ;;
 543 esac
 544
 545 ### If the code above didn't choose an operating system, just choose
 546 ### an operating system based on the configuration name.  You really
 547 ### only want to use this when you have no idea what the right
 548 ### operating system is; if you know what operating systems a machine
 549 ### runs, it's cleaner to make it explicit in the case statement
 550 ### above.
 551 if test x"${opsys}" = x; then
 552   case "${canonical}" in
 553     *-gnu* )                            opsys=gnu ;;
 554     * )
 555       unported=yes
 556     ;;
 557   esac
 558 fi
 559
 560 ]
 561 dnl quotation ends
 562
 563 if test $unported = yes; then
 564   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 565 Check `etc/MACHINES' for recognized configuration names.])
 566 fi
 567
 568 opsysfile="s/${opsys}.h"
 569
 570
 571 #### Choose a compiler.
 572
 573 dnl Sets GCC=yes if using gcc.
 574 AC_PROG_CC
 575 AM_PROG_CC_C_O
 576
 577 if test x$GCC = xyes; then
 578   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 579 else
 580   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 581 fi
 582
 583 # Initialize gnulib right after choosing the compiler.
 584 gl_EARLY
 585
 586 AC_ARG_ENABLE([gcc-warnings],
 587   [AS_HELP_STRING([--enable-gcc-warnings],
 588                   [turn on lots of GCC warnings (for developers)])],
 589   [case $enableval in
 590      yes|no) ;;
 591      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 592    esac
 593    gl_gcc_warnings=$enableval],
 594   [gl_gcc_warnings=no]
 595 )
 596
 597 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 598 # ------------------------------------------------
 599 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 600 # Otherwise, run RUN-IF-NOT-FOUND.
 601 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 602   [AC_PREPROC_IFELSE(
 603     [AC_LANG_PROGRAM(
 604       [[
 605 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 606 /* ok */
 607 #else
 608 # error "your version of gcc is older than $1.$2"
 609 #endif
 610       ]]),
 611     ], [$3], [$4])
 612   ]
 613 )
 614
 615 # When compiling with GCC, prefer -isystem to -I when including system
 616 # include files, to avoid generating useless diagnostics for the files.
 617 if test "$gl_gcc_warnings" != yes; then
 618   isystem='-I'
 619 else
 620   isystem='-isystem '
 621
 622   # This, $nw, is the list of warnings we disable.
 623   nw=
 624
 625   case $with_x_toolkit in
 626     lucid | athena | motif)
 627        # Old toolkits mishandle 'const'.
 628        nw="$nw -Wwrite-strings"
 629        ;;
 630     *)
 631        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 632        ;;
 633   esac
 634   AC_SUBST([WERROR_CFLAGS])
 635
 636   nw="$nw -Waggregate-return"       # anachronistic
 637   nw="$nw -Wlong-long"              # C90 is anachronistic
 638   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
 639   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 640   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 641   nw="$nw -Wcast-qual"              # Too many warnings for now
 642   nw="$nw -Wconversion"             # Too many warnings for now
 643   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 644   nw="$nw -Wsign-conversion"        # Too many warnings for now
 645   nw="$nw -Woverlength-strings"     # Not a problem these days
 646   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 647   nw="$nw -Wpadded"                 # Our structs are not padded
 648   nw="$nw -Wredundant-decls"        # We regularly (re)declare getenv etc.
 649   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 650   nw="$nw -Wformat-nonliteral"      # Emacs does this a lot
 651   nw="$nw -Wvla"                    # warnings in gettext.h
 652   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 653   nw="$nw -Wswitch-enum"            # Too many warnings for now
 654   nw="$nw -Wswitch-default"         # Too many warnings for now
 655   nw="$nw -Wfloat-equal"            # e.g., ftoastr.c
 656   nw="$nw -Winline"                 # e.g., dispnew.c's inlining of row_equal_p
 657
 658   # Emacs doesn't care about shadowing; see
 659   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 660   nw="$nw -Wshadow"
 661
 662   # The following lines should be removable at some point.
 663   nw="$nw -Wstack-protector"
 664   nw="$nw -Wstrict-overflow"
 665   nw="$nw -Wsuggest-attribute=const"
 666   nw="$nw -Wsuggest-attribute=pure"
 667
 668   gl_MANYWARN_ALL_GCC([ws])
 669   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 670   for w in $ws; do
 671     gl_WARN_ADD([$w])
 672   done
 673   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 674   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 675   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 676   gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
 677   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 678   gl_WARN_ADD([-Wno-format-nonliteral])
 679
 680   # In spite of excluding -Wlogical-op above, it is enabled, as of
 681   # gcc 4.5.0 20090517.
 682   gl_WARN_ADD([-Wno-logical-op])
 683
 684   gl_WARN_ADD([-fdiagnostics-show-option])
 685   gl_WARN_ADD([-funit-at-a-time])
 686
 687   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 688   AC_DEFINE([_FORTIFY_SOURCE], [2],
 689     [enable compile-time and run-time bounds-checking, and some warnings])
 690   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 691
 692   # We use a slightly smaller set of warning options for lib/.
 693   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 694   nw=
 695   nw="$nw -Wunused-macros"
 696
 697   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 698   AC_SUBST([GNULIB_WARN_CFLAGS])
 699 fi
 700
 701
 702
 703 dnl Some other nice autoconf tests.
 704 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
 705 dnl AC_PROG_INSTALL
 706 dnl AC_PROG_MKDIR_P
 707 dnl if test "x$RANLIB" = x; then
 708 dnl   AC_PROG_RANLIB
 709 dnl fi
 710
 711 AC_PATH_PROG(INSTALL_INFO, install-info, :,
 712   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
 713 dnl Don't use GZIP, which is used by gzip for additional parameters.
 714 AC_PATH_PROG(GZIP_PROG, gzip)
 715
 716
 717 ## Need makeinfo >= 4.7 (?) to build the manuals.
 718 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 719 dnl By this stage, configure has already checked for egrep and set EGREP,
 720 dnl or exited with an error if no egrep was found.
 721 if test "$MAKEINFO" != "no" && \
 722   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[7-9]]|4\.[[1-6]][[0-9]]+)'`" = x; then
 723    MAKEINFO=no
 724 fi
 725
 726 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 727 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 728 ## therefore in the category of "special tools" not normally required, which
 729 ## configure does not have to check for (eg autoconf itself).
 730 ## In a Bazaar checkout on the other hand, the manuals are not included.
 731 ## So makeinfo is a requirement to build from Bazaar, and configure
 732 ## should test for it as it does for any other build requirement.
 733 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 734 ## with pre-built manuals, from a Bazaar checkout.
 735 HAVE_MAKEINFO=yes
 736
 737 if test "$MAKEINFO" = "no"; then
 738   MAKEINFO=makeinfo
 739   if test "x${with_makeinfo}" = "xno"; then
 740     HAVE_MAKEINFO=no
 741   elif test ! -e $srcdir/info/emacs; then
 742     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
 743 source tree does not seem to have pre-built manuals in the `info' directory.
 744 Either install a suitable version of makeinfo, or re-run configure
 745 with the `--without-makeinfo' option to build without the manuals.] )
 746   fi
 747 fi
 748 AC_SUBST(HAVE_MAKEINFO)
 749
 750 dnl Just so that there is only a single place we need to edit.
 751 INFO_EXT=.info
 752 INFO_OPTS=--no-split
 753 AC_SUBST(INFO_EXT)
 754 AC_SUBST(INFO_OPTS)
 755
 756 dnl Add our options to ac_link now, after it is set up.
 757
 758 if test x$GCC = xyes; then
 759   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 760     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 761 else
 762   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 763     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 764 fi
 765
 766 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 767 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 768 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 769 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 770 dnl if not built to support GNU ld.
 771
 772 late_LDFLAGS=$LDFLAGS
 773 if test x$GCC = xyes; then
 774   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 775 else
 776   LDFLAGS="$LDFLAGS -znocombreloc"
 777 fi
 778
 779 AC_MSG_CHECKING([for -znocombreloc])
 780 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 781   [AC_MSG_RESULT(yes)],
 782   LDFLAGS=$late_LDFLAGS
 783   [AC_MSG_RESULT(no)])
 784
 785
 786 dnl The function dump-emacs will not be defined and temacs will do
 787 dnl (load "loadup") automatically unless told otherwise.
 788 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 789 case "$opsys" in
 790   your-opsys-here) CANNOT_DUMP=yes ;;
 791 esac
 792
 793 test "$CANNOT_DUMP" = "yes" && \
 794   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 795
 796 AC_SUBST(CANNOT_DUMP)
 797
 798
 799 UNEXEC_OBJ=unexelf.o
 800 case "$opsys" in
 801   # MSDOS uses unexcoff.o
 802   # MSWindows uses unexw32.o
 803   aix4-2)
 804    UNEXEC_OBJ=unexaix.o
 805    ;;
 806   cygwin)
 807    UNEXEC_OBJ=unexcw.o
 808    ;;
 809   darwin)
 810    UNEXEC_OBJ=unexmacosx.o
 811    ;;
 812   hpux10-20 | hpux11)
 813    UNEXEC_OBJ=unexhp9k800.o
 814    ;;
 815   sol2-10)
 816    # Use the Solaris dldump() function, called from unexsol.c, to dump
 817    # emacs, instead of the generic ELF dump code found in unexelf.c.
 818    # The resulting binary has a complete symbol table, and is better
 819    # for debugging and other observability tools (debuggers, pstack, etc).
 820    #
 821    # If you encounter a problem using dldump(), please consider sending
 822    # a message to the OpenSolaris tools-linking mailing list:
 823    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 824    #
 825    # It is likely that dldump() works with older Solaris too, but this has
 826    # not been tested, so for now this change is for Solaris 10 or newer.
 827    UNEXEC_OBJ=unexsol.o
 828    ;;
 829 esac
 830
 831 LD_SWITCH_SYSTEM=
 832 case "$opsys" in
 833   freebsd)
 834    ## Let `ld' find image libs and similar things in /usr/local/lib.
 835    ## The system compiler, GCC, has apparently been modified to not
 836    ## look there, contrary to what a stock GCC would do.
 837 ### It's not our place to do this.  See bug#10313#17.
 838 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
 839       :
 840    ;;
 841
 842   gnu-linux)
 843    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 844    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 845    ;;
 846
 847   netbsd)
 848 ### It's not our place to do this.  See bug#10313#17.
 849 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 850       :
 851    ;;
 852
 853   openbsd)
 854    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 855    ## otherwise Emacs dumps core on elf systems.
 856    LD_SWITCH_SYSTEM="-Z"
 857    ;;
 858 esac
 859 AC_SUBST(LD_SWITCH_SYSTEM)
 860
 861 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 862
 863 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
 864 ## which has not been defined yet.  When this was handled with cpp,
 865 ## it was expanded to null when configure sourced the s/*.h file.
 866 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 867 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 868 ## (or somesuch), but because it is supposed to go at the _front_
 869 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 870 ## Compare with the gnu-linux case below, which added to the end
 871 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 872 ## LD_SWITCH_SYSTEM_TEMACS.
 873 case "$opsys" in
 874   netbsd|openbsd)
 875    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
 876 esac
 877
 878
 879 C_SWITCH_MACHINE=
 880 case $canonical in
 881  alpha*)
 882   AC_CHECK_DECL([__ELF__])
 883   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 884     ## With ELF, make sure that all common symbols get allocated to in the
 885     ## data section.  Otherwise, the dump of temacs may miss variables in
 886     ## the shared library that have been initialized.  For example, with
 887     ## GNU libc, __malloc_initialized would normally be resolved to the
 888     ## shared library's .bss section, which is fatal.
 889     if test "x$GCC" = "xyes"; then
 890       C_SWITCH_MACHINE="-fno-common"
 891     else
 892       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 893     fi
 894   else
 895     UNEXEC_OBJ=unexalpha.o
 896   fi
 897   ;;
 898 esac
 899 AC_SUBST(C_SWITCH_MACHINE)
 900
 901 AC_SUBST(UNEXEC_OBJ)
 902
 903 C_SWITCH_SYSTEM=
 904 ## Some programs in src produce warnings saying certain subprograms
 905 ## are too complex and need a MAXMEM value greater than 2000 for
 906 ## additional optimization.  --nils@exp-math.uni-essen.de
 907 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 908   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 909 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 910 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 911 AC_SUBST(C_SWITCH_SYSTEM)
 912
 913
 914 LIBS_SYSTEM=
 915 case "$opsys" in
 916   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 917   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 918
 919   freebsd) LIBS_SYSTEM="-lutil" ;;
 920
 921   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 922
 923   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
 924
 925   ## Motif needs -lgen.
 926   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
 927 esac
 928 AC_SUBST(LIBS_SYSTEM)
 929
 930
 931 ### Make sure subsequent tests use flags consistent with the build flags.
 932
 933 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 934   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 935 else
 936   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
 937 fi
 938
 939 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
 940 AC_DEFUN([AC_TYPE_SIZE_T])
 941 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
 942 AC_DEFUN([AC_TYPE_UID_T])
 943
 944
 945 LIB_MATH=-lm
 946 LIB_STANDARD=
 947 START_FILES=
 948
 949 dnl NB do not use CRT_DIR unquoted here, since it might not be set yet.
 950 case $opsys in
 951   cygwin )
 952     LIB_MATH=
 953     START_FILES='pre-crt0.o'
 954     ;;
 955   darwin )
 956     ## Adding -lm confuses the dynamic linker, so omit it.
 957     LIB_MATH=
 958     START_FILES='pre-crt0.o'
 959     ;;
 960   freebsd )
 961     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
 962     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
 963     ;;
 964   gnu-linux | gnu-kfreebsd )
 965     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
 966     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
 967     ;;
 968   hpux10-20 | hpux11 )
 969     LIB_STANDARD=-lc
 970     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
 971     ;;
 972   dnl NB this may be adjusted below.
 973   netbsd | openbsd )
 974     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
 975     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
 976     ;;
 977 esac
 978
 979 AC_SUBST(LIB_MATH)
 980 AC_SUBST(START_FILES)
 981
 982 dnl Not all platforms use crtn.o files.  Check if the current one does.
 983 crt_files=
 984
 985 for file in x $LIB_STANDARD $START_FILES; do
 986   case "$file" in
 987     *CRT_DIR*) crt_files="$crt_files `echo $file | sed -e 's|.*/||'`" ;;
 988   esac
 989 done
 990
 991 if test "x$crt_files" != x; then
 992
 993   ## If user specified a crt-dir, use that unconditionally.
 994   crt_gcc=no
 995
 996   if test "X$CRT_DIR" = "X"; then
 997
 998     CRT_DIR=/usr/lib            # default
 999
1000     case "$canonical" in
1001       x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1002       ## On x86-64 and s390x GNU/Linux distributions, the standard library
1003       ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1004       ## For anything else (eg /usr/lib32), it is up the user to specify
1005       ## the location (bug#5655).
1006       ## Test for crtn.o, not just the directory, because sometimes the
1007       ## directory exists but does not have the relevant files (bug#1287).
1008       ## FIXME better to test for binary compatibility somehow.
1009       test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1010       ;;
1011
1012       powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1013     esac
1014
1015     case "$opsys" in
1016       hpux10-20) CRT_DIR=/lib ;;
1017     esac
1018
1019     test "x${GCC}" = xyes && crt_gcc=yes
1020
1021   fi                            # CRT_DIR = ""
1022
1023   crt_missing=
1024
1025   for file in $crt_files; do
1026
1027     ## If we're using gcc, try to determine it automatically by asking
1028     ## gcc.  [If this doesn't work, CRT_DIR will remain at the
1029     ## system-dependent default from above.]
1030     if test $crt_gcc = yes && test ! -e $CRT_DIR/$file; then
1031
1032        crt_file=`$CC --print-file-name=$file 2>/dev/null`
1033        case "$crt_file" in
1034          */*)
1035            CRT_DIR=`AS_DIRNAME(["$crt_file"])`
1036            ;;
1037        esac
1038     fi
1039
1040     dnl We expect all the files to be in a single directory, so after the
1041     dnl first there is no point asking gcc.
1042     crt_gcc=no
1043
1044     test -e $CRT_DIR/$file || crt_missing="$crt_missing $file"
1045   done                          # $crt_files
1046
1047   test "x$crt_missing" = x || \
1048     AC_MSG_ERROR([Required file(s) not found:$crt_missing
1049 Try using the --with-crt-dir option.])
1050
1051 fi                              # crt_files != ""
1052
1053 AC_SUBST(CRT_DIR)
1054
1055 case $opsys in
1056   netbsd | openbsd )
1057     if test -f $CRT_DIR/crti.o; then
1058
1059         test -f $CRT_DIR/crtn.o || \
1060           AC_MSG_ERROR([Required file not found: crtn.o])
1061
1062         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1063         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1064     fi
1065     ;;
1066 esac
1067
1068
1069 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1070
1071 dnl This function definition taken from Gnome 2.0
1072 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1073 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1074 dnl also defines GSTUFF_PKG_ERRORS on error
1075 AC_DEFUN([PKG_CHECK_MODULES], [
1076   succeeded=no
1077
1078   if test "$PKG_CONFIG" = "no" ; then
1079      ifelse([$4], , [AC_MSG_ERROR([
1080       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1081   else
1082      PKG_CONFIG_MIN_VERSION=0.9.0
1083      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1084         AC_MSG_CHECKING(for $2)
1085
1086         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD &&
1087            $1_CFLAGS=`$PKG_CONFIG --cflags "$2" 2>&AS_MESSAGE_LOG_FD` &&
1088            $1_LIBS=`$PKG_CONFIG --libs "$2" 2>&AS_MESSAGE_LOG_FD`; then
1089             edit_cflags="
1090               s,///*,/,g
1091               s/^/ /
1092               s/ -I/ $isystem/g
1093               s/^ //
1094             "
1095             $1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1096             $1_LIBS=`AS_ECHO(["$$1_LIBS"]) | sed -e 's,///*,/,g'`
1097             AC_MSG_RESULT([yes CFLAGS='$$1_CFLAGS' LIBS='$$1_LIBS'])
1098             succeeded=yes
1099         else
1100             AC_MSG_RESULT(no)
1101             $1_CFLAGS=""
1102             $1_LIBS=""
1103             ## If we have a custom action on failure, don't print errors, but
1104             ## do set a variable so people can do so.
1105             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1106             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1107         fi
1108
1109         AC_SUBST($1_CFLAGS)
1110         AC_SUBST($1_LIBS)
1111      else
1112         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1113         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1114      fi
1115   fi
1116
1117   if test $succeeded = yes; then
1118      ifelse([$3], , :, [$3])
1119   else
1120      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1121   fi
1122 ])
1123
1124
1125 if test "${with_sound}" != "no"; then
1126   # Sound support for GNU/Linux and the free BSDs.
1127   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1128     have_sound_header=yes)
1129   # Emulation library used on NetBSD.
1130   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1131   AC_SUBST(LIBSOUND)
1132
1133   ALSA_REQUIRED=1.0.0
1134   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1135   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1136   if test $HAVE_ALSA = yes; then
1137     SAVE_CFLAGS="$CFLAGS"
1138     SAVE_LIBS="$LIBS"
1139     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1140     LIBS="$ALSA_LIBS $LIBS"
1141     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1142                     emacs_alsa_normal=yes,
1143                     emacs_alsa_normal=no)
1144     if test "$emacs_alsa_normal" != yes; then
1145       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1146                      [[snd_lib_error_set_handler (0);]])],
1147                      emacs_alsa_subdir=yes,
1148                      emacs_alsa_subdir=no)
1149       if test "$emacs_alsa_subdir" != yes; then
1150         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1151       fi
1152       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1153     fi
1154
1155     CFLAGS="$SAVE_CFLAGS"
1156     LIBS="$SAVE_LIBS"
1157     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1158     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1159     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1160   fi
1161
1162   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1163   dnl compiles only on the specified platforms.  For others, it
1164   dnl probably doesn't make sense to try.
1165   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1166      case "$opsys" in
1167        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1168        gnu-linux|freebsd|netbsd)
1169          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1170          ;;
1171      esac
1172   fi
1173
1174   AC_SUBST(CFLAGS_SOUND)
1175 fi
1176
1177 dnl checks for header files
1178 AC_CHECK_HEADERS_ONCE(
1179   sys/select.h sys/time.h utime.h
1180   linux/version.h sys/systeminfo.h
1181   stdio_ext.h fcntl.h coff.h pty.h
1182   sys/vlimit.h sys/resource.h
1183   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1184
1185 AC_MSG_CHECKING(if personality LINUX32 can be set)
1186 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1187                emacs_cv_personality_linux32=yes,
1188                emacs_cv_personality_linux32=no)
1189 AC_MSG_RESULT($emacs_cv_personality_linux32)
1190
1191 if test $emacs_cv_personality_linux32 = yes; then
1192   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1193             [Define to 1 if personality LINUX32 can be set.])
1194 fi
1195
1196 dnl On Solaris 8 there's a compilation warning for term.h because
1197 dnl it doesn't define `bool'.
1198 AC_CHECK_HEADERS(term.h, , , -)
1199 AC_HEADER_TIME
1200 AC_CHECK_DECLS([sys_siglist])
1201 if test $ac_cv_have_decl_sys_siglist != yes; then
1202   # For Tru64, at least:
1203   AC_CHECK_DECLS([__sys_siglist])
1204   if test $ac_cv_have_decl___sys_siglist = yes; then
1205     AC_DEFINE(sys_siglist, __sys_siglist,
1206               [Define to any substitute for sys_siglist.])
1207   fi
1208 fi
1209 AC_HEADER_SYS_WAIT
1210
1211 dnl Some systems have utime.h but don't declare the struct anyplace.
1212 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1213 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
1214 #include <sys/time.h>
1215 #include <time.h>
1216 #else
1217 #ifdef HAVE_SYS_TIME_H
1218 #include <sys/time.h>
1219 #else
1220 #include <time.h>
1221 #endif
1222 #endif
1223 #ifdef HAVE_UTIME_H
1224 #include <utime.h>
1225 #endif]], [[static struct utimbuf x; x.actime = x.modtime;]])],
1226   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1227 if test $emacs_cv_struct_utimbuf = yes; then
1228   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1229 fi
1230
1231 dnl Check for speed_t typedef.
1232 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1233   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <termios.h>]], [[speed_t x = 1;]])],
1234     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1235 if test $emacs_cv_speed_t = yes; then
1236   AC_DEFINE(HAVE_SPEED_T, 1,
1237            [Define to 1 if `speed_t' is declared by <termios.h>.])
1238 fi
1239
1240 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1241 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
1242 #include <sys/time.h>
1243 #include <time.h>
1244 #else
1245 #ifdef HAVE_SYS_TIME_H
1246 #include <sys/time.h>
1247 #else
1248 #include <time.h>
1249 #endif
1250 #endif]], [[static struct timeval x; x.tv_sec = x.tv_usec;]])],
1251   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1252 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1253 if test $emacs_cv_struct_timeval = yes; then
1254   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1255 fi
1256
1257 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1258 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]],
1259 [[static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;]])],
1260   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1261 HAVE_EXCEPTION=$emacs_cv_struct_exception
1262 if test $emacs_cv_struct_exception != yes; then
1263   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1264 fi
1265
1266 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1267 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1268 #if HAVE_SYS_SOCKET_H
1269 #include <sys/socket.h>
1270 #endif])
1271 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1272 #if HAVE_SYS_SOCKET_H
1273 #include <sys/socket.h>
1274 #endif])
1275 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1276 #if HAVE_SYS_SOCKET_H
1277 #include <sys/socket.h>
1278 #endif])
1279 AC_CHECK_FUNCS(getifaddrs freeifaddrs)
1280
1281 dnl checks for structure members
1282 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1283                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1284                   struct ifreq.ifr_addr,
1285                   struct ifreq.ifr_addr.sa_len], , ,
1286                  [AC_INCLUDES_DEFAULT
1287 #if HAVE_SYS_SOCKET_H
1288 #include <sys/socket.h>
1289 #endif
1290 #if HAVE_NET_IF_H
1291 #include <net/if.h>
1292 #endif])
1293
1294 dnl Check for endianness.
1295 dnl AC_C_BIGENDIAN is done by gnulib.
1296
1297 AC_CACHE_CHECK([for  __attribute__ ((__aligned__ (expr)))],
1298   [emacs_cv_attribute_aligned],
1299   [AC_COMPILE_IFELSE(
1300      [AC_LANG_PROGRAM(
1301         [[char __attribute__ ((__aligned__ (1 << 3))) c;]],
1302         [[]])],
1303      [emacs_cv_attribute_aligned=yes],
1304      [emacs_cv_attribute_aligned=no])])
1305 if test $emacs_cv_attribute_aligned = yes; then
1306   AC_DEFINE([HAVE_ATTRIBUTE_ALIGNED], 1,
1307     [Define to 1 if GCC-style __attribute__ ((__aligned__ (expr))) works.])
1308 fi
1309
1310 dnl check for Make feature
1311 dnl AC_PROG_MAKE_SET is done by Automake.
1312
1313 DEPFLAGS=
1314 MKDEPDIR=":"
1315 deps_frag=deps.mk
1316 dnl check for GNU Make if we have GCC and autodepend is on.
1317 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1318    AC_MSG_CHECKING([whether we are using GNU Make])
1319    HAVE_GNU_MAKE=no
1320    testval=`${MAKE-make} --version 2>/dev/null | grep 'GNU Make'`
1321    if test "x$testval" != x; then
1322       HAVE_GNU_MAKE=yes
1323    else
1324       ac_enable_autodepend=no
1325    fi
1326    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1327    if test $HAVE_GNU_MAKE = yes; then
1328       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1329       SAVE_CFLAGS="$CFLAGS"
1330       CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1331       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1332       CFLAGS="$SAVE_CFLAGS"
1333       test -f deps.d || ac_enable_autodepend=no
1334       rm -rf deps.d
1335       AC_MSG_RESULT([$ac_enable_autodepend])
1336    fi
1337    if test $ac_enable_autodepend = yes; then
1338       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1339       ## MKDIR_P is documented (see AC_PROG_MKDIR_P) to be parallel-safe.
1340       MKDEPDIR='${MKDIR_P} ${DEPDIR}'
1341       deps_frag=autodeps.mk
1342    fi
1343 fi
1344 deps_frag=$srcdir/src/$deps_frag
1345 AC_SUBST(MKDEPDIR)
1346 AC_SUBST(DEPFLAGS)
1347 AC_SUBST_FILE(deps_frag)
1348
1349
1350 lisp_frag=$srcdir/src/lisp.mk
1351 AC_SUBST_FILE(lisp_frag)
1352
1353
1354 dnl checks for operating system services
1355 AC_SYS_LONG_FILE_NAMES
1356
1357 #### Choose a window system.
1358
1359 AC_PATH_X
1360 if test "$no_x" = yes; then
1361   window_system=none
1362 else
1363   window_system=x11
1364 fi
1365
1366 LD_SWITCH_X_SITE_RPATH=
1367 if test "${x_libraries}" != NONE; then
1368   if test -n "${x_libraries}"; then
1369     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1370     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"`
1371   fi
1372   x_default_search_path=""
1373   x_search_path=${x_libraries}
1374   if test -z "${x_search_path}"; then
1375     x_search_path=/usr/lib
1376   fi
1377   for x_library in `echo ${x_search_path}: | \
1378                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1379     x_search_path="\
1380 ${x_library}/X11/%L/%T/%N%C%S:\
1381 ${x_library}/X11/%l/%T/%N%C%S:\
1382 ${x_library}/X11/%T/%N%C%S:\
1383 ${x_library}/X11/%L/%T/%N%S:\
1384 ${x_library}/X11/%l/%T/%N%S:\
1385 ${x_library}/X11/%T/%N%S"
1386     if test x"${x_default_search_path}" = x; then
1387       x_default_search_path=${x_search_path}
1388     else
1389       x_default_search_path="${x_search_path}:${x_default_search_path}"
1390     fi
1391   done
1392 fi
1393 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1394
1395 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1396   C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1397 fi
1398
1399 if test x"${x_includes}" = x; then
1400   bitmapdir=/usr/include/X11/bitmaps
1401 else
1402   # accumulate include directories that have X11 bitmap subdirectories
1403   bmd_acc="dummyval"
1404   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1405     if test -d "${bmd}/X11/bitmaps"; then
1406       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1407     fi
1408     if test -d "${bmd}/bitmaps"; then
1409       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1410     fi
1411   done
1412   if test ${bmd_acc} != "dummyval"; then
1413     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1414   fi
1415 fi
1416
1417 HAVE_NS=no
1418 NS_IMPL_COCOA=no
1419 NS_IMPL_GNUSTEP=no
1420 tmp_CPPFLAGS="$CPPFLAGS"
1421 tmp_CFLAGS="$CFLAGS"
1422 CPPFLAGS="$CPPFLAGS -x objective-c"
1423 CFLAGS="$CFLAGS -x objective-c"
1424 TEMACS_LDFLAGS2="\${LDFLAGS}"
1425 GNU_OBJC_CFLAGS=
1426 if test "${with_ns}" != no; then
1427   if test "${opsys}" = darwin; then
1428      NS_IMPL_COCOA=yes
1429      ns_appdir=`pwd`/nextstep/Emacs.app
1430      ns_appbindir=${ns_appdir}/Contents/MacOS
1431      ns_appresdir=${ns_appdir}/Contents/Resources
1432      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1433   elif test -f $GNUSTEP_CONFIG_FILE; then
1434      NS_IMPL_GNUSTEP=yes
1435      ns_appdir=`pwd`/nextstep/Emacs.app
1436      ns_appbindir=${ns_appdir}
1437      ns_appresdir=${ns_appdir}/Resources
1438      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1439      dnl FIXME sourcing this several times in subshells seems inefficient.
1440      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1441      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1442      dnl I seemed to need these as well with GNUstep-startup 0.25.
1443      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1444      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1445      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1446        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1447      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1448        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1449      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1450      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1451      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1452      LIB_STANDARD=
1453      START_FILES=
1454      TEMACS_LDFLAGS2=
1455      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1456      dnl If they had chosen to either define it or not, we could have
1457      dnl just used AC_CHECK_DECL here.
1458      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1459        emacs_cv_objc_exceptions,
1460 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1461 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1462 1;
1463 #else
1464 fail;
1465 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1466      if test $emacs_cv_objc_exceptions = yes; then
1467        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1468        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1469          [Define if GNUstep uses ObjC exceptions.])
1470        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1471      fi
1472   fi
1473
1474   dnl This is only used while we test the NS headers, it gets reset below.
1475   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1476
1477   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1478                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1479   files are missing or cannot be compiled.])])
1480   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1481                                      [NSInteger i;])],
1482                     ns_have_nsinteger=yes,
1483                     ns_have_nsinteger=no)
1484   if test $ns_have_nsinteger = yes; then
1485     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
1486   fi
1487 fi
1488 AC_SUBST(TEMACS_LDFLAGS2)
1489
1490 INSTALL_ARCH_INDEP_EXTRA=install-etc
1491 ns_self_contained=no
1492 ns_frag=/dev/null
1493 NS_OBJ=
1494 NS_OBJC_OBJ=
1495 if test "${HAVE_NS}" = yes; then
1496   if test "$with_toolkit_scroll_bars" = "no"; then
1497     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1498   fi
1499
1500   window_system=nextstep
1501   with_xft=no
1502   # set up packaging dirs
1503   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1504      ns_self_contained=yes
1505      prefix=${ns_appresdir}
1506      exec_prefix=${ns_appbindir}
1507      dnl This one isn't really used, only archlibdir is.
1508      libexecdir="\${ns_appbindir}/libexec"
1509      archlibdir="\${ns_appbindir}/libexec"
1510      docdir="\${ns_appresdir}/etc"
1511      etcdir="\${ns_appresdir}/etc"
1512      dnl FIXME maybe set datarootdir instead.
1513      dnl That would also get applications, icons, man.
1514      infodir="\${ns_appresdir}/info"
1515      mandir="\${ns_appresdir}/man"
1516      lispdir="\${ns_appresdir}/lisp"
1517      leimdir="\${ns_appresdir}/leim"
1518      INSTALL_ARCH_INDEP_EXTRA=
1519   fi
1520   ns_frag=$srcdir/src/ns.mk
1521   NS_OBJ="fontset.o fringe.o image.o"
1522   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o"
1523 fi
1524 CFLAGS="$tmp_CFLAGS"
1525 CPPFLAGS="$tmp_CPPFLAGS"
1526 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1527 AC_SUBST(ns_self_contained)
1528 AC_SUBST(NS_OBJ)
1529 AC_SUBST(NS_OBJC_OBJ)
1530 AC_SUBST(LIB_STANDARD)
1531 AC_SUBST_FILE(ns_frag)
1532
1533 case "${window_system}" in
1534   x11 )
1535     HAVE_X_WINDOWS=yes
1536     HAVE_X11=yes
1537     case "${with_x_toolkit}" in
1538       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1539       motif ) USE_X_TOOLKIT=MOTIF ;;
1540       gtk ) with_gtk=yes
1541 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
1542 dnl USE_X_TOOLKIT is set.
1543             USE_X_TOOLKIT=none ;;
1544       gtk3 ) with_gtk3=yes
1545              USE_X_TOOLKIT=none ;;
1546       no ) USE_X_TOOLKIT=none ;;
1547 dnl If user did not say whether to use a toolkit, make this decision later:
1548 dnl use the toolkit if we have gtk, or X11R5 or newer.
1549       * ) USE_X_TOOLKIT=maybe ;;
1550     esac
1551   ;;
1552   nextstep | none )
1553     HAVE_X_WINDOWS=no
1554     HAVE_X11=no
1555     USE_X_TOOLKIT=none
1556   ;;
1557 esac
1558
1559 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1560    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1561    if test "$HAVE_XSERVER" = true ||
1562       test -n "$DISPLAY" ||
1563       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1564         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1565 were found.  You should install the relevant development files for X
1566 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1567 sure you have development files for image handling, i.e.
1568 tiff, gif, jpeg, png and xpm.
1569 If you are sure you want Emacs compiled without X window support, pass
1570   --without-x
1571 to configure.])
1572    fi
1573 fi
1574
1575 ### If we're using X11, we should use the X menu package.
1576 HAVE_MENUS=no
1577 case ${HAVE_X11} in
1578   yes ) HAVE_MENUS=yes ;;
1579 esac
1580
1581 # Does the opsystem file prohibit the use of the GNU malloc?
1582 # Assume not, until told otherwise.
1583 GNU_MALLOC=yes
1584
1585 AC_CACHE_CHECK(
1586   [whether malloc is Doug Lea style],
1587   [emacs_cv_var_doug_lea_malloc],
1588   [AC_LINK_IFELSE(
1589      [AC_LANG_PROGRAM(
1590         [[#include <malloc.h>
1591           static void hook (void) {}]],
1592         [[malloc_set_state (malloc_get_state ());
1593           __after_morecore_hook = hook;
1594           __malloc_initialize_hook = hook;]])],
1595      [emacs_cv_var_doug_lea_malloc=yes],
1596      [emacs_cv_var_doug_lea_malloc=no])])
1597 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
1598
1599
1600 dnl See comments in aix4-2.h about maybe using system malloc there.
1601 system_malloc=no
1602 case "$opsys" in
1603   ## darwin ld insists on the use of malloc routines in the System framework.
1604   darwin|sol2-10) system_malloc=yes ;;
1605 esac
1606
1607 if test "${system_malloc}" = "yes"; then
1608   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1609   GNU_MALLOC=no
1610   GNU_MALLOC_reason="
1611     (The GNU allocators don't work with this system configuration.)"
1612   GMALLOC_OBJ=
1613   VMLIMIT_OBJ=
1614 else
1615   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1616   VMLIMIT_OBJ=vm-limit.o
1617 fi
1618 AC_SUBST(GMALLOC_OBJ)
1619 AC_SUBST(VMLIMIT_OBJ)
1620
1621 if test "$doug_lea_malloc" = "yes" ; then
1622   if test "$GNU_MALLOC" = yes ; then
1623     GNU_MALLOC_reason="
1624       (Using Doug Lea's new malloc from the GNU C Library.)"
1625   fi
1626   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1627             [Define to 1 if you are using the GNU C Library.])
1628
1629   ## Use mmap directly for allocating larger buffers.
1630   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1631   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1632   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
1633   case "$opsys" in
1634     gnu*) REL_ALLOC=no ;;
1635   esac
1636 fi
1637
1638 if test x"${REL_ALLOC}" = x; then
1639   REL_ALLOC=${GNU_MALLOC}
1640 fi
1641
1642 use_mmap_for_buffers=no
1643 case "$opsys" in
1644   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1645 esac
1646
1647 AC_FUNC_MMAP
1648 if test $use_mmap_for_buffers = yes; then
1649   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1650   REL_ALLOC=no
1651 fi
1652
1653 LIBS="$LIBS_SYSTEM $LIBS"
1654
1655 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1656 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1657 AC_CHECK_LIB(dnet, dnet_ntoa)
1658 dnl This causes -lresolv to get used in subsequent tests,
1659 dnl which causes failures on some systems such as HPUX 9.
1660 dnl AC_CHECK_LIB(resolv, gethostbyname)
1661
1662 dnl FIXME replace main with a function we actually want from this library.
1663 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1664
1665 dnl Check if pthreads is available.
1666 LIB_PTHREAD=
1667 AC_CHECK_HEADERS_ONCE(pthread.h)
1668 if test "$ac_cv_header_pthread_h"; then
1669   dnl gmalloc.c uses pthread_atfork, which is not available on older-style
1670   dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
1671   dnl testing for pthread_self if Emacs uses gmalloc.c.
1672   if test "$GMALLOC_OBJ" = gmalloc.o; then
1673     emacs_pthread_function=pthread_atfork
1674   else
1675     emacs_pthread_function=pthread_self
1676   fi
1677   AC_CHECK_LIB(pthread, $emacs_pthread_function, HAVE_PTHREAD=yes)
1678 fi
1679 if test "$HAVE_PTHREAD" = yes; then
1680   case "${canonical}" in
1681     *-hpux*) ;;
1682     *) LIB_PTHREAD="-lpthread"
1683        LIBS="$LIB_PTHREAD $LIBS" ;;
1684   esac
1685   AC_DEFINE(HAVE_PTHREAD, 1, [Define to 1 if you have pthread (-lpthread).])
1686 fi
1687 AC_SUBST([LIB_PTHREAD])
1688
1689 AC_CHECK_LIB(pthreads, cma_open)
1690
1691 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1692 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1693 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1694 ## added to LIBS in configure would never contain the pthreads part,
1695 ## but the value used in Makefiles might.  FIXME?
1696 ##
1697 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1698 ## be harmless on older versions of X where it happens to exist.
1699 test "$opsys" = "aix4-2" && \
1700   test $ac_cv_lib_pthreads_cma_open = yes && \
1701   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1702
1703 dnl Check for need for bigtoc support on IBM AIX
1704
1705 case ${host_os} in
1706 aix*)
1707   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1708     case $GCC in
1709     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1710     *) gdb_cv_bigtoc=-bbigtoc ;;
1711     esac
1712
1713     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1714     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
1715   ])
1716   ;;
1717 esac
1718
1719 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1720 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1721 # REAL_CPPFLAGS later on.
1722
1723 REAL_CFLAGS="$CFLAGS"
1724 REAL_CPPFLAGS="$CPPFLAGS"
1725
1726 if test "${HAVE_X11}" = "yes"; then
1727   DEFS="$C_SWITCH_X_SITE $DEFS"
1728   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1729   LIBS="-lX11 $LIBS"
1730   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1731   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1732
1733   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1734   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
1735   # but it's more convenient here to set LD_RUN_PATH since this
1736   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
1737   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1738     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1739     export LD_RUN_PATH
1740   fi
1741
1742   if test "${opsys}" = "gnu-linux"; then
1743     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1744     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1745      [[XOpenDisplay ("foo");]])],
1746      [xgnu_linux_first_failure=no],
1747      [xgnu_linux_first_failure=yes])
1748     if test "${xgnu_linux_first_failure}" = "yes"; then
1749       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1750       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1751       OLD_CPPFLAGS="$CPPFLAGS"
1752       OLD_LIBS="$LIBS"
1753       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1754       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1755       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1756       LIBS="$LIBS -b i486-linuxaout"
1757       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1758        [[XOpenDisplay ("foo");]])],
1759        [xgnu_linux_second_failure=no],
1760        [xgnu_linux_second_failure=yes])
1761       if test "${xgnu_linux_second_failure}" = "yes"; then
1762         # If we get the same failure with -b, there is no use adding -b.
1763         # So take it out.  This plays safe.
1764         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1765         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1766         CPPFLAGS="$OLD_CPPFLAGS"
1767         LIBS="$OLD_LIBS"
1768         AC_MSG_RESULT(no)
1769       else
1770         AC_MSG_RESULT(yes)
1771       fi
1772     else
1773       AC_MSG_RESULT(no)
1774     fi
1775   fi
1776
1777   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1778   # header files included from there.
1779   AC_MSG_CHECKING(for Xkb)
1780   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1781 #include <X11/XKBlib.h>]],
1782         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
1783         emacs_xkb=yes, emacs_xkb=no)
1784   AC_MSG_RESULT($emacs_xkb)
1785   if test $emacs_xkb = yes; then
1786     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1787   fi
1788
1789   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1790 XScreenNumberOfScreen)
1791 fi
1792
1793 if test "${window_system}" = "x11"; then
1794   AC_MSG_CHECKING(X11 version 6)
1795   AC_CACHE_VAL(emacs_cv_x11_version_6,
1796   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
1797 [[#if XlibSpecificationRelease < 6
1798 fail;
1799 #endif
1800 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1801   if test $emacs_cv_x11_version_6 = yes; then
1802     AC_MSG_RESULT(6 or newer)
1803     AC_DEFINE(HAVE_X11R6, 1,
1804               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1805     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1806     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1807     ## XIM support.
1808     case "$opsys" in
1809       sol2-*) : ;;
1810       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1811            [Define if you have usable X11R6-style XIM support.])
1812          ;;
1813     esac
1814   else
1815     AC_MSG_RESULT(before 6)
1816   fi
1817 fi
1818
1819
1820 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1821 HAVE_RSVG=no
1822 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes"; then
1823   if test "${with_rsvg}" != "no"; then
1824     RSVG_REQUIRED=2.11.0
1825     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1826
1827     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1828     AC_SUBST(RSVG_CFLAGS)
1829     AC_SUBST(RSVG_LIBS)
1830
1831     if test $HAVE_RSVG = yes; then
1832       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1833       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1834       LIBS="$RSVG_LIBS $LIBS"
1835     fi
1836   fi
1837 fi
1838
1839 HAVE_IMAGEMAGICK=no
1840 if test "${HAVE_X11}" = "yes"; then
1841   if test "${with_imagemagick}" != "no"; then
1842     ## 6.2.8 is the earliest version known to work, but earlier versions
1843     ## might work - let us know if you find one.
1844     ## 6.0.7 does not work.  See bug#7955.
1845     IMAGEMAGICK_MODULE="Wand >= 6.2.8"
1846     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1847     AC_SUBST(IMAGEMAGICK_CFLAGS)
1848     AC_SUBST(IMAGEMAGICK_LIBS)
1849
1850     if test $HAVE_IMAGEMAGICK = yes; then
1851       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1852       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1853       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1854       AC_CHECK_FUNCS(MagickExportImagePixels)
1855     fi
1856   fi
1857 fi
1858
1859
1860 HAVE_GTK=no
1861 GTK_OBJ=
1862 if test "${with_gtk3}" = "yes"; then
1863   GLIB_REQUIRED=2.28
1864   GTK_REQUIRED=3.0
1865   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1866
1867   dnl Checks for libraries.
1868   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1869   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1870      AC_MSG_ERROR($GTK_PKG_ERRORS)
1871   fi
1872   AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
1873   GTK_OBJ=emacsgtkfixed.o
1874 fi
1875
1876 if test "$pkg_check_gtk" != "yes"; then
1877   HAVE_GTK=no
1878 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1879   GLIB_REQUIRED=2.10
1880   GTK_REQUIRED=2.10
1881   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1882
1883   dnl Checks for libraries.
1884   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1885   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1886      AC_MSG_ERROR($GTK_PKG_ERRORS)
1887   fi
1888 fi
1889 fi
1890
1891 if test x"$pkg_check_gtk" = xyes; then
1892
1893   AC_SUBST(GTK_CFLAGS)
1894   AC_SUBST(GTK_LIBS)
1895   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1896   CFLAGS="$CFLAGS $GTK_CFLAGS"
1897   LIBS="$GTK_LIBS $LIBS"
1898   dnl Try to compile a simple GTK program.
1899   GTK_COMPILES=no
1900   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1901   if test "${GTK_COMPILES}" != "yes"; then
1902     if test "$USE_X_TOOLKIT" != "maybe"; then
1903       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1904     fi
1905   else
1906     HAVE_GTK=yes
1907     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1908     GTK_OBJ="gtkutil.o $GTK_OBJ"
1909     USE_X_TOOLKIT=none
1910     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1911       :
1912     else
1913       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1914        closing open displays.  This is no problem if you just use
1915        one display, but if you use more than one and close one of them
1916        Emacs may crash.]])
1917       sleep 3
1918     fi
1919   fi
1920
1921 fi
1922 AC_SUBST(GTK_OBJ)
1923
1924
1925 if test "${HAVE_GTK}" = "yes"; then
1926
1927   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1928   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1929   if test "$with_toolkit_scroll_bars" != no; then
1930     with_toolkit_scroll_bars=yes
1931   fi
1932
1933   dnl  Check if we have the old file selection dialog declared and
1934   dnl  in the link library.  In 2.x it may be in the library,
1935   dnl  but not declared if deprecated featured has been selected out.
1936   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1937   HAVE_GTK_FILE_SELECTION=no
1938   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1939                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1940 #include <gtk/gtk.h>])
1941   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1942     AC_CHECK_FUNCS(gtk_file_selection_new)
1943   fi
1944
1945
1946   dnl Check for functions introduced in 2.14 and later.
1947   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1948                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1949                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1950                  gtk_orientable_set_orientation \
1951                  gtk_window_set_has_resize_grip)
1952 fi
1953
1954 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1955 dnl other platforms.
1956 HAVE_DBUS=no
1957 DBUS_OBJ=
1958 if test "${with_dbus}" = "yes"; then
1959    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1960    if test "$HAVE_DBUS" = yes; then
1961      LIBS="$LIBS $DBUS_LIBS"
1962      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1963      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
1964      dnl dbus_validate_* have been introduced in D-Bus 1.5.12.
1965      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
1966                     dbus_validate_bus_name \
1967                     dbus_validate_path \
1968                     dbus_validate_interface \
1969                     dbus_validate_member)
1970      DBUS_OBJ=dbusbind.o
1971    fi
1972 fi
1973 AC_SUBST(DBUS_OBJ)
1974
1975 dnl GSettings has been tested under GNU/Linux only.
1976 HAVE_GSETTINGS=no
1977 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
1978    PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
1979    if test "$HAVE_GSETTINGS" = "yes"; then
1980       AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
1981       SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
1982       SETTINGS_LIBS="$GSETTINGS_LIBS"
1983    fi
1984 fi
1985
1986 dnl GConf has been tested under GNU/Linux only.
1987 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1988 HAVE_GCONF=no
1989 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1990    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1991    if test "$HAVE_GCONF" = yes; then
1992       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1993       dnl Newer GConf doesn't link with g_objects, so this is not defined.
1994       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
1995       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
1996    fi
1997 fi
1998
1999 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2000     SAVE_CFLAGS="$CFLAGS"
2001     SAVE_LIBS="$LIBS"
2002     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2003     LIBS="$SETTINGS_LIBS $LIBS"
2004     AC_CHECK_FUNCS([g_type_init])
2005     CFLAGS="$SAVE_CFLAGS"
2006     LIBS="$SAVE_LIBS"
2007 fi
2008 AC_SUBST(SETTINGS_CFLAGS)
2009 AC_SUBST(SETTINGS_LIBS)
2010
2011
2012 dnl SELinux is available for GNU/Linux only.
2013 HAVE_LIBSELINUX=no
2014 LIBSELINUX_LIBS=
2015 if test "${with_selinux}" = "yes"; then
2016    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2017    if test "$HAVE_LIBSELINUX" = yes; then
2018       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2019       LIBSELINUX_LIBS=-lselinux
2020    fi
2021 fi
2022 AC_SUBST(LIBSELINUX_LIBS)
2023
2024 HAVE_GNUTLS=no
2025 HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=no
2026 if test "${with_gnutls}" = "yes" ; then
2027   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2028   if test "${HAVE_GNUTLS}" = "yes"; then
2029     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2030   fi
2031
2032   CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
2033   LIBS="$LIBGNUTLS_LIBS $LIBS"
2034   AC_CHECK_FUNCS(gnutls_certificate_set_verify_function, HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=yes)
2035
2036   if test "${HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY}" = "yes"; then
2037     AC_DEFINE(HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY, 1, [Define if using GnuTLS certificate verification callbacks.])
2038   fi
2039 fi
2040
2041 AC_SUBST(LIBGNUTLS_LIBS)
2042 AC_SUBST(LIBGNUTLS_CFLAGS)
2043
2044 dnl Do not put whitespace before the #include statements below.
2045 dnl Older compilers (eg sunos4 cc) choke on it.
2046 HAVE_XAW3D=no
2047 LUCID_LIBW=
2048 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2049   if test "$with_xaw3d" != no; then
2050     AC_MSG_CHECKING(for xaw3d)
2051     AC_CACHE_VAL(emacs_cv_xaw3d,
2052     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2053 #include <X11/Intrinsic.h>
2054 #include <X11/Xaw3d/Simple.h>]],
2055       [[]])],
2056       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2057                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2058       emacs_cv_xaw3d=no)])
2059   else
2060     emacs_cv_xaw3d=no
2061   fi
2062   if test $emacs_cv_xaw3d = yes; then
2063     AC_MSG_RESULT([yes; using Lucid toolkit])
2064     USE_X_TOOLKIT=LUCID
2065     HAVE_XAW3D=yes
2066     LUCID_LIBW=-lXaw3d
2067     AC_DEFINE(HAVE_XAW3D, 1,
2068               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2069   else
2070     AC_MSG_RESULT(no)
2071     AC_MSG_CHECKING(for libXaw)
2072     AC_CACHE_VAL(emacs_cv_xaw,
2073     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2074 #include <X11/Intrinsic.h>
2075 #include <X11/Xaw/Simple.h>]],
2076       [[]])],
2077       emacs_cv_xaw=yes,
2078       emacs_cv_xaw=no)])
2079     if test $emacs_cv_xaw = yes; then
2080       AC_MSG_RESULT([yes; using Lucid toolkit])
2081       USE_X_TOOLKIT=LUCID
2082       LUCID_LIBW=-lXaw
2083     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2084       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2085     else
2086       AC_MSG_ERROR([No X toolkit could be found.
2087 If you are sure you want Emacs compiled without an X toolkit, pass
2088   --with-x-toolkit=no
2089 to configure.  Otherwise, install the development libraries for the toolkit
2090 that you want to use (e.g. Gtk+) and re-run configure.])
2091     fi
2092   fi
2093 fi
2094
2095 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2096
2097 LIBXTR6=
2098 if test "${USE_X_TOOLKIT}" != "none"; then
2099   AC_MSG_CHECKING(X11 toolkit version)
2100   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2101   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2102 [[#if XtSpecificationRelease < 6
2103 fail;
2104 #endif
2105 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2106   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2107   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2108     AC_MSG_RESULT(6 or newer)
2109     AC_DEFINE(HAVE_X11XTR6, 1,
2110               [Define to 1 if you have the X11R6 or newer version of Xt.])
2111     LIBXTR6="-lSM -lICE"
2112     case "$opsys" in
2113       ## Use libw.a along with X11R6 Xt.
2114       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2115     esac
2116   else
2117     AC_MSG_RESULT(before 6)
2118   fi
2119
2120 dnl If using toolkit, check whether libXmu.a exists.
2121 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2122   OLDLIBS="$LIBS"
2123   if test x$HAVE_X11XTR6 = xyes; then
2124     LIBS="-lXt -lSM -lICE $LIBS"
2125   else
2126     LIBS="-lXt $LIBS"
2127   fi
2128   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2129   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2130 fi
2131 AC_SUBST(LIBXTR6)
2132
2133 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2134 dnl Why not just test for libxmu in the normal way?
2135 LIBXMU=-lXmu
2136 case $opsys in
2137   ## These systems don't supply Xmu.
2138   hpux* | aix4-2 )
2139     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2140     ;;
2141 esac
2142 AC_SUBST(LIBXMU)
2143
2144 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2145 if test "${HAVE_X11}" = "yes"; then
2146   if test "${USE_X_TOOLKIT}" != "none"; then
2147     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2148   fi
2149 fi
2150
2151 LIBXP=
2152 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2153   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2154   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2155     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2156 int x = 5;
2157 #else
2158 Motif version prior to 2.1.
2159 #endif]])],
2160     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2161   if test $emacs_cv_motif_version_2_1 = yes; then
2162     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2163   else
2164     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2165     # We put this in CFLAGS temporarily to precede other -I options
2166     # that might be in CFLAGS temporarily.
2167     # We put this in CPPFLAGS where it precedes the other -I options.
2168     OLD_CPPFLAGS=$CPPFLAGS
2169     OLD_CFLAGS=$CFLAGS
2170     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2171     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2172     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2173       [[int x = 5;]])],
2174       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2175     if test $emacs_cv_lesstif = yes; then
2176       # Make sure this -I option remains in CPPFLAGS after it is set
2177       # back to REAL_CPPFLAGS.
2178       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2179       # have those other -I options anyway.  Ultimately, having this
2180       # directory ultimately in CPPFLAGS will be enough.
2181       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2182       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2183     else
2184       CFLAGS=$OLD_CFLAGS
2185       CPPFLAGS=$OLD_CPPFLAGS
2186     fi
2187   fi
2188   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2189     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2190 fi
2191
2192 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2193 dnl using Motif or Xaw3d is available, and unless
2194 dnl --with-toolkit-scroll-bars=no was specified.
2195
2196 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2197             [Define to 1 if we should use toolkit scroll bars.])dnl
2198 USE_TOOLKIT_SCROLL_BARS=no
2199 if test "${with_toolkit_scroll_bars}" != "no"; then
2200   if test "${USE_X_TOOLKIT}" != "none"; then
2201     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2202       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2203       HAVE_XAW3D=no
2204       USE_TOOLKIT_SCROLL_BARS=yes
2205     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2206       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2207       USE_TOOLKIT_SCROLL_BARS=yes
2208     fi
2209   elif test "${HAVE_GTK}" = "yes"; then
2210     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2211     USE_TOOLKIT_SCROLL_BARS=yes
2212   elif test "${HAVE_NS}" = "yes"; then
2213     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2214     USE_TOOLKIT_SCROLL_BARS=yes
2215   fi
2216 fi
2217
2218 dnl See if XIM is available.
2219 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2220           #include <X11/Xlib.h>
2221           #include <X11/Xresource.h>]],
2222          [[XIMProc  callback;]])],
2223          [HAVE_XIM=yes
2224          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2225          HAVE_XIM=no)
2226
2227 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2228
2229 if test "${with_xim}" != "no"; then
2230   AC_DEFINE(USE_XIM, 1,
2231             [Define to 1 if we should use XIM, if it is available.])
2232 fi
2233
2234
2235 if test "${HAVE_XIM}" != "no"; then
2236   late_CFLAGS=$CFLAGS
2237   if test "$GCC" = yes; then
2238     CFLAGS="$CFLAGS --pedantic-errors"
2239   fi
2240   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2241 #include <X11/Xlib.h>
2242 #include <X11/Xresource.h>]],
2243 [[Display *display;
2244 XrmDatabase db;
2245 char *res_name;
2246 char *res_class;
2247 XIMProc  callback;
2248 XPointer *client_data;
2249 #ifndef __GNUC__
2250 /* If we're not using GCC, it's probably not XFree86, and this is
2251    probably right, but we can't use something like --pedantic-errors.  */
2252 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2253                                            char*, XIMProc, XPointer*);
2254 #endif
2255 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2256    client_data);]])],
2257     [emacs_cv_arg6_star=yes])
2258   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2259          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2260 either XPointer or XPointer*.])dnl
2261   if test "$emacs_cv_arg6_star" = yes; then
2262     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2263   else
2264     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2265   fi
2266   CFLAGS=$late_CFLAGS
2267 fi
2268
2269 ### Start of font-backend (under any platform) section.
2270 # (nothing here yet -- this is a placeholder)
2271 ### End of font-backend (under any platform) section.
2272
2273 ### Start of font-backend (under X11) section.
2274 if test "${HAVE_X11}" = "yes"; then
2275    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2276
2277    ## Use -lXft if available, unless `--with-xft=no'.
2278    HAVE_XFT=maybe
2279     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2280       with_xft="no";
2281     fi
2282     if test "x${with_xft}" != "xno"; then
2283
2284       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2285       ## Because xftfont.c uses XRenderQueryExtension, we also
2286       ## need to link to -lXrender.
2287       HAVE_XRENDER=no
2288       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2289       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2290         OLD_CPPFLAGS="$CPPFLAGS"
2291         OLD_CFLAGS="$CFLAGS"
2292         OLD_LIBS="$LIBS"
2293         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2294         CFLAGS="$CFLAGS $XFT_CFLAGS"
2295         XFT_LIBS="-lXrender $XFT_LIBS"
2296         LIBS="$XFT_LIBS $LIBS"
2297         AC_CHECK_HEADER(X11/Xft/Xft.h,
2298           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2299
2300         if test "${HAVE_XFT}" = "yes"; then
2301           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2302             AC_SUBST(XFT_LIBS)
2303           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2304         else
2305           CPPFLAGS="$OLD_CPPFLAGS"
2306           CFLAGS="$OLD_CFLAGS"
2307           LIBS="$OLD_LIBS"
2308         fi                        # "${HAVE_XFT}" = "yes"
2309       fi                          # "$HAVE_XFT" != no
2310     fi                            # "x${with_xft}" != "xno"
2311
2312     ## We used to allow building with FreeType and without Xft.
2313     ## However, the ftx font backend driver is not in good shape.
2314     if test "$HAVE_XFT" != "yes"; then
2315        dnl For the "Does Emacs use" message at the end.
2316        HAVE_XFT=no
2317        HAVE_FREETYPE=no
2318     else
2319        dnl Strict linkers fail with
2320        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2321        dnl if -lfreetype is not specified.
2322        dnl The following is needed to set FREETYPE_LIBS.
2323        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2324                          HAVE_FREETYPE=no)
2325
2326        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2327     fi
2328
2329     HAVE_LIBOTF=no
2330     if test "${HAVE_FREETYPE}" = "yes"; then
2331       AC_DEFINE(HAVE_FREETYPE, 1,
2332                 [Define to 1 if using the freetype and fontconfig libraries.])
2333       if test "${with_libotf}" != "no"; then
2334         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2335                           HAVE_LIBOTF=no)
2336         if test "$HAVE_LIBOTF" = "yes"; then
2337           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2338           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2339                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2340                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2341           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2342             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2343                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2344           fi
2345         fi
2346       fi
2347     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2348     dnl Does the new font backend require it, or can it work without it?
2349     fi
2350
2351     HAVE_M17N_FLT=no
2352     if test "${HAVE_LIBOTF}" = yes; then
2353       if test "${with_m17n_flt}" != "no"; then
2354         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2355         if test "$HAVE_M17N_FLT" = "yes"; then
2356           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2357         fi
2358       fi
2359     fi
2360 else
2361     HAVE_XFT=no
2362     HAVE_FREETYPE=no
2363     HAVE_LIBOTF=no
2364     HAVE_M17N_FLT=no
2365 fi
2366
2367 ### End of font-backend (under X11) section.
2368
2369 AC_SUBST(FREETYPE_CFLAGS)
2370 AC_SUBST(FREETYPE_LIBS)
2371 AC_SUBST(FONTCONFIG_CFLAGS)
2372 AC_SUBST(FONTCONFIG_LIBS)
2373 AC_SUBST(LIBOTF_CFLAGS)
2374 AC_SUBST(LIBOTF_LIBS)
2375 AC_SUBST(M17N_FLT_CFLAGS)
2376 AC_SUBST(M17N_FLT_LIBS)
2377
2378 ### Use -lXpm if available, unless `--with-xpm=no'.
2379 HAVE_XPM=no
2380 LIBXPM=
2381 if test "${HAVE_X11}" = "yes"; then
2382   if test "${with_xpm}" != "no"; then
2383     AC_CHECK_HEADER(X11/xpm.h,
2384       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2385     if test "${HAVE_XPM}" = "yes"; then
2386       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2387       AC_EGREP_CPP(no_return_alloc_pixels,
2388       [#include "X11/xpm.h"
2389 #ifndef XpmReturnAllocPixels
2390 no_return_alloc_pixels
2391 #endif
2392       ], HAVE_XPM=no, HAVE_XPM=yes)
2393
2394       if test "${HAVE_XPM}" = "yes"; then
2395         AC_MSG_RESULT(yes)
2396       else
2397         AC_MSG_RESULT(no)
2398       fi
2399     fi
2400   fi
2401
2402   if test "${HAVE_XPM}" = "yes"; then
2403     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2404     LIBXPM=-lXpm
2405   fi
2406 fi
2407 AC_SUBST(LIBXPM)
2408
2409 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2410 HAVE_JPEG=no
2411 LIBJPEG=
2412 if test "${HAVE_X11}" = "yes"; then
2413   if test "${with_jpeg}" != "no"; then
2414     dnl Checking for jpeglib.h can lose because of a redefinition of
2415     dnl  HAVE_STDLIB_H.
2416     AC_CHECK_HEADER(jerror.h,
2417       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2418   fi
2419
2420   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2421   if test "${HAVE_JPEG}" = "yes"; then
2422     AC_DEFINE(HAVE_JPEG)
2423     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2424         [#include <jpeglib.h>
2425          version=JPEG_LIB_VERSION
2426 ],
2427         [AC_DEFINE(HAVE_JPEG)],
2428         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2429         HAVE_JPEG=no])
2430   fi
2431   if test "${HAVE_JPEG}" = "yes"; then
2432     LIBJPEG=-ljpeg
2433   fi
2434 fi
2435 AC_SUBST(LIBJPEG)
2436
2437 ### Use -lpng if available, unless `--with-png=no'.
2438 HAVE_PNG=no
2439 LIBPNG=
2440 if test "${HAVE_X11}" = "yes"; then
2441   if test "${with_png}" != "no"; then
2442     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2443     # in /usr/include/libpng.
2444     AC_CHECK_HEADERS(png.h libpng/png.h)
2445     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2446       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2447     fi
2448   fi
2449
2450   if test "${HAVE_PNG}" = "yes"; then
2451     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2452     LIBPNG="-lpng -lz -lm"
2453   fi
2454 fi
2455 AC_SUBST(LIBPNG)
2456
2457 ### Use -ltiff if available, unless `--with-tiff=no'.
2458 HAVE_TIFF=no
2459 LIBTIFF=
2460 if test "${HAVE_X11}" = "yes"; then
2461   if test "${with_tiff}" != "no"; then
2462     AC_CHECK_HEADER(tiffio.h,
2463       [tifflibs="-lz -lm"
2464       # At least one tiff package requires the jpeg library.
2465       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2466       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2467   fi
2468
2469   if test "${HAVE_TIFF}" = "yes"; then
2470     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2471     dnl FIXME -lz -lm, as per libpng?
2472     LIBTIFF=-ltiff
2473   fi
2474 fi
2475 AC_SUBST(LIBTIFF)
2476
2477 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2478 HAVE_GIF=no
2479 LIBGIF=
2480 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2481   AC_CHECK_HEADER(gif_lib.h,
2482 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2483 # Earlier versions can crash Emacs.
2484     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2485
2486   if test "$HAVE_GIF" = yes; then
2487     LIBGIF=-lgif
2488   elif test "$HAVE_GIF" = maybe; then
2489 # If gif_lib.h but no libgif, try libungif.
2490     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2491     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2492   fi
2493
2494   if test "${HAVE_GIF}" = "yes"; then
2495     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2496   fi
2497 fi
2498 AC_SUBST(LIBGIF)
2499
2500 dnl Check for required libraries.
2501 if test "${HAVE_X11}" = "yes"; then
2502   MISSING=""
2503   WITH_NO=""
2504   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2505     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2506   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2507     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2508   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2509     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2510   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2511     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2512   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2513     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2514
2515   if test "X${MISSING}" != X; then
2516     AC_MSG_ERROR([The following required libraries were not found:
2517     $MISSING
2518 Maybe some development libraries/packages are missing?
2519 If you don't want to link with them give
2520     $WITH_NO
2521 as options to configure])
2522   fi
2523 fi
2524
2525 ### Use -lgpm if available, unless `--with-gpm=no'.
2526 HAVE_GPM=no
2527 LIBGPM=
2528 if test "${with_gpm}" != "no"; then
2529   AC_CHECK_HEADER(gpm.h,
2530     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2531
2532   if test "${HAVE_GPM}" = "yes"; then
2533     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2534     LIBGPM=-lgpm
2535   fi
2536 fi
2537 AC_SUBST(LIBGPM)
2538
2539 dnl Check for malloc/malloc.h on darwin
2540 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
2541
2542 GNUSTEP_CFLAGS=
2543 ### Use NeXTstep API to implement GUI.
2544 if test "${HAVE_NS}" = "yes"; then
2545   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2546   if test "${NS_IMPL_COCOA}" = "yes"; then
2547     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2548   fi
2549   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2550     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2551     # See also .m.o rule in Makefile.in */
2552     # FIXME: are all these flags really needed?  Document here why.  */
2553     GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
2554     ## Extra CFLAGS applied to src/*.m files.
2555     GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2556   fi
2557   # We also have mouse menus.
2558   HAVE_MENUS=yes
2559   OTHER_FILES=ns-app
2560 fi
2561
2562
2563 ### Use session management (-lSM -lICE) if available
2564 HAVE_X_SM=no
2565 LIBXSM=
2566 if test "${HAVE_X11}" = "yes"; then
2567   AC_CHECK_HEADER(X11/SM/SMlib.h,
2568     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2569
2570   if test "${HAVE_X_SM}" = "yes"; then
2571     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2572     LIBXSM="-lSM -lICE"
2573     case "$LIBS" in
2574       *-lSM*) ;;
2575       *)      LIBS="$LIBXSM $LIBS" ;;
2576     esac
2577   fi
2578 fi
2579 AC_SUBST(LIBXSM)
2580
2581 ### Use libxml (-lxml2) if available
2582 HAVE_LIBXML2=no
2583 if test "${with_xml2}" != "no"; then
2584   ### I'm not sure what the version number should be, so I just guessed.
2585   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2586   if test "${HAVE_LIBXML2}" = "yes"; then
2587     LIBS="$LIBXML2_LIBS $LIBS"
2588     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2589     if test "${HAVE_LIBXML2}" = "yes"; then
2590       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2591     else
2592       LIBXML2_LIBS=""
2593       LIBXML2_CFLAGS=""
2594     fi
2595   fi
2596 fi
2597 AC_SUBST(LIBXML2_LIBS)
2598 AC_SUBST(LIBXML2_CFLAGS)
2599
2600 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2601 AC_CACHE_CHECK(whether netdb declares h_errno,
2602                emacs_cv_netdb_declares_h_errno,
2603 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
2604   [[return h_errno;]])],
2605   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2606 if test $emacs_cv_netdb_declares_h_errno = yes; then
2607   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2608 fi
2609
2610 # fmod, logb, and frexp are found in -lm on most systems.
2611 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2612 AC_CHECK_LIB(m, sqrt)
2613
2614 # Check for mail-locking functions in a "mail" library.  Probably this should
2615 # have the same check as for liblockfile below.
2616 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2617 if test $have_mail = yes; then
2618   LIBS_MAIL=-lmail
2619   LIBS="$LIBS_MAIL $LIBS"
2620   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2621 else
2622   LIBS_MAIL=
2623 fi
2624 dnl Debian, at least:
2625 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2626 if test $have_lockfile = yes; then
2627    LIBS_MAIL=-llockfile
2628    LIBS="$LIBS_MAIL $LIBS"
2629    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2630 else
2631 # If we have the shared liblockfile, assume we must use it for mail
2632 # locking (e.g. Debian).  If we couldn't link against liblockfile
2633 # (no liblockfile.a installed), ensure that we don't need to.
2634   dnl This works for files generally, not just executables.
2635   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2636   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2637                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2638   if test $ac_cv_prog_liblockfile = yes; then
2639     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2640 This probably means that movemail could lose mail.
2641 There may be a `development' package to install containing liblockfile.])
2642   fi
2643 fi
2644 AC_CHECK_FUNCS(touchlock)
2645 AC_CHECK_HEADERS_ONCE(maillock.h)
2646 AC_SUBST(LIBS_MAIL)
2647
2648 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2649 ## interlock access to the mail spool.  The alternative is a lock file named
2650 ## /usr/spool/mail/$USER.lock.
2651 mail_lock=no
2652 case "$opsys" in
2653   aix4-2) mail_lock="lockf" ;;
2654
2655   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2656
2657   ## On GNU/Linux systems, both methods are used by various mail programs.
2658   ## I assume most people are using newer mailers that have heard of flock.
2659   ## Change this if you need to.
2660   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2661   ## configure gets the right answers, and that means *NOT* using flock.
2662   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2663   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2664   ## Debian maintainer hasn't provided a clean fix for Emacs.
2665   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2666   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2667   ## correct logic.  -- fx
2668   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2669   ## liblockfile is a Free Software replacement for libmail, used on
2670   ## Debian systems and elsewhere. -rfr.
2671   gnu-*)
2672     mail_lock="flock"
2673     if test $have_mail = yes || test $have_lockfile = yes; then
2674       test $ac_cv_header_maillock_h = yes && mail_lock=no
2675     fi
2676     ;;
2677 esac
2678
2679 BLESSMAIL_TARGET=
2680 case "$mail_lock" in
2681   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2682
2683   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2684
2685   *) BLESSMAIL_TARGET="need-blessmail" ;;
2686 esac
2687 AC_SUBST(BLESSMAIL_TARGET)
2688
2689
2690 AC_CHECK_FUNCS(gethostname \
2691 rename closedir mkdir rmdir getrusage get_current_dir_name \
2692 random lrand48 logb frexp fmod rint cbrt setsid \
2693 strerror fpathconf select euidaccess getpagesize setlocale \
2694 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2695 __fpending strsignal setitimer \
2696 sendto recvfrom getsockname getpeername \
2697 gai_strerror mkstemp getline getdelim fsync sync \
2698 difftime posix_memalign \
2699 getpwent endpwent getgrent endgrent \
2700 cfmakeraw cfsetspeed copysign __executable_start)
2701
2702 dnl Cannot use AC_CHECK_FUNCS
2703 AC_CACHE_CHECK([for __builtin_unwind_init],
2704                emacs_cv_func___builtin_unwind_init,
2705 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2706                 emacs_cv_func___builtin_unwind_init=yes,
2707                 emacs_cv_func___builtin_unwind_init=no)])
2708 if test $emacs_cv_func___builtin_unwind_init = yes; then
2709   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2710             [Define to 1 if you have the `__builtin_unwind_init' function.])
2711 fi
2712
2713 AC_CHECK_HEADERS_ONCE(sys/un.h)
2714
2715 AC_FUNC_FSEEKO
2716
2717 AC_FUNC_GETPGRP
2718
2719 # UNIX98 PTYs.
2720 AC_CHECK_FUNCS(grantpt)
2721
2722 # PTY-related GNU extensions.
2723 AC_CHECK_FUNCS(getpt)
2724
2725 # Check this now, so that we will NOT find the above functions in ncurses.
2726 # That is because we have not set up to link ncurses in lib-src.
2727 # It's better to believe a function is not available
2728 # than to expect to find it in ncurses.
2729 # Also we need tputs and friends to be able to build at all.
2730 AC_MSG_CHECKING([for library containing tputs])
2731 # Run a test program that contains a call to tputs, a call that is
2732 # never executed.  This tests whether a pre-'main' dynamic linker
2733 # works with the library.  It's too much trouble to actually call
2734 # tputs in the test program, due to portability hassles.  When
2735 # cross-compiling, assume the test program will run if it links.
2736 AC_DEFUN([tputs_link_source], [
2737   AC_LANG_SOURCE(
2738      [[extern void tputs (const char *, int, int (*)(int));
2739        int main (int argc, char **argv)
2740        {
2741           if (argc == 10000)
2742             tputs (argv[0], 0, 0);
2743           return 0;
2744        }]])
2745 ])
2746 # Maybe curses should be tried earlier?
2747 # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
2748 for tputs_library in '' tinfo ncurses terminfo termcap curses; do
2749   OLIBS=$LIBS
2750   if test -z "$tputs_library"; then
2751     LIBS_TERMCAP=
2752     msg='none required'
2753   else
2754     LIBS_TERMCAP=-l$tputs_library
2755     msg=$LIBS_TERMCAP
2756     LIBS="$LIBS_TERMCAP $LIBS"
2757   fi
2758   AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
2759     [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
2760   LIBS=$OLIBS
2761   if test "X$msg" != Xno; then
2762     break
2763   fi
2764 done
2765 AC_MSG_RESULT([$msg])
2766 if test "X$msg" = Xno; then
2767   AC_MSG_ERROR([The required function `tputs' was not found in any library.
2768 The following libraries were tried (in order):
2769   libtinfo, libncurses, libterminfo, libtermcap, libcurses
2770 Please try installing whichever of these libraries is most appropriate
2771 for your system, together with its header files.
2772 For example, a libncurses-dev(el) or similar package.])
2773 fi
2774
2775 ## Use termcap instead of terminfo?
2776 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
2777 TERMINFO=yes
2778 ## FIXME?  In the cases below where we unconditionally set
2779 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
2780 ## if that was found above to have tputs.
2781 ## Should we use the gnu* logic everywhere?
2782 case "$opsys" in
2783   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2784   ##  The ncurses library has been moved out of the System framework in
2785   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2786   ##  option to use it.
2787   darwin) LIBS_TERMCAP="-lncurses" ;;
2788
2789   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
2790
2791   freebsd)
2792     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2793     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2794     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
2795 [[#if __FreeBSD_version < 400000
2796 fail;
2797 #endif
2798 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2799
2800     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2801
2802     if test $emacs_cv_freebsd_terminfo = yes; then
2803       LIBS_TERMCAP="-lncurses"
2804     else
2805       TERMINFO=no
2806       LIBS_TERMCAP="-ltermcap"
2807     fi
2808     ;;
2809
2810   netbsd)
2811     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
2812       TERMINFO=no
2813       LIBS_TERMCAP="-ltermcap"
2814     fi
2815     ;;
2816
2817   openbsd) LIBS_TERMCAP="-lncurses" ;;
2818
2819   ## hpux: Make sure we get select from libc rather than from libcurses
2820   ##  because libcurses on HPUX 10.10 has a broken version of select.
2821   ##  We used to use -lc -lcurses, but this may be cleaner.
2822   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
2823   # set that way, now it uses the default).  Isn't this a contradiction?
2824   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2825
2826 esac
2827
2828 TERMCAP_OBJ=tparam.o
2829 if test $TERMINFO = yes; then
2830   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2831   TERMCAP_OBJ=terminfo.o
2832 fi
2833 AC_SUBST(LIBS_TERMCAP)
2834 AC_SUBST(TERMCAP_OBJ)
2835
2836
2837 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2838 resolv=no
2839 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2840 #include <arpa/nameser.h>
2841 #include <resolv.h>]],
2842     [[return res_init();]])],
2843     have_res_init=yes, have_res_init=no)
2844 if test "$have_res_init" = no; then
2845   OLIBS="$LIBS"
2846   LIBS="$LIBS -lresolv"
2847   AC_MSG_CHECKING(for res_init with -lresolv)
2848   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2849 #include <arpa/nameser.h>
2850 #include <resolv.h>]],
2851     [[return res_init();]])],
2852     have_res_init=yes, have_res_init=no)
2853   AC_MSG_RESULT($have_res_init)
2854   if test "$have_res_init" = yes ; then
2855     resolv=yes
2856   fi
2857   LIBS="$OLIBS"
2858 fi
2859
2860 if test "$have_res_init" = yes; then
2861   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2862 fi
2863
2864 # Do we need the Hesiod library to provide the support routines?
2865 LIBHESIOD=
2866 if test "$with_hesiod" != no ; then
2867   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2868   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2869      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2870                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2871   if test "$resolv" = yes ; then
2872     RESOLVLIB=-lresolv
2873   else
2874     RESOLVLIB=
2875   fi
2876   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2877         hesiod=yes, :, $RESOLVLIB)])
2878
2879   if test x"$hesiod" = xyes; then
2880     AC_DEFINE(HAVE_LIBHESIOD, 1,
2881               [Define to 1 if you have the hesiod library (-lhesiod).])
2882     LIBHESIOD=-lhesiod
2883   fi
2884 fi
2885 AC_SUBST(LIBHESIOD)
2886
2887 # Do we need libresolv (due to res_init or Hesiod)?
2888 if test "$resolv" = yes ; then
2889   AC_DEFINE(HAVE_LIBRESOLV, 1,
2890             [Define to 1 if you have the resolv library (-lresolv).])
2891   LIBRESOLV=-lresolv
2892 else
2893   LIBRESOLV=
2894 fi
2895 AC_SUBST(LIBRESOLV)
2896
2897 # These tell us which Kerberos-related libraries to use.
2898 COM_ERRLIB=
2899 CRYPTOLIB=
2900 KRB5LIB=
2901 DESLIB=
2902 KRB4LIB=
2903
2904 if test "${with_kerberos}" != no; then
2905   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2906   if test $have_com_err = yes; then
2907     COM_ERRLIB=-lcom_err
2908     LIBS="$COM_ERRLIB $LIBS"
2909     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2910   fi
2911   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2912   if test $have_crypto = yes; then
2913     CRYPTOLIB=-lcrypto
2914     LIBS="$CRYPTOLIB $LIBS"
2915     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2916   fi
2917   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2918   if test $have_k5crypto = yes; then
2919     CRYPTOLIB=-lk5crypto
2920     LIBS="$CRYPTOLIB $LIBS"
2921     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2922   fi
2923   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2924   if test $have_krb5=yes; then
2925     KRB5LIB=-lkrb5
2926     LIBS="$KRB5LIB $LIBS"
2927     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2928   fi
2929   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2930   if test "${with_kerberos5}" = no; then
2931     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2932     if test $have_des425 = yes; then
2933       DESLIB=-ldes425
2934       LIBS="$DESLIB $LIBS"
2935       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2936     else
2937       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2938       if test $have_des = yes; then
2939         DESLIB=-ldes
2940         LIBS="$DESLIB $LIBS"
2941         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2942       fi
2943     fi
2944     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2945     if test $have_krb4 = yes; then
2946       KRB4LIB=-lkrb4
2947       LIBS="$KRB4LIB $LIBS"
2948       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2949     else
2950       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2951       if test $have_krb = yes; then
2952         KRB4LIB=-lkrb
2953         LIBS="$KRB4LIB $LIBS"
2954         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2955       fi
2956     fi
2957   fi
2958
2959   if test "${with_kerberos5}" != no; then
2960     AC_CHECK_HEADERS(krb5.h,
2961       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2962                         [#include <krb5.h>])])
2963   else
2964     AC_CHECK_HEADERS(des.h,,
2965                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2966                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2967     AC_CHECK_HEADERS(krb.h,,
2968                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2969                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2970   fi
2971   AC_CHECK_HEADERS(com_err.h)
2972 fi
2973
2974 AC_SUBST(COM_ERRLIB)
2975 AC_SUBST(CRYPTOLIB)
2976 AC_SUBST(KRB5LIB)
2977 AC_SUBST(DESLIB)
2978 AC_SUBST(KRB4LIB)
2979
2980 AC_CHECK_FUNCS_ONCE(tzset)
2981 AC_MSG_CHECKING(whether localtime caches TZ)
2982 AC_CACHE_VAL(emacs_cv_localtime_cache,
2983 [if test x$ac_cv_func_tzset = xyes; then
2984 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
2985 char TZ_GMT0[] = "TZ=GMT0";
2986 char TZ_PST8[] = "TZ=PST8";
2987 main()
2988 {
2989   time_t now = time ((time_t *) 0);
2990   int hour_GMT0, hour_unset;
2991   if (putenv (TZ_GMT0) != 0)
2992     exit (1);
2993   hour_GMT0 = localtime (&now)->tm_hour;
2994   unsetenv("TZ");
2995   hour_unset = localtime (&now)->tm_hour;
2996   if (putenv (TZ_PST8) != 0)
2997     exit (1);
2998   if (localtime (&now)->tm_hour == hour_GMT0)
2999     exit (1);
3000   unsetenv("TZ");
3001   if (localtime (&now)->tm_hour != hour_unset)
3002     exit (1);
3003   exit (0);
3004 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3005 [# If we have tzset, assume the worst when cross-compiling.
3006 emacs_cv_localtime_cache=yes])
3007 else
3008         # If we lack tzset, report that localtime does not cache TZ,
3009         # since we can't invalidate the cache if we don't have tzset.
3010         emacs_cv_localtime_cache=no
3011 fi])dnl
3012 AC_MSG_RESULT($emacs_cv_localtime_cache)
3013 if test $emacs_cv_localtime_cache = yes; then
3014   AC_DEFINE(LOCALTIME_CACHE, 1,
3015             [Define to 1 if localtime caches TZ.])
3016 fi
3017
3018 if test "x$HAVE_TIMEVAL" = xyes; then
3019   AC_CHECK_FUNCS(gettimeofday)
3020   if test $ac_cv_func_gettimeofday = yes; then
3021     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
3022                    emacs_cv_gettimeofday_two_arguments,
3023     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3024 #ifdef TIME_WITH_SYS_TIME
3025 #include <sys/time.h>
3026 #include <time.h>
3027 #else
3028 #ifdef HAVE_SYS_TIME_H
3029 #include <sys/time.h>
3030 #else
3031 #include <time.h>
3032 #endif
3033 #endif]],
3034       [[struct timeval time;
3035        gettimeofday (&time, 0);]])],
3036       emacs_cv_gettimeofday_two_arguments=yes,
3037       emacs_cv_gettimeofday_two_arguments=no)])
3038     if test $emacs_cv_gettimeofday_two_arguments = no; then
3039       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
3040                 [Define to 1 if gettimeofday accepts only one argument.])
3041     fi
3042   fi
3043 fi
3044
3045 ok_so_far=yes
3046 AC_CHECK_FUNC(socket, , ok_so_far=no)
3047 if test $ok_so_far = yes; then
3048   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3049 fi
3050 if test $ok_so_far = yes; then
3051   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3052 fi
3053 if test $ok_so_far = yes; then
3054 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3055   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3056             [Define to 1 if you have inet sockets.])
3057 fi
3058
3059 if test -f /usr/lpp/X11/bin/smt.exp; then
3060   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3061             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3062 fi
3063
3064 AC_MSG_CHECKING(whether system supports dynamic ptys)
3065 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3066   AC_MSG_RESULT(yes)
3067   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3068 else
3069   AC_MSG_RESULT(no)
3070 fi
3071
3072 AC_FUNC_FORK
3073
3074 AC_CHECK_FUNCS(snprintf)
3075
3076 dnl Adapted from Haible's version.
3077 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3078   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3079     [[char* cs = nl_langinfo(CODESET);]])],
3080     emacs_cv_langinfo_codeset=yes,
3081     emacs_cv_langinfo_codeset=no)
3082   ])
3083 if test $emacs_cv_langinfo_codeset = yes; then
3084   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3085     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3086 fi
3087
3088 AC_TYPE_MBSTATE_T
3089
3090 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3091   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3092                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3093 if test "$emacs_cv_c_restrict_arr" = yes; then
3094   AC_DEFINE(__restrict_arr, __restrict,
3095     [Define to compiler's equivalent of C99 restrict keyword in array
3096      declarations.  Define as empty for no equivalent.])
3097 fi
3098
3099 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3100 dnl how the tty code is related to POSIX and/or other versions of termios.
3101 dnl The following looks like a useful start.
3102 dnl
3103 dnl AC_SYS_POSIX_TERMIOS
3104 dnl if test $ac_cv_sys_posix_termios = yes; then
3105 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3106 dnl                                and macros for terminal control.])
3107 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3108 dnl fi
3109
3110 # Set up the CFLAGS for real compilation, so we can substitute it.
3111 CFLAGS="$REAL_CFLAGS"
3112 CPPFLAGS="$REAL_CPPFLAGS"
3113
3114 ## Hack to detect a buggy GCC version.
3115 if test "x$GCC" = xyes \
3116    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3117    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3118    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3119    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3120 fi
3121
3122 version=$PACKAGE_VERSION
3123
3124 ### Specify what sort of things we'll be editing into Makefile and config.h.
3125 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3126 AC_SUBST(version)
3127 AC_SUBST(configuration)
3128 ## Unused?
3129 AC_SUBST(canonical)
3130 AC_SUBST(srcdir)
3131 AC_SUBST(prefix)
3132 AC_SUBST(exec_prefix)
3133 AC_SUBST(bindir)
3134 AC_SUBST(datadir)
3135 AC_SUBST(sharedstatedir)
3136 AC_SUBST(libexecdir)
3137 AC_SUBST(mandir)
3138 AC_SUBST(infodir)
3139 AC_SUBST(lispdir)
3140 AC_SUBST(leimdir)
3141 AC_SUBST(locallisppath)
3142 AC_SUBST(lisppath)
3143 AC_SUBST(x_default_search_path)
3144 AC_SUBST(etcdir)
3145 AC_SUBST(archlibdir)
3146 AC_SUBST(docdir)
3147 AC_SUBST(bitmapdir)
3148 AC_SUBST(gamedir)
3149 AC_SUBST(gameuser)
3150 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3151 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3152 ## end of LIBX_BASE, but nothing ever set it.
3153 AC_SUBST(LD_SWITCH_X_SITE)
3154 AC_SUBST(C_SWITCH_X_SITE)
3155 AC_SUBST(GNUSTEP_CFLAGS)
3156 AC_SUBST(CFLAGS)
3157 ## Used in lwlib/Makefile.in.
3158 AC_SUBST(X_TOOLKIT_TYPE)
3159 S_FILE="\$(srcdir)/${opsysfile}"
3160 AC_SUBST(S_FILE)
3161 AC_SUBST(ns_appdir)
3162 AC_SUBST(ns_appbindir)
3163 AC_SUBST(ns_appresdir)
3164 AC_SUBST(ns_appsrc)
3165 AC_SUBST(GNU_OBJC_CFLAGS)
3166 AC_SUBST(OTHER_FILES)
3167
3168 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3169                    [Define to the canonical Emacs configuration name.])
3170 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3171                    [Define to the options passed to configure.])
3172 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3173                    [Define to the used os dependent file.])
3174
3175 XMENU_OBJ=
3176 XOBJ=
3177 FONT_OBJ=
3178 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3179   AC_DEFINE(HAVE_X_WINDOWS, 1,
3180             [Define to 1 if you want to use the X window system.])
3181   XMENU_OBJ=xmenu.o
3182   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3183   FONT_OBJ=xfont.o
3184   if test "$HAVE_XFT" = "yes"; then
3185     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3186   elif test "$HAVE_FREETYPE" = "yes"; then
3187     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3188   fi
3189   AC_SUBST(FONT_OBJ)
3190 fi
3191 AC_SUBST(XMENU_OBJ)
3192 AC_SUBST(XOBJ)
3193 AC_SUBST(FONT_OBJ)
3194
3195 WIDGET_OBJ=
3196 MOTIF_LIBW=
3197 if test "${USE_X_TOOLKIT}" != "none" ; then
3198   WIDGET_OBJ=widget.o
3199   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3200   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3201     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3202   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3203     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3204     MOTIF_LIBW=-lXm
3205     case "$opsys" in
3206       gnu-linux)
3207         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3208         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3209         ;;
3210
3211       unixware)
3212         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3213         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3214         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3215         ;;
3216
3217       aix4-2)
3218         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3219         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3220         ;;
3221     esac
3222     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3223   fi
3224 fi
3225 AC_SUBST(WIDGET_OBJ)
3226
3227 TOOLKIT_LIBW=
3228 case "$USE_X_TOOLKIT" in
3229   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3230   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3231   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3232 esac
3233 AC_SUBST(TOOLKIT_LIBW)
3234
3235 if test "$USE_X_TOOLKIT" = "none"; then
3236   LIBXT_OTHER="\$(LIBXSM)"
3237   OLDXMENU_TARGET="really-oldXMenu"
3238 else
3239   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3240   OLDXMENU_TARGET="really-lwlib"
3241 fi
3242 AC_SUBST(LIBXT_OTHER)
3243
3244 ## The X Menu stuff is present in the X10 distribution, but missing
3245 ## from X11.  If we have X10, just use the installed library;
3246 ## otherwise, use our own copy.
3247 if test "${HAVE_X11}" = "yes" ; then
3248   AC_DEFINE(HAVE_X11, 1,
3249             [Define to 1 if you want to use version 11 of X windows.
3250              Otherwise, Emacs expects to use version 10.])
3251
3252   if test "$USE_X_TOOLKIT" = "none"; then
3253     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
3254   else
3255     OLDXMENU="\${lwlibdir}/liblw.a"
3256   fi
3257   LIBXMENU="\$(OLDXMENU)"
3258   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3259   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3260 else
3261   ## For a syntactically valid Makefile; not actually used for anything.
3262   ## See comments in src/Makefile.in.
3263   OLDXMENU=nothing
3264   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3265   if test "${HAVE_X_WINDOWS}" = "yes"; then
3266     LIBXMENU="-lXMenu"
3267   else
3268     LIBXMENU=
3269   fi
3270   LIBX_OTHER=
3271   OLDXMENU_DEPS=
3272 fi
3273
3274 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3275   OLDXMENU_TARGET=
3276   OLDXMENU=nothing
3277   LIBXMENU=
3278   OLDXMENU_DEPS=
3279 fi
3280
3281 AC_SUBST(OLDXMENU_TARGET)
3282 AC_SUBST(OLDXMENU)
3283 AC_SUBST(LIBXMENU)
3284 AC_SUBST(LIBX_OTHER)
3285 AC_SUBST(OLDXMENU_DEPS)
3286
3287 if test "${HAVE_MENUS}" = "yes" ; then
3288   AC_DEFINE(HAVE_MENUS, 1,
3289             [Define to 1 if you have mouse menus.
3290              (This is automatic if you use X, but the option to specify it remains.)
3291              It is also defined with other window systems that support xmenu.c.])
3292 fi
3293
3294 if test "${GNU_MALLOC}" = "yes" ; then
3295   AC_DEFINE(GNU_MALLOC, 1,
3296             [Define to 1 if you want to use the GNU memory allocator.])
3297 fi
3298
3299 RALLOC_OBJ=
3300 if test "${REL_ALLOC}" = "yes" ; then
3301   AC_DEFINE(REL_ALLOC, 1,
3302             [Define REL_ALLOC if you want to use the relocating allocator for
3303              buffer space.])
3304
3305   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3306 fi
3307 AC_SUBST(RALLOC_OBJ)
3308
3309 if test "$opsys" = "cygwin"; then
3310   CYGWIN_OBJ="sheap.o"
3311   ## Cygwin differs because of its unexec().
3312   PRE_ALLOC_OBJ=
3313   POST_ALLOC_OBJ=lastfile.o
3314 else
3315   CYGWIN_OBJ=
3316   PRE_ALLOC_OBJ=lastfile.o
3317   POST_ALLOC_OBJ=
3318 fi
3319 AC_SUBST(CYGWIN_OBJ)
3320 AC_SUBST(PRE_ALLOC_OBJ)
3321 AC_SUBST(POST_ALLOC_OBJ)
3322
3323 # Configure gnulib here, now that we know LIBS.
3324 gl_ASSERT_NO_GNULIB_POSIXCHECK
3325 gl_ASSERT_NO_GNULIB_TESTS
3326 gl_INIT
3327
3328 case "$opsys" in
3329   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3330
3331   darwin)
3332    ## The -headerpad option tells ld (see man page) to leave room at the
3333    ## end of the header for adding load commands.  Needed for dumping.
3334    ## 0x690 is the total size of 30 segment load commands (at 56
3335    ## each); under Cocoa 31 commands are required.
3336    if test "$HAVE_NS" = "yes"; then
3337      libs_nsgui="-framework AppKit"
3338      headerpad_extra=6C8
3339    else
3340      libs_nsgui=
3341      headerpad_extra=690
3342    fi
3343    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3344
3345    ## This is here because src/Makefile.in did some extra fiddling around
3346    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3347    ##   #ifndef LD_SWITCH_SYSTEM
3348    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3349    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3350    ## not using gcc, darwin.
3351    ## Because this was done in src/Makefile.in, the resulting part of
3352    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3353    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3354    ## rather than LD_SWITCH_SYSTEM.
3355    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3356      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3357    ;;
3358
3359   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
3360   ## find X at run-time.
3361   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
3362   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
3363   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3364   ## had different values in configure (in ac_link) and src/Makefile.in.
3365   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3366   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
3367
3368   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3369 esac
3370
3371 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3372   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3373 fi
3374
3375 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3376
3377
3378 LD_FIRSTFLAG=
3379 ORDINARY_LINK=
3380 case "$opsys" in
3381   ## gnu: GNU needs its own crt0.
3382   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3383
3384   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3385   ## library search parth, i.e. it won't search /usr/lib for libc and
3386   ## friends.  Using -nostartfiles instead avoids this problem, and
3387   ## will also work on earlier NetBSD releases.
3388   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
3389
3390   ## powerpc*: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3391   ##   MkLinux/LinuxPPC needs this.
3392   ## s390x-* only supports opsys = gnu-linux so it can be added here.
3393   gnu-*)
3394     case "$canonical" in
3395       powerpc*|s390x-*) LD_FIRSTFLAG="-nostdlib" ;;
3396     esac
3397     ;;
3398 esac
3399
3400
3401 if test "x$ORDINARY_LINK" = "xyes"; then
3402
3403   LD_FIRSTFLAG=""
3404   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3405
3406 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
3407 ## freebsd, gnu-* not on powerpc*|s390x*.
3408 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
3409
3410   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3411   ## places that are difficult to figure out at make time.  Fortunately,
3412   ## these same versions allow you to pass arbitrary flags on to the
3413   ## linker, so there is no reason not to use it as a linker.
3414   ##
3415   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3416   ## searching for libraries in its internal directories, so we have to
3417   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3418   LD_FIRSTFLAG="-nostdlib"
3419 fi
3420
3421 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3422 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
3423
3424 AC_SUBST(LD_FIRSTFLAG)
3425
3426
3427 ## FIXME? The logic here is not precisely the same as that above.
3428 ## There is no check here for a pre-defined LD_FIRSTFLAG.
3429 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3430 LIB_GCC=
3431 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3432
3433   case "$opsys" in
3434     freebsd|netbsd|openbsd) LIB_GCC= ;;
3435
3436     gnu-*)
3437       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3438       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3439       case $host_cpu in
3440       arm*)
3441         LIB_GCC="-lgcc_s"
3442         ;;
3443       *)
3444         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3445         ## immediately undefine it again and redefine it to empty.
3446         ## Was the C_SWITCH_X_SITE part really necessary?
3447 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3448         LIB_GCC=
3449         ;;
3450       esac
3451       ;;
3452
3453     ## Ask GCC where to find libgcc.a.
3454     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3455   esac
3456 fi                              dnl if $GCC
3457 AC_SUBST(LIB_GCC)
3458
3459
3460 ## If we're using X11/GNUstep, define some consequences.
3461 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3462   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3463   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3464 fi
3465
3466
3467 AH_TOP([/* GNU Emacs site configuration template file.
3468
3469 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2012
3470   Free Software Foundation, Inc.
3471
3472 This file is part of GNU Emacs.
3473
3474 GNU Emacs is free software: you can redistribute it and/or modify
3475 it under the terms of the GNU General Public License as published by
3476 the Free Software Foundation, either version 3 of the License, or
3477 (at your option) any later version.
3478
3479 GNU Emacs is distributed in the hope that it will be useful,
3480 but WITHOUT ANY WARRANTY; without even the implied warranty of
3481 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3482 GNU General Public License for more details.
3483
3484 You should have received a copy of the GNU General Public License
3485 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3486
3487
3488 /* No code in Emacs #includes config.h twice, but some bits of code
3489    intended to work with other packages as well (like gmalloc.c)
3490    think they can include it as many times as they like.  */
3491 #ifndef EMACS_CONFIG_H
3492 #define EMACS_CONFIG_H
3493 ])dnl
3494
3495 AH_BOTTOM([
3496 /* On AIX 3 this must be included before any other include file.  */
3497 #include <alloca.h>
3498 #if ! HAVE_ALLOCA
3499 # error "alloca not available on this machine"
3500 #endif
3501
3502 /* Define AMPERSAND_FULL_NAME if you use the convention
3503    that & in the full name stands for the login id.  */
3504 /* Turned on June 1996 supposing nobody will mind it.  */
3505 #define AMPERSAND_FULL_NAME
3506
3507 /* `subprocesses' should be defined if you want to
3508    have code for asynchronous subprocesses
3509    (as used in M-x compile and M-x shell).
3510    Only MSDOS does not support this (it overrides
3511    this in its config_opsysfile below).  */
3512
3513 #define subprocesses
3514
3515 /* Include the os dependent file.  */
3516 #include config_opsysfile
3517
3518 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3519    SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.
3520   (There is probably a better place to do this, but right now the
3521    Cocoa side does this in s/darwin.h and we cannot parallel this
3522    exactly since GNUstep is multi-OS.  */
3523 #if defined HAVE_NS && defined NS_IMPL_GNUSTEP
3524 #  define SYSTEM_PURESIZE_EXTRA 30000
3525 #endif
3526
3527 #ifdef emacs /* Don't do this for lib-src.  */
3528 /* Tell regex.c to use a type compatible with Emacs.  */
3529 #define RE_TRANSLATE_TYPE Lisp_Object
3530 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3531 #ifdef make_number
3532 /* If make_number is a macro, use it.  */
3533 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3534 #else
3535 /* If make_number is a function, avoid it.  */
3536 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3537 #endif
3538 #endif
3539
3540 #include <string.h>
3541 #include <stdlib.h>
3542
3543 #if defined __GNUC__ && (__GNUC__ > 2 \
3544                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3545 #define NO_RETURN       __attribute__ ((__noreturn__))
3546 #else
3547 #define NO_RETURN       /* nothing */
3548 #endif
3549
3550 #if __GNUC__ >= 3  /* On GCC 3.0 we might get a warning.  */
3551 #define NO_INLINE __attribute__((noinline))
3552 #else
3553 #define NO_INLINE
3554 #endif
3555
3556 #if (__GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 1))
3557 #define EXTERNALLY_VISIBLE __attribute__((externally_visible))
3558 #else
3559 #define EXTERNALLY_VISIBLE
3560 #endif
3561
3562 #if __GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 7)
3563 # define ATTRIBUTE_FORMAT(spec) __attribute__ ((__format__ spec))
3564 #else
3565 # define ATTRIBUTE_FORMAT(spec) /* empty */
3566 #endif
3567
3568 #if __GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 4)
3569 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3570    ATTRIBUTE_FORMAT ((__gnu_printf__, formatstring_parameter, first_argument))
3571 #else
3572 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3573    ATTRIBUTE_FORMAT ((__printf__, formatstring_parameter, first_argument))
3574 #endif
3575
3576 /* Some versions of GNU/Linux define noinline in their headers.  */
3577 #ifdef noinline
3578 #undef noinline
3579 #endif
3580
3581 /* These won't be used automatically yet.  We also need to know, at least,
3582    that the stack is continuous.  */
3583 #ifdef __GNUC__
3584 #  ifndef GC_SETJMP_WORKS
3585   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3586 #    define GC_SETJMP_WORKS 1
3587 #  endif
3588 #endif
3589
3590 #endif /* EMACS_CONFIG_H */
3591
3592 /*
3593 Local Variables:
3594 mode: c
3595 End:
3596 */
3597 ])dnl
3598
3599 #### Report on what we decided to do.
3600 #### Report GTK as a toolkit, even if it doesn't use Xt.
3601 #### It makes printing result more understandable as using GTK sets
3602 #### toolkit_scroll_bars to yes by default.
3603 if test "${HAVE_GTK}" = "yes"; then
3604   USE_X_TOOLKIT=GTK
3605 fi
3606
3607 echo "
3608 Configured for \`${canonical}'.
3609
3610   Where should the build process find the source code?    ${srcdir}
3611   What operating system file should Emacs use?
3612         \`${opsysfile}'
3613   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3614   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3615   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3616   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3617   What window system should Emacs use?                    ${window_system}
3618   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3619
3620 if test -n "${x_includes}"; then
3621 echo "  Where do we find X Windows header files?                ${x_includes}"
3622 else
3623 echo "  Where do we find X Windows header files?                Standard dirs"
3624 fi
3625 if test -n "${x_libraries}"; then
3626 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3627 else
3628 echo "  Where do we find X Windows libraries?                   Standard dirs"
3629 fi
3630
3631 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3632 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3633 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3634 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3635 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3636 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3637 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3638 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
3639
3640 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3641 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3642 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3643 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
3644 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3645 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
3646 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
3647
3648 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3649 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3650 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3651 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3652
3653 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3654 echo
3655
3656 if test -n "${EMACSDATA}"; then
3657    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
3658 fi
3659 if test -n "${EMACSDOC}"; then
3660    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
3661 fi
3662
3663 if test $USE_XASSERTS = yes; then
3664    echo "  Compiling with asserts turned on."
3665    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3666 fi
3667
3668 echo
3669
3670 if test "$HAVE_NS" = "yes"; then
3671    echo
3672    echo "You must run \"${MAKE-make} install\" in order to test the built application.
3673 The installed application will go to nextstep/Emacs.app and can be
3674 run or moved from there."
3675    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3676       echo "The application will be fully self-contained."
3677     else
3678       echo "The lisp resources for the application will be installed under ${prefix}.
3679 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
3680 to run if these resources are not installed."
3681    fi
3682    echo
3683 fi
3684
3685 if test "${opsys}" = "cygwin"; then
3686   case `uname -r` in
3687     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
3688            echo
3689            ;;
3690   esac
3691 fi
3692
3693 # Remove any trailing slashes in these variables.
3694 [test "${prefix}" != NONE &&
3695   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3696 test "${exec_prefix}" != NONE &&
3697   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3698
3699 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
3700 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
3701 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
3702 dnl (else you get "no `Makefile.am' found for any configure output").
3703 dnl This will work, but you get a config.status that is not quite right
3704 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
3705 dnl That doesn't have any obvious consequences for Emacs, but on the whole
3706 dnl it seems better to just live with the duplication.
3707 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile"
3708
3709 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
3710        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3711        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
3712        leim/Makefile])
3713
3714 dnl test/ is not present in release tarfiles.
3715 opt_makefile=test/automated/Makefile
3716
3717 if test -f $srcdir/${opt_makefile}.in; then
3718   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
3719   dnl Again, it's best not to use a variable.  Though you can add
3720   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
3721   AC_CONFIG_FILES([test/automated/Makefile])
3722 fi
3723
3724
3725 dnl admin/ may or may not be present.
3726 opt_makefile=admin/unidata/Makefile
3727
3728 if test -f $srcdir/${opt_makefile}.in; then
3729   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
3730   AC_CONFIG_FILES([admin/unidata/Makefile])
3731 fi
3732
3733
3734 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
3735
3736 AC_SUBST(SUBDIR_MAKEFILES_IN)
3737
3738 dnl Make the necessary directories, if they don't exist.
3739 AC_CONFIG_COMMANDS([mkdirs], [
3740 for dir in etc lisp ; do
3741   test -d ${dir} || mkdir ${dir}
3742 done
3743 ])
3744
3745 dnl You might wonder (I did) why epaths.h is generated by running make,
3746 dnl rather than just letting configure generate it from epaths.in.
3747 dnl One reason is that the various paths are not fully expanded (see above);
3748 dnl eg gamedir=${prefix}/var/games/emacs.
3749 dnl Secondly, the GNU Coding standards require that one should be able
3750 dnl to run `make prefix=/some/where/else' and override the values set
3751 dnl by configure.  This also explains the `move-if-change' test and
3752 dnl the use of force in the `epaths-force' rule in Makefile.in.
3753 AC_CONFIG_COMMANDS([epaths], [
3754 echo creating src/epaths.h
3755 ${MAKE-make} epaths-force
3756 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS"])
3757
3758 AC_CONFIG_COMMANDS([gdbinit], [
3759 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3760   echo creating src/.gdbinit
3761   echo source $srcdir/src/.gdbinit > src/.gdbinit
3762 fi
3763 ])
3764
3765 AC_OUTPUT
3766
3767 dnl configure.in ends here