code.delx.au - gnu-emacs/blob - lisp/mail/sendmail.el

   1 ;;; sendmail.el --- mail sending commands for Emacs.
   2
   3 ;; Copyright (C) 1985, 1986, 1992, 1993, 1994 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: mail
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  22 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; This mode provides mail-sending facilities from within Emacs.  It is
  27 ;; documented in the Emacs user's manual.
  28
  29 ;;; Code:
  30
  31 ;;;###autoload
  32 (defvar mail-self-blind nil "\
  33 Non-nil means insert BCC to self in messages to be sent.
  34 This is done when the message is initialized,
  35 so you can remove or alter the BCC field to override the default.")
  36
  37 ;;;###autoload
  38 (defvar mail-interactive nil "\
  39 Non-nil means when sending a message wait for and display errors.
  40 nil means let mailer mail back a message to report errors.")
  41
  42 ;;;###autoload
  43 (defvar mail-yank-ignored-headers "^via:\\|^mail-from:\\|^origin:\\|^status:\\|^remailed\\|^received:\\|^message-id:\\|^summary-line:\\|^to:\\|^subject:\\|^in-reply-to:\\|^return-path:" "\
  44 Delete these headers from old message when it's inserted in a reply.")
  45
  46 ;; Useful to set in site-init.el
  47 ;;;###autoload
  48 (defvar send-mail-function 'sendmail-send-it "\
  49 Function to call to send the current buffer as mail.
  50 The headers are be delimited by a line which is `mail-header-separator'.")
  51
  52 ;;;###autoload
  53 (defvar mail-header-separator "--text follows this line--" "\
  54 *Line used to separate headers from text in messages being composed.")
  55
  56 ;;;###autoload
  57 (defvar mail-archive-file-name nil "\
  58 *Name of file to write all outgoing messages in, or nil for none.
  59 Do not use an rmail file here!  Instead, use its inbox file.")
  60
  61 ;;;###autoload
  62 (defvar mail-default-reply-to t
  63   "*Address to insert as default Reply-to field of outgoing messages.")
  64
  65 ;;;###autoload
  66 (defvar mail-alias-file nil
  67   "*If non-nil, the name of a file to use instead of `/usr/lib/aliases'.
  68 This file defines aliases to be expanded by the mailer; this is a different
  69 feature from that of defining aliases in `.mailrc' to be expanded in Emacs.
  70 This variable has no effect unless your system uses sendmail as its mailer.")
  71
  72 (defvar mail-aliases t
  73   "Alist of mail address aliases,
  74 or t meaning should be initialized from `~/.mailrc'.
  75 The alias definitions in `~/.mailrc' have this form:
  76     alias ALIAS MEANING")
  77
  78 (defvar mail-alias-modtime nil
  79   "The modification time of ~/.mailrc when it was last examined.")
  80
  81 (defvar mail-yank-prefix nil
  82   "*Prefix insert on lines of yanked message being replied to.
  83 nil means use indentation.")
  84 (defvar mail-indentation-spaces 3
  85   "*Number of spaces to insert at the beginning of each cited line.
  86 Used by `mail-yank-original' via `mail-yank-cite'.")
  87 (defvar mail-yank-hooks nil
  88   "Obsolete hook for modifying a citation just inserted in the mail buffer.
  89 Each hook function can find the citation between (point) and (mark t).
  90 And each hook function should leave point and mark around the citation
  91 text as modified.
  92
  93 This is a normal hook, misnamed for historical reasons.
  94 It is semi-obsolete and mail agents should no longer use it.")
  95
  96 (defvar mail-citation-hook nil
  97   "*Hook for modifying a citation just inserted in the mail buffer.
  98 Each hook function can find the citation between (point) and (mark t).
  99 And each hook function should leave point and mark around the citation
 100 text as modified.
 101
 102 If this hook is entirely empty (nil), a default action is taken
 103 instead of no action.")
 104
 105 (defvar mail-abbrevs-loaded nil)
 106 (defvar mail-mode-map nil)
 107
 108 (autoload 'build-mail-aliases "mailalias"
 109   "Read mail aliases from `~/.mailrc' and set `mail-aliases'."
 110   nil)
 111
 112 (autoload 'expand-mail-aliases "mailalias"
 113   "Expand all mail aliases in suitable header fields found between BEG and END.
 114 Suitable header fields are `To', `Cc' and `Bcc' and their `Resent-' variants.
 115 Optional second arg EXCLUDE may be a regular expression defining text to be
 116 removed from alias expansions."
 117   nil)
 118
 119 ;;;###autoload
 120 (defvar mail-signature nil
 121   "*Text inserted at end of mail buffer when a message is initialized.
 122 If t, it means to insert the contents of the file `~/.signature'.")
 123
 124 (defvar mail-reply-buffer nil)
 125 (defvar mail-send-actions nil
 126   "A list of actions to be performed upon successful sending of a message.")
 127
 128 (defvar mail-default-headers nil
 129   "*A string containing header lines, to be inserted in outgoing messages.
 130 It is inserted before you edit the message,
 131 so you can edit or delete these lines.")
 132
 133 (defvar mail-bury-selects-summary t
 134   "*If non-nil, try to show RMAIL summary buffer after returning from mail.
 135 The functions \\[mail-send-on-exit] or \\[mail-dont-send] select
 136 the RMAIL summary buffer before returning, if it exists and this variable
 137 is non-nil.")
 138
 139 ;; Note: could use /usr/ucb/mail instead of sendmail;
 140 ;; options -t, and -v if not interactive.
 141 (defvar mail-mailer-swallows-blank-line
 142   (if (and (string-match "sparc-sun-sunos\\(\\'\\|[^5]\\)" system-configuration)
 143            (file-readable-p "/etc/sendmail.cf")
 144            (let ((buffer (get-buffer-create " *temp*")))
 145              (unwind-protect
 146                  (save-excursion
 147                    (set-buffer buffer)
 148                    (insert-file-contents "/etc/sendmail.cf")
 149                    (goto-char (point-min))
 150                    (let ((case-fold-search nil))
 151                      (re-search-forward "^OR\\>" nil t)))
 152                (kill-buffer buffer))))
 153       '(looking-at "[ \t]\\|[-a-zA-Z]+:"))
 154   "Set this non-nil if the system's mailer runs the header and body together.
 155 \(This problem exists on Sunos 4 when sendmail is run in remote mode.)
 156 The value should be an expression to test whether the problem will
 157 actually occur.")
 158
 159 (defvar mail-mode-syntax-table nil
 160   "Syntax table used while in mail mode.")
 161
 162 (if (not mail-mode-syntax-table)
 163     (progn
 164      (setq mail-mode-syntax-table (copy-syntax-table text-mode-syntax-table))
 165      (modify-syntax-entry ?% ". " mail-mode-syntax-table)))
 166
 167 (defvar mail-font-lock-keywords
 168   (list '("^To:" . font-lock-function-name-face)
 169         '("^B?CC:\\|^Reply-To:" . font-lock-keyword-face)
 170         '("^Subject:" . font-lock-comment-face)
 171         '("^Subject:\\s *\\(.+\\)$" 1 font-lock-type-face)
 172         (list (concat "^\\(" mail-header-separator "\\)$") 1
 173               'font-lock-comment-face)
 174         '("^[ \t]*\\sw*[>|}].*$" . font-lock-reference-face)    ; Citation.
 175         '("^\\(X-[A-Za-z0-9-]+\\|In-reply-to\\):.*$" . font-lock-string-face))
 176   "Additional expressions to highlight in Mail mode.")
 177
 178 (defvar mail-send-hook nil
 179   "Normal hook run before sending mail, in Mail mode.")
 180
 181 (defun sendmail-synch-aliases ()
 182   (let ((modtime (nth 5 (file-attributes "~/.mailrc"))))
 183     (or (equal mail-alias-modtime modtime)
 184         (setq mail-alias-modtime modtime
 185               mail-aliases t))))
 186
 187 (defun mail-setup (to subject in-reply-to cc replybuffer actions)
 188   (if (eq mail-default-reply-to t)
 189       (setq mail-default-reply-to (getenv "REPLYTO")))
 190   (sendmail-synch-aliases)
 191   (if (eq mail-aliases t)
 192       (progn
 193         (setq mail-aliases nil)
 194         (if (file-exists-p "~/.mailrc")
 195             (build-mail-aliases))))
 196   (setq mail-send-actions actions)
 197   (setq mail-reply-buffer replybuffer)
 198   (goto-char (point-min))
 199   (insert "To: ")
 200   (save-excursion
 201     (if to
 202         ;; Here removed code to extract names from within <...>
 203         ;; on the assumption that mail-strip-quoted-names
 204         ;; has been called and has done so.
 205         (let ((fill-prefix "\t")
 206               (address-start (point)))
 207           (insert to "\n")
 208           (fill-region-as-paragraph address-start (point-max)))
 209       (newline))
 210     (if cc
 211         (let ((fill-prefix "\t")
 212               (address-start (progn (insert "CC: ") (point))))
 213           (insert cc "\n")
 214           (fill-region-as-paragraph address-start (point-max))))
 215     (if in-reply-to
 216         (insert "In-reply-to: " in-reply-to "\n"))
 217     (insert "Subject: " (or subject "") "\n")
 218     (if mail-default-headers
 219         (insert mail-default-headers))
 220     (if mail-default-reply-to
 221         (insert "Reply-to: " mail-default-reply-to "\n"))
 222     (if mail-self-blind
 223         (insert "BCC: " (user-login-name) "\n"))
 224     (if mail-archive-file-name
 225         (insert "FCC: " mail-archive-file-name "\n"))
 226     (insert mail-header-separator "\n")
 227     ;; Insert the signature.  But remember the beginning of the message.
 228     (if to (setq to (point)))
 229     (cond ((eq mail-signature t)
 230            (if (file-exists-p "~/.signature")
 231                (progn
 232                  (insert "\n\n-- \n")
 233                  (insert-file-contents "~/.signature"))))
 234           (mail-signature
 235            (insert mail-signature)))
 236     (goto-char (point-max))
 237     (or (bolp) (newline)))
 238   (if to (goto-char to))
 239   (or to subject in-reply-to
 240       (set-buffer-modified-p nil))
 241   (run-hooks 'mail-setup-hook))
 242
 243 ;;;###autoload
 244 (defun mail-mode ()
 245   "Major mode for editing mail to be sent.
 246 Like Text Mode but with these additional commands:
 247 C-c C-s  mail-send (send the message)    C-c C-c  mail-send-and-exit
 248 C-c C-f  move to a header field (and create it if there isn't):
 249          C-c C-f C-t  move to To:       C-c C-f C-s  move to Subj:
 250          C-c C-f C-b  move to BCC:      C-c C-f C-c  move to CC:
 251          C-c C-f C-f  move to FCC:
 252 C-c C-t  move to message text.
 253 C-c C-y  mail-yank-original (insert current message, in Rmail).
 254 C-c C-q  mail-fill-yanked-message (fill what was yanked).
 255 C-c C-v  mail-sent-via (add a sent-via field for each To or CC)."
 256   (interactive)
 257   (kill-all-local-variables)
 258   (make-local-variable 'mail-reply-buffer)
 259   (setq mail-reply-buffer nil)
 260   (make-local-variable 'mail-send-actions)
 261   (set-syntax-table mail-mode-syntax-table)
 262   (use-local-map mail-mode-map)
 263   (setq local-abbrev-table text-mode-abbrev-table)
 264   (setq major-mode 'mail-mode)
 265   (setq mode-name "Mail")
 266   (setq buffer-offer-save t)
 267   (make-local-variable 'font-lock-keywords)
 268   (setq font-lock-keywords mail-font-lock-keywords)
 269   (make-local-variable 'paragraph-separate)
 270   (make-local-variable 'paragraph-start)
 271   (setq paragraph-start (concat "^" mail-header-separator
 272                                 "$\\|^[ \t]*[-_][-_][-_]+$\\|"
 273                                 paragraph-start))
 274   (setq paragraph-separate (concat "^" mail-header-separator
 275                                    "$\\|^[ \t]*[-_][-_][-_]+$\\|"
 276                                    paragraph-separate))
 277   (run-hooks 'text-mode-hook 'mail-mode-hook))
 278 \f
 279 ;;; Set up keymap.
 280
 281 (if mail-mode-map
 282     nil
 283   (setq mail-mode-map (nconc (make-sparse-keymap) text-mode-map))
 284   (define-key mail-mode-map "\C-c?" 'describe-mode)
 285   (define-key mail-mode-map "\C-c\C-f\C-t" 'mail-to)
 286   (define-key mail-mode-map "\C-c\C-f\C-b" 'mail-bcc)
 287   (define-key mail-mode-map "\C-c\C-f\C-f" 'mail-fcc)
 288   (define-key mail-mode-map "\C-c\C-f\C-c" 'mail-cc)
 289   (define-key mail-mode-map "\C-c\C-f\C-s" 'mail-subject)
 290   (define-key mail-mode-map "\C-c\C-t" 'mail-text)
 291   (define-key mail-mode-map "\C-c\C-y" 'mail-yank-original)
 292   (define-key mail-mode-map "\C-c\C-q" 'mail-fill-yanked-message)
 293   (define-key mail-mode-map "\C-c\C-w" 'mail-signature)
 294   (define-key mail-mode-map "\C-c\C-v" 'mail-sent-via)
 295   (define-key mail-mode-map "\C-c\C-c" 'mail-send-and-exit)
 296   (define-key mail-mode-map "\C-c\C-s" 'mail-send))
 297
 298 (define-key mail-mode-map [menu-bar mail]
 299   (cons "Mail" (make-sparse-keymap "Mail")))
 300
 301 (define-key mail-mode-map [menu-bar mail fill]
 302   '("Fill Citation" . mail-fill-yanked-message))
 303
 304 (define-key mail-mode-map [menu-bar mail yank]
 305   '("Cite Original" . mail-yank-original))
 306
 307 (define-key mail-mode-map [menu-bar mail signature]
 308   '("Insert Signature" . mail-signature))
 309
 310 (define-key mail-mode-map [menu-bar mail cancel]
 311   '("Cancel" . mail-dont-send))
 312
 313 (define-key mail-mode-map [menu-bar mail send-stay]
 314   '("Send, Keep Editing" . mail-send))
 315
 316 (define-key mail-mode-map [menu-bar mail send]
 317   '("Send Message" . mail-send-and-exit))
 318
 319 (define-key mail-mode-map [menu-bar headers]
 320   (cons "Headers" (make-sparse-keymap "Headers")))
 321
 322 (define-key mail-mode-map [menu-bar headers sent-via]
 323   '("Sent Via" . mail-sent-via))
 324
 325 (define-key mail-mode-map [menu-bar headers text]
 326   '("Text" . mail-text))
 327
 328 (define-key mail-mode-map [menu-bar headers bcc]
 329   '("Bcc" . mail-bcc))
 330
 331 (define-key mail-mode-map [menu-bar headers fcc]
 332   '("Fcc" . mail-fcc))
 333
 334 (define-key mail-mode-map [menu-bar headers cc]
 335   '("Cc" . mail-cc))
 336
 337 (define-key mail-mode-map [menu-bar headers subject]
 338   '("Subject" . mail-subject))
 339
 340 (define-key mail-mode-map [menu-bar headers to]
 341   '("To" . mail-to))
 342 \f
 343 (defun mail-send-and-exit (arg)
 344   "Send message like `mail-send', then, if no errors, exit from mail buffer.
 345 Prefix arg means don't delete this window."
 346   (interactive "P")
 347   (mail-send)
 348   (mail-bury arg))
 349
 350 (defun mail-dont-send (arg)
 351   "Don't send the message you have been editing.
 352 Prefix arg means don't delete this window."
 353   (interactive "P")
 354   (mail-bury arg))
 355
 356 (defun mail-bury (arg)
 357   "Bury this mail buffer."
 358   (let ((newbuf (other-buffer (current-buffer))))
 359     (bury-buffer (current-buffer))
 360     (if (and (fboundp 'frame-parameters)
 361              (cdr (assq 'dedicated (frame-parameters)))
 362              (not (null (delq (selected-frame) (visible-frame-list)))))
 363         (delete-frame (selected-frame))
 364       (let (rmail-flag summary-buffer)
 365         (and (not arg)
 366              (not (one-window-p))
 367              (save-excursion
 368                (set-buffer (window-buffer (next-window (selected-window) 'not)))
 369                (setq rmail-flag (eq major-mode 'rmail-mode))
 370                (setq summary-buffer
 371                      (and mail-bury-selects-summary
 372                           (boundp 'rmail-summary-buffer)
 373                           rmail-summary-buffer
 374                           (buffer-name rmail-summary-buffer)
 375                           (not (get-buffer-window rmail-summary-buffer))
 376                           rmail-summary-buffer))))
 377         (if rmail-flag
 378             ;; If the Rmail buffer has a summary, show that.
 379             (if summary-buffer (switch-to-buffer summary-buffer)
 380               (delete-window))
 381           (switch-to-buffer newbuf))))))
 382
 383 (defun mail-send ()
 384   "Send the message in the current buffer.
 385 If `mail-interactive' is non-nil, wait for success indication
 386 or error messages, and inform user.
 387 Otherwise any failure is reported in a message back to
 388 the user from the mailer."
 389   (interactive)
 390   (if (if buffer-file-name
 391           (y-or-n-p "Send buffer contents as mail message? ")
 392         (or (buffer-modified-p)
 393             (y-or-n-p "Message already sent; resend? ")))
 394       (progn
 395         (run-hooks 'mail-send-hook)
 396         (message "Sending...")
 397         (funcall send-mail-function)
 398         ;; Now perform actions on successful sending.
 399         (while mail-send-actions
 400           (condition-case nil
 401               (apply (car (car mail-send-actions))
 402                      (cdr (car mail-send-actions)))
 403             (error))
 404           (setq mail-send-actions (cdr mail-send-actions)))
 405         (message "Sending...done")
 406         ;; If buffer has no file, mark it as unmodified and delete autosave.
 407         (if (not buffer-file-name)
 408             (progn
 409               (set-buffer-modified-p nil)
 410               (delete-auto-save-file-if-necessary t))))))
 411
 412 (defun sendmail-send-it ()
 413   (let ((errbuf (if mail-interactive
 414                     (generate-new-buffer " sendmail errors")
 415                   0))
 416         (tembuf (generate-new-buffer " sendmail temp"))
 417         (case-fold-search nil)
 418         resend-to-addresses
 419         delimline
 420         (mailbuf (current-buffer)))
 421     (unwind-protect
 422         (save-excursion
 423           (set-buffer tembuf)
 424           (erase-buffer)
 425           (insert-buffer-substring mailbuf)
 426           (goto-char (point-max))
 427           ;; require one newline at the end.
 428           (or (= (preceding-char) ?\n)
 429               (insert ?\n))
 430           ;; Change header-delimiter to be what sendmail expects.
 431           (goto-char (point-min))
 432           (re-search-forward
 433             (concat "^" (regexp-quote mail-header-separator) "\n"))
 434           (replace-match "\n")
 435           (backward-char 1)
 436           (setq delimline (point-marker))
 437           (sendmail-synch-aliases)
 438           (if mail-aliases
 439               (expand-mail-aliases (point-min) delimline))
 440           (goto-char (point-min))
 441           ;; ignore any blank lines in the header
 442           (while (and (re-search-forward "\n\n\n*" delimline t)
 443                       (< (point) delimline))
 444             (replace-match "\n"))
 445           (let ((case-fold-search t))
 446             (goto-char (point-min))
 447             ;; Find and handle any FCC fields.
 448             (goto-char (point-min))
 449             (if (re-search-forward "^FCC:" delimline t)
 450                 (mail-do-fcc delimline))
 451             (goto-char (point-min))
 452             (require 'mail-utils)
 453             (while (re-search-forward "^Resent-to:" delimline t)
 454               (setq resend-to-addresses
 455                     (save-restriction
 456                       (narrow-to-region (point)
 457                                         (save-excursion
 458                                           (end-of-line)
 459                                           (point)))
 460                       (append (mail-parse-comma-list)
 461                               resend-to-addresses))))
 462 ;;; Apparently this causes a duplicate Sender.
 463 ;;;         ;; If the From is different than current user, insert Sender.
 464 ;;;         (goto-char (point-min))
 465 ;;;         (and (re-search-forward "^From:"  delimline t)
 466 ;;;              (progn
 467 ;;;                (require 'mail-utils)
 468 ;;;                (not (string-equal
 469 ;;;                      (mail-strip-quoted-names
 470 ;;;                       (save-restriction
 471 ;;;                         (narrow-to-region (point-min) delimline)
 472 ;;;                         (mail-fetch-field "From")))
 473 ;;;                      (user-login-name))))
 474 ;;;              (progn
 475 ;;;                (forward-line 1)
 476 ;;;                (insert "Sender: " (user-login-name) "\n")))
 477             ;; "S:" is an abbreviation for "Subject:".
 478             (goto-char (point-min))
 479             (if (re-search-forward "^S:" delimline t)
 480                 (replace-match "Subject:"))
 481             ;; Don't send out a blank subject line
 482             (goto-char (point-min))
 483             (if (re-search-forward "^Subject:[ \t]*\n" delimline t)
 484                 (replace-match ""))
 485             ;; Insert an extra newline if we need it to work around
 486             ;; Sun's bug that swallows newlines.
 487             (goto-char (1+ delimline))
 488             (if (eval mail-mailer-swallows-blank-line)
 489                 (newline))
 490             (if mail-interactive
 491                 (save-excursion
 492                   (set-buffer errbuf)
 493                   (erase-buffer))))
 494           (apply 'call-process-region
 495                  (append (list (point-min) (point-max)
 496                                (if (boundp 'sendmail-program)
 497                                    sendmail-program
 498                                  "/usr/lib/sendmail")
 499                                nil errbuf nil "-oi")
 500                          ;; Always specify who from,
 501                          ;; since some systems have broken sendmails.
 502                          (list "-f" (user-login-name))
 503 ;;;                      ;; Don't say "from root" if running under su.
 504 ;;;                      (and (equal (user-real-login-name) "root")
 505 ;;;                           (list "-f" (user-login-name)))
 506                          (and mail-alias-file
 507                               (list (concat "-oA" mail-alias-file)))
 508                          ;; These mean "report errors by mail"
 509                          ;; and "deliver in background".
 510                          (if (null mail-interactive) '("-oem" "-odb"))
 511                          ;; Get the addresses from the message
 512                          ;; unless this is a resend.
 513                          ;; We must not do that for a resend
 514                          ;; because we would find the original addresses.
 515                          ;; For a resend, include the specific addresses.
 516                          (or resend-to-addresses
 517                              '("-t"))))
 518           (if mail-interactive
 519               (save-excursion
 520                 (set-buffer errbuf)
 521                 (goto-char (point-min))
 522                 (while (re-search-forward "\n\n* *" nil t)
 523                   (replace-match "; "))
 524                 (if (not (zerop (buffer-size)))
 525                     (error "Sending...failed to %s"
 526                            (buffer-substring (point-min) (point-max)))))))
 527       (kill-buffer tembuf)
 528       (if (bufferp errbuf)
 529           (kill-buffer errbuf)))))
 530
 531 (defun mail-do-fcc (header-end)
 532   (let (fcc-list
 533         (rmailbuf (current-buffer))
 534         (time (current-time))
 535         (tembuf (generate-new-buffer " rmail output"))
 536         (case-fold-search t))
 537     (save-excursion
 538       (goto-char (point-min))
 539       (while (re-search-forward "^FCC:[ \t]*" header-end t)
 540         (setq fcc-list (cons (buffer-substring (point)
 541                                                (progn
 542                                                  (end-of-line)
 543                                                  (skip-chars-backward " \t")
 544                                                  (point)))
 545                              fcc-list))
 546         (delete-region (match-beginning 0)
 547                        (progn (forward-line 1) (point))))
 548       (set-buffer tembuf)
 549       (erase-buffer)
 550       ;; This initial newline is written out if the fcc file already exists.
 551       (insert "\nFrom " (user-login-name) " "
 552               (current-time-string time) "\n")
 553       ;; Insert the time zone before the year.
 554       (forward-char -1)
 555       (forward-word -1)
 556       (require 'mail-utils)
 557       (insert (mail-rfc822-time-zone time) " ")
 558       (goto-char (point-max))
 559       (insert-buffer-substring rmailbuf)
 560       ;; Make sure messages are separated.
 561       (goto-char (point-max))
 562       (insert ?\n)
 563       (goto-char 2)
 564       ;; ``Quote'' "^From " as ">From "
 565       ;;  (note that this isn't really quoting, as there is no requirement
 566       ;;   that "^[>]+From " be quoted in the same transparent way.)
 567       (let ((case-fold-search nil))
 568         (while (search-forward "\nFrom " nil t)
 569           (forward-char -5)
 570           (insert ?>)))
 571       (while fcc-list
 572         (let ((buffer (get-file-buffer (car fcc-list))))
 573           (if buffer
 574               ;; File is present in a buffer => append to that buffer.
 575               (let ((curbuf (current-buffer))
 576                     (beg (point-min)) (end (point-max))
 577                     (beg2 (save-excursion (goto-char (point-min))
 578                                           (forward-line 2) (point))))
 579                 (save-excursion
 580                   (set-buffer buffer)
 581                   ;; Keep the end of the accessible portion at the same place
 582                   ;; unless it is the end of the buffer.
 583                   (let ((max (if (/= (1+ (buffer-size)) (point-max))
 584                                  (point-max))))
 585                     (unwind-protect
 586                         ;; Code below lifted from rmailout.el
 587                         ;; function rmail-output-to-rmail-file:
 588                         (let ((buffer-read-only nil)
 589                               (msg (and (boundp 'rmail-current-message)
 590                                         rmail-current-message)))
 591                           ;; If MSG is non-nil, buffer is in RMAIL mode.
 592                           (if msg
 593                               (progn
 594                                 (rmail-maybe-set-message-counters)
 595                                 (widen)
 596                                 (narrow-to-region (point-max) (point-max))
 597                                 (insert "\C-l\n0, unseen,,\n*** EOOH ***\n"
 598                                         "From: " (user-login-name) "\n"
 599                                         "Date: " (mail-rfc822-date) "\n")
 600                                 (insert-buffer-substring curbuf beg2 end)
 601                                 (insert "\n\C-_")
 602                                 (goto-char (point-min))
 603                                 (widen)
 604                                 (search-backward "\n\^_")
 605                                 (narrow-to-region (point) (point-max))
 606                                 (rmail-count-new-messages t)
 607                                 (rmail-show-message msg)
 608                                 (setq max nil))
 609                             ;; Output file not in rmail mode
 610                             ;; => just insert at the end.
 611                             (narrow-to-region (point-min) (1+ (buffer-size)))
 612                             (goto-char (point-max))
 613                             (insert-buffer-substring curbuf beg end)))
 614                       (if max (narrow-to-region (point-min) max))))))
 615             ;; Else append to the file directly.
 616             (write-region
 617              (1+ (point-min)) (point-max) (car fcc-list) t)))
 618         (setq fcc-list (cdr fcc-list))))
 619     (kill-buffer tembuf)))
 620
 621 (defun mail-sent-via ()
 622   "Make a Sent-via header line from each To or CC header line."
 623   (interactive)
 624   (save-excursion
 625     (goto-char (point-min))
 626     ;; find the header-separator
 627     (search-forward (concat "\n" mail-header-separator "\n"))
 628     (forward-line -1)
 629     ;; put a marker at the end of the header
 630     (let ((end (point-marker))
 631           (case-fold-search t)
 632           to-line)
 633       (goto-char (point-min))
 634       ;; search for the To: lines and make Sent-via: lines from them
 635       ;; search for the next To: line
 636       (while (re-search-forward "^\\(to\\|cc\\):" end t)
 637         ;; Grab this line plus all its continuations, sans the `to:'.
 638         (let ((to-line
 639                (buffer-substring (point)
 640                                  (progn
 641                                    (if (re-search-forward "^[^ \t\n]" end t)
 642                                        (backward-char 1)
 643                                      (goto-char end))
 644                                    (point)))))
 645           ;; Insert a copy, with altered header field name.
 646           (insert-before-markers "Sent-via:" to-line))))))
 647 \f
 648 (defun mail-to ()
 649   "Move point to end of To-field."
 650   (interactive)
 651   (expand-abbrev)
 652   (mail-position-on-field "To"))
 653
 654 (defun mail-subject ()
 655   "Move point to end of Subject-field."
 656   (interactive)
 657   (expand-abbrev)
 658   (mail-position-on-field "Subject"))
 659
 660 (defun mail-cc ()
 661   "Move point to end of CC-field.  Create a CC field if none."
 662   (interactive)
 663   (expand-abbrev)
 664   (or (mail-position-on-field "cc" t)
 665       (progn (mail-position-on-field "to")
 666              (insert "\nCC: "))))
 667
 668 (defun mail-bcc ()
 669   "Move point to end of BCC-field.  Create a BCC field if none."
 670   (interactive)
 671   (expand-abbrev)
 672   (or (mail-position-on-field "bcc" t)
 673       (progn (mail-position-on-field "to")
 674              (insert "\nBCC: "))))
 675
 676 (defun mail-fcc (folder)
 677   "Add a new FCC field, with file name completion."
 678   (interactive "FFolder carbon copy: ")
 679   (expand-abbrev)
 680   (or (mail-position-on-field "fcc" t)  ;Put new field after exiting FCC.
 681       (mail-position-on-field "to"))
 682   (insert "\nFCC: " folder))
 683
 684 (defun mail-position-on-field (field &optional soft)
 685   (let (end
 686         (case-fold-search t))
 687     (goto-char (point-min))
 688     (re-search-forward (concat "^" (regexp-quote mail-header-separator) "\n"))
 689     (setq end (match-beginning 0))
 690     (goto-char (point-min))
 691     (if (re-search-forward (concat "^" (regexp-quote field) ":") end t)
 692         (progn
 693           (re-search-forward "^[^ \t]" nil 'move)
 694           (beginning-of-line)
 695           (skip-chars-backward "\n")
 696           t)
 697       (or soft
 698           (progn (goto-char end)
 699                  (insert field ": \n")
 700                  (skip-chars-backward "\n")))
 701       nil)))
 702
 703 (defun mail-text ()
 704   "Move point to beginning of text field."
 705   (interactive)
 706   (goto-char (point-min))
 707   (search-forward (concat "\n" mail-header-separator "\n")))
 708 \f
 709 (defun mail-signature (atpoint)
 710   "Sign letter with contents of the file `~/.signature'.
 711 Prefix arg means put contents at point."
 712   (interactive "P")
 713   (save-excursion
 714     (or atpoint
 715         (goto-char (point-max)))
 716     (skip-chars-backward " \t\n")
 717     (end-of-line)
 718     (or atpoint
 719         (delete-region (point) (point-max)))
 720     (insert "\n\n-- \n")
 721     (insert-file-contents (expand-file-name "~/.signature"))))
 722
 723 (defun mail-fill-yanked-message (&optional justifyp)
 724   "Fill the paragraphs of a message yanked into this one.
 725 Numeric argument means justify as well."
 726   (interactive "P")
 727   (save-excursion
 728     (goto-char (point-min))
 729     (search-forward (concat "\n" mail-header-separator "\n") nil t)
 730     (fill-individual-paragraphs (point)
 731                                 (point-max)
 732                                 justifyp
 733                                 t)))
 734
 735 (defun mail-indent-citation ()
 736   "Modify text just inserted from a message to be cited.
 737 The inserted text should be the region.
 738 When this function returns, the region is again around the modified text.
 739
 740 Normally, indent each nonblank line `mail-indentation-spaces' spaces.
 741 However, if `mail-yank-prefix' is non-nil, insert that prefix on each line."
 742   (let ((start (point)))
 743     (mail-yank-clear-headers start (mark t))
 744     (if (null mail-yank-prefix)
 745         (indent-rigidly start (mark t) mail-indentation-spaces)
 746       (save-excursion
 747         (goto-char start)
 748         (while (< (point) (mark t))
 749           (insert mail-yank-prefix)
 750           (forward-line 1))))))
 751
 752 (defun mail-yank-original (arg)
 753   "Insert the message being replied to, if any (in rmail).
 754 Puts point before the text and mark after.
 755 Normally, indents each nonblank line ARG spaces (default 3).
 756 However, if `mail-yank-prefix' is non-nil, insert that prefix on each line.
 757
 758 Just \\[universal-argument] as argument means don't indent, insert no prefix,
 759 and don't delete any header fields."
 760   (interactive "P")
 761   (if mail-reply-buffer
 762       (let ((start (point)))
 763         ;; If the original message is in another window in the same frame,
 764         ;; delete that window to save screen space.
 765         ;; t means don't alter other frames.
 766         (delete-windows-on mail-reply-buffer t)
 767         (insert-buffer mail-reply-buffer)
 768         (if (consp arg)
 769             nil
 770           (goto-char start)
 771           (let ((mail-indentation-spaces (if arg (prefix-numeric-value arg)
 772                                            mail-indentation-spaces)))
 773             (if mail-citation-hook
 774                 (run-hooks 'mail-citation-hook)
 775               (if mail-yank-hooks
 776                   (run-hooks 'mail-yank-hooks)
 777                 (mail-indent-citation)))))
 778         ;; This is like exchange-point-and-mark, but doesn't activate the mark.
 779         ;; It is cleaner to avoid activation, even though the command
 780         ;; loop would deactivate the mark because we inserted text.
 781         (goto-char (prog1 (mark t)
 782                      (set-marker (mark-marker) (point) (current-buffer))))
 783         (if (not (eolp)) (insert ?\n)))))
 784
 785 (defun mail-yank-clear-headers (start end)
 786   (save-excursion
 787     (goto-char start)
 788     (if (search-forward "\n\n" end t)
 789         (save-restriction
 790           (narrow-to-region start (point))
 791           (goto-char start)
 792           (while (let ((case-fold-search t))
 793                    (re-search-forward mail-yank-ignored-headers nil t))
 794             (beginning-of-line)
 795             (delete-region (point)
 796                            (progn (re-search-forward "\n[^ \t]")
 797                                   (forward-char -1)
 798                                   (point))))))))
 799 \f
 800 ;; Put these last, to reduce chance of lossage from quitting in middle of loading the file.
 801
 802 ;;;###autoload
 803 (defun mail (&optional noerase to subject in-reply-to cc replybuffer actions)
 804   "Edit a message to be sent.  Prefix arg means resume editing (don't erase).
 805 When this function returns, the buffer `*mail*' is selected.
 806 The value is t if the message was newly initialized; otherwise, nil.
 807
 808 By default, the signature file `~/.signature' is inserted at the end;
 809 see the variable `mail-signature'.
 810
 811 \\<mail-mode-map>
 812 While editing message, type \\[mail-send-and-exit] to send the message and exit.
 813
 814 Various special commands starting with C-c are available in sendmail mode
 815 to move to message header fields:
 816 \\{mail-mode-map}
 817
 818 If `mail-self-blind' is non-nil, a BCC to yourself is inserted
 819 when the message is initialized.
 820
 821 If `mail-default-reply-to' is non-nil, it should be an address (a string);
 822 a Reply-to: field with that address is inserted.
 823
 824 If `mail-archive-file-name' is non-nil, an FCC field with that file name
 825 is inserted.
 826
 827 If `mail-setup-hook' is bound, its value is called with no arguments
 828 after the message is initialized.  It can add more default fields.
 829
 830 When calling from a program, the first argument if non-nil says
 831 not to erase the existing contents of the `*mail*' buffer.
 832
 833 The second through fifth arguments,
 834  TO, SUBJECT, IN-REPLY-TO and CC, specify if non-nil
 835  the initial contents of those header fields.
 836  These arguments should not have final newlines.
 837 The sixth argument REPLYBUFFER is a buffer whose contents
 838  should be yanked if the user types C-c C-y.
 839 The seventh argument ACTIONS is a list of actions to take
 840  if/when the message is sent.  Each action looks like (FUNCTION . ARGS);
 841  when the message is sent, we apply FUNCTION to ARGS.
 842  This is how Rmail arranges to mark messages `answered'."
 843   (interactive "P")
 844 ;;; This is commented out because I found it was confusing in practice.
 845 ;;; It is easy enough to rename *mail* by hand with rename-buffer
 846 ;;; if you want to have multiple mail buffers.
 847 ;;; And then you can control which messages to save. --rms.
 848 ;;;  (let ((index 1)
 849 ;;;     buffer)
 850 ;;;    ;; If requested, look for a mail buffer that is modified and go to it.
 851 ;;;    (if noerase
 852 ;;;     (progn
 853 ;;;       (while (and (setq buffer
 854 ;;;                         (get-buffer (if (= 1 index) "*mail*"
 855 ;;;                                       (format "*mail*<%d>" index))))
 856 ;;;                   (not (buffer-modified-p buffer)))
 857 ;;;         (setq index (1+ index)))
 858 ;;;       (if buffer (switch-to-buffer buffer)
 859 ;;;         ;; If none exists, start a new message.
 860 ;;;         ;; This will never re-use an existing unmodified mail buffer
 861 ;;;         ;; (since index is not 1 anymore).  Perhaps it should.
 862 ;;;         (setq noerase nil))))
 863 ;;;    ;; Unless we found a modified message and are happy, start a new message.
 864 ;;;    (if (not noerase)
 865 ;;;     (progn
 866 ;;;       ;; Look for existing unmodified mail buffer.
 867 ;;;       (while (and (setq buffer
 868 ;;;                         (get-buffer (if (= 1 index) "*mail*"
 869 ;;;                                       (format "*mail*<%d>" index))))
 870 ;;;                   (buffer-modified-p buffer))
 871 ;;;         (setq index (1+ index)))
 872 ;;;       ;; If none, make a new one.
 873 ;;;       (or buffer
 874 ;;;           (setq buffer (generate-new-buffer "*mail*")))
 875 ;;;       ;; Go there and initialize it.
 876 ;;;       (switch-to-buffer buffer)
 877 ;;;       (erase-buffer)
 878 ;;;          (setq default-directory (expand-file-name "~/"))
 879 ;;;          (auto-save-mode auto-save-default)
 880 ;;;          (mail-mode)
 881 ;;;          (mail-setup to subject in-reply-to cc replybuffer actions)
 882 ;;;       (if (and buffer-auto-save-file-name
 883 ;;;                (file-exists-p buffer-auto-save-file-name))
 884 ;;;           (message "Auto save file for draft message exists; consider M-x mail-recover"))
 885 ;;;          t))
 886   (switch-to-buffer "*mail*")
 887   (if (file-exists-p (expand-file-name "~/"))
 888       (setq default-directory (expand-file-name "~/")))
 889   (auto-save-mode auto-save-default)
 890   (mail-mode)
 891   ;; Disconnect the buffer from its visited file
 892   ;; (in case the user has actually visited a file *mail*).
 893 ;  (set-visited-file-name nil)
 894   (let (initialized)
 895     (and (not noerase)
 896          (or (not (buffer-modified-p))
 897              (y-or-n-p "Unsent message being composed; erase it? "))
 898          (progn (erase-buffer)
 899                 (mail-setup to subject in-reply-to cc replybuffer actions)
 900                 (setq initialized t)))
 901     (if (and buffer-auto-save-file-name
 902              (file-exists-p buffer-auto-save-file-name))
 903         (message "Auto save file for draft message exists; consider M-x mail-recover"))
 904     initialized))
 905
 906 (defun mail-recover ()
 907   "Reread contents of current buffer from its last auto-save file."
 908   (interactive)
 909   (let ((file-name (make-auto-save-file-name)))
 910     (cond ((save-window-excursion
 911              (if (not (eq system-type 'vax-vms))
 912                  (with-output-to-temp-buffer "*Directory*"
 913                    (buffer-disable-undo standard-output)
 914                    (call-process "ls" nil standard-output nil "-l" file-name)))
 915              (yes-or-no-p (format "Recover auto save file %s? " file-name)))
 916            (let ((buffer-read-only nil))
 917              (erase-buffer)
 918              (insert-file-contents file-name nil)))
 919           (t (error "mail-recover cancelled")))))
 920
 921 ;;;###autoload
 922 (defun mail-other-window (&optional noerase to subject in-reply-to cc replybuffer sendactions)
 923   "Like `mail' command, but display mail buffer in another window."
 924   (interactive "P")
 925   (let ((pop-up-windows t))
 926     (pop-to-buffer "*mail*"))
 927   (mail noerase to subject in-reply-to cc replybuffer sendactions))
 928
 929 ;;;###autoload
 930 (defun mail-other-frame (&optional noerase to subject in-reply-to cc replybuffer sendactions)
 931   "Like `mail' command, but display mail buffer in another frame."
 932   (interactive "P")
 933   (let ((pop-up-frames t))
 934     (pop-to-buffer "*mail*"))
 935   (mail noerase to subject in-reply-to cc replybuffer sendactions))
 936
 937 ;;; Do not execute these when sendmail.el is loaded,
 938 ;;; only in loaddefs.el.
 939 ;;;###autoload (define-key ctl-x-map "m" 'mail)
 940 ;;;###autoload (define-key ctl-x-4-map "m" 'mail-other-window)
 941 ;;;###autoload (define-key ctl-x-5-map "m" 'mail-other-frame)
 942
 943 ;;; Do not add anything but external entries on this page.
 944
 945 (provide 'sendmail)
 946
 947 ;;; sendmail.el ends here