code.delx.au - gnu-emacs/blob - lisp/imenu.el

   1 ;;; imenu.el --- Framework for mode-specific buffer indexes.
   2
   3 ;; Copyright (C) 1994, 1995, 1996 Free Software Foundation, Inc.
   4
   5 ;; Author: Ake Stenhoff <etxaksf@aom.ericsson.se>
   6 ;;         Lars Lindberg <lli@sypro.cap.se>
   7 ;; Created: 8 Feb 1994
   8 ;; Keywords: tools
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Purpose of this package:
  30 ;;   To present a framework for mode-specific buffer indexes.
  31 ;;   A buffer index is an alist of names and buffer positions.
  32 ;;   For instance all functions in a C-file and their positions.
  33 ;;
  34 ;; How it works:
  35
  36 ;;   A mode-specific function is called to generate the index.  It is
  37 ;;   then presented to the user, who can choose from this index.
  38 ;;
  39 ;;   The package comes with a set of example functions for how to
  40 ;;   utilize this package.
  41
  42 ;;   There are *examples* for index gathering functions/regular
  43 ;;   expressions for C/C++ and Lisp/Emacs Lisp but it is easy to
  44 ;;   customize for other modes.  A function for jumping to the chosen
  45 ;;   index position is also supplied.
  46
  47 ;;; Thanks goes to
  48 ;;  [simon] - Simon Leinen simon@lia.di.epfl.ch
  49 ;;  [dean] - Dean Andrews ada@unison.com
  50 ;;  [alon] - Alon Albert al@mercury.co.il
  51 ;;  [greg] - Greg Thompson gregt@porsche.visix.COM
  52 ;;  [wolfgang] - Wolfgang Bangerth zcg51122@rpool1.rus.uni-stuttgart.de
  53 ;;  [kai] - Kai Grossjohann grossjoh@linus.informatik.uni-dortmund.de
  54 ;;  [david] - David M. Smith dsmith@stats.adelaide.edu.au
  55 ;;  [christian] - Christian Egli Christian.Egli@hcsd.hac.com
  56 ;;  [karl] - Karl Fogel kfogel@floss.life.uiuc.edu
  57
  58 ;;; Code
  59
  60 (eval-when-compile (require 'cl))
  61
  62 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  63 ;;;
  64 ;;; Customizable variables
  65 ;;;
  66 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  67
  68 (defvar imenu-auto-rescan nil
  69   "*Non-nil means Imenu should always rescan the buffers.")
  70
  71 (defvar imenu-auto-rescan-maxout 60000
  72   "* auto-rescan is disabled in buffers larger than this.
  73 This variable is buffer-local.")
  74
  75 (defvar imenu-always-use-completion-buffer-p nil
  76   "*Set this to non-nil for displaying the index in a completion buffer.
  77
  78 Non-nil means always display the index in a completion buffer.
  79 Nil means display the index as a mouse menu when the mouse was
  80 used to invoke `imenu'.
  81 `never' means never automatically display a listing of any kind.")
  82
  83 (defvar imenu-sort-function nil
  84   "*The function to use for sorting the index mouse-menu.
  85
  86 Affects only the mouse index menu.
  87
  88 Set this to nil if you don't want any sorting (faster).
  89 The items in the menu are then presented in the order they were found
  90 in the buffer.
  91
  92 Set it to `imenu--sort-by-name' if you want alphabetic sorting.
  93
  94 The function should take two arguments and return T if the first
  95 element should come before the second.  The arguments are cons cells;
  96 \(NAME . POSITION).  Look at `imenu--sort-by-name' for an example.")
  97
  98 (defvar imenu-max-items 25
  99   "*Maximum number of elements in an mouse menu for Imenu.")
 100
 101 (defvar imenu-scanning-message "Scanning buffer for index (%3d%%)"
 102   "*Progress message during the index scanning of the buffer.
 103 If non-nil, user gets a message during the scanning of the buffer
 104
 105 Relevant only if the mode-specific function that creates the buffer
 106 index use `imenu-progress-message'.")
 107
 108 (defvar imenu-space-replacement "^"
 109   "*The replacement string for spaces in index names.
 110 Used when presenting the index in a completion-buffer to make the
 111 names work as tokens.")
 112
 113 (defvar imenu-level-separator ":"
 114   "*The separator between index names of different levels.
 115 Used for making mouse-menu titles and for flattening nested indexes
 116 with name concatenation.")
 117
 118 ;;;###autoload
 119 (defvar imenu-generic-expression nil
 120   "The regex pattern to use for creating a buffer index.
 121
 122 If non-nil this pattern is passed to `imenu-create-index-with-pattern'
 123 to create a buffer index.
 124
 125 It is an alist with elements that look like this: (MENU-TITLE
 126 REGEXP INDEX).
 127
 128 MENU-TITLE is a string used as the title for the submenu or nil if the
 129 entries are not nested.
 130
 131 REGEXP is a regexp that should match a construct in the buffer that is
 132 to be displayed in the menu; i.e., function or variable definitions,
 133 etc.  It contains a substring which is the name to appear in the
 134 menu.  See the info section on Regexps for more information.
 135
 136 INDEX points to the substring in REGEXP that contains the name (of the
 137 function, variable or type) that is to appear in the menu.
 138
 139 For emacs-lisp-mode for example PATTERN would look like:
 140
 141 '((nil \"^\\\\s-*(def\\\\(un\\\\|subst\\\\|macro\\\\|advice\\\\)\\\\s-+\\\\([-A-Za-z0-9+]+\\\\)\" 2)
 142   (\"*Vars*\" \"^\\\\s-*(def\\\\(var\\\\|const\\\\)\\\\s-+\\\\([-A-Za-z0-9+]+\\\\)\" 2)
 143   (\"*Types*\" \"^\\\\s-*(def\\\\(type\\\\|struct\\\\|class\\\\|ine-condition\\\\)\\\\s-+\\\\([-A-Za-z0-9+]+\\\\)\" 2))
 144
 145 The variable is buffer-local.")
 146
 147 ;;;###autoload
 148 (make-variable-buffer-local 'imenu-generic-expression)
 149
 150 ;;;; Hooks
 151
 152 (defvar imenu-create-index-function 'imenu-default-create-index-function
 153   "The function to use for creating a buffer index.
 154
 155 It should be a function that takes no arguments and returns an index
 156 of the current buffer as an alist.  The elements in the alist look
 157 like: (INDEX-NAME . INDEX-POSITION).  You may also nest index list like
 158 \(INDEX-NAME . INDEX-ALIST).
 159
 160 This function is called within a `save-excursion'.
 161
 162 The variable is buffer-local.")
 163 (make-variable-buffer-local 'imenu-create-index-function)
 164
 165 (defvar imenu-prev-index-position-function 'beginning-of-defun
 166   "Function for finding the next index position.
 167
 168 If `imenu-create-index-function' is set to
 169 `imenu-default-create-index-function', then you must set this variable
 170 to a function that will find the next index, looking backwards in the
 171 file.
 172
 173 The function should leave point at the place to be connected to the
 174 index and it should return nil when it doesn't find another index.")
 175 (make-variable-buffer-local 'imenu-prev-index-position-function)
 176
 177 (defvar imenu-extract-index-name-function nil
 178   "Function for extracting the index name.
 179
 180 This function is called after the function pointed out by
 181 `imenu-prev-index-position-function'.")
 182 (make-variable-buffer-local 'imenu-extract-index-name-function)
 183
 184 ;;;
 185 ;;; Macro to display a progress message.
 186 ;;; RELPOS is the relative position to display.
 187 ;;; If RELPOS is nil, then the relative position in the buffer
 188 ;;; is calculated.
 189 ;;; PREVPOS is the variable in which we store the last position displayed.
 190 (defmacro imenu-progress-message (prevpos &optional relpos reverse)
 191   (` (and
 192       imenu-scanning-message
 193       (let ((pos (, (if relpos
 194                         relpos
 195                       (` (imenu--relative-position (, reverse)))))))
 196         (if (, (if relpos t
 197                  (` (> pos (+ 5 (, prevpos))))))
 198             (progn
 199               (message imenu-scanning-message pos)
 200               (setq (, prevpos) pos)))))))
 201
 202
 203 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 204 ;;;;
 205 ;;;; Some examples of functions utilizing the framework of this
 206 ;;;; package.
 207 ;;;;
 208 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 209
 210 ;; Return the current/previous sexp and the location of the sexp (its
 211 ;; beginning) without moving the point.
 212 (defun imenu-example--name-and-position ()
 213   (save-excursion
 214     (forward-sexp -1)
 215     (let ((beg (point))
 216           (end (progn (forward-sexp) (point)))
 217           (marker (make-marker)))
 218       (set-marker marker beg)
 219       (cons (buffer-substring beg end)
 220             marker))))
 221
 222 ;;;
 223 ;;; Lisp
 224 ;;;
 225
 226 (defun imenu-example--lisp-extract-index-name ()
 227   ;; Example of a candidate for `imenu-extract-index-name-function'.
 228   ;; This will generate a flat index of definitions in a lisp file.
 229   (save-match-data
 230     (and (looking-at "(def")
 231          (condition-case nil
 232              (progn
 233                (down-list 1)
 234                (forward-sexp 2)
 235                (let ((beg (point))
 236                      (end (progn (forward-sexp -1) (point))))
 237                  (buffer-substring beg end)))
 238            (error nil)))))
 239
 240 (defun imenu-example--create-lisp-index ()
 241   ;; Example of a candidate for `imenu-create-index-function'.
 242   ;; It will generate a nested index of definitions.
 243   (let ((index-alist '())
 244         (index-var-alist '())
 245         (index-type-alist '())
 246         (index-unknown-alist '())
 247         prev-pos)
 248     (goto-char (point-max))
 249     (imenu-progress-message prev-pos 0)
 250     ;; Search for the function
 251     (while (beginning-of-defun)
 252       (imenu-progress-message prev-pos nil t)
 253       (save-match-data
 254         (and (looking-at "(def")
 255              (save-excursion
 256                (down-list 1)
 257                (cond
 258                 ((looking-at "def\\(var\\|const\\)")
 259                  (forward-sexp 2)
 260                  (push (imenu-example--name-and-position)
 261                        index-var-alist))
 262                 ((looking-at "def\\(un\\|subst\\|macro\\|advice\\)")
 263                  (forward-sexp 2)
 264                  (push (imenu-example--name-and-position)
 265                        index-alist))
 266                 ((looking-at "def\\(type\\|struct\\|class\\|ine-condition\\)")
 267                  (forward-sexp 2)
 268                  (if (= (char-after (1- (point))) ?\))
 269                      (progn
 270                        (forward-sexp -1)
 271                        (down-list 1)
 272                        (forward-sexp 1)))
 273                  (push (imenu-example--name-and-position)
 274                        index-type-alist))
 275                 (t
 276                  (forward-sexp 2)
 277                  (push (imenu-example--name-and-position)
 278                        index-unknown-alist)))))))
 279     (imenu-progress-message prev-pos 100)
 280     (and index-var-alist
 281          (push (cons "Variables" index-var-alist)
 282                index-alist))
 283     (and index-type-alist
 284          (push (cons "Types" index-type-alist)
 285                index-alist))
 286     (and index-unknown-alist
 287          (push (cons "Syntax-unknown" index-unknown-alist)
 288                index-alist))
 289     index-alist))
 290
 291 ;; Regular expression to find C functions
 292 (defvar imenu-example--function-name-regexp-c
 293   (concat
 294    "^[a-zA-Z0-9]+[ \t]?"                ; type specs; there can be no
 295    "\\([a-zA-Z0-9_*]+[ \t]+\\)?"        ; more than 3 tokens, right?
 296    "\\([a-zA-Z0-9_*]+[ \t]+\\)?"
 297    "\\([*&]+[ \t]*\\)?"                 ; pointer
 298    "\\([a-zA-Z0-9_*]+\\)[ \t]*("        ; name
 299    ))
 300
 301 (defun imenu-example--create-c-index (&optional regexp)
 302   (let ((index-alist '())
 303         prev-pos char)
 304     (goto-char (point-min))
 305     (imenu-progress-message prev-pos 0)
 306     ;; Search for the function
 307     (save-match-data
 308       (while (re-search-forward
 309               (or regexp imenu-example--function-name-regexp-c)
 310               nil t)
 311         (imenu-progress-message prev-pos)
 312         (backward-up-list 1)
 313         (save-excursion
 314           (goto-char (scan-sexps (point) 1))
 315           (setq char (following-char)))
 316         ;; Skip this function name if it is a prototype declaration.
 317         (if (not (eq char ?\;))
 318             (push (imenu-example--name-and-position) index-alist))))
 319     (imenu-progress-message prev-pos 100)
 320     (nreverse index-alist)))
 321
 322
 323 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 324 ;;;
 325 ;;; Internal variables
 326 ;;;
 327 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 328
 329 ;; The item to use in the index for rescanning the buffer.
 330 (defconst imenu--rescan-item '("*Rescan*" . -99))
 331
 332 ;; The latest buffer index.
 333 ;; Buffer local.
 334 (defvar imenu--index-alist nil)
 335 (make-variable-buffer-local 'imenu--index-alist)
 336
 337 ;; The latest buffer index used to update the menu bar menu.
 338 (defvar imenu--last-menubar-index-alist nil)
 339 (make-variable-buffer-local 'imenu--last-menubar-index-alist)
 340
 341 ;; History list for 'jump-to-function-in-buffer'.
 342 ;; Making this buffer local caused it not to work!
 343 (defvar imenu--history-list nil)
 344
 345 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 346 ;;;
 347 ;;; Internal support functions
 348 ;;;
 349 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 350
 351 ;;;
 352 ;;; Sort function
 353 ;;; Sorts the items depending on their index name.
 354 ;;; An item look like (NAME . POSITION).
 355 ;;;
 356 (defun imenu--sort-by-name (item1 item2)
 357   (string-lessp (car item1) (car item2)))
 358
 359 (defun imenu--relative-position (&optional reverse)
 360   ;; Support function to calculate relative position in buffer
 361   ;; Beginning of buffer is 0 and end of buffer is 100
 362   ;; If REVERSE is non-nil then the beginning is 100 and the end is 0.
 363   (let ((pos (point))
 364         (total (buffer-size)))
 365     (and reverse (setq pos (- total pos)))
 366     (if (> total 50000)
 367         ;; Avoid overflow from multiplying by 100!
 368         (/ (1- pos) (max (/ total 100) 1))
 369       (/ (* 100 (1- pos)) (max total 1)))))
 370
 371 ;; Split LIST into sublists of max length N.
 372 ;; Example (imenu--split '(1 2 3 4 5 6 7 8) 3)-> '((1 2 3) (4 5 6) (7 8))
 373 (defun imenu--split (list n)
 374   (let ((remain list)
 375         (result '())
 376         (sublist '())
 377         (i 0))
 378     (while remain
 379       (push (pop remain) sublist)
 380       (incf i)
 381       (and (= i n)
 382            ;; We have finished a sublist
 383            (progn (push (nreverse sublist) result)
 384                   (setq i 0)
 385                   (setq sublist '()))))
 386     ;; There might be a sublist (if the length of LIST mod n is != 0)
 387     ;; that has to be added to the result list.
 388     (and sublist
 389          (push (nreverse sublist) result))
 390     (nreverse result)))
 391
 392 ;;; Split the alist MENULIST into a nested alist, if it is long enough.
 393 ;;; In any case, add TITLE to the front of the alist.
 394 (defun imenu--split-menu (menulist title)
 395   (if (> (length menulist) imenu-max-items)
 396       (let ((count 0))
 397         (cons title
 398               (mapcar
 399                (function
 400                 (lambda (menu)
 401                   (cons (format "(%s-%d)" title (setq count (1+ count)))
 402                         menu)))
 403                (imenu--split menulist imenu-max-items))))
 404     (cons title menulist)))
 405
 406 ;;; Split up each long alist that are nested within ALIST
 407 ;;; into nested alists.
 408 (defun imenu--split-submenus (alist)
 409   (mapcar (function (lambda (elt)
 410                       (if (and (consp elt)
 411                                (stringp (car elt))
 412                                (listp (cdr elt)))
 413                           (imenu--split-menu (cdr elt) (car elt))
 414                         elt)))
 415           alist))
 416
 417 ;;;
 418 ;;; Find all items in this buffer that should be in the index.
 419 ;;; Returns an alist on the form
 420 ;;; ((NAME . POSITION) (NAME . POSITION) ...)
 421 ;;;
 422
 423 (defun imenu--make-index-alist (&optional noerror)
 424   ;; Create a list for this buffer only when needed.
 425   (or (and imenu--index-alist
 426            (or (not imenu-auto-rescan)
 427                (and imenu-auto-rescan
 428                     (> (buffer-size)  imenu-auto-rescan-maxout))))
 429       ;; Get the index
 430       (setq imenu--index-alist
 431             (save-excursion
 432               (funcall imenu-create-index-function))))
 433   (or imenu--index-alist noerror
 434       (error "No items suitable for an index found in this buffer"))
 435   (or imenu--index-alist
 436       (setq imenu--index-alist (list nil)))
 437   ;; Add a rescan option to the index.
 438   (cons imenu--rescan-item imenu--index-alist))
 439 ;;;
 440 ;;; Find all markers in alist and makes
 441 ;;; them point nowhere.
 442 ;;;
 443 (defun imenu--cleanup (&optional alist)
 444   ;; Sets the markers in imenu--index-alist
 445   ;; point nowhere.
 446   ;; if alist is provided use that list.
 447   (or alist
 448       (setq alist imenu--index-alist))
 449   (and alist
 450        (mapcar
 451         (function
 452          (lambda (item)
 453            (cond
 454             ((markerp (cdr item))
 455              (set-marker (cdr item) nil))
 456             ((consp (cdr item))
 457              (imenu--cleanup (cdr item))))))
 458         alist)
 459        t))
 460
 461 (defun imenu--create-keymap-2 (alist counter &optional commands)
 462   (let ((map nil))
 463     (mapcar
 464      (function
 465       (lambda (item)
 466         (cond
 467          ((listp (cdr item))
 468           (append (list (setq counter (1+ counter))
 469                         (car item) 'keymap (car item))
 470                   (imenu--create-keymap-2 (cdr item) (+ counter 10) commands)))
 471          (t
 472           (let ((end (if commands `(lambda () (interactive)
 473                                      (imenu--menubar-select ',item))
 474                        (cons '(nil) t))))
 475             (cons (car item)
 476                   (cons (car item) end))))
 477          )))
 478      alist)))
 479
 480 ;; If COMMANDS is non-nil, make a real keymap
 481 ;; with a real command used as the definition.
 482 ;; If it is nil, make something suitable for x-popup-menu.
 483 (defun imenu--create-keymap-1 (title alist &optional commands)
 484   (append (list 'keymap title) (imenu--create-keymap-2 alist 0 commands)))
 485
 486
 487 (defun imenu--in-alist (str alist)
 488   "Check whether the string STR is contained in multi-level ALIST."
 489   (let (elt head tail res)
 490     (setq res nil)
 491     (while alist
 492       (setq elt (car alist)
 493             tail (cdr elt)
 494             alist (cdr alist)
 495             head (car elt))
 496       (if (string= str head)
 497           (setq alist nil res elt)
 498         (if (and (listp tail)
 499                  (setq res (imenu--in-alist str tail)))
 500             (setq alist nil))))
 501     res))
 502
 503 (defun imenu-default-create-index-function ()
 504   "*Wrapper for index searching functions.
 505
 506 Moves point to end of buffer and then repeatedly calls
 507 `imenu-prev-index-position-function' and `imenu-extract-index-name-function'.
 508 Their results are gathered into an index alist."
 509   ;; These should really be done by setting imenu-create-index-function
 510   ;; in these major modes.  But save that change for later.
 511   (cond ((and (fboundp imenu-prev-index-position-function)
 512               (fboundp imenu-extract-index-name-function))
 513          (let ((index-alist '())
 514                prev-pos name)
 515            (goto-char (point-max))
 516            (imenu-progress-message prev-pos 0 t)
 517            ;; Search for the function
 518            (while (funcall imenu-prev-index-position-function)
 519              (imenu-progress-message prev-pos nil t)
 520              (save-excursion
 521                (setq name (funcall imenu-extract-index-name-function)))
 522              (and (stringp name)
 523                   (push (cons name (point)) index-alist)))
 524            (imenu-progress-message prev-pos 100 t)
 525            index-alist))
 526         ;; Use generic expression if possible.
 527         ((and imenu-generic-expression)
 528          (imenu--generic-function imenu-generic-expression))
 529         (t
 530          (error "The mode \"%s\" does not take full advantage of imenu.el yet."
 531                 mode-name))))
 532
 533 (defun imenu--replace-spaces (name replacement)
 534   ;; Replace all spaces in NAME with REPLACEMENT.
 535   ;; That second argument should be a string.
 536   (mapconcat
 537    (function
 538     (lambda (ch)
 539       (if (char-equal ch ?\ )
 540           replacement
 541         (char-to-string ch))))
 542    name
 543    ""))
 544
 545 (defun imenu--flatten-index-alist (index-alist &optional concat-names prefix)
 546   ;; Takes a nested INDEX-ALIST and returns a flat index alist.
 547   ;; If optional CONCAT-NAMES is non-nil, then a nested index has its
 548   ;; name and a space concatenated to the names of the children.
 549   ;; Third argument PREFIX is for internal use only.
 550   (mapcan
 551    (function
 552     (lambda (item)
 553       (let* ((name (car item))
 554              (pos (cdr item))
 555              (new-prefix (and concat-names
 556                               (if prefix
 557                                   (concat prefix imenu-level-separator name)
 558                                 name))))
 559         (cond
 560          ((or (markerp pos) (numberp pos))
 561           (list (cons new-prefix pos)))
 562          (t
 563           (imenu--flatten-index-alist pos new-prefix))))))
 564    index-alist))
 565
 566 ;;;
 567 ;;; Generic index gathering function.
 568 ;;;
 569
 570 (defun imenu--generic-function (patterns)
 571 ;; Built on some ideas that Erik Naggum <erik@naggum.no> once posted
 572 ;; to comp.emacs
 573   "Return an index of the current buffer as an alist.
 574
 575 PATTERN is an alist with elements that look like this: (MENU-TITLE
 576 REGEXP INDEX).
 577
 578 MENU-TITLE is a string used as the title for the submenu or nil if the
 579 entries are not nested.
 580
 581 REGEXP is a regexp that should match a construct in the buffer that is
 582 to be displayed in the menu; i.e., function or variable definitions,
 583 etc.  It contains a substring which is the name to appear in the
 584 menu.  See the info section on Regexps for more information.
 585
 586 INDEX points to the substring in REGEXP that contains the name (of the
 587 function, variable or type) that is to appear in the menu.
 588
 589 For emacs-lisp-mode for example PATTERN would look like:
 590
 591 '((nil \"^\\\\s-*(def\\\\(un\\\\|subst\\\\|macro\\\\|advice\\\\)\\\\s-+\\\\([-A-Za-z0-9]+\\\\)\" 2)
 592   (\"*Vars*\" \"^\\\\s-*(def\\\\(var\\\\|const\\\\)\\\\s-+\\\\([-A-Za-z0-9]+\\\\)\" 2)
 593   (\"*Types*\" \"^\\\\s-*(def\\\\(type\\\\|struct\\\\|class\\\\|ine-condition\\\\)\\\\s-+\\\\([-A-Za-z0-9]+\\\\)\" 2))'
 594
 595 Returns an index of the current buffer as an alist.  The elements in
 596 the alist look like: (INDEX-NAME . INDEX-POSITION).  They may also be
 597 nested index lists like (INDEX-NAME . INDEX-ALIST) depending on
 598 pattern.
 599
 600 \(imenu--generic-function PATTERN\)."
 601
 602   (let ((index-alist (list 'dummy))
 603         (found nil)
 604         (global-regexp
 605          (concat "\\("
 606                  (mapconcat
 607                   (function (lambda (pattern) (identity (cadr pattern))))
 608                   patterns "\\)\\|\\(")
 609                  "\\)"))
 610         prev-pos)
 611
 612     (goto-char (point-max))
 613     (imenu-progress-message prev-pos 0 t)
 614     (save-match-data
 615       (while (re-search-backward global-regexp nil t)
 616         (imenu-progress-message prev-pos nil t)
 617         (setq found nil)
 618         (save-excursion
 619           (goto-char (match-beginning 0))
 620           (mapcar
 621            (function
 622             (lambda (pat)
 623               (let ((menu-title (car pat))
 624                     (regexp (cadr pat))
 625                     (index (caddr pat)))
 626                     (if (and (not found) ; Only allow one entry;
 627                              (looking-at regexp))
 628                         (let ((beg (match-beginning index))
 629                               (end (match-end index)))
 630                           (setq found t)
 631                           (push
 632                            (cons (buffer-substring-no-properties beg end) beg)
 633                            (cdr
 634                             (or (assoc menu-title index-alist)
 635                                 (car (push
 636                                       (cons menu-title '())
 637                                       index-alist))))))))))
 638            patterns))))
 639     (imenu-progress-message prev-pos 100 t)
 640     (let ((main-element (assq nil index-alist)))
 641       (nconc (delq main-element (delq 'dummy index-alist)) main-element))))
 642
 643 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 644 ;;;
 645 ;;; The main functions for this package!
 646 ;;;
 647 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 648
 649 (defun imenu--completion-buffer (index-alist &optional prompt)
 650   "Let the user select from INDEX-ALIST in a completion buffer with PROMPT.
 651
 652 Returns t for rescan and otherwise a position number."
 653   ;; Create a list for this buffer only when needed.
 654   (let (name choice
 655              (prepared-index-alist
 656               (mapcar
 657                (function
 658                 (lambda (item)
 659                   (cons (imenu--replace-spaces (car item) imenu-space-replacement)
 660                         (cdr item))))
 661                index-alist)))
 662     (if (eq imenu-always-use-completion-buffer-p 'never)
 663         (setq name (completing-read (or prompt "Index item: ")
 664                                     prepared-index-alist
 665                                     nil t nil 'imenu--history-list))
 666       (save-window-excursion
 667         ;; Display the completion buffer
 668         (with-output-to-temp-buffer "*Completions*"
 669           (display-completion-list
 670            (all-completions "" prepared-index-alist )))
 671         (let ((minibuffer-setup-hook
 672                (function (lambda ()
 673                            (let ((buffer (current-buffer)))
 674                              (save-excursion
 675                                (set-buffer "*Completions*")
 676                                (setq completion-reference-buffer buffer)))))))
 677           ;; Make a completion question
 678           (setq name (completing-read (or prompt "Index item: ")
 679                                       prepared-index-alist
 680                                       nil t nil 'imenu--history-list)))))
 681     (cond ((not (stringp name))
 682            nil)
 683           ((string= name (car imenu--rescan-item))
 684            t)
 685           (t
 686            (setq choice (assoc name prepared-index-alist))
 687            (if (listp (cdr choice))
 688                (imenu--completion-buffer (cdr choice) prompt)
 689              choice)))))
 690
 691 (defun imenu--mouse-menu (index-alist event &optional title)
 692   "Let the user select from a buffer index from a mouse menu.
 693
 694 INDEX-ALIST is the buffer index and EVENT is a mouse event.
 695
 696 Returns t for rescan and otherwise a position number."
 697   (setq index-alist (imenu--split-submenus index-alist))
 698   (let* ((menu  (imenu--split-menu
 699                  (if imenu-sort-function
 700                      (sort
 701                       (let ((res nil)
 702                             (oldlist index-alist))
 703                         ;; Copy list method from the cl package `copy-list'
 704                         (while (consp oldlist) (push (pop oldlist) res))
 705                         (prog1 (nreverse res) (setcdr res oldlist)))
 706                       imenu-sort-function)
 707                    index-alist)
 708                  (or title (buffer-name))))
 709          position)
 710     (setq menu (imenu--create-keymap-1 (car menu)
 711                                        (if (< 1 (length (cdr menu)))
 712                                            (cdr menu)
 713                                          (cdr (cadr menu)))))
 714     (setq position (x-popup-menu event menu))
 715     (cond ((and (listp position)
 716                 (numberp (car position))
 717                 (stringp (nth (1- (length position)) position)))
 718            (setq position (nth (1- (length position)) position)))
 719           ((and (stringp (car position))
 720                 (null (cdr position)))
 721            (setq position (car position))))
 722     (cond ((eq position nil)
 723            position)
 724           ((listp position)
 725            (imenu--mouse-menu position event
 726                               (if title
 727                                   (concat title imenu-level-separator
 728                                           (car (rassq position index-alist)))
 729                                 (car (rassq position index-alist)))))
 730           ((stringp position)
 731            (or (string= position (car imenu--rescan-item))
 732                (imenu--in-alist position index-alist)))
 733           ((or (= position (cdr imenu--rescan-item))
 734                (and (stringp position)
 735                     (string= position (car imenu--rescan-item))))
 736            t)
 737           (t
 738            (rassq position index-alist)))))
 739
 740 (defun imenu-choose-buffer-index (&optional prompt alist)
 741   "Let the user select from a buffer index and return the chosen index.
 742
 743 If the user originally activated this function with the mouse, a mouse
 744 menu is used.  Otherwise a completion buffer is used and the user is
 745 prompted with PROMPT.
 746
 747 If you call this function with index alist ALIST, then it lets the user
 748 select from ALIST.
 749
 750 With no index alist ALIST, it calls `imenu--make-index-alist' to
 751 create the index alist.
 752
 753 If `imenu-always-use-completion-buffer-p' is non-nil, then the
 754 completion buffer is always used, no matter if the mouse was used or
 755 not.
 756
 757 The returned value is on the form (INDEX-NAME . INDEX-POSITION)."
 758   (let (index-alist
 759         (mouse-triggered (listp last-nonmenu-event))
 760         (result t) )
 761     ;; If selected by mouse, see to that the window where the mouse is
 762     ;; really is selected.
 763     (and mouse-triggered
 764          (not (equal last-nonmenu-event '(menu-bar)))
 765          (let ((window (posn-window (event-start last-nonmenu-event))))
 766            (or (framep window) (null window) (select-window window))))
 767     ;; Create a list for this buffer only when needed.
 768     (while (eq result t)
 769       (setq index-alist (if alist alist (imenu--make-index-alist)))
 770       (setq result
 771             (if (and mouse-triggered
 772                      (not imenu-always-use-completion-buffer-p))
 773                 (imenu--mouse-menu index-alist last-nonmenu-event)
 774               (imenu--completion-buffer index-alist prompt)))
 775       (and (eq result t)
 776            (imenu--cleanup)
 777            (setq imenu--index-alist nil)))
 778     result))
 779
 780 ;;;###autoload
 781 (defun imenu-add-to-menubar (name)
 782   "Adds an `imenu' entry to the menu bar for the current buffer.
 783 NAME is a string used to name the menu bar item.
 784 See the command `imenu' for more information."
 785   (interactive "sImenu menu item name: ")
 786   (let ((newmap (make-sparse-keymap))
 787         (menu-bar (lookup-key (current-local-map) [menu-bar])))
 788     (define-key newmap [menu-bar]
 789       (append (make-sparse-keymap) menu-bar))
 790     (define-key newmap [menu-bar index]
 791       (cons name (nconc (make-sparse-keymap "Imenu")
 792                         (make-sparse-keymap))))
 793     (use-local-map (append newmap (current-local-map))))
 794   (add-hook 'menu-bar-update-hook 'imenu-update-menubar))
 795
 796 (defvar imenu-buffer-menubar nil)
 797
 798 (defun imenu-update-menubar ()
 799   (and (current-local-map)
 800        (keymapp (lookup-key (current-local-map) [menu-bar index]))
 801        (let ((index-alist (imenu--make-index-alist t)))
 802          ;; Don't bother updating if the index-alist has not changed
 803          ;; since the last time we did it.
 804          (or (equal index-alist imenu--last-menubar-index-alist)
 805              (let (menu menu1 old)
 806                (setq imenu--last-menubar-index-alist index-alist)
 807                (setq index-alist (imenu--split-submenus index-alist))
 808                (setq menu (imenu--split-menu
 809                            (if imenu-sort-function
 810                                (sort
 811                                 (let ((res nil)
 812                                       (oldlist index-alist))
 813                                   ;; Copy list method from the cl package `copy-list'
 814                                   (while (consp oldlist) (push (pop oldlist) res))
 815                                   (prog1 (nreverse res) (setcdr res oldlist)))
 816                                 imenu-sort-function)
 817                              index-alist)
 818                            (buffer-name)))
 819                (setq menu1 (imenu--create-keymap-1 (car menu)
 820                                                    (if (< 1 (length (cdr menu)))
 821                                                        (cdr menu)
 822                                                      (cdr (car (cdr menu))))
 823                                                    t))
 824                (setq old (lookup-key (current-local-map) [menu-bar index]))
 825                (if (keymapp old)
 826                    (setcdr (nthcdr 2 old) menu1)))))))
 827
 828 (defun imenu--menubar-select (item)
 829   "Use Imenu to select the function or variable named in this menu item."
 830   (if (equal item '("*Rescan*" . -99))
 831       (progn
 832         (imenu--cleanup)
 833         (setq imenu--index-alist nil)
 834         (imenu-update-menubar))
 835     (imenu item)))
 836
 837 ;;;###autoload
 838 (defun imenu (index-item)
 839   "Jump to a place in the buffer chosen using a buffer menu or mouse menu.
 840 See `imenu-choose-buffer-index' for more information."
 841   (interactive
 842    (list (save-restriction
 843            (widen)
 844            (imenu-choose-buffer-index))))
 845   ;; Convert a string to an alist element.
 846   (if (stringp index-item)
 847       (setq index-item (assoc index-item (imenu--make-index-alist))))
 848   (and index-item
 849        (progn
 850          (push-mark)
 851          (cond
 852           ((markerp (cdr index-item))
 853            (if (or ( > (marker-position (cdr index-item)) (point-min))
 854                    ( < (marker-position (cdr index-item)) (point-max)))
 855                ;; widen if outside narrowing
 856                (widen))
 857            (goto-char (marker-position (cdr index-item))))
 858           (t
 859            (if (or ( > (cdr index-item) (point-min))
 860                    ( < (cdr index-item) (point-max)))
 861                ;; widen if outside narrowing
 862                (widen))
 863            (goto-char (cdr index-item)))))))
 864
 865 (provide 'imenu)
 866
 867 ;;; imenu.el ends here