code.delx.au - gnu-emacs/blob - lisp/vc-git.el

   1 ;;; vc-git.el --- VC backend for the git version control system
   2
   3 ;; Copyright (C) 2006, 2007 Free Software Foundation, Inc.
   4
   5 ;; Author: Alexandre Julliard <julliard@winehq.org>
   6 ;; Keywords: tools
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 3, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This file contains a VC backend for the git version control
  28 ;; system.
  29 ;;
  30
  31 ;;; Installation:
  32
  33 ;; To install: put this file on the load-path and add Git to the list
  34 ;; of supported backends in `vc-handled-backends'; the following line,
  35 ;; placed in your ~/.emacs, will accomplish this:
  36 ;;
  37 ;;     (add-to-list 'vc-handled-backends 'Git)
  38
  39 ;;; Todo:
  40 ;;  - check if more functions could use vc-git-command instead
  41 ;;     of start-process.
  42 ;;  - changelog generation
  43
  44 ;; Implement the rest of the vc interface. See the comment at the
  45 ;; beginning of vc.el. The current status is:
  46 ;; ("??" means: "figure out what to do about it")
  47 ;;
  48 ;; FUNCTION NAME                                   STATUS
  49 ;; BACKEND PROPERTIES
  50 ;; * revision-granularity                          OK
  51 ;; STATE-QUERYING FUNCTIONS
  52 ;; * registered (file)                             OK
  53 ;; * state (file)                                  OK
  54 ;; - state-heuristic (file)                        NOT NEEDED
  55 ;; - dir-state (dir)                               OK
  56 ;; * workfile-version (file)                       OK
  57 ;; - latest-on-branch-p (file)                     NOT NEEDED
  58 ;; * checkout-model (file)                         OK
  59 ;; - workfile-unchanged-p (file)                   OK
  60 ;; - mode-line-string (file)                       NOT NEEDED
  61 ;; - dired-state-info (file)                       OK
  62 ;; STATE-CHANGING FUNCTIONS
  63 ;; * create-repo ()                                OK
  64 ;; * register (files &optional rev comment)        OK
  65 ;; - init-version (file)                           NOT NEEDED
  66 ;; - responsible-p (file)                          OK
  67 ;; - could-register (file)                         NOT NEEDED, DEFAULT IS GOOD
  68 ;; - receive-file (file rev)                       NOT NEEDED
  69 ;; - unregister (file)                             OK
  70 ;; * checkin (files rev comment)                   OK
  71 ;; * find-version (file rev buffer)                OK
  72 ;; * checkout (file &optional editable rev)        OK
  73 ;; * revert (file &optional contents-done)         OK
  74 ;; - rollback (files)                              COULD BE SUPPORTED
  75 ;; - merge (file rev1 rev2)                        It would be possible to merge changes into
  76 ;;                                                 a single file, but when committing they
  77 ;;                                                 wouldn't be identified as a merge by git,
  78 ;;                                                 so it's probably not a good idea.
  79 ;; - merge-news (file)                             see `merge'
  80 ;; - steal-lock (file &optional version)           NOT NEEDED
  81 ;; HISTORY FUNCTIONS
  82 ;; * print-log (files &optional buffer)            OK
  83 ;; - log-view-mode ()                              OK
  84 ;; - show-log-entry (version)                      NOT NEEDED, DEFAULT IS GOOD
  85 ;; - wash-log (file)                               COULD BE SUPPORTED
  86 ;; - logentry-check ()                             NOT NEEDED
  87 ;; - comment-history (file)                        ??
  88 ;; - update-changelog (files)                      COULD BE SUPPORTED
  89 ;; * diff (file &optional rev1 rev2 buffer)        OK
  90 ;; - revision-completion-table (file)              NOT SUPPORTED in emacs-22.x
  91 ;; - diff-tree (dir &optional rev1 rev2)           OK
  92 ;; - annotate-command (file buf &optional rev)     OK
  93 ;; - annotate-time ()                              OK
  94 ;; - annotate-current-time ()                      NOT NEEDED
  95 ;; - annotate-extract-revision-at-line ()          OK
  96 ;; SNAPSHOT SYSTEM
  97 ;; - create-snapshot (dir name branchp)            OK
  98 ;; - assign-name (file name)                       NOT NEEDED
  99 ;; - retrieve-snapshot (dir name update)           OK, needs to update buffers
 100 ;; MISCELLANEOUS
 101 ;; - make-version-backups-p (file)                 NOT NEEDED
 102 ;; - repository-hostname (dirname)                 NOT NEEDED
 103 ;; - previous-version (file rev)                   OK
 104 ;; - next-version (file rev)                       OK
 105 ;; - check-headers ()                              COULD BE SUPPORTED
 106 ;; - clear-headers ()                              NOT NEEDED
 107 ;; - delete-file (file)                            OK
 108 ;; - rename-file (old new)                         OK
 109 ;; - find-file-hook ()                             NOT NEEDED
 110 ;; - find-file-not-found-hook ()                   NOT NEEDED
 111
 112 (eval-when-compile (require 'cl) (require 'vc))
 113
 114 (defvar git-commits-coding-system 'utf-8
 115   "Default coding system for git commits.")
 116
 117 ;;; BACKEND PROPERTIES
 118
 119 (defun vc-git-revision-granularity ()
 120      'repository)
 121
 122 ;;; STATE-QUERYING FUNCTIONS
 123
 124 ;;;###autoload (defun vc-git-registered (file)
 125 ;;;###autoload   "Return non-nil if FILE is registered with git."
 126 ;;;###autoload   (if (vc-find-root file ".git")       ; short cut
 127 ;;;###autoload       (progn
 128 ;;;###autoload         (load "vc-git")
 129 ;;;###autoload         (vc-git-registered file))))
 130
 131 (defun vc-git-registered (file)
 132   "Check whether FILE is registered with git."
 133   (when (vc-git-root file)
 134     (with-temp-buffer
 135       (let* ((dir (file-name-directory file))
 136              (name (file-relative-name file dir)))
 137         (and (ignore-errors
 138               (when dir (cd dir))
 139               (eq 0 (call-process "git" nil '(t nil) nil "ls-files" "-c" "-z" "--" name)))
 140              (let ((str (buffer-string)))
 141                (and (> (length str) (length name))
 142                     (string= (substring str 0 (1+ (length name))) (concat name "\0")))))))))
 143
 144 (defun vc-git-state (file)
 145   "Git-specific version of `vc-state'."
 146   (call-process "git" nil nil nil "add" "--refresh" "--" (file-relative-name file))
 147   (let ((diff (vc-git--run-command-string file "diff-index" "-z" "HEAD" "--")))
 148     (if (and diff (string-match ":[0-7]\\{6\\} [0-7]\\{6\\} [0-9a-f]\\{40\\} [0-9a-f]\\{40\\} [ADMU]\0[^\0]+\0" diff))
 149         'edited
 150       'up-to-date)))
 151
 152 (defun vc-git-dir-state (dir)
 153   (with-temp-buffer
 154     (vc-git-command (current-buffer) nil nil "ls-files" "-t")
 155     (goto-char (point-min))
 156     (let ((status-char nil)
 157           (file nil))
 158       (while (not (eobp))
 159         (setq status-char (char-after))
 160         (setq file
 161               (expand-file-name
 162                (buffer-substring-no-properties (+ (point) 2) (line-end-position))))
 163         (cond
 164          ;; The rest of the possible states in "git ls-files -t" output:
 165          ;;      R              removed/deleted
 166          ;;      K              to be killed
 167          ;; should not show up in vc-dired, so don't deal with them
 168          ;; here.
 169          ((eq status-char ?H)
 170           (vc-file-setprop file 'vc-state 'up-to-date))
 171          ((eq status-char ?M)
 172           (vc-file-setprop file 'vc-state 'edited))
 173          ((eq status-char ?C)
 174           (vc-file-setprop file 'vc-state 'edited))
 175          ((eq status-char ??)
 176           (vc-file-setprop file 'vc-backend 'none)
 177           (vc-file-setprop file 'vc-state 'nil)))
 178         (forward-line)))))
 179
 180 (defun vc-git-workfile-version (file)
 181   "Git-specific version of `vc-workfile-version'."
 182   (let ((str (with-output-to-string
 183                (with-current-buffer standard-output
 184                  (call-process "git" nil '(t nil) nil "symbolic-ref" "HEAD")))))
 185     (if (string-match "^\\(refs/heads/\\)?\\(.+\\)$" str)
 186         (match-string 2 str)
 187       str)))
 188
 189 (defun vc-git-checkout-model (file)
 190   'implicit)
 191
 192 (defun vc-git-workfile-unchanged-p (file)
 193   (eq 'up-to-date (vc-git-state file)))
 194
 195 (defun vc-git-dired-state-info (file)
 196   "Git-specific version of `vc-dired-state-info'."
 197   (let ((git-state (vc-state file)))
 198     (if (eq git-state 'edited)
 199         "(modified)"
 200       ;; fall back to the default VC representation
 201       (vc-default-dired-state-info 'Git file))))
 202
 203 ;;; STATE-CHANGING FUNCTIONS
 204
 205 (defun vc-git-create-repo ()
 206   "Create a new Git repository."
 207   (vc-git-command nil 0 nil "init"))
 208
 209 (defun vc-git-register (files &optional rev comment)
 210   "Register FILE into the git version-control system."
 211   (vc-git-command nil 0 files "update-index" "--add" "--"))
 212
 213 (defalias 'vc-git-responsible-p 'vc-git-root)
 214
 215 (defun vc-git-unregister (file)
 216   (vc-git-command nil 0 file "rm" "-f" "--cached" "--"))
 217
 218
 219 (defun vc-git-checkin (files rev comment)
 220   (let ((coding-system-for-write git-commits-coding-system))
 221     (vc-git-command nil 0 files "commit" "-m" comment "--only" "--")))
 222
 223 (defun vc-git-find-version (file rev buffer)
 224   (let ((coding-system-for-read 'binary)
 225         (coding-system-for-write 'binary)
 226         (fullname (substring
 227                    (vc-git--run-command-string
 228                     file "ls-files" "-z" "--full-name" "--")
 229                    0 -1)))
 230     (vc-git-command
 231      buffer 0
 232      (concat (if rev rev "HEAD") ":" fullname) "cat-file" "blob")))
 233
 234 (defun vc-git-checkout (file &optional editable rev)
 235   (vc-git-command nil 0 file "checkout" (or rev "HEAD")))
 236
 237 (defun vc-git-revert (file &optional contents-done)
 238   "Revert FILE to the version stored in the git repository."
 239   (if contents-done
 240       (vc-git-command nil 0 file "update-index" "--")
 241     (vc-git-command nil 0 file "checkout" "HEAD")))
 242
 243 ;;; HISTORY FUNCTIONS
 244
 245 (defun vc-git-print-log (files &optional buffer)
 246   "Get change log associated with FILES."
 247   (let ((coding-system-for-read git-commits-coding-system)
 248         ;; Support both the old print-log interface that passes a
 249         ;; single file, and the new one that passes a file list.
 250         (flist (if (listp files) files (list files))))
 251     ;; `vc-do-command' creates the buffer, but we need it before running
 252     ;; the command.
 253     (vc-setup-buffer buffer)
 254     ;; If the buffer exists from a previous invocation it might be
 255     ;; read-only.
 256     (let ((inhibit-read-only t))
 257       ;; XXX `log-view-mode' needs to have something to identify where
 258       ;; the log for each individual file starts. It seems that by
 259       ;; default git does not output this info. So loop here and call
 260       ;; "git rev-list" on each file separately to make sure that each
 261       ;; file gets a "File:" header before the corresponding
 262       ;; log. Maybe there is a way to do this with one command...
 263       (dolist (file flist)
 264         (with-current-buffer
 265             buffer
 266           (insert "File: " (file-name-nondirectory file) "\n"))
 267         (vc-git-command buffer 'async (file-relative-name file)
 268                         "rev-list" "--pretty" "HEAD" "--")))))
 269
 270 (defvar log-view-message-re)
 271 (defvar log-view-file-re)
 272 (defvar log-view-font-lock-keywords)
 273
 274 (define-derived-mode vc-git-log-view-mode log-view-mode "Git-Log-View"
 275   (require 'add-log) ;; we need the faces add-log
 276   ;; Don't have file markers, so use impossible regexp.
 277   (set (make-local-variable 'log-view-file-re) "^File:[ \t]+\\(.+\\)")
 278   (set (make-local-variable 'log-view-message-re)
 279        "^commit *\\([0-9a-z]+\\)")
 280   (set (make-local-variable 'log-view-font-lock-keywords)
 281        (append
 282        `((,log-view-message-re  (1 'change-log-acknowledgement))
 283          (,log-view-file-re (1 'change-log-file-face)))
 284          ;; Handle the case:
 285          ;; user: foo@bar
 286          '(("^Author:[ \t]+\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)"
 287             (1 'change-log-email))
 288            ;; Handle the case:
 289            ;; user: FirstName LastName <foo@bar>
 290            ("^Author:[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
 291             (1 'change-log-name)
 292             (2 'change-log-email))
 293            ("^ +\\(?:\\(?:[Aa]cked\\|[Ss]igned-[Oo]ff\\)-[Bb]y:\\)[ \t]+\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)"
 294             (1 'change-log-name))
 295            ("^ +\\(?:\\(?:[Aa]cked\\|[Ss]igned-[Oo]ff\\)-[Bb]y:\\)[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
 296             (1 'change-log-name)
 297             (2 'change-log-email))
 298            ("^Merge: \\([0-9a-z]+\\) \\([0-9a-z]+\\)"
 299             (1 'change-log-acknowledgement)
 300             (2 'change-log-acknowledgement))
 301            ("^Date:   \\(.+\\)" (1 'change-log-date))
 302            ("^summary:[ \t]+\\(.+\\)" (1 'log-view-message))))))
 303
 304 (defun vc-git-diff (files &optional rev1 rev2 buffer)
 305   (let ((buf (or buffer "*vc-diff*")))
 306     (if (and rev1 rev2)
 307         (vc-git-command buf 1 files "diff-tree" "--exit-code" "-p" rev1 rev2 "--")
 308       (vc-git-command buf 1 files "diff-index" "--exit-code" "-p" (or rev1 "HEAD") "--"))))
 309
 310 (defun vc-git-revision-table (file)
 311   (let ((table (list "HEAD")))
 312     (with-temp-buffer
 313       (vc-git-command t nil nil "for-each-ref" "--format=%(refname)")
 314       (goto-char (point-min))
 315       (while (re-search-forward "^refs/\\(heads\\|tags\\)/\\(.*\\)$" nil t)
 316         (push (match-string 2) table)))
 317     table))
 318
 319 (defun vc-git-revision-completion-table (file)
 320   (lexical-let ((file file)
 321                 table)
 322     (setq table (lazy-completion-table
 323                  table (lambda () (vc-git-revision-table file))))
 324     table))
 325
 326 (defun vc-git-diff-tree (dir &optional rev1 rev2)
 327   (vc-git-diff dir rev1 rev2))
 328
 329 (defun vc-git-annotate-command (file buf &optional rev)
 330   ;; FIXME: rev is ignored
 331   (let ((name (file-relative-name file)))
 332     (vc-git-command buf 0 name "blame" (if rev (concat "-r" rev)))))
 333
 334 (defun vc-git-annotate-time ()
 335   (and (re-search-forward "[0-9a-f]+ (.* \\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\) \\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\) \\([-+0-9]+\\) +[0-9]+)" nil t)
 336        (vc-annotate-convert-time
 337         (apply #'encode-time (mapcar (lambda (match) (string-to-number (match-string match))) '(6 5 4 3 2 1 7))))))
 338
 339 (defun vc-git-annotate-extract-revision-at-line ()
 340  (save-excursion
 341    (move-beginning-of-line 1)
 342    (and (looking-at "[0-9a-f]+")
 343         (buffer-substring-no-properties (match-beginning 0) (match-end 0)))))
 344
 345 ;;; SNAPSHOT SYSTEM
 346
 347 (defun vc-git-create-snapshot (dir name branchp)
 348   (let ((default-directory dir))
 349     (and (vc-git-command nil 0 nil "update-index" "--refresh")
 350          (if branchp
 351              (vc-git-command nil 0 nil "checkout" "-b" name)
 352            (vc-git-command nil 0 nil "tag" name)))))
 353
 354 (defun vc-git-retrieve-snapshot (dir name update)
 355   (let ((default-directory dir))
 356     (vc-git-command nil 0 nil "checkout" name)
 357     ;; FIXME: update buffers if `update' is true
 358     ))
 359
 360
 361 ;;; MISCELLANEOUS
 362
 363 (defun vc-git-previous-version (file rev)
 364   "Git-specific version of `vc-previous-version'."
 365   (let ((default-directory (file-name-directory (expand-file-name file)))
 366         (file (file-name-nondirectory file)))
 367     (vc-git-symbolic-commit
 368      (with-temp-buffer
 369        (and
 370         (zerop
 371          (call-process "git" nil '(t nil) nil "rev-list"
 372                        "-2" rev "--" file))
 373         (goto-char (point-max))
 374         (bolp)
 375         (zerop (forward-line -1))
 376         (not (bobp))
 377         (buffer-substring-no-properties
 378            (point)
 379            (1- (point-max))))))))
 380
 381 (defun vc-git-next-version (file rev)
 382   "Git-specific version of `vc-next-version'."
 383   (let* ((default-directory (file-name-directory
 384                              (expand-file-name file)))
 385         (file (file-name-nondirectory file))
 386         (current-rev
 387          (with-temp-buffer
 388            (and
 389             (zerop
 390              (call-process "git" nil '(t nil) nil "rev-list"
 391                            "-1" rev "--" file))
 392             (goto-char (point-max))
 393             (bolp)
 394             (zerop (forward-line -1))
 395             (bobp)
 396             (buffer-substring-no-properties
 397              (point)
 398              (1- (point-max)))))))
 399     (and current-rev
 400          (vc-git-symbolic-commit
 401           (with-temp-buffer
 402             (and
 403              (zerop
 404               (call-process "git" nil '(t nil) nil "rev-list"
 405                             "HEAD" "--" file))
 406              (goto-char (point-min))
 407              (search-forward current-rev nil t)
 408              (zerop (forward-line -1))
 409              (buffer-substring-no-properties
 410               (point)
 411               (progn (forward-line 1) (1- (point))))))))))
 412
 413 (defun vc-git-delete-file (file)
 414   (vc-git-command nil 0 file "rm" "-f" "--"))
 415
 416 (defun vc-git-rename-file (old new)
 417   (vc-git-command nil 0 (list old new) "mv" "-f" "--"))
 418
 419 \f
 420 ;;; Internal commands
 421
 422 (defun vc-git-root (file)
 423   (vc-find-root file ".git"))
 424
 425 (defun vc-git-command (buffer okstatus file-or-list &rest flags)
 426   "A wrapper around `vc-do-command' for use in vc-git.el.
 427 The difference to vc-do-command is that this function always invokes `git'."
 428   (apply 'vc-do-command buffer okstatus "git" file-or-list flags))
 429
 430 (defun vc-git--run-command-string (file &rest args)
 431   "Run a git command on FILE and return its output as string."
 432   (let* ((ok t)
 433          (str (with-output-to-string
 434                 (with-current-buffer standard-output
 435                   (unless (eq 0 (apply #'call-process "git" nil '(t nil) nil
 436                                        (append args (list (file-relative-name file)))))
 437                     (setq ok nil))))))
 438     (and ok str)))
 439
 440 (defun vc-git-symbolic-commit (commit)
 441   "Translate COMMIT string into symbolic form.
 442 Returns nil if not possible."
 443   (and commit
 444        (with-temp-buffer
 445          (and
 446           (zerop
 447            (call-process "git" nil '(t nil) nil "name-rev"
 448                          "--name-only" "--tags"
 449                          commit))
 450           (goto-char (point-min))
 451           (= (forward-line 2) 1)
 452           (bolp)
 453           (buffer-substring-no-properties (point-min) (1- (point-max)))))))
 454
 455 (provide 'vc-git)
 456
 457 ;; arch-tag: bd10664a-0e5b-48f5-a877-6c17b135be12
 458 ;;; vc-git.el ends here