code.delx.au - gnu-emacs/blob - lisp/fast-lock.el

   1 ;;; fast-lock.el --- Automagic text properties caching for fast Font Lock mode.
   2
   3 ;; Copyright (C) 1994, 1995, 1996 Free Software Foundation, Inc.
   4
   5 ;; Author: Simon Marshall <simon@gnu.ai.mit.edu>
   6 ;; Keywords: faces files
   7 ;; Version: 3.10
   8
   9 ;;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Purpose:
  29 ;;
  30 ;; To make visiting a file in `font-lock-mode' faster by restoring its face
  31 ;; text properties from automatically saved associated Font Lock cache files.
  32 ;;
  33 ;; See caveats and feedback below.
  34 ;; See also the lazy-lock package.  (But don't use the two at the same time!)
  35
  36 ;; Installation:
  37 ;;
  38 ;; Put in your ~/.emacs:
  39 ;;
  40 ;; (setq font-lock-support-mode 'fast-lock-mode)
  41 ;;
  42 ;; Start up a new Emacs and use font-lock as usual (except that you can use the
  43 ;; so-called "gaudier" fontification regexps on big files without frustration).
  44 ;;
  45 ;; When you visit a file (which has `font-lock-mode' enabled) that has a
  46 ;; corresponding Font Lock cache file associated with it, the Font Lock cache
  47 ;; will be loaded from that file instead of being generated by Font Lock code.
  48
  49 ;; Caveats:
  50 ;;
  51 ;; A cache will be saved when visiting a compressed file using crypt++, but not
  52 ;; be read.  This is a "feature"/"consequence"/"bug" of crypt++.
  53 ;;
  54 ;; Version control packages are likely to stamp all over file modification
  55 ;; times.  Therefore the act of checking out may invalidate a cache.
  56
  57 ;; Feedback:
  58 ;;
  59 ;; Feedback is welcome.
  60 ;; To submit a bug report (or make comments) please use the mechanism provided:
  61 ;;
  62 ;; M-x fast-lock-submit-bug-report RET
  63 \f
  64 ;; History:
  65 ;;
  66 ;; 0.02--1.00:
  67 ;; - Changed name from turbo-prop to fast-lock.  Automagic for font-lock only
  68 ;; - Made `fast-lock-mode' a minor mode, like G. Dinesh Dutt's fss-mode
  69 ;; 1.00--1.01:
  70 ;; - Turn on `fast-lock-mode' only if `buffer-file-name' or `interactive-p'
  71 ;; - Made `fast-lock-file-name' use `buffer-name' if `buffer-file-name' is nil
  72 ;; - Moved save-all conditions to `fast-lock-save-cache'
  73 ;; - Added `fast-lock-save-text-properties' to `kill-buffer-hook'
  74 ;; 1.01--2.00: complete rewrite---not worth the space to document
  75 ;; - Changed structure of text properties cache and threw out file mod checks
  76 ;; 2.00--2.01:
  77 ;; - Made `condition-case' forms understand `quit'.
  78 ;; - Made `fast-lock' require `font-lock'
  79 ;; - Made `fast-lock-cache-name' chase links (from Ben Liblit)
  80 ;; 2.01--3.00:
  81 ;; - Changed structure of cache to include `font-lock-keywords' (from rms)
  82 ;; - Changed `fast-lock-cache-mechanisms' to `fast-lock-cache-directories'
  83 ;; - Removed `fast-lock-read-others'
  84 ;; - Made `fast-lock-read-cache' ignore cache owner
  85 ;; - Made `fast-lock-save-cache-external' create cache directory
  86 ;; - Made `fast-lock-save-cache-external' save `font-lock-keywords'
  87 ;; - Made `fast-lock-cache-data' check `font-lock-keywords'
  88 ;; 3.00--3.01: incorporated port of 2.00 to Lucid, made by Barry Warsaw
  89 ;; - Package now provides itself
  90 ;; - Lucid: Use `font-lock-any-extents-p' for `font-lock-any-properties-p'
  91 ;; - Lucid: Use `list-faces' for `face-list'
  92 ;; - Lucid: Added `set-text-properties'
  93 ;; - Lucid: Made `turn-on-fast-lock' pass 1 not t to `fast-lock-mode'
  94 ;; - Removed test for `fast-lock-mode' from `fast-lock-read-cache'
  95 ;; - Lucid: Added Lucid-specific `fast-lock-get-face-properties'
  96 ;; 3.01--3.02: now works with Lucid Emacs, thanks to Barry Warsaw
  97 ;; - Made `fast-lock-cache-name' map ":" to ";" for OS/2 (from Serganova Vera)
  98 ;; - Made `fast-lock-cache-name' use abbreviated file name (from Barry Warsaw)
  99 ;; - Lucid: Separated handlers for `error' and `quit' for `condition-case'
 100 ;; 3.02--3.03:
 101 ;; - Changed `fast-lock-save-cache-external' to `fast-lock-save-cache-data'
 102 ;; - Lucid: Added Lucid-specific `fast-lock-set-face-properties'
 103 ;; 3.03--3.04:
 104 ;; - Corrected `subrp' test of Lucid code
 105 ;; - Replaced `font-lock-any-properties-p' with `text-property-not-all'
 106 ;; - Lucid: Made `fast-lock-set-face-properties' put `text-prop' on extents
 107 ;; - Made `fast-lock-cache-directories' a regexp alist (from Colin Rafferty)
 108 ;; - Made `fast-lock-cache-directory' to return a usable cache file directory
 109 ;; 3.04--3.05:
 110 ;; - Lucid: Fix for XEmacs 19.11 `text-property-not-all'
 111 ;; - Replaced `subrp' test of Lucid code with `emacs-version' `string-match'
 112 ;; - Made `byte-compile-warnings' omit `unresolved' on compilation
 113 ;; - Made `fast-lock-save-cache-data' use a buffer (from Rick Sladkey)
 114 ;; - Reverted to old `fast-lock-get-face-properties' (from Rick Sladkey)
 115 ;; 3.05--3.06: incorporated hack of 3.03, made by Jonathan Stigelman (Stig)
 116 ;; - Reverted to 3.04 version of `fast-lock-get-face-properties'
 117 ;; - XEmacs: Removed `list-faces' `defalias'
 118 ;; - Made `fast-lock-mode' and `turn-on-fast-lock' succeed `autoload' cookies
 119 ;; - Added `fast-lock-submit-bug-report'
 120 ;; - Renamed `fast-lock-save-size' to `fast-lock-minimum-size'
 121 ;; - Made `fast-lock-save-cache' output a message if no save ever attempted
 122 ;; - Made `fast-lock-save-cache-data' output a message if save attempted
 123 ;; - Made `fast-lock-cache-data' output a message if load attempted
 124 ;; - Made `fast-lock-save-cache-data' do `condition-case' not `unwind-protect'
 125 ;; - Made `fast-lock-save-cache' and `fast-lock-read-cache' return nothing
 126 ;; - Made `fast-lock-save-cache' check `buffer-modified-p' (Stig)
 127 ;; - Added `fast-lock-save-events'
 128 ;; - Added `fast-lock-after-save-hook' to `after-save-hook' (Stig)
 129 ;; - Added `fast-lock-kill-buffer-hook' to `kill-buffer-hook'
 130 ;; - Changed `fast-lock-save-caches' to `fast-lock-kill-emacs-hook'
 131 ;; - Added `fast-lock-kill-emacs-hook' to `kill-emacs-hook'
 132 ;; - Made `fast-lock-save-cache' check `verify-visited-file-modtime' (Stig)
 133 ;; - Made `visited-file-modtime' be the basis of the timestamp (Stig)
 134 ;; - Made `fast-lock-save-cache-1' and `fast-lock-cache-data' use/reformat it
 135 ;; - Added `fast-lock-cache-filename' to keep track of the cache file name
 136 ;; - Added `fast-lock-after-fontify-buffer'
 137 ;; - Added `fast-lock-save-faces' list of faces to save (idea from Stig/Tibor)
 138 ;; - Made `fast-lock-get-face-properties' functions use it
 139 ;; - XEmacs: Made `fast-lock-set-face-properties' do extents the Font Lock way
 140 ;; - XEmacs: Removed fix for `text-property-not-all' (19.11 support dropped)
 141 ;; - Made `fast-lock-mode' ensure `font-lock-mode' is on
 142 ;; - Made `fast-lock-save-cache' do `cdr-safe' not `cdr' (from Dave Foster)
 143 ;; - Made `fast-lock-save-cache' do `set-buffer' first (from Dave Foster)
 144 ;; - Made `fast-lock-save-cache' loop until saved or quit (from Georg Nikodym)
 145 ;; - Made `fast-lock-cache-data' check `buffer-modified-p'
 146 ;; - Made `fast-lock-cache-data' do `font-lock-compile-keywords' if necessary
 147 ;; - XEmacs: Made `font-lock-compile-keywords' `defalias'
 148 ;; 3.06--3.07:
 149 ;; - XEmacs: Add `fast-lock-after-fontify-buffer' to the Font Lock hook
 150 ;; - Made `fast-lock-cache-name' explain the use of `directory-abbrev-alist'
 151 ;; - Made `fast-lock-mode' use `buffer-file-truename' not `buffer-file-name'
 152 ;; 3.07--3.08:
 153 ;; - Made `fast-lock-read-cache' set `fast-lock-cache-filename'
 154 ;; 3.08--3.09:
 155 ;; - Made `fast-lock-save-cache' cope if `fast-lock-minimum-size' is an a list
 156 ;; - Made `fast-lock-mode' respect the value of `font-lock-inhibit-thing-lock'
 157 ;; - Added `fast-lock-after-unfontify-buffer'
 158 ;; 3.09--3.10:
 159 ;; - Rewrite for Common Lisp macros
 160 ;; - Made fast-lock.el barf on a crap 8+3 pseudo-OS (Eli Zaretskii help)
 161 ;; - XEmacs: Made `add-minor-mode' succeed `autoload' cookie
 162 ;; - XEmacs: Made `fast-lock-save-faces' default to `font-lock-face-list'
 163 ;; - Made `fast-lock-save-cache' use `font-lock-value-in-major-mode'
 164 ;; - Wrap with `save-buffer-state' (Ray Van Tassle report)
 165 ;; - Made `fast-lock-mode' wrap `font-lock-support-mode'
 166 \f
 167 (require 'font-lock)
 168
 169 ;; Make sure fast-lock.el is supported.
 170 (if (and (eq system-type 'ms-dos) (not (msdos-long-file-names)))
 171     (error "`fast-lock' was written for long file name systems"))
 172
 173 (eval-when-compile
 174   ;;
 175   ;; We don't do this at the top-level as we only use non-autoloaded macros.
 176   (require 'cl)
 177   ;;
 178   ;; I prefer lazy code---and lazy mode.
 179   (setq byte-compile-dynamic t byte-compile-dynamic-docstrings t)
 180   ;;
 181   ;; We use this to preserve or protect things when modifying text properties.
 182   (defmacro save-buffer-state (varlist &rest body)
 183     "Bind variables according to VARLIST and eval BODY restoring buffer state."
 184     (` (let* ((,@ (append varlist
 185                    '((modified (buffer-modified-p))
 186                      (inhibit-read-only t) (buffer-undo-list t)
 187                      before-change-functions after-change-functions
 188                      deactivate-mark buffer-file-name buffer-file-truename))))
 189          (,@ body)
 190          (when (and (not modified) (buffer-modified-p))
 191            (set-buffer-modified-p nil)))))
 192   (put 'save-buffer-state 'lisp-indent-function 1))
 193
 194 (defun fast-lock-submit-bug-report ()
 195   "Submit via mail a bug report on fast-lock.el."
 196   (interactive)
 197   (let ((reporter-prompt-for-summary-p t))
 198     (reporter-submit-bug-report "simon@gnu.ai.mit.edu" "fast-lock 3.10"
 199      '(fast-lock-cache-directories fast-lock-minimum-size
 200        fast-lock-save-others fast-lock-save-events fast-lock-save-faces)
 201      nil nil
 202      (concat "Hi Si.,
 203
 204 I want to report a bug.  I've read the `Bugs' section of `Info' on Emacs, so I
 205 know how to make a clear and unambiguous report.  To reproduce the bug:
 206
 207 Start a fresh Emacs via `" invocation-name " -no-init-file -no-site-file'.
 208 In the `*scratch*' buffer, evaluate:"))))
 209
 210 (defvar fast-lock-mode nil)
 211 (defvar fast-lock-cache-timestamp nil)  ; for saving/reading
 212 (defvar fast-lock-cache-filename nil)   ; for deleting
 213 \f
 214 ;; User Variables:
 215
 216 (defvar fast-lock-cache-directories '("." "~/.emacs-flc")
 217 ; - `internal', keep each file's Font Lock cache file in the same file.
 218 ; - `external', keep each file's Font Lock cache file in the same directory.
 219   "*Directories in which Font Lock cache files are saved and read.
 220 Each item should be either DIR or a cons pair of the form (REGEXP . DIR) where
 221 DIR is a directory name (relative or absolute) and REGEXP is a regexp.
 222
 223 An attempt will be made to save or read Font Lock cache files using these items
 224 until one succeeds (i.e., until a readable or writable one is found).  If an
 225 item contains REGEXP, DIR is used only if the buffer file name matches REGEXP.
 226 For example:
 227
 228  (let ((home (expand-file-name (abbreviate-file-name (file-truename \"~/\")))))
 229    (list (cons (concat \"^\" (regexp-quote home)) \".\") \"~/.emacs-flc\"))
 230     =>
 231  ((\"^/your/true/home/directory/\" . \".\") \"~/.emacs-flc\")
 232
 233 would cause a file's current directory to be used if the file is under your
 234 home directory hierarchy, or otherwise the absolute directory `~/.emacs-flc'.")
 235
 236 (defvar fast-lock-minimum-size (* 25 1024)
 237   "*Minimum size of a buffer for cached fontification.
 238 Only buffers more than this can have associated Font Lock cache files saved.
 239 If nil, means cache files are never created.
 240 If a list, each element should be a cons pair of the form (MAJOR-MODE . SIZE),
 241 where MAJOR-MODE is a symbol or t (meaning the default).  For example:
 242  ((c-mode . 25600) (c++-mode . 25600) (rmail-mode . 1048576))
 243 means that the minimum size is 25K for buffers in C or C++ modes, one megabyte
 244 for buffers in Rmail mode, and size is irrelevant otherwise.")
 245
 246 (defvar fast-lock-save-events '(kill-buffer kill-emacs)
 247   "*Events under which caches will be saved.
 248 Valid events are `save-buffer', `kill-buffer' and `kill-emacs'.
 249 If concurrent editing sessions use the same associated cache file for a file's
 250 buffer, then you should add `save-buffer' to this list.")
 251
 252 (defvar fast-lock-save-others t
 253   "*If non-nil, save Font Lock cache files irrespective of file owner.
 254 If nil, means only buffer files known to be owned by you can have associated
 255 Font Lock cache files saved.  Ownership may be unknown for networked files.")
 256
 257 (defvar fast-lock-save-faces
 258   (when (save-match-data (string-match "XEmacs" (emacs-version)))
 259     ;; XEmacs uses extents for everything, so we have to pick the right ones.
 260     font-lock-face-list)
 261   "Faces that will be saved in a Font Lock cache file.
 262 If nil, means information for all faces will be saved.")
 263 \f
 264 ;; User Functions:
 265
 266 ;;;###autoload
 267 (defun fast-lock-mode (&optional arg)
 268   "Toggle Fast Lock mode.
 269 With arg, turn Fast Lock mode on if and only if arg is positive and the buffer
 270 is associated with a file.  Enable it automatically in your `~/.emacs' by:
 271
 272  (setq font-lock-support-mode 'fast-lock-mode)
 273
 274 If Fast Lock mode is enabled, and the current buffer does not contain any text
 275 properties, any associated Font Lock cache is used if its timestamp matches the
 276 buffer's file, and its `font-lock-keywords' match those that you are using.
 277
 278 Font Lock caches may be saved:
 279  - When you save the file's buffer.
 280  - When you kill an unmodified file's buffer.
 281  - When you exit Emacs, for all unmodified or saved buffers.
 282 Depending on the value of `fast-lock-save-events'.
 283 See also the commands `fast-lock-read-cache' and `fast-lock-save-cache'.
 284
 285 Use \\[font-lock-fontify-buffer] to fontify the buffer if the cache is bad.
 286
 287 Various methods of control are provided for the Font Lock cache.  In general,
 288 see variable `fast-lock-cache-directories' and function `fast-lock-cache-name'.
 289 For saving, see variables `fast-lock-minimum-size', `fast-lock-save-events',
 290 `fast-lock-save-others' and `fast-lock-save-faces'.
 291
 292 Use \\[fast-lock-submit-bug-report] to send bug reports or feedback."
 293   (interactive "P")
 294   ;; Only turn on if we are visiting a file.  We could use `buffer-file-name',
 295   ;; but many packages temporarily wrap that to nil when doing their own thing.
 296   (set (make-local-variable 'fast-lock-mode)
 297        (and buffer-file-truename
 298             (not (memq 'fast-lock-mode font-lock-inhibit-thing-lock))
 299             (if arg (> (prefix-numeric-value arg) 0) (not fast-lock-mode))))
 300   (if (and fast-lock-mode (not font-lock-mode))
 301       ;; Turned on `fast-lock-mode' rather than `font-lock-mode'.
 302       (let ((font-lock-support-mode 'fast-lock-mode))
 303         (font-lock-mode t))
 304     ;; Let's get down to business.
 305     (set (make-local-variable 'fast-lock-cache-timestamp) nil)
 306     (set (make-local-variable 'fast-lock-cache-filename) nil)
 307     (when (and fast-lock-mode (not font-lock-fontified))
 308       (fast-lock-read-cache))))
 309
 310 (defun fast-lock-read-cache ()
 311   "Read the Font Lock cache for the current buffer.
 312
 313 The following criteria must be met for a Font Lock cache file to be read:
 314  - Fast Lock mode must be turned on in the buffer.
 315  - The buffer must not be modified.
 316  - The buffer's `font-lock-keywords' must match the cache's.
 317  - The buffer file's timestamp must match the cache's.
 318  - Criteria imposed by `fast-lock-cache-directories'.
 319
 320 See `fast-lock-mode'."
 321   (interactive)
 322   (let ((directories fast-lock-cache-directories)
 323         (modified (buffer-modified-p)) (inhibit-read-only t)
 324         (fontified font-lock-fontified))
 325     (set (make-local-variable 'font-lock-fontified) nil)
 326     ;; Keep trying directories until fontification is turned off.
 327     (while (and directories (not font-lock-fontified))
 328       (let ((directory (fast-lock-cache-directory (car directories) nil)))
 329         (condition-case nil
 330             (when directory
 331               (setq fast-lock-cache-filename (fast-lock-cache-name directory))
 332               (when (file-readable-p fast-lock-cache-filename)
 333                 (load fast-lock-cache-filename t t t)))
 334           (error nil) (quit nil))
 335         (setq directories (cdr directories))))
 336     ;; Unset `fast-lock-cache-filename', and restore `font-lock-fontified', if
 337     ;; we don't use a cache.  (Note that `fast-lock-cache-data' sets the value
 338     ;; of `fast-lock-cache-timestamp'.)
 339     (set-buffer-modified-p modified)
 340     (unless font-lock-fontified
 341       (setq fast-lock-cache-filename nil font-lock-fontified fontified))))
 342
 343 (defun fast-lock-save-cache (&optional buffer)
 344   "Save the Font Lock cache of BUFFER or the current buffer.
 345
 346 The following criteria must be met for a Font Lock cache file to be saved:
 347  - Fast Lock mode must be turned on in the buffer.
 348  - The event must be one of `fast-lock-save-events'.
 349  - The buffer must be at least `fast-lock-minimum-size' bytes long.
 350  - The buffer file must be owned by you, or `fast-lock-save-others' must be t.
 351  - The buffer must contain at least one `face' text property.
 352  - The buffer must not be modified.
 353  - The buffer file's timestamp must be the same as the file's on disk.
 354  - The on disk file's timestamp must be different than the buffer's cache.
 355  - Criteria imposed by `fast-lock-cache-directories'.
 356
 357 See `fast-lock-mode'."
 358   (interactive)
 359   (save-excursion
 360     (when buffer
 361       (set-buffer buffer))
 362     (let ((min-size (font-lock-value-in-major-mode fast-lock-minimum-size))
 363           (file-timestamp (visited-file-modtime)) (saved nil))
 364       (when (and fast-lock-mode
 365              ;;
 366              ;; "Only save if the buffer matches the file, the file has
 367              ;; changed, and it was changed by the current emacs session."
 368              ;;
 369              ;; Only save if the buffer is not modified,
 370              ;; (i.e., so we don't save for something not on disk)
 371              (not (buffer-modified-p))
 372              ;; and the file's timestamp is the same as the buffer's,
 373              ;; (i.e., someone else hasn't written the file in the meantime)
 374              (verify-visited-file-modtime (current-buffer))
 375              ;; and the file's timestamp is different from the cache's.
 376              ;; (i.e., a save has occurred since the cache was read)
 377              (not (equal fast-lock-cache-timestamp file-timestamp))
 378              ;;
 379              ;; Only save if user's restrictions are satisfied.
 380              (and min-size (>= (buffer-size) min-size))
 381              (or fast-lock-save-others
 382                  (eq (user-uid) (nth 2 (file-attributes buffer-file-name))))
 383              ;;
 384              ;; Only save if there are `face' properties to save.
 385              (text-property-not-all (point-min) (point-max) 'face nil))
 386         ;;
 387         ;; Try each directory until we manage to save or the user quits.
 388         (let ((directories fast-lock-cache-directories))
 389           (while (and directories (memq saved '(nil error)))
 390             (let* ((dir (fast-lock-cache-directory (car directories) t))
 391                    (file (and dir (fast-lock-cache-name dir))))
 392               (when (and file (file-writable-p file))
 393                 (setq saved (fast-lock-save-cache-1 file file-timestamp)))
 394               (setq directories (cdr directories)))))))))
 395
 396 ;;;###autoload
 397 (defun turn-on-fast-lock ()
 398   "Unconditionally turn on Fast Lock mode."
 399   (fast-lock-mode t))
 400 \f
 401 ;;; API Functions:
 402
 403 (defun fast-lock-after-fontify-buffer ()
 404   ;; Delete the Font Lock cache file used to restore fontification, if any.
 405   (when fast-lock-cache-filename
 406     (if (file-writable-p fast-lock-cache-filename)
 407         (delete-file fast-lock-cache-filename)
 408       (message "File %s font lock cache cannot be deleted" (buffer-name))))
 409   ;; Flag so that a cache will be saved later even if the file is never saved.
 410   (setq fast-lock-cache-timestamp nil))
 411
 412 (defalias 'fast-lock-after-unfontify-buffer
 413   'ignore)
 414 \f
 415 ;; Miscellaneous Functions:
 416
 417 (defun fast-lock-save-cache-after-save-file ()
 418   ;; Do `fast-lock-save-cache' if `save-buffer' is on `fast-lock-save-events'.
 419   (when (memq 'save-buffer fast-lock-save-events)
 420     (fast-lock-save-cache)))
 421
 422 (defun fast-lock-save-cache-before-kill-buffer ()
 423   ;; Do `fast-lock-save-cache' if `kill-buffer' is on `fast-lock-save-events'.
 424   (when (memq 'kill-buffer fast-lock-save-events)
 425     (fast-lock-save-cache)))
 426
 427 (defun fast-lock-save-caches-before-kill-emacs ()
 428   ;; Do `fast-lock-save-cache's if `kill-emacs' is on `fast-lock-save-events'.
 429   (when (memq 'kill-emacs fast-lock-save-events)
 430     (mapcar 'fast-lock-save-cache (buffer-list))))
 431
 432 (defun fast-lock-cache-directory (directory create)
 433   "Return usable directory based on DIRECTORY.
 434 Returns nil if the directory does not exist, or, if CREATE non-nil, cannot be
 435 created.  DIRECTORY may be a string or a cons pair of the form (REGEXP . DIR).
 436 See `fast-lock-cache-directories'."
 437   (let ((dir
 438          (cond ((not buffer-file-name)
 439                 ;; Should never be nil, but `crypt++' screws it up.
 440                 nil)
 441                ((stringp directory)
 442                 ;; Just a directory.
 443                 directory)
 444                (t
 445                 ;; A directory iff the file name matches the regexp.
 446                 (let ((bufile (expand-file-name buffer-file-truename))
 447                       (case-fold-search nil))
 448                   (when (save-match-data (string-match (car directory) bufile))
 449                     (cdr directory)))))))
 450     (cond ((not dir)
 451            nil)
 452           ((file-accessible-directory-p dir)
 453            dir)
 454           (create
 455            (condition-case nil
 456                (progn (make-directory dir t) dir)
 457              (error nil))))))
 458
 459 ;; If you are wondering why we only hash if the directory is not ".", rather
 460 ;; than if `file-name-absolute-p', it is because if we just appended ".flc" for
 461 ;; relative cache directories (that are not ".") then it is possible that more
 462 ;; than one file would have the same cache name in that directory, if the luser
 463 ;; made a link from one relative cache directory to another.  (Phew!)
 464 (defun fast-lock-cache-name (directory)
 465   "Return full cache path name using caching DIRECTORY.
 466 If DIRECTORY is `.', the path is the buffer file name appended with `.flc'.
 467 Otherwise, the path name is constructed from DIRECTORY and the buffer's true
 468 abbreviated file name, with all `/' characters in the name replaced with `#'
 469 characters, and appended with `.flc'.
 470
 471 If the same file has different cache path names when edited on different
 472 machines, e.g., on one machine the cache file name has the prefix `#home',
 473 perhaps due to automount, try putting in your `~/.emacs' something like:
 474
 475  (setq directory-abbrev-alist (cons '(\"^/home/\" . \"/\") directory-abbrev-alist))
 476
 477 Emacs automagically removes the common `/tmp_mnt' automount prefix by default.
 478
 479 See `fast-lock-cache-directory'."
 480   (if (string-equal directory ".")
 481       (concat buffer-file-name ".flc")
 482     (let* ((bufile (expand-file-name buffer-file-truename))
 483            (chars-alist
 484             (if (eq system-type 'emx)
 485                 '((?/ . (?#)) (?# . (?# ?#)) (?: . (?\;)) (?\; . (?\; ?\;)))
 486               '((?/ . (?#)) (?# . (?# ?#)))))
 487            (mapchars
 488             (function (lambda (c) (or (cdr (assq c chars-alist)) (list c))))))
 489       (concat
 490        (file-name-as-directory (expand-file-name directory))
 491        (mapconcat 'char-to-string (apply 'append (mapcar mapchars bufile)) "")
 492        ".flc"))))
 493 \f
 494 ;; Font Lock Cache Processing Functions:
 495
 496 (defun fast-lock-save-cache-1 (file timestamp)
 497   ;; Save the FILE with the TIMESTAMP as:
 498   ;; (fast-lock-cache-data Version=2 TIMESTAMP font-lock-keywords PROPERTIES).
 499   ;; Returns non-nil if a save was attempted to a writable cache file.
 500   (let ((tpbuf (generate-new-buffer " *fast-lock*"))
 501         (buname (buffer-name)) (saved t))
 502     (message "Saving %s font lock cache..." buname)
 503     (condition-case nil
 504         (save-excursion
 505           (print (list 'fast-lock-cache-data 2
 506                        (list 'quote timestamp)
 507                        (list 'quote font-lock-keywords)
 508                        (list 'quote (fast-lock-get-face-properties)))
 509                  tpbuf)
 510           (set-buffer tpbuf)
 511           (write-region (point-min) (point-max) file nil 'quietly)
 512           (setq fast-lock-cache-timestamp timestamp
 513                 fast-lock-cache-filename file))
 514       (error (setq saved 'error)) (quit (setq saved 'quit)))
 515     (kill-buffer tpbuf)
 516     (message "Saving %s font lock cache...%s" buname
 517              (cond ((eq saved 'error) "failed")
 518                    ((eq saved 'quit) "aborted")
 519                    (t "done")))
 520     ;; We return non-nil regardless of whether a failure occurred.
 521     saved))
 522
 523 (defun fast-lock-cache-data (version timestamp keywords properties
 524                              &rest ignored)
 525   ;; Change from (HIGH LOW) for back compatibility.  Remove for version 3!
 526   (when (consp (cdr-safe timestamp))
 527     (setcdr timestamp (nth 1 timestamp)))
 528   ;; Compile KEYWORDS and `font-lock-keywords' in case one is and one isn't.
 529   (let ((current font-lock-keywords))
 530     (setq keywords (font-lock-compile-keywords keywords)
 531           font-lock-keywords (font-lock-compile-keywords current)))
 532   ;; Use the Font Lock cache PROPERTIES if we're using cache VERSION format 2,
 533   ;; the current buffer's file timestamp matches the TIMESTAMP, and the current
 534   ;; buffer's font-lock-keywords are the same as KEYWORDS.
 535   (let ((buf-timestamp (visited-file-modtime))
 536         (buname (buffer-name)) (loaded t))
 537     (if (or (/= version 2)
 538             (buffer-modified-p)
 539             (not (equal timestamp buf-timestamp))
 540             (not (equal keywords font-lock-keywords)))
 541         (setq loaded nil)
 542       (message "Loading %s font lock cache..." buname)
 543       (condition-case nil
 544           (fast-lock-set-face-properties properties)
 545         (error (setq loaded 'error)) (quit (setq loaded 'quit)))
 546       (message "Loading %s font lock cache...%s" buname
 547                (cond ((eq loaded 'error) "failed")
 548                      ((eq loaded 'quit) "aborted")
 549                      (t "done"))))
 550     (setq font-lock-fontified (eq loaded t)
 551           fast-lock-cache-timestamp (and (eq loaded t) timestamp))))
 552 \f
 553 ;; Text Properties Processing Functions:
 554
 555 ;; This is faster, but fails if adjacent characters have different `face' text
 556 ;; properties.  Maybe that's why I dropped it in the first place?
 557 ;(defun fast-lock-get-face-properties ()
 558 ;  "Return a list of all `face' text properties in the current buffer.
 559 ;Each element of the list is of the form (VALUE START1 END1 START2 END2 ...)
 560 ;where VALUE is a `face' property value and STARTx and ENDx are positions."
 561 ;  (save-restriction
 562 ;    (widen)
 563 ;    (let ((start (text-property-not-all (point-min) (point-max) 'face nil))
 564 ;         (limit (point-max)) end properties value cell)
 565 ;      (while start
 566 ;       (setq end (next-single-property-change start 'face nil limit)
 567 ;             value (get-text-property start 'face))
 568 ;       ;; Make, or add to existing, list of regions with same `face'.
 569 ;       (if (setq cell (assq value properties))
 570 ;           (setcdr cell (cons start (cons end (cdr cell))))
 571 ;         (setq properties (cons (list value start end) properties)))
 572 ;       (setq start (next-single-property-change end 'face)))
 573 ;      properties)))
 574
 575 (defun fast-lock-get-face-properties ()
 576   "Return a list of all `face' text properties in the current buffer.
 577 Each element of the list is of the form (VALUE START1 END1 START2 END2 ...)
 578 where VALUE is a `face' property value and STARTx and ENDx are positions.
 579 Only those `face' VALUEs in `fast-lock-save-faces' are returned."
 580   (save-restriction
 581     (widen)
 582     (let ((faces (or fast-lock-save-faces (face-list))) (limit (point-max))
 583           properties regions face start end)
 584       (while faces
 585         (setq face (car faces) faces (cdr faces) regions () end (point-min))
 586         ;; Make a list of start/end regions with `face' property face.
 587         (while (setq start (text-property-any end limit 'face face))
 588           (setq end (or (text-property-not-all start limit 'face face) limit)
 589                 regions (cons start (cons end regions))))
 590         ;; Add `face' face's regions, if any, to properties.
 591         (when regions
 592           (push (cons face regions) properties)))
 593       properties)))
 594
 595 (defun fast-lock-set-face-properties (properties)
 596   "Set all `face' text properties to PROPERTIES in the current buffer.
 597 Any existing `face' text properties are removed first.
 598 See `fast-lock-get-face-properties' for the format of PROPERTIES."
 599   (save-buffer-state (plist regions)
 600     (save-restriction
 601       (widen)
 602       (font-lock-unfontify-region (point-min) (point-max))
 603       (while properties
 604         (setq plist (list 'face (car (car properties)))
 605               regions (cdr (car properties))
 606               properties (cdr properties))
 607         ;; Set the `face' property for each start/end region.
 608         (while regions
 609           (set-text-properties (nth 0 regions) (nth 1 regions) plist)
 610           (setq regions (nthcdr 2 regions)))))))
 611 \f
 612 ;; Functions for XEmacs:
 613
 614 (when (save-match-data (string-match "XEmacs" (emacs-version)))
 615   ;;
 616   ;; It would be better to use XEmacs' `map-extents' over extents with a
 617   ;; `font-lock' property, but `face' properties are on different extents.
 618   (defun fast-lock-get-face-properties ()
 619     "Return a list of all `face' text properties in the current buffer.
 620 Each element of the list is of the form (VALUE START1 END1 START2 END2 ...)
 621 where VALUE is a `face' property value and STARTx and ENDx are positions.
 622 Only those `face' VALUEs in `fast-lock-save-faces' are returned."
 623     (save-restriction
 624       (widen)
 625       (let ((properties ()) cell)
 626         (map-extents
 627          (function (lambda (extent ignore)
 628             (let ((value (extent-face extent)))
 629               ;; We're only interested if it's one of `fast-lock-save-faces'.
 630               (when (and value (or (null fast-lock-save-faces)
 631                                    (memq value fast-lock-save-faces)))
 632                 (let ((start (extent-start-position extent))
 633                       (end (extent-end-position extent)))
 634                   ;; Make or add to existing list of regions with the same
 635                   ;; `face' property value.
 636                   (if (setq cell (assq value properties))
 637                       (setcdr cell (cons start (cons end (cdr cell))))
 638                     (push (list value start end) properties))))
 639               ;; Return nil to keep `map-extents' going.
 640               nil))))
 641         properties)))
 642   ;;
 643   ;; Make extents just like XEmacs' font-lock.el does.
 644   (defun fast-lock-set-face-properties (properties)
 645     "Set all `face' text properties to PROPERTIES in the current buffer.
 646 Any existing `face' text properties are removed first.
 647 See `fast-lock-get-face-properties' for the format of PROPERTIES."
 648     (save-restriction
 649       (widen)
 650       (font-lock-unfontify-region (point-min) (point-max))
 651       (while properties
 652         (let ((face (car (car properties)))
 653               (regions (cdr (car properties))))
 654           ;; Set the `face' property, etc., for each start/end region.
 655           (while regions
 656             (font-lock-set-face (nth 0 regions) (nth 1 regions) face)
 657             (setq regions (nthcdr 2 regions)))
 658           (setq properties (cdr properties))))))
 659   ;;
 660   ;; XEmacs 19.12 font-lock.el's `font-lock-fontify-buffer' runs a hook.
 661   (add-hook 'font-lock-after-fontify-buffer-hook
 662             'fast-lock-after-fontify-buffer))
 663
 664 (unless (boundp 'font-lock-inhibit-thing-lock)
 665   (defvar font-lock-inhibit-thing-lock nil
 666     "List of Font Lock mode related modes that should not be turned on."))
 667
 668 (unless (fboundp 'font-lock-compile-keywords)
 669   (defalias 'font-lock-compile-keywords 'identity))
 670 \f
 671 ;; Install ourselves:
 672
 673 (add-hook 'after-save-hook 'fast-lock-save-cache-after-save-file)
 674 (add-hook 'kill-buffer-hook 'fast-lock-save-cache-before-kill-buffer)
 675 (add-hook 'kill-emacs-hook 'fast-lock-save-caches-before-kill-emacs)
 676
 677 ;;;###autoload
 678 (if (fboundp 'add-minor-mode) (add-minor-mode 'fast-lock-mode nil))
 679 ;;;###dont-autoload
 680 (unless (assq 'fast-lock-mode minor-mode-alist)
 681   (setq minor-mode-alist (append minor-mode-alist '((fast-lock-mode nil)))))
 682
 683 ;; Provide ourselves:
 684
 685 (provide 'fast-lock)
 686
 687 ;;; fast-lock.el ends here