code.delx.au - gnu-emacs/blob - lisp/mail/mail-utils.el

   1 ;;; mail-utils.el --- utility functions used both by rmail and rnews
   2
   3 ;; Copyright (C) 1985 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: mail, news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Utility functions for mail and netnews handling.  These handle fine
  28 ;; points of header parsing.
  29
  30 ;;; Code:
  31
  32 ;;; We require lisp-mode to make sure that lisp-mode-syntax-table has
  33 ;;; been initialized.
  34 (require 'lisp-mode)
  35
  36 ;;;###autoload
  37 (defvar mail-use-rfc822 nil "\
  38 *If non-nil, use a full, hairy RFC822 parser on mail addresses.
  39 Otherwise, (the default) use a smaller, somewhat faster, and
  40 often correct parser.")
  41
  42 ;; Returns t if file FILE is an Rmail file.
  43 ;;;###autoload
  44 (defun mail-file-babyl-p (file)
  45   (let ((buf (generate-new-buffer " *rmail-file-p*")))
  46     (unwind-protect
  47         (save-excursion
  48           (set-buffer buf)
  49           (insert-file-contents file nil 0 100)
  50           (looking-at "BABYL OPTIONS:"))
  51       (kill-buffer buf))))
  52
  53 (defun mail-string-delete (string start end)
  54   "Returns a string containing all of STRING except the part
  55 from START (inclusive) to END (exclusive)."
  56   (if (null end) (substring string 0 start)
  57     (concat (substring string 0 start)
  58             (substring string end nil))))
  59
  60 (defun mail-strip-quoted-names (address)
  61   "Delete comments and quoted strings in an address list ADDRESS.
  62 Also delete leading/trailing whitespace and replace FOO <BAR> with just BAR.
  63 Return a modified address list."
  64   (if (null address)
  65       nil
  66     (if mail-use-rfc822
  67         (progn (require 'rfc822)
  68                (mapconcat 'identity (rfc822-addresses address) ", "))
  69       (let (pos)
  70        (string-match "\\`[ \t\n]*" address)
  71        ;; strip surrounding whitespace
  72        (setq address (substring address
  73                                 (match-end 0)
  74                                 (string-match "[ \t\n]*\\'" address
  75                                               (match-end 0))))
  76
  77        ;; Detect nested comments.
  78        (if (string-match "[ \t]*(\\([^)\\]\\|\\\\.\\|\\\\\n\\)*(" address)
  79            ;; Strip nested comments.
  80            (save-excursion
  81              (debug)
  82              (set-buffer (get-buffer-create " *temp*"))
  83              (erase-buffer)
  84              (insert address)
  85              (set-syntax-table lisp-mode-syntax-table)
  86              (goto-char 1)
  87              (while (search-forward "(" nil t)
  88                (forward-char -1)
  89                (skip-chars-backward " \t")
  90                (delete-region (point)
  91                               (save-excursion
  92                                 (condition-case ()
  93                                     (forward-sexp 1)
  94                                   (error (goto-char (point-max))))
  95                                   (point))))
  96              (setq address (buffer-string))
  97              (erase-buffer))
  98          ;; Strip non-nested comments an easier way.
  99          (while (setq pos (string-match
 100                             ;; This doesn't hack rfc822 nested comments
 101                             ;;  `(xyzzy (foo) whinge)' properly.  Big deal.
 102                             "[ \t]*(\\([^)\\]\\|\\\\.\\|\\\\\n\\)*)"
 103                             address))
 104            (setq address
 105                  (mail-string-delete address
 106                                      pos (match-end 0)))))
 107
 108        ;; strip `quoted' names (This is supposed to hack `"Foo Bar" <bar@host>')
 109        (setq pos 0)
 110        (while (setq pos (string-match
 111                           "[ \t]*\"\\([^\"\\]\\|\\\\.\\|\\\\\n\\)*\"[ \t\n]*"
 112                           address pos))
 113          ;; If the next thing is "@", we have "foo bar"@host.  Leave it.
 114          (if (and (> (length address) (match-end 0))
 115                   (= (aref address (match-end 0)) ?@))
 116              (setq pos (match-end 0))
 117            (setq address
 118                  (mail-string-delete address
 119                                      pos (match-end 0)))))
 120        ;; Retain only part of address in <> delims, if there is such a thing.
 121        (while (setq pos (string-match "\\(,\\s-*\\|\\`\\)[^,]*<\\([^>,]*>\\)"
 122                                       address))
 123          (let ((junk-beg (match-end 1))
 124                (junk-end (match-beginning 2))
 125                (close (match-end 0)))
 126            (setq address (mail-string-delete address (1- close) close))
 127            (setq address (mail-string-delete address junk-beg junk-end))))
 128        address))))
 129
 130 (or (and (boundp 'rmail-default-dont-reply-to-names)
 131          (not (null rmail-default-dont-reply-to-names)))
 132     (setq rmail-default-dont-reply-to-names "info-"))
 133
 134 ; rmail-dont-reply-to-names is defined in loaddefs
 135 (defun rmail-dont-reply-to (userids)
 136   "Returns string of mail addresses USERIDS sans any recipients
 137 that start with matches for `rmail-dont-reply-to-names'.
 138 Usenet paths ending in an element that matches are removed also."
 139   (if (null rmail-dont-reply-to-names)
 140       (setq rmail-dont-reply-to-names
 141             (concat (if rmail-default-dont-reply-to-names
 142                         (concat rmail-default-dont-reply-to-names "\\|")
 143                         "")
 144                     (concat (regexp-quote (user-login-name))
 145                             "\\>"))))
 146   (let ((match (concat "\\(^\\|,\\)[ \t\n]*\\([^,\n]*!\\|\\)\\("
 147                        rmail-dont-reply-to-names
 148                        "\\)"))
 149         (case-fold-search t)
 150         pos epos)
 151     (while (setq pos (string-match match userids))
 152       (if (> pos 0) (setq pos (match-beginning 2)))
 153       (setq epos
 154             ;; Delete thru the next comma, plus whitespace after.
 155             (if (string-match ",[ \t\n]+" userids (match-end 0))
 156                 (match-end 0)
 157               (length userids)))
 158       (setq userids
 159             (mail-string-delete
 160               userids pos epos)))
 161     ;; get rid of any trailing commas
 162     (if (setq pos (string-match "[ ,\t\n]*\\'" userids))
 163         (setq userids (substring userids 0 pos)))
 164     ;; remove leading spaces. they bother me.
 165     (if (string-match "\\s *" userids)
 166         (substring userids (match-end 0))
 167       userids)))
 168 \f
 169 ;;;###autoload
 170 (defun mail-fetch-field (field-name &optional last all)
 171   "Return the value of the header field FIELD-NAME.
 172 The buffer is expected to be narrowed to just the headers of the message.
 173 If second arg LAST is non-nil, use the last such field if there are several.
 174 If third arg ALL is non-nil, concatenate all such fields with commas between."
 175   (save-excursion
 176     (goto-char (point-min))
 177     (let ((case-fold-search t)
 178           (name (concat "^" (regexp-quote field-name) "[ \t]*:[ \t]*")))
 179       (if all
 180           (let ((value ""))
 181             (while (re-search-forward name nil t)
 182               (let ((opoint (point)))
 183                 (while (progn (forward-line 1)
 184                               (looking-at "[ \t]")))
 185                 ;; Back up over newline, then trailing spaces or tabs
 186                 (forward-char -1)
 187                 (skip-chars-backward " \t" opoint)
 188                 (setq value (concat value
 189                                     (if (string= value "") "" ", ")
 190                                     (buffer-substring-no-properties
 191                                      opoint (point))))))
 192             (and (not (string= value "")) value))
 193         (if (re-search-forward name nil t)
 194             (progn
 195               (if last (while (re-search-forward name nil t)))
 196               (let ((opoint (point)))
 197                 (while (progn (forward-line 1)
 198                               (looking-at "[ \t]")))
 199                 ;; Back up over newline, then trailing spaces or tabs
 200                 (forward-char -1)
 201                 (skip-chars-backward " \t" opoint)
 202                 (buffer-substring-no-properties opoint (point)))))))))
 203 \f
 204 ;; Parse a list of tokens separated by commas.
 205 ;; It runs from point to the end of the visible part of the buffer.
 206 ;; Whitespace before or after tokens is ignored,
 207 ;; but whitespace within tokens is kept.
 208 (defun mail-parse-comma-list ()
 209   (let (accumulated
 210         beg)
 211     (skip-chars-forward " ")
 212     (while (not (eobp))
 213       (setq beg (point))
 214       (skip-chars-forward "^,")
 215       (skip-chars-backward " ")
 216       (setq accumulated
 217             (cons (buffer-substring beg (point))
 218                   accumulated))
 219       (skip-chars-forward "^,")
 220       (skip-chars-forward ", "))
 221     accumulated))
 222
 223 (defun mail-comma-list-regexp (labels)
 224   (let (pos)
 225     (setq pos (or (string-match "[^ \t]" labels) 0))
 226     ;; Remove leading and trailing whitespace.
 227     (setq labels (substring labels pos (string-match "[ \t]*$" labels pos)))
 228     ;; Change each comma to \|, and flush surrounding whitespace.
 229     (while (setq pos (string-match "[ \t]*,[ \t]*" labels))
 230       (setq labels
 231             (concat (substring labels 0 pos)
 232                     "\\|"
 233                     (substring labels (match-end 0))))))
 234   labels)
 235 \f
 236 (defun mail-rfc822-time-zone (time)
 237   (let* ((sec (or (car (current-time-zone time)) 0))
 238          (absmin (/ (abs sec) 60)))
 239     (format "%c%02d%02d" (if (< sec 0) ?- ?+) (/ absmin 60) (% absmin 60))))
 240
 241 (defun mail-rfc822-date ()
 242   (let* ((time (current-time))
 243          (s (current-time-string time)))
 244     (string-match "[^ ]+ +\\([^ ]+\\) +\\([^ ]+\\) \\([^ ]+\\) \\([^ ]+\\)" s)
 245     (concat (substring s (match-beginning 2) (match-end 2)) " "
 246             (substring s (match-beginning 1) (match-end 1)) " "
 247             (substring s (match-beginning 4) (match-end 4)) " "
 248             (substring s (match-beginning 3) (match-end 3)) " "
 249             (mail-rfc822-time-zone time))))
 250
 251 (provide 'mail-utils)
 252
 253 ;;; mail-utils.el ends here