code.delx.au - gnu-emacs/blob - lisp/ls-lisp.el

   1 ;;; ls-lisp.el --- emulate insert-directory completely in Emacs Lisp
   2
   3 ;; Copyright (C) 1992, 1994, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   5
   6 ;; Author: Sebastian Kremer <sk@thp.uni-koeln.de>
   7 ;; Modified by: Francis J. Wright <F.J.Wright@maths.qmw.ac.uk>
   8 ;; Maintainer: FSF
   9 ;; Keywords: unix, dired
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; OVERVIEW ==========================================================
  29
  30 ;; This file redefines the function `insert-directory' to implement it
  31 ;; directly from Emacs lisp, without running ls in a subprocess.  It
  32 ;; is useful if you cannot afford to fork Emacs on a real memory UNIX,
  33 ;; or other non-UNIX platforms if you don't have the ls
  34 ;; program, or if you want a different format from what ls offers.
  35
  36 ;; This function can use regexps instead of shell wildcards.  If you
  37 ;; enter regexps remember to double each $ sign.  For example, to
  38 ;; include files *.el, enter `.*\.el$$', resulting in the regexp
  39 ;; `.*\.el$'.
  40
  41 ;; RESTRICTIONS ======================================================
  42
  43 ;; * A few obscure ls switches are still ignored: see the docstring of
  44 ;; `insert-directory'.
  45
  46 ;; TO DO =============================================================
  47
  48 ;; Complete handling of F switch (if/when possible).
  49
  50 ;; FJW: May be able to sort much faster by consing the sort key onto
  51 ;; the front of each list element, sorting and then stripping the key
  52 ;; off again!
  53
  54 ;;; History:
  55
  56 ;; Written originally by Sebastian Kremer <sk@thp.uni-koeln.de>
  57 ;; Revised by Andrew Innes and Geoff Volker (and maybe others).
  58
  59 ;; Modified by Francis J. Wright <F.J.Wright@maths.qmw.ac.uk>, mainly
  60 ;; to support many more ls options, "platform emulation" and more
  61 ;; robust sorting.
  62
  63 ;;; Code:
  64
  65 (eval-when-compile (require 'cl))
  66
  67 (defgroup ls-lisp nil
  68   "Emulate the ls program completely in Emacs Lisp."
  69   :version "21.1"
  70   :group 'dired)
  71
  72 (defcustom ls-lisp-emulation
  73   (cond ;; ((eq system-type 'windows-nt) 'MS-Windows)
  74         ((memq system-type
  75                '(hpux usg-unix-v irix berkeley-unix))
  76          'UNIX))                        ; very similar to GNU
  77   ;; Anything else defaults to nil, meaning GNU.
  78   "Platform to emulate: GNU (default), MacOS, MS-Windows, UNIX.
  79 Corresponding value is one of the atoms: nil, MacOS, MS-Windows, UNIX.
  80 Sets default values for: `ls-lisp-ignore-case', `ls-lisp-dirs-first',
  81 `ls-lisp-verbosity'.  Need not match actual platform.  Changing this
  82 option will have no effect until you restart Emacs."
  83   :type '(choice (const :tag "GNU" nil)
  84                  (const MacOS)
  85                  (const MS-Windows)
  86                  (const UNIX))
  87   :group 'ls-lisp)
  88
  89 (defcustom ls-lisp-ignore-case
  90   ;; Name change for consistency with other option names.
  91   (or (memq ls-lisp-emulation '(MS-Windows MacOS))
  92       (and (boundp 'ls-lisp-dired-ignore-case) ls-lisp-dired-ignore-case))
  93   "Non-nil causes ls-lisp alphabetic sorting to ignore case."
  94   :type 'boolean
  95   :group 'ls-lisp)
  96
  97 (defcustom ls-lisp-dirs-first (eq ls-lisp-emulation 'MS-Windows)
  98   "Non-nil causes ls-lisp to sort directories first in any ordering.
  99 \(Or last if it is reversed.)  Follows Microsoft Windows Explorer."
 100   ;; Functionality suggested by Chris McMahan <cmcmahan@one.net>
 101   :type 'boolean
 102   :group 'ls-lisp)
 103
 104 (defcustom ls-lisp-verbosity
 105   (cond ((eq ls-lisp-emulation 'MacOS) nil)
 106         ((eq ls-lisp-emulation 'MS-Windows)
 107          (if (and (fboundp 'w32-using-nt) (w32-using-nt))
 108              '(links)))                 ; distinguish NT/2K from 9x
 109         ((eq ls-lisp-emulation 'UNIX) '(links uid)) ; UNIX ls
 110         (t '(links uid gid)))           ; GNU ls
 111   "A list of optional file attributes that ls-lisp should display.
 112 It should contain none or more of the symbols: links, uid, gid.
 113 A value of nil (or an empty list) means display none of them.
 114
 115 Concepts come from UNIX: `links' means count of names associated with
 116 the file\; `uid' means user (owner) identifier\; `gid' means group
 117 identifier.
 118
 119 If emulation is MacOS then default is nil\;
 120 if emulation is MS-Windows then default is `(links)' if platform is
 121 Windows NT/2K, nil otherwise\;
 122 if emulation is UNIX then default is `(links uid)'\;
 123 if emulation is GNU then default is `(links uid gid)'."
 124   ;; Functionality suggested by Howard Melman <howard@silverstream.com>
 125   :type '(set (const :tag "Show Link Count" links)
 126               (const :tag "Show User" uid)
 127               (const :tag "Show Group" gid))
 128   :group 'ls-lisp)
 129
 130 (defcustom ls-lisp-use-insert-directory-program
 131   (not (memq system-type '(ms-dos windows-nt)))
 132   "Non-nil causes ls-lisp to revert back to using `insert-directory-program'.
 133 This is useful on platforms where ls-lisp is dumped into Emacs, such as
 134 Microsoft Windows, but you would still like to use a program to list
 135 the contents of a directory."
 136   :type 'boolean
 137   :group 'ls-lisp)
 138
 139 ;;; Autoloaded because it is let-bound in `recover-session', `mail-recover-1'.
 140 ;;;###autoload
 141 (defcustom ls-lisp-support-shell-wildcards t
 142   "Non-nil means ls-lisp treats file patterns as shell wildcards.
 143 Otherwise they are treated as Emacs regexps (for backward compatibility)."
 144   :type 'boolean
 145   :group 'ls-lisp)
 146
 147 (defcustom ls-lisp-format-time-list
 148   '("%b %e %H:%M"
 149     "%b %e  %Y")
 150   "List of `format-time-string' specs to display file time stamps.
 151 These specs are used ONLY if a valid locale can not be determined.
 152
 153 If `ls-lisp-use-localized-time-format' is non-nil, these specs are used
 154 regardless of whether the locale can be determined.
 155
 156 Syntax:  (EARLY-TIME-FORMAT OLD-TIME-FORMAT)
 157
 158 The EARLY-TIME-FORMAT is used if file has been modified within the
 159 current year. The OLD-TIME-FORMAT is used for older files.  To use ISO
 160 8601 dates, you could set:
 161
 162 \(setq ls-lisp-format-time-list
 163        '(\"%Y-%m-%d %H:%M\"
 164          \"%Y-%m-%d      \"))"
 165   :type '(list (string :tag "Early time format")
 166                (string :tag "Old time format"))
 167   :group 'ls-lisp)
 168
 169 (defcustom ls-lisp-use-localized-time-format nil
 170   "Non-nil causes ls-lisp to use `ls-lisp-format-time-list' even if
 171 a valid locale is specified.
 172
 173 WARNING: Using localized date/time format might cause Dired columns
 174 to fail to lign up, e.g. if month names are not all of the same length."
 175   :type 'boolean
 176   :group 'ls-lisp)
 177
 178 (defvar original-insert-directory nil
 179   "This holds the original function definition of `insert-directory'.")
 180
 181 (defvar ls-lisp-uid-d-fmt "-%d"
 182   "Format to display integer UIDs.")
 183 (defvar ls-lisp-uid-s-fmt "-%s"
 184   "Format to display user names.")
 185 (defvar ls-lisp-gid-d-fmt "-%d"
 186   "Format to display integer GIDs.")
 187 (defvar ls-lisp-gid-s-fmt "-%s"
 188   "Format to display user group names.")
 189 (defvar ls-lisp-filesize-d-fmt "%d"
 190   "Format to display integer file sizes.")
 191 (defvar ls-lisp-filesize-f-fmt "%.0f"
 192   "Format to display float file sizes.")
 193
 194 ;; Remember the original insert-directory function
 195 (or (featurep 'ls-lisp)  ; FJW: unless this file is being reloaded!
 196     (setq original-insert-directory (symbol-function 'insert-directory)))
 197
 198 \f
 199 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 200
 201 (defun insert-directory (file switches &optional wildcard full-directory-p)
 202   "Insert directory listing for FILE, formatted according to SWITCHES.
 203 Leaves point after the inserted text.
 204 SWITCHES may be a string of options, or a list of strings.
 205 Optional third arg WILDCARD means treat FILE as shell wildcard.
 206 Optional fourth arg FULL-DIRECTORY-P means file is a directory and
 207 switches do not contain `d', so that a full listing is expected.
 208
 209 This version of the function comes from `ls-lisp.el'.
 210 If the value of `ls-lisp-use-insert-directory-program' is non-nil then
 211 it works exactly like the version from `files.el' and runs a directory
 212 listing program whose name is in the variable
 213 `insert-directory-program'; if also WILDCARD is non-nil then it runs
 214 the shell specified by `shell-file-name'.  If the value of
 215 `ls-lisp-use-insert-directory-program' is nil then it runs a Lisp
 216 emulation.
 217
 218 The Lisp emulation does not run any external programs or shells.  It
 219 supports ordinary shell wildcards if `ls-lisp-support-shell-wildcards'
 220 is non-nil; otherwise, it interprets wildcards as regular expressions
 221 to match file names.  It does not support all `ls' switches -- those
 222 that work are: A a c i r S s t u U X g G B C R n and F partly."
 223   (if ls-lisp-use-insert-directory-program
 224       (funcall original-insert-directory
 225                file switches wildcard full-directory-p)
 226     ;; We need the directory in order to find the right handler.
 227     (let ((handler (find-file-name-handler (expand-file-name file)
 228                                            'insert-directory))
 229           (orig-file file)
 230           wildcard-regexp)
 231       (if handler
 232           (funcall handler 'insert-directory file switches
 233                    wildcard full-directory-p)
 234         ;; Remove --dired switch
 235         (if (string-match "--dired " switches)
 236             (setq switches (replace-match "" nil nil switches)))
 237         ;; Convert SWITCHES to a list of characters.
 238         (setq switches (delete ?- (append switches nil)))
 239         ;; Sometimes we get ".../foo*/" as FILE.  While the shell and
 240         ;; `ls' don't mind, we certainly do, because it makes us think
 241         ;; there is no wildcard, only a directory name.
 242         (if (and ls-lisp-support-shell-wildcards
 243                  (string-match "[[?*]" file)
 244                  ;; Prefer an existing file to wildcards, like
 245                  ;; dired-noselect does.
 246                  (not (file-exists-p file)))
 247             (progn
 248               (or (not (eq (aref file (1- (length file))) ?/))
 249                   (setq file (substring file 0 (1- (length file)))))
 250               (setq wildcard t)))
 251         (if wildcard
 252             (setq wildcard-regexp
 253                   (if ls-lisp-support-shell-wildcards
 254                       (wildcard-to-regexp (file-name-nondirectory file))
 255                     (file-name-nondirectory file))
 256                   file (file-name-directory file))
 257           (if (memq ?B switches) (setq wildcard-regexp "[^~]\\'")))
 258         (condition-case err
 259             (ls-lisp-insert-directory
 260              file switches (ls-lisp-time-index switches)
 261              wildcard-regexp full-directory-p)
 262           (invalid-regexp
 263            ;; Maybe they wanted a literal file that just happens to
 264            ;; use characters special to shell wildcards.
 265            (if (equal (cadr err) "Unmatched [ or [^")
 266                (progn
 267                  (setq wildcard-regexp (if (memq ?B switches) "[^~]\\'")
 268                        file (file-relative-name orig-file))
 269                  (ls-lisp-insert-directory
 270                   file switches (ls-lisp-time-index switches)
 271                   nil full-directory-p))
 272              (signal (car err) (cdr err)))))
 273         ;; Try to insert the amount of free space.
 274         (save-excursion
 275           (goto-char (point-min))
 276           ;; First find the line to put it on.
 277           (when (re-search-forward "^total" nil t)
 278             (let ((available (get-free-disk-space ".")))
 279               (when available
 280                 ;; Replace "total" with "total used", to avoid confusion.
 281                 (replace-match "total used in directory")
 282                 (end-of-line)
 283                 (insert " available " available)))))))))
 284
 285 (defun ls-lisp-insert-directory
 286   (file switches time-index wildcard-regexp full-directory-p)
 287   "Insert directory listing for FILE, formatted according to SWITCHES.
 288 Leaves point after the inserted text.  This is an internal function
 289 optionally called by the `ls-lisp.el' version of `insert-directory'.
 290 It is called recursively if the -R switch is used.
 291 SWITCHES is a *list* of characters.  TIME-INDEX is the time index into
 292 file-attributes according to SWITCHES.  WILDCARD-REGEXP is nil or an *Emacs
 293 regexp*.  FULL-DIRECTORY-P means file is a directory and SWITCHES does
 294 not contain `d', so that a full listing is expected."
 295   (if (or wildcard-regexp full-directory-p)
 296       (let* ((dir (file-name-as-directory file))
 297              (default-directory dir)    ; so that file-attributes works
 298              (file-alist
 299               (directory-files-and-attributes dir nil wildcard-regexp t
 300                                               (if (memq ?n switches)
 301                                                   'integer
 302                                                 'string)))
 303              (now (current-time))
 304              (sum 0)
 305              (max-uid-len 0)
 306              (max-gid-len 0)
 307              (max-file-size 0)
 308              ;; do all bindings here for speed
 309              total-line files elt short file-size fil attr
 310              fuid fgid uid-len gid-len)
 311         (cond ((memq ?A switches)
 312                (setq file-alist
 313                      (ls-lisp-delete-matching "^\\.\\.?$" file-alist)))
 314               ((not (memq ?a switches))
 315                ;; if neither -A  nor -a, flush . files
 316                (setq file-alist
 317                      (ls-lisp-delete-matching "^\\." file-alist))))
 318         (setq file-alist
 319               (ls-lisp-handle-switches file-alist switches))
 320         (if (memq ?C switches)          ; column (-C) format
 321             (ls-lisp-column-format file-alist)
 322           (setq total-line (cons (point) (car-safe file-alist)))
 323           ;; Find the appropriate format for displaying uid, gid, and
 324           ;; file size, by finding the longest strings among all the
 325           ;; files we are about to display.
 326           (dolist (elt file-alist)
 327             (setq attr (cdr elt)
 328                   fuid (nth 2 attr)
 329                   uid-len (if (stringp fuid) (string-width fuid)
 330                             (length (format "%d" fuid)))
 331                   fgid (nth 3 attr)
 332                   gid-len (if (stringp fgid) (string-width fgid)
 333                             (length (format "%d" fgid)))
 334                   file-size (nth 7 attr))
 335             (if (> uid-len max-uid-len)
 336                 (setq max-uid-len uid-len))
 337             (if (> gid-len max-gid-len)
 338                 (setq max-gid-len gid-len))
 339             (if (> file-size max-file-size)
 340                 (setq max-file-size file-size)))
 341           (setq ls-lisp-uid-d-fmt (format " %%-%dd" max-uid-len))
 342           (setq ls-lisp-uid-s-fmt (format " %%-%ds" max-uid-len))
 343           (setq ls-lisp-gid-d-fmt (format " %%-%dd" max-gid-len))
 344           (setq ls-lisp-gid-s-fmt (format " %%-%ds" max-gid-len))
 345           (setq ls-lisp-filesize-d-fmt
 346                 (format " %%%dd"
 347                         (if (memq ?s switches)
 348                             (length (format "%.0f"
 349                                             (fceiling (/ max-file-size 1024.0))))
 350                           (length (format "%.0f" max-file-size)))))
 351           (setq ls-lisp-filesize-f-fmt
 352                 (format " %%%d.0f"
 353                         (if (memq ?s switches)
 354                             (length (format "%.0f"
 355                                             (fceiling (/ max-file-size 1024.0))))
 356                           (length (format "%.0f" max-file-size)))))
 357           (setq files file-alist)
 358           (while files                  ; long (-l) format
 359             (setq elt (car files)
 360                   files (cdr files)
 361                   short (car elt)
 362                   attr (cdr elt)
 363                   file-size (nth 7 attr))
 364             (and attr
 365                  (setq sum (+ file-size
 366                               ;; Even if neither SUM nor file's size
 367                               ;; overflow, their sum could.
 368                               (if (or (< sum (- 134217727 file-size))
 369                                       (floatp sum)
 370                                       (floatp file-size))
 371                                   sum
 372                                 (float sum))))
 373                  (insert (ls-lisp-format short attr file-size
 374                                          switches time-index now))))
 375           ;; Insert total size of all files:
 376           (save-excursion
 377             (goto-char (car total-line))
 378             (or (cdr total-line)
 379                 ;; Shell says ``No match'' if no files match
 380                 ;; the wildcard; let's say something similar.
 381                 (insert "(No match)\n"))
 382             (insert (format "total %.0f\n" (fceiling (/ sum 1024.0))))))
 383         (if (memq ?R switches)
 384             ;; List the contents of all directories recursively.
 385             ;; cadr of each element of `file-alist' is t for
 386             ;; directory, string (name linked to) for symbolic
 387             ;; link, or nil.
 388             (while file-alist
 389               (setq elt (car file-alist)
 390                     file-alist (cdr file-alist))
 391               (when (and (eq (cadr elt) t) ; directory
 392                          ;; Under -F, we have already decorated all
 393                          ;; directories, including "." and "..", with
 394                          ;; a /, so allow for that as well.
 395                          (not (string-match "\\`\\.\\.?/?\\'" (car elt))))
 396                 (setq elt (expand-file-name (car elt) dir))
 397                 (insert "\n" elt ":\n")
 398                 (ls-lisp-insert-directory
 399                  elt switches time-index wildcard-regexp full-directory-p)))))
 400     ;; If not full-directory-p, FILE *must not* end in /, as
 401     ;; file-attributes will not recognize a symlink to a directory,
 402     ;; so must make it a relative filename as ls does:
 403     (if (eq (aref file (1- (length file))) ?/)
 404         (setq file (substring file 0 -1)))
 405     (let ((fattr (file-attributes file 'string)))
 406       (if fattr
 407           (insert (ls-lisp-format file fattr (nth 7 fattr)
 408                                   switches time-index (current-time)))
 409         (message "%s: doesn't exist or is inaccessible" file)
 410         (ding) (sit-for 2)))))          ; to show user the message!
 411
 412 (defun ls-lisp-column-format (file-alist)
 413   "Insert the file names (only) in FILE-ALIST into the current buffer.
 414 Format in columns, sorted vertically, following GNU ls -C.
 415 Responds to the window width as ls should but may not!"
 416   (let (files fmt ncols collen (nfiles 0) (colwid 0))
 417     ;; Count number of files as `nfiles', build list of filenames as
 418     ;; `files', and find maximum filename length as `colwid':
 419     (let (file len)
 420       (while file-alist
 421         (setq nfiles (1+ nfiles)
 422               file (caar file-alist)
 423               files (cons file files)
 424               file-alist (cdr file-alist)
 425               len (length file))
 426         (if (> len colwid) (setq colwid len))))
 427     (setq files (nreverse files)
 428           colwid (+ 2 colwid)           ; 2 character column gap
 429           fmt (format "%%-%ds" colwid)  ; print format
 430           ncols (/ (window-width) colwid) ; no of columns
 431           collen (/ nfiles ncols))      ; floor of column length
 432     (if (> nfiles (* collen ncols)) (setq collen (1+ collen)))
 433     ;; Output the file names in columns, sorted vertically:
 434     (let ((i 0) j)
 435       (while (< i collen)
 436         (setq j i)
 437         (while (< j nfiles)
 438           (insert (format fmt (nth j files)))
 439           (setq j (+ j collen)))
 440         ;; FJW: This is completely unnecessary, but I don't like
 441         ;; trailing white space...
 442         (delete-region (point) (progn (skip-chars-backward " \t") (point)))
 443         (insert ?\n)
 444         (setq i (1+ i))))))
 445
 446 (defun ls-lisp-delete-matching (regexp list)
 447   "Delete all elements matching REGEXP from LIST, return new list."
 448   ;; Should perhaps use setcdr for efficiency.
 449   (let (result)
 450     (while list
 451       (or (string-match regexp (caar list))
 452           (setq result (cons (car list) result)))
 453       (setq list (cdr list)))
 454     result))
 455
 456 (defsubst ls-lisp-string-lessp (s1 s2)
 457   "Return t if string S1 is less than string S2 in lexicographic order.
 458 Case is significant if `ls-lisp-ignore-case' is nil.
 459 Unibyte strings are converted to multibyte for comparison."
 460   (let ((u (compare-strings s1 0 nil s2 0 nil ls-lisp-ignore-case)))
 461     (and (numberp u) (< u 0))))
 462
 463 (defun ls-lisp-handle-switches (file-alist switches)
 464   "Return new FILE-ALIST sorted according to SWITCHES.
 465 SWITCHES is a list of characters.  Default sorting is alphabetic."
 466   ;; FILE-ALIST's elements are (FILE . FILE-ATTRIBUTES).
 467   (or (memq ?U switches)                ; unsorted
 468       ;; Catch and ignore unexpected sorting errors
 469       (condition-case err
 470           (setq file-alist
 471                 (let (index)
 472                   ;; Copy file-alist in case of error
 473                   (sort (copy-sequence file-alist) ; modifies its argument!
 474                         (cond ((memq ?S switches)
 475                                (lambda (x y) ; sorted on size
 476                                  ;; 7th file attribute is file size
 477                                  ;; Make largest file come first
 478                                  (< (nth 7 (cdr y))
 479                                     (nth 7 (cdr x)))))
 480                               ((setq index (ls-lisp-time-index switches))
 481                                (lambda (x y) ; sorted on time
 482                                  (ls-lisp-time-lessp (nth index (cdr y))
 483                                                      (nth index (cdr x)))))
 484                               ((memq ?X switches)
 485                                (lambda (x y) ; sorted on extension
 486                                  (ls-lisp-string-lessp
 487                                   (ls-lisp-extension (car x))
 488                                   (ls-lisp-extension (car y)))))
 489                               (t
 490                                (lambda (x y) ; sorted alphabetically
 491                                  (ls-lisp-string-lessp (car x) (car y))))))))
 492         (error (message "Unsorted (ls-lisp sorting error) - %s"
 493                         (error-message-string err))
 494                (ding) (sit-for 2))))    ; to show user the message!
 495   (if (memq ?F switches)                ; classify switch
 496       (setq file-alist (mapcar 'ls-lisp-classify file-alist)))
 497   (if ls-lisp-dirs-first
 498   ;; Re-sort directories first, without otherwise changing the
 499   ;; ordering, and reverse whole list.  cadr of each element of
 500   ;; `file-alist' is t for directory, string (name linked to) for
 501   ;; symbolic link, or nil.
 502       (let (el dirs files)
 503         (while file-alist
 504           (if (or (eq (cadr (setq el (car file-alist))) t) ; directory
 505                   (and (stringp (cadr el))
 506                        (file-directory-p (cadr el)))) ; symlink to a directory
 507               (setq dirs (cons el dirs))
 508             (setq files (cons el files)))
 509           (setq file-alist (cdr file-alist)))
 510         (setq file-alist
 511               (if (memq ?U switches)    ; unsorted order is reversed
 512                   (nconc dirs files)
 513                 (nconc files dirs)
 514                 ))))
 515   ;; Finally reverse file alist if necessary.
 516   ;; (eq below MUST compare `(not (memq ...))' to force comparison of
 517   ;; `t' or `nil', rather than list tails!)
 518   (if (eq (eq (not (memq ?U switches))  ; unsorted order is reversed
 519               (not (memq ?r switches))) ; reversed sort order requested
 520           ls-lisp-dirs-first)           ; already reversed
 521       (nreverse file-alist)
 522     file-alist))
 523
 524 (defun ls-lisp-classify (filedata)
 525   "Append a character to each file name indicating the file type.
 526 Also, for regular files that are executable, append `*'.
 527 The file type indicators are `/' for directories, `@' for symbolic
 528 links, `|' for FIFOs, `=' for sockets, and nothing for regular files.
 529 \[But FIFOs and sockets are not recognized.]
 530 FILEDATA has the form (filename . `file-attributes').  Its `cadr' is t
 531 for directory, string (name linked to) for symbolic link, or nil."
 532   (let ((file-name (car filedata))
 533         (type (cadr filedata)))
 534     (cond (type
 535            (cons
 536             (concat (propertize file-name 'dired-filename t)
 537                     (if (eq type t) "/" "@"))
 538             (cdr filedata)))
 539           ((string-match "x" (nth 9 filedata))
 540            (cons
 541             (concat (propertize file-name 'dired-filename t) "*")
 542             (cdr filedata)))
 543           (t
 544            (cons
 545             (propertize file-name 'dired-filename t)
 546             (cdr filedata))))))
 547
 548 (defun ls-lisp-extension (filename)
 549   "Return extension of FILENAME (ignoring any version extension)
 550 FOLLOWED by null and full filename, SOLELY for full alpha sort."
 551   ;; Force extension sort order: `no ext' then `null ext' then `ext'
 552   ;; to agree with GNU ls.
 553   (concat
 554    (let* ((i (length filename)) end)
 555      (if (= (aref filename (1- i)) ?.) ; null extension
 556          "\0"
 557        (while (and (>= (setq i (1- i)) 0)
 558                    (/= (aref filename i) ?.)))
 559        (if (< i 0) "\0\0"               ; no extension
 560          (if (/= (aref filename (1+ i)) ?~)
 561              (substring filename (1+ i))
 562            ;; version extension found -- ignore it
 563            (setq end i)
 564            (while (and (>= (setq i (1- i)) 0)
 565                        (/= (aref filename i) ?.)))
 566            (if (< i 0) "\0\0"   ; no extension
 567              (substring filename (1+ i) end))))
 568        )) "\0" filename))
 569
 570 ;; From Roland McGrath.  Can use this to sort on time.
 571 (defun ls-lisp-time-lessp (time0 time1)
 572   "Return t if time TIME0 is earlier than time TIME1."
 573   (let ((hi0 (car time0)) (hi1 (car time1)))
 574     (or (< hi0 hi1)
 575         (and (= hi0 hi1)
 576              (< (cadr time0) (cadr time1))))))
 577
 578 (defun ls-lisp-format (file-name file-attr file-size switches time-index now)
 579   "Format one line of long ls output for file FILE-NAME.
 580 FILE-ATTR and FILE-SIZE give the file's attributes and size.
 581 SWITCHES, TIME-INDEX and NOW give the full switch list and time data."
 582   (let ((file-type (nth 0 file-attr))
 583         ;; t for directory, string (name linked to)
 584         ;; for symbolic link, or nil.
 585         (drwxrwxrwx (nth 8 file-attr))) ; attribute string ("drwxrwxrwx")
 586     (concat (if (memq ?i switches)      ; inode number
 587                 (let ((inode (nth 10 file-attr)))
 588                   (if (consp inode)
 589                       (if (consp (cdr inode))
 590                           ;; 2^(24+16) = 1099511627776.0, but
 591                           ;; multiplying by it and then adding the
 592                           ;; other members of the cons cell in one go
 593                           ;; loses precision, since a double does not
 594                           ;; have enough significant digits to hold a
 595                           ;; full 64-bit value.  So below we split
 596                           ;; 1099511627776 into high 13 and low 5
 597                           ;; digits and compute in two parts.
 598                           (let ((p1 (* (car inode) 10995116.0))
 599                                 (p2 (+ (* (car inode) 27776.0)
 600                                        (* (cadr inode) 65536.0)
 601                                        (cddr inode))))
 602                             (format " %13.0f%05.0f "
 603                                     ;; Use floor to emulate integer
 604                                     ;; division.
 605                                     (+ p1 (floor p2 100000.0))
 606                                     (mod p2 100000.0)))
 607                         (format " %18.0f "
 608                                 (+ (* (car inode) 65536.0)
 609                                    (cdr inode))))
 610                     (format " %18d " inode))))
 611             ;; nil is treated like "" in concat
 612             (if (memq ?s switches)      ; size in K
 613                 (format ls-lisp-filesize-f-fmt
 614                         (fceiling (/ file-size 1024.0))))
 615             drwxrwxrwx                  ; attribute string
 616             (if (memq 'links ls-lisp-verbosity)
 617                 (format "%3d" (nth 1 file-attr))) ; link count
 618             ;; Numeric uid/gid are more confusing than helpful;
 619             ;; Emacs should be able to make strings of them.
 620             ;; They tend to be bogus on non-UNIX platforms anyway so
 621             ;; optionally hide them.
 622             (if (memq 'uid ls-lisp-verbosity)
 623                 ;; uid can be a sting or an integer
 624                 (let ((uid (nth 2 file-attr)))
 625                   (format (if (stringp uid)
 626                               ls-lisp-uid-s-fmt
 627                             ls-lisp-uid-d-fmt)
 628                           uid)))
 629             (if (not (memq ?G switches)) ; GNU ls -- shows group by default
 630                 (if (or (memq ?g switches) ; UNIX ls -- no group by default
 631                         (memq 'gid ls-lisp-verbosity))
 632                     (let ((gid (nth 3 file-attr)))
 633                       (format (if (stringp gid)
 634                                   ls-lisp-gid-s-fmt
 635                                 ls-lisp-gid-d-fmt)
 636                               gid))))
 637             (ls-lisp-format-file-size file-size (memq ?h switches))
 638             " "
 639             (ls-lisp-format-time file-attr time-index now)
 640             " "
 641             (if (not (memq ?F switches)) ; ls-lisp-classify already did that
 642                 (propertize file-name 'dired-filename t)
 643               file-name)
 644             (if (stringp file-type)     ; is a symbolic link
 645                 (concat " -> " file-type))
 646             "\n"
 647             )))
 648
 649 (defun ls-lisp-time-index (switches)
 650   "Return time index into file-attributes according to ls SWITCHES list.
 651 Return nil if no time switch found."
 652   ;; FJW: Default of nil is IMPORTANT and used in `ls-lisp-handle-switches'!
 653   (cond ((memq ?c switches) 6)          ; last mode change
 654         ((memq ?t switches) 5)          ; last modtime
 655         ((memq ?u switches) 4)))        ; last access
 656
 657 (defun ls-lisp-time-to-seconds (time)
 658   "Convert TIME to a floating point number."
 659   (+ (* (car time) 65536.0)
 660      (cadr time)
 661      (/ (or (nth 2 time) 0) 1000000.0)))
 662
 663 (defun ls-lisp-format-time (file-attr time-index now)
 664   "Format time for file with attributes FILE-ATTR according to TIME-INDEX.
 665 Use the same method as ls to decide whether to show time-of-day or year,
 666 depending on distance between file date and NOW.
 667 All ls time options, namely c, t and u, are handled."
 668   (let* ((time (nth (or time-index 5) file-attr)) ; default is last modtime
 669          (diff (- (ls-lisp-time-to-seconds time)
 670                   (ls-lisp-time-to-seconds now)))
 671          ;; Consider a time to be recent if it is within the past six
 672          ;; months.  A Gregorian year has 365.2425 * 24 * 60 * 60 ==
 673          ;; 31556952 seconds on the average, and half of that is 15778476.
 674          ;; Write the constant explicitly to avoid roundoff error.
 675          (past-cutoff -15778476)) ; half a Gregorian year
 676     (condition-case nil
 677         ;; Use traditional time format in the C or POSIX locale,
 678         ;; ISO-style time format otherwise, so columns line up.
 679         (let ((locale system-time-locale))
 680           (if (not locale)
 681               (let ((vars '("LC_ALL" "LC_TIME" "LANG")))
 682                 (while (and vars (not (setq locale (getenv (car vars)))))
 683                   (setq vars (cdr vars)))))
 684           (if (member locale '("C" "POSIX"))
 685               (setq locale nil))
 686           (format-time-string
 687            (if (and (<= past-cutoff diff) (<= diff 0))
 688                (if (and locale (not ls-lisp-use-localized-time-format))
 689                    "%m-%d %H:%M"
 690                  (nth 0 ls-lisp-format-time-list))
 691              (if (and locale (not ls-lisp-use-localized-time-format))
 692                  "%Y-%m-%d "
 693                (nth 1 ls-lisp-format-time-list)))
 694            time))
 695       (error "Unk  0  0000"))))
 696
 697 (defun ls-lisp-format-file-size (file-size human-readable)
 698   (if (not human-readable)
 699       (format (if (floatp file-size)
 700                   ls-lisp-filesize-f-fmt
 701                 ls-lisp-filesize-d-fmt)
 702               file-size)
 703     (if (< file-size 1024)
 704         (format " %4d" file-size)
 705       (do ((file-size (/ file-size 1024.0) (/ file-size 1024.0))
 706            ;; kilo, mega, giga, tera, peta, exa
 707            (post-fixes (list "k" "M" "G" "T" "P" "E") (cdr post-fixes)))
 708           ((< file-size 1024)
 709            (format " %3.0f%s"  file-size (car post-fixes)))))))
 710
 711 (provide 'ls-lisp)
 712
 713 ;; arch-tag: e55f399b-05ec-425c-a6d5-f5e349c35ab4
 714 ;;; ls-lisp.el ends here