code.delx.au - gnu-emacs/blob - lisp/vc-git.el

   1 ;;; vc-git.el --- VC backend for the git version control system
   2
   3 ;; Copyright (C) 2006, 2007, 2008 Free Software Foundation, Inc.
   4
   5 ;; Author: Alexandre Julliard <julliard@winehq.org>
   6 ;; Keywords: tools
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 3, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This file contains a VC backend for the git version control
  28 ;; system.
  29 ;;
  30
  31 ;;; Installation:
  32
  33 ;; To install: put this file on the load-path and add Git to the list
  34 ;; of supported backends in `vc-handled-backends'; the following line,
  35 ;; placed in your ~/.emacs, will accomplish this:
  36 ;;
  37 ;;     (add-to-list 'vc-handled-backends 'Git)
  38
  39 ;;; Todo:
  40 ;;  - check if more functions could use vc-git-command instead
  41 ;;     of start-process.
  42 ;;  - changelog generation
  43
  44 ;; Implement the rest of the vc interface. See the comment at the
  45 ;; beginning of vc.el. The current status is:
  46 ;; ("??" means: "figure out what to do about it")
  47 ;;
  48 ;; FUNCTION NAME                                   STATUS
  49 ;; BACKEND PROPERTIES
  50 ;; * revision-granularity                          OK
  51 ;; STATE-QUERYING FUNCTIONS
  52 ;; * registered (file)                             OK
  53 ;; * state (file)                                  OK
  54 ;; - state-heuristic (file)                        NOT NEEDED
  55 ;; - dir-state (dir)                               OK
  56 ;; * working-revision (file)                       OK
  57 ;; - latest-on-branch-p (file)                     NOT NEEDED
  58 ;; * checkout-model (file)                         OK
  59 ;; - workfile-unchanged-p (file)                   OK
  60 ;; - mode-line-string (file)                       OK
  61 ;; - dired-state-info (file)                       OK
  62 ;; STATE-CHANGING FUNCTIONS
  63 ;; * create-repo ()                                OK
  64 ;; * register (files &optional rev comment)        OK
  65 ;; - init-revision (file)                          NOT NEEDED
  66 ;; - responsible-p (file)                          OK
  67 ;; - could-register (file)                         NOT NEEDED, DEFAULT IS GOOD
  68 ;; - receive-file (file rev)                       NOT NEEDED
  69 ;; - unregister (file)                             OK
  70 ;; * checkin (files rev comment)                   OK
  71 ;; * find-revision (file rev buffer)               OK
  72 ;; * checkout (file &optional editable rev)        OK
  73 ;; * revert (file &optional contents-done)         OK
  74 ;; - rollback (files)                              COULD BE SUPPORTED
  75 ;; - merge (file rev1 rev2)                        It would be possible to merge changes into
  76 ;;                                                 a single file, but when committing they
  77 ;;                                                 wouldn't be identified as a merge by git,
  78 ;;                                                 so it's probably not a good idea.
  79 ;; - merge-news (file)                             see `merge'
  80 ;; - steal-lock (file &optional revision)          NOT NEEDED
  81 ;; HISTORY FUNCTIONS
  82 ;; * print-log (files &optional buffer)            OK
  83 ;; - log-view-mode ()                              OK
  84 ;; - show-log-entry (revision)                     OK
  85 ;; - wash-log (file)                               COULD BE SUPPORTED
  86 ;; - logentry-check ()                             NOT NEEDED
  87 ;; - comment-history (file)                        ??
  88 ;; - update-changelog (files)                      COULD BE SUPPORTED
  89 ;; * diff (file &optional rev1 rev2 buffer)        OK
  90 ;; - revision-completion-table (files)             NEEDED?
  91 ;; - annotate-command (file buf &optional rev)     OK
  92 ;; - annotate-time ()                              OK
  93 ;; - annotate-current-time ()                      NOT NEEDED
  94 ;; - annotate-extract-revision-at-line ()          OK
  95 ;; SNAPSHOT SYSTEM
  96 ;; - create-snapshot (dir name branchp)            OK
  97 ;; - assign-name (file name)                       NOT NEEDED
  98 ;; - retrieve-snapshot (dir name update)           OK, needs to update buffers
  99 ;; MISCELLANEOUS
 100 ;; - make-version-backups-p (file)                 NOT NEEDED
 101 ;; - repository-hostname (dirname)                 NOT NEEDED
 102 ;; - previous-revision (file rev)                  OK
 103 ;; - next-revision (file rev)                      OK
 104 ;; - check-headers ()                              COULD BE SUPPORTED
 105 ;; - clear-headers ()                              NOT NEEDED
 106 ;; - delete-file (file)                            OK
 107 ;; - rename-file (old new)                         OK
 108 ;; - find-file-hook ()                             NOT NEEDED
 109 ;; - find-file-not-found-hook ()                   NOT NEEDED
 110
 111 (eval-when-compile (require 'cl) (require 'vc))
 112
 113 (defvar git-commits-coding-system 'utf-8
 114   "Default coding system for git commits.")
 115
 116 ;;; BACKEND PROPERTIES
 117
 118 (defun vc-git-revision-granularity ()
 119   'repository)
 120
 121 ;;; STATE-QUERYING FUNCTIONS
 122
 123 ;;;###autoload (defun vc-git-registered (file)
 124 ;;;###autoload   "Return non-nil if FILE is registered with git."
 125 ;;;###autoload   (if (vc-find-root file ".git")       ; short cut
 126 ;;;###autoload       (progn
 127 ;;;###autoload         (load "vc-git")
 128 ;;;###autoload         (vc-git-registered file))))
 129
 130 (defun vc-git-registered (file)
 131   "Check whether FILE is registered with git."
 132   (when (vc-git-root file)
 133     (with-temp-buffer
 134       (let* ((dir (file-name-directory file))
 135              (name (file-relative-name file dir)))
 136         (and (ignore-errors
 137                (when dir (cd dir))
 138                (vc-git--out-ok "ls-files" "-c" "-z" "--" name))
 139              (let ((str (buffer-string)))
 140                (and (> (length str) (length name))
 141                     (string= (substring str 0 (1+ (length name)))
 142                              (concat name "\0")))))))))
 143
 144 (defun vc-git-state (file)
 145   "Git-specific version of `vc-state'."
 146   ;; FIXME: This can't set 'ignored yet
 147   (vc-git--call nil "add" "--refresh" "--" (file-relative-name file))
 148   (let ((diff (vc-git--run-command-string file "diff-index" "-z" "HEAD" "--")))
 149     (if (and diff (string-match ":[0-7]\\{6\\} [0-7]\\{6\\} [0-9a-f]\\{40\\} [0-9a-f]\\{40\\} \\([ADMU]\\)\0[^\0]+\0"
 150                                 diff))
 151         (if (string= (match-string 1 diff) "A") 'added 'edited)
 152       'up-to-date)))
 153
 154 (defun vc-git--ls-files-state (state &rest args)
 155   "Set state to STATE on all files found with git-ls-files ARGS."
 156   (with-temp-buffer
 157     (apply 'vc-git-command (current-buffer) nil nil "ls-files" "-z" args)
 158     (goto-char (point-min))
 159     (let ((start (point)))
 160       (while (search-forward "\0" nil t)
 161         (let ((file (expand-file-name
 162                      (buffer-substring-no-properties start (1- (point))))))
 163           (vc-file-setprop file 'vc-backend (if state 'Git 'none))
 164           (vc-file-setprop file 'vc-state state))
 165         (setq start (point))))))
 166
 167 (defun vc-git-dir-state (dir)
 168   "Git-specific version of `dir-state'."
 169   (vc-git--ls-files-state 'up-to-date "-c")
 170   (vc-git--ls-files-state 'edited "-m")
 171   (vc-git--ls-files-state 'removed "-d")
 172   (vc-git--ls-files-state 'ignored "-o" "-i" "--exclude-standard")
 173   (vc-git--ls-files-state nil "-o" "--exclude-standard"))
 174
 175 (defun vc-git-working-revision (file)
 176   "Git-specific version of `vc-working-revision'."
 177   (let ((str (with-output-to-string
 178                (with-current-buffer standard-output
 179                  (vc-git--out-ok "symbolic-ref" "HEAD")))))
 180     (if (string-match "^\\(refs/heads/\\)?\\(.+\\)$" str)
 181         (match-string 2 str)
 182       str)))
 183
 184 (defun vc-git-checkout-model (file)
 185   'implicit)
 186
 187 (defun vc-git-workfile-unchanged-p (file)
 188   (eq 'up-to-date (vc-git-state file)))
 189
 190 (defun vc-git-mode-line-string (file)
 191   "Return string for placement into the modeline for FILE."
 192   (let* ((branch (vc-git-working-revision file))
 193          (def-ml (vc-default-mode-line-string 'Git file))
 194          (help-echo (get-text-property 0 'help-echo def-ml)))
 195     (if (zerop (length branch))
 196         (propertize
 197          (concat def-ml "!")
 198          'help-echo (concat help-echo "\nNo current branch (detached HEAD)"))
 199       (propertize def-ml
 200                   'help-echo (concat help-echo "\nCurrent branch: " branch)))))
 201
 202 (defun vc-git-dired-state-info (file)
 203   "Git-specific version of `vc-dired-state-info'."
 204   (let ((git-state (vc-state file)))
 205     (if (eq git-state 'edited)
 206         "(modified)"
 207       ;; fall back to the default VC representation
 208       (vc-default-dired-state-info 'Git file))))
 209
 210 (defun vc-git-dir-status (dir update-function status-buffer)
 211   "Return a list of conses (file . state) for DIR."
 212   ;; Further things that would have to be fixed later:
 213   ;; - support for an empty repository (with no initial commit)
 214   ;; - how to handle unregistered directories
 215   ;; - how to support vc-status on a subdir of the project tree
 216   (with-current-buffer
 217       (get-buffer-create
 218        (expand-file-name " *VC-Git* tmp status" dir))
 219     (cd dir)
 220     (let (result)
 221       (erase-buffer)
 222       (vc-git-command (current-buffer) 0 nil "diff-index" "-z" "HEAD")
 223       (goto-char (point-min))
 224       (while (re-search-forward
 225               ":[0-7]\\{6\\} [0-7]\\{6\\} [0-9a-f]\\{40\\} [0-9a-f]\\{40\\} \\([ADMUT]\\)\0\\([^\0]+\\)\0"
 226               nil t 1)
 227         (let ((filename (match-string 2))
 228               (status (case (string-to-char( match-string 1))
 229                         (?M 'edited)
 230                         (?A 'added)
 231                         (?D 'removed)
 232                         (?U 'edited)    ;; FIXME
 233                         (?T 'edited)))) ;; FIXME
 234           (push (cons filename status) result)))
 235       (erase-buffer)
 236       (vc-git-command (current-buffer) 0 nil "ls-files" "-z" "-o"
 237                       "--directory" "--no-empty-directory" "--exclude-standard")
 238       (goto-char (point-min))
 239       (while (re-search-forward "\\([^\0]*?\\)\0" nil t 1)
 240         (push (cons (match-string 1) 'unregistered) result))
 241       (funcall update-function (nreverse result) status-buffer))
 242     (current-buffer)))
 243
 244 ;;; STATE-CHANGING FUNCTIONS
 245
 246 (defun vc-git-create-repo ()
 247   "Create a new Git repository."
 248   (vc-git-command nil 0 nil "init"))
 249
 250 (defun vc-git-register (files &optional rev comment)
 251   "Register FILE into the git version-control system."
 252   (vc-git-command nil 0 files "update-index" "--add" "--"))
 253
 254 (defalias 'vc-git-responsible-p 'vc-git-root)
 255
 256 (defun vc-git-unregister (file)
 257   (vc-git-command nil 0 file "rm" "-f" "--cached" "--"))
 258
 259
 260 (defun vc-git-checkin (files rev comment)
 261   (let ((coding-system-for-write git-commits-coding-system))
 262     (vc-git-command nil 0 files "commit" "-m" comment "--only" "--")))
 263
 264 (defun vc-git-find-revision (file rev buffer)
 265   (let ((coding-system-for-read 'binary)
 266         (coding-system-for-write 'binary)
 267         (fullname (substring
 268                    (vc-git--run-command-string
 269                     file "ls-files" "-z" "--full-name" "--")
 270                    0 -1)))
 271     (vc-git-command
 272      buffer 0
 273      (concat (if rev rev "HEAD") ":" fullname) "cat-file" "blob")))
 274
 275 (defun vc-git-checkout (file &optional editable rev)
 276   (vc-git-command nil 0 file "checkout" (or rev "HEAD")))
 277
 278 (defun vc-git-revert (file &optional contents-done)
 279   "Revert FILE to the version stored in the git repository."
 280   (if contents-done
 281       (vc-git-command nil 0 file "update-index" "--")
 282     (vc-git-command nil 0 file "checkout" "HEAD")))
 283
 284 ;;; HISTORY FUNCTIONS
 285
 286 (defun vc-git-print-log (files &optional buffer)
 287   "Get change log associated with FILES."
 288   (let ((coding-system-for-read git-commits-coding-system)
 289         ;; Support both the old print-log interface that passes a
 290         ;; single file, and the new one that passes a file list.
 291         (flist (if (listp files) files (list files))))
 292     ;; `vc-do-command' creates the buffer, but we need it before running
 293     ;; the command.
 294     (vc-setup-buffer buffer)
 295     ;; If the buffer exists from a previous invocation it might be
 296     ;; read-only.
 297     (let ((inhibit-read-only t))
 298       ;; XXX `log-view-mode' needs to have something to identify where
 299       ;; the log for each individual file starts. It seems that by
 300       ;; default git does not output this info. So loop here and call
 301       ;; "git rev-list" on each file separately to make sure that each
 302       ;; file gets a "File:" header before the corresponding
 303       ;; log. Maybe there is a way to do this with one command...
 304       (dolist (file flist)
 305         (with-current-buffer
 306             buffer
 307           (insert "File: " (file-name-nondirectory file) "\n"))
 308         (vc-git-command buffer 'async (file-relative-name file)
 309                         "rev-list" "--pretty" "HEAD" "--")))))
 310
 311 (defvar log-view-message-re)
 312 (defvar log-view-file-re)
 313 (defvar log-view-font-lock-keywords)
 314
 315 (define-derived-mode vc-git-log-view-mode log-view-mode "Git-Log-View"
 316   (require 'add-log) ;; we need the faces add-log
 317   ;; Don't have file markers, so use impossible regexp.
 318   (set (make-local-variable 'log-view-file-re) "^File:[ \t]+\\(.+\\)")
 319   (set (make-local-variable 'log-view-message-re)
 320        "^commit *\\([0-9a-z]+\\)")
 321   (set (make-local-variable 'log-view-font-lock-keywords)
 322        (append
 323         `((,log-view-message-re  (1 'change-log-acknowledgement))
 324           (,log-view-file-re (1 'change-log-file-face)))
 325         ;; Handle the case:
 326         ;; user: foo@bar
 327         '(("^Author:[ \t]+\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)"
 328            (1 'change-log-email))
 329           ;; Handle the case:
 330           ;; user: FirstName LastName <foo@bar>
 331           ("^Author:[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
 332            (1 'change-log-name)
 333            (2 'change-log-email))
 334           ("^ +\\(?:\\(?:[Aa]cked\\|[Ss]igned-[Oo]ff\\)-[Bb]y:\\)[ \t]+\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)"
 335            (1 'change-log-name))
 336           ("^ +\\(?:\\(?:[Aa]cked\\|[Ss]igned-[Oo]ff\\)-[Bb]y:\\)[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
 337            (1 'change-log-name)
 338            (2 'change-log-email))
 339           ("^Merge: \\([0-9a-z]+\\) \\([0-9a-z]+\\)"
 340            (1 'change-log-acknowledgement)
 341            (2 'change-log-acknowledgement))
 342           ("^Date:   \\(.+\\)" (1 'change-log-date))
 343           ("^summary:[ \t]+\\(.+\\)" (1 'log-view-message))))))
 344
 345 (defun vc-git-show-log-entry (revision)
 346   "Move to the log entry for REVISION.
 347 REVISION may have the form BRANCH, BRANCH~N,
 348 or BRANCH^ (where \"^\" can be repeated)."
 349   (goto-char (point-min))
 350   (search-forward "\ncommit" nil t
 351                   (cond ((string-match "~\\([0-9]\\)$" revision)
 352                          (1+ (string-to-number (match-string 1 revision))))
 353                         ((string-match "\\^+$" revision)
 354                          (1+ (length (match-string 0 revision))))
 355                         (t nil)))
 356   (beginning-of-line))
 357
 358 (defun vc-git-diff (files &optional rev1 rev2 buffer)
 359   (let ((buf (or buffer "*vc-diff*")))
 360     (if (and rev1 rev2)
 361         (vc-git-command buf 1 files "diff-tree" "--exit-code" "-p"
 362                         rev1 rev2 "--")
 363       (vc-git-command buf 1 files "diff-index" "--exit-code" "-p"
 364                       (or rev1 "HEAD") "--"))))
 365
 366 (defun vc-git-revision-table (files)
 367   ;; What about `files'?!?  --Stef
 368   (let ((table (list "HEAD")))
 369     (with-temp-buffer
 370       (vc-git-command t nil nil "for-each-ref" "--format=%(refname)")
 371       (goto-char (point-min))
 372       (while (re-search-forward "^refs/\\(heads\\|tags\\)/\\(.*\\)$" nil t)
 373         (push (match-string 2) table)))
 374     table))
 375
 376 (defun vc-git-revision-completion-table (files)
 377   (lexical-let ((files files)
 378                 table)
 379     (setq table (lazy-completion-table
 380                  table (lambda () (vc-git-revision-table files))))
 381     table))
 382
 383 (defun vc-git-annotate-command (file buf &optional rev)
 384   ;; FIXME: rev is ignored
 385   (let ((name (file-relative-name file)))
 386     (vc-git-command buf 0 name "blame" (if rev (concat "-r" rev)))))
 387
 388 (defun vc-git-annotate-time ()
 389   (and (re-search-forward "[0-9a-f]+[^()]+(.* \\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\) \\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\) \\([-+0-9]+\\) +[0-9]+) " nil t)
 390        (vc-annotate-convert-time
 391         (apply #'encode-time (mapcar (lambda (match)
 392                                        (string-to-number (match-string match)))
 393                                      '(6 5 4 3 2 1 7))))))
 394
 395 (defun vc-git-annotate-extract-revision-at-line ()
 396   (save-excursion
 397     (move-beginning-of-line 1)
 398     (and (looking-at "[0-9a-f]+")
 399          (buffer-substring-no-properties (match-beginning 0) (match-end 0)))))
 400
 401 ;;; SNAPSHOT SYSTEM
 402
 403 (defun vc-git-create-snapshot (dir name branchp)
 404   (let ((default-directory dir))
 405     (and (vc-git-command nil 0 nil "update-index" "--refresh")
 406          (if branchp
 407              (vc-git-command nil 0 nil "checkout" "-b" name)
 408            (vc-git-command nil 0 nil "tag" name)))))
 409
 410 (defun vc-git-retrieve-snapshot (dir name update)
 411   (let ((default-directory dir))
 412     (vc-git-command nil 0 nil "checkout" name)
 413     ;; FIXME: update buffers if `update' is true
 414     ))
 415
 416
 417 ;;; MISCELLANEOUS
 418
 419 (defun vc-git-previous-revision (file rev)
 420   "Git-specific version of `vc-previous-revision'."
 421   (let ((default-directory (file-name-directory (expand-file-name file)))
 422         (file (file-name-nondirectory file)))
 423     (vc-git-symbolic-commit
 424      (with-temp-buffer
 425        (and
 426         (vc-git--out-ok "rev-list" "-2" rev "--" file)
 427         (goto-char (point-max))
 428         (bolp)
 429         (zerop (forward-line -1))
 430         (not (bobp))
 431         (buffer-substring-no-properties
 432          (point)
 433          (1- (point-max))))))))
 434
 435 (defun vc-git-next-revision (file rev)
 436   "Git-specific version of `vc-next-revision'."
 437   (let* ((default-directory (file-name-directory
 438                              (expand-file-name file)))
 439          (file (file-name-nondirectory file))
 440          (current-rev
 441           (with-temp-buffer
 442             (and
 443              (vc-git--out-ok "rev-list" "-1" rev "--" file)
 444              (goto-char (point-max))
 445              (bolp)
 446              (zerop (forward-line -1))
 447              (bobp)
 448              (buffer-substring-no-properties
 449               (point)
 450               (1- (point-max)))))))
 451     (and current-rev
 452          (vc-git-symbolic-commit
 453           (with-temp-buffer
 454             (and
 455              (vc-git--out-ok "rev-list" "HEAD" "--" file)
 456              (goto-char (point-min))
 457              (search-forward current-rev nil t)
 458              (zerop (forward-line -1))
 459              (buffer-substring-no-properties
 460               (point)
 461               (progn (forward-line 1) (1- (point))))))))))
 462
 463 (defun vc-git-delete-file (file)
 464   (vc-git-command nil 0 file "rm" "-f" "--"))
 465
 466 (defun vc-git-rename-file (old new)
 467   (vc-git-command nil 0 (list old new) "mv" "-f" "--"))
 468
 469 \f
 470 ;;; Internal commands
 471
 472 (defun vc-git-root (file)
 473   (vc-find-root file ".git"))
 474
 475 (defun vc-git-command (buffer okstatus file-or-list &rest flags)
 476   "A wrapper around `vc-do-command' for use in vc-git.el.
 477 The difference to vc-do-command is that this function always invokes `git'."
 478   (apply 'vc-do-command buffer okstatus "git" file-or-list flags))
 479
 480 (defun vc-git--call (buffer command &rest args)
 481   ;; We don't need to care the arguments.  If there is a file name, it
 482   ;; is always a relative one.  This works also for remote
 483   ;; directories.
 484   (apply 'process-file "git" nil buffer nil command args))
 485
 486 (defun vc-git--out-ok (command &rest args)
 487   (zerop (apply 'vc-git--call '(t nil) command args)))
 488
 489 (defun vc-git--run-command-string (file &rest args)
 490   "Run a git command on FILE and return its output as string."
 491   (let* ((ok t)
 492          (str (with-output-to-string
 493                 (with-current-buffer standard-output
 494                   (unless (apply 'vc-git--out-ok
 495                                  (append args (list (file-relative-name
 496                                                      file))))
 497                     (setq ok nil))))))
 498     (and ok str)))
 499
 500 (defun vc-git-symbolic-commit (commit)
 501   "Translate COMMIT string into symbolic form.
 502 Returns nil if not possible."
 503   (and commit
 504        (with-temp-buffer
 505          (and
 506           (vc-git--out-ok "name-rev" "--name-only" "--tags" commit)
 507           (goto-char (point-min))
 508           (= (forward-line 2) 1)
 509           (bolp)
 510           (buffer-substring-no-properties (point-min) (1- (point-max)))))))
 511
 512 (provide 'vc-git)
 513
 514 ;; arch-tag: bd10664a-0e5b-48f5-a877-6c17b135be12
 515 ;;; vc-git.el ends here