code.delx.au - gnu-emacs/blob - lisp/vc-hooks.el

   1 ;;; vc-hooks.el --- resident support for version-control
   2
   3 ;; Copyright (C) 1992, 1993 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric S. Raymond <esr@snark.thyrsus.com>
   6 ;; Version: 5.3
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  22 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; See the commentary of vc.el.
  27
  28 ;;; Code:
  29
  30 (defvar vc-master-templates
  31   '(("%sRCS/%s,v" . RCS) ("%s%s,v" . RCS) ("%sRCS/%s" . RCS)
  32     ("%sSCCS/s.%s" . SCCS) ("%ss.%s". SCCS))
  33   "*Where to look for version-control master files.
  34 The first pair corresponding to a given back end is used as a template
  35 when creating new masters.")
  36
  37 (defvar vc-make-backup-files nil
  38   "*If non-nil, backups of registered files are made as with other files.
  39 If nil (the default), files covered by version control don't get backups.")
  40
  41 (defvar vc-rcs-status t
  42   "*If non-nil, revision and locks on RCS working file displayed in modeline.
  43 Otherwise, not displayed.")
  44
  45 ;; Tell Emacs about this new kind of minor mode
  46 (if (not (assoc 'vc-mode minor-mode-alist))
  47     (setq minor-mode-alist (cons '(vc-mode vc-mode)
  48                                  minor-mode-alist)))
  49
  50 (make-variable-buffer-local 'vc-mode)
  51 (put 'vc-mode 'permanent-local t)
  52
  53 ;; We need a notion of per-file properties because the version
  54 ;; control state of a file is expensive to derive --- we don't
  55 ;; want to recompute it even on every find.
  56
  57 (defmacro vc-error-occurred (&rest body)
  58   (list 'condition-case nil (cons 'progn (append body '(nil))) '(error t)))
  59
  60 (defvar vc-file-prop-obarray [0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0]
  61   "Obarray for per-file properties.")
  62
  63 (defun vc-file-setprop (file property value)
  64   ;; set per-file property
  65   (put (intern file vc-file-prop-obarray) property value))
  66
  67 (defun vc-file-getprop (file property)
  68   ;; get per-file property
  69   (get (intern file vc-file-prop-obarray) property))
  70
  71 ;;; actual version-control code starts here
  72
  73 (defun vc-registered (file)
  74   (let (handler handlers)
  75     (if (boundp 'file-name-handler-alist)
  76         (save-match-data
  77           (setq handlers file-name-handler-alist)
  78           (while (and (consp handlers) (null handler))
  79             (if (and (consp (car handlers))
  80                      (stringp (car (car handlers)))
  81                      (string-match (car (car handlers)) file))
  82                 (setq handler (cdr (car handlers))))
  83             (setq handlers (cdr handlers)))))
  84     (if handler
  85         (funcall handler 'vc-registered file)
  86       ;; Search for a master corresponding to the given file
  87       (let ((dirname (or (file-name-directory file) ""))
  88             (basename (file-name-nondirectory file)))
  89         (catch 'found
  90           (mapcar
  91            (function (lambda (s)
  92               (let ((trial (format (car s) dirname basename)))
  93                 (if (and (file-exists-p trial)
  94                          ;; Make sure the file we found with name
  95                          ;; TRIAL is not the source file itself.
  96                          ;; That can happen with RCS-style names
  97                          ;; if the file name is truncated
  98                          ;; (e.g. to 14 chars).  See if either
  99                          ;; directory or attributes differ.
 100                          (or (not (string= dirname
 101                                            (file-name-directory trial)))
 102                              (not (equal
 103                                    (file-attributes file)
 104                                    (file-attributes trial)))))
 105                     (throw 'found (cons trial (cdr s)))))))
 106            vc-master-templates)
 107           nil)))))
 108
 109 (defun vc-name (file)
 110   "Return the master name of a file, nil if it is not registered."
 111   (or (vc-file-getprop file 'vc-name)
 112       (let ((name-and-type (vc-registered file)))
 113         (if name-and-type
 114             (progn
 115               (vc-file-setprop file 'vc-backend (cdr name-and-type))
 116               (vc-file-setprop file 'vc-name (car name-and-type)))))))
 117
 118 (defun vc-backend-deduce (file)
 119   "Return the version-control type of a file, nil if it is not registered."
 120   (and file
 121        (or (vc-file-getprop file 'vc-backend)
 122            (let ((name-and-type (vc-registered file)))
 123              (if name-and-type
 124                  (progn
 125                    (vc-file-setprop file 'vc-name (car name-and-type))
 126                    (vc-file-setprop file 'vc-backend (cdr name-and-type))))))))
 127
 128 (defun vc-toggle-read-only ()
 129   "Change read-only status of current buffer, perhaps via version control.
 130 If the buffer is visiting a file registered with version control,
 131 then check the file in or out.  Otherwise, just change the read-only flag
 132 of the buffer."
 133   (interactive)
 134   (if (vc-backend-deduce (buffer-file-name))
 135       (vc-next-action nil)
 136     (toggle-read-only)))
 137 (define-key global-map "\C-x\C-q" 'vc-toggle-read-only)
 138
 139 (defun vc-mode-line (file &optional label)
 140   "Set `vc-mode' to display type of version control for FILE.
 141 The value is set in the current buffer, which should be the buffer
 142 visiting FILE."
 143   (interactive (list buffer-file-name nil))
 144   (let ((vc-type (vc-backend-deduce file)))
 145     (setq vc-mode
 146           (and vc-type
 147                (concat " " (or label (symbol-name vc-type))
 148                        (if (and vc-rcs-status (eq vc-type 'RCS))
 149                            (vc-rcs-status file)))))
 150     ;; Even root shouldn't modify a registered file without locking it first.
 151     (and vc-type
 152          (not buffer-read-only)
 153          (zerop (user-uid))
 154          (require 'vc)
 155          (not (string-equal (user-login-name) (vc-locking-user file)))
 156          (setq buffer-read-only t))
 157     (and (null vc-type)
 158          (file-symlink-p file)
 159          (let ((link-type (vc-backend-deduce (file-symlink-p file))))
 160            (if link-type
 161                (message "Warning: symbolic link to %s-controlled source file"
 162                         link-type))))
 163     (force-mode-line-update)
 164     ;;(set-buffer-modified-p (buffer-modified-p))  ;;use this if Emacs 18
 165     vc-type))
 166
 167 (defun vc-rcs-status (file)
 168   ;; Return string for placement in modeline by `vc-mode-line'.
 169   ;; If FILE is not registered under RCS, return nil.
 170   ;; If FILE is registered but not locked, return " REV" if there is a head
 171   ;; revision and " @@" otherwise.
 172   ;; If FILE is locked then return all locks in a string of the
 173   ;; form " LOCKER1:REV1 LOCKER2:REV2 ...", where "LOCKERi:" is empty if you
 174   ;; are the locker, and otherwise is the name of the locker followed by ":".
 175
 176   ;; Algorithm:
 177
 178   ;; 1. Check for master file corresponding to FILE being visited.
 179   ;;
 180   ;; 2. Insert the first few characters of the master file into a work
 181   ;; buffer.
 182   ;;
 183   ;; 3. Search work buffer for "locks...;" phrase; if not found, then
 184   ;; keep inserting more characters until the phrase is found.
 185   ;;
 186   ;; 4. Extract the locks, and remove control characters
 187   ;; separating them, like newlines; the string " user1:revision1
 188   ;; user2:revision2 ..." is returned.
 189
 190   ;; Limitations:
 191
 192   ;; The output doesn't show which version you are actually looking at.
 193   ;; The modeline can get quite cluttered when there are multiple locks.
 194   ;; The head revision is probably not what you want if you've used `rcs -b'.
 195
 196   (let ((master (vc-name file))
 197         found)
 198
 199     ;; If master file exists, then parse its contents, otherwise we return the
 200     ;; nil value of this if form.
 201     (if master
 202         (save-excursion
 203
 204           ;; Create work buffer.
 205           (set-buffer (get-buffer-create " *vc-rcs-status*"))
 206           (setq buffer-read-only nil
 207                 default-directory (file-name-directory master))
 208           (erase-buffer)
 209
 210           ;; Check if we have enough of the header.
 211           ;; If not, then keep including more.
 212           (while
 213               (not (or found
 214                        (let ((s (buffer-size)))
 215                          (goto-char (1+ s))
 216                          (zerop (car (cdr (insert-file-contents
 217                                            master nil s (+ s 8192))))))))
 218             (beginning-of-line)
 219             (setq found (re-search-forward "^locks\\([^;]*\\);" nil t)))
 220
 221           (if found
 222               ;; Clean control characters and self-locks from text.
 223               (let* ((lock-pattern
 224                       (concat "[ \b\t\n\v\f\r]+\\("
 225                               (regexp-quote (user-login-name))
 226                               ":\\)?"))
 227                      (locks
 228                       (save-restriction
 229                         (narrow-to-region (match-beginning 1) (match-end 1))
 230                         (goto-char (point-min))
 231                         (while (re-search-forward lock-pattern nil t)
 232                           (replace-match (if (eobp) "" ":") t t))
 233                         (buffer-string)))
 234                      (status
 235                       (if (not (string-equal locks ""))
 236                           locks
 237                         (goto-char (point-min))
 238                         (if (looking-at "head[ \b\t\n\v\f\r]+\\([.0-9]+\\)")
 239                             (concat "-" (buffer-substring (match-beginning 1)
 240                                                           (match-end 1)))
 241                           " @@"))))
 242                 ;; Clean work buffer.
 243                 (erase-buffer)
 244                 (set-buffer-modified-p nil)
 245                 status))))))
 246
 247 ;;; install a call to the above as a find-file hook
 248 (defun vc-find-file-hook ()
 249   ;; Recompute whether file is version controlled,
 250   ;; if user has killed the buffer and revisited.
 251   (if buffer-file-name
 252       (vc-file-setprop buffer-file-name 'vc-backend nil))
 253   (if (and (vc-mode-line buffer-file-name) (not vc-make-backup-files))
 254       (progn
 255         ;; Use this variable, not make-backup-files,
 256         ;; because this is for things that depend on the file name.
 257         (make-local-variable 'backup-inhibited)
 258         (setq backup-inhibited t))))
 259
 260 (add-hook 'find-file-hooks 'vc-find-file-hook)
 261
 262 ;;; more hooks, this time for file-not-found
 263 (defun vc-file-not-found-hook ()
 264   "When file is not found, try to check it out from RCS or SCCS.
 265 Returns t if checkout was successful, nil otherwise."
 266   (if (vc-backend-deduce buffer-file-name)
 267       (progn
 268         (require 'vc)
 269         (not (vc-error-occurred (vc-checkout buffer-file-name))))))
 270
 271 (add-hook 'find-file-not-found-hooks 'vc-file-not-found-hook)
 272
 273 ;;; Now arrange for bindings and autoloading of the main package.
 274 ;;; Bindings for this have to go in the global map, as we'll often
 275 ;;; want to call them from random buffers.
 276
 277 (setq vc-prefix-map (lookup-key global-map "\C-xv"))
 278 (if (not (keymapp vc-prefix-map))
 279     (progn
 280       (setq vc-prefix-map (make-sparse-keymap))
 281       (define-key global-map "\C-xv" vc-prefix-map)
 282       (define-key vc-prefix-map "a" 'vc-update-change-log)
 283       (define-key vc-prefix-map "c" 'vc-cancel-version)
 284       (define-key vc-prefix-map "d" 'vc-directory)
 285       (define-key vc-prefix-map "h" 'vc-insert-headers)
 286       (define-key vc-prefix-map "i" 'vc-register)
 287       (define-key vc-prefix-map "l" 'vc-print-log)
 288       (define-key vc-prefix-map "r" 'vc-retrieve-snapshot)
 289       (define-key vc-prefix-map "s" 'vc-create-snapshot)
 290       (define-key vc-prefix-map "u" 'vc-revert-buffer)
 291       (define-key vc-prefix-map "v" 'vc-next-action)
 292       (define-key vc-prefix-map "=" 'vc-diff)
 293       (define-key vc-prefix-map "~" 'vc-version-other-window)
 294       ))
 295
 296 (provide 'vc-hooks)
 297
 298 ;;; vc-hooks.el ends here