code.delx.au - gnu-emacs/blob - configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2011  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.0.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28 AM_INIT_AUTOMAKE
  29
  30 dnl Support for --program-prefix, --program-suffix and
  31 dnl --program-transform-name options
  32 AC_ARG_PROGRAM
  33
  34 dnl It is important that variables on the RHS not be expanded here,
  35 dnl hence the single quotes.  This is per the GNU coding standards, see
  36 dnl (autoconf) Installation Directory Variables
  37 dnl See also epaths.h below.
  38 lispdir='${datadir}/emacs/${version}/lisp'
  39 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  40 '${datadir}/emacs/site-lisp'
  41 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  42 etcdir='${datadir}/emacs/${version}/etc'
  43 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  44 docdir='${datadir}/emacs/${version}/etc'
  45 gamedir='${localstatedir}/games/emacs'
  46
  47 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  48 dnl Create a new --with option that defaults to being disabled.
  49 dnl NAME is the base name of the option.  The shell variable with_NAME
  50 dnl   will be set to either the user's value (if the option is
  51 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  52 dnl   option is not specified).  Note that the shell variable name is
  53 dnl   constructed as autoconf does, by replacing non-alphanumeric
  54 dnl   characters with "_".
  55 dnl HELP-STRING is the help text for the option.
  56 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  57   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  58     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  59 ])dnl
  60
  61 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  62 dnl Create a new --with option that defaults to being enabled.  NAME
  63 dnl   is the base name of the option.  The shell variable with_NAME
  64 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  65 dnl   'yes' (if the option is not specified).  Note that the shell
  66 dnl   variable name is constructed as autoconf does, by replacing
  67 dnl   non-alphanumeric characters with "_".
  68 dnl HELP-STRING is the help text for the option.
  69 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  70   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  71    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  72 ])dnl
  73
  74 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  75 if test "$with_pop" = yes; then
  76    AC_DEFINE(MAIL_USE_POP)
  77 fi
  78 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  79
  80 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  81 if test "$with_kerberos" != no; then
  82    AC_DEFINE(KERBEROS)
  83 fi
  84 AH_TEMPLATE(KERBEROS,
  85             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  86
  87 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  88 if test "${with_kerberos5}" != no; then
  89   if test "${with_kerberos}" = no; then
  90     with_kerberos=yes
  91     AC_DEFINE(KERBEROS)
  92   fi
  93   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  94 fi
  95
  96 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  97 dnl FIXME hesiod support may not be present, so it seems like an error
  98 dnl to define, or at least use, this unconditionally.
  99 if test "$with_hesiod" != no; then
 100   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 101 fi
 102
 103 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 104 if test "$with_mmdf" != no; then
 105    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 106 fi
 107
 108 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 109 if test "$with_mail_unlink" != no; then
 110    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 111 fi
 112
 113 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 114     [string giving default POP mail host])],
 115     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 116
 117 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 118
 119 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 120 if test "$with_sync_input" = yes; then
 121    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 122 fi
 123
 124 dnl FIXME currently it is not the last.
 125 dnl This should be the last --with option, because --with-x is
 126 dnl added later on when we find the path of X, and it's best to
 127 dnl keep them together visually.
 128 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 129  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 130 [         case "${withval}" in
 131             y | ye | yes )      val=gtk ;;
 132             n | no )            val=no  ;;
 133             l | lu | luc | luci | lucid )       val=lucid ;;
 134             a | at | ath | athe | athen | athena )      val=athena ;;
 135             m | mo | mot | moti | motif )       val=motif ;;
 136             g | gt | gtk  )     val=gtk ;;
 137             gtk3  )     val=gtk3 ;;
 138             * )
 139 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 140 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 141 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 142             ;;
 143           esac
 144           with_x_toolkit=$val
 145 ])
 146
 147 dnl _ON results in a '--without' option in the --help output, so
 148 dnl the help text should refer to "don't compile", etc.
 149 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 150 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 151 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 152 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 153 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 154 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 155 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 156 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 157
 158 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 159 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 160 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 161
 162 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 163 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 164 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 165 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 166
 167 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 168 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 169 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 170 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 171 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 172
 173 ## For the times when you want to build Emacs but don't have
 174 ## a suitable makeinfo, and can live without the manuals.
 175 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 176 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 177
 178 ## This is an option because I do not know if all info/man support
 179 ## compressed files, nor how to test if they do so.
 180 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 181 if test $with_compress_info = yes; then
 182    GZIP_INFO=yes
 183 else
 184    GZIP_INFO=
 185 fi
 186 AC_SUBST(GZIP_INFO)
 187
 188 AC_ARG_WITH([pkg-config-prog],dnl
 189 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 190                   [path to pkg-config for finding GTK and librsvg])])
 191 if test "X${with_pkg_config_prog}" != X; then
 192    if test "${with_pkg_config_prog}" != yes; then
 193       PKG_CONFIG="${with_pkg_config_prog}"
 194    fi
 195 fi
 196
 197 CRT_DIR=
 198 AC_ARG_WITH([crt-dir],dnl
 199 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 200 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 201 CRT_DIR="${with_crt_dir}"
 202
 203 AC_ARG_WITH(gameuser,dnl
 204 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 205 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 206   && gameuser="${with_gameuser}"
 207 test "X$gameuser" = X && gameuser=games
 208
 209 AC_ARG_WITH([gnustep-conf],dnl
 210 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 211 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 212   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 213 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 214      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 215
 216 AC_ARG_ENABLE(ns-self-contained,
 217 [AS_HELP_STRING([--disable-ns-self-contained],
 218                 [disable self contained build under NeXTstep])],
 219    EN_NS_SELF_CONTAINED=$enableval,
 220    EN_NS_SELF_CONTAINED=yes)
 221
 222 AC_ARG_ENABLE(asserts,
 223 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 224       USE_XASSERTS=$enableval,
 225       USE_XASSERTS=no)
 226
 227 AC_ARG_ENABLE(maintainer-mode,
 228 [AS_HELP_STRING([--enable-maintainer-mode],
 229                 [enable make rules and dependencies not useful (and sometimes
 230                  confusing) to the casual installer])],
 231       USE_MAINTAINER_MODE=$enableval,
 232       USE_MAINTAINER_MODE=no)
 233 if test $USE_MAINTAINER_MODE = yes; then
 234   MAINT=
 235 else
 236   MAINT=#
 237 fi
 238 AC_SUBST(MAINT)
 239
 240 AC_ARG_ENABLE(locallisppath,
 241 [AS_HELP_STRING([--enable-locallisppath=PATH],
 242                 [directories Emacs should search for lisp files specific
 243                  to this site])],
 244 if test "${enableval}" = "no"; then
 245   locallisppath=
 246 elif test "${enableval}" != "yes"; then
 247   locallisppath=${enableval}
 248 fi)
 249
 250 AC_ARG_ENABLE(checking,
 251 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 252                 [enable expensive run-time checks.  With LIST,
 253                  enable only specific categories of checks.
 254                  Categories are: all,yes,no.
 255                  Flags are: stringbytes, stringoverrun, stringfreelist,
 256                  xmallocoverrun, conslist])],
 257 [ac_checking_flags="${enableval}"],[])
 258 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 259 for check in $ac_checking_flags
 260 do
 261         case $check in
 262         # these set all the flags to specific states
 263         yes)            ac_enable_checking=1 ;;
 264         no)             ac_enable_checking= ;
 265                         ac_gc_check_stringbytes= ;
 266                         ac_gc_check_string_overrun= ;
 267                         ac_gc_check_string_free_list= ;
 268                         ac_xmalloc_overrun= ;
 269                         ac_gc_check_cons_list= ;;
 270         all)            ac_enable_checking=1 ;
 271                         ac_gc_check_stringbytes=1 ;
 272                         ac_gc_check_string_overrun=1 ;
 273                         ac_gc_check_string_free_list=1 ;
 274                         ac_xmalloc_overrun=1 ;
 275                         ac_gc_check_cons_list=1 ;;
 276         # these enable particular checks
 277         stringbytes)    ac_gc_check_stringbytes=1 ;;
 278         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 279         stringfreelist) ac_gc_check_string_free_list=1 ;;
 280         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 281         conslist)       ac_gc_check_cons_list=1 ;;
 282         *)      AC_MSG_ERROR(unknown check category $check) ;;
 283         esac
 284 done
 285 IFS="$ac_save_IFS"
 286
 287 if test x$ac_enable_checking != x ; then
 288   AC_DEFINE(ENABLE_CHECKING, 1,
 289 [Enable expensive run-time checking of data types?])
 290 fi
 291 if test x$ac_gc_check_stringbytes != x ; then
 292   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 293 [Define this temporarily to hunt a bug.  If defined, the size of
 294    strings is redundantly recorded in sdata structures so that it can
 295    be compared to the sizes recorded in Lisp strings.])
 296 fi
 297 if test x$ac_gc_check_stringoverrun != x ; then
 298   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 299 [Define this to check for short string overrun.])
 300 fi
 301 if test x$ac_gc_check_string_free_list != x ; then
 302   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 303 [Define this to check the string free list.])
 304 fi
 305 if test x$ac_xmalloc_overrun != x ; then
 306   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 307 [Define this to check for malloc buffer overrun.])
 308 fi
 309 if test x$ac_gc_check_cons_list != x ; then
 310   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 311 [Define this to check for errors in cons list.])
 312 fi
 313
 314 AC_ARG_ENABLE(use-lisp-union-type,
 315 [AS_HELP_STRING([--enable-use-lisp-union-type],
 316                 [use a union for the Lisp_Object data type.
 317                 This is only useful for development for catching certain types of bugs.])],
 318 if test "${enableval}" != "no"; then
 319    AC_DEFINE(USE_LISP_UNION_TYPE, 1,
 320    [Define this to use a lisp union for the Lisp_Object data type.])
 321 fi)
 322
 323
 324 AC_ARG_ENABLE(profiling,
 325 [AS_HELP_STRING([--enable-profiling],
 326                 [build emacs with profiling support.
 327                  This might not work on all platforms])],
 328 [ac_enable_profiling="${enableval}"],[])
 329 if test x$ac_enable_profiling != x ; then
 330    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 331 else
 332    PROFILING_CFLAGS=
 333 fi
 334 AC_SUBST(PROFILING_CFLAGS)
 335
 336 AC_ARG_ENABLE(autodepend,
 337 [AS_HELP_STRING([--enable-autodepend],
 338                 [automatically generate dependencies to .h-files.
 339                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 340                  found])],
 341 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 342
 343 #### Make srcdir absolute, if it isn't already.  It's important to
 344 #### avoid running the path through pwd unnecessarily, since pwd can
 345 #### give you automounter prefixes, which can go away.  We do all this
 346 #### so Emacs can find its files when run uninstalled.
 347 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 348 unset CDPATH
 349 case "${srcdir}" in
 350   /* ) ;;
 351   . )
 352     ## We may be able to use the $PWD environment variable to make this
 353     ## absolute.  But sometimes PWD is inaccurate.
 354     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 355     ## but that tested only for a well-formed and valid PWD,
 356     ## it did not object when PWD was well-formed and valid but just wrong.
 357     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 358     then
 359       srcdir="$PWD"
 360     else
 361       srcdir="`(cd ${srcdir}; pwd)`"
 362     fi
 363   ;;
 364   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 365 esac
 366
 367 #### Check if the source directory already has a configured system in it.
 368 if test `pwd` != `(cd ${srcdir} && pwd)` \
 369    && test -f "${srcdir}/src/config.h" ; then
 370   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 371    as a build directory right now; it has been configured in its own
 372    right.  To configure in another directory as well, you MUST
 373    use GNU make.  If you do not have GNU make, then you must
 374    now do `make distclean' in ${srcdir},
 375    and then run $0 again.]])
 376 fi
 377
 378 #### Given the configuration name, set machfile and opsysfile to the
 379 #### names of the m/*.h and s/*.h files we should use.
 380
 381 ### Canonicalize the configuration name.
 382
 383 AC_CANONICAL_HOST
 384 canonical=$host
 385 configuration=${host_alias-${build_alias-$host}}
 386
 387 dnl This used to use changequote, but, apart from `changequote is evil'
 388 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 389 dnl the great gob of text.  Thus it's not processed for possible expansion.
 390 dnl Just make sure the brackets remain balanced.
 391 dnl
 392 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 393 dnl indicated by comments.
 394 dnl quotation begins
 395 [
 396
 397 ### If you add support for a new configuration, add code to this
 398 ### switch statement to recognize your configuration name and select
 399 ### the appropriate operating system and machine description files.
 400
 401 ### You would hope that you could choose an m/*.h file pretty much
 402 ### based on the machine portion of the configuration name, and an s/*.h
 403 ### file based on the operating system portion.  However, it turns out
 404 ### that each m/*.h file is pretty manufacturer-specific - for
 405 ### example mips.h is MIPS
 406 ### So we basically have to have a special case for each
 407 ### configuration name.
 408 ###
 409 ### As far as handling version numbers on operating systems is
 410 ### concerned, make sure things will fail in a fixable way.  If
 411 ### /etc/MACHINES doesn't say anything about version numbers, be
 412 ### prepared to handle anything reasonably.  If version numbers
 413 ### matter, be sure /etc/MACHINES says something about it.
 414
 415 machine='' opsys='' unported=no
 416 case "${canonical}" in
 417
 418   ## GNU/Linux ports
 419   *-*-linux-gnu*)
 420     opsys=gnu-linux
 421     case ${canonical} in
 422       alpha*)   machine=alpha ;;
 423       s390-*)   machine=ibms390 ;;
 424       s390x-*)  machine=ibms390x ;;
 425       powerpc*) machine=macppc ;;
 426       sparc*)   machine=sparc ;;
 427       ia64*)    machine=ia64 ;;
 428       m68k*)    machine=m68k ;;
 429       x86_64*)  machine=amdx86-64 ;;
 430     esac
 431   ;;
 432
 433   ## FreeBSD ports
 434   *-*-freebsd* )
 435     opsys=freebsd
 436     case "${canonical}" in
 437       alpha*)           machine=alpha ;;
 438       amd64-*|x86_64-*) machine=amdx86-64 ;;
 439       ia64-*)           machine=ia64 ;;
 440       i[3456]86-*)      machine=intel386 ;;
 441       powerpc-*)        machine=macppc ;;
 442       sparc-*)          machine=sparc ;;
 443       sparc64-*)        machine=sparc ;;
 444     esac
 445   ;;
 446
 447   ## FreeBSD kernel + glibc based userland
 448   *-*-kfreebsd*gnu* )
 449     opsys=gnu-kfreebsd
 450     case "${canonical}" in
 451       alpha*)           machine=alpha ;;
 452       amd64-*|x86_64-*) machine=amdx86-64 ;;
 453       ia64-*)           machine=ia64 ;;
 454       i[3456]86-*)      machine=intel386 ;;
 455       powerpc-*)        machine=macppc ;;
 456       sparc-*)          machine=sparc ;;
 457       sparc64-*)        machine=sparc ;;
 458     esac
 459   ;;
 460
 461   ## NetBSD ports
 462   *-*-netbsd* )
 463     opsys=netbsd
 464     case "${canonical}" in
 465       alpha*)      machine=alpha ;;
 466       x86_64-*)    machine=amdx86-64 ;;
 467       i[3456]86-*) machine=intel386 ;;
 468       m68k-*)      machine=m68k ;;
 469       powerpc-*)   machine=macppc ;;
 470       sparc*-)     machine=sparc ;;
 471       vax-*)       machine=vax ;;
 472     esac
 473   ;;
 474
 475   ## OpenBSD ports
 476   *-*-openbsd* )
 477     opsys=openbsd
 478     case "${canonical}" in
 479       alpha*)    machine=alpha ;;
 480       x86_64-*)  machine=amdx86-64 ;;
 481       i386-*)    machine=intel386 ;;
 482       powerpc-*) machine=macppc ;;
 483       sparc*)    machine=sparc ;;
 484       vax-*)     machine=vax ;;
 485     esac
 486   ;;
 487
 488   ## Apple Darwin / Mac OS X
 489   *-apple-darwin* )
 490     case "${canonical}" in
 491       i[3456]86-* )  machine=intel386 ;;
 492       powerpc-* )    machine=macppc ;;
 493       x86_64-* )     machine=amdx86-64 ;;
 494       * )            unported=yes ;;
 495     esac
 496     opsys=darwin
 497     # Define CPP as follows to make autoconf work correctly.
 498     CPP="${CC-cc} -E -no-cpp-precomp"
 499     # Use fink packages if available.
 500     if test -d /sw/include && test -d /sw/lib; then
 501       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 502       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 503       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 504     fi
 505   ;;
 506
 507   ## HP 9000 series 700 and 800, running HP/UX
 508   hppa*-hp-hpux10.2* )
 509     opsys=hpux10-20
 510   ;;
 511   hppa*-hp-hpux1[1-9]* )
 512     opsys=hpux11
 513     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 514   ;;
 515
 516   ia64*-hp-hpux1[1-9]* )
 517     machine=hp800 opsys=hpux11
 518     ## FIXME.  Peter O'Gorman reports that dumping using unexelf.o doesn't
 519     ## work either: http://debbugs.gnu.org/cgi/bugreport.cgi?bug=6811
 520     CANNOT_DUMP=yes
 521   ;;
 522
 523   hppa*-*-linux-gnu* )
 524     machine=hp800 opsys=gnu-linux
 525   ;;
 526
 527   ## IBM machines
 528   rs6000-ibm-aix4.[23]* )
 529     machine=ibmrs6000 opsys=aix4-2
 530   ;;
 531   powerpc-ibm-aix4.[23]*  )
 532     machine=ibmrs6000 opsys=aix4-2
 533   ;;
 534   rs6000-ibm-aix[56]* )
 535     machine=ibmrs6000 opsys=aix4-2
 536   ;;
 537   powerpc-ibm-aix[56]*  )
 538     machine=ibmrs6000 opsys=aix4-2
 539   ;;
 540
 541   ## Silicon Graphics machines
 542   ## Iris 4D
 543   mips-sgi-irix6.5 )
 544     machine=iris4d opsys=irix6-5
 545     # Without defining _LANGUAGE_C, things get masked out in the headers
 546     # so that, for instance, grepping for `free' in stdlib.h fails and
 547     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 548     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 549     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 550   ;;
 551
 552   ## Suns
 553   *-sun-solaris* \
 554     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 555     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 556     case "${canonical}" in
 557       i[3456]86-*-* )     machine=intel386 ;;
 558       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 559       sparc* )          machine=sparc ;;
 560       * )               unported=yes ;;
 561     esac
 562     case "${canonical}" in
 563       *-sunos5.6* | *-solaris2.6* )
 564                 opsys=sol2-6
 565                 NON_GNU_CPP=/usr/ccs/lib/cpp
 566                 RANLIB="ar -ts"
 567                 ;;
 568       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 569                 opsys=sol2-6
 570                 emacs_check_sunpro_c=yes
 571                 NON_GNU_CPP=/usr/ccs/lib/cpp
 572                 ;;
 573       *-sunos5* | *-solaris* )
 574                 opsys=sol2-10
 575                 emacs_check_sunpro_c=yes
 576                 NON_GNU_CPP=/usr/ccs/lib/cpp
 577                 ;;
 578     esac
 579     ## Watch out for a compiler that we know will not work.
 580     case "${canonical}" in
 581      *-solaris* | *-sunos5* )
 582                 if [ "x$CC" = x/usr/ucb/cc ]; then
 583                   ## /usr/ucb/cc doesn't work;
 584                   ## we should find some other compiler that does work.
 585                   unset CC
 586                 fi
 587                 ;;
 588       *) ;;
 589     esac
 590   ;;
 591
 592   ## Intel 386 machines where we don't care about the manufacturer.
 593   i[3456]86-*-* )
 594     machine=intel386
 595     case "${canonical}" in
 596       *-cygwin )                opsys=cygwin ;;
 597       *-darwin* )               opsys=darwin
 598                                 CPP="${CC-cc} -E -no-cpp-precomp"
 599                                 ;;
 600       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 601       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 602       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 603       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 604     esac
 605   ;;
 606
 607   * )
 608     unported=yes
 609   ;;
 610 esac
 611
 612 ### If the code above didn't choose an operating system, just choose
 613 ### an operating system based on the configuration name.  You really
 614 ### only want to use this when you have no idea what the right
 615 ### operating system is; if you know what operating systems a machine
 616 ### runs, it's cleaner to make it explicit in the case statement
 617 ### above.
 618 if test x"${opsys}" = x; then
 619   case "${canonical}" in
 620     *-gnu* )                            opsys=gnu ;;
 621     * )
 622       unported=yes
 623     ;;
 624   esac
 625 fi
 626
 627 ]
 628 dnl quotation ends
 629
 630 if test $unported = yes; then
 631   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 632 Check `etc/MACHINES' for recognized configuration names.])
 633 fi
 634
 635 if test -n "$machine"; then
 636   machfile="m/${machine}.h"
 637 else
 638   machfile=
 639 fi
 640 opsysfile="s/${opsys}.h"
 641
 642
 643 #### Choose a compiler.
 644 test -n "$CC" && cc_specified=yes
 645
 646 # Save the value of CFLAGS that the user specified.
 647 SPECIFIED_CFLAGS="$CFLAGS"
 648
 649 dnl Sets GCC=yes if using gcc.
 650 AC_PROG_CC
 651 AM_PROG_CC_C_O
 652
 653 # Initialize gnulib right after verifying that the C compiler works.
 654 gl_EARLY
 655
 656 # On Suns, sometimes $CPP names a directory.
 657 if test -n "$CPP" && test -d "$CPP"; then
 658   CPP=
 659 fi
 660
 661 ## If not using gcc, and on Solaris, and no CPP specified, see if
 662 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 663 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 664  test x"$CPP" = x; then
 665   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 666   AC_CACHE_VAL(emacs_cv_sunpro_c,
 667   [AC_TRY_LINK([],
 668 [#ifndef __SUNPRO_C
 669 fail;
 670 #endif
 671 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 672   AC_MSG_RESULT($emacs_cv_sunpro_c)
 673
 674   if test x"$emacs_cv_sunpro_c" = xyes; then
 675     NON_GNU_CPP="$CC -E -Xs"
 676   fi
 677 fi
 678
 679 #### Some systems specify a CPP to use unless we are using GCC.
 680 #### Now that we know whether we are using GCC, we can decide whether
 681 #### to use that one.
 682 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 683 then
 684   CPP="$NON_GNU_CPP"
 685 fi
 686
 687 #### Some systems specify a CC to use unless we are using GCC.
 688 #### Now that we know whether we are using GCC, we can decide whether
 689 #### to use that one.
 690 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 691   test x$cc_specified != xyes
 692 then
 693   CC="$NON_GNU_CC"
 694 fi
 695
 696 if test x$GCC = xyes; then
 697   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 698 else
 699   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 700 fi
 701
 702 ### Use -Wno-pointer-sign if the compiler supports it
 703 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 704 SAVE_CFLAGS="$CFLAGS"
 705 CFLAGS="$CFLAGS -Wno-pointer-sign"
 706 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 707 if test $has_option = yes; then
 708    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 709 fi
 710 AC_MSG_RESULT($has_option)
 711 CFLAGS="$SAVE_CFLAGS"
 712 unset has_option
 713 unset SAVE_CFLAGS
 714
 715 ### Use -Wdeclaration-after-statement if the compiler supports it
 716 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 717 SAVE_CFLAGS="$CFLAGS"
 718 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 719 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 720 if test $has_option = yes; then
 721    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 722 fi
 723 AC_MSG_RESULT($has_option)
 724 CFLAGS="$SAVE_CFLAGS"
 725 unset has_option
 726 unset SAVE_CFLAGS
 727
 728 ### Use -Wold-style-definition if the compiler supports it
 729 # This can be removed when conversion to standard C is finished.
 730 AC_MSG_CHECKING([whether gcc understands -Wold-style-definition])
 731 SAVE_CFLAGS="$CFLAGS"
 732 CFLAGS="$CFLAGS -Wold-style-definition"
 733 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 734 if test $has_option = yes; then
 735    C_WARNINGS_SWITCH="-Wold-style-definition $C_WARNINGS_SWITCH"
 736 fi
 737 AC_MSG_RESULT($has_option)
 738 CFLAGS="$SAVE_CFLAGS"
 739 unset has_option
 740 unset SAVE_CFLAGS
 741
 742 ### Use -Wimplicit-function-declaration if the compiler supports it
 743 AC_MSG_CHECKING([whether gcc understands -Wimplicit-function-declaration])
 744 SAVE_CFLAGS="$CFLAGS"
 745 CFLAGS="$CFLAGS -Wimplicit-function-declaration"
 746 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 747 if test $has_option = yes; then
 748    C_WARNINGS_SWITCH="-Wimplicit-function-declaration $C_WARNINGS_SWITCH"
 749 fi
 750 AC_MSG_RESULT($has_option)
 751 CFLAGS="$SAVE_CFLAGS"
 752 unset has_option
 753 unset SAVE_CFLAGS
 754
 755 AC_SUBST(C_WARNINGS_SWITCH)
 756
 757
 758 #### Some other nice autoconf tests.
 759
 760 dnl checks for programs
 761 AC_PROG_CPP
 762 AC_PROG_INSTALL
 763 if test "x$RANLIB" = x; then
 764   AC_PROG_RANLIB
 765 fi
 766
 767 ## Although we're running on an amd64 kernel, we're actually compiling for
 768 ## the x86 architecture.  The user should probably have provided an
 769 ## explicit --build to `configure', but if everything else than the kernel
 770 ## is running in i386 mode, we can help them out.
 771 if test "$machine" = "amdx86-64"; then
 772   AC_CHECK_DECL([i386])
 773   if test "$ac_cv_have_decl_i386" = "yes"; then
 774     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 775     machine=intel386
 776     machfile="m/${machine}.h"
 777   fi
 778 fi
 779
 780 AC_PATH_PROG(INSTALL_INFO, install-info)
 781 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 782 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 783 dnl Don't use GZIP, which is used by gzip for additional parameters.
 784 AC_PATH_PROG(GZIP_PROG, gzip)
 785
 786
 787 ## Need makeinfo >= 4.6 (?) to build the manuals.
 788 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 789 dnl By this stage, configure has already checked for egrep and set EGREP,
 790 dnl or exited with an error if no egrep was found.
 791 if test "$MAKEINFO" != "no" && \
 792   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 793    MAKEINFO=no
 794 fi
 795
 796 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 797 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 798 ## therefore in the category of "special tools" not normally required, which
 799 ## configure does not have to check for (eg autoconf itself).
 800 ## In a Bazaar checkout on the other hand, the manuals are not included.
 801 ## So makeinfo is a requirement to build from Bazaar, and configure
 802 ## should test for it as it does for any other build requirement.
 803 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 804 ## with pre-built manuals, from a Bazaar checkout.
 805 HAVE_MAKEINFO=yes
 806
 807 if test "$MAKEINFO" = "no"; then
 808   MAKEINFO=makeinfo
 809   if test "x${with_makeinfo}" = "xno"; then
 810     HAVE_MAKEINFO=no
 811   elif test ! -e $srcdir/info/emacs; then
 812     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 813 source tree does not seem to have pre-built manuals in the `info' directory.
 814 Either install a suitable version of makeinfo, or re-run configure
 815 with the `--without-makeinfo' option to build without the manuals.] )
 816   fi
 817 fi
 818 AC_SUBST(HAVE_MAKEINFO)
 819
 820 dnl Add our options to ac_link now, after it is set up.
 821
 822 if test x$GCC = xyes; then
 823   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 824     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 825 else
 826   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 827     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 828 fi
 829
 830 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 831 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 832 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 833 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 834 dnl if not built to support GNU ld.
 835
 836 late_LDFLAGS=$LDFLAGS
 837 if test x$GCC = xyes; then
 838   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 839 else
 840   LDFLAGS="$LDFLAGS -znocombreloc"
 841 fi
 842
 843 AC_MSG_CHECKING([for -znocombreloc])
 844 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 845   [AC_MSG_RESULT(yes)],
 846   LDFLAGS=$late_LDFLAGS
 847   [AC_MSG_RESULT(no)])
 848
 849
 850 # The value of CPP is a quoted variable reference, so we need to do this
 851 # to get its actual value...
 852 CPP=`eval "echo $CPP"`
 853
 854
 855 dnl The function dump-emacs will not be defined and temacs will do
 856 dnl (load "loadup") automatically unless told otherwise.
 857 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 858 case "$opsys" in
 859   your-opsys-here) CANNOT_DUMP=yes ;;
 860 esac
 861
 862 test "$CANNOT_DUMP" = "yes" && \
 863   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 864
 865 AC_SUBST(CANNOT_DUMP)
 866
 867
 868 UNEXEC_OBJ=unexelf.o
 869 case "$opsys" in
 870   # MSDOS uses unexcoff.o
 871   # MSWindows uses unexw32.o
 872   aix4-2)
 873    UNEXEC_OBJ=unexaix.o
 874    ;;
 875   cygwin)
 876    UNEXEC_OBJ=unexcw.o
 877    ;;
 878   darwin)
 879    UNEXEC_OBJ=unexmacosx.o
 880    ;;
 881   hpux10-20 | hpux11)
 882    UNEXEC_OBJ=unexhp9k800.o
 883    ;;
 884   sol2-10)
 885    # Use the Solaris dldump() function, called from unexsol.c, to dump
 886    # emacs, instead of the generic ELF dump code found in unexelf.c.
 887    # The resulting binary has a complete symbol table, and is better
 888    # for debugging and other observability tools (debuggers, pstack, etc).
 889    #
 890    # If you encounter a problem using dldump(), please consider sending
 891    # a message to the OpenSolaris tools-linking mailing list:
 892    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 893    #
 894    # It is likely that dldump() works with older Solaris too, but this has
 895    # not been tested, so for now this change is for Solaris 10 or newer.
 896    UNEXEC_OBJ=unexsol.o
 897    ;;
 898 esac
 899
 900 LD_SWITCH_SYSTEM=
 901 case "$opsys" in
 902   freebsd)
 903    ## Let `ld' find image libs and similar things in /usr/local/lib.
 904    ## The system compiler, GCC, has apparently been modified to not
 905    ## look there, contrary to what a stock GCC would do.
 906    LD_SWITCH_SYSTEM=-L/usr/local/lib
 907    ;;
 908
 909   gnu-linux)
 910    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 911    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 912    ;;
 913
 914   netbsd)
 915    LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 916    ;;
 917
 918   openbsd)
 919    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 920    ## otherwise Emacs dumps core on elf systems.
 921    LD_SWITCH_SYSTEM="-Z"
 922    ;;
 923 esac
 924 AC_SUBST(LD_SWITCH_SYSTEM)
 925
 926 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 927
 928 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_AUX,
 929 ## which has not been defined yet.  When this was handled with cpp,
 930 ## it was expanded to null when configure sourced the s/*.h file.
 931 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 932 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 933 ## (or somesuch), but because it is supposed to go at the _front_
 934 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 935 ## Compare with the gnu-linux case below, which added to the end
 936 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 937 ## LD_SWITCH_SYSTEM_TEMACS.
 938 case "$opsys" in
 939   netbsd|openbsd)
 940    ## _AUX_RPATH is like _AUX, but uses -rpath instead of -R.
 941    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_AUX_RPATH) $LD_SWITCH_SYSTEM" ;;
 942 esac
 943
 944
 945 C_SWITCH_MACHINE=
 946 if test "$machine" = "alpha"; then
 947   AC_CHECK_DECL([__ELF__])
 948   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 949     ## With ELF, make sure that all common symbols get allocated to in the
 950     ## data section.  Otherwise, the dump of temacs may miss variables in
 951     ## the shared library that have been initialized.  For example, with
 952     ## GNU libc, __malloc_initialized would normally be resolved to the
 953     ## shared library's .bss section, which is fatal.
 954     if test "x$GCC" = "xyes"; then
 955       C_SWITCH_MACHINE="-fno-common"
 956     else
 957       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 958     fi
 959   else
 960     UNEXEC_OBJ=unexalpha.o
 961   fi
 962 fi
 963 AC_SUBST(C_SWITCH_MACHINE)
 964
 965 AC_SUBST(UNEXEC_OBJ)
 966
 967 C_SWITCH_SYSTEM=
 968 ## Some programs in src produce warnings saying certain subprograms
 969 ## are too complex and need a MAXMEM value greater than 2000 for
 970 ## additional optimization.  --nils@exp-math.uni-essen.de
 971 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 972   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 973 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 974 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 975 AC_SUBST(C_SWITCH_SYSTEM)
 976
 977
 978 LIBS_SYSTEM=
 979 case "$opsys" in
 980   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 981   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 982
 983   freebsd) LIBS_SYSTEM="-lutil" ;;
 984
 985   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 986
 987   sol2*) LIBS_SYSTEM="-lsocket -lnsl -lkstat" ;;
 988
 989   ## Motif needs -lgen.
 990   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
 991 esac
 992 AC_SUBST(LIBS_SYSTEM)
 993
 994
 995 ### Make sure subsequent tests use flags consistent with the build flags.
 996
 997 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 998   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 999 else
1000   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1001 fi
1002
1003 dnl For AC_FUNC_GETLOADAVG, at least:
1004 AC_CONFIG_LIBOBJ_DIR(src)
1005
1006 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1007 AC_SYS_LARGEFILE
1008
1009
1010 ## If user specified a crt-dir, use that unconditionally.
1011 if test "X$CRT_DIR" = "X"; then
1012
1013   case "$canonical" in
1014     x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1015     ## On x86-64 and s390x GNU/Linux distributions, the standard library
1016     ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1017     ## For anything else (eg /usr/lib32), it is up the user to specify
1018     ## the location (bug#5655).
1019     ## Test for crtn.o, not just the directory, because sometimes the
1020     ## directory exists but does not have the relevant files (bug#1287).
1021     ## FIXME better to test for binary compatibility somehow.
1022     test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1023     ;;
1024
1025     powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1026   esac
1027
1028   case "$opsys" in
1029     hpux10-20) CRT_DIR=/lib ;;
1030   esac
1031
1032   ## Default is /usr/lib.
1033   test "X$CRT_DIR" = "X" && CRT_DIR=/usr/lib
1034
1035 else
1036
1037   ## Some platforms don't use any of these files, so it is not
1038   ## appropriate to put this test outside the if block.
1039   test -e $CRT_DIR/crtn.o || test -e $CRT_DIR/crt0.o || \
1040     AC_MSG_ERROR([crt*.o not found in specified location.])
1041
1042 fi
1043
1044 AC_SUBST(CRT_DIR)
1045
1046 LIB_MATH=-lm
1047 LIB_STANDARD=
1048 START_FILES=
1049
1050 case $opsys in
1051   cygwin )
1052     LIB_MATH=
1053     START_FILES='pre-crt0.o'
1054     ;;
1055   darwin )
1056     ## Adding -lm confuses the dynamic linker, so omit it.
1057     LIB_MATH=
1058     START_FILES='pre-crt0.o'
1059     ;;
1060   freebsd )
1061     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1062     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1063     ;;
1064   gnu-linux | gnu-kfreebsd )
1065     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1066     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1067     ;;
1068   hpux10-20 | hpux11 )
1069     LIB_STANDARD=-lc
1070     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1071     ;;
1072   netbsd | openbsd )
1073     if test -f $CRT_DIR/crti.o; then
1074         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1075         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1076     else
1077         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1078         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1079     fi
1080     ;;
1081 esac
1082
1083 AC_SUBST(LIB_MATH)
1084 AC_SUBST(START_FILES)
1085
1086 dnl This function definition taken from Gnome 2.0
1087 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1088 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1089 dnl also defines GSTUFF_PKG_ERRORS on error
1090 AC_DEFUN([PKG_CHECK_MODULES], [
1091   succeeded=no
1092
1093   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1094
1095   if test "$PKG_CONFIG" = "no" ; then
1096      ifelse([$4], , [AC_MSG_ERROR([
1097       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1098   else
1099      PKG_CONFIG_MIN_VERSION=0.9.0
1100      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1101         AC_MSG_CHECKING(for $2)
1102
1103         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1104             AC_MSG_RESULT(yes)
1105             succeeded=yes
1106
1107             AC_MSG_CHECKING($1_CFLAGS)
1108             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1109             AC_MSG_RESULT($$1_CFLAGS)
1110
1111             AC_MSG_CHECKING($1_LIBS)
1112             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1113             AC_MSG_RESULT($$1_LIBS)
1114         else
1115             AC_MSG_RESULT(no)
1116             $1_CFLAGS=""
1117             $1_LIBS=""
1118             ## If we have a custom action on failure, don't print errors, but
1119             ## do set a variable so people can do so.
1120             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1121             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1122         fi
1123
1124         AC_SUBST($1_CFLAGS)
1125         AC_SUBST($1_LIBS)
1126      else
1127         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1128         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1129      fi
1130   fi
1131
1132   if test $succeeded = yes; then
1133      ifelse([$3], , :, [$3])
1134   else
1135      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1136   fi
1137 ])
1138
1139
1140 if test "${with_sound}" != "no"; then
1141   # Sound support for GNU/Linux and the free BSDs.
1142   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1143     have_sound_header=yes)
1144   # Emulation library used on NetBSD.
1145   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1146   AC_SUBST(LIBSOUND)
1147
1148   ALSA_REQUIRED=1.0.0
1149   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1150   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1151   if test $HAVE_ALSA = yes; then
1152     SAVE_CFLAGS="$CFLAGS"
1153     SAVE_LDFLAGS="$LDFLAGS"
1154     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1155     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1156     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1157                     emacs_alsa_normal=yes,
1158                     emacs_alsa_normal=no)
1159     if test "$emacs_alsa_normal" != yes; then
1160       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1161                      [snd_lib_error_set_handler (0);],
1162                      emacs_alsa_subdir=yes,
1163                      emacs_alsa_subdir=no)
1164       if test "$emacs_alsa_subdir" != yes; then
1165         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1166       fi
1167       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1168     fi
1169
1170     CFLAGS="$SAVE_CFLAGS"
1171     LDFLAGS="$SAVE_LDFLAGS"
1172     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1173     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1174     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1175   fi
1176
1177   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1178   dnl compiles only on the specified platforms.  For others, it
1179   dnl probably doesn't make sense to try.
1180   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1181      case "$opsys" in
1182        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1183        gnu-linux|freebsd|netbsd)
1184          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1185          ;;
1186      esac
1187   fi
1188
1189   AC_SUBST(CFLAGS_SOUND)
1190 fi
1191
1192 dnl checks for header files
1193 AC_CHECK_HEADERS(sys/select.h sys/time.h unistd.h utime.h \
1194   linux/version.h sys/systeminfo.h limits.h \
1195   stdio_ext.h fcntl.h coff.h pty.h sys/mman.h \
1196   sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1197   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1198
1199 AC_MSG_CHECKING(if personality LINUX32 can be set)
1200 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1201                emacs_cv_personality_linux32=yes,
1202                emacs_cv_personality_linux32=no)
1203 AC_MSG_RESULT($emacs_cv_personality_linux32)
1204
1205 if test $emacs_cv_personality_linux32 = yes; then
1206   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1207             [Define to 1 if personality LINUX32 can be set.])
1208 fi
1209
1210 dnl On Solaris 8 there's a compilation warning for term.h because
1211 dnl it doesn't define `bool'.
1212 AC_CHECK_HEADERS(term.h, , , -)
1213 AC_HEADER_STDC
1214 AC_HEADER_TIME
1215 AC_CHECK_DECLS([sys_siglist])
1216 if test $ac_cv_have_decl_sys_siglist != yes; then
1217   # For Tru64, at least:
1218   AC_CHECK_DECLS([__sys_siglist])
1219   if test $ac_cv_have_decl___sys_siglist = yes; then
1220     AC_DEFINE(sys_siglist, __sys_siglist,
1221               [Define to any substitute for sys_siglist.])
1222   fi
1223 fi
1224 AC_HEADER_SYS_WAIT
1225
1226 dnl Some systems have utime.h but don't declare the struct anyplace.
1227 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1228 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1229 #include <sys/time.h>
1230 #include <time.h>
1231 #else
1232 #ifdef HAVE_SYS_TIME_H
1233 #include <sys/time.h>
1234 #else
1235 #include <time.h>
1236 #endif
1237 #endif
1238 #ifdef HAVE_UTIME_H
1239 #include <utime.h>
1240 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1241   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1242 if test $emacs_cv_struct_utimbuf = yes; then
1243   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1244 fi
1245
1246 dnl checks for typedefs
1247 AC_TYPE_SIGNAL
1248
1249 dnl Check for speed_t typedef.
1250 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1251   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1252     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1253 if test $emacs_cv_speed_t = yes; then
1254   AC_DEFINE(HAVE_SPEED_T, 1,
1255            [Define to 1 if `speed_t' is declared by <termios.h>.])
1256 fi
1257
1258 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1259 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1260 #include <sys/time.h>
1261 #include <time.h>
1262 #else
1263 #ifdef HAVE_SYS_TIME_H
1264 #include <sys/time.h>
1265 #else
1266 #include <time.h>
1267 #endif
1268 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1269   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1270 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1271 if test $emacs_cv_struct_timeval = yes; then
1272   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1273 fi
1274
1275 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1276 AC_TRY_COMPILE([#include <math.h>],
1277 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1278   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1279 HAVE_EXCEPTION=$emacs_cv_struct_exception
1280 if test $emacs_cv_struct_exception != yes; then
1281   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1282 fi
1283
1284 AC_CHECK_HEADERS(sys/socket.h)
1285 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1286 #if HAVE_SYS_SOCKET_H
1287 #include <sys/socket.h>
1288 #endif])
1289
1290 dnl checks for structure members
1291 AC_STRUCT_TM
1292 AC_STRUCT_TIMEZONE
1293 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1294                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1295                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1296                 [#include <time.h>])
1297 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1298                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1299                   struct ifreq.ifr_addr], , ,
1300                  [AC_INCLUDES_DEFAULT
1301 #if HAVE_SYS_SOCKET_H
1302 #include <sys/socket.h>
1303 #endif
1304 #if HAVE_NET_IF_H
1305 #include <net/if.h>
1306 #endif])
1307
1308 dnl checks for compiler characteristics
1309
1310 dnl Testing __STDC__ to determine prototype support isn't good enough.
1311 dnl DEC C, for instance, doesn't define it with default options, and
1312 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1313 dnl and void *.
1314 AC_C_PROTOTYPES
1315 AC_C_VOLATILE
1316 AC_C_CONST
1317 dnl This isn't useful because we can't turn on use of `inline' unless
1318 dnl the compiler groks `extern inline'.
1319 dnl AC_C_INLINE
1320 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1321   [AC_TRY_COMPILE(, [void * foo;],
1322                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1323 if test $emacs_cv_void_star = yes; then
1324   AC_DEFINE(POINTER_TYPE, void)
1325 else
1326   AC_DEFINE(POINTER_TYPE, char)
1327 fi
1328 AH_TEMPLATE(POINTER_TYPE,
1329             [Define as `void' if your compiler accepts `void *'; otherwise
1330              define as `char'.])dnl
1331
1332 dnl Check for endianess
1333 AC_C_BIGENDIAN
1334
1335 AC_CACHE_CHECK([for  __attribute__ ((__aligned__ (expr)))],
1336   [emacs_cv_attribute_aligned],
1337   [AC_COMPILE_IFELSE(
1338      [AC_LANG_PROGRAM(
1339         [[char __attribute__ ((__aligned__ (1 << 3))) c;]],
1340         [[]])],
1341      [emacs_cv_attribute_aligned=yes],
1342      [emacs_cv_attribute_aligned=no])])
1343 if test $emacs_cv_attribute_aligned = yes; then
1344   AC_DEFINE([HAVE_ATTRIBUTE_ALIGNED], 1,
1345     [Define to 1 if GCC-style __attribute__ ((__aligned__ (expr))) works.])
1346 fi
1347
1348 dnl check for Make feature
1349 AC_PROG_MAKE_SET
1350
1351 DEPFLAGS=
1352 MKDEPDIR=":"
1353 deps_frag=deps.mk
1354 dnl check for GNU Make if we have GCC and autodepend is on.
1355 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1356    AC_MSG_CHECKING([whether we are using GNU Make])
1357    HAVE_GNU_MAKE=no
1358    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1359    if test "x$testval" != x; then
1360       HAVE_GNU_MAKE=yes
1361    else
1362       ac_enable_autodepend=no
1363    fi
1364    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1365    if test $HAVE_GNU_MAKE = yes; then
1366       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1367       SAVE_CFLAGS="$CFLAGS"
1368       CFLAGS="$CFLAGS -MMD -MF deps.d"
1369       AC_TRY_COMPILE([], [], , ac_enable_autodepend=no)
1370       CFLAGS="$SAVE_CFLAGS"
1371       test -f deps.d || ac_enable_autodepend=no
1372       rm -rf deps.d
1373       AC_MSG_RESULT([$ac_enable_autodepend])
1374    fi
1375    if test $ac_enable_autodepend = yes; then
1376       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d'
1377       ## In parallel builds, another make might create depdir between
1378       ## the first test and mkdir, so stick another test on the end.
1379       ## Or use mkinstalldirs?  mkdir -p is not portable.
1380       MKDEPDIR='test -d ${DEPDIR} || mkdir ${DEPDIR} || test -d ${DEPDIR}'
1381       deps_frag=autodeps.mk
1382    fi
1383 fi
1384 deps_frag=$srcdir/src/$deps_frag
1385 AC_SUBST(MKDEPDIR)
1386 AC_SUBST(DEPFLAGS)
1387 AC_SUBST_FILE(deps_frag)
1388
1389
1390 dnl checks for operating system services
1391 AC_SYS_LONG_FILE_NAMES
1392
1393 #### Choose a window system.
1394
1395 AC_PATH_X
1396 if test "$no_x" = yes; then
1397   window_system=none
1398 else
1399   window_system=x11
1400 fi
1401
1402 ## Workaround for bug in autoconf <= 2.62.
1403 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1404 ## No need to do anything special for these standard directories.
1405 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1406
1407    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1408
1409 fi
1410
1411 LD_SWITCH_X_SITE_AUX=
1412 LD_SWITCH_X_SITE_AUX_RPATH=
1413 if test "${x_libraries}" != NONE; then
1414   if test -n "${x_libraries}"; then
1415     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1416     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1417     LD_SWITCH_X_SITE_AUX_RPATH=`echo ${LD_SWITCH_X_SITE_AUX} | sed -e 's/-R/-Wl,-rpath,/'`
1418   fi
1419   x_default_search_path=""
1420   x_search_path=${x_libraries}
1421   if test -z "${x_search_path}"; then
1422     x_search_path=/usr/lib
1423   fi
1424   for x_library in `echo ${x_search_path}: | \
1425                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1426     x_search_path="\
1427 ${x_library}/X11/%L/%T/%N%C%S:\
1428 ${x_library}/X11/%l/%T/%N%C%S:\
1429 ${x_library}/X11/%T/%N%C%S:\
1430 ${x_library}/X11/%L/%T/%N%S:\
1431 ${x_library}/X11/%l/%T/%N%S:\
1432 ${x_library}/X11/%T/%N%S"
1433     if test x"${x_default_search_path}" = x; then
1434       x_default_search_path=${x_search_path}
1435     else
1436       x_default_search_path="${x_search_path}:${x_default_search_path}"
1437     fi
1438   done
1439 fi
1440 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1441 AC_SUBST(LD_SWITCH_X_SITE_AUX_RPATH)
1442
1443 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1444   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1445 fi
1446
1447 if test x"${x_includes}" = x; then
1448   bitmapdir=/usr/include/X11/bitmaps
1449 else
1450   # accumulate include directories that have X11 bitmap subdirectories
1451   bmd_acc="dummyval"
1452   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1453     if test -d "${bmd}/X11/bitmaps"; then
1454       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1455     fi
1456     if test -d "${bmd}/bitmaps"; then
1457       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1458     fi
1459   done
1460   if test ${bmd_acc} != "dummyval"; then
1461     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1462   fi
1463 fi
1464
1465 HAVE_NS=no
1466 NS_IMPL_COCOA=no
1467 NS_IMPL_GNUSTEP=no
1468 tmp_CPPFLAGS="$CPPFLAGS"
1469 tmp_CFLAGS="$CFLAGS"
1470 CPPFLAGS="$CPPFLAGS -x objective-c"
1471 CFLAGS="$CFLAGS -x objective-c"
1472 TEMACS_LDFLAGS2="\${LDFLAGS}"
1473 dnl I don't think it's especially important, but src/Makefile.in
1474 dnl (now the only user of ns_appdir) used to go to the trouble of adding a
1475 dnl trailing "/" to it, so now we do it here.
1476 if test "${with_ns}" != no; then
1477   if test "${opsys}" = darwin; then
1478      NS_IMPL_COCOA=yes
1479      ns_appdir=`pwd`/nextstep/Emacs.app
1480      ns_appbindir=${ns_appdir}/Contents/MacOS/
1481      ns_appresdir=${ns_appdir}/Contents/Resources
1482      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1483   elif test -f $GNUSTEP_CONFIG_FILE; then
1484      NS_IMPL_GNUSTEP=yes
1485      ns_appdir=`pwd`/nextstep/Emacs.app
1486      ns_appbindir=${ns_appdir}/
1487      ns_appresdir=${ns_appdir}/Resources
1488      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1489      dnl FIXME sourcing this several times in subshells seems inefficient.
1490      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1491      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1492      dnl I seemed to need these as well with GNUstep-startup 0.25.
1493      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1494      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1495      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1496        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1497      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1498        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1499      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1500      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1501      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1502      LIB_STANDARD=
1503      START_FILES=
1504      TEMACS_LDFLAGS2=
1505   fi
1506   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1507                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1508   files are missing or cannot be compiled.])])
1509   NS_HAVE_NSINTEGER=yes
1510   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1511                                      [NSInteger i;])],
1512                     ns_have_nsinteger=yes,
1513                     ns_have_nsinteger=no)
1514   if test $ns_have_nsinteger = no; then
1515     NS_HAVE_NSINTEGER=no
1516   fi
1517 fi
1518 AC_SUBST(TEMACS_LDFLAGS2)
1519
1520 ns_frag=/dev/null
1521 NS_OBJ=
1522 NS_SUPPORT=
1523 if test "${HAVE_NS}" = yes; then
1524   window_system=nextstep
1525   with_xft=no
1526   # set up packaging dirs
1527   exec_prefix=${ns_appbindir}
1528   libexecdir=${ns_appbindir}/libexec
1529   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1530      prefix=${ns_appresdir}
1531   fi
1532   ns_frag=$srcdir/src/ns.mk
1533   NS_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o fontset.o fringe.o image.o"
1534   NS_SUPPORT="\${lispsource}/emacs-lisp/easymenu.elc \${lispsource}/term/ns-win.elc"
1535 fi
1536 CFLAGS="$tmp_CFLAGS"
1537 CPPFLAGS="$tmp_CPPFLAGS"
1538 AC_SUBST(NS_OBJ)
1539 AC_SUBST(NS_SUPPORT)
1540 AC_SUBST(LIB_STANDARD)
1541 AC_SUBST_FILE(ns_frag)
1542
1543 case "${window_system}" in
1544   x11 )
1545     HAVE_X_WINDOWS=yes
1546     HAVE_X11=yes
1547     case "${with_x_toolkit}" in
1548       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1549       motif ) USE_X_TOOLKIT=MOTIF ;;
1550       gtk ) with_gtk=yes
1551 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1552 dnl USE_X_TOOLKIT is set.
1553             USE_X_TOOLKIT=none ;;
1554       gtk3 ) with_gtk3=yes
1555              USE_X_TOOLKIT=none ;;
1556       no ) USE_X_TOOLKIT=none ;;
1557 dnl If user did not say whether to use a toolkit, make this decision later:
1558 dnl use the toolkit if we have gtk, or X11R5 or newer.
1559       * ) USE_X_TOOLKIT=maybe ;;
1560     esac
1561   ;;
1562   nextstep | none )
1563     HAVE_X_WINDOWS=no
1564     HAVE_X11=no
1565     USE_X_TOOLKIT=none
1566   ;;
1567 esac
1568
1569 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1570    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1571    if test "$HAVE_XSERVER" = true ||
1572       test -n "$DISPLAY" ||
1573       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1574         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1575 were found.  You should install the relevant development files for X
1576 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1577 sure you have development files for image handling, i.e.
1578 tiff, gif, jpeg, png and xpm.
1579 If you are sure you want Emacs compiled without X window support, pass
1580   --without-x
1581 to configure.])
1582    fi
1583 fi
1584
1585 ### If we're using X11, we should use the X menu package.
1586 HAVE_MENUS=no
1587 case ${HAVE_X11} in
1588   yes ) HAVE_MENUS=yes ;;
1589 esac
1590
1591 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1592 # Assume not, until told otherwise.
1593 GNU_MALLOC=yes
1594 doug_lea_malloc=yes
1595 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1596 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1597 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1598                emacs_cv_var___after_morecore_hook,
1599 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1600   emacs_cv_var___after_morecore_hook=yes,
1601   emacs_cv_var___after_morecore_hook=no)])
1602 if test $emacs_cv_var___after_morecore_hook = no; then
1603   doug_lea_malloc=no
1604 fi
1605
1606
1607 dnl See comments in aix4-2.h about maybe using system malloc there.
1608 system_malloc=no
1609 case "$opsys" in
1610   ## darwin ld insists on the use of malloc routines in the System framework.
1611   darwin|sol2-10) system_malloc=yes ;;
1612 esac
1613
1614 if test "${system_malloc}" = "yes"; then
1615   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1616   GNU_MALLOC=no
1617   GNU_MALLOC_reason="
1618     (The GNU allocators don't work with this system configuration.)"
1619   GMALLOC_OBJ=
1620   VMLIMIT_OBJ=
1621 else
1622   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1623   VMLIMIT_OBJ=vm-limit.o
1624 fi
1625 AC_SUBST(GMALLOC_OBJ)
1626 AC_SUBST(VMLIMIT_OBJ)
1627
1628 if test "$doug_lea_malloc" = "yes" ; then
1629   if test "$GNU_MALLOC" = yes ; then
1630     GNU_MALLOC_reason="
1631       (Using Doug Lea's new malloc from the GNU C Library.)"
1632   fi
1633   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1634             [Define to 1 if you are using the GNU C Library.])
1635
1636   ## Use mmap directly for allocating larger buffers.
1637   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1638   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1639   ## Does the AC_FUNC_MMAP test below make this check unecessary?
1640   case "$opsys" in
1641     gnu*) REL_ALLOC=no ;;
1642   esac
1643 fi
1644
1645 if test x"${REL_ALLOC}" = x; then
1646   REL_ALLOC=${GNU_MALLOC}
1647 fi
1648
1649 use_mmap_for_buffers=no
1650 case "$opsys" in
1651   freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1652 esac
1653
1654 AC_FUNC_MMAP
1655 if test $use_mmap_for_buffers = yes; then
1656   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1657   REL_ALLOC=no
1658 fi
1659
1660 LIBS="$LIBS_SYSTEM $LIBS"
1661
1662 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1663 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1664 AC_CHECK_LIB(dnet, dnet_ntoa)
1665 dnl This causes -lresolv to get used in subsequent tests,
1666 dnl which causes failures on some systems such as HPUX 9.
1667 dnl AC_CHECK_LIB(resolv, gethostbyname)
1668
1669 dnl FIXME replace main with a function we actually want from this library.
1670 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1671
1672 AC_CHECK_LIB(pthreads, cma_open)
1673
1674 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1675 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1676 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1677 ## added to LIBS in configure would never contain the pthreads part,
1678 ## but the value used in Makefiles might.  FIXME?
1679 ##
1680 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1681 ## be harmless on older versions of X where it happens to exist.
1682 test "$opsys" = "aix4-2" && \
1683   test $ac_cv_lib_pthreads_cma_open = yes && \
1684   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1685
1686 dnl Check for need for bigtoc support on IBM AIX
1687
1688 case ${host_os} in
1689 aix*)
1690   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1691     case $GCC in
1692     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1693     *) gdb_cv_bigtoc=-bbigtoc ;;
1694     esac
1695
1696     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1697     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1698   ])
1699   ;;
1700 esac
1701
1702 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1703 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1704 # REAL_CPPFLAGS later on.
1705
1706 REAL_CFLAGS="$CFLAGS"
1707 REAL_CPPFLAGS="$CPPFLAGS"
1708
1709 if test "${HAVE_X11}" = "yes"; then
1710   DEFS="$C_SWITCH_X_SITE $DEFS"
1711   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1712   LIBS="-lX11 $LIBS"
1713   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1714   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1715
1716   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1717   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1718   # but it's more convenient here to set LD_RUN_PATH
1719   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1720   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1721     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1722     export LD_RUN_PATH
1723   fi
1724
1725   if test "${opsys}" = "gnu-linux"; then
1726     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1727     AC_TRY_LINK([],
1728      [XOpenDisplay ("foo");],
1729      [xlinux_first_failure=no],
1730      [xlinux_first_failure=yes])
1731     if test "${xlinux_first_failure}" = "yes"; then
1732       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1733       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1734       OLD_CPPFLAGS="$CPPFLAGS"
1735       OLD_LIBS="$LIBS"
1736       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1737       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1738       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1739       LIBS="$LIBS -b i486-linuxaout"
1740       AC_TRY_LINK([],
1741        [XOpenDisplay ("foo");],
1742        [xlinux_second_failure=no],
1743        [xlinux_second_failure=yes])
1744       if test "${xlinux_second_failure}" = "yes"; then
1745         # If we get the same failure with -b, there is no use adding -b.
1746         # So take it out.  This plays safe.
1747         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1748         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1749         CPPFLAGS="$OLD_CPPFLAGS"
1750         LIBS="$OLD_LIBS"
1751         AC_MSG_RESULT(no)
1752       else
1753         AC_MSG_RESULT(yes)
1754       fi
1755     else
1756       AC_MSG_RESULT(no)
1757     fi
1758   fi
1759
1760   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1761   # header files included from there.
1762   AC_MSG_CHECKING(for Xkb)
1763   AC_TRY_LINK([#include <X11/Xlib.h>
1764 #include <X11/XKBlib.h>],
1765         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1766         emacs_xkb=yes, emacs_xkb=no)
1767   AC_MSG_RESULT($emacs_xkb)
1768   if test $emacs_xkb = yes; then
1769     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1770   fi
1771
1772   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1773 XScreenNumberOfScreen XSetWMProtocols)
1774 fi
1775
1776 if test "${window_system}" = "x11"; then
1777   AC_MSG_CHECKING(X11 version 6)
1778   AC_CACHE_VAL(emacs_cv_x11_version_6,
1779   [AC_TRY_LINK([#include <X11/Xlib.h>],
1780 [#if XlibSpecificationRelease < 6
1781 fail;
1782 #endif
1783 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1784   if test $emacs_cv_x11_version_6 = yes; then
1785     AC_MSG_RESULT(6 or newer)
1786     AC_DEFINE(HAVE_X11R6, 1,
1787               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1788     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1789     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1790     ## XIM support.
1791     case "$opsys" in
1792       sol2-*) : ;;
1793       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1794            [Define if you have usable X11R6-style XIM support.])
1795          ;;
1796     esac
1797   else
1798     AC_MSG_RESULT(before 6)
1799   fi
1800 fi
1801
1802
1803 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1804 HAVE_RSVG=no
1805 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1806   if test "${with_rsvg}" != "no"; then
1807     RSVG_REQUIRED=2.11.0
1808     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1809
1810     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1811     AC_SUBST(RSVG_CFLAGS)
1812     AC_SUBST(RSVG_LIBS)
1813
1814     if test $HAVE_RSVG = yes; then
1815       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1816       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1817       LIBS="$RSVG_LIBS $LIBS"
1818     fi
1819   fi
1820 fi
1821
1822 HAVE_IMAGEMAGICK=no
1823 if test "${HAVE_X11}" = "yes"; then
1824   if test "${with_imagemagick}" != "no"; then
1825     IMAGEMAGICK_MODULE="Wand"
1826     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1827     AC_SUBST(IMAGEMAGICK_CFLAGS)
1828     AC_SUBST(IMAGEMAGICK_LIBS)
1829
1830     if test $HAVE_IMAGEMAGICK = yes; then
1831       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1832       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1833       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1834       AC_CHECK_FUNCS(MagickExportImagePixels)
1835     fi
1836   fi
1837 fi
1838
1839
1840 HAVE_GTK=no
1841 if test "${with_gtk3}" = "yes"; then
1842   GLIB_REQUIRED=2.6
1843   GTK_REQUIRED=2.90
1844   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1845
1846   dnl Checks for libraries.
1847   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1848   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1849      AC_MSG_ERROR($GTK_PKG_ERRORS)
1850   fi
1851 fi
1852
1853 if test "$pkg_check_gtk" != "yes"; then
1854   HAVE_GTK=no
1855 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1856   GLIB_REQUIRED=2.6
1857   GTK_REQUIRED=2.6
1858   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1859
1860   dnl Checks for libraries.
1861   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1862   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1863      AC_MSG_ERROR($GTK_PKG_ERRORS)
1864   fi
1865 fi
1866 fi
1867
1868 GTK_OBJ=
1869 if test x"$pkg_check_gtk" = xyes; then
1870
1871   AC_SUBST(GTK_CFLAGS)
1872   AC_SUBST(GTK_LIBS)
1873   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1874   CFLAGS="$CFLAGS $GTK_CFLAGS"
1875   LIBS="$GTK_LIBS $LIBS"
1876   dnl Try to compile a simple GTK program.
1877   GTK_COMPILES=no
1878   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1879   if test "${GTK_COMPILES}" != "yes"; then
1880     if test "$USE_X_TOOLKIT" != "maybe"; then
1881       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1882     fi
1883   else
1884     HAVE_GTK=yes
1885     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1886     GTK_OBJ=gtkutil.o
1887     USE_X_TOOLKIT=none
1888     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1889       :
1890     else
1891       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1892        closing open displays.  This is no problem if you just use
1893        one display, but if you use more than one and close one of them
1894        Emacs may crash.]])
1895       sleep 3
1896     fi
1897   fi
1898
1899 fi
1900 AC_SUBST(GTK_OBJ)
1901
1902
1903 if test "${HAVE_GTK}" = "yes"; then
1904
1905   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1906   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1907   if test "$with_toolkit_scroll_bars" != no; then
1908     with_toolkit_scroll_bars=yes
1909   fi
1910
1911   dnl  Check if we have the old file selection dialog declared and
1912   dnl  in the link library.  In 2.x it may be in the library,
1913   dnl  but not declared if deprecated featured has been selected out.
1914   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1915   HAVE_GTK_FILE_SELECTION=no
1916   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1917                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1918 #include <gtk/gtk.h>])
1919   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1920     AC_CHECK_FUNCS(gtk_file_selection_new)
1921   fi
1922
1923   dnl Check if pthreads are available.  Emacs only needs this when using
1924   dnl gtk_file_chooser under Gnome.
1925     HAVE_GTK_AND_PTHREAD=no
1926     AC_CHECK_HEADERS(pthread.h)
1927     if test "$ac_cv_header_pthread_h"; then
1928       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1929     fi
1930     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1931       case "${canonical}" in
1932         *-hpux*) ;;
1933         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1934       esac
1935       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1936                [Define to 1 if you have GTK and pthread (-lpthread).])
1937     fi
1938
1939   dnl Check for functions introduced in 2.14 and later.
1940   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1941                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1942                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1943                  gtk_orientable_set_orientation)
1944
1945 fi
1946
1947 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1948 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1949 dnl also not configured.
1950 HAVE_DBUS=no
1951 DBUS_OBJ=
1952 if test "${with_dbus}" = "yes"; then
1953    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1954    if test "$HAVE_DBUS" = yes; then
1955      LIBS="$LIBS $DBUS_LIBS"
1956      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1957      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1958      DBUS_OBJ=dbusbind.o
1959    fi
1960 fi
1961 AC_SUBST(DBUS_OBJ)
1962
1963 dnl GConf has been tested under GNU/Linux only.
1964 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1965 HAVE_GCONF=no
1966 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1967    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1968    if test "$HAVE_GCONF" = yes; then
1969       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1970       dnl Newer GConf doesn't link with g_objects, so this is not defined.
1971       AC_CHECK_FUNCS([g_type_init])
1972    fi
1973 fi
1974
1975 dnl SELinux is available for GNU/Linux only.
1976 HAVE_LIBSELINUX=no
1977 LIBSELINUX_LIBS=
1978 if test "${with_selinux}" = "yes"; then
1979    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
1980    if test "$HAVE_LIBSELINUX" = yes; then
1981       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
1982       LIBSELINUX_LIBS=-lselinux
1983    fi
1984 fi
1985 AC_SUBST(LIBSELINUX_LIBS)
1986
1987 HAVE_GNUTLS=no
1988 if test "${with_gnutls}" = "yes" ; then
1989   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.2.4], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
1990   if test "${HAVE_GNUTLS}" = "yes"; then
1991     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
1992   fi
1993 fi
1994 AC_SUBST(LIBGNUTLS_LIBS)
1995 AC_SUBST(LIBGNUTLS_CFLAGS)
1996
1997 dnl Do not put whitespace before the #include statements below.
1998 dnl Older compilers (eg sunos4 cc) choke on it.
1999 HAVE_XAW3D=no
2000 LUCID_LIBW=
2001 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2002   if test "$with_xaw3d" != no; then
2003     AC_MSG_CHECKING(for xaw3d)
2004     AC_CACHE_VAL(emacs_cv_xaw3d,
2005     [AC_TRY_LINK([
2006 #include <X11/Intrinsic.h>
2007 #include <X11/Xaw3d/Simple.h>],
2008       [],
2009       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2010                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2011       emacs_cv_xaw3d=no)])
2012   else
2013     emacs_cv_xaw3d=no
2014   fi
2015   if test $emacs_cv_xaw3d = yes; then
2016     AC_MSG_RESULT([yes; using Lucid toolkit])
2017     USE_X_TOOLKIT=LUCID
2018     HAVE_XAW3D=yes
2019     LUCID_LIBW=-lXaw3d
2020     AC_DEFINE(HAVE_XAW3D, 1,
2021               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2022   else
2023     AC_MSG_RESULT(no)
2024     AC_MSG_CHECKING(for libXaw)
2025     AC_CACHE_VAL(emacs_cv_xaw,
2026     [AC_TRY_LINK([
2027 #include <X11/Intrinsic.h>
2028 #include <X11/Xaw/Simple.h>],
2029       [],
2030       emacs_cv_xaw=yes,
2031       emacs_cv_xaw=no)])
2032     if test $emacs_cv_xaw = yes; then
2033       AC_MSG_RESULT([yes; using Lucid toolkit])
2034       USE_X_TOOLKIT=LUCID
2035       LUCID_LIBW=-lXaw
2036     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2037       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2038     else
2039       AC_MSG_RESULT([no; do not use toolkit by default])
2040       USE_X_TOOLKIT=none
2041     fi
2042   fi
2043 fi
2044
2045 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2046
2047 LIBXTR6=
2048 if test "${USE_X_TOOLKIT}" != "none"; then
2049   AC_MSG_CHECKING(X11 toolkit version)
2050   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2051   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
2052 [#if XtSpecificationRelease < 6
2053 fail;
2054 #endif
2055 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2056   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2057   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2058     AC_MSG_RESULT(6 or newer)
2059     AC_DEFINE(HAVE_X11XTR6, 1,
2060               [Define to 1 if you have the X11R6 or newer version of Xt.])
2061     LIBXTR6="-lSM -lICE"
2062     case "$opsys" in
2063       ## Use libw.a along with X11R6 Xt.
2064       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2065     esac
2066   else
2067     AC_MSG_RESULT(before 6)
2068   fi
2069
2070 dnl If using toolkit, check whether libXmu.a exists.
2071 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2072   OLDLIBS="$LIBS"
2073   if test x$HAVE_X11XTR6 = xyes; then
2074     LIBS="-lXt -lSM -lICE $LIBS"
2075   else
2076     LIBS="-lXt $LIBS"
2077   fi
2078   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2079   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2080 fi
2081 AC_SUBST(LIBXTR6)
2082
2083 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2084 dnl Why not just test for libxmu in the normal way?
2085 LIBXMU=-lXmu
2086 case $opsys in
2087   ## These systems don't supply Xmu.
2088   hpux* | aix4-2 )
2089     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2090     ;;
2091 esac
2092 AC_SUBST(LIBXMU)
2093
2094 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2095 if test "${HAVE_X11}" = "yes"; then
2096   if test "${USE_X_TOOLKIT}" != "none"; then
2097     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2098   fi
2099 fi
2100
2101 LIBXP=
2102 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2103   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2104   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
2105     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2106 int x = 5;
2107 #else
2108 Motif version prior to 2.1.
2109 #endif],
2110     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2111   if test $emacs_cv_motif_version_2_1 = yes; then
2112     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2113   else
2114     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2115     # We put this in CFLAGS temporarily to precede other -I options
2116     # that might be in CFLAGS temporarily.
2117     # We put this in CPPFLAGS where it precedes the other -I options.
2118     OLD_CPPFLAGS=$CPPFLAGS
2119     OLD_CFLAGS=$CFLAGS
2120     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2121     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2122     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
2123       [int x = 5;],
2124       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2125     if test $emacs_cv_lesstif = yes; then
2126       # Make sure this -I option remains in CPPFLAGS after it is set
2127       # back to REAL_CPPFLAGS.
2128       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2129       # have those other -I options anyway.  Ultimately, having this
2130       # directory ultimately in CPPFLAGS will be enough.
2131       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2132       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2133     else
2134       CFLAGS=$OLD_CFLAGS
2135       CPPFLAGS=$OLD_CPPFLAGS
2136     fi
2137   fi
2138 fi
2139
2140 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2141 dnl using Motif or Xaw3d is available, and unless
2142 dnl --with-toolkit-scroll-bars=no was specified.
2143
2144 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2145             [Define to 1 if we should use toolkit scroll bars.])dnl
2146 USE_TOOLKIT_SCROLL_BARS=no
2147 if test "${with_toolkit_scroll_bars}" != "no"; then
2148   if test "${USE_X_TOOLKIT}" != "none"; then
2149     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2150       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2151       HAVE_XAW3D=no
2152       USE_TOOLKIT_SCROLL_BARS=yes
2153     elif test "${HAVE_XAW3D}" = "yes"; then
2154       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2155       USE_TOOLKIT_SCROLL_BARS=yes
2156     fi
2157   elif test "${HAVE_GTK}" = "yes"; then
2158     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2159     USE_TOOLKIT_SCROLL_BARS=yes
2160   elif test "${HAVE_NS}" = "yes"; then
2161     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2162     USE_TOOLKIT_SCROLL_BARS=yes
2163   fi
2164 fi
2165
2166 dnl See if XIM is available.
2167 AC_TRY_COMPILE([
2168           #include <X11/Xlib.h>
2169           #include <X11/Xresource.h>],
2170          [XIMProc  callback;],
2171          [HAVE_XIM=yes
2172          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2173          HAVE_XIM=no)
2174
2175 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2176
2177 if test "${with_xim}" != "no"; then
2178   AC_DEFINE(USE_XIM, 1,
2179             [Define to 1 if we should use XIM, if it is available.])
2180 fi
2181
2182
2183 if test "${HAVE_XIM}" != "no"; then
2184   late_CFLAGS=$CFLAGS
2185   if test "$GCC" = yes; then
2186     CFLAGS="$CFLAGS --pedantic-errors"
2187   fi
2188   AC_TRY_COMPILE([
2189 #include <X11/Xlib.h>
2190 #include <X11/Xresource.h>],
2191 [Display *display;
2192 XrmDatabase db;
2193 char *res_name;
2194 char *res_class;
2195 XIMProc  callback;
2196 XPointer *client_data;
2197 #ifndef __GNUC__
2198 /* If we're not using GCC, it's probably not XFree86, and this is
2199    probably right, but we can't use something like --pedantic-errors.  */
2200 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2201                                            char*, XIMProc, XPointer*);
2202 #endif
2203 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2204    client_data);],
2205     [emacs_cv_arg6_star=yes])
2206   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2207          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2208 either XPointer or XPointer*.])dnl
2209   if test "$emacs_cv_arg6_star" = yes; then
2210     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2211   else
2212     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2213   fi
2214   CFLAGS=$late_CFLAGS
2215 fi
2216
2217 ### Start of font-backend (under any platform) section.
2218 # (nothing here yet -- this is a placeholder)
2219 ### End of font-backend (under any platform) section.
2220
2221 ### Start of font-backend (under X11) section.
2222 if test "${HAVE_X11}" = "yes"; then
2223    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2224
2225    ## Use -lXft if available, unless `--with-xft=no'.
2226    HAVE_XFT=maybe
2227     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2228       with_xft="no";
2229     fi
2230     if test "x${with_xft}" != "xno"; then
2231
2232       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2233       ## Because xftfont.c uses XRenderQueryExtension, we also
2234       ## need to link to -lXrender.
2235       HAVE_XRENDER=no
2236       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2237       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2238         OLD_CPPFLAGS="$CPPFLAGS"
2239         OLD_CFLAGS="$CFLAGS"
2240         OLD_LIBS="$LIBS"
2241         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2242         CFLAGS="$CFLAGS $XFT_CFLAGS"
2243         XFT_LIBS="-lXrender $XFT_LIBS"
2244         LIBS="$XFT_LIBS $LIBS"
2245         AC_CHECK_HEADER(X11/Xft/Xft.h,
2246           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2247
2248         if test "${HAVE_XFT}" = "yes"; then
2249           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2250             AC_SUBST(XFT_LIBS)
2251           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2252         else
2253           CPPFLAGS="$OLD_CPPFLAGS"
2254           CFLAGS="$OLD_CFLAGS"
2255           LIBS="$OLD_LIBS"
2256         fi                        # "${HAVE_XFT}" = "yes"
2257       fi                          # "$HAVE_XFT" != no
2258     fi                            # "x${with_xft}" != "xno"
2259
2260     dnl For the "Does Emacs use" message at the end.
2261     if test "$HAVE_XFT" != "yes"; then
2262        HAVE_XFT=no
2263     fi
2264
2265     ## We used to allow building with FreeType and without Xft.
2266     ## However, the ftx font backend driver is not in good shape.
2267     HAVE_FREETYPE=$HAVE_XFT
2268
2269     HAVE_LIBOTF=no
2270     if test "${HAVE_FREETYPE}" = "yes"; then
2271       AC_DEFINE(HAVE_FREETYPE, 1,
2272                 [Define to 1 if using the freetype and fontconfig libraries.])
2273       if test "${with_libotf}" != "no"; then
2274         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2275                           HAVE_LIBOTF=no)
2276         if test "$HAVE_LIBOTF" = "yes"; then
2277           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2278           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2279                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2280                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2281           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2282             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2283                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2284           fi
2285         fi
2286       fi
2287     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2288     dnl Does the new font backend require it, or can it work without it?
2289     fi
2290
2291     HAVE_M17N_FLT=no
2292     if test "${HAVE_LIBOTF}" = yes; then
2293       if test "${with_m17n_flt}" != "no"; then
2294         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2295         if test "$HAVE_M17N_FLT" = "yes"; then
2296           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2297         fi
2298       fi
2299     fi
2300 else
2301     HAVE_XFT=no
2302     HAVE_FREETYPE=no
2303     HAVE_LIBOTF=no
2304     HAVE_M17N_FLT=no
2305 fi
2306
2307 ### End of font-backend (under X11) section.
2308
2309 AC_SUBST(FREETYPE_CFLAGS)
2310 AC_SUBST(FREETYPE_LIBS)
2311 AC_SUBST(FONTCONFIG_CFLAGS)
2312 AC_SUBST(FONTCONFIG_LIBS)
2313 AC_SUBST(LIBOTF_CFLAGS)
2314 AC_SUBST(LIBOTF_LIBS)
2315 AC_SUBST(M17N_FLT_CFLAGS)
2316 AC_SUBST(M17N_FLT_LIBS)
2317
2318 ### Use -lXpm if available, unless `--with-xpm=no'.
2319 HAVE_XPM=no
2320 LIBXPM=
2321 if test "${HAVE_X11}" = "yes"; then
2322   if test "${with_xpm}" != "no"; then
2323     AC_CHECK_HEADER(X11/xpm.h,
2324       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2325     if test "${HAVE_XPM}" = "yes"; then
2326       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2327       AC_EGREP_CPP(no_return_alloc_pixels,
2328       [#include "X11/xpm.h"
2329 #ifndef XpmReturnAllocPixels
2330 no_return_alloc_pixels
2331 #endif
2332       ], HAVE_XPM=no, HAVE_XPM=yes)
2333
2334       if test "${HAVE_XPM}" = "yes"; then
2335         AC_MSG_RESULT(yes)
2336       else
2337         AC_MSG_RESULT(no)
2338       fi
2339     fi
2340   fi
2341
2342   if test "${HAVE_XPM}" = "yes"; then
2343     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2344     LIBXPM=-lXpm
2345   fi
2346 fi
2347 AC_SUBST(LIBXPM)
2348
2349 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2350 HAVE_JPEG=no
2351 LIBJPEG=
2352 if test "${HAVE_X11}" = "yes"; then
2353   if test "${with_jpeg}" != "no"; then
2354     dnl Checking for jpeglib.h can lose because of a redefinition of
2355     dnl  HAVE_STDLIB_H.
2356     AC_CHECK_HEADER(jerror.h,
2357       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2358   fi
2359
2360   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2361   if test "${HAVE_JPEG}" = "yes"; then
2362     AC_DEFINE(HAVE_JPEG)
2363     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2364         [#include <jpeglib.h>
2365          version=JPEG_LIB_VERSION
2366 ],
2367         [AC_DEFINE(HAVE_JPEG)],
2368         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2369         HAVE_JPEG=no])
2370   fi
2371   if test "${HAVE_JPEG}" = "yes"; then
2372     LIBJPEG=-ljpeg
2373   fi
2374 fi
2375 AC_SUBST(LIBJPEG)
2376
2377 ### Use -lpng if available, unless `--with-png=no'.
2378 HAVE_PNG=no
2379 LIBPNG=
2380 if test "${HAVE_X11}" = "yes"; then
2381   if test "${with_png}" != "no"; then
2382     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2383     # in /usr/include/libpng.
2384     AC_CHECK_HEADERS(png.h libpng/png.h)
2385     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2386       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2387     fi
2388   fi
2389
2390   if test "${HAVE_PNG}" = "yes"; then
2391     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2392     LIBPNG="-lpng -lz -lm"
2393   fi
2394 fi
2395 AC_SUBST(LIBPNG)
2396
2397 ### Use -ltiff if available, unless `--with-tiff=no'.
2398 HAVE_TIFF=no
2399 LIBTIFF=
2400 if test "${HAVE_X11}" = "yes"; then
2401   if test "${with_tiff}" != "no"; then
2402     AC_CHECK_HEADER(tiffio.h,
2403       [tifflibs="-lz -lm"
2404       # At least one tiff package requires the jpeg library.
2405       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2406       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2407   fi
2408
2409   if test "${HAVE_TIFF}" = "yes"; then
2410     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2411     dnl FIXME -lz -lm, as per libpng?
2412     LIBTIFF=-ltiff
2413   fi
2414 fi
2415 AC_SUBST(LIBTIFF)
2416
2417 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2418 HAVE_GIF=no
2419 LIBGIF=
2420 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2421   AC_CHECK_HEADER(gif_lib.h,
2422 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2423 # Earlier versions can crash Emacs.
2424     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2425
2426   if test "$HAVE_GIF" = yes; then
2427     LIBGIF=-lgif
2428   elif test "$HAVE_GIF" = maybe; then
2429 # If gif_lib.h but no libgif, try libungif.
2430     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2431     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2432   fi
2433
2434   if test "${HAVE_GIF}" = "yes"; then
2435     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2436   fi
2437 fi
2438 AC_SUBST(LIBGIF)
2439
2440 dnl Check for required libraries.
2441 if test "${HAVE_X11}" = "yes"; then
2442   MISSING=""
2443   WITH_NO=""
2444   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2445     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2446   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2447     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2448   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2449     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2450   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2451     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2452   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2453     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2454
2455   if test "X${MISSING}" != X; then
2456     AC_MSG_ERROR([The following required libraries were not found:
2457     $MISSING
2458 Maybe some development libraries/packages are missing?
2459 If you don't want to link with them give
2460     $WITH_NO
2461 as options to configure])
2462   fi
2463 fi
2464
2465 ### Use -lgpm if available, unless `--with-gpm=no'.
2466 HAVE_GPM=no
2467 LIBGPM=
2468 MOUSE_SUPPORT=
2469 if test "${with_gpm}" != "no"; then
2470   AC_CHECK_HEADER(gpm.h,
2471     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2472
2473   if test "${HAVE_GPM}" = "yes"; then
2474     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2475     LIBGPM=-lgpm
2476     ## May be reset below.
2477     MOUSE_SUPPORT="\$(GPM_MOUSE_SUPPORT)"
2478   fi
2479 fi
2480 AC_SUBST(LIBGPM)
2481
2482 dnl Check for malloc/malloc.h on darwin
2483 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2484
2485 C_SWITCH_X_SYSTEM=
2486 ### Use NeXTstep API to implement GUI.
2487 if test "${HAVE_NS}" = "yes"; then
2488   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2489   if test "${NS_IMPL_COCOA}" = "yes"; then
2490     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2491     GNU_OBJC_CFLAGS=
2492   fi
2493   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2494     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2495     # See also .m.o rule in Makefile.in */
2496     # FIXME: are all these flags really needed?  Document here why.  */
2497     C_SWITCH_X_SYSTEM="-D_REENTRANT -fPIC -fno-strict-aliasing"
2498     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2499   fi
2500   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2501     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2502   fi
2503   # We also have mouse menus.
2504   HAVE_MENUS=yes
2505   OTHER_FILES=ns-app
2506 fi
2507
2508
2509 ### Use session management (-lSM -lICE) if available
2510 HAVE_X_SM=no
2511 LIBXSM=
2512 if test "${HAVE_X11}" = "yes"; then
2513   AC_CHECK_HEADER(X11/SM/SMlib.h,
2514     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2515
2516   if test "${HAVE_X_SM}" = "yes"; then
2517     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2518     LIBXSM="-lSM -lICE"
2519     case "$LIBS" in
2520       *-lSM*) ;;
2521       *)      LIBS="$LIBXSM $LIBS" ;;
2522     esac
2523   fi
2524 fi
2525 AC_SUBST(LIBXSM)
2526
2527 ### Use libxml (-lxml2) if available
2528 if test "${with_xml2}" != "no"; then
2529   ### I'm not sure what the version number should be, so I just guessed.
2530   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2531   if test "${HAVE_LIBXML2}" = "yes"; then
2532     LIBS="$LIBXML2_LIBS $LIBS"
2533     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2534     if test "${HAVE_LIBXML2}" = "yes"; then
2535       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2536     else
2537       LIBXML2_LIBS=""
2538       LIBXML2_CFLAGS=""
2539     fi
2540   fi
2541 fi
2542 AC_SUBST(LIBXML2_LIBS)
2543 AC_SUBST(LIBXML2_CFLAGS)
2544
2545 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2546 AC_CACHE_CHECK(whether netdb declares h_errno,
2547                emacs_cv_netdb_declares_h_errno,
2548 [AC_TRY_LINK([#include <netdb.h>],
2549   [return h_errno;],
2550   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2551 if test $emacs_cv_netdb_declares_h_errno = yes; then
2552   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2553 fi
2554
2555 AC_FUNC_ALLOCA
2556
2557 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2558 dnl FIXME is there an autoconf test that does the right thing, without
2559 dnl needing to call A_M_E afterwards?
2560 if test x"$ac_cv_func_alloca_works" != xyes; then
2561    AC_MSG_ERROR( [a system implementation of alloca is required] )
2562 fi
2563
2564 # fmod, logb, and frexp are found in -lm on most systems.
2565 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2566 AC_CHECK_LIB(m, sqrt)
2567
2568 # Check for mail-locking functions in a "mail" library.  Probably this should
2569 # have the same check as for liblockfile below.
2570 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2571 if test $have_mail = yes; then
2572   LIBS_MAIL=-lmail
2573   LIBS="$LIBS_MAIL $LIBS"
2574   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2575 else
2576   LIBS_MAIL=
2577 fi
2578 dnl Debian, at least:
2579 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2580 if test $have_lockfile = yes; then
2581    LIBS_MAIL=-llockfile
2582    LIBS="$LIBS_MAIL $LIBS"
2583    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2584 else
2585 # If we have the shared liblockfile, assume we must use it for mail
2586 # locking (e.g. Debian).  If we couldn't link against liblockfile
2587 # (no liblockfile.a installed), ensure that we don't need to.
2588   dnl This works for files generally, not just executables.
2589   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2590   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2591                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2592   if test $ac_cv_prog_liblockfile = yes; then
2593     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2594 This probably means that movemail could lose mail.
2595 There may be a `development' package to install containing liblockfile.])
2596   fi
2597 fi
2598 AC_CHECK_FUNCS(touchlock)
2599 AC_CHECK_HEADERS(maillock.h)
2600 AC_SUBST(LIBS_MAIL)
2601
2602 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2603 ## interlock access to the mail spool.  The alternative is a lock file named
2604 ## /usr/spool/mail/$USER.lock.
2605 mail_lock=no
2606 case "$opsys" in
2607   aix4-2) mail_lock="lockf" ;;
2608
2609   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2610
2611   ## On GNU/Linux systems, both methods are used by various mail programs.
2612   ## I assume most people are using newer mailers that have heard of flock.
2613   ## Change this if you need to.
2614   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2615   ## configure gets the right answers, and that means *NOT* using flock.
2616   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2617   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2618   ## Debian maintainer hasn't provided a clean fix for Emacs.
2619   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2620   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2621   ## correct logic.  -- fx
2622   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2623   ## liblockfile is a Free Software replacement for libmail, used on
2624   ## Debian systems and elsewhere. -rfr.
2625   gnu-*)
2626     mail_lock="flock"
2627     if test $have_mail = yes || test $have_lockfile = yes; then
2628       test $ac_cv_header_maillock_h = yes && mail_lock=no
2629     fi
2630     ;;
2631 esac
2632
2633 BLESSMAIL_TARGET=
2634 case "$mail_lock" in
2635   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2636
2637   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2638
2639   *) BLESSMAIL_TARGET="need-blessmail" ;;
2640 esac
2641 AC_SUBST(BLESSMAIL_TARGET)
2642
2643
2644 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2645 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2646 random lrand48 logb frexp fmod rint cbrt ftime setsid \
2647 strerror fpathconf select euidaccess getpagesize tzset setlocale \
2648 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2649 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm strchr strrchr \
2650 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2651 gai_strerror mkstemp getline getdelim mremap memmove fsync sync \
2652 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2653 cfmakeraw cfsetspeed isnan copysign __executable_start)
2654
2655 dnl Cannot use AC_CHECK_FUNCS
2656 AC_CACHE_CHECK([for __builtin_unwind_init],
2657                emacs_cv_func___builtin_unwind_init,
2658 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2659                 emacs_cv_func___builtin_unwind_init=yes,
2660                 emacs_cv_func___builtin_unwind_init=no)])
2661 if test $emacs_cv_func___builtin_unwind_init = yes; then
2662   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2663             [Define to 1 if you have the `__builtin_unwind_init' function.])
2664 fi
2665
2666 AC_CHECK_HEADERS(sys/un.h)
2667
2668 AC_FUNC_GETLOADAVG
2669
2670 AC_FUNC_FSEEKO
2671
2672 AC_FUNC_GETPGRP
2673
2674 # Configure gnulib.
2675 gl_ASSERT_NO_GNULIB_POSIXCHECK
2676 gl_ASSERT_NO_GNULIB_TESTS
2677 gl_INIT
2678
2679 # UNIX98 PTYs.
2680 AC_CHECK_FUNCS(grantpt)
2681
2682 # PTY-related GNU extensions.
2683 AC_CHECK_FUNCS(getpt)
2684
2685 # Check this now, so that we will NOT find the above functions in ncurses.
2686 # That is because we have not set up to link ncurses in lib-src.
2687 # It's better to believe a function is not available
2688 # than to expect to find it in ncurses.
2689 # Also we need tputs and friends to be able to build at all.
2690 have_tputs_et_al=true
2691 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2692 if test "$have_tputs_et_al" != true; then
2693   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2694 Maybe some development libraries/packages are missing?  Try installing
2695 libncurses-dev(el), libterminfo-dev(el) or similar.])
2696 fi
2697 # Must define this when any termcap library is found.
2698 AC_DEFINE(HAVE_LIBNCURSES, 1,
2699           [Define to 1 if you have the `ncurses' library (-lncurses).])
2700 ## FIXME This was the cpp logic, but I am not sure it is right.
2701 ## The above test has not necessarily found libncurses.
2702 HAVE_LIBNCURSES=yes
2703
2704 ## Use terminfo instead of termcap?
2705 ## Note only system files NOT using terminfo are:
2706 ## freebsd < 40000, ms-w32, msdos, netbsd < 599002500, and
2707 ## darwin|gnu without ncurses.
2708 TERMINFO=no
2709 LIBS_TERMCAP=
2710 case "$opsys" in
2711   ## cygwin: Fewer environment variables to go wrong, more terminal types.
2712   ## hpux10-20: Use the system provided termcap(3) library.
2713   ## openbsd: David Mazieres <dm@reeducation-labor.lcs.mit.edu> says this
2714   ##  is necessary.  Otherwise Emacs dumps core when run -nw.
2715   aix4-2|cygwin|hpux*|irix6-5|openbsd|sol2*|unixware) TERMINFO=yes ;;
2716
2717   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2718   ##  The ncurses library has been moved out of the System framework in
2719   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2720   ##  option to use it.
2721   darwin|gnu*)
2722     ## (HAVE_LIBNCURSES was not always true, but is since 2010-03-18.)
2723     if test "x$HAVE_LIBNCURSES" = "xyes"; then
2724       TERMINFO=yes
2725       LIBS_TERMCAP="-lncurses"
2726     fi
2727     ;;
2728
2729   freebsd)
2730     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2731     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2732     [AC_TRY_LINK([#include <osreldate.h>],
2733 [#if __FreeBSD_version < 400000
2734 fail;
2735 #endif
2736 ], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2737
2738     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2739
2740     if test $emacs_cv_freebsd_terminfo = yes; then
2741       TERMINFO=yes
2742       LIBS_TERMCAP="-lncurses"
2743     else
2744       LIBS_TERMCAP="-ltermcap"
2745     fi
2746     ;;
2747
2748   netbsd)
2749     if test $ac_cv_search_tputs = -lterminfo; then
2750       TERMINFO=yes
2751       LIBS_TERMCAP="-lterminfo"
2752     else
2753       LIBS_TERMCAP="-ltermcap"
2754     fi
2755     ;;
2756
2757 esac
2758
2759 case "$opsys" in
2760   ## hpux: Make sure we get select from libc rather than from libcurses
2761   ##  because libcurses on HPUX 10.10 has a broken version of select.
2762   ##  We used to use -lc -lcurses, but this may be cleaner.
2763   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2764
2765   openbsd) LIBS_TERMCAP="-lncurses" ;;
2766
2767   ## Must use system termcap, if we use any termcap.  It does special things.
2768   sol2*) test "$TERMINFO" != yes && LIBS_TERMCAP="-ltermcap" ;;
2769 esac
2770
2771 TERMCAP_OBJ=tparam.o
2772 if test $TERMINFO = yes; then
2773   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2774
2775   ## Default used to be -ltermcap.  Add a case above if need something else.
2776   test "x$LIBS_TERMCAP" = "x" && LIBS_TERMCAP="-lcurses"
2777
2778   TERMCAP_OBJ=terminfo.o
2779 fi
2780 AC_SUBST(LIBS_TERMCAP)
2781 AC_SUBST(TERMCAP_OBJ)
2782
2783
2784 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2785 resolv=no
2786 AC_TRY_LINK([#include <netinet/in.h>
2787 #include <arpa/nameser.h>
2788 #include <resolv.h>],
2789     [return res_init();],
2790     have_res_init=yes, have_res_init=no)
2791 if test "$have_res_init" = no; then
2792   OLIBS="$LIBS"
2793   LIBS="$LIBS -lresolv"
2794   AC_MSG_CHECKING(for res_init with -lresolv)
2795   AC_TRY_LINK([#include <netinet/in.h>
2796 #include <arpa/nameser.h>
2797 #include <resolv.h>],
2798     [return res_init();],
2799     have_res_init=yes, have_res_init=no)
2800   AC_MSG_RESULT($have_res_init)
2801   if test "$have_res_init" = yes ; then
2802     resolv=yes
2803   fi
2804   LIBS="$OLIBS"
2805 fi
2806
2807 if test "$have_res_init" = yes; then
2808   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2809 fi
2810
2811 # Do we need the Hesiod library to provide the support routines?
2812 LIBHESIOD=
2813 if test "$with_hesiod" != no ; then
2814   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2815   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2816      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2817                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2818   if test "$resolv" = yes ; then
2819     RESOLVLIB=-lresolv
2820   else
2821     RESOLVLIB=
2822   fi
2823   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2824         hesiod=yes, :, $RESOLVLIB)])
2825
2826   if test x"$hesiod" = xyes; then
2827     AC_DEFINE(HAVE_LIBHESIOD, 1,
2828               [Define to 1 if you have the hesiod library (-lhesiod).])
2829     LIBHESIOD=-lhesiod
2830   fi
2831 fi
2832 AC_SUBST(LIBHESIOD)
2833
2834 # Do we need libresolv (due to res_init or Hesiod)?
2835 if test "$resolv" = yes ; then
2836   AC_DEFINE(HAVE_LIBRESOLV, 1,
2837             [Define to 1 if you have the resolv library (-lresolv).])
2838   LIBRESOLV=-lresolv
2839 else
2840   LIBRESOLV=
2841 fi
2842 AC_SUBST(LIBRESOLV)
2843
2844 # These tell us which Kerberos-related libraries to use.
2845 COM_ERRLIB=
2846 CRYPTOLIB=
2847 KRB5LIB=
2848 DESLIB=
2849 KRB4LIB=
2850
2851 if test "${with_kerberos}" != no; then
2852   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2853   if test $have_com_err = yes; then
2854     COM_ERRLIB=-lcom_err
2855     LIBS="$COM_ERRLIB $LIBS"
2856     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2857   fi
2858   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2859   if test $have_crypto = yes; then
2860     CRYPTOLIB=-lcrypto
2861     LIBS="$CRYPTOLIB $LIBS"
2862     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2863   fi
2864   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2865   if test $have_k5crypto = yes; then
2866     CRYPTOLIB=-lk5crypto
2867     LIBS="$CRYPTOLIB $LIBS"
2868     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2869   fi
2870   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2871   if test $have_krb5=yes; then
2872     KRB5LIB=-lkrb5
2873     LIBS="$KRB5LIB $LIBS"
2874     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2875   fi
2876   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2877   if test "${with_kerberos5}" = no; then
2878     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2879     if test $have_des425 = yes; then
2880       DESLIB=-ldes425
2881       LIBS="$DESLIB $LIBS"
2882       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2883     else
2884       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2885       if test $have_des = yes; then
2886         DESLIB=-ldes
2887         LIBS="$DESLIB $LIBS"
2888         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2889       fi
2890     fi
2891     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2892     if test $have_krb4 = yes; then
2893       KRB4LIB=-lkrb4
2894       LIBS="$KRB4LIB $LIBS"
2895       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2896     else
2897       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2898       if test $have_krb = yes; then
2899         KRB4LIB=-lkrb
2900         LIBS="$KRB4LIB $LIBS"
2901         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2902       fi
2903     fi
2904   fi
2905
2906   if test "${with_kerberos5}" != no; then
2907     AC_CHECK_HEADERS(krb5.h,
2908       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2909                         [#include <krb5.h>])])
2910   else
2911     AC_CHECK_HEADERS(des.h,,
2912                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2913                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2914     AC_CHECK_HEADERS(krb.h,,
2915                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2916                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2917   fi
2918   AC_CHECK_HEADERS(com_err.h)
2919 fi
2920
2921 AC_SUBST(COM_ERRLIB)
2922 AC_SUBST(CRYPTOLIB)
2923 AC_SUBST(KRB5LIB)
2924 AC_SUBST(DESLIB)
2925 AC_SUBST(KRB4LIB)
2926
2927 # Solaris requires -lintl if you want strerror (which calls dgettext)
2928 # to return localized messages.
2929 AC_CHECK_LIB(intl, dgettext)
2930
2931 AC_MSG_CHECKING(whether localtime caches TZ)
2932 AC_CACHE_VAL(emacs_cv_localtime_cache,
2933 [if test x$ac_cv_func_tzset = xyes; then
2934 AC_TRY_RUN([#include <time.h>
2935 char TZ_GMT0[] = "TZ=GMT0";
2936 char TZ_PST8[] = "TZ=PST8";
2937 main()
2938 {
2939   time_t now = time ((time_t *) 0);
2940   int hour_GMT0, hour_unset;
2941   if (putenv (TZ_GMT0) != 0)
2942     exit (1);
2943   hour_GMT0 = localtime (&now)->tm_hour;
2944   unsetenv("TZ");
2945   hour_unset = localtime (&now)->tm_hour;
2946   if (putenv (TZ_PST8) != 0)
2947     exit (1);
2948   if (localtime (&now)->tm_hour == hour_GMT0)
2949     exit (1);
2950   unsetenv("TZ");
2951   if (localtime (&now)->tm_hour != hour_unset)
2952     exit (1);
2953   exit (0);
2954 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2955 [# If we have tzset, assume the worst when cross-compiling.
2956 emacs_cv_localtime_cache=yes])
2957 else
2958         # If we lack tzset, report that localtime does not cache TZ,
2959         # since we can't invalidate the cache if we don't have tzset.
2960         emacs_cv_localtime_cache=no
2961 fi])dnl
2962 AC_MSG_RESULT($emacs_cv_localtime_cache)
2963 if test $emacs_cv_localtime_cache = yes; then
2964   AC_DEFINE(LOCALTIME_CACHE, 1,
2965             [Define to 1 if localtime caches TZ.])
2966 fi
2967
2968 if test "x$HAVE_TIMEVAL" = xyes; then
2969   AC_CHECK_FUNCS(gettimeofday)
2970   if test $ac_cv_func_gettimeofday = yes; then
2971     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2972                    emacs_cv_gettimeofday_two_arguments,
2973     [AC_TRY_COMPILE([
2974 #ifdef TIME_WITH_SYS_TIME
2975 #include <sys/time.h>
2976 #include <time.h>
2977 #else
2978 #ifdef HAVE_SYS_TIME_H
2979 #include <sys/time.h>
2980 #else
2981 #include <time.h>
2982 #endif
2983 #endif],
2984       [struct timeval time;
2985        gettimeofday (&time, 0);],
2986       emacs_cv_gettimeofday_two_arguments=yes,
2987       emacs_cv_gettimeofday_two_arguments=no)])
2988     if test $emacs_cv_gettimeofday_two_arguments = no; then
2989       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2990                 [Define to 1 if gettimeofday accepts only one argument.])
2991     fi
2992   fi
2993 fi
2994
2995 ok_so_far=yes
2996 AC_CHECK_FUNC(socket, , ok_so_far=no)
2997 if test $ok_so_far = yes; then
2998   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2999 fi
3000 if test $ok_so_far = yes; then
3001   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3002 fi
3003 if test $ok_so_far = yes; then
3004 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3005   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3006             [Define to 1 if you have inet sockets.])
3007 fi
3008
3009 if test -f /usr/lpp/X11/bin/smt.exp; then
3010   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3011             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3012 fi
3013
3014 AC_MSG_CHECKING(whether system supports dynamic ptys)
3015 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3016   AC_MSG_RESULT(yes)
3017   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3018 else
3019   AC_MSG_RESULT(no)
3020 fi
3021
3022 AC_FUNC_FORK
3023
3024 dnl Adapted from Haible's version.
3025 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3026   [AC_TRY_LINK([#include <langinfo.h>],
3027     [char* cs = nl_langinfo(CODESET);],
3028     emacs_cv_langinfo_codeset=yes,
3029     emacs_cv_langinfo_codeset=no)
3030   ])
3031 if test $emacs_cv_langinfo_codeset = yes; then
3032   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3033     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3034 fi
3035
3036 AC_CHECK_TYPES(size_t)
3037
3038 AC_TYPE_MBSTATE_T
3039
3040 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3041   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
3042                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3043 if test "$emacs_cv_c_restrict_arr" = yes; then
3044   AC_DEFINE(__restrict_arr, __restrict,
3045     [Define to compiler's equivalent of C99 restrict keyword in array
3046      declarations.  Define as empty for no equivalent.])
3047 fi
3048
3049 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3050 dnl how the tty code is related to POSIX and/or other versions of termios.
3051 dnl The following looks like a useful start.
3052 dnl
3053 dnl AC_SYS_POSIX_TERMIOS
3054 dnl if test $ac_cv_sys_posix_termios = yes; then
3055 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3056 dnl                                and macros for terminal control.])
3057 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3058 dnl fi
3059
3060 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
3061
3062 # Set up the CFLAGS for real compilation, so we can substitute it.
3063 CFLAGS="$REAL_CFLAGS"
3064 CPPFLAGS="$REAL_CPPFLAGS"
3065
3066 ## Hack to detect a buggy GCC version.
3067 if test "x$GCC" = xyes \
3068    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3069    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3070    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3071    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3072 fi
3073
3074 version=$PACKAGE_VERSION
3075
3076 ### Specify what sort of things we'll be editing into Makefile and config.h.
3077 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3078 AC_SUBST(version)
3079 AC_SUBST(configuration)
3080 ## Unused?
3081 AC_SUBST(canonical)
3082 AC_SUBST(srcdir)
3083 AC_SUBST(prefix)
3084 AC_SUBST(exec_prefix)
3085 AC_SUBST(bindir)
3086 AC_SUBST(datadir)
3087 AC_SUBST(sharedstatedir)
3088 AC_SUBST(libexecdir)
3089 AC_SUBST(mandir)
3090 AC_SUBST(infodir)
3091 AC_SUBST(lispdir)
3092 AC_SUBST(locallisppath)
3093 AC_SUBST(lisppath)
3094 AC_SUBST(x_default_search_path)
3095 AC_SUBST(etcdir)
3096 AC_SUBST(archlibdir)
3097 AC_SUBST(docdir)
3098 AC_SUBST(bitmapdir)
3099 AC_SUBST(gamedir)
3100 AC_SUBST(gameuser)
3101 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3102 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3103 ## end of LIBX_BASE, but nothing ever set it.
3104 AC_SUBST(LD_SWITCH_X_SITE)
3105 AC_SUBST(C_SWITCH_X_SITE)
3106 AC_SUBST(C_SWITCH_X_SYSTEM)
3107 AC_SUBST(CFLAGS)
3108 ## Used in lwlib/Makefile.in.
3109 AC_SUBST(X_TOOLKIT_TYPE)
3110 if test -n "${machfile}"; then
3111   M_FILE="\$(srcdir)/${machfile}"
3112 else
3113   M_FILE=
3114 fi
3115 S_FILE="\$(srcdir)/${opsysfile}"
3116 AC_SUBST(M_FILE)
3117 AC_SUBST(S_FILE)
3118 AC_SUBST(GETLOADAVG_LIBS)
3119 AC_SUBST(ns_appdir)
3120 AC_SUBST(ns_appbindir)
3121 AC_SUBST(ns_appresdir)
3122 AC_SUBST(ns_appsrc)
3123 AC_SUBST(GNU_OBJC_CFLAGS)
3124 AC_SUBST(OTHER_FILES)
3125
3126 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3127                    [Define to the canonical Emacs configuration name.])
3128 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3129                    [Define to the options passed to configure.])
3130 if test -n "$machfile"; then
3131   AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3132                      [Define to the used machine dependent file.])
3133 fi
3134 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3135                    [Define to the used os dependent file.])
3136
3137 XMENU_OBJ=
3138 XOBJ=
3139 FONT_OBJ=
3140 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3141   AC_DEFINE(HAVE_X_WINDOWS, 1,
3142             [Define to 1 if you want to use the X window system.])
3143   XMENU_OBJ=xmenu.o
3144   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3145   FONT_OBJ=xfont.o
3146   if test "$HAVE_XFT" = "yes"; then
3147     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3148   elif test "$HAVE_FREETYPE" = "yes"; then
3149     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3150   fi
3151   AC_SUBST(FONT_OBJ)
3152 fi
3153 AC_SUBST(XMENU_OBJ)
3154 AC_SUBST(XOBJ)
3155 AC_SUBST(FONT_OBJ)
3156
3157 WIDGET_OBJ=
3158 MOTIF_LIBW=
3159 if test "${USE_X_TOOLKIT}" != "none" ; then
3160   WIDGET_OBJ=widget.o
3161   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3162   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3163     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3164   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3165     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3166     MOTIF_LIBW=-lXm
3167     case "$opsys" in
3168       gnu-linux)
3169         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3170         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3171         ;;
3172
3173       unixware)
3174         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3175         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3176         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3177         ;;
3178
3179       aix4-2)
3180         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3181         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3182         ;;
3183     esac
3184     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3185   fi
3186 fi
3187 AC_SUBST(WIDGET_OBJ)
3188
3189 TOOLKIT_LIBW=
3190 case "$USE_X_TOOLKIT" in
3191   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3192   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3193   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3194 esac
3195 AC_SUBST(TOOLKIT_LIBW)
3196
3197 if test "$USE_X_TOOLKIT" = "none"; then
3198   LIBXT_OTHER="\$(LIBXSM)"
3199   OLDXMENU_TARGET="really-oldXMenu"
3200 else
3201   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3202   OLDXMENU_TARGET="really-lwlib"
3203 fi
3204 AC_SUBST(LIBXT_OTHER)
3205
3206 ## The X Menu stuff is present in the X10 distribution, but missing
3207 ## from X11.  If we have X10, just use the installed library;
3208 ## otherwise, use our own copy.
3209 if test "${HAVE_X11}" = "yes" ; then
3210   AC_DEFINE(HAVE_X11, 1,
3211             [Define to 1 if you want to use version 11 of X windows.
3212              Otherwise, Emacs expects to use version 10.])
3213
3214   if test "$USE_X_TOOLKIT" = "none"; then
3215     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
3216   else
3217     OLDXMENU="\${lwlibdir}/liblw.a"
3218   fi
3219   LIBXMENU="\$(OLDXMENU)"
3220   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3221   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3222 else
3223   ## For a syntactically valid Makefile; not actually used for anything.
3224   ## See comments in src/Makefile.in.
3225   OLDXMENU=nothing
3226   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3227   if test "${HAVE_X_WINDOWS}" = "yes"; then
3228     LIBXMENU="-lXMenu"
3229   else
3230     LIBXMENU=
3231   fi
3232   LIBX_OTHER=
3233   OLDXMENU_DEPS=
3234 fi
3235
3236 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3237   OLDXMENU_TARGET=
3238   OLDXMENU=nothing
3239   LIBXMENU=
3240   OLDXMENU_DEPS=
3241 fi
3242
3243 AC_SUBST(OLDXMENU_TARGET)
3244 AC_SUBST(OLDXMENU)
3245 AC_SUBST(LIBXMENU)
3246 AC_SUBST(LIBX_OTHER)
3247 AC_SUBST(OLDXMENU_DEPS)
3248
3249 if test "${HAVE_MENUS}" = "yes" ; then
3250   AC_DEFINE(HAVE_MENUS, 1,
3251             [Define to 1 if you have mouse menus.
3252              (This is automatic if you use X, but the option to specify it remains.)
3253              It is also defined with other window systems that support xmenu.c.])
3254 fi
3255
3256 if test "${GNU_MALLOC}" = "yes" ; then
3257   AC_DEFINE(GNU_MALLOC, 1,
3258             [Define to 1 if you want to use the GNU memory allocator.])
3259 fi
3260
3261 RALLOC_OBJ=
3262 if test "${REL_ALLOC}" = "yes" ; then
3263   AC_DEFINE(REL_ALLOC, 1,
3264             [Define REL_ALLOC if you want to use the relocating allocator for
3265              buffer space.])
3266
3267   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3268 fi
3269 AC_SUBST(RALLOC_OBJ)
3270
3271 if test "$opsys" = "cygwin"; then
3272   CYGWIN_OBJ="sheap.o"
3273   ## Cygwin differs because of its unexec().
3274   PRE_ALLOC_OBJ=
3275   POST_ALLOC_OBJ=lastfile.o
3276 else
3277   CYGWIN_OBJ=
3278   PRE_ALLOC_OBJ=lastfile.o
3279   POST_ALLOC_OBJ=
3280 fi
3281 AC_SUBST(CYGWIN_OBJ)
3282 AC_SUBST(PRE_ALLOC_OBJ)
3283 AC_SUBST(POST_ALLOC_OBJ)
3284
3285
3286 case "$opsys" in
3287   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3288
3289   darwin)
3290    ## The -headerpad option tells ld (see man page) to leave room at the
3291    ## end of the header for adding load commands.  Needed for dumping.
3292    ## 0x690 is the total size of 30 segment load commands (at 56
3293    ## each); under Cocoa 31 commands are required.
3294    if test "$HAVE_NS" = "yes"; then
3295      libs_nsgui="-framework AppKit"
3296      headerpad_extra=6C8
3297    else
3298      libs_nsgui=
3299      headerpad_extra=690
3300    fi
3301    LD_SWITCH_SYSTEM_TEMACS="-prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3302
3303    ## This is here because src/Makefile.in did some extra fiddling around
3304    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3305    ##   #ifndef LD_SWITCH_SYSTEM
3306    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3307    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3308    ## not using gcc, darwin system not on an alpha (ie darwin, since
3309    ## darwin + alpha does not occur).
3310    ## Because this was done in src/Makefile.in, the resulting part of
3311    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3312    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3313    ## rather than LD_SWITCH_SYSTEM.
3314    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3315      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3316    ;;
3317
3318   ## LD_SWITCH_X_SITE_AUX is a -R option saying where to find X at run-time.
3319   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at
3320   ## the point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_AUX
3321   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3322   ## had different values in configure (in ac_link) and src/Makefile.in.
3323   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3324   gnu-linux) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_AUX)" ;;
3325
3326   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3327 esac
3328
3329 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3330   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3331 fi
3332
3333 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3334
3335
3336 LD_FIRSTFLAG=
3337 ORDINARY_LINK=
3338 case "$opsys" in
3339   ## gnu: GNU needs its own crt0.
3340   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3341
3342   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3343   ## library search parth, i.e. it won't search /usr/lib for libc and
3344   ## friends.  Using -nostartfiles instead avoids this problem, and
3345   ## will also work on earlier NetBSD releases.
3346   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
3347
3348   ## macpcc: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3349   ##   MkLinux/LinuxPPC needs this.
3350   ## ibms390x only supports opsys = gnu-linux so it can be added here.
3351   gnu-*)
3352     case "$machine" in
3353       macppc|ibms390x) LD_FIRSTFLAG="-nostdlib" ;;
3354     esac
3355     ;;
3356 esac
3357
3358
3359 if test "x$ORDINARY_LINK" = "xyes"; then
3360
3361   LD_FIRSTFLAG=""
3362   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3363
3364 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
3365 ## freebsd, gnu-* not on macppc|ibms390x.
3366 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
3367
3368   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3369   ## places that are difficult to figure out at make time.  Fortunately,
3370   ## these same versions allow you to pass arbitrary flags on to the
3371   ## linker, so there is no reason not to use it as a linker.
3372   ##
3373   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3374   ## searching for libraries in its internal directories, so we have to
3375   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3376   LD_FIRSTFLAG="-nostdlib"
3377 fi
3378
3379 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3380 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
3381
3382 AC_SUBST(LD_FIRSTFLAG)
3383
3384
3385 ## FIXME? The logic here is not precisely the same as that above.
3386 ## There is no check here for a pre-defined LD_FIRSTFLAG.
3387 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3388 LIB_GCC=
3389 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3390
3391   case "$opsys" in
3392     freebsd|netbsd|openbsd) LIB_GCC= ;;
3393
3394     gnu-*)
3395       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3396       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3397       case $host_cpu in
3398       arm*)
3399         LIB_GCC="-lgcc_s"
3400         ;;
3401       *)
3402         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3403         ## immediately undefine it again and redefine it to empty.
3404         ## Was the C_SWITCH_X_SITE part really necessary?
3405 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3406         LIB_GCC=
3407         ;;
3408       esac
3409       ;;
3410
3411     ## Ask GCC where to find libgcc.a.
3412     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3413   esac
3414 fi                              dnl if $GCC
3415 AC_SUBST(LIB_GCC)
3416
3417
3418 TOOLTIP_SUPPORT=
3419 WINDOW_SUPPORT=
3420 ## If we're using X11/GNUstep, define some consequences.
3421 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3422   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3423   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3424   MOUSE_SUPPORT="\$(REAL_MOUSE_SUPPORT)"
3425   TOOLTIP_SUPPORT="\${lispsource}/mouse.elc"
3426
3427   WINDOW_SUPPORT="\$(BASE_WINDOW_SUPPORT)"
3428   test "$HAVE_X_WINDOWS" = "yes" && \
3429     WINDOW_SUPPORT="$WINDOW_SUPPORT \$(X_WINDOW_SUPPORT)"
3430
3431 fi
3432 AC_SUBST(MOUSE_SUPPORT)
3433 AC_SUBST(TOOLTIP_SUPPORT)
3434 AC_SUBST(WINDOW_SUPPORT)
3435
3436
3437 AH_TOP([/* GNU Emacs site configuration template file.
3438
3439 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2011
3440   Free Software Foundation, Inc.
3441
3442 This file is part of GNU Emacs.
3443
3444 GNU Emacs is free software: you can redistribute it and/or modify
3445 it under the terms of the GNU General Public License as published by
3446 the Free Software Foundation, either version 3 of the License, or
3447 (at your option) any later version.
3448
3449 GNU Emacs is distributed in the hope that it will be useful,
3450 but WITHOUT ANY WARRANTY; without even the implied warranty of
3451 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3452 GNU General Public License for more details.
3453
3454 You should have received a copy of the GNU General Public License
3455 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3456
3457
3458 /* No code in Emacs #includes config.h twice, but some bits of code
3459    intended to work with other packages as well (like gmalloc.c)
3460    think they can include it as many times as they like.  */
3461 #ifndef EMACS_CONFIG_H
3462 #define EMACS_CONFIG_H
3463 ])dnl
3464
3465 AH_BOTTOM([
3466 /* Define AMPERSAND_FULL_NAME if you use the convention
3467    that & in the full name stands for the login id.  */
3468 /* Turned on June 1996 supposing nobody will mind it.  */
3469 #define AMPERSAND_FULL_NAME
3470
3471 /* If using GNU, then support inline function declarations.  */
3472 /* Don't try to switch on inline handling as detected by AC_C_INLINE
3473    generally, because even if non-gcc compilers accept `inline', they
3474    may reject `extern inline'.  */
3475 #if defined (__GNUC__)
3476 #define INLINE __inline__
3477 #else
3478 #define INLINE
3479 #endif
3480
3481 /* `subprocesses' should be defined if you want to
3482    have code for asynchronous subprocesses
3483    (as used in M-x compile and M-x shell).
3484    Only MSDOS does not support this (it overrides
3485    this in its config_opsysfile below).  */
3486
3487 #define subprocesses
3488
3489 /* Include the os and machine dependent files.  */
3490 #include config_opsysfile
3491 #ifdef config_machfile
3492 # include config_machfile
3493 #endif
3494
3495 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3496    SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.
3497   (There is probably a better place to do this, but right now the
3498    Cocoa side does this in s/darwin.h and we cannot parallel this
3499    exactly since GNUstep is multi-OS.  */
3500 #if defined HAVE_NS && defined NS_IMPL_GNUSTEP
3501 #  define SYSTEM_PURESIZE_EXTRA 30000
3502 #endif
3503
3504 /* SIGTYPE is the macro we actually use.  */
3505 #ifndef SIGTYPE
3506 #define SIGTYPE RETSIGTYPE
3507 #endif
3508
3509 #ifdef emacs /* Don't do this for lib-src.  */
3510 /* Tell regex.c to use a type compatible with Emacs.  */
3511 #define RE_TRANSLATE_TYPE Lisp_Object
3512 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3513 #ifdef make_number
3514 /* If make_number is a macro, use it.  */
3515 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3516 #else
3517 /* If make_number is a function, avoid it.  */
3518 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3519 #endif
3520 #endif
3521
3522 /* These default definitions are good for almost all machines.
3523    The exceptions override them in m/MACHINE.h.  */
3524
3525 #ifndef BITS_PER_CHAR
3526 #define BITS_PER_CHAR 8
3527 #endif
3528
3529 #ifndef BITS_PER_SHORT
3530 #define BITS_PER_SHORT 16
3531 #endif
3532
3533 /* Note that lisp.h uses this in a preprocessor conditional, so it
3534    would not work to use sizeof.  That being so, we do all of them
3535    without sizeof, for uniformity's sake.  */
3536 #ifndef BITS_PER_INT
3537 #define BITS_PER_INT 32
3538 #endif
3539
3540 #ifndef BITS_PER_LONG
3541 #ifdef _LP64
3542 #define BITS_PER_LONG 64
3543 #else
3544 #define BITS_PER_LONG 32
3545 #endif
3546 #endif
3547
3548 /* Define if the compiler supports function prototypes.  It may do so but
3549    not define __STDC__ (e.g. DEC C by default) or may define it as zero.  */
3550 #undef PROTOTYPES
3551
3552 #include <string.h>
3553 #include <stdlib.h>
3554
3555 #ifdef HAVE_ALLOCA_H
3556 # include <alloca.h>
3557 #elif defined __GNUC__
3558 # define alloca __builtin_alloca
3559 #elif defined _AIX
3560 # define alloca __alloca
3561 #else
3562 # include <stddef.h>
3563 # ifdef  __cplusplus
3564 extern "C"
3565 # endif
3566 void *alloca (size_t);
3567 #endif
3568
3569 #ifndef HAVE_SIZE_T
3570 typedef unsigned size_t;
3571 #endif
3572
3573 #ifndef HAVE_STRCHR
3574 #define strchr(a, b) index (a, b)
3575 #endif
3576
3577 #ifndef HAVE_STRRCHR
3578 #define strrchr(a, b) rindex (a, b)
3579 #endif
3580
3581 #if defined __GNUC__ && (__GNUC__ > 2 \
3582                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3583 #define NO_RETURN       __attribute__ ((__noreturn__))
3584 #else
3585 #define NO_RETURN       /* nothing */
3586 #endif
3587
3588 #if __GNUC__ >= 3  /* On GCC 3.0 we might get a warning.  */
3589 #define NO_INLINE __attribute__((noinline))
3590 #else
3591 #define NO_INLINE
3592 #endif
3593
3594 #if (__GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 1))
3595 #define EXTERNALLY_VISIBLE __attribute__((externally_visible))
3596 #else
3597 #define EXTERNALLY_VISIBLE
3598 #endif
3599
3600 /* Some versions of GNU/Linux define noinline in their headers.  */
3601 #ifdef noinline
3602 #undef noinline
3603 #endif
3604
3605 /* These won't be used automatically yet.  We also need to know, at least,
3606    that the stack is continuous.  */
3607 #ifdef __GNUC__
3608 #  ifndef GC_SETJMP_WORKS
3609   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3610 #    define GC_SETJMP_WORKS 1
3611 #  endif
3612 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3613 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3614 #  endif
3615 #endif
3616
3617 #endif /* EMACS_CONFIG_H */
3618
3619 /*
3620 Local Variables:
3621 mode: c
3622 End:
3623 */
3624 ])dnl
3625
3626 #### Report on what we decided to do.
3627 #### Report GTK as a toolkit, even if it doesn't use Xt.
3628 #### It makes printing result more understandable as using GTK sets
3629 #### toolkit_scroll_bars to yes by default.
3630 if test "${HAVE_GTK}" = "yes"; then
3631   USE_X_TOOLKIT=GTK
3632 fi
3633
3634 and_machfile=
3635 if test -n "$machfile"; then
3636   and_machfile=" and \`${machfile}'"
3637 fi
3638
3639 echo "
3640 Configured for \`${canonical}'.
3641
3642   Where should the build process find the source code?    ${srcdir}
3643   What operating system and machine description files should Emacs use?
3644         \`${opsysfile}'${and_machfile}
3645   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3646   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3647   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3648   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3649   What window system should Emacs use?                    ${window_system}
3650   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3651
3652 if test -n "${x_includes}"; then
3653 echo "  Where do we find X Windows header files?                ${x_includes}"
3654 else
3655 echo "  Where do we find X Windows header files?                Standard dirs"
3656 fi
3657 if test -n "${x_libraries}"; then
3658 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3659 else
3660 echo "  Where do we find X Windows libraries?                   Standard dirs"
3661 fi
3662
3663 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3664 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3665 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3666 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3667 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3668 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3669 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3670 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
3671
3672 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3673 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3674 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3675 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3676 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
3677 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
3678
3679 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3680 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3681 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3682 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3683
3684 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3685 echo
3686
3687 if test $USE_XASSERTS = yes; then
3688    echo "  Compiling with asserts turned on."
3689    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3690 fi
3691
3692 echo
3693
3694 if test "$HAVE_NS" = "yes"; then
3695    echo
3696    echo "You must run \"make install\" in order to test the built application.
3697 The installed application will go to nextstep/Emacs.app and can be
3698 run or moved from there."
3699    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3700       echo "The application will be fully self-contained."
3701     else
3702       echo "The lisp resources for the application will be installed under ${prefix}.
3703 You may need to run \"make install\" with sudo.  The application will fail
3704 to run if these resources are not installed."
3705    fi
3706    echo
3707 fi
3708
3709
3710 # Remove any trailing slashes in these variables.
3711 [test "${prefix}" != NONE &&
3712   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3713 test "${exec_prefix}" != NONE &&
3714   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3715
3716 dnl You might wonder (I did) why epaths.h is generated by running make,
3717 dnl rather than just letting configure generate it from epaths.in.
3718 dnl One reason is that the various paths are not fully expanded (see above);
3719 dnl eg gamedir=${prefix}/var/games/emacs.
3720 dnl Secondly, the GNU Coding standards require that one should be able
3721 dnl to run `make prefix=/some/where/else' and override the values set
3722 dnl by configure.  This also explains the `move-if-change' test and
3723 dnl the use of force in the `epaths-force' rule in Makefile.in.
3724 AC_OUTPUT(Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
3725         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3726         doc/lispref/Makefile src/Makefile \
3727         lwlib/Makefile lisp/Makefile leim/Makefile test/automated/Makefile, [
3728
3729 ### Make the necessary directories, if they don't exist.
3730 for dir in etc lisp ; do
3731   test -d ${dir} || mkdir ${dir}
3732 done
3733
3734 echo creating src/epaths.h
3735 ${MAKE-make} epaths-force
3736
3737 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3738   echo creating src/.gdbinit
3739   echo source $srcdir/src/.gdbinit > src/.gdbinit
3740 fi
3741
3742 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPPFLAGS="$CPPFLAGS"])