code.delx.au - gnu-emacs/blob - configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2011  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.0.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28 AM_INIT_AUTOMAKE
  29
  30 dnl Support for --program-prefix, --program-suffix and
  31 dnl --program-transform-name options
  32 AC_ARG_PROGRAM
  33
  34 dnl It is important that variables on the RHS not be expanded here,
  35 dnl hence the single quotes.  This is per the GNU coding standards, see
  36 dnl (autoconf) Installation Directory Variables
  37 dnl See also epaths.h below.
  38 lispdir='${datadir}/emacs/${version}/lisp'
  39 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  40 '${datadir}/emacs/site-lisp'
  41 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  42 etcdir='${datadir}/emacs/${version}/etc'
  43 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  44 docdir='${datadir}/emacs/${version}/etc'
  45 gamedir='${localstatedir}/games/emacs'
  46
  47 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  48 dnl Create a new --with option that defaults to being disabled.
  49 dnl NAME is the base name of the option.  The shell variable with_NAME
  50 dnl   will be set to either the user's value (if the option is
  51 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  52 dnl   option is not specified).  Note that the shell variable name is
  53 dnl   constructed as autoconf does, by replacing non-alphanumeric
  54 dnl   characters with "_".
  55 dnl HELP-STRING is the help text for the option.
  56 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  57   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  58     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  59 ])dnl
  60
  61 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  62 dnl Create a new --with option that defaults to being enabled.  NAME
  63 dnl   is the base name of the option.  The shell variable with_NAME
  64 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  65 dnl   'yes' (if the option is not specified).  Note that the shell
  66 dnl   variable name is constructed as autoconf does, by replacing
  67 dnl   non-alphanumeric characters with "_".
  68 dnl HELP-STRING is the help text for the option.
  69 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  70   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  71    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  72 ])dnl
  73
  74 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  75 if test "$with_pop" = yes; then
  76    AC_DEFINE(MAIL_USE_POP)
  77 fi
  78 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  79
  80 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  81 if test "$with_kerberos" != no; then
  82    AC_DEFINE(KERBEROS)
  83 fi
  84 AH_TEMPLATE(KERBEROS,
  85             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  86
  87 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  88 if test "${with_kerberos5}" != no; then
  89   if test "${with_kerberos}" = no; then
  90     with_kerberos=yes
  91     AC_DEFINE(KERBEROS)
  92   fi
  93   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  94 fi
  95
  96 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  97 dnl FIXME hesiod support may not be present, so it seems like an error
  98 dnl to define, or at least use, this unconditionally.
  99 if test "$with_hesiod" != no; then
 100   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 101 fi
 102
 103 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 104 if test "$with_mmdf" != no; then
 105    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 106 fi
 107
 108 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 109 if test "$with_mail_unlink" != no; then
 110    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 111 fi
 112
 113 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 114     [string giving default POP mail host])],
 115     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 116
 117 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 118
 119 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 120 if test "$with_sync_input" = yes; then
 121    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 122 fi
 123
 124 dnl FIXME currently it is not the last.
 125 dnl This should be the last --with option, because --with-x is
 126 dnl added later on when we find the path of X, and it's best to
 127 dnl keep them together visually.
 128 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 129  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 130 [         case "${withval}" in
 131             y | ye | yes )      val=gtk ;;
 132             n | no )            val=no  ;;
 133             l | lu | luc | luci | lucid )       val=lucid ;;
 134             a | at | ath | athe | athen | athena )      val=athena ;;
 135             m | mo | mot | moti | motif )       val=motif ;;
 136             g | gt | gtk  )     val=gtk ;;
 137             gtk3  )     val=gtk3 ;;
 138             * )
 139 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 140 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 141 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 142             ;;
 143           esac
 144           with_x_toolkit=$val
 145 ])
 146
 147 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 148 if test "$with_wide_int" = yes; then
 149   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 150 fi
 151
 152 dnl _ON results in a '--without' option in the --help output, so
 153 dnl the help text should refer to "don't compile", etc.
 154 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 155 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 156 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 157 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 158 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 159 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 160 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 161 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 162
 163 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 164 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 165 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 166
 167 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 168 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 169 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 170 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 171
 172 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 173 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 174 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 175 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 176 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 177 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 178
 179 ## For the times when you want to build Emacs but don't have
 180 ## a suitable makeinfo, and can live without the manuals.
 181 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 182 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 183
 184 ## This is an option because I do not know if all info/man support
 185 ## compressed files, nor how to test if they do so.
 186 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 187 if test $with_compress_info = yes; then
 188    GZIP_INFO=yes
 189 else
 190    GZIP_INFO=
 191 fi
 192 AC_SUBST(GZIP_INFO)
 193
 194 AC_ARG_WITH([pkg-config-prog],dnl
 195 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 196                   [path to pkg-config for finding GTK and librsvg])])
 197 if test "X${with_pkg_config_prog}" != X; then
 198    if test "${with_pkg_config_prog}" != yes; then
 199       PKG_CONFIG="${with_pkg_config_prog}"
 200    fi
 201 fi
 202
 203 CRT_DIR=
 204 AC_ARG_WITH([crt-dir],dnl
 205 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 206 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 207 CRT_DIR="${with_crt_dir}"
 208
 209 AC_ARG_WITH(gameuser,dnl
 210 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 211 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 212   && gameuser="${with_gameuser}"
 213 test "X$gameuser" = X && gameuser=games
 214
 215 AC_ARG_WITH([gnustep-conf],dnl
 216 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 217 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 218   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 219 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 220      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 221
 222 AC_ARG_ENABLE(ns-self-contained,
 223 [AS_HELP_STRING([--disable-ns-self-contained],
 224                 [disable self contained build under NeXTstep])],
 225    EN_NS_SELF_CONTAINED=$enableval,
 226    EN_NS_SELF_CONTAINED=yes)
 227
 228 AC_ARG_ENABLE(asserts,
 229 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 230       USE_XASSERTS=$enableval,
 231       USE_XASSERTS=no)
 232
 233 AC_ARG_ENABLE(maintainer-mode,
 234 [AS_HELP_STRING([--enable-maintainer-mode],
 235                 [enable make rules and dependencies not useful (and sometimes
 236                  confusing) to the casual installer])],
 237       USE_MAINTAINER_MODE=$enableval,
 238       USE_MAINTAINER_MODE=yes)
 239 if test $USE_MAINTAINER_MODE = yes; then
 240   MAINT=
 241 else
 242   MAINT=#
 243 fi
 244 AC_SUBST(MAINT)
 245
 246 AC_ARG_ENABLE(locallisppath,
 247 [AS_HELP_STRING([--enable-locallisppath=PATH],
 248                 [directories Emacs should search for lisp files specific
 249                  to this site])],
 250 if test "${enableval}" = "no"; then
 251   locallisppath=
 252 elif test "${enableval}" != "yes"; then
 253   locallisppath=${enableval}
 254 fi)
 255
 256 AC_ARG_ENABLE(checking,
 257 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 258                 [enable expensive run-time checks.  With LIST,
 259                  enable only specific categories of checks.
 260                  Categories are: all,yes,no.
 261                  Flags are: stringbytes, stringoverrun, stringfreelist,
 262                  xmallocoverrun, conslist])],
 263 [ac_checking_flags="${enableval}"],[])
 264 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 265 for check in $ac_checking_flags
 266 do
 267         case $check in
 268         # these set all the flags to specific states
 269         yes)            ac_enable_checking=1 ;;
 270         no)             ac_enable_checking= ;
 271                         ac_gc_check_stringbytes= ;
 272                         ac_gc_check_string_overrun= ;
 273                         ac_gc_check_string_free_list= ;
 274                         ac_xmalloc_overrun= ;
 275                         ac_gc_check_cons_list= ;;
 276         all)            ac_enable_checking=1 ;
 277                         ac_gc_check_stringbytes=1 ;
 278                         ac_gc_check_string_overrun=1 ;
 279                         ac_gc_check_string_free_list=1 ;
 280                         ac_xmalloc_overrun=1 ;
 281                         ac_gc_check_cons_list=1 ;;
 282         # these enable particular checks
 283         stringbytes)    ac_gc_check_stringbytes=1 ;;
 284         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 285         stringfreelist) ac_gc_check_string_free_list=1 ;;
 286         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 287         conslist)       ac_gc_check_cons_list=1 ;;
 288         *)      AC_MSG_ERROR(unknown check category $check) ;;
 289         esac
 290 done
 291 IFS="$ac_save_IFS"
 292
 293 if test x$ac_enable_checking != x ; then
 294   AC_DEFINE(ENABLE_CHECKING, 1,
 295 [Enable expensive run-time checking of data types?])
 296 fi
 297 if test x$ac_gc_check_stringbytes != x ; then
 298   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 299 [Define this temporarily to hunt a bug.  If defined, the size of
 300    strings is redundantly recorded in sdata structures so that it can
 301    be compared to the sizes recorded in Lisp strings.])
 302 fi
 303 if test x$ac_gc_check_string_overrun != x ; then
 304   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 305 [Define this to check for short string overrun.])
 306 fi
 307 if test x$ac_gc_check_string_free_list != x ; then
 308   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 309 [Define this to check the string free list.])
 310 fi
 311 if test x$ac_xmalloc_overrun != x ; then
 312   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 313 [Define this to check for malloc buffer overrun.])
 314 fi
 315 if test x$ac_gc_check_cons_list != x ; then
 316   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 317 [Define this to check for errors in cons list.])
 318 fi
 319
 320 AC_ARG_ENABLE(use-lisp-union-type,
 321 [AS_HELP_STRING([--enable-use-lisp-union-type],
 322                 [use a union for the Lisp_Object data type.
 323                 This is only useful for development for catching certain types of bugs.])],
 324 if test "${enableval}" != "no"; then
 325    AC_DEFINE(USE_LISP_UNION_TYPE, 1,
 326    [Define this to use a lisp union for the Lisp_Object data type.])
 327 fi)
 328
 329
 330 AC_ARG_ENABLE(profiling,
 331 [AS_HELP_STRING([--enable-profiling],
 332                 [build emacs with profiling support.
 333                  This might not work on all platforms])],
 334 [ac_enable_profiling="${enableval}"],[])
 335 if test x$ac_enable_profiling != x ; then
 336    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 337 else
 338    PROFILING_CFLAGS=
 339 fi
 340 AC_SUBST(PROFILING_CFLAGS)
 341
 342 AC_ARG_ENABLE(autodepend,
 343 [AS_HELP_STRING([--enable-autodepend],
 344                 [automatically generate dependencies to .h-files.
 345                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 346                  found])],
 347 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 348
 349 #### Make srcdir absolute, if it isn't already.  It's important to
 350 #### avoid running the path through pwd unnecessarily, since pwd can
 351 #### give you automounter prefixes, which can go away.  We do all this
 352 #### so Emacs can find its files when run uninstalled.
 353 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 354 unset CDPATH
 355 case "${srcdir}" in
 356   /* ) ;;
 357   . )
 358     ## We may be able to use the $PWD environment variable to make this
 359     ## absolute.  But sometimes PWD is inaccurate.
 360     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 361     ## but that tested only for a well-formed and valid PWD,
 362     ## it did not object when PWD was well-formed and valid but just wrong.
 363     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 364     then
 365       srcdir="$PWD"
 366     else
 367       srcdir="`(cd ${srcdir}; pwd)`"
 368     fi
 369   ;;
 370   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 371 esac
 372
 373 #### Given the configuration name, set machfile and opsysfile to the
 374 #### names of the m/*.h and s/*.h files we should use.
 375
 376 ### Canonicalize the configuration name.
 377
 378 AC_CANONICAL_HOST
 379 canonical=$host
 380 configuration=${host_alias-${build_alias-$host}}
 381
 382 dnl This used to use changequote, but, apart from `changequote is evil'
 383 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 384 dnl the great gob of text.  Thus it's not processed for possible expansion.
 385 dnl Just make sure the brackets remain balanced.
 386 dnl
 387 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 388 dnl indicated by comments.
 389 dnl quotation begins
 390 [
 391
 392 ### If you add support for a new configuration, add code to this
 393 ### switch statement to recognize your configuration name and select
 394 ### the appropriate operating system and machine description files.
 395
 396 ### You would hope that you could choose an m/*.h file pretty much
 397 ### based on the machine portion of the configuration name, and an s/*.h
 398 ### file based on the operating system portion.  However, it turns out
 399 ### that each m/*.h file is pretty manufacturer-specific - for
 400 ### example mips.h is MIPS
 401 ### So we basically have to have a special case for each
 402 ### configuration name.
 403 ###
 404 ### As far as handling version numbers on operating systems is
 405 ### concerned, make sure things will fail in a fixable way.  If
 406 ### /etc/MACHINES doesn't say anything about version numbers, be
 407 ### prepared to handle anything reasonably.  If version numbers
 408 ### matter, be sure /etc/MACHINES says something about it.
 409
 410 machine='' opsys='' unported=no
 411 case "${canonical}" in
 412
 413   ## GNU/Linux ports
 414   *-*-linux-gnu*)
 415     opsys=gnu-linux
 416     case ${canonical} in
 417       alpha*)   machine=alpha ;;
 418       s390-*)   machine=ibms390 ;;
 419       s390x-*)  machine=ibms390x ;;
 420       powerpc*) machine=macppc ;;
 421       sparc*)   machine=sparc ;;
 422       ia64*)    machine=ia64 ;;
 423       m68k*)    machine=m68k ;;
 424       x86_64*)  machine=amdx86-64 ;;
 425     esac
 426   ;;
 427
 428   ## FreeBSD ports
 429   *-*-freebsd* )
 430     opsys=freebsd
 431     case "${canonical}" in
 432       alpha*)           machine=alpha ;;
 433       amd64-*|x86_64-*) machine=amdx86-64 ;;
 434       ia64-*)           machine=ia64 ;;
 435       i[3456]86-*)      machine=intel386 ;;
 436       powerpc-*)        machine=macppc ;;
 437       sparc-*)          machine=sparc ;;
 438       sparc64-*)        machine=sparc ;;
 439     esac
 440   ;;
 441
 442   ## FreeBSD kernel + glibc based userland
 443   *-*-kfreebsd*gnu* )
 444     opsys=gnu-kfreebsd
 445     case "${canonical}" in
 446       alpha*)           machine=alpha ;;
 447       amd64-*|x86_64-*) machine=amdx86-64 ;;
 448       ia64-*)           machine=ia64 ;;
 449       i[3456]86-*)      machine=intel386 ;;
 450       powerpc-*)        machine=macppc ;;
 451       sparc-*)          machine=sparc ;;
 452       sparc64-*)        machine=sparc ;;
 453     esac
 454   ;;
 455
 456   ## NetBSD ports
 457   *-*-netbsd* )
 458     opsys=netbsd
 459     case "${canonical}" in
 460       alpha*)      machine=alpha ;;
 461       x86_64-*)    machine=amdx86-64 ;;
 462       i[3456]86-*) machine=intel386 ;;
 463       m68k-*)      machine=m68k ;;
 464       powerpc-*)   machine=macppc ;;
 465       sparc*-)     machine=sparc ;;
 466       vax-*)       machine=vax ;;
 467     esac
 468   ;;
 469
 470   ## OpenBSD ports
 471   *-*-openbsd* )
 472     opsys=openbsd
 473     case "${canonical}" in
 474       alpha*)    machine=alpha ;;
 475       x86_64-*)  machine=amdx86-64 ;;
 476       i386-*)    machine=intel386 ;;
 477       powerpc-*) machine=macppc ;;
 478       sparc*)    machine=sparc ;;
 479       vax-*)     machine=vax ;;
 480     esac
 481   ;;
 482
 483   ## Apple Darwin / Mac OS X
 484   *-apple-darwin* )
 485     case "${canonical}" in
 486       i[3456]86-* )  machine=intel386 ;;
 487       powerpc-* )    machine=macppc ;;
 488       x86_64-* )     machine=amdx86-64 ;;
 489       * )            unported=yes ;;
 490     esac
 491     opsys=darwin
 492     # Define CPP as follows to make autoconf work correctly.
 493     CPP="${CC-cc} -E -no-cpp-precomp"
 494     # Use fink packages if available.
 495     if test -d /sw/include && test -d /sw/lib; then
 496       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 497       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 498       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 499     fi
 500   ;;
 501
 502   ## HP 9000 series 700 and 800, running HP/UX
 503   hppa*-hp-hpux10.2* )
 504     opsys=hpux10-20
 505   ;;
 506   hppa*-hp-hpux1[1-9]* )
 507     opsys=hpux11
 508     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 509   ;;
 510
 511   ia64*-hp-hpux1[1-9]* )
 512     machine=hp800 opsys=hpux11
 513     ## FIXME.  Peter O'Gorman reports that dumping using unexelf.o doesn't
 514     ## work either: http://debbugs.gnu.org/cgi/bugreport.cgi?bug=6811
 515     CANNOT_DUMP=yes
 516   ;;
 517
 518   hppa*-*-linux-gnu* )
 519     machine=hp800 opsys=gnu-linux
 520   ;;
 521
 522   ## IBM machines
 523   rs6000-ibm-aix4.[23]* )
 524     machine=ibmrs6000 opsys=aix4-2
 525   ;;
 526   powerpc-ibm-aix4.[23]*  )
 527     machine=ibmrs6000 opsys=aix4-2
 528   ;;
 529   rs6000-ibm-aix[56]* )
 530     machine=ibmrs6000 opsys=aix4-2
 531   ;;
 532   powerpc-ibm-aix[56]*  )
 533     machine=ibmrs6000 opsys=aix4-2
 534   ;;
 535
 536   ## Silicon Graphics machines
 537   ## Iris 4D
 538   mips-sgi-irix6.5 )
 539     machine=iris4d opsys=irix6-5
 540     # Without defining _LANGUAGE_C, things get masked out in the headers
 541     # so that, for instance, grepping for `free' in stdlib.h fails and
 542     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 543     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 544     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 545   ;;
 546
 547   ## Suns
 548   *-sun-solaris* \
 549     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 550     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 551     case "${canonical}" in
 552       i[3456]86-*-* )     machine=intel386 ;;
 553       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 554       sparc* )          machine=sparc ;;
 555       * )               unported=yes ;;
 556     esac
 557     case "${canonical}" in
 558       *-sunos5.6* | *-solaris2.6* )
 559                 opsys=sol2-6
 560                 NON_GNU_CPP=/usr/ccs/lib/cpp
 561                 RANLIB="ar -ts"
 562                 ;;
 563       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 564                 opsys=sol2-6
 565                 emacs_check_sunpro_c=yes
 566                 NON_GNU_CPP=/usr/ccs/lib/cpp
 567                 ;;
 568       *-sunos5* | *-solaris* )
 569                 opsys=sol2-10
 570                 emacs_check_sunpro_c=yes
 571                 NON_GNU_CPP=/usr/ccs/lib/cpp
 572                 ;;
 573     esac
 574     ## Watch out for a compiler that we know will not work.
 575     case "${canonical}" in
 576      *-solaris* | *-sunos5* )
 577                 if [ "x$CC" = x/usr/ucb/cc ]; then
 578                   ## /usr/ucb/cc doesn't work;
 579                   ## we should find some other compiler that does work.
 580                   unset CC
 581                 fi
 582                 ;;
 583       *) ;;
 584     esac
 585   ;;
 586
 587   ## Intel 386 machines where we don't care about the manufacturer.
 588   i[3456]86-*-* )
 589     machine=intel386
 590     case "${canonical}" in
 591       *-cygwin )                opsys=cygwin ;;
 592       *-darwin* )               opsys=darwin
 593                                 CPP="${CC-cc} -E -no-cpp-precomp"
 594                                 ;;
 595       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 596       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 597       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 598       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 599     esac
 600   ;;
 601
 602   * )
 603     unported=yes
 604   ;;
 605 esac
 606
 607 ### If the code above didn't choose an operating system, just choose
 608 ### an operating system based on the configuration name.  You really
 609 ### only want to use this when you have no idea what the right
 610 ### operating system is; if you know what operating systems a machine
 611 ### runs, it's cleaner to make it explicit in the case statement
 612 ### above.
 613 if test x"${opsys}" = x; then
 614   case "${canonical}" in
 615     *-gnu* )                            opsys=gnu ;;
 616     * )
 617       unported=yes
 618     ;;
 619   esac
 620 fi
 621
 622 ]
 623 dnl quotation ends
 624
 625 if test $unported = yes; then
 626   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 627 Check `etc/MACHINES' for recognized configuration names.])
 628 fi
 629
 630 if test -n "$machine"; then
 631   machfile="m/${machine}.h"
 632 else
 633   machfile=
 634 fi
 635 opsysfile="s/${opsys}.h"
 636
 637
 638 #### Choose a compiler.
 639 test -n "$CC" && cc_specified=yes
 640
 641 # Save the value of CFLAGS that the user specified.
 642 SPECIFIED_CFLAGS="$CFLAGS"
 643
 644 dnl Sets GCC=yes if using gcc.
 645 AC_PROG_CC
 646 AM_PROG_CC_C_O
 647
 648 # Initialize gnulib right after verifying that the C compiler works.
 649 gl_EARLY
 650
 651 # On Suns, sometimes $CPP names a directory.
 652 if test -n "$CPP" && test -d "$CPP"; then
 653   CPP=
 654 fi
 655
 656 ## If not using gcc, and on Solaris, and no CPP specified, see if
 657 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 658 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 659  test x"$CPP" = x; then
 660   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 661   AC_CACHE_VAL(emacs_cv_sunpro_c,
 662   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
 663 [[#ifndef __SUNPRO_C
 664 fail;
 665 #endif
 666 ]])], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 667   AC_MSG_RESULT($emacs_cv_sunpro_c)
 668
 669   if test x"$emacs_cv_sunpro_c" = xyes; then
 670     NON_GNU_CPP="$CC -E -Xs"
 671   fi
 672 fi
 673
 674 #### Some systems specify a CPP to use unless we are using GCC.
 675 #### Now that we know whether we are using GCC, we can decide whether
 676 #### to use that one.
 677 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 678 then
 679   CPP="$NON_GNU_CPP"
 680 fi
 681
 682 #### Some systems specify a CC to use unless we are using GCC.
 683 #### Now that we know whether we are using GCC, we can decide whether
 684 #### to use that one.
 685 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 686   test x$cc_specified != xyes
 687 then
 688   CC="$NON_GNU_CC"
 689 fi
 690
 691 if test x$GCC = xyes; then
 692   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 693 else
 694   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 695 fi
 696
 697 ### Use -Wdeclaration-after-statement if the compiler supports it
 698 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 699 SAVE_CFLAGS="$CFLAGS"
 700 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 701 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], has_option=yes, has_option=no)
 702 if test $has_option = yes; then
 703    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 704 fi
 705 AC_MSG_RESULT($has_option)
 706 CFLAGS="$SAVE_CFLAGS"
 707 unset has_option
 708 unset SAVE_CFLAGS
 709
 710 ### Use -Wold-style-definition if the compiler supports it
 711 # This can be removed when conversion to standard C is finished.
 712 AC_MSG_CHECKING([whether gcc understands -Wold-style-definition])
 713 SAVE_CFLAGS="$CFLAGS"
 714 CFLAGS="$CFLAGS -Wold-style-definition"
 715 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], has_option=yes, has_option=no)
 716 if test $has_option = yes; then
 717    C_WARNINGS_SWITCH="-Wold-style-definition $C_WARNINGS_SWITCH"
 718 fi
 719 AC_MSG_RESULT($has_option)
 720 CFLAGS="$SAVE_CFLAGS"
 721 unset has_option
 722 unset SAVE_CFLAGS
 723
 724 ### Use -Wimplicit-function-declaration if the compiler supports it
 725 AC_MSG_CHECKING([whether gcc understands -Wimplicit-function-declaration])
 726 SAVE_CFLAGS="$CFLAGS"
 727 CFLAGS="$CFLAGS -Wimplicit-function-declaration"
 728 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], has_option=yes, has_option=no)
 729 if test $has_option = yes; then
 730    C_WARNINGS_SWITCH="-Wimplicit-function-declaration $C_WARNINGS_SWITCH"
 731 fi
 732 AC_MSG_RESULT($has_option)
 733 CFLAGS="$SAVE_CFLAGS"
 734 unset has_option
 735 unset SAVE_CFLAGS
 736
 737 AC_SUBST(C_WARNINGS_SWITCH)
 738
 739
 740 #### Some other nice autoconf tests.
 741
 742 dnl checks for programs
 743 AC_PROG_CPP
 744 AC_PROG_INSTALL
 745 if test "x$RANLIB" = x; then
 746   AC_PROG_RANLIB
 747 fi
 748
 749 ## Although we're running on an amd64 kernel, we're actually compiling for
 750 ## the x86 architecture.  The user should probably have provided an
 751 ## explicit --build to `configure', but if everything else than the kernel
 752 ## is running in i386 mode, we can help them out.
 753 if test "$machine" = "amdx86-64"; then
 754   AC_CHECK_DECL([i386])
 755   if test "$ac_cv_have_decl_i386" = "yes"; then
 756     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 757     machine=intel386
 758     machfile="m/${machine}.h"
 759   fi
 760 fi
 761
 762 AC_PATH_PROG(INSTALL_INFO, install-info)
 763 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 764 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 765 dnl Don't use GZIP, which is used by gzip for additional parameters.
 766 AC_PATH_PROG(GZIP_PROG, gzip)
 767
 768
 769 ## Need makeinfo >= 4.6 (?) to build the manuals.
 770 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 771 dnl By this stage, configure has already checked for egrep and set EGREP,
 772 dnl or exited with an error if no egrep was found.
 773 if test "$MAKEINFO" != "no" && \
 774   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 775    MAKEINFO=no
 776 fi
 777
 778 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 779 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 780 ## therefore in the category of "special tools" not normally required, which
 781 ## configure does not have to check for (eg autoconf itself).
 782 ## In a Bazaar checkout on the other hand, the manuals are not included.
 783 ## So makeinfo is a requirement to build from Bazaar, and configure
 784 ## should test for it as it does for any other build requirement.
 785 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 786 ## with pre-built manuals, from a Bazaar checkout.
 787 HAVE_MAKEINFO=yes
 788
 789 if test "$MAKEINFO" = "no"; then
 790   MAKEINFO=makeinfo
 791   if test "x${with_makeinfo}" = "xno"; then
 792     HAVE_MAKEINFO=no
 793   elif test ! -e $srcdir/info/emacs; then
 794     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 795 source tree does not seem to have pre-built manuals in the `info' directory.
 796 Either install a suitable version of makeinfo, or re-run configure
 797 with the `--without-makeinfo' option to build without the manuals.] )
 798   fi
 799 fi
 800 AC_SUBST(HAVE_MAKEINFO)
 801
 802 dnl Add our options to ac_link now, after it is set up.
 803
 804 if test x$GCC = xyes; then
 805   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 806     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 807 else
 808   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 809     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 810 fi
 811
 812 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 813 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 814 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 815 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 816 dnl if not built to support GNU ld.
 817
 818 late_LDFLAGS=$LDFLAGS
 819 if test x$GCC = xyes; then
 820   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 821 else
 822   LDFLAGS="$LDFLAGS -znocombreloc"
 823 fi
 824
 825 AC_MSG_CHECKING([for -znocombreloc])
 826 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 827   [AC_MSG_RESULT(yes)],
 828   LDFLAGS=$late_LDFLAGS
 829   [AC_MSG_RESULT(no)])
 830
 831
 832 # The value of CPP is a quoted variable reference, so we need to do this
 833 # to get its actual value...
 834 CPP=`eval "echo $CPP"`
 835
 836
 837 dnl The function dump-emacs will not be defined and temacs will do
 838 dnl (load "loadup") automatically unless told otherwise.
 839 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 840 case "$opsys" in
 841   your-opsys-here) CANNOT_DUMP=yes ;;
 842 esac
 843
 844 test "$CANNOT_DUMP" = "yes" && \
 845   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 846
 847 AC_SUBST(CANNOT_DUMP)
 848
 849
 850 UNEXEC_OBJ=unexelf.o
 851 case "$opsys" in
 852   # MSDOS uses unexcoff.o
 853   # MSWindows uses unexw32.o
 854   aix4-2)
 855    UNEXEC_OBJ=unexaix.o
 856    ;;
 857   cygwin)
 858    UNEXEC_OBJ=unexcw.o
 859    ;;
 860   darwin)
 861    UNEXEC_OBJ=unexmacosx.o
 862    ;;
 863   hpux10-20 | hpux11)
 864    UNEXEC_OBJ=unexhp9k800.o
 865    ;;
 866   sol2-10)
 867    # Use the Solaris dldump() function, called from unexsol.c, to dump
 868    # emacs, instead of the generic ELF dump code found in unexelf.c.
 869    # The resulting binary has a complete symbol table, and is better
 870    # for debugging and other observability tools (debuggers, pstack, etc).
 871    #
 872    # If you encounter a problem using dldump(), please consider sending
 873    # a message to the OpenSolaris tools-linking mailing list:
 874    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 875    #
 876    # It is likely that dldump() works with older Solaris too, but this has
 877    # not been tested, so for now this change is for Solaris 10 or newer.
 878    UNEXEC_OBJ=unexsol.o
 879    ;;
 880 esac
 881
 882 LD_SWITCH_SYSTEM=
 883 case "$opsys" in
 884   freebsd)
 885    ## Let `ld' find image libs and similar things in /usr/local/lib.
 886    ## The system compiler, GCC, has apparently been modified to not
 887    ## look there, contrary to what a stock GCC would do.
 888    LD_SWITCH_SYSTEM=-L/usr/local/lib
 889    ;;
 890
 891   gnu-linux)
 892    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 893    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 894    ;;
 895
 896   netbsd)
 897    LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 898    ;;
 899
 900   openbsd)
 901    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 902    ## otherwise Emacs dumps core on elf systems.
 903    LD_SWITCH_SYSTEM="-Z"
 904    ;;
 905 esac
 906 AC_SUBST(LD_SWITCH_SYSTEM)
 907
 908 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 909
 910 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_AUX,
 911 ## which has not been defined yet.  When this was handled with cpp,
 912 ## it was expanded to null when configure sourced the s/*.h file.
 913 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 914 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 915 ## (or somesuch), but because it is supposed to go at the _front_
 916 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 917 ## Compare with the gnu-linux case below, which added to the end
 918 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 919 ## LD_SWITCH_SYSTEM_TEMACS.
 920 case "$opsys" in
 921   netbsd|openbsd)
 922    ## _AUX_RPATH is like _AUX, but uses -rpath instead of -R.
 923    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_AUX_RPATH) $LD_SWITCH_SYSTEM" ;;
 924 esac
 925
 926
 927 C_SWITCH_MACHINE=
 928 if test "$machine" = "alpha"; then
 929   AC_CHECK_DECL([__ELF__])
 930   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 931     ## With ELF, make sure that all common symbols get allocated to in the
 932     ## data section.  Otherwise, the dump of temacs may miss variables in
 933     ## the shared library that have been initialized.  For example, with
 934     ## GNU libc, __malloc_initialized would normally be resolved to the
 935     ## shared library's .bss section, which is fatal.
 936     if test "x$GCC" = "xyes"; then
 937       C_SWITCH_MACHINE="-fno-common"
 938     else
 939       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 940     fi
 941   else
 942     UNEXEC_OBJ=unexalpha.o
 943   fi
 944 fi
 945 AC_SUBST(C_SWITCH_MACHINE)
 946
 947 AC_SUBST(UNEXEC_OBJ)
 948
 949 C_SWITCH_SYSTEM=
 950 ## Some programs in src produce warnings saying certain subprograms
 951 ## are too complex and need a MAXMEM value greater than 2000 for
 952 ## additional optimization.  --nils@exp-math.uni-essen.de
 953 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 954   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 955 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 956 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 957 AC_SUBST(C_SWITCH_SYSTEM)
 958
 959
 960 LIBS_SYSTEM=
 961 case "$opsys" in
 962   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 963   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 964
 965   freebsd) LIBS_SYSTEM="-lutil" ;;
 966
 967   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 968
 969   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
 970
 971   ## Motif needs -lgen.
 972   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
 973 esac
 974 AC_SUBST(LIBS_SYSTEM)
 975
 976
 977 ### Make sure subsequent tests use flags consistent with the build flags.
 978
 979 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 980   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 981 else
 982   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
 983 fi
 984
 985 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
 986 AC_DEFUN([AC_TYPE_SIZE_T])
 987
 988 dnl Do this early because it can frob feature test macros for Unix-98 &c.
 989 AC_SYS_LARGEFILE
 990
 991
 992 LIB_MATH=-lm
 993 LIB_STANDARD=
 994 START_FILES=
 995
 996 case $opsys in
 997   cygwin )
 998     LIB_MATH=
 999     START_FILES='pre-crt0.o'
1000     ;;
1001   darwin )
1002     ## Adding -lm confuses the dynamic linker, so omit it.
1003     LIB_MATH=
1004     START_FILES='pre-crt0.o'
1005     ;;
1006   freebsd )
1007     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1008     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1009     ;;
1010   gnu-linux | gnu-kfreebsd )
1011     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1012     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1013     ;;
1014   hpux10-20 | hpux11 )
1015     LIB_STANDARD=-lc
1016     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1017     ;;
1018   netbsd | openbsd )
1019     if test -f $CRT_DIR/crti.o; then
1020         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1021         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1022     else
1023         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1024         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1025     fi
1026     ;;
1027 esac
1028
1029 AC_SUBST(LIB_MATH)
1030 AC_SUBST(START_FILES)
1031
1032 dnl Not all platforms use crtn.o files.  Check if the current one does.
1033 crt_files=
1034
1035 for file in x $LIB_STANDARD $START_FILES; do
1036   case "$file" in
1037     *CRT_DIR*) crt_files="$crt_files `echo $file | sed -e 's|.*/||'`" ;;
1038   esac
1039 done
1040
1041 if test "x$crt_files" != x; then
1042
1043   ## If user specified a crt-dir, use that unconditionally.
1044   crt_gcc=no
1045
1046   if test "X$CRT_DIR" = "X"; then
1047
1048     CRT_DIR=/usr/lib            # default
1049
1050     case "$canonical" in
1051       x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1052       ## On x86-64 and s390x GNU/Linux distributions, the standard library
1053       ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1054       ## For anything else (eg /usr/lib32), it is up the user to specify
1055       ## the location (bug#5655).
1056       ## Test for crtn.o, not just the directory, because sometimes the
1057       ## directory exists but does not have the relevant files (bug#1287).
1058       ## FIXME better to test for binary compatibility somehow.
1059       test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1060       ;;
1061
1062       powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1063     esac
1064
1065     case "$opsys" in
1066       hpux10-20) CRT_DIR=/lib ;;
1067     esac
1068
1069     test "x${GCC}" = xyes && crt_gcc=yes
1070
1071   fi                            # CRT_DIR = ""
1072
1073   crt_missing=
1074
1075   for file in $crt_files; do
1076
1077     ## If we're using gcc, try to determine it automatically by asking
1078     ## gcc.  [If this doesn't work, CRT_DIR will remain at the
1079     ## system-dependent default from above.]
1080     if test $crt_gcc = yes && test ! -e $CRT_DIR/$file; then
1081
1082        crt_file=`$CC --print-file-name=$file 2>/dev/null`
1083        case "$crt_file" in
1084          */*)
1085            CRT_DIR=`AS_DIRNAME(["$crt_file"])`
1086            ;;
1087        esac
1088     fi
1089
1090     dnl We expect all the files to be in a single directory, so after the
1091     dnl first there is no point asking gcc.
1092     crt_gcc=no
1093
1094     test -e $CRT_DIR/$file || crt_missing="$crt_missing $file"
1095   done                          # $crt_files
1096
1097   test "x$crt_missing" = x || \
1098     AC_MSG_ERROR([Required file(s) not found:$crt_missing
1099 Try using the --with-crt-dir option.])
1100
1101 fi                              # crt_files != ""
1102
1103 AC_SUBST(CRT_DIR)
1104
1105
1106 dnl This function definition taken from Gnome 2.0
1107 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1108 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1109 dnl also defines GSTUFF_PKG_ERRORS on error
1110 AC_DEFUN([PKG_CHECK_MODULES], [
1111   succeeded=no
1112
1113   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1114
1115   if test "$PKG_CONFIG" = "no" ; then
1116      ifelse([$4], , [AC_MSG_ERROR([
1117       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1118   else
1119      PKG_CONFIG_MIN_VERSION=0.9.0
1120      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1121         AC_MSG_CHECKING(for $2)
1122
1123         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1124             AC_MSG_RESULT(yes)
1125             succeeded=yes
1126
1127             AC_MSG_CHECKING($1_CFLAGS)
1128             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1129             AC_MSG_RESULT($$1_CFLAGS)
1130
1131             AC_MSG_CHECKING($1_LIBS)
1132             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1133             AC_MSG_RESULT($$1_LIBS)
1134         else
1135             AC_MSG_RESULT(no)
1136             $1_CFLAGS=""
1137             $1_LIBS=""
1138             ## If we have a custom action on failure, don't print errors, but
1139             ## do set a variable so people can do so.
1140             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1141             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1142         fi
1143
1144         AC_SUBST($1_CFLAGS)
1145         AC_SUBST($1_LIBS)
1146      else
1147         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1148         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1149      fi
1150   fi
1151
1152   if test $succeeded = yes; then
1153      ifelse([$3], , :, [$3])
1154   else
1155      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1156   fi
1157 ])
1158
1159
1160 if test "${with_sound}" != "no"; then
1161   # Sound support for GNU/Linux and the free BSDs.
1162   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1163     have_sound_header=yes)
1164   # Emulation library used on NetBSD.
1165   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1166   AC_SUBST(LIBSOUND)
1167
1168   ALSA_REQUIRED=1.0.0
1169   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1170   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1171   if test $HAVE_ALSA = yes; then
1172     SAVE_CFLAGS="$CFLAGS"
1173     SAVE_LDFLAGS="$LDFLAGS"
1174     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1175     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1176     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1177                     emacs_alsa_normal=yes,
1178                     emacs_alsa_normal=no)
1179     if test "$emacs_alsa_normal" != yes; then
1180       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1181                      [[snd_lib_error_set_handler (0);]])],
1182                      emacs_alsa_subdir=yes,
1183                      emacs_alsa_subdir=no)
1184       if test "$emacs_alsa_subdir" != yes; then
1185         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1186       fi
1187       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1188     fi
1189
1190     CFLAGS="$SAVE_CFLAGS"
1191     LDFLAGS="$SAVE_LDFLAGS"
1192     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1193     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1194     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1195   fi
1196
1197   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1198   dnl compiles only on the specified platforms.  For others, it
1199   dnl probably doesn't make sense to try.
1200   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1201      case "$opsys" in
1202        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1203        gnu-linux|freebsd|netbsd)
1204          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1205          ;;
1206      esac
1207   fi
1208
1209   AC_SUBST(CFLAGS_SOUND)
1210 fi
1211
1212 dnl checks for header files
1213 AC_CHECK_HEADERS(sys/select.h sys/time.h unistd.h utime.h \
1214   linux/version.h sys/systeminfo.h \
1215   stdio_ext.h fcntl.h coff.h pty.h sys/mman.h \
1216   sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1217   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1218
1219 AC_MSG_CHECKING(if personality LINUX32 can be set)
1220 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1221                emacs_cv_personality_linux32=yes,
1222                emacs_cv_personality_linux32=no)
1223 AC_MSG_RESULT($emacs_cv_personality_linux32)
1224
1225 if test $emacs_cv_personality_linux32 = yes; then
1226   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1227             [Define to 1 if personality LINUX32 can be set.])
1228 fi
1229
1230 dnl On Solaris 8 there's a compilation warning for term.h because
1231 dnl it doesn't define `bool'.
1232 AC_CHECK_HEADERS(term.h, , , -)
1233 AC_HEADER_TIME
1234 AC_CHECK_DECLS([sys_siglist])
1235 if test $ac_cv_have_decl_sys_siglist != yes; then
1236   # For Tru64, at least:
1237   AC_CHECK_DECLS([__sys_siglist])
1238   if test $ac_cv_have_decl___sys_siglist = yes; then
1239     AC_DEFINE(sys_siglist, __sys_siglist,
1240               [Define to any substitute for sys_siglist.])
1241   fi
1242 fi
1243 AC_HEADER_SYS_WAIT
1244
1245 dnl Some systems have utime.h but don't declare the struct anyplace.
1246 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1247 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
1248 #include <sys/time.h>
1249 #include <time.h>
1250 #else
1251 #ifdef HAVE_SYS_TIME_H
1252 #include <sys/time.h>
1253 #else
1254 #include <time.h>
1255 #endif
1256 #endif
1257 #ifdef HAVE_UTIME_H
1258 #include <utime.h>
1259 #endif]], [[static struct utimbuf x; x.actime = x.modtime;]])],
1260   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1261 if test $emacs_cv_struct_utimbuf = yes; then
1262   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1263 fi
1264
1265 dnl Check for speed_t typedef.
1266 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1267   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <termios.h>]], [[speed_t x = 1;]])],
1268     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1269 if test $emacs_cv_speed_t = yes; then
1270   AC_DEFINE(HAVE_SPEED_T, 1,
1271            [Define to 1 if `speed_t' is declared by <termios.h>.])
1272 fi
1273
1274 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1275 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
1276 #include <sys/time.h>
1277 #include <time.h>
1278 #else
1279 #ifdef HAVE_SYS_TIME_H
1280 #include <sys/time.h>
1281 #else
1282 #include <time.h>
1283 #endif
1284 #endif]], [[static struct timeval x; x.tv_sec = x.tv_usec;]])],
1285   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1286 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1287 if test $emacs_cv_struct_timeval = yes; then
1288   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1289 fi
1290
1291 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1292 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]],
1293 [[static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;]])],
1294   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1295 HAVE_EXCEPTION=$emacs_cv_struct_exception
1296 if test $emacs_cv_struct_exception != yes; then
1297   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1298 fi
1299
1300 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1301 #if HAVE_SYS_SOCKET_H
1302 #include <sys/socket.h>
1303 #endif])
1304
1305 dnl checks for structure members
1306 AC_STRUCT_TM
1307 AC_STRUCT_TIMEZONE
1308 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1309                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1310                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1311                 [#include <time.h>])
1312 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1313                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1314                   struct ifreq.ifr_addr], , ,
1315                  [AC_INCLUDES_DEFAULT
1316 #if HAVE_SYS_SOCKET_H
1317 #include <sys/socket.h>
1318 #endif
1319 #if HAVE_NET_IF_H
1320 #include <net/if.h>
1321 #endif])
1322
1323 dnl checks for compiler characteristics
1324
1325 dnl Testing __STDC__ to determine prototype support isn't good enough.
1326 dnl DEC C, for instance, doesn't define it with default options, and
1327 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1328 dnl and void *.
1329 AC_C_PROTOTYPES
1330 AC_C_VOLATILE
1331 AC_C_CONST
1332 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1333   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [[void * foo;]])],
1334                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1335 if test $emacs_cv_void_star = yes; then
1336   AC_DEFINE(POINTER_TYPE, void)
1337 else
1338   AC_DEFINE(POINTER_TYPE, char)
1339 fi
1340 AH_TEMPLATE(POINTER_TYPE,
1341             [Define as `void' if your compiler accepts `void *'; otherwise
1342              define as `char'.])dnl
1343
1344 dnl Check for endianess
1345 AC_C_BIGENDIAN
1346
1347 AC_CACHE_CHECK([for  __attribute__ ((__aligned__ (expr)))],
1348   [emacs_cv_attribute_aligned],
1349   [AC_COMPILE_IFELSE(
1350      [AC_LANG_PROGRAM(
1351         [[char __attribute__ ((__aligned__ (1 << 3))) c;]],
1352         [[]])],
1353      [emacs_cv_attribute_aligned=yes],
1354      [emacs_cv_attribute_aligned=no])])
1355 if test $emacs_cv_attribute_aligned = yes; then
1356   AC_DEFINE([HAVE_ATTRIBUTE_ALIGNED], 1,
1357     [Define to 1 if GCC-style __attribute__ ((__aligned__ (expr))) works.])
1358 fi
1359
1360 dnl check for Make feature
1361 AC_PROG_MAKE_SET
1362
1363 DEPFLAGS=
1364 MKDEPDIR=":"
1365 deps_frag=deps.mk
1366 dnl check for GNU Make if we have GCC and autodepend is on.
1367 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1368    AC_MSG_CHECKING([whether we are using GNU Make])
1369    HAVE_GNU_MAKE=no
1370    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1371    if test "x$testval" != x; then
1372       HAVE_GNU_MAKE=yes
1373    else
1374       ac_enable_autodepend=no
1375    fi
1376    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1377    if test $HAVE_GNU_MAKE = yes; then
1378       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1379       SAVE_CFLAGS="$CFLAGS"
1380       CFLAGS="$CFLAGS -MMD -MF deps.d"
1381       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1382       CFLAGS="$SAVE_CFLAGS"
1383       test -f deps.d || ac_enable_autodepend=no
1384       rm -rf deps.d
1385       AC_MSG_RESULT([$ac_enable_autodepend])
1386    fi
1387    if test $ac_enable_autodepend = yes; then
1388       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d'
1389       ## In parallel builds, another make might create depdir between
1390       ## the first test and mkdir, so stick another test on the end.
1391       ## Or use install-sh -d?  mkdir -p is not portable.
1392       MKDEPDIR='test -d ${DEPDIR} || mkdir ${DEPDIR} || test -d ${DEPDIR}'
1393       deps_frag=autodeps.mk
1394    fi
1395 fi
1396 deps_frag=$srcdir/src/$deps_frag
1397 AC_SUBST(MKDEPDIR)
1398 AC_SUBST(DEPFLAGS)
1399 AC_SUBST_FILE(deps_frag)
1400
1401
1402 lisp_frag=$srcdir/src/lisp.mk
1403 AC_SUBST_FILE(lisp_frag)
1404
1405
1406 dnl checks for operating system services
1407 AC_SYS_LONG_FILE_NAMES
1408
1409 #### Choose a window system.
1410
1411 AC_PATH_X
1412 if test "$no_x" = yes; then
1413   window_system=none
1414 else
1415   window_system=x11
1416 fi
1417
1418 ## Workaround for bug in autoconf <= 2.62.
1419 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1420 ## No need to do anything special for these standard directories.
1421 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1422
1423    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1424
1425 fi
1426
1427 LD_SWITCH_X_SITE_AUX=
1428 LD_SWITCH_X_SITE_AUX_RPATH=
1429 if test "${x_libraries}" != NONE; then
1430   if test -n "${x_libraries}"; then
1431     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1432     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1433     LD_SWITCH_X_SITE_AUX_RPATH=`echo ${LD_SWITCH_X_SITE_AUX} | sed -e 's/-R/-Wl,-rpath,/'`
1434   fi
1435   x_default_search_path=""
1436   x_search_path=${x_libraries}
1437   if test -z "${x_search_path}"; then
1438     x_search_path=/usr/lib
1439   fi
1440   for x_library in `echo ${x_search_path}: | \
1441                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1442     x_search_path="\
1443 ${x_library}/X11/%L/%T/%N%C%S:\
1444 ${x_library}/X11/%l/%T/%N%C%S:\
1445 ${x_library}/X11/%T/%N%C%S:\
1446 ${x_library}/X11/%L/%T/%N%S:\
1447 ${x_library}/X11/%l/%T/%N%S:\
1448 ${x_library}/X11/%T/%N%S"
1449     if test x"${x_default_search_path}" = x; then
1450       x_default_search_path=${x_search_path}
1451     else
1452       x_default_search_path="${x_search_path}:${x_default_search_path}"
1453     fi
1454   done
1455 fi
1456 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1457 AC_SUBST(LD_SWITCH_X_SITE_AUX_RPATH)
1458
1459 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1460   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1461 fi
1462
1463 if test x"${x_includes}" = x; then
1464   bitmapdir=/usr/include/X11/bitmaps
1465 else
1466   # accumulate include directories that have X11 bitmap subdirectories
1467   bmd_acc="dummyval"
1468   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1469     if test -d "${bmd}/X11/bitmaps"; then
1470       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1471     fi
1472     if test -d "${bmd}/bitmaps"; then
1473       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1474     fi
1475   done
1476   if test ${bmd_acc} != "dummyval"; then
1477     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1478   fi
1479 fi
1480
1481 HAVE_NS=no
1482 NS_IMPL_COCOA=no
1483 NS_IMPL_GNUSTEP=no
1484 tmp_CPPFLAGS="$CPPFLAGS"
1485 tmp_CFLAGS="$CFLAGS"
1486 CPPFLAGS="$CPPFLAGS -x objective-c"
1487 CFLAGS="$CFLAGS -x objective-c"
1488 TEMACS_LDFLAGS2="\${LDFLAGS}"
1489 dnl I don't think it's especially important, but src/Makefile.in
1490 dnl (now the only user of ns_appdir) used to go to the trouble of adding a
1491 dnl trailing "/" to it, so now we do it here.
1492 if test "${with_ns}" != no; then
1493   if test "${opsys}" = darwin; then
1494      NS_IMPL_COCOA=yes
1495      ns_appdir=`pwd`/nextstep/Emacs.app
1496      ns_appbindir=${ns_appdir}/Contents/MacOS/
1497      ns_appresdir=${ns_appdir}/Contents/Resources
1498      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1499   elif test -f $GNUSTEP_CONFIG_FILE; then
1500      NS_IMPL_GNUSTEP=yes
1501      ns_appdir=`pwd`/nextstep/Emacs.app
1502      ns_appbindir=${ns_appdir}/
1503      ns_appresdir=${ns_appdir}/Resources
1504      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1505      dnl FIXME sourcing this several times in subshells seems inefficient.
1506      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1507      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1508      dnl I seemed to need these as well with GNUstep-startup 0.25.
1509      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1510      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1511      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1512        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1513      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1514        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1515      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1516      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1517      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1518      LIB_STANDARD=
1519      START_FILES=
1520      TEMACS_LDFLAGS2=
1521   fi
1522   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1523                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1524   files are missing or cannot be compiled.])])
1525   NS_HAVE_NSINTEGER=yes
1526   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1527                                      [NSInteger i;])],
1528                     ns_have_nsinteger=yes,
1529                     ns_have_nsinteger=no)
1530   if test $ns_have_nsinteger = no; then
1531     NS_HAVE_NSINTEGER=no
1532   fi
1533 fi
1534 AC_SUBST(TEMACS_LDFLAGS2)
1535
1536 ns_frag=/dev/null
1537 NS_OBJ=
1538 NS_OBJC_OBJ=
1539 if test "${HAVE_NS}" = yes; then
1540   window_system=nextstep
1541   with_xft=no
1542   # set up packaging dirs
1543   exec_prefix=${ns_appbindir}
1544   libexecdir=${ns_appbindir}/libexec
1545   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1546      prefix=${ns_appresdir}
1547   fi
1548   ns_frag=$srcdir/src/ns.mk
1549   NS_OBJ="fontset.o fringe.o image.o"
1550   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o"
1551 fi
1552 CFLAGS="$tmp_CFLAGS"
1553 CPPFLAGS="$tmp_CPPFLAGS"
1554 AC_SUBST(NS_OBJ)
1555 AC_SUBST(NS_OBJC_OBJ)
1556 AC_SUBST(LIB_STANDARD)
1557 AC_SUBST_FILE(ns_frag)
1558
1559 case "${window_system}" in
1560   x11 )
1561     HAVE_X_WINDOWS=yes
1562     HAVE_X11=yes
1563     case "${with_x_toolkit}" in
1564       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1565       motif ) USE_X_TOOLKIT=MOTIF ;;
1566       gtk ) with_gtk=yes
1567 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1568 dnl USE_X_TOOLKIT is set.
1569             USE_X_TOOLKIT=none ;;
1570       gtk3 ) with_gtk3=yes
1571              USE_X_TOOLKIT=none ;;
1572       no ) USE_X_TOOLKIT=none ;;
1573 dnl If user did not say whether to use a toolkit, make this decision later:
1574 dnl use the toolkit if we have gtk, or X11R5 or newer.
1575       * ) USE_X_TOOLKIT=maybe ;;
1576     esac
1577   ;;
1578   nextstep | none )
1579     HAVE_X_WINDOWS=no
1580     HAVE_X11=no
1581     USE_X_TOOLKIT=none
1582   ;;
1583 esac
1584
1585 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1586    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1587    if test "$HAVE_XSERVER" = true ||
1588       test -n "$DISPLAY" ||
1589       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1590         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1591 were found.  You should install the relevant development files for X
1592 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1593 sure you have development files for image handling, i.e.
1594 tiff, gif, jpeg, png and xpm.
1595 If you are sure you want Emacs compiled without X window support, pass
1596   --without-x
1597 to configure.])
1598    fi
1599 fi
1600
1601 ### If we're using X11, we should use the X menu package.
1602 HAVE_MENUS=no
1603 case ${HAVE_X11} in
1604   yes ) HAVE_MENUS=yes ;;
1605 esac
1606
1607 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1608 # Assume not, until told otherwise.
1609 GNU_MALLOC=yes
1610 doug_lea_malloc=yes
1611 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1612 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1613 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1614                emacs_cv_var___after_morecore_hook,
1615 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[extern void (* __after_morecore_hook)();]],[[__after_morecore_hook = 0]])],
1616   emacs_cv_var___after_morecore_hook=yes,
1617   emacs_cv_var___after_morecore_hook=no)])
1618 if test $emacs_cv_var___after_morecore_hook = no; then
1619   doug_lea_malloc=no
1620 fi
1621
1622
1623 dnl See comments in aix4-2.h about maybe using system malloc there.
1624 system_malloc=no
1625 case "$opsys" in
1626   ## darwin ld insists on the use of malloc routines in the System framework.
1627   darwin|sol2-10) system_malloc=yes ;;
1628 esac
1629
1630 if test "${system_malloc}" = "yes"; then
1631   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1632   GNU_MALLOC=no
1633   GNU_MALLOC_reason="
1634     (The GNU allocators don't work with this system configuration.)"
1635   GMALLOC_OBJ=
1636   VMLIMIT_OBJ=
1637 else
1638   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1639   VMLIMIT_OBJ=vm-limit.o
1640 fi
1641 AC_SUBST(GMALLOC_OBJ)
1642 AC_SUBST(VMLIMIT_OBJ)
1643
1644 if test "$doug_lea_malloc" = "yes" ; then
1645   if test "$GNU_MALLOC" = yes ; then
1646     GNU_MALLOC_reason="
1647       (Using Doug Lea's new malloc from the GNU C Library.)"
1648   fi
1649   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1650             [Define to 1 if you are using the GNU C Library.])
1651
1652   ## Use mmap directly for allocating larger buffers.
1653   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1654   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1655   ## Does the AC_FUNC_MMAP test below make this check unecessary?
1656   case "$opsys" in
1657     gnu*) REL_ALLOC=no ;;
1658   esac
1659 fi
1660
1661 if test x"${REL_ALLOC}" = x; then
1662   REL_ALLOC=${GNU_MALLOC}
1663 fi
1664
1665 use_mmap_for_buffers=no
1666 case "$opsys" in
1667   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1668 esac
1669
1670 AC_FUNC_MMAP
1671 if test $use_mmap_for_buffers = yes; then
1672   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1673   REL_ALLOC=no
1674 fi
1675
1676 LIBS="$LIBS_SYSTEM $LIBS"
1677
1678 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1679 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1680 AC_CHECK_LIB(dnet, dnet_ntoa)
1681 dnl This causes -lresolv to get used in subsequent tests,
1682 dnl which causes failures on some systems such as HPUX 9.
1683 dnl AC_CHECK_LIB(resolv, gethostbyname)
1684
1685 dnl FIXME replace main with a function we actually want from this library.
1686 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1687
1688 AC_CHECK_LIB(pthreads, cma_open)
1689
1690 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1691 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1692 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1693 ## added to LIBS in configure would never contain the pthreads part,
1694 ## but the value used in Makefiles might.  FIXME?
1695 ##
1696 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1697 ## be harmless on older versions of X where it happens to exist.
1698 test "$opsys" = "aix4-2" && \
1699   test $ac_cv_lib_pthreads_cma_open = yes && \
1700   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1701
1702 dnl Check for need for bigtoc support on IBM AIX
1703
1704 case ${host_os} in
1705 aix*)
1706   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1707     case $GCC in
1708     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1709     *) gdb_cv_bigtoc=-bbigtoc ;;
1710     esac
1711
1712     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1713     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
1714   ])
1715   ;;
1716 esac
1717
1718 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1719 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1720 # REAL_CPPFLAGS later on.
1721
1722 REAL_CFLAGS="$CFLAGS"
1723 REAL_CPPFLAGS="$CPPFLAGS"
1724
1725 if test "${HAVE_X11}" = "yes"; then
1726   DEFS="$C_SWITCH_X_SITE $DEFS"
1727   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1728   LIBS="-lX11 $LIBS"
1729   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1730   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1731
1732   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1733   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1734   # but it's more convenient here to set LD_RUN_PATH
1735   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1736   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1737     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1738     export LD_RUN_PATH
1739   fi
1740
1741   if test "${opsys}" = "gnu-linux"; then
1742     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1743     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1744      [[XOpenDisplay ("foo");]])],
1745      [xlinux_first_failure=no],
1746      [xlinux_first_failure=yes])
1747     if test "${xlinux_first_failure}" = "yes"; then
1748       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1749       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1750       OLD_CPPFLAGS="$CPPFLAGS"
1751       OLD_LIBS="$LIBS"
1752       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1753       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1754       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1755       LIBS="$LIBS -b i486-linuxaout"
1756       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1757        [[XOpenDisplay ("foo");]])],
1758        [xlinux_second_failure=no],
1759        [xlinux_second_failure=yes])
1760       if test "${xlinux_second_failure}" = "yes"; then
1761         # If we get the same failure with -b, there is no use adding -b.
1762         # So take it out.  This plays safe.
1763         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1764         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1765         CPPFLAGS="$OLD_CPPFLAGS"
1766         LIBS="$OLD_LIBS"
1767         AC_MSG_RESULT(no)
1768       else
1769         AC_MSG_RESULT(yes)
1770       fi
1771     else
1772       AC_MSG_RESULT(no)
1773     fi
1774   fi
1775
1776   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1777   # header files included from there.
1778   AC_MSG_CHECKING(for Xkb)
1779   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1780 #include <X11/XKBlib.h>]],
1781         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
1782         emacs_xkb=yes, emacs_xkb=no)
1783   AC_MSG_RESULT($emacs_xkb)
1784   if test $emacs_xkb = yes; then
1785     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1786   fi
1787
1788   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1789 XScreenNumberOfScreen XSetWMProtocols)
1790 fi
1791
1792 if test "${window_system}" = "x11"; then
1793   AC_MSG_CHECKING(X11 version 6)
1794   AC_CACHE_VAL(emacs_cv_x11_version_6,
1795   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
1796 [[#if XlibSpecificationRelease < 6
1797 fail;
1798 #endif
1799 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1800   if test $emacs_cv_x11_version_6 = yes; then
1801     AC_MSG_RESULT(6 or newer)
1802     AC_DEFINE(HAVE_X11R6, 1,
1803               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1804     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1805     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1806     ## XIM support.
1807     case "$opsys" in
1808       sol2-*) : ;;
1809       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1810            [Define if you have usable X11R6-style XIM support.])
1811          ;;
1812     esac
1813   else
1814     AC_MSG_RESULT(before 6)
1815   fi
1816 fi
1817
1818
1819 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1820 HAVE_RSVG=no
1821 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1822   if test "${with_rsvg}" != "no"; then
1823     RSVG_REQUIRED=2.11.0
1824     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1825
1826     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1827     AC_SUBST(RSVG_CFLAGS)
1828     AC_SUBST(RSVG_LIBS)
1829
1830     if test $HAVE_RSVG = yes; then
1831       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1832       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1833       LIBS="$RSVG_LIBS $LIBS"
1834     fi
1835   fi
1836 fi
1837
1838 HAVE_IMAGEMAGICK=no
1839 if test "${HAVE_X11}" = "yes"; then
1840   if test "${with_imagemagick}" != "no"; then
1841     ## 6.2.8 is the earliest version known to work, but earlier versions
1842     ## might work - let us know if you find one.
1843     ## 6.0.7 does not work.  See bug#7955.
1844     IMAGEMAGICK_MODULE="Wand >= 6.2.8"
1845     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1846     AC_SUBST(IMAGEMAGICK_CFLAGS)
1847     AC_SUBST(IMAGEMAGICK_LIBS)
1848
1849     if test $HAVE_IMAGEMAGICK = yes; then
1850       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1851       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1852       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1853       AC_CHECK_FUNCS(MagickExportImagePixels)
1854     fi
1855   fi
1856 fi
1857
1858
1859 HAVE_GTK=no
1860 GTK_OBJ=
1861 if test "${with_gtk3}" = "yes"; then
1862   GLIB_REQUIRED=2.28
1863   GTK_REQUIRED=3.0
1864   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1865
1866   dnl Checks for libraries.
1867   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1868   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1869      AC_MSG_ERROR($GTK_PKG_ERRORS)
1870   fi
1871   AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
1872   GTK_OBJ=emacsgtkfixed.o
1873 fi
1874
1875 if test "$pkg_check_gtk" != "yes"; then
1876   HAVE_GTK=no
1877 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1878   GLIB_REQUIRED=2.6
1879   GTK_REQUIRED=2.6
1880   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1881
1882   dnl Checks for libraries.
1883   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1884   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1885      AC_MSG_ERROR($GTK_PKG_ERRORS)
1886   fi
1887 fi
1888 fi
1889
1890 if test x"$pkg_check_gtk" = xyes; then
1891
1892   AC_SUBST(GTK_CFLAGS)
1893   AC_SUBST(GTK_LIBS)
1894   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1895   CFLAGS="$CFLAGS $GTK_CFLAGS"
1896   LIBS="$GTK_LIBS $LIBS"
1897   dnl Try to compile a simple GTK program.
1898   GTK_COMPILES=no
1899   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1900   if test "${GTK_COMPILES}" != "yes"; then
1901     if test "$USE_X_TOOLKIT" != "maybe"; then
1902       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1903     fi
1904   else
1905     HAVE_GTK=yes
1906     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1907     GTK_OBJ="gtkutil.o $GTK_OBJ"
1908     USE_X_TOOLKIT=none
1909     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1910       :
1911     else
1912       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1913        closing open displays.  This is no problem if you just use
1914        one display, but if you use more than one and close one of them
1915        Emacs may crash.]])
1916       sleep 3
1917     fi
1918   fi
1919
1920 fi
1921 AC_SUBST(GTK_OBJ)
1922
1923
1924 if test "${HAVE_GTK}" = "yes"; then
1925
1926   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1927   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1928   if test "$with_toolkit_scroll_bars" != no; then
1929     with_toolkit_scroll_bars=yes
1930   fi
1931
1932   dnl  Check if we have the old file selection dialog declared and
1933   dnl  in the link library.  In 2.x it may be in the library,
1934   dnl  but not declared if deprecated featured has been selected out.
1935   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1936   HAVE_GTK_FILE_SELECTION=no
1937   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1938                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1939 #include <gtk/gtk.h>])
1940   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1941     AC_CHECK_FUNCS(gtk_file_selection_new)
1942   fi
1943
1944   dnl Check if pthreads are available.  Emacs only needs this when using
1945   dnl gtk_file_chooser under Gnome.
1946     HAVE_GTK_AND_PTHREAD=no
1947     AC_CHECK_HEADERS(pthread.h)
1948     if test "$ac_cv_header_pthread_h"; then
1949       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1950     fi
1951     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1952       case "${canonical}" in
1953         *-hpux*) ;;
1954         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1955       esac
1956       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1957                [Define to 1 if you have GTK and pthread (-lpthread).])
1958     fi
1959
1960   dnl Check for functions introduced in 2.14 and later.
1961   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1962                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1963                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1964                  gtk_orientable_set_orientation)
1965
1966 fi
1967
1968 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1969 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1970 dnl also not configured.
1971 HAVE_DBUS=no
1972 DBUS_OBJ=
1973 if test "${with_dbus}" = "yes"; then
1974    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1975    if test "$HAVE_DBUS" = yes; then
1976      LIBS="$LIBS $DBUS_LIBS"
1977      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1978      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1979      DBUS_OBJ=dbusbind.o
1980    fi
1981 fi
1982 AC_SUBST(DBUS_OBJ)
1983
1984 dnl GSettings has been tested under GNU/Linux only.
1985 HAVE_GSETTINGS=no
1986 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
1987    PKG_CHECK_MODULES(GSETTINGS, glib-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
1988    if test "$HAVE_GSETTINGS" = "yes"; then
1989       AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
1990       SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
1991       SETTINGS_LIBS="$GSETTINGS_LIBS"
1992    fi
1993 fi
1994
1995 dnl GConf has been tested under GNU/Linux only.
1996 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1997 HAVE_GCONF=no
1998 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1999    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
2000    if test "$HAVE_GCONF" = yes; then
2001       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2002       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2003       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2004       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2005    fi
2006 fi
2007
2008 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2009     SAVE_CFLAGS="$CFLAGS"
2010     SAVE_LDFLAGS="$LDFLAGS"
2011     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2012     LDFLAGS="$SETTINGS_LIBS $LDFLAGS"
2013     AC_CHECK_FUNCS([g_type_init])
2014     CFLAGS="$SAVE_CFLAGS"
2015     LDFLAGS="$SAVE_LDFLAGS"
2016 fi
2017 AC_SUBST(SETTINGS_CFLAGS)
2018 AC_SUBST(SETTINGS_LIBS)
2019
2020
2021 dnl SELinux is available for GNU/Linux only.
2022 HAVE_LIBSELINUX=no
2023 LIBSELINUX_LIBS=
2024 if test "${with_selinux}" = "yes"; then
2025    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2026    if test "$HAVE_LIBSELINUX" = yes; then
2027       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2028       LIBSELINUX_LIBS=-lselinux
2029    fi
2030 fi
2031 AC_SUBST(LIBSELINUX_LIBS)
2032
2033 HAVE_GNUTLS=no
2034 HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=no
2035 if test "${with_gnutls}" = "yes" ; then
2036   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.0], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2037   if test "${HAVE_GNUTLS}" = "yes"; then
2038     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2039   fi
2040
2041   CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
2042   LIBS="$LIBGNUTLS_LIBS $LIBS"
2043   AC_CHECK_FUNCS(gnutls_certificate_set_verify_function, HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=yes)
2044
2045   if test "${HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY}" = "yes"; then
2046     AC_DEFINE(HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY, 1, [Define if using GnuTLS certificate verification callbacks.])
2047   fi
2048 fi
2049
2050 AC_SUBST(LIBGNUTLS_LIBS)
2051 AC_SUBST(LIBGNUTLS_CFLAGS)
2052
2053 dnl Do not put whitespace before the #include statements below.
2054 dnl Older compilers (eg sunos4 cc) choke on it.
2055 HAVE_XAW3D=no
2056 LUCID_LIBW=
2057 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2058   if test "$with_xaw3d" != no; then
2059     AC_MSG_CHECKING(for xaw3d)
2060     AC_CACHE_VAL(emacs_cv_xaw3d,
2061     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2062 #include <X11/Intrinsic.h>
2063 #include <X11/Xaw3d/Simple.h>]],
2064       [[]])],
2065       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2066                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2067       emacs_cv_xaw3d=no)])
2068   else
2069     emacs_cv_xaw3d=no
2070   fi
2071   if test $emacs_cv_xaw3d = yes; then
2072     AC_MSG_RESULT([yes; using Lucid toolkit])
2073     USE_X_TOOLKIT=LUCID
2074     HAVE_XAW3D=yes
2075     LUCID_LIBW=-lXaw3d
2076     AC_DEFINE(HAVE_XAW3D, 1,
2077               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2078   else
2079     AC_MSG_RESULT(no)
2080     AC_MSG_CHECKING(for libXaw)
2081     AC_CACHE_VAL(emacs_cv_xaw,
2082     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2083 #include <X11/Intrinsic.h>
2084 #include <X11/Xaw/Simple.h>]],
2085       [[]])],
2086       emacs_cv_xaw=yes,
2087       emacs_cv_xaw=no)])
2088     if test $emacs_cv_xaw = yes; then
2089       AC_MSG_RESULT([yes; using Lucid toolkit])
2090       USE_X_TOOLKIT=LUCID
2091       LUCID_LIBW=-lXaw
2092     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2093       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2094     else
2095       AC_MSG_ERROR([No X toolkit could be found.
2096 If you are sure you want Emacs compiled without an X toolkit, pass
2097   --with-x-toolkit=no
2098 to configure.  Otherwise, install the development libraries for the toolkit
2099 that you want to use (e.g. Gtk+) and re-run configure.])
2100     fi
2101   fi
2102 fi
2103
2104 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2105
2106 LIBXTR6=
2107 if test "${USE_X_TOOLKIT}" != "none"; then
2108   AC_MSG_CHECKING(X11 toolkit version)
2109   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2110   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2111 [[#if XtSpecificationRelease < 6
2112 fail;
2113 #endif
2114 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2115   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2116   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2117     AC_MSG_RESULT(6 or newer)
2118     AC_DEFINE(HAVE_X11XTR6, 1,
2119               [Define to 1 if you have the X11R6 or newer version of Xt.])
2120     LIBXTR6="-lSM -lICE"
2121     case "$opsys" in
2122       ## Use libw.a along with X11R6 Xt.
2123       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2124     esac
2125   else
2126     AC_MSG_RESULT(before 6)
2127   fi
2128
2129 dnl If using toolkit, check whether libXmu.a exists.
2130 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2131   OLDLIBS="$LIBS"
2132   if test x$HAVE_X11XTR6 = xyes; then
2133     LIBS="-lXt -lSM -lICE $LIBS"
2134   else
2135     LIBS="-lXt $LIBS"
2136   fi
2137   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2138   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2139 fi
2140 AC_SUBST(LIBXTR6)
2141
2142 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2143 dnl Why not just test for libxmu in the normal way?
2144 LIBXMU=-lXmu
2145 case $opsys in
2146   ## These systems don't supply Xmu.
2147   hpux* | aix4-2 )
2148     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2149     ;;
2150 esac
2151 AC_SUBST(LIBXMU)
2152
2153 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2154 if test "${HAVE_X11}" = "yes"; then
2155   if test "${USE_X_TOOLKIT}" != "none"; then
2156     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2157   fi
2158 fi
2159
2160 LIBXP=
2161 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2162   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2163   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2164     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2165 int x = 5;
2166 #else
2167 Motif version prior to 2.1.
2168 #endif]])],
2169     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2170   if test $emacs_cv_motif_version_2_1 = yes; then
2171     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2172   else
2173     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2174     # We put this in CFLAGS temporarily to precede other -I options
2175     # that might be in CFLAGS temporarily.
2176     # We put this in CPPFLAGS where it precedes the other -I options.
2177     OLD_CPPFLAGS=$CPPFLAGS
2178     OLD_CFLAGS=$CFLAGS
2179     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2180     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2181     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2182       [[int x = 5;]])],
2183       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2184     if test $emacs_cv_lesstif = yes; then
2185       # Make sure this -I option remains in CPPFLAGS after it is set
2186       # back to REAL_CPPFLAGS.
2187       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2188       # have those other -I options anyway.  Ultimately, having this
2189       # directory ultimately in CPPFLAGS will be enough.
2190       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2191       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2192     else
2193       CFLAGS=$OLD_CFLAGS
2194       CPPFLAGS=$OLD_CPPFLAGS
2195     fi
2196   fi
2197 fi
2198
2199 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2200 dnl using Motif or Xaw3d is available, and unless
2201 dnl --with-toolkit-scroll-bars=no was specified.
2202
2203 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2204             [Define to 1 if we should use toolkit scroll bars.])dnl
2205 USE_TOOLKIT_SCROLL_BARS=no
2206 if test "${with_toolkit_scroll_bars}" != "no"; then
2207   if test "${USE_X_TOOLKIT}" != "none"; then
2208     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2209       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2210       HAVE_XAW3D=no
2211       USE_TOOLKIT_SCROLL_BARS=yes
2212     elif test "${HAVE_XAW3D}" = "yes"; then
2213       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2214       USE_TOOLKIT_SCROLL_BARS=yes
2215     fi
2216   elif test "${HAVE_GTK}" = "yes"; then
2217     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2218     USE_TOOLKIT_SCROLL_BARS=yes
2219   elif test "${HAVE_NS}" = "yes"; then
2220     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2221     USE_TOOLKIT_SCROLL_BARS=yes
2222   fi
2223 fi
2224
2225 dnl See if XIM is available.
2226 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2227           #include <X11/Xlib.h>
2228           #include <X11/Xresource.h>]],
2229          [[XIMProc  callback;]])],
2230          [HAVE_XIM=yes
2231          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2232          HAVE_XIM=no)
2233
2234 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2235
2236 if test "${with_xim}" != "no"; then
2237   AC_DEFINE(USE_XIM, 1,
2238             [Define to 1 if we should use XIM, if it is available.])
2239 fi
2240
2241
2242 if test "${HAVE_XIM}" != "no"; then
2243   late_CFLAGS=$CFLAGS
2244   if test "$GCC" = yes; then
2245     CFLAGS="$CFLAGS --pedantic-errors"
2246   fi
2247   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2248 #include <X11/Xlib.h>
2249 #include <X11/Xresource.h>]],
2250 [[Display *display;
2251 XrmDatabase db;
2252 char *res_name;
2253 char *res_class;
2254 XIMProc  callback;
2255 XPointer *client_data;
2256 #ifndef __GNUC__
2257 /* If we're not using GCC, it's probably not XFree86, and this is
2258    probably right, but we can't use something like --pedantic-errors.  */
2259 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2260                                            char*, XIMProc, XPointer*);
2261 #endif
2262 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2263    client_data);]])],
2264     [emacs_cv_arg6_star=yes])
2265   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2266          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2267 either XPointer or XPointer*.])dnl
2268   if test "$emacs_cv_arg6_star" = yes; then
2269     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2270   else
2271     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2272   fi
2273   CFLAGS=$late_CFLAGS
2274 fi
2275
2276 ### Start of font-backend (under any platform) section.
2277 # (nothing here yet -- this is a placeholder)
2278 ### End of font-backend (under any platform) section.
2279
2280 ### Start of font-backend (under X11) section.
2281 if test "${HAVE_X11}" = "yes"; then
2282    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2283
2284    ## Use -lXft if available, unless `--with-xft=no'.
2285    HAVE_XFT=maybe
2286     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2287       with_xft="no";
2288     fi
2289     if test "x${with_xft}" != "xno"; then
2290
2291       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2292       ## Because xftfont.c uses XRenderQueryExtension, we also
2293       ## need to link to -lXrender.
2294       HAVE_XRENDER=no
2295       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2296       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2297         OLD_CPPFLAGS="$CPPFLAGS"
2298         OLD_CFLAGS="$CFLAGS"
2299         OLD_LIBS="$LIBS"
2300         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2301         CFLAGS="$CFLAGS $XFT_CFLAGS"
2302         XFT_LIBS="-lXrender $XFT_LIBS"
2303         LIBS="$XFT_LIBS $LIBS"
2304         AC_CHECK_HEADER(X11/Xft/Xft.h,
2305           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2306
2307         if test "${HAVE_XFT}" = "yes"; then
2308           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2309             AC_SUBST(XFT_LIBS)
2310           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2311         else
2312           CPPFLAGS="$OLD_CPPFLAGS"
2313           CFLAGS="$OLD_CFLAGS"
2314           LIBS="$OLD_LIBS"
2315         fi                        # "${HAVE_XFT}" = "yes"
2316       fi                          # "$HAVE_XFT" != no
2317     fi                            # "x${with_xft}" != "xno"
2318
2319     ## We used to allow building with FreeType and without Xft.
2320     ## However, the ftx font backend driver is not in good shape.
2321     if test "$HAVE_XFT" != "yes"; then
2322        dnl For the "Does Emacs use" message at the end.
2323        HAVE_XFT=no
2324        HAVE_FREETYPE=no
2325     else
2326        dnl Strict linkers fail with
2327        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2328        dnl if -lfreetype is not specified.
2329        dnl The following is needed to set FREETYPE_LIBS.
2330        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2331                          HAVE_FREETYPE=no)
2332
2333        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2334     fi
2335
2336     HAVE_LIBOTF=no
2337     if test "${HAVE_FREETYPE}" = "yes"; then
2338       AC_DEFINE(HAVE_FREETYPE, 1,
2339                 [Define to 1 if using the freetype and fontconfig libraries.])
2340       if test "${with_libotf}" != "no"; then
2341         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2342                           HAVE_LIBOTF=no)
2343         if test "$HAVE_LIBOTF" = "yes"; then
2344           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2345           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2346                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2347                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2348           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2349             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2350                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2351           fi
2352         fi
2353       fi
2354     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2355     dnl Does the new font backend require it, or can it work without it?
2356     fi
2357
2358     HAVE_M17N_FLT=no
2359     if test "${HAVE_LIBOTF}" = yes; then
2360       if test "${with_m17n_flt}" != "no"; then
2361         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2362         if test "$HAVE_M17N_FLT" = "yes"; then
2363           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2364         fi
2365       fi
2366     fi
2367 else
2368     HAVE_XFT=no
2369     HAVE_FREETYPE=no
2370     HAVE_LIBOTF=no
2371     HAVE_M17N_FLT=no
2372 fi
2373
2374 ### End of font-backend (under X11) section.
2375
2376 AC_SUBST(FREETYPE_CFLAGS)
2377 AC_SUBST(FREETYPE_LIBS)
2378 AC_SUBST(FONTCONFIG_CFLAGS)
2379 AC_SUBST(FONTCONFIG_LIBS)
2380 AC_SUBST(LIBOTF_CFLAGS)
2381 AC_SUBST(LIBOTF_LIBS)
2382 AC_SUBST(M17N_FLT_CFLAGS)
2383 AC_SUBST(M17N_FLT_LIBS)
2384
2385 ### Use -lXpm if available, unless `--with-xpm=no'.
2386 HAVE_XPM=no
2387 LIBXPM=
2388 if test "${HAVE_X11}" = "yes"; then
2389   if test "${with_xpm}" != "no"; then
2390     AC_CHECK_HEADER(X11/xpm.h,
2391       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2392     if test "${HAVE_XPM}" = "yes"; then
2393       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2394       AC_EGREP_CPP(no_return_alloc_pixels,
2395       [#include "X11/xpm.h"
2396 #ifndef XpmReturnAllocPixels
2397 no_return_alloc_pixels
2398 #endif
2399       ], HAVE_XPM=no, HAVE_XPM=yes)
2400
2401       if test "${HAVE_XPM}" = "yes"; then
2402         AC_MSG_RESULT(yes)
2403       else
2404         AC_MSG_RESULT(no)
2405       fi
2406     fi
2407   fi
2408
2409   if test "${HAVE_XPM}" = "yes"; then
2410     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2411     LIBXPM=-lXpm
2412   fi
2413 fi
2414 AC_SUBST(LIBXPM)
2415
2416 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2417 HAVE_JPEG=no
2418 LIBJPEG=
2419 if test "${HAVE_X11}" = "yes"; then
2420   if test "${with_jpeg}" != "no"; then
2421     dnl Checking for jpeglib.h can lose because of a redefinition of
2422     dnl  HAVE_STDLIB_H.
2423     AC_CHECK_HEADER(jerror.h,
2424       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2425   fi
2426
2427   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2428   if test "${HAVE_JPEG}" = "yes"; then
2429     AC_DEFINE(HAVE_JPEG)
2430     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2431         [#include <jpeglib.h>
2432          version=JPEG_LIB_VERSION
2433 ],
2434         [AC_DEFINE(HAVE_JPEG)],
2435         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2436         HAVE_JPEG=no])
2437   fi
2438   if test "${HAVE_JPEG}" = "yes"; then
2439     LIBJPEG=-ljpeg
2440   fi
2441 fi
2442 AC_SUBST(LIBJPEG)
2443
2444 ### Use -lpng if available, unless `--with-png=no'.
2445 HAVE_PNG=no
2446 LIBPNG=
2447 if test "${HAVE_X11}" = "yes"; then
2448   if test "${with_png}" != "no"; then
2449     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2450     # in /usr/include/libpng.
2451     AC_CHECK_HEADERS(png.h libpng/png.h)
2452     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2453       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2454     fi
2455   fi
2456
2457   if test "${HAVE_PNG}" = "yes"; then
2458     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2459     LIBPNG="-lpng -lz -lm"
2460   fi
2461 fi
2462 AC_SUBST(LIBPNG)
2463
2464 ### Use -ltiff if available, unless `--with-tiff=no'.
2465 HAVE_TIFF=no
2466 LIBTIFF=
2467 if test "${HAVE_X11}" = "yes"; then
2468   if test "${with_tiff}" != "no"; then
2469     AC_CHECK_HEADER(tiffio.h,
2470       [tifflibs="-lz -lm"
2471       # At least one tiff package requires the jpeg library.
2472       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2473       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2474   fi
2475
2476   if test "${HAVE_TIFF}" = "yes"; then
2477     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2478     dnl FIXME -lz -lm, as per libpng?
2479     LIBTIFF=-ltiff
2480   fi
2481 fi
2482 AC_SUBST(LIBTIFF)
2483
2484 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2485 HAVE_GIF=no
2486 LIBGIF=
2487 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2488   AC_CHECK_HEADER(gif_lib.h,
2489 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2490 # Earlier versions can crash Emacs.
2491     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2492
2493   if test "$HAVE_GIF" = yes; then
2494     LIBGIF=-lgif
2495   elif test "$HAVE_GIF" = maybe; then
2496 # If gif_lib.h but no libgif, try libungif.
2497     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2498     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2499   fi
2500
2501   if test "${HAVE_GIF}" = "yes"; then
2502     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2503   fi
2504 fi
2505 AC_SUBST(LIBGIF)
2506
2507 dnl Check for required libraries.
2508 if test "${HAVE_X11}" = "yes"; then
2509   MISSING=""
2510   WITH_NO=""
2511   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2512     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2513   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2514     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2515   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2516     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2517   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2518     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2519   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2520     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2521
2522   if test "X${MISSING}" != X; then
2523     AC_MSG_ERROR([The following required libraries were not found:
2524     $MISSING
2525 Maybe some development libraries/packages are missing?
2526 If you don't want to link with them give
2527     $WITH_NO
2528 as options to configure])
2529   fi
2530 fi
2531
2532 ### Use -lgpm if available, unless `--with-gpm=no'.
2533 HAVE_GPM=no
2534 LIBGPM=
2535 if test "${with_gpm}" != "no"; then
2536   AC_CHECK_HEADER(gpm.h,
2537     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2538
2539   if test "${HAVE_GPM}" = "yes"; then
2540     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2541     LIBGPM=-lgpm
2542   fi
2543 fi
2544 AC_SUBST(LIBGPM)
2545
2546 dnl Check for malloc/malloc.h on darwin
2547 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2548
2549 C_SWITCH_X_SYSTEM=
2550 ### Use NeXTstep API to implement GUI.
2551 if test "${HAVE_NS}" = "yes"; then
2552   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2553   if test "${NS_IMPL_COCOA}" = "yes"; then
2554     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2555     GNU_OBJC_CFLAGS=
2556   fi
2557   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2558     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2559     # See also .m.o rule in Makefile.in */
2560     # FIXME: are all these flags really needed?  Document here why.  */
2561     C_SWITCH_X_SYSTEM="-D_REENTRANT -fPIC -fno-strict-aliasing"
2562     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2563   fi
2564   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2565     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2566   fi
2567   # We also have mouse menus.
2568   HAVE_MENUS=yes
2569   OTHER_FILES=ns-app
2570 fi
2571
2572
2573 ### Use session management (-lSM -lICE) if available
2574 HAVE_X_SM=no
2575 LIBXSM=
2576 if test "${HAVE_X11}" = "yes"; then
2577   AC_CHECK_HEADER(X11/SM/SMlib.h,
2578     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2579
2580   if test "${HAVE_X_SM}" = "yes"; then
2581     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2582     LIBXSM="-lSM -lICE"
2583     case "$LIBS" in
2584       *-lSM*) ;;
2585       *)      LIBS="$LIBXSM $LIBS" ;;
2586     esac
2587   fi
2588 fi
2589 AC_SUBST(LIBXSM)
2590
2591 ### Use libxml (-lxml2) if available
2592 if test "${with_xml2}" != "no"; then
2593   ### I'm not sure what the version number should be, so I just guessed.
2594   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2595   if test "${HAVE_LIBXML2}" = "yes"; then
2596     LIBS="$LIBXML2_LIBS $LIBS"
2597     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2598     if test "${HAVE_LIBXML2}" = "yes"; then
2599       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2600     else
2601       LIBXML2_LIBS=""
2602       LIBXML2_CFLAGS=""
2603     fi
2604   fi
2605 fi
2606 AC_SUBST(LIBXML2_LIBS)
2607 AC_SUBST(LIBXML2_CFLAGS)
2608
2609 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2610 AC_CACHE_CHECK(whether netdb declares h_errno,
2611                emacs_cv_netdb_declares_h_errno,
2612 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
2613   [[return h_errno;]])],
2614   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2615 if test $emacs_cv_netdb_declares_h_errno = yes; then
2616   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2617 fi
2618
2619 # fmod, logb, and frexp are found in -lm on most systems.
2620 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2621 AC_CHECK_LIB(m, sqrt)
2622
2623 # Check for mail-locking functions in a "mail" library.  Probably this should
2624 # have the same check as for liblockfile below.
2625 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2626 if test $have_mail = yes; then
2627   LIBS_MAIL=-lmail
2628   LIBS="$LIBS_MAIL $LIBS"
2629   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2630 else
2631   LIBS_MAIL=
2632 fi
2633 dnl Debian, at least:
2634 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2635 if test $have_lockfile = yes; then
2636    LIBS_MAIL=-llockfile
2637    LIBS="$LIBS_MAIL $LIBS"
2638    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2639 else
2640 # If we have the shared liblockfile, assume we must use it for mail
2641 # locking (e.g. Debian).  If we couldn't link against liblockfile
2642 # (no liblockfile.a installed), ensure that we don't need to.
2643   dnl This works for files generally, not just executables.
2644   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2645   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2646                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2647   if test $ac_cv_prog_liblockfile = yes; then
2648     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2649 This probably means that movemail could lose mail.
2650 There may be a `development' package to install containing liblockfile.])
2651   fi
2652 fi
2653 AC_CHECK_FUNCS(touchlock)
2654 AC_CHECK_HEADERS(maillock.h)
2655 AC_SUBST(LIBS_MAIL)
2656
2657 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2658 ## interlock access to the mail spool.  The alternative is a lock file named
2659 ## /usr/spool/mail/$USER.lock.
2660 mail_lock=no
2661 case "$opsys" in
2662   aix4-2) mail_lock="lockf" ;;
2663
2664   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2665
2666   ## On GNU/Linux systems, both methods are used by various mail programs.
2667   ## I assume most people are using newer mailers that have heard of flock.
2668   ## Change this if you need to.
2669   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2670   ## configure gets the right answers, and that means *NOT* using flock.
2671   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2672   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2673   ## Debian maintainer hasn't provided a clean fix for Emacs.
2674   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2675   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2676   ## correct logic.  -- fx
2677   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2678   ## liblockfile is a Free Software replacement for libmail, used on
2679   ## Debian systems and elsewhere. -rfr.
2680   gnu-*)
2681     mail_lock="flock"
2682     if test $have_mail = yes || test $have_lockfile = yes; then
2683       test $ac_cv_header_maillock_h = yes && mail_lock=no
2684     fi
2685     ;;
2686 esac
2687
2688 BLESSMAIL_TARGET=
2689 case "$mail_lock" in
2690   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2691
2692   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2693
2694   *) BLESSMAIL_TARGET="need-blessmail" ;;
2695 esac
2696 AC_SUBST(BLESSMAIL_TARGET)
2697
2698
2699 AC_CHECK_FUNCS(gethostname getdomainname \
2700 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2701 random lrand48 logb frexp fmod rint cbrt ftime setsid \
2702 strerror fpathconf select euidaccess getpagesize tzset setlocale \
2703 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2704 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm \
2705 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2706 gai_strerror mkstemp getline getdelim mremap fsync sync \
2707 difftime mempcpy mblen mbrlen posix_memalign \
2708 cfmakeraw cfsetspeed isnan copysign __executable_start)
2709
2710 dnl Cannot use AC_CHECK_FUNCS
2711 AC_CACHE_CHECK([for __builtin_unwind_init],
2712                emacs_cv_func___builtin_unwind_init,
2713 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2714                 emacs_cv_func___builtin_unwind_init=yes,
2715                 emacs_cv_func___builtin_unwind_init=no)])
2716 if test $emacs_cv_func___builtin_unwind_init = yes; then
2717   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2718             [Define to 1 if you have the `__builtin_unwind_init' function.])
2719 fi
2720
2721 AC_CHECK_HEADERS(sys/un.h)
2722
2723 AC_FUNC_FSEEKO
2724
2725 AC_FUNC_GETPGRP
2726
2727 # Configure gnulib.
2728 gl_ASSERT_NO_GNULIB_POSIXCHECK
2729 gl_ASSERT_NO_GNULIB_TESTS
2730 gl_INIT
2731
2732 # UNIX98 PTYs.
2733 AC_CHECK_FUNCS(grantpt)
2734
2735 # PTY-related GNU extensions.
2736 AC_CHECK_FUNCS(getpt)
2737
2738 # Check this now, so that we will NOT find the above functions in ncurses.
2739 # That is because we have not set up to link ncurses in lib-src.
2740 # It's better to believe a function is not available
2741 # than to expect to find it in ncurses.
2742 # Also we need tputs and friends to be able to build at all.
2743 have_tputs_et_al=true
2744 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2745 if test "$have_tputs_et_al" != true; then
2746   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2747 Maybe some development libraries/packages are missing?  Try installing
2748 libncurses-dev(el), libterminfo-dev(el) or similar.])
2749 fi
2750 # Must define this when any termcap library is found.
2751 AC_DEFINE(HAVE_LIBNCURSES, 1,
2752           [Define to 1 if you have the `ncurses' library (-lncurses).])
2753 ## FIXME This was the cpp logic, but I am not sure it is right.
2754 ## The above test has not necessarily found libncurses.
2755 HAVE_LIBNCURSES=yes
2756
2757 ## Use terminfo instead of termcap?
2758 ## Note only system files NOT using terminfo are:
2759 ## freebsd < 40000, ms-w32, msdos, netbsd < 599002500, and
2760 ## darwin|gnu without ncurses.
2761 TERMINFO=no
2762 LIBS_TERMCAP=
2763 case "$opsys" in
2764   ## cygwin: Fewer environment variables to go wrong, more terminal types.
2765   ## hpux10-20: Use the system provided termcap(3) library.
2766   ## openbsd: David Mazieres <dm@reeducation-labor.lcs.mit.edu> says this
2767   ##  is necessary.  Otherwise Emacs dumps core when run -nw.
2768   aix4-2|cygwin|hpux*|irix6-5|openbsd|sol2*|unixware) TERMINFO=yes ;;
2769
2770   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2771   ##  The ncurses library has been moved out of the System framework in
2772   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2773   ##  option to use it.
2774   darwin|gnu*)
2775     ## (HAVE_LIBNCURSES was not always true, but is since 2010-03-18.)
2776     if test "x$HAVE_LIBNCURSES" = "xyes"; then
2777       TERMINFO=yes
2778       LIBS_TERMCAP="-lncurses"
2779     fi
2780     ;;
2781
2782   freebsd)
2783     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2784     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2785     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
2786 [[#if __FreeBSD_version < 400000
2787 fail;
2788 #endif
2789 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2790
2791     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2792
2793     if test $emacs_cv_freebsd_terminfo = yes; then
2794       TERMINFO=yes
2795       LIBS_TERMCAP="-lncurses"
2796     else
2797       LIBS_TERMCAP="-ltermcap"
2798     fi
2799     ;;
2800
2801   netbsd)
2802     if test $ac_cv_search_tputs = -lterminfo; then
2803       TERMINFO=yes
2804       LIBS_TERMCAP="-lterminfo"
2805     else
2806       LIBS_TERMCAP="-ltermcap"
2807     fi
2808     ;;
2809
2810 esac
2811
2812 case "$opsys" in
2813   ## hpux: Make sure we get select from libc rather than from libcurses
2814   ##  because libcurses on HPUX 10.10 has a broken version of select.
2815   ##  We used to use -lc -lcurses, but this may be cleaner.
2816   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2817
2818   openbsd) LIBS_TERMCAP="-lncurses" ;;
2819
2820   ## Must use system termcap, if we use any termcap.  It does special things.
2821   sol2*) test "$TERMINFO" != yes && LIBS_TERMCAP="-ltermcap" ;;
2822 esac
2823
2824 TERMCAP_OBJ=tparam.o
2825 if test $TERMINFO = yes; then
2826   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2827
2828   ## Default used to be -ltermcap.  Add a case above if need something else.
2829   test "x$LIBS_TERMCAP" = "x" && LIBS_TERMCAP="-lcurses"
2830
2831   TERMCAP_OBJ=terminfo.o
2832 fi
2833 AC_SUBST(LIBS_TERMCAP)
2834 AC_SUBST(TERMCAP_OBJ)
2835
2836
2837 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2838 resolv=no
2839 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2840 #include <arpa/nameser.h>
2841 #include <resolv.h>]],
2842     [[return res_init();]])],
2843     have_res_init=yes, have_res_init=no)
2844 if test "$have_res_init" = no; then
2845   OLIBS="$LIBS"
2846   LIBS="$LIBS -lresolv"
2847   AC_MSG_CHECKING(for res_init with -lresolv)
2848   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2849 #include <arpa/nameser.h>
2850 #include <resolv.h>]],
2851     [[return res_init();]])],
2852     have_res_init=yes, have_res_init=no)
2853   AC_MSG_RESULT($have_res_init)
2854   if test "$have_res_init" = yes ; then
2855     resolv=yes
2856   fi
2857   LIBS="$OLIBS"
2858 fi
2859
2860 if test "$have_res_init" = yes; then
2861   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2862 fi
2863
2864 # Do we need the Hesiod library to provide the support routines?
2865 LIBHESIOD=
2866 if test "$with_hesiod" != no ; then
2867   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2868   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2869      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2870                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2871   if test "$resolv" = yes ; then
2872     RESOLVLIB=-lresolv
2873   else
2874     RESOLVLIB=
2875   fi
2876   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2877         hesiod=yes, :, $RESOLVLIB)])
2878
2879   if test x"$hesiod" = xyes; then
2880     AC_DEFINE(HAVE_LIBHESIOD, 1,
2881               [Define to 1 if you have the hesiod library (-lhesiod).])
2882     LIBHESIOD=-lhesiod
2883   fi
2884 fi
2885 AC_SUBST(LIBHESIOD)
2886
2887 # Do we need libresolv (due to res_init or Hesiod)?
2888 if test "$resolv" = yes ; then
2889   AC_DEFINE(HAVE_LIBRESOLV, 1,
2890             [Define to 1 if you have the resolv library (-lresolv).])
2891   LIBRESOLV=-lresolv
2892 else
2893   LIBRESOLV=
2894 fi
2895 AC_SUBST(LIBRESOLV)
2896
2897 # These tell us which Kerberos-related libraries to use.
2898 COM_ERRLIB=
2899 CRYPTOLIB=
2900 KRB5LIB=
2901 DESLIB=
2902 KRB4LIB=
2903
2904 if test "${with_kerberos}" != no; then
2905   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2906   if test $have_com_err = yes; then
2907     COM_ERRLIB=-lcom_err
2908     LIBS="$COM_ERRLIB $LIBS"
2909     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2910   fi
2911   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2912   if test $have_crypto = yes; then
2913     CRYPTOLIB=-lcrypto
2914     LIBS="$CRYPTOLIB $LIBS"
2915     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2916   fi
2917   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2918   if test $have_k5crypto = yes; then
2919     CRYPTOLIB=-lk5crypto
2920     LIBS="$CRYPTOLIB $LIBS"
2921     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2922   fi
2923   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2924   if test $have_krb5=yes; then
2925     KRB5LIB=-lkrb5
2926     LIBS="$KRB5LIB $LIBS"
2927     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2928   fi
2929   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2930   if test "${with_kerberos5}" = no; then
2931     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2932     if test $have_des425 = yes; then
2933       DESLIB=-ldes425
2934       LIBS="$DESLIB $LIBS"
2935       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2936     else
2937       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2938       if test $have_des = yes; then
2939         DESLIB=-ldes
2940         LIBS="$DESLIB $LIBS"
2941         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2942       fi
2943     fi
2944     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2945     if test $have_krb4 = yes; then
2946       KRB4LIB=-lkrb4
2947       LIBS="$KRB4LIB $LIBS"
2948       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2949     else
2950       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2951       if test $have_krb = yes; then
2952         KRB4LIB=-lkrb
2953         LIBS="$KRB4LIB $LIBS"
2954         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2955       fi
2956     fi
2957   fi
2958
2959   if test "${with_kerberos5}" != no; then
2960     AC_CHECK_HEADERS(krb5.h,
2961       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2962                         [#include <krb5.h>])])
2963   else
2964     AC_CHECK_HEADERS(des.h,,
2965                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2966                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2967     AC_CHECK_HEADERS(krb.h,,
2968                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2969                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2970   fi
2971   AC_CHECK_HEADERS(com_err.h)
2972 fi
2973
2974 AC_SUBST(COM_ERRLIB)
2975 AC_SUBST(CRYPTOLIB)
2976 AC_SUBST(KRB5LIB)
2977 AC_SUBST(DESLIB)
2978 AC_SUBST(KRB4LIB)
2979
2980 # Solaris requires -lintl if you want strerror (which calls dgettext)
2981 # to return localized messages.
2982 AC_CHECK_LIB(intl, dgettext)
2983
2984 AC_MSG_CHECKING(whether localtime caches TZ)
2985 AC_CACHE_VAL(emacs_cv_localtime_cache,
2986 [if test x$ac_cv_func_tzset = xyes; then
2987 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
2988 char TZ_GMT0[] = "TZ=GMT0";
2989 char TZ_PST8[] = "TZ=PST8";
2990 main()
2991 {
2992   time_t now = time ((time_t *) 0);
2993   int hour_GMT0, hour_unset;
2994   if (putenv (TZ_GMT0) != 0)
2995     exit (1);
2996   hour_GMT0 = localtime (&now)->tm_hour;
2997   unsetenv("TZ");
2998   hour_unset = localtime (&now)->tm_hour;
2999   if (putenv (TZ_PST8) != 0)
3000     exit (1);
3001   if (localtime (&now)->tm_hour == hour_GMT0)
3002     exit (1);
3003   unsetenv("TZ");
3004   if (localtime (&now)->tm_hour != hour_unset)
3005     exit (1);
3006   exit (0);
3007 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3008 [# If we have tzset, assume the worst when cross-compiling.
3009 emacs_cv_localtime_cache=yes])
3010 else
3011         # If we lack tzset, report that localtime does not cache TZ,
3012         # since we can't invalidate the cache if we don't have tzset.
3013         emacs_cv_localtime_cache=no
3014 fi])dnl
3015 AC_MSG_RESULT($emacs_cv_localtime_cache)
3016 if test $emacs_cv_localtime_cache = yes; then
3017   AC_DEFINE(LOCALTIME_CACHE, 1,
3018             [Define to 1 if localtime caches TZ.])
3019 fi
3020
3021 if test "x$HAVE_TIMEVAL" = xyes; then
3022   AC_CHECK_FUNCS(gettimeofday)
3023   if test $ac_cv_func_gettimeofday = yes; then
3024     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
3025                    emacs_cv_gettimeofday_two_arguments,
3026     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3027 #ifdef TIME_WITH_SYS_TIME
3028 #include <sys/time.h>
3029 #include <time.h>
3030 #else
3031 #ifdef HAVE_SYS_TIME_H
3032 #include <sys/time.h>
3033 #else
3034 #include <time.h>
3035 #endif
3036 #endif]],
3037       [[struct timeval time;
3038        gettimeofday (&time, 0);]])],
3039       emacs_cv_gettimeofday_two_arguments=yes,
3040       emacs_cv_gettimeofday_two_arguments=no)])
3041     if test $emacs_cv_gettimeofday_two_arguments = no; then
3042       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
3043                 [Define to 1 if gettimeofday accepts only one argument.])
3044     fi
3045   fi
3046 fi
3047
3048 ok_so_far=yes
3049 AC_CHECK_FUNC(socket, , ok_so_far=no)
3050 if test $ok_so_far = yes; then
3051   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3052 fi
3053 if test $ok_so_far = yes; then
3054   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3055 fi
3056 if test $ok_so_far = yes; then
3057 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3058   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3059             [Define to 1 if you have inet sockets.])
3060 fi
3061
3062 if test -f /usr/lpp/X11/bin/smt.exp; then
3063   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3064             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3065 fi
3066
3067 AC_MSG_CHECKING(whether system supports dynamic ptys)
3068 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3069   AC_MSG_RESULT(yes)
3070   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3071 else
3072   AC_MSG_RESULT(no)
3073 fi
3074
3075 AC_FUNC_FORK
3076
3077 dnl Adapted from Haible's version.
3078 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3079   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3080     [[char* cs = nl_langinfo(CODESET);]])],
3081     emacs_cv_langinfo_codeset=yes,
3082     emacs_cv_langinfo_codeset=no)
3083   ])
3084 if test $emacs_cv_langinfo_codeset = yes; then
3085   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3086     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3087 fi
3088
3089 AC_TYPE_MBSTATE_T
3090
3091 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3092   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3093                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3094 if test "$emacs_cv_c_restrict_arr" = yes; then
3095   AC_DEFINE(__restrict_arr, __restrict,
3096     [Define to compiler's equivalent of C99 restrict keyword in array
3097      declarations.  Define as empty for no equivalent.])
3098 fi
3099
3100 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3101 dnl how the tty code is related to POSIX and/or other versions of termios.
3102 dnl The following looks like a useful start.
3103 dnl
3104 dnl AC_SYS_POSIX_TERMIOS
3105 dnl if test $ac_cv_sys_posix_termios = yes; then
3106 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3107 dnl                                and macros for terminal control.])
3108 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3109 dnl fi
3110
3111 # Set up the CFLAGS for real compilation, so we can substitute it.
3112 CFLAGS="$REAL_CFLAGS"
3113 CPPFLAGS="$REAL_CPPFLAGS"
3114
3115 ## Hack to detect a buggy GCC version.
3116 if test "x$GCC" = xyes \
3117    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3118    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3119    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3120    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3121 fi
3122
3123 version=$PACKAGE_VERSION
3124
3125 ### Specify what sort of things we'll be editing into Makefile and config.h.
3126 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3127 AC_SUBST(version)
3128 AC_SUBST(configuration)
3129 ## Unused?
3130 AC_SUBST(canonical)
3131 AC_SUBST(srcdir)
3132 AC_SUBST(prefix)
3133 AC_SUBST(exec_prefix)
3134 AC_SUBST(bindir)
3135 AC_SUBST(datadir)
3136 AC_SUBST(sharedstatedir)
3137 AC_SUBST(libexecdir)
3138 AC_SUBST(mandir)
3139 AC_SUBST(infodir)
3140 AC_SUBST(lispdir)
3141 AC_SUBST(locallisppath)
3142 AC_SUBST(lisppath)
3143 AC_SUBST(x_default_search_path)
3144 AC_SUBST(etcdir)
3145 AC_SUBST(archlibdir)
3146 AC_SUBST(docdir)
3147 AC_SUBST(bitmapdir)
3148 AC_SUBST(gamedir)
3149 AC_SUBST(gameuser)
3150 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3151 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3152 ## end of LIBX_BASE, but nothing ever set it.
3153 AC_SUBST(LD_SWITCH_X_SITE)
3154 AC_SUBST(C_SWITCH_X_SITE)
3155 AC_SUBST(C_SWITCH_X_SYSTEM)
3156 AC_SUBST(CFLAGS)
3157 ## Used in lwlib/Makefile.in.
3158 AC_SUBST(X_TOOLKIT_TYPE)
3159 if test -n "${machfile}"; then
3160   M_FILE="\$(srcdir)/${machfile}"
3161 else
3162   M_FILE=
3163 fi
3164 S_FILE="\$(srcdir)/${opsysfile}"
3165 AC_SUBST(M_FILE)
3166 AC_SUBST(S_FILE)
3167 AC_SUBST(ns_appdir)
3168 AC_SUBST(ns_appbindir)
3169 AC_SUBST(ns_appresdir)
3170 AC_SUBST(ns_appsrc)
3171 AC_SUBST(GNU_OBJC_CFLAGS)
3172 AC_SUBST(OTHER_FILES)
3173
3174 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3175                    [Define to the canonical Emacs configuration name.])
3176 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3177                    [Define to the options passed to configure.])
3178 if test -n "$machfile"; then
3179   AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3180                      [Define to the used machine dependent file.])
3181 fi
3182 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3183                    [Define to the used os dependent file.])
3184
3185 XMENU_OBJ=
3186 XOBJ=
3187 FONT_OBJ=
3188 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3189   AC_DEFINE(HAVE_X_WINDOWS, 1,
3190             [Define to 1 if you want to use the X window system.])
3191   XMENU_OBJ=xmenu.o
3192   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3193   FONT_OBJ=xfont.o
3194   if test "$HAVE_XFT" = "yes"; then
3195     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3196   elif test "$HAVE_FREETYPE" = "yes"; then
3197     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3198   fi
3199   AC_SUBST(FONT_OBJ)
3200 fi
3201 AC_SUBST(XMENU_OBJ)
3202 AC_SUBST(XOBJ)
3203 AC_SUBST(FONT_OBJ)
3204
3205 WIDGET_OBJ=
3206 MOTIF_LIBW=
3207 if test "${USE_X_TOOLKIT}" != "none" ; then
3208   WIDGET_OBJ=widget.o
3209   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3210   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3211     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3212   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3213     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3214     MOTIF_LIBW=-lXm
3215     case "$opsys" in
3216       gnu-linux)
3217         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3218         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3219         ;;
3220
3221       unixware)
3222         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3223         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3224         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3225         ;;
3226
3227       aix4-2)
3228         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3229         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3230         ;;
3231     esac
3232     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3233   fi
3234 fi
3235 AC_SUBST(WIDGET_OBJ)
3236
3237 TOOLKIT_LIBW=
3238 case "$USE_X_TOOLKIT" in
3239   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3240   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3241   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3242 esac
3243 AC_SUBST(TOOLKIT_LIBW)
3244
3245 if test "$USE_X_TOOLKIT" = "none"; then
3246   LIBXT_OTHER="\$(LIBXSM)"
3247   OLDXMENU_TARGET="really-oldXMenu"
3248 else
3249   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3250   OLDXMENU_TARGET="really-lwlib"
3251 fi
3252 AC_SUBST(LIBXT_OTHER)
3253
3254 ## The X Menu stuff is present in the X10 distribution, but missing
3255 ## from X11.  If we have X10, just use the installed library;
3256 ## otherwise, use our own copy.
3257 if test "${HAVE_X11}" = "yes" ; then
3258   AC_DEFINE(HAVE_X11, 1,
3259             [Define to 1 if you want to use version 11 of X windows.
3260              Otherwise, Emacs expects to use version 10.])
3261
3262   if test "$USE_X_TOOLKIT" = "none"; then
3263     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
3264   else
3265     OLDXMENU="\${lwlibdir}/liblw.a"
3266   fi
3267   LIBXMENU="\$(OLDXMENU)"
3268   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3269   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3270 else
3271   ## For a syntactically valid Makefile; not actually used for anything.
3272   ## See comments in src/Makefile.in.
3273   OLDXMENU=nothing
3274   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3275   if test "${HAVE_X_WINDOWS}" = "yes"; then
3276     LIBXMENU="-lXMenu"
3277   else
3278     LIBXMENU=
3279   fi
3280   LIBX_OTHER=
3281   OLDXMENU_DEPS=
3282 fi
3283
3284 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3285   OLDXMENU_TARGET=
3286   OLDXMENU=nothing
3287   LIBXMENU=
3288   OLDXMENU_DEPS=
3289 fi
3290
3291 AC_SUBST(OLDXMENU_TARGET)
3292 AC_SUBST(OLDXMENU)
3293 AC_SUBST(LIBXMENU)
3294 AC_SUBST(LIBX_OTHER)
3295 AC_SUBST(OLDXMENU_DEPS)
3296
3297 if test "${HAVE_MENUS}" = "yes" ; then
3298   AC_DEFINE(HAVE_MENUS, 1,
3299             [Define to 1 if you have mouse menus.
3300              (This is automatic if you use X, but the option to specify it remains.)
3301              It is also defined with other window systems that support xmenu.c.])
3302 fi
3303
3304 if test "${GNU_MALLOC}" = "yes" ; then
3305   AC_DEFINE(GNU_MALLOC, 1,
3306             [Define to 1 if you want to use the GNU memory allocator.])
3307 fi
3308
3309 RALLOC_OBJ=
3310 if test "${REL_ALLOC}" = "yes" ; then
3311   AC_DEFINE(REL_ALLOC, 1,
3312             [Define REL_ALLOC if you want to use the relocating allocator for
3313              buffer space.])
3314
3315   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3316 fi
3317 AC_SUBST(RALLOC_OBJ)
3318
3319 if test "$opsys" = "cygwin"; then
3320   CYGWIN_OBJ="sheap.o"
3321   ## Cygwin differs because of its unexec().
3322   PRE_ALLOC_OBJ=
3323   POST_ALLOC_OBJ=lastfile.o
3324 else
3325   CYGWIN_OBJ=
3326   PRE_ALLOC_OBJ=lastfile.o
3327   POST_ALLOC_OBJ=
3328 fi
3329 AC_SUBST(CYGWIN_OBJ)
3330 AC_SUBST(PRE_ALLOC_OBJ)
3331 AC_SUBST(POST_ALLOC_OBJ)
3332
3333
3334 case "$opsys" in
3335   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3336
3337   darwin)
3338    ## The -headerpad option tells ld (see man page) to leave room at the
3339    ## end of the header for adding load commands.  Needed for dumping.
3340    ## 0x690 is the total size of 30 segment load commands (at 56
3341    ## each); under Cocoa 31 commands are required.
3342    if test "$HAVE_NS" = "yes"; then
3343      libs_nsgui="-framework AppKit"
3344      headerpad_extra=6C8
3345    else
3346      libs_nsgui=
3347      headerpad_extra=690
3348    fi
3349    LD_SWITCH_SYSTEM_TEMACS="-prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3350
3351    ## This is here because src/Makefile.in did some extra fiddling around
3352    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3353    ##   #ifndef LD_SWITCH_SYSTEM
3354    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3355    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3356    ## not using gcc, darwin system not on an alpha (ie darwin, since
3357    ## darwin + alpha does not occur).
3358    ## Because this was done in src/Makefile.in, the resulting part of
3359    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3360    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3361    ## rather than LD_SWITCH_SYSTEM.
3362    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3363      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3364    ;;
3365
3366   ## LD_SWITCH_X_SITE_AUX is a -R option saying where to find X at run-time.
3367   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at
3368   ## the point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_AUX
3369   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3370   ## had different values in configure (in ac_link) and src/Makefile.in.
3371   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3372   gnu-linux) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_AUX)" ;;
3373
3374   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3375 esac
3376
3377 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3378   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3379 fi
3380
3381 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3382
3383
3384 LD_FIRSTFLAG=
3385 ORDINARY_LINK=
3386 case "$opsys" in
3387   ## gnu: GNU needs its own crt0.
3388   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3389
3390   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3391   ## library search parth, i.e. it won't search /usr/lib for libc and
3392   ## friends.  Using -nostartfiles instead avoids this problem, and
3393   ## will also work on earlier NetBSD releases.
3394   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
3395
3396   ## macpcc: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3397   ##   MkLinux/LinuxPPC needs this.
3398   ## ibms390x only supports opsys = gnu-linux so it can be added here.
3399   gnu-*)
3400     case "$machine" in
3401       macppc|ibms390x) LD_FIRSTFLAG="-nostdlib" ;;
3402     esac
3403     ;;
3404 esac
3405
3406
3407 if test "x$ORDINARY_LINK" = "xyes"; then
3408
3409   LD_FIRSTFLAG=""
3410   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3411
3412 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
3413 ## freebsd, gnu-* not on macppc|ibms390x.
3414 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
3415
3416   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3417   ## places that are difficult to figure out at make time.  Fortunately,
3418   ## these same versions allow you to pass arbitrary flags on to the
3419   ## linker, so there is no reason not to use it as a linker.
3420   ##
3421   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3422   ## searching for libraries in its internal directories, so we have to
3423   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3424   LD_FIRSTFLAG="-nostdlib"
3425 fi
3426
3427 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3428 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
3429
3430 AC_SUBST(LD_FIRSTFLAG)
3431
3432
3433 ## FIXME? The logic here is not precisely the same as that above.
3434 ## There is no check here for a pre-defined LD_FIRSTFLAG.
3435 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3436 LIB_GCC=
3437 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3438
3439   case "$opsys" in
3440     freebsd|netbsd|openbsd) LIB_GCC= ;;
3441
3442     gnu-*)
3443       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3444       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3445       case $host_cpu in
3446       arm*)
3447         LIB_GCC="-lgcc_s"
3448         ;;
3449       *)
3450         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3451         ## immediately undefine it again and redefine it to empty.
3452         ## Was the C_SWITCH_X_SITE part really necessary?
3453 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3454         LIB_GCC=
3455         ;;
3456       esac
3457       ;;
3458
3459     ## Ask GCC where to find libgcc.a.
3460     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3461   esac
3462 fi                              dnl if $GCC
3463 AC_SUBST(LIB_GCC)
3464
3465
3466 ## If we're using X11/GNUstep, define some consequences.
3467 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3468   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3469   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3470 fi
3471
3472
3473 AH_TOP([/* GNU Emacs site configuration template file.
3474
3475 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2011
3476   Free Software Foundation, Inc.
3477
3478 This file is part of GNU Emacs.
3479
3480 GNU Emacs is free software: you can redistribute it and/or modify
3481 it under the terms of the GNU General Public License as published by
3482 the Free Software Foundation, either version 3 of the License, or
3483 (at your option) any later version.
3484
3485 GNU Emacs is distributed in the hope that it will be useful,
3486 but WITHOUT ANY WARRANTY; without even the implied warranty of
3487 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3488 GNU General Public License for more details.
3489
3490 You should have received a copy of the GNU General Public License
3491 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3492
3493
3494 /* No code in Emacs #includes config.h twice, but some bits of code
3495    intended to work with other packages as well (like gmalloc.c)
3496    think they can include it as many times as they like.  */
3497 #ifndef EMACS_CONFIG_H
3498 #define EMACS_CONFIG_H
3499 ])dnl
3500
3501 AH_BOTTOM([
3502 /* On AIX 3 this must be included before any other include file.  */
3503 #include <alloca.h>
3504 #if ! HAVE_ALLOCA
3505 # error "alloca not available on this machine"
3506 #endif
3507
3508 /* Define AMPERSAND_FULL_NAME if you use the convention
3509    that & in the full name stands for the login id.  */
3510 /* Turned on June 1996 supposing nobody will mind it.  */
3511 #define AMPERSAND_FULL_NAME
3512
3513 /* `subprocesses' should be defined if you want to
3514    have code for asynchronous subprocesses
3515    (as used in M-x compile and M-x shell).
3516    Only MSDOS does not support this (it overrides
3517    this in its config_opsysfile below).  */
3518
3519 #define subprocesses
3520
3521 /* Include the os and machine dependent files.  */
3522 #include config_opsysfile
3523 #ifdef config_machfile
3524 # include config_machfile
3525 #endif
3526
3527 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3528    SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.
3529   (There is probably a better place to do this, but right now the
3530    Cocoa side does this in s/darwin.h and we cannot parallel this
3531    exactly since GNUstep is multi-OS.  */
3532 #if defined HAVE_NS && defined NS_IMPL_GNUSTEP
3533 #  define SYSTEM_PURESIZE_EXTRA 30000
3534 #endif
3535
3536 #ifdef emacs /* Don't do this for lib-src.  */
3537 /* Tell regex.c to use a type compatible with Emacs.  */
3538 #define RE_TRANSLATE_TYPE Lisp_Object
3539 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3540 #ifdef make_number
3541 /* If make_number is a macro, use it.  */
3542 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3543 #else
3544 /* If make_number is a function, avoid it.  */
3545 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3546 #endif
3547 #endif
3548
3549 /* These default definitions are good for almost all machines.
3550    Any exceptions should override them in m/MACHINE.h.
3551    They must be usable in preprocessor conditionals.  */
3552
3553 #ifndef BITS_PER_CHAR
3554 #define BITS_PER_CHAR 8
3555 #endif
3556
3557 #ifndef BITS_PER_SHORT
3558 #define BITS_PER_SHORT 16
3559 #endif
3560
3561 #ifndef BITS_PER_INT
3562 #define BITS_PER_INT 32
3563 #endif
3564
3565 #ifndef BITS_PER_LONG
3566 #ifdef _LP64
3567 #define BITS_PER_LONG 64
3568 #else
3569 #define BITS_PER_LONG 32
3570 #endif
3571 #endif
3572
3573 #if !defined BITS_PER_LONG_LONG && HAVE_LONG_LONG_INT
3574 #define BITS_PER_LONG_LONG 64
3575 #endif
3576
3577 /* Define if the compiler supports function prototypes.  It may do so but
3578    not define __STDC__ (e.g. DEC C by default) or may define it as zero.  */
3579 #undef PROTOTYPES
3580
3581 #include <string.h>
3582 #include <stdlib.h>
3583
3584 #if defined __GNUC__ && (__GNUC__ > 2 \
3585                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3586 #define NO_RETURN       __attribute__ ((__noreturn__))
3587 #else
3588 #define NO_RETURN       /* nothing */
3589 #endif
3590
3591 #if __GNUC__ >= 3  /* On GCC 3.0 we might get a warning.  */
3592 #define NO_INLINE __attribute__((noinline))
3593 #else
3594 #define NO_INLINE
3595 #endif
3596
3597 #if (__GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 1))
3598 #define EXTERNALLY_VISIBLE __attribute__((externally_visible))
3599 #else
3600 #define EXTERNALLY_VISIBLE
3601 #endif
3602
3603 #if __GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 7)
3604 # define ATTRIBUTE_FORMAT(spec) __attribute__ ((__format__ spec))
3605 #else
3606 # define ATTRIBUTE_FORMAT(spec) /* empty */
3607 #endif
3608
3609 #if __GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 4)
3610 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3611    ATTRIBUTE_FORMAT ((__gnu_printf__, formatstring_parameter, first_argument))
3612 #else
3613 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3614    ATTRIBUTE_FORMAT ((__printf__, formatstring_parameter, first_argument))
3615 #endif
3616
3617 /* Some versions of GNU/Linux define noinline in their headers.  */
3618 #ifdef noinline
3619 #undef noinline
3620 #endif
3621
3622 /* These won't be used automatically yet.  We also need to know, at least,
3623    that the stack is continuous.  */
3624 #ifdef __GNUC__
3625 #  ifndef GC_SETJMP_WORKS
3626   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3627 #    define GC_SETJMP_WORKS 1
3628 #  endif
3629 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3630 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3631 #  endif
3632 #endif
3633
3634 #endif /* EMACS_CONFIG_H */
3635
3636 /*
3637 Local Variables:
3638 mode: c
3639 End:
3640 */
3641 ])dnl
3642
3643 #### Report on what we decided to do.
3644 #### Report GTK as a toolkit, even if it doesn't use Xt.
3645 #### It makes printing result more understandable as using GTK sets
3646 #### toolkit_scroll_bars to yes by default.
3647 if test "${HAVE_GTK}" = "yes"; then
3648   USE_X_TOOLKIT=GTK
3649 fi
3650
3651 and_machfile=
3652 if test -n "$machfile"; then
3653   and_machfile=" and \`${machfile}'"
3654 fi
3655
3656 echo "
3657 Configured for \`${canonical}'.
3658
3659   Where should the build process find the source code?    ${srcdir}
3660   What operating system and machine description files should Emacs use?
3661         \`${opsysfile}'${and_machfile}
3662   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3663   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3664   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3665   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3666   What window system should Emacs use?                    ${window_system}
3667   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3668
3669 if test -n "${x_includes}"; then
3670 echo "  Where do we find X Windows header files?                ${x_includes}"
3671 else
3672 echo "  Where do we find X Windows header files?                Standard dirs"
3673 fi
3674 if test -n "${x_libraries}"; then
3675 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3676 else
3677 echo "  Where do we find X Windows libraries?                   Standard dirs"
3678 fi
3679
3680 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3681 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3682 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3683 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3684 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3685 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3686 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3687 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
3688
3689 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3690 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3691 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3692 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
3693 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3694 echo "  Does Emacs use -lgnutls (2.6.x or higher)?              ${HAVE_GNUTLS}"
3695 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
3696
3697 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3698 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3699 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3700 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3701
3702 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3703 echo
3704
3705 if test $USE_XASSERTS = yes; then
3706    echo "  Compiling with asserts turned on."
3707    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3708 fi
3709
3710 echo
3711
3712 if test "$HAVE_NS" = "yes"; then
3713    echo
3714    echo "You must run \"make install\" in order to test the built application.
3715 The installed application will go to nextstep/Emacs.app and can be
3716 run or moved from there."
3717    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3718       echo "The application will be fully self-contained."
3719     else
3720       echo "The lisp resources for the application will be installed under ${prefix}.
3721 You may need to run \"make install\" with sudo.  The application will fail
3722 to run if these resources are not installed."
3723    fi
3724    echo
3725 fi
3726
3727
3728 # Remove any trailing slashes in these variables.
3729 [test "${prefix}" != NONE &&
3730   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3731 test "${exec_prefix}" != NONE &&
3732   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3733
3734 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
3735 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
3736 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
3737 dnl (else you get "no `Makefile.am' found for any configure output").
3738 dnl This will work, but you get a config.status that is not quite right
3739 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
3740 dnl That doesn't have any obvious consequences for Emacs, but on the whole
3741 dnl it seems better to just live with the duplication.
3742 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile"
3743
3744 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
3745        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3746        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
3747        leim/Makefile])
3748
3749 dnl test/ is not present in release tarfiles.
3750 opt_makefile=test/automated/Makefile
3751
3752 if test -f $srcdir/${opt_makefile}.in; then
3753   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
3754   dnl Again, it's best not to use a variable.  Though you can add
3755   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
3756   AC_CONFIG_FILES([test/automated/Makefile])
3757 fi
3758
3759 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
3760
3761 AC_SUBST(SUBDIR_MAKEFILES_IN)
3762
3763 dnl Make the necessary directories, if they don't exist.
3764 AC_CONFIG_COMMANDS([mkdirs], [
3765 for dir in etc lisp ; do
3766   test -d ${dir} || mkdir ${dir}
3767 done
3768 ])
3769
3770 dnl You might wonder (I did) why epaths.h is generated by running make,
3771 dnl rather than just letting configure generate it from epaths.in.
3772 dnl One reason is that the various paths are not fully expanded (see above);
3773 dnl eg gamedir=${prefix}/var/games/emacs.
3774 dnl Secondly, the GNU Coding standards require that one should be able
3775 dnl to run `make prefix=/some/where/else' and override the values set
3776 dnl by configure.  This also explains the `move-if-change' test and
3777 dnl the use of force in the `epaths-force' rule in Makefile.in.
3778 AC_CONFIG_COMMANDS([epaths], [
3779 echo creating src/epaths.h
3780 ${MAKE-make} epaths-force
3781 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPPFLAGS="$CPPFLAGS"])
3782
3783 AC_CONFIG_COMMANDS([gdbinit], [
3784 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3785   echo creating src/.gdbinit
3786   echo source $srcdir/src/.gdbinit > src/.gdbinit
3787 fi
3788 ])
3789
3790 AC_OUTPUT
3791
3792 dnl configure.in ends here