code.delx.au - gnu-emacs/blob - lisp/net/tramp-cache.el

   1 ;;; tramp-cache.el --- file information caching for Tramp
   2
   3 ;; Copyright (C) 2000, 2005-2014 Free Software Foundation, Inc.
   4
   5 ;; Author: Daniel Pittman <daniel@inanna.danann.net>
   6 ;;         Michael Albinus <michael.albinus@gmx.de>
   7 ;; Keywords: comm, processes
   8 ;; Package: tramp
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; An implementation of information caching for remote files.
  28
  29 ;; Each connection, identified by a vector [method user host
  30 ;; localname] or by a process, has a unique cache. We distinguish 3
  31 ;; kind of caches, depending on the key:
  32 ;;
  33 ;; - localname is NIL.  This are reusable properties.  Examples:
  34 ;;   "remote-shell" identifies the POSIX shell to be called on the
  35 ;;   remote host, or "perl" is the command to be called on the remote
  36 ;;   host when starting a Perl script.  These properties are saved in
  37 ;;   the file `tramp-persistency-file-name'.
  38 ;;
  39 ;; - localname is a string.  This are temporary properties, which are
  40 ;;   related to the file localname is referring to.  Examples:
  41 ;;   "file-exists-p" is t or nil, depending on the file existence, or
  42 ;;   "file-attributes" caches the result of the function
  43 ;;   `file-attributes'.  These entries have a timestamp, and they
  44 ;;   expire after `remote-file-name-inhibit-cache' seconds if this
  45 ;;   variable is set.
  46 ;;
  47 ;; - The key is a process.  This are temporary properties related to
  48 ;;   an open connection.  Examples: "scripts" keeps shell script
  49 ;;   definitions already sent to the remote shell, "last-cmd-time" is
  50 ;;   the time stamp a command has been sent to the remote process.
  51
  52 ;;; Code:
  53
  54 (require 'tramp)
  55 (autoload 'time-stamp-string "time-stamp")
  56
  57 ;;; -- Cache --
  58
  59 ;;;###tramp-autoload
  60 (defvar tramp-cache-data (make-hash-table :test 'equal)
  61   "Hash table for remote files properties.")
  62
  63 ;;;###tramp-autoload
  64 (defcustom tramp-connection-properties nil
  65   "List of static connection properties.
  66 Every entry has the form (REGEXP PROPERTY VALUE).  The regexp
  67 matches remote file names.  It can be nil.  PROPERTY is a string,
  68 and VALUE the corresponding value.  They are used, if there is no
  69 matching entry for PROPERTY in `tramp-cache-data'."
  70   :group 'tramp
  71   :version "24.4"
  72   :type '(repeat (list (choice :tag "File Name regexp" regexp (const nil))
  73                        (choice :tag "        Property" string)
  74                        (choice :tag "           Value" sexp))))
  75
  76 (defcustom tramp-persistency-file-name
  77   (cond
  78    ;; GNU Emacs.
  79    ((and (fboundp 'locate-user-emacs-file))
  80     (expand-file-name (tramp-compat-funcall 'locate-user-emacs-file "tramp")))
  81    ((and (boundp 'user-emacs-directory)
  82          (stringp (symbol-value 'user-emacs-directory))
  83          (file-directory-p (symbol-value 'user-emacs-directory)))
  84     (expand-file-name "tramp" (symbol-value 'user-emacs-directory)))
  85    ((and (not (featurep 'xemacs)) (file-directory-p "~/.emacs.d/"))
  86     "~/.emacs.d/tramp")
  87    ;; XEmacs.
  88    ((and (boundp 'user-init-directory)
  89          (stringp (symbol-value 'user-init-directory))
  90          (file-directory-p (symbol-value 'user-init-directory)))
  91     (expand-file-name "tramp" (symbol-value 'user-init-directory)))
  92    ((and (featurep 'xemacs) (file-directory-p "~/.xemacs/"))
  93     "~/.xemacs/tramp")
  94    ;; For users without `~/.emacs.d/' or `~/.xemacs/'.
  95    (t "~/.tramp"))
  96   "File which keeps connection history for Tramp connections."
  97   :group 'tramp
  98   :type 'file)
  99
 100 (defvar tramp-cache-data-changed nil
 101   "Whether persistent cache data have been changed.")
 102
 103 (defun tramp-get-hash-table (key)
 104   "Returns the hash table for KEY.
 105 If it doesn't exist yet, it is created and initialized with
 106 matching entries of `tramp-connection-properties'."
 107   (or (gethash key tramp-cache-data)
 108       (let ((hash
 109              (puthash key (make-hash-table :test 'equal) tramp-cache-data)))
 110         (when (vectorp key)
 111           (dolist (elt tramp-connection-properties)
 112             (when (string-match
 113                    (or (nth 0 elt) "")
 114                    (tramp-make-tramp-file-name
 115                     (aref key 0) (aref key 1) (aref key 2) nil))
 116               (tramp-set-connection-property key (nth 1 elt) (nth 2 elt)))))
 117         hash)))
 118
 119 ;;;###tramp-autoload
 120 (defun tramp-get-file-property (key file property default)
 121   "Get the PROPERTY of FILE from the cache context of KEY.
 122 Returns DEFAULT if not set."
 123   ;; Unify localname.
 124   (setq key (copy-sequence key))
 125   (aset key 3 (tramp-run-real-handler 'directory-file-name (list file)))
 126   (let* ((hash (tramp-get-hash-table key))
 127          (value (when (hash-table-p hash) (gethash property hash))))
 128     (if
 129         ;; We take the value only if there is any, and
 130         ;; `remote-file-name-inhibit-cache' indicates that it is still
 131         ;; valid.  Otherwise, DEFAULT is set.
 132         (and (consp value)
 133              (or (null remote-file-name-inhibit-cache)
 134                  (and (integerp remote-file-name-inhibit-cache)
 135                       (<=
 136                        (tramp-time-diff (current-time) (car value))
 137                        remote-file-name-inhibit-cache))
 138                  (and (consp remote-file-name-inhibit-cache)
 139                       (tramp-time-less-p
 140                        remote-file-name-inhibit-cache (car value)))))
 141         (setq value (cdr value))
 142       (setq value default))
 143
 144     (tramp-message key 8 "%s %s %s" file property value)
 145     (when (>= tramp-verbose 10)
 146       (let* ((var (intern (concat "tramp-cache-get-count-" property)))
 147              (val (or (ignore-errors (symbol-value var)) 0)))
 148         (set var (1+ val))))
 149     value))
 150
 151 ;;;###tramp-autoload
 152 (defun tramp-set-file-property (key file property value)
 153   "Set the PROPERTY of FILE to VALUE, in the cache context of KEY.
 154 Returns VALUE."
 155   ;; Unify localname.
 156   (setq key (copy-sequence key))
 157   (aset key 3 (tramp-run-real-handler 'directory-file-name (list file)))
 158   (let ((hash (tramp-get-hash-table key)))
 159     ;; We put the timestamp there.
 160     (puthash property (cons (current-time) value) hash)
 161     (tramp-message key 8 "%s %s %s" file property value)
 162     (when (>= tramp-verbose 10)
 163       (let* ((var (intern (concat "tramp-cache-set-count-" property)))
 164              (val (or (ignore-errors (symbol-value var)) 0)))
 165         (set var (1+ val))))
 166     value))
 167
 168 ;;;###tramp-autoload
 169 (defun tramp-flush-file-property (key file)
 170   "Remove all properties of FILE in the cache context of KEY."
 171   ;; Remove file properties of symlinks.
 172   (let ((truename (tramp-get-file-property key file "file-truename" nil)))
 173     (when (and (stringp truename)
 174                (not (string-equal file truename)))
 175       (tramp-flush-file-property key truename)))
 176   ;; Unify localname.
 177   (setq key (copy-sequence key))
 178   (aset key 3 (tramp-run-real-handler 'directory-file-name (list file)))
 179   (tramp-message key 8 "%s" file)
 180   (remhash key tramp-cache-data))
 181
 182 ;;;###tramp-autoload
 183 (defun tramp-flush-directory-property (key directory)
 184   "Remove all properties of DIRECTORY in the cache context of KEY.
 185 Remove also properties of all files in subdirectories."
 186   (let* ((directory (tramp-run-real-handler
 187                     'directory-file-name (list directory)))
 188          (truename (tramp-get-file-property key directory "file-truename" nil)))
 189     ;; Remove file properties of symlinks.
 190     (when (and (stringp truename)
 191                (not (string-equal directory truename)))
 192       (tramp-flush-directory-property key truename))
 193     (tramp-message key 8 "%s" directory)
 194     (maphash
 195      (lambda (key _value)
 196        (when (and (stringp (tramp-file-name-localname key))
 197                   (string-match directory (tramp-file-name-localname key)))
 198          (remhash key tramp-cache-data)))
 199      tramp-cache-data)))
 200
 201 ;; Reverting or killing a buffer should also flush file properties.
 202 ;; They could have been changed outside Tramp.  In eshell, "ls" would
 203 ;; not show proper directory contents when a file has been copied or
 204 ;; deleted before.
 205 (defun tramp-flush-file-function ()
 206   "Flush all Tramp cache properties from `buffer-file-name'."
 207   (let ((bfn (if (stringp (buffer-file-name))
 208                  (buffer-file-name)
 209                default-directory)))
 210     (when (tramp-tramp-file-p bfn)
 211       (with-parsed-tramp-file-name bfn nil
 212         (tramp-flush-file-property v localname)))))
 213
 214 (add-hook 'before-revert-hook 'tramp-flush-file-function)
 215 (add-hook 'eshell-pre-command-hook 'tramp-flush-file-function)
 216 (add-hook 'kill-buffer-hook 'tramp-flush-file-function)
 217 (add-hook 'tramp-cache-unload-hook
 218           (lambda ()
 219             (remove-hook 'before-revert-hook
 220                          'tramp-flush-file-function)
 221             (remove-hook 'eshell-pre-command-hook
 222                          'tramp-flush-file-function)
 223             (remove-hook 'kill-buffer-hook
 224                          'tramp-flush-file-function)))
 225
 226 ;;; -- Properties --
 227
 228 ;;;###tramp-autoload
 229 (defun tramp-get-connection-property (key property default)
 230   "Get the named PROPERTY for the connection.
 231 KEY identifies the connection, it is either a process or a vector.
 232 If the value is not set for the connection, returns DEFAULT."
 233   ;; Unify key by removing localname from vector.  Work with a copy in
 234   ;; order to avoid side effects.
 235   (when (vectorp key)
 236     (setq key (copy-sequence key))
 237     (aset key 3 nil))
 238   (let* ((hash (tramp-get-hash-table key))
 239          (value (if (hash-table-p hash)
 240                     (gethash property hash default)
 241                   default)))
 242     (tramp-message key 7 "%s %s" property value)
 243     value))
 244
 245 ;;;###tramp-autoload
 246 (defun tramp-set-connection-property (key property value)
 247   "Set the named PROPERTY of a connection to VALUE.
 248 KEY identifies the connection, it is either a process or a vector.
 249 PROPERTY is set persistent when KEY is a vector."
 250   ;; Unify key by removing localname from vector.  Work with a copy in
 251   ;; order to avoid side effects.
 252   (when (vectorp key)
 253     (setq key (copy-sequence key))
 254     (aset key 3 nil))
 255   (let ((hash (tramp-get-hash-table key)))
 256     (puthash property value hash)
 257     (setq tramp-cache-data-changed t)
 258     (tramp-message key 7 "%s %s" property value)
 259     value))
 260
 261 ;;;###tramp-autoload
 262 (defun tramp-connection-property-p (key property)
 263   "Check whether named PROPERTY of a connection is defined.
 264 KEY identifies the connection, it is either a process or a vector."
 265   (not (eq (tramp-get-connection-property key property 'undef) 'undef)))
 266
 267 ;;;###tramp-autoload
 268 (defun tramp-flush-connection-property (key)
 269   "Remove all properties identified by KEY.
 270 KEY identifies the connection, it is either a process or a vector."
 271   ;; Unify key by removing localname from vector.  Work with a copy in
 272   ;; order to avoid side effects.
 273   (when (vectorp key)
 274     (setq key (copy-sequence key))
 275     (aset key 3 nil))
 276   (tramp-message
 277    key 7 "%s %s" key
 278    (let ((hash (gethash key tramp-cache-data))
 279          properties)
 280      (when (hash-table-p hash)
 281        (maphash (lambda (x _y) (add-to-list 'properties x 'append)) hash))
 282      properties))
 283   (setq tramp-cache-data-changed t)
 284   (remhash key tramp-cache-data))
 285
 286 ;;;###tramp-autoload
 287 (defun tramp-cache-print (table)
 288   "Print hash table TABLE."
 289   (when (hash-table-p table)
 290     (let (result)
 291       (maphash
 292        (lambda (key value)
 293          ;; Remove text properties from KEY and VALUE.
 294          ;; `substring-no-properties' does not exist in XEmacs.
 295          (when (functionp 'substring-no-properties)
 296            (when (vectorp key)
 297              (dotimes (i (length key))
 298                (when (stringp (aref key i))
 299                  (aset key i
 300                        (tramp-compat-funcall
 301                         'substring-no-properties (aref key i))))))
 302            (when (stringp key)
 303              (setq key (tramp-compat-funcall 'substring-no-properties key)))
 304            (when (stringp value)
 305              (setq value
 306                    (tramp-compat-funcall 'substring-no-properties value))))
 307          ;; Dump.
 308          (let ((tmp (format
 309                      "(%s %s)"
 310                      (if (processp key)
 311                          (prin1-to-string (prin1-to-string key))
 312                        (prin1-to-string key))
 313                      (if (hash-table-p value)
 314                          (tramp-cache-print value)
 315                        (if (bufferp value)
 316                            (prin1-to-string (prin1-to-string value))
 317                          (prin1-to-string value))))))
 318            (setq result (if result (concat result " " tmp) tmp))))
 319        table)
 320       result)))
 321
 322 ;;;###tramp-autoload
 323 (defun tramp-list-connections ()
 324   "Return a list of all known connection vectors according to `tramp-cache'."
 325     (let (result)
 326       (maphash
 327        (lambda (key _value)
 328          (when (and (vectorp key) (null (aref key 3)))
 329            (add-to-list 'result key)))
 330        tramp-cache-data)
 331       result))
 332
 333 (defun tramp-dump-connection-properties ()
 334   "Write persistent connection properties into file `tramp-persistency-file-name'."
 335   ;; We shouldn't fail, otherwise (X)Emacs might not be able to be closed.
 336   (ignore-errors
 337     (when (and (hash-table-p tramp-cache-data)
 338                (not (zerop (hash-table-count tramp-cache-data)))
 339                tramp-cache-data-changed
 340                (stringp tramp-persistency-file-name))
 341       (let ((cache (copy-hash-table tramp-cache-data))
 342             print-length print-level)
 343         ;; Remove temporary data.  If there is the key "login-as", we
 344         ;; don't save either, because all other properties might
 345         ;; depend on the login name, and we want to give the
 346         ;; possibility to use another login name later on.
 347         (maphash
 348          (lambda (key value)
 349            (if (and (vectorp key)
 350                     (not (tramp-file-name-localname key))
 351                     (not (gethash "login-as" value)))
 352                (progn
 353                  (remhash "process-name" value)
 354                  (remhash "process-buffer" value)
 355                  (remhash "first-password-request" value))
 356              (remhash key cache)))
 357          cache)
 358         ;; Dump it.
 359         (with-temp-buffer
 360           (insert
 361            ";; -*- emacs-lisp -*-"
 362            ;; `time-stamp-string' might not exist in all (X)Emacs flavors.
 363            (condition-case nil
 364                (progn
 365                  (format
 366                   " <%s %s>\n"
 367                   (time-stamp-string "%02y/%02m/%02d %02H:%02M:%02S")
 368                   tramp-persistency-file-name))
 369              (error "\n"))
 370            ";; Tramp connection history.  Don't change this file.\n"
 371            ";; You can delete it, forcing Tramp to reapply the checks.\n\n"
 372            (with-output-to-string
 373              (pp (read (format "(%s)" (tramp-cache-print cache))))))
 374           (write-region
 375            (point-min) (point-max) tramp-persistency-file-name))))))
 376
 377 (unless noninteractive
 378   (add-hook 'kill-emacs-hook 'tramp-dump-connection-properties))
 379 (add-hook 'tramp-cache-unload-hook
 380           (lambda ()
 381             (remove-hook 'kill-emacs-hook
 382                          'tramp-dump-connection-properties)))
 383
 384 ;;;###tramp-autoload
 385 (defun tramp-parse-connection-properties (method)
 386   "Return a list of (user host) tuples allowed to access for METHOD.
 387 This function is added always in `tramp-get-completion-function'
 388 for all methods.  Resulting data are derived from connection history."
 389   (let (res)
 390     (maphash
 391      (lambda (key _value)
 392        (if (and (vectorp key)
 393                 (string-equal method (tramp-file-name-method key))
 394                 (not (tramp-file-name-localname key)))
 395            (push (list (tramp-file-name-user key)
 396                        (tramp-file-name-host key))
 397                  res)))
 398      tramp-cache-data)
 399     res))
 400
 401 ;; Read persistent connection history.
 402 (when (and (stringp tramp-persistency-file-name)
 403            (zerop (hash-table-count tramp-cache-data))
 404            ;; When "emacs -Q" has been called, both variables are nil.
 405            ;; We do not load the persistency file then, in order to
 406            ;; have a clean test environment.
 407            (or (and (boundp 'init-file-user) (symbol-value 'init-file-user))
 408                (and (boundp 'site-run-file) (symbol-value 'site-run-file))))
 409   (condition-case err
 410       (with-temp-buffer
 411         (insert-file-contents tramp-persistency-file-name)
 412         (let ((list (read (current-buffer)))
 413               (tramp-verbose 0)
 414               element key item)
 415           (while (setq element (pop list))
 416             (setq key (pop element))
 417             (while (setq item (pop element))
 418               ;; We set only values which are not contained in
 419               ;; `tramp-connection-properties'.  The cache is
 420               ;; initialized properly by side effect.
 421               (unless (tramp-connection-property-p key (car item))
 422                 (tramp-set-connection-property key (pop item) (car item))))))
 423         (setq tramp-cache-data-changed nil))
 424     (file-error
 425      ;; Most likely because the file doesn't exist yet.  No message.
 426      (clrhash tramp-cache-data))
 427     (error
 428      ;; File is corrupted.
 429      (message "Tramp persistency file '%s' is corrupted: %s"
 430               tramp-persistency-file-name (error-message-string err))
 431      (clrhash tramp-cache-data))))
 432
 433 (add-hook 'tramp-unload-hook
 434           (lambda ()
 435             (unload-feature 'tramp-cache 'force)))
 436
 437 (provide 'tramp-cache)
 438
 439 ;;; tramp-cache.el ends here