code.delx.au - gnu-emacs/blob - lisp/gnus/nnspool.el

   1 ;;; nnspool.el --- spool access for GNU Emacs
   2
   3 ;; Copyright (C) 1988, 1989, 1990, 1993, 1994, 1995, 1996, 1997, 1998,
   4 ;;               2000, 2002, 2003
   5 ;;               Free Software Foundation, Inc.
   6
   7 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   8 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   9 ;; Keywords: news
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  26 ;; Boston, MA 02111-1307, USA.
  27
  28 ;;; Commentary:
  29
  30 ;;; Code:
  31
  32 (require 'nnheader)
  33 (require 'nntp)
  34 (require 'nnoo)
  35 (eval-when-compile (require 'cl))
  36
  37 (nnoo-declare nnspool)
  38
  39 (defvoo nnspool-inews-program news-inews-program
  40   "Program to post news.
  41 This is most commonly `inews' or `injnews'.")
  42
  43 (defvoo nnspool-inews-switches '("-h" "-S")
  44   "Switches for nnspool-request-post to pass to `inews' for posting news.
  45 If you are using Cnews, you probably should set this variable to nil.")
  46
  47 (defvoo nnspool-spool-directory (file-name-as-directory news-path)
  48   "Local news spool directory.")
  49
  50 (defvoo nnspool-nov-directory (concat nnspool-spool-directory "over.view/")
  51   "Local news nov directory.")
  52
  53 (defvoo nnspool-lib-dir
  54     (if (file-exists-p "/usr/lib/news/active")
  55         "/usr/lib/news/"
  56       "/var/lib/news/")
  57   "Where the local news library files are stored.")
  58
  59 (defvoo nnspool-active-file (concat nnspool-lib-dir "active")
  60   "Local news active file.")
  61
  62 (defvoo nnspool-newsgroups-file (concat nnspool-lib-dir "newsgroups")
  63   "Local news newsgroups file.")
  64
  65 (defvoo nnspool-distributions-file (concat nnspool-lib-dir "distribs.pat")
  66   "Local news distributions file.")
  67
  68 (defvoo nnspool-history-file (concat nnspool-lib-dir "history")
  69   "Local news history file.")
  70
  71 (defvoo nnspool-active-times-file (concat nnspool-lib-dir "active.times")
  72   "Local news active date file.")
  73
  74 (defvoo nnspool-large-newsgroup 50
  75   "The number of articles which indicates a large newsgroup.
  76 If the number of articles is greater than the value, verbose
  77 messages will be shown to indicate the current status.")
  78
  79 (defvoo nnspool-nov-is-evil nil
  80   "Non-nil means that nnspool will never return NOV lines instead of headers.")
  81
  82 (defconst nnspool-sift-nov-with-sed nil
  83   "If non-nil, use sed to get the relevant portion from the overview file.
  84 If nil, nnspool will load the entire file into a buffer and process it
  85 there.")
  86
  87 (defvoo nnspool-rejected-article-hook nil
  88   "*A hook that will be run when an article has been rejected by the server.")
  89
  90 (defvoo nnspool-file-coding-system nnheader-file-coding-system
  91   "Coding system for nnspool.")
  92
  93 \f
  94
  95 (defconst nnspool-version "nnspool 2.0"
  96   "Version numbers of this version of NNSPOOL.")
  97
  98 (defvoo nnspool-current-directory nil
  99   "Current news group directory.")
 100
 101 (defvoo nnspool-current-group nil)
 102 (defvoo nnspool-status-string "")
 103
 104 \f
 105 ;;; Interface functions.
 106
 107 (nnoo-define-basics nnspool)
 108
 109 (deffoo nnspool-retrieve-headers (articles &optional group server fetch-old)
 110   "Retrieve the headers of ARTICLES."
 111   (save-excursion
 112     (set-buffer nntp-server-buffer)
 113     (erase-buffer)
 114     (when (nnspool-possibly-change-directory group)
 115       (let* ((number (length articles))
 116              (count 0)
 117              (default-directory nnspool-current-directory)
 118              (do-message (and (numberp nnspool-large-newsgroup)
 119                               (> number nnspool-large-newsgroup)))
 120              (nnheader-file-coding-system nnspool-file-coding-system)
 121              file beg article ag)
 122         (if (and (numberp (car articles))
 123                  (nnspool-retrieve-headers-with-nov articles fetch-old))
 124             ;; We successfully retrieved the NOV headers.
 125             'nov
 126           ;; No NOV headers here, so we do it the hard way.
 127           (while (setq article (pop articles))
 128             (if (stringp article)
 129                 ;; This is a Message-ID.
 130                 (setq ag (nnspool-find-id article)
 131                       file (and ag (nnspool-article-pathname
 132                                     (car ag) (cdr ag)))
 133                       article (cdr ag))
 134               ;; This is an article in the current group.
 135               (setq file (int-to-string article)))
 136             ;; Insert the head of the article.
 137             (when (and file
 138                        (file-exists-p file))
 139               (insert "221 ")
 140               (princ article (current-buffer))
 141               (insert " Article retrieved.\n")
 142               (setq beg (point))
 143               (inline (nnheader-insert-head file))
 144               (goto-char beg)
 145               (if (search-forward "\n\n" nil t)
 146                   (progn
 147                     (forward-char -1)
 148                     (insert ".\n"))
 149                 (goto-char (point-max))
 150                 (if (bolp)
 151                     (insert ".\n")
 152                   (insert "\n.\n")))
 153               (delete-region (point) (point-max)))
 154
 155             (and do-message
 156                  (zerop (% (incf count) 20))
 157                  (nnheader-message 5 "nnspool: Receiving headers... %d%%"
 158                                    (/ (* count 100) number))))
 159
 160           (when do-message
 161             (nnheader-message 5 "nnspool: Receiving headers...done"))
 162
 163           ;; Fold continuation lines.
 164           (nnheader-fold-continuation-lines)
 165           'headers)))))
 166
 167 (deffoo nnspool-open-server (server &optional defs)
 168   (nnoo-change-server 'nnspool server defs)
 169   (cond
 170    ((not (file-exists-p nnspool-spool-directory))
 171     (nnspool-close-server)
 172     (nnheader-report 'nnspool "Spool directory doesn't exist: %s"
 173                      nnspool-spool-directory))
 174    ((not (file-directory-p
 175           (directory-file-name
 176            (file-truename nnspool-spool-directory))))
 177     (nnspool-close-server)
 178     (nnheader-report 'nnspool "Not a directory: %s" nnspool-spool-directory))
 179    ((not (file-exists-p nnspool-active-file))
 180     (nnheader-report 'nnspool "The active file doesn't exist: %s"
 181                      nnspool-active-file))
 182    (t
 183     (nnheader-report 'nnspool "Opened server %s using directory %s"
 184                      server nnspool-spool-directory)
 185     t)))
 186
 187 (deffoo nnspool-request-article (id &optional group server buffer)
 188   "Select article by message ID (or number)."
 189   (nnspool-possibly-change-directory group)
 190   (let ((nntp-server-buffer (or buffer nntp-server-buffer))
 191         file ag)
 192     (if (stringp id)
 193         ;; This is a Message-ID.
 194         (when (setq ag (nnspool-find-id id))
 195           (setq file (nnspool-article-pathname (car ag) (cdr ag))))
 196       (setq file (nnspool-article-pathname nnspool-current-group id)))
 197     (and file
 198          (file-exists-p file)
 199          (not (file-directory-p file))
 200          (save-excursion (nnspool-find-file file))
 201          ;; We return the article number and group name.
 202          (if (numberp id)
 203              (cons nnspool-current-group id)
 204            ag))))
 205
 206 (deffoo nnspool-request-body (id &optional group server)
 207   "Select article body by message ID (or number)."
 208   (nnspool-possibly-change-directory group)
 209   (let ((res (nnspool-request-article id)))
 210     (when res
 211       (save-excursion
 212         (set-buffer nntp-server-buffer)
 213         (goto-char (point-min))
 214         (when (search-forward "\n\n" nil t)
 215           (delete-region (point-min) (point)))
 216         res))))
 217
 218 (deffoo nnspool-request-head (id &optional group server)
 219   "Select article head by message ID (or number)."
 220   (nnspool-possibly-change-directory group)
 221   (let ((res (nnspool-request-article id)))
 222     (when res
 223       (save-excursion
 224         (set-buffer nntp-server-buffer)
 225         (goto-char (point-min))
 226         (when (search-forward "\n\n" nil t)
 227           (delete-region (1- (point)) (point-max)))
 228         (nnheader-fold-continuation-lines)))
 229     res))
 230
 231 (deffoo nnspool-request-group (group &optional server dont-check)
 232   "Select news GROUP."
 233   (let ((pathname (nnspool-article-pathname group))
 234         dir)
 235     (if (not (file-directory-p pathname))
 236         (nnheader-report
 237          'nnspool "Invalid group name (no such directory): %s" group)
 238       (setq nnspool-current-directory pathname)
 239       (nnheader-report 'nnspool "Selected group %s" group)
 240       (if dont-check
 241           (progn
 242             (nnheader-report 'nnspool "Selected group %s" group)
 243             t)
 244         ;; Yes, completely empty spool directories *are* possible.
 245         ;; Fix by Sudish Joseph <joseph@cis.ohio-state.edu>
 246         (when (setq dir (directory-files pathname nil "^[0-9]+$" t))
 247           (setq dir
 248                 (sort (mapcar (lambda (name) (string-to-int name)) dir) '<)))
 249         (if dir
 250             (nnheader-insert
 251              "211 %d %d %d %s\n" (length dir) (car dir)
 252              (progn (while (cdr dir) (setq dir (cdr dir))) (car dir))
 253              group)
 254           (nnheader-report 'nnspool "Empty group %s" group)
 255           (nnheader-insert "211 0 0 0 %s\n" group))))))
 256
 257 (deffoo nnspool-request-type (group &optional article)
 258   'news)
 259
 260 (deffoo nnspool-close-group (group &optional server)
 261   t)
 262
 263 (deffoo nnspool-request-list (&optional server)
 264   "List active newsgroups."
 265   (save-excursion
 266     (or (nnspool-find-file nnspool-active-file)
 267         (nnheader-report 'nnspool (nnheader-file-error nnspool-active-file)))))
 268
 269 (deffoo nnspool-request-list-newsgroups (&optional server)
 270   "List newsgroups (defined in NNTP2)."
 271   (save-excursion
 272     (or (nnspool-find-file nnspool-newsgroups-file)
 273         (nnheader-report 'nnspool (nnheader-file-error
 274                                    nnspool-newsgroups-file)))))
 275
 276 (deffoo nnspool-request-list-distributions (&optional server)
 277   "List distributions (defined in NNTP2)."
 278   (save-excursion
 279     (or (nnspool-find-file nnspool-distributions-file)
 280         (nnheader-report 'nnspool (nnheader-file-error
 281                                    nnspool-distributions-file)))))
 282
 283 ;; Suggested by Hallvard B Furuseth <h.b.furuseth@usit.uio.no>.
 284 (deffoo nnspool-request-newgroups (date &optional server)
 285   "List groups created after DATE."
 286   (if (nnspool-find-file nnspool-active-times-file)
 287       (save-excursion
 288         ;; Find the last valid line.
 289         (goto-char (point-max))
 290         (while (and (not (looking-at
 291                           "\\([^ ]+\\) +\\([0-9]+\\)[0-9][0-9][0-9] "))
 292                     (zerop (forward-line -1))))
 293         (let ((seconds (time-to-seconds (date-to-time date)))
 294               groups)
 295           ;; Go through lines and add the latest groups to a list.
 296           (while (and (looking-at "\\([^ ]+\\) +[0-9]+ ")
 297                       (progn
 298                         ;; We insert a .0 to make the list reader
 299                         ;; interpret the number as a float.  It is far
 300                         ;; too big to be stored in a lisp integer.
 301                         (goto-char (1- (match-end 0)))
 302                         (insert ".0")
 303                         (> (progn
 304                              (goto-char (match-end 1))
 305                              (read (current-buffer)))
 306                            seconds))
 307                       (push (buffer-substring
 308                              (match-beginning 1) (match-end 1))
 309                             groups)
 310                       (zerop (forward-line -1))))
 311           (erase-buffer)
 312           (while groups
 313             (insert (car groups) " 0 0 y\n")
 314             (setq groups (cdr groups))))
 315         t)
 316     nil))
 317
 318 (deffoo nnspool-request-post (&optional server)
 319   "Post a new news in current buffer."
 320   (save-excursion
 321     (let* ((process-connection-type nil) ; t bugs out on Solaris
 322            (inews-buffer (generate-new-buffer " *nnspool post*"))
 323            (proc
 324             (condition-case err
 325                 (apply 'start-process "*nnspool inews*" inews-buffer
 326                        nnspool-inews-program nnspool-inews-switches)
 327               (error
 328                (nnheader-report 'nnspool "inews error: %S" err)))))
 329       (if (not proc)
 330           ;; The inews program failed.
 331           ()
 332         (nnheader-report 'nnspool "")
 333         (set-process-sentinel proc 'nnspool-inews-sentinel)
 334         (mm-with-unibyte-current-buffer
 335           (process-send-region proc (point-min) (point-max)))
 336         ;; We slap a condition-case around this, because the process may
 337         ;; have exited already...
 338         (ignore-errors
 339           (process-send-eof proc))
 340         t))))
 341
 342
 343 \f
 344 ;;; Internal functions.
 345
 346 (defun nnspool-inews-sentinel (proc status)
 347   (save-excursion
 348     (set-buffer (process-buffer proc))
 349     (goto-char (point-min))
 350     (if (or (zerop (buffer-size))
 351             (search-forward "spooled" nil t))
 352         (kill-buffer (current-buffer))
 353       ;; Make status message by folding lines.
 354       (while (re-search-forward "[ \t\n]+" nil t)
 355         (replace-match " " t t))
 356       (nnheader-report 'nnspool "%s" (buffer-string))
 357       (nnheader-message 5 "nnspool: %s" nnspool-status-string)
 358       (ding)
 359       (run-hooks 'nnspool-rejected-article-hook))))
 360
 361 (defun nnspool-retrieve-headers-with-nov (articles &optional fetch-old)
 362   (if (or gnus-nov-is-evil nnspool-nov-is-evil)
 363       nil
 364     (let ((nov (nnheader-group-pathname
 365                 nnspool-current-group nnspool-nov-directory ".overview"))
 366           (arts articles)
 367           (nnheader-file-coding-system nnspool-file-coding-system)
 368           last)
 369       (if (not (file-exists-p nov))
 370           ()
 371         (save-excursion
 372           (set-buffer nntp-server-buffer)
 373           (erase-buffer)
 374           (if nnspool-sift-nov-with-sed
 375               (nnspool-sift-nov-with-sed articles nov)
 376             (nnheader-insert-file-contents nov)
 377             (if (and fetch-old
 378                      (not (numberp fetch-old)))
 379                 t                       ; We want all the headers.
 380               (ignore-errors
 381                 ;; Delete unwanted NOV lines.
 382                 (nnheader-nov-delete-outside-range
 383                  (if fetch-old (max 1 (- (car articles) fetch-old))
 384                    (car articles))
 385                  (car (last articles)))
 386                 ;; If the buffer is empty, this wasn't very successful.
 387                 (unless (zerop (buffer-size))
 388                   ;; We check what the last article number was.
 389                   ;; The NOV file may be out of sync with the articles
 390                   ;; in the group.
 391                   (forward-line -1)
 392                   (setq last (read (current-buffer)))
 393                   (if (= last (car articles))
 394                       ;; Yup, it's all there.
 395                       t
 396                     ;; Perhaps not.  We try to find the missing articles.
 397                     (while (and arts
 398                                 (<= last (car arts)))
 399                       (pop arts))
 400                     ;; The articles in `arts' are missing from the buffer.
 401                     (while arts
 402                       (nnspool-insert-nov-head (pop arts)))
 403                     t))))))))))
 404
 405 (defun nnspool-insert-nov-head (article)
 406   "Read the head of ARTICLE, convert to NOV headers, and insert."
 407   (save-excursion
 408     (let ((cur (current-buffer))
 409           buf)
 410       (setq buf (nnheader-set-temp-buffer " *nnspool head*"))
 411       (when (nnheader-insert-head
 412              (nnspool-article-pathname nnspool-current-group article))
 413         (nnheader-insert-article-line article)
 414         (let ((headers (nnheader-parse-head)))
 415           (set-buffer cur)
 416           (goto-char (point-max))
 417           (nnheader-insert-nov headers)))
 418       (kill-buffer buf))))
 419
 420 (defun nnspool-sift-nov-with-sed (articles file)
 421   (let ((first (car articles))
 422         (last (progn (while (cdr articles) (setq articles (cdr articles)))
 423                      (car articles))))
 424     (call-process "awk" nil t nil
 425                   (format "BEGIN {firstmsg=%d; lastmsg=%d;}\n $1 >= firstmsg && $1 <= lastmsg {print;}"
 426                           (1- first) (1+ last))
 427                   file)))
 428
 429 ;; Fixed by fdc@cliwe.ping.de (Frank D. Cringle).
 430 ;; Find out what group an article identified by a Message-ID is in.
 431 (defun nnspool-find-id (id)
 432   (save-excursion
 433     (set-buffer (get-buffer-create " *nnspool work*"))
 434     (erase-buffer)
 435     (ignore-errors
 436       (call-process "grep" nil t nil (regexp-quote id) nnspool-history-file))
 437     (goto-char (point-min))
 438     (prog1
 439         (when (looking-at "<[^>]+>[ \t]+[-0-9~]+[ \t]+\\([^ /\t\n]+\\)/\\([0-9]+\\)[ \t\n]")
 440           (cons (match-string 1) (string-to-int (match-string 2))))
 441       (kill-buffer (current-buffer)))))
 442
 443 (defun nnspool-find-file (file)
 444   "Insert FILE in server buffer safely."
 445   (set-buffer nntp-server-buffer)
 446   (erase-buffer)
 447   (condition-case ()
 448       (let ((coding-system-for-read nnspool-file-coding-system))
 449         (mm-insert-file-contents file)
 450         t)
 451     (file-error nil)))
 452
 453 (defun nnspool-possibly-change-directory (group)
 454   (if (not group)
 455       t
 456     (let ((pathname (nnspool-article-pathname group)))
 457       (if (file-directory-p pathname)
 458           (setq nnspool-current-directory pathname
 459                 nnspool-current-group group)
 460         (nnheader-report 'nnspool "No such newsgroup: %s" group)))))
 461
 462 (defun nnspool-article-pathname (group &optional article)
 463   "Find the file name for GROUP."
 464   (nnheader-group-pathname group nnspool-spool-directory article))
 465
 466 (provide 'nnspool)
 467
 468 ;;; arch-tag: bdac8d27-2934-4eee-bad0-49e6b90c0d05
 469 ;;; nnspool.el ends here