code.delx.au - gnu-emacs/blob - lisp/textmodes/refer.el

   1 ;;; refer.el --- look up references in bibliography files.
   2
   3 ;; Copyright (C) 1992, 1996 Free Software Foundation, Inc.
   4
   5 ;; Author: Ashwin Ram <ashwin@cc.gatech.edu>
   6 ;; Maintainer: Gernot Heiser <gernot@jungfrau.disy.cse.unsw.EDU.AU>
   7 ;; Adapted-By: ESR
   8 ;; Keywords: bib
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Functions to look up references in bibliography files given lists of
  30 ;; keywords, similar to refer(1).  I don't use tags since tags on .bib files
  31 ;; only picks up the cite key, where as refer-find-entry looks for occurrences
  32 ;; of keywords anywhere in the bibliography entry.
  33 ;;
  34 ;; To use:
  35 ;;      (autoload 'refer-find-entry "refer" nil t)
  36 ;; or   (require 'refer)
  37 ;;
  38 ;;      To look for an article by Knuth about semaphores:
  39 ;;          Invoke refer-find-entry, then in response to the Keywords: prompt,
  40 ;;          say: Knuth semaphores (a blank-separated list of keywords to be used
  41 ;;          as search strings).
  42 ;;
  43 ;;      To continue the previous search, i.e., to search for the next occurrence
  44 ;;      of the keywords, use refer-find-next-entry, or invoke refer-find-entry
  45 ;;      with a prefix argument.
  46 ;;
  47 ;;      Once you've found the entry you want to reference, invoke
  48 ;;      refer-yank-key to insert it at point in the current buffer
  49 ;;      (typically as the argument of a \cite{} command).
  50 ;;
  51 ;;      I use (define-key tex-mode-map    "\C-c\C-y"  'refer-yank-key)
  52 ;;      to bind this often-used function to a key in (la)tex-mode.
  53 ;;
  54 ;;      If the list of bibliography files changes, reinitialize the variable
  55 ;;      refer-bib-files.
  56 ;;
  57 ;; To customize:
  58 ;;      See variables refer-bib-files, refer-cache-bib-files and
  59 ;;      refer-bib-files-regexp.  By default, these are set up so that refer
  60 ;;      looks for the keywords you specify in all the .bib files in the current
  61 ;;      directory.
  62 ;;
  63 ;;      The only assumption I make about bib files is that they contain a bunch
  64 ;;      of entries, one to a paragraph.  refer-find-entry searches paragraph by
  65 ;;      paragraph, looking for a paragraph containing all the keywords
  66 ;;      specified.  So you should be able to use pretty much any bib file with
  67 ;;      this code.  If your bib file does not use paragraphs to separate
  68 ;;      entries, try setting the paragraph-start/separate variables, or changing
  69 ;;      the (forward-paragraph 1) call in refer-find-entry-in-file.
  70
  71 ;;; Code:
  72
  73 (provide 'refer)
  74
  75 (defvar refer-bib-directory nil
  76   "Directory, or list of directories, to search for \\.bib files. Can
  77 be set to 'bibinputs or 'texinputs, in which case the environment
  78 variable BIBINPUTS or TEXINPUTS, respectively, is used to obtain a
  79 list of directories.  Useful only if refer-bib-files is set to 'dir or
  80 a list of file names (without directory). A value of nil indicates the
  81 current working directory.
  82
  83 If refer-bib-directory is 'bibinputs or 'texinputs, it is setq'd to
  84 the appropriate list of directories when it is first used.
  85
  86 Note that an empty directory is interpreted by BibTeX as indicating
  87 the default search path. Since Refer does not know that default path,
  88 it cannot search it. Include that path explicitly in your BIBINPUTS
  89 environment if you really want it searched (which is not likely to
  90 happen anyway).")
  91
  92 (defvar refer-bib-files 'dir
  93    "*List of \\.bib files to search for references,
  94 or one of the following special values:
  95 nil  = prompt for \\.bib file (if visiting a \\.bib file, use it as default)
  96 auto = read \\.bib file names from appropriate command in buffer (see
  97        refer-bib-files-regexp) unless the buffer's mode is bibtex-mode,
  98        in which case only the buffer is searched
  99 dir  = use all \\.bib files in directories referenced by refer-bib-directory.
 100
 101 If a specified file doesn't exist and has no extension, a \\.bib extension
 102 is automatically tried.
 103
 104 If refer-bib-files is nil, auto or dir, it is setq'd to the appropriate
 105 list of files when it is first used if refer-cache-bib-files is t.  If
 106 refer-cache-bib-files is nil, the list of \\.bib files to use is re-read
 107 each time it is needed.")
 108
 109 (defvar refer-cache-bib-files t
 110    "*Variable determining whether the value of refer-bib-files should be cached.
 111 If t, initialize the value of refer-bib-files the first time it is used.  If
 112 nil, re-read the list of \\.bib files depending on the value of refer-bib-files
 113 each time it is needed.")
 114
 115 (defvar refer-bib-files-regexp "\\\\bibliography"
 116    "*Regexp matching a bibliography file declaration.
 117 The current buffer is expected to contain a line such as
 118 \\bibliography{file1,file2,file3}
 119 which is read to set up refer-bib-files.  The regexp must specify the command
 120 (such as \\bibliography) that is used to specify the list of bib files.  The
 121 command is expected to specify a file name, or a list of comma-separated file
 122 names, within curly braces.
 123 If a specified file doesn't exist and has no extension, a \\.bib extension
 124 is automatically tried.")
 125
 126 (make-variable-buffer-local 'refer-bib-files)
 127 (make-variable-buffer-local 'refer-cache-bib-files)
 128 (make-variable-buffer-local 'refer-bib-directory)
 129
 130 ;;; Internal variables
 131 (defvar refer-saved-state nil)
 132 (defvar refer-previous-keywords nil)
 133 (defvar refer-saved-pos nil)
 134 (defvar refer-same-file nil)
 135
 136 (defun refer-find-entry (keywords &optional continue)
 137    "Find entry in refer-bib-files containing KEYWORDS.
 138 If KEYWORDS is nil, prompt user for blank-separated list of keywords.
 139 If CONTINUE is t, or if called interactively with a prefix arg, look for next
 140 entry by continuing search from previous point."
 141    (interactive (list nil current-prefix-arg))
 142    (or keywords (setq keywords (if continue
 143                                    refer-previous-keywords
 144                                  (read-string "Keywords: "))))
 145    (setq refer-previous-keywords keywords)
 146    (refer-find-entry-internal keywords continue))
 147
 148 (defun refer-find-next-entry ()
 149    "Find next occurrence of entry in refer-bib-files.  See refer-find-entry."
 150    (interactive)
 151    (refer-find-entry-internal refer-previous-keywords t))
 152
 153 (defun refer-yank-key ()
 154   "Inserts at point in current buffer the \"key\" field of the entry
 155 found on the last refer-find-entry or refer-find-next-entry."
 156   (interactive)
 157   (let ((old-point (point)))
 158     (insert
 159      (save-window-excursion
 160        (save-excursion
 161          (find-file (car refer-saved-state))
 162          (if (looking-at
 163               "[ \t\n]*@\\s-*[a-zA-Z][a-zA-Z0-9]*\\s-*{\\s-*\\([^ \t\n,]+\\)\\s-*,")
 164              (buffer-substring (match-beginning 1) (match-end 1))
 165            (error "Cannot find key for entry in file %s."
 166                   (car refer-saved-state))))))
 167     (if (not (= (point) old-point))
 168       (set-mark old-point))))
 169
 170 (defun refer-find-entry-internal (keywords continue)
 171    (let ((keywords-list (refer-convert-string-to-list-of-strings keywords))
 172          (old-buffer (current-buffer))
 173          (old-window (selected-window))
 174          (new-window (selected-window))
 175          (files (if continue
 176                     refer-saved-state
 177                   (setq refer-saved-pos nil)
 178                   (refer-get-bib-files)))
 179          (n 0)
 180          (found nil)
 181          (file nil))
 182      ;; find window in which to display bibliography file.
 183      ;; if a bibliography file is already displayed in a window, use
 184      ;; that one, otherwise use any window other than the current one
 185      (while (not found)
 186        (while (and (not (null (setq file (nth n files))))
 187                    (setq n (1+ n))
 188                    (not (string-equal file
 189                                       (buffer-file-name
 190                                        (window-buffer new-window))))))
 191        (setq found
 192              (if (null file)
 193                  (eq (setq new-window (next-window new-window 'nomini))
 194                      old-window)
 195                't)))
 196      (if (null file)                     ; didn't find bib file in any window:
 197          (progn (if (one-window-p 'nomini)
 198                     (setq old-window (split-window)))
 199                 (setq new-window (next-window old-window 'nomini))))
 200      (select-window (if refer-same-file
 201                         old-window
 202                       new-window))  ; the window in which to show the bib file
 203      (catch 'found
 204        (while files
 205          (let ((file (cond ((file-exists-p (car files)) (car files))
 206                            ((file-exists-p (concat (car files) ".bib"))
 207                             (concat (car files) ".bib")))))
 208            (setq refer-saved-state files)
 209            (if file
 210                (if (refer-find-entry-in-file keywords-list file refer-saved-pos)
 211                    (progn
 212                      (setq refer-saved-pos (point))
 213                      (recenter 0)
 214                      (throw 'found (find-file file)))
 215                  (setq refer-saved-pos nil
 216                        files (cdr files)))
 217              (progn (message "Scanning %s... No such file" (car files) (ding))
 218                     (sit-for 1)
 219                     (setq files (cdr files))))))
 220        (message "Keywords \"%s\" not found in any \.bib file" keywords (ding)))
 221      (select-window old-window)))
 222
 223 (defun refer-find-entry-in-file (keywords-list file &optional old-pos)
 224    (message "Scanning %s..." file)
 225    (expand-file-name file)
 226    (set-buffer (find-file-noselect file))
 227    (find-file file)
 228    (if (not old-pos)
 229        (goto-char (point-min))
 230      (goto-char old-pos)
 231      (forward-paragraph 1))
 232    (let ((begin (point))
 233          (end 0)
 234          (found nil))
 235      (while (and (not found)
 236                  (not (eobp)))
 237        (forward-paragraph 1)
 238        (setq end (point))
 239        (setq found
 240              (refer-every (function (lambda (keyword)
 241                                 (goto-char begin)
 242                                 (re-search-forward keyword end t)))
 243                     keywords-list))
 244        (if (not found)
 245            (progn
 246              (setq begin end)
 247              (goto-char begin))))
 248      (if found
 249          (progn (goto-char begin)
 250                 (re-search-forward "\\W" nil t)
 251                 (message "Scanning %s... found" file))
 252        (progn (message "Scanning %s... not found" file)
 253               nil))))
 254
 255 (defun refer-every (pred l)
 256   (cond ((null l) nil)
 257         ((funcall pred (car l))
 258          (or (null (cdr l))
 259              (refer-every pred (cdr l))))))
 260
 261 (defun refer-convert-string-to-list-of-strings (s)
 262    (let ((current (current-buffer))
 263          (temp-buffer (get-buffer-create "*refer-temp*")))
 264       (set-buffer temp-buffer)
 265       (erase-buffer)
 266       (insert (regexp-quote s))
 267       (goto-char (point-min))
 268       (insert "(\"")
 269       (while (re-search-forward "[ \t]+" nil t)
 270          (replace-match "\" \"" t t))
 271       (goto-char (point-max))
 272       (insert "\")")
 273       (goto-char (point-min))
 274       (prog1 (read temp-buffer)
 275          (set-buffer current))))
 276
 277 (defun refer-expand-files (file-list dir-list)
 278   (let (file files dir dirs)
 279     (while (setq file (car file-list))
 280       (setq dirs (copy-alist dir-list))
 281       (while (setq dir (car dirs))
 282         (if (file-exists-p (expand-file-name file dir))
 283             (setq files (append files (list (expand-file-name file dir)))
 284                   dirs  nil)
 285           (if (file-exists-p (expand-file-name (concat file ".bib") dir))
 286               (setq files (append files (list (expand-file-name (concat file ".bib")
 287                                                                 dir)))
 288                     dirs  nil)
 289             (setq dirs (cdr dirs)))))
 290       (setq file-list (cdr file-list)))
 291     files))
 292
 293 (defun refer-get-bib-files ()
 294   (let* ((dir-list
 295           (cond
 296            ((null refer-bib-directory)
 297             '("."))
 298            ((or (eq refer-bib-directory 'texinputs)
 299                 (eq refer-bib-directory 'bibinputs))
 300             (let ((envvar (getenv (if (eq refer-bib-directory 'texinputs)
 301                                       "TEXINPUTS"
 302                                     "BIBINPUTS")))
 303                   (dirs nil))
 304               (if (null envvar)
 305                   (setq envvar "."))
 306               (while (string-match ":" envvar)
 307                 (let ((dir (substring envvar 0 (match-beginning 0))))
 308                   (if (and (not (string-equal "" dir))
 309                            (file-directory-p dir))
 310                       (setq dirs (append (list (expand-file-name dir nil))
 311                                          dirs))))
 312                 (setq envvar (substring envvar (match-end 0))))
 313               (if (and (not (string-equal "" envvar))
 314                        (file-directory-p envvar))
 315                   (setq dirs (append (list envvar) dirs)))
 316               (setq dirs (nreverse dirs))))
 317            ((listp refer-bib-directory)
 318             refer-bib-directory)
 319            (t
 320             (list refer-bib-directory))))
 321          (files
 322            (cond
 323             ((null refer-bib-files)
 324              (list (expand-file-name
 325                     (if (eq major-mode 'bibtex-mode)
 326                         (read-file-name
 327                          (format ".bib file: (default %s) "
 328                                  (file-name-nondirectory
 329                                   (buffer-file-name)))
 330                          (file-name-directory (buffer-file-name))
 331                          (file-name-nondirectory (buffer-file-name))
 332                          t)
 333                       (read-file-name ".bib file: " nil nil t)))))
 334             ((eq refer-bib-files 'auto)
 335              (let ((files
 336                     (save-excursion
 337                       (if (setq refer-same-file (eq major-mode 'bibtex-mode))
 338                           (list buffer-file-name)
 339                         (if (progn
 340                               (goto-char (point-min))
 341                               (re-search-forward (concat refer-bib-files-regexp
 342                                                          "\\s-*\{") nil t))
 343                             (let ((files (list (buffer-substring
 344                                                 (point)
 345                                                 (progn
 346                                                   (re-search-forward "[,\}]"
 347                                                                      nil t)
 348                                                   (backward-char 1)
 349                                                   (point))))))
 350                               (while (not (looking-at "\}"))
 351                                 (setq files (append files
 352                                                     (list (buffer-substring
 353                                                            (progn (forward-char 1)
 354                                                                   (point))
 355                                                            (progn (re-search-forward
 356                                                                    "[,\}]" nil t)
 357                                                                   (backward-char 1)
 358                                                                   (point)))))))
 359                               files)
 360                           (error (concat "No \\\\bibliography command in this "
 361                                          "buffer, can't read refer-bib-files")))))))
 362                (refer-expand-files files dir-list)))
 363             ((eq refer-bib-files 'dir)
 364              (let ((dirs (nreverse dir-list))
 365                    dir files)
 366                (while (setq dir (car dirs))
 367                  (setq files
 368                        (append (directory-files dir t "\\.bib$")
 369                                files))
 370                  (setq dirs (cdr dirs)))
 371                files))
 372             ((and (listp refer-bib-files)
 373                   (or (eq refer-bib-directory 'texinputs)
 374                       (eq refer-bib-directory 'bibinputs)))
 375              (refer-expand-files refer-bib-files dir-list))
 376             ((listp refer-bib-files) refer-bib-files)
 377             (t (error "Illegal value for refer-bib-files: %s"
 378                       refer-bib-files)))))
 379     (if (or (eq refer-bib-directory 'texinputs)
 380             (eq refer-bib-directory 'bibinputs))
 381         (setq refer-bib-directory dir-list))
 382     (if refer-cache-bib-files
 383         (setq refer-bib-files files))
 384     files))
 385
 386 ;;; refer.el ends here
 387