code.delx.au - gnu-emacs/blob - lisp/cus-face.el

   1 ;;; cus-face.el --- customization support for faces
   2 ;;
   3 ;; Copyright (C) 1996, 1997, 1999, 2000, 2001, 2002 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Per Abrahamsen <abraham@dina.kvl.dk>
   6 ;; Keywords: help, faces
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26 ;;
  27 ;; See `custom.el'.
  28
  29 ;;; Code:
  30
  31 (defalias 'custom-facep 'facep)
  32
  33 ;;; Declaring a face.
  34
  35 ;;;###autoload
  36 (defun custom-declare-face (face spec doc &rest args)
  37   "Like `defface', but FACE is evaluated as a normal argument."
  38   (unless (get face 'face-defface-spec)
  39     (when (fboundp 'facep)
  40       (unless (facep face)
  41         ;; If the user has already created the face, respect that.
  42         (let ((value (or (get face 'saved-face) spec)))
  43           ;; Create global face.
  44           (make-empty-face face)
  45           ;; Create frame-local faces
  46           (dolist (frame (frame-list))
  47             (face-spec-set face value frame)))
  48         ;; When making a face after frames already exist
  49         (if (memq window-system '(x w32))
  50             (make-face-x-resource-internal face))))
  51     ;; Don't record SPEC until we see it causes no errors.
  52     (put face 'face-defface-spec spec)
  53     (push (cons 'defface face) current-load-list)
  54     (when (and doc (null (face-documentation face)))
  55       (set-face-documentation face (purecopy doc)))
  56     (custom-handle-all-keywords face args 'custom-face)
  57     (run-hooks 'custom-define-hook))
  58   face)
  59
  60 ;;; Face attributes.
  61
  62 ;;;###autoload
  63 (defconst custom-face-attributes
  64   '((:family
  65      (string :tag "Font Family"
  66              :help-echo "Font family or fontset alias name."))
  67
  68     (:width
  69      (choice :tag "Width"
  70              :help-echo "Font width."
  71              :value normal              ; default
  72              (const :tag "compressed" condensed)
  73              (const :tag "condensed" condensed)
  74              (const :tag "demiexpanded" semi-expanded)
  75              (const :tag "expanded" expanded)
  76              (const :tag "extracondensed" extra-condensed)
  77              (const :tag "extraexpanded" extra-expanded)
  78              (const :tag "medium" normal)
  79              (const :tag "narrow" condensed)
  80              (const :tag "normal" normal)
  81              (const :tag "regular" normal)
  82              (const :tag "semicondensed" semi-condensed)
  83              (const :tag "semiexpanded" semi-expanded)
  84              (const :tag "ultracondensed" ultra-condensed)
  85              (const :tag "ultraexpanded" ultra-expanded)
  86              (const :tag "wide" extra-expanded)))
  87
  88     (:height
  89      (choice :tag "Height"
  90              :help-echo "Face's font height."
  91              :value 1.0                 ; default
  92              (integer :tag "Height in 1/10 pt")
  93              (number :tag "Scale" 1.0)))
  94
  95     (:weight
  96      (choice :tag "Weight"
  97              :help-echo "Font weight."
  98              :value normal              ; default
  99              (const :tag "black" ultra-bold)
 100              (const :tag "bold" bold)
 101              (const :tag "book" semi-light)
 102              (const :tag "demibold" semi-bold)
 103              (const :tag "extralight" extra-light)
 104              (const :tag "extrabold" extra-bold)
 105              (const :tag "heavy" extra-bold)
 106              (const :tag "light" light)
 107              (const :tag "medium" normal)
 108              (const :tag "normal" normal)
 109              (const :tag "regular" normal)
 110              (const :tag "semibold" semi-bold)
 111              (const :tag "semilight" semi-light)
 112              (const :tag "ultralight" ultra-light)
 113              (const :tag "ultrabold" ultra-bold)))
 114
 115     (:slant
 116      (choice :tag "Slant"
 117              :help-echo "Font slant."
 118              :value normal              ; default
 119              (const :tag "italic" italic)
 120              (const :tag "oblique" oblique)
 121              (const :tag "normal" normal)))
 122
 123     (:underline
 124      (choice :tag "Underline"
 125              :help-echo "Control text underlining."
 126              (const :tag "Off" nil)
 127              (const :tag "On" t)
 128              (color :tag "Colored")))
 129
 130     (:overline
 131      (choice :tag "Overline"
 132              :help-echo "Control text overlining."
 133              (const :tag "Off" nil)
 134              (const :tag "On" t)
 135              (color :tag "Colored")))
 136
 137     (:strike-through
 138      (choice :tag "Strike-through"
 139              :help-echo "Control text strike-through."
 140              (const :tag "Off" nil)
 141              (const :tag "On" t)
 142              (color :tag "Colored")))
 143
 144     (:box
 145      ;; Fixme: this can probably be done better.
 146      (choice :tag "Box around text"
 147              :help-echo "Control box around text."
 148              (const :tag "Off" nil)
 149              (list :tag "Box"
 150                    :value (:line-width 2 :color "grey75" :style released-button)
 151                    (const :format "" :value :line-width)
 152                    (integer :tag "Width")
 153                    (const :format "" :value :color)
 154                    (choice :tag "Color" (const :tag "*" nil) color)
 155                    (const :format "" :value :style)
 156                    (choice :tag "Style"
 157                            (const :tag "Raised" released-button)
 158                            (const :tag "Sunken" pressed-button)
 159                            (const :tag "None" nil))))
 160      ;; filter to make value suitable for customize
 161      (lambda (real-value)
 162        (and real-value
 163             (let ((lwidth
 164                    (or (and (consp real-value)
 165                             (plist-get real-value :line-width))
 166                        (and (integerp real-value) real-value)
 167                        1))
 168                   (color
 169                    (or (and (consp real-value) (plist-get real-value :color))
 170                        (and (stringp real-value) real-value)
 171                        nil))
 172                   (style
 173                    (and (consp real-value) (plist-get real-value :style))))
 174               (list :line-width lwidth :color color :style style))))
 175      ;; filter to make customized-value suitable for storing
 176      (lambda (cus-value)
 177        (and cus-value
 178             (let ((lwidth (plist-get cus-value :line-width))
 179                   (color (plist-get cus-value :color))
 180                   (style (plist-get cus-value :style)))
 181               (cond ((and (null color) (null style))
 182                      lwidth)
 183                     ((and (null lwidth) (null style))
 184                      ;; actually can't happen, because LWIDTH is always an int
 185                      color)
 186                     (t
 187                      ;; Keep as a plist, but remove null entries
 188                      (nconc (and lwidth `(:line-width ,lwidth))
 189                             (and color  `(:color ,color))
 190                             (and style  `(:style ,style)))))))))
 191
 192     (:inverse-video
 193      (choice :tag "Inverse-video"
 194              :help-echo "Control whether text should be in inverse-video."
 195              (const :tag "Off" nil)
 196              (const :tag "On" t)))
 197
 198     (:foreground
 199      (color :tag "Foreground"
 200             :help-echo "Set foreground color (name or #RRGGBB hex spec)."))
 201
 202     (:background
 203      (color :tag "Background"
 204             :help-echo "Set background color (name or #RRGGBB hex spec)."))
 205
 206     (:stipple
 207      (choice :tag "Stipple"
 208              :help-echo "Background bit-mask"
 209              (const :tag "None" nil)
 210              (file :tag "File"
 211                    :help-echo "Name of bitmap file."
 212                    :must-match t)))
 213
 214     (:inherit
 215      (repeat :tag "Inherit"
 216              :help-echo "List of faces to inherit attributes from."
 217              (face :Tag "Face" default))
 218      ;; filter to make value suitable for customize
 219      (lambda (real-value)
 220        (cond ((or (null real-value) (eq real-value 'unspecified))
 221               nil)
 222              ((symbolp real-value)
 223               (list real-value))
 224              (t
 225               real-value)))
 226      ;; filter to make customized-value suitable for storing
 227      (lambda (cus-value)
 228        (if (and (consp cus-value) (null (cdr cus-value)))
 229            (car cus-value)
 230          cus-value))))
 231
 232   "Alist of face attributes.
 233
 234 The elements are of the form (KEY TYPE PRE-FILTER POST-FILTER),
 235 where KEY is the name of the attribute, TYPE is a widget type for
 236 editing the attribute, PRE-FILTER is a function to make the attribute's
 237 value suitable for the customization widget, and POST-FILTER is a
 238 function to make the customized value suitable for storing.  PRE-FILTER
 239 and POST-FILTER are optional.
 240
 241 The PRE-FILTER should take a single argument, the attribute value as
 242 stored, and should return a value for customization (using the
 243 customization type TYPE).
 244
 245 The POST-FILTER should also take a single argument, the value after
 246 being customized, and should return a value suitable for setting the
 247 given face attribute.")
 248
 249 (defun custom-face-attributes-get (face frame)
 250   "For FACE on FRAME, return an alternating list describing its attributes.
 251 The list has the form (KEYWORD VALUE KEYWORD VALUE...).
 252 Each keyword should be listed in `custom-face-attributes'.
 253
 254 If FRAME is nil, use the global defaults for FACE."
 255   (let ((attrs custom-face-attributes)
 256         plist)
 257     (while attrs
 258       (let* ((attribute (car (car attrs)))
 259              (value (face-attribute face attribute frame)))
 260         (setq attrs (cdr attrs))
 261         (unless (or (eq value 'unspecified)
 262                     (and (null value) (memq attribute '(:inherit))))
 263           (setq plist (cons attribute (cons value plist))))))
 264     plist))
 265
 266 ;;; Initializing.
 267
 268 ;;;###autoload
 269 (defun custom-set-faces (&rest args)
 270   "Initialize faces according to user preferences.
 271 This associates the settings with the `user' theme.
 272 The arguments should be a list where each entry has the form:
 273
 274   (FACE SPEC [NOW [COMMENT]])
 275
 276 SPEC is stored as the saved value for FACE, as well as the value for the
 277 `user' theme.  The `user' theme is one of the default themes known to Emacs.
 278 See `custom-known-themes' for more information on the known themes.
 279 See `custom-theme-set-faces' for more information on the interplay
 280 between themes and faces.
 281 See `defface' for the format of SPEC.
 282
 283 If NOW is present and non-nil, FACE is created now, according to SPEC.
 284 COMMENT is a string comment about FACE."
 285   (apply 'custom-theme-set-faces 'user args))
 286
 287 (defun custom-theme-set-faces (theme &rest args)
 288   "Initialize faces for theme THEME.
 289 The arguments should be a list where each entry has the form:
 290
 291   (FACE SPEC [NOW [COMMENT]])
 292
 293 SPEC is stored as the saved value for FACE, as well as the value for the
 294 `user' theme.  The `user' theme is one of the default themes known to Emacs.
 295 See `custom-known-themes' for more information on the known themes.
 296 See `custom-theme-set-faces' for more information on the interplay
 297 between themes and faces.
 298 See `defface' for the format of SPEC.
 299
 300 If NOW is present and non-nil, FACE is created now, according to SPEC.
 301 COMMENT is a string comment about FACE.
 302
 303 Several properties of THEME and FACE are used in the process:
 304
 305 If THEME property `theme-immediate' is non-nil, this is equivalent of
 306 providing the NOW argument to all faces in the argument list: FACE is
 307 created now.  The only difference is FACE property `force-face': if NOW
 308 is non-nil, FACE property `force-face' is set to the symbol `rogue', else
 309 if THEME property `theme-immediate' is non-nil, FACE property `force-face'
 310 is set to the symbol `immediate'.
 311
 312 SPEC itself is saved in FACE property `saved-face' and it is stored in
 313 FACE's list property `theme-face' \(using `custom-push-theme')."
 314   (custom-check-theme theme)
 315   (let ((immediate (get theme 'theme-immediate)))
 316     (while args
 317       (let ((entry (car args)))
 318         (if (listp entry)
 319             (let ((face (nth 0 entry))
 320                   (spec (nth 1 entry))
 321                   (now (nth 2 entry))
 322                   (comment (nth 3 entry)))
 323               ;; If FACE is actually an alias, customize the face it
 324               ;; is aliased to.
 325               (if (get face 'face-alias)
 326                   (setq face (get face 'face-alias)))
 327               (put face 'saved-face spec)
 328               (put face 'saved-face-comment comment)
 329               (custom-push-theme 'theme-face face theme 'set spec)
 330               (when (or now immediate)
 331                 (put face 'force-face (if now 'rogue 'immediate)))
 332               (when (or now immediate (facep face))
 333                 (unless (facep face)
 334                   (make-empty-face face))
 335                 (put face 'face-comment comment)
 336                 (face-spec-set face spec))
 337             (setq args (cdr args)))
 338         ;; Old format, a plist of FACE SPEC pairs.
 339         (let ((face (nth 0 args))
 340               (spec (nth 1 args)))
 341           (if (get face 'face-alias)
 342                   (setq face (get face 'face-alias)))
 343           (put face 'saved-face spec)
 344           (custom-push-theme 'theme-face face theme 'set spec))
 345         (setq args (cdr (cdr args))))))))
 346
 347 ;;;###autoload
 348 (defun custom-theme-reset-faces (theme &rest args)
 349   "Reset the specs in THEME of some faces to their specs in other themes.
 350 Each of the arguments ARGS has this form:
 351
 352     (FACE FROM-THEME)
 353
 354 This means reset FACE to its value in FROM-THEME."
 355   (custom-check-theme theme)
 356   (dolist (arg args)
 357     (custom-push-theme 'theme-face (car arg) theme 'reset (cadr arg))))
 358
 359 ;;;###autoload
 360 (defun custom-reset-faces (&rest args)
 361   "Reset the specs of some faces to their specs in specified themes.
 362 This creates settings in the `user' theme.
 363
 364 Each of the arguments ARGS has this form:
 365
 366     (FACE FROM-THEME)
 367
 368 This means reset FACE to its value in FROM-THEME."
 369   (apply 'custom-theme-reset-faces 'user args))
 370
 371 ;;; The End.
 372
 373 (provide 'cus-face)
 374
 375 ;;; arch-tag: 9a5c4b63-0d27-4c92-a5af-f2c7ed764c2b
 376 ;;; cus-face.el ends here