code.delx.au - gnu-emacs/blob - lisp/select.el

   1 ;;; select.el --- lisp portion of standard selection support
   2
   3 ;; Maintainer: FSF
   4 ;; Keywords: internal
   5
   6 ;; Copyright (C) 1993, 1994, 2001, 2002, 2003, 2004, 2005, 2006, 2007,
   7 ;;   2008, 2009, 2010 Free Software Foundation, Inc.
   8 ;; Based partially on earlier release by Lucid.
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (defcustom selection-coding-system nil
  30   "Coding system for communicating with other X clients.
  31
  32 When sending text via selection and clipboard, if the target
  33 data-type matches with the type of this coding system, it is used
  34 for encoding the text.  Otherwise (including the case that this
  35 variable is nil), a proper coding system is used as below:
  36
  37 data-type       coding system
  38 ---------       -------------
  39 UTF8_STRING     utf-8
  40 COMPOUND_TEXT   compound-text-with-extensions
  41 STRING          iso-latin-1
  42 C_STRING        no-conversion
  43
  44 When receiving text, if this coding system is non-nil, it is used
  45 for decoding regardless of the data-type.  If this is nil, a
  46 proper coding system is used according to the data-type as above.
  47
  48 See also the documentation of the variable `x-select-request-type' how
  49 to control which data-type to request for receiving text.
  50
  51 The default value is nil."
  52   :type 'coding-system
  53   :group 'mule
  54   ;; Default was compound-text-with-extensions in 22.x (pre-unicode).
  55   :version "23.1"
  56   :set (lambda (symbol value)
  57          (set-selection-coding-system value)
  58          (set symbol value)))
  59
  60 (defvar next-selection-coding-system nil
  61   "Coding system for the next communication with other X clients.
  62 Usually, `selection-coding-system' is used for communicating with
  63 other X clients.  But, if this variable is set, it is used for
  64 the next communication only.  After the communication, this
  65 variable is set to nil.")
  66
  67 (declare-function x-get-selection-internal "xselect.c"
  68                   (selection-symbol target-type &optional time-stamp))
  69
  70 ;; This is for temporary compatibility with pre-release Emacs 19.
  71 (defalias 'x-selection 'x-get-selection)
  72 (defun x-get-selection (&optional type data-type)
  73   "Return the value of an X Windows selection.
  74 The argument TYPE (default `PRIMARY') says which selection,
  75 and the argument DATA-TYPE (default `STRING') says
  76 how to convert the data.
  77
  78 TYPE may be any symbol \(but nil stands for `PRIMARY').  However,
  79 only a few symbols are commonly used.  They conventionally have
  80 all upper-case names.  The most often used ones, in addition to
  81 `PRIMARY', are `SECONDARY' and `CLIPBOARD'.
  82
  83 DATA-TYPE is usually `STRING', but can also be one of the symbols
  84 in `selection-converter-alist', which see."
  85   (let ((data (x-get-selection-internal (or type 'PRIMARY)
  86                                         (or data-type 'STRING)))
  87         coding)
  88     (when (and (stringp data)
  89                (setq data-type (get-text-property 0 'foreign-selection data)))
  90       (setq coding (or next-selection-coding-system
  91                        selection-coding-system
  92                        (cond ((eq data-type 'UTF8_STRING)
  93                               'utf-8)
  94                              ((eq data-type 'COMPOUND_TEXT)
  95                               'compound-text-with-extensions)
  96                              ((eq data-type 'C_STRING)
  97                               nil)
  98                              ((eq data-type 'STRING)
  99                               'iso-8859-1)
 100                              (t
 101                               (error "Unknow selection data type: %S" type))))
 102             data (if coding (decode-coding-string data coding)
 103                    (string-to-multibyte data)))
 104       (setq next-selection-coding-system nil)
 105       (put-text-property 0 (length data) 'foreign-selection data-type data))
 106     data))
 107
 108 (defun x-get-clipboard ()
 109   "Return text pasted to the clipboard."
 110   (x-get-selection-internal 'CLIPBOARD 'STRING))
 111
 112 (declare-function x-own-selection-internal "xselect.c"
 113                   (selection-name selection-value))
 114 (declare-function x-disown-selection-internal "xselect.c"
 115                   (selection &optional time))
 116
 117 (defun x-set-selection (type data)
 118   "Make an X selection of type TYPE and value DATA.
 119 The argument TYPE (nil means `PRIMARY') says which selection, and
 120 DATA specifies the contents.  TYPE must be a symbol.  \(It can also
 121 be a string, which stands for the symbol with that name, but this
 122 is considered obsolete.)  DATA may be a string, a symbol, an
 123 integer (or a cons of two integers or list of two integers).
 124
 125 The selection may also be a cons of two markers pointing to the same buffer,
 126 or an overlay.  In these cases, the selection is considered to be the text
 127 between the markers *at whatever time the selection is examined*.
 128 Thus, editing done in the buffer after you specify the selection
 129 can alter the effective value of the selection.
 130
 131 The data may also be a vector of valid non-vector selection values.
 132
 133 The return value is DATA.
 134
 135 Interactively, this command sets the primary selection.  Without
 136 prefix argument, it reads the selection in the minibuffer.  With
 137 prefix argument, it uses the text of the region as the selection value.
 138
 139 Note that on MS-Windows, primary and secondary selections set by Emacs
 140 are not available to other programs."
 141   (interactive (if (not current-prefix-arg)
 142                    (list 'PRIMARY (read-string "Set text for pasting: "))
 143                  (list 'PRIMARY (buffer-substring (region-beginning) (region-end)))))
 144   (if (stringp type) (setq type (intern type)))
 145   (or (x-valid-simple-selection-p data)
 146       (and (vectorp data)
 147            (let ((valid t)
 148                  (i (1- (length data))))
 149              (while (>= i 0)
 150                (or (x-valid-simple-selection-p (aref data i))
 151                    (setq valid nil))
 152                (setq i (1- i)))
 153              valid))
 154       (signal 'error (list "invalid selection" data)))
 155   (or type (setq type 'PRIMARY))
 156   (if data
 157       (x-own-selection-internal type data)
 158     (x-disown-selection-internal type))
 159   data)
 160
 161 (defun x-valid-simple-selection-p (data)
 162   (or (bufferp data)
 163       (and (consp data)
 164            (markerp (car data))
 165            (markerp (cdr data))
 166            (marker-buffer (car data))
 167            (buffer-name (marker-buffer (car data)))
 168            (eq (marker-buffer (car data))
 169                (marker-buffer (cdr data))))
 170       (stringp data)
 171       (and (overlayp data)
 172            (overlay-buffer data)
 173            (buffer-name (overlay-buffer data)))
 174       (symbolp data)
 175       (integerp data)))
 176 \f
 177 ;; Functions to convert the selection into various other selection types.
 178 ;; Every selection type that Emacs handles is implemented this way, except
 179 ;; for TIMESTAMP, which is a special case.
 180
 181 (defun xselect--selection-bounds (value)
 182   "Return bounds of X selection value VALUE.
 183 The return value is a list (BEG END BUF) if VALUE is a cons of
 184 two markers or an overlay.  Otherwise, it is nil."
 185   (cond ((bufferp value)
 186          (with-current-buffer value
 187            (when (mark t)
 188              (list (mark t) (point) value))))
 189         ((and (consp value)
 190               (markerp (car value))
 191               (markerp (cdr value)))
 192          (when (and (marker-buffer (car value))
 193                     (buffer-name (marker-buffer (car value)))
 194                     (eq (marker-buffer (car value))
 195                         (marker-buffer (cdr value))))
 196            (list (marker-position (car value))
 197                  (marker-position (cdr value))
 198                  (marker-buffer (car value)))))
 199         ((overlayp value)
 200          (when (overlay-buffer value)
 201            (list (overlay-start value)
 202                  (overlay-end value)
 203                  (overlay-buffer value))))))
 204
 205 (defun xselect--int-to-cons (n)
 206   (cons (ash n -16) (logand n 65535)))
 207
 208 (defun xselect-convert-to-string (selection type value)
 209   (let (str coding)
 210     ;; Get the actual string from VALUE.
 211     (cond ((stringp value)
 212            (setq str value))
 213           ((setq value (xselect--selection-bounds value))
 214            (with-current-buffer (nth 2 value)
 215              (setq str (buffer-substring (nth 0 value)
 216                                          (nth 1 value))))))
 217     (when str
 218       ;; If TYPE is nil, this is a local request, thus return STR as
 219       ;; is.  Otherwise, encode STR.
 220       (if (not type)
 221           str
 222         (setq coding (or next-selection-coding-system selection-coding-system))
 223         (if coding
 224             (setq coding (coding-system-base coding)))
 225         (let ((inhibit-read-only t))
 226           ;; Suppress producing escape sequences for compositions.
 227           (remove-text-properties 0 (length str) '(composition nil) str)
 228           (if (eq type 'TEXT)
 229               ;; TEXT is a polymorphic target.  We must select the
 230               ;; actual type from `UTF8_STRING', `COMPOUND_TEXT',
 231               ;; `STRING', and `C_STRING'.
 232               (if (not (multibyte-string-p str))
 233                   (setq type 'C_STRING)
 234                 (let (non-latin-1 non-unicode eight-bit)
 235                   (mapc #'(lambda (x)
 236                             (if (>= x #x100)
 237                                 (if (< x #x110000)
 238                                     (setq non-latin-1 t)
 239                                   (if (< x #x3FFF80)
 240                                       (setq non-unicode t)
 241                                     (setq eight-bit t)))))
 242                         str)
 243                   (setq type (if non-unicode 'COMPOUND_TEXT
 244                                (if non-latin-1 'UTF8_STRING
 245                                  (if eight-bit 'C_STRING 'STRING)))))))
 246           (cond
 247            ((eq type 'UTF8_STRING)
 248             (if (or (not coding)
 249                     (not (eq (coding-system-type coding) 'utf-8)))
 250                 (setq coding 'utf-8))
 251             (setq str (encode-coding-string str coding)))
 252
 253            ((eq type 'STRING)
 254             (if (or (not coding)
 255                     (not (eq (coding-system-type coding) 'charset)))
 256                 (setq coding 'iso-8859-1))
 257             (setq str (encode-coding-string str coding)))
 258
 259            ((eq type 'COMPOUND_TEXT)
 260             (if (or (not coding)
 261                     (not (eq (coding-system-type coding) 'iso-2022)))
 262                 (setq coding 'compound-text-with-extensions))
 263             (setq str (encode-coding-string str coding)))
 264
 265            ((eq type 'C_STRING)
 266             (setq str (string-make-unibyte str)))
 267
 268            (t
 269             (error "Unknown selection type: %S" type)))))
 270
 271       (setq next-selection-coding-system nil)
 272       (cons type str))))
 273
 274 (defun xselect-convert-to-length (selection type value)
 275   (let ((len (cond ((stringp value)
 276                     (length value))
 277                    ((setq value (xselect--selection-bounds value))
 278                     (abs (- (nth 0 value) (nth 1 value)))))))
 279     (if len
 280         (xselect--int-to-cons len))))
 281
 282 (defun xselect-convert-to-targets (selection type value)
 283   ;; return a vector of atoms, but remove duplicates first.
 284   (let* ((all (cons 'TIMESTAMP (mapcar 'car selection-converter-alist)))
 285          (rest all))
 286     (while rest
 287       (cond ((memq (car rest) (cdr rest))
 288              (setcdr rest (delq (car rest) (cdr rest))))
 289             ((eq (car (cdr rest)) '_EMACS_INTERNAL)  ; shh, it's a secret
 290              (setcdr rest (cdr (cdr rest))))
 291             (t
 292              (setq rest (cdr rest)))))
 293     (apply 'vector all)))
 294
 295 (defun xselect-convert-to-delete (selection type value)
 296   (x-disown-selection-internal selection)
 297   ;; A return value of nil means that we do not know how to do this conversion,
 298   ;; and replies with an "error".  A return value of NULL means that we have
 299   ;; done the conversion (and any side-effects) but have no value to return.
 300   'NULL)
 301
 302 (defun xselect-convert-to-filename (selection type value)
 303   (when (setq value (xselect--selection-bounds value))
 304     (buffer-file-name (nth 2 value))))
 305
 306 (defun xselect-convert-to-charpos (selection type value)
 307   (when (setq value (xselect--selection-bounds value))
 308     (let ((beg (1- (nth 0 value))) ; zero-based
 309           (end (1- (nth 1 value))))
 310       (cons 'SPAN (vector (xselect--int-to-cons (min beg end))
 311                           (xselect--int-to-cons (max beg end)))))))
 312
 313 (defun xselect-convert-to-lineno (selection type value)
 314   (when (setq value (xselect--selection-bounds value))
 315     (with-current-buffer (nth 2 value)
 316       (let ((beg (line-number-at-pos (nth 0 value)))
 317             (end (line-number-at-pos (nth 1 value))))
 318         (cons 'SPAN (vector (xselect--int-to-cons (min beg end))
 319                             (xselect--int-to-cons (max beg end))))))))
 320
 321 (defun xselect-convert-to-colno (selection type value)
 322   (when (setq value (xselect--selection-bounds value))
 323     (with-current-buffer (nth 2 value)
 324       (let ((beg (progn (goto-char (nth 0 value)) (current-column)))
 325             (end (progn (goto-char (nth 1 value)) (current-column))))
 326         (cons 'SPAN (vector (xselect--int-to-cons (min beg end))
 327                             (xselect--int-to-cons (max beg end))))))))
 328
 329 (defun xselect-convert-to-os (selection type size)
 330   (symbol-name system-type))
 331
 332 (defun xselect-convert-to-host (selection type size)
 333   (system-name))
 334
 335 (defun xselect-convert-to-user (selection type size)
 336   (user-full-name))
 337
 338 (defun xselect-convert-to-class (selection type size)
 339   "Convert selection to class.
 340 This function returns the string \"Emacs\"."
 341   "Emacs")
 342
 343 ;; We do not try to determine the name Emacs was invoked with,
 344 ;; because it is not clean for a program's behavior to depend on that.
 345 (defun xselect-convert-to-name (selection type size)
 346   "Convert selection to name.
 347 This function returns the string \"emacs\"."
 348   "emacs")
 349
 350 (defun xselect-convert-to-integer (selection type value)
 351   (and (integerp value)
 352        (xselect--int-to-cons value)))
 353
 354 (defun xselect-convert-to-atom (selection type value)
 355   (and (symbolp value) value))
 356
 357 (defun xselect-convert-to-identity (selection type value) ; used internally
 358   (vector value))
 359
 360 (setq selection-converter-alist
 361       '((TEXT . xselect-convert-to-string)
 362         (COMPOUND_TEXT . xselect-convert-to-string)
 363         (STRING . xselect-convert-to-string)
 364         (UTF8_STRING . xselect-convert-to-string)
 365         (TARGETS . xselect-convert-to-targets)
 366         (LENGTH . xselect-convert-to-length)
 367         (DELETE . xselect-convert-to-delete)
 368         (FILE_NAME . xselect-convert-to-filename)
 369         (CHARACTER_POSITION . xselect-convert-to-charpos)
 370         (LINE_NUMBER . xselect-convert-to-lineno)
 371         (COLUMN_NUMBER . xselect-convert-to-colno)
 372         (OWNER_OS . xselect-convert-to-os)
 373         (HOST_NAME . xselect-convert-to-host)
 374         (USER . xselect-convert-to-user)
 375         (CLASS . xselect-convert-to-class)
 376         (NAME . xselect-convert-to-name)
 377         (ATOM . xselect-convert-to-atom)
 378         (INTEGER . xselect-convert-to-integer)
 379         (_EMACS_INTERNAL . xselect-convert-to-identity)))
 380
 381 (provide 'select)
 382
 383 ;; arch-tag: bb634f97-8a3b-4b0a-b940-f6e09982328c
 384 ;;; select.el ends here