code.delx.au - gnu-emacs/blob - lisp/mh-e/mh-speed.el

   1 ;;; mh-speed.el --- Speedbar interface for MH-E.
   2
   3 ;; Copyright (C) 2002, 2003, 2004, 2005 Free Software Foundation, Inc.
   4
   5 ;; Author: Satyaki Das <satyaki@theforce.stanford.edu>
   6 ;; Maintainer: Bill Wohler <wohler@newt.com>
   7 ;; Keywords: mail
   8 ;; See: mh-e.el
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28 ;;   Future versions should only use flists.
  29
  30 ;; Speedbar support for MH-E package.
  31
  32 ;;; Change Log:
  33
  34 ;;; Code:
  35
  36 ;;(message "> mh-speed")
  37 (eval-when-compile (require 'mh-acros))
  38 (mh-require-cl)
  39 (require 'mh-e)
  40 (require 'speedbar)
  41 (require 'timer)
  42 ;;(message "< mh-speed")
  43
  44 ;; Global variables
  45 (defvar mh-speed-refresh-flag nil)
  46 (defvar mh-speed-last-selected-folder nil)
  47 (defvar mh-speed-folder-map (make-hash-table :test #'equal))
  48 (defvar mh-speed-flists-cache (make-hash-table :test #'equal))
  49 (defvar mh-speed-flists-process nil)
  50 (defvar mh-speed-flists-timer nil)
  51 (defvar mh-speed-partial-line "")
  52
  53 ;; Add our stealth update function
  54 (unless (member 'mh-speed-stealth-update
  55                 (cdr (assoc "files" speedbar-stealthy-function-list)))
  56   ;; Is changing constant lists in elisp safe?
  57   (setq speedbar-stealthy-function-list
  58         (copy-tree speedbar-stealthy-function-list))
  59   (push 'mh-speed-stealth-update
  60         (cdr (assoc "files" speedbar-stealthy-function-list))))
  61
  62 ;; Functions called by speedbar to initialize display...
  63 ;;;###mh-autoload
  64 (defun mh-folder-speedbar-buttons (buffer)
  65   "Interface function to create MH-E speedbar buffer.
  66 BUFFER is the MH-E buffer for which the speedbar buffer is to be
  67 created."
  68   (unless (get-text-property (point-min) 'mh-level)
  69     (erase-buffer)
  70     (clrhash mh-speed-folder-map)
  71     (speedbar-make-tag-line 'bracket ?+ 'mh-speed-toggle nil " " 'ignore nil
  72                             'mh-speedbar-folder 0)
  73     (forward-line -1)
  74     (setf (gethash nil mh-speed-folder-map)
  75           (set-marker (or (gethash nil mh-speed-folder-map) (make-marker))
  76                       (1+ (line-beginning-position))))
  77     (add-text-properties
  78      (line-beginning-position) (1+ (line-beginning-position))
  79      `(mh-folder nil mh-expanded nil mh-children-p t mh-level 0))
  80     (mh-speed-stealth-update t)
  81     (when (> mh-speed-update-interval 0)
  82       (mh-speed-flists nil))))
  83
  84 ;;;###mh-autoload
  85 (defalias 'mh-show-speedbar-buttons 'mh-folder-speedbar-buttons)
  86 ;;;###mh-autoload
  87 (defalias 'mh-letter-speedbar-buttons 'mh-folder-speedbar-buttons)
  88
  89 ;; Keymaps for speedbar...
  90 (defvar mh-folder-speedbar-key-map (speedbar-make-specialized-keymap)
  91   "Specialized speedbar keymap for MH-E buffers.")
  92 (gnus-define-keys mh-folder-speedbar-key-map
  93   "+"           mh-speed-expand-folder
  94   "-"           mh-speed-contract-folder
  95   "\r"          mh-speed-view
  96   "r"           mh-speed-refresh)
  97
  98 (defvar mh-show-speedbar-key-map mh-folder-speedbar-key-map)
  99 (defvar mh-letter-speedbar-key-map mh-folder-speedbar-key-map)
 100
 101 ;; Menus for speedbar...
 102 (defvar mh-folder-speedbar-menu-items
 103   '("--"
 104     ["Visit Folder" mh-speed-view
 105      (save-excursion
 106        (set-buffer speedbar-buffer)
 107        (get-text-property (line-beginning-position) 'mh-folder))]
 108     ["Expand Nested Folders" mh-speed-expand-folder
 109      (and (get-text-property (line-beginning-position) 'mh-children-p)
 110           (not (get-text-property (line-beginning-position) 'mh-expanded)))]
 111     ["Contract Nested Folders" mh-speed-contract-folder
 112      (and (get-text-property (line-beginning-position) 'mh-children-p)
 113           (get-text-property (line-beginning-position) 'mh-expanded))]
 114     ["Refresh Speedbar" mh-speed-refresh t])
 115   "Extra menu items for speedbar.")
 116
 117 (defvar mh-show-speedbar-menu-items mh-folder-speedbar-menu-items)
 118 (defvar mh-letter-speedbar-menu-items mh-folder-speedbar-menu-items)
 119
 120 (defmacro mh-speed-select-attached-frame ()
 121   "Compatibility macro to handle speedbar versions 0.11a and 0.14beta4."
 122   (cond ((fboundp 'dframe-select-attached-frame)
 123          '(dframe-select-attached-frame speedbar-frame))
 124         ((boundp 'speedbar-attached-frame)
 125          '(select-frame speedbar-attached-frame))
 126         (t (error "Installed speedbar version not supported by MH-E"))))
 127
 128 (defun mh-speed-update-current-folder (force)
 129   "Update speedbar highlighting of the current folder.
 130 The function tries to be smart so that work done is minimized.
 131 The currently highlighted folder is cached and no highlighting
 132 happens unless it changes.
 133 Also highlighting is suspended while the speedbar frame is selected.
 134 Otherwise you get the disconcerting behavior of folders popping open
 135 on their own when you are trying to navigate around in the speedbar
 136 buffer.
 137
 138 The update is always carried out if FORCE is non-nil."
 139   (let* ((lastf (selected-frame))
 140          (newcf (save-excursion
 141                   (mh-speed-select-attached-frame)
 142                   (prog1 (mh-speed-extract-folder-name (buffer-name))
 143                     (select-frame lastf))))
 144          (lastb (current-buffer))
 145          (case-fold-search t))
 146     (when (or force
 147               (and mh-speed-refresh-flag (not (eq lastf speedbar-frame)))
 148               (and (stringp newcf)
 149                    (equal (substring newcf 0 1) "+")
 150                    (not (equal newcf mh-speed-last-selected-folder))))
 151       (setq mh-speed-refresh-flag nil)
 152       (select-frame speedbar-frame)
 153       (set-buffer speedbar-buffer)
 154
 155       ;; Remove highlight from previous match...
 156       (mh-speed-highlight mh-speed-last-selected-folder 'mh-speedbar-folder)
 157
 158       ;; If we found a match highlight it...
 159       (when (mh-speed-goto-folder newcf)
 160         (mh-speed-highlight newcf 'mh-speedbar-selected-folder))
 161
 162       (setq mh-speed-last-selected-folder newcf)
 163       (speedbar-position-cursor-on-line)
 164       (set-window-point (frame-first-window speedbar-frame) (point))
 165       (set-buffer lastb)
 166       (select-frame lastf))
 167     (when (eq lastf speedbar-frame)
 168       (setq mh-speed-refresh-flag t))))
 169
 170 (defun mh-speed-normal-face (face)
 171   "Return normal face for given FACE."
 172   (cond ((eq face 'mh-speedbar-folder-with-unseen-messages)
 173          'mh-speedbar-folder)
 174         ((eq face 'mh-speedbar-selected-folder-with-unseen-messages)
 175          'mh-speedbar-selected-folder)
 176         (t face)))
 177
 178 (defun mh-speed-bold-face (face)
 179   "Return bold face for given FACE."
 180   (cond ((eq face 'mh-speedbar-folder)
 181          'mh-speedbar-folder-with-unseen-messages)
 182         ((eq face 'mh-speedbar-selected-folder)
 183          'mh-speedbar-selected-folder-with-unseen-messages)
 184         (t face)))
 185
 186 (defun mh-speed-highlight (folder face)
 187   "Set FOLDER to FACE."
 188   (save-excursion
 189     (speedbar-with-writable
 190       (goto-char (gethash folder mh-speed-folder-map (point)))
 191       (beginning-of-line)
 192       (if (re-search-forward "([1-9][0-9]*/[0-9]+)" (line-end-position) t)
 193           (setq face (mh-speed-bold-face face))
 194         (setq face (mh-speed-normal-face face)))
 195       (beginning-of-line)
 196       (when (re-search-forward "\\[.\\] " (line-end-position) t)
 197         (put-text-property (point) (line-end-position) 'face face)))))
 198
 199 (defun mh-speed-stealth-update (&optional force)
 200   "Do stealth update.
 201 With non-nil FORCE, the update is always carried out."
 202   (cond ((save-excursion (set-buffer speedbar-buffer)
 203                          (get-text-property (point-min) 'mh-level))
 204          ;; Execute this hook and *don't* run anything else
 205          (mh-speed-update-current-folder force)
 206          nil)
 207         ;; Otherwise on to your regular programming
 208         (t t)))
 209
 210 (defun mh-speed-goto-folder (folder)
 211   "Move point to line containing FOLDER.
 212 The function will expand out parent folders of FOLDER if needed."
 213   (let ((prefix folder)
 214         (suffix-list ())
 215         (last-slash t))
 216     (while (and (not (gethash prefix mh-speed-folder-map)) last-slash)
 217       (setq last-slash (mh-search-from-end ?/ prefix))
 218       (when (integerp last-slash)
 219         (push (substring prefix (1+ last-slash)) suffix-list)
 220         (setq prefix (substring prefix 0 last-slash))))
 221     (let ((prefix-position (gethash prefix mh-speed-folder-map)))
 222       (if prefix-position
 223           (goto-char prefix-position)
 224         (goto-char (point-min))
 225         (mh-speed-toggle)
 226         (unless (get-text-property (point) 'mh-expanded)
 227           (mh-speed-toggle))
 228         (goto-char (gethash prefix mh-speed-folder-map))))
 229     (while suffix-list
 230       ;; We always need atleast one toggle. We need two if the directory list
 231       ;; is stale since a folder was added.
 232       (when (equal prefix (get-text-property (line-beginning-position)
 233                                              'mh-folder))
 234         (mh-speed-toggle)
 235         (unless (get-text-property (point) 'mh-expanded)
 236           (mh-speed-toggle)))
 237       (setq prefix (format "%s/%s" prefix (pop suffix-list)))
 238       (goto-char (gethash prefix mh-speed-folder-map (point))))
 239     (beginning-of-line)
 240     (equal folder (get-text-property (point) 'mh-folder))))
 241
 242 (defun mh-speed-extract-folder-name (buffer)
 243   "Given an MH-E BUFFER find the folder that should be highlighted.
 244 Do the right thing for the different kinds of buffers that MH-E
 245 uses."
 246   (save-excursion
 247     (set-buffer buffer)
 248     (cond ((eq major-mode 'mh-folder-mode)
 249            mh-current-folder)
 250           ((eq major-mode 'mh-show-mode)
 251            (set-buffer mh-show-folder-buffer)
 252            mh-current-folder)
 253           ((eq major-mode 'mh-letter-mode)
 254            (when (string-match mh-user-path buffer-file-name)
 255              (let* ((rel-path (substring buffer-file-name (match-end 0)))
 256                     (directory-end (mh-search-from-end ?/ rel-path)))
 257                (when directory-end
 258                  (format "+%s" (substring rel-path 0 directory-end)))))))))
 259
 260 (defun mh-speed-add-buttons (folder level)
 261   "Add speedbar button for FOLDER which is at indented by LEVEL amount."
 262   (let ((folder-list (mh-sub-folders folder)))
 263     (mapc
 264      (lambda (f)
 265        (let* ((folder-name (format "%s%s%s" (or folder "+")
 266                                    (if folder "/" "") (car f)))
 267               (counts (gethash folder-name mh-speed-flists-cache)))
 268          (speedbar-with-writable
 269            (speedbar-make-tag-line
 270             'bracket (if (cdr f) ?+ ? )
 271             'mh-speed-toggle nil
 272             (format "%s%s"
 273                     (car f)
 274                     (if counts
 275                         (format " (%s/%s)" (car counts) (cdr counts))
 276                       ""))
 277             'mh-speed-view nil
 278             (if (and counts (> (car counts) 0))
 279                 'mh-speedbar-folder-with-unseen-messages
 280               'mh-speedbar-folder)
 281             level)
 282            (save-excursion
 283              (forward-line -1)
 284              (setf (gethash folder-name mh-speed-folder-map)
 285                    (set-marker (or (gethash folder-name mh-speed-folder-map)
 286                                    (make-marker))
 287                                (1+ (line-beginning-position))))
 288              (add-text-properties
 289               (line-beginning-position) (1+ (line-beginning-position))
 290               `(mh-folder ,folder-name
 291                           mh-expanded nil
 292                           mh-children-p ,(not (not (cdr f)))
 293                           ,@(if counts `(mh-count
 294                                          (,(car counts) . ,(cdr counts))) ())
 295                           mh-level ,level))))))
 296      folder-list)))
 297
 298 ;;;###mh-autoload
 299 (defun mh-speed-toggle (&rest args)
 300   "Toggle the display of child folders in the speedbar.
 301 The optional ARGS from speedbar are ignored."
 302   (interactive)
 303   (declare (ignore args))
 304   (beginning-of-line)
 305   (let ((parent (get-text-property (point) 'mh-folder))
 306         (kids-p (get-text-property (point) 'mh-children-p))
 307         (expanded (get-text-property (point) 'mh-expanded))
 308         (level (get-text-property (point) 'mh-level))
 309         (point (point))
 310         start-region)
 311     (speedbar-with-writable
 312       (cond ((not kids-p) nil)
 313             (expanded
 314              (forward-line)
 315              (setq start-region (point))
 316              (while (and (get-text-property (point) 'mh-level)
 317                          (> (get-text-property (point) 'mh-level) level))
 318                (let ((folder (get-text-property (point) 'mh-folder)))
 319                  (when (gethash folder mh-speed-folder-map)
 320                    (set-marker (gethash folder mh-speed-folder-map) nil)
 321                    (remhash folder mh-speed-folder-map)))
 322                (forward-line))
 323              (delete-region start-region (point))
 324              (forward-line -1)
 325              (speedbar-change-expand-button-char ?+)
 326              (add-text-properties
 327               (line-beginning-position) (1+ (line-beginning-position))
 328               '(mh-expanded nil)))
 329             (t
 330              (forward-line)
 331              (mh-speed-add-buttons parent (1+ level))
 332              (goto-char point)
 333              (speedbar-change-expand-button-char ?-)
 334              (add-text-properties
 335               (line-beginning-position) (1+ (line-beginning-position))
 336               `(mh-expanded t)))))))
 337
 338 (defalias 'mh-speed-expand-folder 'mh-speed-toggle)
 339 (defalias 'mh-speed-contract-folder 'mh-speed-toggle)
 340
 341 ;;;###mh-autoload
 342 (defun mh-speed-view (&rest args)
 343   "Visits the selected folder just as if you had used \\<mh-folder-mode-map>\\[mh-visit-folder].
 344 The optional ARGS from speedbar are ignored."
 345   (interactive)
 346   (declare (ignore args))
 347   (let* ((folder (get-text-property (line-beginning-position) 'mh-folder))
 348          (range (and (stringp folder)
 349                      (mh-read-range "Scan" folder t nil nil
 350                                     mh-interpret-number-as-range-flag))))
 351     (when (stringp folder)
 352       (speedbar-with-attached-buffer
 353        (mh-visit-folder folder range)
 354        (delete-other-windows)))))
 355
 356 (defvar mh-speed-current-folder nil)
 357 (defvar mh-speed-flists-folder nil)
 358
 359 (defmacro mh-process-kill-without-query (process)
 360   "PROCESS can be killed without query on Emacs exit.
 361 Avoid using `process-kill-without-query' if possible since it is
 362 now obsolete."
 363   (if (fboundp 'set-process-query-on-exit-flag)
 364       `(set-process-query-on-exit-flag ,process nil)
 365     `(process-kill-without-query ,process)))
 366
 367 ;;;###mh-autoload
 368 (defun mh-speed-flists (force &rest folders)
 369   "Execute flists -recurse and update message counts.
 370 If FORCE is non-nil the timer is reset.
 371
 372 Any number of optional FOLDERS can be specified. If specified,
 373 flists is run only for that one folder."
 374   (interactive (list t))
 375   (when force
 376     (when mh-speed-flists-timer
 377       (cancel-timer mh-speed-flists-timer)
 378       (setq mh-speed-flists-timer nil))
 379     (when (and (processp mh-speed-flists-process)
 380                (not (eq (process-status mh-speed-flists-process) 'exit)))
 381       (set-process-filter mh-speed-flists-process t)
 382       (kill-process mh-speed-flists-process)
 383       (setq mh-speed-partial-line "")
 384       (setq mh-speed-flists-process nil)))
 385   (setq mh-speed-flists-folder folders)
 386   (unless mh-speed-flists-timer
 387     (setq mh-speed-flists-timer
 388           (run-at-time
 389            nil (if (> mh-speed-update-interval 0)
 390                    mh-speed-update-interval
 391                  nil)
 392            (lambda ()
 393              (unless (and (processp mh-speed-flists-process)
 394                           (not (eq (process-status mh-speed-flists-process)
 395                                    'exit)))
 396                (setq mh-speed-current-folder
 397                      (concat
 398                       (if mh-speed-flists-folder
 399                           (substring (car (reverse mh-speed-flists-folder)) 1)
 400                         (with-temp-buffer
 401                           (call-process (expand-file-name "folder" mh-progs)
 402                                         nil '(t nil) nil "-fast")
 403                           (buffer-substring (point-min) (1- (point-max)))))
 404                       "+"))
 405                (setq mh-speed-flists-process
 406                      (apply #'start-process "*flists*" nil
 407                             (expand-file-name "flists" mh-progs)
 408                             (if mh-speed-flists-folder "-noall" "-all")
 409                             "-sequence" (symbol-name mh-unseen-seq)
 410                             (or mh-speed-flists-folder '("-recurse"))))
 411                ;; Run flists on all folders the next time around...
 412                (setq mh-speed-flists-folder nil)
 413                (mh-process-kill-without-query mh-speed-flists-process)
 414                (set-process-filter mh-speed-flists-process
 415                                    'mh-speed-parse-flists-output)))))))
 416
 417 ;; Copied from mh-make-folder-list-filter...
 418 (defun mh-speed-parse-flists-output (process output)
 419   "Parse the incremental results from flists.
 420 PROCESS is the flists process and OUTPUT is the results that must
 421 be handled next."
 422   (let ((prevailing-match-data (match-data))
 423         (position 0)
 424         line-end line folder unseen total)
 425     (unwind-protect
 426         (while (setq line-end (string-match "\n" output position))
 427           (setq line (format "%s%s"
 428                              mh-speed-partial-line
 429                              (substring output position line-end))
 430                 mh-speed-partial-line "")
 431           (multiple-value-setq (folder unseen total)
 432             (mh-parse-flist-output-line line mh-speed-current-folder))
 433           (when (and folder unseen total
 434                      (let ((old-pair (gethash folder mh-speed-flists-cache)))
 435                        (or (not (equal (car old-pair) unseen))
 436                            (not (equal (cdr old-pair) total)))))
 437             (setf (gethash folder mh-speed-flists-cache) (cons unseen total))
 438             (save-excursion
 439               (when (buffer-live-p (get-buffer speedbar-buffer))
 440                 (set-buffer speedbar-buffer)
 441                 (speedbar-with-writable
 442                   (when (get-text-property (point-min) 'mh-level)
 443                     (let ((pos (gethash folder mh-speed-folder-map))
 444                           face)
 445                       (when pos
 446                         (goto-char pos)
 447                         (goto-char (line-beginning-position))
 448                         (cond
 449                          ((null (get-text-property (point) 'mh-count))
 450                           (goto-char (line-end-position))
 451                           (setq face (get-text-property (1- (point)) 'face))
 452                           (insert (format " (%s/%s)" unseen total))
 453                           (mh-speed-highlight 'unknown face)
 454                           (goto-char (line-beginning-position))
 455                           (add-text-properties (point) (1+ (point))
 456                                                `(mh-count (,unseen . ,total))))
 457                          ((not (equal (get-text-property (point) 'mh-count)
 458                                       (cons unseen total)))
 459                           (goto-char (line-end-position))
 460                           (setq face (get-text-property (1- (point)) 'face))
 461                           (re-search-backward " " (line-beginning-position) t)
 462                           (delete-region (point) (line-end-position))
 463                           (insert (format " (%s/%s)" unseen total))
 464                           (mh-speed-highlight 'unknown face)
 465                           (goto-char (line-beginning-position))
 466                           (add-text-properties
 467                            (point) (1+ (point))
 468                            `(mh-count (,unseen . ,total))))))))))))
 469           (setq position (1+ line-end)))
 470       (set-match-data prevailing-match-data))
 471     (setq mh-speed-partial-line (substring output position))))
 472
 473 ;;;###mh-autoload
 474 (defun mh-speed-invalidate-map (folder)
 475   "Remove FOLDER from various optimization caches."
 476   (interactive (list ""))
 477   (save-excursion
 478     (set-buffer speedbar-buffer)
 479     (let* ((speedbar-update-flag nil)
 480            (last-slash (mh-search-from-end ?/ folder))
 481            (parent (if last-slash (substring folder 0 last-slash) nil))
 482            (parent-position (gethash parent mh-speed-folder-map))
 483            (parent-change nil))
 484       (when parent-position
 485         (let ((parent-kids (mh-sub-folders parent)))
 486           (cond ((null parent-kids)
 487                  (setq parent-change ?+))
 488                 ((and (null (cdr parent-kids))
 489                       (equal (if last-slash
 490                                  (substring folder (1+ last-slash))
 491                                (substring folder 1))
 492                              (caar parent-kids)))
 493                  (setq parent-change ? ))))
 494         (goto-char parent-position)
 495         (when (equal (get-text-property (line-beginning-position) 'mh-folder)
 496                      parent)
 497           (when (get-text-property (line-beginning-position) 'mh-expanded)
 498             (mh-speed-toggle))
 499           (when parent-change
 500             (speedbar-with-writable
 501               (mh-speedbar-change-expand-button-char parent-change)
 502               (add-text-properties
 503                (line-beginning-position) (1+ (line-beginning-position))
 504                `(mh-children-p ,(equal parent-change ?+)))))
 505           (mh-speed-highlight mh-speed-last-selected-folder 'mh-speedbar-folder)
 506           (setq mh-speed-last-selected-folder nil)
 507           (setq mh-speed-refresh-flag t)))
 508       (when (equal folder "")
 509         (clrhash mh-sub-folders-cache)))))
 510
 511 (defun mh-speed-refresh ()
 512   "Regenerates the list of folders in the speedbar.
 513
 514 Run this command if you've added or deleted a folder, or want to
 515 update the unseen message count before the next automatic
 516 update."
 517   (interactive)
 518   (mh-speed-flists t)
 519   (mh-speed-invalidate-map ""))
 520
 521 ;;;###mh-autoload
 522 (defun mh-speed-add-folder (folder)
 523   "Add FOLDER since it is being created.
 524 The function invalidates the latest ancestor that is present."
 525   (save-excursion
 526     (set-buffer speedbar-buffer)
 527     (let ((speedbar-update-flag nil)
 528           (last-slash (mh-search-from-end ?/ folder))
 529           (ancestor folder)
 530           (ancestor-pos nil))
 531       (block while-loop
 532         (while last-slash
 533           (setq ancestor (substring ancestor 0 last-slash))
 534           (setq ancestor-pos (gethash ancestor mh-speed-folder-map))
 535           (when ancestor-pos
 536             (return-from while-loop))
 537           (setq last-slash (mh-search-from-end ?/ ancestor))))
 538       (unless ancestor-pos (setq ancestor nil))
 539       (goto-char (or ancestor-pos (gethash nil mh-speed-folder-map)))
 540       (speedbar-with-writable
 541         (mh-speedbar-change-expand-button-char ?+)
 542         (add-text-properties
 543          (line-beginning-position) (1+ (line-beginning-position))
 544          `(mh-children-p t)))
 545       (when (get-text-property (line-beginning-position) 'mh-expanded)
 546         (mh-speed-toggle))
 547       (setq mh-speed-refresh-flag t))))
 548
 549 ;; Make it slightly more general to allow for [ ] buttons to be changed to
 550 ;; [+].
 551 (defun mh-speedbar-change-expand-button-char (char)
 552   "Change the expansion button character to CHAR for the current line."
 553   (save-excursion
 554     (beginning-of-line)
 555     (if (re-search-forward "\\[.\\]" (line-end-position) t)
 556         (speedbar-with-writable
 557           (backward-char 2)
 558           (delete-char 1)
 559           (insert-char char 1 t)
 560           (put-text-property (point) (1- (point)) 'invisible nil)
 561           ;; make sure we fix the image on the text here.
 562           (mh-funcall-if-exists
 563            speedbar-insert-image-button-maybe (- (point) 2) 3)))))
 564
 565 (provide 'mh-speed)
 566
 567 ;; Local Variables:
 568 ;; indent-tabs-mode: nil
 569 ;; sentence-end-double-space: nil
 570 ;; End:
 571
 572 ;; arch-tag: d38ddcd4-3c00-4e37-99bf-8b89dda7b32c
 573 ;;; mh-speed.el ends here