code.delx.au - gnu-emacs/blob - lisp/emacs-lisp/derived.el

   1 ;;; derived.el --- allow inheritance of major modes
   2 ;; (formerly mode-clone.el)
   3
   4 ;; Copyright (C) 1993-1994, 1999, 2001-2016 Free Software Foundation,
   5 ;; Inc.
   6
   7 ;; Author: David Megginson (dmeggins@aix1.uottawa.ca)
   8 ;; Maintainer: emacs-devel@gnu.org
   9 ;; Keywords: extensions
  10 ;; Package: emacs
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26 \f
  27 ;;; Commentary:
  28
  29 ;; GNU Emacs is already, in a sense, object oriented -- each object
  30 ;; (buffer) belongs to a class (major mode), and that class defines
  31 ;; the relationship between messages (input events) and methods
  32 ;; (commands) by means of a keymap.
  33 ;;
  34 ;; The only thing missing is a good scheme of inheritance.  It is
  35 ;; possible to simulate a single level of inheritance with generous
  36 ;; use of hooks and a bit of work -- sgml-mode, for example, also runs
  37 ;; the hooks for text-mode, and keymaps can inherit from other keymaps
  38 ;; -- but generally, each major mode ends up reinventing the wheel.
  39 ;; Ideally, someone should redesign all of Emacs's major modes to
  40 ;; follow a more conventional object-oriented system: when defining a
  41 ;; new major mode, the user should need only to name the existing mode
  42 ;; it is most similar to, then list the (few) differences.
  43 ;;
  44 ;; In the mean time, this package offers most of the advantages of
  45 ;; full inheritance with the existing major modes.  The macro
  46 ;; `define-derived-mode' allows the user to make a variant of an existing
  47 ;; major mode, with its own keymap.  The new mode will inherit the key
  48 ;; bindings of its parent, and will, in fact, run its parent first
  49 ;; every time it is called.  For example, the commands
  50 ;;
  51 ;;  (define-derived-mode hypertext-mode text-mode "Hypertext"
  52 ;;    "Major mode for hypertext.\n\n\\{hypertext-mode-map}"
  53 ;;    (setq case-fold-search nil))
  54 ;;
  55 ;;  (define-key hypertext-mode-map [down-mouse-3] 'do-hyper-link)
  56 ;;
  57 ;; will create a function `hypertext-mode' with its own (sparse)
  58 ;; keymap `hypertext-mode-map.'  The command M-x hypertext-mode will
  59 ;; perform the following actions:
  60 ;;
  61 ;; - run the command (text-mode) to get its default setup
  62 ;; - replace the current keymap with 'hypertext-mode-map,' which will
  63 ;;   inherit from 'text-mode-map'.
  64 ;; - replace the current syntax table with
  65 ;;   'hypertext-mode-syntax-table', which will borrow its defaults
  66 ;;   from the current text-mode-syntax-table.
  67 ;; - replace the current abbrev table with
  68 ;;   'hypertext-mode-abbrev-table', which will borrow its defaults
  69 ;;   from the current text-mode-abbrev table
  70 ;; - change the mode line to read "Hypertext"
  71 ;; - assign the value 'hypertext-mode' to the 'major-mode' variable
  72 ;; - run the body of commands provided in the macro -- in this case,
  73 ;;   set the local variable `case-fold-search' to nil.
  74 ;;
  75 ;; The advantages of this system are threefold.  First, text mode is
  76 ;; untouched -- if you had added the new keystroke to `text-mode-map,'
  77 ;; possibly using hooks, you would have added it to all text buffers
  78 ;; -- here, it appears only in hypertext buffers, where it makes
  79 ;; sense.  Second, it is possible to build even further, and make
  80 ;; a derived mode from a derived mode.  The commands
  81 ;;
  82 ;;   (define-derived-mode html-mode hypertext-mode "HTML")
  83 ;;   [various key definitions]
  84 ;;
  85 ;; will add a new major mode for HTML with very little fuss.
  86 ;;
  87 ;; Note also the function `derived-mode-p' which can tell if the current
  88 ;; mode derives from another.  In a hypertext-mode, buffer, for example,
  89 ;; (derived-mode-p 'text-mode) would return non-nil.  This should always
  90 ;; be used in place of (eq major-mode 'text-mode).
  91 \f
  92 ;;; Code:
  93
  94 ;;; PRIVATE: defsubst must be defined before they are first used
  95
  96 (defsubst derived-mode-hook-name (mode)
  97   "Construct a mode-hook name based on a MODE name."
  98   (intern (concat (symbol-name mode) "-hook")))
  99
 100 (defsubst derived-mode-map-name (mode)
 101   "Construct a map name based on a MODE name."
 102   (intern (concat (symbol-name mode) "-map")))
 103
 104 (defsubst derived-mode-syntax-table-name (mode)
 105   "Construct a syntax-table name based on a MODE name."
 106   (intern (concat (symbol-name mode) "-syntax-table")))
 107
 108 (defsubst derived-mode-abbrev-table-name (mode)
 109   "Construct an abbrev-table name based on a MODE name."
 110   (intern (concat (symbol-name mode) "-abbrev-table")))
 111
 112 ;; PUBLIC: define a new major mode which inherits from an existing one.
 113
 114 ;;;###autoload
 115 (defmacro define-derived-mode (child parent name &optional docstring &rest body)
 116   "Create a new mode as a variant of an existing mode.
 117
 118 The arguments to this command are as follow:
 119
 120 CHILD:     the name of the command for the derived mode.
 121 PARENT:    the name of the command for the parent mode (e.g. `text-mode')
 122            or nil if there is no parent.
 123 NAME:      a string which will appear in the status line (e.g. \"Hypertext\")
 124 DOCSTRING: an optional documentation string--if you do not supply one,
 125            the function will attempt to invent something useful.
 126 BODY:      forms to execute just before running the
 127            hooks for the new mode.  Do not use `interactive' here.
 128
 129 BODY can start with a bunch of keyword arguments.  The following keyword
 130   arguments are currently understood:
 131 :group GROUP
 132         Declare the customization group that corresponds to this mode.
 133         The command `customize-mode' uses this.
 134 :syntax-table TABLE
 135         Use TABLE instead of the default (CHILD-syntax-table).
 136         A nil value means to simply use the same syntax-table as the parent.
 137 :abbrev-table TABLE
 138         Use TABLE instead of the default (CHILD-abbrev-table).
 139         A nil value means to simply use the same abbrev-table as the parent.
 140
 141 Here is how you could define LaTeX-Thesis mode as a variant of LaTeX mode:
 142
 143   (define-derived-mode LaTeX-thesis-mode LaTeX-mode \"LaTeX-Thesis\")
 144
 145 You could then make new key bindings for `LaTeX-thesis-mode-map'
 146 without changing regular LaTeX mode.  In this example, BODY is empty,
 147 and DOCSTRING is generated by default.
 148
 149 On a more complicated level, the following command uses `sgml-mode' as
 150 the parent, and then sets the variable `case-fold-search' to nil:
 151
 152   (define-derived-mode article-mode sgml-mode \"Article\"
 153     \"Major mode for editing technical articles.\"
 154     (setq case-fold-search nil))
 155
 156 Note that if the documentation string had been left out, it would have
 157 been generated automatically, with a reference to the keymap.
 158
 159 The new mode runs the hook constructed by the function
 160 `derived-mode-hook-name'.
 161
 162 See Info node `(elisp)Derived Modes' for more details."
 163   (declare (debug (&define name symbolp sexp [&optional stringp]
 164                            [&rest keywordp sexp] def-body))
 165            (doc-string 4)
 166            (indent 3))
 167
 168   (when (and docstring (not (stringp docstring)))
 169     ;; Some trickiness, since what appears to be the docstring may really be
 170     ;; the first element of the body.
 171     (push docstring body)
 172     (setq docstring nil))
 173
 174   (when (eq parent 'fundamental-mode) (setq parent nil))
 175
 176   (let ((map (derived-mode-map-name child))
 177         (syntax (derived-mode-syntax-table-name child))
 178         (abbrev (derived-mode-abbrev-table-name child))
 179         (declare-abbrev t)
 180         (declare-syntax t)
 181         (hook (derived-mode-hook-name child))
 182         (group nil))
 183
 184     ;; Process the keyword args.
 185     (while (keywordp (car body))
 186       (pcase (pop body)
 187         (`:group (setq group (pop body)))
 188         (`:abbrev-table (setq abbrev (pop body)) (setq declare-abbrev nil))
 189         (`:syntax-table (setq syntax (pop body)) (setq declare-syntax nil))
 190         (_ (pop body))))
 191
 192     (setq docstring (derived-mode-make-docstring
 193                      parent child docstring syntax abbrev))
 194
 195     `(progn
 196        (defvar ,hook nil
 197          ,(format "Hook run after entering %s mode.
 198 No problems result if this variable is not bound.
 199 `add-hook' automatically binds it.  (This is true for all hook variables.)"
 200                   name))
 201        (unless (boundp ',map)
 202          (put ',map 'definition-name ',child))
 203        (with-no-warnings (defvar ,map (make-sparse-keymap)))
 204        (unless (get ',map 'variable-documentation)
 205          (put ',map 'variable-documentation
 206               (purecopy ,(format "Keymap for `%s'." child))))
 207        ,(if declare-syntax
 208             `(progn
 209                (unless (boundp ',syntax)
 210                  (put ',syntax 'definition-name ',child))
 211                (defvar ,syntax (make-syntax-table))
 212                (unless (get ',syntax 'variable-documentation)
 213                  (put ',syntax 'variable-documentation
 214                       (purecopy ,(format "Syntax table for `%s'." child))))))
 215        ,(if declare-abbrev
 216             `(progn
 217                (put ',abbrev 'definition-name ',child)
 218                (defvar ,abbrev
 219                  (progn (define-abbrev-table ',abbrev nil) ,abbrev))
 220                (unless (get ',abbrev 'variable-documentation)
 221                  (put ',abbrev 'variable-documentation
 222                       (purecopy ,(format "Abbrev table for `%s'." child))))))
 223        (put ',child 'derived-mode-parent ',parent)
 224        ,(if group `(put ',child 'custom-mode-group ,group))
 225
 226        (defun ,child ()
 227          ,docstring
 228          (interactive)
 229                                         ; Run the parent.
 230          (delay-mode-hooks
 231
 232           (,(or parent 'kill-all-local-variables))
 233                                         ; Identify the child mode.
 234           (setq major-mode (quote ,child))
 235           (setq mode-name ,name)
 236                                         ; Identify special modes.
 237           ,(when parent
 238              `(progn
 239                 (if (get (quote ,parent) 'mode-class)
 240                     (put (quote ,child) 'mode-class
 241                          (get (quote ,parent) 'mode-class)))
 242                                         ; Set up maps and tables.
 243                 (unless (keymap-parent ,map)
 244                   ;; It would probably be better to set the keymap's parent
 245                   ;; at the toplevel rather than inside the mode function,
 246                   ;; but this is not easy for at least the following reasons:
 247                   ;; - the parent (and its keymap) may not yet be loaded.
 248                   ;; - the parent's keymap name may be called something else
 249                   ;;   than <parent>-mode-map.
 250                   (set-keymap-parent ,map (current-local-map)))
 251                 ,(when declare-syntax
 252                    `(let ((parent (char-table-parent ,syntax)))
 253                       (unless (and parent
 254                                    (not (eq parent (standard-syntax-table))))
 255                         (set-char-table-parent ,syntax (syntax-table)))))
 256                 ,(when declare-abbrev
 257                    `(unless (or (abbrev-table-get ,abbrev :parents)
 258                                 ;; This can happen if the major mode defines
 259                                 ;; the abbrev-table to be its parent's.
 260                                 (eq ,abbrev local-abbrev-table))
 261                       (abbrev-table-put ,abbrev :parents
 262                                         (list local-abbrev-table))))))
 263           (use-local-map ,map)
 264           ,(when syntax `(set-syntax-table ,syntax))
 265           ,(when abbrev `(setq local-abbrev-table ,abbrev))
 266                                         ; Splice in the body (if any).
 267           ,@body
 268           )
 269          ;; Run the hooks, if any.
 270          (run-mode-hooks ',hook)))))
 271
 272 ;; PUBLIC: find the ultimate class of a derived mode.
 273
 274 (defun derived-mode-class (mode)
 275   "Find the class of a major MODE.
 276 A mode's class is the first ancestor which is NOT a derived mode.
 277 Use the `derived-mode-parent' property of the symbol to trace backwards.
 278 Since major-modes might all derive from `fundamental-mode', this function
 279 is not very useful."
 280   (declare (obsolete derived-mode-p "22.1"))
 281   (while (get mode 'derived-mode-parent)
 282     (setq mode (get mode 'derived-mode-parent)))
 283   mode)
 284
 285 \f
 286 ;;; PRIVATE
 287
 288 (defun derived-mode-make-docstring (parent child &optional
 289                                            docstring syntax abbrev)
 290   "Construct a docstring for a new mode if none is provided."
 291
 292   (let ((map (derived-mode-map-name child))
 293         (hook (derived-mode-hook-name child)))
 294
 295     (unless (stringp docstring)
 296       ;; Use a default docstring.
 297       (setq docstring
 298             (if (null parent)
 299                 ;; FIXME filling.
 300                 (format "Major-mode.\nUses keymap `%s'%s%s." map
 301                         (if abbrev (format "%s abbrev table `%s'"
 302                                            (if syntax "," " and") abbrev) "")
 303                         (if syntax (format " and syntax-table `%s'" syntax) ""))
 304               (format "Major mode derived from `%s' by `define-derived-mode'.
 305 It inherits all of the parent's attributes, but has its own keymap%s:
 306
 307   `%s'%s
 308
 309 which more-or-less shadow%s %s's corresponding table%s."
 310                       parent
 311                       (cond ((and abbrev syntax)
 312                              ",\nabbrev table and syntax table")
 313                             (abbrev "\nand abbrev table")
 314                             (syntax "\nand syntax table")
 315                             (t ""))
 316                       map
 317                       (cond ((and abbrev syntax)
 318                              (format ", `%s' and `%s'" abbrev syntax))
 319                             ((or abbrev syntax)
 320                              (format " and `%s'" (or abbrev syntax)))
 321                             (t ""))
 322                       (if (or abbrev syntax) "" "s")
 323                       parent
 324                       (if (or abbrev syntax) "s" "")))))
 325
 326     (unless (string-match (regexp-quote (symbol-name hook)) docstring)
 327       ;; Make sure the docstring mentions the mode's hook.
 328       (setq docstring
 329             (concat docstring
 330                     (if (null parent)
 331                         "\n\nThis mode "
 332                       (concat
 333                        "\n\nIn addition to any hooks its parent mode "
 334                        (if (string-match (format "[`‘]%s['’]"
 335                                                  (regexp-quote
 336                                                   (symbol-name parent)))
 337                                          docstring)
 338                            nil
 339                          (format "`%s' " parent))
 340                        "might have run,\nthis mode "))
 341                     (format "runs the hook `%s'" hook)
 342                     ", as the final step\nduring initialization.")))
 343
 344     (unless (string-match "\\\\[{[]" docstring)
 345       ;; And don't forget to put the mode's keymap.
 346       (setq docstring (concat docstring "\n\n\\{" (symbol-name map) "}")))
 347
 348     docstring))
 349
 350 \f
 351 ;;; OBSOLETE
 352 ;; The functions below are only provided for backward compatibility with
 353 ;; code byte-compiled with versions of derived.el prior to Emacs-21.
 354
 355 (defsubst derived-mode-setup-function-name (mode)
 356   "Construct a setup-function name based on a MODE name."
 357   (intern (concat (symbol-name mode) "-setup")))
 358
 359 \f
 360 ;; Utility functions for defining a derived mode.
 361
 362 ;;;###autoload
 363 (defun derived-mode-init-mode-variables (mode)
 364   "Initialize variables for a new MODE.
 365 Right now, if they don't already exist, set up a blank keymap, an
 366 empty syntax table, and an empty abbrev table -- these will be merged
 367 the first time the mode is used."
 368
 369   (if (boundp (derived-mode-map-name mode))
 370       t
 371     (eval `(defvar ,(derived-mode-map-name mode)
 372                (make-sparse-keymap)
 373                ,(format "Keymap for %s." mode)))
 374     (put (derived-mode-map-name mode) 'derived-mode-unmerged t))
 375
 376   (if (boundp (derived-mode-syntax-table-name mode))
 377       t
 378     (eval `(defvar ,(derived-mode-syntax-table-name mode)
 379              ;; Make a syntax table which doesn't specify anything
 380              ;; for any char.  Valid data will be merged in by
 381              ;; derived-mode-merge-syntax-tables.
 382              (make-char-table 'syntax-table nil)
 383              ,(format "Syntax table for %s." mode)))
 384     (put (derived-mode-syntax-table-name mode) 'derived-mode-unmerged t))
 385
 386   (if (boundp (derived-mode-abbrev-table-name mode))
 387       t
 388     (eval `(defvar ,(derived-mode-abbrev-table-name mode)
 389              (progn
 390                (define-abbrev-table (derived-mode-abbrev-table-name mode) nil)
 391                (make-abbrev-table))
 392              ,(format "Abbrev table for %s." mode)))))
 393 \f
 394 ;; Utility functions for running a derived mode.
 395
 396 (defun derived-mode-set-keymap (mode)
 397   "Set the keymap of the new MODE, maybe merging with the parent."
 398   (let* ((map-name (derived-mode-map-name mode))
 399          (new-map (eval map-name))
 400          (old-map (current-local-map)))
 401     (and old-map
 402          (get map-name 'derived-mode-unmerged)
 403          (derived-mode-merge-keymaps old-map new-map))
 404     (put map-name 'derived-mode-unmerged nil)
 405     (use-local-map new-map)))
 406
 407 (defun derived-mode-set-syntax-table (mode)
 408   "Set the syntax table of the new MODE, maybe merging with the parent."
 409   (let* ((table-name (derived-mode-syntax-table-name mode))
 410          (old-table (syntax-table))
 411          (new-table (eval table-name)))
 412     (if (get table-name 'derived-mode-unmerged)
 413         (derived-mode-merge-syntax-tables old-table new-table))
 414     (put table-name 'derived-mode-unmerged nil)
 415     (set-syntax-table new-table)))
 416
 417 (defun derived-mode-set-abbrev-table (mode)
 418   "Set the abbrev table for MODE if it exists.
 419 Always merge its parent into it, since the merge is non-destructive."
 420   (let* ((table-name (derived-mode-abbrev-table-name mode))
 421          (old-table local-abbrev-table)
 422          (new-table (eval table-name)))
 423     (derived-mode-merge-abbrev-tables old-table new-table)
 424     (setq local-abbrev-table new-table)))
 425
 426 (defun derived-mode-run-hooks (mode)
 427    "Run the mode hook for MODE."
 428    (let ((hooks-name (derived-mode-hook-name mode)))
 429      (if (boundp hooks-name)
 430          (run-hooks hooks-name))))
 431
 432 ;; Functions to merge maps and tables.
 433
 434 (defun derived-mode-merge-keymaps (old new)
 435   "Merge an OLD keymap into a NEW one.
 436 The old keymap is set to be the last cdr of the new one, so that there will
 437 be automatic inheritance."
 438   ;; ?? Can this just use `set-keymap-parent'?
 439   (let ((tail new))
 440     ;; Scan the NEW map for prefix keys.
 441     (while (consp tail)
 442       (and (consp (car tail))
 443            (let* ((key (vector (car (car tail))))
 444                   (subnew (lookup-key new key))
 445                   (subold (lookup-key old key)))
 446              ;; If KEY is a prefix key in both OLD and NEW, merge them.
 447              (and (keymapp subnew) (keymapp subold)
 448                   (derived-mode-merge-keymaps subold subnew))))
 449       (and (vectorp (car tail))
 450            ;; Search a vector of ASCII char bindings for prefix keys.
 451            (let ((i (1- (length (car tail)))))
 452              (while (>= i 0)
 453                (let* ((key (vector i))
 454                       (subnew (lookup-key new key))
 455                       (subold (lookup-key old key)))
 456                  ;; If KEY is a prefix key in both OLD and NEW, merge them.
 457                  (and (keymapp subnew) (keymapp subold)
 458                       (derived-mode-merge-keymaps subold subnew)))
 459                (setq i (1- i)))))
 460       (setq tail (cdr tail))))
 461   (setcdr (nthcdr (1- (length new)) new) old))
 462
 463 (defun derived-mode-merge-syntax-tables (old new)
 464   "Merge an OLD syntax table into a NEW one.
 465 Where the new table already has an entry, nothing is copied from the old one."
 466   (set-char-table-parent new old))
 467
 468 ;; Merge an old abbrev table into a new one.
 469 ;; This function requires internal knowledge of how abbrev tables work,
 470 ;; presuming that they are obarrays with the abbrev as the symbol, the expansion
 471 ;; as the value of the symbol, and the hook as the function definition.
 472 (defun derived-mode-merge-abbrev-tables (old new)
 473   (if old
 474       (mapatoms
 475        (lambda (symbol)
 476          (or (intern-soft (symbol-name symbol) new)
 477              (define-abbrev new (symbol-name symbol)
 478                (symbol-value symbol) (symbol-function symbol))))
 479        old)))
 480
 481 (provide 'derived)
 482
 483 ;;; derived.el ends here