code.delx.au - gnu-emacs/blob - lisp/finder.el

   1 ;;; finder.el --- topic & keyword-based code finder
   2
   3 ;; Copyright (C) 1992 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric S. Raymond <esr@snark.thyrsus.com>
   6 ;; Created: 16 Jun 1992
   7 ;; Version: 1.0
   8 ;; Keywords: help
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 1, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  24 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This mode uses the Keywords library header to provide code-finding
  29 ;; services by keyword.
  30 ;;
  31 ;; Things to do:
  32 ;;    1. Support multiple keywords per search.  This could be extremely hairy;
  33 ;; there doesn't seem to be any way to get completing-read to exit on
  34 ;; an EOL with no substring pending, which is what we'd want to end the loop.
  35 ;;    2. Search by string in synopsis line?
  36 ;;    3. Function to check finder-package-info for unknown keywords.
  37
  38 ;;; Code:
  39
  40 (require 'lisp-mnt)
  41 (require 'finder-inf)
  42 (require 'picture)
  43
  44 ;; Local variable in finder buffer.
  45 (defvar finder-headmark)
  46
  47 (defvar finder-known-keywords
  48   '(
  49     (abbrev     . "abbreviation handling, typing shortcuts, macros")
  50     (bib        . "code related to the bib(1) bibliography processor")
  51     (c          . "C and C++ language support")
  52     (calendar   . "calendar and time management support")
  53     (comm       . "communications, networking, remote access to files")
  54     (docs       . "support for Emacs documentation")
  55     (emulations . "emulations of other editors")
  56     (extensions . "Emacs Lisp language extensions")
  57     (games      . "games, jokes and amusements")
  58     (hardware   . "support for interfacing with exotic hardware")
  59     (help       . "support for on-line help systems")
  60     (i18n       . "internationalization and alternate character-set support")
  61     (internal   . "code for Emacs internals, build process, defaults")
  62     (languages  . "specialized modes for editing programming languages")
  63     (lisp       . "Lisp support, including Emacs Lisp")
  64     (local      . "code local to your site")
  65     (maint      . "maintenance aids for the Emacs development group")
  66     (mail       . "modes for electronic-mail handling")
  67     (news       . "support for netnews reading and posting")
  68     (processes  . "process, subshell, compilation, and job control support")
  69     (terminals  . "support for terminal types")
  70     (tex        . "code related to the TeX formatter")
  71     (tools      . "programming tools")
  72     (unix       . "front-ends/assistants for, or emulators of, UNIX features")
  73     (vms        . "support code for vms")
  74     (wp         . "word processing")
  75     ))
  76
  77 (defvar finder-mode-map nil)
  78 ;(if finder-mode-map
  79 ;    nil
  80   (setq finder-mode-map (make-sparse-keymap))
  81   (define-key finder-mode-map " "       'finder-select)
  82   (define-key finder-mode-map "?"       'finder-summary)
  83   (define-key finder-mode-map "q"       'finder-exit)
  84   (define-key finder-mode-map "f"       'finder-list-keywords)
  85 ;  )
  86
  87 ;;; Code for regenerating the keyword list.
  88
  89 (defvar finder-package-info nil
  90   "Assoc list mapping file names to description & keyword lists.")
  91
  92 (defun finder-compile-keywords (&rest dirs)
  93   "Regenerate the keywords association list into the file `finder-inf.el'.
  94 Optional arguments are a list of Emacs Lisp directories to compile from; no
  95 arguments compiles from `load-path'."
  96   (save-excursion
  97     (let ((processed nil))
  98       (find-file "finder-inf.el")
  99       (erase-buffer)
 100       (insert ";;; finder-inf.el --- keyword-to-package mapping\n")
 101       (insert ";; Keywords: help\n")
 102       (insert ";;; Commentary:\n")
 103       (insert ";; Don't edit this file.  It's generated by finder.el\n\n")
 104       (insert ";;; Code:\n")
 105       (insert "\n(setq finder-package-info '(\n")
 106       (mapcar
 107        (function
 108         (lambda (d)
 109           (mapcar
 110            (function
 111             (lambda (f)
 112               (if (and (string-match "^[^=].*\\.el$" f)
 113                        (not (member f processed)))
 114                   (let (summary keystart keywords)
 115                     (setq processed (cons f processed))
 116                     (save-excursion
 117                       (set-buffer (get-buffer-create "*finder-scratch*"))
 118                       (buffer-disable-undo (current-buffer))
 119                       (erase-buffer)
 120                       (insert-file-contents
 121                        (concat (file-name-as-directory (or d ".")) f))
 122                       (setq summary (lm-synopsis))
 123                       (setq keywords (lm-keywords)))
 124                     (insert
 125                      (format "    (\"%s\"\n        " f))
 126                     (prin1 summary (current-buffer))
 127                     (insert
 128                      "\n        ")
 129                     (setq keystart (point))
 130                     (insert
 131                      (if keywords (format "(%s)" keywords) "nil")
 132                      ")\n")
 133                     (subst-char-in-region keystart (point) ?, ? )
 134                     (let ((end (point)))
 135                       (goto-char keystart)
 136                       (while (search-forward "i14n" end t)
 137                         (replace-match "i18n"))
 138                       (goto-char end)))
 139                 )))
 140            (directory-files (or d ".")))
 141           ))
 142        (or dirs load-path))
 143       (insert "))\n\n(provide 'finder-inf)\n\n;;; finder-inf.el ends here\n")
 144       (kill-buffer "*finder-scratch*")
 145       (eval-current-buffer) ;; So we get the new keyword list immediately
 146       (basic-save-buffer)
 147       )))
 148
 149 ;;; Now the retrieval code
 150
 151 (defun finder-list-keywords ()
 152   "Display descriptions of the keywords in the Finder buffer."
 153   (interactive)
 154   (setq buffer-read-only nil)
 155   (erase-buffer)
 156   (mapcar
 157    (function (lambda (assoc)
 158                (let ((keyword (car assoc)))
 159                  (insert (symbol-name keyword))
 160                  (insert-at-column 14 (concat (cdr assoc) "\n"))
 161                  (cons (symbol-name keyword) keyword))))
 162    finder-known-keywords)
 163   (goto-char (point-min))
 164   (setq finder-headmark (point))
 165   (setq buffer-read-only t)
 166   (set-buffer-modified-p nil)
 167   (balance-windows)
 168   (finder-summary))
 169
 170 (defun finder-list-matches (key)
 171   (setq buffer-read-only nil)
 172   (erase-buffer)
 173   (let ((id (intern key)))
 174     (insert
 175      "The following packages match the keyword `" key "':\n\n")
 176     (setq finder-headmark (point))
 177     (mapcar
 178      (function (lambda (x)
 179                  (if (memq id (car (cdr (cdr x))))
 180                      (progn
 181                        (insert (car x))
 182                        (insert-at-column 16
 183                                          (concat (car (cdr x)) "\n"))
 184                        ))
 185                  ))
 186      finder-package-info)
 187     (goto-char (point-min))
 188     (forward-line)
 189     (setq buffer-read-only t)
 190     (set-buffer-modified-p nil)
 191     (shrink-window-if-larger-than-buffer)
 192     (finder-summary)))
 193
 194 (defun finder-commentary (file)
 195   (interactive)
 196   (let* ((str (lm-commentary file)))
 197     (if (null str)
 198         (error "Can't find any Commentary section."))
 199     (pop-to-buffer "*Finder*")
 200     (setq buffer-read-only nil)
 201     (erase-buffer)
 202     (insert str)
 203     (goto-char (point-min))
 204     (delete-blank-lines)
 205     (goto-char (point-max))
 206     (delete-blank-lines)
 207     (goto-char (point-min))
 208     (while (re-search-forward "^;+ ?" nil t)
 209       (replace-match "" nil nil))
 210     (goto-char (point-min))
 211     (setq buffer-read-only t)
 212     (set-buffer-modified-p nil)
 213     (shrink-window-if-larger-than-buffer)
 214     (finder-summary)
 215     ))
 216
 217 (defun finder-current-item ()
 218   (if (and finder-headmark (< (point) finder-headmark))
 219       (error "No keyword or filename on this line")
 220     (save-excursion
 221       (beginning-of-line)
 222       (current-word))))
 223
 224 (defun finder-select ()
 225   (interactive)
 226   (let ((key (finder-current-item)))
 227     (if (string-match "\\.el$" key)
 228         (finder-commentary key)
 229       (finder-list-matches key))))
 230
 231 (defun finder-by-keyword ()
 232   "Find packages matching a given keyword."
 233   (interactive)
 234   (finder-mode)
 235   (finder-list-keywords))
 236
 237 (defun finder-mode ()
 238   "Major mode for browsing package documentation.
 239 \\<finder-mode-map>
 240 \\[finder-select]       more help for the item on the current line
 241 \\[finder-exit] exit Finder mode and fill the Finder buffer.
 242 "
 243   (interactive)
 244   (pop-to-buffer "*Finder*")
 245   (setq buffer-read-only nil)
 246   (erase-buffer)
 247   (use-local-map finder-mode-map)
 248   (set-syntax-table emacs-lisp-mode-syntax-table)
 249   (setq mode-name "Finder")
 250   (setq major-mode 'finder-mode)
 251   (make-local-variable 'finder-headmark)
 252   (setq finder-headmark nil)
 253 )
 254
 255 (defun finder-summary ()
 256   "Summarize basic Finder commands."
 257   (interactive)
 258   (message
 259    (substitute-command-keys
 260     "\\<finder-mode-map>\\[finder-select] = select, \\[finder-list-keywords] = back to finder, \\[finder-exit] = quit, \\[finder-summary] = help")))
 261
 262 (defun finder-exit ()
 263   "Exit Finder mode and kill the buffer"
 264   (interactive)
 265   (delete-window)
 266   (kill-buffer "*Finder*"))
 267
 268 (provide 'finder)
 269
 270 ;;; finder.el ends here