code.delx.au - gnu-emacs/blob - lisp/replace.el

   1 ;;; replace.el --- replace commands for Emacs
   2
   3 ;; Copyright (C) 1985, 86, 87, 92, 94, 96, 1997, 2000, 2001, 2002
   4 ;;  Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This package supplies the string and regular-expression replace functions
  28 ;; documented in the Emacs user's manual.
  29
  30 ;;; Code:
  31
  32 (defcustom case-replace t
  33   "*Non-nil means `query-replace' should preserve case in replacements."
  34   :type 'boolean
  35   :group 'matching)
  36
  37 (defvar query-replace-history nil)
  38
  39 (defcustom query-replace-interactive nil
  40   "Non-nil means `query-replace' uses the last search string.
  41 That becomes the \"string to replace\"."
  42   :type 'boolean
  43   :group 'matching)
  44
  45 (defcustom query-replace-from-history-variable 'query-replace-history
  46   "History list to use for the FROM argument of `query-replace' commands.
  47 The value of this variable should be a symbol; that symbol
  48 is used as a variable to hold a history list for the strings
  49 or patterns to be replaced."
  50   :group 'matching
  51   :type 'symbol
  52   :version "20.3")
  53
  54 (defcustom query-replace-to-history-variable 'query-replace-history
  55   "History list to use for the TO argument of `query-replace' commands.
  56 The value of this variable should be a symbol; that symbol
  57 is used as a variable to hold a history list for replacement
  58 strings or patterns."
  59   :group 'matching
  60   :type 'symbol
  61   :version "20.3")
  62
  63 (defcustom query-replace-skip-read-only nil
  64   "*Non-nil means `query-replace' and friends ignore read-only matches."
  65   :type 'boolean
  66   :group 'matching
  67   :version "21.4")
  68
  69 (defun query-replace-read-args (string regexp-flag &optional noerror)
  70   (unless noerror
  71     (barf-if-buffer-read-only))
  72   (let (from to)
  73     (if query-replace-interactive
  74         (setq from (car (if regexp-flag regexp-search-ring search-ring)))
  75       ;; The save-excursion here is in case the user marks and copies
  76       ;; a region in order to specify the minibuffer input.
  77       ;; That should not clobber the region for the query-replace itself.
  78       (save-excursion
  79         (setq from (read-from-minibuffer (format "%s: " string)
  80                                          nil nil nil
  81                                          query-replace-from-history-variable
  82                                          nil t)))
  83       ;; Warn if user types \n or \t, but don't reject the input.
  84       (if (string-match "\\\\[nt]" from)
  85           (let ((match (match-string 0 from)))
  86             (cond
  87              ((string= match "\\n")
  88               (message "Note: `\\n' here doesn't match a newline; to do that, type C-q C-j instead"))
  89              ((string= match "\\t")
  90               (message "Note: `\\t' here doesn't match a tab; to do that, just type TAB")))
  91             (sit-for 2))))
  92
  93     (save-excursion
  94       (setq to (read-from-minibuffer (format "%s %s with: " string from)
  95                                      nil nil nil
  96                                      query-replace-to-history-variable from t)))
  97     (list from to current-prefix-arg)))
  98
  99 (defun query-replace (from-string to-string &optional delimited start end)
 100   "Replace some occurrences of FROM-STRING with TO-STRING.
 101 As each match is found, the user must type a character saying
 102 what to do with it.  For directions, type \\[help-command] at that time.
 103
 104 In Transient Mark mode, if the mark is active, operate on the contents
 105 of the region.  Otherwise, operate from point to the end of the buffer.
 106
 107 If `query-replace-interactive' is non-nil, the last incremental search
 108 string is used as FROM-STRING--you don't have to specify it with the
 109 minibuffer.
 110
 111 Matching is independent of case if `case-fold-search' is non-nil and
 112 FROM-STRING has no uppercase letters.  Replacement transfers the case
 113 pattern of the old text to the new text, if `case-replace' and
 114 `case-fold-search' are non-nil and FROM-STRING has no uppercase
 115 letters.  \(Transferring the case pattern means that if the old text
 116 matched is all caps, or capitalized, then its replacement is upcased
 117 or capitalized.)
 118
 119 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 120 only matches surrounded by word boundaries.
 121 Fourth and fifth arg START and END specify the region to operate on.
 122
 123 To customize possible responses, change the \"bindings\" in `query-replace-map'."
 124   (interactive (let ((common
 125                       (query-replace-read-args "Query replace" nil)))
 126                  (list (nth 0 common) (nth 1 common) (nth 2 common)
 127                        ;; These are done separately here
 128                        ;; so that command-history will record these expressions
 129                        ;; rather than the values they had this time.
 130                        (if (and transient-mark-mode mark-active)
 131                            (region-beginning))
 132                        (if (and transient-mark-mode mark-active)
 133                            (region-end)))))
 134   (perform-replace from-string to-string t nil delimited nil nil start end))
 135
 136 (define-key esc-map "%" 'query-replace)
 137
 138 (defun query-replace-regexp (regexp to-string &optional delimited start end)
 139   "Replace some things after point matching REGEXP with TO-STRING.
 140 As each match is found, the user must type a character saying
 141 what to do with it.  For directions, type \\[help-command] at that time.
 142
 143 In Transient Mark mode, if the mark is active, operate on the contents
 144 of the region.  Otherwise, operate from point to the end of the buffer.
 145
 146 If `query-replace-interactive' is non-nil, the last incremental search
 147 regexp is used as REGEXP--you don't have to specify it with the
 148 minibuffer.
 149
 150 Matching is independent of case if `case-fold-search' is non-nil and
 151 REGEXP has no uppercase letters.  Replacement transfers the case
 152 pattern of the old text to the new text, if `case-replace' and
 153 `case-fold-search' are non-nil and REGEXP has no uppercase letters.
 154 \(Transferring the case pattern means that if the old text matched is
 155 all caps, or capitalized, then its replacement is upcased or
 156 capitalized.)
 157
 158 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 159 only matches surrounded by word boundaries.
 160 Fourth and fifth arg START and END specify the region to operate on.
 161
 162 In TO-STRING, `\\&' stands for whatever matched the whole of REGEXP,
 163 and `\\=\\N' (where N is a digit) stands for
 164  whatever what matched the Nth `\\(...\\)' in REGEXP."
 165   (interactive
 166    (let ((common
 167           (query-replace-read-args "Query replace regexp" t)))
 168      (list (nth 0 common) (nth 1 common) (nth 2 common)
 169            ;; These are done separately here
 170            ;; so that command-history will record these expressions
 171            ;; rather than the values they had this time.
 172            (if (and transient-mark-mode mark-active)
 173                (region-beginning))
 174            (if (and transient-mark-mode mark-active)
 175                (region-end)))))
 176
 177   (perform-replace regexp to-string t t delimited nil nil start end))
 178 (define-key esc-map [?\C-%] 'query-replace-regexp)
 179
 180 (defun query-replace-regexp-eval (regexp to-expr &optional delimited start end)
 181   "Replace some things after point matching REGEXP with the result of TO-EXPR.
 182 As each match is found, the user must type a character saying
 183 what to do with it.  For directions, type \\[help-command] at that time.
 184
 185 TO-EXPR is a Lisp expression evaluated to compute each replacement.  It may
 186 reference `replace-count' to get the number of replacements already made.
 187 If the result of TO-EXPR is not a string, it is converted to one using
 188 `prin1-to-string' with the NOESCAPE argument (which see).
 189
 190 For convenience, when entering TO-EXPR interactively, you can use `\\&' or
 191 `\\0' to stand for whatever matched the whole of REGEXP, and `\\N' (where
 192 N is a digit) to stand for whatever matched the Nth `\\(...\\)' in REGEXP.
 193 Use `\\#&' or `\\#N' if you want a number instead of a string.
 194
 195 In Transient Mark mode, if the mark is active, operate on the contents
 196 of the region.  Otherwise, operate from point to the end of the buffer.
 197
 198 If `query-replace-interactive' is non-nil, the last incremental search
 199 regexp is used as REGEXP--you don't have to specify it with the
 200 minibuffer.
 201
 202 Preserves case in each replacement if `case-replace' and `case-fold-search'
 203 are non-nil and REGEXP has no uppercase letters.
 204
 205 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 206 only matches that are surrounded by word boundaries.
 207 Fourth and fifth arg START and END specify the region to operate on."
 208   (interactive
 209    (let (from to)
 210      (if query-replace-interactive
 211          (setq from (car regexp-search-ring))
 212        (setq from (read-from-minibuffer "Query replace regexp: "
 213                                         nil nil nil
 214                                         query-replace-from-history-variable
 215                                         nil t)))
 216      (setq to (list (read-from-minibuffer
 217                      (format "Query replace regexp %s with eval: " from)
 218                      nil nil t query-replace-to-history-variable from t)))
 219      ;; We make TO a list because replace-match-string-symbols requires one,
 220      ;; and the user might enter a single token.
 221      (replace-match-string-symbols to)
 222      (list from (car to) current-prefix-arg
 223            (if (and transient-mark-mode mark-active)
 224                (region-beginning))
 225            (if (and transient-mark-mode mark-active)
 226                (region-end)))))
 227   (perform-replace regexp (cons 'replace-eval-replacement to-expr)
 228                    t 'literal delimited nil nil start end))
 229
 230 (defun map-query-replace-regexp (regexp to-strings &optional n start end)
 231   "Replace some matches for REGEXP with various strings, in rotation.
 232 The second argument TO-STRINGS contains the replacement strings,
 233 separated by spaces.  Third arg DELIMITED (prefix arg if interactive),
 234 if non-nil, means replace only matches surrounded by word boundaries.
 235 This command works like `query-replace-regexp' except that each
 236 successive replacement uses the next successive replacement string,
 237 wrapping around from the last such string to the first.
 238
 239 In Transient Mark mode, if the mark is active, operate on the contents
 240 of the region.  Otherwise, operate from point to the end of the buffer.
 241
 242 Non-interactively, TO-STRINGS may be a list of replacement strings.
 243
 244 If `query-replace-interactive' is non-nil, the last incremental search
 245 regexp is used as REGEXP--you don't have to specify it with the minibuffer.
 246
 247 A prefix argument N says to use each replacement string N times
 248 before rotating to the next.
 249 Fourth and fifth arg START and END specify the region to operate on."
 250   (interactive
 251    (let (from to)
 252      (setq from (if query-replace-interactive
 253                     (car regexp-search-ring)
 254                   (read-from-minibuffer "Map query replace (regexp): "
 255                                         nil nil nil
 256                                         'query-replace-history nil t)))
 257      (setq to (read-from-minibuffer
 258                (format "Query replace %s with (space-separated strings): "
 259                        from)
 260                nil nil nil
 261                'query-replace-history from t))
 262      (list from to
 263            (and current-prefix-arg
 264                 (prefix-numeric-value current-prefix-arg))
 265            (if (and transient-mark-mode mark-active)
 266                (region-beginning))
 267            (if (and transient-mark-mode mark-active)
 268                (region-end)))))
 269   (let (replacements)
 270     (if (listp to-strings)
 271         (setq replacements to-strings)
 272       (while (/= (length to-strings) 0)
 273         (if (string-match " " to-strings)
 274             (setq replacements
 275                   (append replacements
 276                           (list (substring to-strings 0
 277                                            (string-match " " to-strings))))
 278                   to-strings (substring to-strings
 279                                        (1+ (string-match " " to-strings))))
 280           (setq replacements (append replacements (list to-strings))
 281                 to-strings ""))))
 282     (perform-replace regexp replacements t t nil n nil start end)))
 283
 284 (defun replace-string (from-string to-string &optional delimited start end)
 285   "Replace occurrences of FROM-STRING with TO-STRING.
 286 Preserve case in each match if `case-replace' and `case-fold-search'
 287 are non-nil and FROM-STRING has no uppercase letters.
 288 \(Preserving case means that if the string matched is all caps, or capitalized,
 289 then its replacement is upcased or capitalized.)
 290
 291 In Transient Mark mode, if the mark is active, operate on the contents
 292 of the region.  Otherwise, operate from point to the end of the buffer.
 293
 294 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 295 only matches surrounded by word boundaries.
 296 Fourth and fifth arg START and END specify the region to operate on.
 297
 298 If `query-replace-interactive' is non-nil, the last incremental search
 299 string is used as FROM-STRING--you don't have to specify it with the
 300 minibuffer.
 301
 302 This function is usually the wrong thing to use in a Lisp program.
 303 What you probably want is a loop like this:
 304   (while (search-forward FROM-STRING nil t)
 305     (replace-match TO-STRING nil t))
 306 which will run faster and will not set the mark or print anything.
 307 \(You may need a more complex loop if FROM-STRING can match the null string
 308 and TO-STRING is also null.)"
 309   (interactive
 310    (let ((common
 311           (query-replace-read-args "Replace string" nil)))
 312      (list (nth 0 common) (nth 1 common) (nth 2 common)
 313            (if (and transient-mark-mode mark-active)
 314                (region-beginning))
 315            (if (and transient-mark-mode mark-active)
 316                (region-end)))))
 317   (perform-replace from-string to-string nil nil delimited nil nil start end))
 318
 319 (defun replace-regexp (regexp to-string &optional delimited start end)
 320   "Replace things after point matching REGEXP with TO-STRING.
 321 Preserve case in each match if `case-replace' and `case-fold-search'
 322 are non-nil and REGEXP has no uppercase letters.
 323
 324 In Transient Mark mode, if the mark is active, operate on the contents
 325 of the region.  Otherwise, operate from point to the end of the buffer.
 326
 327 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 328 only matches surrounded by word boundaries.
 329 Fourth and fifth arg START and END specify the region to operate on.
 330
 331 In TO-STRING, `\\&' stands for whatever matched the whole of REGEXP,
 332 and `\\=\\N' (where N is a digit) stands for
 333  whatever what matched the Nth `\\(...\\)' in REGEXP.
 334
 335 If `query-replace-interactive' is non-nil, the last incremental search
 336 regexp is used as REGEXP--you don't have to specify it with the minibuffer.
 337
 338 This function is usually the wrong thing to use in a Lisp program.
 339 What you probably want is a loop like this:
 340   (while (re-search-forward REGEXP nil t)
 341     (replace-match TO-STRING nil nil))
 342 which will run faster and will not set the mark or print anything."
 343   (interactive
 344    (let ((common
 345           (query-replace-read-args "Replace regexp" t)))
 346      (list (nth 0 common) (nth 1 common) (nth 2 common)
 347            (if (and transient-mark-mode mark-active)
 348                (region-beginning))
 349            (if (and transient-mark-mode mark-active)
 350                (region-end)))))
 351   (perform-replace regexp to-string nil t delimited nil nil start end))
 352
 353 \f
 354 (defvar regexp-history nil
 355   "History list for some commands that read regular expressions.")
 356
 357
 358 (defalias 'delete-non-matching-lines 'keep-lines)
 359 (defalias 'delete-matching-lines 'flush-lines)
 360 (defalias 'count-matches 'how-many)
 361
 362
 363 (defun keep-lines-read-args (prompt)
 364   "Read arguments for `keep-lines' and friends.
 365 Prompt for a regexp with PROMPT.
 366 Value is a list, (REGEXP)."
 367   (list (read-from-minibuffer prompt nil nil nil
 368                               'regexp-history nil t)))
 369
 370 (defun keep-lines (regexp &optional rstart rend)
 371   "Delete all lines except those containing matches for REGEXP.
 372 A match split across lines preserves all the lines it lies in.
 373 Applies to all lines after point.
 374
 375 If REGEXP contains upper case characters (excluding those preceded by `\\'),
 376 the matching is case-sensitive.
 377
 378 Second and third arg RSTART and REND specify the region to operate on.
 379
 380 Interactively, in Transient Mark mode when the mark is active, operate
 381 on the contents of the region.  Otherwise, operate from point to the
 382 end of the buffer."
 383
 384   (interactive
 385    (progn
 386      (barf-if-buffer-read-only)
 387      (keep-lines-read-args "Keep lines (containing match for regexp): ")))
 388   (if rstart
 389       (progn
 390         (goto-char (min rstart rend))
 391         (setq rend (copy-marker (max rstart rend))))
 392     (if (and transient-mark-mode mark-active)
 393         (setq rstart (region-beginning)
 394               rend (copy-marker (region-end)))
 395       (setq rstart (point)
 396             rend (point-max-marker)))
 397     (goto-char rstart))
 398   (save-excursion
 399     (or (bolp) (forward-line 1))
 400     (let ((start (point))
 401           (case-fold-search  (and case-fold-search
 402                                   (isearch-no-upper-case-p regexp t))))
 403       (while (< (point) rend)
 404         ;; Start is first char not preserved by previous match.
 405         (if (not (re-search-forward regexp rend 'move))
 406             (delete-region start rend)
 407           (let ((end (save-excursion (goto-char (match-beginning 0))
 408                                      (beginning-of-line)
 409                                      (point))))
 410             ;; Now end is first char preserved by the new match.
 411             (if (< start end)
 412                 (delete-region start end))))
 413
 414         (setq start (save-excursion (forward-line 1) (point)))
 415         ;; If the match was empty, avoid matching again at same place.
 416         (and (< (point) rend)
 417              (= (match-beginning 0) (match-end 0))
 418              (forward-char 1))))))
 419
 420
 421 (defun flush-lines (regexp &optional rstart rend)
 422   "Delete lines containing matches for REGEXP.
 423 If a match is split across lines, all the lines it lies in are deleted.
 424 Applies to lines after point.
 425
 426 If REGEXP contains upper case characters (excluding those preceded by `\\'),
 427 the matching is case-sensitive.
 428
 429 Second and third arg RSTART and REND specify the region to operate on.
 430
 431 Interactively, in Transient Mark mode when the mark is active, operate
 432 on the contents of the region.  Otherwise, operate from point to the
 433 end of the buffer."
 434
 435   (interactive
 436    (progn
 437      (barf-if-buffer-read-only)
 438      (keep-lines-read-args "Flush lines (containing match for regexp): ")))
 439   (if rstart
 440       (progn
 441         (goto-char (min rstart rend))
 442         (setq rend (copy-marker (max rstart rend))))
 443     (if (and transient-mark-mode mark-active)
 444         (setq rstart (region-beginning)
 445               rend (copy-marker (region-end)))
 446       (setq rstart (point)
 447             rend (point-max-marker)))
 448     (goto-char rstart))
 449   (let ((case-fold-search (and case-fold-search
 450                                (isearch-no-upper-case-p regexp t))))
 451     (save-excursion
 452       (while (and (< (point) rend)
 453                   (re-search-forward regexp rend t))
 454         (delete-region (save-excursion (goto-char (match-beginning 0))
 455                                        (beginning-of-line)
 456                                        (point))
 457                        (progn (forward-line 1) (point)))))))
 458
 459
 460 (defun how-many (regexp &optional rstart rend)
 461   "Print number of matches for REGEXP following point.
 462
 463 If REGEXP contains upper case characters (excluding those preceded by `\\'),
 464 the matching is case-sensitive.
 465
 466 Second and third arg RSTART and REND specify the region to operate on.
 467
 468 Interactively, in Transient Mark mode when the mark is active, operate
 469 on the contents of the region.  Otherwise, operate from point to the
 470 end of the buffer."
 471
 472   (interactive
 473    (keep-lines-read-args "How many matches for (regexp): "))
 474   (save-excursion
 475     (if rstart
 476         (goto-char (min rstart rend))
 477       (if (and transient-mark-mode mark-active)
 478           (setq rstart (region-beginning)
 479                 rend (copy-marker (region-end)))
 480         (setq rstart (point)
 481               rend (point-max-marker)))
 482       (goto-char rstart))
 483     (let ((count 0)
 484           opoint
 485           (case-fold-search (and case-fold-search
 486                                  (isearch-no-upper-case-p regexp t))))
 487       (while (and (< (point) rend)
 488                   (progn (setq opoint (point))
 489                          (re-search-forward regexp rend t)))
 490         (if (= opoint (point))
 491             (forward-char 1)
 492           (setq count (1+ count))))
 493       (message "%d occurrences" count))))
 494
 495 \f
 496 (defvar occur-mode-map
 497   (let ((map (make-sparse-keymap)))
 498     (define-key map [mouse-2] 'occur-mode-mouse-goto)
 499     (define-key map "\C-c\C-c" 'occur-mode-goto-occurrence)
 500     (define-key map "\C-m" 'occur-mode-goto-occurrence)
 501     (define-key map "o" 'occur-mode-goto-occurrence-other-window)
 502     (define-key map "\C-o" 'occur-mode-display-occurrence)
 503     (define-key map "\M-n" 'occur-next)
 504     (define-key map "\M-p" 'occur-prev)
 505     (define-key map "r" 'occur-rename-buffer)
 506     (define-key map "c" 'clone-buffer)
 507     (define-key map "g" 'revert-buffer)
 508     (define-key map "q" 'quit-window)
 509     (define-key map "z" 'kill-this-buffer)
 510     map)
 511   "Keymap for `occur-mode'.")
 512
 513 (defvar occur-revert-arguments nil
 514   "Arguments to pass to `occur-1' to revert an Occur mode buffer.
 515 See `occur-revert-function'.")
 516
 517 (defcustom occur-mode-hook '(turn-on-font-lock)
 518   "Hook run when entering Occur mode."
 519   :type 'hook
 520   :group 'matching)
 521
 522 (defcustom occur-hook nil
 523   "Hook run when `occur' is called."
 524   :type 'hook
 525   :group 'matching)
 526
 527 (put 'occur-mode 'mode-class 'special)
 528 (defun occur-mode ()
 529   "Major mode for output from \\[occur].
 530 \\<occur-mode-map>Move point to one of the items in this buffer, then use
 531 \\[occur-mode-goto-occurrence] to go to the occurrence that the item refers to.
 532 Alternatively, click \\[occur-mode-mouse-goto] on an item to go to it.
 533
 534 \\{occur-mode-map}"
 535   (interactive)
 536   (kill-all-local-variables)
 537   (use-local-map occur-mode-map)
 538   (setq major-mode 'occur-mode)
 539   (setq mode-name "Occur")
 540   (set (make-local-variable 'revert-buffer-function) 'occur-revert-function)
 541   (make-local-variable 'occur-revert-arguments)
 542   (add-hook 'change-major-mode-hook 'font-lock-defontify nil t)
 543   (setq next-error-function 'occur-next-error)
 544   (run-hooks 'occur-mode-hook))
 545
 546 (defun occur-revert-function (ignore1 ignore2)
 547   "Handle `revert-buffer' for Occur mode buffers."
 548   (apply 'occur-1 (append occur-revert-arguments (list (buffer-name)))))
 549
 550 (defun occur-mode-mouse-goto (event)
 551   "In Occur mode, go to the occurrence whose line you click on."
 552   (interactive "e")
 553   (let (pos)
 554     (save-excursion
 555       (set-buffer (window-buffer (posn-window (event-end event))))
 556       (save-excursion
 557         (goto-char (posn-point (event-end event)))
 558         (setq pos (occur-mode-find-occurrence))))
 559     (pop-to-buffer (marker-buffer pos))
 560     (goto-char pos)))
 561
 562 (defun occur-mode-find-occurrence ()
 563   (let ((pos (get-text-property (point) 'occur-target)))
 564     (unless pos
 565       (error "No occurrence on this line"))
 566     (unless (buffer-live-p (marker-buffer pos))
 567       (error "Buffer for this occurrence was killed"))
 568     pos))
 569
 570 (defun occur-mode-goto-occurrence ()
 571   "Go to the occurrence the current line describes."
 572   (interactive)
 573   (let ((pos (occur-mode-find-occurrence)))
 574     (pop-to-buffer (marker-buffer pos))
 575     (goto-char pos)))
 576
 577 (defun occur-mode-goto-occurrence-other-window ()
 578   "Go to the occurrence the current line describes, in another window."
 579   (interactive)
 580   (let ((pos (occur-mode-find-occurrence)))
 581     (switch-to-buffer-other-window (marker-buffer pos))
 582     (goto-char pos)))
 583
 584 (defun occur-mode-display-occurrence ()
 585   "Display in another window the occurrence the current line describes."
 586   (interactive)
 587   (let ((pos (occur-mode-find-occurrence))
 588         window
 589         ;; Bind these to ensure `display-buffer' puts it in another window.
 590         same-window-buffer-names
 591         same-window-regexps)
 592     (setq window (display-buffer (marker-buffer pos)))
 593     ;; This is the way to set point in the proper window.
 594     (save-selected-window
 595       (select-window window)
 596       (goto-char pos))))
 597
 598 (defun occur-find-match (n search message)
 599   (if (not n) (setq n 1))
 600   (let ((r))
 601     (while (> n 0)
 602       (setq r (funcall search (point) 'occur-match))
 603       (and r
 604            (get-text-property r 'occur-match)
 605            (setq r (funcall search r 'occur-match)))
 606       (if r
 607           (goto-char r)
 608         (error message))
 609       (setq n (1- n)))))
 610
 611 (defun occur-next (&optional n)
 612   "Move to the Nth (default 1) next match in an Occur mode buffer."
 613   (interactive "p")
 614   (occur-find-match n #'next-single-property-change "No more matches"))
 615
 616 (defun occur-prev (&optional n)
 617   "Move to the Nth (default 1) previous match in an Occur mode buffer."
 618   (interactive "p")
 619   (occur-find-match n #'previous-single-property-change "No earlier matches"))
 620
 621 (defun occur-next-error (&optional argp reset)
 622   "Move to the Nth (default 1) next match in an Occur mode buffer.
 623 Compatibility function for \\[next-error] invocations."
 624   (interactive "p")
 625   (when reset
 626     (occur-find-match 0 #'next-single-property-change "No first match"))
 627   (occur-find-match
 628    (prefix-numeric-value argp)
 629    (if (> 0 (prefix-numeric-value argp))
 630        #'previous-single-property-change
 631      #'next-single-property-change)
 632    "No more matches")
 633   (occur-mode-goto-occurrence))
 634
 635 \f
 636 (defcustom list-matching-lines-default-context-lines 0
 637   "*Default number of context lines included around `list-matching-lines' matches.
 638 A negative number means to include that many lines before the match.
 639 A positive number means to include that many lines both before and after."
 640   :type 'integer
 641   :group 'matching)
 642
 643 (defalias 'list-matching-lines 'occur)
 644
 645 (defcustom list-matching-lines-face 'bold
 646   "*Face used by \\[list-matching-lines] to show the text that matches.
 647 If the value is nil, don't highlight the matching portions specially."
 648   :type 'face
 649   :group 'matching)
 650
 651 (defcustom list-matching-lines-buffer-name-face 'underline
 652   "*Face used by \\[list-matching-lines] to show the names of buffers.
 653 If the value is nil, don't highlight the buffer names specially."
 654   :type 'face
 655   :group 'matching)
 656
 657 (defun occur-accumulate-lines (count &optional no-props)
 658   (save-excursion
 659     (let ((forwardp (> count 0))
 660           (result nil))
 661       (while (not (or (zerop count)
 662                       (if forwardp
 663                           (eobp)
 664                         (bobp))))
 665         (setq count (+ count (if forwardp -1 1)))
 666         (push
 667          (funcall (if no-props
 668                       #'buffer-substring-no-properties
 669                     #'buffer-substring)
 670           (line-beginning-position)
 671           (line-end-position))
 672          result)
 673         (forward-line (if forwardp 1 -1)))
 674       (nreverse result))))
 675
 676 (defun occur-read-primary-args ()
 677   (list (let* ((default (car regexp-history))
 678                (input
 679                 (read-from-minibuffer
 680                  (if default
 681                      (format "List lines matching regexp (default `%s'): "
 682                              default)
 683                    "List lines matching regexp: ")
 684                  nil
 685                  nil
 686                  nil
 687                  'regexp-history)))
 688           (if (equal input "")
 689               default
 690             input))
 691         (when current-prefix-arg
 692           (prefix-numeric-value current-prefix-arg))))
 693
 694 (defun occur-rename-buffer (&optional unique-p)
 695   "Rename the current *Occur* buffer to *Occur: original-buffer-name*.
 696 Here `original-buffer-name' is the buffer name were occur was originally run.
 697 When given the prefix argument, the renaming will not clobber the existing
 698 buffer(s) of that name, but use `generate-new-buffer-name' instead.
 699 You can add this to `occur-hook' if you always want a separate *Occur*
 700 buffer for each buffer where you invoke `occur'."
 701   (interactive "P")
 702   (with-current-buffer
 703       (if (eq major-mode 'occur-mode) (current-buffer) (get-buffer "*Occur*"))
 704     (rename-buffer (concat "*Occur: "
 705                            (mapconcat #'buffer-name
 706                                       (car (cddr occur-revert-arguments)) "/")
 707                            "*")
 708                    unique-p)))
 709
 710 (defun occur (regexp &optional nlines)
 711   "Show all lines in the current buffer containing a match for REGEXP.
 712
 713 If a match spreads across multiple lines, all those lines are shown.
 714
 715 Each line is displayed with NLINES lines before and after, or -NLINES
 716 before if NLINES is negative.
 717 NLINES defaults to `list-matching-lines-default-context-lines'.
 718 Interactively it is the prefix arg.
 719
 720 The lines are shown in a buffer named `*Occur*'.
 721 It serves as a menu to find any of the occurrences in this buffer.
 722 \\<occur-mode-map>\\[describe-mode] in that buffer will explain how.
 723
 724 If REGEXP contains upper case characters (excluding those preceded by `\\'),
 725 the matching is case-sensitive."
 726   (interactive (occur-read-primary-args))
 727   (occur-1 regexp nlines (list (current-buffer))))
 728
 729 (defun multi-occur (bufs regexp &optional nlines)
 730   "Show all lines in buffers BUFS containing a match for REGEXP.
 731 This function acts on multiple buffers; otherwise, it is exactly like
 732 `occur'."
 733   (interactive
 734    (cons
 735     (let* ((bufs (list (read-buffer "First buffer to search: "
 736                                     (current-buffer) t)))
 737            (buf nil)
 738            (ido-ignore-item-temp-list bufs))
 739       (while (not (string-equal
 740                    (setq buf (read-buffer
 741                               (if (eq read-buffer-function 'ido-read-buffer)
 742                                   "Next buffer to search (C-j to end): "
 743                                 "Next buffer to search (RET to end): ")
 744                               nil t))
 745                    ""))
 746         (add-to-list 'bufs buf)
 747         (setq ido-ignore-item-temp-list bufs))
 748       (nreverse (mapcar #'get-buffer bufs)))
 749     (occur-read-primary-args)))
 750   (occur-1 regexp nlines bufs))
 751
 752 (defun multi-occur-by-filename-regexp (bufregexp regexp &optional nlines)
 753   "Show all lines matching REGEXP in buffers named by BUFREGEXP.
 754 See also `multi-occur'."
 755   (interactive
 756    (cons
 757     (let* ((default (car regexp-history))
 758            (input
 759             (read-from-minibuffer
 760              "List lines in buffers whose filename matches regexp: "
 761              nil
 762              nil
 763              nil
 764              'regexp-history)))
 765       (if (equal input "")
 766           default
 767         input))
 768     (occur-read-primary-args)))
 769   (when bufregexp
 770     (occur-1 regexp nlines
 771              (delq nil
 772                    (mapcar (lambda (buf)
 773                              (when (and (buffer-file-name buf)
 774                                         (string-match bufregexp
 775                                                       (buffer-file-name buf)))
 776                                buf))
 777                            (buffer-list))))))
 778
 779 (defun occur-1 (regexp nlines bufs &optional buf-name)
 780   (unless buf-name
 781     (setq buf-name "*Occur*"))
 782   (let ((occur-buf (get-buffer-create buf-name))
 783         (made-temp-buf nil)
 784         (active-bufs (delq nil (mapcar #'(lambda (buf)
 785                                            (when (buffer-live-p buf) buf))
 786                                        bufs))))
 787     ;; Handle the case where one of the buffers we're searching is the
 788     ;; *Occur* buffer itself.
 789     (when (memq occur-buf bufs)
 790       (setq occur-buf (with-current-buffer occur-buf
 791                         (clone-buffer "*Occur-temp*"))
 792             made-temp-buf t))
 793     (with-current-buffer occur-buf
 794       (setq buffer-read-only nil)
 795       (occur-mode)
 796       (erase-buffer)
 797       (let ((count (occur-engine
 798                     regexp active-bufs occur-buf
 799                     (or nlines list-matching-lines-default-context-lines)
 800                     (and case-fold-search
 801                          (isearch-no-upper-case-p regexp t))
 802                     list-matching-lines-buffer-name-face
 803                     nil list-matching-lines-face nil)))
 804         (let* ((bufcount (length active-bufs))
 805                (diff (- (length bufs) bufcount)))
 806           (message "Searched %d buffer%s%s; %s match%s for `%s'"
 807                    bufcount (if (= bufcount 1) "" "s")
 808                    (if (zerop diff) "" (format " (%d killed)" diff))
 809                    (if (zerop count) "no" (format "%d" count))
 810                    (if (= count 1) "" "es")
 811                    regexp))
 812         ;; If we had to make a temporary buffer, make it the *Occur*
 813         ;; buffer now.
 814         (when made-temp-buf
 815           (with-current-buffer (get-buffer buf-name)
 816             (kill-buffer (current-buffer)))
 817           (rename-buffer buf-name))
 818         (setq occur-revert-arguments (list regexp nlines bufs)
 819               buffer-read-only t)
 820         (if (> count 0)
 821             (progn
 822               (display-buffer occur-buf)
 823               (setq next-error-last-buffer occur-buf))
 824           (kill-buffer occur-buf)))
 825       (run-hooks 'occur-hook))))
 826
 827 (defun occur-engine-add-prefix (lines)
 828   (mapcar
 829    #'(lambda (line)
 830        (concat "       :" line "\n"))
 831    lines))
 832
 833 (defun occur-engine (regexp buffers out-buf nlines case-fold-search
 834                             title-face prefix-face match-face keep-props)
 835   (with-current-buffer out-buf
 836     (setq buffer-read-only nil)
 837     (let ((globalcount 0)
 838           (coding nil))
 839       ;; Map over all the buffers
 840       (dolist (buf buffers)
 841         (when (buffer-live-p buf)
 842           (let ((matches 0)     ;; count of matched lines
 843                 (lines 1)       ;; line count
 844                 (matchbeg 0)
 845                 (matchend 0)
 846                 (origpt nil)
 847                 (begpt nil)
 848                 (endpt nil)
 849                 (marker nil)
 850                 (curstring "")
 851                 (headerpt (with-current-buffer out-buf (point))))
 852             (save-excursion
 853               (set-buffer buf)
 854               (or coding
 855                   ;; Set CODING only if the current buffer locally
 856                   ;; binds buffer-file-coding-system.
 857                   (not (local-variable-p 'buffer-file-coding-system))
 858                   (setq coding buffer-file-coding-system))
 859               (save-excursion
 860                 (goto-char (point-min)) ;; begin searching in the buffer
 861                 (while (not (eobp))
 862                   (setq origpt (point))
 863                   (when (setq endpt (re-search-forward regexp nil t))
 864                     (setq matches (1+ matches)) ;; increment match count
 865                     (setq matchbeg (match-beginning 0)
 866                           matchend (match-end 0))
 867                     (setq begpt (save-excursion
 868                                   (goto-char matchbeg)
 869                                   (line-beginning-position)))
 870                     (setq lines (+ lines (1- (count-lines origpt endpt))))
 871                     (setq marker (make-marker))
 872                     (set-marker marker matchbeg)
 873                     (setq curstring (buffer-substring begpt
 874                                                       (line-end-position)))
 875                     ;; Depropertize the string, and maybe
 876                     ;; highlight the matches
 877                     (let ((len (length curstring))
 878                           (start 0))
 879                       (unless keep-props
 880                         (set-text-properties 0 len nil curstring))
 881                       (while (and (< start len)
 882                                   (string-match regexp curstring start))
 883                         (add-text-properties (match-beginning 0)
 884                                              (match-end 0)
 885                                              (append
 886                                               `(occur-match t)
 887                                               (when match-face
 888                                                 `(font-lock-face ,match-face)))
 889                                              curstring)
 890                         (setq start (match-end 0))))
 891                     ;; Generate the string to insert for this match
 892                     (let* ((out-line
 893                             (concat
 894                              ;; Using 7 digits aligns tabs properly.
 895                              (apply #'propertize (format "%7d:" lines)
 896                                     (append
 897                                      (when prefix-face
 898                                        `(font-lock-face prefix-face))
 899                                      '(occur-prefix t)))
 900                              curstring
 901                              "\n"))
 902                            (data
 903                             (if (= nlines 0)
 904                                 ;; The simple display style
 905                                 out-line
 906                               ;; The complex multi-line display
 907                               ;; style.  Generate a list of lines,
 908                               ;; concatenate them all together.
 909                               (apply #'concat
 910                                      (nconc
 911                                       (occur-engine-add-prefix (nreverse (cdr (occur-accumulate-lines (- (1+ nlines)) keep-props))))
 912                                       (list out-line)
 913                                       (occur-engine-add-prefix (cdr (occur-accumulate-lines (1+ nlines) keep-props))))))))
 914                       ;; Actually insert the match display data
 915                       (with-current-buffer out-buf
 916                         (let ((beg (point))
 917                               (end (progn (insert data) (point))))
 918                           (unless (= nlines 0)
 919                             (insert "-------\n"))
 920                           (add-text-properties
 921                            beg end
 922                            `(occur-target ,marker help-echo "mouse-2: go to this occurrence"))
 923                           ;; We don't put `mouse-face' on the newline,
 924                           ;; because that loses.
 925                           (add-text-properties beg (1- end) '(mouse-face highlight)))))
 926                     (goto-char endpt))
 927                   (if endpt
 928                       (progn
 929                         (setq lines (1+ lines))
 930                         ;; On to the next match...
 931                         (forward-line 1))
 932                     (goto-char (point-max))))))
 933             (when (not (zerop matches)) ;; is the count zero?
 934               (setq globalcount (+ globalcount matches))
 935               (with-current-buffer out-buf
 936                 (goto-char headerpt)
 937                 (let ((beg (point))
 938                       end)
 939                   (insert (format "%d match%s for \"%s\" in buffer: %s\n"
 940                                   matches (if (= matches 1) "" "es")
 941                                   regexp (buffer-name buf)))
 942                   (setq end (point))
 943                   (add-text-properties beg end
 944                                        (append
 945                                         (when title-face
 946                                           `(font-lock-face ,title-face))
 947                                         `(occur-title ,buf))))
 948                 (goto-char (point-min)))))))
 949       (if coding
 950           ;; CODING is buffer-file-coding-system of the first buffer
 951           ;; that locally binds it.  Let's use it also for the output
 952           ;; buffer.
 953           (set-buffer-file-coding-system coding))
 954       ;; Return the number of matches
 955       globalcount)))
 956
 957 \f
 958 ;; It would be nice to use \\[...], but there is no reasonable way
 959 ;; to make that display both SPC and Y.
 960 (defconst query-replace-help
 961   "Type Space or `y' to replace one match, Delete or `n' to skip to next,
 962 RET or `q' to exit, Period to replace one match and exit,
 963 Comma to replace but not move point immediately,
 964 C-r to enter recursive edit (\\[exit-recursive-edit] to get out again),
 965 C-w to delete match and recursive edit,
 966 C-l to clear the screen, redisplay, and offer same replacement again,
 967 ! to replace all remaining matches with no more questions,
 968 ^ to move point back to previous match,
 969 E to edit the replacement string"
 970   "Help message while in `query-replace'.")
 971
 972 (defvar query-replace-map (make-sparse-keymap)
 973   "Keymap that defines the responses to questions in `query-replace'.
 974 The \"bindings\" in this map are not commands; they are answers.
 975 The valid answers include `act', `skip', `act-and-show',
 976 `exit', `act-and-exit', `edit', `delete-and-edit', `recenter',
 977 `automatic', `backup', `exit-prefix', and `help'.")
 978
 979 (define-key query-replace-map " " 'act)
 980 (define-key query-replace-map "\d" 'skip)
 981 (define-key query-replace-map [delete] 'skip)
 982 (define-key query-replace-map [backspace] 'skip)
 983 (define-key query-replace-map "y" 'act)
 984 (define-key query-replace-map "n" 'skip)
 985 (define-key query-replace-map "Y" 'act)
 986 (define-key query-replace-map "N" 'skip)
 987 (define-key query-replace-map "e" 'edit-replacement)
 988 (define-key query-replace-map "E" 'edit-replacement)
 989 (define-key query-replace-map "," 'act-and-show)
 990 (define-key query-replace-map "q" 'exit)
 991 (define-key query-replace-map "\r" 'exit)
 992 (define-key query-replace-map [return] 'exit)
 993 (define-key query-replace-map "." 'act-and-exit)
 994 (define-key query-replace-map "\C-r" 'edit)
 995 (define-key query-replace-map "\C-w" 'delete-and-edit)
 996 (define-key query-replace-map "\C-l" 'recenter)
 997 (define-key query-replace-map "!" 'automatic)
 998 (define-key query-replace-map "^" 'backup)
 999 (define-key query-replace-map "\C-h" 'help)
1000 (define-key query-replace-map [f1] 'help)
1001 (define-key query-replace-map [help] 'help)
1002 (define-key query-replace-map "?" 'help)
1003 (define-key query-replace-map "\C-g" 'quit)
1004 (define-key query-replace-map "\C-]" 'quit)
1005 (define-key query-replace-map "\e" 'exit-prefix)
1006 (define-key query-replace-map [escape] 'exit-prefix)
1007
1008 (defun replace-match-string-symbols (n)
1009   "Process a list (and any sub-lists), expanding certain symbols.
1010 Symbol  Expands To
1011 N     (match-string N)           (where N is a string of digits)
1012 #N    (string-to-number (match-string N))
1013 &     (match-string 0)
1014 #&    (string-to-number (match-string 0))
1015
1016 Note that these symbols must be preceeded by a backslash in order to
1017 type them."
1018   (while n
1019     (cond
1020      ((consp (car n))
1021       (replace-match-string-symbols (car n))) ;Process sub-list
1022      ((symbolp (car n))
1023       (let ((name (symbol-name (car n))))
1024         (cond
1025          ((string-match "^[0-9]+$" name)
1026           (setcar n (list 'match-string (string-to-number name))))
1027          ((string-match "^#[0-9]+$" name)
1028           (setcar n (list 'string-to-number
1029                           (list 'match-string
1030                                 (string-to-number (substring name 1))))))
1031          ((string= "&" name)
1032           (setcar n '(match-string 0)))
1033          ((string= "#&" name)
1034           (setcar n '(string-to-number (match-string 0))))))))
1035     (setq n (cdr n))))
1036
1037 (defun replace-eval-replacement (expression replace-count)
1038   (let ((replacement (eval expression)))
1039     (if (stringp replacement)
1040         replacement
1041       (prin1-to-string replacement t))))
1042
1043 (defun replace-loop-through-replacements (data replace-count)
1044   ;; DATA is a vector contaning the following values:
1045   ;;   0 next-rotate-count
1046   ;;   1 repeat-count
1047   ;;   2 next-replacement
1048   ;;   3 replacements
1049   (if (= (aref data 0) replace-count)
1050       (progn
1051         (aset data 0 (+ replace-count (aref data 1)))
1052         (let ((next (cdr (aref data 2))))
1053           (aset data 2 (if (consp next) next (aref data 3))))))
1054   (car (aref data 2)))
1055
1056 (defun perform-replace (from-string replacements
1057                         query-flag regexp-flag delimited-flag
1058                         &optional repeat-count map start end)
1059   "Subroutine of `query-replace'.  Its complexity handles interactive queries.
1060 Don't use this in your own program unless you want to query and set the mark
1061 just as `query-replace' does.  Instead, write a simple loop like this:
1062
1063   (while (re-search-forward \"foo[ \\t]+bar\" nil t)
1064     (replace-match \"foobar\" nil nil))
1065
1066 which will run faster and probably do exactly what you want.  Please
1067 see the documentation of `replace-match' to find out how to simulate
1068 `case-replace'.
1069
1070 This function returns nil if and only if there were no matches to
1071 make, or the user didn't cancel the call."
1072   (or map (setq map query-replace-map))
1073   (and query-flag minibuffer-auto-raise
1074        (raise-frame (window-frame (minibuffer-window))))
1075   (let ((nocasify (not (and case-fold-search case-replace
1076                             (string-equal from-string
1077                                           (downcase from-string)))))
1078         (case-fold-search (and case-fold-search
1079                                (string-equal from-string
1080                                              (downcase from-string))))
1081         (literal (or (not regexp-flag) (eq regexp-flag 'literal)))
1082         (search-function (if regexp-flag 're-search-forward 'search-forward))
1083         (search-string from-string)
1084         (real-match-data nil)           ; the match data for the current match
1085         (next-replacement nil)
1086         (keep-going t)
1087         (stack nil)
1088         (replace-count 0)
1089         (nonempty-match nil)
1090
1091         ;; If non-nil, it is marker saying where in the buffer to stop.
1092         (limit nil)
1093
1094         ;; Data for the next match.  If a cons, it has the same format as
1095         ;; (match-data); otherwise it is t if a match is possible at point.
1096         (match-again t)
1097
1098         (message
1099          (if query-flag
1100              (substitute-command-keys
1101               "Query replacing %s with %s: (\\<query-replace-map>\\[help] for help) "))))
1102
1103     ;; If region is active, in Transient Mark mode, operate on region.
1104     (when start
1105       (setq limit (copy-marker (max start end)))
1106       (goto-char (min start end))
1107       (deactivate-mark))
1108
1109     ;; REPLACEMENTS is either a string, a list of strings, or a cons cell
1110     ;; containing a function and its first argument.  The function is
1111     ;; called to generate each replacement like this:
1112     ;;   (funcall (car replacements) (cdr replacements) replace-count)
1113     ;; It must return a string.
1114     (cond
1115      ((stringp replacements)
1116       (setq next-replacement replacements
1117             replacements     nil))
1118      ((stringp (car replacements)) ; If it isn't a string, it must be a cons
1119       (or repeat-count (setq repeat-count 1))
1120       (setq replacements (cons 'replace-loop-through-replacements
1121                                (vector repeat-count repeat-count
1122                                        replacements replacements)))))
1123
1124     (if delimited-flag
1125         (setq search-function 're-search-forward
1126               search-string (concat "\\b"
1127                                     (if regexp-flag from-string
1128                                       (regexp-quote from-string))
1129                                     "\\b")))
1130     (push-mark)
1131     (undo-boundary)
1132     (unwind-protect
1133         ;; Loop finding occurrences that perhaps should be replaced.
1134         (while (and keep-going
1135                     (not (eobp))
1136                     ;; Use the next match if it is already known;
1137                     ;; otherwise, search for a match after moving forward
1138                     ;; one char if progress is required.
1139                     (setq real-match-data
1140                           (if (consp match-again)
1141                               (progn (goto-char (nth 1 match-again))
1142                                      match-again)
1143                             (and (or match-again
1144                                      ;; MATCH-AGAIN non-nil means we
1145                                      ;; accept an adjacent match.  If
1146                                      ;; we don't, move one char to the
1147                                      ;; right.  This takes us a
1148                                      ;; character too far at the end,
1149                                      ;; but this is undone after the
1150                                      ;; while-loop.
1151                                      (progn (forward-char 1) (not (eobp))))
1152                                  (funcall search-function search-string limit t)
1153                                  ;; For speed, use only integers and
1154                                  ;; reuse the list used last time.
1155                                  (match-data t real-match-data)))))
1156           ;; Optionally ignore matches that have a read-only property.
1157           (unless (and query-replace-skip-read-only
1158                        (text-property-not-all
1159                         (match-beginning 0) (match-end 0)
1160                         'read-only nil))
1161
1162             ;; Record whether the match is nonempty, to avoid an infinite loop
1163             ;; repeatedly matching the same empty string.
1164             (setq nonempty-match
1165                   (/= (nth 0 real-match-data) (nth 1 real-match-data)))
1166
1167             ;; If the match is empty, record that the next one can't be
1168             ;; adjacent.
1169
1170             ;; Otherwise, if matching a regular expression, do the next
1171             ;; match now, since the replacement for this match may
1172             ;; affect whether the next match is adjacent to this one.
1173             ;; If that match is empty, don't use it.
1174             (setq match-again
1175                   (and nonempty-match
1176                        (or (not regexp-flag)
1177                            (and (looking-at search-string)
1178                                 (let ((match (match-data)))
1179                                   (and (/= (nth 0 match) (nth 1 match))
1180                                        match))))))
1181
1182             ;; Calculate the replacement string, if necessary.
1183             (when replacements
1184               (set-match-data real-match-data)
1185               (setq next-replacement
1186                     (funcall (car replacements) (cdr replacements)
1187                              replace-count)))
1188             (if (not query-flag)
1189                 (let ((inhibit-read-only query-replace-skip-read-only))
1190                   (set-match-data real-match-data)
1191                   (replace-match next-replacement nocasify literal)
1192                   (setq replace-count (1+ replace-count)))
1193               (undo-boundary)
1194               (let (done replaced key def)
1195                 ;; Loop reading commands until one of them sets done,
1196                 ;; which means it has finished handling this occurrence.
1197                 (while (not done)
1198                   (set-match-data real-match-data)
1199                   (replace-highlight (match-beginning 0) (match-end 0))
1200                   ;; Bind message-log-max so we don't fill up the message log
1201                   ;; with a bunch of identical messages.
1202                   (let ((message-log-max nil))
1203                     (message message from-string next-replacement))
1204                   (setq key (read-event))
1205                   ;; Necessary in case something happens during read-event
1206                   ;; that clobbers the match data.
1207                   (set-match-data real-match-data)
1208                   (setq key (vector key))
1209                   (setq def (lookup-key map key))
1210                   ;; Restore the match data while we process the command.
1211                   (cond ((eq def 'help)
1212                          (with-output-to-temp-buffer "*Help*"
1213                            (princ
1214                             (concat "Query replacing "
1215                                     (if regexp-flag "regexp " "")
1216                                     from-string " with "
1217                                     next-replacement ".\n\n"
1218                                     (substitute-command-keys
1219                                      query-replace-help)))
1220                            (with-current-buffer standard-output
1221                              (help-mode))))
1222                         ((eq def 'exit)
1223                          (setq keep-going nil)
1224                          (setq done t))
1225                         ((eq def 'backup)
1226                          (if stack
1227                              (let ((elt (pop stack)))
1228                                (goto-char (car elt))
1229                                (setq replaced (eq t (cdr elt)))
1230                                (or replaced
1231                                    (set-match-data (cdr elt))))
1232                            (message "No previous match")
1233                            (ding 'no-terminate)
1234                            (sit-for 1)))
1235                         ((eq def 'act)
1236                          (or replaced
1237                              (progn
1238                                (replace-match next-replacement nocasify literal)
1239                                (setq replace-count (1+ replace-count))))
1240                          (setq done t replaced t))
1241                         ((eq def 'act-and-exit)
1242                          (or replaced
1243                              (progn
1244                                (replace-match next-replacement nocasify literal)
1245                                (setq replace-count (1+ replace-count))))
1246                          (setq keep-going nil)
1247                          (setq done t replaced t))
1248                         ((eq def 'act-and-show)
1249                          (if (not replaced)
1250                              (progn
1251                                (replace-match next-replacement nocasify literal)
1252                                (setq replace-count (1+ replace-count))
1253                                (setq replaced t))))
1254                         ((eq def 'automatic)
1255                          (or replaced
1256                              (progn
1257                                (replace-match next-replacement nocasify literal)
1258                                (setq replace-count (1+ replace-count))))
1259                          (setq done t query-flag nil replaced t))
1260                         ((eq def 'skip)
1261                          (setq done t))
1262                         ((eq def 'recenter)
1263                          (recenter nil))
1264                         ((eq def 'edit)
1265                          (let ((opos (point-marker)))
1266                            (goto-char (match-beginning 0))
1267                            (save-excursion
1268                              (funcall search-function search-string limit t)
1269                              (setq real-match-data (match-data)))
1270                            (save-excursion
1271                              (save-window-excursion
1272                                (recursive-edit)))
1273                            (goto-char opos))
1274                          (set-match-data real-match-data)
1275                          ;; Before we make the replacement,
1276                          ;; decide whether the search string
1277                          ;; can match again just after this match.
1278                          (if (and regexp-flag nonempty-match)
1279                              (setq match-again (and (looking-at search-string)
1280                                                     (match-data)))))
1281
1282                         ;; Edit replacement.
1283                         ((eq def 'edit-replacement)
1284                          (setq next-replacement
1285                                (read-input "Edit replacement string: "
1286                                            next-replacement))
1287                          (or replaced
1288                              (replace-match next-replacement nocasify literal))
1289                          (setq done t))
1290
1291                         ((eq def 'delete-and-edit)
1292                          (delete-region (match-beginning 0) (match-end 0))
1293                          (set-match-data
1294                           (prog1 (match-data)
1295                             (save-excursion (recursive-edit))))
1296                          (setq replaced t))
1297                         ;; Note: we do not need to treat `exit-prefix'
1298                         ;; specially here, since we reread
1299                         ;; any unrecognized character.
1300                         (t
1301                          (setq this-command 'mode-exited)
1302                          (setq keep-going nil)
1303                          (setq unread-command-events
1304                                (append (listify-key-sequence key)
1305                                        unread-command-events))
1306                          (setq done t))))
1307                 ;; Record previous position for ^ when we move on.
1308                 ;; Change markers to numbers in the match data
1309                 ;; since lots of markers slow down editing.
1310                 (setq stack
1311                       (cons (cons (point)
1312                                   (or replaced (match-data t)))
1313                             stack))))))
1314
1315       ;; The code preventing adjacent regexp matches in the condition
1316       ;; of the while-loop above will haven taken us one character
1317       ;; beyond the last replacement.  Undo that.
1318       (when (and regexp-flag (not match-again) (> replace-count 0))
1319         (backward-char 1))
1320
1321       (replace-dehighlight))
1322     (or unread-command-events
1323         (message "Replaced %d occurrence%s"
1324                  replace-count
1325                  (if (= replace-count 1) "" "s")))
1326     (and keep-going stack)))
1327
1328 (defcustom query-replace-highlight t
1329   "*Non-nil means to highlight words during query replacement."
1330   :type 'boolean
1331   :group 'matching)
1332
1333 (defvar replace-overlay nil)
1334
1335 (defun replace-dehighlight ()
1336   (and replace-overlay
1337        (progn
1338          (delete-overlay replace-overlay)
1339          (setq replace-overlay nil))))
1340
1341 (defun replace-highlight (start end)
1342   (and query-replace-highlight
1343        (progn
1344          (or replace-overlay
1345              (progn
1346                (setq replace-overlay (make-overlay start end))
1347                (overlay-put replace-overlay 'face
1348                             (if (facep 'query-replace)
1349                                 'query-replace 'region))))
1350          (move-overlay replace-overlay start end (current-buffer)))))
1351
1352 ;;; arch-tag: 16b4cd61-fd40-497b-b86f-b667c4cf88e4
1353 ;;; replace.el ends here