]> code.delx.au - gnu-emacs/blob - configure.in
delx.au / code / gnu-emacs / blob
summary | shortlog | log | commit | commitdiff | tree
history | raw | HEAD
Add support for mipseb-*-netbsd* machines.
[gnu-emacs] / configure.in
1 dnl Autoconf script for GNU Emacs
2 dnl To rebuild the `configure' script from this, execute the command
3 dnl autoconf
4 dnl in the directory containing this script.
5 dnl
6 dnl Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002
7 dnl Free Software Foundation, Inc.
8 dnl
9 dnl This file is part of GNU Emacs.
10 dnl
11 dnl GNU Emacs is free software; you can redistribute it and/or modify
12 dnl it under the terms of the GNU General Public License as published by
13 dnl the Free Software Foundation; either version 2, or (at your option)
14 dnl any later version.
15 dnl
16 dnl GNU Emacs is distributed in the hope that it will be useful,
17 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
18 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
19 dnl GNU General Public License for more details.
20 dnl
21 dnl You should have received a copy of the GNU General Public License
22 dnl along with GNU Emacs; see the file COPYING. If not, write to the
23 dnl Free Software Foundation, Inc., 59 Temple Place - Suite 330,
24 dnl Boston, MA 02111-1307, USA.
25
26 AC_PREREQ(2.51)dnl
27 AC_INIT(src/lisp.h)
28 AC_CONFIG_HEADER(src/config.h:src/config.in)
29
30 dnl Support for --program-prefix, --program-suffix and
31 dnl --program-transform-name options
32 AC_ARG_PROGRAM
33
34 lispdir='${datadir}/emacs/${version}/lisp'
35 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
36 '${datadir}/emacs/site-lisp:${datadir}/emacs/${version}/leim'
37 lisppath='${locallisppath}:${lispdir}'
38 etcdir='${datadir}/emacs/${version}/etc'
39 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
40 docdir='${datadir}/emacs/${version}/etc'
41 gamedir=yes
42
43 AC_ARG_WITH(game-dir,
44 [ --with-game-dir use a shared game directory if possible],
45 [
46 gamedir="$withval"
47 ])
48 if test "$gamedir" = yes; then
49 gamedir="${localstatedir}/games/emacs"
50 fi
51 eval tgamedir=\"$gamedir\"
52 if test "$gamedir" != no; then
53 AC_DEFINE_UNQUOTED(HAVE_SHARED_GAME_DIR, "$tgamedir",
54 [Define to the name of the shared game directory.])
55 fi
56
57 gameuser=games
58 AC_ARG_WITH(game-user,
59 [ --with-game-user use specified user for game directory],
60 [gameuser="$withval"])
61
62 AC_ARG_WITH(gcc,
63 [ --without-gcc don't use GCC to compile Emacs if GCC is found])
64 AC_ARG_WITH(pop,
65 [ --without-pop don't support POP mail retrieval with movemail],
66 [if test "$withval" = yes; then
67 AC_DEFINE(MAIL_USE_POP)
68 else :
69 fi],
70 AC_DEFINE(MAIL_USE_POP))
71 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
72 AC_ARG_WITH(kerberos,
73 [ --with-kerberos support Kerberos-authenticated POP],
74 [AC_DEFINE(KERBEROS)])
75 AH_TEMPLATE(KERBEROS,
76 [Define to support Kerberos-authenticated POP mail retrieval.])dnl
77 AC_ARG_WITH(kerberos5,
78 [ --with-kerberos5 support Kerberos version 5 authenticated POP],
79 [if test "${with_kerberos5+set}" = set; then
80 if test "${with_kerberos+set}" != set; then
81 with_kerberos=yes
82 AC_DEFINE(KERBEROS)
83 fi
84 fi
85 AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])])
86 AC_ARG_WITH(hesiod,
87 [ --with-hesiod support Hesiod to get the POP server host],
88 [AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])])
89
90 AC_ARG_WITH(sound,
91 [ --without-sound don't compile with sound support])
92
93 dnl This should be the last --with option, because --with-x is
94 dnl added later on when we find the path of X, and it's best to
95 dnl keep them together visually.
96 AC_ARG_WITH(x-toolkit,
97 [ --with-x-toolkit=KIT use an X toolkit (KIT = yes/lucid/athena/motif/no)],
98 [ case "${withval}" in
99 y | ye | yes ) val=athena ;;
100 n | no ) val=no ;;
101 l | lu | luc | luci | lucid ) val=lucid ;;
102 a | at | ath | athe | athen | athena ) val=athena ;;
103 m | mo | mot | moti | motif ) val=motif ;;
104 dnl These don't currently work.
105 dnl o | op | ope | open | open- | open-l | open-lo \
106 dnl | open-loo | open-look ) val=open-look ;;
107 * )
108 dnl AC_MSG_ERROR([the \`--with-x-toolkit' option is supposed to have a value
109 dnl which is \`yes', \`no', \`lucid', \`athena', \`motif' or \`open-look'.])
110 AC_MSG_ERROR([\`--with-x-toolkit=$withval' is invalid\;
111 this option's value should be \`yes', \`no', \`lucid', \`athena', or \`motif'.
112 Currently, \`yes', \`athena' and \`lucid' are synonyms.])
113 ;;
114 esac
115 with_x_toolkit=$val
116 ])
117 AC_ARG_WITH(xpm,
118 [ --with-xpm use -lXpm for displaying XPM images])
119 AC_ARG_WITH(jpeg,
120 [ --with-jpeg use -ljpeg for displaying JPEG images])
121 AC_ARG_WITH(tiff,
122 [ --with-tiff use -ltiff for displaying TIFF images])
123 AC_ARG_WITH(gif,
124 [ --with-gif use -lungif for displaying GIF images])
125 AC_ARG_WITH(png,
126 [ --with-png use -lpng for displaying PNG images])
127 AC_ARG_WITH(toolkit-scroll-bars,
128 [ --without-toolkit-scroll-bars
129 don't use Motif or Xaw3d scroll bars])
130 AC_ARG_WITH(xim,
131 [ --without-xim don't use X11 XIM])
132 AC_ARG_WITH(carbon,
133 [ --without-carbon don't use Carbon GUI on Mac OS X])
134
135 #### Make srcdir absolute, if it isn't already. It's important to
136 #### avoid running the path through pwd unnecessarily, since pwd can
137 #### give you automounter prefixes, which can go away. We do all this
138 #### so Emacs can find its files when run uninstalled.
139 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
140 unset CDPATH
141 case "${srcdir}" in
142 /* ) ;;
143 . )
144 ## We may be able to use the $PWD environment variable to make this
145 ## absolute. But sometimes PWD is inaccurate.
146 ## Note: we used to use ${PWD} at the end instead of `pwd`,
147 ## but that tested only for a well-formed and valid PWD,
148 ## it did not object when PWD was well-formed and valid but just wrong.
149 if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`" ;
150 then
151 srcdir="$PWD"
152 else
153 srcdir="`(cd ${srcdir}; pwd)`"
154 fi
155 ;;
156 * ) srcdir="`(cd ${srcdir}; pwd)`" ;;
157 esac
158
159 #### Check if the source directory already has a configured system in it.
160 if test `pwd` != `(cd ${srcdir} && pwd)` \
161 && test -f "${srcdir}/src/config.h" ; then
162 AC_MSG_WARN([The directory tree \`${srcdir}' is being used
163 as a build directory right now; it has been configured in its own
164 right. To configure in another directory as well, you MUST
165 use GNU make. If you do not have GNU make, then you must
166 now do \`make distclean' in ${srcdir},
167 and then run $0 again.])
168
169 changequote(, )dnl
170 extrasub='/^VPATH[ ]*=/c\
171 changequote([, ])dnl
172 vpath %.c $(srcdir)\
173 vpath %.h $(srcdir)\
174 vpath %.y $(srcdir)\
175 vpath %.l $(srcdir)\
176 vpath %.s $(srcdir)\
177 vpath %.in $(srcdir)\
178 vpath %.texi $(srcdir)'
179 fi
180
181 #### Given the configuration name, set machfile and opsysfile to the
182 #### names of the m/*.h and s/*.h files we should use.
183
184 ### Canonicalize the configuration name.
185
186 AC_CANONICAL_HOST
187 canonical=$host
188 configuration=${host_alias-$host}
189
190 changequote(, )dnl
191
192 ### If you add support for a new configuration, add code to this
193 ### switch statement to recognize your configuration name and select
194 ### the appropriate operating system and machine description files.
195
196 ### You would hope that you could choose an m/*.h file pretty much
197 ### based on the machine portion of the configuration name, and an s-
198 ### file based on the operating system portion. However, it turns out
199 ### that each m/*.h file is pretty manufacturer-specific - for
200 ### example, apollo.h, hp9000s300.h, mega68k, news.h, and tad68k are
201 ### all 68000 machines; mips.h, pmax.h, and news-risc are all MIPS
202 ### machines. So we basically have to have a special case for each
203 ### configuration name.
204 ###
205 ### As far as handling version numbers on operating systems is
206 ### concerned, make sure things will fail in a fixable way. If
207 ### /etc/MACHINES doesn't say anything about version numbers, be
208 ### prepared to handle anything reasonably. If version numbers
209 ### matter, be sure /etc/MACHINES says something about it.
210 ###
211 ### Eric Raymond says we should accept strings like "sysvr4" to mean
212 ### "System V Release 4"; he writes, "The old convention encouraged
213 ### confusion between `system' and `release' levels'."
214
215 machine='' opsys='' unported=no
216 case "${canonical}" in
217
218 ## FreeBSD ports
219 *-*-freebsd* )
220 opsys=freebsd
221 case "${canonical}" in
222 alpha*-*-freebsd*) machine=alpha ;;
223 i[3456]86-*-freebsd*) machine=intel386 ;;
224 esac
225 ;;
226
227 ## NetBSD ports
228 *-*-netbsd* )
229 opsys=netbsd
230 case "${canonical}" in
231 alpha*-*-netbsd*) machine=alpha ;;
232 i[3456]86-*-netbsd*) machine=intel386 ;;
233 m68k-*-netbsd*)
234 # This is somewhat bogus.
235 machine=hp9000s300 ;;
236 powerpc-apple-netbsd*) machine=macppc ;;
237 mips-*-netbsd*) machine=pmax ;;
238 mipsel-*-netbsd*) machine=pmax ;;
239 mipseb-*-netbsd*) machine=pmax ;;
240 ns32k-*-netbsd*) machine=ns32000 ;;
241 powerpc-*-netbsd*) machine=macppc ;;
242 sparc*-*-netbsd*) machine=sparc ;;
243 vax-*-netbsd*) machine=vax ;;
244 arm-*-netbsd*) machine=arm ;;
245 esac
246 ;;
247
248 ## OpenBSD ports
249 *-*-openbsd* )
250 opsys=openbsd
251 case "${canonical}" in
252 alpha*-*-openbsd*) machine=alpha ;;
253 i386-*-openbsd*) machine=intel386 ;;
254 m68k-*-openbsd*) machine=hp9000s300 ;;
255 mipsel-*-openbsd*) machine=pmax ;;
256 ns32k-*-openbsd*) machine=ns32000 ;;
257 sparc-*-openbsd*) machine=sparc ;;
258 vax-*-openbsd*) machine=vax ;;
259 esac
260 ;;
261
262 ## Acorn RISCiX:
263 arm-acorn-riscix1.1* )
264 machine=acorn opsys=riscix1-1
265 ;;
266 arm-acorn-riscix1.2* | arm-acorn-riscix )
267 ## This name is riscix12 instead of riscix1.2
268 ## to avoid a file name conflict on MSDOS.
269 machine=acorn opsys=riscix12
270 ;;
271
272 ## BSDI ports
273 *-*-bsdi* )
274 opsys=bsdi
275 case "${canonical}" in
276 i[345]86-*-bsdi*) machine=intel386 ;;
277 sparc-*-bsdi*) machine=sparc ;;
278 powerpc-*-bsdi*) machine=macppc ;;
279 esac
280 case "${canonical}" in
281 *-*-bsd386* | *-*-bsdi1* ) opsys=bsd386 ;;
282 *-*-bsdi2.0* ) opsys=bsdos2 ;;
283 *-*-bsdi2* ) opsys=bsdos2-1 ;;
284 *-*-bsdi3* ) opsys=bsdos3 ;;
285 *-*-bsdi[45]* ) opsys=bsdos4 ;;
286 esac
287 ;;
288
289 ## Alliant machines
290 ## Strictly speaking, we need the version of the alliant operating
291 ## system to choose the right machine file, but currently the
292 ## configuration name doesn't tell us enough to choose the right
293 ## one; we need to give alliants their own operating system name to
294 ## do this right. When someone cares, they can help us.
295 fx80-alliant-* )
296 machine=alliant4 opsys=bsd4-2
297 ;;
298 i860-alliant-* )
299 machine=alliant-2800 opsys=bsd4-3
300 ;;
301
302 ## Alpha (DEC) machines.
303 alpha*-dec-osf* )
304 machine=alpha opsys=osf1
305 # This is needed to find X11R6.1 libraries for certain tests.
306 NON_GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
307 GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
308 # NON_GNU_CPP is necessary on 5.0 to avoid mangling src/Makefile
309 # due to non-traditional preprocessing with the current compiler
310 # defaults. OSF 4 can also have that compiler version, and there
311 # seems always to have been a usable /usr/bin/cpp.
312 NON_GNU_CPP=/usr/bin/cpp
313 case "${canonical}" in
314 alpha*-dec-osf[5-9]*)
315 opsys=osf5-0 ;;
316 esac
317 ;;
318
319 alpha*-*-linux-gnu* )
320 machine=alpha opsys=gnu-linux
321 ;;
322
323 arm*-*-linux-gnu* )
324 machine=arm opsys=gnu-linux
325 ;;
326
327 ppc-*-linux | \
328 powerpc-*-linux* )
329 machine=macppc opsys=gnu-linux
330 ;;
331
332 ## Altos 3068
333 m68*-altos-sysv* )
334 machine=altos opsys=usg5-2
335 ;;
336
337 ## Amdahl UTS
338 580-amdahl-sysv* )
339 machine=amdahl opsys=usg5-2-2
340 ;;
341
342 ## Apollo, Domain/OS
343 m68*-apollo-* )
344 machine=apollo opsys=bsd4-3
345 ;;
346
347 ## AT&T 3b2, 3b5, 3b15, 3b20
348 we32k-att-sysv* )
349 machine=att3b opsys=usg5-2-2
350 ;;
351
352 ## AT&T 3b1 - The Mighty Unix PC!
353 m68*-att-sysv* )
354 machine=7300 opsys=usg5-2-2
355 ;;
356
357 ## Bull dpx20
358 rs6000-bull-bosx* )
359 machine=ibmrs6000 opsys=aix3-2
360 ;;
361
362 ## Bull dpx2
363 m68*-bull-sysv3* )
364 machine=dpx2 opsys=usg5-3
365 ;;
366
367 ## Bull sps7
368 m68*-bull-sysv2* )
369 machine=sps7 opsys=usg5-2
370 ;;
371
372 ## CCI 5/32, 6/32 -- see "Tahoe".
373
374 ## Celerity
375 ## I don't know what configuration name to use for this; config.sub
376 ## doesn't seem to know anything about it. Hey, Celerity users, get
377 ## in touch with us!
378 celerity-celerity-bsd* )
379 machine=celerity opsys=bsd4-2
380 ;;
381
382 ## Clipper
383 ## What operating systems does this chip run that Emacs has been
384 ## tested on?
385 clipper-* )
386 machine=clipper
387 ## We'll use the catch-all code at the bottom to guess the
388 ## operating system.
389 ;;
390
391 ## Compaq Nonstop
392 mips-compaq-nonstopux* )
393 machine=nonstopux opsys=nonstopux
394 ;;
395
396 ## Convex
397 *-convex-bsd* | *-convex-convexos* )
398 machine=convex opsys=bsd4-3
399 ## Prevents spurious white space in makefiles - d.m.cooke@larc.nasa.gov
400 NON_GNU_CPP="cc -E -P"
401 ;;
402
403 ## Cubix QBx/386
404 i[3456]86-cubix-sysv* )
405 machine=intel386 opsys=usg5-3
406 ;;
407
408 ## Cydra 5
409 cydra*-cydrome-sysv* )
410 machine=cydra5 opsys=usg5-3
411 ;;
412
413 ## Data General AViiON Machines
414 ## DG changed naming conventions with the release of 5.4.4.10, they
415 ## dropped the initial 5.4 but left the intervening R. Because of the
416 ## R this shouldn't conflict with older versions of the OS (which I
417 ## think were named like dgux4.*). In addition, DG new AViiONs series
418 ## uses either Motorola M88k or Intel Pentium CPUs.
419 m88k-dg-dguxR4.* | m88k-dg-dgux4* )
420 machine=aviion opsys=dgux4
421 ;;
422 m88k-dg-dgux5.4R3* | m88k-dg-dgux5.4.3* )
423 ## This name is dgux5-4-3 instead of dgux5-4r3
424 ## to avoid a file name conflict on MSDOS.
425 machine=aviion opsys=dgux5-4-3
426 ;;
427 m88k-dg-dgux5.4R2* | m88k-dg-dgux5.4.2* )
428 machine=aviion opsys=dgux5-4r2
429 ;;
430 m88k-dg-dgux* )
431 machine=aviion opsys=dgux
432 ;;
433
434 ## Data General AViiON Intel (x86) Machines
435 ## Exists from 5.4.3 (current i586-dg-dguxR4.11)
436 ## Ehud Karni, 1998-may-30, ehud@unix.simonwiesel.co.il
437 i[345]86-dg-dguxR4* )
438 machine=aviion-intel opsys=dgux4
439 ;;
440
441 ## DECstations
442 mips-dec-ultrix[0-3].* | mips-dec-ultrix4.0* | mips-dec-bsd4.2* )
443 machine=pmax opsys=bsd4-2
444 ;;
445 mips-dec-ultrix4.[12]* | mips-dec-bsd* )
446 machine=pmax opsys=bsd4-3
447 ;;
448 mips-dec-ultrix* )
449 machine=pmax opsys=ultrix4-3
450 ;;
451 mips-dec-osf* )
452 machine=pmax opsys=osf1
453 ;;
454 mips-dec-mach_bsd4.3* )
455 machine=pmax opsys=mach-bsd4-3
456 ;;
457
458 ## Motorola Delta machines
459 m68k-motorola-sysv* | m68000-motorola-sysv* )
460 machine=delta opsys=usg5-3
461 if test -z "`type gnucc | grep 'not found'`"
462 then
463 if test -s /etc/167config
464 then CC="gnucc -m68040"
465 else CC="gnucc -m68881"
466 fi
467 else
468 if test -z "`type gcc | grep 'not found'`"
469 then CC=gcc
470 else CC=cc
471 fi
472 fi
473 ;;
474 m88k-motorola-sysv4* )
475 # jbotte@bnr.ca says that UNIX_System_V <hostName> 4.0 R40V4.3 m88k mc88110
476 # needs POSIX_SIGNALS and therefore needs usg5-4-2.
477 # I hope there are not other 4.0 versions for this machine
478 # which really need usg5-4 instead.
479 machine=delta88k opsys=usg5-4-2
480 ;;
481 m88k-motorola-sysv* | m88k-motorola-m88kbcs* )
482 machine=delta88k opsys=usg5-3
483 ;;
484
485 ## Dual machines
486 m68*-dual-sysv* )
487 machine=dual opsys=usg5-2
488 ;;
489 m68*-dual-uniplus* )
490 machine=dual opsys=unipl5-2
491 ;;
492
493 ## Elxsi 6400
494 elxsi-elxsi-sysv* )
495 machine=elxsi opsys=usg5-2
496 ;;
497
498 ## Encore machines
499 ns16k-encore-bsd* )
500 machine=ns16000 opsys=umax
501 ;;
502
503 ## The GEC 63 - apparently, this port isn't really finished yet.
504 # I'm sure we finished off the last of the machines, though. -- fx
505
506 ## Gould Power Node and NP1
507 pn-gould-bsd4.2* )
508 machine=gould opsys=bsd4-2
509 ;;
510 pn-gould-bsd4.3* )
511 machine=gould opsys=bsd4-3
512 ;;
513 np1-gould-bsd* )
514 machine=gould-np1 opsys=bsd4-3
515 ;;
516
517 ## Harris Night Hawk machines running CX/UX (a 5000 looks just like a 4000
518 ## as far as Emacs is concerned).
519 m88k-harris-cxux* )
520 # Build needs to be different on 7.0 and later releases
521 case "`uname -r`" in
522 [56].[0-9] ) machine=nh4000 opsys=cxux ;;
523 [7].[0-9] ) machine=nh4000 opsys=cxux7 ;;
524 esac
525 NON_GNU_CPP="/lib/cpp"
526 ;;
527 ## Harris ecx or gcx running CX/UX (Series 1200, Series 3000)
528 m68k-harris-cxux* )
529 machine=nh3000 opsys=cxux
530 ;;
531 ## Harris power pc NightHawk running Power UNIX (Series 6000)
532 powerpc-harris-powerunix )
533 machine=nh6000 opsys=powerunix
534 NON_GNU_CPP="cc -Xo -E -P"
535 ;;
536 ## SR2001/SR2201 running HI-UX/MPP
537 hppa1.1-hitachi-hiuxmpp* )
538 machine=sr2k opsys=hiuxmpp
539 ;;
540 hppa1.1-hitachi-hiuxwe2* )
541 machine=sr2k opsys=hiuxwe2
542 ;;
543 ## Honeywell XPS100
544 xps*-honeywell-sysv* )
545 machine=xps100 opsys=usg5-2
546 ;;
547
548 ## HP 9000 series 200 or 300
549 m68*-hp-bsd* )
550 machine=hp9000s300 opsys=bsd4-3
551 ;;
552 ## HP/UX 7, 8, 9, and 10 are supported on these machines.
553 m68*-hp-hpux* )
554 case "`uname -r`" in
555 ## Someone's system reports A.B8.05 for this.
556 ## I wonder what other possibilities there are.
557 *.B8.* ) machine=hp9000s300 opsys=hpux8 ;;
558 *.08.* ) machine=hp9000s300 opsys=hpux8 ;;
559 *.09.* ) machine=hp9000s300 opsys=hpux9 ;;
560 *.1[0-9].* ) machine=hp9000s300 opsys=hpux9shr ;;
561 *) machine=hp9000s300 opsys=hpux ;;
562 esac
563 ;;
564
565 ## HP 9000 series 700 and 800, running HP/UX
566 hppa*-hp-hpux7* )
567 machine=hp800 opsys=hpux
568 ;;
569 hppa*-hp-hpux8* )
570 machine=hp800 opsys=hpux8
571 ;;
572 hppa*-hp-hpux9shr* )
573 machine=hp800 opsys=hpux9shr
574 ;;
575 hppa*-hp-hpux9* )
576 machine=hp800 opsys=hpux9
577 ;;
578 hppa*-hp-hpux10* )
579 machine=hp800 opsys=hpux10
580 ;;
581 hppa*-hp-hpux1[1-9]* )
582 machine=hp800 opsys=hpux11
583 ;;
584
585 hppa*-*-linux-gnu* )
586 machine=hp800 opsys=gnu-linux
587 ;;
588
589 ## HP 9000 series 700 and 800, running HP/UX
590 hppa*-hp-hpux* )
591 ## Cross-compilation? Nah!
592 case "`uname -r`" in
593 ## Someone's system reports A.B8.05 for this.
594 ## I wonder what other possibilities there are.
595 *.B8.* ) machine=hp800 opsys=hpux8 ;;
596 *.08.* ) machine=hp800 opsys=hpux8 ;;
597 *.09.* ) machine=hp800 opsys=hpux9 ;;
598 *) machine=hp800 opsys=hpux10 ;;
599 esac
600 ;;
601 hppa*-*-nextstep* )
602 machine=hp800 opsys=nextstep
603 ;;
604
605 ## Orion machines
606 orion-orion-bsd* )
607 machine=orion opsys=bsd4-2
608 ;;
609 clipper-orion-bsd* )
610 machine=orion105 opsys=bsd4-2
611 ;;
612
613 ## IBM machines
614 i[3456]86-ibm-aix1.1* )
615 machine=ibmps2-aix opsys=usg5-2-2
616 ;;
617 i[3456]86-ibm-aix1.[23]* | i[3456]86-ibm-aix* )
618 machine=ibmps2-aix opsys=usg5-3
619 ;;
620 i370-ibm-aix*)
621 machine=ibm370aix opsys=usg5-3
622 ;;
623 s390-*-linux-gnu)
624 machine=ibms390 opsys=gnu-linux
625 ;;
626 rs6000-ibm-aix3.1* | powerpc-ibm-aix3.1* )
627 machine=ibmrs6000 opsys=aix3-1
628 ;;
629 rs6000-ibm-aix3.2.5 | powerpc-ibm-aix3.2.5 )
630 machine=ibmrs6000 opsys=aix3-2-5
631 ;;
632 rs6000-ibm-aix4.1* | powerpc-ibm-aix4.1* )
633 machine=ibmrs6000 opsys=aix4-1
634 ;;
635 rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2* )
636 machine=ibmrs6000 opsys=aix4-2
637 ;;
638 rs6000-ibm-aix5.1* | powerpc-ibm-aix5.1* )
639 machine=ibmrs6000 opsys=aix4-2
640 ;;
641 rs6000-ibm-aix4.0* | powerpc-ibm-aix4.0* )
642 machine=ibmrs6000 opsys=aix4
643 ;;
644 rs6000-ibm-aix4* | powerpc-ibm-aix4* )
645 machine=ibmrs6000 opsys=aix4-1
646 ;;
647 rs6000-ibm-aix* | powerpc-ibm-aix* )
648 machine=ibmrs6000 opsys=aix3-2
649 ;;
650 romp-ibm-bsd4.3* )
651 machine=ibmrt opsys=bsd4-3
652 ;;
653 romp-ibm-bsd4.2* )
654 machine=ibmrt opsys=bsd4-2
655 ;;
656 romp-ibm-aos4.3* )
657 machine=ibmrt opsys=bsd4-3
658 ;;
659 romp-ibm-aos4.2* )
660 machine=ibmrt opsys=bsd4-2
661 ;;
662 romp-ibm-aos* )
663 machine=ibmrt opsys=bsd4-3
664 ;;
665 romp-ibm-bsd* )
666 machine=ibmrt opsys=bsd4-3
667 ;;
668 romp-ibm-aix* )
669 machine=ibmrt-aix opsys=usg5-2-2
670 ;;
671
672 ## Integrated Solutions `Optimum V'
673 m68*-isi-bsd4.2* )
674 machine=isi-ov opsys=bsd4-2
675 ;;
676 m68*-isi-bsd4.3* )
677 machine=isi-ov opsys=bsd4-3
678 ;;
679
680 ## Intel 386 machines where we do care about the manufacturer
681 i[3456]86-intsys-sysv* )
682 machine=is386 opsys=usg5-2-2
683 ;;
684
685 ## Prime EXL
686 i[3456]86-prime-sysv* )
687 machine=i386 opsys=usg5-3
688 ;;
689
690 ## Sequent Symmetry running Dynix
691 i[3456]86-sequent-bsd* )
692 machine=symmetry opsys=bsd4-3
693 ;;
694
695 ## Sequent Symmetry running ptx 4, which is a modified SVR4.
696 i[3456]86-sequent-ptx4* | i[3456]86-sequent-sysv4* )
697 machine=sequent-ptx opsys=ptx4
698 NON_GNU_CPP=/lib/cpp
699 ;;
700
701 ## Sequent Symmetry running DYNIX/ptx
702 ## Use the old cpp rather than the newer ANSI one.
703 i[3456]86-sequent-ptx* )
704 machine=sequent-ptx opsys=ptx
705 NON_GNU_CPP="/lib/cpp"
706 ;;
707
708 ## ncr machine running svr4.3.
709 i[3456]86-ncr-sysv4.3 )
710 machine=ncr386 opsys=usg5-4-3
711 ;;
712
713 ## Unspecified sysv on an ncr machine defaults to svr4.2.
714 ## (Plain usg5-4 doesn't turn on POSIX signals, which we need.)
715 i[3456]86-ncr-sysv* )
716 machine=ncr386 opsys=usg5-4-2
717 ;;
718
719 ## Intel Paragon OSF/1
720 i860-intel-osf1* )
721 machine=paragon opsys=osf1 NON_GNU_CPP=/usr/mach/lib/cpp
722 ;;
723
724 ## Intel 860
725 i860-*-sysv4* )
726 machine=i860 opsys=usg5-4
727 NON_GNU_CC="/bin/cc" # Ie, not the one in /usr/ucb/cc.
728 NON_GNU_CPP="/usr/ccs/lib/cpp" # cc -E tokenizes macro expansion.
729 ;;
730
731 ## Macintosh PowerPC
732 powerpc*-*-linux-gnu* )
733 machine=macppc opsys=gnu-linux
734 ;;
735
736 ## Masscomp machines
737 m68*-masscomp-rtu* )
738 machine=masscomp opsys=rtu
739 ;;
740
741 ## Megatest machines
742 m68*-megatest-bsd* )
743 machine=mega68 opsys=bsd4-2
744 ;;
745
746 ## Workstations sold by MIPS
747 ## This is not necessarily all workstations using the MIPS processor -
748 ## Irises are produced by SGI, and DECstations by DEC.
749
750 ## etc/MACHINES lists mips.h and mips4.h as possible machine files,
751 ## and usg5-2-2 and bsd4-3 as possible OS files. The only guidance
752 ## it gives for choosing between the alternatives seems to be "Use
753 ## -machine=mips4 for RISCOS version 4; use -opsystem=bsd4-3 with
754 ## the BSD world." I'll assume that these are instructions for
755 ## handling two odd situations, and that every other situation
756 ## should use mips.h and usg5-2-2, they being listed first.
757 mips-mips-usg* )
758 machine=mips4
759 ## Fall through to the general code at the bottom to decide on the OS.
760 ;;
761 mips-mips-riscos4* )
762 machine=mips4 opsys=bsd4-3
763 NON_GNU_CC="cc -systype bsd43"
764 NON_GNU_CPP="cc -systype bsd43 -E"
765 ;;
766 mips-mips-riscos5* )
767 machine=mips4 opsys=riscos5
768 NON_GNU_CC="cc -systype bsd43"
769 NON_GNU_CPP="cc -systype bsd43 -E"
770 ;;
771 mips-mips-bsd* )
772 machine=mips opsys=bsd4-3
773 ;;
774 mips-mips-* )
775 machine=mips opsys=usg5-2-2
776 ;;
777
778 ## NeXT
779 m68*-next-* | m68k-*-nextstep* )
780 machine=m68k opsys=nextstep
781 ;;
782
783 ## The complete machine from National Semiconductor
784 ns32k-ns-genix* )
785 machine=ns32000 opsys=usg5-2
786 ;;
787
788 ## NCR machines
789 m68*-ncr-sysv2* | m68*-ncr-sysvr2* )
790 machine=tower32 opsys=usg5-2-2
791 ;;
792 m68*-ncr-sysv3* | m68*-ncr-sysvr3* )
793 machine=tower32v3 opsys=usg5-3
794 ;;
795
796 ## NEC EWS4800
797 mips-nec-sysv4*)
798 machine=ews4800 opsys=ux4800
799 ;;
800
801 ## Nixdorf Targon 31
802 m68*-nixdorf-sysv* )
803 machine=targon31 opsys=usg5-2-2
804 ;;
805
806 ## Nu (TI or LMI)
807 m68*-nu-sysv* )
808 machine=nu opsys=usg5-2
809 ;;
810
811 ## Plexus
812 m68*-plexus-sysv* )
813 machine=plexus opsys=usg5-2
814 ;;
815
816 ## PowerPC reference platform
817 powerpcle-*-solaris2* )
818 machine=prep
819 opsys=sol2-5
820 ;;
821
822 ## Pyramid machines
823 ## I don't really have any idea what sort of processor the Pyramid has,
824 ## so I'm assuming it is its own architecture.
825 pyramid-pyramid-bsd* )
826 machine=pyramid opsys=bsd4-2
827 ;;
828
829 ## Sequent Balance
830 ns32k-sequent-bsd4.2* )
831 machine=sequent opsys=bsd4-2
832 ;;
833 ns32k-sequent-bsd4.3* )
834 machine=sequent opsys=bsd4-3
835 ;;
836
837 ## Siemens Nixdorf
838 mips-siemens-sysv* | mips-sni-sysv*)
839 machine=mips-siemens opsys=usg5-4
840 NON_GNU_CC=/usr/ccs/bin/cc
841 NON_GNU_CPP=/usr/ccs/lib/cpp
842 ;;
843
844 ## Silicon Graphics machines
845 ## Iris 2500 and Iris 2500 Turbo (aka the Iris 3030)
846 m68*-sgi-iris3.5* )
847 machine=irist opsys=iris3-5
848 ;;
849 m68*-sgi-iris3.6* | m68*-sgi-iris*)
850 machine=irist opsys=iris3-6
851 ;;
852 ## Iris 4D
853 mips-sgi-irix3* )
854 machine=iris4d opsys=irix3-3
855 ;;
856 mips-sgi-irix4* )
857 machine=iris4d opsys=irix4-0
858 ;;
859 mips-sgi-irix6.5 )
860 machine=iris4d opsys=irix6-5
861 # Without defining _LANGUAGE_C, things get masked out in the headers
862 # so that, for instance, grepping for `free' in stdlib.h fails and
863 # AC_HEADER_STD_C fails. (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
864 NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
865 NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
866 ;;
867 mips-sgi-irix6* )
868 machine=iris4d opsys=irix6-0
869 # It's not clear whether -D_LANGUAGE_C is necessary as it is for 6.5,
870 # but presumably it does no harm.
871 NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
872 # -32 probably isn't necessary in later v.6s -- anyone know which?
873 NON_GCC_TEST_OPTIONS=-32
874 ;;
875 mips-sgi-irix5.[01]* )
876 machine=iris4d opsys=irix5-0
877 ;;
878 mips-sgi-irix5* | mips-sgi-irix* )
879 machine=iris4d opsys=irix5-2
880 ;;
881
882 ## SONY machines
883 m68*-sony-bsd4.2* )
884 machine=news opsys=bsd4-2
885 ;;
886 m68*-sony-bsd4.3* )
887 machine=news opsys=bsd4-3
888 ;;
889 m68*-sony-newsos3* | m68*-sony-news3*)
890 machine=news opsys=bsd4-3
891 ;;
892 mips-sony-bsd* | mips-sony-newsos4* | mips-sony-news4*)
893 machine=news-risc opsys=bsd4-3
894 ;;
895 mips-sony-newsos6* )
896 machine=news-r6 opsys=newsos6
897 ;;
898 mips-sony-news* )
899 machine=news-risc opsys=newsos5
900 ;;
901
902 ## Stride
903 m68*-stride-sysv* )
904 machine=stride opsys=usg5-2
905 ;;
906
907 ## Suns
908 sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
909 machine=sparc opsys=gnu-linux
910 ;;
911
912 *-auspex-sunos* | *-sun-sunos* | *-sun-bsd* | *-sun-solaris* \
913 | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* | powerpc*-*-solaris2* \
914 | rs6000-*-solaris2*)
915 case "${canonical}" in
916 m68*-sunos1* ) machine=sun1 ;;
917 m68*-sunos2* ) machine=sun2 ;;
918 m68* ) machine=sun3 ;;
919 i[3456]86-sun-sunos[34]* ) machine=sun386 ;;
920 i[3456]86-*-* ) machine=intel386 ;;
921 powerpcle* ) machine=powerpcle ;;
922 powerpc* | rs6000* ) machine=ibmrs6000 ;;
923 sparc* ) machine=sparc ;;
924 * ) unported=yes ;;
925 esac
926 case "${canonical}" in
927 ## The Sun386 didn't get past 4.0.
928 i[3456]86-*-sunos4 ) opsys=sunos4-0 ;;
929 *-sunos4.0* ) opsys=sunos4-0 ;;
930 *-sunos4.1.[3-9]*noshare )
931 ## This name is sunos413 instead of sunos4-1-3
932 ## to avoid a file name conflict on MSDOS.
933 opsys=sunos413
934 NON_GNU_CPP=/usr/lib/cpp
935 NON_GCC_TEST_OPTIONS=-Bstatic
936 GCC_TEST_OPTIONS=-static
937 ;;
938 *-sunos4.1.[3-9]* | *-sunos4shr*)
939 opsys=sunos4shr
940 NON_GNU_CPP=/usr/lib/cpp
941 ;;
942 *-sunos4* | *-sunos )
943 opsys=sunos4-1
944 NON_GCC_TEST_OPTIONS=-Bstatic
945 GCC_TEST_OPTIONS=-static
946 ;;
947 *-sunos5.3* | *-solaris2.3* )
948 opsys=sol2-3
949 NON_GNU_CPP=/usr/ccs/lib/cpp
950 ;;
951 *-sunos5.4* | *-solaris2.4* )
952 opsys=sol2-4
953 NON_GNU_CPP=/usr/ccs/lib/cpp
954 RANLIB="ar -ts"
955 ;;
956 *-sunos5.5* | *-solaris2.5* )
957 opsys=sol2-5
958 NON_GNU_CPP=/usr/ccs/lib/cpp
959 RANLIB="ar -ts"
960 ;;
961 *-sunos5* | *-solaris* )
962 opsys=sol2-5
963 NON_GNU_CPP=/usr/ccs/lib/cpp
964 ;;
965 * ) opsys=bsd4-2 ;;
966 esac
967 ## Watch out for a compiler that we know will not work.
968 case "${canonical}" in
969 *-solaris* | *-sunos5* )
970 if [ "x$CC" = x/usr/ucb/cc ]; then
971 ## /usr/ucb/cc doesn't work;
972 ## we should find some other compiler that does work.
973 unset CC
974 fi
975 ;;
976 *) ;;
977 esac
978 ;;
979 sparc-*-nextstep* )
980 machine=sparc opsys=nextstep
981 ;;
982
983 ## Tadpole 68k
984 m68*-tadpole-sysv* )
985 machine=tad68k opsys=usg5-3
986 ;;
987
988 ## Tahoe machines
989 tahoe-tahoe-bsd4.2* )
990 machine=tahoe opsys=bsd4-2
991 ;;
992 tahoe-tahoe-bsd4.3* )
993 machine=tahoe opsys=bsd4-3
994 ;;
995
996 ## Tandem Integrity S2
997 mips-tandem-sysv* )
998 machine=tandem-s2 opsys=usg5-3
999 ;;
1000
1001 ## Tektronix XD88
1002 m88k-tektronix-sysv3* )
1003 machine=tekxd88 opsys=usg5-3
1004 ;;
1005
1006 ## Tektronix 16000 box (6130?)
1007 ns16k-tektronix-bsd* )
1008 machine=ns16000 opsys=bsd4-2
1009 ;;
1010 ## Tektronix 4300
1011 ## src/m/tek4300.h hints that this is a m68k machine.
1012 m68*-tektronix-bsd* )
1013 machine=tek4300 opsys=bsd4-3
1014 ;;
1015
1016 ## Titan P2 or P3
1017 ## We seem to have lost the machine-description file titan.h!
1018 titan-titan-sysv* )
1019 machine=titan opsys=usg5-3
1020 ;;
1021
1022 ## Ustation E30 (SS5E)
1023 m68*-unisys-uniplus* )
1024 machine=ustation opsystem=unipl5-2
1025 ;;
1026
1027 ## Vaxen.
1028 vax-dec-* )
1029 machine=vax
1030 case "${canonical}" in
1031 *-bsd4.1* ) opsys=bsd4-1 ;;
1032 *-bsd4.2* | *-ultrix[0-3].* | *-ultrix4.0* ) opsys=bsd4-2 ;;
1033 *-bsd4.3* | *-ultrix* ) opsys=bsd4-3 ;;
1034 *-sysv[01]* | *-sysvr[01]* ) opsys=usg5-0 ;;
1035 *-sysv2* | *-sysvr2* ) opsys=usg5-2 ;;
1036 *-vms* ) opsys=vms ;;
1037 * ) unported=yes
1038 esac
1039 ;;
1040
1041 ## Whitechapel MG1
1042 ns16k-whitechapel-* )
1043 machine=mg1
1044 ## We don't know what sort of OS runs on these; we'll let the
1045 ## operating system guessing code below try.
1046 ;;
1047
1048 ## Wicat
1049 m68*-wicat-sysv* )
1050 machine=wicat opsys=usg5-2
1051 ;;
1052
1053 ## IA-64
1054 ia64*-*-linux* )
1055 machine=ia64 opsys=gnu-linux
1056 ;;
1057
1058 ## Intel 386 machines where we don't care about the manufacturer
1059 i[3456]86-*-* )
1060 machine=intel386
1061 case "${canonical}" in
1062 *-lynxos* ) opsys=lynxos ;;
1063 *-isc1.* | *-isc2.[01]* ) opsys=386-ix ;;
1064 *-isc2.2* ) opsys=isc2-2 ;;
1065 *-isc4.0* ) opsys=isc4-0 ;;
1066 *-isc4.* ) opsys=isc4-1
1067 GCC_TEST_OPTIONS=-posix
1068 NON_GCC_TEST_OPTIONS=-Xp
1069 ;;
1070 *-isc* ) opsys=isc3-0 ;;
1071 *-esix5* ) opsys=esix5r4; NON_GNU_CPP=/usr/lib/cpp ;;
1072 *-esix* ) opsys=esix ;;
1073 *-xenix* ) opsys=xenix ;;
1074 *-linux-gnu* ) opsys=gnu-linux ;;
1075 *-sco3.2v4* ) opsys=sco4 ; NON_GNU_CPP=/lib/cpp ;;
1076 *-sco3.2v5* ) opsys=sco5
1077 NON_GNU_CPP=/lib/cpp
1078 # Prevent -belf from being passed to $CPP.
1079 # /lib/cpp does not accept it.
1080 OVERRIDE_CPPFLAGS=" "
1081 ;;
1082 *-sysv4.2uw* ) opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
1083 *-386bsd* ) opsys=386bsd ;;
1084 *-nextstep* ) opsys=nextstep ;;
1085 ## Otherwise, we'll fall through to the generic opsys code at the bottom.
1086 esac
1087 ;;
1088
1089 ## m68k Linux-based GNU system
1090 m68k-*-linux-gnu* )
1091 machine=m68k opsys=gnu-linux
1092 ;;
1093
1094 ## Mips Linux-based GNU system
1095 mips-*-linux-gnu* )
1096 machine=mips opsys=gnu-linux
1097 ;;
1098
1099 ## UXP/DS
1100 sparc-fujitsu-sysv4* )
1101 machine=sparc opsys=uxpds
1102 NON_GNU_CPP=/usr/ccs/lib/cpp
1103 RANLIB="ar -ts"
1104 ;;
1105
1106 ## UXP/V
1107 f301-fujitsu-uxpv4.1)
1108 machine=f301 opsys=uxpv
1109 ;;
1110
1111 ## Darwin / Mac OS X
1112 powerpc-apple-darwin* )
1113 machine=powermac opsys=darwin
1114 # Define CPP as follows to make autoconf work correctly.
1115 CPP="cc -E -traditional-cpp"
1116 ;;
1117
1118 ## AMD x86-64 Linux-based GNU system
1119 x86_64-*-linux-gnu* )
1120 machine=amdx86-64 opsys=gnu-linux
1121 ;;
1122
1123 * )
1124 unported=yes
1125 ;;
1126 esac
1127
1128 ### If the code above didn't choose an operating system, just choose
1129 ### an operating system based on the configuration name. You really
1130 ### only want to use this when you have no idea what the right
1131 ### operating system is; if you know what operating systems a machine
1132 ### runs, it's cleaner to make it explicit in the case statement
1133 ### above.
1134 if test x"${opsys}" = x; then
1135 case "${canonical}" in
1136 *-gnu* ) opsys=gnu ;;
1137 *-bsd4.[01] ) opsys=bsd4-1 ;;
1138 *-bsd4.2 ) opsys=bsd4-2 ;;
1139 *-bsd4.3 ) opsys=bsd4-3 ;;
1140 *-sysv0 | *-sysvr0 ) opsys=usg5-0 ;;
1141 *-sysv2 | *-sysvr2 ) opsys=usg5-2 ;;
1142 *-sysv2.2 | *-sysvr2.2 ) opsys=usg5-2-2 ;;
1143 *-sysv3* | *-sysvr3* ) opsys=usg5-3 ;;
1144 *-sysv4.2uw* ) opsys=unixware ;;
1145 *-sysv4.1* | *-sysvr4.1* )
1146 NON_GNU_CPP=/usr/lib/cpp
1147 opsys=usg5-4 ;;
1148 *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
1149 if [ x$NON_GNU_CPP = x ]; then
1150 if [ -f /usr/ccs/lib/cpp ]; then
1151 NON_GNU_CPP=/usr/ccs/lib/cpp
1152 else
1153 NON_GNU_CPP=/lib/cpp
1154 fi
1155 fi
1156 opsys=usg5-4-2 ;;
1157 *-sysv4* | *-sysvr4* ) opsys=usg5-4 ;;
1158 * )
1159 unported=yes
1160 ;;
1161 esac
1162 fi
1163
1164 changequote([, ])dnl
1165
1166 if test $unported = yes; then
1167 AC_MSG_ERROR([Emacs hasn't been ported to \`${canonical}' systems.
1168 Check \`etc/MACHINES' for recognized configuration names.])
1169 fi
1170
1171 machfile="m/${machine}.h"
1172 opsysfile="s/${opsys}.h"
1173
1174
1175 #### Choose a compiler.
1176 test -n "$CC" && cc_specified=yes
1177
1178 # Save the value of CFLAGS that the user specified.
1179 SPECIFIED_CFLAGS="$CFLAGS"
1180
1181 case ${with_gcc} in
1182 "yes" ) CC="gcc" GCC=yes ;;
1183 "no" ) : ${CC=cc} ;;
1184 * )
1185 esac
1186 AC_PROG_CC
1187
1188 # On Suns, sometimes $CPP names a directory.
1189 if test -n "$CPP" && test -d "$CPP"; then
1190 CPP=
1191 fi
1192
1193 #### Some systems specify a CPP to use unless we are using GCC.
1194 #### Now that we know whether we are using GCC, we can decide whether
1195 #### to use that one.
1196 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
1197 then
1198 CPP="$NON_GNU_CPP"
1199 fi
1200
1201 #### Some systems specify a CC to use unless we are using GCC.
1202 #### Now that we know whether we are using GCC, we can decide whether
1203 #### to use that one.
1204 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
1205 test x$cc_specified != xyes
1206 then
1207 CC="$NON_GNU_CC"
1208 fi
1209
1210 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
1211 then
1212 CC="$CC $GCC_TEST_OPTIONS"
1213 fi
1214
1215 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
1216 then
1217 CC="$CC $NON_GCC_TEST_OPTIONS"
1218 fi
1219
1220 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
1221 then
1222 ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1223 fi
1224
1225 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
1226 then
1227 ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1228 fi
1229
1230 #### Some other nice autoconf tests. If you add a test here which
1231 #### should make an entry in src/config.h, don't forget to add an
1232 #### #undef clause to src/config.h.in for autoconf to modify.
1233
1234 dnl checks for programs
1235 AC_PROG_LN_S
1236 AC_PROG_CPP
1237 AC_PROG_INSTALL
1238 AC_PROG_YACC
1239 if test "x$RANLIB" = x; then
1240 AC_PROG_RANLIB
1241 fi
1242
1243 dnl checks for Unix variants
1244 AC_AIX
1245
1246 #### Extract some information from the operating system and machine files.
1247
1248 AC_CHECKING([the machine- and system-dependent files to find out
1249 - which libraries the lib-src programs will want, and
1250 - whether the GNU malloc routines are usable])
1251
1252 ### First figure out CFLAGS (which we use for running the compiler here)
1253 ### and REAL_CFLAGS (which we use for real compilation).
1254 ### The two are the same except on a few systems, where they are made
1255 ### different to work around various lossages. For example,
1256 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
1257 ### as implying static linking.
1258
1259 ### If the CFLAGS env var is specified, we use that value
1260 ### instead of the default.
1261
1262 ### It's not important that this name contain the PID; you can't run
1263 ### two configures in the same directory and have anything work
1264 ### anyway.
1265 tempcname="conftest.c"
1266
1267 echo '
1268 #include "'${srcdir}'/src/'${opsysfile}'"
1269 #include "'${srcdir}'/src/'${machfile}'"
1270 #ifndef LIBS_MACHINE
1271 #define LIBS_MACHINE
1272 #endif
1273 #ifndef LIBS_SYSTEM
1274 #define LIBS_SYSTEM
1275 #endif
1276 #ifndef C_SWITCH_SYSTEM
1277 #define C_SWITCH_SYSTEM
1278 #endif
1279 #ifndef C_SWITCH_MACHINE
1280 #define C_SWITCH_MACHINE
1281 #endif
1282 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
1283 configure___ c_switch_system=C_SWITCH_SYSTEM
1284 configure___ c_switch_machine=C_SWITCH_MACHINE
1285
1286 #ifndef LIB_X11_LIB
1287 #define LIB_X11_LIB -lX11
1288 #endif
1289
1290 #ifndef LIBX11_MACHINE
1291 #define LIBX11_MACHINE
1292 #endif
1293
1294 #ifndef LIBX11_SYSTEM
1295 #define LIBX11_SYSTEM
1296 #endif
1297 configure___ LIBX=LIB_X11_LIB LIBX11_MACHINE LIBX11_SYSTEM
1298
1299 #ifdef UNEXEC
1300 configure___ unexec=UNEXEC
1301 #else
1302 configure___ unexec=unexec.o
1303 #endif
1304
1305 #ifdef SYSTEM_MALLOC
1306 configure___ system_malloc=yes
1307 #else
1308 configure___ system_malloc=no
1309 #endif
1310
1311 #ifdef USE_MMAP_FOR_BUFFERS
1312 configure___ use_mmap_for_buffers=yes
1313 #else
1314 configure___ use_mmap_for_buffers=no
1315 #endif
1316
1317 #ifndef C_DEBUG_SWITCH
1318 #define C_DEBUG_SWITCH -g
1319 #endif
1320
1321 #ifndef C_OPTIMIZE_SWITCH
1322 #ifdef __GNUC__
1323 #define C_OPTIMIZE_SWITCH -O2
1324 #else
1325 #define C_OPTIMIZE_SWITCH -O
1326 #endif
1327 #endif
1328
1329 #ifndef LD_SWITCH_MACHINE
1330 #define LD_SWITCH_MACHINE
1331 #endif
1332
1333 #ifndef LD_SWITCH_SYSTEM
1334 #define LD_SWITCH_SYSTEM
1335 #endif
1336
1337 #ifndef LD_SWITCH_X_SITE_AUX
1338 #define LD_SWITCH_X_SITE_AUX
1339 #endif
1340
1341 configure___ ld_switch_system=LD_SWITCH_SYSTEM
1342 configure___ ld_switch_machine=LD_SWITCH_MACHINE
1343
1344 #ifdef THIS_IS_CONFIGURE
1345
1346 /* Get the CFLAGS for tests in configure. */
1347 #ifdef __GNUC__
1348 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1349 #else
1350 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1351 #endif
1352
1353 #else /* not THIS_IS_CONFIGURE */
1354
1355 /* Get the CFLAGS for real compilation. */
1356 #ifdef __GNUC__
1357 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1358 #else
1359 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1360 #endif
1361
1362 #endif /* not THIS_IS_CONFIGURE */
1363 ' > ${tempcname}
1364
1365 # The value of CPP is a quoted variable reference, so we need to do this
1366 # to get its actual value...
1367 CPP=`eval "echo $CPP"`
1368 changequote(, )dnl
1369 eval `${CPP} -Isrc ${tempcname} \
1370 | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1371 if test "x$SPECIFIED_CFLAGS" = x; then
1372 eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
1373 | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1374 else
1375 REAL_CFLAGS="$CFLAGS"
1376 fi
1377 changequote([, ])dnl
1378 rm ${tempcname}
1379
1380 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
1381
1382 ### Make sure subsequent tests use flags consistent with the build flags.
1383
1384 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1385 CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1386 else
1387 CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
1388 fi
1389
1390 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1391 AC_SYS_LARGEFILE
1392
1393 if test "${with_sound}" != "no"; then
1394 # Sound support for GNU/Linux and the free BSDs.
1395 AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1396 # Emulation library used on NetBSD.
1397 AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1398 AC_SUBST(LIBSOUND)
1399 fi
1400
1401 dnl checks for header files
1402 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1403 linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1404 termcap.h stdio_ext.h fcntl.h term.h strings.h coff.h)
1405 AC_HEADER_STDC
1406 AC_HEADER_TIME
1407 AC_DECL_SYS_SIGLIST
1408 AC_HEADER_SYS_WAIT
1409
1410 dnl Some systems have utime.h but don't declare the struct anyplace.
1411 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1412 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1413 #include <sys/time.h>
1414 #include <time.h>
1415 #else
1416 #ifdef HAVE_SYS_TIME_H
1417 #include <sys/time.h>
1418 #else
1419 #include <time.h>
1420 #endif
1421 #endif
1422 #ifdef HAVE_UTIME_H
1423 #include <utime.h>
1424 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1425 emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1426 if test $emacs_cv_struct_utimbuf = yes; then
1427 AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1428 fi
1429
1430 dnl checks for typedefs
1431 AC_TYPE_SIGNAL
1432
1433 dnl Check for speed_t typedef.
1434 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1435 [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1436 emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1437 if test $emacs_cv_speed_t = yes; then
1438 AC_DEFINE(HAVE_SPEED_T, 1,
1439 [Define to 1 if `speed_t' is declared by <termios.h>.])
1440 fi
1441
1442 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1443 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1444 #include <sys/time.h>
1445 #include <time.h>
1446 #else
1447 #ifdef HAVE_SYS_TIME_H
1448 #include <sys/time.h>
1449 #else
1450 #include <time.h>
1451 #endif
1452 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1453 emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1454 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1455 if test $emacs_cv_struct_timeval = yes; then
1456 AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1457 fi
1458
1459 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1460 AC_TRY_COMPILE([#include <math.h>],
1461 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1462 emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1463 HAVE_EXCEPTION=$emacs_cv_struct_exception
1464 if test $emacs_cv_struct_exception != yes; then
1465 AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1466 fi
1467
1468 dnl checks for structure members
1469 AC_STRUCT_TM
1470 AC_STRUCT_TIMEZONE
1471 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1472 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1473 [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1474 [#include <time.h>])
1475
1476 dnl checks for compiler characteristics
1477
1478 dnl Testing __STDC__ to determine prototype support isn't good enough.
1479 dnl DEC C, for instance, doesn't define it with default options, and
1480 dnl is used on 64-bit systems (OSF Alphas). Similarly for volatile
1481 dnl and void *.
1482 AC_C_PROTOTYPES
1483 AC_C_VOLATILE
1484 AC_C_CONST
1485 dnl This isn't useful because we can't turn on use of `inline' unless
1486 dnl the compiler groks `extern inline'.
1487 dnl AC_C_INLINE
1488 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1489 [AC_TRY_COMPILE(, [void * foo;],
1490 emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1491 if test $emacs_cv_void_star = yes; then
1492 AC_DEFINE(POINTER_TYPE, void)
1493 else
1494 AC_DEFINE(POINTER_TYPE, char)
1495 fi
1496 AH_TEMPLATE(POINTER_TYPE,
1497 [Define as `void' if your compiler accepts `void *'; otherwise
1498 define as `char'.])dnl
1499
1500 dnl check for Make feature
1501 AC_PROG_MAKE_SET
1502
1503 dnl checks for operating system services
1504 AC_SYS_LONG_FILE_NAMES
1505
1506 #### Choose a window system.
1507
1508 AC_PATH_X
1509 if test "$no_x" = yes; then
1510 window_system=none
1511 else
1512 window_system=x11
1513 fi
1514
1515 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1516 LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1517 LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1518 x_default_search_path=""
1519 for x_library in `echo ${x_libraries} | sed -e "s/:/ /g"`; do
1520 x_search_path="\
1521 ${x_library}/X11/%L/%T/%N%C%S:\
1522 ${x_library}/X11/%l/%T/%N%C%S:\
1523 ${x_library}/X11/%T/%N%C%S:\
1524 ${x_library}/X11/%L/%T/%N%S:\
1525 ${x_library}/X11/%l/%T/%N%S:\
1526 ${x_library}/X11/%T/%N%S"
1527 if test x"${x_default_search_path}" = x; then
1528 x_default_search_path=${x_search_path}
1529 else
1530 x_default_search_path="${x_search_path}:${x_default_search_path}"
1531 fi
1532 done
1533 fi
1534 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1535 C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1536 fi
1537
1538 if test x"${x_includes}" = x; then
1539 bitmapdir=/usr/include/X11/bitmaps
1540 else
1541 # accumulate include directories that have X11 bitmap subdirectories
1542 bmd_acc="dummyval"
1543 for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1544 if test -d "${bmd}/X11/bitmaps"; then
1545 bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1546 fi
1547 if test -d "${bmd}/bitmaps"; then
1548 bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1549 fi
1550 done
1551 if test ${bmd_acc} != "dummyval"; then
1552 bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1553 fi
1554 fi
1555
1556 case "${window_system}" in
1557 x11 )
1558 HAVE_X_WINDOWS=yes
1559 HAVE_X11=yes
1560 case "${with_x_toolkit}" in
1561 athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1562 motif ) USE_X_TOOLKIT=MOTIF ;;
1563 dnl open-look ) USE_X_TOOLKIT=OPEN_LOOK ;;
1564 no ) USE_X_TOOLKIT=none ;;
1565 dnl If user did not say whether to use a toolkit,
1566 dnl make this decision later: use the toolkit if we have X11R5 or newer.
1567 * ) USE_X_TOOLKIT=maybe ;;
1568 esac
1569 ;;
1570 none )
1571 HAVE_X_WINDOWS=no
1572 HAVE_X11=no
1573 USE_X_TOOLKIT=none
1574 ;;
1575 esac
1576
1577 ### If we're using X11, we should use the X menu package.
1578 HAVE_MENUS=no
1579 case ${HAVE_X11} in
1580 yes ) HAVE_MENUS=yes ;;
1581 esac
1582
1583 if test "${opsys}" = "hpux9"; then
1584 case "${x_libraries}" in
1585 *X11R4* )
1586 opsysfile="s/hpux9-x11r4.h"
1587 ;;
1588 esac
1589 fi
1590
1591 if test "${opsys}" = "hpux9shr"; then
1592 case "${x_libraries}" in
1593 *X11R4* )
1594 opsysfile="s/hpux9shxr4.h"
1595 ;;
1596 esac
1597 fi
1598
1599 ### Compute the unexec source name from the object name.
1600 UNEXEC_SRC="`echo ${unexec} | sed 's/\.o/.c/'`"
1601
1602 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1603 # Assume not, until told otherwise.
1604 GNU_MALLOC=yes
1605 doug_lea_malloc=yes
1606 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1607 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1608 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1609 emacs_cv_var___after_morecore_hook,
1610 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1611 emacs_cv_var___after_morecore_hook=yes,
1612 emacs_cv_var___after_morecore_hook=no)])
1613 if test $emacs_cv_var___after_morecore_hook = no; then
1614 doug_lea_malloc=no
1615 fi
1616 if test "${system_malloc}" = "yes"; then
1617 GNU_MALLOC=no
1618 GNU_MALLOC_reason="
1619 (The GNU allocators don't work with this system configuration.)"
1620 fi
1621 if test "$doug_lea_malloc" = "yes" ; then
1622 if test "$GNU_MALLOC" = yes ; then
1623 GNU_MALLOC_reason="
1624 (Using Doug Lea's new malloc from the GNU C Library.)"
1625 fi
1626 AC_DEFINE(DOUG_LEA_MALLOC, 1,
1627 [Define to 1 if you are using the GNU C Library.])
1628 fi
1629
1630 if test x"${REL_ALLOC}" = x; then
1631 REL_ALLOC=${GNU_MALLOC}
1632 fi
1633
1634 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1635 dnl the system configuration file (s/*.h) to turn the use of mmap
1636 dnl in the relocating allocator on.
1637
1638 AC_FUNC_MMAP
1639 if test $use_mmap_for_buffers = yes; then
1640 REL_ALLOC=no
1641 fi
1642
1643 LIBS="$libsrc_libs $LIBS"
1644
1645 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1646 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1647 AC_CHECK_LIB(dnet, dnet_ntoa)
1648 dnl This causes -lresolv to get used in subsequent tests,
1649 dnl which causes failures on some systems such as HPUX 9.
1650 dnl AC_CHECK_LIB(resolv, gethostbyname)
1651
1652 dnl FIXME replace main with a function we actually want from this library.
1653 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1654
1655 AC_CHECK_LIB(pthreads, cma_open)
1656
1657 AC_MSG_CHECKING(for XFree86 in /usr/X386)
1658 if test -d /usr/X386/include; then
1659 HAVE_XFREE386=yes
1660 : ${C_SWITCH_X_SITE="-I/usr/X386/include"}
1661 else
1662 HAVE_XFREE386=no
1663 fi
1664 AC_MSG_RESULT($HAVE_XFREE386)
1665
1666 # Change CFLAGS temporarily so that C_SWITCH_X_SITE gets used
1667 # for the tests that follow. We set it back to REAL_CFLAGS later on.
1668
1669 REAL_CPPFLAGS="$CPPFLAGS"
1670
1671 if test "${HAVE_X11}" = "yes"; then
1672 DEFS="$C_SWITCH_X_SITE $DEFS"
1673 LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1674 LIBS="$LIBX $LIBS"
1675 CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1676 CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1677
1678 # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1679 # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1680 # but it's more convenient here to set LD_RUN_PATH
1681 # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1682 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1683 LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1684 export LD_RUN_PATH
1685 fi
1686
1687 if test "${opsys}" = "gnu-linux"; then
1688 AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1689 AC_TRY_LINK([],
1690 [XOpenDisplay ("foo");],
1691 [xlinux_first_failure=no],
1692 [xlinux_first_failure=yes])
1693 if test "${xlinux_first_failure}" = "yes"; then
1694 OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1695 OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1696 OLD_CPPFLAGS="$CPPFLAGS"
1697 OLD_LIBS="$LIBS"
1698 LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1699 C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1700 CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1701 LIBS="$LIBS -b i486-linuxaout"
1702 AC_TRY_LINK([],
1703 [XOpenDisplay ("foo");],
1704 [xlinux_second_failure=no],
1705 [xlinux_second_failure=yes])
1706 if test "${xlinux_second_failure}" = "yes"; then
1707 # If we get the same failure with -b, there is no use adding -b.
1708 # So take it out. This plays safe.
1709 LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1710 C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1711 CPPFLAGS="$OLD_CPPFLAGS"
1712 LIBS="$OLD_LIBS"
1713 AC_MSG_RESULT(no)
1714 else
1715 AC_MSG_RESULT(yes)
1716 fi
1717 else
1718 AC_MSG_RESULT(no)
1719 fi
1720 fi
1721
1722 # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1723 # header files included from there.
1724 AC_MSG_CHECKING(for Xkb)
1725 AC_TRY_LINK([#include <X11/Xlib.h>
1726 #include <X11/XKBlib.h>],
1727 [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1728 emacs_xkb=yes, emacs_xkb=no)
1729 AC_MSG_RESULT($emacs_xkb)
1730 if test $emacs_xkb = yes; then
1731 AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1732 fi
1733
1734 AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1735 XScreenNumberOfScreen XSetWMProtocols)
1736 fi
1737
1738 if test "${window_system}" = "x11"; then
1739 AC_MSG_CHECKING(X11 version 6)
1740 AC_CACHE_VAL(emacs_cv_x11_version_6,
1741 [AC_TRY_LINK([#include <X11/Xlib.h>],
1742 [#if XlibSpecificationRelease < 6
1743 fail;
1744 #endif
1745 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1746 if test $emacs_cv_x11_version_6 = yes; then
1747 AC_MSG_RESULT(6 or newer)
1748 AC_DEFINE(HAVE_X11R6, 1,
1749 [Define to 1 if you have the X11R6 or newer version of Xlib.])
1750 else
1751 AC_MSG_RESULT(before 6)
1752 fi
1753 fi
1754
1755 if test "${window_system}" = "x11"; then
1756 AC_MSG_CHECKING(X11 version 5)
1757 AC_CACHE_VAL(emacs_cv_x11_version_5,
1758 [AC_TRY_LINK([#include <X11/Xlib.h>],
1759 [#if XlibSpecificationRelease < 5
1760 fail;
1761 #endif
1762 ], emacs_cv_x11_version_5=yes, emacs_cv_x11_version_5=no)])
1763 if test $emacs_cv_x11_version_5 = yes; then
1764 AC_MSG_RESULT(5 or newer)
1765 HAVE_X11R5=yes
1766 AC_DEFINE(HAVE_X11R5, 1,
1767 [Define to 1 if you have the X11R5 or newer version of Xlib.])
1768 else
1769 HAVE_X11R5=no
1770 AC_MSG_RESULT(before 5)
1771 fi
1772 fi
1773
1774 dnl Do not put whitespace before the #include statements below.
1775 dnl Older compilers (eg sunos4 cc) choke on it.
1776 if test x"${USE_X_TOOLKIT}" = xmaybe; then
1777 if test x"${HAVE_X11R5}" = xyes; then
1778 AC_MSG_CHECKING(X11 version 5 with Xaw)
1779 AC_CACHE_VAL(emacs_cv_x11_version_5_with_xaw,
1780 [AC_TRY_LINK([
1781 #include <X11/Intrinsic.h>
1782 #include <X11/Xaw/Simple.h>],
1783 [],
1784 emacs_cv_x11_version_5_with_xaw=yes,
1785 emacs_cv_x11_version_5_with_xaw=no)])
1786 if test $emacs_cv_x11_version_5_with_xaw = yes; then
1787 AC_MSG_RESULT([5 or newer, with Xaw; use toolkit by default])
1788 USE_X_TOOLKIT=LUCID
1789 else
1790 AC_MSG_RESULT(before 5 or no Xaw; do not use toolkit by default)
1791 USE_X_TOOLKIT=none
1792 fi
1793 else
1794 USE_X_TOOLKIT=none
1795 fi
1796 fi
1797
1798 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1799
1800 if test "${USE_X_TOOLKIT}" != "none"; then
1801 AC_MSG_CHECKING(X11 toolkit version)
1802 AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1803 [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1804 [#if XtSpecificationRelease < 6
1805 fail;
1806 #endif
1807 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1808 HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1809 if test $emacs_cv_x11_toolkit_version_6 = yes; then
1810 AC_MSG_RESULT(6 or newer)
1811 AC_DEFINE(HAVE_X11XTR6, 1,
1812 [Define to 1 if you have the X11R6 or newer version of Xt.])
1813 else
1814 AC_MSG_RESULT(before 6)
1815 fi
1816
1817 dnl If using toolkit, check whether libXmu.a exists.
1818 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1819 OLDLIBS="$LIBS"
1820 if test x$HAVE_X11XTR6 = xyes; then
1821 LIBS="-lXt -lSM -lICE $LIBS"
1822 else
1823 LIBS="-lXt $LIBS"
1824 fi
1825 AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1826 test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1827 fi
1828
1829 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1830 if test "${HAVE_X11}" = "yes"; then
1831 if test "${USE_X_TOOLKIT}" != "none"; then
1832 AC_CHECK_LIB(Xext, XShapeQueryExtension)
1833 fi
1834 fi
1835
1836 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1837 AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1838 [AC_TRY_COMPILE([#include <Xm/Xm.h>],
1839 [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1840 int x = 5;
1841 #else
1842 Motif version prior to 2.1.
1843 #endif],
1844 emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
1845 HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1846 if test $emacs_cv_motif_version_2_1 = yes; then
1847 HAVE_LIBXP=no
1848 AC_DEFINE(HAVE_MOTIF_2_1, 1,
1849 [Define to 1 if you have Motif 2.1 or newer.])
1850 AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
1851 if test ${HAVE_LIBXP} = yes; then
1852 AC_DEFINE(HAVE_LIBXP, 1,
1853 [Define to 1 if you have the Xp library (-lXp).])
1854 fi
1855 fi
1856 fi
1857
1858 ### Is -lXaw3d available?
1859 HAVE_XAW3D=no
1860 if test "${HAVE_X11}" = "yes"; then
1861 if test "${USE_X_TOOLKIT}" != "none"; then
1862 AC_CHECK_HEADER(X11/Xaw3d/Scrollbar.h,
1863 AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb, HAVE_XAW3D=yes))
1864 if test "${HAVE_XAW3D}" = "yes"; then
1865 AC_DEFINE(HAVE_XAW3D, 1,
1866 [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1867 fi
1868 fi
1869 fi
1870
1871 dnl Use toolkit scroll bars if configured for X toolkit and either
1872 dnl using Motif or Xaw3d is available, and unless
1873 dnl --with-toolkit-scroll-bars=no was specified.
1874
1875 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
1876 [Define to 1 if we should use toolkit scroll bars.])dnl
1877 USE_TOOLKIT_SCROLL_BARS=no
1878 if test "${with_toolkit_scroll_bars}" != "no"; then
1879 if test "${USE_X_TOOLKIT}" != "none"; then
1880 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1881 AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1882 HAVE_XAW3D=no
1883 USE_TOOLKIT_SCROLL_BARS=yes
1884 elif test "${HAVE_XAW3D}" = "yes"; then
1885 AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1886 USE_TOOLKIT_SCROLL_BARS=yes
1887 fi
1888 fi
1889 fi
1890
1891 dnl Don't use X11 input methods if user specifies he doesn't want it
1892 dnl with `--with-xim=no'.
1893
1894 if test "${with_xim}" != "no"; then
1895 AC_DEFINE(USE_XIM, 1,
1896 [Define to 1 if we should use XIM, if it is available.])
1897 fi
1898
1899 ### Use -lXpm if available, unless `--with-xpm=no'.
1900 HAVE_XPM=no
1901 if test "${HAVE_X11}" = "yes"; then
1902 if test "${with_xpm}" != "no"; then
1903 AC_CHECK_HEADER(X11/xpm.h,
1904 AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11))
1905 if test "${HAVE_XPM}" = "yes"; then
1906 AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
1907 AC_EGREP_CPP(no_return_alloc_pixels,
1908 [#include "X11/xpm.h"
1909 #ifndef XpmReturnAllocPixels
1910 no_return_alloc_pixels
1911 #endif
1912 ], HAVE_XPM=no, HAVE_XPM=yes)
1913
1914 if test "${HAVE_XPM}" = "yes"; then
1915 AC_MSG_RESULT(yes)
1916 else
1917 AC_MSG_RESULT(no)
1918 fi
1919 fi
1920 fi
1921
1922 if test "${HAVE_XPM}" = "yes"; then
1923 AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
1924 fi
1925 fi
1926
1927 ### Use -ljpeg if available, unless `--with-jpeg=no'.
1928 HAVE_JPEG=no
1929 if test "${HAVE_X11}" = "yes"; then
1930 if test "${with_jpeg}" != "no"; then
1931 dnl Checking for jpeglib.h can lose becsue of a redefinition of
1932 dnl HAVE_STDLIB_H.
1933 AC_CHECK_HEADER(jerror.h,
1934 AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes))
1935 fi
1936
1937 AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
1938 if test "${HAVE_JPEG}" = "yes"; then
1939 AC_DEFINE(HAVE_JPEG)
1940 AC_EGREP_CPP(
1941 changequote({, })dnl avoid leadingspace on the next line
1942 {version= *(6[2-9]|[7-9][0-9])},
1943 changequote([, ])dnl
1944 [#include <jpeglib.h>
1945 version=JPEG_LIB_VERSION
1946 ],
1947 AC_DEFINE(HAVE_JPEG),
1948 [AC_MSG_WARN([libjpeg found, but not version 6b or later])
1949 HAVE_JPEG=no])
1950 fi
1951 fi
1952
1953 ### Use -lpng if available, unless `--with-png=no'.
1954 HAVE_PNG=no
1955 if test "${HAVE_X11}" = "yes"; then
1956 if test "${with_png}" != "no"; then
1957 AC_CHECK_HEADER(png.h,
1958 AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm))
1959 fi
1960
1961 if test "${HAVE_PNG}" = "yes"; then
1962 AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
1963 fi
1964 fi
1965
1966 ### Use -ltiff if available, unless `--with-tiff=no'.
1967 HAVE_TIFF=no
1968 if test "${HAVE_X11}" = "yes"; then
1969 if test "${with_tiff}" != "no"; then
1970 AC_CHECK_HEADER(tiffio.h,
1971 tifflibs="-lz -lm"
1972 # At least one tiff package requires the jpeg library.
1973 if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
1974 AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs))
1975 fi
1976
1977 if test "${HAVE_TIFF}" = "yes"; then
1978 AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
1979 fi
1980 fi
1981
1982 ### Use -lgif if available, unless `--with-gif=no'.
1983 HAVE_GIF=no
1984 if test "${HAVE_X11}" = "yes"; then
1985 if test "${with_gif}" != "no"; then
1986 AC_CHECK_HEADER(gif_lib.h,
1987 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
1988 # Earlier versions can crash Emacs.
1989 AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes))
1990 fi
1991
1992 if test "${HAVE_GIF}" = "yes"; then
1993 AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have the ungif library (-lungif).])
1994 fi
1995 fi
1996
1997 ### Use Mac OS X Carbon API to implement GUI.
1998 HAVE_CARBON=no
1999 if test "${with_carbon}" != "no"; then
2000 AC_CHECK_HEADER(Carbon/Carbon.h, HAVE_CARBON=yes)
2001 fi
2002
2003 if test "${HAVE_CARBON}" = "yes"; then
2004 AC_DEFINE(HAVE_CARBON, 1, [Define to 1 if you are using the Carbon API on Mac OS X.])
2005 fi
2006
2007 ### Use session management (-lSM -lICE) if available
2008 HAVE_X_SM=no
2009 if test "${HAVE_X11}" = "yes"; then
2010 AC_CHECK_HEADER(X11/SM/SMlib.h,
2011 AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, -lICE))
2012
2013 if test "${HAVE_X_SM}" = "yes"; then
2014 AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2015 case "$LIBS" in
2016 *-lSM*) ;;
2017 *) LIBS="-lSM -lICE $LIBS" ;;
2018 esac
2019 fi
2020 fi
2021
2022 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2023 AC_CACHE_CHECK(whether netdb declares h_errno,
2024 emacs_cv_netdb_declares_h_errno,
2025 [AC_TRY_LINK([#include <netdb.h>],
2026 [return h_errno;],
2027 emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2028 if test $emacs_cv_netdb_declares_h_errno = yes; then
2029 AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2030 fi
2031
2032 AC_FUNC_ALLOCA
2033
2034 # fmod, logb, and frexp are found in -lm on most systems.
2035 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2036 AC_CHECK_LIB(m, sqrt)
2037
2038 # Check for mail-locking functions in a "mail" library
2039 AC_CHECK_LIB(mail, maillock)
2040 dnl Debian, at least:
2041 dnl AC_CHECK_LIB(lockfile, maillock, [AC_DEFINE(HAVE_LIBMAIL)])
2042 AC_CHECK_LIB(lockfile, maillock)
2043 # If we have the shared liblockfile, assume we must use it for mail
2044 # locking (e.g. Debian). If we couldn't link against liblockfile
2045 # (no liblockfile.a installed), ensure that we don't need to.
2046 if test "$ac_cv_lib_lockfile_maillock" = no; then
2047 dnl This works for files generally, not just executables.
2048 dnl Should we look elsewhere for it? Maybe examine /etc/ld.so.conf?
2049 AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2050 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2051 if test $ac_cv_prog_liblockfile = yes; then
2052 AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2053 This probably means that movemail could lose mail.
2054 There may be a \`development' package to install containing liblockfile.])
2055 else AC_DEFINE(LIBMAIL, -llockfile, [Define to -llockfile if it is usable.])
2056 fi
2057 else :
2058 fi
2059 AC_CHECK_FUNCS(touchlock)
2060 AC_CHECK_HEADERS(maillock.h)
2061
2062 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2063 rename closedir mkdir rmdir sysinfo \
2064 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime res_init setsid \
2065 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2066 utimes setrlimit setpgid getcwd getwd shutdown strftime getaddrinfo \
2067 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2068 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2069 gai_strerror mkstemp getline getdelim)
2070
2071 AC_CHECK_HEADERS(sys/un.h)
2072
2073 AC_FUNC_MKTIME
2074 if test "$ac_cv_func_working_mktime" = no; then
2075 AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2076 fi
2077
2078 AC_FUNC_GETLOADAVG
2079
2080 AC_FUNC_FSEEKO
2081
2082 # UNIX98 PTYs.
2083 AC_CHECK_FUNCS(grantpt)
2084
2085 # PTY-related GNU extensions.
2086 AC_CHECK_FUNCS(getpt)
2087
2088 # Check this now, so that we will NOT find the above functions in ncurses.
2089 # That is because we have not set up to link ncurses in lib-src.
2090 # It's better to believe a function is not available
2091 # than to expect to find it in ncurses.
2092 AC_CHECK_LIB(ncurses, tparm)
2093
2094 # Do we need the Hesiod library to provide the support routines?
2095 if test "$with_hesiod" = yes ; then
2096 # Don't set $LIBS here -- see comments above.
2097 resolv=no
2098 AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2099 [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2100 [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2101 if test "$resolv" = yes ; then
2102 RESOLVLIB=-lresolv
2103 AC_DEFINE(HAVE_LIBRESOLV, 1,
2104 [Define to 1 if you have the resolv library (-lresolv).])
2105 else
2106 RESOLVLIB=
2107 fi
2108 AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2109 AC_DEFINE(HAVE_LIBHESIOD, 1,
2110 [Define to 1 if you have the hesiod library (-lhesiod).]),
2111 :, $RESOLVLIB)])
2112 fi
2113
2114 # These tell us which Kerberos-related libraries to use.
2115 if test "${with_kerberos+set}" = set; then
2116 AC_CHECK_LIB(com_err, com_err)
2117 AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
2118 AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
2119 AC_CHECK_LIB(krb5, krb5_init_context)
2120 if test "${with_kerberos5+set}" != set; then
2121 AC_CHECK_LIB(des425, des_cbc_encrypt,,
2122 AC_CHECK_LIB(des, des_cbc_encrypt))
2123 AC_CHECK_LIB(krb4, krb_get_cred,,
2124 AC_CHECK_LIB(krb, krb_get_cred))
2125 fi
2126
2127 if test "${with_kerberos5+set}" = set; then
2128 AC_CHECK_HEADERS(krb5.h)
2129 else
2130 AC_CHECK_HEADERS(des.h,,
2131 [AC_CHECK_HEADERS(kerberosIV/des.h,,
2132 [AC_CHECK_HEADERS(kerberos/des.h)])])
2133 AC_CHECK_HEADERS(krb.h,,
2134 [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2135 [AC_CHECK_HEADERS(kerberos/krb.h)])])
2136 fi
2137 AC_CHECK_HEADERS(com_err.h)
2138 fi
2139
2140 # Solaris requires -lintl if you want strerror (which calls dgettext)
2141 # to return localized messages.
2142 AC_CHECK_LIB(intl, dgettext)
2143
2144 AC_MSG_CHECKING(whether localtime caches TZ)
2145 AC_CACHE_VAL(emacs_cv_localtime_cache,
2146 [if test x$ac_cv_func_tzset = xyes; then
2147 AC_TRY_RUN([#include <time.h>
2148 extern char **environ;
2149 unset_TZ ()
2150 {
2151 char **from, **to;
2152 for (to = from = environ; (*to = *from); from++)
2153 if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2154 to++;
2155 }
2156 char TZ_GMT0[] = "TZ=GMT0";
2157 char TZ_PST8[] = "TZ=PST8";
2158 main()
2159 {
2160 time_t now = time ((time_t *) 0);
2161 int hour_GMT0, hour_unset;
2162 if (putenv (TZ_GMT0) != 0)
2163 exit (1);
2164 hour_GMT0 = localtime (&now)->tm_hour;
2165 unset_TZ ();
2166 hour_unset = localtime (&now)->tm_hour;
2167 if (putenv (TZ_PST8) != 0)
2168 exit (1);
2169 if (localtime (&now)->tm_hour == hour_GMT0)
2170 exit (1);
2171 unset_TZ ();
2172 if (localtime (&now)->tm_hour != hour_unset)
2173 exit (1);
2174 exit (0);
2175 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2176 [# If we have tzset, assume the worst when cross-compiling.
2177 emacs_cv_localtime_cache=yes])
2178 else
2179 # If we lack tzset, report that localtime does not cache TZ,
2180 # since we can't invalidate the cache if we don't have tzset.
2181 emacs_cv_localtime_cache=no
2182 fi])dnl
2183 AC_MSG_RESULT($emacs_cv_localtime_cache)
2184 if test $emacs_cv_localtime_cache = yes; then
2185 AC_DEFINE(LOCALTIME_CACHE, 1,
2186 [Define to 1 if localtime caches TZ.])
2187 fi
2188
2189 if test "x$HAVE_TIMEVAL" = xyes; then
2190 AC_CHECK_FUNCS(gettimeofday)
2191 if test $ac_cv_func_gettimeofday = yes; then
2192 AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2193 emacs_cv_gettimeofday_two_arguments,
2194 [AC_TRY_COMPILE([
2195 #ifdef TIME_WITH_SYS_TIME
2196 #include <sys/time.h>
2197 #include <time.h>
2198 #else
2199 #ifdef HAVE_SYS_TIME_H
2200 #include <sys/time.h>
2201 #else
2202 #include <time.h>
2203 #endif
2204 #endif],
2205 [struct timeval time;
2206 gettimeofday (&time, 0);],
2207 emacs_cv_gettimeofday_two_arguments=yes,
2208 emacs_cv_gettimeofday_two_arguments=no)])
2209 if test $emacs_cv_gettimeofday_two_arguments = no; then
2210 AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2211 [Define to 1 if gettimeofday accepts only one argument.])
2212 fi
2213 fi
2214 fi
2215
2216 dnl Note that AC_STRUCT_TIMEZONE doesn't do what you might expect.
2217 if test "$ac_cv_func_gettimeofday" = yes; then
2218 AC_CACHE_CHECK([for struct timezone], emacs_cv_struct_timezone,
2219 [AC_TRY_COMPILE([#include <sys/time.h>],
2220 [struct timezone tz;],
2221 dnl It may be that we can't call gettimeofday with a non-null pointer,
2222 dnl even though we have struct timezone (e.g. HPUX). In that case
2223 dnl we'll lie about struct timezone.
2224 [AC_TRY_RUN([
2225 #ifdef TIME_WITH_SYS_TIME
2226 #include <sys/time.h>
2227 #include <time.h>
2228 #else
2229 #ifdef HAVE_SYS_TIME_H
2230 #include <sys/time.h>
2231 #else
2232 #include <time.h>
2233 #endif
2234 #endif
2235 main () {
2236 struct timeval time;
2237 struct timezone dummy;
2238 exit (gettimeofday (&time, &dummy));
2239 }],
2240 emacs_cv_struct_timezone=yes,
2241 emacs_cv_struct_timezone=no, emacs_cv_struct_timezone=yes)],
2242 emacs_cv_struct_timezone=no)])
2243 fi
2244
2245 ok_so_far=yes
2246 AC_CHECK_FUNC(socket, , ok_so_far=no)
2247 if test $ok_so_far = yes; then
2248 AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2249 fi
2250 if test $ok_so_far = yes; then
2251 AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2252 fi
2253 if test $ok_so_far = yes; then
2254 AC_DEFINE(HAVE_INET_SOCKETS, 1,
2255 [Define to 1 if you have inet sockets.])
2256 fi
2257
2258 if test -f /usr/lpp/X11/bin/smt.exp; then
2259 AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2260 [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2261 fi
2262
2263 AC_MSG_CHECKING(whether system supports dynamic ptys)
2264 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2265 AC_MSG_RESULT(yes)
2266 AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2267 else
2268 AC_MSG_RESULT(no)
2269 fi
2270
2271 AC_FUNC_FORK
2272
2273 # Fixme: This should be replaced when we have autoconf 2.14.
2274 AC_SIZE_T
2275
2276 # Set up the CFLAGS for real compilation, so we can substitute it.
2277 CFLAGS="$REAL_CFLAGS"
2278 CPPFLAGS="$REAL_CPPFLAGS"
2279
2280 changequote(, )dnl
2281 #### Find out which version of Emacs this is.
2282 version=`grep 'defconst[ ]*emacs-version' ${srcdir}/lisp/version.el \
2283 | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`
2284 changequote([, ])dnl
2285 if test x"${version}" = x; then
2286 AC_MSG_ERROR(can't find current emacs version in \`${srcdir}/lisp/version.el'.)
2287 fi
2288
2289 ### Specify what sort of things we'll be editing into Makefile and config.h.
2290 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2291 AC_SUBST(version)
2292 AC_SUBST(configuration)
2293 AC_SUBST(canonical)
2294 AC_SUBST(srcdir)
2295 AC_SUBST(prefix)
2296 AC_SUBST(exec_prefix)
2297 AC_SUBST(bindir)
2298 AC_SUBST(datadir)
2299 AC_SUBST(sharedstatedir)
2300 AC_SUBST(libexecdir)
2301 AC_SUBST(mandir)
2302 AC_SUBST(infodir)
2303 AC_SUBST(lispdir)
2304 AC_SUBST(locallisppath)
2305 AC_SUBST(lisppath)
2306 AC_SUBST(x_default_search_path)
2307 AC_SUBST(etcdir)
2308 AC_SUBST(archlibdir)
2309 AC_SUBST(docdir)
2310 AC_SUBST(bitmapdir)
2311 AC_SUBST(gamedir)
2312 AC_SUBST(gameuser)
2313 AC_SUBST(c_switch_system)
2314 AC_SUBST(c_switch_machine)
2315 AC_SUBST(LD_SWITCH_X_SITE)
2316 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2317 AC_SUBST(C_SWITCH_X_SITE)
2318 AC_SUBST(CFLAGS)
2319 AC_SUBST(X_TOOLKIT_TYPE)
2320 AC_SUBST(machfile)
2321 AC_SUBST(opsysfile)
2322 AC_SUBST(GETLOADAVG_LIBS)
2323
2324 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION, "${canonical}",
2325 [Define to the canonical Emacs configuration name.])
2326 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2327 [Define to the options passed to configure.])
2328 AC_DEFINE_UNQUOTED(config_machfile, "${machfile}",
2329 [Define to the used machine dependent file.])
2330 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2331 [Define to the used os dependent file.])
2332 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2333 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2334 may need to deal with X Windows. For instance, if you've defined
2335 HAVE_X_WINDOWS above and your X libraries aren't in a place that
2336 your loader can find on its own, you might want to add "-L/..." or
2337 something similar.])
2338 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2339 [Define LD_SWITCH_X_SITE_AUX with an -R option
2340 in case it's needed (for Solaris, for example).])
2341 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE, ${C_SWITCH_X_SITE},
2342 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2343 may need to deal with X Windows. For instance, if you've defined
2344 HAVE_X_WINDOWS above and your X include files aren't in a place
2345 that your compiler can find on its own, you might want to add
2346 "-I/..." or something similar.])
2347 AC_DEFINE_UNQUOTED(UNEXEC_SRC, ${UNEXEC_SRC},
2348 [Define to the unexec source file name.])
2349
2350 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2351 AC_DEFINE(HAVE_X_WINDOWS, 1,
2352 [Define to 1 if you want to use the X window system.])
2353 fi
2354 if test "${USE_X_TOOLKIT}" != "none" ; then
2355 AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2356 fi
2357 if test "${HAVE_X11}" = "yes" ; then
2358 AC_DEFINE(HAVE_X11, 1,
2359 [Define to 1 if you want to use version 11 of X windows.
2360 Otherwise, Emacs expects to use version 10.])
2361 fi
2362 if test "${HAVE_XFREE386}" = "yes" ; then
2363 AC_DEFINE(HAVE_XFREE386, 1, [Define to 1 if you're using XFree386.])
2364 fi
2365 if test "${HAVE_MENUS}" = "yes" ; then
2366 AC_DEFINE(HAVE_MENUS, 1,
2367 [Define to 1 if you have mouse menus.
2368 (This is automatic if you use X, but the option to specify it remains.)
2369 It is also defined with other window systems that support xmenu.c.])
2370 fi
2371 if test "${GNU_MALLOC}" = "yes" ; then
2372 AC_DEFINE(GNU_MALLOC, 1,
2373 [Define to 1 if you want to use the GNU memory allocator.])
2374 fi
2375 if test "${REL_ALLOC}" = "yes" ; then
2376 AC_DEFINE(REL_ALLOC, 1,
2377 [Define REL_ALLOC if you want to use the relocating allocator for
2378 buffer space.])
2379 fi
2380
2381 AC_CHECK_HEADERS(nlist.h, [AC_DEFINE(NLIST_STRUCT, 1,
2382 [Define to 1 if you have <nlist.h>.])])
2383
2384 AH_TOP([/* GNU Emacs site configuration template file. -*- C -*-
2385 Copyright (C) 1988, 1993, 1994, 1999, 2000 Free Software Foundation, Inc.
2386
2387 This file is part of GNU Emacs.
2388
2389 GNU Emacs is free software; you can redistribute it and/or modify
2390 it under the terms of the GNU General Public License as published by
2391 the Free Software Foundation; either version 2, or (at your option)
2392 any later version.
2393
2394 GNU Emacs is distributed in the hope that it will be useful,
2395 but WITHOUT ANY WARRANTY; without even the implied warranty of
2396 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
2397 GNU General Public License for more details.
2398
2399 You should have received a copy of the GNU General Public License
2400 along with GNU Emacs; see the file COPYING. If not, write to the
2401 Free Software Foundation, Inc., 59 Temple Place - Suite 330,
2402 Boston, MA 02111-1307, USA. */
2403
2404
2405 /* No code in Emacs #includes config.h twice, but some of the code
2406 intended to work with other packages as well (like gmalloc.c)
2407 think they can include it as many times as they like. */
2408 #ifndef EMACS_CONFIG_H
2409 #define EMACS_CONFIG_H
2410 ])dnl
2411
2412 AH_BOTTOM([
2413 /* If we're using any sort of window system, define some consequences. */
2414 #ifdef HAVE_X_WINDOWS
2415 #define HAVE_WINDOW_SYSTEM
2416 #define MULTI_KBOARD
2417 #define HAVE_MOUSE
2418 #endif
2419
2420 /* If we're using the Carbon API on Mac OS X, define a few more
2421 variables as well. */
2422 #ifdef HAVE_CARBON
2423 #define HAVE_WINDOW_SYSTEM
2424 #define HAVE_MOUSE
2425 #define HAVE_MENUS
2426 #endif
2427
2428 /* Define USER_FULL_NAME to return a string
2429 that is the user's full name.
2430 It can assume that the variable `pw'
2431 points to the password file entry for this user.
2432
2433 At some sites, the pw_gecos field contains
2434 the user's full name. If neither this nor any other
2435 field contains the right thing, use pw_name,
2436 giving the user's login name, since that is better than nothing. */
2437 #define USER_FULL_NAME pw->pw_gecos
2438
2439 /* Define AMPERSAND_FULL_NAME if you use the convention
2440 that & in the full name stands for the login id. */
2441 /* Turned on June 1996 supposing nobody will mind it. */
2442 #define AMPERSAND_FULL_NAME
2443
2444 /* Define HAVE_SOUND if we have sound support. We know it works
2445 and compiles only on the specified platforms. For others,
2446 it probably doesn't make sense to try. */
2447
2448 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2449 #ifdef HAVE_MACHINE_SOUNDCARD_H
2450 #define HAVE_SOUND 1
2451 #endif
2452 #ifdef HAVE_SYS_SOUNDCARD_H
2453 #define HAVE_SOUND 1
2454 #endif
2455 #ifdef HAVE_SOUNDCARD_H
2456 #define HAVE_SOUND 1
2457 #endif
2458 #endif /* __FreeBSD__ || __NetBSD__ || __linux__ */
2459
2460 /* If using GNU, then support inline function declarations. */
2461 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2462 generally, because even if non-gcc compilers accept `inline', they
2463 may reject `extern inline'. */
2464 #ifdef __GNUC__
2465 #define INLINE __inline__
2466 #else
2467 #define INLINE
2468 #endif
2469
2470 /* Include the os and machine dependent files. */
2471 #include config_opsysfile
2472 #include config_machfile
2473
2474 /* Load in the conversion definitions if this system
2475 needs them and the source file being compiled has not
2476 said to inhibit this. There should be no need for you
2477 to alter these lines. */
2478
2479 #ifdef SHORTNAMES
2480 #ifndef NO_SHORTNAMES
2481 #include "../shortnames/remap.h"
2482 #endif /* not NO_SHORTNAMES */
2483 #endif /* SHORTNAMES */
2484
2485 /* If no remapping takes place, static variables cannot be dumped as
2486 pure, so don't worry about the `static' keyword. */
2487 #ifdef NO_REMAP
2488 #undef static
2489 #endif
2490
2491 /* Define `subprocesses' should be defined if you want to
2492 have code for asynchronous subprocesses
2493 (as used in M-x compile and M-x shell).
2494 These do not work for some USG systems yet;
2495 for the ones where they work, the s/SYSTEM.h file defines this flag. */
2496
2497 #ifndef VMS
2498 #ifndef USG
2499 /* #define subprocesses */
2500 #endif
2501 #endif
2502
2503 /* SIGTYPE is the macro we actually use. */
2504 #ifndef SIGTYPE
2505 #define SIGTYPE RETSIGTYPE
2506 #endif
2507
2508 #ifdef emacs /* Don't do this for lib-src. */
2509 /* Tell regex.c to use a type compatible with Emacs. */
2510 #define RE_TRANSLATE_TYPE Lisp_Object
2511 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2512 #define RE_TRANSLATE_P(TBL) (XFASTINT (TBL) != 0)
2513 #endif
2514
2515 /* Avoid link-time collision with system mktime if we will use our own. */
2516 #if ! HAVE_MKTIME || BROKEN_MKTIME
2517 #define mktime emacs_mktime
2518 #endif
2519
2520 /* The rest of the code currently tests the CPP symbol BSTRING.
2521 Override any claims made by the system-description files.
2522 Note that on some SCO version it is possible to have bcopy and not bcmp. */
2523 #undef BSTRING
2524 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2525 #define BSTRING
2526 #endif
2527
2528 /* Some of the files of Emacs which are intended for use with other
2529 programs assume that if you have a config.h file, you must declare
2530 the type of getenv.
2531
2532 This declaration shouldn't appear when alloca.s or Makefile.in
2533 includes config.h. */
2534 #ifndef NOT_C_CODE
2535 extern char *getenv ();
2536 #endif
2537
2538 #endif /* EMACS_CONFIG_H */
2539
2540 /* These default definitions are good for almost all machines.
2541 The exceptions override them in m/MACHINE.h. */
2542
2543 #ifndef BITS_PER_CHAR
2544 #define BITS_PER_CHAR 8
2545 #endif
2546
2547 #ifndef BITS_PER_SHORT
2548 #define BITS_PER_SHORT 16
2549 #endif
2550
2551 /* Note that lisp.h uses this in a preprocessor conditional, so it
2552 would not work to use sizeof. That being so, we do all of them
2553 without sizeof, for uniformity's sake. */
2554 #ifndef BITS_PER_INT
2555 #define BITS_PER_INT 32
2556 #endif
2557
2558 #ifndef BITS_PER_LONG
2559 #ifdef _LP64
2560 #define BITS_PER_LONG 64
2561 #else
2562 #define BITS_PER_LONG 32
2563 #endif
2564 #endif
2565
2566 /* Define if the compiler supports function prototypes. It may do so
2567 but not define __STDC__ (e.g. DEC C by default) or may define it as
2568 zero. */
2569 #undef PROTOTYPES
2570 /* For mktime.c: */
2571 #ifndef __P
2572 # if defined PROTOTYPES
2573 # define __P(args) args
2574 # else
2575 # define __P(args) ()
2576 # endif /* GCC. */
2577 #endif /* __P */
2578
2579
2580 /* Don't include "string.h" or <stdlib.h> in non-C code. */
2581 #ifndef NOT_C_CODE
2582 #ifdef HAVE_STRING_H
2583 #include "string.h"
2584 #endif
2585 #ifdef HAVE_STDLIB_H
2586 #include <stdlib.h>
2587 #endif
2588 #endif
2589
2590 /* Define HAVE_X_I18N if we have usable i18n support. */
2591
2592 #ifdef HAVE_X11R6
2593 #define HAVE_X_I18N
2594 #elif defined HAVE_X11R5 && !defined X11R5_INHIBIT_I18N
2595 #define HAVE_X_I18N
2596 #endif
2597
2598 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support. */
2599
2600 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
2601 #define HAVE_X11R6_XIM
2602 #endif
2603
2604 /* Should we enable expensive run-time checking of data types? */
2605 #undef ENABLE_CHECKING
2606
2607 #if defined __GNUC__ && (__GNUC__ > 2 \
2608 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
2609 #define NO_RETURN __attribute__ ((__noreturn__))
2610 #else
2611 #define NO_RETURN /* nothing */
2612 #endif
2613 ])dnl
2614
2615 #### Report on what we decided to do.
2616 echo "
2617 Configured for \`${canonical}'.
2618
2619 Where should the build process find the source code? ${srcdir}
2620 What operating system and machine description files should Emacs use?
2621 \`${opsysfile}' and \`${machfile}'
2622 What compiler should emacs be built with? ${CC} ${CFLAGS}
2623 Should Emacs use the GNU version of malloc? ${GNU_MALLOC}${GNU_MALLOC_reason}
2624 Should Emacs use a relocating allocator for buffers? ${REL_ALLOC}
2625 Should Emacs use mmap(2) for buffer allocation? $use_mmap_for_buffers
2626 What window system should Emacs use? ${window_system}
2627 What toolkit should Emacs use? ${USE_X_TOOLKIT}
2628 Should Emacs use a shared game state directory? ${gamedir}"
2629
2630 if test -n "${x_includes}"; then
2631 echo " Where do we find X Windows header files? ${x_includes}"
2632 else
2633 echo " Where do we find X Windows header files? Standard dirs"
2634 fi
2635 if test -n "${x_libraries}"; then
2636 echo " Where do we find X Windows libraries? ${x_libraries}"
2637 else
2638 echo " Where do we find X Windows libraries? Standard dirs"
2639 fi
2640
2641 echo " Does Emacs use -lXaw3d? ${HAVE_XAW3D}"
2642 echo " Does Emacs use -lXpm? ${HAVE_XPM}"
2643 echo " Does Emacs use -ljpeg? ${HAVE_JPEG}"
2644 echo " Does Emacs use -ltiff? ${HAVE_TIFF}"
2645 echo " Does Emacs use -lungif? ${HAVE_GIF}"
2646 echo " Does Emacs use -lpng? ${HAVE_PNG}"
2647 echo " Does Emacs use X toolkit scroll bars? ${USE_TOOLKIT_SCROLL_BARS}"
2648 echo
2649
2650 # Remove any trailing slashes in these variables.
2651 changequote(, )dnl
2652 test "${prefix}" != NONE &&
2653 prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
2654 test "${exec_prefix}" != NONE &&
2655 exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`
2656 changequote([, ])dnl
2657
2658 ## Check if the C preprocessor will convert `..' to `. .'. If so, set
2659 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
2660 ## from Makefile.c can correctly provide the arg `-traditional' to the
2661 ## C preprocessor.
2662
2663 AC_EGREP_CPP(yes..yes,
2664 [yes..yes],
2665 CPP_NEED_TRADITIONAL=no,
2666 CPP_NEED_TRADITIONAL=yes)
2667
2668 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
2669 man/Makefile lwlib/Makefile src/Makefile.c:src/Makefile.in \
2670 lisp/Makefile lispref/Makefile lispintro/Makefile leim/Makefile, [
2671
2672 ### Make the necessary directories, if they don't exist.
2673 for dir in etc lisp ; do
2674 test -d ${dir} || mkdir ${dir}
2675 done
2676
2677 # Build src/Makefile from ${srcdir}/src/Makefile.c
2678 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
2679 # This must be done after src/config.h is built, since we rely on that file.
2680
2681 changequote(, )dnl The horror, the horror.
2682 # Now get this: Some word that is part of the ${srcdir} directory name
2683 # or the ${configuration} value might, just might, happen to be an
2684 # identifier like `sun4' or `i386' or something, and be predefined by
2685 # the C preprocessor to some helpful value like 1, or maybe the empty
2686 # string. Needless to say consequent macro substitutions are less
2687 # than conducive to the makefile finding the correct directory.
2688 undefs="`echo $top_srcdir $configuration $canonical |
2689 sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/ *$//' \
2690 -e 's/ */ -U/g' -e 's/-U[0-9][^ ]*//g' \
2691 `"
2692 changequote([, ])dnl
2693
2694 echo creating src/epaths.h
2695 ${MAKE-make} epaths-force
2696
2697 # As of 2000-11-19, newest development versions of GNU cpp preprocess
2698 # `..' to `. .' unless invoked with -traditional
2699
2700 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
2701 CPPFLAGS="$CPPFLAGS -traditional"
2702 fi
2703
2704 echo creating lib-src/Makefile
2705 ( cd lib-src
2706 rm -f junk.c junk1.c junk2.c
2707 sed -e '/start of cpp stuff/q' \
2708 < Makefile.c > junk1.c
2709 sed -e '1,/start of cpp stuff/d'\
2710 -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
2711 < Makefile.c > junk.c
2712 $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
2713 sed -e 's/^ / /' -e '/^#/d' -e '/^[ \f]*$/d' > junk2.c
2714 cat junk1.c junk2.c > Makefile.new
2715 rm -f junk.c junk1.c junk2.c
2716 chmod 444 Makefile.new
2717 mv -f Makefile.new Makefile
2718 )
2719
2720 echo creating src/Makefile
2721 ( cd src
2722 rm -f junk.c junk1.c junk2.c
2723 sed -e '/start of cpp stuff/q' \
2724 < Makefile.c > junk1.c
2725 sed -e '1,/start of cpp stuff/d'\
2726 -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
2727 < Makefile.c > junk.c
2728 $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
2729 sed -e 's/^ / /' -e '/^#/d' -e '/^[ \f]*$/d' > junk2.c
2730 cat junk1.c junk2.c > Makefile.new
2731 rm -f junk.c junk1.c junk2.c
2732 chmod 444 Makefile.new
2733 mv -f Makefile.new Makefile
2734 )
2735
2736 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
2737 echo creating src/.gdbinit
2738 echo source $srcdir/src/.gdbinit > src/.gdbinit
2739 fi
2740
2741 # This is how we know whether to re-run configure in certain cases.
2742 touch src/config.stamp
2743
2744 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS"])
2745