code.delx.au - gnu-emacs/blob - lisp/emacs-lisp/lisp-mnt.el

   1 ;;; lisp-mnt.el --- minor mode for Emacs Lisp maintainers
   2
   3 ;; Copyright (C) 1992, 1994, 1997 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric S. Raymond <esr@snark.thyrsus.com>
   6 ;; Maintainer: Eric S. Raymond <esr@snark.thyrsus.com>
   7 ;; Created: 14 Jul 1992
   8 ;; Keywords: docs
   9 ;; X-Bogus-Bureaucratic-Cruft: Gruad will get you if you don't watch out!
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  25 ;; the Free Software Foundation,  Inc., 59 Temple Place - Suite 330,
  26 ;; Boston, MA 02111-1307, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; This minor mode adds some services to Emacs-Lisp editing mode.
  31 ;;
  32 ;; First, it knows about the header conventions for library packages.
  33 ;; One entry point supports generating synopses from a library directory.
  34 ;; Another can be used to check for missing headers in library files.
  35 ;;
  36 ;; Another entry point automatically addresses bug mail to a package's
  37 ;; maintainer or author.
  38
  39 ;; This file can be loaded by your lisp-mode-hook.  Have it (require 'lisp-mnt)
  40
  41 ;; This file is an example of the header conventions.  Note the following
  42 ;; features:
  43 ;;
  44 ;;    * Header line --- makes it possible to extract a one-line summary of
  45 ;; the package's uses automatically for use in library synopses, KWIC
  46 ;; indexes and the like.
  47 ;;
  48 ;;    Format is three semicolons, followed by the filename, followed by
  49 ;; three dashes, followed by the summary.  All fields space-separated.
  50 ;;
  51 ;;    * Author line --- contains the name and net address of at least
  52 ;; the principal author.
  53 ;;
  54 ;;    If there are multiple authors, they should be listed on continuation
  55 ;; lines led by ;;<TAB>, like this:
  56 ;;
  57 ;; ;; Author: Ashwin Ram <Ram-Ashwin@cs.yale.edu>
  58 ;; ;;   Dave Sill <de5@ornl.gov>
  59 ;; ;;   David Lawrence <tale@pawl.rpi.edu>
  60 ;; ;;   Noah Friedman <friedman@ai.mit.edu>
  61 ;; ;;   Joe Wells <jbw@maverick.uswest.com>
  62 ;; ;;   Dave Brennan <brennan@hal.com>
  63 ;; ;;   Eric Raymond <esr@snark.thyrsus.com>
  64 ;;
  65 ;; This field may have some special values; notably "FSF", meaning
  66 ;; "Free Software Foundation".
  67 ;;
  68 ;;    * Maintainer line --- should be a single name/address as in the Author
  69 ;; line, or an address only, or the string "FSF".  If there is no maintainer
  70 ;; line, the person(s) in the Author field are presumed to be it.  The example
  71 ;; in this file is mildly bogus because the maintainer line is redundant.
  72 ;;    The idea behind these two fields is to be able to write a Lisp function
  73 ;; that does "send mail to the author" without having to mine the name out by
  74 ;; hand. Please be careful about surrounding the network address with <> if
  75 ;; there's also a name in the field.
  76 ;;
  77 ;;    * Created line --- optional, gives the original creation date of the
  78 ;; file.  For historical interest, basically.
  79 ;;
  80 ;;    * Version line --- intended to give the reader a clue if they're looking
  81 ;; at a different version of the file than the one they're accustomed to.  This
  82 ;; may be an RCS or SCCS header.
  83 ;;
  84 ;;    * Adapted-By line --- this is for FSF's internal use.  The person named
  85 ;; in this field was the one responsible for installing and adapting the
  86 ;; package for the distribution.  (This file doesn't have one because the
  87 ;; author *is* one of the maintainers.)
  88 ;;
  89 ;;    * Keywords line --- used by the finder code (now under construction)
  90 ;; for finding Emacs Lisp code related to a topic.
  91 ;;
  92 ;;    * X-Bogus-Bureaucratic-Cruft line --- this is a joke and an example
  93 ;; of a comment header.  Headers starting with `X-' should never be used
  94 ;; for any real purpose; this is the way to safely add random headers
  95 ;; without invoking the wrath of any program.
  96 ;;
  97 ;;    * Commentary line --- enables Lisp code to find the developer's and
  98 ;; maintainers' explanations of the package internals.
  99 ;;
 100 ;;    * Change log line --- optional, exists to terminate the commentary
 101 ;; section and start a change-log part, if one exists.
 102 ;;
 103 ;;    * Code line --- exists so Lisp can know where commentary and/or
 104 ;; change-log sections end.
 105 ;;
 106 ;;    * Footer line --- marks end-of-file so it can be distinguished from
 107 ;; an expanded formfeed or the results of truncation.
 108
 109 ;;; Change Log:
 110
 111 ;; Tue Jul 14 23:44:17 1992     ESR
 112 ;;      * Created.
 113
 114 ;;; Code:
 115
 116 (require 'emacsbug)
 117
 118 ;;; Variables:
 119
 120 (defgroup lisp-mnt nil
 121   "Minor mode for Emacs Lisp maintainers."
 122   :prefix "lm-"
 123   :group 'maint)
 124
 125 (defcustom lm-header-prefix "^;;*[ \t]+\\(@\(#\)\\)?[ \t]*\\([\$]\\)?"
 126   "Prefix that is ignored before the tag.
 127 For example, you can write the 1st line synopsis string and headers like this
 128 in your Lisp package:
 129
 130    ;; @(#) package.el -- pacakge description
 131    ;;
 132    ;; @(#) $Maintainer:   Person Foo Bar $
 133
 134 The @(#) construct is used by unix what(1) and
 135 then $identifier: doc string $ is used by GNU ident(1)"
 136   :type 'regexp
 137   :group 'lisp-mnt)
 138
 139 (defcustom lm-comment-column 16
 140   "Column used for placing formatted output."
 141   :type 'integer
 142   :group 'lisp-mnt)
 143
 144 (defcustom lm-commentary-header "Commentary\\|Documentation"
 145   "Regexp which matches start of documentation section."
 146   :type 'regexp
 147   :group 'lisp-mnt)
 148
 149 (defcustom lm-history-header "Change Log\\|History"
 150   "Regexp which matches the start of code log section."
 151   :type 'regexp
 152   :group 'lisp-mnt)
 153
 154 ;;; Functions:
 155
 156 ;; These functions all parse the headers of the current buffer
 157
 158 (defsubst lm-get-header-re (header &optional mode)
 159   "Return regexp for matching HEADER.
 160 If called with optional MODE and with value `section',
 161 return section regexp instead."
 162   (cond ((eq mode 'section)
 163          (concat "^;;;;* " header ":[ \t]*$"))
 164         (t
 165          (concat lm-header-prefix header ":[ \t]*"))))
 166
 167 (defsubst lm-get-package-name ()
 168   "Return package name by looking at the first line."
 169   (save-excursion
 170     (goto-char (point-min))
 171     (if (and (looking-at (concat lm-header-prefix))
 172              (progn (goto-char (match-end 0))
 173                     (looking-at "\\([^\t ]+\\)")
 174                     (match-end 1)))
 175         (buffer-substring-no-properties (match-beginning 1) (match-end 1))
 176       )))
 177
 178 (defun lm-section-mark (header &optional after)
 179   "Return the buffer location of a given section start marker.
 180 The HEADER is the section mark string to search for.
 181 If AFTER is non-nil, return the location of the next line."
 182   (save-excursion
 183     (let ((case-fold-search t))
 184       (goto-char (point-min))
 185       (if (re-search-forward (lm-get-header-re header 'section) nil t)
 186           (progn
 187             (beginning-of-line)
 188             (if after (forward-line 1))
 189             (point))
 190         nil))))
 191
 192 (defsubst lm-code-mark ()
 193   "Return the buffer location of the `Code' start marker."
 194   (lm-section-mark "Code"))
 195
 196 (defsubst lm-commentary-mark ()
 197   "Return the buffer location of the `Commentary' start marker."
 198   (lm-section-mark lm-commentary-header))
 199
 200 (defsubst lm-history-mark ()
 201   "Return the buffer location of the `History' start marker."
 202   (lm-section-mark lm-history-header))
 203
 204 (defun lm-header (header)
 205   "Return the contents of the header named HEADER."
 206   (goto-char (point-min))
 207   (let ((case-fold-search t))
 208     (if (and (re-search-forward (lm-get-header-re header) (lm-code-mark) t)
 209              ;;   RCS ident likes format "$identifier: data$"
 210              (looking-at "\\([^$\n]+\\)")
 211              (match-end 1))
 212         (buffer-substring-no-properties (match-beginning 1) (match-end 1))
 213       nil)))
 214
 215 (defun lm-header-multiline (header)
 216   "Return the contents of the header named HEADER, with continuation lines.
 217 The returned value is a list of strings, one per line."
 218   (save-excursion
 219     (goto-char (point-min))
 220     (let ((res (lm-header header)))
 221       (cond
 222        (res
 223         (setq res (list res))
 224         (forward-line 1)
 225
 226         (while (and (looking-at (concat lm-header-prefix "[\t ]+"))
 227                     (progn
 228                       (goto-char (match-end 0))
 229                       (looking-at "\\(.*\\)"))
 230                     (match-end 1))
 231           (setq res (cons (buffer-substring-no-properties
 232                            (match-beginning 1)
 233                            (match-end 1))
 234                           res))
 235           (forward-line 1))
 236         ))
 237       res
 238       )))
 239
 240 ;; These give us smart access to the header fields and commentary
 241
 242 (defun lm-summary (&optional file)
 243   "Return the one-line summary of file FILE, or current buffer if FILE is nil."
 244   (save-excursion
 245     (if file
 246         (find-file file))
 247     (goto-char (point-min))
 248     (prog1
 249       (if (and
 250            (looking-at lm-header-prefix)
 251            (progn (goto-char (match-end 0))
 252                   (looking-at "[^ ]+[ \t]+--+[ \t]+\\(.*\\)")))
 253           (let ((summary (buffer-substring-no-properties (match-beginning 1)
 254                                                          (match-end 1))))
 255             ;; Strip off -*- specifications.
 256             (if (string-match "[ \t]*-\\*-.*-\\*-" summary)
 257                 (substring summary 0 (match-beginning 0))
 258               summary)))
 259       (if file
 260           (kill-buffer (current-buffer)))
 261       )))
 262
 263 (defun lm-crack-address (x)
 264   "Split up an email address X into full name and real email address.
 265 The value is a cons of the form (FULLNAME . ADDRESS)."
 266   (cond ((string-match "\\(.+\\) [(<]\\(\\S-+@\\S-+\\)[>)]" x)
 267          (cons (substring x (match-beginning 1) (match-end 1))
 268                (substring x (match-beginning 2) (match-end 2))))
 269         ((string-match "\\(\\S-+@\\S-+\\) [(<]\\(.*\\)[>)]" x)
 270          (cons (substring x (match-beginning 2) (match-end 2))
 271                (substring x (match-beginning 1) (match-end 1))))
 272         ((string-match "\\S-+@\\S-+" x)
 273          (cons nil x))
 274         (t
 275          (cons x nil))))
 276
 277 (defun lm-authors (&optional file)
 278   "Return the author list of file FILE, or current buffer if FILE is nil.
 279 Each element of the list is a cons; the car is the full name,
 280 the cdr is an email address."
 281   (save-excursion
 282     (if file
 283         (find-file file))
 284     (let ((authorlist (lm-header-multiline "author")))
 285       (prog1
 286          (mapcar 'lm-crack-address authorlist)
 287           (if file
 288               (kill-buffer (current-buffer)))
 289         ))))
 290
 291 (defun lm-maintainer (&optional file)
 292   "Return the maintainer of file FILE, or current buffer if FILE is nil.
 293 The return value has the form (NAME . ADDRESS)."
 294   (save-excursion
 295     (if file
 296         (find-file file))
 297     (prog1
 298         (let ((maint (lm-header "maintainer")))
 299           (if maint
 300               (lm-crack-address maint)
 301             (car (lm-authors))))
 302       (if file
 303           (kill-buffer (current-buffer)))
 304       )))
 305
 306 (defun lm-creation-date (&optional file)
 307   "Return the created date given in file FILE, or current buffer if FILE is nil."
 308   (save-excursion
 309     (if file
 310         (find-file file))
 311     (prog1
 312         (lm-header "created")
 313       (if file
 314           (kill-buffer (current-buffer)))
 315       )))
 316
 317
 318 (defun lm-last-modified-date (&optional file)
 319   "Return the modify-date given in file FILE, or current buffer if FILE is nil."
 320   (save-excursion
 321     (if file
 322         (find-file file))
 323     (prog1
 324         (if (progn
 325               (goto-char (point-min))
 326               (re-search-forward
 327                "\\$[I]d: [^ ]+ [^ ]+ \\([^/]+\\)/\\([^/]+\\)/\\([^ ]+\\) "
 328                (lm-code-mark) t))
 329             (format "%s %s %s"
 330                     (buffer-substring (match-beginning 3) (match-end 3))
 331                     (nth (string-to-int
 332                           (buffer-substring (match-beginning 2) (match-end 2)))
 333                          '("" "Jan" "Feb" "Mar" "Apr" "May" "Jun"
 334                            "Jul" "Aug" "Sep" "Oct" "Nov" "Dec"))
 335                     (buffer-substring (match-beginning 1) (match-end 1))
 336                     ))
 337       (if file
 338           (kill-buffer (current-buffer)))
 339       )))
 340
 341 (defun lm-version (&optional file)
 342   "Return the version listed in file FILE, or current buffer if FILE is nil.
 343 This can befound in an RCS or SCCS header to crack it out of."
 344   (save-excursion
 345     (if file
 346         (find-file file))
 347     (prog1
 348         (or
 349          (lm-header "version")
 350          (let ((header-max (lm-code-mark)))
 351            (goto-char (point-min))
 352            (cond
 353             ;; Look for an RCS header
 354             ((re-search-forward "\\$[I]d: [^ ]+ \\([^ ]+\\) " header-max t)
 355              (buffer-substring-no-properties (match-beginning 1) (match-end 1)))
 356
 357             ;; Look for an SCCS header
 358             ((re-search-forward
 359               (concat
 360                (regexp-quote "@(#)")
 361                (regexp-quote (file-name-nondirectory (buffer-file-name)))
 362                "\t\\([012345679.]*\\)")
 363               header-max t)
 364              (buffer-substring-no-properties (match-beginning 1) (match-end 1)))
 365
 366             (t nil))))
 367       (if file
 368           (kill-buffer (current-buffer)))
 369       )))
 370
 371 (defun lm-keywords (&optional file)
 372   "Return the keywords given in file FILE, or current buffer if FILE is nil."
 373   (save-excursion
 374     (if file
 375         (find-file file))
 376     (prog1
 377         (let ((keywords (lm-header "keywords")))
 378           (and keywords (downcase keywords)))
 379       (if file
 380           (kill-buffer (current-buffer)))
 381       )))
 382
 383 (defun lm-adapted-by (&optional file)
 384   "Return the adapted-by names in file FILE, or current buffer if FILE is nil.
 385 This is the name of the person who cleaned up this package for
 386 distribution."
 387   (save-excursion
 388     (if file
 389         (find-file file))
 390     (prog1
 391         (lm-header "adapted-by")
 392       (if file
 393           (kill-buffer (current-buffer)))
 394       )))
 395
 396 (defun lm-commentary (&optional file)
 397   "Return the commentary in file FILE, or current buffer if FILE is nil.
 398 The value is returned as a string.  In the file, the commentary starts
 399 with the tag `Commentary' or `Documentation' and ends with one of the
 400 tags `Code', `Change Log' or `History'."
 401   (save-excursion
 402     (if file
 403         (find-file file))
 404     (prog1
 405         (let ((commentary       (lm-commentary-mark))
 406               (change-log       (lm-history-mark))
 407               (code             (lm-code-mark))
 408               )
 409           (cond
 410            ((and commentary change-log)
 411             (buffer-substring-no-properties commentary change-log))
 412            ((and commentary code)
 413             (buffer-substring-no-properties commentary code))
 414            (t
 415             nil)))
 416       (if file
 417           (kill-buffer (current-buffer)))
 418       )))
 419
 420 ;;; Verification and synopses
 421
 422 (defun lm-insert-at-column (col &rest strings)
 423   "Insert, at column COL, list of STRINGS."
 424   (if (> (current-column) col) (insert "\n"))
 425   (move-to-column col t)
 426   (apply 'insert strings))
 427
 428 (defun lm-verify (&optional file showok verb)
 429   "Check that the current buffer (or FILE if given) is in proper format.
 430 If FILE is a directory, recurse on its files and generate a report in
 431 a temporary buffer."
 432   (interactive)
 433   (let* ((verb    (or verb (interactive-p)))
 434          ret
 435          name
 436          )
 437     (if verb
 438         (setq ret "Ok."))               ;init value
 439
 440     (if (and file (file-directory-p file))
 441         (setq
 442          ret
 443          (progn
 444            (switch-to-buffer (get-buffer-create "*lm-verify*"))
 445            (erase-buffer)
 446            (mapcar
 447             '(lambda (f)
 448                (if (string-match ".*\\.el$" f)
 449                    (let ((status (lm-verify f)))
 450                      (if status
 451                          (progn
 452                            (insert f ":")
 453                            (lm-insert-at-column lm-comment-column status "\n"))
 454                        (and showok
 455                             (progn
 456                               (insert f ":")
 457                               (lm-insert-at-column lm-comment-column "OK\n")))))))
 458             (directory-files file))
 459            ))
 460       (save-excursion
 461         (if file
 462             (find-file file))
 463         (setq name (lm-get-package-name))
 464
 465         (setq
 466          ret
 467          (prog1
 468              (cond
 469               ((null name)
 470                "Can't find a package NAME")
 471
 472               ((not (lm-authors))
 473                "Author: tag missing.")
 474
 475               ((not (lm-maintainer))
 476                "Maintainer: tag missing.")
 477
 478               ((not (lm-summary))
 479                "Can't find a one-line 'Summary' description")
 480
 481               ((not (lm-keywords))
 482                "Keywords: tag missing.")
 483
 484               ((not (lm-commentary-mark))
 485                "Can't find a 'Commentary' section marker.")
 486
 487               ((not (lm-history-mark))
 488                "Can't find a 'History' section marker.")
 489
 490               ((not (lm-code-mark))
 491                "Can't find a 'Code' section marker")
 492
 493               ((progn
 494                  (goto-char (point-max))
 495                  (not
 496                   (re-search-backward
 497                    (concat "^;;;[ \t]+" name "[ \t]+ends here[ \t]*$"
 498                            "\\|^;;;[ \t]+ End of file[ \t]+" name)
 499                    nil t
 500                    )))
 501                (format "Can't find a footer line for [%s]" name))
 502               (t
 503                ret))
 504            (if file
 505                (kill-buffer (current-buffer)))
 506           ))))
 507     (if verb
 508         (message ret))
 509     ret
 510     ))
 511
 512 (defun lm-synopsis (&optional file showall)
 513   "Generate a synopsis listing for the buffer or the given FILE if given.
 514 If FILE is a directory, recurse on its files and generate a report in
 515 a temporary buffer.  If SHOWALL is non-nil, also generate a line for files
 516 which do not include a recognizable synopsis."
 517   (interactive
 518    (list
 519     (read-file-name "Synopsis for (file or dir): ")))
 520
 521   (if (and file (file-directory-p file))
 522       (progn
 523         (switch-to-buffer (get-buffer-create "*lm-verify*"))
 524         (erase-buffer)
 525         (mapcar
 526          '(lambda (f)
 527             (if (string-match ".*\\.el$" f)
 528                 (let ((syn (lm-synopsis f)))
 529                   (if syn
 530                       (progn
 531                         (insert f ":")
 532                         (lm-insert-at-column lm-comment-column syn "\n"))
 533                     (and showall
 534                          (progn
 535                            (insert f ":")
 536                            (lm-insert-at-column lm-comment-column "NA\n")))))))
 537          (directory-files file))
 538         )
 539     (save-excursion
 540       (if file
 541           (find-file file))
 542       (prog1
 543           (lm-summary)
 544         (if file
 545             (kill-buffer (current-buffer)))
 546         ))))
 547
 548 (defun lm-report-bug (topic)
 549   "Report a bug in the package currently being visited to its maintainer.
 550 Prompts for bug subject TOPIC.  Leaves you in a mail buffer."
 551   (interactive "sBug Subject: ")
 552   (let ((package        (lm-get-package-name))
 553         (addr           (lm-maintainer))
 554         (version        (lm-version)))
 555     (mail nil
 556           (if addr
 557               (concat (car addr) " <" (cdr addr) ">")
 558             report-emacs-bug-address)
 559           topic)
 560     (goto-char (point-max))
 561     (insert "\nIn "
 562             package
 563             (if version (concat " version " version) "")
 564             "\n\n")
 565     (message
 566      (substitute-command-keys "Type \\[mail-send] to send bug report."))))
 567
 568 (provide 'lisp-mnt)
 569
 570 ;;; lisp-mnt.el ends here
 571