code.delx.au - gnu-emacs/blob - configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2012 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.1.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28 AC_CONFIG_AUX_DIR(build-aux)
  29 AM_INIT_AUTOMAKE
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 dnl It is important that variables on the RHS not be expanded here,
  36 dnl hence the single quotes.  This is per the GNU coding standards, see
  37 dnl (autoconf) Installation Directory Variables
  38 dnl See also epaths.h below.
  39 lispdir='${datadir}/emacs/${version}/lisp'
  40 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  41 '${datadir}/emacs/site-lisp'
  42 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  43 etcdir='${datadir}/emacs/${version}/etc'
  44 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  45 docdir='${datadir}/emacs/${version}/etc'
  46 gamedir='${localstatedir}/games/emacs'
  47
  48 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  49 dnl Create a new --with option that defaults to being disabled.
  50 dnl NAME is the base name of the option.  The shell variable with_NAME
  51 dnl   will be set to either the user's value (if the option is
  52 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  53 dnl   option is not specified).  Note that the shell variable name is
  54 dnl   constructed as autoconf does, by replacing non-alphanumeric
  55 dnl   characters with "_".
  56 dnl HELP-STRING is the help text for the option.
  57 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  58   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  59     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  60 ])dnl
  61
  62 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  63 dnl Create a new --with option that defaults to being enabled.  NAME
  64 dnl   is the base name of the option.  The shell variable with_NAME
  65 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  66 dnl   'yes' (if the option is not specified).  Note that the shell
  67 dnl   variable name is constructed as autoconf does, by replacing
  68 dnl   non-alphanumeric characters with "_".
  69 dnl HELP-STRING is the help text for the option.
  70 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  71   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  72    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  73 ])dnl
  74
  75 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  76 if test "$with_pop" = yes; then
  77    AC_DEFINE(MAIL_USE_POP)
  78 fi
  79 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  80
  81 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  82 if test "$with_kerberos" != no; then
  83    AC_DEFINE(KERBEROS)
  84 fi
  85 AH_TEMPLATE(KERBEROS,
  86             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  87
  88 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  89 if test "${with_kerberos5}" != no; then
  90   if test "${with_kerberos}" = no; then
  91     with_kerberos=yes
  92     AC_DEFINE(KERBEROS)
  93   fi
  94   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  95 fi
  96
  97 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  98 dnl FIXME hesiod support may not be present, so it seems like an error
  99 dnl to define, or at least use, this unconditionally.
 100 if test "$with_hesiod" != no; then
 101   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 102 fi
 103
 104 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 105 if test "$with_mmdf" != no; then
 106    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 107 fi
 108
 109 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 110 if test "$with_mail_unlink" != no; then
 111    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 112 fi
 113
 114 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 115     [string giving default POP mail host])],
 116     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 117
 118 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 119
 120 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 121 if test "$with_sync_input" = yes; then
 122    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 123 fi
 124
 125 dnl FIXME currently it is not the last.
 126 dnl This should be the last --with option, because --with-x is
 127 dnl added later on when we find the path of X, and it's best to
 128 dnl keep them together visually.
 129 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 130  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 131 [         case "${withval}" in
 132             y | ye | yes )      val=gtk ;;
 133             n | no )            val=no  ;;
 134             l | lu | luc | luci | lucid )       val=lucid ;;
 135             a | at | ath | athe | athen | athena )      val=athena ;;
 136             m | mo | mot | moti | motif )       val=motif ;;
 137             g | gt | gtk  )     val=gtk ;;
 138             gtk3  )     val=gtk3 ;;
 139             * )
 140 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 141 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 142 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 143             ;;
 144           esac
 145           with_x_toolkit=$val
 146 ])
 147
 148 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 149 if test "$with_wide_int" = yes; then
 150   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 151 fi
 152
 153 dnl _ON results in a '--without' option in the --help output, so
 154 dnl the help text should refer to "don't compile", etc.
 155 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 156 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 157 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 158 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 159 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 160 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 161 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 162 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 163
 164 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 165 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 166 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 167
 168 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 169 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 170 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 171 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 172
 173 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 174 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 175 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 176 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 177 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 178 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 179
 180 OPTION_DEFAULT_OFF([xwidgets],[enable use of some gtk widgets it Emacs buffers])
 181
 182 ## For the times when you want to build Emacs but don't have
 183 ## a suitable makeinfo, and can live without the manuals.
 184 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 185 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 186
 187 ## Makefile.in needs the cache file name.
 188 AC_SUBST(cache_file)
 189
 190 ## This is an option because I do not know if all info/man support
 191 ## compressed files, nor how to test if they do so.
 192 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 193 if test $with_compress_info = yes; then
 194    GZIP_INFO=yes
 195 else
 196    GZIP_INFO=
 197 fi
 198 AC_SUBST(GZIP_INFO)
 199
 200 AC_ARG_WITH([pkg-config-prog],dnl
 201 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 202                   [path to pkg-config for finding GTK and librsvg])])
 203 if test "X${with_pkg_config_prog}" != X; then
 204    if test "${with_pkg_config_prog}" != yes; then
 205       PKG_CONFIG="${with_pkg_config_prog}"
 206    fi
 207 fi
 208
 209 CRT_DIR=
 210 AC_ARG_WITH([crt-dir],dnl
 211 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 212 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 213 CRT_DIR="${with_crt_dir}"
 214
 215 AC_ARG_WITH(gameuser,dnl
 216 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 217 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 218   && gameuser="${with_gameuser}"
 219 test "X$gameuser" = X && gameuser=games
 220
 221 AC_ARG_WITH([gnustep-conf],dnl
 222 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 223 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 224   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 225 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 226      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 227
 228 AC_ARG_ENABLE(ns-self-contained,
 229 [AS_HELP_STRING([--disable-ns-self-contained],
 230                 [disable self contained build under NeXTstep])],
 231    EN_NS_SELF_CONTAINED=$enableval,
 232    EN_NS_SELF_CONTAINED=yes)
 233
 234 AC_ARG_ENABLE(asserts,
 235 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 236       USE_XASSERTS=$enableval,
 237       USE_XASSERTS=no)
 238
 239 AC_ARG_ENABLE(maintainer-mode,
 240 [AS_HELP_STRING([--disable-maintainer-mode],
 241                 [disable make rules and dependencies not useful (and sometimes
 242                  confusing) to the casual installer])],
 243       USE_MAINTAINER_MODE=$enableval,
 244       USE_MAINTAINER_MODE=yes)
 245 if test $USE_MAINTAINER_MODE = yes; then
 246   MAINT=
 247 else
 248   MAINT=#
 249 fi
 250 AC_SUBST(MAINT)
 251
 252 AC_ARG_ENABLE(locallisppath,
 253 [AS_HELP_STRING([--enable-locallisppath=PATH],
 254                 [directories Emacs should search for lisp files specific
 255                  to this site])],
 256 if test "${enableval}" = "no"; then
 257   locallisppath=
 258 elif test "${enableval}" != "yes"; then
 259   locallisppath=${enableval}
 260 fi)
 261
 262 AC_ARG_ENABLE(checking,
 263 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 264                 [enable expensive run-time checks.  With LIST,
 265                  enable only specific categories of checks.
 266                  Categories are: all,yes,no.
 267                  Flags are: stringbytes, stringoverrun, stringfreelist,
 268                  xmallocoverrun, conslist])],
 269 [ac_checking_flags="${enableval}"],[])
 270 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 271 for check in $ac_checking_flags
 272 do
 273         case $check in
 274         # these set all the flags to specific states
 275         yes)            ac_enable_checking=1 ;;
 276         no)             ac_enable_checking= ;
 277                         ac_gc_check_stringbytes= ;
 278                         ac_gc_check_string_overrun= ;
 279                         ac_gc_check_string_free_list= ;
 280                         ac_xmalloc_overrun= ;
 281                         ac_gc_check_cons_list= ;;
 282         all)            ac_enable_checking=1 ;
 283                         ac_gc_check_stringbytes=1 ;
 284                         ac_gc_check_string_overrun=1 ;
 285                         ac_gc_check_string_free_list=1 ;
 286                         ac_xmalloc_overrun=1 ;
 287                         ac_gc_check_cons_list=1 ;;
 288         # these enable particular checks
 289         stringbytes)    ac_gc_check_stringbytes=1 ;;
 290         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 291         stringfreelist) ac_gc_check_string_free_list=1 ;;
 292         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 293         conslist)       ac_gc_check_cons_list=1 ;;
 294         *)      AC_MSG_ERROR(unknown check category $check) ;;
 295         esac
 296 done
 297 IFS="$ac_save_IFS"
 298
 299 if test x$ac_enable_checking != x ; then
 300   AC_DEFINE(ENABLE_CHECKING, 1,
 301 [Enable expensive run-time checking of data types?])
 302 fi
 303 if test x$ac_gc_check_stringbytes != x ; then
 304   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 305 [Define this temporarily to hunt a bug.  If defined, the size of
 306    strings is redundantly recorded in sdata structures so that it can
 307    be compared to the sizes recorded in Lisp strings.])
 308 fi
 309 if test x$ac_gc_check_string_overrun != x ; then
 310   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 311 [Define this to check for short string overrun.])
 312 fi
 313 if test x$ac_gc_check_string_free_list != x ; then
 314   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 315 [Define this to check the string free list.])
 316 fi
 317 if test x$ac_xmalloc_overrun != x ; then
 318   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 319 [Define this to check for malloc buffer overrun.])
 320 fi
 321 if test x$ac_gc_check_cons_list != x ; then
 322   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 323 [Define this to check for errors in cons list.])
 324 fi
 325
 326 AC_ARG_ENABLE(use-lisp-union-type,
 327 [AS_HELP_STRING([--enable-use-lisp-union-type],
 328                 [use a union for the Lisp_Object data type.
 329                 This is only useful for development for catching certain types of bugs.])],
 330 if test "${enableval}" != "no"; then
 331    AC_DEFINE(USE_LISP_UNION_TYPE, 1,
 332    [Define this to use a lisp union for the Lisp_Object data type.])
 333 fi)
 334
 335
 336 AC_ARG_ENABLE(profiling,
 337 [AS_HELP_STRING([--enable-profiling],
 338                 [build emacs with profiling support.
 339                  This might not work on all platforms])],
 340 [ac_enable_profiling="${enableval}"],[])
 341 if test x$ac_enable_profiling != x ; then
 342    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 343 else
 344    PROFILING_CFLAGS=
 345 fi
 346 AC_SUBST(PROFILING_CFLAGS)
 347
 348 AC_ARG_ENABLE(autodepend,
 349 [AS_HELP_STRING([--enable-autodepend],
 350                 [automatically generate dependencies to .h-files.
 351                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 352                  found])],
 353 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 354
 355 #### Make srcdir absolute, if it isn't already.  It's important to
 356 #### avoid running the path through pwd unnecessarily, since pwd can
 357 #### give you automounter prefixes, which can go away.  We do all this
 358 #### so Emacs can find its files when run uninstalled.
 359 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 360 unset CDPATH
 361 case "${srcdir}" in
 362   /* ) ;;
 363   . )
 364     ## We may be able to use the $PWD environment variable to make this
 365     ## absolute.  But sometimes PWD is inaccurate.
 366     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 367     ## but that tested only for a well-formed and valid PWD,
 368     ## it did not object when PWD was well-formed and valid but just wrong.
 369     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 370     then
 371       srcdir="$PWD"
 372     else
 373       srcdir="`(cd ${srcdir}; pwd)`"
 374     fi
 375   ;;
 376   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 377 esac
 378
 379 #### Given the configuration name, set machfile and opsysfile to the
 380 #### names of the m/*.h and s/*.h files we should use.
 381
 382 ### Canonicalize the configuration name.
 383
 384 AC_CANONICAL_HOST
 385 canonical=$host
 386 configuration=${host_alias-${build_alias-$host}}
 387
 388 dnl This used to use changequote, but, apart from `changequote is evil'
 389 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 390 dnl the great gob of text.  Thus it's not processed for possible expansion.
 391 dnl Just make sure the brackets remain balanced.
 392 dnl
 393 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 394 dnl indicated by comments.
 395 dnl quotation begins
 396 [
 397
 398 ### If you add support for a new configuration, add code to this
 399 ### switch statement to recognize your configuration name and select
 400 ### the appropriate operating system and machine description files.
 401
 402 ### You would hope that you could choose an m/*.h file pretty much
 403 ### based on the machine portion of the configuration name, and an s/*.h
 404 ### file based on the operating system portion.  However, it turns out
 405 ### that each m/*.h file is pretty manufacturer-specific - for
 406 ### example mips.h is MIPS
 407 ### So we basically have to have a special case for each
 408 ### configuration name.
 409 ###
 410 ### As far as handling version numbers on operating systems is
 411 ### concerned, make sure things will fail in a fixable way.  If
 412 ### /etc/MACHINES doesn't say anything about version numbers, be
 413 ### prepared to handle anything reasonably.  If version numbers
 414 ### matter, be sure /etc/MACHINES says something about it.
 415
 416 machine='' opsys='' unported=no
 417 case "${canonical}" in
 418
 419   ## GNU/Linux and similar ports
 420   *-*-linux* )
 421     opsys=gnu-linux
 422     case ${canonical} in
 423       alpha*)   machine=alpha ;;
 424       s390x-*)  machine=ibms390x ;;
 425       powerpc*) machine=macppc ;;
 426       sparc*)   machine=sparc ;;
 427       ia64*)    machine=ia64 ;;
 428       m68k*)    machine=m68k ;;
 429       x86_64*)  machine=amdx86-64 ;;
 430     esac
 431   ;;
 432
 433   ## FreeBSD ports
 434   *-*-freebsd* )
 435     opsys=freebsd
 436     case "${canonical}" in
 437       alpha*)           machine=alpha ;;
 438       amd64-*|x86_64-*) machine=amdx86-64 ;;
 439       ia64-*)           machine=ia64 ;;
 440       i[3456]86-*)      machine=intel386 ;;
 441       powerpc-*)        machine=macppc ;;
 442       sparc-*)          machine=sparc ;;
 443       sparc64-*)        machine=sparc ;;
 444     esac
 445   ;;
 446
 447   ## FreeBSD kernel + glibc based userland
 448   *-*-kfreebsd*gnu* )
 449     opsys=gnu-kfreebsd
 450     case "${canonical}" in
 451       alpha*)           machine=alpha ;;
 452       amd64-*|x86_64-*) machine=amdx86-64 ;;
 453       ia64-*)           machine=ia64 ;;
 454       i[3456]86-*)      machine=intel386 ;;
 455       powerpc-*)        machine=macppc ;;
 456       sparc-*)          machine=sparc ;;
 457       sparc64-*)        machine=sparc ;;
 458     esac
 459   ;;
 460
 461   ## NetBSD ports
 462   *-*-netbsd* )
 463     opsys=netbsd
 464     case "${canonical}" in
 465       alpha*)      machine=alpha ;;
 466       x86_64-*)    machine=amdx86-64 ;;
 467       i[3456]86-*) machine=intel386 ;;
 468       m68k-*)      machine=m68k ;;
 469       powerpc-*)   machine=macppc ;;
 470       sparc*-)     machine=sparc ;;
 471       vax-*)       machine=vax ;;
 472     esac
 473   ;;
 474
 475   ## OpenBSD ports
 476   *-*-openbsd* )
 477     opsys=openbsd
 478     case "${canonical}" in
 479       alpha*)    machine=alpha ;;
 480       x86_64-*)  machine=amdx86-64 ;;
 481       i386-*)    machine=intel386 ;;
 482       powerpc-*) machine=macppc ;;
 483       sparc*)    machine=sparc ;;
 484       vax-*)     machine=vax ;;
 485     esac
 486   ;;
 487
 488   ## Apple Darwin / Mac OS X
 489   *-apple-darwin* )
 490     case "${canonical}" in
 491       i[3456]86-* )  machine=intel386 ;;
 492       powerpc-* )    machine=macppc ;;
 493       x86_64-* )     machine=amdx86-64 ;;
 494       * )            unported=yes ;;
 495     esac
 496     opsys=darwin
 497     # Define CPP as follows to make autoconf work correctly.
 498     CPP="${CC-cc} -E -no-cpp-precomp"
 499     # Use fink packages if available.
 500     if test -d /sw/include && test -d /sw/lib; then
 501       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 502       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 503       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 504     fi
 505   ;;
 506
 507   ## HP 9000 series 700 and 800, running HP/UX
 508   hppa*-hp-hpux10.2* )
 509     opsys=hpux10-20
 510   ;;
 511   hppa*-hp-hpux1[1-9]* )
 512     opsys=hpux11
 513     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 514   ;;
 515
 516   ## IBM machines
 517   rs6000-ibm-aix4.[23]* )
 518     machine=ibmrs6000 opsys=aix4-2
 519   ;;
 520   powerpc-ibm-aix4.[23]*  )
 521     machine=ibmrs6000 opsys=aix4-2
 522   ;;
 523   rs6000-ibm-aix[56]* )
 524     machine=ibmrs6000 opsys=aix4-2
 525   ;;
 526   powerpc-ibm-aix[56]*  )
 527     machine=ibmrs6000 opsys=aix4-2
 528   ;;
 529
 530   ## Silicon Graphics machines
 531   ## Iris 4D
 532   mips-sgi-irix6.5 )
 533     opsys=irix6-5
 534     # Without defining _LANGUAGE_C, things get masked out in the headers
 535     # so that, for instance, grepping for `free' in stdlib.h fails and
 536     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 537     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 538     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 539   ;;
 540
 541   ## Suns
 542   *-sun-solaris* \
 543     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 544     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 545     case "${canonical}" in
 546       i[3456]86-*-* )     machine=intel386 ;;
 547       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 548       sparc* )          machine=sparc ;;
 549       * )               unported=yes ;;
 550     esac
 551     case "${canonical}" in
 552       *-sunos5.6* | *-solaris2.6* )
 553                 opsys=sol2-6
 554                 NON_GNU_CPP=/usr/ccs/lib/cpp
 555                 RANLIB="ar -ts"
 556                 ;;
 557       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 558                 opsys=sol2-6
 559                 emacs_check_sunpro_c=yes
 560                 NON_GNU_CPP=/usr/ccs/lib/cpp
 561                 ;;
 562       *-sunos5* | *-solaris* )
 563                 opsys=sol2-10
 564                 emacs_check_sunpro_c=yes
 565                 NON_GNU_CPP=/usr/ccs/lib/cpp
 566                 ;;
 567     esac
 568     ## Watch out for a compiler that we know will not work.
 569     case "${canonical}" in
 570      *-solaris* | *-sunos5* )
 571                 if [ "x$CC" = x/usr/ucb/cc ]; then
 572                   ## /usr/ucb/cc doesn't work;
 573                   ## we should find some other compiler that does work.
 574                   unset CC
 575                 fi
 576                 ;;
 577       *) ;;
 578     esac
 579   ;;
 580
 581   ## Intel 386 machines where we don't care about the manufacturer.
 582   i[3456]86-*-* )
 583     machine=intel386
 584     case "${canonical}" in
 585       *-cygwin )                opsys=cygwin ;;
 586       *-darwin* )               opsys=darwin
 587                                 CPP="${CC-cc} -E -no-cpp-precomp"
 588                                 ;;
 589       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 590       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 591       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 592       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 593     esac
 594   ;;
 595
 596   * )
 597     unported=yes
 598   ;;
 599 esac
 600
 601 ### If the code above didn't choose an operating system, just choose
 602 ### an operating system based on the configuration name.  You really
 603 ### only want to use this when you have no idea what the right
 604 ### operating system is; if you know what operating systems a machine
 605 ### runs, it's cleaner to make it explicit in the case statement
 606 ### above.
 607 if test x"${opsys}" = x; then
 608   case "${canonical}" in
 609     *-gnu* )                            opsys=gnu ;;
 610     * )
 611       unported=yes
 612     ;;
 613   esac
 614 fi
 615
 616 ]
 617 dnl quotation ends
 618
 619 if test $unported = yes; then
 620   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 621 Check `etc/MACHINES' for recognized configuration names.])
 622 fi
 623
 624 if test -n "$machine"; then
 625   machfile="m/${machine}.h"
 626 else
 627   machfile=
 628 fi
 629 opsysfile="s/${opsys}.h"
 630
 631
 632 #### Choose a compiler.
 633 test -n "$CC" && cc_specified=yes
 634
 635 # Save the value of CFLAGS that the user specified.
 636 SPECIFIED_CFLAGS="$CFLAGS"
 637
 638 dnl Sets GCC=yes if using gcc.
 639 AC_PROG_CC
 640 AM_PROG_CC_C_O
 641
 642 # Initialize gnulib right after verifying that the C compiler works.
 643 gl_EARLY
 644
 645 # On Suns, sometimes $CPP names a directory.
 646 if test -n "$CPP" && test -d "$CPP"; then
 647   CPP=
 648 fi
 649
 650 ## If not using gcc, and on Solaris, and no CPP specified, see if
 651 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 652 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 653  test x"$CPP" = x; then
 654   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 655   AC_CACHE_VAL(emacs_cv_sunpro_c,
 656   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
 657 [[#ifndef __SUNPRO_C
 658 fail;
 659 #endif
 660 ]])], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 661   AC_MSG_RESULT($emacs_cv_sunpro_c)
 662
 663   if test x"$emacs_cv_sunpro_c" = xyes; then
 664     NON_GNU_CPP="$CC -E -Xs"
 665   fi
 666 fi
 667
 668 #### Some systems specify a CPP to use unless we are using GCC.
 669 #### Now that we know whether we are using GCC, we can decide whether
 670 #### to use that one.
 671 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 672 then
 673   CPP="$NON_GNU_CPP"
 674 fi
 675
 676 #### Some systems specify a CC to use unless we are using GCC.
 677 #### Now that we know whether we are using GCC, we can decide whether
 678 #### to use that one.
 679 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 680   test x$cc_specified != xyes
 681 then
 682   CC="$NON_GNU_CC"
 683 fi
 684
 685 if test x$GCC = xyes; then
 686   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 687 else
 688   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 689 fi
 690
 691 ### Use -Wdeclaration-after-statement if the compiler supports it
 692 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 693 SAVE_CFLAGS="$CFLAGS"
 694 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 695 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], has_option=yes, has_option=no)
 696 if test $has_option = yes; then
 697    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 698 fi
 699 AC_MSG_RESULT($has_option)
 700 CFLAGS="$SAVE_CFLAGS"
 701 unset has_option
 702 unset SAVE_CFLAGS
 703
 704 ### Use -Wold-style-definition if the compiler supports it
 705 # This can be removed when conversion to standard C is finished.
 706 AC_MSG_CHECKING([whether gcc understands -Wold-style-definition])
 707 SAVE_CFLAGS="$CFLAGS"
 708 CFLAGS="$CFLAGS -Wold-style-definition"
 709 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], has_option=yes, has_option=no)
 710 if test $has_option = yes; then
 711    C_WARNINGS_SWITCH="-Wold-style-definition $C_WARNINGS_SWITCH"
 712 fi
 713 AC_MSG_RESULT($has_option)
 714 CFLAGS="$SAVE_CFLAGS"
 715 unset has_option
 716 unset SAVE_CFLAGS
 717
 718 ### Use -Wimplicit-function-declaration if the compiler supports it
 719 AC_MSG_CHECKING([whether gcc understands -Wimplicit-function-declaration])
 720 SAVE_CFLAGS="$CFLAGS"
 721 CFLAGS="$CFLAGS -Wimplicit-function-declaration"
 722 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], has_option=yes, has_option=no)
 723 if test $has_option = yes; then
 724    C_WARNINGS_SWITCH="-Wimplicit-function-declaration $C_WARNINGS_SWITCH"
 725 fi
 726 AC_MSG_RESULT($has_option)
 727 CFLAGS="$SAVE_CFLAGS"
 728 unset has_option
 729 unset SAVE_CFLAGS
 730
 731 AC_SUBST(C_WARNINGS_SWITCH)
 732
 733
 734 #### Some other nice autoconf tests.
 735
 736 dnl checks for programs
 737 AC_PROG_CPP
 738 AC_PROG_INSTALL
 739 if test "x$RANLIB" = x; then
 740   AC_PROG_RANLIB
 741 fi
 742
 743 ## Although we're running on an amd64 kernel, we're actually compiling for
 744 ## the x86 architecture.  The user should probably have provided an
 745 ## explicit --build to `configure', but if everything else than the kernel
 746 ## is running in i386 mode, we can help them out.
 747 if test "$machine" = "amdx86-64"; then
 748   AC_CHECK_DECL([i386])
 749   if test "$ac_cv_have_decl_i386" = "yes"; then
 750     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 751     machine=intel386
 752     machfile="m/${machine}.h"
 753   fi
 754 fi
 755
 756 AC_PATH_PROG(INSTALL_INFO, install-info)
 757 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 758 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 759 dnl Don't use GZIP, which is used by gzip for additional parameters.
 760 AC_PATH_PROG(GZIP_PROG, gzip)
 761
 762
 763 ## Need makeinfo >= 4.7 (?) to build the manuals.
 764 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 765 dnl By this stage, configure has already checked for egrep and set EGREP,
 766 dnl or exited with an error if no egrep was found.
 767 if test "$MAKEINFO" != "no" && \
 768   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[7-9]]|4\.[[1-6]][[0-9]]+)'`" = x; then
 769    MAKEINFO=no
 770 fi
 771
 772 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 773 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 774 ## therefore in the category of "special tools" not normally required, which
 775 ## configure does not have to check for (eg autoconf itself).
 776 ## In a Bazaar checkout on the other hand, the manuals are not included.
 777 ## So makeinfo is a requirement to build from Bazaar, and configure
 778 ## should test for it as it does for any other build requirement.
 779 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 780 ## with pre-built manuals, from a Bazaar checkout.
 781 HAVE_MAKEINFO=yes
 782
 783 if test "$MAKEINFO" = "no"; then
 784   MAKEINFO=makeinfo
 785   if test "x${with_makeinfo}" = "xno"; then
 786     HAVE_MAKEINFO=no
 787   elif test ! -e $srcdir/info/emacs; then
 788     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
 789 source tree does not seem to have pre-built manuals in the `info' directory.
 790 Either install a suitable version of makeinfo, or re-run configure
 791 with the `--without-makeinfo' option to build without the manuals.] )
 792   fi
 793 fi
 794 AC_SUBST(HAVE_MAKEINFO)
 795
 796 dnl Add our options to ac_link now, after it is set up.
 797
 798 if test x$GCC = xyes; then
 799   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 800     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 801 else
 802   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 803     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 804 fi
 805
 806 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 807 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 808 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 809 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 810 dnl if not built to support GNU ld.
 811
 812 late_LDFLAGS=$LDFLAGS
 813 if test x$GCC = xyes; then
 814   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 815 else
 816   LDFLAGS="$LDFLAGS -znocombreloc"
 817 fi
 818
 819 AC_MSG_CHECKING([for -znocombreloc])
 820 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 821   [AC_MSG_RESULT(yes)],
 822   LDFLAGS=$late_LDFLAGS
 823   [AC_MSG_RESULT(no)])
 824
 825
 826 # The value of CPP is a quoted variable reference, so we need to do this
 827 # to get its actual value...
 828 CPP=`eval "echo $CPP"`
 829
 830
 831 dnl The function dump-emacs will not be defined and temacs will do
 832 dnl (load "loadup") automatically unless told otherwise.
 833 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 834 case "$opsys" in
 835   your-opsys-here) CANNOT_DUMP=yes ;;
 836 esac
 837
 838 test "$CANNOT_DUMP" = "yes" && \
 839   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 840
 841 AC_SUBST(CANNOT_DUMP)
 842
 843
 844 UNEXEC_OBJ=unexelf.o
 845 case "$opsys" in
 846   # MSDOS uses unexcoff.o
 847   # MSWindows uses unexw32.o
 848   aix4-2)
 849    UNEXEC_OBJ=unexaix.o
 850    ;;
 851   cygwin)
 852    UNEXEC_OBJ=unexcw.o
 853    ;;
 854   darwin)
 855    UNEXEC_OBJ=unexmacosx.o
 856    ;;
 857   hpux10-20 | hpux11)
 858    UNEXEC_OBJ=unexhp9k800.o
 859    ;;
 860   sol2-10)
 861    # Use the Solaris dldump() function, called from unexsol.c, to dump
 862    # emacs, instead of the generic ELF dump code found in unexelf.c.
 863    # The resulting binary has a complete symbol table, and is better
 864    # for debugging and other observability tools (debuggers, pstack, etc).
 865    #
 866    # If you encounter a problem using dldump(), please consider sending
 867    # a message to the OpenSolaris tools-linking mailing list:
 868    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 869    #
 870    # It is likely that dldump() works with older Solaris too, but this has
 871    # not been tested, so for now this change is for Solaris 10 or newer.
 872    UNEXEC_OBJ=unexsol.o
 873    ;;
 874 esac
 875
 876 LD_SWITCH_SYSTEM=
 877 case "$opsys" in
 878   freebsd)
 879    ## Let `ld' find image libs and similar things in /usr/local/lib.
 880    ## The system compiler, GCC, has apparently been modified to not
 881    ## look there, contrary to what a stock GCC would do.
 882    LD_SWITCH_SYSTEM=-L/usr/local/lib
 883    ;;
 884
 885   gnu-linux)
 886    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 887    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 888    ;;
 889
 890   netbsd)
 891    LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 892    ;;
 893
 894   openbsd)
 895    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 896    ## otherwise Emacs dumps core on elf systems.
 897    LD_SWITCH_SYSTEM="-Z"
 898    ;;
 899 esac
 900 AC_SUBST(LD_SWITCH_SYSTEM)
 901
 902 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 903
 904 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_AUX,
 905 ## which has not been defined yet.  When this was handled with cpp,
 906 ## it was expanded to null when configure sourced the s/*.h file.
 907 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 908 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 909 ## (or somesuch), but because it is supposed to go at the _front_
 910 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 911 ## Compare with the gnu-linux case below, which added to the end
 912 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 913 ## LD_SWITCH_SYSTEM_TEMACS.
 914 case "$opsys" in
 915   netbsd|openbsd)
 916    ## _AUX_RPATH is like _AUX, but uses -rpath instead of -R.
 917    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_AUX_RPATH) $LD_SWITCH_SYSTEM" ;;
 918 esac
 919
 920
 921 C_SWITCH_MACHINE=
 922 if test "$machine" = "alpha"; then
 923   AC_CHECK_DECL([__ELF__])
 924   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 925     ## With ELF, make sure that all common symbols get allocated to in the
 926     ## data section.  Otherwise, the dump of temacs may miss variables in
 927     ## the shared library that have been initialized.  For example, with
 928     ## GNU libc, __malloc_initialized would normally be resolved to the
 929     ## shared library's .bss section, which is fatal.
 930     if test "x$GCC" = "xyes"; then
 931       C_SWITCH_MACHINE="-fno-common"
 932     else
 933       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 934     fi
 935   else
 936     UNEXEC_OBJ=unexalpha.o
 937   fi
 938 fi
 939 AC_SUBST(C_SWITCH_MACHINE)
 940
 941 AC_SUBST(UNEXEC_OBJ)
 942
 943 C_SWITCH_SYSTEM=
 944 ## Some programs in src produce warnings saying certain subprograms
 945 ## are too complex and need a MAXMEM value greater than 2000 for
 946 ## additional optimization.  --nils@exp-math.uni-essen.de
 947 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 948   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 949 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 950 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 951 AC_SUBST(C_SWITCH_SYSTEM)
 952
 953
 954 LIBS_SYSTEM=
 955 case "$opsys" in
 956   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 957   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 958
 959   freebsd) LIBS_SYSTEM="-lutil" ;;
 960
 961   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 962
 963   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
 964
 965   ## Motif needs -lgen.
 966   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
 967 esac
 968 AC_SUBST(LIBS_SYSTEM)
 969
 970
 971 ### Make sure subsequent tests use flags consistent with the build flags.
 972
 973 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 974   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 975 else
 976   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
 977 fi
 978
 979 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
 980 AC_DEFUN([AC_TYPE_SIZE_T])
 981 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
 982 AC_DEFUN([AC_TYPE_UID_T])
 983
 984 dnl Do this early because it can frob feature test macros for Unix-98 &c.
 985 AC_SYS_LARGEFILE
 986
 987
 988 LIB_MATH=-lm
 989 LIB_STANDARD=
 990 START_FILES=
 991
 992 dnl NB do not use CRT_DIR unquoted here, since it might not be set yet.
 993 case $opsys in
 994   cygwin )
 995     LIB_MATH=
 996     START_FILES='pre-crt0.o'
 997     ;;
 998   darwin )
 999     ## Adding -lm confuses the dynamic linker, so omit it.
1000     LIB_MATH=
1001     START_FILES='pre-crt0.o'
1002     ;;
1003   freebsd )
1004     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1005     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1006     ;;
1007   gnu-linux | gnu-kfreebsd )
1008     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1009     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1010     ;;
1011   hpux10-20 | hpux11 )
1012     LIB_STANDARD=-lc
1013     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1014     ;;
1015   dnl NB this may be adjusted below.
1016   netbsd | openbsd )
1017     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1018     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1019     ;;
1020 esac
1021
1022 AC_SUBST(LIB_MATH)
1023 AC_SUBST(START_FILES)
1024
1025 dnl Not all platforms use crtn.o files.  Check if the current one does.
1026 crt_files=
1027
1028 for file in x $LIB_STANDARD $START_FILES; do
1029   case "$file" in
1030     *CRT_DIR*) crt_files="$crt_files `echo $file | sed -e 's|.*/||'`" ;;
1031   esac
1032 done
1033
1034 if test "x$crt_files" != x; then
1035
1036   ## If user specified a crt-dir, use that unconditionally.
1037   crt_gcc=no
1038
1039   if test "X$CRT_DIR" = "X"; then
1040
1041     CRT_DIR=/usr/lib            # default
1042
1043     case "$canonical" in
1044       x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1045       ## On x86-64 and s390x GNU/Linux distributions, the standard library
1046       ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1047       ## For anything else (eg /usr/lib32), it is up the user to specify
1048       ## the location (bug#5655).
1049       ## Test for crtn.o, not just the directory, because sometimes the
1050       ## directory exists but does not have the relevant files (bug#1287).
1051       ## FIXME better to test for binary compatibility somehow.
1052       test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1053       ;;
1054
1055       powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1056     esac
1057
1058     case "$opsys" in
1059       hpux10-20) CRT_DIR=/lib ;;
1060     esac
1061
1062     test "x${GCC}" = xyes && crt_gcc=yes
1063
1064   fi                            # CRT_DIR = ""
1065
1066   crt_missing=
1067
1068   for file in $crt_files; do
1069
1070     ## If we're using gcc, try to determine it automatically by asking
1071     ## gcc.  [If this doesn't work, CRT_DIR will remain at the
1072     ## system-dependent default from above.]
1073     if test $crt_gcc = yes && test ! -e $CRT_DIR/$file; then
1074
1075        crt_file=`$CC --print-file-name=$file 2>/dev/null`
1076        case "$crt_file" in
1077          */*)
1078            CRT_DIR=`AS_DIRNAME(["$crt_file"])`
1079            ;;
1080        esac
1081     fi
1082
1083     dnl We expect all the files to be in a single directory, so after the
1084     dnl first there is no point asking gcc.
1085     crt_gcc=no
1086
1087     test -e $CRT_DIR/$file || crt_missing="$crt_missing $file"
1088   done                          # $crt_files
1089
1090   test "x$crt_missing" = x || \
1091     AC_MSG_ERROR([Required file(s) not found:$crt_missing
1092 Try using the --with-crt-dir option.])
1093
1094 fi                              # crt_files != ""
1095
1096 AC_SUBST(CRT_DIR)
1097
1098 case $opsys in
1099   netbsd | openbsd )
1100     if test -f $CRT_DIR/crti.o; then
1101
1102         test -f $CRT_DIR/crtn.o || \
1103           AC_MSG_ERROR([Required file not found: crtn.o])
1104
1105         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1106         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1107     fi
1108     ;;
1109 esac
1110
1111
1112 dnl This function definition taken from Gnome 2.0
1113 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1114 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1115 dnl also defines GSTUFF_PKG_ERRORS on error
1116 AC_DEFUN([PKG_CHECK_MODULES], [
1117   succeeded=no
1118
1119   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1120
1121   if test "$PKG_CONFIG" = "no" ; then
1122      ifelse([$4], , [AC_MSG_ERROR([
1123       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1124   else
1125      PKG_CONFIG_MIN_VERSION=0.9.0
1126      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1127         AC_MSG_CHECKING(for $2)
1128
1129         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD &&
1130            $1_CFLAGS=`$PKG_CONFIG --cflags "$2" 2>&AS_MESSAGE_LOG_FD` &&
1131            $1_LIBS=`$PKG_CONFIG --libs "$2" 2>&AS_MESSAGE_LOG_FD`; then
1132
1133             $1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e 's,///*,/,g'`
1134             $1_LIBS=`AS_ECHO(["$$1_LIBS"]) | sed -e 's,///*,/,g'`
1135             AC_MSG_RESULT([yes CFLAGS='$$1_CFLAGS' LIBS='$$1_LIBS'])
1136             succeeded=yes
1137         else
1138             AC_MSG_RESULT(no)
1139             $1_CFLAGS=""
1140             $1_LIBS=""
1141             ## If we have a custom action on failure, don't print errors, but
1142             ## do set a variable so people can do so.
1143             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1144             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1145         fi
1146
1147         AC_SUBST($1_CFLAGS)
1148         AC_SUBST($1_LIBS)
1149      else
1150         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1151         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1152      fi
1153   fi
1154
1155   if test $succeeded = yes; then
1156      ifelse([$3], , :, [$3])
1157   else
1158      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1159   fi
1160 ])
1161
1162
1163 if test "${with_sound}" != "no"; then
1164   # Sound support for GNU/Linux and the free BSDs.
1165   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1166     have_sound_header=yes)
1167   # Emulation library used on NetBSD.
1168   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1169   AC_SUBST(LIBSOUND)
1170
1171   ALSA_REQUIRED=1.0.0
1172   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1173   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1174   if test $HAVE_ALSA = yes; then
1175     SAVE_CFLAGS="$CFLAGS"
1176     SAVE_LIBS="$LIBS"
1177     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1178     LIBS="$ALSA_LIBS $LIBS"
1179     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1180                     emacs_alsa_normal=yes,
1181                     emacs_alsa_normal=no)
1182     if test "$emacs_alsa_normal" != yes; then
1183       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1184                      [[snd_lib_error_set_handler (0);]])],
1185                      emacs_alsa_subdir=yes,
1186                      emacs_alsa_subdir=no)
1187       if test "$emacs_alsa_subdir" != yes; then
1188         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1189       fi
1190       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1191     fi
1192
1193     CFLAGS="$SAVE_CFLAGS"
1194     LIBS="$SAVE_LIBS"
1195     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1196     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1197     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1198   fi
1199
1200   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1201   dnl compiles only on the specified platforms.  For others, it
1202   dnl probably doesn't make sense to try.
1203   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1204      case "$opsys" in
1205        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1206        gnu-linux|freebsd|netbsd)
1207          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1208          ;;
1209      esac
1210   fi
1211
1212   AC_SUBST(CFLAGS_SOUND)
1213 fi
1214
1215 dnl checks for header files
1216 AC_CHECK_HEADERS(sys/select.h sys/time.h unistd.h utime.h \
1217   linux/version.h sys/systeminfo.h \
1218   stdio_ext.h fcntl.h coff.h pty.h sys/mman.h \
1219   sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1220   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1221
1222 AC_MSG_CHECKING(if personality LINUX32 can be set)
1223 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1224                emacs_cv_personality_linux32=yes,
1225                emacs_cv_personality_linux32=no)
1226 AC_MSG_RESULT($emacs_cv_personality_linux32)
1227
1228 if test $emacs_cv_personality_linux32 = yes; then
1229   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1230             [Define to 1 if personality LINUX32 can be set.])
1231 fi
1232
1233 dnl On Solaris 8 there's a compilation warning for term.h because
1234 dnl it doesn't define `bool'.
1235 AC_CHECK_HEADERS(term.h, , , -)
1236 AC_HEADER_TIME
1237 AC_CHECK_DECLS([sys_siglist])
1238 if test $ac_cv_have_decl_sys_siglist != yes; then
1239   # For Tru64, at least:
1240   AC_CHECK_DECLS([__sys_siglist])
1241   if test $ac_cv_have_decl___sys_siglist = yes; then
1242     AC_DEFINE(sys_siglist, __sys_siglist,
1243               [Define to any substitute for sys_siglist.])
1244   fi
1245 fi
1246 AC_HEADER_SYS_WAIT
1247
1248 dnl Some systems have utime.h but don't declare the struct anyplace.
1249 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1250 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
1251 #include <sys/time.h>
1252 #include <time.h>
1253 #else
1254 #ifdef HAVE_SYS_TIME_H
1255 #include <sys/time.h>
1256 #else
1257 #include <time.h>
1258 #endif
1259 #endif
1260 #ifdef HAVE_UTIME_H
1261 #include <utime.h>
1262 #endif]], [[static struct utimbuf x; x.actime = x.modtime;]])],
1263   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1264 if test $emacs_cv_struct_utimbuf = yes; then
1265   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1266 fi
1267
1268 dnl Check for speed_t typedef.
1269 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1270   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <termios.h>]], [[speed_t x = 1;]])],
1271     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1272 if test $emacs_cv_speed_t = yes; then
1273   AC_DEFINE(HAVE_SPEED_T, 1,
1274            [Define to 1 if `speed_t' is declared by <termios.h>.])
1275 fi
1276
1277 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1278 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
1279 #include <sys/time.h>
1280 #include <time.h>
1281 #else
1282 #ifdef HAVE_SYS_TIME_H
1283 #include <sys/time.h>
1284 #else
1285 #include <time.h>
1286 #endif
1287 #endif]], [[static struct timeval x; x.tv_sec = x.tv_usec;]])],
1288   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1289 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1290 if test $emacs_cv_struct_timeval = yes; then
1291   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1292 fi
1293
1294 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1295 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]],
1296 [[static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;]])],
1297   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1298 HAVE_EXCEPTION=$emacs_cv_struct_exception
1299 if test $emacs_cv_struct_exception != yes; then
1300   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1301 fi
1302
1303 AC_CHECK_HEADERS(sys/socket.h)
1304 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1305 #if HAVE_SYS_SOCKET_H
1306 #include <sys/socket.h>
1307 #endif])
1308 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1309 #if HAVE_SYS_SOCKET_H
1310 #include <sys/socket.h>
1311 #endif])
1312 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1313 #if HAVE_SYS_SOCKET_H
1314 #include <sys/socket.h>
1315 #endif])
1316 AC_CHECK_FUNCS(getifaddrs freeifaddrs)
1317
1318 dnl checks for structure members
1319 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1320                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1321                   struct ifreq.ifr_addr,
1322                   struct ifreq.ifr_addr.sa_len], , ,
1323                  [AC_INCLUDES_DEFAULT
1324 #if HAVE_SYS_SOCKET_H
1325 #include <sys/socket.h>
1326 #endif
1327 #if HAVE_NET_IF_H
1328 #include <net/if.h>
1329 #endif])
1330
1331 dnl checks for compiler characteristics
1332
1333 dnl Testing __STDC__ to determine prototype support isn't good enough.
1334 dnl DEC C, for instance, doesn't define it with default options, and
1335 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1336 dnl and void *.
1337 AC_C_PROTOTYPES
1338 AC_C_VOLATILE
1339 AC_C_CONST
1340 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1341   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [[void * foo;]])],
1342                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1343 if test $emacs_cv_void_star = yes; then
1344   AC_DEFINE(POINTER_TYPE, void)
1345 else
1346   AC_DEFINE(POINTER_TYPE, char)
1347 fi
1348 AH_TEMPLATE(POINTER_TYPE,
1349             [Define as `void' if your compiler accepts `void *'; otherwise
1350              define as `char'.])dnl
1351
1352 dnl Check for endianness.
1353 AC_C_BIGENDIAN
1354
1355 AC_CACHE_CHECK([for  __attribute__ ((__aligned__ (expr)))],
1356   [emacs_cv_attribute_aligned],
1357   [AC_COMPILE_IFELSE(
1358      [AC_LANG_PROGRAM(
1359         [[char __attribute__ ((__aligned__ (1 << 3))) c;]],
1360         [[]])],
1361      [emacs_cv_attribute_aligned=yes],
1362      [emacs_cv_attribute_aligned=no])])
1363 if test $emacs_cv_attribute_aligned = yes; then
1364   AC_DEFINE([HAVE_ATTRIBUTE_ALIGNED], 1,
1365     [Define to 1 if GCC-style __attribute__ ((__aligned__ (expr))) works.])
1366 fi
1367
1368 dnl check for Make feature
1369 AC_PROG_MAKE_SET
1370
1371 DEPFLAGS=
1372 MKDEPDIR=":"
1373 deps_frag=deps.mk
1374 dnl check for GNU Make if we have GCC and autodepend is on.
1375 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1376    AC_MSG_CHECKING([whether we are using GNU Make])
1377    HAVE_GNU_MAKE=no
1378    testval=`${MAKE-make} --version 2>/dev/null | grep 'GNU Make'`
1379    if test "x$testval" != x; then
1380       HAVE_GNU_MAKE=yes
1381    else
1382       ac_enable_autodepend=no
1383    fi
1384    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1385    if test $HAVE_GNU_MAKE = yes; then
1386       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1387       SAVE_CFLAGS="$CFLAGS"
1388       CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1389       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1390       CFLAGS="$SAVE_CFLAGS"
1391       test -f deps.d || ac_enable_autodepend=no
1392       rm -rf deps.d
1393       AC_MSG_RESULT([$ac_enable_autodepend])
1394    fi
1395    if test $ac_enable_autodepend = yes; then
1396       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1397       ## In parallel builds, another make might create depdir between
1398       ## the first test and mkdir, so stick another test on the end.
1399       ## Or use install-sh -d?  mkdir -p is not portable.
1400       MKDEPDIR='test -d ${DEPDIR} || mkdir ${DEPDIR} || test -d ${DEPDIR}'
1401       deps_frag=autodeps.mk
1402    fi
1403 fi
1404 deps_frag=$srcdir/src/$deps_frag
1405 AC_SUBST(MKDEPDIR)
1406 AC_SUBST(DEPFLAGS)
1407 AC_SUBST_FILE(deps_frag)
1408
1409
1410 lisp_frag=$srcdir/src/lisp.mk
1411 AC_SUBST_FILE(lisp_frag)
1412
1413
1414 dnl checks for operating system services
1415 AC_SYS_LONG_FILE_NAMES
1416
1417 #### Choose a window system.
1418
1419 AC_PATH_X
1420 if test "$no_x" = yes; then
1421   window_system=none
1422 else
1423   window_system=x11
1424 fi
1425
1426 ## Workaround for bug in autoconf <= 2.62.
1427 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1428 ## No need to do anything special for these standard directories.
1429 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1430
1431    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1432
1433 fi
1434
1435 LD_SWITCH_X_SITE_AUX=
1436 LD_SWITCH_X_SITE_AUX_RPATH=
1437 if test "${x_libraries}" != NONE; then
1438   if test -n "${x_libraries}"; then
1439     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1440     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1441     LD_SWITCH_X_SITE_AUX_RPATH=`echo ${LD_SWITCH_X_SITE_AUX} | sed -e 's/-R/-Wl,-rpath,/'`
1442   fi
1443   x_default_search_path=""
1444   x_search_path=${x_libraries}
1445   if test -z "${x_search_path}"; then
1446     x_search_path=/usr/lib
1447   fi
1448   for x_library in `echo ${x_search_path}: | \
1449                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1450     x_search_path="\
1451 ${x_library}/X11/%L/%T/%N%C%S:\
1452 ${x_library}/X11/%l/%T/%N%C%S:\
1453 ${x_library}/X11/%T/%N%C%S:\
1454 ${x_library}/X11/%L/%T/%N%S:\
1455 ${x_library}/X11/%l/%T/%N%S:\
1456 ${x_library}/X11/%T/%N%S"
1457     if test x"${x_default_search_path}" = x; then
1458       x_default_search_path=${x_search_path}
1459     else
1460       x_default_search_path="${x_search_path}:${x_default_search_path}"
1461     fi
1462   done
1463 fi
1464 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1465 AC_SUBST(LD_SWITCH_X_SITE_AUX_RPATH)
1466
1467 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1468   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1469 fi
1470
1471 if test x"${x_includes}" = x; then
1472   bitmapdir=/usr/include/X11/bitmaps
1473 else
1474   # accumulate include directories that have X11 bitmap subdirectories
1475   bmd_acc="dummyval"
1476   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1477     if test -d "${bmd}/X11/bitmaps"; then
1478       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1479     fi
1480     if test -d "${bmd}/bitmaps"; then
1481       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1482     fi
1483   done
1484   if test ${bmd_acc} != "dummyval"; then
1485     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1486   fi
1487 fi
1488
1489 HAVE_NS=no
1490 NS_IMPL_COCOA=no
1491 NS_IMPL_GNUSTEP=no
1492 tmp_CPPFLAGS="$CPPFLAGS"
1493 tmp_CFLAGS="$CFLAGS"
1494 CPPFLAGS="$CPPFLAGS -x objective-c"
1495 CFLAGS="$CFLAGS -x objective-c"
1496 TEMACS_LDFLAGS2="\${LDFLAGS}"
1497 GNU_OBJC_CFLAGS=
1498 dnl I don't think it's especially important, but src/Makefile.in
1499 dnl (now the only user of ns_appdir) used to go to the trouble of adding a
1500 dnl trailing "/" to it, so now we do it here.
1501 if test "${with_ns}" != no; then
1502   if test "${opsys}" = darwin; then
1503      NS_IMPL_COCOA=yes
1504      ns_appdir=`pwd`/nextstep/Emacs.app
1505      ns_appbindir=${ns_appdir}/Contents/MacOS/
1506      ns_appresdir=${ns_appdir}/Contents/Resources
1507      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1508   elif test -f $GNUSTEP_CONFIG_FILE; then
1509      NS_IMPL_GNUSTEP=yes
1510      ns_appdir=`pwd`/nextstep/Emacs.app
1511      ns_appbindir=${ns_appdir}/
1512      ns_appresdir=${ns_appdir}/Resources
1513      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1514      dnl FIXME sourcing this several times in subshells seems inefficient.
1515      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1516      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1517      dnl I seemed to need these as well with GNUstep-startup 0.25.
1518      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1519      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1520      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1521        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1522      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1523        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1524      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1525      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1526      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1527      LIB_STANDARD=
1528      START_FILES=
1529      TEMACS_LDFLAGS2=
1530      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1531      dnl If they had chosen to either define it or not, we could have
1532      dnl just used AC_CHECK_DECL here.
1533      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1534        emacs_cv_objc_exceptions,
1535 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1536 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1537 1;
1538 #else
1539 fail;
1540 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1541      if test $emacs_cv_objc_exceptions = yes; then
1542        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1543        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1544          [Define if GNUstep uses ObjC exceptions.])
1545        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1546      fi
1547   fi
1548
1549   dnl This is only used while we test the NS headers, it gets reset below.
1550   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1551
1552   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1553                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1554   files are missing or cannot be compiled.])])
1555   NS_HAVE_NSINTEGER=yes
1556   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1557                                      [NSInteger i;])],
1558                     ns_have_nsinteger=yes,
1559                     ns_have_nsinteger=no)
1560   if test $ns_have_nsinteger = no; then
1561     NS_HAVE_NSINTEGER=no
1562   fi
1563 fi
1564 AC_SUBST(TEMACS_LDFLAGS2)
1565
1566 ns_frag=/dev/null
1567 NS_OBJ=
1568 NS_OBJC_OBJ=
1569 if test "${HAVE_NS}" = yes; then
1570   if test "$with_toolkit_scroll_bars" = "no"; then
1571     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1572   fi
1573
1574   window_system=nextstep
1575   with_xft=no
1576   # set up packaging dirs
1577   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1578      prefix=${ns_appresdir}
1579      exec_prefix=${ns_appbindir}
1580      libexecdir=${ns_appbindir}/libexec
1581   fi
1582   ns_frag=$srcdir/src/ns.mk
1583   NS_OBJ="fontset.o fringe.o image.o"
1584   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o"
1585 fi
1586 CFLAGS="$tmp_CFLAGS"
1587 CPPFLAGS="$tmp_CPPFLAGS"
1588 AC_SUBST(NS_OBJ)
1589 AC_SUBST(NS_OBJC_OBJ)
1590 AC_SUBST(LIB_STANDARD)
1591 AC_SUBST_FILE(ns_frag)
1592
1593 case "${window_system}" in
1594   x11 )
1595     HAVE_X_WINDOWS=yes
1596     HAVE_X11=yes
1597     case "${with_x_toolkit}" in
1598       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1599       motif ) USE_X_TOOLKIT=MOTIF ;;
1600       gtk ) with_gtk=yes
1601 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
1602 dnl USE_X_TOOLKIT is set.
1603             USE_X_TOOLKIT=none ;;
1604       gtk3 ) with_gtk3=yes
1605              USE_X_TOOLKIT=none ;;
1606       no ) USE_X_TOOLKIT=none ;;
1607 dnl If user did not say whether to use a toolkit, make this decision later:
1608 dnl use the toolkit if we have gtk, or X11R5 or newer.
1609       * ) USE_X_TOOLKIT=maybe ;;
1610     esac
1611   ;;
1612   nextstep | none )
1613     HAVE_X_WINDOWS=no
1614     HAVE_X11=no
1615     USE_X_TOOLKIT=none
1616   ;;
1617 esac
1618
1619 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1620    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1621    if test "$HAVE_XSERVER" = true ||
1622       test -n "$DISPLAY" ||
1623       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1624         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1625 were found.  You should install the relevant development files for X
1626 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1627 sure you have development files for image handling, i.e.
1628 tiff, gif, jpeg, png and xpm.
1629 If you are sure you want Emacs compiled without X window support, pass
1630   --without-x
1631 to configure.])
1632    fi
1633 fi
1634
1635 ### If we're using X11, we should use the X menu package.
1636 HAVE_MENUS=no
1637 case ${HAVE_X11} in
1638   yes ) HAVE_MENUS=yes ;;
1639 esac
1640
1641 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1642 # Assume not, until told otherwise.
1643 GNU_MALLOC=yes
1644 doug_lea_malloc=yes
1645 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1646 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1647 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1648                emacs_cv_var___after_morecore_hook,
1649 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[extern void (* __after_morecore_hook)();]],[[__after_morecore_hook = 0]])],
1650   emacs_cv_var___after_morecore_hook=yes,
1651   emacs_cv_var___after_morecore_hook=no)])
1652 if test $emacs_cv_var___after_morecore_hook = no; then
1653   doug_lea_malloc=no
1654 fi
1655
1656
1657 dnl See comments in aix4-2.h about maybe using system malloc there.
1658 system_malloc=no
1659 case "$opsys" in
1660   ## darwin ld insists on the use of malloc routines in the System framework.
1661   darwin|sol2-10) system_malloc=yes ;;
1662 esac
1663
1664 if test "${system_malloc}" = "yes"; then
1665   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1666   GNU_MALLOC=no
1667   GNU_MALLOC_reason="
1668     (The GNU allocators don't work with this system configuration.)"
1669   GMALLOC_OBJ=
1670   VMLIMIT_OBJ=
1671 else
1672   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1673   VMLIMIT_OBJ=vm-limit.o
1674 fi
1675 AC_SUBST(GMALLOC_OBJ)
1676 AC_SUBST(VMLIMIT_OBJ)
1677
1678 if test "$doug_lea_malloc" = "yes" ; then
1679   if test "$GNU_MALLOC" = yes ; then
1680     GNU_MALLOC_reason="
1681       (Using Doug Lea's new malloc from the GNU C Library.)"
1682   fi
1683   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1684             [Define to 1 if you are using the GNU C Library.])
1685
1686   ## Use mmap directly for allocating larger buffers.
1687   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1688   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1689   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
1690   case "$opsys" in
1691     gnu*) REL_ALLOC=no ;;
1692   esac
1693 fi
1694
1695 if test x"${REL_ALLOC}" = x; then
1696   REL_ALLOC=${GNU_MALLOC}
1697 fi
1698
1699 use_mmap_for_buffers=no
1700 case "$opsys" in
1701   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1702 esac
1703
1704 AC_FUNC_MMAP
1705 if test $use_mmap_for_buffers = yes; then
1706   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1707   REL_ALLOC=no
1708 fi
1709
1710 LIBS="$LIBS_SYSTEM $LIBS"
1711
1712 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1713 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1714 AC_CHECK_LIB(dnet, dnet_ntoa)
1715 dnl This causes -lresolv to get used in subsequent tests,
1716 dnl which causes failures on some systems such as HPUX 9.
1717 dnl AC_CHECK_LIB(resolv, gethostbyname)
1718
1719 dnl FIXME replace main with a function we actually want from this library.
1720 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1721
1722 dnl Check if pthreads is available.
1723 LIB_PTHREAD=
1724 AC_CHECK_HEADERS(pthread.h)
1725 if test "$ac_cv_header_pthread_h"; then
1726   dnl gmalloc.c uses pthread_atfork, which is not available on older-style
1727   dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
1728   dnl testing for pthread_self if Emacs uses gmalloc.c.
1729   if test "$GMALLOC_OBJ" = gmalloc.o; then
1730     emacs_pthread_function=pthread_atfork
1731   else
1732     emacs_pthread_function=pthread_self
1733   fi
1734   AC_CHECK_LIB(pthread, $emacs_pthread_function, HAVE_PTHREAD=yes)
1735 fi
1736 if test "$HAVE_PTHREAD" = yes; then
1737   case "${canonical}" in
1738     *-hpux*) ;;
1739     *) LIB_PTHREAD="-lpthread"
1740        LIBS="$LIB_PTHREAD $LIBS" ;;
1741   esac
1742   AC_DEFINE(HAVE_PTHREAD, 1, [Define to 1 if you have pthread (-lpthread).])
1743 fi
1744 AC_SUBST([LIB_PTHREAD])
1745
1746 AC_CHECK_LIB(pthreads, cma_open)
1747
1748 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1749 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1750 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1751 ## added to LIBS in configure would never contain the pthreads part,
1752 ## but the value used in Makefiles might.  FIXME?
1753 ##
1754 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1755 ## be harmless on older versions of X where it happens to exist.
1756 test "$opsys" = "aix4-2" && \
1757   test $ac_cv_lib_pthreads_cma_open = yes && \
1758   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1759
1760 dnl Check for need for bigtoc support on IBM AIX
1761
1762 case ${host_os} in
1763 aix*)
1764   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1765     case $GCC in
1766     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1767     *) gdb_cv_bigtoc=-bbigtoc ;;
1768     esac
1769
1770     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1771     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
1772   ])
1773   ;;
1774 esac
1775
1776 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1777 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1778 # REAL_CPPFLAGS later on.
1779
1780 REAL_CFLAGS="$CFLAGS"
1781 REAL_CPPFLAGS="$CPPFLAGS"
1782
1783 if test "${HAVE_X11}" = "yes"; then
1784   DEFS="$C_SWITCH_X_SITE $DEFS"
1785   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1786   LIBS="-lX11 $LIBS"
1787   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1788   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1789
1790   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1791   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1792   # but it's more convenient here to set LD_RUN_PATH
1793   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1794   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1795     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1796     export LD_RUN_PATH
1797   fi
1798
1799   if test "${opsys}" = "gnu-linux"; then
1800     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1801     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1802      [[XOpenDisplay ("foo");]])],
1803      [xgnu_linux_first_failure=no],
1804      [xgnu_linux_first_failure=yes])
1805     if test "${xgnu_linux_first_failure}" = "yes"; then
1806       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1807       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1808       OLD_CPPFLAGS="$CPPFLAGS"
1809       OLD_LIBS="$LIBS"
1810       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1811       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1812       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1813       LIBS="$LIBS -b i486-linuxaout"
1814       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1815        [[XOpenDisplay ("foo");]])],
1816        [xgnu_linux_second_failure=no],
1817        [xgnu_linux_second_failure=yes])
1818       if test "${xgnu_linux_second_failure}" = "yes"; then
1819         # If we get the same failure with -b, there is no use adding -b.
1820         # So take it out.  This plays safe.
1821         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1822         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1823         CPPFLAGS="$OLD_CPPFLAGS"
1824         LIBS="$OLD_LIBS"
1825         AC_MSG_RESULT(no)
1826       else
1827         AC_MSG_RESULT(yes)
1828       fi
1829     else
1830       AC_MSG_RESULT(no)
1831     fi
1832   fi
1833
1834   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1835   # header files included from there.
1836   AC_MSG_CHECKING(for Xkb)
1837   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1838 #include <X11/XKBlib.h>]],
1839         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
1840         emacs_xkb=yes, emacs_xkb=no)
1841   AC_MSG_RESULT($emacs_xkb)
1842   if test $emacs_xkb = yes; then
1843     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1844   fi
1845
1846   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1847 XScreenNumberOfScreen XSetWMProtocols)
1848 fi
1849
1850 if test "${window_system}" = "x11"; then
1851   AC_MSG_CHECKING(X11 version 6)
1852   AC_CACHE_VAL(emacs_cv_x11_version_6,
1853   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
1854 [[#if XlibSpecificationRelease < 6
1855 fail;
1856 #endif
1857 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1858   if test $emacs_cv_x11_version_6 = yes; then
1859     AC_MSG_RESULT(6 or newer)
1860     AC_DEFINE(HAVE_X11R6, 1,
1861               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1862     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1863     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1864     ## XIM support.
1865     case "$opsys" in
1866       sol2-*) : ;;
1867       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1868            [Define if you have usable X11R6-style XIM support.])
1869          ;;
1870     esac
1871   else
1872     AC_MSG_RESULT(before 6)
1873   fi
1874 fi
1875
1876
1877 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1878 HAVE_RSVG=no
1879 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes"; then
1880   if test "${with_rsvg}" != "no"; then
1881     RSVG_REQUIRED=2.11.0
1882     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1883
1884     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1885     AC_SUBST(RSVG_CFLAGS)
1886     AC_SUBST(RSVG_LIBS)
1887
1888     if test $HAVE_RSVG = yes; then
1889       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1890       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1891       LIBS="$RSVG_LIBS $LIBS"
1892     fi
1893   fi
1894 fi
1895
1896 HAVE_IMAGEMAGICK=no
1897 if test "${HAVE_X11}" = "yes"; then
1898   if test "${with_imagemagick}" != "no"; then
1899     ## 6.2.8 is the earliest version known to work, but earlier versions
1900     ## might work - let us know if you find one.
1901     ## 6.0.7 does not work.  See bug#7955.
1902     IMAGEMAGICK_MODULE="Wand >= 6.2.8"
1903     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1904     AC_SUBST(IMAGEMAGICK_CFLAGS)
1905     AC_SUBST(IMAGEMAGICK_LIBS)
1906
1907     if test $HAVE_IMAGEMAGICK = yes; then
1908       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1909       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1910       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1911       AC_CHECK_FUNCS(MagickExportImagePixels)
1912     fi
1913   fi
1914 fi
1915
1916
1917 HAVE_GTK=no
1918 GTK_OBJ=
1919 if test "${with_gtk3}" = "yes"; then
1920   GLIB_REQUIRED=2.28
1921   GTK_REQUIRED=3.0
1922   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1923
1924   dnl Checks for libraries.
1925   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1926   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1927      AC_MSG_ERROR($GTK_PKG_ERRORS)
1928   fi
1929   AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
1930   GTK_OBJ=emacsgtkfixed.o
1931 fi
1932
1933 if test "$pkg_check_gtk" != "yes"; then
1934   HAVE_GTK=no
1935 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1936   GLIB_REQUIRED=2.10
1937   GTK_REQUIRED=2.10
1938   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1939
1940   dnl Checks for libraries.
1941   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1942   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1943      AC_MSG_ERROR($GTK_PKG_ERRORS)
1944   fi
1945 fi
1946 fi
1947
1948 if test x"$pkg_check_gtk" = xyes; then
1949
1950   AC_SUBST(GTK_CFLAGS)
1951   AC_SUBST(GTK_LIBS)
1952   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1953   CFLAGS="$CFLAGS $GTK_CFLAGS"
1954   LIBS="$GTK_LIBS $LIBS"
1955   dnl Try to compile a simple GTK program.
1956   GTK_COMPILES=no
1957   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1958   if test "${GTK_COMPILES}" != "yes"; then
1959     if test "$USE_X_TOOLKIT" != "maybe"; then
1960       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1961     fi
1962   else
1963     HAVE_GTK=yes
1964     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1965     GTK_OBJ="gtkutil.o $GTK_OBJ"
1966     USE_X_TOOLKIT=none
1967     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1968       :
1969     else
1970       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1971        closing open displays.  This is no problem if you just use
1972        one display, but if you use more than one and close one of them
1973        Emacs may crash.]])
1974       sleep 3
1975     fi
1976   fi
1977
1978 fi
1979 AC_SUBST(GTK_OBJ)
1980
1981
1982 if test "${HAVE_GTK}" = "yes"; then
1983
1984   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1985   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1986   if test "$with_toolkit_scroll_bars" != no; then
1987     with_toolkit_scroll_bars=yes
1988   fi
1989
1990   dnl  Check if we have the old file selection dialog declared and
1991   dnl  in the link library.  In 2.x it may be in the library,
1992   dnl  but not declared if deprecated featured has been selected out.
1993   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1994   HAVE_GTK_FILE_SELECTION=no
1995   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1996                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1997 #include <gtk/gtk.h>])
1998   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1999     AC_CHECK_FUNCS(gtk_file_selection_new)
2000   fi
2001
2002
2003   dnl Check for functions introduced in 2.14 and later.
2004   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2005                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2006                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2007                  gtk_orientable_set_orientation \
2008                  gtk_window_set_has_resize_grip)
2009 fi
2010
2011
2012 HAVE_XWIDGETS=no
2013 HAVE_WEBKIT=no
2014 HAVE_GOOCANVAS=no
2015 HAVE_CLUTTER=no
2016 if test "${with_xwidgets}" != "no"; then
2017    echo "xwidgets enabled, checking webkit, and others"
2018    HAVE_XWIDGETS=yes
2019    AC_DEFINE(HAVE_XWIDGETS, 1, [Define to 1 if you have xwidgets support.])
2020 #xwidgets
2021 #TODO
2022 # - enable only if gtk/gtk3 enabled
2023 # - webkit, goocanvas, clutter
2024 # - only webkit_osr is good so remove plain webkit laterish
2025
2026 #webkit version for gtk3.
2027   WEBKIT_REQUIRED=1.4.0
2028   WEBKIT_MODULES="webkitgtk-3.0 >= $WEBKIT_REQUIRED"
2029
2030   if test "${with_gtk3}" = "yes"; then
2031     PKG_CHECK_MODULES(WEBKIT, $WEBKIT_MODULES, HAVE_WEBKIT=yes, HAVE_WEBKIT=no)
2032     if test $HAVE_WEBKIT = yes; then
2033         AC_DEFINE(HAVE_WEBKIT_OSR, 1, [Define to 1 if you have webkit_osr support.])
2034     fi
2035   fi
2036
2037   if test "${with_xwdemo}"  = "yes"; then
2038 #clutter and goocanvas are just proof of concept so disable for now
2039   CLUTTER_REQUIRED=1.0.0
2040   CLUTTER_MODULES="clutter-gtk-1.0 >= $CLUTTER_REQUIRED"
2041
2042   PKG_CHECK_MODULES(CLUTTER, $CLUTTER_MODULES, HAVE_CLUTTER=yes, HAVE_CLUTTER=no)
2043   if test $HAVE_CLUTTER = yes;  then
2044      AC_DEFINE(HAVE_CLUTTER, 1, [Define to 1 if you have clutter support.])
2045   fi
2046
2047
2048   GOOCANVAS_REQUIRED=1.4.0
2049   GOOCANVAS_MODULES="goocanvasgtk-3.0 >= $GOOCANVAS_REQUIRED"
2050
2051   PKG_CHECK_MODULES(GOOCANVAS, $GOOCANVAS_MODULES, HAVE_GOOCANVAS=yes, HAVE_GOOCANVAS=no)
2052   if test $HAVE_GOOCANVAS = yes; then
2053      AC_DEFINE(HAVE_GOOCANVAS, 1, [Define to 1 if you have goocanvas support.])
2054   fi
2055   fi
2056 fi
2057
2058
2059 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2060 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
2061 dnl also not configured.
2062 HAVE_DBUS=no
2063 DBUS_OBJ=
2064 if test "${with_dbus}" = "yes"; then
2065    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
2066    if test "$HAVE_DBUS" = yes; then
2067      LIBS="$LIBS $DBUS_LIBS"
2068      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2069      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
2070      DBUS_OBJ=dbusbind.o
2071    fi
2072 fi
2073 AC_SUBST(DBUS_OBJ)
2074
2075 dnl GSettings has been tested under GNU/Linux only.
2076 HAVE_GSETTINGS=no
2077 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2078    PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
2079    if test "$HAVE_GSETTINGS" = "yes"; then
2080       AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2081       SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2082       SETTINGS_LIBS="$GSETTINGS_LIBS"
2083    fi
2084 fi
2085
2086 dnl GConf has been tested under GNU/Linux only.
2087 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2088 HAVE_GCONF=no
2089 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2090    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
2091    if test "$HAVE_GCONF" = yes; then
2092       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2093       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2094       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2095       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2096    fi
2097 fi
2098
2099 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2100     SAVE_CFLAGS="$CFLAGS"
2101     SAVE_LIBS="$LIBS"
2102     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2103     LIBS="$SETTINGS_LIBS $LIBS"
2104     AC_CHECK_FUNCS([g_type_init])
2105     CFLAGS="$SAVE_CFLAGS"
2106     LIBS="$SAVE_LIBS"
2107 fi
2108 AC_SUBST(SETTINGS_CFLAGS)
2109 AC_SUBST(SETTINGS_LIBS)
2110
2111
2112 dnl SELinux is available for GNU/Linux only.
2113 HAVE_LIBSELINUX=no
2114 LIBSELINUX_LIBS=
2115 if test "${with_selinux}" = "yes"; then
2116    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2117    if test "$HAVE_LIBSELINUX" = yes; then
2118       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2119       LIBSELINUX_LIBS=-lselinux
2120    fi
2121 fi
2122 AC_SUBST(LIBSELINUX_LIBS)
2123
2124 HAVE_GNUTLS=no
2125 HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=no
2126 if test "${with_gnutls}" = "yes" ; then
2127   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2128   if test "${HAVE_GNUTLS}" = "yes"; then
2129     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2130   fi
2131
2132   CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
2133   LIBS="$LIBGNUTLS_LIBS $LIBS"
2134   AC_CHECK_FUNCS(gnutls_certificate_set_verify_function, HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=yes)
2135
2136   if test "${HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY}" = "yes"; then
2137     AC_DEFINE(HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY, 1, [Define if using GnuTLS certificate verification callbacks.])
2138   fi
2139 fi
2140
2141 AC_SUBST(LIBGNUTLS_LIBS)
2142 AC_SUBST(LIBGNUTLS_CFLAGS)
2143
2144 dnl Do not put whitespace before the #include statements below.
2145 dnl Older compilers (eg sunos4 cc) choke on it.
2146 HAVE_XAW3D=no
2147 LUCID_LIBW=
2148 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2149   if test "$with_xaw3d" != no; then
2150     AC_MSG_CHECKING(for xaw3d)
2151     AC_CACHE_VAL(emacs_cv_xaw3d,
2152     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2153 #include <X11/Intrinsic.h>
2154 #include <X11/Xaw3d/Simple.h>]],
2155       [[]])],
2156       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2157                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2158       emacs_cv_xaw3d=no)])
2159   else
2160     emacs_cv_xaw3d=no
2161   fi
2162   if test $emacs_cv_xaw3d = yes; then
2163     AC_MSG_RESULT([yes; using Lucid toolkit])
2164     USE_X_TOOLKIT=LUCID
2165     HAVE_XAW3D=yes
2166     LUCID_LIBW=-lXaw3d
2167     AC_DEFINE(HAVE_XAW3D, 1,
2168               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2169   else
2170     AC_MSG_RESULT(no)
2171     AC_MSG_CHECKING(for libXaw)
2172     AC_CACHE_VAL(emacs_cv_xaw,
2173     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2174 #include <X11/Intrinsic.h>
2175 #include <X11/Xaw/Simple.h>]],
2176       [[]])],
2177       emacs_cv_xaw=yes,
2178       emacs_cv_xaw=no)])
2179     if test $emacs_cv_xaw = yes; then
2180       AC_MSG_RESULT([yes; using Lucid toolkit])
2181       USE_X_TOOLKIT=LUCID
2182       LUCID_LIBW=-lXaw
2183     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2184       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2185     else
2186       AC_MSG_ERROR([No X toolkit could be found.
2187 If you are sure you want Emacs compiled without an X toolkit, pass
2188   --with-x-toolkit=no
2189 to configure.  Otherwise, install the development libraries for the toolkit
2190 that you want to use (e.g. Gtk+) and re-run configure.])
2191     fi
2192   fi
2193 fi
2194
2195 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2196
2197 LIBXTR6=
2198 if test "${USE_X_TOOLKIT}" != "none"; then
2199   AC_MSG_CHECKING(X11 toolkit version)
2200   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2201   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2202 [[#if XtSpecificationRelease < 6
2203 fail;
2204 #endif
2205 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2206   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2207   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2208     AC_MSG_RESULT(6 or newer)
2209     AC_DEFINE(HAVE_X11XTR6, 1,
2210               [Define to 1 if you have the X11R6 or newer version of Xt.])
2211     LIBXTR6="-lSM -lICE"
2212     case "$opsys" in
2213       ## Use libw.a along with X11R6 Xt.
2214       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2215     esac
2216   else
2217     AC_MSG_RESULT(before 6)
2218   fi
2219
2220 dnl If using toolkit, check whether libXmu.a exists.
2221 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2222   OLDLIBS="$LIBS"
2223   if test x$HAVE_X11XTR6 = xyes; then
2224     LIBS="-lXt -lSM -lICE $LIBS"
2225   else
2226     LIBS="-lXt $LIBS"
2227   fi
2228   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2229   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2230 fi
2231 AC_SUBST(LIBXTR6)
2232
2233 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2234 dnl Why not just test for libxmu in the normal way?
2235 LIBXMU=-lXmu
2236 case $opsys in
2237   ## These systems don't supply Xmu.
2238   hpux* | aix4-2 )
2239     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2240     ;;
2241 esac
2242 AC_SUBST(LIBXMU)
2243
2244 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2245 if test "${HAVE_X11}" = "yes"; then
2246   if test "${USE_X_TOOLKIT}" != "none"; then
2247     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2248   fi
2249 fi
2250
2251 LIBXP=
2252 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2253   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2254   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2255     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2256 int x = 5;
2257 #else
2258 Motif version prior to 2.1.
2259 #endif]])],
2260     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2261   if test $emacs_cv_motif_version_2_1 = yes; then
2262     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2263   else
2264     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2265     # We put this in CFLAGS temporarily to precede other -I options
2266     # that might be in CFLAGS temporarily.
2267     # We put this in CPPFLAGS where it precedes the other -I options.
2268     OLD_CPPFLAGS=$CPPFLAGS
2269     OLD_CFLAGS=$CFLAGS
2270     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2271     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2272     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2273       [[int x = 5;]])],
2274       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2275     if test $emacs_cv_lesstif = yes; then
2276       # Make sure this -I option remains in CPPFLAGS after it is set
2277       # back to REAL_CPPFLAGS.
2278       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2279       # have those other -I options anyway.  Ultimately, having this
2280       # directory ultimately in CPPFLAGS will be enough.
2281       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2282       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2283     else
2284       CFLAGS=$OLD_CFLAGS
2285       CPPFLAGS=$OLD_CPPFLAGS
2286     fi
2287   fi
2288   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2289     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2290 fi
2291
2292 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2293 dnl using Motif or Xaw3d is available, and unless
2294 dnl --with-toolkit-scroll-bars=no was specified.
2295
2296 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2297             [Define to 1 if we should use toolkit scroll bars.])dnl
2298 USE_TOOLKIT_SCROLL_BARS=no
2299 if test "${with_toolkit_scroll_bars}" != "no"; then
2300   if test "${USE_X_TOOLKIT}" != "none"; then
2301     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2302       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2303       HAVE_XAW3D=no
2304       USE_TOOLKIT_SCROLL_BARS=yes
2305     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2306       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2307       USE_TOOLKIT_SCROLL_BARS=yes
2308     fi
2309   elif test "${HAVE_GTK}" = "yes"; then
2310     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2311     USE_TOOLKIT_SCROLL_BARS=yes
2312   elif test "${HAVE_NS}" = "yes"; then
2313     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2314     USE_TOOLKIT_SCROLL_BARS=yes
2315   fi
2316 fi
2317
2318 dnl See if XIM is available.
2319 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2320           #include <X11/Xlib.h>
2321           #include <X11/Xresource.h>]],
2322          [[XIMProc  callback;]])],
2323          [HAVE_XIM=yes
2324          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2325          HAVE_XIM=no)
2326
2327 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2328
2329 if test "${with_xim}" != "no"; then
2330   AC_DEFINE(USE_XIM, 1,
2331             [Define to 1 if we should use XIM, if it is available.])
2332 fi
2333
2334
2335 if test "${HAVE_XIM}" != "no"; then
2336   late_CFLAGS=$CFLAGS
2337   if test "$GCC" = yes; then
2338     CFLAGS="$CFLAGS --pedantic-errors"
2339   fi
2340   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2341 #include <X11/Xlib.h>
2342 #include <X11/Xresource.h>]],
2343 [[Display *display;
2344 XrmDatabase db;
2345 char *res_name;
2346 char *res_class;
2347 XIMProc  callback;
2348 XPointer *client_data;
2349 #ifndef __GNUC__
2350 /* If we're not using GCC, it's probably not XFree86, and this is
2351    probably right, but we can't use something like --pedantic-errors.  */
2352 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2353                                            char*, XIMProc, XPointer*);
2354 #endif
2355 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2356    client_data);]])],
2357     [emacs_cv_arg6_star=yes])
2358   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2359          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2360 either XPointer or XPointer*.])dnl
2361   if test "$emacs_cv_arg6_star" = yes; then
2362     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2363   else
2364     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2365   fi
2366   CFLAGS=$late_CFLAGS
2367 fi
2368
2369 ### Start of font-backend (under any platform) section.
2370 # (nothing here yet -- this is a placeholder)
2371 ### End of font-backend (under any platform) section.
2372
2373 ### Start of font-backend (under X11) section.
2374 if test "${HAVE_X11}" = "yes"; then
2375    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2376
2377    ## Use -lXft if available, unless `--with-xft=no'.
2378    HAVE_XFT=maybe
2379     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2380       with_xft="no";
2381     fi
2382     if test "x${with_xft}" != "xno"; then
2383
2384       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2385       ## Because xftfont.c uses XRenderQueryExtension, we also
2386       ## need to link to -lXrender.
2387       HAVE_XRENDER=no
2388       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2389       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2390         OLD_CPPFLAGS="$CPPFLAGS"
2391         OLD_CFLAGS="$CFLAGS"
2392         OLD_LIBS="$LIBS"
2393         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2394         CFLAGS="$CFLAGS $XFT_CFLAGS"
2395         XFT_LIBS="-lXrender $XFT_LIBS"
2396         LIBS="$XFT_LIBS $LIBS"
2397         AC_CHECK_HEADER(X11/Xft/Xft.h,
2398           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2399
2400         if test "${HAVE_XFT}" = "yes"; then
2401           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2402             AC_SUBST(XFT_LIBS)
2403           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2404         else
2405           CPPFLAGS="$OLD_CPPFLAGS"
2406           CFLAGS="$OLD_CFLAGS"
2407           LIBS="$OLD_LIBS"
2408         fi                        # "${HAVE_XFT}" = "yes"
2409       fi                          # "$HAVE_XFT" != no
2410     fi                            # "x${with_xft}" != "xno"
2411
2412     ## We used to allow building with FreeType and without Xft.
2413     ## However, the ftx font backend driver is not in good shape.
2414     if test "$HAVE_XFT" != "yes"; then
2415        dnl For the "Does Emacs use" message at the end.
2416        HAVE_XFT=no
2417        HAVE_FREETYPE=no
2418     else
2419        dnl Strict linkers fail with
2420        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2421        dnl if -lfreetype is not specified.
2422        dnl The following is needed to set FREETYPE_LIBS.
2423        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2424                          HAVE_FREETYPE=no)
2425
2426        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2427     fi
2428
2429     HAVE_LIBOTF=no
2430     if test "${HAVE_FREETYPE}" = "yes"; then
2431       AC_DEFINE(HAVE_FREETYPE, 1,
2432                 [Define to 1 if using the freetype and fontconfig libraries.])
2433       if test "${with_libotf}" != "no"; then
2434         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2435                           HAVE_LIBOTF=no)
2436         if test "$HAVE_LIBOTF" = "yes"; then
2437           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2438           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2439                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2440                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2441           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2442             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2443                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2444           fi
2445         fi
2446       fi
2447     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2448     dnl Does the new font backend require it, or can it work without it?
2449     fi
2450
2451     HAVE_M17N_FLT=no
2452     if test "${HAVE_LIBOTF}" = yes; then
2453       if test "${with_m17n_flt}" != "no"; then
2454         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2455         if test "$HAVE_M17N_FLT" = "yes"; then
2456           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2457         fi
2458       fi
2459     fi
2460 else
2461     HAVE_XFT=no
2462     HAVE_FREETYPE=no
2463     HAVE_LIBOTF=no
2464     HAVE_M17N_FLT=no
2465 fi
2466
2467 ### End of font-backend (under X11) section.
2468
2469 AC_SUBST(FREETYPE_CFLAGS)
2470 AC_SUBST(FREETYPE_LIBS)
2471 AC_SUBST(FONTCONFIG_CFLAGS)
2472 AC_SUBST(FONTCONFIG_LIBS)
2473 AC_SUBST(LIBOTF_CFLAGS)
2474 AC_SUBST(LIBOTF_LIBS)
2475 AC_SUBST(M17N_FLT_CFLAGS)
2476 AC_SUBST(M17N_FLT_LIBS)
2477
2478 ### Use -lXpm if available, unless `--with-xpm=no'.
2479 HAVE_XPM=no
2480 LIBXPM=
2481 if test "${HAVE_X11}" = "yes"; then
2482   if test "${with_xpm}" != "no"; then
2483     AC_CHECK_HEADER(X11/xpm.h,
2484       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2485     if test "${HAVE_XPM}" = "yes"; then
2486       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2487       AC_EGREP_CPP(no_return_alloc_pixels,
2488       [#include "X11/xpm.h"
2489 #ifndef XpmReturnAllocPixels
2490 no_return_alloc_pixels
2491 #endif
2492       ], HAVE_XPM=no, HAVE_XPM=yes)
2493
2494       if test "${HAVE_XPM}" = "yes"; then
2495         AC_MSG_RESULT(yes)
2496       else
2497         AC_MSG_RESULT(no)
2498       fi
2499     fi
2500   fi
2501
2502   if test "${HAVE_XPM}" = "yes"; then
2503     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2504     LIBXPM=-lXpm
2505   fi
2506 fi
2507 AC_SUBST(LIBXPM)
2508
2509 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2510 HAVE_JPEG=no
2511 LIBJPEG=
2512 if test "${HAVE_X11}" = "yes"; then
2513   if test "${with_jpeg}" != "no"; then
2514     dnl Checking for jpeglib.h can lose because of a redefinition of
2515     dnl  HAVE_STDLIB_H.
2516     AC_CHECK_HEADER(jerror.h,
2517       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2518   fi
2519
2520   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2521   if test "${HAVE_JPEG}" = "yes"; then
2522     AC_DEFINE(HAVE_JPEG)
2523     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2524         [#include <jpeglib.h>
2525          version=JPEG_LIB_VERSION
2526 ],
2527         [AC_DEFINE(HAVE_JPEG)],
2528         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2529         HAVE_JPEG=no])
2530   fi
2531   if test "${HAVE_JPEG}" = "yes"; then
2532     LIBJPEG=-ljpeg
2533   fi
2534 fi
2535 AC_SUBST(LIBJPEG)
2536
2537 ### Use -lpng if available, unless `--with-png=no'.
2538 HAVE_PNG=no
2539 LIBPNG=
2540 if test "${HAVE_X11}" = "yes"; then
2541   if test "${with_png}" != "no"; then
2542     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2543     # in /usr/include/libpng.
2544     AC_CHECK_HEADERS(png.h libpng/png.h)
2545     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2546       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2547     fi
2548   fi
2549
2550   if test "${HAVE_PNG}" = "yes"; then
2551     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2552     LIBPNG="-lpng -lz -lm"
2553   fi
2554 fi
2555 AC_SUBST(LIBPNG)
2556
2557 ### Use -ltiff if available, unless `--with-tiff=no'.
2558 HAVE_TIFF=no
2559 LIBTIFF=
2560 if test "${HAVE_X11}" = "yes"; then
2561   if test "${with_tiff}" != "no"; then
2562     AC_CHECK_HEADER(tiffio.h,
2563       [tifflibs="-lz -lm"
2564       # At least one tiff package requires the jpeg library.
2565       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2566       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2567   fi
2568
2569   if test "${HAVE_TIFF}" = "yes"; then
2570     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2571     dnl FIXME -lz -lm, as per libpng?
2572     LIBTIFF=-ltiff
2573   fi
2574 fi
2575 AC_SUBST(LIBTIFF)
2576
2577 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2578 HAVE_GIF=no
2579 LIBGIF=
2580 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2581   AC_CHECK_HEADER(gif_lib.h,
2582 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2583 # Earlier versions can crash Emacs.
2584     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2585
2586   if test "$HAVE_GIF" = yes; then
2587     LIBGIF=-lgif
2588   elif test "$HAVE_GIF" = maybe; then
2589 # If gif_lib.h but no libgif, try libungif.
2590     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2591     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2592   fi
2593
2594   if test "${HAVE_GIF}" = "yes"; then
2595     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2596   fi
2597 fi
2598 AC_SUBST(LIBGIF)
2599
2600 dnl Check for required libraries.
2601 if test "${HAVE_X11}" = "yes"; then
2602   MISSING=""
2603   WITH_NO=""
2604   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2605     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2606   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2607     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2608   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2609     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2610   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2611     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2612   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2613     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2614
2615   if test "X${MISSING}" != X; then
2616     AC_MSG_ERROR([The following required libraries were not found:
2617     $MISSING
2618 Maybe some development libraries/packages are missing?
2619 If you don't want to link with them give
2620     $WITH_NO
2621 as options to configure])
2622   fi
2623 fi
2624
2625 ### Use -lgpm if available, unless `--with-gpm=no'.
2626 HAVE_GPM=no
2627 LIBGPM=
2628 if test "${with_gpm}" != "no"; then
2629   AC_CHECK_HEADER(gpm.h,
2630     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2631
2632   if test "${HAVE_GPM}" = "yes"; then
2633     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2634     LIBGPM=-lgpm
2635   fi
2636 fi
2637 AC_SUBST(LIBGPM)
2638
2639 dnl Check for malloc/malloc.h on darwin
2640 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2641
2642 C_SWITCH_X_SYSTEM=
2643 ### Use NeXTstep API to implement GUI.
2644 if test "${HAVE_NS}" = "yes"; then
2645   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2646   if test "${NS_IMPL_COCOA}" = "yes"; then
2647     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2648   fi
2649   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2650     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2651     # See also .m.o rule in Makefile.in */
2652     # FIXME: are all these flags really needed?  Document here why.  */
2653     dnl FIXME this should be renamed to GNUSTEP_CFLAGS, and only
2654     dnl used in src/Makefile.in.
2655     C_SWITCH_X_SYSTEM="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
2656     ## Extra CFLAGS applied to src/*.m files.
2657     GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2658   fi
2659   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2660     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2661   fi
2662   # We also have mouse menus.
2663   HAVE_MENUS=yes
2664   OTHER_FILES=ns-app
2665 fi
2666
2667
2668 ### Use session management (-lSM -lICE) if available
2669 HAVE_X_SM=no
2670 LIBXSM=
2671 if test "${HAVE_X11}" = "yes"; then
2672   AC_CHECK_HEADER(X11/SM/SMlib.h,
2673     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2674
2675   if test "${HAVE_X_SM}" = "yes"; then
2676     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2677     LIBXSM="-lSM -lICE"
2678     case "$LIBS" in
2679       *-lSM*) ;;
2680       *)      LIBS="$LIBXSM $LIBS" ;;
2681     esac
2682   fi
2683 fi
2684 AC_SUBST(LIBXSM)
2685
2686 ### Use libxml (-lxml2) if available
2687 HAVE_LIBXML2=no
2688 if test "${with_xml2}" != "no"; then
2689   ### I'm not sure what the version number should be, so I just guessed.
2690   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2691   if test "${HAVE_LIBXML2}" = "yes"; then
2692     LIBS="$LIBXML2_LIBS $LIBS"
2693     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2694     if test "${HAVE_LIBXML2}" = "yes"; then
2695       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2696     else
2697       LIBXML2_LIBS=""
2698       LIBXML2_CFLAGS=""
2699     fi
2700   fi
2701 fi
2702 AC_SUBST(LIBXML2_LIBS)
2703 AC_SUBST(LIBXML2_CFLAGS)
2704
2705 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2706 AC_CACHE_CHECK(whether netdb declares h_errno,
2707                emacs_cv_netdb_declares_h_errno,
2708 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
2709   [[return h_errno;]])],
2710   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2711 if test $emacs_cv_netdb_declares_h_errno = yes; then
2712   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2713 fi
2714
2715 # fmod, logb, and frexp are found in -lm on most systems.
2716 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2717 AC_CHECK_LIB(m, sqrt)
2718
2719 # Check for mail-locking functions in a "mail" library.  Probably this should
2720 # have the same check as for liblockfile below.
2721 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2722 if test $have_mail = yes; then
2723   LIBS_MAIL=-lmail
2724   LIBS="$LIBS_MAIL $LIBS"
2725   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2726 else
2727   LIBS_MAIL=
2728 fi
2729 dnl Debian, at least:
2730 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2731 if test $have_lockfile = yes; then
2732    LIBS_MAIL=-llockfile
2733    LIBS="$LIBS_MAIL $LIBS"
2734    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2735 else
2736 # If we have the shared liblockfile, assume we must use it for mail
2737 # locking (e.g. Debian).  If we couldn't link against liblockfile
2738 # (no liblockfile.a installed), ensure that we don't need to.
2739   dnl This works for files generally, not just executables.
2740   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2741   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2742                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2743   if test $ac_cv_prog_liblockfile = yes; then
2744     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2745 This probably means that movemail could lose mail.
2746 There may be a `development' package to install containing liblockfile.])
2747   fi
2748 fi
2749 AC_CHECK_FUNCS(touchlock)
2750 AC_CHECK_HEADERS(maillock.h)
2751 AC_SUBST(LIBS_MAIL)
2752
2753 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2754 ## interlock access to the mail spool.  The alternative is a lock file named
2755 ## /usr/spool/mail/$USER.lock.
2756 mail_lock=no
2757 case "$opsys" in
2758   aix4-2) mail_lock="lockf" ;;
2759
2760   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2761
2762   ## On GNU/Linux systems, both methods are used by various mail programs.
2763   ## I assume most people are using newer mailers that have heard of flock.
2764   ## Change this if you need to.
2765   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2766   ## configure gets the right answers, and that means *NOT* using flock.
2767   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2768   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2769   ## Debian maintainer hasn't provided a clean fix for Emacs.
2770   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2771   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2772   ## correct logic.  -- fx
2773   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2774   ## liblockfile is a Free Software replacement for libmail, used on
2775   ## Debian systems and elsewhere. -rfr.
2776   gnu-*)
2777     mail_lock="flock"
2778     if test $have_mail = yes || test $have_lockfile = yes; then
2779       test $ac_cv_header_maillock_h = yes && mail_lock=no
2780     fi
2781     ;;
2782 esac
2783
2784 BLESSMAIL_TARGET=
2785 case "$mail_lock" in
2786   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2787
2788   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2789
2790   *) BLESSMAIL_TARGET="need-blessmail" ;;
2791 esac
2792 AC_SUBST(BLESSMAIL_TARGET)
2793
2794
2795 AC_CHECK_FUNCS(gethostname getdomainname \
2796 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2797 random lrand48 logb frexp fmod rint cbrt ftime setsid \
2798 strerror fpathconf select euidaccess getpagesize tzset setlocale \
2799 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2800 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm \
2801 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2802 gai_strerror mkstemp getline getdelim mremap fsync sync \
2803 difftime mempcpy mblen mbrlen posix_memalign \
2804 cfmakeraw cfsetspeed copysign __executable_start)
2805
2806 dnl Cannot use AC_CHECK_FUNCS
2807 AC_CACHE_CHECK([for __builtin_unwind_init],
2808                emacs_cv_func___builtin_unwind_init,
2809 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2810                 emacs_cv_func___builtin_unwind_init=yes,
2811                 emacs_cv_func___builtin_unwind_init=no)])
2812 if test $emacs_cv_func___builtin_unwind_init = yes; then
2813   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2814             [Define to 1 if you have the `__builtin_unwind_init' function.])
2815 fi
2816
2817 AC_CHECK_HEADERS(sys/un.h)
2818
2819 AC_FUNC_FSEEKO
2820
2821 AC_FUNC_GETPGRP
2822
2823 # UNIX98 PTYs.
2824 AC_CHECK_FUNCS(grantpt)
2825
2826 # PTY-related GNU extensions.
2827 AC_CHECK_FUNCS(getpt)
2828
2829 # Check this now, so that we will NOT find the above functions in ncurses.
2830 # That is because we have not set up to link ncurses in lib-src.
2831 # It's better to believe a function is not available
2832 # than to expect to find it in ncurses.
2833 # Also we need tputs and friends to be able to build at all.
2834 AC_MSG_CHECKING([for library containing tputs])
2835 # Run a test program that contains a call to tputs, a call that is
2836 # never executed.  This tests whether a pre-'main' dynamic linker
2837 # works with the library.  It's too much trouble to actually call
2838 # tputs in the test program, due to portability hassles.  When
2839 # cross-compiling, assume the test program will run if it links.
2840 AC_DEFUN([tputs_link_source], [
2841   AC_LANG_SOURCE(
2842      [[extern void tputs (const char *, int, int (*)(int));
2843        int main (int argc, char **argv)
2844        {
2845           if (argc == 10000)
2846             tputs (argv[0], 0, 0);
2847           return 0;
2848        }]])
2849 ])
2850 # Maybe curses should be tried earlier?
2851 # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
2852 for tputs_library in '' ncurses terminfo termcap curses; do
2853   OLIBS=$LIBS
2854   if test -z "$tputs_library"; then
2855     LIBS_TERMCAP=
2856     msg='none required'
2857   else
2858     LIBS_TERMCAP=-l$tputs_library
2859     msg=$LIBS_TERMCAP
2860     LIBS="$LIBS_TERMCAP $LIBS"
2861   fi
2862   AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
2863     [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
2864   LIBS=$OLIBS
2865   if test "X$msg" != Xno; then
2866     break
2867   fi
2868 done
2869 AC_MSG_RESULT([$msg])
2870 if test "X$msg" = Xno; then
2871   AC_MSG_ERROR([The required function `tputs' was not found in any library.
2872 These libraries were tried: libncurses, libterminfo, libtermcap, libcurses.
2873 Please try installing whichever of these libraries is most appropriate
2874 for your system, together with its header files.
2875 For example, a libncurses-dev(el) or similar package.])
2876 fi
2877 # Must define this when any termcap library is found.
2878 AC_DEFINE(HAVE_LIBNCURSES, 1,
2879           [Define to 1 if you have the `ncurses' library (-lncurses).])
2880 ## FIXME This was the cpp logic, but I am not sure it is right.
2881 ## The above test has not necessarily found libncurses.
2882 HAVE_LIBNCURSES=yes
2883
2884 ## Use terminfo instead of termcap?
2885 ## Note only system files NOT using terminfo are:
2886 ## freebsd < 40000, ms-w32, msdos, netbsd < 599002500, and
2887 ## darwin|gnu without ncurses.
2888 TERMINFO=no
2889 case "$opsys" in
2890   ## cygwin: Fewer environment variables to go wrong, more terminal types.
2891   ## hpux10-20: Use the system provided termcap(3) library.
2892   ## openbsd: David Mazieres <dm@reeducation-labor.lcs.mit.edu> says this
2893   ##  is necessary.  Otherwise Emacs dumps core when run -nw.
2894   aix4-2|cygwin|hpux*|irix6-5|openbsd|sol2*|unixware) TERMINFO=yes ;;
2895
2896   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2897   ##  The ncurses library has been moved out of the System framework in
2898   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2899   ##  option to use it.
2900   darwin|gnu*)
2901     ## (HAVE_LIBNCURSES was not always true, but is since 2010-03-18.)
2902     if test "x$HAVE_LIBNCURSES" = "xyes"; then
2903       TERMINFO=yes
2904       LIBS_TERMCAP="-lncurses"
2905     fi
2906     ;;
2907
2908   freebsd)
2909     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2910     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2911     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
2912 [[#if __FreeBSD_version < 400000
2913 fail;
2914 #endif
2915 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2916
2917     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2918
2919     if test $emacs_cv_freebsd_terminfo = yes; then
2920       TERMINFO=yes
2921       LIBS_TERMCAP="-lncurses"
2922     else
2923       LIBS_TERMCAP="-ltermcap"
2924     fi
2925     ;;
2926
2927   netbsd)
2928     if test $ac_cv_search_tputs = -lterminfo; then
2929       TERMINFO=yes
2930       LIBS_TERMCAP="-lterminfo"
2931     else
2932       LIBS_TERMCAP="-ltermcap"
2933     fi
2934     ;;
2935
2936 esac
2937
2938 case "$opsys" in
2939   ## hpux: Make sure we get select from libc rather than from libcurses
2940   ##  because libcurses on HPUX 10.10 has a broken version of select.
2941   ##  We used to use -lc -lcurses, but this may be cleaner.
2942   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2943
2944   openbsd) LIBS_TERMCAP="-lncurses" ;;
2945
2946   ## Must use system termcap, if we use any termcap.  It does special things.
2947   sol2*) test "$TERMINFO" != yes && LIBS_TERMCAP="-ltermcap" ;;
2948 esac
2949
2950 TERMCAP_OBJ=tparam.o
2951 if test $TERMINFO = yes; then
2952   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2953   TERMCAP_OBJ=terminfo.o
2954 fi
2955 AC_SUBST(LIBS_TERMCAP)
2956 AC_SUBST(TERMCAP_OBJ)
2957
2958
2959 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2960 resolv=no
2961 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2962 #include <arpa/nameser.h>
2963 #include <resolv.h>]],
2964     [[return res_init();]])],
2965     have_res_init=yes, have_res_init=no)
2966 if test "$have_res_init" = no; then
2967   OLIBS="$LIBS"
2968   LIBS="$LIBS -lresolv"
2969   AC_MSG_CHECKING(for res_init with -lresolv)
2970   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2971 #include <arpa/nameser.h>
2972 #include <resolv.h>]],
2973     [[return res_init();]])],
2974     have_res_init=yes, have_res_init=no)
2975   AC_MSG_RESULT($have_res_init)
2976   if test "$have_res_init" = yes ; then
2977     resolv=yes
2978   fi
2979   LIBS="$OLIBS"
2980 fi
2981
2982 if test "$have_res_init" = yes; then
2983   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2984 fi
2985
2986 # Do we need the Hesiod library to provide the support routines?
2987 LIBHESIOD=
2988 if test "$with_hesiod" != no ; then
2989   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2990   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2991      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2992                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2993   if test "$resolv" = yes ; then
2994     RESOLVLIB=-lresolv
2995   else
2996     RESOLVLIB=
2997   fi
2998   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2999         hesiod=yes, :, $RESOLVLIB)])
3000
3001   if test x"$hesiod" = xyes; then
3002     AC_DEFINE(HAVE_LIBHESIOD, 1,
3003               [Define to 1 if you have the hesiod library (-lhesiod).])
3004     LIBHESIOD=-lhesiod
3005   fi
3006 fi
3007 AC_SUBST(LIBHESIOD)
3008
3009 # Do we need libresolv (due to res_init or Hesiod)?
3010 if test "$resolv" = yes ; then
3011   AC_DEFINE(HAVE_LIBRESOLV, 1,
3012             [Define to 1 if you have the resolv library (-lresolv).])
3013   LIBRESOLV=-lresolv
3014 else
3015   LIBRESOLV=
3016 fi
3017 AC_SUBST(LIBRESOLV)
3018
3019 # These tell us which Kerberos-related libraries to use.
3020 COM_ERRLIB=
3021 CRYPTOLIB=
3022 KRB5LIB=
3023 DESLIB=
3024 KRB4LIB=
3025
3026 if test "${with_kerberos}" != no; then
3027   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
3028   if test $have_com_err = yes; then
3029     COM_ERRLIB=-lcom_err
3030     LIBS="$COM_ERRLIB $LIBS"
3031     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
3032   fi
3033   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
3034   if test $have_crypto = yes; then
3035     CRYPTOLIB=-lcrypto
3036     LIBS="$CRYPTOLIB $LIBS"
3037     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
3038   fi
3039   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
3040   if test $have_k5crypto = yes; then
3041     CRYPTOLIB=-lk5crypto
3042     LIBS="$CRYPTOLIB $LIBS"
3043     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
3044   fi
3045   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
3046   if test $have_krb5=yes; then
3047     KRB5LIB=-lkrb5
3048     LIBS="$KRB5LIB $LIBS"
3049     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
3050   fi
3051   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
3052   if test "${with_kerberos5}" = no; then
3053     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
3054     if test $have_des425 = yes; then
3055       DESLIB=-ldes425
3056       LIBS="$DESLIB $LIBS"
3057       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
3058     else
3059       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
3060       if test $have_des = yes; then
3061         DESLIB=-ldes
3062         LIBS="$DESLIB $LIBS"
3063         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
3064       fi
3065     fi
3066     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
3067     if test $have_krb4 = yes; then
3068       KRB4LIB=-lkrb4
3069       LIBS="$KRB4LIB $LIBS"
3070       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
3071     else
3072       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
3073       if test $have_krb = yes; then
3074         KRB4LIB=-lkrb
3075         LIBS="$KRB4LIB $LIBS"
3076         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
3077       fi
3078     fi
3079   fi
3080
3081   if test "${with_kerberos5}" != no; then
3082     AC_CHECK_HEADERS(krb5.h,
3083       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
3084                         [#include <krb5.h>])])
3085   else
3086     AC_CHECK_HEADERS(des.h,,
3087                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
3088                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
3089     AC_CHECK_HEADERS(krb.h,,
3090                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
3091                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
3092   fi
3093   AC_CHECK_HEADERS(com_err.h)
3094 fi
3095
3096 AC_SUBST(COM_ERRLIB)
3097 AC_SUBST(CRYPTOLIB)
3098 AC_SUBST(KRB5LIB)
3099 AC_SUBST(DESLIB)
3100 AC_SUBST(KRB4LIB)
3101
3102 AC_MSG_CHECKING(whether localtime caches TZ)
3103 AC_CACHE_VAL(emacs_cv_localtime_cache,
3104 [if test x$ac_cv_func_tzset = xyes; then
3105 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
3106 char TZ_GMT0[] = "TZ=GMT0";
3107 char TZ_PST8[] = "TZ=PST8";
3108 main()
3109 {
3110   time_t now = time ((time_t *) 0);
3111   int hour_GMT0, hour_unset;
3112   if (putenv (TZ_GMT0) != 0)
3113     exit (1);
3114   hour_GMT0 = localtime (&now)->tm_hour;
3115   unsetenv("TZ");
3116   hour_unset = localtime (&now)->tm_hour;
3117   if (putenv (TZ_PST8) != 0)
3118     exit (1);
3119   if (localtime (&now)->tm_hour == hour_GMT0)
3120     exit (1);
3121   unsetenv("TZ");
3122   if (localtime (&now)->tm_hour != hour_unset)
3123     exit (1);
3124   exit (0);
3125 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3126 [# If we have tzset, assume the worst when cross-compiling.
3127 emacs_cv_localtime_cache=yes])
3128 else
3129         # If we lack tzset, report that localtime does not cache TZ,
3130         # since we can't invalidate the cache if we don't have tzset.
3131         emacs_cv_localtime_cache=no
3132 fi])dnl
3133 AC_MSG_RESULT($emacs_cv_localtime_cache)
3134 if test $emacs_cv_localtime_cache = yes; then
3135   AC_DEFINE(LOCALTIME_CACHE, 1,
3136             [Define to 1 if localtime caches TZ.])
3137 fi
3138
3139 if test "x$HAVE_TIMEVAL" = xyes; then
3140   AC_CHECK_FUNCS(gettimeofday)
3141   if test $ac_cv_func_gettimeofday = yes; then
3142     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
3143                    emacs_cv_gettimeofday_two_arguments,
3144     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3145 #ifdef TIME_WITH_SYS_TIME
3146 #include <sys/time.h>
3147 #include <time.h>
3148 #else
3149 #ifdef HAVE_SYS_TIME_H
3150 #include <sys/time.h>
3151 #else
3152 #include <time.h>
3153 #endif
3154 #endif]],
3155       [[struct timeval time;
3156        gettimeofday (&time, 0);]])],
3157       emacs_cv_gettimeofday_two_arguments=yes,
3158       emacs_cv_gettimeofday_two_arguments=no)])
3159     if test $emacs_cv_gettimeofday_two_arguments = no; then
3160       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
3161                 [Define to 1 if gettimeofday accepts only one argument.])
3162     fi
3163   fi
3164 fi
3165
3166 ok_so_far=yes
3167 AC_CHECK_FUNC(socket, , ok_so_far=no)
3168 if test $ok_so_far = yes; then
3169   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3170 fi
3171 if test $ok_so_far = yes; then
3172   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3173 fi
3174 if test $ok_so_far = yes; then
3175 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3176   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3177             [Define to 1 if you have inet sockets.])
3178 fi
3179
3180 if test -f /usr/lpp/X11/bin/smt.exp; then
3181   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3182             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3183 fi
3184
3185 AC_MSG_CHECKING(whether system supports dynamic ptys)
3186 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3187   AC_MSG_RESULT(yes)
3188   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3189 else
3190   AC_MSG_RESULT(no)
3191 fi
3192
3193 AC_FUNC_FORK
3194
3195 AC_CHECK_FUNCS(snprintf)
3196
3197 dnl Adapted from Haible's version.
3198 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3199   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3200     [[char* cs = nl_langinfo(CODESET);]])],
3201     emacs_cv_langinfo_codeset=yes,
3202     emacs_cv_langinfo_codeset=no)
3203   ])
3204 if test $emacs_cv_langinfo_codeset = yes; then
3205   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3206     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3207 fi
3208
3209 AC_TYPE_MBSTATE_T
3210
3211 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3212   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3213                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3214 if test "$emacs_cv_c_restrict_arr" = yes; then
3215   AC_DEFINE(__restrict_arr, __restrict,
3216     [Define to compiler's equivalent of C99 restrict keyword in array
3217      declarations.  Define as empty for no equivalent.])
3218 fi
3219
3220 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3221 dnl how the tty code is related to POSIX and/or other versions of termios.
3222 dnl The following looks like a useful start.
3223 dnl
3224 dnl AC_SYS_POSIX_TERMIOS
3225 dnl if test $ac_cv_sys_posix_termios = yes; then
3226 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3227 dnl                                and macros for terminal control.])
3228 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3229 dnl fi
3230
3231 # Set up the CFLAGS for real compilation, so we can substitute it.
3232 CFLAGS="$REAL_CFLAGS"
3233 CPPFLAGS="$REAL_CPPFLAGS"
3234
3235 ## Hack to detect a buggy GCC version.
3236 if test "x$GCC" = xyes \
3237    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3238    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3239    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3240    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3241 fi
3242
3243 version=$PACKAGE_VERSION
3244
3245 ### Specify what sort of things we'll be editing into Makefile and config.h.
3246 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3247 AC_SUBST(version)
3248 AC_SUBST(configuration)
3249 ## Unused?
3250 AC_SUBST(canonical)
3251 AC_SUBST(srcdir)
3252 AC_SUBST(prefix)
3253 AC_SUBST(exec_prefix)
3254 AC_SUBST(bindir)
3255 AC_SUBST(datadir)
3256 AC_SUBST(sharedstatedir)
3257 AC_SUBST(libexecdir)
3258 AC_SUBST(mandir)
3259 AC_SUBST(infodir)
3260 AC_SUBST(lispdir)
3261 AC_SUBST(locallisppath)
3262 AC_SUBST(lisppath)
3263 AC_SUBST(x_default_search_path)
3264 AC_SUBST(etcdir)
3265 AC_SUBST(archlibdir)
3266 AC_SUBST(docdir)
3267 AC_SUBST(bitmapdir)
3268 AC_SUBST(gamedir)
3269 AC_SUBST(gameuser)
3270 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3271 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3272 ## end of LIBX_BASE, but nothing ever set it.
3273 AC_SUBST(LD_SWITCH_X_SITE)
3274 AC_SUBST(C_SWITCH_X_SITE)
3275 AC_SUBST(C_SWITCH_X_SYSTEM)
3276 AC_SUBST(CFLAGS)
3277 ## Used in lwlib/Makefile.in.
3278 AC_SUBST(X_TOOLKIT_TYPE)
3279 if test -n "${machfile}"; then
3280   M_FILE="\$(srcdir)/${machfile}"
3281 else
3282   M_FILE=
3283 fi
3284 S_FILE="\$(srcdir)/${opsysfile}"
3285 AC_SUBST(M_FILE)
3286 AC_SUBST(S_FILE)
3287 AC_SUBST(ns_appdir)
3288 AC_SUBST(ns_appbindir)
3289 AC_SUBST(ns_appresdir)
3290 AC_SUBST(ns_appsrc)
3291 AC_SUBST(GNU_OBJC_CFLAGS)
3292 AC_SUBST(OTHER_FILES)
3293
3294 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3295                    [Define to the canonical Emacs configuration name.])
3296 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3297                    [Define to the options passed to configure.])
3298 if test -n "$machfile"; then
3299   AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3300                      [Define to the used machine dependent file.])
3301 fi
3302 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3303                    [Define to the used os dependent file.])
3304
3305 XMENU_OBJ=
3306 XOBJ=
3307 FONT_OBJ=
3308 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3309   AC_DEFINE(HAVE_X_WINDOWS, 1,
3310             [Define to 1 if you want to use the X window system.])
3311   XMENU_OBJ=xmenu.o
3312   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3313   FONT_OBJ=xfont.o
3314   if test "$HAVE_XFT" = "yes"; then
3315     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3316   elif test "$HAVE_FREETYPE" = "yes"; then
3317     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3318   fi
3319   AC_SUBST(FONT_OBJ)
3320 fi
3321 AC_SUBST(XMENU_OBJ)
3322 AC_SUBST(XOBJ)
3323 AC_SUBST(FONT_OBJ)
3324
3325 WIDGET_OBJ=
3326 MOTIF_LIBW=
3327 if test "${USE_X_TOOLKIT}" != "none" ; then
3328   WIDGET_OBJ=widget.o
3329   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3330   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3331     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3332   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3333     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3334     MOTIF_LIBW=-lXm
3335     case "$opsys" in
3336       gnu-linux)
3337         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3338         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3339         ;;
3340
3341       unixware)
3342         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3343         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3344         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3345         ;;
3346
3347       aix4-2)
3348         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3349         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3350         ;;
3351     esac
3352     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3353   fi
3354 fi
3355 AC_SUBST(WIDGET_OBJ)
3356
3357 TOOLKIT_LIBW=
3358 case "$USE_X_TOOLKIT" in
3359   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3360   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3361   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS -lXcomposite" ;;
3362 esac
3363 AC_SUBST(TOOLKIT_LIBW)
3364
3365 if test "$USE_X_TOOLKIT" = "none"; then
3366   LIBXT_OTHER="\$(LIBXSM)"
3367   OLDXMENU_TARGET="really-oldXMenu"
3368 else
3369   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3370   OLDXMENU_TARGET="really-lwlib"
3371 fi
3372 AC_SUBST(LIBXT_OTHER)
3373
3374 ## The X Menu stuff is present in the X10 distribution, but missing
3375 ## from X11.  If we have X10, just use the installed library;
3376 ## otherwise, use our own copy.
3377 if test "${HAVE_X11}" = "yes" ; then
3378   AC_DEFINE(HAVE_X11, 1,
3379             [Define to 1 if you want to use version 11 of X windows.
3380              Otherwise, Emacs expects to use version 10.])
3381
3382   if test "$USE_X_TOOLKIT" = "none"; then
3383     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
3384   else
3385     OLDXMENU="\${lwlibdir}/liblw.a"
3386   fi
3387   LIBXMENU="\$(OLDXMENU)"
3388   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3389   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3390 else
3391   ## For a syntactically valid Makefile; not actually used for anything.
3392   ## See comments in src/Makefile.in.
3393   OLDXMENU=nothing
3394   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3395   if test "${HAVE_X_WINDOWS}" = "yes"; then
3396     LIBXMENU="-lXMenu"
3397   else
3398     LIBXMENU=
3399   fi
3400   LIBX_OTHER=
3401   OLDXMENU_DEPS=
3402 fi
3403
3404 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3405   OLDXMENU_TARGET=
3406   OLDXMENU=nothing
3407   LIBXMENU=
3408   OLDXMENU_DEPS=
3409 fi
3410
3411 AC_SUBST(OLDXMENU_TARGET)
3412 AC_SUBST(OLDXMENU)
3413 AC_SUBST(LIBXMENU)
3414 AC_SUBST(LIBX_OTHER)
3415 AC_SUBST(OLDXMENU_DEPS)
3416
3417 if test "${HAVE_MENUS}" = "yes" ; then
3418   AC_DEFINE(HAVE_MENUS, 1,
3419             [Define to 1 if you have mouse menus.
3420              (This is automatic if you use X, but the option to specify it remains.)
3421              It is also defined with other window systems that support xmenu.c.])
3422 fi
3423
3424 if test "${GNU_MALLOC}" = "yes" ; then
3425   AC_DEFINE(GNU_MALLOC, 1,
3426             [Define to 1 if you want to use the GNU memory allocator.])
3427 fi
3428
3429 RALLOC_OBJ=
3430 if test "${REL_ALLOC}" = "yes" ; then
3431   AC_DEFINE(REL_ALLOC, 1,
3432             [Define REL_ALLOC if you want to use the relocating allocator for
3433              buffer space.])
3434
3435   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3436 fi
3437 AC_SUBST(RALLOC_OBJ)
3438
3439 if test "$opsys" = "cygwin"; then
3440   CYGWIN_OBJ="sheap.o"
3441   ## Cygwin differs because of its unexec().
3442   PRE_ALLOC_OBJ=
3443   POST_ALLOC_OBJ=lastfile.o
3444 else
3445   CYGWIN_OBJ=
3446   PRE_ALLOC_OBJ=lastfile.o
3447   POST_ALLOC_OBJ=
3448 fi
3449 AC_SUBST(CYGWIN_OBJ)
3450 AC_SUBST(PRE_ALLOC_OBJ)
3451 AC_SUBST(POST_ALLOC_OBJ)
3452
3453 # Configure gnulib here, now that we know LIBS.
3454 gl_ASSERT_NO_GNULIB_POSIXCHECK
3455 gl_ASSERT_NO_GNULIB_TESTS
3456 gl_INIT
3457
3458 case "$opsys" in
3459   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3460
3461   darwin)
3462    ## The -headerpad option tells ld (see man page) to leave room at the
3463    ## end of the header for adding load commands.  Needed for dumping.
3464    ## 0x690 is the total size of 30 segment load commands (at 56
3465    ## each); under Cocoa 31 commands are required.
3466    if test "$HAVE_NS" = "yes"; then
3467      libs_nsgui="-framework AppKit"
3468      headerpad_extra=6C8
3469    else
3470      libs_nsgui=
3471      headerpad_extra=690
3472    fi
3473    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3474
3475    ## This is here because src/Makefile.in did some extra fiddling around
3476    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3477    ##   #ifndef LD_SWITCH_SYSTEM
3478    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3479    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3480    ## not using gcc, darwin system not on an alpha (ie darwin, since
3481    ## darwin + alpha does not occur).
3482    ## Because this was done in src/Makefile.in, the resulting part of
3483    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3484    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3485    ## rather than LD_SWITCH_SYSTEM.
3486    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3487      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3488    ;;
3489
3490   ## LD_SWITCH_X_SITE_AUX is a -R option saying where to find X at run-time.
3491   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at
3492   ## the point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_AUX
3493   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3494   ## had different values in configure (in ac_link) and src/Makefile.in.
3495   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3496   gnu-linux) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_AUX)" ;;
3497
3498   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3499 esac
3500
3501 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3502   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3503 fi
3504
3505 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3506
3507
3508 LD_FIRSTFLAG=
3509 ORDINARY_LINK=
3510 case "$opsys" in
3511   ## gnu: GNU needs its own crt0.
3512   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3513
3514   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3515   ## library search parth, i.e. it won't search /usr/lib for libc and
3516   ## friends.  Using -nostartfiles instead avoids this problem, and
3517   ## will also work on earlier NetBSD releases.
3518   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
3519
3520   ## macpcc: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3521   ##   MkLinux/LinuxPPC needs this.
3522   ## ibms390x only supports opsys = gnu-linux so it can be added here.
3523   gnu-*)
3524     case "$machine" in
3525       macppc|ibms390x) LD_FIRSTFLAG="-nostdlib" ;;
3526     esac
3527     ;;
3528 esac
3529
3530
3531 if test "x$ORDINARY_LINK" = "xyes"; then
3532
3533   LD_FIRSTFLAG=""
3534   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3535
3536 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
3537 ## freebsd, gnu-* not on macppc|ibms390x.
3538 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
3539
3540   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3541   ## places that are difficult to figure out at make time.  Fortunately,
3542   ## these same versions allow you to pass arbitrary flags on to the
3543   ## linker, so there is no reason not to use it as a linker.
3544   ##
3545   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3546   ## searching for libraries in its internal directories, so we have to
3547   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3548   LD_FIRSTFLAG="-nostdlib"
3549 fi
3550
3551 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3552 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
3553
3554 AC_SUBST(LD_FIRSTFLAG)
3555
3556
3557 ## FIXME? The logic here is not precisely the same as that above.
3558 ## There is no check here for a pre-defined LD_FIRSTFLAG.
3559 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3560 LIB_GCC=
3561 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3562
3563   case "$opsys" in
3564     freebsd|netbsd|openbsd) LIB_GCC= ;;
3565
3566     gnu-*)
3567       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3568       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3569       case $host_cpu in
3570       arm*)
3571         LIB_GCC="-lgcc_s"
3572         ;;
3573       *)
3574         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3575         ## immediately undefine it again and redefine it to empty.
3576         ## Was the C_SWITCH_X_SITE part really necessary?
3577 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3578         LIB_GCC=
3579         ;;
3580       esac
3581       ;;
3582
3583     ## Ask GCC where to find libgcc.a.
3584     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3585   esac
3586 fi                              dnl if $GCC
3587 AC_SUBST(LIB_GCC)
3588
3589
3590 ## If we're using X11/GNUstep, define some consequences.
3591 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3592   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3593   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3594 fi
3595
3596
3597 AH_TOP([/* GNU Emacs site configuration template file.
3598
3599 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2012
3600   Free Software Foundation, Inc.
3601
3602 This file is part of GNU Emacs.
3603
3604 GNU Emacs is free software: you can redistribute it and/or modify
3605 it under the terms of the GNU General Public License as published by
3606 the Free Software Foundation, either version 3 of the License, or
3607 (at your option) any later version.
3608
3609 GNU Emacs is distributed in the hope that it will be useful,
3610 but WITHOUT ANY WARRANTY; without even the implied warranty of
3611 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3612 GNU General Public License for more details.
3613
3614 You should have received a copy of the GNU General Public License
3615 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3616
3617
3618 /* No code in Emacs #includes config.h twice, but some bits of code
3619    intended to work with other packages as well (like gmalloc.c)
3620    think they can include it as many times as they like.  */
3621 #ifndef EMACS_CONFIG_H
3622 #define EMACS_CONFIG_H
3623 ])dnl
3624
3625 AH_BOTTOM([
3626 /* On AIX 3 this must be included before any other include file.  */
3627 #include <alloca.h>
3628 #if ! HAVE_ALLOCA
3629 # error "alloca not available on this machine"
3630 #endif
3631
3632 /* Define AMPERSAND_FULL_NAME if you use the convention
3633    that & in the full name stands for the login id.  */
3634 /* Turned on June 1996 supposing nobody will mind it.  */
3635 #define AMPERSAND_FULL_NAME
3636
3637 /* `subprocesses' should be defined if you want to
3638    have code for asynchronous subprocesses
3639    (as used in M-x compile and M-x shell).
3640    Only MSDOS does not support this (it overrides
3641    this in its config_opsysfile below).  */
3642
3643 #define subprocesses
3644
3645 /* Include the os and machine dependent files.  */
3646 #include config_opsysfile
3647 #ifdef config_machfile
3648 # include config_machfile
3649 #endif
3650
3651 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3652    SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.
3653   (There is probably a better place to do this, but right now the
3654    Cocoa side does this in s/darwin.h and we cannot parallel this
3655    exactly since GNUstep is multi-OS.  */
3656 #if defined HAVE_NS && defined NS_IMPL_GNUSTEP
3657 #  define SYSTEM_PURESIZE_EXTRA 30000
3658 #endif
3659
3660 #ifdef emacs /* Don't do this for lib-src.  */
3661 /* Tell regex.c to use a type compatible with Emacs.  */
3662 #define RE_TRANSLATE_TYPE Lisp_Object
3663 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3664 #ifdef make_number
3665 /* If make_number is a macro, use it.  */
3666 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3667 #else
3668 /* If make_number is a function, avoid it.  */
3669 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3670 #endif
3671 #endif
3672
3673 /* These default definitions are good for almost all machines.
3674    Any exceptions should override them in m/MACHINE.h.
3675    They must be usable in preprocessor conditionals.  */
3676
3677 #ifndef BITS_PER_CHAR
3678 #define BITS_PER_CHAR 8
3679 #endif
3680
3681 #ifndef BITS_PER_SHORT
3682 #define BITS_PER_SHORT 16
3683 #endif
3684
3685 #ifndef BITS_PER_INT
3686 #define BITS_PER_INT 32
3687 #endif
3688
3689 #ifndef BITS_PER_LONG
3690 #ifdef _LP64
3691 #define BITS_PER_LONG 64
3692 #else
3693 #define BITS_PER_LONG 32
3694 #endif
3695 #endif
3696
3697 #if !defined BITS_PER_LONG_LONG && HAVE_LONG_LONG_INT
3698 #define BITS_PER_LONG_LONG 64
3699 #endif
3700
3701 /* Define if the compiler supports function prototypes.  It may do so but
3702    not define __STDC__ (e.g. DEC C by default) or may define it as zero.  */
3703 #undef PROTOTYPES
3704
3705 #include <string.h>
3706 #include <stdlib.h>
3707
3708 #if defined __GNUC__ && (__GNUC__ > 2 \
3709                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3710 #define NO_RETURN       __attribute__ ((__noreturn__))
3711 #else
3712 #define NO_RETURN       /* nothing */
3713 #endif
3714
3715 #if __GNUC__ >= 3  /* On GCC 3.0 we might get a warning.  */
3716 #define NO_INLINE __attribute__((noinline))
3717 #else
3718 #define NO_INLINE
3719 #endif
3720
3721 #if (__GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 1))
3722 #define EXTERNALLY_VISIBLE __attribute__((externally_visible))
3723 #else
3724 #define EXTERNALLY_VISIBLE
3725 #endif
3726
3727 #if __GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 7)
3728 # define ATTRIBUTE_FORMAT(spec) __attribute__ ((__format__ spec))
3729 #else
3730 # define ATTRIBUTE_FORMAT(spec) /* empty */
3731 #endif
3732
3733 #if __GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 4)
3734 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3735    ATTRIBUTE_FORMAT ((__gnu_printf__, formatstring_parameter, first_argument))
3736 #else
3737 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3738    ATTRIBUTE_FORMAT ((__printf__, formatstring_parameter, first_argument))
3739 #endif
3740
3741 /* Some versions of GNU/Linux define noinline in their headers.  */
3742 #ifdef noinline
3743 #undef noinline
3744 #endif
3745
3746 /* These won't be used automatically yet.  We also need to know, at least,
3747    that the stack is continuous.  */
3748 #ifdef __GNUC__
3749 #  ifndef GC_SETJMP_WORKS
3750   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3751 #    define GC_SETJMP_WORKS 1
3752 #  endif
3753 #endif
3754
3755 #endif /* EMACS_CONFIG_H */
3756
3757 /*
3758 Local Variables:
3759 mode: c
3760 End:
3761 */
3762 ])dnl
3763
3764 #### Report on what we decided to do.
3765 #### Report GTK as a toolkit, even if it doesn't use Xt.
3766 #### It makes printing result more understandable as using GTK sets
3767 #### toolkit_scroll_bars to yes by default.
3768 if test "${HAVE_GTK}" = "yes"; then
3769   USE_X_TOOLKIT=GTK
3770 fi
3771
3772 and_machfile=
3773 if test -n "$machfile"; then
3774   and_machfile=" and \`${machfile}'"
3775 fi
3776
3777 echo "
3778 Configured for \`${canonical}'.
3779
3780   Where should the build process find the source code?    ${srcdir}
3781   What operating system and machine description files should Emacs use?
3782         \`${opsysfile}'${and_machfile}
3783   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3784   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3785   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3786   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3787   What window system should Emacs use?                    ${window_system}
3788   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3789
3790 if test -n "${x_includes}"; then
3791 echo "  Where do we find X Windows header files?                ${x_includes}"
3792 else
3793 echo "  Where do we find X Windows header files?                Standard dirs"
3794 fi
3795 if test -n "${x_libraries}"; then
3796 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3797 else
3798 echo "  Where do we find X Windows libraries?                   Standard dirs"
3799 fi
3800
3801 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3802 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3803 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3804 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3805 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3806 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3807 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3808 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
3809
3810 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3811 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3812 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3813 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
3814 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3815 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
3816 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
3817
3818 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3819 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3820 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3821 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3822
3823 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3824
3825 echo "  Does Emacs support Xwidgets?                            ${HAVE_XWIDGETS}"
3826 echo "       Does xwidgets support webkit(requires gtk3)?       ${HAVE_WEBKIT}"
3827 echo "       Does xwidgets support clutter(demo code)?          ${HAVE_CLUTTER}"
3828 echo "       Does xwidgets support goocanvas(demo code)?        ${HAVE_GOOCANVAS}"
3829 echo
3830
3831 if test -n "${EMACSDATA}"; then
3832    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
3833 fi
3834 if test -n "${EMACSDOC}"; then
3835    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
3836 fi
3837
3838 if test $USE_XASSERTS = yes; then
3839    echo "  Compiling with asserts turned on."
3840    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3841 fi
3842
3843 echo
3844
3845 if test "$HAVE_NS" = "yes"; then
3846    echo
3847    echo "You must run \"${MAKE-make} install\" in order to test the built application.
3848 The installed application will go to nextstep/Emacs.app and can be
3849 run or moved from there."
3850    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3851       echo "The application will be fully self-contained."
3852     else
3853       echo "The lisp resources for the application will be installed under ${prefix}.
3854 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
3855 to run if these resources are not installed."
3856    fi
3857    echo
3858 fi
3859
3860
3861 # Remove any trailing slashes in these variables.
3862 [test "${prefix}" != NONE &&
3863   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3864 test "${exec_prefix}" != NONE &&
3865   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3866
3867 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
3868 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
3869 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
3870 dnl (else you get "no `Makefile.am' found for any configure output").
3871 dnl This will work, but you get a config.status that is not quite right
3872 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
3873 dnl That doesn't have any obvious consequences for Emacs, but on the whole
3874 dnl it seems better to just live with the duplication.
3875 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile"
3876
3877 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
3878        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3879        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
3880        leim/Makefile])
3881
3882 dnl test/ is not present in release tarfiles.
3883 opt_makefile=test/automated/Makefile
3884
3885 if test -f $srcdir/${opt_makefile}.in; then
3886   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
3887   dnl Again, it's best not to use a variable.  Though you can add
3888   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
3889   AC_CONFIG_FILES([test/automated/Makefile])
3890 fi
3891
3892
3893 dnl admin/ may or may not be present.
3894 opt_makefile=admin/unidata/Makefile
3895
3896 if test -f $srcdir/${opt_makefile}.in; then
3897   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
3898   AC_CONFIG_FILES([admin/unidata/Makefile])
3899 fi
3900
3901
3902 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
3903
3904 AC_SUBST(SUBDIR_MAKEFILES_IN)
3905
3906 dnl Make the necessary directories, if they don't exist.
3907 AC_CONFIG_COMMANDS([mkdirs], [
3908 for dir in etc lisp ; do
3909   test -d ${dir} || mkdir ${dir}
3910 done
3911 ])
3912
3913 dnl You might wonder (I did) why epaths.h is generated by running make,
3914 dnl rather than just letting configure generate it from epaths.in.
3915 dnl One reason is that the various paths are not fully expanded (see above);
3916 dnl eg gamedir=${prefix}/var/games/emacs.
3917 dnl Secondly, the GNU Coding standards require that one should be able
3918 dnl to run `make prefix=/some/where/else' and override the values set
3919 dnl by configure.  This also explains the `move-if-change' test and
3920 dnl the use of force in the `epaths-force' rule in Makefile.in.
3921 AC_CONFIG_COMMANDS([epaths], [
3922 echo creating src/epaths.h
3923 ${MAKE-make} epaths-force
3924 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPPFLAGS="$CPPFLAGS"])
3925
3926 AC_CONFIG_COMMANDS([gdbinit], [
3927 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3928   echo creating src/.gdbinit
3929   echo source $srcdir/src/.gdbinit > src/.gdbinit
3930 fi
3931 ])
3932
3933 AC_OUTPUT
3934
3935 dnl configure.in ends here