code.delx.au - gnu-emacs/blob - lisp/window.el

   1 ;;; windows.el --- GNU Emacs window commands aside from those written in C.
   2
   3 ;;; Copyright (C) 1985, 1989, 1992 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  21 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  22
  23 ;;; Code:
  24
  25 (defun count-windows (&optional minibuf)
  26    "Returns the number of visible windows.
  27 Optional arg NO-MINI non-nil means don't count the minibuffer
  28 even if it is active."
  29    (let ((count 0))
  30      (walk-windows (function (lambda ()
  31                                (setq count (+ count 1))))
  32                    minibuf)
  33      count))
  34
  35 (defun balance-windows ()
  36   "Makes all visible windows the same size (approximately)."
  37   (interactive)
  38   (let ((count 0))
  39     (walk-windows (function (lambda (w)
  40                               (setq count (+ count 1))))
  41                   'nomini)
  42     (let ((size (/ (frame-height) count)))
  43       (walk-windows (function (lambda (w)
  44                                 (select-window w)
  45                                 (enlarge-window (- size (window-height)))))
  46                     'nomini))))
  47
  48 ;;; I think this should be the default; I think people will prefer it--rms.
  49
  50 (defvar split-window-keep-point t
  51   "*If non-nil, split windows so that both windows keep the original
  52 value of point.  This is often more convenient for editing.
  53 If nil, split windows to minimize redisplay.  This is convenient on
  54 slow terminals, but point may be moved strangely to accommodate the
  55 redisplay.")
  56
  57 (defun split-window-vertically (&optional arg)
  58   "Split current window into two windows, one above the other.
  59 The uppermost window gets ARG lines and the other gets the rest.
  60 With no argument, split equally or close to it.
  61 Both windows display the same buffer now current.
  62
  63 If the variable split-window-keep-point is non-nil, both new windows
  64 will get the same value of point as the current window.  This is often
  65 more convenient for editing.
  66
  67 Otherwise, we chose window starts so as to minimize the amount of
  68 redisplay; this is convenient on slow terminals.  The new selected
  69 window is the one that the current value of point appears in.  The
  70 value of point can change if the text around point is hidden by the
  71 new mode line."
  72   (interactive "P")
  73   (let ((old-w (selected-window))
  74         (old-point (point))
  75         new-w bottom switch)
  76     (setq new-w (split-window nil (and arg (prefix-numeric-value arg))))
  77     (or split-window-keep-point
  78         (progn
  79           (save-excursion
  80             (set-buffer (window-buffer))
  81             (goto-char (window-start))
  82             (vertical-motion (window-height))
  83             (set-window-start new-w (point))
  84             (if (> (point) (window-point new-w))
  85                 (set-window-point new-w (point)))
  86             (vertical-motion -1)
  87             (setq bottom (point)))
  88           (if (<= bottom (point))
  89               (set-window-point old-w (1- bottom)))
  90           (if (< (window-start new-w) old-point)
  91               (progn
  92                 (set-window-point new-w old-point)
  93                 (select-window new-w)))))
  94     new-w))
  95
  96 (defun split-window-horizontally (&optional arg)
  97   "Split current window into two windows side by side.
  98 This window becomes the leftmost of the two, and gets
  99 ARG columns.  No arg means split equally."
 100   (interactive "P")
 101   (split-window nil (and arg (prefix-numeric-value arg)) t))
 102
 103 (defun enlarge-window-horizontally (arg)
 104   "Make current window ARG columns wider."
 105   (interactive "p")
 106   (enlarge-window arg t))
 107
 108 (defun shrink-window-horizontally (arg)
 109   "Make current window ARG columns narrower."
 110   (interactive "p")
 111   (shrink-window arg t))
 112
 113 (defun shrink-window-if-larger-than-buffer (&optional window)
 114   "Shrink the WINDOW to be as small as possible to display its contents.  Do
 115 nothing if only one window is displayed or if the buffer contains more lines
 116 than the present window height."
 117   (save-excursion
 118     (set-buffer (window-buffer window))
 119     (let ((w (selected-window)) ;save-window-excursion can't win
 120           (buffer-file-name buffer-file-name)
 121           (p (point))
 122           (n 0)
 123           (window-min-height 0)
 124           (buffer-read-only nil)
 125           (modified (buffer-modified-p))
 126           (buffer (current-buffer)))
 127       (unwind-protect
 128           (progn
 129             (select-window (or window w))
 130             (goto-char (point-min))
 131             (while (pos-visible-in-window-p (point-max))
 132               ;; defeat file locking... don't try this at home, kids!
 133               (setq buffer-file-name nil)
 134               (insert ?\n) (setq n (1+ n)))
 135             (if (> n 0) (shrink-window (1- n))))
 136         (delete-region (point-min) (point))
 137         (set-buffer-modified-p modified)
 138         (goto-char p)
 139         (select-window w)
 140         ;; Make sure we unbind buffer-read-only
 141         ;; with the proper current buffer.
 142         (set-buffer buffer)))))
 143
 144 (define-key ctl-x-map "2" 'split-window-vertically)
 145 (define-key ctl-x-map "3" 'split-window-horizontally)
 146 (define-key ctl-x-map "}" 'enlarge-window-horizontally)
 147 (define-key ctl-x-map "{" 'shrink-window-horizontally)
 148 (define-key ctl-x-map "-" 'shrink-window-if-larger-than-buffer)
 149 (define-key ctl-x-map "+" 'balance-windows)
 150
 151 ;;; windows.el ends here