code.delx.au - gnu-emacs/blob - lisp/gnus/gnus-msg.el

   1 ;;; gnus-msg.el --- mail and post interface for Gnus
   2 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   6 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'cl))
  31
  32 (require 'gnus)
  33 (require 'gnus-ems)
  34 (require 'message)
  35 (require 'gnus-art)
  36 (require 'gnus-util)
  37
  38 (defcustom gnus-post-method 'current
  39   "*Preferred method for posting USENET news.
  40
  41 If this variable is `current' (which is the default), Gnus will use
  42 the \"current\" select method when posting.  If it is `native', Gnus
  43 will use the native select method when posting.
  44
  45 This method will not be used in mail groups and the like, only in
  46 \"real\" newsgroups.
  47
  48 If not `native' nor `current', the value must be a valid method as discussed
  49 in the documentation of `gnus-select-method'.  It can also be a list of
  50 methods.  If that is the case, the user will be queried for what select
  51 method to use when posting."
  52   :group 'gnus-group-foreign
  53   :link '(custom-manual "(gnus)Posting Server")
  54   :type `(choice (const native)
  55                  (const current)
  56                  (sexp :tag "Methods" ,gnus-select-method)))
  57
  58 (defcustom gnus-outgoing-message-group nil
  59   "*All outgoing messages will be put in this group.
  60 If you want to store all your outgoing mail and articles in the group
  61 \"nnml:archive\", you set this variable to that value.  This variable
  62 can also be a list of group names.
  63
  64 If you want to have greater control over what group to put each
  65 message in, you can set this variable to a function that checks the
  66 current newsgroup name and then returns a suitable group name (or list
  67 of names)."
  68   :group 'gnus-message
  69   :type '(choice (string :tag "Group")
  70                  (function)))
  71
  72 (defcustom gnus-mailing-list-groups nil
  73   "*If non-nil a regexp matching groups that are really mailing lists.
  74 This is useful when you're reading a mailing list that has been
  75 gatewayed to a newsgroup, and you want to followup to an article in
  76 the group."
  77   :group 'gnus-message
  78   :type '(choice (regexp)
  79                  (const nil)))
  80
  81 (defcustom gnus-add-to-list nil
  82   "*If non-nil, add a `to-list' parameter automatically."
  83   :group 'gnus-message
  84   :type 'boolean)
  85
  86 (defcustom gnus-crosspost-complaint
  87   "Hi,
  88
  89 You posted the article below with the following Newsgroups header:
  90
  91 Newsgroups: %s
  92
  93 The %s group, at least, was an inappropriate recipient
  94 of this message.  Please trim your Newsgroups header to exclude this
  95 group before posting in the future.
  96
  97 Thank you.
  98
  99 "
 100   "Format string to be inserted when complaining about crossposts.
 101 The first %s will be replaced by the Newsgroups header;
 102 the second with the current group name."
 103   :group 'gnus-message
 104   :type 'string)
 105
 106 (defcustom gnus-message-setup-hook nil
 107   "Hook run after setting up a message buffer."
 108   :group 'gnus-message
 109   :type 'hook)
 110
 111 (defcustom gnus-bug-create-help-buffer t
 112   "*Should we create the *Gnus Help Bug* buffer?"
 113   :group 'gnus-message
 114   :type 'boolean)
 115
 116 (defcustom gnus-posting-styles nil
 117   "*Alist of styles to use when posting.
 118 See Info node `(gnus)Posting Styles'."
 119   :group 'gnus-message
 120   :link '(custom-manual "(gnus)Posting Styles")
 121   :type '(repeat (cons (choice (regexp)
 122                                (variable)
 123                                (list (const header)
 124                                      (string :tag "Header")
 125                                      (regexp :tag "Regexp"))
 126                                (function)
 127                                (sexp))
 128                        (repeat (list
 129                                 (choice (const signature)
 130                                         (const signature-file)
 131                                         (const organization)
 132                                         (const address)
 133                                         (const x-face-file)
 134                                         (const name)
 135                                         (const body)
 136                                         (symbol)
 137                                         (string :tag "Header"))
 138                                 (choice (string)
 139                                         (function)
 140                                         (variable)
 141                                         (sexp)))))))
 142
 143 (defcustom gnus-gcc-mark-as-read nil
 144   "If non-nil, automatically mark Gcc articles as read."
 145   :version "21.4"
 146   :group 'gnus-message
 147   :type 'boolean)
 148
 149 (make-obsolete-variable 'gnus-inews-mark-gcc-as-read
 150                         'gnus-gcc-mark-as-read)
 151
 152 (defcustom gnus-gcc-externalize-attachments nil
 153   "Should local-file attachments be included as external parts in Gcc copies?
 154 If it is `all', attach files as external parts;
 155 if a regexp and matches the Gcc group name, attach files as external parts;
 156 if nil, attach files as normal parts."
 157   :version "21.4"
 158   :group 'gnus-message
 159   :type '(choice (const nil :tag "None")
 160                  (const all :tag "Any")
 161                  (string :tag "Regexp")))
 162
 163 (gnus-define-group-parameter
 164  posting-charset-alist
 165  :type list
 166  :function-document
 167  "Return the permitted unencoded charsets for posting of GROUP."
 168  :variable gnus-group-posting-charset-alist
 169  :variable-default
 170   '(("^\\(no\\|fr\\)\\.[^,]*\\(,[ \t\n]*\\(no\\|fr\\)\\.[^,]*\\)*$" iso-8859-1 (iso-8859-1))
 171     ("^\\(fido7\\|relcom\\)\\.[^,]*\\(,[ \t\n]*\\(fido7\\|relcom\\)\\.[^,]*\\)*$" koi8-r (koi8-r))
 172     (message-this-is-mail nil nil)
 173     (message-this-is-news nil t))
 174  :variable-document
 175   "Alist of regexps and permitted unencoded charsets for posting.
 176 Each element of the alist has the form (TEST HEADER BODY-LIST), where
 177 TEST is either a regular expression matching the newsgroup header or a
 178 variable to query,
 179 HEADER is the charset which may be left unencoded in the header (nil
 180 means encode all charsets),
 181 BODY-LIST is a list of charsets which may be encoded using 8bit
 182 content-transfer encoding in the body, or one of the special values
 183 nil (always encode using quoted-printable) or t (always use 8bit).
 184
 185 Note that any value other than nil for HEADER infringes some RFCs, so
 186 use this option with care."
 187  :variable-group gnus-charset
 188  :variable-type
 189  '(repeat (list :tag "Permitted unencoded charsets"
 190                 (choice :tag "Where"
 191                         (regexp :tag "Group")
 192                         (const :tag "Mail message" :value message-this-is-mail)
 193                         (const :tag "News article" :value message-this-is-news))
 194                 (choice :tag "Header"
 195                         (const :tag "None" nil)
 196                         (symbol :tag "Charset"))
 197                 (choice :tag "Body"
 198                         (const :tag "Any" :value t)
 199                         (const :tag "None" :value nil)
 200                         (repeat :tag "Charsets"
 201                                 (symbol :tag "Charset")))))
 202  :parameter-type '(choice :tag "Permitted unencoded charsets"
 203                           :value nil
 204                           (repeat (symbol)))
 205  :parameter-document       "\
 206 List of charsets that are permitted to be unencoded.")
 207
 208 (defcustom gnus-debug-files
 209   '("gnus.el" "gnus-sum.el" "gnus-group.el"
 210     "gnus-art.el" "gnus-start.el" "gnus-async.el"
 211     "gnus-msg.el" "gnus-score.el" "gnus-win.el" "gnus-topic.el"
 212     "gnus-agent.el" "gnus-cache.el" "gnus-srvr.el"
 213     "mm-util.el" "mm-decode.el" "nnmail.el" "message.el")
 214   "Files whose variables will be reported in `gnus-bug'."
 215   :version "21.4"
 216   :group 'gnus-message
 217   :type '(repeat (string :tag "File")))
 218
 219 (defcustom gnus-debug-exclude-variables
 220   '(mm-mime-mule-charset-alist
 221     nnmail-split-fancy message-minibuffer-local-map)
 222   "Variables that should not be reported in `gnus-bug'."
 223   :version "21.4"
 224   :group 'gnus-message
 225   :type '(repeat (symbol :tag "Variable")))
 226
 227 (defcustom gnus-discouraged-post-methods
 228   '(nndraft nnml nnimap nnmaildir nnmh nnfolder nndir)
 229   "A list of back ends that are not used in \"real\" newsgroups.
 230 This variable is used only when `gnus-post-method' is `current'."
 231   :version "21.4"
 232   :group 'gnus-group-foreign
 233   :type '(repeat (symbol :tag "Back end")))
 234
 235 (defcustom gnus-message-replysign
 236   nil
 237   "Automatically sign replies to signed messages.
 238 See also the `mml-default-sign-method' variable."
 239   :group 'gnus-message
 240   :type 'boolean)
 241
 242 (defcustom gnus-message-replyencrypt
 243   nil
 244   "Automatically encrypt replies to encrypted messages.
 245 See also the `mml-default-encrypt-method' variable."
 246   :group 'gnus-message
 247   :type 'boolean)
 248
 249 (defcustom gnus-message-replysignencrypted
 250   t
 251   "Setting this causes automatically encrypted messages to also be signed."
 252   :group 'gnus-message
 253   :type 'boolean)
 254
 255 (defcustom gnus-confirm-mail-reply-to-news nil
 256   "If non-nil, Gnus requests confirmation when replying to news.
 257 This is done because new users often reply by mistake when reading
 258 news.
 259 This can also be a function receiving the group name as the only
 260 parameter which should return non-nil iff a confirmation is needed, or
 261 a regexp, in which case a confirmation is asked for iff the group name
 262 matches the regexp."
 263   :version "21.4"
 264   :group 'gnus-message
 265   :type '(choice (const :tag "No" nil)
 266                  (const :tag "Yes" t)
 267                  (regexp :tag "Iff group matches regexp")
 268                  (function :tag "Iff function evaluates to non-nil")))
 269
 270 (defcustom gnus-confirm-treat-mail-like-news
 271   nil
 272   "If non-nil, Gnus will treat mail like news with regard to confirmation
 273 when replying by mail.  See the `gnus-confirm-mail-reply-to-news' variable
 274 for fine-tuning this.
 275 If nil, Gnus will never ask for confirmation if replying to mail."
 276   :version "21.4"
 277   :group 'gnus-message
 278   :type 'boolean)
 279
 280 (defcustom gnus-summary-resend-default-address t
 281   "If non-nil, Gnus tries to suggest a default address to resend to.
 282 If nil, the address field will always be empty after invoking
 283 `gnus-summary-resend-message'."
 284   :group 'gnus-message
 285   :type 'boolean)
 286
 287 ;;; Internal variables.
 288
 289 (defvar gnus-inhibit-posting-styles nil
 290   "Inhibit the use of posting styles.")
 291
 292 (defvar gnus-article-yanked-articles nil)
 293 (defvar gnus-message-buffer "*Mail Gnus*")
 294 (defvar gnus-article-copy nil)
 295 (defvar gnus-check-before-posting nil)
 296 (defvar gnus-last-posting-server nil)
 297 (defvar gnus-message-group-art nil)
 298
 299 (defvar gnus-msg-force-broken-reply-to nil)
 300
 301 (defconst gnus-bug-message
 302   "Sending a bug report to the Gnus Towers.
 303 ========================================
 304
 305 The buffer below is a mail buffer.  When you press `C-c C-c', it will
 306 be sent to the Gnus Bug Exterminators.
 307
 308 The thing near the bottom of the buffer is how the environment
 309 settings will be included in the mail.  Please do not delete that.
 310 They will tell the Bug People what your environment is, so that it
 311 will be easier to locate the bugs.
 312
 313 If you have found a bug that makes Emacs go \"beep\", set
 314 debug-on-error to t (`M-x set-variable RET debug-on-error RET t RET')
 315 and include the backtrace in your bug report.
 316
 317 Please describe the bug in annoying, painstaking detail.
 318
 319 Thank you for your help in stamping out bugs.
 320 ")
 321
 322 (eval-and-compile
 323   (autoload 'gnus-uu-post-news "gnus-uu" nil t)
 324   (autoload 'news-setup "rnewspost")
 325   (autoload 'news-reply-mode "rnewspost")
 326   (autoload 'rmail-dont-reply-to "mail-utils")
 327   (autoload 'rmail-output "rmailout"))
 328
 329 \f
 330 ;;;
 331 ;;; Gnus Posting Functions
 332 ;;;
 333
 334 (gnus-define-keys (gnus-summary-send-map "S" gnus-summary-mode-map)
 335   "p" gnus-summary-post-news
 336   "i" gnus-summary-news-other-window
 337   "f" gnus-summary-followup
 338   "F" gnus-summary-followup-with-original
 339   "c" gnus-summary-cancel-article
 340   "s" gnus-summary-supersede-article
 341   "r" gnus-summary-reply
 342   "y" gnus-summary-yank-message
 343   "R" gnus-summary-reply-with-original
 344   "w" gnus-summary-wide-reply
 345   "W" gnus-summary-wide-reply-with-original
 346   "v" gnus-summary-very-wide-reply
 347   "V" gnus-summary-very-wide-reply-with-original
 348   "n" gnus-summary-followup-to-mail
 349   "N" gnus-summary-followup-to-mail-with-original
 350   "m" gnus-summary-mail-other-window
 351   "u" gnus-uu-post-news
 352   "\M-c" gnus-summary-mail-crosspost-complaint
 353   "Br" gnus-summary-reply-broken-reply-to
 354   "BR" gnus-summary-reply-broken-reply-to-with-original
 355   "om" gnus-summary-mail-forward
 356   "op" gnus-summary-post-forward
 357   "Om" gnus-uu-digest-mail-forward
 358   "Op" gnus-uu-digest-post-forward)
 359
 360 (gnus-define-keys (gnus-send-bounce-map "D" gnus-summary-send-map)
 361   "b" gnus-summary-resend-bounced-mail
 362   ;; "c" gnus-summary-send-draft
 363   "r" gnus-summary-resend-message
 364   "e" gnus-summary-resend-message-edit)
 365
 366 ;;; Internal functions.
 367
 368 (defun gnus-inews-make-draft ()
 369   `(lambda ()
 370      (gnus-inews-make-draft-meta-information
 371       ,gnus-newsgroup-name ',gnus-article-reply)))
 372
 373 (defvar gnus-article-reply nil)
 374 (defmacro gnus-setup-message (config &rest forms)
 375   (let ((winconf (make-symbol "gnus-setup-message-winconf"))
 376         (buffer (make-symbol "gnus-setup-message-buffer"))
 377         (article (make-symbol "gnus-setup-message-article"))
 378         (yanked (make-symbol "gnus-setup-yanked-articles"))
 379         (group (make-symbol "gnus-setup-message-group")))
 380     `(let ((,winconf (current-window-configuration))
 381            (,buffer (buffer-name (current-buffer)))
 382            (,article gnus-article-reply)
 383            (,yanked gnus-article-yanked-articles)
 384            (,group gnus-newsgroup-name)
 385            (message-header-setup-hook
 386             (copy-sequence message-header-setup-hook))
 387            (mbl mml-buffer-list)
 388            (message-mode-hook (copy-sequence message-mode-hook)))
 389        (setq mml-buffer-list nil)
 390        (add-hook 'message-header-setup-hook 'gnus-inews-insert-gcc)
 391        (add-hook 'message-header-setup-hook 'gnus-inews-insert-archive-gcc)
 392        ;; #### FIXME: for a reason that I did not manage to identify yet,
 393        ;; the variable `gnus-newsgroup-name' does not honor a dynamically
 394        ;; scoped or setq'ed value from a caller like `C-u gnus-summary-mail'.
 395        ;; After evaluation of @forms below, it gets the value we actually want
 396        ;; to override, and the posting styles are used. For that reason, I've
 397        ;; added an optional argument to `gnus-configure-posting-styles' to
 398        ;; make sure that the correct value for the group name is used. -- drv
 399        (add-hook 'message-mode-hook
 400                  (if (memq ,config '(reply-yank reply))
 401                      (lambda ()
 402                        (gnus-configure-posting-styles ,group))
 403                    (lambda ()
 404                      ;; There may be an old " *gnus article copy*" buffer.
 405                      (let (gnus-article-copy)
 406                        (gnus-configure-posting-styles ,group)))))
 407        (gnus-pull ',(intern gnus-draft-meta-information-header)
 408                   message-required-headers)
 409        (when (and ,group
 410                   (not (string= ,group "")))
 411          (push (cons
 412                 (intern gnus-draft-meta-information-header)
 413                 (gnus-inews-make-draft))
 414                message-required-headers))
 415        (unwind-protect
 416            (progn
 417              ,@forms)
 418          (gnus-inews-add-send-actions ,winconf ,buffer ,article ,config
 419                                       ,yanked)
 420          (setq gnus-message-buffer (current-buffer))
 421          (set (make-local-variable 'gnus-message-group-art)
 422               (cons ,group ,article))
 423          (set (make-local-variable 'gnus-newsgroup-name) ,group)
 424          (gnus-run-hooks 'gnus-message-setup-hook)
 425          (if (eq major-mode 'message-mode)
 426              (let ((mbl1 mml-buffer-list))
 427                (setq mml-buffer-list mbl)  ;; Global value
 428                (set (make-local-variable 'mml-buffer-list) mbl1);; Local value
 429                (gnus-make-local-hook 'kill-buffer-hook)
 430                (gnus-make-local-hook 'change-major-mode-hook)
 431                (add-hook 'change-major-mode-hook 'mml-destroy-buffers nil t)
 432                (add-hook 'kill-buffer-hook 'mml-destroy-buffers t t))
 433            (mml-destroy-buffers)
 434            (setq mml-buffer-list mbl)))
 435        (message-hide-headers)
 436        (gnus-add-buffer)
 437        (gnus-configure-windows ,config t)
 438        (run-hooks 'post-command-hook)
 439        (set-buffer-modified-p nil))))
 440
 441 (defun gnus-inews-make-draft-meta-information (group article)
 442   (concat "(\"" group "\" "
 443           (if article (number-to-string
 444                        (if (listp article)
 445                            (car article)
 446                          article)) "\"\"")
 447           ")"))
 448
 449 ;;;###autoload
 450 (defun gnus-msg-mail (&optional to subject other-headers continue
 451                                 switch-action yank-action send-actions)
 452   "Start editing a mail message to be sent.
 453 Like `message-mail', but with Gnus paraphernalia, particularly the
 454 Gcc: header for archiving purposes."
 455   (interactive)
 456   (let ((buf (current-buffer))
 457         mail-buf)
 458     (gnus-setup-message 'message
 459       (message-mail to subject other-headers continue
 460                     nil yank-action send-actions))
 461     (when switch-action
 462       (setq mail-buf (current-buffer))
 463       (switch-to-buffer buf)
 464       (apply switch-action mail-buf nil)))
 465   ;; COMPOSEFUNC should return t if succeed.  Undocumented ???
 466   t)
 467
 468 (defvar save-selected-window-window)
 469
 470 ;;;###autoload
 471 (defun gnus-button-mailto (address)
 472   "Mail to ADDRESS."
 473   (set-buffer (gnus-copy-article-buffer))
 474   (gnus-setup-message 'message
 475     (message-reply address))
 476   (and (boundp 'save-selected-window-window)
 477        (not (window-live-p save-selected-window-window))
 478        (setq save-selected-window-window (selected-window))))
 479
 480 ;;;###autoload
 481 (defun gnus-button-reply (&optional to-address wide)
 482   "Like `message-reply'."
 483   (interactive)
 484   (gnus-setup-message 'message
 485     (message-reply to-address wide))
 486   (and (boundp 'save-selected-window-window)
 487        (not (window-live-p save-selected-window-window))
 488        (setq save-selected-window-window (selected-window))))
 489
 490 ;;;###autoload
 491 (define-mail-user-agent 'gnus-user-agent
 492   'gnus-msg-mail 'message-send-and-exit
 493   'message-kill-buffer 'message-send-hook)
 494
 495 (defun gnus-setup-posting-charset (group)
 496   (let ((alist gnus-group-posting-charset-alist)
 497         (group (or group ""))
 498         elem)
 499     (when group
 500       (catch 'found
 501         (while (setq elem (pop alist))
 502           (when (or (and (stringp (car elem))
 503                          (string-match (car elem) group))
 504                     (and (functionp (car elem))
 505                          (funcall (car elem) group))
 506                     (and (symbolp (car elem))
 507                          (symbol-value (car elem))))
 508             (throw 'found (cons (cadr elem) (caddr elem)))))))))
 509
 510 (defun gnus-inews-add-send-actions (winconf buffer article
 511                                             &optional config yanked)
 512   (gnus-make-local-hook 'message-sent-hook)
 513   (add-hook 'message-sent-hook (if gnus-agent 'gnus-agent-possibly-do-gcc
 514                                  'gnus-inews-do-gcc) nil t)
 515   (when gnus-agent
 516     (gnus-make-local-hook 'message-header-hook)
 517     (add-hook 'message-header-hook 'gnus-agent-possibly-save-gcc nil t))
 518   (setq message-post-method
 519         `(lambda (arg)
 520            (gnus-post-method arg ,gnus-newsgroup-name)))
 521   (setq message-newsreader (setq message-mailer (gnus-extended-version)))
 522   (message-add-action
 523    `(when (gnus-buffer-exists-p ,buffer)
 524       (set-window-configuration ,winconf))
 525    'exit 'postpone 'kill)
 526   (let ((to-be-marked (cond
 527                        (yanked
 528                         (mapcar
 529                          (lambda (x) (if (listp x) (car x) x)) yanked))
 530                        (article (if (listp article) article (list article)))
 531                        (t nil))))
 532     (message-add-action
 533      `(when (gnus-buffer-exists-p ,buffer)
 534         (save-excursion
 535           (set-buffer ,buffer)
 536           ,(when to-be-marked
 537              (if (eq config 'forward)
 538                  `(gnus-summary-mark-article-as-forwarded ',to-be-marked)
 539                `(gnus-summary-mark-article-as-replied ',to-be-marked)))))
 540      'send)))
 541
 542 (put 'gnus-setup-message 'lisp-indent-function 1)
 543 (put 'gnus-setup-message 'edebug-form-spec '(form body))
 544
 545 ;;; Post news commands of Gnus group mode and summary mode
 546
 547 (defun gnus-group-mail (&optional arg)
 548   "Start composing a mail.
 549 If ARG, use the group under the point to find a posting style.
 550 If ARG is 1, prompt for a group name to find the posting style."
 551   (interactive "P")
 552   ;; We can't `let' gnus-newsgroup-name here, since that leads
 553   ;; to local variables leaking.
 554   (let ((group gnus-newsgroup-name)
 555         ;; make sure last viewed article doesn't affect posting styles:
 556         (gnus-article-copy)
 557         (buffer (current-buffer)))
 558     (unwind-protect
 559         (progn
 560           (setq gnus-newsgroup-name
 561                 (if arg
 562                     (if (= 1 (prefix-numeric-value arg))
 563                         (completing-read "Use posting style of group: "
 564                                          gnus-active-hashtb nil
 565                                          (gnus-read-active-file-p))
 566                       (gnus-group-group-name))
 567                   ""))
 568           ;; #### see comment in gnus-setup-message -- drv
 569           (gnus-setup-message 'message (message-mail)))
 570       (save-excursion
 571         (set-buffer buffer)
 572         (setq gnus-newsgroup-name group)))))
 573
 574 (defun gnus-group-news (&optional arg)
 575   "Start composing a news.
 576 If ARG, post to group under point.
 577 If ARG is 1, prompt for group name to post to.
 578
 579 This function prepares a news even when using mail groups.  This is useful
 580 for posting messages to mail groups without actually sending them over the
 581 network.  The corresponding back end must have a 'request-post method."
 582   (interactive "P")
 583   ;; We can't `let' gnus-newsgroup-name here, since that leads
 584   ;; to local variables leaking.
 585   (let ((group gnus-newsgroup-name)
 586         ;; make sure last viewed article doesn't affect posting styles:
 587         (gnus-article-copy)
 588         (buffer (current-buffer)))
 589     (unwind-protect
 590         (progn
 591           (setq gnus-newsgroup-name
 592                 (if arg
 593                     (if (= 1 (prefix-numeric-value arg))
 594                         (completing-read "Use group: "
 595                                          gnus-active-hashtb nil
 596                                          (gnus-read-active-file-p))
 597                       (gnus-group-group-name))
 598                   ""))
 599           ;; #### see comment in gnus-setup-message -- drv
 600           (gnus-setup-message 'message
 601             (message-news (gnus-group-real-name gnus-newsgroup-name))))
 602       (save-excursion
 603         (set-buffer buffer)
 604         (setq gnus-newsgroup-name group)))))
 605
 606 (defun gnus-group-post-news (&optional arg)
 607   "Start composing a message (a news by default).
 608 If ARG, post to group under point.  If ARG is 1, prompt for group name.
 609 Depending on the selected group, the message might be either a mail or
 610 a news."
 611   (interactive "P")
 612   ;; Bind this variable here to make message mode hooks work ok.
 613   (let ((gnus-newsgroup-name
 614          (if arg
 615              (if (= 1 (prefix-numeric-value arg))
 616                  (completing-read "Newsgroup: " gnus-active-hashtb nil
 617                                   (gnus-read-active-file-p))
 618                (gnus-group-group-name))
 619            ""))
 620         ;; make sure last viewed article doesn't affect posting styles:
 621         (gnus-article-copy))
 622     (gnus-post-news 'post gnus-newsgroup-name nil nil nil nil
 623                     (string= gnus-newsgroup-name ""))))
 624
 625 (defun gnus-summary-mail-other-window (&optional arg)
 626   "Start composing a mail in another window.
 627 Use the posting of the current group by default.
 628 If ARG, don't do that.  If ARG is 1, prompt for group name to find the
 629 posting style."
 630   (interactive "P")
 631   ;; We can't `let' gnus-newsgroup-name here, since that leads
 632   ;; to local variables leaking.
 633   (let ((group gnus-newsgroup-name)
 634         ;; make sure last viewed article doesn't affect posting styles:
 635         (gnus-article-copy)
 636         (buffer (current-buffer)))
 637     (unwind-protect
 638         (progn
 639           (setq gnus-newsgroup-name
 640                 (if arg
 641                     (if (= 1 (prefix-numeric-value arg))
 642                         (completing-read "Use group: "
 643                                          gnus-active-hashtb nil
 644                                          (gnus-read-active-file-p))
 645                       "")
 646                   gnus-newsgroup-name))
 647           ;; #### see comment in gnus-setup-message -- drv
 648           (gnus-setup-message 'message (message-mail)))
 649       (save-excursion
 650         (set-buffer buffer)
 651         (setq gnus-newsgroup-name group)))))
 652
 653 (defun gnus-summary-news-other-window (&optional arg)
 654   "Start composing a news in another window.
 655 Post to the current group by default.
 656 If ARG, don't do that.  If ARG is 1, prompt for group name to post to.
 657
 658 This function prepares a news even when using mail groups.  This is useful
 659 for posting messages to mail groups without actually sending them over the
 660 network.  The corresponding back end must have a 'request-post method."
 661   (interactive "P")
 662   ;; We can't `let' gnus-newsgroup-name here, since that leads
 663   ;; to local variables leaking.
 664   (let ((group gnus-newsgroup-name)
 665         ;; make sure last viewed article doesn't affect posting styles:
 666         (gnus-article-copy)
 667         (buffer (current-buffer)))
 668     (unwind-protect
 669         (progn
 670           (setq gnus-newsgroup-name
 671                 (if arg
 672                     (if (= 1 (prefix-numeric-value arg))
 673                         (completing-read "Use group: "
 674                                          gnus-active-hashtb nil
 675                                          (gnus-read-active-file-p))
 676                       "")
 677                   gnus-newsgroup-name))
 678           ;; #### see comment in gnus-setup-message -- drv
 679           (gnus-setup-message 'message
 680             (progn
 681               (message-news (gnus-group-real-name gnus-newsgroup-name))
 682               (set (make-local-variable 'gnus-discouraged-post-methods)
 683                    (delq
 684                     (car (gnus-find-method-for-group gnus-newsgroup-name))
 685                     (copy-sequence gnus-discouraged-post-methods))))))
 686       (save-excursion
 687         (set-buffer buffer)
 688         (setq gnus-newsgroup-name group)))))
 689
 690 (defun gnus-summary-post-news (&optional arg)
 691   "Start composing a message.  Post to the current group by default.
 692 If ARG, don't do that.  If ARG is 1, prompt for a group name to post to.
 693 Depending on the selected group, the message might be either a mail or
 694 a news."
 695   (interactive "P")
 696   ;; Bind this variable here to make message mode hooks work ok.
 697   (let ((gnus-newsgroup-name
 698          (if arg
 699              (if (= 1 (prefix-numeric-value arg))
 700                  (completing-read "Newsgroup: " gnus-active-hashtb nil
 701                                   (gnus-read-active-file-p))
 702                "")
 703            gnus-newsgroup-name))
 704         ;; make sure last viewed article doesn't affect posting styles:
 705         (gnus-article-copy))
 706     (gnus-post-news 'post gnus-newsgroup-name)))
 707
 708
 709 (defun gnus-summary-followup (yank &optional force-news)
 710   "Compose a followup to an article.
 711 If prefix argument YANK is non-nil, the original article is yanked
 712 automatically.
 713 YANK is a list of elements, where the car of each element is the
 714 article number, and the cdr is the string to be yanked."
 715   (interactive
 716    (list (and current-prefix-arg
 717               (gnus-summary-work-articles 1))))
 718   (when yank
 719     (gnus-summary-goto-subject
 720      (if (listp (car yank))
 721          (caar yank)
 722        (car yank))))
 723   (save-window-excursion
 724     (gnus-summary-select-article))
 725   (let ((headers (gnus-summary-article-header (gnus-summary-article-number)))
 726         (gnus-newsgroup-name gnus-newsgroup-name))
 727     ;; Send a followup.
 728     (gnus-post-news nil gnus-newsgroup-name
 729                     headers gnus-article-buffer
 730                     yank nil force-news)
 731     (gnus-summary-handle-replysign)))
 732
 733 (defun gnus-summary-followup-with-original (n &optional force-news)
 734   "Compose a followup to an article and include the original article.
 735 The text in the region will be yanked.  If the region isn't
 736 active, the entire article will be yanked."
 737   (interactive "P")
 738   (gnus-summary-followup (gnus-summary-work-articles n) force-news))
 739
 740 (defun gnus-summary-followup-to-mail (&optional arg)
 741   "Followup to the current mail message via news."
 742   (interactive
 743    (list (and current-prefix-arg
 744               (gnus-summary-work-articles 1))))
 745   (gnus-summary-followup arg t))
 746
 747 (defun gnus-summary-followup-to-mail-with-original (&optional arg)
 748   "Followup to the current mail message via news."
 749   (interactive "P")
 750   (gnus-summary-followup (gnus-summary-work-articles arg) t))
 751
 752 (defun gnus-inews-yank-articles (articles)
 753   (let (beg article yank-string)
 754     (message-goto-body)
 755     (while (setq article (pop articles))
 756       (when (listp article)
 757         (setq yank-string (nth 1 article)
 758               article (nth 0 article)))
 759       (save-window-excursion
 760         (set-buffer gnus-summary-buffer)
 761         (gnus-summary-select-article nil nil nil article)
 762         (gnus-summary-remove-process-mark article))
 763       (gnus-copy-article-buffer nil yank-string)
 764       (let ((message-reply-buffer gnus-article-copy)
 765             (message-reply-headers
 766              ;; The headers are decoded.
 767              (with-current-buffer gnus-article-copy
 768                (save-restriction
 769                  (nnheader-narrow-to-headers)
 770                  (nnheader-parse-naked-head)))))
 771         (message-yank-original)
 772         (setq beg (or beg (mark t))))
 773       (when articles
 774         (insert "\n")))
 775     (push-mark)
 776     (goto-char beg)))
 777
 778 (defun gnus-summary-cancel-article (&optional n symp)
 779   "Cancel an article you posted.
 780 Uses the process-prefix convention.  If given the symbolic
 781 prefix `a', cancel using the standard posting method; if not
 782 post using the current select method."
 783   (interactive (gnus-interactive "P\ny"))
 784   (let ((articles (gnus-summary-work-articles n))
 785         (message-post-method
 786          `(lambda (arg)
 787             (gnus-post-method (eq ',symp 'a) ,gnus-newsgroup-name)))
 788         article)
 789     (while (setq article (pop articles))
 790       (when (gnus-summary-select-article t nil nil article)
 791         (when (gnus-eval-in-buffer-window gnus-original-article-buffer
 792                 (message-cancel-news))
 793           (gnus-summary-mark-as-read article gnus-canceled-mark)
 794           (gnus-cache-remove-article 1))
 795         (gnus-article-hide-headers-if-wanted))
 796       (gnus-summary-remove-process-mark article))))
 797
 798 (defun gnus-summary-supersede-article ()
 799   "Compose an article that will supersede a previous article.
 800 This is done simply by taking the old article and adding a Supersedes
 801 header line with the old Message-ID."
 802   (interactive)
 803   (let ((article (gnus-summary-article-number)))
 804     (gnus-setup-message 'reply-yank
 805       (gnus-summary-select-article t)
 806       (set-buffer gnus-original-article-buffer)
 807       (message-supersede)
 808       (push
 809        `((lambda ()
 810            (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 811              (save-excursion
 812                (set-buffer ,gnus-summary-buffer)
 813                (gnus-cache-possibly-remove-article ,article nil nil nil t)
 814                (gnus-summary-mark-as-read ,article gnus-canceled-mark)))))
 815        message-send-actions))))
 816
 817 \f
 818
 819 (defun gnus-copy-article-buffer (&optional article-buffer yank-string)
 820   ;; make a copy of the article buffer with all text properties removed
 821   ;; this copy is in the buffer gnus-article-copy.
 822   ;; if ARTICLE-BUFFER is nil, gnus-article-buffer is used
 823   ;; this buffer should be passed to all mail/news reply/post routines.
 824   (setq gnus-article-copy (gnus-get-buffer-create " *gnus article copy*"))
 825   (save-excursion
 826     (set-buffer gnus-article-copy)
 827     (mm-enable-multibyte))
 828   (let ((article-buffer (or article-buffer gnus-article-buffer))
 829         end beg)
 830     (if (not (and (get-buffer article-buffer)
 831                   (gnus-buffer-exists-p article-buffer)))
 832         (error "Can't find any article buffer")
 833       (save-excursion
 834         (set-buffer article-buffer)
 835         (let ((gnus-newsgroup-charset (or gnus-article-charset
 836                                           gnus-newsgroup-charset))
 837               (gnus-newsgroup-ignored-charsets
 838                (or gnus-article-ignored-charsets
 839                    gnus-newsgroup-ignored-charsets)))
 840           (save-restriction
 841             ;; Copy over the (displayed) article buffer, delete
 842             ;; hidden text and remove text properties.
 843             (widen)
 844             (copy-to-buffer gnus-article-copy (point-min) (point-max))
 845             (set-buffer gnus-article-copy)
 846             (when yank-string
 847               (message-goto-body)
 848               (delete-region (point) (point-max))
 849               (insert yank-string))
 850             (gnus-article-delete-text-of-type 'annotation)
 851             (gnus-remove-text-with-property 'gnus-prev)
 852             (gnus-remove-text-with-property 'gnus-next)
 853             (gnus-remove-text-with-property 'gnus-decoration)
 854             (insert
 855              (prog1
 856                  (buffer-substring-no-properties (point-min) (point-max))
 857                (erase-buffer)))
 858             ;; Find the original headers.
 859             (set-buffer gnus-original-article-buffer)
 860             (goto-char (point-min))
 861             (while (looking-at message-unix-mail-delimiter)
 862               (forward-line 1))
 863             (let ((mail-header-separator ""))
 864               (setq beg (point)
 865                     end (or (message-goto-body)
 866                             ;; There may be just a header.
 867                             (point-max))))
 868             ;; Delete the headers from the displayed articles.
 869             (set-buffer gnus-article-copy)
 870             (let ((mail-header-separator ""))
 871               (delete-region (goto-char (point-min))
 872                              (or (message-goto-body) (point-max))))
 873             ;; Insert the original article headers.
 874             (insert-buffer-substring gnus-original-article-buffer beg end)
 875             ;; Decode charsets.
 876             (let ((gnus-article-decode-hook
 877                    (delq 'article-decode-charset
 878                          (copy-sequence gnus-article-decode-hook))))
 879               (run-hooks 'gnus-article-decode-hook)))))
 880       gnus-article-copy)))
 881
 882 (defun gnus-post-news (post &optional group header article-buffer yank subject
 883                             force-news)
 884   (when article-buffer
 885     (gnus-copy-article-buffer))
 886   (let ((gnus-article-reply (and article-buffer (gnus-summary-article-number)))
 887         (gnus-article-yanked-articles yank)
 888         (add-to-list gnus-add-to-list))
 889     (gnus-setup-message (cond (yank 'reply-yank)
 890                               (article-buffer 'reply)
 891                               (t 'message))
 892       (let* ((group (or group gnus-newsgroup-name))
 893              (charset (gnus-group-name-charset nil group))
 894              (pgroup group)
 895              to-address to-group mailing-list to-list
 896              newsgroup-p)
 897         (when group
 898           (setq to-address (gnus-parameter-to-address group)
 899                 to-group (gnus-group-find-parameter group 'to-group)
 900                 to-list (gnus-parameter-to-list group)
 901                 newsgroup-p (gnus-group-find-parameter group 'newsgroup)
 902                 mailing-list (when gnus-mailing-list-groups
 903                                (string-match gnus-mailing-list-groups group))
 904                 group (gnus-group-name-decode (gnus-group-real-name group)
 905                                               charset)))
 906         (if (or (and to-group
 907                      (gnus-news-group-p to-group))
 908                 newsgroup-p
 909                 force-news
 910                 (and (gnus-news-group-p
 911                       (or pgroup gnus-newsgroup-name)
 912                       (or header gnus-current-article))
 913                      (not mailing-list)
 914                      (not to-list)
 915                      (not to-address)))
 916             ;; This is news.
 917             (if post
 918                 (message-news
 919                  (or to-group
 920                      (and (not (gnus-virtual-group-p pgroup)) group)))
 921               (set-buffer gnus-article-copy)
 922               (gnus-msg-treat-broken-reply-to)
 923               (message-followup (if (or newsgroup-p force-news)
 924                                     (if (save-restriction
 925                                           (article-narrow-to-head)
 926                                           (message-fetch-field "newsgroups"))
 927                                         nil
 928                                       "")
 929                                   to-group)))
 930           ;; The is mail.
 931           (if post
 932               (progn
 933                 (message-mail (or to-address to-list))
 934                 ;; Arrange for mail groups that have no `to-address' to
 935                 ;; get that when the user sends off the mail.
 936                 (when (and (not to-list)
 937                            (not to-address)
 938                            add-to-list)
 939                   (push (list 'gnus-inews-add-to-address pgroup)
 940                         message-send-actions)))
 941             (set-buffer gnus-article-copy)
 942             (gnus-msg-treat-broken-reply-to)
 943             (message-wide-reply to-address)))
 944         (when yank
 945           (gnus-inews-yank-articles yank))))))
 946
 947 (defun gnus-msg-treat-broken-reply-to (&optional force)
 948   "Remove the Reply-to header if broken-reply-to."
 949   (when (or force
 950             (gnus-group-find-parameter
 951              gnus-newsgroup-name 'broken-reply-to))
 952     (save-restriction
 953       (message-narrow-to-head)
 954       (message-remove-header "reply-to"))))
 955
 956 (defun gnus-post-method (arg group &optional silent)
 957   "Return the posting method based on GROUP and ARG.
 958 If SILENT, don't prompt the user."
 959   (let ((gnus-post-method (or (gnus-parameter-post-method group)
 960                               gnus-post-method))
 961         (group-method (gnus-find-method-for-group group)))
 962     (cond
 963      ;; If the group-method is nil (which shouldn't happen) we use
 964      ;; the default method.
 965      ((null group-method)
 966       (or (and (listp gnus-post-method) ;If not current/native/nil
 967                (not (listp (car gnus-post-method))) ; and not a list of methods
 968                gnus-post-method)        ;then use it.
 969           gnus-select-method
 970           message-post-method))
 971      ;; We want the inverse of the default
 972      ((and arg (not (eq arg 0)))
 973       (if (eq gnus-post-method 'current)
 974           gnus-select-method
 975         group-method))
 976      ;; We query the user for a post method.
 977      ((or arg
 978           (and (listp gnus-post-method)
 979                (listp (car gnus-post-method))))
 980       (let* ((methods
 981               ;; Collect all methods we know about.
 982               (append
 983                (when (listp gnus-post-method)
 984                  (if (listp (car gnus-post-method))
 985                      gnus-post-method
 986                    (list gnus-post-method)))
 987                gnus-secondary-select-methods
 988                (mapcar 'cdr gnus-server-alist)
 989                (mapcar 'car gnus-opened-servers)
 990                (list gnus-select-method)
 991                (list group-method)))
 992              method-alist post-methods method)
 993         ;; Weed out all mail methods.
 994         (while methods
 995           (setq method (gnus-server-get-method "" (pop methods)))
 996           (when (and (or (gnus-method-option-p method 'post)
 997                          (gnus-method-option-p method 'post-mail))
 998                      (not (member method post-methods)))
 999             (push method post-methods)))
1000         ;; Create a name-method alist.
1001         (setq method-alist
1002               (mapcar
1003                (lambda (m)
1004                  (if (equal (cadr m) "")
1005                      (list (symbol-name (car m)) m)
1006                    (list (concat (cadr m) " (" (symbol-name (car m)) ")") m)))
1007                post-methods))
1008         ;; Query the user.
1009         (cadr
1010          (assoc
1011           (setq gnus-last-posting-server
1012                 (if (and silent
1013                          gnus-last-posting-server)
1014                     ;; Just use the last value.
1015                     gnus-last-posting-server
1016                   (completing-read
1017                    "Posting method: " method-alist nil t
1018                    (cons (or gnus-last-posting-server "") 0))))
1019           method-alist))))
1020      ;; Override normal method.
1021      ((and (eq gnus-post-method 'current)
1022            (not (memq (car group-method) gnus-discouraged-post-methods))
1023            (gnus-get-function group-method 'request-post t))
1024       (assert (not arg))
1025       group-method)
1026      ;; Use gnus-post-method.
1027      ((listp gnus-post-method)          ;A method...
1028       (assert (not (listp (car gnus-post-method)))) ;... not a list of methods.
1029       gnus-post-method)
1030      ;; Use the normal select method (nil or native).
1031      (t gnus-select-method))))
1032
1033 \f
1034
1035 (defun gnus-extended-version ()
1036   "Stringified Gnus version and Emacs version.
1037 See the variable `gnus-user-agent'."
1038   (interactive)
1039   (let* ((float-output-format nil)
1040          (gnus-v
1041           (concat "Gnus/"
1042                   (prin1-to-string (gnus-continuum-version gnus-version) t)
1043                   " (" gnus-version ")"))
1044          (emacs-v (gnus-emacs-version)))
1045     (if (stringp gnus-user-agent)
1046         gnus-user-agent
1047       (concat gnus-v
1048               (when emacs-v
1049                 (concat " " emacs-v))))))
1050
1051 \f
1052 ;;;
1053 ;;; Gnus Mail Functions
1054 ;;;
1055
1056 ;;; Mail reply commands of Gnus summary mode
1057
1058 (defun gnus-summary-reply (&optional yank wide very-wide)
1059   "Start composing a mail reply to the current message.
1060 If prefix argument YANK is non-nil, the original article is yanked
1061 automatically.
1062 If WIDE, make a wide reply.
1063 If VERY-WIDE, make a very wide reply."
1064   (interactive
1065    (list (and current-prefix-arg
1066               (gnus-summary-work-articles 1))))
1067   ;; Allow user to require confirmation before replying by mail to the
1068   ;; author of a news article (or mail message).
1069   (when (or
1070             (not (or (gnus-news-group-p gnus-newsgroup-name)
1071                      gnus-confirm-treat-mail-like-news))
1072             (not (cond ((stringp gnus-confirm-mail-reply-to-news)
1073                         (string-match gnus-confirm-mail-reply-to-news
1074                                       gnus-newsgroup-name))
1075                        ((functionp gnus-confirm-mail-reply-to-news)
1076                         (funcall gnus-confirm-mail-reply-to-news gnus-newsgroup-name))
1077                        (t gnus-confirm-mail-reply-to-news)))
1078             (y-or-n-p "Really reply by mail to article author? "))
1079     (let* ((article
1080             (if (listp (car yank))
1081                 (caar yank)
1082               (car yank)))
1083            (gnus-article-reply (or article (gnus-summary-article-number)))
1084            (gnus-article-yanked-articles yank)
1085            (headers ""))
1086       ;; Stripping headers should be specified with mail-yank-ignored-headers.
1087       (when yank
1088         (gnus-summary-goto-subject article))
1089       (gnus-setup-message (if yank 'reply-yank 'reply)
1090         (if (not very-wide)
1091             (gnus-summary-select-article)
1092           (dolist (article very-wide)
1093             (gnus-summary-select-article nil nil nil article)
1094             (save-excursion
1095               (set-buffer (gnus-copy-article-buffer))
1096               (gnus-msg-treat-broken-reply-to)
1097               (save-restriction
1098                 (message-narrow-to-head)
1099                 (setq headers (concat headers (buffer-string)))))))
1100         (set-buffer (gnus-copy-article-buffer))
1101         (gnus-msg-treat-broken-reply-to gnus-msg-force-broken-reply-to)
1102         (save-restriction
1103           (message-narrow-to-head)
1104           (when very-wide
1105             (erase-buffer)
1106             (insert headers))
1107           (goto-char (point-max)))
1108         (mml-quote-region (point) (point-max))
1109         (message-reply nil wide)
1110         (when yank
1111           (gnus-inews-yank-articles yank))
1112         (gnus-summary-handle-replysign)))))
1113
1114 (defun gnus-summary-handle-replysign ()
1115   "Check the various replysign variables and take action accordingly."
1116   (when (or gnus-message-replysign gnus-message-replyencrypt)
1117     (let (signed encrypted)
1118       (save-excursion
1119         (set-buffer gnus-article-buffer)
1120         (setq signed (memq 'signed gnus-article-wash-types))
1121         (setq encrypted (memq 'encrypted gnus-article-wash-types)))
1122       (cond ((and gnus-message-replyencrypt encrypted)
1123              (mml-secure-message mml-default-encrypt-method
1124                                  (if gnus-message-replysignencrypted
1125                                      'signencrypt
1126                                    'encrypt)))
1127             ((and gnus-message-replysign signed)
1128              (mml-secure-message mml-default-sign-method 'sign))))))
1129
1130 (defun gnus-summary-reply-with-original (n &optional wide)
1131   "Start composing a reply mail to the current message.
1132 The original article will be yanked."
1133   (interactive "P")
1134   (gnus-summary-reply (gnus-summary-work-articles n) wide))
1135
1136 (defun gnus-summary-reply-broken-reply-to (&optional yank wide very-wide)
1137   "Like `gnus-summary-reply' except removing reply-to field.
1138 If prefix argument YANK is non-nil, the original article is yanked
1139 automatically.
1140 If WIDE, make a wide reply.
1141 If VERY-WIDE, make a very wide reply."
1142   (interactive
1143    (list (and current-prefix-arg
1144               (gnus-summary-work-articles 1))))
1145   (let ((gnus-msg-force-broken-reply-to t))
1146     (gnus-summary-reply yank wide very-wide)))
1147
1148 (defun gnus-summary-reply-broken-reply-to-with-original (n &optional wide)
1149   "Like `gnus-summary-reply-with-original' except removing reply-to field.
1150 The original article will be yanked."
1151   (interactive "P")
1152   (gnus-summary-reply-broken-reply-to (gnus-summary-work-articles n) wide))
1153
1154 (defun gnus-summary-wide-reply (&optional yank)
1155   "Start composing a wide reply mail to the current message.
1156 If prefix argument YANK is non-nil, the original article is yanked
1157 automatically."
1158   (interactive
1159    (list (and current-prefix-arg
1160               (gnus-summary-work-articles 1))))
1161   (gnus-summary-reply yank t))
1162
1163 (defun gnus-summary-wide-reply-with-original (n)
1164   "Start composing a wide reply mail to the current message.
1165 The original article will be yanked.
1166 Uses the process/prefix convention."
1167   (interactive "P")
1168   (gnus-summary-reply-with-original n t))
1169
1170 (defun gnus-summary-very-wide-reply (&optional yank)
1171   "Start composing a very wide reply mail to the current message.
1172 If prefix argument YANK is non-nil, the original article is yanked
1173 automatically."
1174   (interactive
1175    (list (and current-prefix-arg
1176               (gnus-summary-work-articles 1))))
1177   (gnus-summary-reply yank t (gnus-summary-work-articles yank)))
1178
1179 (defun gnus-summary-very-wide-reply-with-original (n)
1180   "Start composing a very wide reply mail to the current message.
1181 The original article will be yanked."
1182   (interactive "P")
1183   (gnus-summary-reply
1184    (gnus-summary-work-articles n) t (gnus-summary-work-articles n)))
1185
1186 (defun gnus-summary-mail-forward (&optional arg post)
1187   "Forward the current message(s) to another user.
1188 If process marks exist, forward all marked messages;
1189 if ARG is nil, see `message-forward-as-mime' and `message-forward-show-mml';
1190 if ARG is 1, decode the message and forward directly inline;
1191 if ARG is 2, forward message as an rfc822 MIME section;
1192 if ARG is 3, decode message and forward as an rfc822 MIME section;
1193 if ARG is 4, forward message directly inline;
1194 otherwise, use flipped `message-forward-as-mime'.
1195 If POST, post instead of mail.
1196 For the `inline' alternatives, also see the variable
1197 `message-forward-ignored-headers'."
1198   (interactive "P")
1199   (if (cdr (gnus-summary-work-articles nil))
1200       ;; Process marks are given.
1201       (gnus-uu-digest-mail-forward arg post)
1202     ;; No process marks.
1203     (let ((message-forward-as-mime message-forward-as-mime)
1204           (message-forward-show-mml message-forward-show-mml))
1205       (cond
1206        ((null arg))
1207        ((eq arg 1)
1208         (setq message-forward-as-mime nil
1209               message-forward-show-mml t))
1210        ((eq arg 2)
1211         (setq message-forward-as-mime t
1212               message-forward-show-mml nil))
1213        ((eq arg 3)
1214         (setq message-forward-as-mime t
1215               message-forward-show-mml t))
1216        ((eq arg 4)
1217         (setq message-forward-as-mime nil
1218               message-forward-show-mml nil))
1219        (t
1220         (setq message-forward-as-mime (not message-forward-as-mime))))
1221       (let* ((gnus-article-reply (gnus-summary-article-number))
1222              (gnus-article-yanked-articles (list gnus-article-reply)))
1223         (gnus-setup-message 'forward
1224           (gnus-summary-select-article)
1225           (let ((mail-parse-charset
1226                  (or (and (gnus-buffer-live-p gnus-article-buffer)
1227                           (with-current-buffer gnus-article-buffer
1228                             gnus-article-charset))
1229                      gnus-newsgroup-charset))
1230                 (mail-parse-ignored-charsets
1231                  gnus-newsgroup-ignored-charsets))
1232             (set-buffer gnus-original-article-buffer)
1233             (message-forward post)))))))
1234
1235 (defun gnus-summary-resend-message (address n)
1236   "Resend the current article to ADDRESS."
1237   (interactive
1238    (list (message-read-from-minibuffer
1239           "Resend message(s) to: "
1240           (when (and gnus-summary-resend-default-address
1241                      (gnus-buffer-live-p gnus-original-article-buffer))
1242             ;; If some other article is currently selected, the
1243             ;; initial-contents is wrong. Whatever, it is just the
1244             ;; initial-contents.
1245             (with-current-buffer gnus-original-article-buffer
1246               (nnmail-fetch-field "to"))))
1247          current-prefix-arg))
1248   (let ((articles (gnus-summary-work-articles n))
1249         article)
1250     (while (setq article (pop articles))
1251       (gnus-summary-select-article nil nil nil article)
1252       (save-excursion
1253         (set-buffer gnus-original-article-buffer)
1254         (message-resend address))
1255       (gnus-summary-mark-article-as-forwarded article))))
1256
1257 ;; From: Matthieu Moy <Matthieu.Moy@imag.fr>
1258 (defun gnus-summary-resend-message-edit ()
1259   "Resend an article that has already been sent.
1260 A new buffer will be created to allow the user to modify body and
1261 contents of the message, and then, everything will happen as when
1262 composing a new message."
1263   (interactive)
1264   (let ((article (gnus-summary-article-number)))
1265     (gnus-setup-message 'reply-yank
1266       (gnus-summary-select-article t)
1267       (set-buffer gnus-original-article-buffer)
1268       (let ((cur (current-buffer))
1269             (to (message-fetch-field "to")))
1270         ;; Get a normal message buffer.
1271         (message-pop-to-buffer (message-buffer-name "Resend" to))
1272         (insert-buffer-substring cur)
1273         (mime-to-mml)
1274         (message-narrow-to-head-1)
1275         ;; Gnus will generate a new one when sending.
1276         (message-remove-header "Message-ID")
1277         (message-remove-header message-ignored-resent-headers t)
1278         ;; Remove unwanted headers.
1279         (goto-char (point-max))
1280         (insert mail-header-separator)
1281         (goto-char (point-min))
1282         (when (re-search-forward "^To:\\|^Newsgroups:" nil 'move)
1283           (forward-char 1))
1284         (widen)))))
1285
1286 (defun gnus-summary-post-forward (&optional arg)
1287   "Forward the current article to a newsgroup.
1288 See `gnus-summary-mail-forward' for ARG."
1289   (interactive "P")
1290   (gnus-summary-mail-forward arg t))
1291
1292 (defvar gnus-nastygram-message
1293   "The following article was inappropriately posted to %s.\n\n"
1294   "Format string to insert in nastygrams.
1295 The current group name will be inserted at \"%s\".")
1296
1297 (defun gnus-summary-mail-nastygram (n)
1298   "Send a nastygram to the author of the current article."
1299   (interactive "P")
1300   (when (or gnus-expert-user
1301             (gnus-y-or-n-p
1302              "Really send a nastygram to the author of the current article? "))
1303     (let ((group gnus-newsgroup-name))
1304       (gnus-summary-reply-with-original n)
1305       (set-buffer gnus-message-buffer)
1306       (message-goto-body)
1307       (insert (format gnus-nastygram-message group))
1308       (message-send-and-exit))))
1309
1310 (defun gnus-summary-mail-crosspost-complaint (n)
1311   "Send a complaint about crossposting to the current article(s)."
1312   (interactive "P")
1313   (let ((articles (gnus-summary-work-articles n))
1314         article)
1315     (while (setq article (pop articles))
1316       (set-buffer gnus-summary-buffer)
1317       (gnus-summary-goto-subject article)
1318       (let ((group (gnus-group-real-name gnus-newsgroup-name))
1319             newsgroups followup-to)
1320         (gnus-summary-select-article)
1321         (set-buffer gnus-original-article-buffer)
1322         (if (and (<= (length (message-tokenize-header
1323                               (setq newsgroups
1324                                     (mail-fetch-field "newsgroups"))
1325                               ", "))
1326                      1)
1327                  (or (not (setq followup-to (mail-fetch-field "followup-to")))
1328                      (not (member group (message-tokenize-header
1329                                          followup-to ", ")))))
1330             (if followup-to
1331                 (gnus-message 1 "Followup-to restricted")
1332               (gnus-message 1 "Not a crossposted article"))
1333           (set-buffer gnus-summary-buffer)
1334           (gnus-summary-reply-with-original 1)
1335           (set-buffer gnus-message-buffer)
1336           (message-goto-body)
1337           (insert (format gnus-crosspost-complaint newsgroups group))
1338           (message-goto-subject)
1339           (re-search-forward " *$")
1340           (replace-match " (crosspost notification)" t t)
1341           (gnus-deactivate-mark)
1342           (when (gnus-y-or-n-p "Send this complaint? ")
1343             (message-send-and-exit)))))))
1344
1345 (defun gnus-mail-parse-comma-list ()
1346   (let (accumulated
1347         beg)
1348     (skip-chars-forward " ")
1349     (while (not (eobp))
1350       (setq beg (point))
1351       (skip-chars-forward "^,")
1352       (while (zerop
1353               (save-excursion
1354                 (save-restriction
1355                   (let ((i 0))
1356                     (narrow-to-region beg (point))
1357                     (goto-char beg)
1358                     (logand (progn
1359                               (while (search-forward "\"" nil t)
1360                                 (incf i))
1361                               (if (zerop i) 2 i))
1362                             2)))))
1363         (skip-chars-forward ",")
1364         (skip-chars-forward "^,"))
1365       (skip-chars-backward " ")
1366       (push (buffer-substring beg (point))
1367             accumulated)
1368       (skip-chars-forward "^,")
1369       (skip-chars-forward ", "))
1370     accumulated))
1371
1372 (defun gnus-inews-add-to-address (group)
1373   (let ((to-address (mail-fetch-field "to")))
1374     (when (and to-address
1375                (gnus-alive-p))
1376       ;; This mail group doesn't have a `to-list', so we add one
1377       ;; here.  Magic!
1378       (when (gnus-y-or-n-p
1379              (format "Do you want to add this as `to-list': %s? " to-address))
1380         (gnus-group-add-parameter group (cons 'to-list to-address))))))
1381
1382 (defun gnus-put-message ()
1383   "Put the current message in some group and return to Gnus."
1384   (interactive)
1385   (let ((reply gnus-article-reply)
1386         (winconf gnus-prev-winconf)
1387         (group gnus-newsgroup-name))
1388     (unless (and group
1389                  (not (gnus-group-read-only-p group)))
1390       (setq group (read-string "Put in group: " nil (gnus-writable-groups))))
1391
1392     (when (gnus-gethash group gnus-newsrc-hashtb)
1393       (error "No such group: %s" group))
1394     (save-excursion
1395       (save-restriction
1396         (widen)
1397         (message-narrow-to-headers)
1398         (let ((gnus-deletable-headers nil))
1399           (message-generate-headers
1400            (if (message-news-p)
1401                message-required-news-headers
1402              message-required-mail-headers)))
1403         (goto-char (point-max))
1404         (if (string-match " " group)
1405             (insert "Gcc: \"" group "\"\n")
1406           (insert "Gcc: " group "\n"))
1407         (widen)))
1408     (gnus-inews-do-gcc)
1409     (when (and (get-buffer gnus-group-buffer)
1410                (gnus-buffer-exists-p (car-safe reply))
1411                (cdr reply))
1412       (set-buffer (car reply))
1413       (gnus-summary-mark-article-as-replied (cdr reply)))
1414     (when winconf
1415       (set-window-configuration winconf))))
1416
1417 (defun gnus-article-mail (yank)
1418   "Send a reply to the address near point.
1419 If YANK is non-nil, include the original article."
1420   (interactive "P")
1421   (let ((address
1422          (buffer-substring
1423           (save-excursion (re-search-backward "[ \t\n]" nil t) (1+ (point)))
1424           (save-excursion (re-search-forward "[ \t\n]" nil t) (1- (point))))))
1425     (when address
1426       (gnus-msg-mail address)
1427       (when yank
1428         (gnus-inews-yank-articles (list (cdr gnus-article-current)))))))
1429
1430 (defvar nntp-server-type)
1431 (defun gnus-bug ()
1432   "Send a bug report to the Gnus maintainers."
1433   (interactive)
1434   (unless (gnus-alive-p)
1435     (error "Gnus has been shut down"))
1436   (gnus-setup-message (if (message-mail-user-agent) 'message 'bug)
1437     (unless (message-mail-user-agent)
1438       (delete-other-windows)
1439       (when gnus-bug-create-help-buffer
1440         (switch-to-buffer "*Gnus Help Bug*")
1441         (erase-buffer)
1442         (insert gnus-bug-message)
1443         (goto-char (point-min)))
1444       (message-pop-to-buffer "*Gnus Bug*"))
1445     (let ((message-this-is-mail t))
1446       (message-setup `((To . ,gnus-maintainer) (Subject . ""))))
1447     (when gnus-bug-create-help-buffer
1448       (push `(gnus-bug-kill-buffer) message-send-actions))
1449     (goto-char (point-min))
1450     (re-search-forward (concat "^" (regexp-quote mail-header-separator) "$"))
1451     (forward-line 1)
1452     (insert (gnus-version) "\n"
1453             (emacs-version) "\n")
1454     (when (and (boundp 'nntp-server-type)
1455                (stringp nntp-server-type))
1456       (insert nntp-server-type))
1457     (insert "\n\n\n\n\n")
1458     (let (text)
1459       (save-excursion
1460         (set-buffer (gnus-get-buffer-create " *gnus environment info*"))
1461         (erase-buffer)
1462         (gnus-debug)
1463         (setq text (buffer-string)))
1464       (insert "<#part type=application/emacs-lisp disposition=inline description=\"User settings\">\n" text "\n<#/part>"))
1465     (goto-char (point-min))
1466     (search-forward "Subject: " nil t)
1467     (message "")))
1468
1469 (defun gnus-bug-kill-buffer ()
1470   (when (get-buffer "*Gnus Help Bug*")
1471     (kill-buffer "*Gnus Help Bug*")))
1472
1473 (defun gnus-summary-yank-message (buffer n)
1474   "Yank the current article into a composed message."
1475   (interactive
1476    (list (completing-read "Buffer: " (mapcar 'list (message-buffers)) nil t)
1477          current-prefix-arg))
1478   (gnus-summary-iterate n
1479     (let ((gnus-inhibit-treatment t))
1480       (gnus-summary-select-article))
1481     (save-excursion
1482       (set-buffer buffer)
1483       (message-yank-buffer gnus-article-buffer))))
1484
1485 (defun gnus-debug ()
1486   "Attempts to go through the Gnus source file and report what variables have been changed.
1487 The source file has to be in the Emacs load path."
1488   (interactive)
1489   (let ((files gnus-debug-files)
1490         (point (point))
1491         file expr olist sym)
1492     (gnus-message 4 "Please wait while we snoop your variables...")
1493     (sit-for 0)
1494     ;; Go through all the files looking for non-default values for variables.
1495     (save-excursion
1496       (set-buffer (gnus-get-buffer-create " *gnus bug info*"))
1497       (while files
1498         (erase-buffer)
1499         (when (and (setq file (locate-library (pop files)))
1500                    (file-exists-p file))
1501           (insert-file-contents file)
1502           (goto-char (point-min))
1503           (if (not (re-search-forward "^;;* *Internal variables" nil t))
1504               (gnus-message 4 "Malformed sources in file %s" file)
1505             (narrow-to-region (point-min) (point))
1506             (goto-char (point-min))
1507             (while (setq expr (ignore-errors (read (current-buffer))))
1508               (ignore-errors
1509                 (and (or (eq (car expr) 'defvar)
1510                          (eq (car expr) 'defcustom))
1511                      (stringp (nth 3 expr))
1512                      (not (memq (nth 1 expr) gnus-debug-exclude-variables))
1513                      (or (not (boundp (nth 1 expr)))
1514                          (not (equal (eval (nth 2 expr))
1515                                      (symbol-value (nth 1 expr)))))
1516                      (push (nth 1 expr) olist)))))))
1517       (kill-buffer (current-buffer)))
1518     (when (setq olist (nreverse olist))
1519       (insert "------------------ Environment follows ------------------\n\n"))
1520     (while olist
1521       (if (boundp (car olist))
1522           (ignore-errors
1523            (gnus-pp
1524             `(setq ,(car olist)
1525                    ,(if (or (consp (setq sym (symbol-value (car olist))))
1526                             (and (symbolp sym)
1527                                  (not (or (eq sym nil)
1528                                           (eq sym t)))))
1529                         (list 'quote (symbol-value (car olist)))
1530                       (symbol-value (car olist))))))
1531         (insert ";; (makeunbound '" (symbol-name (car olist)) ")\n"))
1532       (setq olist (cdr olist)))
1533     (insert "\n\n")
1534     ;; Remove any control chars - they seem to cause trouble for some
1535     ;; mailers.  (Byte-compiled output from the stuff above.)
1536     (goto-char point)
1537     (while (re-search-forward "[\000-\010\013-\037\200-\237]" nil t)
1538       (replace-match (format "\\%03o" (string-to-char (match-string 0)))
1539                      t t))))
1540
1541 ;;; Treatment of rejected articles.
1542 ;;; Bounced mail.
1543
1544 (defun gnus-summary-resend-bounced-mail (&optional fetch)
1545   "Re-mail the current message.
1546 This only makes sense if the current message is a bounce message that
1547 contains some mail you have written which has been bounced back to
1548 you.
1549 If FETCH, try to fetch the article that this is a reply to, if indeed
1550 this is a reply."
1551   (interactive "P")
1552   (gnus-summary-select-article t)
1553   (set-buffer gnus-original-article-buffer)
1554   (gnus-setup-message 'compose-bounce
1555     (let* ((references (mail-fetch-field "references"))
1556            (parent (and references (gnus-parent-id references))))
1557       (message-bounce)
1558       ;; If there are references, we fetch the article we answered to.
1559       (and fetch parent
1560            (gnus-summary-refer-article parent)
1561            (gnus-summary-show-all-headers)))))
1562
1563 ;;; Gcc handling.
1564
1565 (defun gnus-inews-group-method (group)
1566   (cond
1567    ;; If the group doesn't exist, we assume
1568    ;; it's an archive group...
1569    ((and (null (gnus-get-info group))
1570          (eq (car (gnus-server-to-method gnus-message-archive-method))
1571              (car (gnus-server-to-method (gnus-group-method group)))))
1572     gnus-message-archive-method)
1573    ;; Use the method.
1574    ((gnus-info-method (gnus-get-info group))
1575     (gnus-info-method (gnus-get-info group)))
1576    ;; Find the method.
1577    (t (gnus-server-to-method (gnus-group-method group)))))
1578
1579 ;; Do Gcc handling, which copied the message over to some group.
1580 (defun gnus-inews-do-gcc (&optional gcc)
1581   (interactive)
1582   (save-excursion
1583     (save-restriction
1584       (message-narrow-to-headers)
1585       (let ((gcc (or gcc (mail-fetch-field "gcc" nil t)))
1586             (cur (current-buffer))
1587             groups group method group-art
1588             mml-externalize-attachments)
1589         (when gcc
1590           (message-remove-header "gcc")
1591           (widen)
1592           (setq groups (message-unquote-tokens
1593                         (message-tokenize-header gcc " ,")))
1594           ;; Copy the article over to some group(s).
1595           (while (setq group (pop groups))
1596             (unless (gnus-check-server
1597                      (setq method (gnus-inews-group-method group)))
1598               (error "Can't open server %s" (if (stringp method) method
1599                                               (car method))))
1600             (unless (gnus-request-group group nil method)
1601               (gnus-request-create-group group method))
1602             (setq mml-externalize-attachments
1603                   (if (stringp gnus-gcc-externalize-attachments)
1604                       (string-match gnus-gcc-externalize-attachments group)
1605                     gnus-gcc-externalize-attachments))
1606             (save-excursion
1607               (nnheader-set-temp-buffer " *acc*")
1608               (insert-buffer-substring cur)
1609               (message-encode-message-body)
1610               (save-restriction
1611                 (message-narrow-to-headers)
1612                 (let* ((mail-parse-charset message-default-charset)
1613                        (newsgroups-field (save-restriction
1614                                            (message-narrow-to-headers-or-head)
1615                                            (message-fetch-field "Newsgroups")))
1616                        (followup-field (save-restriction
1617                                          (message-narrow-to-headers-or-head)
1618                                          (message-fetch-field "Followup-To")))
1619                        ;; BUG: We really need to get the charset for
1620                        ;; each name in the Newsgroups and Followup-To
1621                        ;; lines to allow crossposting between group
1622                        ;; namess with incompatible character sets.
1623                        ;; -- Per Abrahamsen <abraham@dina.kvl.dk> 2001-10-08.
1624                        (group-field-charset
1625                         (gnus-group-name-charset
1626                          method (or newsgroups-field "")))
1627                        (followup-field-charset
1628                         (gnus-group-name-charset
1629                          method (or followup-field "")))
1630                        (rfc2047-header-encoding-alist
1631                         (append
1632                          (when group-field-charset
1633                            (list (cons "Newsgroups" group-field-charset)))
1634                          (when followup-field-charset
1635                            (list (cons "Followup-To" followup-field-charset)))
1636                          rfc2047-header-encoding-alist)))
1637                   (mail-encode-encoded-word-buffer)))
1638               (goto-char (point-min))
1639               (when (re-search-forward
1640                      (concat "^" (regexp-quote mail-header-separator) "$")
1641                      nil t)
1642                 (replace-match "" t t ))
1643               (unless (setq group-art
1644                             (gnus-request-accept-article group method t t))
1645                 (gnus-message 1 "Couldn't store article in group %s: %s"
1646                               group (gnus-status-message method))
1647                 (sit-for 2))
1648               (when (and group-art
1649                          ;; FIXME: Should gcc-mark-as-read work when
1650                          ;; Gnus is not running?
1651                          (gnus-alive-p)
1652                          (or gnus-gcc-mark-as-read
1653                              (and
1654                               (boundp 'gnus-inews-mark-gcc-as-read)
1655                               (symbol-value 'gnus-inews-mark-gcc-as-read))))
1656                 (gnus-group-mark-article-read group (cdr group-art)))
1657               (kill-buffer (current-buffer)))))))))
1658
1659 (defun gnus-inews-insert-gcc ()
1660   "Insert Gcc headers based on `gnus-outgoing-message-group'."
1661   (save-excursion
1662     (save-restriction
1663       (message-narrow-to-headers)
1664       (let* ((group gnus-outgoing-message-group)
1665              (gcc (cond
1666                    ((functionp group)
1667                     (funcall group))
1668                    ((or (stringp group) (list group))
1669                     group))))
1670         (when gcc
1671           (insert "Gcc: "
1672                   (if (stringp gcc)
1673                       (if (string-match " " gcc)
1674                           (concat "\"" gcc "\"")
1675                         gcc)
1676                     (mapconcat (lambda (group)
1677                                  (if (string-match " " group)
1678                                      (concat "\"" group "\"")
1679                                    group))
1680                                gcc " "))
1681                   "\n"))))))
1682
1683 (defun gnus-inews-insert-archive-gcc (&optional group)
1684   "Insert the Gcc to say where the article is to be archived."
1685   (let* ((var gnus-message-archive-group)
1686          (group (or group gnus-newsgroup-name ""))
1687          (gcc-self-val
1688           (and gnus-newsgroup-name
1689                (not (equal gnus-newsgroup-name ""))
1690                (gnus-group-find-parameter
1691                 gnus-newsgroup-name 'gcc-self)))
1692          result
1693          (groups
1694           (cond
1695            ((null gnus-message-archive-method)
1696             ;; Ignore.
1697             nil)
1698            ((stringp var)
1699             ;; Just a single group.
1700             (list var))
1701            ((null var)
1702             ;; We don't want this.
1703             nil)
1704            ((and (listp var) (stringp (car var)))
1705             ;; A list of groups.
1706             var)
1707            ((functionp var)
1708             ;; A function.
1709             (funcall var group))
1710            (t
1711             ;; An alist of regexps/functions/forms.
1712             (while (and var
1713                         (not
1714                          (setq result
1715                                (cond
1716                                 ((stringp (caar var))
1717                                  ;; Regexp.
1718                                  (when (string-match (caar var) group)
1719                                    (cdar var)))
1720                                 ((functionp (car var))
1721                                  ;; Function.
1722                                  (funcall (car var) group))
1723                                 (t
1724                                  (eval (car var)))))))
1725               (setq var (cdr var)))
1726             result)))
1727          name)
1728     (when (or groups gcc-self-val)
1729       (when (stringp groups)
1730         (setq groups (list groups)))
1731       (save-excursion
1732         (save-restriction
1733           (message-narrow-to-headers)
1734           (goto-char (point-max))
1735           (insert "Gcc: ")
1736           (if gcc-self-val
1737               ;; Use the `gcc-self' param value instead.
1738               (progn
1739                 (insert
1740                  (if (stringp gcc-self-val)
1741                      (if (string-match " " gcc-self-val)
1742                          (concat "\"" gcc-self-val "\"")
1743                        gcc-self-val)
1744                    ;; In nndoc groups, we use the parent group name
1745                    ;; instead of the current group.
1746                    (let ((group (or (gnus-group-find-parameter
1747                                      gnus-newsgroup-name 'parent-group)
1748                                     group)))
1749                      (if (string-match " " group)
1750                          (concat "\"" group "\"")
1751                        group))))
1752                 (if (not (eq gcc-self-val 'none))
1753                     (insert "\n")
1754                   (gnus-delete-line)))
1755             ;; Use the list of groups.
1756             (while (setq name (pop groups))
1757               (let ((str (if (string-match ":" name)
1758                              name
1759                            (gnus-group-prefixed-name
1760                             name gnus-message-archive-method))))
1761                 (insert (if (string-match " " str)
1762                             (concat "\"" str "\"")
1763                           str)))
1764               (when groups
1765                 (insert " ")))
1766             (insert "\n")))))))
1767
1768 (defun gnus-mailing-list-followup-to ()
1769   "Look at the headers in the current buffer and return a Mail-Followup-To address."
1770   (let ((x-been-there (gnus-fetch-original-field "x-beenthere"))
1771         (list-post (gnus-fetch-original-field "list-post")))
1772     (when (and list-post
1773                (string-match "mailto:\\([^>]+\\)" list-post))
1774       (setq list-post (match-string 1 list-post)))
1775     (or list-post
1776         x-been-there)))
1777
1778 ;;; Posting styles.
1779
1780 (defun gnus-configure-posting-styles (&optional group-name)
1781   "Configure posting styles according to `gnus-posting-styles'."
1782   (unless gnus-inhibit-posting-styles
1783     (let ((group (or group-name gnus-newsgroup-name ""))
1784           (styles gnus-posting-styles)
1785           style match attribute value v results
1786           filep name address element)
1787       ;; If the group has a posting-style parameter, add it at the end with a
1788       ;; regexp matching everything, to be sure it takes precedence over all
1789       ;; the others.
1790       (when gnus-newsgroup-name
1791         (let ((tmp-style (gnus-group-find-parameter group 'posting-style t)))
1792           (when tmp-style
1793             (setq styles (append styles (list (cons ".*" tmp-style)))))))
1794       ;; Go through all styles and look for matches.
1795       (dolist (style styles)
1796         (setq match (pop style))
1797         (goto-char (point-min))
1798         (when (cond
1799                ((stringp match)
1800                 ;; Regexp string match on the group name.
1801                 (string-match match group))
1802                ((eq match 'header)
1803                 ;; Obsolete format of header match.
1804                 (and (gnus-buffer-live-p gnus-article-copy)
1805                      (with-current-buffer gnus-article-copy
1806                        (save-restriction
1807                          (nnheader-narrow-to-headers)
1808                          (let ((header (message-fetch-field (pop style))))
1809                            (and header
1810                                 (string-match (pop style) header)))))))
1811                ((or (symbolp match)
1812                     (functionp match))
1813                 (cond
1814                  ((functionp match)
1815                   ;; Function to be called.
1816                   (funcall match))
1817                  ((boundp match)
1818                   ;; Variable to be checked.
1819                   (symbol-value match))))
1820                ((listp match)
1821                 (cond
1822                  ((eq (car match) 'header)
1823                   ;; New format of header match.
1824                   (and (gnus-buffer-live-p gnus-article-copy)
1825                        (with-current-buffer gnus-article-copy
1826                          (save-restriction
1827                            (nnheader-narrow-to-headers)
1828                            (let ((header (message-fetch-field (nth 1 match))))
1829                              (and header
1830                                   (string-match (nth 2 match) header)))))))
1831                  (t
1832                   ;; This is a form to be evaled.
1833                   (eval match)))))
1834           ;; We have a match, so we set the variables.
1835           (dolist (attribute style)
1836             (setq element (pop attribute)
1837                   filep nil)
1838             (setq value
1839                   (cond
1840                    ((eq (car attribute) :file)
1841                     (setq filep t)
1842                     (cadr attribute))
1843                    ((eq (car attribute) :value)
1844                     (cadr attribute))
1845                    (t
1846                     (car attribute))))
1847             ;; We get the value.
1848             (setq v
1849                   (cond
1850                    ((stringp value)
1851                     value)
1852                    ((or (symbolp value)
1853                         (functionp value))
1854                     (cond ((functionp value)
1855                            (funcall value))
1856                           ((boundp value)
1857                            (symbol-value value))))
1858                    ((listp value)
1859                     (eval value))))
1860             ;; Translate obsolescent value.
1861             (cond
1862              ((eq element 'signature-file)
1863               (setq element 'signature
1864                     filep t))
1865              ((eq element 'x-face-file)
1866               (setq element 'x-face
1867                     filep t)))
1868             ;; Get the contents of file elems.
1869             (when (and filep v)
1870               (setq v (with-temp-buffer
1871                         (insert-file-contents v)
1872                         (goto-char (point-max))
1873                         (while (bolp)
1874                           (delete-char -1))
1875                         (buffer-string))))
1876             (setq results (delq (assoc element results) results))
1877             (push (cons element v) results))))
1878       ;; Now we have all the styles, so we insert them.
1879       (setq name (assq 'name results)
1880             address (assq 'address results))
1881       (setq results (delq name (delq address results)))
1882       (gnus-make-local-hook 'message-setup-hook)
1883       (setq results (sort results (lambda (x y)
1884                                     (string-lessp (car x) (car y)))))
1885       (dolist (result results)
1886         (add-hook 'message-setup-hook
1887                   (cond
1888                    ((eq 'eval (car result))
1889                     'ignore)
1890                    ((eq 'body (car result))
1891                     `(lambda ()
1892                        (save-excursion
1893                          (message-goto-body)
1894                          (insert ,(cdr result)))))
1895                    ((eq 'signature (car result))
1896                     (set (make-local-variable 'message-signature) nil)
1897                     (set (make-local-variable 'message-signature-file) nil)
1898                     (if (not (cdr result))
1899                         'ignore
1900                       `(lambda ()
1901                          (save-excursion
1902                            (let ((message-signature ,(cdr result)))
1903                              (when message-signature
1904                                (message-insert-signature)))))))
1905                    (t
1906                     (let ((header
1907                            (if (symbolp (car result))
1908                                (capitalize (symbol-name (car result)))
1909                              (car result))))
1910                       `(lambda ()
1911                          (save-excursion
1912                            (message-remove-header ,header)
1913                            (let ((value ,(cdr result)))
1914                              (when value
1915                                (message-goto-eoh)
1916                                (insert ,header ": " value)
1917                                (unless (bolp)
1918                                  (insert "\n")))))))))
1919                   nil 'local))
1920       (when (or name address)
1921         (add-hook 'message-setup-hook
1922                   `(lambda ()
1923                      (set (make-local-variable 'user-mail-address)
1924                           ,(or (cdr address) user-mail-address))
1925                      (let ((user-full-name ,(or (cdr name) (user-full-name)))
1926                            (user-mail-address
1927                             ,(or (cdr address) user-mail-address)))
1928                        (save-excursion
1929                          (message-remove-header "From")
1930                          (message-goto-eoh)
1931                          (insert "From: " (message-make-from) "\n"))))
1932                   nil 'local)))))
1933
1934 ;;; Allow redefinition of functions.
1935
1936 (gnus-ems-redefine)
1937
1938 (provide 'gnus-msg)
1939
1940 ;;; arch-tag: 9f22b2f5-1c0a-49de-916e-4c88e984852b
1941 ;;; gnus-msg.el ends here