code.delx.au - gnu-emacs/blob - configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2015 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 dnl Note this is parsed by (at least) make-dist and lisp/cedet/ede/emacs.el.
  26 AC_INIT(GNU Emacs, 25.0.50, bug-gnu-emacs@gnu.org)
  27
  28 dnl Set emacs_config_options to the options of 'configure', quoted for the shell,
  29 dnl and then quoted again for a C string.  Separate options with spaces.
  30 dnl Add some environment variables, if they were passed via the environment
  31 dnl rather than on the command-line.
  32 emacs_config_options=
  33 optsep=
  34 dnl This is the documented way to record the args passed to configure,
  35 dnl rather than $ac_configure_args.
  36 for opt in ${1+"$@"} CFLAGS CPPFLAGS LDFLAGS; do
  37   case $opt in
  38     -n | --no-create | --no-recursion)
  39       continue ;;
  40     CFLAGS | CPPFLAGS | LDFLAGS)
  41       eval 'test "${'$opt'+set}" = set' || continue
  42       case " $*" in
  43         *" $opt="*) continue ;;
  44       esac
  45       eval opt=$opt=\$$opt ;;
  46   esac
  47
  48   emacs_shell_specials=$IFS\''"#$&()*;<>?@<:@\\`{|~'
  49   case $opt in
  50     *[["$emacs_shell_specials"]]*)
  51       case $opt in
  52         *\'*)
  53           emacs_quote_apostrophes="s/'/'\\\\''/g"
  54           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_apostrophes"` ;;
  55       esac
  56       opt="'$opt'"
  57       case $opt in
  58         *[['"\\']]*)
  59           emacs_quote_for_c='s/[["\\]]/\\&/g; $!s/$/\\n\\/'
  60           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_for_c"` ;;
  61       esac ;;
  62   esac
  63   AS_VAR_APPEND([emacs_config_options], ["$optsep$opt"])
  64   optsep=' '
  65 done
  66
  67 AC_CONFIG_HEADERS(src/config.h:src/config.in)
  68 AC_CONFIG_SRCDIR(src/lisp.h)
  69 AC_CONFIG_AUX_DIR(build-aux)
  70 dnl automake 1.13 and later understand this, making -I m4 unnecessary.
  71 dnl With older versions this is a no-op.
  72 AC_CONFIG_MACRO_DIR(m4)
  73
  74 xcsdkdir=
  75 AC_CHECK_PROGS(XCRUN, [xcrun])
  76 if test -n "$XCRUN"; then
  77   if test -z "$MAKE"; then
  78     dnl Call the variable MAKE_PROG, not MAKE, to avoid confusion with
  79     dnl the usual MAKE variable that 'make' itself uses.
  80     AC_CHECK_PROG([MAKE_PROG], [make], [yes])
  81     if test -z "$MAKE_PROG"; then
  82       MAKE="$XCRUN MAKE"
  83       export MAKE
  84       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
  85     fi
  86   fi
  87 fi
  88
  89 dnl GNU Make is required, so don't test for its individual features.
  90 am_cv_make_support_nested_variables=yes
  91 AC_DEFUN([AC_PROG_MAKE_SET],
  92   [SET_MAKE=
  93    AC_SUBST([SET_MAKE])])
  94
  95 dnl Check for GNU Make and possibly set MAKE before running AM_INIT_AUTOMAKE.
  96 [emacs_check_gnu_make ()
  97 {
  98   emacs_makeout=`($1 --version) 2>/dev/null` &&
  99   case $emacs_makeout in
 100     'GNU Make '3.8[1-9]* | 'GNU Make '3.9[0-9]* | \
 101     'GNU Make '3.[1-9][0-9][0-9]* | 'GNU Make '[4-9]* | 'GNU Make '[1-9][0-9]* )
 102        ac_path_MAKE_found=:;;
 103   esac
 104 }]
 105 AC_CACHE_CHECK([for GNU Make], [ac_cv_path_MAKE],
 106   [ac_path_MAKE_found=false
 107    if test -n "$MAKE"; then
 108      emacs_check_gnu_make "$MAKE"
 109      ac_cv_path_MAKE=$MAKE
 110    else
 111      emacs_tried_make=false
 112      emacs_tried_gmake=false
 113      emacs_tried_gnumake=false
 114      AC_PATH_PROGS_FEATURE_CHECK([MAKE], [make gmake gnumake],
 115        [[emacs_check_gnu_make "$ac_path_MAKE"
 116          if $ac_path_MAKE_found; then
 117            # Use the fully-qualified program name only if the basename
 118            # would not resolve to it.
 119            if eval \$emacs_tried_$ac_prog; then
 120              ac_cv_path_MAKE=$ac_path_MAKE
 121            else
 122              ac_cv_path_MAKE=$ac_prog
 123            fi
 124          fi
 125          eval emacs_tried_$ac_prog=:]])
 126    fi])
 127 $ac_path_MAKE_found || {
 128 AC_MSG_ERROR([[Building Emacs requires GNU Make, at least version 3.81.
 129 If you have it installed under another name, configure with 'MAKE=...'.
 130 For example, run '$0 MAKE=gnu-make'.]])
 131 }
 132 MAKE=$ac_cv_path_MAKE
 133 export MAKE
 134
 135 dnl Fairly arbitrary, older versions might work too.
 136 AM_INIT_AUTOMAKE(1.11)
 137
 138 dnl Canonicalize the configuration name.
 139 AC_CANONICAL_HOST
 140
 141 case $host in
 142  *-mingw*)
 143
 144   if test -z "$host_alias"; then
 145
 146       # No --host argument was given to 'configure'; therefore $host
 147       # was set to a default value based on the build platform.  But
 148       # this default value may be wrong if we are building from a
 149       # 64-bit MSYS[2] pre-configured to build 32-bit MinGW programs.
 150       # Therefore, we'll try to get the right host platform from the
 151       # compiler's target.
 152
 153       AC_MSG_CHECKING([the compiler's target])
 154       if test -z "$CC"; then
 155           cc=gcc
 156       else
 157           cc=$CC
 158       fi
 159       cc_target=`$cc -v 2>&1 | sed -n 's/Target: //p'`
 160       case "$cc_target" in
 161           *-*) host=$cc_target
 162               ;;
 163           "") AC_MSG_ERROR([Impossible to obtain $cc compiler target.
 164 Please explicitly provide --host.])
 165               ;;
 166           *) AC_MSG_WARN([Compiler reported non-standard target.
 167 Defaulting to $host.])
 168               ;;
 169       esac
 170       AC_MSG_RESULT([$host])
 171   fi
 172
 173   . $srcdir/nt/mingw-cfg.site
 174
 175   case $srcdir in
 176     /* | ?:*)
 177       # srcdir is an absolute path.  In this case, force the format
 178       # "/c/foo/bar", to simplify later conversions to native Windows
 179       # format ("c:/foo/bar").
 180       srcdir=`cd "${srcdir}" && pwd -W`
 181       # 'eval' pacifies strict POSIX non-MinGW shells (Bug#18612).
 182       eval 'srcdir="/${srcdir:0:1}${srcdir:2}"'
 183       ;;
 184   esac;;
 185 esac
 186
 187 canonical=$host
 188 configuration=${host_alias-${build_alias-$host}}
 189
 190 dnl Support for --program-prefix, --program-suffix and
 191 dnl --program-transform-name options
 192 AC_ARG_PROGRAM
 193
 194 dnl It is important that variables on the RHS not be expanded here,
 195 dnl hence the single quotes.  This is per the GNU coding standards, see
 196 dnl (autoconf) Installation Directory Variables
 197 dnl See also epaths.h below.
 198 lispdir='${datadir}/emacs/${version}/lisp'
 199 standardlisppath='${lispdir}'
 200 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
 201 '${datadir}/emacs/site-lisp'
 202 lisppath='${locallisppath}:${standardlisppath}'
 203 etcdir='${datadir}/emacs/${version}/etc'
 204 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
 205 etcdocdir='${datadir}/emacs/${version}/etc'
 206 gamedir='${localstatedir}/games/emacs'
 207
 208 dnl Special option to disable the most of other options.
 209 AC_ARG_WITH(all,
 210 [AS_HELP_STRING([--without-all],
 211                 [omit almost all features and build
 212                 small executable with minimal dependencies])],
 213   [with_features=$withval],
 214   [with_features=yes])
 215
 216 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
 217 dnl Create a new --with option that defaults to being disabled.
 218 dnl NAME is the base name of the option.  The shell variable with_NAME
 219 dnl   will be set to either the user's value (if the option is
 220 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
 221 dnl   option is not specified).  Note that the shell variable name is
 222 dnl   constructed as autoconf does, by replacing non-alphanumeric
 223 dnl   characters with "_".
 224 dnl HELP-STRING is the help text for the option.
 225 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
 226   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
 227     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
 228 ])dnl
 229
 230 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
 231 dnl Create a new --with option that defaults to $with_features.
 232 dnl NAME is the base name of the option.  The shell variable with_NAME
 233 dnl   will be set either to 'no' (for a plain --without-NAME) or to
 234 dnl   'yes' (if the option is not specified).  Note that the shell
 235 dnl   variable name is constructed as autoconf does, by replacing
 236 dnl   non-alphanumeric characters with "_".
 237 dnl HELP-STRING is the help text for the option.
 238 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
 239   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
 240    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl
 241 ])dnl
 242
 243 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
 244 if test "$with_pop" = yes; then
 245    AC_DEFINE(MAIL_USE_POP)
 246 fi
 247 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
 248
 249 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
 250 if test "$with_kerberos" != no; then
 251    AC_DEFINE(KERBEROS)
 252 fi
 253 AH_TEMPLATE(KERBEROS,
 254             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
 255
 256 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
 257 if test "${with_kerberos5}" != no; then
 258   if test "${with_kerberos}" = no; then
 259     with_kerberos=yes
 260     AC_DEFINE(KERBEROS)
 261   fi
 262   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
 263 fi
 264
 265 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 266 dnl FIXME hesiod support may not be present, so it seems like an error
 267 dnl to define, or at least use, this unconditionally.
 268 if test "$with_hesiod" != no; then
 269   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 270 fi
 271
 272 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 273 if test "$with_mmdf" != no; then
 274    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 275 fi
 276
 277 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 278 if test "$with_mail_unlink" != no; then
 279    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 280 fi
 281
 282 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 283     [string giving default POP mail host])],
 284     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 285
 286 AC_ARG_WITH([sound],[AS_HELP_STRING([--with-sound=VALUE],
 287   [compile with sound support (VALUE one of: yes, alsa, oss, bsd-ossaudio, no;
 288 default yes).  Only for GNU/Linux, FreeBSD, NetBSD, MinGW, Cygwin.])],
 289   [ case "${withval}" in
 290       yes|no|alsa|oss|bsd-ossaudio) val=$withval ;;
 291       *) AC_MSG_ERROR([`--with-sound=$withval' is invalid;
 292 this option's value should be `yes', `no', `alsa', `oss', or `bsd-ossaudio'.])
 293       ;;
 294     esac
 295     with_sound=$val
 296   ],
 297   [with_sound=$with_features])
 298
 299 dnl FIXME currently it is not the last.
 300 dnl This should be the last --with option, because --with-x is
 301 dnl added later on when we find the file name of X, and it's best to
 302 dnl keep them together visually.
 303 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 304  [use an X toolkit (KIT one of: yes or gtk, gtk2, gtk3, lucid or athena, motif, no)])],
 305 [         case "${withval}" in
 306             y | ye | yes )      val=gtk ;;
 307             n | no )            val=no  ;;
 308             l | lu | luc | luci | lucid )       val=lucid ;;
 309             a | at | ath | athe | athen | athena )      val=athena ;;
 310             m | mo | mot | moti | motif )       val=motif ;;
 311             g | gt | gtk  )     val=gtk ;;
 312             gtk2  )     val=gtk2 ;;
 313             gtk3  )     val=gtk3 ;;
 314             * )
 315 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 316 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk',
 317 `gtk2' or `gtk3'.  `yes' and `gtk' are synonyms.
 318 `athena' and `lucid' are synonyms.])
 319             ;;
 320           esac
 321           with_x_toolkit=$val
 322 ])
 323
 324 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 325 if test "$with_wide_int" = yes; then
 326   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 327 fi
 328
 329 dnl _ON results in a '--without' option in the --help output, so
 330 dnl the help text should refer to "don't compile", etc.
 331 with_xpm_set=${with_xpm+set}
 332 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 333 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 334 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 335 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 336 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 337 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 338 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 339 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 340
 341 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 342 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 343 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 344
 345 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 346 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 347 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 348 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 349 OPTION_DEFAULT_OFF([w32], [use native MS Windows GUI in a Cygwin build])
 350
 351 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 352 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 353 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 354 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 355 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 356 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 357 OPTION_DEFAULT_ON([zlib],[don't compile with zlib decompression support])
 358
 359 AC_ARG_WITH([file-notification],[AS_HELP_STRING([--with-file-notification=LIB],
 360  [use a file notification library (LIB one of: yes, gfile, inotify, w32, no)])],
 361  [ case "${withval}" in
 362     y | ye | yes )      val=yes ;;
 363     n | no )            val=no  ;;
 364     g | gf | gfi | gfil | gfile )       val=gfile ;;
 365     i | in | ino | inot | inoti | inotif | inotify )    val=inotify ;;
 366     w | w3 | w32 )      val=w32 ;;
 367     * ) AC_MSG_ERROR([`--with-file-notification=$withval' is invalid;
 368 this option's value should be `yes', `no', `gfile', `inotify' or `w32'.
 369 `yes' is a synonym for `w32' on MS-Windows, for `no' on Nextstep,
 370 otherwise for the first of `gfile' or `inotify' that is usable.])
 371     ;;
 372    esac
 373    with_file_notification=$val
 374  ],
 375  [with_file_notification=$with_features])
 376
 377 ## For the times when you want to build Emacs but don't have
 378 ## a suitable makeinfo, and can live without the manuals.
 379 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 380 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 381
 382 ## This might be a 'configure' arg.
 383 AC_SUBST([ACLOCAL_PATH])
 384
 385 ## Makefile.in needs the cache file name.
 386 AC_SUBST(cache_file)
 387
 388 ## This is an option because I do not know if all info/man support
 389 ## compressed files, nor how to test if they do so.
 390 OPTION_DEFAULT_ON([compress-install],
 391   [don't compress some files (.el, .info, etc.) when installing.  Equivalent to:
 392 make GZIP_PROG= install])
 393
 394 AC_ARG_WITH(gameuser,dnl
 395 [AS_HELP_STRING([--with-gameuser=USER_OR_GROUP],
 396                 [user for shared game score files.
 397                 An argument prefixed by ':' specifies a group instead.])])
 398 gameuser=
 399 gamegroup=
 400 # We don't test if we can actually chown/chgrp here, because configure
 401 # may run without root privileges.  lib-src/Makefile.in will handle
 402 # any errors due to missing user/group gracefully.
 403 case ${with_gameuser} in
 404   no) ;;
 405   "" | yes) gamegroup=games ;;
 406   :*) gamegroup=`echo "${with_gameuser}" | sed -e "s/://"` ;;
 407   *) gameuser=${with_gameuser} ;;
 408 esac
 409
 410 AC_ARG_WITH([gnustep-conf],dnl
 411 [AS_HELP_STRING([--with-gnustep-conf=FILENAME],
 412    [name of GNUstep configuration file to use on systems where the command
 413     'gnustep-config' does not work; default $GNUSTEP_CONFIG_FILE, or
 414     /etc/GNUstep/GNUstep.conf])])
 415 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 416   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 417 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 418      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 419
 420 AC_ARG_ENABLE(ns-self-contained,
 421 [AS_HELP_STRING([--disable-ns-self-contained],
 422                 [disable self contained build under NeXTstep])],
 423    EN_NS_SELF_CONTAINED=$enableval,
 424    EN_NS_SELF_CONTAINED=yes)
 425
 426 locallisppathset=no
 427 AC_ARG_ENABLE(locallisppath,
 428 [AS_HELP_STRING([--enable-locallisppath=PATH],
 429                 [directories Emacs should search for lisp files specific
 430                  to this site])],
 431 if test "${enableval}" = "no"; then
 432   locallisppath=
 433 elif test "${enableval}" != "yes"; then
 434   locallisppath=${enableval} locallisppathset=yes
 435 fi)
 436
 437 AC_ARG_ENABLE(checking,
 438 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 439                 [enable expensive run-time checks.  With LIST,
 440                  enable only specific categories of checks.
 441                  Categories are: all,yes,no.
 442                  Flags are: stringbytes, stringoverrun, stringfreelist,
 443                  xmallocoverrun, conslist, glyphs])],
 444 [ac_checking_flags="${enableval}"],[])
 445 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 446 for check in $ac_checking_flags
 447 do
 448         case $check in
 449         # these set all the flags to specific states
 450         yes)            ac_enable_checking=1 ;;
 451         no)             ac_enable_checking= ;
 452                         ac_gc_check_stringbytes= ;
 453                         ac_gc_check_string_overrun= ;
 454                         ac_gc_check_string_free_list= ;
 455                         ac_xmalloc_overrun= ;
 456                         ac_gc_check_cons_list= ;
 457                         ac_glyphs_debug= ;;
 458         all)            ac_enable_checking=1 ;
 459                         ac_gc_check_stringbytes=1 ;
 460                         ac_gc_check_string_overrun=1 ;
 461                         ac_gc_check_string_free_list=1 ;
 462                         ac_xmalloc_overrun=1 ;
 463                         ac_gc_check_cons_list=1 ;
 464                         ac_glyphs_debug=1 ;;
 465         # these enable particular checks
 466         stringbytes)    ac_gc_check_stringbytes=1 ;;
 467         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 468         stringfreelist) ac_gc_check_string_free_list=1 ;;
 469         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 470         conslist)       ac_gc_check_cons_list=1 ;;
 471         glyphs)         ac_glyphs_debug=1 ;;
 472         *)      AC_MSG_ERROR(unknown check category $check) ;;
 473         esac
 474 done
 475 IFS="$ac_save_IFS"
 476
 477 if test x$ac_enable_checking != x ; then
 478   AC_DEFINE(ENABLE_CHECKING, 1,
 479 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 480 fi
 481 if test x$ac_gc_check_stringbytes != x ; then
 482   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 483 [Define this temporarily to hunt a bug.  If defined, the size of
 484    strings is redundantly recorded in sdata structures so that it can
 485    be compared to the sizes recorded in Lisp strings.])
 486 fi
 487 if test x$ac_gc_check_string_overrun != x ; then
 488   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 489 [Define this to check for short string overrun.])
 490 fi
 491 if test x$ac_gc_check_string_free_list != x ; then
 492   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 493 [Define this to check the string free list.])
 494 fi
 495 if test x$ac_xmalloc_overrun != x ; then
 496   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 497 [Define this to check for malloc buffer overrun.])
 498 fi
 499 if test x$ac_gc_check_cons_list != x ; then
 500   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 501 [Define this to check for errors in cons list.])
 502 fi
 503 if test x$ac_glyphs_debug != x ; then
 504   AC_DEFINE(GLYPH_DEBUG, 1,
 505 [Define this to enable glyphs debugging code.])
 506 fi
 507
 508 AC_ARG_ENABLE(check-lisp-object-type,
 509 [AS_HELP_STRING([--enable-check-lisp-object-type],
 510                 [enable compile time checks for the Lisp_Object data type.
 511                 This is useful for development for catching certain types of bugs.])],
 512 if test "${enableval}" != "no"; then
 513    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 514    [Define this to enable compile time checks for the Lisp_Object data type.])
 515 fi)
 516
 517
 518 dnl The name of this option is unfortunate.  It predates, and has no
 519 dnl relation to, the "sampling-based elisp profiler" added in 24.3.
 520 dnl Actually, it stops it working.
 521 dnl http://lists.gnu.org/archive/html/emacs-devel/2012-11/msg00393.html
 522 AC_ARG_ENABLE(profiling,
 523 [AS_HELP_STRING([--enable-profiling],
 524                 [build emacs with low-level, gprof profiling support.
 525                 Mainly useful for debugging Emacs itself.  May not work on
 526                 all platforms.  Stops profiler.el working.])],
 527 [ac_enable_profiling="${enableval}"],[])
 528 if test x$ac_enable_profiling != x ; then
 529    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 530 else
 531    PROFILING_CFLAGS=
 532 fi
 533 AC_SUBST(PROFILING_CFLAGS)
 534
 535 AC_ARG_ENABLE(autodepend,
 536 [AS_HELP_STRING([--enable-autodepend],
 537                 [automatically generate dependencies to .h-files.
 538                  Requires gcc, enabled if found.])],
 539 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 540
 541 AC_ARG_ENABLE(gtk-deprecation-warnings,
 542 [AS_HELP_STRING([--enable-gtk-deprecation-warnings],
 543                 [Show Gtk+/Gdk deprecation warnings for Gtk+ >= 3.0])],
 544 [ac_enable_gtk_deprecation_warnings="${enableval}"],[])
 545
 546 dnl This used to use changequote, but, apart from `changequote is evil'
 547 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 548 dnl the great gob of text.  Thus it's not processed for possible expansion.
 549 dnl Just make sure the brackets remain balanced.
 550 dnl
 551 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 552 dnl indicated by comments.
 553 dnl quotation begins
 554 [
 555
 556 ### If you add support for a new configuration, add code to this
 557 ### switch statement to recognize your configuration name and select
 558 ### the appropriate opsys.
 559
 560 ### As far as handling version numbers on operating systems is
 561 ### concerned, make sure things will fail in a fixable way.  If
 562 ### /etc/MACHINES doesn't say anything about version numbers, be
 563 ### prepared to handle anything reasonably.  If version numbers
 564 ### matter, be sure /etc/MACHINES says something about it.
 565
 566 opsys='' unported=no
 567 case "${canonical}" in
 568
 569   ## GNU/Linux and similar ports
 570   *-*-linux* )
 571     opsys=gnu-linux
 572   ;;
 573
 574   ## FreeBSD ports
 575   *-*-freebsd* )
 576     opsys=freebsd
 577   ;;
 578
 579   ## DragonFly ports
 580   *-*-dragonfly* )
 581     opsys=dragonfly
 582   ;;
 583
 584   ## FreeBSD kernel + glibc based userland
 585   *-*-kfreebsd*gnu* )
 586     opsys=gnu-kfreebsd
 587   ;;
 588
 589   ## NetBSD ports
 590   *-*-netbsd* )
 591     opsys=netbsd
 592   ;;
 593
 594   ## OpenBSD ports
 595   *-*-openbsd* | *-*-mirbsd* )
 596     opsys=openbsd
 597   ;;
 598
 599   ## Apple Darwin / Mac OS X
 600   *-apple-darwin* )
 601     case "${canonical}" in
 602       *-apple-darwin[0-9].*) unported=yes ;;
 603       i[3456]86-* | x86_64-* )  ;;
 604       * )            unported=yes ;;
 605     esac
 606     opsys=darwin
 607     ## Use fink packages if available.
 608     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 609 ##    if test -d /sw/include && test -d /sw/lib; then
 610 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 611 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 612 ##    fi
 613   ;;
 614
 615   ## Cygwin ports
 616   *-*-cygwin )
 617     opsys=cygwin
 618   ;;
 619
 620   ## HP 9000 series 700 and 800, running HP/UX
 621   hppa*-hp-hpux10.2* )
 622     opsys=hpux10-20
 623   ;;
 624   hppa*-hp-hpux1[1-9]* )
 625     opsys=hpux11
 626     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 627   ;;
 628
 629   ## IBM machines
 630   rs6000-ibm-aix4.[23]* )
 631     opsys=aix4-2
 632   ;;
 633   powerpc-ibm-aix4.[23]*  )
 634     opsys=aix4-2
 635   ;;
 636   rs6000-ibm-aix[56]* )
 637     opsys=aix4-2
 638   ;;
 639   powerpc-ibm-aix[5-9]* | powerpc-ibm-aix[1-9][0-9]* )
 640     opsys=aix4-2
 641   ;;
 642
 643   ## Silicon Graphics machines
 644   ## Iris 4D
 645   mips-sgi-irix6.5 )
 646     opsys=irix6-5
 647     # Without defining _LANGUAGE_C, things get masked out in the headers
 648     # so that, for instance, grepping for `free' in stdlib.h fails and
 649     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 650     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 651   ;;
 652
 653   ## Suns
 654   *-sun-solaris* \
 655     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 656     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 657     case "${canonical}" in
 658       i[3456]86-*-* )   ;;
 659       amd64-*-*|x86_64-*-*) ;;
 660       sparc* )          ;;
 661       * )               unported=yes ;;
 662     esac
 663     case "${canonical}" in
 664       *-sunos5.[1-9][0-9]* | *-solaris2.[1-9][0-9]* )
 665                 opsys=sol2-10
 666                 emacs_check_sunpro_c=yes
 667                 ;;
 668       *-sunos5.[1-5]* | *-solaris2.[1-5]* ) unported=yes ;;
 669       ## Note that Emacs 23.1's NEWS said the following would be dropped.
 670       *-sunos5.6* | *-solaris2.6* )
 671                 opsys=sol2-6
 672                 RANLIB="ar -ts"
 673                 ;;
 674       ## 5.7 EOL Aug 2008, 5.8 EOL Mar 2012.
 675       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 676                 opsys=sol2-6
 677                 emacs_check_sunpro_c=yes
 678                 ;;
 679     esac
 680     ## Watch out for a compiler that we know will not work.
 681     case "${canonical}" in
 682      *-solaris* | *-sunos5* )
 683                 if [ "x$CC" = x/usr/ucb/cc ]; then
 684                   ## /usr/ucb/cc doesn't work;
 685                   ## we should find some other compiler that does work.
 686                   unset CC
 687                 fi
 688                 ;;
 689       *) ;;
 690     esac
 691   ;;
 692
 693   ## Intel 386 machines where we don't care about the manufacturer.
 694   i[3456]86-*-* )
 695     case "${canonical}" in
 696       *-darwin* )               opsys=darwin ;;
 697       *-mingw* )
 698                 opsys=mingw32
 699                 # MinGW overrides and adds some system headers in nt/inc.
 700                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 701                 ;;
 702       *-sysv4.2uw* )            opsys=unixware ;;
 703       *-sysv5uw* )              opsys=unixware ;;
 704       *-sysv5OpenUNIX* )        opsys=unixware ;;
 705       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 706     esac
 707   ;;
 708
 709   # MinGW64
 710   x86_64-*-* )
 711     case "${canonical}" in
 712       *-mingw* )
 713                 opsys=mingw32
 714                 # MinGW overrides and adds some system headers in nt/inc.
 715                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 716                 ;;
 717       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 718     esac
 719   ;;
 720
 721   * )
 722     unported=yes
 723   ;;
 724 esac
 725
 726 ### If the code above didn't choose an operating system, just choose
 727 ### an operating system based on the configuration name.  You really
 728 ### only want to use this when you have no idea what the right
 729 ### operating system is; if you know what operating systems a machine
 730 ### runs, it's cleaner to make it explicit in the case statement
 731 ### above.
 732 if test x"${opsys}" = x; then
 733   case "${canonical}" in
 734     *-gnu* )                            opsys=gnu ;;
 735     * )
 736       unported=yes
 737     ;;
 738   esac
 739 fi
 740
 741 ]
 742 dnl quotation ends
 743
 744 if test $unported = yes; then
 745   AC_MSG_ERROR([Emacs does not support `${canonical}' systems.
 746 If you think it should, please send a report to ${PACKAGE_BUGREPORT}.
 747 Check `etc/MACHINES' for recognized configuration names.])
 748 fi
 749
 750 #### Choose a compiler.
 751
 752 dnl Don't bother to test for C89.
 753 AC_DEFUN([_AC_PROG_CC_C89], [$2])
 754
 755 dnl Sets GCC=yes if using gcc.
 756 AC_PROG_CC([gcc cc cl clang "$XCRUN gcc" "$XCRUN clang"])
 757 if test -n "$XCRUN"; then
 758   AC_CHECK_PROGS(AR, [ar "$XCRUN ar"])
 759   test -n "$AR" && export AR
 760 fi
 761
 762 dnl Emacs needs C99 or later.
 763 gl_PROG_CC_C99
 764
 765 AM_PROG_CC_C_O
 766
 767 if test x$GCC = xyes; then
 768   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 769 else
 770   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 771 fi
 772
 773 dnl This is used in lib/Makefile.am to use nt/gnulib.mk, the
 774 dnl alternative to lib/gnulib.mk, so as to avoid generating header files
 775 dnl that clash with MinGW.
 776 AM_CONDITIONAL([BUILDING_FOR_WINDOWSNT], [test "x$opsys" = "xmingw32"])
 777
 778 # Avoid gnulib's tests for -lcrypto, so that there's no static dependency on it.
 779 AC_DEFUN([gl_CRYPTO_CHECK])
 780 # Avoid gnulib's tests for HAVE_WORKING_O_NOATIME and HAVE_WORKING_O_NOFOLLOW,
 781 # as we don't use them.
 782 AC_DEFUN([gl_FCNTL_O_FLAGS])
 783 # Avoid gnulib's test for pthread_sigmask.
 784 funcs=
 785 for func in $ac_func_list; do
 786   test $func = pthread_sigmask || AS_VAR_APPEND([funcs], [" $func"])
 787 done
 788 ac_func_list=$funcs
 789 # Use the system putenv even if it lacks GNU features, as we don't need them,
 790 # and the gnulib replacement runs afoul of a FreeBSD 10.1 bug; see Bug#19874.
 791 AC_CHECK_FUNCS_ONCE([putenv])
 792 AC_DEFUN([gl_FUNC_PUTENV],
 793   [test "$ac_cv_func_putenv" = yes || REPLACE_PUTENV=1])
 794
 795 # Initialize gnulib right after choosing the compiler.
 796 dnl Amongst other things, this sets AR and ARFLAGS.
 797 gl_EARLY
 798
 799 if test "$ac_test_CFLAGS" != set; then
 800   # It's helpful to have C macros available to GDB, so prefer -g3 to -g
 801   # if -g3 works and the user does not specify CFLAGS.
 802   # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains.
 803   case $CFLAGS in
 804     '-g')
 805       emacs_g3_CFLAGS='-g3';;
 806     '-g -O2')
 807       emacs_g3_CFLAGS='-g3 -O2';;
 808     *)
 809       emacs_g3_CFLAGS='';;
 810   esac
 811   if test -n "$emacs_g3_CFLAGS"; then
 812     emacs_save_CFLAGS=$CFLAGS
 813     CFLAGS=$emacs_g3_CFLAGS
 814     AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS],
 815       [emacs_cv_prog_cc_g3],
 816       [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 817          [emacs_cv_prog_cc_g3=yes],
 818          [emacs_cv_prog_cc_g3=no])])
 819     if test $emacs_cv_prog_cc_g3 != yes; then
 820       CFLAGS=$emacs_save_CFLAGS
 821     fi
 822     if test $opsys = mingw32; then
 823       CFLAGS="$CFLAGS -gdwarf-2"
 824     fi
 825   fi
 826
 827   case $CFLAGS in
 828     *-O*) ;;
 829     *)
 830       # No optimization flag was inferred for this non-GCC compiler.
 831       # Try -O.  This is needed for xlc on AIX; see Bug#14258.
 832       emacs_save_CFLAGS=$CFLAGS
 833       test -z "$CFLAGS" || CFLAGS="$CFLAGS "
 834       CFLAGS=${CFLAGS}-O
 835       AC_CACHE_CHECK([whether $CC accepts -O],
 836         [emacs_cv_prog_cc_o],
 837         [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 838            [emacs_cv_prog_cc_o=yes],
 839            [emacs_cv_prog_cc_o=no])])
 840       if test $emacs_cv_prog_cc_o != yes; then
 841         CFLAGS=$emacs_save_CFLAGS
 842       fi ;;
 843   esac
 844 fi
 845
 846 AC_ARG_ENABLE([gcc-warnings],
 847   [AS_HELP_STRING([--enable-gcc-warnings],
 848                   [turn on lots of GCC warnings/errors. This is intended for
 849                    developers, and may generate false alarms when used
 850                    with older or non-GNU development tools.])],
 851   [case $enableval in
 852      yes|no) ;;
 853      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 854    esac
 855    gl_gcc_warnings=$enableval],
 856   [gl_gcc_warnings=no]
 857 )
 858
 859 # clang is unduly picky about some things.
 860 AC_CACHE_CHECK([whether the compiler is clang], [emacs_cv_clang],
 861   [AC_COMPILE_IFELSE(
 862      [AC_LANG_PROGRAM([[
 863           #ifndef __clang__
 864             error "not clang";
 865           #endif
 866         ]])],
 867      [emacs_cv_clang=yes],
 868      [emacs_cv_clang=no])])
 869
 870 # When compiling with GCC, prefer -isystem to -I when including system
 871 # include files, to avoid generating useless diagnostics for the files.
 872 if test "$gl_gcc_warnings" != yes; then
 873   isystem='-I'
 874   if test "$emacs_cv_clang" = yes
 875   then
 876      # Turn off some warnings if supported.
 877      gl_WARN_ADD([-Wno-switch])
 878      gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 879      gl_WARN_ADD([-Wno-pointer-sign])
 880      gl_WARN_ADD([-Wno-string-plus-int])
 881   fi
 882 else
 883   isystem='-isystem '
 884
 885   # This, $nw, is the list of warnings we disable.
 886   nw=
 887
 888   case $with_x_toolkit in
 889     lucid | athena | motif)
 890        # Old toolkits mishandle 'const'.
 891        nw="$nw -Wwrite-strings"
 892        ;;
 893     *)
 894        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 895        ;;
 896   esac
 897   AC_SUBST([WERROR_CFLAGS])
 898
 899   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 900   nw="$nw -Woverlength-strings"     # Not a problem these days
 901   nw="$nw -Wformat-nonliteral"      # we do this a lot
 902   nw="$nw -Wvla"                    # Emacs uses <vla.h>.
 903   nw="$nw -Wswitch-default"         # Too many warnings for now
 904   nw="$nw -Winline"                 # OK to ignore 'inline'
 905   nw="$nw -Wjump-misses-init"       # We sometimes safely jump over init.
 906   nw="$nw -Wstrict-overflow"        # OK to optimize assuming that
 907                                     # signed overflow has undefined behavior
 908   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 909   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 910   nw="$nw -Wbad-function-cast"      # These casts are no worse than others.
 911
 912   # Emacs doesn't care about shadowing; see
 913   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 914   nw="$nw -Wshadow"
 915
 916   # Emacs's use of alloca inhibits protecting the stack.
 917   nw="$nw -Wstack-protector"
 918
 919   # Emacs's use of partly-const functions such as Fgnutls_available_p
 920   # make this option problematic.
 921   nw="$nw -Wsuggest-attribute=const"
 922
 923   # Emacs's use of partly-pure functions such as CHECK_TYPE make this
 924   # option problematic.
 925   nw="$nw -Wsuggest-attribute=pure"
 926
 927   # This part is merely for shortening the command line,
 928   # since -Wno-FOO needs to be added below regardless.
 929   nw="$nw -Wmissing-field-initializers"
 930   nw="$nw -Wswitch"
 931   nw="$nw -Wtype-limits"
 932   nw="$nw -Wunused-parameter"
 933
 934   if test $emacs_cv_clang = yes; then
 935     nw="$nw -Wcast-align"
 936   fi
 937
 938   gl_MANYWARN_ALL_GCC([ws])
 939   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 940   for w in $ws; do
 941     gl_WARN_ADD([$w])
 942   done
 943   gl_WARN_ADD([-Wredundant-decls])     # Prefer this, as we don't use Bison.
 944   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 945   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 946   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 947   gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
 948   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 949   gl_WARN_ADD([-Wno-format-nonliteral])
 950
 951   # More things that clang is unduly picky about.
 952   if test $emacs_cv_clang = yes; then
 953     gl_WARN_ADD([-Wno-format-extra-args])
 954     gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 955     gl_WARN_ADD([-Wno-unused-command-line-argument])
 956     gl_WARN_ADD([-Wno-unused-value])
 957   fi
 958
 959   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 960   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 961   AH_VERBATIM([GNULIB_PORTCHECK_FORTIFY_SOURCE],
 962   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 963       without upsetting glibc 2.15+. */
 964    #if (defined GNULIB_PORTCHECK && !defined _FORTIFY_SOURCE \
 965         && defined __OPTIMIZE__ && __OPTIMIZE__)
 966    # define _FORTIFY_SOURCE 2
 967    #endif
 968   ])
 969
 970   # We use a slightly smaller set of warning options for lib/.
 971   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 972   nw=
 973   nw="$nw -Wunused-macros"
 974
 975   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 976   AC_SUBST([GNULIB_WARN_CFLAGS])
 977 fi
 978
 979 edit_cflags="
 980   s,///*,/,g
 981   s/^/ /
 982   s/ -I/ $isystem/g
 983   s/^ //
 984 "
 985
 986 AC_ARG_ENABLE(link-time-optimization,
 987 [AS_HELP_STRING([--enable-link-time-optimization],
 988                 [build emacs with link-time optimization.
 989                  This requires GCC 4.5.0 or later, or clang.
 990                  (Note that clang support is experimental - see INSTALL.)
 991                  It also makes Emacs harder to debug, and when we tried it
 992                  with GCC 4.9.0 x86-64 it made Emacs slower, so it's not
 993                  recommended for typical use.])],
 994 if test "${enableval}" != "no"; then
 995    ac_lto_supported=no
 996    if test $emacs_cv_clang = yes; then
 997       AC_MSG_CHECKING([whether link-time optimization is supported by clang])
 998       GOLD_PLUGIN=`$CC -print-file-name=LLVMgold.so 2>/dev/null`
 999       if test -x "$GOLD_PLUGIN"; then
1000          LTO="-flto"
1001       fi
1002    elif test x$GCC = xyes; then
1003       AC_MSG_CHECKING([whether link-time optimization is supported by gcc])
1004       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
1005       if test x$CPUS != x; then
1006          LTO="-flto=$CPUS"
1007       else
1008          LTO="-flto"
1009       fi
1010    else
1011       AC_MSG_ERROR([Link-time optimization is not supported with your compiler.])
1012    fi
1013    if test -z "$LTO"; then
1014       ac_lto_supported=no
1015    else
1016       old_CFLAGS=$CFLAGS
1017       CFLAGS="$CFLAGS $LTO"
1018       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
1019          [ac_lto_supported=yes], [ac_lto_supported=no])
1020          CFLAGS="$old_CFLAGS"
1021    fi
1022    AC_MSG_RESULT([$ac_lto_supported])
1023    if test "$ac_lto_supported" = "yes"; then
1024       CFLAGS="$CFLAGS $LTO"
1025       if test x$emacs_cv_clang = xyes; then
1026          AC_MSG_WARN([Please read INSTALL before using link-time optimization with clang])
1027          # WARNING: 'ar --plugin ...' doesn't work without
1028          # command, so plugin name is appended to ARFLAGS.
1029          ARFLAGS="cru --plugin $GOLD_PLUGIN"
1030          RANLIB="$RANLIB --plugin $GOLD_PLUGIN"
1031       else
1032         dnl The following is needed for GCC 4.9.0.  The GCC 4.9.0 release notes
1033         dnl suggest that instead of -ffat-lto-objects we should use gcc-ar and
1034         dnl gcc-ranlib in place of ar and ranlib, but gcc-ar makes /usr/bin/ar
1035         dnl dump core on Fedora 20, so play it safe for now.
1036         gl_COMPILER_OPTION_IF([-ffat-lto-objects],
1037           [CFLAGS="$CFLAGS -ffat-lto-objects"])
1038       fi
1039    fi
1040 fi)
1041
1042 dnl Prefer silent make output.  For verbose output, use
1043 dnl 'configure --disable-silent-rules' or 'make V=1' .
1044 AM_SILENT_RULES([yes])
1045 dnl Port to Automake 1.11.
1046 dnl This section can be removed once we assume Automake 1.14 or later.
1047 : ${AM_V=$AM_DEFAULT_VERBOSITY}
1048 : ${AM_DEFAULT_V=$AM_DEFAULT_VERBOSITY}
1049 AC_SUBST([AM_V])
1050 AM_SUBST_NOTMAKE([AM_V])
1051 AC_SUBST([AM_DEFAULT_V])
1052 AM_SUBST_NOTMAKE([AM_DEFAULT_V])
1053 AC_SUBST([AM_DEFAULT_VERBOSITY])
1054
1055 dnl Some other nice autoconf tests.
1056 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
1057 dnl AC_PROG_INSTALL
1058 dnl AC_PROG_MKDIR_P
1059 dnl if test "x$RANLIB" = x; then
1060 dnl   AC_PROG_RANLIB
1061 dnl fi
1062
1063
1064 dnl Sadly, AC_PROG_LN_S is too restrictive.  It also tests whether links
1065 dnl can be made to directories.  This is not relevant for our usage, and
1066 dnl excludes some cases that work fine for us.  Eg MS Windows or files
1067 dnl hosted on AFS, both examples where simple links work, but links to
1068 dnl directories fail.  We use a cut-down version instead.
1069 dnl AC_PROG_LN_S
1070
1071 AC_MSG_CHECKING([whether ln -s works for files in the same directory])
1072 rm -f conf$$ conf$$.file
1073
1074 LN_S_FILEONLY='cp -p'
1075
1076 dnl On MinGW, ensure we will call the MSYS /bin/ln.exe, not some
1077 dnl random program in the current directory.
1078 if (echo >conf$$.file) 2>/dev/null; then
1079   if ln -s conf$$.file conf$$ 2>/dev/null; then
1080     if test "$opsys" = "mingw32"; then
1081       LN_S_FILEONLY='/bin/ln -s'
1082     else
1083       LN_S_FILEONLY='ln -s'
1084     fi
1085   elif ln conf$$.file conf$$ 2>/dev/null; then
1086     if test "$opsys" = "mingw32"; then
1087       LN_S_FILEONLY=/bin/ln
1088     else
1089       LN_S_FILEONLY=ln
1090     fi
1091   fi
1092 fi
1093
1094 rm -f conf$$ conf$$.file
1095
1096 if test "$LN_S_FILEONLY" = "ln -s"; then
1097    AC_MSG_RESULT([yes])
1098 else
1099    AC_MSG_RESULT([no, using $LN_S_FILEONLY])
1100 fi
1101
1102 AC_SUBST(LN_S_FILEONLY)
1103
1104
1105 dnl AC_PROG_LN_S sets LN_S to 'cp -pR' for MinGW, on the premise that 'ln'
1106 dnl doesn't support links to directories, as in "ln file dir".  But that
1107 dnl use is non-portable, and OTOH MinGW wants to use hard links for Emacs
1108 dnl executables at "make install" time.
1109 dnl See http://lists.gnu.org/archive/html/emacs-devel/2013-04/msg00475.html
1110 dnl for more details.
1111 if test "$opsys" = "mingw32"; then
1112   LN_S="/bin/ln"
1113 fi
1114
1115 dnl On some Debian versions, "install-info" prints irritating messages
1116 dnl "This is not dpkg install-info anymore, but GNU install-info"
1117 dnl if called via an absolute file name.
1118 dnl Use the entirely-identical-but-quieter ginstall-info instead if present.
1119 dnl Sadly some people may have an old ginstall-info installed on
1120 dnl non-Debian systems, so we can't use this.
1121 dnl AC_PATH_PROGS(INSTALL_INFO, [ginstall-info install-info], :,
1122 dnl   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1123
1124 AC_PATH_PROG(INSTALL_INFO, install-info, :,
1125   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1126 dnl Don't use GZIP, which is used by gzip for additional parameters.
1127 AC_PATH_PROG(GZIP_PROG, gzip)
1128
1129 test $with_compress_install != yes && test -n "$GZIP_PROG" && \
1130    GZIP_PROG=" # $GZIP_PROG # (disabled by configure --without-compress-install)"
1131
1132 if test $opsys = gnu-linux; then
1133   AC_PATH_PROG(PAXCTL, paxctl,,
1134     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
1135   if test "X$PAXCTL" != X; then
1136     AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
1137     AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1138       [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then AC_MSG_RESULT(yes)
1139       else AC_MSG_RESULT(no); PAXCTL=""; fi])
1140   fi
1141
1142   if test "${SETFATTR+set}" != set; then
1143     AC_CACHE_CHECK([for setfattr],
1144       [emacs_cv_prog_setfattr],
1145       [touch conftest.tmp
1146        if (setfattr -n user.pax.flags conftest.tmp) >/dev/null 2>&1; then
1147          emacs_cv_prog_setfattr=yes
1148        else
1149          emacs_cv_prog_setfattr=no
1150        fi])
1151     if test "$emacs_cv_prog_setfattr" = yes; then
1152       SETFATTR=setfattr
1153     else
1154       SETFATTR=
1155     fi
1156     rm -f conftest.tmp
1157     AC_SUBST([SETFATTR])
1158   fi
1159 fi
1160
1161 ## Need makeinfo >= 4.7 (?) to build the manuals.
1162 if test "$MAKEINFO" != "no"; then
1163   if test "$MAKEINFO" = "${am_missing_run}makeinfo"; then
1164     MAKEINFO=makeinfo
1165   fi
1166   case `($MAKEINFO --version) 2>/dev/null` in
1167     *' (GNU texinfo) '4.[[7-9]]* | \
1168     *' (GNU texinfo) '4.[[1-9][0-9]]* | \
1169     *' (GNU texinfo) '[[5-9]]* | \
1170     *' (GNU texinfo) '[[1-9][0-9]]* ) ;;
1171     *) MAKEINFO=no;;
1172   esac
1173 fi
1174
1175 ## Makeinfo is unusual.  For a released Emacs, the manuals are
1176 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
1177 ## therefore in the category of "special tools" not normally required, which
1178 ## configure does not have to check for (eg autoconf itself).
1179 ## In a repository checkout on the other hand, the manuals are not included.
1180 ## So makeinfo is a requirement to build from the repository, and configure
1181 ## should test for it as it does for any other build requirement.
1182 ## We use the presence of $srcdir/info/emacs to distinguish a release,
1183 ## with pre-built manuals, from a repository checkout.
1184 HAVE_MAKEINFO=yes
1185
1186 if test "$MAKEINFO" = "no"; then
1187   MAKEINFO=makeinfo
1188   if test "x${with_makeinfo}" = "xno"; then
1189     HAVE_MAKEINFO=no
1190   elif test ! -e "$srcdir/info/emacs" && test ! -e "$srcdir/info/emacs.info"; then
1191     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
1192 source tree does not seem to have pre-built manuals in the `info' directory.
1193 Either install a suitable version of makeinfo, or re-run configure
1194 with the `--without-makeinfo' option to build without the manuals.] )
1195   fi
1196 fi
1197 AC_SUBST(HAVE_MAKEINFO)
1198
1199 if test $opsys = mingw32; then
1200    DOCMISC_W32=efaq-w32
1201 else
1202    DOCMISC_W32=
1203 fi
1204 AC_SUBST(DOCMISC_W32)
1205
1206 dnl Add our options to ac_link now, after it is set up.
1207
1208 if test x$GCC = xyes; then
1209   test "x$GCC_LINK_TEST_OPTIONS" != x && \
1210     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1211 else
1212   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
1213     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1214 fi
1215
1216 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
1217 dnl If we can link with the flag, it shouldn't do any harm anyhow.
1218 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
1219 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
1220 dnl if not built to support GNU ld.
1221
1222 dnl For a long time, -znocombreloc was added to LDFLAGS rather than
1223 dnl LD_SWITCH_SYSTEM_TEMACS.  That is:
1224 dnl * inappropriate, as LDFLAGS is a user option but this is essential.
1225 dnl   Eg "make LDFLAGS=... all" could run into problems,
1226 dnl   http://bugs.debian.org/684788
1227 dnl * unnecessary, since temacs is the only thing that actually needs it.
1228 dnl   Indeed this is where it was originally, prior to:
1229 dnl   http://lists.gnu.org/archive/html/emacs-pretest-bug/2004-03/msg00170.html
1230 late_LDFLAGS="$LDFLAGS"
1231 if test x$GCC = xyes; then
1232   LDFLAGS_NOCOMBRELOC="-Wl,-znocombreloc"
1233 else
1234   LDFLAGS_NOCOMBRELOC="-znocombreloc"
1235 fi
1236
1237 LDFLAGS="$LDFLAGS $LDFLAGS_NOCOMBRELOC"
1238
1239 AC_MSG_CHECKING([for -znocombreloc])
1240 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1241   [AC_MSG_RESULT(yes)],
1242   LDFLAGS_NOCOMBRELOC=
1243   [AC_MSG_RESULT(no)])
1244
1245 LDFLAGS="$late_LDFLAGS"
1246
1247 AC_CACHE_CHECK([whether addresses are sanitized],
1248   [emacs_cv_sanitize_address],
1249   [AC_COMPILE_IFELSE(
1250      [AC_LANG_PROGRAM(
1251         [[#ifndef __has_feature
1252           #define __has_feature(f) 0
1253           #endif
1254           #if defined __SANITIZE_ADDRESS__ || __has_feature (address_sanitizer)
1255           #else
1256            error "Addresses are not sanitized.";
1257           #endif
1258         ]])],
1259      [emacs_cv_sanitize_address=yes],
1260      [emacs_cv_sanitize_address=no])])
1261
1262 dnl The function dump-emacs will not be defined and temacs will do
1263 dnl (load "loadup") automatically unless told otherwise.
1264 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
1265 case "$opsys" in
1266   your-opsys-here) CANNOT_DUMP=yes ;;
1267 esac
1268
1269 if test "$CANNOT_DUMP" = "yes"; then
1270   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
1271 elif test "$emacs_cv_sanitize_address" = yes; then
1272   AC_MSG_WARN([[Addresses are sanitized; suggest CANNOT_DUMP=yes]])
1273 fi
1274
1275 AC_SUBST(CANNOT_DUMP)
1276
1277
1278 UNEXEC_OBJ=unexelf.o
1279 case "$opsys" in
1280   # MSDOS uses unexcoff.o
1281   aix4-2)
1282    UNEXEC_OBJ=unexaix.o
1283    ;;
1284   cygwin)
1285    UNEXEC_OBJ=unexcw.o
1286    ;;
1287   darwin)
1288    UNEXEC_OBJ=unexmacosx.o
1289    ;;
1290   hpux10-20 | hpux11)
1291    UNEXEC_OBJ=unexhp9k800.o
1292    ;;
1293   mingw32)
1294    UNEXEC_OBJ=unexw32.o
1295    ;;
1296   sol2-10)
1297    # Use the Solaris dldump() function, called from unexsol.c, to dump
1298    # emacs, instead of the generic ELF dump code found in unexelf.c.
1299    # The resulting binary has a complete symbol table, and is better
1300    # for debugging and other observability tools (debuggers, pstack, etc).
1301    #
1302    # If you encounter a problem using dldump(), please consider sending
1303    # a message to the OpenSolaris tools-linking mailing list:
1304    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
1305    #
1306    # It is likely that dldump() works with older Solaris too, but this has
1307    # not been tested, so for now this change is for Solaris 10 or newer.
1308    UNEXEC_OBJ=unexsol.o
1309    ;;
1310 esac
1311
1312 LD_SWITCH_SYSTEM=
1313 case "$opsys" in
1314   freebsd|dragonfly)
1315    ## Let `ld' find image libs and similar things in /usr/local/lib.
1316    ## The system compiler, GCC, has apparently been modified to not
1317    ## look there, contrary to what a stock GCC would do.
1318 ### It's not our place to do this.  See bug#10313#17.
1319 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
1320       :
1321    ;;
1322
1323   gnu-linux)
1324    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
1325    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
1326    ;;
1327
1328   netbsd)
1329 ### It's not our place to do this.  See bug#10313#17.
1330 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
1331       :
1332    ;;
1333
1334   openbsd)
1335    ## Han Boetes <han@boetes.org> says this is necessary,
1336    ## otherwise Emacs dumps core on elf systems.
1337    LD_SWITCH_SYSTEM="-Z"
1338    ;;
1339 esac
1340 AC_SUBST(LD_SWITCH_SYSTEM)
1341
1342 ac_link="$ac_link $LD_SWITCH_SYSTEM"
1343
1344 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
1345 ## which has not been defined yet.  When this was handled with cpp,
1346 ## it was expanded to null when configure sourced the s/*.h file.
1347 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
1348 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
1349 ## (or somesuch), but because it is supposed to go at the _front_
1350 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
1351 ## Compare with the gnu-linux case below, which added to the end
1352 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
1353 ## LD_SWITCH_SYSTEM_TEMACS.
1354 case "$opsys" in
1355   netbsd|openbsd)
1356    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
1357 esac
1358
1359
1360 C_SWITCH_MACHINE=
1361 case $canonical in
1362  alpha*)
1363   AC_CHECK_DECL([__ELF__])
1364   if test "$ac_cv_have_decl___ELF__" = "yes"; then
1365     ## With ELF, make sure that all common symbols get allocated to in the
1366     ## data section.  Otherwise, the dump of temacs may miss variables in
1367     ## the shared library that have been initialized.  For example, with
1368     ## GNU libc, __malloc_initialized would normally be resolved to the
1369     ## shared library's .bss section, which is fatal.
1370     if test "x$GCC" = "xyes"; then
1371       C_SWITCH_MACHINE="-fno-common"
1372     else
1373       AC_MSG_ERROR([Non-GCC compilers are not supported.])
1374     fi
1375   else
1376       dnl This was the unexalpha.c case.  Removed in 24.1, 2010-07-24,
1377       dnl albeit under the mistaken assumption that said file
1378       dnl was no longer used.
1379       AC_MSG_ERROR([Non-ELF systems are not supported since Emacs 24.1.])
1380   fi
1381   ;;
1382 esac
1383 AC_SUBST(C_SWITCH_MACHINE)
1384
1385 AC_SUBST(UNEXEC_OBJ)
1386
1387 C_SWITCH_SYSTEM=
1388 ## Some programs in src produce warnings saying certain subprograms
1389 ## are too complex and need a MAXMEM value greater than 2000 for
1390 ## additional optimization.  --nils@exp-math.uni-essen.de
1391 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1392   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1393 if test "$opsys" = "mingw32"; then
1394   case "$canonical" in
1395     x86_64-*-mingw*) C_SWITCH_SYSTEM="-mtune=generic" ;;
1396     *) C_SWITCH_SYSTEM="-mtune=pentium4" ;;
1397   esac
1398 fi
1399 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1400 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1401 AC_SUBST(C_SWITCH_SYSTEM)
1402
1403
1404 LIBS_SYSTEM=
1405 case "$opsys" in
1406   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1407   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1408
1409   freebsd|dragonfly) LIBS_SYSTEM="-lutil" ;;
1410
1411   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1412
1413   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
1414
1415   ## Motif needs -lgen.
1416   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1417 esac
1418
1419 AC_SUBST(LIBS_SYSTEM)
1420
1421 ### Make sure subsequent tests use flags consistent with the build flags.
1422
1423 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1424   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1425 else
1426   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1427 fi
1428
1429 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C99 or better.
1430 AC_DEFUN([AC_TYPE_SIZE_T])
1431 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1432 AC_DEFUN([AC_TYPE_UID_T])
1433
1434 # sqrt and other floating-point functions such as fmod and frexp
1435 # are found in -lm on many systems.
1436 OLD_LIBS=$LIBS
1437 AC_SEARCH_LIBS([sqrt], [m])
1438 if test "X$LIBS" = "X$OLD_LIBS"; then
1439   LIB_MATH=
1440 else
1441   LIB_MATH=$ac_cv_search_sqrt
1442 fi
1443 LIBS=$OLD_LIBS
1444
1445 dnl Current possibilities handled by sed (aix4-2 -> aix,
1446 dnl gnu-linux -> gnu/linux, etc.):
1447 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
1448 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
1449 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
1450
1451 case $opsys in
1452   cygwin )
1453     LIB_MATH=
1454     ;;
1455   darwin )
1456     ## Adding -lm confuses the dynamic linker, so omit it.
1457     LIB_MATH=
1458     ;;
1459   freebsd | dragonfly )
1460     SYSTEM_TYPE=berkeley-unix
1461     ;;
1462   gnu-linux | gnu-kfreebsd )
1463     ;;
1464   hpux10-20 | hpux11 )
1465     ;;
1466   mingw32 )
1467     LIB_MATH=
1468     SYSTEM_TYPE=windows-nt
1469     ;;
1470   dnl NB this may be adjusted below.
1471   netbsd | openbsd )
1472     SYSTEM_TYPE=berkeley-unix
1473     ;;
1474
1475   sol2* | unixware )
1476     SYSTEM_TYPE=usg-unix-v
1477     ;;
1478
1479 esac
1480
1481 AC_SUBST(LIB_MATH)
1482 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1483   [The type of system you are compiling for; sets `system-type'.])
1484
1485
1486 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1487 pre_PKG_CONFIG_LIBS=$LIBS
1488
1489 PKG_PROG_PKG_CONFIG(0.9.0)
1490
1491 dnl EMACS_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4)
1492 dnl acts like PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4,
1493 dnl HAVE_GSTUFF=yes, HAVE_GSTUFF=no) -- see pkg-config man page --
1494 dnl except that it postprocesses CFLAGS as needed for --enable-gcc-warnings.
1495 dnl EMACS_CHECK_MODULES accepts optional 3rd and 4th arguments that
1496 dnl can take the place of the default HAVE_GSTUFF=yes and HAVE_GSTUFF=no
1497 dnl actions.
1498 AC_DEFUN([EMACS_CHECK_MODULES],
1499   [PKG_CHECK_MODULES([$1], [$2],
1500      [$1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1501       m4_default([$3], [HAVE_$1=yes])],
1502      [m4_default([$4], [HAVE_$1=no])])])
1503
1504 HAVE_SOUND=no
1505 if test "${with_sound}" != "no"; then
1506   # Sound support for GNU/Linux, the free BSDs, MinGW, and Cygwin.
1507   AC_CHECK_HEADERS([machine/soundcard.h sys/soundcard.h soundcard.h mmsystem.h],
1508     have_sound_header=yes, [], [
1509     #ifdef __MINGW32__
1510     #define WIN32_LEAN_AND_MEAN
1511     #include <windows.h>
1512     #endif
1513     ])
1514   test "${with_sound}" = "oss" && test "${have_sound_header}" != "yes" && \
1515     AC_MSG_ERROR([OSS sound support requested but not found.])
1516
1517   if test "${with_sound}" = "bsd-ossaudio" || test "${with_sound}" = "yes"; then
1518     # Emulation library used on NetBSD.
1519     AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1520     test "${with_sound}" = "bsd-ossaudio" && test -z "$LIBSOUND" && \
1521       AC_MSG_ERROR([bsd-ossaudio sound support requested but not found.])
1522     dnl FIXME?  If we did find ossaudio, should we set with_sound=bsd-ossaudio?
1523     dnl Traditionally, we go on to check for alsa too.  Does that make sense?
1524   fi
1525   AC_SUBST(LIBSOUND)
1526
1527   if test "${with_sound}" = "alsa" || test "${with_sound}" = "yes"; then
1528     ALSA_REQUIRED=1.0.0
1529     ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1530     EMACS_CHECK_MODULES([ALSA], [$ALSA_MODULES])
1531     if test $HAVE_ALSA = yes; then
1532       SAVE_CFLAGS="$CFLAGS"
1533       SAVE_LIBS="$LIBS"
1534       CFLAGS="$ALSA_CFLAGS $CFLAGS"
1535       LIBS="$ALSA_LIBS $LIBS"
1536       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1537                       emacs_alsa_normal=yes,
1538                     emacs_alsa_normal=no)
1539       if test "$emacs_alsa_normal" != yes; then
1540         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1541                        [[snd_lib_error_set_handler (0);]])],
1542                        emacs_alsa_subdir=yes,
1543                      emacs_alsa_subdir=no)
1544         if test "$emacs_alsa_subdir" != yes; then
1545           AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1546         fi
1547         ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1548       fi
1549
1550       CFLAGS="$SAVE_CFLAGS"
1551       LIBS="$SAVE_LIBS"
1552       LIBSOUND="$LIBSOUND $ALSA_LIBS"
1553       CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1554       AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1555     elif test "${with_sound}" = "alsa"; then
1556       AC_MSG_ERROR([ALSA sound support requested but not found.])
1557     fi
1558   fi                            dnl with_sound = alsa|yes
1559
1560   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1561   dnl compiles only on the specified platforms.  For others, it
1562   dnl probably doesn't make sense to try.
1563   dnl FIXME So surely we should bypass this whole section if not using
1564   dnl one of these platforms?
1565   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1566      case "$opsys" in
1567        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1568        dnl Adjust the --with-sound help text if you change this.
1569        gnu-linux|freebsd|netbsd|mingw32|cygwin)
1570          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1571          HAVE_SOUND=yes
1572          ;;
1573      esac
1574   fi
1575
1576   AC_SUBST(CFLAGS_SOUND)
1577 fi
1578
1579 dnl checks for header files
1580 AC_CHECK_HEADERS_ONCE(
1581   sys/systeminfo.h
1582   sys/sysinfo.h
1583   coff.h pty.h
1584   sys/resource.h
1585   sys/utsname.h pwd.h utmp.h util.h)
1586
1587 AC_MSG_CHECKING(if personality LINUX32 can be set)
1588 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1589                emacs_cv_personality_linux32=yes,
1590                emacs_cv_personality_linux32=no)
1591 AC_MSG_RESULT($emacs_cv_personality_linux32)
1592
1593 if test $emacs_cv_personality_linux32 = yes; then
1594   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1595             [Define to 1 if personality LINUX32 can be set.])
1596 fi
1597
1598 # Note that Solaris has sys/sysinfo.h which defines struct
1599 # sysinfo as well.  To make sure that we're using GNU/Linux
1600 # sysinfo, we explicitly set one of its fields.
1601 if test "$ac_cv_header_sys_sysinfo_h" = yes; then
1602   AC_MSG_CHECKING([if Linux sysinfo may be used])
1603   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1604                                      [[struct sysinfo si;
1605                                        si.totalram = 0;
1606                                        sysinfo (&si)]])],
1607     emacs_cv_linux_sysinfo=yes, emacs_cv_linux_sysinfo=no)
1608   AC_MSG_RESULT($emacs_cv_linux_sysinfo)
1609   if test $emacs_cv_linux_sysinfo = yes; then
1610     AC_DEFINE([HAVE_LINUX_SYSINFO], 1, [Define to 1 if you have Linux sysinfo function.])
1611     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1612                                        [[struct sysinfo si; return si.mem_unit]])],
1613       AC_DEFINE(LINUX_SYSINFO_UNIT, 1,
1614                 [Define to 1 if Linux sysinfo sizes are in multiples of mem_unit bytes.]))
1615   fi
1616 fi
1617
1618 dnl On Solaris 8 there's a compilation warning for term.h because
1619 dnl it doesn't define `bool'.
1620 AC_CHECK_HEADERS(term.h, , , -)
1621 AC_HEADER_TIME
1622 AC_CHECK_DECLS([sys_siglist], [], [], [[#include <signal.h>
1623                                       ]])
1624 if test $ac_cv_have_decl_sys_siglist != yes; then
1625   # For Tru64, at least:
1626   AC_CHECK_DECLS([__sys_siglist], [], [], [[#include <signal.h>
1627                                           ]])
1628 fi
1629 AC_HEADER_SYS_WAIT
1630
1631 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1632 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1633 #if HAVE_SYS_SOCKET_H
1634 #include <sys/socket.h>
1635 #endif])
1636 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1637 #if HAVE_SYS_SOCKET_H
1638 #include <sys/socket.h>
1639 #endif])
1640 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1641 #if HAVE_SYS_SOCKET_H
1642 #include <sys/socket.h>
1643 #endif])
1644
1645 dnl checks for structure members
1646 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1647                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1648                   struct ifreq.ifr_addr,
1649                   struct ifreq.ifr_addr.sa_len], , ,
1650                  [AC_INCLUDES_DEFAULT
1651 #if HAVE_SYS_SOCKET_H
1652 #include <sys/socket.h>
1653 #endif
1654 #if HAVE_NET_IF_H
1655 #include <net/if.h>
1656 #endif])
1657
1658 dnl Check for endianness.
1659 dnl AC_C_BIGENDIAN is done by gnulib.
1660
1661 dnl check for Make feature
1662
1663 DEPFLAGS=
1664 MKDEPDIR=":"
1665 deps_frag=deps.mk
1666 dnl check if we have GCC and autodepend is on.
1667 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1668    AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1669    SAVE_CFLAGS="$CFLAGS"
1670    CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1671    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1672    CFLAGS="$SAVE_CFLAGS"
1673    test -f deps.d || ac_enable_autodepend=no
1674    rm -rf deps.d
1675    AC_MSG_RESULT([$ac_enable_autodepend])
1676    if test $ac_enable_autodepend = yes; then
1677       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1678       ## MKDIR_P is documented (see AC_PROG_MKDIR_P) to be parallel-safe.
1679       MKDEPDIR='${MKDIR_P} ${DEPDIR}'
1680       deps_frag=autodeps.mk
1681    fi
1682 fi
1683 lwlib_deps_frag=$srcdir/lwlib/$deps_frag
1684 oldxmenu_deps_frag=$srcdir/oldXMenu/$deps_frag
1685 deps_frag=$srcdir/src/$deps_frag
1686 AC_SUBST(MKDEPDIR)
1687 AC_SUBST(DEPFLAGS)
1688 AC_SUBST_FILE(deps_frag)
1689 AC_SUBST_FILE(lwlib_deps_frag)
1690 AC_SUBST_FILE(oldxmenu_deps_frag)
1691
1692 lisp_frag=$srcdir/src/lisp.mk
1693 AC_SUBST_FILE(lisp_frag)
1694
1695
1696 dnl checks for operating system services
1697 AC_SYS_LONG_FILE_NAMES
1698
1699 #### Choose a window system.
1700
1701 ## We leave window_system equal to none if
1702 ## we end up building without one.  Any new window system should
1703 ## set window_system to an appropriate value and add objects to
1704 ## window-system-specific substs.
1705
1706 window_system=none
1707 AC_PATH_X
1708 if test "$no_x" != yes; then
1709   window_system=x11
1710 fi
1711
1712 LD_SWITCH_X_SITE_RPATH=
1713 if test "${x_libraries}" != NONE; then
1714   if test -n "${x_libraries}"; then
1715     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1716     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"`
1717   fi
1718   x_default_search_path=""
1719   x_search_path=${x_libraries}
1720   if test -z "${x_search_path}"; then
1721     x_search_path=/usr/lib
1722   fi
1723   for x_library in `echo ${x_search_path}: | \
1724                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1725     x_search_path="\
1726 ${x_library}/X11/%L/%T/%N%C%S:\
1727 ${x_library}/X11/%l/%T/%N%C%S:\
1728 ${x_library}/X11/%T/%N%C%S:\
1729 ${x_library}/X11/%L/%T/%N%S:\
1730 ${x_library}/X11/%l/%T/%N%S:\
1731 ${x_library}/X11/%T/%N%S"
1732     if test x"${x_default_search_path}" = x; then
1733       x_default_search_path=${x_search_path}
1734     else
1735       x_default_search_path="${x_search_path}:${x_default_search_path}"
1736     fi
1737   done
1738 fi
1739 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1740
1741 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1742   C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1743 fi
1744
1745 if test x"${x_includes}" = x; then
1746   bitmapdir=/usr/include/X11/bitmaps
1747 else
1748   # accumulate include directories that have X11 bitmap subdirectories
1749   bmd_acc="dummyval"
1750   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1751     if test -d "${bmd}/X11/bitmaps"; then
1752       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1753     fi
1754     if test -d "${bmd}/bitmaps"; then
1755       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1756     fi
1757   done
1758   if test ${bmd_acc} != "dummyval"; then
1759     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1760   fi
1761 fi
1762
1763 HAVE_NS=no
1764 NS_GNUSTEP_CONFIG=no
1765 NS_IMPL_COCOA=no
1766 NS_IMPL_GNUSTEP=no
1767 tmp_CPPFLAGS="$CPPFLAGS"
1768 tmp_CFLAGS="$CFLAGS"
1769 CPPFLAGS="$CPPFLAGS -x objective-c"
1770 CFLAGS="$CFLAGS -x objective-c"
1771 GNU_OBJC_CFLAGS=
1772 LIBS_GNUSTEP=
1773 if test "${with_ns}" != no; then
1774   if test "${opsys}" = darwin; then
1775      NS_IMPL_COCOA=yes
1776      ns_appdir=`pwd`/nextstep/Emacs.app
1777      ns_appbindir=${ns_appdir}/Contents/MacOS
1778      ns_appresdir=${ns_appdir}/Contents/Resources
1779      ns_appsrc=Cocoa/Emacs.base
1780      ns_fontfile=macfont.o
1781   elif flags=$( (gnustep-config --objc-flags) 2>/dev/null); then
1782      NS_IMPL_GNUSTEP=yes
1783      NS_GNUSTEP_CONFIG=yes
1784      GNU_OBJC_CFLAGS=$flags
1785      LIBS_GNUSTEP=$(gnustep-config --gui-libs) || exit
1786   elif test -f $GNUSTEP_CONFIG_FILE; then
1787      NS_IMPL_GNUSTEP=yes
1788      dnl FIXME sourcing this several times in subshells seems inefficient.
1789      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1790      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1791      dnl I seemed to need these as well with GNUstep-startup 0.25.
1792      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1793      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1794      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1795        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1796      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1797        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1798      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1799      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1800      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1801      LIBS_GNUSTEP="-lgnustep-gui -lgnustep-base -lobjc -lpthread"
1802      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1803      dnl If they had chosen to either define it or not, we could have
1804      dnl just used AC_CHECK_DECL here.
1805      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1806        emacs_cv_objc_exceptions,
1807 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1808 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1809 1;
1810 #else
1811 fail;
1812 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1813      if test $emacs_cv_objc_exceptions = yes; then
1814        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1815        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1816          [Define if GNUstep uses ObjC exceptions.])
1817        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1818      fi
1819   fi
1820   if test $NS_IMPL_GNUSTEP = yes; then
1821      ns_appdir=`pwd`/nextstep/Emacs.app
1822      ns_appbindir=${ns_appdir}
1823      ns_appresdir=${ns_appdir}/Resources
1824      ns_appsrc=GNUstep/Emacs.base
1825      ns_fontfile=nsfont.o
1826   fi
1827
1828   dnl This is only used while we test the NS headers, it gets reset below.
1829   CPPFLAGS="$CPPFLAGS $GNU_OBJC_CFLAGS"
1830   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1831
1832   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1833                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1834   files are missing or cannot be compiled.])])
1835
1836   macfont_file=""
1837   if test "${NS_IMPL_COCOA}" = "yes"; then
1838     AC_MSG_CHECKING([for OSX 10.6 or newer])
1839     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1840                                      [
1841 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1842 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1060
1843  ; /* OK */
1844 #else
1845  error "OSX 10.6 or newer required";
1846 #endif
1847 #endif
1848                     ])],
1849                     ns_osx_have_106=yes,
1850                     ns_osx_have_106=no)
1851     AC_MSG_RESULT([$ns_osx_have_106])
1852
1853     if test $ns_osx_have_106 = no; then
1854        AC_MSG_ERROR([`OSX 10.6 or newer is required']);
1855     fi
1856   fi
1857 fi
1858
1859 AC_SUBST(LIBS_GNUSTEP)
1860
1861 INSTALL_ARCH_INDEP_EXTRA=install-etc
1862 ns_self_contained=no
1863 NS_OBJ=
1864 NS_OBJC_OBJ=
1865 if test "${HAVE_NS}" = yes; then
1866   if test "$with_toolkit_scroll_bars" = "no"; then
1867     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1868   fi
1869
1870   window_system=nextstep
1871   # set up packaging dirs
1872   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1873      ns_self_contained=yes
1874      prefix=${ns_appresdir}
1875      exec_prefix=${ns_appbindir}
1876      dnl This one isn't really used, only archlibdir is.
1877      libexecdir="\${ns_appbindir}/libexec"
1878      archlibdir="\${ns_appbindir}/libexec"
1879      etcdocdir="\${ns_appresdir}/etc"
1880      etcdir="\${ns_appresdir}/etc"
1881      dnl FIXME maybe set datarootdir instead.
1882      dnl That would also get applications, icons, man.
1883      infodir="\${ns_appresdir}/info"
1884      mandir="\${ns_appresdir}/man"
1885      lispdir="\${ns_appresdir}/lisp"
1886      test "$locallisppathset" = no && locallisppath=""
1887      INSTALL_ARCH_INDEP_EXTRA=
1888   fi
1889
1890   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o $ns_fontfile"
1891 fi
1892 CFLAGS="$tmp_CFLAGS"
1893 CPPFLAGS="$tmp_CPPFLAGS"
1894 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1895 AC_SUBST(ns_self_contained)
1896 AC_SUBST(NS_OBJ)
1897 AC_SUBST(NS_OBJC_OBJ)
1898
1899 HAVE_W32=no
1900 W32_OBJ=
1901 W32_LIBS=
1902 EMACSRES=
1903 CLIENTRES=
1904 CLIENTW=
1905 W32_RES_LINK=
1906 EMACS_MANIFEST=
1907 UPDATE_MANIFEST=
1908 if test "${with_w32}" != no; then
1909   case "${opsys}" in
1910     cygwin)
1911       AC_CHECK_HEADER([windows.h], [HAVE_W32=yes],
1912              [AC_MSG_ERROR([`--with-w32' was specified, but windows.h
1913                    cannot be found.])])
1914     ;;
1915     mingw32)
1916     ## Using --with-w32 with MinGW is a no-op, but we allow it.
1917     ;;
1918     *)
1919       AC_MSG_ERROR([Using w32 with an autotools build is only supported for Cygwin and MinGW32.])
1920     ;;
1921   esac
1922 fi
1923
1924 if test "${opsys}" = "mingw32"; then
1925   AC_MSG_CHECKING([whether Windows API headers are recent enough])
1926   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1927      #include <windows.h>
1928      #include <usp10.h>]],
1929    [[PIMAGE_NT_HEADERS pHeader;
1930      PIMAGE_SECTION_HEADER pSection = IMAGE_FIRST_SECTION(pHeader)]])],
1931    [emacs_cv_w32api=yes
1932     HAVE_W32=yes],
1933    emacs_cv_w32api=no)
1934   AC_MSG_RESULT($emacs_cv_w32api)
1935   if test "${emacs_cv_w32api}" = "no"; then
1936     AC_MSG_ERROR([the Windows API headers are too old to support this build.])
1937   fi
1938 fi
1939
1940 FIRSTFILE_OBJ=
1941 NTDIR=
1942 LIBS_ECLIENT=
1943 LIB_WSOCK32=
1944 NTLIB=
1945 CM_OBJ="cm.o"
1946 XARGS_LIMIT=
1947 if test "${HAVE_W32}" = "yes"; then
1948   AC_DEFINE(HAVE_NTGUI, 1, [Define to use native MS Windows GUI.])
1949   if test "$with_toolkit_scroll_bars" = "no"; then
1950     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for w32 build.])
1951   fi
1952   AC_CHECK_TOOL(WINDRES, [windres],
1953                 [AC_MSG_ERROR([No resource compiler found.])])
1954   W32_OBJ="w32fns.o w32menu.o w32reg.o w32font.o w32term.o"
1955   W32_OBJ="$W32_OBJ w32xfns.o w32select.o w32uniscribe.o"
1956   EMACSRES="emacs.res"
1957   case "$canonical" in
1958     x86_64-*-*) EMACS_MANIFEST="emacs-x64.manifest" ;;
1959     *) EMACS_MANIFEST="emacs-x86.manifest" ;;
1960   esac
1961   dnl Construct something of the form "24,4,0,0" with 4 components.
1962   comma_version=`echo "${PACKAGE_VERSION}.0.0" | sed -e 's/\./,/g' -e 's/^\([[^,]]*,[[^,]]*,[[^,]]*,[[^,]]*\).*/\1/'`
1963
1964   comma_space_version=`echo "$comma_version" | sed 's/,/, /g'`
1965   AC_SUBST(comma_version)
1966   AC_SUBST(comma_space_version)
1967   AC_CONFIG_FILES([nt/emacs.rc nt/emacsclient.rc])
1968   if test "${opsys}" = "cygwin"; then
1969     W32_LIBS="$W32_LIBS -lkernel32 -luser32 -lgdi32 -lole32 -lcomdlg32"
1970     W32_LIBS="$W32_LIBS -lusp10 -lcomctl32 -lwinspool"
1971     # Tell the linker that emacs.res is an object (which we compile from
1972     # the rc file), not a linker script.
1973     W32_RES_LINK="-Wl,emacs.res"
1974   else
1975     UPDATE_MANIFEST=update-game-score.exe.manifest
1976     W32_OBJ="$W32_OBJ w32.o w32console.o w32heap.o w32inevt.o w32proc.o"
1977     W32_LIBS="$W32_LIBS -lwinmm -lgdi32 -lcomdlg32"
1978     W32_LIBS="$W32_LIBS -lmpr -lwinspool -lole32 -lcomctl32 -lusp10"
1979     W32_RES_LINK="\$(EMACSRES)"
1980     CLIENTRES="emacsclient.res"
1981     CLIENTW="emacsclientw\$(EXEEXT)"
1982     FIRSTFILE_OBJ=firstfile.o
1983     NTDIR=nt
1984     CM_OBJ=
1985     LIBS_ECLIENT="-lcomctl32"
1986     LIB_WSOCK32="-lwsock32"
1987     NTLIB="ntlib.$ac_objext"
1988     XARGS_LIMIT="-s 10000"
1989   fi
1990 fi
1991 AC_SUBST(W32_OBJ)
1992 AC_SUBST(W32_LIBS)
1993 AC_SUBST(EMACSRES)
1994 AC_SUBST(EMACS_MANIFEST)
1995 AC_SUBST(UPDATE_MANIFEST)
1996 AC_SUBST(CLIENTRES)
1997 AC_SUBST(CLIENTW)
1998 AC_SUBST(W32_RES_LINK)
1999 AC_SUBST(FIRSTFILE_OBJ)
2000 AC_SUBST(NTDIR)
2001 AC_SUBST(CM_OBJ)
2002 AC_SUBST(LIBS_ECLIENT)
2003 AC_SUBST(LIB_WSOCK32)
2004 AC_SUBST(NTLIB)
2005 AC_SUBST(XARGS_LIMIT)
2006
2007 if test "${HAVE_W32}" = "yes"; then
2008   window_system=w32
2009   with_xft=no
2010 fi
2011
2012 ## $window_system is now set to the window system we will
2013 ## ultimately use.
2014
2015 if test "$window_system" = none && test "$gl_gcc_warnings" = yes; then
2016    # Too many warnings for now.
2017    nw=
2018    nw="$nw -Wsuggest-attribute=noreturn"
2019    gl_MANYWARN_COMPLEMENT([WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
2020
2021    gl_WARN_ADD([-Wno-unused-variable])
2022    gl_WARN_ADD([-Wno-unused-but-set-variable])
2023    gl_WARN_ADD([-Wno-unused-but-set-parameter])
2024 fi
2025
2026 term_header=
2027 HAVE_X_WINDOWS=no
2028 HAVE_X11=no
2029 USE_X_TOOLKIT=none
2030
2031 case "${window_system}" in
2032   x11 )
2033     HAVE_X_WINDOWS=yes
2034     HAVE_X11=yes
2035     term_header=xterm.h
2036     case "${with_x_toolkit}" in
2037       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
2038       motif ) USE_X_TOOLKIT=MOTIF ;;
2039       gtk ) with_gtk=yes
2040             term_header=gtkutil.h
2041 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
2042 dnl USE_X_TOOLKIT is set.
2043             USE_X_TOOLKIT=none ;;
2044       gtk2 ) with_gtk2=yes
2045              term_header=gtkutil.h
2046              USE_X_TOOLKIT=none ;;
2047       gtk3 ) with_gtk3=yes
2048              term_header=gtkutil.h
2049              USE_X_TOOLKIT=none ;;
2050       no ) USE_X_TOOLKIT=none ;;
2051 dnl If user did not say whether to use a toolkit, make this decision later:
2052 dnl use the toolkit if we have gtk, or X11R5 or newer.
2053       * ) USE_X_TOOLKIT=maybe ;;
2054     esac
2055   ;;
2056   nextstep )
2057     term_header=nsterm.h
2058   ;;
2059   w32 )
2060     term_header=w32term.h
2061   ;;
2062 esac
2063
2064 if test "$window_system" = none && test "X$with_x" != "Xno"; then
2065    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
2066    if test "$HAVE_XSERVER" = true ||
2067       test -n "$DISPLAY" ||
2068       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
2069         AC_MSG_ERROR([You seem to be running X, but no X development libraries
2070 were found.  You should install the relevant development files for X
2071 and for the toolkit you want, such as Gtk+ or Motif.  Also make
2072 sure you have development files for image handling, i.e.
2073 tiff, gif, jpeg, png and xpm.
2074 If you are sure you want Emacs compiled without X window support, pass
2075   --without-x
2076 to configure.])
2077    fi
2078 fi
2079
2080 # Does the opsystem file prohibit the use of the GNU malloc?
2081 # Assume not, until told otherwise.
2082 GNU_MALLOC=yes
2083
2084 AC_CACHE_CHECK(
2085   [whether malloc is Doug Lea style],
2086   [emacs_cv_var_doug_lea_malloc],
2087   [emacs_cv_var_doug_lea_malloc=no
2088    dnl Hooks do not work with address sanitization.
2089    if test "$emacs_cv_sanitize_address" != yes; then
2090      AC_LINK_IFELSE(
2091        [AC_LANG_PROGRAM(
2092           [[#include <malloc.h>
2093             static void hook (void) {}]],
2094           [[malloc_set_state (malloc_get_state ());
2095             __after_morecore_hook = hook;
2096             __malloc_initialize_hook = hook;]])],
2097        [emacs_cv_var_doug_lea_malloc=yes])])
2098    fi
2099 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
2100
2101 system_malloc=$emacs_cv_sanitize_address
2102
2103 hybrid_malloc=
2104
2105 case "$opsys" in
2106   ## darwin ld insists on the use of malloc routines in the System framework.
2107   darwin|mingw32|sol2-10) system_malloc=yes ;;
2108   cygwin) hybrid_malloc=yes;;
2109 esac
2110
2111 GMALLOC_OBJ=
2112 if test "${system_malloc}" = "yes"; then
2113   AC_DEFINE([SYSTEM_MALLOC], 1,
2114     [Define to 1 to use the system memory allocator, even if it is not
2115      Doug Lea style.])
2116   GNU_MALLOC=no
2117   GNU_MALLOC_reason="
2118     (The GNU allocators don't work with this system configuration.)"
2119   VMLIMIT_OBJ=
2120 elif test "$hybrid_malloc" = yes; then
2121   AC_DEFINE(HYBRID_MALLOC, 1,
2122     [Define to use gmalloc before dumping and the system malloc after.])
2123   GNU_MALLOC=
2124   GNU_MALLOC_reason="only before dumping"
2125   GMALLOC_OBJ=gmalloc.o
2126   VMLIMIT_OBJ=
2127 else
2128   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
2129   VMLIMIT_OBJ=vm-limit.o
2130
2131   AC_CHECK_HEADERS([sys/vlimit.h])
2132   AC_CACHE_CHECK([for data_start], [emacs_cv_data_start],
2133     [AC_LINK_IFELSE(
2134        [AC_LANG_PROGRAM(
2135          [[extern char data_start[]; char ch;]],
2136          [[return data_start < &ch;]])],
2137        [emacs_cv_data_start=yes],
2138        [emacs_cv_data_start=no])])
2139   if test $emacs_cv_data_start = yes; then
2140     AC_DEFINE([HAVE_DATA_START], 1,
2141       [Define to 1 if data_start is the address of the start
2142        of the main data segment.])
2143   fi
2144 fi
2145 AC_SUBST(GMALLOC_OBJ)
2146 AC_SUBST(VMLIMIT_OBJ)
2147
2148 if test "$doug_lea_malloc" = "yes" ; then
2149   if test "$GNU_MALLOC" = yes ; then
2150     GNU_MALLOC_reason="
2151       (Using Doug Lea's new malloc from the GNU C Library.)"
2152   fi
2153   AC_DEFINE(DOUG_LEA_MALLOC, 1,
2154     [Define to 1 if the system memory allocator is Doug Lea style,
2155      with malloc hooks and malloc_set_state.])
2156
2157   ## Use mmap directly for allocating larger buffers.
2158   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
2159   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
2160   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
2161   case "$opsys" in
2162     mingw32|gnu*) REL_ALLOC=no ;;
2163   esac
2164 fi
2165
2166 if test x"${REL_ALLOC}" = x; then
2167   REL_ALLOC=${GNU_MALLOC}
2168 fi
2169
2170 use_mmap_for_buffers=no
2171 case "$opsys" in
2172   cygwin|mingw32|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
2173 esac
2174
2175 AC_FUNC_MMAP
2176 if test $use_mmap_for_buffers = yes; then
2177   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
2178   REL_ALLOC=no
2179 fi
2180
2181 LIBS="$LIBS_SYSTEM $LIBS"
2182
2183 dnl FIXME replace main with a function we actually want from this library.
2184 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
2185
2186 dnl Check for the POSIX thread library.
2187 LIB_PTHREAD=
2188 AC_CHECK_HEADERS_ONCE(pthread.h)
2189 if test "$ac_cv_header_pthread_h" && test "$opsys" != "mingw32"; then
2190   AC_CACHE_CHECK([for pthread library],
2191     [emacs_cv_pthread_lib],
2192     [emacs_cv_pthread_lib=no
2193      OLD_CPPFLAGS=$CPPFLAGS
2194      OLD_LIBS=$LIBS
2195      for emacs_pthread_lib in 'none needed' -lpthread; do
2196        case $emacs_pthread_lib in
2197          -*) LIBS="$OLD_LIBS $emacs_pthread_lib";;
2198        esac
2199        AC_LINK_IFELSE(
2200          [AC_LANG_PROGRAM(
2201             [[#include <pthread.h>
2202               #include <signal.h>
2203               sigset_t old_mask, new_mask;
2204               void noop (void) {}]],
2205             [[pthread_t th = pthread_self ();
2206               int status = 0;
2207               status += pthread_create (&th, 0, 0, 0);
2208               status += pthread_sigmask (SIG_BLOCK, &new_mask, &old_mask);
2209               status += pthread_kill (th, 0);
2210               #if ! (defined SYSTEM_MALLOC || defined HYBRID_MALLOC \
2211                      || defined DOUG_LEA_MALLOC)
2212               /* Test for pthread_atfork only if gmalloc uses it,
2213                  as older-style hosts like MirBSD 10 lack it.  */
2214               status += pthread_atfork (noop, noop, noop);
2215               #endif
2216               return status;]])],
2217          [emacs_cv_pthread_lib=$emacs_pthread_lib])
2218        LIBS=$OLD_LIBS
2219        if test "$emacs_cv_pthread_lib" != no; then
2220          break
2221        fi
2222      done
2223      CPPFLAGS=$OLD_CPPFLAGS])
2224   if test "$emacs_cv_pthread_lib" != no; then
2225     AC_DEFINE([HAVE_PTHREAD], 1, [Define to 1 if you have POSIX threads.])
2226     case $emacs_cv_pthread_lib in
2227       -*) LIB_PTHREAD=$emacs_cv_pthread_lib;;
2228     esac
2229     ac_cv_func_pthread_sigmask=yes
2230     # Some systems optimize for single-threaded programs by default, and
2231     # need special flags to disable these optimizations. For example, the
2232     # definition of 'errno' in <errno.h>.
2233     case $opsys in
2234       hpux* | sol*)
2235         AC_DEFINE([_REENTRANT], 1,
2236           [Define to 1 if your system requires this in multithreaded code.]);;
2237       aix4-2)
2238         AC_DEFINE([_THREAD_SAFE], 1,
2239           [Define to 1 if your system requires this in multithreaded code.]);;
2240     esac
2241   fi
2242 fi
2243 AC_SUBST([LIB_PTHREAD])
2244
2245 dnl Check for need for bigtoc support on IBM AIX
2246
2247 case ${host_os} in
2248 aix*)
2249   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
2250     case $GCC in
2251     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
2252     *) gdb_cv_bigtoc=-bbigtoc ;;
2253     esac
2254
2255     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
2256     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
2257   ])
2258   ;;
2259 esac
2260
2261 # Change CFLAGS, CPPFLAGS, and LIBS temporarily so that C_SWITCH_X_SITE
2262 # is for the tests that follow.  We set them back later on.
2263
2264 REAL_CFLAGS="$CFLAGS"
2265 REAL_CPPFLAGS="$CPPFLAGS"
2266 REAL_LIBS="$LIBS"
2267
2268 if test "${HAVE_X11}" = "yes"; then
2269   DEFS="$C_SWITCH_X_SITE $DEFS"
2270   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
2271   LIBS="-lX11 $LIBS"
2272   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
2273   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
2274
2275   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
2276   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
2277   # but it's more convenient here to set LD_RUN_PATH since this
2278   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
2279   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
2280     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
2281     export LD_RUN_PATH
2282   fi
2283
2284   if test "${opsys}" = "gnu-linux"; then
2285     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
2286     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2287      [[XOpenDisplay ("foo");]])],
2288      [xgnu_linux_first_failure=no],
2289      [xgnu_linux_first_failure=yes])
2290     if test "${xgnu_linux_first_failure}" = "yes"; then
2291       OLD_CPPFLAGS="$CPPFLAGS"
2292       OLD_LIBS="$LIBS"
2293       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
2294       LIBS="$LIBS -b i486-linuxaout"
2295       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2296        [[XOpenDisplay ("foo");]])],
2297        [xgnu_linux_second_failure=no],
2298        [xgnu_linux_second_failure=yes])
2299       if test "${xgnu_linux_second_failure}" = "yes"; then
2300         # If we get the same failure with -b, there is no use adding -b.
2301         # So leave it out.  This plays safe.
2302         AC_MSG_RESULT(no)
2303       else
2304         LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
2305         C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
2306         AC_MSG_RESULT(yes)
2307       fi
2308       CPPFLAGS=$OLD_CPPFLAGS
2309       LIBS=$OLD_LIBS
2310     else
2311       AC_MSG_RESULT(no)
2312     fi
2313   fi
2314
2315   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
2316   # header files included from there.
2317   AC_MSG_CHECKING(for Xkb)
2318   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
2319 #include <X11/XKBlib.h>]],
2320         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
2321         emacs_xkb=yes, emacs_xkb=no)
2322   AC_MSG_RESULT($emacs_xkb)
2323   if test $emacs_xkb = yes; then
2324     AC_DEFINE(HAVE_XKB, 1, [Define to 1 if you have the Xkb extension.])
2325   fi
2326
2327   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
2328 XScreenNumberOfScreen)
2329 fi
2330
2331 if test "${window_system}" = "x11"; then
2332   AC_MSG_CHECKING(X11 version 6)
2333   AC_CACHE_VAL(emacs_cv_x11_version_6,
2334   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
2335 [[#if XlibSpecificationRelease < 6
2336 fail;
2337 #endif
2338 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
2339   if test $emacs_cv_x11_version_6 = yes; then
2340     AC_MSG_RESULT(6 or newer)
2341     AC_DEFINE(HAVE_X11R6, 1,
2342               [Define to 1 if you have the X11R6 or newer version of Xlib.])
2343     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
2344     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
2345     ## XIM support.
2346     case "$opsys" in
2347       sol2-*) : ;;
2348       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
2349            [Define if you have usable X11R6-style XIM support.])
2350          ;;
2351     esac
2352   else
2353     AC_MSG_RESULT(before 6)
2354   fi
2355 fi
2356
2357
2358 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
2359 HAVE_RSVG=no
2360 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${opsys}" = "mingw32"; then
2361   if test "${with_rsvg}" != "no"; then
2362     RSVG_REQUIRED=2.11.0
2363     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
2364
2365     EMACS_CHECK_MODULES([RSVG], [$RSVG_MODULE])
2366     AC_SUBST(RSVG_CFLAGS)
2367     AC_SUBST(RSVG_LIBS)
2368
2369     if test $HAVE_RSVG = yes; then
2370       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
2371       CFLAGS="$CFLAGS $RSVG_CFLAGS"
2372       # Windows loads librsvg dynamically
2373       if test "${opsys}" = "mingw32"; then
2374         RSVG_LIBS=
2375       fi
2376     fi
2377   fi
2378 fi
2379
2380 HAVE_IMAGEMAGICK=no
2381 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${HAVE_W32}" = "yes"; then
2382   if test "${with_imagemagick}" != "no"; then
2383     ## 6.3.5 is the earliest version known to work; see Bug#17339.
2384     ## 6.8.2 makes Emacs crash; see Bug#13867.
2385     IMAGEMAGICK_MODULE="Wand >= 6.3.5 Wand != 6.8.2"
2386     EMACS_CHECK_MODULES([IMAGEMAGICK], [$IMAGEMAGICK_MODULE])
2387     AC_SUBST(IMAGEMAGICK_CFLAGS)
2388     AC_SUBST(IMAGEMAGICK_LIBS)
2389
2390     if test $HAVE_IMAGEMAGICK = yes; then
2391       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
2392       OLD_CFLAGS=$CFLAGS
2393       OLD_LIBS=$LIBS
2394       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
2395       LIBS="$IMAGEMAGICK_LIBS $LIBS"
2396       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers)
2397       CFLAGS=$OLD_CFLAGS
2398       LIBS=$OLD_LIBS
2399     fi
2400   fi
2401 fi
2402
2403
2404 HAVE_GTK=no
2405 GTK_OBJ=
2406 gtk_term_header=$term_header
2407 check_gtk2=no
2408 gtk3_pkg_errors=
2409 if test "${opsys}" != "mingw32"; then
2410   if test "${with_gtk3}" = "yes" || test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
2411     GLIB_REQUIRED=2.28
2412     GTK_REQUIRED=3.0
2413     GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2414
2415     dnl Checks for libraries.
2416     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2417       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2418     if test "$pkg_check_gtk" = "no" && test "$with_gtk3" = "yes"; then
2419        AC_MSG_ERROR($GTK_PKG_ERRORS)
2420     fi
2421     if test "$pkg_check_gtk" = "yes"; then
2422        AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
2423        GTK_OBJ=emacsgtkfixed.o
2424        gtk_term_header=gtkutil.h
2425        USE_GTK_TOOLKIT="GTK3"
2426        if test "x$ac_enable_gtk_deprecation_warnings" = x; then
2427          AC_DEFINE([GDK_DISABLE_DEPRECATION_WARNINGS], [1],
2428            [Define to 1 to disable GTK+/GDK deprecation warnings.])
2429          AC_DEFINE([GLIB_DISABLE_DEPRECATION_WARNINGS], [1],
2430            [Define to 1 to disable Glib deprecation warnings.])
2431        fi
2432     else
2433        check_gtk2=yes
2434        gtk3_pkg_errors="$GTK_PKG_ERRORS "
2435     fi
2436   fi
2437
2438   if test "${with_gtk2}" = "yes" || test "$check_gtk2" = "yes"; then
2439     GLIB_REQUIRED=2.10
2440     GTK_REQUIRED=2.10
2441     GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2442
2443     dnl Checks for libraries.
2444     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2445       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2446     if test "$pkg_check_gtk" = "no" &&
2447        { test "$with_gtk" = yes || test "$with_gtk2" = "yes"; }
2448     then
2449       AC_MSG_ERROR($gtk3_pkg_errors$GTK_PKG_ERRORS)
2450     fi
2451     test "$pkg_check_gtk" = "yes" && USE_GTK_TOOLKIT="GTK2"
2452   fi
2453 fi
2454
2455 OLD_CFLAGS=$CFLAGS
2456 OLD_LIBS=$LIBS
2457
2458 if test x"$pkg_check_gtk" = xyes; then
2459
2460   AC_SUBST(GTK_LIBS)
2461   CFLAGS="$CFLAGS $GTK_CFLAGS"
2462   LIBS="$GTK_LIBS $LIBS"
2463   dnl Try to compile a simple GTK program.
2464   AC_MSG_CHECKING([whether GTK compiles])
2465   GTK_COMPILES=no
2466   AC_LINK_IFELSE(
2467     [AC_LANG_PROGRAM(
2468        [[/* Check the Gtk and Glib APIs.  */
2469          #include <gtk/gtk.h>
2470          #include <glib-object.h>
2471          static void
2472          callback (GObject *go, GParamSpec *spec, gpointer user_data)
2473          {}
2474        ]],
2475        [[
2476          GtkSettings *gs = 0;
2477          /* Use G_CALLBACK to make sure function pointers can be cast to void *;
2478             strict C prohibits this.  Use gtk_main_iteration to test that the
2479             libraries are there.  */
2480          if (g_signal_handler_find (G_OBJECT (gs), G_SIGNAL_MATCH_FUNC,
2481                                     0, 0, 0, G_CALLBACK (callback), 0))
2482            gtk_main_iteration ();
2483        ]])],
2484     [GTK_COMPILES=yes])
2485   AC_MSG_RESULT([$GTK_COMPILES])
2486   if test "${GTK_COMPILES}" != "yes"; then
2487     GTK_OBJ=
2488     if test "$USE_X_TOOLKIT" != "maybe"; then
2489       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
2490     fi
2491   else
2492     C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
2493     HAVE_GTK=yes
2494     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
2495     GTK_OBJ="gtkutil.o $GTK_OBJ"
2496     term_header=$gtk_term_header
2497     USE_X_TOOLKIT=none
2498     if "$PKG_CONFIG" --atleast-version=2.10 gtk+-2.0; then
2499       :
2500     else
2501       AC_MSG_WARN([[Your version of Gtk+ will have problems with
2502        closing open displays.  This is no problem if you just use
2503        one display, but if you use more than one and close one of them
2504        Emacs may crash.]])
2505       sleep 3
2506     fi
2507   fi
2508
2509 fi
2510 AC_SUBST(GTK_OBJ)
2511
2512
2513 if test "${HAVE_GTK}" = "yes"; then
2514
2515   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2516   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
2517   if test "$with_toolkit_scroll_bars" != no; then
2518     with_toolkit_scroll_bars=yes
2519   fi
2520
2521   dnl  Check if we have the old file selection dialog declared and
2522   dnl  in the link library.  In 2.x it may be in the library,
2523   dnl  but not declared if deprecated featured has been selected out.
2524   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
2525   HAVE_GTK_FILE_SELECTION=no
2526   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
2527                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
2528 #include <gtk/gtk.h>])
2529   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
2530     AC_CHECK_FUNCS(gtk_file_selection_new)
2531   fi
2532
2533   dnl Same as above for gtk_handle_box.
2534   HAVE_GTK_HANDLE_BOX=no
2535   AC_CHECK_DECL(GTK_TYPE_HANDLE_BOX, HAVE_GTK_HANDLE_BOX=yes,
2536                    HAVE_GTK_HANDLE_BOX=no, [AC_INCLUDES_DEFAULT
2537 #include <gtk/gtk.h>])
2538   if test "$HAVE_GTK_HANDLE_BOX" = yes; then
2539     AC_CHECK_FUNCS(gtk_handle_box_new)
2540   fi
2541
2542   dnl Same as above for gtk_tearoff_menu_item.
2543   HAVE_GTK_TEAROFF_MENU_ITEM=no
2544   AC_CHECK_DECL(GTK_TYPE_TEAROFF_MENU_ITEM, HAVE_GTK_TEAROFF_MENU_ITEM=yes,
2545                    HAVE_GTK_TEAROFF_MENU_ITEM=no, [AC_INCLUDES_DEFAULT
2546 #include <gtk/gtk.h>])
2547   if test "$HAVE_GTK_TEAROFF_MENU_ITEM" = yes; then
2548     AC_CHECK_FUNCS(gtk_tearoff_menu_item_new)
2549   fi
2550
2551   dnl Check for functions introduced in 2.14 and later.
2552   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2553                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2554                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2555                  gtk_orientable_set_orientation \
2556                  gtk_window_set_has_resize_grip)
2557
2558  term_header=gtkutil.h
2559 fi
2560
2561 CFLAGS=$OLD_CFLAGS
2562 LIBS=$OLD_LIBS
2563
2564 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2565 dnl other platforms.
2566 HAVE_DBUS=no
2567 DBUS_OBJ=
2568 if test "${with_dbus}" = "yes"; then
2569    EMACS_CHECK_MODULES([DBUS], [dbus-1 >= 1.0])
2570    if test "$HAVE_DBUS" = yes; then
2571      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2572      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2573      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
2574      dnl D-Bus 1.5.12.
2575      OLD_LIBS=$LIBS
2576      LIBS="$LIBS $DBUS_LIBS"
2577      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2578                     dbus_type_is_valid \
2579                     dbus_validate_bus_name \
2580                     dbus_validate_path \
2581                     dbus_validate_interface \
2582                     dbus_validate_member)
2583      LIBS=$OLD_LIBS
2584      DBUS_OBJ=dbusbind.o
2585    fi
2586 fi
2587 AC_SUBST(DBUS_CFLAGS)
2588 AC_SUBST(DBUS_LIBS)
2589 AC_SUBST(DBUS_OBJ)
2590
2591 dnl GSettings has been tested under GNU/Linux only.
2592 HAVE_GSETTINGS=no
2593 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2594    EMACS_CHECK_MODULES([GSETTINGS], [gio-2.0 >= 2.26])
2595    if test "$HAVE_GSETTINGS" = "yes"; then
2596       old_CFLAGS=$CFLAGS
2597       CFLAGS="$CFLAGS $GSETTINGS_CFLAGS"
2598       old_LIBS=$LIBS
2599       LIBS="$LIBS $GSETTINGS_LIBS"
2600       AC_MSG_CHECKING([whether GSettings is in gio])
2601       AC_LINK_IFELSE(
2602          [AC_LANG_PROGRAM(
2603              [[/* Check that gsettings really is present.  */
2604              #include <glib-object.h>
2605              #include <gio/gio.h>
2606              ]],
2607              [[
2608                GSettings *settings;
2609                GVariant *val = g_settings_get_value (settings, "");
2610              ]])],
2611          [], HAVE_GSETTINGS=no)
2612       AC_MSG_RESULT([$HAVE_GSETTINGS])
2613
2614       if test "$HAVE_GSETTINGS" = "yes"; then
2615         AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2616         SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2617         SETTINGS_LIBS="$GSETTINGS_LIBS"
2618       fi
2619       CFLAGS=$old_CFLAGS
2620       LIBS=$old_LIBS
2621    fi
2622 fi
2623
2624 dnl GConf has been tested under GNU/Linux only.
2625 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2626 HAVE_GCONF=no
2627 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2628    EMACS_CHECK_MODULES([GCONF], [gconf-2.0 >= 2.13])
2629    if test "$HAVE_GCONF" = yes; then
2630       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2631       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2632       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2633       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2634    fi
2635 fi
2636
2637 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2638     EMACS_CHECK_MODULES([GOBJECT], [gobject-2.0 >= 2.0])
2639     if test "$HAVE_GOBJECT" = "yes"; then
2640        SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GOBJECT_CFLAGS"
2641        SETTINGS_LIBS="$SETTINGS_LIBS $GOBJECT_LIBS"
2642     fi
2643     SAVE_CFLAGS="$CFLAGS"
2644     SAVE_LIBS="$LIBS"
2645     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2646     LIBS="$SETTINGS_LIBS $LIBS"
2647     CFLAGS="$SAVE_CFLAGS"
2648     LIBS="$SAVE_LIBS"
2649 fi
2650 AC_SUBST(SETTINGS_CFLAGS)
2651 AC_SUBST(SETTINGS_LIBS)
2652
2653
2654 dnl SELinux is available for GNU/Linux only.
2655 HAVE_LIBSELINUX=no
2656 LIBSELINUX_LIBS=
2657 if test "${with_selinux}" = "yes"; then
2658    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2659    if test "$HAVE_LIBSELINUX" = yes; then
2660       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2661       LIBSELINUX_LIBS=-lselinux
2662    fi
2663 fi
2664 AC_SUBST(LIBSELINUX_LIBS)
2665
2666 HAVE_GNUTLS=no
2667 if test "${with_gnutls}" = "yes" ; then
2668   EMACS_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6],
2669     [HAVE_GNUTLS=yes], [HAVE_GNUTLS=no])
2670   if test "${HAVE_GNUTLS}" = "yes"; then
2671     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2672     EMACS_CHECK_MODULES([LIBGNUTLS3], [gnutls >= 3.0.0],
2673       [AC_DEFINE(HAVE_GNUTLS3, 1, [Define if using GnuTLS v3.])], [])
2674   fi
2675
2676   # Windows loads GnuTLS dynamically
2677   if test "${opsys}" = "mingw32"; then
2678     LIBGNUTLS_LIBS=
2679   fi
2680 fi
2681
2682 AC_SUBST(LIBGNUTLS_LIBS)
2683 AC_SUBST(LIBGNUTLS_CFLAGS)
2684
2685 NOTIFY_OBJ=
2686 NOTIFY_SUMMARY=no
2687
2688 dnl FIXME?  Don't auto-detect on NS, but do allow someone to specify
2689 dnl a particular library.  This doesn't make much sense?
2690 if test "${with_ns}" = yes && test ${with_file_notification} = yes; then
2691   with_file_notification=no
2692 fi
2693
2694 dnl MS Windows native file monitor is available for mingw32 only.
2695 case $with_file_notification,$opsys in
2696   w32,cygwin)
2697     AC_MSG_ERROR([`--with-file-notification=w32' was specified, but
2698     this is only supported on MS-Windows native and MinGW32 builds.
2699     Consider using gfile instead.])
2700     ;;
2701   w32,* | yes,mingw32)
2702     AC_CHECK_HEADER(windows.h)
2703     if test "$ac_cv_header_windows_h" = yes ; then
2704        AC_DEFINE(HAVE_W32NOTIFY, 1, [Define to 1 to use w32notify.])
2705        NOTIFY_OBJ=w32notify.o
2706        NOTIFY_SUMMARY="yes (w32)"
2707     fi ;;
2708 esac
2709
2710 dnl g_file_monitor exists since glib 2.18.  G_FILE_MONITOR_EVENT_MOVED
2711 dnl has been added in glib 2.24.  It has been tested under
2712 dnl GNU/Linux only.  We take precedence over inotify, but this makes
2713 dnl only sense when glib has been compiled with inotify support.  How
2714 dnl to check?
2715 case $with_file_notification,$NOTIFY_OBJ in
2716   gfile, | yes,)
2717     EMACS_CHECK_MODULES([GFILENOTIFY], [gio-2.0 >= 2.24])
2718     if test "$HAVE_GFILENOTIFY" = "yes"; then
2719        AC_DEFINE(HAVE_GFILENOTIFY, 1, [Define to 1 if using GFile.])
2720        NOTIFY_OBJ=gfilenotify.o
2721        NOTIFY_SUMMARY="yes -lgio (gfile)"
2722     fi ;;
2723 esac
2724
2725 dnl inotify is only available on GNU/Linux.
2726 case $with_file_notification,$NOTIFY_OBJ in
2727   inotify, | yes,)
2728     AC_CHECK_HEADER(sys/inotify.h)
2729     if test "$ac_cv_header_sys_inotify_h" = yes ; then
2730         AC_CHECK_FUNC(inotify_init1)
2731         if test "$ac_cv_func_inotify_init1" = yes; then
2732           AC_DEFINE(HAVE_INOTIFY, 1, [Define to 1 to use inotify.])
2733           NOTIFY_OBJ=inotify.o
2734           NOTIFY_SUMMARY="yes -lglibc (inotify)"
2735        fi
2736     fi ;;
2737 esac
2738
2739 case $with_file_notification,$NOTIFY_OBJ in
2740   yes,* | no,* | *,?*) ;;
2741   *) AC_MSG_ERROR([File notification `$with_file_notification' requested but requirements not found.]) ;;
2742 esac
2743
2744 if test -n "$NOTIFY_OBJ"; then
2745    AC_DEFINE(USE_FILE_NOTIFY, 1, [Define to 1 if using file notifications.])
2746 fi
2747 AC_SUBST(NOTIFY_OBJ)
2748 AC_SUBST(GFILENOTIFY_CFLAGS)
2749 AC_SUBST(GFILENOTIFY_LIBS)
2750
2751 dnl Do not put whitespace before the #include statements below.
2752 dnl Older compilers (eg sunos4 cc) choke on it.
2753 HAVE_XAW3D=no
2754 LUCID_LIBW=
2755 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2756   if test "$with_xaw3d" != no; then
2757     AC_CACHE_VAL(emacs_cv_xaw3d,
2758     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2759 #include <X11/Intrinsic.h>
2760 #include <X11/Xaw3d/Simple.h>]],
2761       [[]])],
2762       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2763                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2764       emacs_cv_xaw3d=no)])
2765   else
2766     emacs_cv_xaw3d=no
2767   fi
2768   if test $emacs_cv_xaw3d = yes; then
2769     AC_MSG_CHECKING(for xaw3d)
2770     AC_MSG_RESULT([yes; using Lucid toolkit])
2771     USE_X_TOOLKIT=LUCID
2772     HAVE_XAW3D=yes
2773     LUCID_LIBW=-lXaw3d
2774     AC_DEFINE(HAVE_XAW3D, 1,
2775               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2776   else
2777     AC_MSG_CHECKING(for xaw3d)
2778     AC_MSG_RESULT(no)
2779     AC_MSG_CHECKING(for libXaw)
2780     AC_CACHE_VAL(emacs_cv_xaw,
2781     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2782 #include <X11/Intrinsic.h>
2783 #include <X11/Xaw/Simple.h>]],
2784       [[]])],
2785       emacs_cv_xaw=yes,
2786       emacs_cv_xaw=no)])
2787     if test $emacs_cv_xaw = yes; then
2788       AC_MSG_RESULT([yes; using Lucid toolkit])
2789       USE_X_TOOLKIT=LUCID
2790       LUCID_LIBW=-lXaw
2791     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2792       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2793     else
2794       AC_MSG_ERROR([No X toolkit could be found.
2795 If you are sure you want Emacs compiled without an X toolkit, pass
2796   --with-x-toolkit=no
2797 to configure.  Otherwise, install the development libraries for the toolkit
2798 that you want to use (e.g. Gtk+) and re-run configure.])
2799     fi
2800   fi
2801 fi
2802
2803 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2804
2805 LIBXTR6=
2806 LIBXMU=
2807 if test "${USE_X_TOOLKIT}" != "none"; then
2808   AC_MSG_CHECKING(X11 toolkit version)
2809   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2810   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2811 [[#if XtSpecificationRelease < 6
2812 fail;
2813 #endif
2814 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2815   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2816   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2817     AC_MSG_RESULT(6 or newer)
2818     AC_DEFINE(HAVE_X11XTR6, 1,
2819               [Define to 1 if you have the X11R6 or newer version of Xt.])
2820     LIBXTR6="-lSM -lICE"
2821     case "$opsys" in
2822       ## Use libw.a along with X11R6 Xt.
2823       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2824     esac
2825   else
2826     AC_MSG_RESULT(before 6)
2827   fi
2828
2829 dnl If using toolkit, check whether libXmu.a exists.
2830 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2831   OLDLIBS="$LIBS"
2832   if test x$HAVE_X11XTR6 = xyes; then
2833     OTHERLIBS='-lXt -lSM -lICE'
2834   else
2835     OTHERLIBS='-lXt'
2836   fi
2837   AC_SEARCH_LIBS([XmuConvertStandardSelection], [Xmu], [], [], [$OTHERLIBS])
2838   if test "X$LIBS" != "X$OLDLIBS"; then
2839     LIBXMU=$ac_cv_search_XmuConvertStandardSelection
2840   fi
2841   LIBS=$OLDLIBS
2842   dnl ac_cv_search_XmuConvertStandardSelection is also referenced below.
2843 fi
2844 AC_SUBST(LIBXTR6)
2845 AC_SUBST(LIBXMU)
2846
2847 LIBXP=
2848 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2849   # OpenMotif may be installed in such a way on some GNU/Linux systems.
2850   if test -d /usr/include/openmotif; then
2851     CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2852     emacs_cv_openmotif=yes
2853     case "$canonical" in
2854       x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2855       test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2856       ;;
2857       *)
2858       test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2859     esac
2860   else
2861     emacs_cv_openmotif=no
2862   fi
2863   AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2864   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2865     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2866 int x = 5;
2867 #else
2868 Motif version prior to 2.1.
2869 #endif]])],
2870     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2871   if test $emacs_cv_motif_version_2_1 = yes; then
2872     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2873     if test x$emacs_cv_openmotif = xyes; then
2874       REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2875     fi
2876   else
2877     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2878     # We put this in CFLAGS temporarily to precede other -I options
2879     # that might be in CFLAGS temporarily.
2880     # We put this in CPPFLAGS where it precedes the other -I options.
2881     OLD_CPPFLAGS=$CPPFLAGS
2882     OLD_CFLAGS=$CFLAGS
2883     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2884     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2885     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2886       [[int x = 5;]])],
2887       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2888     if test $emacs_cv_lesstif = yes; then
2889       # Make sure this -I option remains in CPPFLAGS after it is set
2890       # back to REAL_CPPFLAGS.
2891       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2892       # have those other -I options anyway.  Ultimately, having this
2893       # directory ultimately in CPPFLAGS will be enough.
2894       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2895       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2896     else
2897       CFLAGS=$OLD_CFLAGS
2898       CPPFLAGS=$OLD_CPPFLAGS
2899     fi
2900   fi
2901   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2902     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2903 fi
2904
2905 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2906 dnl using Motif or Xaw3d is available, and unless
2907 dnl --with-toolkit-scroll-bars=no was specified.
2908
2909 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2910             [Define to 1 if we should use toolkit scroll bars.])dnl
2911 USE_TOOLKIT_SCROLL_BARS=no
2912 if test "${with_toolkit_scroll_bars}" != "no"; then
2913   if test "${USE_X_TOOLKIT}" != "none"; then
2914     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2915       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2916       HAVE_XAW3D=no
2917       USE_TOOLKIT_SCROLL_BARS=yes
2918     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2919       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2920       USE_TOOLKIT_SCROLL_BARS=yes
2921     fi
2922   elif test "${HAVE_GTK}" = "yes"; then
2923     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2924     USE_TOOLKIT_SCROLL_BARS=yes
2925   elif test "${HAVE_NS}" = "yes"; then
2926     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2927     USE_TOOLKIT_SCROLL_BARS=yes
2928   elif test "${HAVE_W32}" = "yes"; then
2929     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2930     USE_TOOLKIT_SCROLL_BARS=yes
2931   fi
2932 fi
2933
2934 dnl See if XIM is available.
2935 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2936           #include <X11/Xlib.h>
2937           #include <X11/Xresource.h>]],
2938          [[XIMProc  callback;]])],
2939          [HAVE_XIM=yes
2940          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2941          HAVE_XIM=no)
2942
2943 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2944
2945 if test "${with_xim}" != "no"; then
2946   AC_DEFINE(USE_XIM, 1,
2947             [Define to 1 if we should use XIM, if it is available.])
2948 fi
2949
2950
2951 if test "${HAVE_XIM}" != "no"; then
2952   late_CFLAGS=$CFLAGS
2953   if test "$GCC" = yes; then
2954     CFLAGS="$CFLAGS --pedantic-errors"
2955   fi
2956   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2957 #include <X11/Xlib.h>
2958 #include <X11/Xresource.h>]],
2959 [[Display *display;
2960 XrmDatabase db;
2961 char *res_name;
2962 char *res_class;
2963 XIMProc  callback;
2964 XPointer *client_data;
2965 #ifndef __GNUC__
2966 /* If we're not using GCC, it's probably not XFree86, and this is
2967    probably right, but we can't use something like --pedantic-errors.  */
2968 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2969                                            char*, XIMProc, XPointer*);
2970 #endif
2971 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2972    client_data);]])],
2973     [emacs_cv_arg6_star=yes])
2974   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2975          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2976 either XPointer or XPointer*.])dnl
2977   if test "$emacs_cv_arg6_star" = yes; then
2978     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2979   else
2980     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2981   fi
2982   CFLAGS=$late_CFLAGS
2983 fi
2984
2985 ### Start of font-backend (under any platform) section.
2986 # (nothing here yet -- this is a placeholder)
2987 ### End of font-backend (under any platform) section.
2988
2989 ### Start of font-backend (under X11) section.
2990 if test "${HAVE_X11}" = "yes"; then
2991     ## Use -lXft if available, unless `--with-xft=no'.
2992     HAVE_XFT=maybe
2993     if test "x${with_x}" = "xno"; then
2994       with_xft="no";
2995     fi
2996
2997     if test "$with_xft" != no; then
2998       EMACS_CHECK_MODULES([FONTCONFIG], [fontconfig >= 2.2.0])
2999       with_xft=$HAVE_FONTCONFIG
3000     fi
3001
3002     if test "x${with_xft}" != "xno"; then
3003
3004       EMACS_CHECK_MODULES([XFT], [xft >= 0.13.0], [], [HAVE_XFT=no])
3005       ## Because xftfont.c uses XRenderQueryExtension, we also
3006       ## need to link to -lXrender.
3007       HAVE_XRENDER=no
3008       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
3009       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
3010         OLD_CPPFLAGS="$CPPFLAGS"
3011         OLD_CFLAGS="$CFLAGS"
3012         OLD_LIBS="$LIBS"
3013         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
3014         CFLAGS="$CFLAGS $XFT_CFLAGS"
3015         XFT_LIBS="-lXrender $XFT_LIBS"
3016         LIBS="$XFT_LIBS $LIBS"
3017         AC_CHECK_HEADER(X11/Xft/Xft.h,
3018           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS) , ,
3019           [[#include <X11/X.h>]])
3020
3021         if test "${HAVE_XFT}" = "yes"; then
3022           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
3023             AC_SUBST(XFT_LIBS)
3024           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
3025         fi                        # "${HAVE_XFT}" = "yes"
3026         CPPFLAGS=$OLD_CPPFLAGS
3027         CFLAGS=$OLD_CFLAGS
3028         LIBS=$OLD_LIBS
3029       fi                          # "$HAVE_XFT" != no
3030     fi                            # "x${with_xft}" != "xno"
3031
3032     ## We used to allow building with FreeType and without Xft.
3033     ## However, the ftx font backend driver is not in good shape.
3034     if test "$HAVE_XFT" != "yes"; then
3035        dnl For the "Does Emacs use" message at the end.
3036        HAVE_XFT=no
3037        HAVE_FREETYPE=no
3038     else
3039        dnl Strict linkers fail with
3040        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
3041        dnl if -lfreetype is not specified.
3042        dnl The following is needed to set FREETYPE_LIBS.
3043        EMACS_CHECK_MODULES([FREETYPE], [freetype2])
3044
3045        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
3046     fi
3047
3048     HAVE_LIBOTF=no
3049     if test "${HAVE_FREETYPE}" = "yes"; then
3050       AC_DEFINE(HAVE_FREETYPE, 1,
3051                 [Define to 1 if using the freetype and fontconfig libraries.])
3052       if test "${with_libotf}" != "no"; then
3053         EMACS_CHECK_MODULES([LIBOTF], [libotf])
3054         if test "$HAVE_LIBOTF" = "yes"; then
3055           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
3056           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
3057                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
3058                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
3059           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
3060             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
3061                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
3062           fi
3063         fi
3064       fi
3065     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
3066     dnl Does the new font backend require it, or can it work without it?
3067     fi
3068
3069     HAVE_M17N_FLT=no
3070     if test "${HAVE_LIBOTF}" = yes; then
3071       if test "${with_m17n_flt}" != "no"; then
3072         EMACS_CHECK_MODULES([M17N_FLT], [m17n-flt])
3073         if test "$HAVE_M17N_FLT" = "yes"; then
3074           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
3075         fi
3076       fi
3077     fi
3078 else
3079     HAVE_XFT=no
3080     HAVE_FREETYPE=no
3081     HAVE_LIBOTF=no
3082     HAVE_M17N_FLT=no
3083 fi
3084
3085 ### End of font-backend (under X11) section.
3086
3087 AC_SUBST(FREETYPE_CFLAGS)
3088 AC_SUBST(FREETYPE_LIBS)
3089 AC_SUBST(FONTCONFIG_CFLAGS)
3090 AC_SUBST(FONTCONFIG_LIBS)
3091 AC_SUBST(LIBOTF_CFLAGS)
3092 AC_SUBST(LIBOTF_LIBS)
3093 AC_SUBST(M17N_FLT_CFLAGS)
3094 AC_SUBST(M17N_FLT_LIBS)
3095
3096 ### Use -lXpm if available, unless `--with-xpm=no'.
3097 ### mingw32 doesn't use -lXpm, since it loads the library dynamically.
3098 ### In the Cygwin-w32 build, we need to use /usr/include/noX/X11/xpm.h
3099 ### rather than /usr/include/X11/xpm.h, so we set CPPFLAGS (and
3100 ### LDFLAGS) accordingly.
3101 HAVE_XPM=no
3102 LIBXPM=
3103 if test "${HAVE_W32}" = "yes" && test "${opsys}" = "cygwin"; then
3104   if test "${with_xpm}" != "no"; then
3105     SAVE_CPPFLAGS="$CPPFLAGS"
3106     SAVE_LDFLAGS="$LDFLAGS"
3107     CPPFLAGS="$CPPFLAGS -I/usr/include/noX"
3108     LDFLAGS="$LDFLAGS -L/usr/lib/noX"
3109     AC_CHECK_HEADER(X11/xpm.h,
3110       [AC_CHECK_LIB(Xpm, XpmReadFileToImage, HAVE_XPM=yes)])
3111     if test "${HAVE_XPM}" = "yes"; then
3112       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3113       AC_EGREP_CPP(no_return_alloc_pixels,
3114       [#include "X11/xpm.h"
3115 #ifndef XpmReturnAllocPixels
3116 no_return_alloc_pixels
3117 #endif
3118       ], HAVE_XPM=no, HAVE_XPM=yes)
3119
3120       if test "${HAVE_XPM}" = "yes"; then
3121         REAL_CPPFLAGS="$REAL_CPPFLAGS -I/usr/include/noX"
3122         AC_MSG_RESULT(yes)
3123       else
3124         AC_MSG_RESULT(no)
3125         CPPFLAGS="$SAVE_CPPFLAGS"
3126         LDFLAGS="$SAVE_LDFLAGS"
3127       fi
3128     fi
3129   fi
3130
3131   if test "${HAVE_XPM}" = "yes"; then
3132     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3133     LIBXPM=-lXpm
3134   fi
3135 fi
3136
3137 if test "${HAVE_X11}" = "yes"; then
3138   dnl Avoid Xpm on AIX unless requested, as it crashes; see Bug#17598.
3139   test "$opsys$with_xpm_set" = aix4-2 && with_xpm=no
3140
3141   if test "${with_xpm}" != "no"; then
3142     AC_CHECK_HEADER(X11/xpm.h,
3143       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
3144     if test "${HAVE_XPM}" = "yes"; then
3145       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3146       AC_EGREP_CPP(no_return_alloc_pixels,
3147       [#include "X11/xpm.h"
3148 #ifndef XpmReturnAllocPixels
3149 no_return_alloc_pixels
3150 #endif
3151       ], HAVE_XPM=no, HAVE_XPM=yes)
3152
3153       if test "${HAVE_XPM}" = "yes"; then
3154         AC_MSG_RESULT(yes)
3155       else
3156         AC_MSG_RESULT(no)
3157       fi
3158     fi
3159   fi
3160
3161   if test "${HAVE_XPM}" = "yes"; then
3162     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3163     LIBXPM=-lXpm
3164   elif test "$opsys,$LUCID_LIBW" = aix4-2,-lXaw; then
3165     dnl AIX -lXaw needs -lXpm linked too; see Bug#17598 Message#152.
3166     LIBXPM=-lXpm
3167   fi
3168 fi
3169
3170 ### FIXME: Perhaps regroup to minimize code duplication due to MinGW's
3171 ### slightly different requirements wrt image libraries (it doesn't
3172 ### use -lXpm because it loads the xpm shared library dynamically at
3173 ### run time).
3174 if test "${opsys}" = "mingw32"; then
3175   if test "${with_xpm}" != "no"; then
3176     AC_CHECK_HEADER(X11/xpm.h, HAVE_XPM=yes, HAVE_XPM=no, [
3177 #define FOR_MSW 1])
3178   fi
3179
3180   if test "${HAVE_XPM}" = "yes"; then
3181     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3182   fi
3183 fi
3184
3185 AC_SUBST(LIBXPM)
3186
3187 ### Use -ljpeg if available, unless `--with-jpeg=no'.
3188 ### mingw32 doesn't use -ljpeg, since it loads the library dynamically.
3189 HAVE_JPEG=no
3190 LIBJPEG=
3191 if test "${opsys}" = "mingw32"; then
3192   if test "${with_jpeg}" != "no"; then
3193     dnl Checking for jpeglib.h can lose because of a redefinition of
3194     dnl HAVE_STDLIB_H.
3195     AC_CHECK_HEADER(jerror.h, HAVE_JPEG=yes, HAVE_JPEG=no)
3196   fi
3197   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
3198   if test "${HAVE_JPEG}" = "yes"; then
3199     AC_DEFINE(HAVE_JPEG)
3200     AC_EGREP_CPP([version 6b or later],
3201         [#include <jpeglib.h>
3202          #if JPEG_LIB_VERSION >= 62
3203          version 6b or later
3204          #endif
3205         ],
3206         [AC_DEFINE(HAVE_JPEG)],
3207         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
3208         HAVE_JPEG=no])
3209   fi
3210 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3211   if test "${with_jpeg}" != "no"; then
3212     dnl Checking for jpeglib.h can lose because of a redefinition of
3213     dnl  HAVE_STDLIB_H.
3214     AC_CHECK_HEADER(jerror.h,
3215       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
3216   fi
3217
3218   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
3219   if test "${HAVE_JPEG}" = "yes"; then
3220     AC_DEFINE(HAVE_JPEG)
3221     AC_EGREP_CPP([version 6b or later],
3222         [#include <jpeglib.h>
3223          #if JPEG_LIB_VERSION >= 62
3224          version 6b or later
3225          #endif
3226         ],
3227         [AC_DEFINE(HAVE_JPEG)],
3228         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
3229         HAVE_JPEG=no])
3230   fi
3231   if test "${HAVE_JPEG}" = "yes"; then
3232     LIBJPEG=-ljpeg
3233   fi
3234 fi
3235 AC_SUBST(LIBJPEG)
3236
3237 HAVE_ZLIB=no
3238 LIBZ=
3239 if test "${with_zlib}" != "no"; then
3240   OLIBS=$LIBS
3241   AC_SEARCH_LIBS([inflateEnd], [z], [HAVE_ZLIB=yes])
3242   LIBS=$OLIBS
3243   case $ac_cv_search_inflateEnd in
3244     -*) LIBZ=$ac_cv_search_inflateEnd ;;
3245   esac
3246 fi
3247 if test "${HAVE_ZLIB}" = "yes"; then
3248   AC_DEFINE([HAVE_ZLIB], 1, [Define to 1 if you have the zlib library (-lz).])
3249   ### mingw32 doesn't use -lz, since it loads the library dynamically.
3250   if test "${opsys}" = "mingw32"; then
3251      LIBZ=
3252   fi
3253 fi
3254 AC_SUBST(LIBZ)
3255
3256 ### Use -lpng if available, unless `--with-png=no'.
3257 HAVE_PNG=no
3258 LIBPNG=
3259 PNG_CFLAGS=
3260 if test "${NS_IMPL_COCOA}" = yes; then
3261   : # Nothing to do
3262 elif test "${with_png}" != no; then
3263   # mingw32 loads the library dynamically.
3264   if test "$opsys" = mingw32; then
3265     AC_CHECK_HEADER([png.h], [HAVE_PNG=yes])
3266   elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3267     AC_MSG_CHECKING([for png])
3268     png_cflags=`(libpng-config --cflags) 2>&AS_MESSAGE_LOG_FD` &&
3269     png_libs=`(libpng-config --libs) 2>&AS_MESSAGE_LOG_FD` || {
3270       # libpng-config does not work; configure by hand.
3271       # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
3272       # in /usr/include/libpng.
3273       if test -r /usr/include/libpng/png.h &&
3274          test ! -r /usr/include/png.h; then
3275         png_cflags=-I/usr/include/libpng
3276       else
3277         png_cflags=
3278       fi
3279       png_libs='-lpng'
3280     }
3281     SAVE_CFLAGS=$CFLAGS
3282     SAVE_LIBS=$LIBS
3283     CFLAGS="$CFLAGS $png_cflags"
3284     LIBS="$png_libs -lz -lm $LIBS"
3285     AC_LINK_IFELSE(
3286       [AC_LANG_PROGRAM([[#include <png.h>]],
3287          [[return !png_get_channels (0, 0);]])],
3288       [HAVE_PNG=yes
3289        PNG_CFLAGS=`AS_ECHO(["$png_cflags"]) | sed -e "$edit_cflags"`
3290        LIBPNG=$png_libs
3291        # $LIBPNG requires explicit -lz in some cases.
3292        # We don't know what those cases are, exactly, so play it safe and
3293        # append -lz to any nonempty $LIBPNG, unless we're already using LIBZ.
3294        if test -n "$LIBPNG" && test -z "$LIBZ"; then
3295          LIBPNG="$LIBPNG -lz"
3296        fi])
3297     CFLAGS=$SAVE_CFLAGS
3298     LIBS=$SAVE_LIBS
3299     AC_MSG_RESULT([$HAVE_PNG])
3300   fi
3301 fi
3302 if test $HAVE_PNG = yes; then
3303   AC_DEFINE([HAVE_PNG], [1], [Define to 1 if you have the png library.])
3304
3305   SAVE_CFLAGS=$CFLAGS
3306   CFLAGS="$CFLAGS $PNG_CFLAGS"
3307   AC_CHECK_DECL([png_longjmp],
3308     [],
3309     [AC_DEFINE([PNG_DEPSTRUCT], [],
3310        [Define to empty to suppress deprecation warnings when building
3311         with --enable-gcc-warnings and with libpng versions before 1.5,
3312         which lack png_longjmp.])],
3313     [[#include <png.h>
3314     ]])
3315   CFLAGS=$SAVE_CFLAGS
3316 fi
3317 AC_SUBST(LIBPNG)
3318 AC_SUBST(PNG_CFLAGS)
3319
3320 ### Use -ltiff if available, unless `--with-tiff=no'.
3321 ### mingw32 doesn't use -ltiff, since it loads the library dynamically.
3322 HAVE_TIFF=no
3323 LIBTIFF=
3324 if test "${opsys}" = "mingw32"; then
3325   if test "${with_tiff}" != "no"; then
3326     AC_CHECK_HEADER(tiffio.h, HAVE_TIFF=yes, HAVE_TIFF=no)
3327   fi
3328   if test "${HAVE_TIFF}" = "yes"; then
3329     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3330   fi
3331 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3332   if test "${with_tiff}" != "no"; then
3333     AC_CHECK_HEADER(tiffio.h,
3334       [tifflibs="-lz -lm"
3335       # At least one tiff package requires the jpeg library.
3336       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
3337       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
3338   fi
3339
3340   if test "${HAVE_TIFF}" = "yes"; then
3341     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3342     dnl FIXME -lz -lm, as per libpng?
3343     LIBTIFF=-ltiff
3344   fi
3345 fi
3346 AC_SUBST(LIBTIFF)
3347
3348 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
3349 ### mingw32 doesn't use -lgif/-lungif, since it loads the library dynamically.
3350 HAVE_GIF=no
3351 LIBGIF=
3352 if test "${opsys}" = "mingw32"; then
3353   if test "${with_gif}" != "no"; then
3354     AC_CHECK_HEADER(gif_lib.h, HAVE_GIF=yes, HAVE_GIF=no)
3355   fi
3356   if test "${HAVE_GIF}" = "yes"; then
3357     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3358   fi
3359 elif test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no" \
3360         || test "${HAVE_W32}" = "yes"; then
3361   AC_CHECK_HEADER(gif_lib.h,
3362 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
3363 # Earlier versions can crash Emacs, but version 5.0 removes EGifPutExtensionLast.
3364     [AC_CHECK_LIB(gif, GifMakeMapObject, HAVE_GIF=yes,
3365         [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])])
3366
3367   if test "$HAVE_GIF" = yes; then
3368     LIBGIF=-lgif
3369   elif test "$HAVE_GIF" = maybe; then
3370 # If gif_lib.h but no libgif, try libungif.
3371     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
3372     test "$HAVE_GIF" = yes && LIBGIF=-lungif
3373   fi
3374
3375   if test "${HAVE_GIF}" = "yes"; then
3376     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3377   fi
3378 fi
3379 AC_SUBST(LIBGIF)
3380
3381 dnl Check for required libraries.
3382 if test "${HAVE_X11}" = "yes"; then
3383   MISSING=""
3384   WITH_NO=""
3385   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
3386     MISSING="libXpm" && WITH_NO="--with-xpm=no"
3387   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
3388     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
3389   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
3390     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
3391   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
3392     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
3393   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
3394     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
3395
3396   if test "X${MISSING}" != X; then
3397     AC_MSG_ERROR([The following required libraries were not found:
3398     $MISSING
3399 Maybe some development libraries/packages are missing?
3400 If you don't want to link with them give
3401     $WITH_NO
3402 as options to configure])
3403   fi
3404 fi
3405
3406 ### Use -lgpm if available, unless `--with-gpm=no'.
3407 HAVE_GPM=no
3408 LIBGPM=
3409 if test "${with_gpm}" != "no"; then
3410   AC_CHECK_HEADER(gpm.h,
3411     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
3412
3413   if test "${HAVE_GPM}" = "yes"; then
3414     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
3415     LIBGPM=-lgpm
3416   fi
3417 fi
3418 AC_SUBST(LIBGPM)
3419
3420 dnl Check for malloc/malloc.h on darwin
3421 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
3422
3423 GNUSTEP_CFLAGS=
3424 ### Use NeXTstep API to implement GUI.
3425 if test "${HAVE_NS}" = "yes"; then
3426   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
3427   if test "${NS_IMPL_COCOA}" = "yes"; then
3428     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
3429   fi
3430   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
3431     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
3432     if test $NS_GNUSTEP_CONFIG != yes; then
3433       # See also .m.o rule in src/Makefile.in.  */
3434       # FIXME: are all these flags really needed?  Document here why.  */
3435       GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
3436       ## Extra CFLAGS applied to src/*.m files.
3437       GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
3438     fi
3439   fi
3440   OTHER_FILES=ns-app
3441 fi
3442
3443 ### Use session management (-lSM -lICE) if available
3444 HAVE_X_SM=no
3445 LIBXSM=
3446 if test "${HAVE_X11}" = "yes"; then
3447   AC_CHECK_HEADER(X11/SM/SMlib.h,
3448     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
3449
3450   if test "${HAVE_X_SM}" = "yes"; then
3451     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
3452     LIBXSM="-lSM -lICE"
3453   fi
3454 fi
3455 AC_SUBST(LIBXSM)
3456
3457 ### Use XRandr (-lXrandr) if available
3458 HAVE_XRANDR=no
3459 if test "${HAVE_X11}" = "yes"; then
3460   XRANDR_REQUIRED=1.2.2
3461   XRANDR_MODULES="xrandr >= $XRANDR_REQUIRED"
3462   EMACS_CHECK_MODULES([XRANDR], [$XRANDR_MODULES])
3463   if test $HAVE_XRANDR = no; then
3464     # Test old way in case pkg-config doesn't have it (older machines).
3465     # Include Xrender.h by hand to work around bug in older Xrandr.h
3466     # (e.g. RHEL5) and silence (harmless) configure warning (bug#18465).
3467     AC_CHECK_HEADER(X11/extensions/Xrandr.h,
3468       [AC_CHECK_LIB(Xrandr, XRRGetScreenResources, HAVE_XRANDR=yes)],
3469       [], [AC_INCLUDES_DEFAULT
3470 #include <X11/extensions/Xrender.h>])
3471     if test $HAVE_XRANDR = yes; then
3472       XRANDR_LIBS=-lXrandr
3473     fi
3474   fi
3475   if test $HAVE_XRANDR = yes; then
3476     SAVE_CFLAGS="$CFLAGS"
3477     SAVE_LIBS="$LIBS"
3478     CFLAGS="$XRANDR_CFLAGS $CFLAGS"
3479     LIBS="$XRANDR_LIBS $LIBS"
3480     AC_CHECK_FUNCS(XRRGetOutputPrimary XRRGetScreenResourcesCurrent)
3481     CFLAGS="$SAVE_CFLAGS"
3482     LIBS="$SAVE_LIBS"
3483
3484     AC_DEFINE(HAVE_XRANDR, 1, [Define to 1 if you have the XRandr extension.])
3485   fi
3486 fi
3487 AC_SUBST(XRANDR_CFLAGS)
3488 AC_SUBST(XRANDR_LIBS)
3489
3490 ### Use Xinerama (-lXinerama) if available
3491 HAVE_XINERAMA=no
3492 if test "${HAVE_X11}" = "yes"; then
3493   XINERAMA_REQUIRED=1.0.2
3494   XINERAMA_MODULES="xinerama >= $XINERAMA_REQUIRED"
3495   EMACS_CHECK_MODULES([XINERAMA], [$XINERAMA_MODULES])
3496   if test $HAVE_XINERAMA = no; then
3497     # Test old way in case pkg-config doesn't have it (older machines).
3498     AC_CHECK_HEADER(X11/extensions/Xinerama.h,
3499       [AC_CHECK_LIB(Xinerama, XineramaQueryExtension, HAVE_XINERAMA=yes)])
3500     if test $HAVE_XINERAMA = yes; then
3501       XINERAMA_LIBS=-lXinerama
3502     fi
3503   fi
3504   if test $HAVE_XINERAMA = yes; then
3505     AC_DEFINE(HAVE_XINERAMA, 1, [Define to 1 if you have the Xinerama extension.])
3506   fi
3507 fi
3508 AC_SUBST(XINERAMA_CFLAGS)
3509 AC_SUBST(XINERAMA_LIBS)
3510
3511 ### Use Xfixes (-lXfixes) if available
3512 HAVE_XFIXES=no
3513 if test "${HAVE_X11}" = "yes"; then
3514   XFIXES_REQUIRED=4.0.0
3515   XFIXES_MODULES="xfixes >= $XFIXES_REQUIRED"
3516   EMACS_CHECK_MODULES([XFIXES], [$XFIXES_MODULES])
3517   if test $HAVE_XFIXES = no; then
3518     # Test old way in case pkg-config doesn't have it (older machines).
3519     AC_CHECK_HEADER(X11/extensions/Xfixes.h,
3520       [AC_CHECK_LIB(Xfixes, XFixesHideCursor, HAVE_XFIXES=yes)])
3521     if test $HAVE_XFIXES = yes; then
3522       XFIXES_LIBS=-lXfixes
3523     fi
3524   fi
3525   if test $HAVE_XFIXES = yes; then
3526     AC_DEFINE(HAVE_XFIXES, 1, [Define to 1 if you have the Xfixes extension.])
3527   fi
3528 fi
3529 AC_SUBST(XFIXES_CFLAGS)
3530 AC_SUBST(XFIXES_LIBS)
3531
3532 ### Use libxml (-lxml2) if available
3533 ### mingw32 doesn't use -lxml2, since it loads the library dynamically.
3534 HAVE_LIBXML2=no
3535 if test "${with_xml2}" != "no"; then
3536   ### I'm not sure what the version number should be, so I just guessed.
3537   EMACS_CHECK_MODULES([LIBXML2], [libxml-2.0 > 2.6.17])
3538   # Built-in libxml2 on OS X 10.8 lacks libxml-2.0.pc.
3539   if test "${HAVE_LIBXML2}" != "yes" && test "$opsys" = "darwin"; then
3540     SAVE_CPPFLAGS="$CPPFLAGS"
3541     CPPFLAGS="$CPPFLAGS -I$xcsdkdir/usr/include/libxml2"
3542     AC_CHECK_HEADER(libxml/HTMLparser.h,
3543       [AC_CHECK_DECL(HTML_PARSE_RECOVER, HAVE_LIBXML2=yes, ,
3544                      [#include <libxml/HTMLparser.h>])])
3545     CPPFLAGS="$SAVE_CPPFLAGS"
3546     if test "${HAVE_LIBXML2}" = "yes"; then
3547       LIBXML2_CFLAGS="-I'$xcsdkdir/usr/include/libxml2'"
3548       LIBXML2_LIBS="-lxml2"
3549     fi
3550   fi
3551   if test "${HAVE_LIBXML2}" = "yes"; then
3552     if test "${opsys}" != "mingw32"; then
3553       AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no,
3554         [$LIBXML2_LIBS])
3555     else
3556       LIBXML2_LIBS=""
3557     fi
3558     if test "${HAVE_LIBXML2}" = "yes"; then
3559       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
3560     else
3561       LIBXML2_LIBS=""
3562       LIBXML2_CFLAGS=""
3563     fi
3564   fi
3565 fi
3566 AC_SUBST(LIBXML2_LIBS)
3567 AC_SUBST(LIBXML2_CFLAGS)
3568
3569 # If netdb.h doesn't declare h_errno, we must declare it by hand.
3570 # On MinGW, that is provided by nt/inc/sys/socket.h and w32.c.
3571 if test "${opsys}" = "mingw32"; then
3572   emacs_cv_netdb_declares_h_errno=yes
3573 fi
3574 AC_CACHE_CHECK(whether netdb declares h_errno,
3575                emacs_cv_netdb_declares_h_errno,
3576 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
3577   [[return h_errno;]])],
3578   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
3579 if test $emacs_cv_netdb_declares_h_errno = yes; then
3580   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
3581 fi
3582
3583 # Check for mail-locking functions in a "mail" library.  Probably this should
3584 # have the same check as for liblockfile below.
3585 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
3586 if test $have_mail = yes; then
3587   LIBS_MAIL=-lmail
3588   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
3589
3590   OLD_LIBS=$LIBS
3591   LIBS="$LIBS_MAIL $LIBS"
3592   AC_CHECK_FUNCS(touchlock)
3593   LIBS=$OLD_LIBS
3594 else
3595   LIBS_MAIL=
3596 fi
3597 dnl Debian, at least:
3598 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
3599 if test $have_lockfile = yes; then
3600    LIBS_MAIL=-llockfile
3601    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
3602 else
3603 # If we have the shared liblockfile, assume we must use it for mail
3604 # locking (e.g. Debian).  If we couldn't link against liblockfile
3605 # (no liblockfile.a installed), ensure that we don't need to.
3606   dnl This works for files generally, not just executables.
3607   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
3608   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
3609                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
3610   if test $ac_cv_prog_liblockfile = yes; then
3611     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
3612 This probably means that movemail could lose mail.
3613 There may be a `development' package to install containing liblockfile.])
3614   fi
3615 fi
3616 AC_CHECK_HEADERS_ONCE(maillock.h)
3617 AC_SUBST(LIBS_MAIL)
3618
3619 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
3620 ## interlock access to the mail spool.  The alternative is a lock file named
3621 ## /usr/spool/mail/$USER.lock.
3622 mail_lock=no
3623 case "$opsys" in
3624   aix4-2) mail_lock="lockf" ;;
3625
3626   gnu|freebsd|dragonfly|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
3627
3628   ## On GNU/Linux systems, both methods are used by various mail programs.
3629   ## I assume most people are using newer mailers that have heard of flock.
3630   ## Change this if you need to.
3631   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
3632   ## configure gets the right answers, and that means *NOT* using flock.
3633   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
3634   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
3635   ## Debian maintainer hasn't provided a clean fix for Emacs.
3636   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
3637   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
3638   ## correct logic.  -- fx
3639   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
3640   ## liblockfile is a Free Software replacement for libmail, used on
3641   ## Debian systems and elsewhere. -rfr.
3642   gnu-*)
3643     mail_lock="flock"
3644     if test $have_mail = yes || test $have_lockfile = yes; then
3645       test $ac_cv_header_maillock_h = yes && mail_lock=no
3646     fi
3647     ;;
3648
3649   mingw32)
3650     mail_lock="none-needed" ;;
3651 esac
3652
3653 BLESSMAIL_TARGET=
3654 case "$mail_lock" in
3655   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
3656
3657   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
3658
3659   none-needed) ;;
3660
3661   *) BLESSMAIL_TARGET="need-blessmail" ;;
3662 esac
3663 AC_SUBST(BLESSMAIL_TARGET)
3664
3665 OLD_LIBS=$LIBS
3666 LIBS="$LIB_PTHREAD $LIB_MATH $LIBS"
3667 AC_CHECK_FUNCS(accept4 fchdir gethostname \
3668 getrusage get_current_dir_name \
3669 lrand48 random rint \
3670 select getpagesize setlocale newlocale \
3671 getrlimit setrlimit shutdown getaddrinfo \
3672 pthread_sigmask strsignal setitimer \
3673 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
3674 gai_strerror sync \
3675 getpwent endpwent getgrent endgrent \
3676 cfmakeraw cfsetspeed copysign __executable_start log2)
3677 LIBS=$OLD_LIBS
3678
3679 dnl No need to check for aligned_alloc and posix_memalign if using
3680 dnl gmalloc.o, as it supplies them, unless we're using hybrid_malloc.
3681 dnl Don't use these functions on Darwin as they are incompatible with
3682 dnl unexmacosx.c.
3683 if (test -z "$GMALLOC_OBJ" || test "$hybrid_malloc" = yes) \
3684   && test "$opsys" != darwin; then
3685   AC_CHECK_FUNCS([aligned_alloc posix_memalign], [break])
3686 fi
3687
3688 dnl Cannot use AC_CHECK_FUNCS
3689 AC_CACHE_CHECK([for __builtin_unwind_init],
3690                emacs_cv_func___builtin_unwind_init,
3691 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
3692                 emacs_cv_func___builtin_unwind_init=yes,
3693                 emacs_cv_func___builtin_unwind_init=no)])
3694 if test $emacs_cv_func___builtin_unwind_init = yes; then
3695   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
3696             [Define to 1 if you have the `__builtin_unwind_init' function.])
3697 fi
3698
3699 AC_CHECK_HEADERS_ONCE(sys/un.h)
3700
3701 AC_FUNC_FSEEKO
3702
3703 # UNIX98 PTYs.
3704 AC_CHECK_FUNCS(grantpt)
3705
3706 # PTY-related GNU extensions.
3707 AC_CHECK_FUNCS(getpt posix_openpt)
3708
3709 # Check this now, so that we will NOT find the above functions in ncurses.
3710 # That is because we have not set up to link ncurses in lib-src.
3711 # It's better to believe a function is not available
3712 # than to expect to find it in ncurses.
3713 # Also we need tputs and friends to be able to build at all.
3714 AC_MSG_CHECKING([for library containing tputs])
3715 # Run a test program that contains a call to tputs, a call that is
3716 # never executed.  This tests whether a pre-'main' dynamic linker
3717 # works with the library.  It's too much trouble to actually call
3718 # tputs in the test program, due to portability hassles.  When
3719 # cross-compiling, assume the test program will run if it links.
3720 AC_DEFUN([tputs_link_source], [
3721   AC_LANG_SOURCE(
3722      [[extern void tputs (const char *, int, int (*)(int));
3723        int main (int argc, char **argv)
3724        {
3725           if (argc == 10000)
3726             tputs (argv[0], 0, 0);
3727           return 0;
3728        }]])
3729 ])
3730 if test "${opsys}" = "mingw32"; then
3731   msg='none required'
3732 else
3733   # Maybe curses should be tried earlier?
3734   # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
3735   for tputs_library in '' tinfo ncurses terminfo termcap curses; do
3736     OLIBS=$LIBS
3737     if test -z "$tputs_library"; then
3738       LIBS_TERMCAP=
3739       msg='none required'
3740     else
3741       LIBS_TERMCAP=-l$tputs_library
3742       msg=$LIBS_TERMCAP
3743       LIBS="$LIBS_TERMCAP $LIBS"
3744     fi
3745     AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
3746       [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
3747     LIBS=$OLIBS
3748     if test "X$msg" != Xno; then
3749       break
3750     fi
3751   done
3752 fi
3753 AC_MSG_RESULT([$msg])
3754 if test "X$msg" = Xno; then
3755   AC_MSG_ERROR([The required function `tputs' was not found in any library.
3756 The following libraries were tried (in order):
3757   libtinfo, libncurses, libterminfo, libtermcap, libcurses
3758 Please try installing whichever of these libraries is most appropriate
3759 for your system, together with its header files.
3760 For example, a libncurses-dev(el) or similar package.])
3761 fi
3762
3763 ## Use termcap instead of terminfo?
3764 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
3765 TERMINFO=yes
3766 ## FIXME?  In the cases below where we unconditionally set
3767 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
3768 ## if that was found above to have tputs.
3769 ## Should we use the gnu* logic everywhere?
3770 case "$opsys" in
3771   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
3772   ##  The ncurses library has been moved out of the System framework in
3773   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
3774   ##  option to use it.
3775   darwin) LIBS_TERMCAP="-lncurses" ;;
3776
3777   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
3778
3779   freebsd)
3780     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
3781     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
3782     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
3783 [[#if __FreeBSD_version < 400000
3784 fail;
3785 #endif
3786 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
3787
3788     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
3789
3790     if test $emacs_cv_freebsd_terminfo = yes; then
3791       LIBS_TERMCAP="-lncurses"
3792     else
3793       TERMINFO=no
3794       LIBS_TERMCAP="-ltermcap"
3795     fi
3796     ;;
3797
3798   mingw32)
3799     TERMINFO=no
3800     LIBS_TERMCAP=
3801     ;;
3802
3803   netbsd)
3804     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
3805       TERMINFO=no
3806       LIBS_TERMCAP="-ltermcap"
3807     fi
3808     ;;
3809
3810   openbsd | dragonfly) LIBS_TERMCAP="-lncurses" ;;
3811
3812   ## hpux: Make sure we get select from libc rather than from libcurses
3813   ##  because libcurses on HPUX 10.10 has a broken version of select.
3814   ##  We used to use -lc -lcurses, but this may be cleaner.
3815   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
3816   # set that way, now it uses the default).  Isn't this a contradiction?
3817   hpux*) LIBS_TERMCAP="-ltermcap" ;;
3818
3819 esac
3820
3821 TERMCAP_OBJ=tparam.o
3822 if test $TERMINFO = yes; then
3823   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
3824   TERMCAP_OBJ=terminfo.o
3825 fi
3826 if test "X$LIBS_TERMCAP" = "X-lncurses"; then
3827   AC_DEFINE(USE_NCURSES, 1, [Define to 1 if you use ncurses.])
3828 fi
3829 AC_SUBST(LIBS_TERMCAP)
3830 AC_SUBST(TERMCAP_OBJ)
3831
3832 # GNU/Linux-specific timer functions.
3833 AC_CACHE_CHECK([for timerfd interface], [emacs_cv_have_timerfd],
3834   [AC_COMPILE_IFELSE(
3835      [AC_LANG_PROGRAM([[#include <sys/timerfd.h>
3836                       ]],
3837                       [[timerfd_create (CLOCK_REALTIME,
3838                                         TFD_CLOEXEC | TFD_NONBLOCK);
3839                         timerfd_settime (0, TFD_TIMER_ABSTIME, 0, 0);]])],
3840      [emacs_cv_have_timerfd=yes],
3841      [emacs_cv_have_timerfd=no])])
3842 if test "$emacs_cv_have_timerfd" = yes; then
3843   AC_DEFINE([HAVE_TIMERFD], 1,
3844     [Define to 1 if timerfd functions are supported as in GNU/Linux.])
3845 fi
3846
3847 # Alternate stack for signal handlers.
3848 AC_CACHE_CHECK([whether signals can be handled on alternate stack],
3849                [emacs_cv_alternate_stack],
3850   [AC_COMPILE_IFELSE(
3851      [AC_LANG_PROGRAM([[#include <signal.h>
3852                       ]],
3853                       [[stack_t ss;
3854                         struct sigaction sa;
3855                         ss.ss_sp = malloc (SIGSTKSZ);
3856                         ss.ss_size = SIGSTKSZ;
3857                         sa.sa_flags = SA_SIGINFO | SA_ONSTACK;
3858                         sigaltstack (&ss, 0);
3859                         sigaction (SIGSEGV, &sa, 0);]])],
3860      [emacs_cv_alternate_stack=yes],
3861      [emacs_cv_alternate_stack=no])])
3862
3863 # Do we have res_init, for detecting changes in /etc/resolv.conf?
3864 # On Darwin, res_init appears not to be useful: see bug#562 and
3865 # http://lists.gnu.org/archive/html/emacs-devel/2007-11/msg01467.html
3866 resolv=no
3867
3868 if test $opsys != darwin; then
3869
3870   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3871 #include <arpa/nameser.h>
3872 #include <resolv.h>]],
3873     [[return res_init();]])],
3874     have_res_init=yes, have_res_init=no)
3875   if test "$have_res_init" = no; then
3876     OLIBS="$LIBS"
3877     LIBS="$LIBS -lresolv"
3878     AC_MSG_CHECKING(for res_init with -lresolv)
3879     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3880 #include <arpa/nameser.h>
3881 #include <resolv.h>]],
3882       [[return res_init();]])],
3883       have_res_init=yes, have_res_init=no)
3884     AC_MSG_RESULT($have_res_init)
3885     if test "$have_res_init" = yes ; then
3886       resolv=yes
3887     fi
3888     LIBS="$OLIBS"
3889   fi
3890
3891   if test "$have_res_init" = yes; then
3892     AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
3893   fi
3894 fi                              dnl !darwin
3895
3896 # Do we need the Hesiod library to provide the support routines?
3897 dnl FIXME?  Should we be skipping this on Darwin too?
3898 LIBHESIOD=
3899 if test "$with_hesiod" != no ; then
3900   # Don't set $LIBS here -- see comments above.  FIXME which comments?
3901   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
3902      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
3903                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
3904   if test "$resolv" = yes ; then
3905     RESOLVLIB=-lresolv
3906   else
3907     RESOLVLIB=
3908   fi
3909   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
3910         hesiod=yes, :, $RESOLVLIB)])
3911
3912   if test x"$hesiod" = xyes; then
3913     LIBHESIOD=-lhesiod
3914   fi
3915 fi
3916 AC_SUBST(LIBHESIOD)
3917
3918 # Do we need libresolv (due to res_init or Hesiod)?
3919 if test "$resolv" = yes && test $opsys != darwin; then
3920   LIBRESOLV=-lresolv
3921 else
3922   LIBRESOLV=
3923 fi
3924 AC_SUBST(LIBRESOLV)
3925
3926 # These tell us which Kerberos-related libraries to use.
3927 COM_ERRLIB=
3928 CRYPTOLIB=
3929 KRB5LIB=
3930 DESLIB=
3931 KRB4LIB=
3932
3933 if test "${with_kerberos}" != no; then
3934   OLD_LIBS=$LIBS
3935   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
3936   if test $have_com_err = yes; then
3937     COM_ERRLIB=-lcom_err
3938     LIBS="$COM_ERRLIB $LIBS"
3939   fi
3940   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
3941   if test $have_crypto = yes; then
3942     CRYPTOLIB=-lcrypto
3943     LIBS="$CRYPTOLIB $LIBS"
3944   fi
3945   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
3946   if test $have_k5crypto = yes; then
3947     CRYPTOLIB=-lk5crypto
3948     LIBS="$CRYPTOLIB $LIBS"
3949   fi
3950   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
3951   if test $have_krb5=yes; then
3952     KRB5LIB=-lkrb5
3953     LIBS="$KRB5LIB $LIBS"
3954   fi
3955   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
3956   if test "${with_kerberos5}" = no; then
3957     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
3958     if test $have_des425 = yes; then
3959       DESLIB=-ldes425
3960       LIBS="$DESLIB $LIBS"
3961     else
3962       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
3963       if test $have_des = yes; then
3964         DESLIB=-ldes
3965         LIBS="$DESLIB $LIBS"
3966       fi
3967     fi
3968     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
3969     if test $have_krb4 = yes; then
3970       KRB4LIB=-lkrb4
3971       LIBS="$KRB4LIB $LIBS"
3972     else
3973       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
3974       if test $have_krb = yes; then
3975         KRB4LIB=-lkrb
3976         LIBS="$KRB4LIB $LIBS"
3977       fi
3978     fi
3979   fi
3980
3981   if test "${with_kerberos5}" != no; then
3982     AC_CHECK_HEADERS(krb5.h,
3983       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
3984                         [#include <krb5.h>])])
3985   else
3986     AC_CHECK_HEADERS(krb.h,,
3987                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
3988                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
3989   fi
3990   AC_CHECK_HEADERS(com_err.h)
3991   LIBS=$OLD_LIBS
3992 fi
3993
3994 AC_SUBST(COM_ERRLIB)
3995 AC_SUBST(CRYPTOLIB)
3996 AC_SUBST(KRB5LIB)
3997 AC_SUBST(DESLIB)
3998 AC_SUBST(KRB4LIB)
3999
4000 AC_CHECK_HEADERS(valgrind/valgrind.h)
4001
4002 AC_CHECK_FUNCS_ONCE(tzalloc tzset)
4003
4004 ok_so_far=yes
4005 AC_CHECK_FUNC(socket, , ok_so_far=no)
4006 if test $ok_so_far = yes; then
4007   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
4008 fi
4009 if test $ok_so_far = yes; then
4010   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
4011 fi
4012 if test $ok_so_far = yes; then
4013 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
4014   AC_DEFINE(HAVE_INET_SOCKETS, 1,
4015             [Define to 1 if you have inet sockets.])
4016 fi
4017
4018 AC_FUNC_FORK
4019
4020 AC_CHECK_FUNCS(snprintf)
4021
4022 dnl Check for glib.  This differs from other library checks in that
4023 dnl Emacs need not link to glib unless some other library is already
4024 dnl linking to glib.  Although glib provides no facilities that Emacs
4025 dnl needs for its own purposes, when glib is present Emacs needs to
4026 dnl use primitives like g_main_context_query to avoid clashing with
4027 dnl glib at a low level.
4028 dnl
4029 dnl Check this late, since it depends on $GTK_CFLAGS etc.
4030 XGSELOBJ=
4031 OLDCFLAGS="$CFLAGS"
4032 OLDLIBS="$LIBS"
4033 CFLAGS="$CFLAGS $GTK_CFLAGS $RSVG_CFLAGS $DBUS_CFLAGS $SETTINGS_CFLAGS"
4034 LIBS="$LIBS $GTK_LIBS $RSVG_LIBS $DBUS_LIBS $SETTINGS_LIBS"
4035 CFLAGS="$CFLAGS $GFILENOTIFY_CFLAGS"
4036 LIBS="$LIBS $GFILENOTIFY_LIBS"
4037 AC_MSG_CHECKING([whether GLib is linked in])
4038 AC_LINK_IFELSE([AC_LANG_PROGRAM(
4039         [[#include <glib.h>
4040         ]],
4041         [[g_print ("Hello world");]])],
4042      [links_glib=yes],
4043      [links_glib=no])
4044 AC_MSG_RESULT([$links_glib])
4045 if test "${links_glib}" = "yes"; then
4046   AC_DEFINE(HAVE_GLIB, 1, [Define to 1 if GLib is linked in.])
4047   if test "$HAVE_NS" = no;then
4048     XGSELOBJ=xgselect.o
4049   fi
4050 fi
4051 CFLAGS="$OLDCFLAGS"
4052 LIBS="$OLDLIBS"
4053 AC_SUBST(XGSELOBJ)
4054
4055 dnl Adapted from Haible's version.
4056 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
4057   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
4058     [[char* cs = nl_langinfo(CODESET);]])],
4059     emacs_cv_langinfo_codeset=yes,
4060     emacs_cv_langinfo_codeset=no)
4061   ])
4062 if test $emacs_cv_langinfo_codeset = yes; then
4063   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
4064     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
4065 fi
4066
4067 AC_TYPE_MBSTATE_T
4068
4069 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
4070 dnl how the tty code is related to POSIX and/or other versions of termios.
4071 dnl The following looks like a useful start.
4072 dnl
4073 dnl AC_SYS_POSIX_TERMIOS
4074 dnl if test $ac_cv_sys_posix_termios = yes; then
4075 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
4076 dnl                                and macros for terminal control.])
4077 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
4078 dnl fi
4079
4080 dnl Turned on June 1996 supposing nobody will mind it.
4081 dnl MinGW emulates passwd database, so this feature doesn't make sense there.
4082 if test "${opsys}" != "mingw32"; then
4083    AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
4084      in the full name stands for the login id.])
4085 fi
4086
4087 dnl Everybody supports this, except MS.
4088 dnl Seems like the kind of thing we should be testing for, though.
4089 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
4090 if test "${opsys}" != "mingw32"; then
4091   AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
4092 fi
4093
4094 dnl Everybody supports this, except MS-DOS.
4095 dnl Seems like the kind of thing we should be testing for, though.
4096 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
4097 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
4098   4.2-compatible sockets.])
4099
4100 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
4101
4102 AH_TEMPLATE(NULL_DEVICE, [Name of the file to open to get
4103   a null file, or a data sink.])
4104 if test "${opsys}" = "mingw32"; then
4105   AC_DEFINE(NULL_DEVICE, ["NUL:"])
4106 else
4107   AC_DEFINE(NULL_DEVICE, ["/dev/null"])
4108 fi
4109
4110 if test "${opsys}" = "mingw32"; then
4111   SEPCHAR=';'
4112 else
4113   SEPCHAR=':'
4114 fi
4115 AC_DEFINE_UNQUOTED(SEPCHAR, ['$SEPCHAR'], [Character that separates PATH elements.])
4116 dnl This is for MinGW, and is used in test/automated/Makefile.in.
4117 dnl The MSYS Bash has heuristics for replacing ':' with ';' when it
4118 dnl decides that a command-line argument to be passed to a MinGW program
4119 dnl is a PATH-style list of directories.  But that heuristics plays it
4120 dnl safe, and only does the replacement when it is _absolutely_ sure it
4121 dnl sees a colon-separated list of file names; e.g. ":." is left alone,
4122 dnl which breaks in-tree builds.  So we do this manually instead.
4123 dnl Note that we cannot rely on PATH_SEPARATOR, as that one will always
4124 dnl be computed as ':' in MSYS Bash.
4125 AC_SUBST(SEPCHAR)
4126
4127 dnl Everybody supports this, except MS-DOS.
4128 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
4129
4130 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
4131
4132
4133 AC_DEFINE(DIRECTORY_SEP, ['/'],
4134   [Character that separates directories in a file name.])
4135
4136 if test "${opsys}" = "mingw32"; then
4137   AC_DEFINE(IS_DEVICE_SEP(_c_), [((_c_) == ':')],
4138     [Returns true if character is a device separator.])
4139
4140   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == '/' || (_c_) == '\\')],
4141     [Returns true if character is a directory separator.])
4142
4143   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_) || IS_DEVICE_SEP(_c_))],
4144     [Returns true if character is any form of separator.])
4145 else
4146   AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
4147     [Returns true if character is a device separator.])
4148
4149   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
4150     [Returns true if character is a directory separator.])
4151
4152   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
4153     [Returns true if character is any form of separator.])
4154 fi
4155
4156 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
4157
4158 case $opsys in
4159   aix4-2)
4160     dnl Unfortunately without libXmu we cannot support EditRes.
4161     if test "x$ac_cv_search_XmuConvertStandardSelection" = xno; then
4162       AC_DEFINE(NO_EDITRES, 1)
4163     fi
4164     ;;
4165
4166   hpux*)
4167     dnl Assar Westerlund <assar@sics.se> says this is necessary for
4168     dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
4169     AC_DEFINE(NO_EDITRES, 1)
4170     ;;
4171 esac
4172
4173
4174 case $opsys in
4175   irix6-5 | sol2* | unixware )
4176     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
4177     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
4178     dnl need the constant to dimension an array.  So wire in the appropriate
4179     dnl value here.
4180     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
4181     ;;
4182 esac
4183
4184 emacs_broken_SIGIO=no
4185
4186 case $opsys in
4187   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
4188   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
4189   hpux* | irix6-5 | openbsd | sol2* | unixware )
4190     emacs_broken_SIGIO=yes
4191     ;;
4192
4193   aix4-2)
4194     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
4195     dnl the way this system works, libc functions that return malloced
4196     dnl memory use the libc malloc implementation. Calling xfree or
4197     dnl xrealloc on the results of such functions results in a crash.
4198     dnl
4199     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
4200     dnl but that does not currently work on this system.
4201     dnl
4202     dnl It is possible to completely override the malloc implementation on
4203     dnl AIX, but that involves putting the malloc functions in a shared
4204     dnl library and setting the MALLOCTYPE environment variable to point to
4205     dnl that shared library.
4206     dnl
4207     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
4208     dnl to avoid a crash just use the Emacs implementation for that function.
4209     dnl
4210     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
4211     dnl of this file, so that we do not check for get_current_dir_name
4212     dnl on AIX.  But that might be fragile if something else ends
4213     dnl up testing for get_current_dir_name as a dependency.
4214     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
4215       get_current_dir_name should not be used.])
4216     ;;
4217
4218   freebsd)
4219     dnl Circumvent a bug in FreeBSD.  In the following sequence of
4220     dnl writes/reads on a PTY, read(2) returns bogus data:
4221     dnl
4222     dnl write(2)  1022 bytes
4223     dnl write(2)   954 bytes, get EAGAIN
4224     dnl read(2)   1024 bytes in process_read_output
4225     dnl read(2)     11 bytes in process_read_output
4226     dnl
4227     dnl That is, read(2) returns more bytes than have ever been written
4228     dnl successfully.  The 1033 bytes read are the 1022 bytes written
4229     dnl successfully after processing (for example with CRs added if the
4230     dnl terminal is set up that way which it is here).  The same bytes will
4231     dnl be seen again in a later read(2), without the CRs.
4232     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
4233       work around an issue when reading from a PTY.])
4234     ;;
4235 esac
4236
4237 case $opsys in
4238   gnu-* | sol2-10 )
4239     dnl FIXME Can't we test if this exists (eg /proc/$$)?
4240     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
4241   ;;
4242 esac
4243
4244 case $opsys in
4245   darwin | dragonfly | freebsd | netbsd | openbsd )
4246     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
4247       close a pty to make it a controlling terminal (it is already a
4248       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
4249   ;;
4250 esac
4251
4252 dnl FIXME Surely we can test for this rather than hard-code it.
4253 case $opsys in
4254   netbsd | openbsd) sound_device="/dev/audio" ;;
4255   *) sound_device="/dev/dsp" ;;
4256 esac
4257
4258 dnl Used in sound.c
4259 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
4260   [Name of the default sound device.])
4261
4262
4263 dnl Emacs can read input using SIGIO and buffering characters itself,
4264 dnl or using CBREAK mode and making C-g cause SIGINT.
4265 dnl The choice is controlled by the variable interrupt_input.
4266 dnl
4267 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
4268 dnl
4269 dnl Emacs uses the presence of the USABLE_SIGIO macro
4270 dnl to indicate whether or not signal-driven I/O is possible.  It uses
4271 dnl INTERRUPT_INPUT to decide whether to use it by default.
4272 dnl
4273 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
4274 dnl CBREAK mode has two disadvantages
4275 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
4276 dnl I hear that in system V this problem does not exist.
4277 dnl 2) Control-G causes output to be discarded.
4278 dnl I do not know whether this can be fixed in system V.
4279 dnl
4280 dnl Another method of doing input is planned but not implemented.
4281 dnl It would have Emacs fork off a separate process
4282 dnl to read the input and send it to the true Emacs process
4283 dnl through a pipe.
4284 case $opsys in
4285   darwin | gnu-linux | gnu-kfreebsd )
4286     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
4287   ;;
4288 esac
4289
4290
4291 dnl If the system's imake configuration file defines `NeedWidePrototypes'
4292 dnl as `NO', we must define NARROWPROTO manually.  Such a define is
4293 dnl generated in the Makefile generated by `xmkmf'.  If we don't define
4294 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
4295 dnl taking float or double parameters.
4296 case $opsys in
4297   cygwin|gnu|gnu-linux|gnu-kfreebsd|irix6-5|freebsd|netbsd|openbsd)
4298     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
4299       file defines `NeedWidePrototypes' as `NO'.])
4300   ;;
4301 esac
4302
4303
4304 dnl Used in process.c, this must be a loop, even if it only runs once.
4305 dnl (Except on SGI; see below.  Take that, clarity and consistency!)
4306 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
4307 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
4308 dnl trying suffixes 0-16.
4309 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
4310   first PTY, if PTYs are supported.])
4311 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
4312 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
4313   end of a PTY, if non-standard.])
4314 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
4315   end of a PTY, if non-standard.])
4316
4317 case $opsys in
4318   aix4-2 )
4319     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
4320     dnl You allocate a pty by opening /dev/ptc to get the master side.
4321     dnl To get the name of the slave side, you just ttyname() the master side.
4322     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
4323     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
4324     ;;
4325
4326   cygwin )
4327     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4328     dnl multi-line AC_DEFINEs are hard. :(
4329     AC_DEFINE(PTY_OPEN, [ do { int dummy; sigset_t blocked, procmask; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, &procmask); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; pthread_sigmask (SIG_SETMASK, &procmask, 0); if (fd >= 0) emacs_close (dummy); } while (false)])
4330     AC_DEFINE(PTY_NAME_SPRINTF, [])
4331     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4332     ;;
4333
4334   dnl FIXME?  Maybe use same as freebsd - see bug#12040.
4335   darwin )
4336     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4337     dnl Not used, because PTY_ITERATION is defined.
4338     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4339     dnl Note that openpty may fork via grantpt on Mac OS X 10.4/Darwin 8.
4340     dnl But we don't have to block SIGCHLD because it is blocked in the
4341     dnl implementation of grantpt.
4342     AC_DEFINE(PTY_OPEN, [ do { int slave; if (openpty (&fd, &slave, pty_name, NULL, NULL) == -1) fd = -1; else emacs_close (slave); } while (false)])
4343     AC_DEFINE(PTY_NAME_SPRINTF, [])
4344     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4345     ;;
4346
4347   gnu | openbsd )
4348     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4349     ;;
4350
4351   gnu-linux | gnu-kfreebsd | dragonfly | freebsd | netbsd )
4352     dnl if HAVE_GRANTPT
4353     if test "x$ac_cv_func_grantpt" = xyes; then
4354       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
4355       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4356       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
4357       dnl to prevent sigchld_handler from intercepting the child's death.
4358       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname = 0; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); if (grantpt (fd) != -1 && unlockpt (fd) != -1) ptyname = ptsname(fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (!ptyname) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4359       dnl if HAVE_POSIX_OPENPT
4360       if test "x$ac_cv_func_posix_openpt" = xyes; then
4361         AC_DEFINE(PTY_OPEN, [do { fd = posix_openpt (O_RDWR | O_CLOEXEC | O_NOCTTY); if (fd < 0 && errno == EINVAL) fd = posix_openpt (O_RDWR | O_NOCTTY); } while (false)])
4362         AC_DEFINE(PTY_NAME_SPRINTF, [])
4363       dnl if HAVE_GETPT
4364       elif test "x$ac_cv_func_getpt" = xyes; then
4365         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
4366         AC_DEFINE(PTY_NAME_SPRINTF, [])
4367       else
4368         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4369       fi
4370     else
4371       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4372     fi
4373     ;;
4374
4375   hpux*)
4376     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4377     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
4378     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
4379     ;;
4380
4381   irix6-5 )
4382     dnl It looks like this cannot be right, because it is not a loop.
4383     dnl However, process.c actually does this:
4384     dnl # ifndef __sgi
4385     dnl   continue;
4386     dnl # else
4387     dnl   return -1;
4388     dnl # endif
4389     dnl which presumably makes it OK, since irix == sgi (?).
4390     dnl FIXME it seems like this special treatment is unnecessary?
4391     dnl Why can't irix use a single-trip loop like eg cygwin?
4392     AC_DEFINE(PTY_ITERATION, [])
4393     dnl Not used, because PTY_ITERATION is defined.
4394     AC_DEFINE(FIRST_PTY_LETTER, ['q'])
4395     AC_DEFINE(PTY_OPEN, [ { struct sigaction ocstat, cstat; struct stat stb; char * name; sigemptyset(&cstat.sa_mask); cstat.sa_handler = SIG_DFL; cstat.sa_flags = 0; sigaction(SIGCHLD, &cstat, &ocstat); name = _getpty (&fd, O_RDWR | O_NDELAY, 0600, 0); sigaction(SIGCHLD, &ocstat, (struct sigaction *)0); if (name == 0) return -1; if (fd < 0) return -1; if (fstat (fd, &stb) < 0) return -1; strcpy (pty_name, name); }])
4396     dnl No need to get the pty name at all.
4397     AC_DEFINE(PTY_NAME_SPRINTF, [])
4398     dnl No need to use sprintf to get the tty name--we get that from _getpty.
4399     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4400     ;;
4401
4402   sol2* )
4403     dnl On SysVr4, grantpt(3) forks a subprocess, so keep sigchld_handler()
4404     dnl from intercepting that death.  If any child but grantpt's should die
4405     dnl within, it should be caught after sigrelse(2).
4406     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4407     ;;
4408
4409   unixware )
4410     dnl Comments are as per sol2*.
4411     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1) fatal("could not grant slave pty"); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4412     ;;
4413 esac
4414
4415
4416 case $opsys in
4417   sol2* | unixware )
4418     dnl This change means that we don't loop through allocate_pty too
4419     dnl many times in the (rare) event of a failure.
4420     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
4421     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4422     dnl Push various streams modules onto a PTY channel.  Used in process.c.
4423     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (xforkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (xforkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (xforkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
4424     ;;
4425 esac
4426
4427
4428 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
4429 "typing" a signal character on the pty.])
4430
4431 case $opsys in
4432   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
4433   dnl thomas@mathematik.uni-bremen.de says this is needed for IRIX.
4434   aix4-2 | cygwin | gnu | irix6-5 | dragonfly | freebsd | netbsd | openbsd | darwin )
4435     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4436     ;;
4437
4438   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
4439   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
4440   gnu-linux | gnu-kfreebsd )
4441
4442     AC_MSG_CHECKING([for signals via characters])
4443     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4444 #include <linux/version.h>
4445 #if LINUX_VERSION_CODE < 0x20400
4446 # error "Linux version too old"
4447 #endif
4448       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
4449
4450     AC_MSG_RESULT([$emacs_signals_via_chars])
4451     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4452     ;;
4453 esac
4454
4455
4456 AH_TEMPLATE(TAB3, [Undocumented.])
4457
4458 case $opsys in
4459   darwin) AC_DEFINE(TAB3, OXTABS) ;;
4460
4461   gnu | dragonfly | freebsd | netbsd | openbsd )
4462     AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
4463     AC_DEFINE(TAB3, OXTABS)
4464     ;;
4465
4466   gnu-linux | gnu-kfreebsd )
4467     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4468 #ifndef __ia64__
4469 # error "not ia64"
4470 #endif
4471       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
4472         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (false)],
4473         [Mark a secondary stack, like the register stack on the ia64.]), [])
4474     ;;
4475
4476   hpux*)
4477     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
4478       run_time_remap; for HPUX.])
4479     ;;
4480 esac
4481
4482
4483 dnl This won't be used automatically yet.  We also need to know, at least,
4484 dnl that the stack is continuous.
4485 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
4486   registers relevant for conservative garbage collection in the jmp_buf.])
4487
4488
4489 case $opsys in
4490   dnl Not all the architectures are tested, but there are Debian packages
4491   dnl for SCM and/or Guile on them, so the technique must work.  See also
4492   dnl comments in alloc.c concerning setjmp and gcc.
4493   dnl Fixme: it's probably safe to just use the GCC conditional below.
4494   gnu-linux | gnu-kfreebsd )
4495     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4496 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
4497   || defined __alpha__ || defined __mips__ || defined __s390__ \
4498   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
4499   || defined __ia64__ || defined __sh__
4500 /* ok */
4501 #else
4502 # error "setjmp not known to work on this arch"
4503 #endif
4504     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1))
4505     ;;
4506 esac
4507
4508
4509 if test x$GCC = xyes; then
4510    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
4511    AC_DEFINE(GC_SETJMP_WORKS, 1)
4512 else
4513   case $opsys in
4514     dnl irix: Tested on Irix 6.5.  SCM worked on earlier versions.
4515     aix* | dragonfly | freebsd | netbsd | openbsd | irix6-5 | sol2* )
4516       AC_DEFINE(GC_SETJMP_WORKS, 1)
4517       ;;
4518   esac
4519 fi                              dnl GCC?
4520
4521 dnl In a weird quirk, MS runtime uses _setjmp and longjmp.
4522 AC_CACHE_CHECK([for _setjmp], [emacs_cv_func__setjmp],
4523   [AC_LINK_IFELSE(
4524      [AC_LANG_PROGRAM(
4525        [[#include <setjmp.h>
4526          #ifdef __MINGW32__
4527          # define _longjmp longjmp
4528          #endif
4529        ]],
4530        [[jmp_buf j;
4531          if (! _setjmp (j))
4532            _longjmp (j, 1);]])],
4533      [emacs_cv_func__setjmp=yes],
4534      [emacs_cv_func__setjmp=no])])
4535 if test $emacs_cv_func__setjmp = yes; then
4536   AC_DEFINE([HAVE__SETJMP], 1, [Define to 1 if _setjmp and _longjmp work.])
4537 fi
4538
4539 # We need to preserve signal mask to handle C stack overflows.
4540 AC_CACHE_CHECK([for sigsetjmp], [emacs_cv_func_sigsetjmp],
4541   [AC_LINK_IFELSE(
4542      [AC_LANG_PROGRAM(
4543        [[#include <setjmp.h>
4544        ]],
4545        [[sigjmp_buf j;
4546          if (! sigsetjmp (j, 1))
4547            siglongjmp (j, 1);]])],
4548      [emacs_cv_func_sigsetjmp=yes],
4549      [emacs_cv_func_sigsetjmp=no])])
4550 if test $emacs_cv_func_sigsetjmp = yes; then
4551   AC_DEFINE([HAVE_SIGSETJMP], 1,
4552     [Define to 1 if sigsetjmp and siglongjmp work.])
4553 fi
4554
4555 # We need all of these features to handle C stack overflows.
4556 if test "$ac_cv_header_sys_resource_h" = "yes" &&
4557    test "$ac_cv_func_getrlimit" = "yes" &&
4558    test "$emacs_cv_func_sigsetjmp" = "yes" &&
4559    test "$emacs_cv_alternate_stack" = yes; then
4560   AC_DEFINE([HAVE_STACK_OVERFLOW_HANDLING], 1,
4561     [Define to 1 if C stack overflow can be handled in some cases.])
4562 fi
4563
4564 case $opsys in
4565   sol2* | unixware )
4566     dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
4567     dnl subprocesses the usual way.  But TIOCSIGNAL does work for PTYs,
4568     dnl and this is all we need.
4569     AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
4570     ;;
4571 esac
4572
4573
4574 case $opsys in
4575   hpux* | sol2* )
4576     dnl Used in xfaces.c.
4577     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
4578       some systems, where it requires time.h.])
4579     ;;
4580 esac
4581
4582
4583 dnl Define symbols to identify the version of Unix this is.
4584 dnl Define all the symbols that apply correctly.
4585 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
4586 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
4587 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
4588 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
4589
4590 case $opsys in
4591   aix4-2)
4592     AC_DEFINE(USG, [])
4593     dnl This symbol should be defined on AIX Version 3  ???????
4594     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4595 #ifndef _AIX
4596 # error "_AIX not defined"
4597 #endif
4598     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
4599     ;;
4600
4601   cygwin)
4602     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
4603     ;;
4604
4605   darwin)
4606     dnl Not __APPLE__, as this may not be defined on non-OSX Darwin.
4607     dnl Not DARWIN, because Panther and lower CoreFoundation.h use DARWIN to
4608     dnl distinguish OS X from pure Darwin.
4609     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
4610     ;;
4611
4612   gnu-linux | gnu-kfreebsd )
4613     AC_DEFINE(USG, [])
4614     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
4615     ;;
4616
4617   hpux*)
4618     AC_DEFINE(USG, [])
4619     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
4620     ;;
4621
4622   irix6-5)
4623     AC_DEFINE(USG, [])
4624     AC_DEFINE(USG5_4, [])
4625     AC_DEFINE(IRIX6_5, [], [Define if the system is IRIX.])
4626     ;;
4627
4628   mingw32)
4629     AC_DEFINE(DOS_NT, [])
4630     AC_DEFINE(WINDOWSNT, 1, [Define if compiling for native MS Windows.])
4631     if test "x$ac_enable_checking" != "x" ; then
4632       AC_DEFINE(EMACSDEBUG, 1, [Define to 1 to enable w32 debug facilities.])
4633     fi
4634     ;;
4635
4636   sol2*)
4637     AC_DEFINE(USG, [])
4638     AC_DEFINE(USG5_4, [])
4639     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
4640     ;;
4641
4642   unixware)
4643     AC_DEFINE(USG, [])
4644     AC_DEFINE(USG5_4, [])
4645     ;;
4646 esac
4647
4648 AC_CACHE_CHECK([for usable FIONREAD], [emacs_cv_usable_FIONREAD],
4649   [case $opsys in
4650      aix4-2)
4651        dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
4652        emacs_cv_usable_FIONREAD=no
4653        ;;
4654
4655      mingw32)
4656        emacs_cv_usable_FIONREAD=yes
4657        ;;
4658
4659      *)
4660        AC_COMPILE_IFELSE(
4661          [AC_LANG_PROGRAM([[#include <sys/types.h>
4662                             #include <sys/ioctl.h>
4663                             #ifdef USG5_4
4664                             # include <sys/filio.h>
4665                             #endif
4666                           ]],
4667                           [[int foo = ioctl (0, FIONREAD, &foo);]])],
4668          [emacs_cv_usable_FIONREAD=yes],
4669          [emacs_cv_usable_FIONREAD=no])
4670        ;;
4671    esac])
4672 if test $emacs_cv_usable_FIONREAD = yes; then
4673   AC_DEFINE([USABLE_FIONREAD], [1], [Define to 1 if FIONREAD is usable.])
4674
4675   if test $emacs_broken_SIGIO = no; then
4676     AC_CACHE_CHECK([for usable SIGIO], [emacs_cv_usable_SIGIO],
4677       [AC_COMPILE_IFELSE(
4678          [AC_LANG_PROGRAM([[#include <fcntl.h>
4679                             #include <signal.h>
4680                           ]],
4681                           [[int foo = SIGIO | F_SETFL | FASYNC;]])],
4682          [emacs_cv_usable_SIGIO=yes],
4683          [emacs_cv_usable_SIGIO=no])],
4684       [emacs_cv_usable_SIGIO=yes],
4685       [emacs_cv_usable_SIGIO=no])
4686     if test $emacs_cv_usable_SIGIO = yes; then
4687       AC_DEFINE([USABLE_SIGIO], [1], [Define to 1 if SIGIO is usable.])
4688     fi
4689   fi
4690 fi
4691
4692 case $opsys in
4693   hpux11)
4694     dnl It works to open the pty's tty in the parent (Emacs), then
4695     dnl close and reopen it in the child.
4696     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
4697       works to open a pty's tty in the parent process, then close and
4698       reopen it in the child.])
4699     ;;
4700
4701   irix6-5)
4702     AC_DEFINE(PREFER_VSUSP, 1, [Define if process_send_signal should
4703       use VSUSP instead of VSWTCH.])
4704     ;;
4705
4706   sol2-10)
4707     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
4708       on Solaris.])
4709     ;;
4710 esac
4711
4712 # Set up the CFLAGS for real compilation, so we can substitute it.
4713 CFLAGS="$REAL_CFLAGS"
4714 CPPFLAGS="$REAL_CPPFLAGS"
4715 LIBS="$REAL_LIBS"
4716
4717 ## Hack to detect a buggy GCC version.
4718 if test "x$GCC" = xyes \
4719    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
4720    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
4721    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
4722    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
4723 fi
4724
4725 version=$PACKAGE_VERSION
4726
4727 copyright="Copyright (C) 2015 Free Software Foundation, Inc."
4728 AC_DEFINE_UNQUOTED(COPYRIGHT, ["$copyright"],
4729   [Short copyright string for this version of Emacs.])
4730 AC_SUBST(copyright)
4731
4732 ### Specify what sort of things we'll be editing into Makefile and config.h.
4733 ### Use configuration here uncanonicalized to avoid exceeding size limits.
4734 AC_SUBST(version)
4735 AC_SUBST(configuration)
4736 ## Unused?
4737 AC_SUBST(canonical)
4738 AC_SUBST(srcdir)
4739 AC_SUBST(prefix)
4740 AC_SUBST(exec_prefix)
4741 AC_SUBST(bindir)
4742 AC_SUBST(datadir)
4743 AC_SUBST(sharedstatedir)
4744 AC_SUBST(libexecdir)
4745 AC_SUBST(mandir)
4746 AC_SUBST(infodir)
4747 AC_SUBST(lispdir)
4748 AC_SUBST(standardlisppath)
4749 AC_SUBST(locallisppath)
4750 AC_SUBST(lisppath)
4751 AC_SUBST(x_default_search_path)
4752 AC_SUBST(etcdir)
4753 AC_SUBST(archlibdir)
4754 AC_SUBST(etcdocdir)
4755 AC_SUBST(bitmapdir)
4756 AC_SUBST(gamedir)
4757 AC_SUBST(gameuser)
4758 AC_SUBST(gamegroup)
4759 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
4760 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
4761 ## end of LIBX_BASE, but nothing ever set it.
4762 AC_SUBST(LD_SWITCH_X_SITE)
4763 AC_SUBST(C_SWITCH_X_SITE)
4764 AC_SUBST(GNUSTEP_CFLAGS)
4765 AC_SUBST(CFLAGS)
4766 ## Used in lwlib/Makefile.in.
4767 AC_SUBST(X_TOOLKIT_TYPE)
4768 AC_SUBST(ns_appdir)
4769 AC_SUBST(ns_appbindir)
4770 AC_SUBST(ns_appresdir)
4771 AC_SUBST(ns_appsrc)
4772 AC_SUBST(GNU_OBJC_CFLAGS)
4773 AC_SUBST(OTHER_FILES)
4774
4775 if test -n "${term_header}"; then
4776     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
4777         [Define to the header for the built-in window system.])
4778 fi
4779
4780 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
4781                    [Define to the canonical Emacs configuration name.])
4782 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${emacs_config_options}",
4783                    [Define to the options passed to configure.])
4784 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
4785   define this to include extra configuration information.])
4786
4787 case $opsys in
4788   mingw32)
4789     AC_DEFINE(config_opsysfile, <ms-w32.h>, [])
4790     ;;
4791 esac
4792
4793 XMENU_OBJ=
4794 XOBJ=
4795 FONT_OBJ=
4796 if test "${HAVE_X_WINDOWS}" = "yes" ; then
4797   AC_DEFINE(HAVE_X_WINDOWS, 1,
4798             [Define to 1 if you want to use the X window system.])
4799   XMENU_OBJ=xmenu.o
4800   XOBJ="xterm.o xfns.o xselect.o xrdb.o xsmfns.o xsettings.o"
4801   FONT_OBJ=xfont.o
4802   if test "$HAVE_XFT" = "yes"; then
4803     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
4804   elif test "$HAVE_FREETYPE" = "yes"; then
4805     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
4806   fi
4807   AC_SUBST(FONT_OBJ)
4808 fi
4809 AC_SUBST(XMENU_OBJ)
4810 AC_SUBST(XOBJ)
4811 AC_SUBST(FONT_OBJ)
4812
4813 WIDGET_OBJ=
4814 MOTIF_LIBW=
4815 if test "${USE_X_TOOLKIT}" != "none" ; then
4816   WIDGET_OBJ=widget.o
4817   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
4818   if test "${USE_X_TOOLKIT}" = "LUCID"; then
4819     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
4820   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
4821     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
4822     MOTIF_LIBW=-lXm
4823     case "$opsys" in
4824       gnu-linux)
4825         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
4826         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
4827         ;;
4828
4829       unixware)
4830         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
4831         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
4832         MOTIF_LIBW="MOTIF_LIBW -lXimp"
4833         ;;
4834
4835       aix4-2)
4836         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
4837         MOTIF_LIBW="$MOTIF_LIBW -li18n"
4838         ;;
4839     esac
4840     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
4841   fi
4842 fi
4843 AC_SUBST(WIDGET_OBJ)
4844
4845 TOOLKIT_LIBW=
4846 case "$USE_X_TOOLKIT" in
4847   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
4848   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
4849   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
4850 esac
4851 AC_SUBST(TOOLKIT_LIBW)
4852
4853 if test "${opsys}" != "mingw32"; then
4854   if test "$USE_X_TOOLKIT" = "none"; then
4855     LIBXT_OTHER="\$(LIBXSM)"
4856   else
4857     LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
4858   fi
4859 fi
4860 AC_SUBST(LIBXT_OTHER)
4861
4862 if test "${HAVE_X11}" = "yes" ; then
4863   AC_DEFINE(HAVE_X11, 1,
4864             [Define to 1 if you want to use version 11 of X windows.])
4865   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
4866 else
4867   LIBX_OTHER=
4868 fi
4869 AC_SUBST(LIBX_OTHER)
4870
4871 if test "$HAVE_GTK" = yes || test "$HAVE_X11" != yes; then
4872   LIBXMENU=
4873 elif test "$USE_X_TOOLKIT" = none; then
4874   LIBXMENU='$(oldXMenudir)/libXMenu11.a'
4875 else
4876   LIBXMENU='$(lwlibdir)/liblw.a'
4877 fi
4878 AC_SUBST(LIBXMENU)
4879
4880 AC_CACHE_CHECK([for struct alignment],
4881   [emacs_cv_struct_alignment],
4882   [AC_COMPILE_IFELSE(
4883      [AC_LANG_PROGRAM([[#include <stddef.h>
4884                         struct __attribute__ ((aligned (8))) s { char c; };
4885                         struct t { char c; struct s s; };
4886                         char verify[offsetof (struct t, s) == 8 ? 1 : -1];
4887                       ]])],
4888      [emacs_cv_struct_alignment=yes],
4889      [emacs_cv_struct_alignment=no])])
4890 if test "$emacs_cv_struct_alignment" = yes; then
4891   AC_DEFINE([HAVE_STRUCT_ATTRIBUTE_ALIGNED], 1,
4892     [Define to 1 if 'struct __attribute__ ((aligned (N)))' aligns the
4893      structure to an N-byte boundary.])
4894 fi
4895
4896 if test "${GNU_MALLOC}" = "yes" ; then
4897   AC_DEFINE(GNU_MALLOC, 1,
4898             [Define to 1 if you want to use the GNU memory allocator.])
4899 fi
4900
4901 RALLOC_OBJ=
4902 if test "${REL_ALLOC}" = "yes" ; then
4903   AC_DEFINE(REL_ALLOC, 1,
4904             [Define REL_ALLOC if you want to use the relocating allocator for
4905              buffer space.])
4906
4907   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
4908 fi
4909 AC_SUBST(RALLOC_OBJ)
4910
4911 if test "$opsys" = "cygwin"; then
4912   CYGWIN_OBJ="sheap.o cygw32.o"
4913   ## Cygwin differs because of its unexec().
4914   PRE_ALLOC_OBJ=
4915   POST_ALLOC_OBJ=lastfile.o
4916 elif test "$opsys" = "mingw32"; then
4917   CYGWIN_OBJ=
4918   PRE_ALLOC_OBJ=
4919   POST_ALLOC_OBJ=lastfile.o
4920 else
4921   CYGWIN_OBJ=
4922   PRE_ALLOC_OBJ=lastfile.o
4923   POST_ALLOC_OBJ=
4924 fi
4925 AC_SUBST(CYGWIN_OBJ)
4926 AC_SUBST(PRE_ALLOC_OBJ)
4927 AC_SUBST(POST_ALLOC_OBJ)
4928
4929 dnl Call this 'FORTIFY_SOUR' so that it sorts before the 'FORTIFY_SOURCE'
4930 dnl verbatim defined above.  The tricky name is apropos, as this hack
4931 dnl makes Fortify go sour!
4932 AH_VERBATIM([FORTIFY_SOUR],
4933 [/* Without the following workaround, Emacs runs slowly on OS X 10.8.
4934    The workaround disables some useful run-time checking, so it
4935    should be conditional to the platforms with the performance bug.
4936    Perhaps Apple will fix this some day; also see m4/extern-inline.m4.  */
4937 #if defined __APPLE__ && defined __GNUC__
4938 # ifndef _DONT_USE_CTYPE_INLINE_
4939 #  define _DONT_USE_CTYPE_INLINE_
4940 # endif
4941 # ifndef _FORTIFY_SOURCE
4942 #  define _FORTIFY_SOURCE 0
4943 # endif
4944 #endif
4945 ])
4946
4947 # If user asks to omit features, disable optional features that gnulib
4948 # might otherwise enable.
4949 if test "$with_features" = no && test "$enable_acl" != yes; then
4950   enable_acl=no
4951 fi
4952
4953 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
4954 # it temporarily reverts them to their pre-pkg-config values,
4955 # because gnulib needs to work with both src (which uses the
4956 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
4957 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
4958 # and it therefore needs to run in an environment where LIBS does not
4959 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
4960 # for some package unrelated to lib-src.
4961 SAVE_CFLAGS=$CFLAGS
4962 SAVE_LIBS=$LIBS
4963 CFLAGS=$pre_PKG_CONFIG_CFLAGS
4964 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
4965 gl_ASSERT_NO_GNULIB_POSIXCHECK
4966 gl_ASSERT_NO_GNULIB_TESTS
4967 gl_INIT
4968 CFLAGS=$SAVE_CFLAGS
4969 LIBS=$SAVE_LIBS
4970
4971 if test "${opsys}" = "mingw32"; then
4972   CPPFLAGS="$CPPFLAGS -DUSE_CRT_DLL=1 -I \${abs_top_srcdir}/nt/inc"
4973   # Remove unneeded switches from the value of CC that goes to Makefiles
4974   CC=`echo $CC | sed -e "s,$GCC_TEST_OPTIONS,,"`
4975 fi
4976
4977 case "$opsys" in
4978   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
4979
4980   cygwin) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000" ;;
4981
4982   darwin)
4983    ## The -headerpad option tells ld (see man page) to leave room at the
4984    ## end of the header for adding load commands.  Needed for dumping.
4985    ## 0x1000 is enough for roughly 52 load commands on the x86_64
4986    ## architecture (where they are 78 bytes each). The actual number of
4987    ## load commands added is not consistent but normally ranges from
4988    ## about 14 to about 34. Setting it high gets us plenty of slop and
4989    ## only costs about 1.5K of wasted binary space.
4990    headerpad_extra=1000
4991    if test "$HAVE_NS" = "yes"; then
4992      libs_nsgui="-framework AppKit"
4993      if test "$NS_IMPL_COCOA" = "yes"; then
4994         libs_nsgui="$libs_nsgui -framework IOKit"
4995      fi
4996    else
4997      libs_nsgui=
4998    fi
4999    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
5000
5001    ## This is here because src/Makefile.in did some extra fiddling around
5002    ## with LD_SWITCH_SYSTEM.  It seems cleaner to put this in
5003    ## LD_SWITCH_SYSTEM_TEMACS instead,
5004    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
5005      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
5006    ;;
5007
5008   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
5009   ## find X at run-time.
5010   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
5011   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
5012   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
5013   ## had different values in configure (in ac_link) and src/Makefile.in.
5014   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
5015   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
5016
5017   mingw32)
5018    ## Is it any better under MinGW64 to relocate emacs into higher addresses?
5019    case "$canonical" in
5020      x86_64-*-*) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x400000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
5021      *) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
5022    esac
5023    ;;
5024
5025   openbsd) LD_SWITCH_SYSTEM_TEMACS='-nopie' ;;
5026
5027   *) LD_SWITCH_SYSTEM_TEMACS= ;;
5028 esac
5029
5030 if test x$ac_enable_profiling != x ; then
5031   case $opsys in
5032     *freebsd | gnu-linux) ;;
5033     *) LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -pg" ;;
5034   esac
5035 fi
5036
5037 LD_SWITCH_SYSTEM_TEMACS="$LDFLAGS_NOCOMBRELOC $LD_SWITCH_SYSTEM_TEMACS"
5038
5039 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
5040
5041 ## Common for all window systems
5042 if test "$window_system" != "none"; then
5043   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
5044   AC_DEFINE(POLL_FOR_INPUT, 1, [Define if you poll periodically to detect C-g.])
5045   WINDOW_SYSTEM_OBJ="fontset.o fringe.o image.o"
5046 fi
5047
5048 AC_SUBST(WINDOW_SYSTEM_OBJ)
5049
5050 AH_TOP([/* GNU Emacs site configuration template file.
5051
5052 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2015
5053   Free Software Foundation, Inc.
5054
5055 This file is part of GNU Emacs.
5056
5057 GNU Emacs is free software: you can redistribute it and/or modify
5058 it under the terms of the GNU General Public License as published by
5059 the Free Software Foundation, either version 3 of the License, or
5060 (at your option) any later version.
5061
5062 GNU Emacs is distributed in the hope that it will be useful,
5063 but WITHOUT ANY WARRANTY; without even the implied warranty of
5064 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
5065 GNU General Public License for more details.
5066
5067 You should have received a copy of the GNU General Public License
5068 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
5069
5070
5071 /* No code in Emacs #includes config.h twice, but some bits of code
5072    intended to work with other packages as well (like gmalloc.c)
5073    think they can include it as many times as they like.  */
5074 #ifndef EMACS_CONFIG_H
5075 #define EMACS_CONFIG_H
5076 ])dnl
5077
5078 AH_BOTTOM([#include <conf_post.h>
5079
5080 #endif /* EMACS_CONFIG_H */
5081
5082 /*
5083 Local Variables:
5084 mode: c
5085 End:
5086 */
5087 ])dnl
5088
5089 #### Report on what we decided to do.
5090 #### Report GTK as a toolkit, even if it doesn't use Xt.
5091 #### It makes printing result more understandable as using GTK sets
5092 #### toolkit_scroll_bars to yes by default.
5093 if test "${HAVE_GTK}" = "yes"; then
5094   USE_X_TOOLKIT="$USE_GTK_TOOLKIT"
5095 fi
5096
5097 if test $USE_ACL -ne 0; then
5098   ACL_SUMMARY="yes $LIB_ACL"
5099 else
5100   ACL_SUMMARY=no
5101 fi
5102
5103 echo "
5104 Configured for \`${canonical}'.
5105
5106   Where should the build process find the source code?    ${srcdir}
5107   What compiler should emacs be built with?               ${CC} ${CFLAGS}
5108   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
5109   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
5110   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
5111   What window system should Emacs use?                    ${window_system}
5112   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
5113
5114 if test -n "${x_includes}"; then
5115 echo "  Where do we find X Windows header files?                ${x_includes}"
5116 else
5117 echo "  Where do we find X Windows header files?                Standard dirs"
5118 fi
5119 if test -n "${x_libraries}"; then
5120 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
5121 else
5122 echo "  Where do we find X Windows libraries?                   Standard dirs"
5123 fi
5124
5125 optsep=
5126 emacs_config_features=
5127 for opt in XAW3D XPM JPEG TIFF GIF PNG RSVG IMAGEMAGICK SOUND GPM DBUS \
5128   GCONF GSETTINGS NOTIFY ACL LIBSELINUX GNUTLS LIBXML2 FREETYPE M17N_FLT \
5129   LIBOTF XFT ZLIB; do
5130
5131     case $opt in
5132       NOTIFY|ACL) eval val=\${${opt}_SUMMARY} ;;
5133       *) eval val=\${HAVE_$opt} ;;
5134     esac
5135     test x"$val" = xno && continue
5136     AS_VAR_APPEND([emacs_config_features], ["$optsep$opt"])
5137     optsep=' '
5138 done
5139 AC_DEFINE_UNQUOTED(EMACS_CONFIG_FEATURES, "${emacs_config_features}",
5140   [Summary of some of the main features enabled by configure.])
5141
5142 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
5143 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
5144 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
5145 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
5146 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
5147 echo "  Does Emacs use a png library?                           ${HAVE_PNG} $LIBPNG"
5148 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
5149 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
5150
5151 echo "  Does Emacs support sound?                               ${HAVE_SOUND}"
5152
5153 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
5154 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
5155 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
5156 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
5157 echo "  Does Emacs use a file notification library?             ${NOTIFY_SUMMARY}"
5158 echo "  Does Emacs use access control lists?                    ${ACL_SUMMARY}"
5159 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
5160 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
5161 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
5162
5163 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
5164 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
5165 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
5166 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
5167 echo "  Does Emacs directly use zlib?                           ${HAVE_ZLIB}"
5168
5169 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
5170 echo
5171
5172 if test -n "${EMACSDATA}"; then
5173    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
5174 fi
5175 if test -n "${EMACSDOC}"; then
5176    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
5177 fi
5178
5179 echo
5180
5181 if test "$HAVE_NS" = "yes"; then
5182    echo
5183    echo "You must run \"${MAKE-make} install\" in order to test the built application.
5184 The installed application will go to nextstep/Emacs.app and can be
5185 run or moved from there."
5186    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
5187       echo "The application will be fully self-contained."
5188     else
5189       echo "The lisp resources for the application will be installed under ${prefix}.
5190 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
5191 to run if these resources are not installed."
5192    fi
5193    echo
5194 fi
5195
5196 if test "${opsys}" = "cygwin"; then
5197   case `uname -r` in
5198     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
5199            echo
5200            ;;
5201   esac
5202 fi
5203
5204 # Remove any trailing slashes in these variables.
5205 [test "${prefix}" != NONE &&
5206   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
5207 test "${exec_prefix}" != NONE &&
5208   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
5209
5210 if test "$HAVE_NS" = "yes"; then
5211   if test "$NS_IMPL_GNUSTEP" = yes; then
5212     AC_CONFIG_FILES([nextstep/GNUstep/Emacs.base/Resources/Info-gnustep.plist:nextstep/templates/Info-gnustep.plist.in \
5213       nextstep/GNUstep/Emacs.base/Resources/Emacs.desktop:nextstep/templates/Emacs.desktop.in])
5214     ns_check_file=Resources/Info-gnustep.plist
5215   else
5216     AC_CONFIG_FILES([nextstep/Cocoa/Emacs.base/Contents/Info.plist:nextstep/templates/Info.plist.in \
5217       nextstep/Cocoa/Emacs.base/Contents/Resources/English.lproj/InfoPlist.strings:nextstep/templates/InfoPlist.strings.in])
5218     ns_check_file=Contents/Info.plist
5219   fi
5220   AC_SUBST(ns_check_file)
5221 fi
5222
5223 dnl config.status treats $srcdir specially, so I think this is ok...
5224 AC_CONFIG_FILES([$srcdir/doc/man/emacs.1])
5225
5226 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
5227 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
5228 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
5229 dnl (else you get "no `Makefile.am' found for any configure output").
5230 dnl This will work, but you get a config.status that is not quite right
5231 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
5232 dnl That doesn't have any obvious consequences for Emacs, but on the whole
5233 dnl it seems better to just live with the duplication.
5234 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile nextstep/Makefile nt/Makefile"
5235
5236 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
5237        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
5238        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
5239        leim/Makefile nextstep/Makefile nt/Makefile])
5240
5241 dnl test/ is not present in release tarfiles.
5242 opt_makefile=test/automated/Makefile
5243
5244 if test -f "$srcdir/$opt_makefile.in"; then
5245   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
5246   dnl Again, it's best not to use a variable.  Though you can add
5247   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
5248   AC_CONFIG_FILES([test/automated/Makefile])
5249 fi
5250
5251
5252 dnl The admin/ directory used to be excluded from tarfiles.
5253 if test -d $srcdir/admin; then
5254   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES admin/unidata/Makefile admin/grammars/Makefile"
5255   AC_CONFIG_FILES([admin/unidata/Makefile])
5256   AC_CONFIG_FILES([admin/grammars/Makefile])
5257 fi                              dnl -d admin
5258
5259
5260 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
5261
5262 AC_SUBST(SUBDIR_MAKEFILES_IN)
5263
5264 dnl You might wonder (I did) why epaths.h is generated by running make,
5265 dnl rather than just letting configure generate it from epaths.in.
5266 dnl One reason is that the various paths are not fully expanded (see above);
5267 dnl eg gamedir=${prefix}/var/games/emacs.
5268 dnl Secondly, the GNU Coding standards require that one should be able
5269 dnl to run `make prefix=/some/where/else' and override the values set
5270 dnl by configure.  This also explains the `move-if-change' test and
5271 dnl the use of force in the `epaths-force' rule in Makefile.in.
5272 AC_CONFIG_COMMANDS([src/epaths.h], [
5273 if test "${opsys}" = "mingw32"; then
5274   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force-w32
5275 else
5276   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
5277 fi || AC_MSG_ERROR(['src/epaths.h' could not be made.])
5278 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS" opsys="$opsys"])
5279
5280 dnl NB we have to cheat and use the ac_... version because abs_top_srcdir
5281 dnl is not yet set, sigh.  Or we could use ../$srcdir/src/.gdbinit,
5282 dnl or a symlink?
5283 AC_CONFIG_COMMANDS([src/.gdbinit], [
5284 if test ! -f src/.gdbinit && test -f "$srcdir/src/.gdbinit"; then
5285   echo "source $ac_abs_top_srcdir/src/.gdbinit" > src/.gdbinit
5286 fi
5287 ])
5288
5289 dnl Perhaps this would be better named doc-emacs-emacsver.texi?
5290 dnl See comments for etc-refcards-emacsver.tex.
5291 dnl Since we get a doc/emacs directory generated anyway, for the Makefile,
5292 dnl it is not quite the same.  But we are generating in $srcdir.
5293 AC_CONFIG_COMMANDS([doc/emacs/emacsver.texi], [
5294 ${MAKE-make} -s --no-print-directory -C doc/emacs doc-emacsver || \
5295 AC_MSG_ERROR(['doc/emacs/emacsver.texi' could not be made.])
5296 ])
5297
5298 dnl If we give this the more natural name, etc/refcards/emacsver.texi,
5299 dnl then a directory etc/refcards is created in the build directory,
5300 dnl which is probably harmless, but confusing (in out-of-tree builds).
5301 dnl (If we were to generate etc/refcards/Makefile, this might change.)
5302 dnl It is really $srcdir/etc/refcards/emacsver.tex that we generate.
5303 AC_CONFIG_COMMANDS([etc-refcards-emacsver.tex], [
5304 ${MAKE-make} -s MAKEFILE_NAME=do-not-make-Makefile etc-emacsver || \
5305 AC_MSG_ERROR(['etc/refcards/emacsver.tex' could not be made.])
5306 ])
5307
5308 AC_OUTPUT
5309
5310 test "$MAKE" = make || AC_MSG_NOTICE([Now you can run '$MAKE'.])