code.delx.au - gnu-emacs/blob - lisp/international/mule-util.el

   1 ;;; mule-util.el --- Utility functions for mulitilingual environment (mule)
   2
   3 ;; Copyright (C) 1995 Electrotechnical Laboratory, JAPAN.
   4 ;; Licensed to the Free Software Foundation.
   5
   6 ;; Keywords: mule, multilingual
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Code:
  26
  27 ;;; String manipulations while paying attention to multibyte
  28 ;;; characters.
  29
  30 ;;;###autoload
  31 (defun string-to-sequence (string type)
  32   "Convert STRING to a sequence of TYPE which contains characters in STRING.
  33 TYPE should be `list' or `vector'."
  34   (let ((len (length string))
  35         (i 0)
  36         val)
  37     (cond ((eq type 'list)
  38            (setq val (make-list len 0))
  39            (let ((l val))
  40              (while (< i len)
  41                (setcar l (aref string i))
  42                (setq l (cdr l) i (1+ i)))))
  43           ((eq type 'vector)
  44            (setq val (make-vector len 0))
  45            (while (< i len)
  46              (aset val i (aref string i))
  47              (setq i (1+ i))))
  48           (t
  49            (error "Invalid type: %s" type)))
  50     val))
  51
  52 ;;;###autoload
  53 (defsubst string-to-list (string)
  54   "Return a list of characters in STRING."
  55   (string-to-sequence string 'list))
  56
  57 ;;;###autoload
  58 (defsubst string-to-vector (string)
  59   "Return a vector of characters in STRING."
  60   (string-to-sequence string 'vector))
  61
  62 ;;;###autoload
  63 (defun store-substring (string idx obj)
  64   "Embed OBJ (string or character) at index IDX of STRING."
  65   (if (integerp obj)
  66       (aset string idx obj)
  67     (let ((len1 (length obj))
  68           (len2 (length string))
  69           (i 0))
  70       (while (< i len1)
  71         (aset string (+ idx i) (aref obj i))
  72         (setq i (1+ i)))))
  73   string)
  74
  75 ;;;###autoload
  76 (defun truncate-string-to-width (str end-column &optional start-column padding)
  77   "Truncate string STR to end at column END-COLUMN.
  78 The optional 2nd arg START-COLUMN, if non-nil, specifies
  79 the starting column; that means to return the characters occupying
  80 columns START-COLUMN ... END-COLUMN of STR.
  81
  82 The optional 3rd arg PADDING, if non-nil, specifies a padding character
  83 to add at the end of the result if STR doesn't reach column END-COLUMN,
  84 or if END-COLUMN comes in the middle of a character in STR.
  85 PADDING is also added at the beginning of the result
  86 if column START-COLUMN appears in the middle of a character in STR.
  87
  88 If PADDING is nil, no padding is added in these cases, so
  89 the resulting string may be narrower than END-COLUMN."
  90   (or start-column
  91       (setq start-column 0))
  92   (let ((len (length str))
  93         (idx 0)
  94         (column 0)
  95         (head-padding "") (tail-padding "")
  96         ch last-column last-idx from-idx)
  97     (condition-case nil
  98         (while (< column start-column)
  99           (setq ch (aref str idx)
 100                 column (+ column (char-width ch))
 101                 idx (1+ idx)))
 102       (args-out-of-range (setq idx len)))
 103     (if (< column start-column)
 104         (if padding (make-string end-column padding) "")
 105       (if (and padding (> column start-column))
 106           (setq head-padding (make-string (- column start-column) padding)))
 107       (setq from-idx idx)
 108       (if (< end-column column)
 109           (setq idx from-idx)
 110         (condition-case nil
 111             (while (< column end-column)
 112               (setq last-column column
 113                     last-idx idx
 114                     ch (aref str idx)
 115                     column (+ column (char-width ch))
 116                     idx (1+ idx)))
 117           (args-out-of-range (setq idx len)))
 118         (if (> column end-column)
 119             (setq column last-column idx last-idx))
 120         (if (and padding (< column end-column))
 121             (setq tail-padding (make-string (- end-column column) padding))))
 122       (setq str (substring str from-idx idx))
 123       (if padding
 124           (concat head-padding str tail-padding)
 125         str))))
 126
 127 ;;; For backward compatibility ...
 128 ;;;###autoload
 129 (defalias 'truncate-string 'truncate-string-to-width)
 130 (make-obsolete 'truncate-string 'truncate-string-to-width)
 131 \f
 132 ;;; Nested alist handler.  Nested alist is alist whose elements are
 133 ;;; also nested alist.
 134
 135 ;;;###autoload
 136 (defsubst nested-alist-p (obj)
 137   "Return t if OBJ is a nested alist.
 138
 139 Nested alist is a list of the form (ENTRY . BRANCHES), where ENTRY is
 140 any Lisp object, and BRANCHES is a list of cons cells of the form
 141 (KEY-ELEMENT . NESTED-ALIST).
 142
 143 You can use a nested alist to store any Lisp object (ENTRY) for a key
 144 sequence KEYSEQ, where KEYSEQ is a sequence of KEY-ELEMENT.  KEYSEQ
 145 can be a string, a vector, or a list."
 146   (and obj (listp obj) (listp (cdr obj))))
 147
 148 ;;;###autoload
 149 (defun set-nested-alist (keyseq entry alist &optional len branches)
 150   "Set ENTRY for KEYSEQ in a nested alist ALIST.
 151 Optional 4th arg LEN non-nil means the first LEN elements in KEYSEQ
 152  is considered.
 153 Optional argument BRANCHES if non-nil is branches for a keyseq
 154 longer than KEYSEQ.
 155 See the documentation of `nested-alist-p' for more detail."
 156   (or (nested-alist-p alist)
 157       (error "Invalid argument %s" alist))
 158   (let ((islist (listp keyseq))
 159         (len (or len (length keyseq)))
 160         (i 0)
 161         key-elt slot)
 162     (while (< i len)
 163       (if (null (nested-alist-p alist))
 164           (error "Keyseq %s is too long for this nested alist" keyseq))
 165       (setq key-elt (if islist (nth i keyseq) (aref keyseq i)))
 166       (setq slot (assoc key-elt (cdr alist)))
 167       (if (null slot)
 168           (progn
 169             (setq slot (cons key-elt (list t)))
 170             (setcdr alist (cons slot (cdr alist)))))
 171       (setq alist (cdr slot))
 172       (setq i (1+ i)))
 173     (setcar alist entry)
 174     (if branches
 175         (if (cdr alist)
 176             (error "Can't set branches for keyseq %s" keyseq)
 177           (setcdr alist branches)))))
 178
 179 ;;;###autoload
 180 (defun lookup-nested-alist (keyseq alist &optional len start nil-for-too-long)
 181   "Look up key sequence KEYSEQ in nested alist ALIST.  Return the definition.
 182 Optional 1st argument LEN specifies the length of KEYSEQ.
 183 Optional 2nd argument START specifies index of the starting key.
 184 The returned value is normally a nested alist of which
 185 car part is the entry for KEYSEQ.
 186 If ALIST is not deep enough for KEYSEQ, return number which is
 187  how many key elements at the front of KEYSEQ it takes
 188  to reach a leaf in ALIST.
 189 Optional 3rd argument NIL-FOR-TOO-LONG non-nil means return nil
 190  even if ALIST is not deep enough."
 191   (or (nested-alist-p alist)
 192       (error "invalid argument %s" alist))
 193   (or len
 194       (setq len (length keyseq)))
 195   (let ((i (or start 0)))
 196     (if (catch 'lookup-nested-alist-tag
 197           (if (listp keyseq)
 198               (while (< i len)
 199                 (if (setq alist (cdr (assoc (nth i keyseq) (cdr alist))))
 200                     (setq i (1+ i))
 201                   (throw 'lookup-nested-alist-tag t))))
 202           (while (< i len)
 203             (if (setq alist (cdr (assoc (aref keyseq i) (cdr alist))))
 204                 (setq i (1+ i))
 205               (throw 'lookup-nested-alist-tag t))))
 206         ;; KEYSEQ is too long.
 207         (if nil-for-too-long nil i)
 208       alist)))
 209
 210 \f
 211 ;; Coding system related functions.
 212
 213 ;;;###autoload
 214 (defun coding-system-eol-type-mnemonic (coding-system)
 215   "Return mnemonic letter of eol-type of CODING-SYSTEM."
 216   (let ((eol-type (coding-system-eol-type coding-system)))
 217     (cond ((vectorp eol-type) eol-mnemonic-undecided)
 218           ((eq eol-type 0) eol-mnemonic-unix)
 219           ((eq eol-type 1) eol-mnemonic-dos)
 220           ((eq eol-type 2) eol-mnemonic-mac)
 221           (t ?-))))
 222
 223 ;;;###autoload
 224 (defun coding-system-post-read-conversion (coding-system)
 225   "Return the value of CODING-SYSTEM's post-read-conversion property."
 226   (coding-system-get coding-system 'post-read-conversion))
 227
 228 ;;;###autoload
 229 (defun coding-system-pre-write-conversion (coding-system)
 230   "Return the value of CODING-SYSTEM's pre-write-conversion property."
 231   (coding-system-get coding-system 'pre-write-conversion))
 232
 233 ;;;###autoload
 234 (defun coding-system-translation-table-for-decode (coding-system)
 235   "Return the value of CODING-SYSTEM's translation-table-for-decode property."
 236   (coding-system-get coding-system 'translation-table-for-decode))
 237
 238 ;;;###autoload
 239 (defun coding-system-translation-table-for-encode (coding-system)
 240   "Return the value of CODING-SYSTEM's translation-table-for-encode property."
 241   (coding-system-get coding-system 'translation-table-for-encode))
 242
 243 ;;;###autoload
 244 (defun coding-system-list (&optional base-only)
 245   "Return a list of all existing coding systems.
 246 If optional arg BASE-ONLY is non-nil, only base coding systems are listed."
 247   (let* ((codings (copy-sequence coding-system-list))
 248          (tail (cons nil codings)))
 249     ;; Remove subsidiary coding systems (eol variants) and alias
 250     ;; coding systems (if necessary).
 251     (while (cdr tail)
 252       (let* ((coding (car (cdr tail)))
 253              (aliases (coding-system-get coding 'alias-coding-systems)))
 254         (if (or
 255              ;; CODING is an eol variant if not in ALIASES.
 256              (not (memq coding aliases))
 257              ;; CODING is an alias if it is not car of ALIASES.
 258              (and base-only (not (eq coding (car aliases)))))
 259             (setcdr tail (cdr (cdr tail)))
 260           (setq tail (cdr tail)))))
 261     codings))
 262
 263 ;;;###autoload
 264 (defun coding-system-equal (coding-system-1 coding-system-2)
 265   "Return t if and only if CODING-SYSTEM-1 and CODING-SYSTEM-2 are identical.
 266 Two coding systems are identical if two symbols are equal
 267 or one is an alias of the other."
 268   (or (eq coding-system-1 coding-system-2)
 269       (and (equal (coding-system-spec coding-system-1)
 270                   (coding-system-spec coding-system-2))
 271            (let ((eol-type-1 (coding-system-eol-type coding-system-1))
 272                  (eol-type-2 (coding-system-eol-type coding-system-2)))
 273              (or (eq eol-type-1 eol-type-2)
 274                  (and (vectorp eol-type-1) (vectorp eol-type-2)))))))
 275
 276 ;;;###autoload
 277 (defmacro detect-coding-with-priority (from to priority-list)
 278   "Detect a coding system of the text between FROM and TO with PRIORITY-LIST.
 279 PRIORITY-LIST is an alist of coding categories vs the corresponding
 280 coding systems ordered by priority."
 281   `(let* ((prio-list ,priority-list)
 282           (coding-category-list coding-category-list)
 283           ,@(mapcar (function (lambda (x) (list x x))) coding-category-list))
 284      (mapcar (function (lambda (x) (set (car x) (cdr x))))
 285              prio-list)
 286      (set-coding-priority (mapcar (function (lambda (x) (car x))) prio-list))
 287      (detect-coding-region ,from ,to)))
 288
 289 ;;;###autoload
 290 (defun detect-coding-with-language-environment (from to lang-env)
 291   "Detect a coding system of the text between FROM and TO with LANG-ENV.
 292 The detection takes into account the coding system priorities for the
 293 language environment LANG-ENV."
 294   (let ((coding-priority (get-language-info lang-env 'coding-priority)))
 295     (if coding-priority
 296         (detect-coding-with-priority
 297          from to
 298          (mapcar (function (lambda (x)
 299                              (cons (coding-system-get x 'coding-category) x)))
 300                  coding-priority))
 301       (detect-coding-region from to))))
 302
 303 \f
 304 ;;; Composite character manipulations.
 305
 306 ;;;###autoload
 307 (defun compose-region (start end)
 308   "Compose all characters in the current region into one composite character.
 309 When called from a program, expects two arguments,
 310 positions (integers or markers) specifying the region."
 311   (interactive "r")
 312   (save-excursion
 313     (let ((str (buffer-substring start end)))
 314       (goto-char start)
 315       (insert (compose-string str))
 316       (delete-char (- end start)))))
 317
 318 ;;;###autoload
 319 (defun decompose-region (start end)
 320   "Decompose all composite characters in the current region.
 321 Composite characters are broken up into individual components.
 322 When called from a program, expects two arguments,
 323 positions (integers or markers) specifying the region."
 324   (interactive "r")
 325   (let ((buf (current-buffer))
 326         (cmpchar-head (char-to-string leading-code-composition)))
 327     (with-temp-buffer
 328       (insert-buffer-substring buf start end)
 329       (set-buffer-multibyte nil)
 330       (goto-char (point-min))
 331       (while (search-forward cmpchar-head nil t)
 332         (if (looking-at "[\240-\377][\240-\377][\240-\377][\240-\377]+")
 333             (let* ((from (1- (point)))
 334                    (to (match-end 0))
 335                    (str (string-as-multibyte (buffer-substring from to))))
 336               (if (cmpcharp (string-to-char str))
 337                   (progn
 338                     (delete-region from to)
 339                     (insert (string-as-unibyte (decompose-string str))))
 340                 (goto-char to)))))
 341       (set-buffer-multibyte t)
 342       (let ((tempbuf (current-buffer)))
 343         (save-excursion
 344           (set-buffer buf)
 345           (goto-char start)
 346           (delete-region start end)
 347           (insert-buffer tempbuf))))))
 348
 349 ;;;###autoload
 350 (defun decompose-string (string)
 351   "Decompose all composite characters in STRING."
 352   (let ((len (length string))
 353         (idx 0)
 354         (i 0)
 355         (str-list nil)
 356         ch)
 357     (while (< idx len)
 358       (setq ch (aref string idx))
 359       (if (>= ch min-composite-char)
 360           (progn
 361             (if (> idx i)
 362                 (setq str-list (cons (substring string i idx) str-list)))
 363             (setq str-list (cons (decompose-composite-char ch) str-list))
 364             (setq i (1+ idx))))
 365       (setq idx (1+ idx)))
 366     (if (not str-list)
 367         (copy-sequence string)
 368       (if (> idx i)
 369           (setq str-list (cons (substring string i idx) str-list)))
 370       (apply 'concat (nreverse str-list)))))
 371
 372 ;;;###autoload
 373 (defconst reference-point-alist
 374   '((tl . 0) (tc . 1) (tr . 2)
 375     (ml . 3) (mc . 4) (mr . 5)
 376     (bl . 6) (bc . 7) (br . 8)
 377     (top-left . 0) (top-center . 1) (top-right . 2)
 378     (mid-left . 3) (mid-center . 4) (mid-right . 5)
 379     (bottom-left . 6) (bottom-center . 7) (bottom-right . 8)
 380     (0 . 0) (1 . 1) (2 . 2)
 381     (3 . 3) (4 . 4) (5 . 5)
 382     (6 . 6) (7 . 7) (8 . 8))
 383   "Alist of reference point symbols vs reference point codes.
 384 A reference point symbol is to be used to specify a composition rule
 385 while making a composite character by the function `compose-chars'
 386 (which see).
 387
 388 Meanings of reference point codes are as follows:
 389
 390     0----1----2 <-- ascent      0:tl or top-left
 391     |         |                 1:tc or top-center
 392     |         |                 2:tr or top-right
 393     |         |                 3:ml or mid-left
 394     |    4 <--+---- center      4:mc or mid-center
 395     |         |                 5:mr or mid-right
 396 --- 3         5 <-- baseline    6:bl or bottom-left
 397     |         |                 7:bc or bottom-center
 398     6----7----8 <-- descent     8:br or bottom-right
 399
 400 Reference point symbols are to be used to specify composition rule of
 401 the form \(GLOBAL-REF-POINT . NEW-REF-POINT), where GLOBAL-REF-POINT
 402 is a reference point in the overall glyphs already composed, and
 403 NEW-REF-POINT is a reference point in the new glyph to be added.
 404
 405 For instance, if GLOBAL-REF-POINT is 8 and NEW-REF-POINT is 1, the
 406 overall glyph is updated as follows:
 407
 408     +-------+--+ <--- new ascent
 409     |       |  |
 410     | global|  |
 411     | glyph |  |
 412 --- |       |  | <--- baseline (doesn't change)
 413     +----+--+--+
 414     |    | new |
 415     |    |glyph|
 416     +----+-----+ <--- new descent
 417 ")
 418
 419 ;; Return a string for char CH to be embedded in multibyte form of
 420 ;; composite character.
 421 ;;;###autoload
 422 (defun compose-chars-component (ch)
 423   (if (< ch 128)
 424       (format "\240%c" (+ ch 128))
 425     (let ((str (string-as-unibyte (char-to-string ch))))
 426       (if (cmpcharp ch)
 427           (if (= (aref str 1) ?\xFF)
 428               (error "Can't compose a rule-based composition character")
 429             (substring str (if (= (aref str 1) ?\xFF) 2 1)))
 430         (aset str 0 (+ (aref str 0) ?\x20))
 431         str))))
 432
 433 ;; Return a string for composition rule RULE to be embedded in
 434 ;; multibyte form of composite character.
 435 (defsubst compose-chars-rule (rule)
 436   (char-to-string (+ ?\xA0
 437                      (* (cdr (assq (car rule) reference-point-alist)) 9)
 438                      (cdr (assq (cdr rule) reference-point-alist)))))
 439
 440 ;;;###autoload
 441 (defun compose-chars (first-component &rest args)
 442   "Return one char string composed from the arguments.
 443 For relative composition, each argument should be a non-composition character
 444 or a relative-composition character.
 445 For rule-based composition, Nth (where N is odd) argument should be
 446 a non-composition character or a rule-based-composition character,
 447 and Mth (where M is even) argument should be a composition rule.
 448 A composition rule has the form \(GLOBAL-REF-POINT . NEW-REF-POINT).
 449 See the documentation of `reference-point-alist' for more detail."
 450   (if (= (length args) 0)
 451       (char-to-string first-component)
 452     (let* ((with-rule (consp (car args)))
 453            (str (if (cmpcharp first-component)
 454                     (string-as-unibyte (char-to-string first-component))
 455                   (if with-rule
 456                       (concat (vector leading-code-composition ?\xFF)
 457                               (compose-chars-component first-component))
 458                     (concat (char-to-string leading-code-composition)
 459                             (compose-chars-component first-component))))))
 460       (if (and (cmpcharp first-component)
 461                (eq with-rule (/= (aref str 1) ?\xFF)))
 462           (error "%s-compostion-character is not allowed in %s composition: %c"
 463                  (if with-rule "relative" "rule-based")
 464                  (if with-rule "rule-based" "relative")
 465                  first-component))
 466       (while args
 467         (if with-rule
 468             (setq str (concat str (compose-chars-rule (car args)))
 469                   args (cdr args)))
 470         (if (cmpcharp (car args))
 471             (let ((cmp-str (string-as-unibyte (char-to-string (car args)))))
 472               (if (eq with-rule (/= (aref cmp-str 1) ?\xFF))
 473                   (error "%s-compostion-character is not allowed in %s composition: %c"
 474                          (if with-rule "relative" "rule-based")
 475                          (if with-rule "rule-based" "relative")
 476                          (car args)))
 477               (setq str (concat str (substring cmp-str
 478                                                (if with-rule 2 1)))))
 479           (setq str (concat str (compose-chars-component (car args)))))
 480         (setq args (cdr args)))
 481       (string-as-multibyte str))))
 482
 483 ;;;###autoload
 484 (defun decompose-composite-char (char &optional type with-composition-rule)
 485   "Convert composite character CHAR to a sequence of the components.
 486 Optional 1st arg TYPE specifies the type of sequence returned.
 487 It should be `string' (default), `list', or `vector'.
 488 Optional 2nd arg WITH-COMPOSITION-RULE non-nil means the returned
 489 sequence contains embedded composition rules if any.  In this case, the
 490 order of elements in the sequence is the same as arguments for
 491 `compose-chars' to create CHAR.
 492 If TYPE is omitted or is `string', composition rules are omitted
 493 even if WITH-COMPOSITION-RULE is t."
 494   (or type
 495       (setq type 'string))
 496   (let* ((len (composite-char-component-count char))
 497          (i (1- len))
 498          l)
 499     (setq with-composition-rule (and with-composition-rule
 500                                     (not (eq type 'string))
 501                                     (composite-char-composition-rule-p char)))
 502     (while (> i 0)
 503       (setq l (cons (composite-char-component char i) l))
 504       (if  with-composition-rule
 505           (let ((rule (- (composite-char-composition-rule char i) ?\xA0)))
 506             (setq l (cons (cons (/ rule 9) (% rule 9)) l))))
 507       (setq i (1- i)))
 508     (setq l (cons (composite-char-component char 0) l))
 509     (cond ((eq type 'string)
 510            (apply 'string l))
 511           ((eq type 'list)
 512            l)
 513           (t                            ; i.e. TYPE is vector
 514            (vconcat l)))))
 515
 516 ;;; mule-util.el ends here