code.delx.au - gnu-emacs/blob - lisp/net/tramp-gw.el

   1 ;;; tramp-gw.el --- Tramp utility functions for HTTP tunnels and SOCKS gateways
   2
   3 ;; Copyright (C) 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   4
   5 ;; Author: Michael Albinus <michael.albinus@gmx.de>
   6 ;; Keywords: comm, processes
   7 ;; Package: tramp
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Access functions for HTTP tunnels and SOCKS gateways from Tramp.
  27 ;; SOCKS functionality is implemented by socks.el from the w3 package.
  28 ;; HTTP tunnels are partly implemented in socks.el and url-http.el;
  29 ;; both implementations are not complete.  Therefore, it is
  30 ;; implemented in this package.
  31
  32 ;;; Code:
  33
  34 (require 'tramp)
  35
  36 ;; Pacify byte-compiler
  37 (eval-when-compile
  38   (require 'cl)
  39   (require 'custom))
  40
  41 ;; Avoid byte-compiler warnings if the byte-compiler supports this.
  42 ;; Currently, XEmacs supports this.
  43 (eval-when-compile
  44   (when (featurep 'xemacs)
  45       (byte-compiler-options (warnings (- unused-vars)))))
  46
  47 ;; We don't add the following methods to `tramp-methods', in order to
  48 ;; exclude them from file name completion.
  49
  50 ;; Define HTTP tunnel method ...
  51 ;;;###tramp-autoload
  52 (defconst tramp-gw-tunnel-method "tunnel"
  53   "*Method to connect HTTP gateways.")
  54
  55 ;; ... and port.
  56 (defconst tramp-gw-default-tunnel-port 8080
  57   "*Default port for HTTP gateways.")
  58
  59 ;; Define SOCKS method ...
  60 ;;;###tramp-autoload
  61 (defconst tramp-gw-socks-method "socks"
  62   "*Method to connect SOCKS servers.")
  63
  64 ;; ... and port.
  65 (defconst tramp-gw-default-socks-port 1080
  66   "*Default port for SOCKS servers.")
  67
  68 ;; Autoload the socks library.  It is used only when we access a SOCKS server.
  69 (autoload 'socks-open-network-stream "socks")
  70 (defvar socks-username (user-login-name))
  71 (defvar socks-server
  72   (list "Default server" "socks" tramp-gw-default-socks-port 5))
  73
  74 ;; Add a default for `tramp-default-user-alist'.  Default is the local user.
  75 (add-to-list
  76  'tramp-default-user-alist
  77  (list (concat "\\`"
  78                (regexp-opt (list tramp-gw-tunnel-method tramp-gw-socks-method))
  79                "\\'")
  80        nil (user-login-name)))
  81
  82 ;; Internal file name functions and variables.
  83
  84 (defvar tramp-gw-vector nil
  85   "Keeps the remote host identification.  Needed for Tramp messages.")
  86
  87 (defvar tramp-gw-gw-vector nil
  88   "Current gateway identification vector.")
  89
  90 (defvar tramp-gw-gw-proc nil
  91   "Current gateway process.")
  92
  93 ;; This variable keeps the listening process, in order to reuse it for
  94 ;; new processes.
  95 (defvar tramp-gw-aux-proc nil
  96   "Process listening on local port, as mediation between SSH and the gateway.")
  97
  98 (defun tramp-gw-gw-proc-sentinel (proc event)
  99   "Delete auxiliary process when we are deleted."
 100   (unless (memq (process-status proc) '(run open))
 101     (tramp-message
 102      tramp-gw-vector 4 "Deleting auxiliary process `%s'" tramp-gw-gw-proc)
 103     (let* (tramp-verbose
 104            (p (tramp-get-connection-property proc "process" nil)))
 105       (when (processp p) (delete-process p)))))
 106
 107 (defun tramp-gw-aux-proc-sentinel (proc event)
 108   "Activate the different filters for involved gateway and auxiliary processes."
 109   (when (memq (process-status proc) '(run open))
 110     ;; A new process has been spawned from `tramp-gw-aux-proc'.
 111     (tramp-message
 112      tramp-gw-vector 4
 113      "Opening auxiliary process `%s', speaking with process `%s'"
 114      proc tramp-gw-gw-proc)
 115     (tramp-compat-set-process-query-on-exit-flag proc nil)
 116     ;; We don't want debug messages, because the corresponding debug
 117     ;; buffer might be undecided.
 118     (let (tramp-verbose)
 119       (tramp-set-connection-property tramp-gw-gw-proc "process" proc)
 120       (tramp-set-connection-property proc "process" tramp-gw-gw-proc))
 121     ;; Set the process-filter functions for both processes.
 122     (set-process-filter proc 'tramp-gw-process-filter)
 123     (set-process-filter tramp-gw-gw-proc 'tramp-gw-process-filter)
 124     ;; There might be already some output from the gateway process.
 125     (with-current-buffer (process-buffer tramp-gw-gw-proc)
 126       (unless (= (point-min) (point-max))
 127         (let ((s (buffer-string)))
 128           (delete-region (point) (point-max))
 129           (tramp-gw-process-filter tramp-gw-gw-proc s))))))
 130
 131 (defun tramp-gw-process-filter (proc string)
 132   (let (tramp-verbose)
 133     (process-send-string
 134      (tramp-get-connection-property proc "process" nil) string)))
 135
 136 ;;;###tramp-autoload
 137 (defun tramp-gw-open-connection (vec gw-vec target-vec)
 138   "Open a remote connection to VEC (see `tramp-file-name' structure).
 139 Take GW-VEC as SOCKS or HTTP gateway, i.e. its method must be a
 140 gateway method.  TARGET-VEC identifies where to connect to via
 141 the gateway, it can be different from VEC when there are more
 142 hops to be applied.
 143
 144 It returns a string like \"localhost#port\", which must be used
 145 instead of the host name declared in TARGET-VEC."
 146
 147   ;; Remember vectors for property retrieval.
 148   (setq tramp-gw-vector vec
 149         tramp-gw-gw-vector gw-vec)
 150
 151   ;; Start listening auxiliary process.
 152   (unless (and (processp tramp-gw-aux-proc)
 153                (memq (process-status tramp-gw-aux-proc) '(listen)))
 154     (let ((aux-vec
 155            (vector "aux" (tramp-file-name-user gw-vec)
 156                    (tramp-file-name-host gw-vec) nil)))
 157       (setq tramp-gw-aux-proc
 158             (make-network-process
 159              :name (tramp-buffer-name aux-vec) :buffer nil :host 'local
 160              :server t :noquery t :service t :coding 'binary))
 161       (set-process-sentinel tramp-gw-aux-proc 'tramp-gw-aux-proc-sentinel)
 162       (tramp-compat-set-process-query-on-exit-flag tramp-gw-aux-proc nil)
 163       (tramp-message
 164        vec 4 "Opening auxiliary process `%s', listening on port %d"
 165        tramp-gw-aux-proc (process-contact tramp-gw-aux-proc :service))))
 166
 167   (let* ((gw-method
 168           (intern
 169            (tramp-find-method
 170             (tramp-file-name-method gw-vec)
 171             (tramp-file-name-user gw-vec)
 172             (tramp-file-name-host gw-vec))))
 173          (socks-username
 174           (tramp-find-user
 175            (tramp-file-name-method gw-vec)
 176            (tramp-file-name-user gw-vec)
 177            (tramp-file-name-host gw-vec)))
 178          ;; Declare the SOCKS server to be used.
 179          (socks-server
 180           (list "Tramp tempory socks server list"
 181                 ;; Host name.
 182                 (tramp-file-name-real-host gw-vec)
 183                 ;; Port number.
 184                 (or (tramp-file-name-port gw-vec)
 185                     (case gw-method
 186                       (tunnel tramp-gw-default-tunnel-port)
 187                       (socks tramp-gw-default-socks-port)))
 188                 ;; Type.  We support only http and socks5, NO socks4.
 189                 ;; 'http could be used when HTTP tunnel works in socks.el.
 190                 5))
 191          ;; The function to be called.
 192          (socks-function
 193           (case gw-method
 194             (tunnel 'tramp-gw-open-network-stream)
 195             (socks 'socks-open-network-stream)))
 196          socks-noproxy)
 197
 198     ;; Open SOCKS process.
 199     (setq tramp-gw-gw-proc
 200           (funcall
 201            socks-function
 202            (tramp-get-connection-name gw-vec)
 203            (tramp-get-connection-buffer gw-vec)
 204            (tramp-file-name-real-host target-vec)
 205            (tramp-file-name-port target-vec)))
 206     (set-process-sentinel tramp-gw-gw-proc 'tramp-gw-gw-proc-sentinel)
 207     (tramp-compat-set-process-query-on-exit-flag tramp-gw-gw-proc nil)
 208     (tramp-message
 209      vec 4 "Opened %s process `%s'"
 210      (case gw-method ('tunnel "HTTP tunnel") ('socks "SOCKS"))
 211      tramp-gw-gw-proc)
 212
 213     ;; Return the new host for gateway access.
 214     (format "localhost#%d" (process-contact tramp-gw-aux-proc :service))))
 215
 216 (defun tramp-gw-open-network-stream (name buffer host service)
 217   "Open stream to proxy server HOST:SERVICE.
 218 Resulting process has name NAME and buffer BUFFER.  If
 219 authentication is requested from proxy server, provide it."
 220   (let ((command (format (concat
 221                           "CONNECT %s:%d HTTP/1.1\r\n"
 222                           "Host: %s:%d\r\n"
 223                           "Connection: keep-alive\r\n"
 224                           "User-Agent: Tramp/%s\r\n")
 225                          host service host service tramp-version))
 226         (authentication "")
 227         (first t)
 228         found proc)
 229
 230     (while (not found)
 231       ;; Clean up.
 232       (when (processp proc) (delete-process proc))
 233       (with-current-buffer buffer (erase-buffer))
 234       ;; Open network stream.
 235       (setq proc (open-network-stream
 236                   name buffer (nth 1 socks-server) (nth 2 socks-server)))
 237       (set-process-coding-system proc 'binary 'binary)
 238       (tramp-compat-set-process-query-on-exit-flag proc nil)
 239       ;; Send CONNECT command.
 240       (process-send-string proc (format "%s%s\r\n" command authentication))
 241       (tramp-message
 242        tramp-gw-vector 6 "\n%s"
 243        (format
 244         "%s%s\r\n" command
 245         (replace-regexp-in-string ;; no password in trace!
 246          "Basic [^\r\n]+" "Basic xxxxx" authentication t)))
 247       (with-current-buffer buffer
 248         ;; Trap errors to be traced in the right trace buffer.  Often,
 249         ;; proxies have a timeout of 60".  We wait 65" in order to
 250         ;; receive an answer this case.
 251         (ignore-errors
 252           (let (tramp-verbose)
 253             (tramp-wait-for-regexp proc 65 "\r?\n\r?\n")))
 254         ;; Check return code.
 255         (goto-char (point-min))
 256         (narrow-to-region
 257          (point-min)
 258          (or (search-forward-regexp "\r?\n\r?\n" nil t) (point-max)))
 259         (tramp-message tramp-gw-vector 6 "\n%s" (buffer-string))
 260         (goto-char (point-min))
 261         (search-forward-regexp "^HTTP/[1-9]\\.[0-9]" nil t)
 262         (case (condition-case nil (read (current-buffer)) (error))
 263           ;; Connected.
 264           (200 (setq found t))
 265           ;; We need basic authentication.
 266           (401 (setq authentication (tramp-gw-basic-authentication nil first)))
 267           ;; Target host not found.
 268           (404 (tramp-error-with-buffer
 269                 (current-buffer) tramp-gw-vector 'file-error
 270                 "Host %s not found." host))
 271           ;; We need basic proxy authentication.
 272           (407 (setq authentication (tramp-gw-basic-authentication t first)))
 273           ;; Connection failed.
 274           (503 (tramp-error-with-buffer
 275                 (current-buffer) tramp-gw-vector 'file-error
 276                 "Connection to %s:%d failed." host service))
 277           ;; That doesn't work at all.
 278           (t (tramp-error-with-buffer
 279               (current-buffer) tramp-gw-vector 'file-error
 280               "Access to HTTP server %s:%d failed."
 281               (nth 1 socks-server) (nth 2 socks-server))))
 282         ;; Remove HTTP headers.
 283         (delete-region (point-min) (point-max))
 284         (widen)
 285         (setq first nil)))
 286     ;; Return the process.
 287     proc))
 288
 289 (defun tramp-gw-basic-authentication (proxy pw-cache)
 290   "Return authentication header for CONNECT, based on server request.
 291 PROXY is an indication whether we need a Proxy-Authorization header
 292 or an Authorization header.  If PW-CACHE is non-nil, check for
 293 password in password cache.  This is done for the first try only."
 294
 295   ;; `tramp-current-*' must be set for `tramp-read-passwd'.
 296   (let ((tramp-current-method (tramp-file-name-method tramp-gw-gw-vector))
 297         (tramp-current-user (tramp-file-name-user tramp-gw-gw-vector))
 298         (tramp-current-host (tramp-file-name-host tramp-gw-gw-vector)))
 299     (unless pw-cache (tramp-clear-passwd tramp-gw-gw-vector))
 300     ;; We are already in the right buffer.
 301     (tramp-message
 302      tramp-gw-vector 5 "%s required"
 303      (if proxy "Proxy authentication" "Authentication"))
 304     ;; Search for request header.  We accept only basic authentication.
 305     (goto-char (point-min))
 306     (search-forward-regexp
 307      "^\\(Proxy\\|WWW\\)-Authenticate:\\s-*Basic\\s-+realm=")
 308     ;; Return authentication string.
 309     (format
 310      "%s: Basic %s\r\n"
 311      (if proxy "Proxy-Authorization" "Authorization")
 312      (base64-encode-string
 313       (format
 314        "%s:%s"
 315        socks-username
 316        (tramp-read-passwd
 317         nil
 318         (format
 319          "Password for %s@[%s]: " socks-username (read (current-buffer)))))))))
 320
 321 (add-hook 'tramp-unload-hook
 322           (lambda ()
 323             (unload-feature 'tramp-gw 'force)))
 324
 325 (provide 'tramp-gw)
 326
 327 ;;; TODO:
 328
 329 ;; * Provide descriptive Commentary.
 330 ;; * Enable it for several gateway processes in parallel.
 331
 332 ;;; tramp-gw.el ends here