code.delx.au - gnu-emacs/blob - lisp/frame.el

   1 ;;; frame.el --- multi-frame management independent of window systems
   2
   3 ;; Copyright (C) 1993, 1994, 1996, 1997, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: internal
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 3, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (defvar frame-creation-function-alist
  31   (list (cons nil
  32               (if (fboundp 'tty-create-frame-with-faces)
  33                   'tty-create-frame-with-faces
  34                 (function
  35                  (lambda (parameters)
  36                    (error "Can't create multiple frames without a window system"))))))
  37   "Alist of window-system dependent functions to call to create a new frame.
  38 The window system startup file should add its frame creation
  39 function to this list, which should take an alist of parameters
  40 as its argument.")
  41
  42 (defvar window-system-default-frame-alist nil
  43   "Alist of window-system dependent default frame parameters.
  44 You can set this in your `.emacs' file; for example,
  45
  46     ;; Disable menubar and toolbar on the console, but enable them under X.
  47     (setq window-system-default-frame-alist
  48           '((x (menu-bar-lines . 1) (tool-bar-lines . 1))
  49             (nil (menu-bar-lines . 0) (tool-bar-lines . 0))))
  50
  51 Parameters specified here supersede the values given in `default-frame-alist'.")
  52
  53 ;; The initial value given here used to ask for a minibuffer.
  54 ;; But that's not necessary, because the default is to have one.
  55 ;; By not specifying it here, we let an X resource specify it.
  56 (defcustom initial-frame-alist nil
  57   "*Alist of frame parameters for creating the initial X window frame.
  58 You can set this in your `.emacs' file; for example,
  59  (setq initial-frame-alist '((top . 1) (left . 1) (width . 80) (height . 55)))
  60 Parameters specified here supersede the values given in `default-frame-alist'.
  61
  62 If the value calls for a frame without a minibuffer, and you have not created
  63 a minibuffer frame on your own, one is created according to
  64 `minibuffer-frame-alist'.
  65
  66 You can specify geometry-related options for just the initial frame
  67 by setting this variable in your `.emacs' file; however, they won't
  68 take effect until Emacs reads `.emacs', which happens after first creating
  69 the frame.  If you want the frame to have the proper geometry as soon
  70 as it appears, you need to use this three-step process:
  71 * Specify X resources to give the geometry you want.
  72 * Set `default-frame-alist' to override these options so that they
  73   don't affect subsequent frames.
  74 * Set `initial-frame-alist' in a way that matches the X resources,
  75   to override what you put in `default-frame-alist'."
  76   :type '(repeat (cons :format "%v"
  77                        (symbol :tag "Parameter")
  78                        (sexp :tag "Value")))
  79   :group 'frames)
  80
  81 (defcustom minibuffer-frame-alist '((width . 80) (height . 2))
  82   "*Alist of frame parameters for initially creating a minibuffer frame.
  83 You can set this in your `.emacs' file; for example,
  84  (setq minibuffer-frame-alist
  85    '((top . 1) (left . 1) (width . 80) (height . 2)))
  86 Parameters specified here supersede the values given in
  87 `default-frame-alist', for a minibuffer frame."
  88   :type '(repeat (cons :format "%v"
  89                        (symbol :tag "Parameter")
  90                        (sexp :tag "Value")))
  91   :group 'frames)
  92
  93 (defcustom pop-up-frame-alist nil
  94   "*Alist of frame parameters used when creating pop-up frames.
  95 Pop-up frames are used for completions, help, and the like.
  96 This variable can be set in your init file, like this:
  97   (setq pop-up-frame-alist '((width . 80) (height . 20)))
  98 These supersede the values given in `default-frame-alist',
  99 for pop-up frames."
 100   :type '(repeat (cons :format "%v"
 101                        (symbol :tag "Parameter")
 102                        (sexp :tag "Value")))
 103   :group 'frames)
 104
 105 (setq pop-up-frame-function
 106       ;; Using `function' here caused some sort of problem.
 107       '(lambda ()
 108          (make-frame pop-up-frame-alist)))
 109
 110 (defcustom special-display-frame-alist
 111   '((height . 14) (width . 80) (unsplittable . t))
 112   "*Alist of frame parameters used when creating special frames.
 113 Special frames are used for buffers whose names are in
 114 `special-display-buffer-names' and for buffers whose names match
 115 one of the regular expressions in `special-display-regexps'.
 116 This variable can be set in your init file, like this:
 117   (setq special-display-frame-alist '((width . 80) (height . 20)))
 118 These supersede the values given in `default-frame-alist'."
 119   :type '(repeat (cons :format "%v"
 120                          (symbol :tag "Parameter")
 121                          (sexp :tag "Value")))
 122   :group 'frames)
 123
 124 (defun special-display-popup-frame (buffer &optional args)
 125   "Display BUFFER in its own frame, reusing an existing window if any.
 126 Return the window chosen.
 127 Currently we do not insist on selecting the window within its frame.
 128 If ARGS is an alist, use it as a list of frame parameter specs.
 129 If ARGS is a list whose car is a symbol,
 130 use (car ARGS) as a function to do the work.
 131 Pass it BUFFER as first arg, and (cdr ARGS) gives the rest of the args."
 132   (if (and args (symbolp (car args)))
 133       (apply (car args) buffer (cdr args))
 134     (let ((window (get-buffer-window buffer 0)))
 135       (or
 136        ;; If we have a window already, make it visible.
 137        (when window
 138          (let ((frame (window-frame window)))
 139            (make-frame-visible frame)
 140            (raise-frame frame)
 141            window))
 142        ;; Reuse the current window if the user requested it.
 143        (when (cdr (assq 'same-window args))
 144          (condition-case nil
 145              (progn (switch-to-buffer buffer) (selected-window))
 146            (error nil)))
 147        ;; Stay on the same frame if requested.
 148        (when (or (cdr (assq 'same-frame args)) (cdr (assq 'same-window args)))
 149          (let* ((pop-up-frames nil) (pop-up-windows t)
 150                 special-display-regexps special-display-buffer-names
 151                 (window (display-buffer buffer)))
 152            ;; Only do it if this is a new window:
 153            ;; (set-window-dedicated-p window t)
 154            window))
 155        ;; If no window yet, make one in a new frame.
 156        (let ((frame
 157               (with-current-buffer buffer
 158                 (make-frame (append args special-display-frame-alist)))))
 159          (set-window-buffer (frame-selected-window frame) buffer)
 160          (set-window-dedicated-p (frame-selected-window frame) t)
 161          (frame-selected-window frame))))))
 162
 163 (defun handle-delete-frame (event)
 164   "Handle delete-frame events from the X server."
 165   (interactive "e")
 166   (let ((frame (posn-window (event-start event)))
 167         (i 0)
 168         (tail (frame-list)))
 169     (while tail
 170       (and (frame-visible-p (car tail))
 171            (not (eq (car tail) frame))
 172           (setq i (1+ i)))
 173       (setq tail (cdr tail)))
 174     (if (> i 0)
 175         (delete-frame frame t)
 176       ;; Gildea@x.org says it is ok to ask questions before terminating.
 177       (save-buffers-kill-emacs))))
 178 \f
 179 ;;;; Arrangement of frames at startup
 180
 181 ;; 1) Load the window system startup file from the lisp library and read the
 182 ;; high-priority arguments (-q and the like).  The window system startup
 183 ;; file should create any frames specified in the window system defaults.
 184 ;;
 185 ;; 2) If no frames have been opened, we open an initial text frame.
 186 ;;
 187 ;; 3) Once the init file is done, we apply any newly set parameters
 188 ;; in initial-frame-alist to the frame.
 189
 190 ;; These are now called explicitly at the proper times,
 191 ;; since that is easier to understand.
 192 ;; Actually using hooks within Emacs is bad for future maintenance. --rms.
 193 ;; (add-hook 'before-init-hook 'frame-initialize)
 194 ;; (add-hook 'window-setup-hook 'frame-notice-user-settings)
 195
 196 ;; If we create the initial frame, this is it.
 197 (defvar frame-initial-frame nil)
 198
 199 ;; Record the parameters used in frame-initialize to make the initial frame.
 200 (defvar frame-initial-frame-alist)
 201
 202 (defvar frame-initial-geometry-arguments nil)
 203
 204 ;; startup.el calls this function before loading the user's init
 205 ;; file - if there is no frame with a minibuffer open now, create
 206 ;; one to display messages while loading the init file.
 207 (defun frame-initialize ()
 208   "Create an initial frame if necessary."
 209   ;; Are we actually running under a window system at all?
 210   (if (and initial-window-system
 211            (not noninteractive)
 212            (not (eq initial-window-system 'pc)))
 213       (progn
 214         ;; Turn on special-display processing only if there's a window system.
 215         (setq special-display-function 'special-display-popup-frame)
 216
 217         ;; If there is no frame with a minibuffer besides the terminal
 218         ;; frame, then we need to create the opening frame.  Make sure
 219         ;; it has a minibuffer, but let initial-frame-alist omit the
 220         ;; minibuffer spec.
 221         (or (delq terminal-frame (minibuffer-frame-list))
 222             (progn
 223               (setq frame-initial-frame-alist
 224                     (append initial-frame-alist default-frame-alist nil))
 225               (or (assq 'horizontal-scroll-bars frame-initial-frame-alist)
 226                   (setq frame-initial-frame-alist
 227                         (cons '(horizontal-scroll-bars . t)
 228                               frame-initial-frame-alist)))
 229               (setq frame-initial-frame-alist
 230                     (cons (cons 'window-system initial-window-system)
 231                           frame-initial-frame-alist))
 232               (setq default-minibuffer-frame
 233                     (setq frame-initial-frame
 234                           (make-frame frame-initial-frame-alist)))
 235               ;; Delete any specifications for window geometry parameters
 236               ;; so that we won't reapply them in frame-notice-user-settings.
 237               ;; It would be wrong to reapply them then,
 238               ;; because that would override explicit user resizing.
 239               (setq initial-frame-alist
 240                     (frame-remove-geometry-params initial-frame-alist))))
 241         ;; Copy the environment of the Emacs process into the new frame.
 242         (set-frame-parameter frame-initial-frame 'environment
 243                              (frame-parameter terminal-frame 'environment))
 244         (set-frame-parameter frame-initial-frame 'display-environment-variable
 245                              (getenv "DISPLAY"))
 246         ;; At this point, we know that we have a frame open, so we
 247         ;; can delete the terminal frame.
 248         (delete-frame terminal-frame)
 249         (setq terminal-frame nil))))
 250
 251 (defvar frame-notice-user-settings t
 252   "Non-nil means function `frame-notice-user-settings' wasn't run yet.")
 253
 254 ;; startup.el calls this function after loading the user's init
 255 ;; file.  Now default-frame-alist and initial-frame-alist contain
 256 ;; information to which we must react; do what needs to be done.
 257 (defun frame-notice-user-settings ()
 258   "Act on user's init file settings of frame parameters.
 259 React to settings of `initial-frame-alist',
 260 `window-system-default-frame-alist' and `default-frame-alist'
 261 there (in decreasing order of priority)."
 262   ;; Make menu-bar-mode and default-frame-alist consistent.
 263   (when (boundp 'menu-bar-mode)
 264     (let ((default (assq 'menu-bar-lines default-frame-alist)))
 265       (if default
 266           (setq menu-bar-mode (not (eq (cdr default) 0)))
 267         (setq default-frame-alist
 268               (cons (cons 'menu-bar-lines (if menu-bar-mode 1 0))
 269                     default-frame-alist)))))
 270
 271   ;; Make tool-bar-mode and default-frame-alist consistent.  Don't do
 272   ;; it in batch mode since that would leave a tool-bar-lines
 273   ;; parameter in default-frame-alist in a dumped Emacs, which is not
 274   ;; what we want.
 275   (when (and (boundp 'tool-bar-mode)
 276              (not noninteractive))
 277     (let ((default (assq 'tool-bar-lines default-frame-alist)))
 278       (if default
 279           (setq tool-bar-mode (not (eq (cdr default) 0)))
 280         ;; If Emacs was started on a tty, changing default-frame-alist
 281         ;; would disable the toolbar on X frames created later.  We
 282         ;; want to keep the default of showing a toolbar under X even
 283         ;; in this case.
 284         ;;
 285         ;; If the user explicitly called `tool-bar-mode' in .emacs,
 286         ;; then default-frame-alist is already changed anyway.
 287         (when initial-window-system
 288           (setq default-frame-alist
 289                 (cons (cons 'tool-bar-lines (if tool-bar-mode 1 0))
 290                       default-frame-alist))))))
 291
 292   ;; Creating and deleting frames may shift the selected frame around,
 293   ;; and thus the current buffer.  Protect against that.  We don't
 294   ;; want to use save-excursion here, because that may also try to set
 295   ;; the buffer of the selected window, which fails when the selected
 296   ;; window is the minibuffer.
 297   (let ((old-buffer (current-buffer))
 298         (window-system-frame-alist (cdr (assq initial-window-system
 299                                               window-system-default-frame-alist))))
 300
 301     (when (and frame-notice-user-settings
 302                (null frame-initial-frame))
 303       ;; This case happens when we don't have a window system, and
 304       ;; also for MS-DOS frames.
 305       (let ((parms (frame-parameters frame-initial-frame)))
 306         ;; Don't change the frame names.
 307         (setq parms (delq (assq 'name parms) parms))
 308         ;; Can't modify the minibuffer parameter, so don't try.
 309         (setq parms (delq (assq 'minibuffer parms) parms))
 310         (modify-frame-parameters nil
 311                                  (if (null initial-window-system)
 312                                      (append initial-frame-alist
 313                                              window-system-frame-alist
 314                                              default-frame-alist
 315                                              parms
 316                                              nil)
 317                                    ;; initial-frame-alist and
 318                                    ;; default-frame-alist were already
 319                                    ;; applied in pc-win.el.
 320                                    parms))
 321         (if (null initial-window-system) ;; MS-DOS does this differently in pc-win.el
 322             (let ((newparms (frame-parameters))
 323                   (frame (selected-frame)))
 324               (tty-handle-reverse-video frame newparms)
 325               ;; If we changed the background color, we need to update
 326               ;; the background-mode parameter, and maybe some faces,
 327               ;; too.
 328               (when (assq 'background-color newparms)
 329                 (unless (or (assq 'background-mode initial-frame-alist)
 330                             (assq 'background-mode default-frame-alist))
 331                   (frame-set-background-mode frame))
 332                 (face-set-after-frame-default frame))))))
 333
 334     ;; If the initial frame is still around, apply initial-frame-alist
 335     ;; and default-frame-alist to it.
 336     (when (frame-live-p frame-initial-frame)
 337
 338       ;; When tool-bar has been switched off, correct the frame size
 339       ;; by the lines added in x-create-frame for the tool-bar and
 340       ;; switch `tool-bar-mode' off.
 341       (when (display-graphic-p)
 342         (let ((tool-bar-lines (or (assq 'tool-bar-lines initial-frame-alist)
 343                                   (assq 'tool-bar-lines window-system-frame-alist)
 344                                   (assq 'tool-bar-lines default-frame-alist))))
 345           (when (and tool-bar-originally-present
 346                      (or (null tool-bar-lines)
 347                          (null (cdr tool-bar-lines))
 348                          (eq 0 (cdr tool-bar-lines))))
 349             (let* ((char-height (frame-char-height frame-initial-frame))
 350                    (image-height tool-bar-images-pixel-height)
 351                    (margin (cond ((and (consp tool-bar-button-margin)
 352                                        (integerp (cdr tool-bar-button-margin))
 353                                        (> tool-bar-button-margin 0))
 354                                   (cdr tool-bar-button-margin))
 355                                  ((and (integerp tool-bar-button-margin)
 356                                        (> tool-bar-button-margin 0))
 357                                   tool-bar-button-margin)
 358                                  (t 0)))
 359                    (relief (if (and (integerp tool-bar-button-relief)
 360                                     (> tool-bar-button-relief 0))
 361                                tool-bar-button-relief 3))
 362                    (lines (/ (+ image-height
 363                                 (* 2 margin)
 364                                 (* 2 relief)
 365                                 (1- char-height))
 366                              char-height))
 367                    (height (frame-parameter frame-initial-frame 'height))
 368                    (newparms (list (cons 'height (- height lines))))
 369                    (initial-top (cdr (assq 'top
 370                                            frame-initial-geometry-arguments)))
 371                    (top (frame-parameter frame-initial-frame 'top)))
 372               (when (and (consp initial-top) (eq '- (car initial-top)))
 373                 (let ((adjusted-top
 374                        (cond ((and (consp top)
 375                                    (eq '+ (car top)))
 376                               (list '+
 377                                     (+ (cadr top)
 378                                        (* lines char-height))))
 379                              ((and (consp top)
 380                                    (eq '- (car top)))
 381                               (list '-
 382                                     (- (cadr top)
 383                                        (* lines char-height))))
 384                              (t (+ top (* lines char-height))))))
 385                   (setq newparms
 386                         (append newparms
 387                                 `((top . ,adjusted-top))
 388                                 nil))))
 389               (modify-frame-parameters frame-initial-frame newparms)
 390               (tool-bar-mode -1)))))
 391
 392       ;; The initial frame we create above always has a minibuffer.
 393       ;; If the user wants to remove it, or make it a minibuffer-only
 394       ;; frame, then we'll have to delete the current frame and make a
 395       ;; new one; you can't remove or add a root window to/from an
 396       ;; existing frame.
 397       ;;
 398       ;; NOTE: default-frame-alist was nil when we created the
 399       ;; existing frame.  We need to explicitly include
 400       ;; default-frame-alist in the parameters of the screen we
 401       ;; create here, so that its new value, gleaned from the user's
 402       ;; .emacs file, will be applied to the existing screen.
 403       (if (not (eq (cdr (or (assq 'minibuffer initial-frame-alist)
 404                             (assq 'minibuffer window-system-frame-alist)
 405                             (assq 'minibuffer default-frame-alist)
 406                             '(minibuffer . t)))
 407                    t))
 408           ;; Create the new frame.
 409           (let (parms new)
 410             ;; If the frame isn't visible yet, wait till it is.
 411             ;; If the user has to position the window,
 412             ;; Emacs doesn't know its real position until
 413             ;; the frame is seen to be visible.
 414             (while (not (cdr (assq 'visibility
 415                                    (frame-parameters frame-initial-frame))))
 416               (sleep-for 1))
 417             (setq parms (frame-parameters frame-initial-frame))
 418
 419             ;; Get rid of `name' unless it was specified explicitly before.
 420             (or (assq 'name frame-initial-frame-alist)
 421                 (setq parms (delq (assq 'name parms) parms)))
 422
 423             (setq parms (append initial-frame-alist
 424                                 window-system-frame-alist
 425                                 default-frame-alist
 426                                 parms
 427                                 nil))
 428
 429             ;; Get rid of `reverse', because that was handled
 430             ;; when we first made the frame.
 431             (setq parms (cons '(reverse) (delq (assq 'reverse parms) parms)))
 432
 433             (if (assq 'height frame-initial-geometry-arguments)
 434                 (setq parms (assq-delete-all 'height parms)))
 435             (if (assq 'width frame-initial-geometry-arguments)
 436                 (setq parms (assq-delete-all 'width parms)))
 437             (if (assq 'left frame-initial-geometry-arguments)
 438                 (setq parms (assq-delete-all 'left parms)))
 439             (if (assq 'top frame-initial-geometry-arguments)
 440                 (setq parms (assq-delete-all 'top parms)))
 441             (setq new
 442                   (make-frame
 443                    ;; Use the geometry args that created the existing
 444                    ;; frame, rather than the parms we get for it.
 445                    (append frame-initial-geometry-arguments
 446                            '((user-size . t) (user-position . t))
 447                            parms)))
 448             ;; The initial frame, which we are about to delete, may be
 449             ;; the only frame with a minibuffer.  If it is, create a
 450             ;; new one.
 451             (or (delq frame-initial-frame (minibuffer-frame-list))
 452                 (make-initial-minibuffer-frame nil))
 453
 454             ;; If the initial frame is serving as a surrogate
 455             ;; minibuffer frame for any frames, we need to wean them
 456             ;; onto a new frame.  The default-minibuffer-frame
 457             ;; variable must be handled similarly.
 458             (let ((users-of-initial
 459                    (filtered-frame-list
 460                     (lambda (frame)
 461                       (and (not (eq frame frame-initial-frame))
 462                            (eq (window-frame
 463                                 (minibuffer-window frame))
 464                                frame-initial-frame))))))
 465               (if (or users-of-initial
 466                       (eq default-minibuffer-frame frame-initial-frame))
 467
 468                   ;; Choose an appropriate frame.  Prefer frames which
 469                   ;; are only minibuffers.
 470                   (let* ((new-surrogate
 471                           (car
 472                            (or (filtered-frame-list
 473                                 (lambda (frame)
 474                                   (eq (cdr (assq 'minibuffer
 475                                                  (frame-parameters frame)))
 476                                       'only)))
 477                                (minibuffer-frame-list))))
 478                          (new-minibuffer (minibuffer-window new-surrogate)))
 479
 480                     (if (eq default-minibuffer-frame frame-initial-frame)
 481                         (setq default-minibuffer-frame new-surrogate))
 482
 483                     ;; Wean the frames using frame-initial-frame as
 484                     ;; their minibuffer frame.
 485                     (dolist (frame users-of-initial)
 486                       (modify-frame-parameters
 487                        frame (list (cons 'minibuffer new-minibuffer)))))))
 488
 489             ;; Redirect events enqueued at this frame to the new frame.
 490             ;; Is this a good idea?
 491             (redirect-frame-focus frame-initial-frame new)
 492
 493             ;; Finally, get rid of the old frame.
 494             (delete-frame frame-initial-frame t))
 495
 496         ;; Otherwise, we don't need all that rigamarole; just apply
 497         ;; the new parameters.
 498         (let (newparms allparms tail)
 499           (setq allparms (append initial-frame-alist
 500                                  window-system-frame-alist
 501                                  default-frame-alist nil))
 502           (if (assq 'height frame-initial-geometry-arguments)
 503               (setq allparms (assq-delete-all 'height allparms)))
 504           (if (assq 'width frame-initial-geometry-arguments)
 505               (setq allparms (assq-delete-all 'width allparms)))
 506           (if (assq 'left frame-initial-geometry-arguments)
 507               (setq allparms (assq-delete-all 'left allparms)))
 508           (if (assq 'top frame-initial-geometry-arguments)
 509               (setq allparms (assq-delete-all 'top allparms)))
 510           (setq tail allparms)
 511           ;; Find just the parms that have changed since we first
 512           ;; made this frame.  Those are the ones actually set by
 513           ;; the init file.  For those parms whose values we already knew
 514           ;; (such as those spec'd by command line options)
 515           ;; it is undesirable to specify the parm again
 516           ;; once the user has seen the frame and been able to alter it
 517           ;; manually.
 518           (while tail
 519             (let (newval oldval)
 520               (setq oldval (assq (car (car tail))
 521                                  frame-initial-frame-alist))
 522               (setq newval (cdr (assq (car (car tail)) allparms)))
 523               (or (and oldval (eq (cdr oldval) newval))
 524                   (setq newparms
 525                         (cons (cons (car (car tail)) newval) newparms))))
 526             (setq tail (cdr tail)))
 527           (setq newparms (nreverse newparms))
 528           (modify-frame-parameters frame-initial-frame
 529                                    newparms)
 530           ;; If we changed the background color,
 531           ;; we need to update the background-mode parameter
 532           ;; and maybe some faces too.
 533           (when (assq 'background-color newparms)
 534             (unless (assq 'background-mode newparms)
 535               (frame-set-background-mode frame-initial-frame))
 536             (face-set-after-frame-default frame-initial-frame)))))
 537
 538     ;; Restore the original buffer.
 539     (set-buffer old-buffer)
 540
 541     ;; Make sure the initial frame can be GC'd if it is ever deleted.
 542     ;; Make sure frame-notice-user-settings does nothing if called twice.
 543     (setq frame-notice-user-settings nil)
 544     (setq frame-initial-frame nil)))
 545
 546 (defun make-initial-minibuffer-frame (display)
 547   (let ((parms (append minibuffer-frame-alist '((minibuffer . only)))))
 548     (if display
 549         (make-frame-on-display display parms)
 550       (make-frame parms))))
 551
 552 ;;;; Creation of additional frames, and other frame miscellanea
 553
 554 (defun modify-all-frames-parameters (alist)
 555   "Modify all current and future frames' parameters according to ALIST.
 556 This changes `default-frame-alist' and possibly `initial-frame-alist'.
 557 Furthermore, this function removes all parameters in ALIST from
 558 `window-system-default-frame-alist'.
 559 See help of `modify-frame-parameters' for more information."
 560   (dolist (frame (frame-list))
 561     (modify-frame-parameters frame alist))
 562
 563   (dolist (pair alist) ;; conses to add/replace
 564     ;; initial-frame-alist needs setting only when
 565     ;; frame-notice-user-settings is true.
 566     (and frame-notice-user-settings
 567          (setq initial-frame-alist
 568                (assq-delete-all (car pair) initial-frame-alist)))
 569     (setq default-frame-alist
 570           (assq-delete-all (car pair) default-frame-alist))
 571     ;; Remove any similar settings from the window-system specific
 572     ;; parameters---they would override default-frame-alist.
 573     (dolist (w window-system-default-frame-alist)
 574       (setcdr w (assq-delete-all (car pair) (cdr w)))))
 575
 576   (and frame-notice-user-settings
 577        (setq initial-frame-alist (append initial-frame-alist alist)))
 578   (setq default-frame-alist (append default-frame-alist alist)))
 579
 580 (defun get-other-frame ()
 581   "Return some frame other than the current frame.
 582 Create one if necessary.  Note that the minibuffer frame, if separate,
 583 is not considered (see `next-frame')."
 584   (let ((s (if (equal (next-frame (selected-frame)) (selected-frame))
 585                (make-frame)
 586              (next-frame (selected-frame)))))
 587     s))
 588
 589 (defun next-multiframe-window ()
 590   "Select the next window, regardless of which frame it is on."
 591   (interactive)
 592   (select-window (next-window (selected-window)
 593                               (> (minibuffer-depth) 0)
 594                               0))
 595   (select-frame-set-input-focus (selected-frame)))
 596
 597 (defun previous-multiframe-window ()
 598   "Select the previous window, regardless of which frame it is on."
 599   (interactive)
 600   (select-window (previous-window (selected-window)
 601                                   (> (minibuffer-depth) 0)
 602                                   0))
 603   (select-frame-set-input-focus (selected-frame)))
 604
 605 (defun make-frame-on-display (display &optional parameters)
 606   "Make a frame on X display DISPLAY.
 607 The optional second argument PARAMETERS specifies additional frame parameters."
 608   (interactive "sMake frame on display: ")
 609   (or (string-match "\\`[^:]*:[0-9]+\\(\\.[0-9]+\\)?\\'" display)
 610       (error "Invalid display, not HOST:SERVER or HOST:SERVER.SCREEN"))
 611   (when (and (boundp 'x-initialized) (not x-initialized))
 612     (setq x-display-name display)
 613     (x-initialize-window-system))
 614   (make-frame `((window-system . x) (display . ,display) . ,parameters)))
 615
 616 (defun make-frame-on-tty (tty type &optional parameters)
 617   "Make a frame on terminal device TTY.
 618 TTY should be the file name of the tty device to use.  TYPE
 619 should be the terminal type string of TTY, for example \"xterm\"
 620 or \"vt100\".  The optional third argument PARAMETERS specifies
 621 additional frame parameters."
 622   (interactive "fOpen frame on tty device: \nsTerminal type of %s: ")
 623   (unless tty
 624     (error "Invalid terminal device"))
 625   (unless type
 626     (error "Invalid terminal type"))
 627   (make-frame `((window-system . nil) (tty . ,tty) (tty-type . ,type) . ,parameters)))
 628
 629 (defun close-display-connection (display)
 630   "Close the connection to a display, deleting all its associated frames.
 631 For DISPLAY, specify either a frame or a display name (a string).
 632 If DISPLAY is nil, that stands for the selected frame's display."
 633   (interactive
 634    (list
 635     (let* ((default (frame-parameter nil 'display))
 636            (display (completing-read
 637                      (format "Close display (default %s): " default)
 638                      (delete-dups
 639                       (mapcar (lambda (frame)
 640                                 (frame-parameter frame 'display))
 641                               (frame-list)))
 642                      nil t nil nil
 643                      default)))
 644       (if (zerop (length display)) default display))))
 645   (let ((frames (delq nil
 646                       (mapcar (lambda (frame)
 647                                 (if (equal display
 648                                            (frame-parameter frame 'display))
 649                                     frame))
 650                               (frame-list)))))
 651     (if (and (consp frames)
 652              (not (y-or-n-p (if (cdr frames)
 653                                 (format "Delete %s frames? " (length frames))
 654                               (format "Delete %s ? " (car frames))))))
 655         (error "Abort!")
 656       (mapc 'delete-frame frames)
 657       (x-close-connection display))))
 658
 659 (defun make-frame-command ()
 660   "Make a new frame, and select it if the terminal displays only one frame."
 661   (interactive)
 662   (if (and window-system (not (eq window-system 'pc)))
 663       (make-frame)
 664     (select-frame (make-frame))))
 665
 666 (defvar before-make-frame-hook nil
 667   "Functions to run before a frame is created.")
 668
 669 (defvar after-make-frame-functions nil
 670   "Functions to run after a frame is created.
 671 The functions are run with one arg, the newly created frame.")
 672
 673 (defvar after-setting-font-hook nil
 674   "Functions to run after a frame's font has been changed.")
 675
 676 ;; Alias, kept temporarily.
 677 (define-obsolete-function-alias 'new-frame 'make-frame "22.1")
 678
 679 (defun make-frame (&optional parameters)
 680   "Return a newly created frame displaying the current buffer.
 681 Optional argument PARAMETERS is an alist of parameters for the new frame.
 682 Each element of PARAMETERS should have the form (NAME . VALUE), for example:
 683
 684  (name . STRING)        The frame should be named STRING.
 685
 686  (width . NUMBER)       The frame should be NUMBER characters in width.
 687  (height . NUMBER)      The frame should be NUMBER text lines high.
 688
 689 You cannot specify either `width' or `height', you must use neither or both.
 690
 691  (minibuffer . t)       The frame should have a minibuffer.
 692  (minibuffer . nil)     The frame should have no minibuffer.
 693  (minibuffer . only)    The frame should contain only a minibuffer.
 694  (minibuffer . WINDOW)  The frame should use WINDOW as its minibuffer window.
 695
 696  (window-system . nil)  The frame should be displayed on a terminal device.
 697  (window-system . x)    The frame should be displayed in an X window.
 698
 699  (terminal . ID)          The frame should use the terminal identified by ID.
 700
 701 Before the frame is created (via `frame-creation-function-alist'), functions on the
 702 hook `before-make-frame-hook' are run.  After the frame is created, functions
 703 on `after-make-frame-functions' are run with one arg, the newly created frame.
 704
 705 This function itself does not make the new frame the selected frame.
 706 The previously selected frame remains selected.  However, the
 707 window system may select the new frame for its own reasons, for
 708 instance if the frame appears under the mouse pointer and your
 709 setup is for focus to follow the pointer."
 710   (interactive)
 711   (let* ((w (cond
 712              ((assq 'terminal parameters)
 713               (let ((type (terminal-live-p (cdr (assq 'terminal parameters)))))
 714                 (cond
 715                  ((eq type t) nil)
 716                  ((eq type nil) (error "Terminal %s does not exist" (cdr (assq 'terminal parameters))))
 717                  (t type))))
 718              ((assq 'window-system parameters)
 719               (cdr (assq 'window-system parameters)))
 720              (t window-system)))
 721          (frame-creation-function (cdr (assq w frame-creation-function-alist)))
 722          (oldframe (selected-frame))
 723          frame)
 724     (unless frame-creation-function
 725       (error "Don't know how to create a frame on window system %s" w))
 726     (run-hooks 'before-make-frame-hook)
 727     (setq frame (funcall frame-creation-function (append parameters (cdr (assq w window-system-default-frame-alist)))))
 728     (normal-erase-is-backspace-setup-frame frame)
 729     ;; Inherit the 'environment and 'client parameters.
 730     (let ((env (frame-parameter oldframe 'environment))
 731           (client (frame-parameter oldframe 'client))
 732            (displayenv (frame-parameter oldframe 'display-environment-variable)))
 733       (if (not (framep env))
 734           (setq env oldframe))
 735       (if (and env (not (assq 'environment parameters)))
 736           (set-frame-parameter frame 'environment env))
 737       (if (and displayenv (not (assq 'display-environment-variable parameters)))
 738           (set-frame-parameter frame 'display-environment-variable displayenv))
 739       (if (and client (not (assq 'client parameters)))
 740           (set-frame-parameter frame 'client client)))
 741     (run-hook-with-args 'after-make-frame-functions frame)
 742     frame))
 743
 744 (defun filtered-frame-list (predicate)
 745   "Return a list of all live frames which satisfy PREDICATE."
 746   (let* ((frames (frame-list))
 747          (list frames))
 748     (while (consp frames)
 749       (unless (funcall predicate (car frames))
 750         (setcar frames nil))
 751       (setq frames (cdr frames)))
 752     (delq nil list)))
 753
 754 (defun minibuffer-frame-list ()
 755   "Return a list of all frames with their own minibuffers."
 756   (filtered-frame-list
 757    (lambda (frame)
 758      (eq frame (window-frame (minibuffer-window frame))))))
 759
 760 (defun frames-on-display-list (&optional terminal)
 761   "Return a list of all frames on TERMINAL.
 762
 763 TERMINAL should be a terminal identifier (an integer), a frame,
 764 or a name of an X display (a string of the form
 765 HOST:SERVER.SCREEN).
 766
 767 If TERMINAL is omitted or nil, it defaults to the selected
 768 frame's terminal device."
 769   (let* ((terminal (terminal-id terminal))
 770          (func #'(lambda (frame)
 771                    (eq (frame-terminal frame) terminal))))
 772     (filtered-frame-list func)))
 773
 774 (defun framep-on-display (&optional terminal)
 775   "Return the type of frames on TERMINAL.
 776 TERMINAL may be a terminal id, a display name or a frame.  If it
 777 is a frame, its type is returned.  If TERMINAL is omitted or nil,
 778 it defaults to the selected frame's terminal device.  All frames
 779 on a given display are of the same type."
 780   (or (terminal-live-p terminal)
 781       (framep terminal)
 782       (framep (car (frames-on-display-list terminal)))))
 783
 784 (defun frame-remove-geometry-params (param-list)
 785   "Return the parameter list PARAM-LIST, but with geometry specs removed.
 786 This deletes all bindings in PARAM-LIST for `top', `left', `width',
 787 `height', `user-size' and `user-position' parameters.
 788 Emacs uses this to avoid overriding explicit moves and resizings from
 789 the user during startup."
 790   (setq param-list (cons nil param-list))
 791   (let ((tail param-list))
 792     (while (consp (cdr tail))
 793       (if (and (consp (car (cdr tail)))
 794                (memq (car (car (cdr tail)))
 795                      '(height width top left user-position user-size)))
 796           (progn
 797             (setq frame-initial-geometry-arguments
 798                   (cons (car (cdr tail)) frame-initial-geometry-arguments))
 799             (setcdr tail (cdr (cdr tail))))
 800         (setq tail (cdr tail)))))
 801   (setq frame-initial-geometry-arguments
 802         (nreverse frame-initial-geometry-arguments))
 803   (cdr param-list))
 804
 805 (defcustom focus-follows-mouse (not (eq window-system 'mac))
 806   "*Non-nil if window system changes focus when you move the mouse.
 807 You should set this variable to tell Emacs how your window manager
 808 handles focus, since there is no way in general for Emacs to find out
 809 automatically.
 810
 811 This variable does not have any effect on MS-Windows."
 812   :type 'boolean
 813   :group 'frames
 814   :version "20.3")
 815
 816 (defun select-frame-set-input-focus (frame)
 817   "Select FRAME, raise it, and set input focus, if possible."
 818     (select-frame frame)
 819     (raise-frame frame)
 820     ;; Ensure, if possible, that frame gets input focus.
 821     (cond ((memq (window-system frame) '(x max w32))
 822            (x-focus-frame frame)))
 823     (cond (focus-follows-mouse
 824            (set-mouse-position (selected-frame) (1- (frame-width)) 0))))
 825
 826 (defun other-frame (arg)
 827   "Select the ARGth different visible frame on current display, and raise it.
 828 All frames are arranged in a cyclic order.
 829 This command selects the frame ARG steps away in that order.
 830 A negative ARG moves in the opposite order.
 831
 832 To make this command work properly, you must tell Emacs
 833 how the system (or the window manager) generally handles
 834 focus-switching between windows.  If moving the mouse onto a window
 835 selects it (gives it focus), set `focus-follows-mouse' to t.
 836 Otherwise, that variable should be nil."
 837   (interactive "p")
 838   (let ((frame (selected-frame)))
 839     (while (> arg 0)
 840       (setq frame (next-frame frame))
 841       (while (not (eq (frame-visible-p frame) t))
 842         (setq frame (next-frame frame)))
 843       (setq arg (1- arg)))
 844     (while (< arg 0)
 845       (setq frame (previous-frame frame))
 846       (while (not (eq (frame-visible-p frame) t))
 847         (setq frame (previous-frame frame)))
 848       (setq arg (1+ arg)))
 849     (select-frame-set-input-focus frame)))
 850
 851 (defun iconify-or-deiconify-frame ()
 852   "Iconify the selected frame, or deiconify if it's currently an icon."
 853   (interactive)
 854   (if (eq (cdr (assq 'visibility (frame-parameters))) t)
 855       (iconify-frame)
 856     (make-frame-visible)))
 857
 858 (defun suspend-frame ()
 859   "Do whatever is right to suspend the current frame.
 860 Calls `suspend-emacs' if invoked from the controlling tty device,
 861 `suspend-tty' from a secondary tty device, and
 862 `iconify-or-deiconify-frame' from an X frame."
 863   (interactive)
 864   (let ((type (framep (selected-frame))))
 865     (cond
 866      ((eq type 'x) (iconify-or-deiconify-frame))
 867      ((eq type t)
 868       (if (controlling-tty-p)
 869           (suspend-emacs)
 870         (suspend-tty)))
 871      (t (suspend-emacs)))))
 872
 873 (defun make-frame-names-alist ()
 874   (let* ((current-frame (selected-frame))
 875          (falist
 876           (cons
 877            (cons (frame-parameter current-frame 'name) current-frame) nil))
 878          (frame (next-frame nil t)))
 879     (while (not (eq frame current-frame))
 880       (progn
 881         (setq falist (cons (cons (frame-parameter frame 'name) frame) falist))
 882         (setq frame (next-frame frame t))))
 883     falist))
 884
 885 (defvar frame-name-history nil)
 886 (defun select-frame-by-name (name)
 887   "Select the frame on the current terminal whose name is NAME and raise it.
 888 If there is no frame by that name, signal an error."
 889   (interactive
 890    (let* ((frame-names-alist (make-frame-names-alist))
 891            (default (car (car frame-names-alist)))
 892            (input (completing-read
 893                    (format "Select Frame (default %s): " default)
 894                    frame-names-alist nil t nil 'frame-name-history)))
 895      (if (= (length input) 0)
 896          (list default)
 897        (list input))))
 898   (let* ((frame-names-alist (make-frame-names-alist))
 899          (frame (cdr (assoc name frame-names-alist))))
 900     (or frame
 901         (error "There is no frame named `%s'" name))
 902     (make-frame-visible frame)
 903     (raise-frame frame)
 904     (select-frame frame)
 905     ;; Ensure, if possible, that frame gets input focus.
 906     (cond ((memq (window-system frame) '(x w32))
 907            (x-focus-frame frame)))
 908     (when focus-follows-mouse
 909       (set-mouse-position frame (1- (frame-width frame)) 0))))
 910 \f
 911 ;;;; Frame configurations
 912
 913 (defun current-frame-configuration ()
 914   "Return a list describing the positions and states of all frames.
 915 Its car is `frame-configuration'.
 916 Each element of the cdr is a list of the form (FRAME ALIST WINDOW-CONFIG),
 917 where
 918   FRAME is a frame object,
 919   ALIST is an association list specifying some of FRAME's parameters, and
 920   WINDOW-CONFIG is a window configuration object for FRAME."
 921   (cons 'frame-configuration
 922         (mapcar (lambda (frame)
 923                   (list frame
 924                         (frame-parameters frame)
 925                         (current-window-configuration frame)))
 926                 (frame-list))))
 927
 928 (defun set-frame-configuration (configuration &optional nodelete)
 929   "Restore the frames to the state described by CONFIGURATION.
 930 Each frame listed in CONFIGURATION has its position, size, window
 931 configuration, and other parameters set as specified in CONFIGURATION.
 932 However, this function does not restore deleted frames.
 933
 934 Ordinarily, this function deletes all existing frames not
 935 listed in CONFIGURATION.  But if optional second argument NODELETE
 936 is given and non-nil, the unwanted frames are iconified instead."
 937   (or (frame-configuration-p configuration)
 938       (signal 'wrong-type-argument
 939               (list 'frame-configuration-p configuration)))
 940   (let ((config-alist (cdr configuration))
 941         frames-to-delete)
 942     (dolist (frame (frame-list))
 943       (let ((parameters (assq frame config-alist)))
 944         (if parameters
 945             (progn
 946               (modify-frame-parameters
 947                frame
 948                ;; Since we can't set a frame's minibuffer status,
 949                ;; we might as well omit the parameter altogether.
 950                (let* ((parms (nth 1 parameters))
 951                       (mini (assq 'minibuffer parms)))
 952                  (if mini (setq parms (delq mini parms)))
 953                  parms))
 954               (set-window-configuration (nth 2 parameters)))
 955           (setq frames-to-delete (cons frame frames-to-delete)))))
 956     (mapc (if nodelete
 957               ;; Note: making frames invisible here was tried
 958               ;; but led to some strange behavior--each time the frame
 959               ;; was made visible again, the window manager asked afresh
 960               ;; for where to put it.
 961               'iconify-frame
 962             'delete-frame)
 963           frames-to-delete)))
 964 \f
 965 ;;;; Convenience functions for accessing and interactively changing
 966 ;;;; frame parameters.
 967
 968 (defun frame-height (&optional frame)
 969   "Return number of lines available for display on FRAME.
 970 If FRAME is omitted, describe the currently selected frame."
 971   (cdr (assq 'height (frame-parameters frame))))
 972
 973 (defun frame-width (&optional frame)
 974   "Return number of columns available for display on FRAME.
 975 If FRAME is omitted, describe the currently selected frame."
 976   (cdr (assq 'width (frame-parameters frame))))
 977
 978 (defalias 'set-default-font 'set-frame-font)
 979 (defun set-frame-font (font-name &optional keep-size)
 980   "Set the font of the selected frame to FONT-NAME.
 981 When called interactively, prompt for the name of the font to use.
 982 To get the frame's current default font, use `frame-parameters'.
 983
 984 The default behavior is to keep the numbers of lines and columns in
 985 the frame, thus may change its pixel size.  If optional KEEP-SIZE is
 986 non-nil (interactively, prefix argument) the current frame size (in
 987 pixels) is kept by adjusting the numbers of the lines and columns."
 988   (interactive
 989    (let* ((completion-ignore-case t)
 990           (font (completing-read "Font name: "
 991                                  ;; x-list-fonts will fail with an error
 992                                  ;; if this frame doesn't support fonts.
 993                                  (x-list-fonts "*" nil (selected-frame))
 994                                  nil nil nil nil
 995                                  (frame-parameter nil 'font))))
 996      (list font current-prefix-arg)))
 997   (let (fht fwd)
 998     (if keep-size
 999         (setq fht (* (frame-parameter nil 'height) (frame-char-height))
1000               fwd (* (frame-parameter nil 'width)  (frame-char-width))))
1001     (modify-frame-parameters (selected-frame)
1002                              (list (cons 'font font-name)))
1003     (if keep-size
1004         (modify-frame-parameters
1005          (selected-frame)
1006          (list (cons 'height (round fht (frame-char-height)))
1007                (cons 'width (round fwd (frame-char-width)))))))
1008   (run-hooks 'after-setting-font-hook 'after-setting-font-hooks))
1009
1010 (defun set-frame-parameter (frame parameter value)
1011   "Set frame parameter PARAMETER to VALUE on FRAME.
1012 If FRAME is nil, it defaults to the selected frame.
1013 See `modify-frame-parameters'."
1014   (modify-frame-parameters frame (list (cons parameter value))))
1015
1016 (defun set-background-color (color-name)
1017   "Set the background color of the selected frame to COLOR-NAME.
1018 When called interactively, prompt for the name of the color to use.
1019 To get the frame's current background color, use `frame-parameters'."
1020   (interactive (list (facemenu-read-color "Background color: ")))
1021   (modify-frame-parameters (selected-frame)
1022                            (list (cons 'background-color color-name)))
1023   (or window-system
1024       (face-set-after-frame-default (selected-frame))))
1025
1026 (defun set-foreground-color (color-name)
1027   "Set the foreground color of the selected frame to COLOR-NAME.
1028 When called interactively, prompt for the name of the color to use.
1029 To get the frame's current foreground color, use `frame-parameters'."
1030   (interactive (list (facemenu-read-color "Foreground color: ")))
1031   (modify-frame-parameters (selected-frame)
1032                            (list (cons 'foreground-color color-name)))
1033   (or window-system
1034       (face-set-after-frame-default (selected-frame))))
1035
1036 (defun set-cursor-color (color-name)
1037   "Set the text cursor color of the selected frame to COLOR-NAME.
1038 When called interactively, prompt for the name of the color to use.
1039 To get the frame's current cursor color, use `frame-parameters'."
1040   (interactive (list (facemenu-read-color "Cursor color: ")))
1041   (modify-frame-parameters (selected-frame)
1042                            (list (cons 'cursor-color color-name))))
1043
1044 (defun set-mouse-color (color-name)
1045   "Set the color of the mouse pointer of the selected frame to COLOR-NAME.
1046 When called interactively, prompt for the name of the color to use.
1047 To get the frame's current mouse color, use `frame-parameters'."
1048   (interactive (list (facemenu-read-color "Mouse color: ")))
1049   (modify-frame-parameters (selected-frame)
1050                            (list (cons 'mouse-color
1051                                        (or color-name
1052                                            (cdr (assq 'mouse-color
1053                                                       (frame-parameters))))))))
1054
1055 (defun set-border-color (color-name)
1056   "Set the color of the border of the selected frame to COLOR-NAME.
1057 When called interactively, prompt for the name of the color to use.
1058 To get the frame's current border color, use `frame-parameters'."
1059   (interactive (list (facemenu-read-color "Border color: ")))
1060   (modify-frame-parameters (selected-frame)
1061                            (list (cons 'border-color color-name))))
1062
1063 (defun auto-raise-mode (arg)
1064   "Toggle whether or not the selected frame should auto-raise.
1065 With arg, turn auto-raise mode on if and only if arg is positive.
1066 Note that this controls Emacs's own auto-raise feature.
1067 Some window managers allow you to enable auto-raise for certain windows.
1068 You can use that for Emacs windows if you wish, but if you do,
1069 that is beyond the control of Emacs and this command has no effect on it."
1070   (interactive "P")
1071   (if (null arg)
1072       (setq arg
1073             (if (cdr (assq 'auto-raise (frame-parameters (selected-frame))))
1074                 -1 1)))
1075   (if (> arg 0)
1076       (raise-frame (selected-frame)))
1077   (modify-frame-parameters (selected-frame)
1078                            (list (cons 'auto-raise (> arg 0)))))
1079
1080 (defun auto-lower-mode (arg)
1081   "Toggle whether or not the selected frame should auto-lower.
1082 With arg, turn auto-lower mode on if and only if arg is positive.
1083 Note that this controls Emacs's own auto-lower feature.
1084 Some window managers allow you to enable auto-lower for certain windows.
1085 You can use that for Emacs windows if you wish, but if you do,
1086 that is beyond the control of Emacs and this command has no effect on it."
1087   (interactive "P")
1088   (if (null arg)
1089       (setq arg
1090             (if (cdr (assq 'auto-lower (frame-parameters (selected-frame))))
1091                 -1 1)))
1092   (modify-frame-parameters (selected-frame)
1093                            (list (cons 'auto-lower (> arg 0)))))
1094 (defun set-frame-name (name)
1095   "Set the name of the selected frame to NAME.
1096 When called interactively, prompt for the name of the frame.
1097 The frame name is displayed on the modeline if the terminal displays only
1098 one frame, otherwise the name is displayed on the frame's caption bar."
1099   (interactive "sFrame name: ")
1100   (modify-frame-parameters (selected-frame)
1101                            (list (cons 'name name))))
1102
1103 (defun frame-current-scroll-bars (&optional frame)
1104   "Return the current scroll-bar settings in frame FRAME.
1105 Value is a cons (VERTICAL . HORIZ0NTAL) where VERTICAL specifies the
1106 current location of the vertical scroll-bars (left, right, or nil),
1107 and HORIZONTAL specifies the current location of the horizontal scroll
1108 bars (top, bottom, or nil)."
1109   (let ((vert (frame-parameter frame 'vertical-scroll-bars))
1110         (hor nil))
1111     (unless (memq vert '(left right nil))
1112       (setq vert default-frame-scroll-bars))
1113     (cons vert hor)))
1114 \f
1115 ;;;; Frame/display capabilities.
1116 (defun selected-terminal ()
1117   "Return the terminal that is now selected."
1118   (frame-terminal (selected-frame)))
1119
1120 (defun display-mouse-p (&optional display)
1121   "Return non-nil if DISPLAY has a mouse available.
1122 DISPLAY can be a display name, a frame, or nil (meaning the selected
1123 frame's display)."
1124   (let ((frame-type (framep-on-display display)))
1125     (cond
1126      ((eq frame-type 'pc)
1127       (msdos-mouse-p))
1128      ((eq system-type 'windows-nt)
1129       (with-no-warnings
1130        (> w32-num-mouse-buttons 0)))
1131      ((memq frame-type '(x mac))
1132       t)    ;; We assume X and Mac *always* have a pointing device
1133      (t
1134       (or (and (featurep 'xt-mouse)
1135                xterm-mouse-mode)
1136           ;; t-mouse is distributed with the GPM package.  It doesn't have
1137           ;; a toggle.
1138           (featurep 't-mouse))))))
1139
1140 (defun display-popup-menus-p (&optional display)
1141   "Return non-nil if popup menus are supported on DISPLAY.
1142 DISPLAY can be a display name, a frame, or nil (meaning the selected
1143 frame's display).
1144 Support for popup menus requires that the mouse be available."
1145   (and
1146    (let ((frame-type (framep-on-display display)))
1147      (memq frame-type '(x w32 pc mac)))
1148    (display-mouse-p display)))
1149
1150 (defun display-graphic-p (&optional display)
1151   "Return non-nil if DISPLAY is a graphic display.
1152 Graphical displays are those which are capable of displaying several
1153 frames and several different fonts at once.  This is true for displays
1154 that use a window system such as X, and false for text-only terminals.
1155 DISPLAY can be a display name, a frame, or nil (meaning the selected
1156 frame's display)."
1157   (not (null (memq (framep-on-display display) '(x w32 mac)))))
1158
1159 (defun display-images-p (&optional display)
1160   "Return non-nil if DISPLAY can display images.
1161
1162 DISPLAY can be a display name, a frame, or nil (meaning the selected
1163 frame's display)."
1164   (and (display-graphic-p display)
1165        (fboundp 'image-mask-p)
1166        (fboundp 'image-size)))
1167
1168 (defalias 'display-multi-frame-p 'display-graphic-p)
1169 (defalias 'display-multi-font-p 'display-graphic-p)
1170
1171 (defun display-selections-p (&optional display)
1172   "Return non-nil if DISPLAY supports selections.
1173 A selection is a way to transfer text or other data between programs
1174 via special system buffers called `selection' or `cut buffer' or
1175 `clipboard'.
1176 DISPLAY can be a display name, a frame, or nil (meaning the selected
1177 frame's display)."
1178   (let ((frame-type (framep-on-display display)))
1179     (cond
1180      ((eq frame-type 'pc)
1181       ;; MS-DOG frames support selections when Emacs runs inside
1182       ;; the Windows' DOS Box.
1183       (with-no-warnings
1184        (not (null dos-windows-version))))
1185      ((memq frame-type '(x w32 mac))
1186       t)    ;; FIXME?
1187      (t
1188       nil))))
1189
1190 (defun display-screens (&optional display)
1191   "Return the number of screens associated with DISPLAY."
1192   (let ((frame-type (framep-on-display display)))
1193     (cond
1194      ((memq frame-type '(x w32 mac))
1195       (x-display-screens display))
1196      (t
1197       1))))
1198
1199 (defun display-pixel-height (&optional display)
1200   "Return the height of DISPLAY's screen in pixels.
1201 For character terminals, each character counts as a single pixel."
1202   (let ((frame-type (framep-on-display display)))
1203     (cond
1204      ((memq frame-type '(x w32 mac))
1205       (x-display-pixel-height display))
1206      (t
1207       (frame-height (if (framep display) display (selected-frame)))))))
1208
1209 (defun display-pixel-width (&optional display)
1210   "Return the width of DISPLAY's screen in pixels.
1211 For character terminals, each character counts as a single pixel."
1212   (let ((frame-type (framep-on-display display)))
1213     (cond
1214      ((memq frame-type '(x w32 mac))
1215       (x-display-pixel-width display))
1216      (t
1217       (frame-width (if (framep display) display (selected-frame)))))))
1218
1219 (defcustom display-mm-dimensions-alist nil
1220   "Alist for specifying screen dimensions in millimeters.
1221 The dimensions will be used for `display-mm-height' and
1222 `display-mm-width' if defined for the respective display.
1223
1224 Each element of the alist has the form (display . (width . height)),
1225 e.g. (\":0.0\" . (287 . 215)).
1226
1227 If `display' equals t, it specifies dimensions for all graphical
1228 displays not explicitely specified."
1229   :version "22.1"
1230   :type '(alist :key-type (choice (string :tag "Display name")
1231                                   (const :tag "Default" t))
1232                 :value-type (cons :tag "Dimensions"
1233                                   (integer :tag "Width")
1234                                   (integer :tag "Height")))
1235   :group 'frames)
1236
1237 (defun display-mm-height (&optional display)
1238   "Return the height of DISPLAY's screen in millimeters.
1239 System values can be overriden by `display-mm-dimensions-alist'.
1240 If the information is unavailable, value is nil."
1241   (and (memq (framep-on-display display) '(x w32 mac))
1242        (or (cddr (assoc (or display (frame-parameter nil 'display))
1243                         display-mm-dimensions-alist))
1244            (cddr (assoc t display-mm-dimensions-alist))
1245            (x-display-mm-height display))))
1246
1247 (defun display-mm-width (&optional display)
1248   "Return the width of DISPLAY's screen in millimeters.
1249 System values can be overriden by `display-mm-dimensions-alist'.
1250 If the information is unavailable, value is nil."
1251   (and (memq (framep-on-display display) '(x w32 mac))
1252        (or (cadr (assoc (or display (frame-parameter nil 'display))
1253                         display-mm-dimensions-alist))
1254            (cadr (assoc t display-mm-dimensions-alist))
1255            (x-display-mm-width display))))
1256
1257 (defun display-backing-store (&optional display)
1258   "Return the backing store capability of DISPLAY's screen.
1259 The value may be `always', `when-mapped', `not-useful', or nil if
1260 the question is inapplicable to a certain kind of display."
1261   (let ((frame-type (framep-on-display display)))
1262     (cond
1263      ((memq frame-type '(x w32 mac))
1264       (x-display-backing-store display))
1265      (t
1266       'not-useful))))
1267
1268 (defun display-save-under (&optional display)
1269   "Return non-nil if DISPLAY's screen supports the SaveUnder feature."
1270   (let ((frame-type (framep-on-display display)))
1271     (cond
1272      ((memq frame-type '(x w32 mac))
1273       (x-display-save-under display))
1274      (t
1275       'not-useful))))
1276
1277 (defun display-planes (&optional display)
1278   "Return the number of planes supported by DISPLAY."
1279   (let ((frame-type (framep-on-display display)))
1280     (cond
1281      ((memq frame-type '(x w32 mac))
1282       (x-display-planes display))
1283      ((eq frame-type 'pc)
1284       4)
1285      (t
1286       (truncate (log (length (tty-color-alist)) 2))))))
1287
1288 (defun display-color-cells (&optional display)
1289   "Return the number of color cells supported by DISPLAY."
1290   (let ((frame-type (framep-on-display display)))
1291     (cond
1292      ((memq frame-type '(x w32 mac))
1293       (x-display-color-cells display))
1294      ((eq frame-type 'pc)
1295       16)
1296      (t
1297       (tty-display-color-cells display)))))
1298
1299 (defun display-visual-class (&optional display)
1300   "Returns the visual class of DISPLAY.
1301 The value is one of the symbols `static-gray', `gray-scale',
1302 `static-color', `pseudo-color', `true-color', or `direct-color'."
1303   (let ((frame-type (framep-on-display display)))
1304     (cond
1305      ((memq frame-type '(x w32 mac))
1306       (x-display-visual-class display))
1307      ((and (memq frame-type '(pc t))
1308            (tty-display-color-p display))
1309       'static-color)
1310      (t
1311       'static-gray))))
1312
1313 \f
1314 ;;;; Aliases for backward compatibility with Emacs 18.
1315 (define-obsolete-function-alias 'screen-height 'frame-height) ;before 19.15
1316 (define-obsolete-function-alias 'screen-width 'frame-width) ;before 19.15
1317
1318 (defun set-screen-width (cols &optional pretend)
1319   "Change the size of the screen to COLS columns.
1320 Optional second arg non-nil means that redisplay should use COLS columns
1321 but that the idea of the actual width of the frame should not be changed.
1322 This function is provided only for compatibility with Emacs 18."
1323   (set-frame-width (selected-frame) cols pretend))
1324
1325 (defun set-screen-height (lines &optional pretend)
1326   "Change the height of the screen to LINES lines.
1327 Optional second arg non-nil means that redisplay should use LINES lines
1328 but that the idea of the actual height of the screen should not be changed.
1329 This function is provided only for compatibility with Emacs 18."
1330   (set-frame-height (selected-frame) lines pretend))
1331
1332 (defun delete-other-frames (&optional frame)
1333   "Delete all frames except FRAME.
1334 If FRAME uses another frame's minibuffer, the minibuffer frame is
1335 left untouched.  FRAME nil or omitted means use the selected frame."
1336   (interactive)
1337   (unless frame
1338     (setq frame (selected-frame)))
1339   (let* ((mini-frame (window-frame (minibuffer-window frame)))
1340          (frames (delq mini-frame (delq frame (frame-list)))))
1341     ;; Delete mon-minibuffer-only frames first, because `delete-frame'
1342     ;; signals an error when trying to delete a mini-frame that's
1343     ;; still in use by another frame.
1344     (dolist (frame frames)
1345       (unless (eq (frame-parameter frame 'minibuffer) 'only)
1346         (delete-frame frame)))
1347     ;; Delete minibuffer-only frames.
1348     (dolist (frame frames)
1349       (when (eq (frame-parameter frame 'minibuffer) 'only)
1350         (delete-frame frame)))))
1351
1352 (make-obsolete 'set-screen-width 'set-frame-width) ;before 19.15
1353 (make-obsolete 'set-screen-height 'set-frame-height) ;before 19.15
1354
1355 ;; miscellaneous obsolescence declarations
1356 (define-obsolete-variable-alias 'delete-frame-hook
1357     'delete-frame-functions "22.1")
1358
1359 \f
1360 ;; Highlighting trailing whitespace.
1361
1362 (make-variable-buffer-local 'show-trailing-whitespace)
1363
1364 (defcustom show-trailing-whitespace nil
1365   "*Non-nil means highlight trailing whitespace.
1366 This is done in the face `trailing-whitespace'."
1367   :type 'boolean
1368   :group 'whitespace-faces)
1369
1370
1371 \f
1372 ;; Scrolling
1373
1374 (defgroup scrolling nil
1375   "Scrolling windows."
1376   :version "21.1"
1377   :group 'frames)
1378
1379 (defcustom auto-hscroll-mode t
1380   "*Allow or disallow automatic scrolling windows horizontally.
1381 If non-nil, windows are automatically scrolled horizontally to make
1382 point visible."
1383   :version "21.1"
1384   :type 'boolean
1385   :group 'scrolling)
1386 (defvaralias 'automatic-hscrolling 'auto-hscroll-mode)
1387
1388 \f
1389 ;; Blinking cursor
1390
1391 (defgroup cursor nil
1392   "Displaying text cursors."
1393   :version "21.1"
1394   :group 'frames)
1395
1396 (defcustom blink-cursor-delay 0.5
1397   "*Seconds of idle time after which cursor starts to blink."
1398   :type 'number
1399   :group 'cursor)
1400
1401 (defcustom blink-cursor-interval 0.5
1402   "*Length of cursor blink interval in seconds."
1403   :type 'number
1404   :group 'cursor)
1405
1406 (defvar blink-cursor-idle-timer nil
1407   "Timer started after `blink-cursor-delay' seconds of Emacs idle time.
1408 The function `blink-cursor-start' is called when the timer fires.")
1409
1410 (defvar blink-cursor-timer nil
1411   "Timer started from `blink-cursor-start'.
1412 This timer calls `blink-cursor-timer-function' every
1413 `blink-cursor-interval' seconds.")
1414
1415 (defun blink-cursor-start ()
1416   "Timer function called from the timer `blink-cursor-idle-timer'.
1417 This starts the timer `blink-cursor-timer', which makes the cursor blink
1418 if appropriate.  It also arranges to cancel that timer when the next
1419 command starts, by installing a pre-command hook."
1420   (when (null blink-cursor-timer)
1421     ;; Set up the timer first, so that if this signals an error,
1422     ;; blink-cursor-end is not added to pre-command-hook.
1423     (setq blink-cursor-timer
1424           (run-with-timer blink-cursor-interval blink-cursor-interval
1425                           'blink-cursor-timer-function))
1426     (add-hook 'pre-command-hook 'blink-cursor-end)
1427     (internal-show-cursor nil nil)))
1428
1429 (defun blink-cursor-timer-function ()
1430   "Timer function of timer `blink-cursor-timer'."
1431   (internal-show-cursor nil (not (internal-show-cursor-p))))
1432
1433 (defun blink-cursor-end ()
1434   "Stop cursor blinking.
1435 This is installed as a pre-command hook by `blink-cursor-start'.
1436 When run, it cancels the timer `blink-cursor-timer' and removes
1437 itself as a pre-command hook."
1438   (remove-hook 'pre-command-hook 'blink-cursor-end)
1439   (internal-show-cursor nil t)
1440   (when blink-cursor-timer
1441     (cancel-timer blink-cursor-timer)
1442     (setq blink-cursor-timer nil)))
1443
1444 (define-minor-mode blink-cursor-mode
1445   "Toggle blinking cursor mode.
1446 With a numeric argument, turn blinking cursor mode on if ARG is positive,
1447 otherwise turn it off.  When blinking cursor mode is enabled, the
1448 cursor of the selected window blinks.
1449
1450 Note that this command is effective only when Emacs
1451 displays through a window system, because then Emacs does its own
1452 cursor display.  On a text-only terminal, this is not implemented."
1453   :init-value (not (or noninteractive
1454                        no-blinking-cursor
1455                        (eq system-type 'ms-dos)
1456                        (not (memq window-system '(x w32 mac)))))
1457   :initialize 'custom-initialize-safe-default
1458   :group 'cursor
1459   :global t
1460   (if blink-cursor-idle-timer (cancel-timer blink-cursor-idle-timer))
1461   (setq blink-cursor-idle-timer nil)
1462   (blink-cursor-end)
1463   (when blink-cursor-mode
1464     ;; Hide the cursor.
1465     ;;(internal-show-cursor nil nil)
1466     (setq blink-cursor-idle-timer
1467           (run-with-idle-timer blink-cursor-delay
1468                                blink-cursor-delay
1469                                'blink-cursor-start))))
1470
1471 (define-obsolete-variable-alias 'blink-cursor 'blink-cursor-mode "22.1")
1472 \f
1473 ;; Hourglass pointer
1474
1475 (defcustom display-hourglass t
1476   "*Non-nil means show an hourglass pointer, when Emacs is busy.
1477 This feature only works when on a window system that can change
1478 cursor shapes."
1479   :type 'boolean
1480   :group 'cursor)
1481
1482 (defcustom hourglass-delay 1
1483   "*Seconds to wait before displaying an hourglass pointer when Emacs is busy."
1484   :type 'number
1485   :group 'cursor)
1486
1487 \f
1488 (defcustom cursor-in-non-selected-windows t
1489   "*Non-nil means show a hollow box cursor in non-selected windows.
1490 If nil, don't show a cursor except in the selected window.
1491 Use Custom to set this variable to get the display updated."
1492   :tag "Cursor In Non-selected Windows"
1493   :type 'boolean
1494   :group 'cursor
1495   :set #'(lambda (symbol value)
1496            (set-default symbol value)
1497            (force-mode-line-update t)))
1498
1499 \f
1500 ;;;; Key bindings
1501
1502 (define-key ctl-x-5-map "2" 'make-frame-command)
1503 (define-key ctl-x-5-map "1" 'delete-other-frames)
1504 (define-key ctl-x-5-map "0" 'delete-frame)
1505 (define-key ctl-x-5-map "o" 'other-frame)
1506
1507 (provide 'frame)
1508
1509 ;; arch-tag: 82979c70-b8f2-4306-b2ad-ddbd6b328b56
1510 ;;; frame.el ends here