code.delx.au - gnu-emacs/blob - lisp/mail/mail-utils.el

   1 ;;; mail-utils.el --- utility functions used both by rmail and rnews
   2
   3 ;; Copyright (C) 1985, 2001 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: mail, news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Utility functions for mail and netnews handling.  These handle fine
  28 ;; points of header parsing.
  29
  30 ;;; Code:
  31
  32 ;;; We require lisp-mode to make sure that lisp-mode-syntax-table has
  33 ;;; been initialized.
  34 (require 'lisp-mode)
  35
  36 ;;;###autoload
  37 (defcustom mail-use-rfc822 nil "\
  38 *If non-nil, use a full, hairy RFC822 parser on mail addresses.
  39 Otherwise, (the default) use a smaller, somewhat faster, and
  40 often correct parser."
  41   :type 'boolean
  42   :group 'mail)
  43
  44 ;; Returns t if file FILE is an Rmail file.
  45 ;;;###autoload
  46 (defun mail-file-babyl-p (file)
  47   (let ((buf (generate-new-buffer " *rmail-file-p*")))
  48     (unwind-protect
  49         (save-excursion
  50           (set-buffer buf)
  51           (insert-file-contents file nil 0 100)
  52           (looking-at "BABYL OPTIONS:"))
  53       (kill-buffer buf))))
  54
  55 (defun mail-string-delete (string start end)
  56   "Returns a string containing all of STRING except the part
  57 from START (inclusive) to END (exclusive)."
  58   (if (null end) (substring string 0 start)
  59     (concat (substring string 0 start)
  60             (substring string end nil))))
  61
  62 ;;;###autoload
  63 (defun mail-quote-printable (string &optional wrapper)
  64   "Convert a string to the \"quoted printable\" Q encoding.
  65 If the optional argument WRAPPER is non-nil,
  66 we add the wrapper characters =?ISO-8859-1?Q?....?=."
  67   (let ((i 0) (result ""))
  68     (save-match-data
  69       (while (string-match "[?=\"\200-\377]" string i)
  70         (setq result
  71               (concat result (substring string i (match-beginning 0))
  72                       (upcase (format "=%02x"
  73                                       (aref string (match-beginning 0))))))
  74         (setq i (match-end 0)))
  75       (if wrapper
  76           (concat "=?ISO-8859-1?Q?"
  77                   result (substring string i)
  78                   "?=")
  79         (concat result (substring string i))))))
  80
  81 (defun mail-unquote-printable-hexdigit (char)
  82   (setq char (upcase char))
  83   (if (>= char ?A)
  84       (+ (- char ?A) 10)
  85     (- char ?0)))
  86
  87 ;;;###autoload
  88 (defun mail-unquote-printable (string &optional wrapper)
  89   "Undo the \"quoted printable\" encoding.
  90 If the optional argument WRAPPER is non-nil,
  91 we expect to find and remove the wrapper characters =?ISO-8859-1?Q?....?=."
  92   (save-match-data
  93     (and wrapper
  94          (string-match "\\`=\\?ISO-8859-1\\?Q\\?\\([^?]*\\)\\?" string)
  95          (setq string (match-string 1 string)))
  96     (let ((i 0) strings)
  97       (while (string-match "=\\(..\\|\n\\)" string i)
  98         (setq strings (cons (substring string i (match-beginning 0)) strings))
  99         (unless (= (aref string (match-beginning 1)) ?\n)
 100           (setq strings
 101                 (cons (make-string 1
 102                                    (+ (* 16 (mail-unquote-printable-hexdigit
 103                                              (aref string (match-beginning 1))))
 104                                       (mail-unquote-printable-hexdigit
 105                                        (aref string (1+ (match-beginning 1))))))
 106                       strings)))
 107         (setq i (match-end 0)))
 108       (apply 'concat (nreverse (cons (substring string i) strings))))))
 109
 110 ;;;###autoload
 111 (defun mail-unquote-printable-region (beg end &optional wrapper noerror)
 112   "Undo the \"quoted printable\" encoding in buffer from BEG to END.
 113 If the optional argument WRAPPER is non-nil,
 114 we expect to find and remove the wrapper characters =?ISO-8859-1?Q?....?=.
 115 If NOERROR is non-nil, return t if successful."
 116   (interactive "r\nP")
 117   (let (failed)
 118     (save-match-data
 119       (save-excursion
 120         (save-restriction
 121           (narrow-to-region beg end)
 122           (goto-char (point-min))
 123           (when (and wrapper
 124                      (looking-at "\\`=\\?ISO-8859-1\\?Q\\?\\([^?]*\\)\\?"))
 125             (delete-region (match-end 1) end)
 126             (delete-region (point) (match-beginning 1)))
 127           (while (re-search-forward "=\\(\\([0-9A-F][0-9A-F]\\)\\|[=\n]\\|..\\)" nil t)
 128             (goto-char (match-end 0))
 129             (cond ((= (char-after (match-beginning 1)) ?\n)
 130                    (replace-match ""))
 131                   ((= (char-after (match-beginning 1)) ?=)
 132                    (replace-match "="))
 133                   ((match-beginning 2)
 134                    (replace-match
 135                     (make-string 1
 136                                  (+ (* 16 (mail-unquote-printable-hexdigit
 137                                            (char-after (match-beginning 2))))
 138                                     (mail-unquote-printable-hexdigit
 139                                      (char-after (1+ (match-beginning 2))))))
 140                     t t))
 141                   (noerror
 142                    (setq failed t))
 143                   (t
 144                    (error "Malformed MIME quoted-printable message"))))
 145           (not failed))))))
 146
 147 (eval-when-compile (require 'rfc822))
 148
 149 (defun mail-strip-quoted-names (address)
 150   "Delete comments and quoted strings in an address list ADDRESS.
 151 Also delete leading/trailing whitespace and replace FOO <BAR> with just BAR.
 152 Return a modified address list."
 153   (if (null address)
 154       nil
 155     (if mail-use-rfc822
 156         (progn (require 'rfc822)
 157                (mapconcat 'identity (rfc822-addresses address) ", "))
 158       (let (pos)
 159
 160        ;; Detect nested comments.
 161        (if (string-match "[ \t]*(\\([^)\\]\\|\\\\.\\|\\\\\n\\)*(" address)
 162            ;; Strip nested comments.
 163            (with-current-buffer (get-buffer-create " *temp*")
 164              (erase-buffer)
 165              (insert address)
 166              (set-syntax-table lisp-mode-syntax-table)
 167              (goto-char 1)
 168              (while (search-forward "(" nil t)
 169                (forward-char -1)
 170                (skip-chars-backward " \t")
 171                (delete-region (point)
 172                               (save-excursion
 173                                 (condition-case ()
 174                                     (forward-sexp 1)
 175                                   (error (goto-char (point-max))))
 176                                   (point))))
 177              (setq address (buffer-string))
 178              (erase-buffer))
 179          ;; Strip non-nested comments an easier way.
 180          (while (setq pos (string-match
 181                             ;; This doesn't hack rfc822 nested comments
 182                             ;;  `(xyzzy (foo) whinge)' properly.  Big deal.
 183                             "[ \t]*(\\([^)\\]\\|\\\\.\\|\\\\\n\\)*)"
 184                             address))
 185            (setq address (replace-match "" nil nil address 0))))
 186
 187        ;; strip surrounding whitespace
 188        (string-match "\\`[ \t\n]*" address)
 189        (setq address (substring address
 190                                 (match-end 0)
 191                                 (string-match "[ \t\n]*\\'" address
 192                                               (match-end 0))))
 193
 194        ;; strip `quoted' names (This is supposed to hack `"Foo Bar" <bar@host>')
 195        (setq pos 0)
 196        (while (setq pos (string-match
 197                           "\\([ \t]?\\)\\([ \t]*\"\\([^\"\\]\\|\\\\.\\|\\\\\n\\)*\"[ \t\n]*\\)"
 198                           address pos))
 199          ;; If the next thing is "@", we have "foo bar"@host.  Leave it.
 200          (if (and (> (length address) (match-end 0))
 201                   (= (aref address (match-end 0)) ?@))
 202              (setq pos (match-end 0))
 203            ;; Otherwise discard the "..." part.
 204            (setq address (replace-match "" nil nil address 2))))
 205        ;; If this address contains <...>, replace it with just
 206        ;; the part between the <...>.
 207        (while (setq pos (string-match "\\(,\\s-*\\|\\`\\)\\([^,]*<\\([^>,:]*\\)>[^,]*\\)\\(\\s-*,\\|\\'\\)"
 208                                       address))
 209          (setq address (replace-match (match-string 3 address)
 210                                       nil 'literal address 2)))
 211        address))))
 212
 213 ;;; The following piece of ugliness is legacy code.  The name was an
 214 ;;; unfortunate choice --- a flagrant violation of the Emacs Lisp
 215 ;;; coding conventions.  `mail-dont-reply-to' would have been
 216 ;;; infinitely better.  Also, `rmail-dont-reply-to-names' might have
 217 ;;; been better named `mail-dont-reply-to-names' and sourced from this
 218 ;;; file instead of in rmail.el.  Yuck.  -pmr
 219 (defun rmail-dont-reply-to (destinations)
 220   "Prune addresses from DESTINATIONS, a list of recipient addresses.
 221 All addresses matching `rmail-dont-reply-to-names' are removed from
 222 the comma-separated list.  The pruned list is returned."
 223   (if (null rmail-dont-reply-to-names)
 224       (setq rmail-dont-reply-to-names
 225             (concat (if rmail-default-dont-reply-to-names
 226                         (concat rmail-default-dont-reply-to-names "\\|")
 227                       "")
 228                     (if (and user-mail-address
 229                              (not (equal user-mail-address user-login-name)))
 230                         (concat (regexp-quote user-mail-address) "\\|")
 231                       "")
 232                     (concat (regexp-quote user-login-name) "\\>"))))
 233   ;; Split up DESTINATIONS and match each element separately.
 234   (let ((start-pos 0) (cur-pos 0)
 235         (case-fold-search t))
 236     (while start-pos
 237       (setq cur-pos (string-match "[,\"]" destinations cur-pos))
 238       (if (and cur-pos (equal (match-string 0 destinations) "\""))
 239           ;; Search for matching quote.
 240           (let ((next-pos (string-match "\"" destinations (1+ cur-pos))))
 241             (if next-pos
 242                 (setq cur-pos (1+ next-pos))
 243               ;; If the open-quote has no close-quote,
 244               ;; delete the open-quote to get something well-defined.
 245               ;; This case is not valid, but it can happen if things
 246               ;; are weird elsewhere.
 247               (setq destinations (concat (substring destinations 0 cur-pos)
 248                                     (substring destinations (1+ cur-pos))))
 249               (setq cur-pos start-pos)))
 250         (let* ((address (substring destinations start-pos cur-pos))
 251                (naked-address (mail-strip-quoted-names address)))
 252           (if (string-match rmail-dont-reply-to-names naked-address)
 253               (setq destinations (concat (substring destinations 0 start-pos)
 254                                     (and cur-pos (substring destinations
 255                                                             (1+ cur-pos))))
 256                     cur-pos start-pos)
 257             (setq cur-pos (and cur-pos (1+ cur-pos))
 258                   start-pos cur-pos))))))
 259   ;; get rid of any trailing commas
 260   (let ((pos (string-match "[ ,\t\n]*\\'" destinations)))
 261     (if pos
 262         (setq destinations (substring destinations 0 pos))))
 263   ;; remove leading spaces. they bother me.
 264   (if (string-match "\\(\\s \\|,\\)*" destinations)
 265       (substring destinations (match-end 0))
 266     destinations))
 267
 268 \f
 269 ;;;###autoload
 270 (defun mail-fetch-field (field-name &optional last all list)
 271   "Return the value of the header field whose type is FIELD-NAME.
 272 The buffer is expected to be narrowed to just the header of the message.
 273 If second arg LAST is non-nil, use the last field of type FIELD-NAME.
 274 If third arg ALL is non-nil, concatenate all such fields with commas between.
 275 If 4th arg LIST is non-nil, return a list of all such fields."
 276   (save-excursion
 277     (goto-char (point-min))
 278     (let ((case-fold-search t)
 279           (name (concat "^" (regexp-quote field-name) "[ \t]*:[ \t]*")))
 280       (if (or all list)
 281           (let ((value (if all "")))
 282             (while (re-search-forward name nil t)
 283               (let ((opoint (point)))
 284                 (while (progn (forward-line 1)
 285                               (looking-at "[ \t]")))
 286                 ;; Back up over newline, then trailing spaces or tabs
 287                 (forward-char -1)
 288                 (skip-chars-backward " \t" opoint)
 289                 (if list
 290                     (setq value (cons (buffer-substring-no-properties
 291                                        opoint (point))
 292                                       value))
 293                   (setq value (concat value
 294                                       (if (string= value "") "" ", ")
 295                                       (buffer-substring-no-properties
 296                                        opoint (point)))))))
 297             (if list
 298                 value
 299               (and (not (string= value "")) value)))
 300         (if (re-search-forward name nil t)
 301             (progn
 302               (if last (while (re-search-forward name nil t)))
 303               (let ((opoint (point)))
 304                 (while (progn (forward-line 1)
 305                               (looking-at "[ \t]")))
 306                 ;; Back up over newline, then trailing spaces or tabs
 307                 (forward-char -1)
 308                 (skip-chars-backward " \t" opoint)
 309                 (buffer-substring-no-properties opoint (point)))))))))
 310 \f
 311 ;; Parse a list of tokens separated by commas.
 312 ;; It runs from point to the end of the visible part of the buffer.
 313 ;; Whitespace before or after tokens is ignored,
 314 ;; but whitespace within tokens is kept.
 315 (defun mail-parse-comma-list ()
 316   (let (accumulated
 317         beg)
 318     (skip-chars-forward " \t\n")
 319     (while (not (eobp))
 320       (setq beg (point))
 321       (skip-chars-forward "^,")
 322       (skip-chars-backward " \t\n")
 323       (setq accumulated
 324             (cons (buffer-substring-no-properties beg (point))
 325                   accumulated))
 326       (skip-chars-forward "^,")
 327       (skip-chars-forward ", \t\n"))
 328     accumulated))
 329
 330 (defun mail-comma-list-regexp (labels)
 331   (let (pos)
 332     (setq pos (or (string-match "[^ \t]" labels) 0))
 333     ;; Remove leading and trailing whitespace.
 334     (setq labels (substring labels pos (string-match "[ \t]*$" labels pos)))
 335     ;; Change each comma to \|, and flush surrounding whitespace.
 336     (while (setq pos (string-match "[ \t]*,[ \t]*" labels))
 337       (setq labels
 338             (concat (substring labels 0 pos)
 339                     "\\|"
 340                     (substring labels (match-end 0))))))
 341   labels)
 342 \f
 343 (defun mail-rfc822-time-zone (time)
 344   (let* ((sec (or (car (current-time-zone time)) 0))
 345          (absmin (/ (abs sec) 60)))
 346     (format "%c%02d%02d" (if (< sec 0) ?- ?+) (/ absmin 60) (% absmin 60))))
 347
 348 (defun mail-rfc822-date ()
 349   (let* ((time (current-time))
 350          (s (current-time-string time)))
 351     (string-match "[^ ]+ +\\([^ ]+\\) +\\([^ ]+\\) \\([^ ]+\\) \\([^ ]+\\)" s)
 352     (concat (substring s (match-beginning 2) (match-end 2)) " "
 353             (substring s (match-beginning 1) (match-end 1)) " "
 354             (substring s (match-beginning 4) (match-end 4)) " "
 355             (substring s (match-beginning 3) (match-end 3)) " "
 356             (mail-rfc822-time-zone time))))
 357
 358 (provide 'mail-utils)
 359
 360 ;;; arch-tag: b24aec2f-fd65-4ceb-9e39-3cc2827036fd
 361 ;;; mail-utils.el ends here