code.delx.au - gnu-emacs/blob - lisp/tar-mode.el

   1 ;;; tar-mode.el --- simple editing of tar files from GNU emacs
   2
   3 ;; Copyright (C) 1990, 1991, 1993, 1994, 1995, 1996, 1997, 1998, 1999,
   4 ;;   2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Jamie Zawinski <jwz@lucid.com>
   7 ;; Maintainer: FSF
   8 ;; Created: 04 Apr 1990
   9 ;; Keywords: unix
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 3, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  26 ;; Boston, MA 02110-1301, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; This package attempts to make dealing with Unix 'tar' archives easier.
  31 ;; When this code is loaded, visiting a file whose name ends in '.tar' will
  32 ;; cause the contents of that archive file to be displayed in a Dired-like
  33 ;; listing.  It is then possible to use the customary Dired keybindings to
  34 ;; extract sub-files from that archive, either by reading them into their own
  35 ;; editor buffers, or by copying them directly to arbitrary files on disk.
  36 ;; It is also possible to delete sub-files from within the tar file and write
  37 ;; the modified archive back to disk, or to edit sub-files within the archive
  38 ;; and re-insert the modified files into the archive.  See the documentation
  39 ;; string of tar-mode for more info.
  40
  41 ;; This code now understands the extra fields that GNU tar adds to tar files.
  42
  43 ;; This interacts correctly with "uncompress.el" in the Emacs library,
  44 ;; which you get with
  45 ;;
  46 ;;  (autoload 'uncompress-while-visiting "uncompress")
  47 ;;  (setq auto-mode-alist (cons '("\\.Z$" . uncompress-while-visiting)
  48 ;;                         auto-mode-alist))
  49 ;;
  50 ;; Do not attempt to use tar-mode.el with crypt.el, you will lose.
  51
  52 ;;    ***************   TO DO   ***************
  53 ;;
  54 ;; o  chmod should understand "a+x,og-w".
  55 ;;
  56 ;; o  It's not possible to add a NEW file to a tar archive; not that
  57 ;;    important, but still...
  58 ;;
  59 ;; o  The code is less efficient that it could be - in a lot of places, I
  60 ;;    pull a 512-character string out of the buffer and parse it, when I could
  61 ;;    be parsing it in place, not garbaging a string.  Should redo that.
  62 ;;
  63 ;; o  I'd like a command that searches for a string/regexp in every subfile
  64 ;;    of an archive, where <esc> would leave you in a subfile-edit buffer.
  65 ;;    (Like the Meta-R command of the Zmacs mail reader.)
  66 ;;
  67 ;; o  Sometimes (but not always) reverting the tar-file buffer does not
  68 ;;    re-grind the listing, and you are staring at the binary tar data.
  69 ;;    Typing 'g' again immediately after that will always revert and re-grind
  70 ;;    it, though.  I have no idea why this happens.
  71 ;;
  72 ;; o  Tar-mode interacts poorly with crypt.el and zcat.el because the tar
  73 ;;    write-file-hook actually writes the file.  Instead it should remove the
  74 ;;    header (and conspire to put it back afterwards) so that other write-file
  75 ;;    hooks which frob the buffer have a chance to do their dirty work.  There
  76 ;;    might be a problem if the tar write-file-hook does not come *first* on
  77 ;;    the list.
  78 ;;
  79 ;; o  Block files, sparse files, continuation files, and the various header
  80 ;;    types aren't editable.  Actually I don't know that they work at all.
  81
  82 ;; Rationale:
  83
  84 ;; Why does tar-mode edit the file itself instead of using tar?
  85
  86 ;; That means that you can edit tar files which you don't have room for
  87 ;; on your local disk.
  88
  89 ;; I don't know about recent features in gnu tar, but old versions of tar
  90 ;; can't replace a file in the middle of a tar file with a new version.
  91 ;; Tar-mode can.  I don't think tar can do things like chmod the subfiles.
  92 ;; An implementation which involved unpacking and repacking the file into
  93 ;; some scratch directory would be very wasteful, and wouldn't be able to
  94 ;; preserve the file owners.
  95
  96 ;;; Code:
  97
  98 (defgroup tar nil
  99   "Simple editing of tar files."
 100   :prefix "tar-"
 101   :group 'data)
 102
 103 (defcustom tar-anal-blocksize 20
 104   "The blocksize of tar files written by Emacs, or nil, meaning don't care.
 105 The blocksize of a tar file is not really the size of the blocks; rather, it is
 106 the number of blocks written with one system call.  When tarring to a tape,
 107 this is the size of the *tape* blocks, but when writing to a file, it doesn't
 108 matter much.  The only noticeable difference is that if a tar file does not
 109 have a blocksize of 20, tar will tell you that; all this really controls is
 110 how many null padding bytes go on the end of the tar file."
 111   :type '(choice integer (const nil))
 112   :group 'tar)
 113
 114 (defcustom tar-update-datestamp nil
 115   "Non-nil means Tar mode should play fast and loose with sub-file datestamps.
 116 If this is true, then editing and saving a tar file entry back into its
 117 tar file will update its datestamp.  If false, the datestamp is unchanged.
 118 You may or may not want this - it is good in that you can tell when a file
 119 in a tar archive has been changed, but it is bad for the same reason that
 120 editing a file in the tar archive at all is bad - the changed version of
 121 the file never exists on disk."
 122   :type 'boolean
 123   :group 'tar)
 124
 125 (defcustom tar-mode-show-date nil
 126   "Non-nil means Tar mode should show the date/time of each subfile.
 127 This information is useful, but it takes screen space away from file names."
 128   :type 'boolean
 129   :group 'tar)
 130
 131 (defvar tar-parse-info nil)
 132 ;; Be sure that this variable holds byte position, not char position.
 133 (defvar tar-header-offset nil)
 134 (defvar tar-superior-buffer nil)
 135 (defvar tar-superior-descriptor nil)
 136 (defvar tar-subfile-mode nil)
 137
 138 (put 'tar-parse-info 'permanent-local t)
 139 (put 'tar-header-offset 'permanent-local t)
 140 (put 'tar-superior-buffer 'permanent-local t)
 141 (put 'tar-superior-descriptor 'permanent-local t)
 142 \f
 143 (defmacro tar-setf (form val)
 144   "A mind-numbingly simple implementation of setf."
 145   (let ((mform (macroexpand form (and (boundp 'byte-compile-macro-environment)
 146                                       byte-compile-macro-environment))))
 147     (cond ((symbolp mform) (list 'setq mform val))
 148           ((not (consp mform)) (error "can't setf %s" form))
 149           ((eq (car mform) 'aref)
 150            (list 'aset (nth 1 mform) (nth 2 mform) val))
 151           ((eq (car mform) 'car)
 152            (list 'setcar (nth 1 mform) val))
 153           ((eq (car mform) 'cdr)
 154            (list 'setcdr (nth 1 mform) val))
 155           (t (error "don't know how to setf %s" form)))))
 156 \f
 157 ;;; down to business.
 158
 159 (defmacro make-tar-header (name mode uid git size date ck lt ln
 160                            magic uname gname devmaj devmin)
 161   (list 'vector name mode uid git size date ck lt ln
 162         magic uname gname devmaj devmin))
 163
 164 (defmacro tar-header-name (x) (list 'aref x 0))
 165 (defmacro tar-header-mode (x) (list 'aref x 1))
 166 (defmacro tar-header-uid  (x) (list 'aref x 2))
 167 (defmacro tar-header-gid  (x) (list 'aref x 3))
 168 (defmacro tar-header-size (x) (list 'aref x 4))
 169 (defmacro tar-header-date (x) (list 'aref x 5))
 170 (defmacro tar-header-checksum  (x) (list 'aref x 6))
 171 (defmacro tar-header-link-type (x) (list 'aref x 7))
 172 (defmacro tar-header-link-name (x) (list 'aref x 8))
 173 (defmacro tar-header-magic (x) (list 'aref x 9))
 174 (defmacro tar-header-uname (x) (list 'aref x 10))
 175 (defmacro tar-header-gname (x) (list 'aref x 11))
 176 (defmacro tar-header-dmaj (x) (list 'aref x 12))
 177 (defmacro tar-header-dmin (x) (list 'aref x 13))
 178
 179 (defmacro make-tar-desc (data-start tokens)
 180   (list 'cons data-start tokens))
 181
 182 (defmacro tar-desc-data-start (x) (list 'car x))
 183 (defmacro tar-desc-tokens     (x) (list 'cdr x))
 184
 185 (defconst tar-name-offset 0)
 186 (defconst tar-mode-offset (+ tar-name-offset 100))
 187 (defconst tar-uid-offset  (+ tar-mode-offset 8))
 188 (defconst tar-gid-offset  (+ tar-uid-offset 8))
 189 (defconst tar-size-offset (+ tar-gid-offset 8))
 190 (defconst tar-time-offset (+ tar-size-offset 12))
 191 (defconst tar-chk-offset  (+ tar-time-offset 12))
 192 (defconst tar-linkp-offset (+ tar-chk-offset 8))
 193 (defconst tar-link-offset (+ tar-linkp-offset 1))
 194 ;;; GNU-tar specific slots.
 195 (defconst tar-magic-offset (+ tar-link-offset 100))
 196 (defconst tar-uname-offset (+ tar-magic-offset 8))
 197 (defconst tar-gname-offset (+ tar-uname-offset 32))
 198 (defconst tar-dmaj-offset (+ tar-gname-offset 32))
 199 (defconst tar-dmin-offset (+ tar-dmaj-offset 8))
 200 (defconst tar-end-offset (+ tar-dmin-offset 8))
 201
 202 (defun tar-header-block-tokenize (string)
 203   "Return a `tar-header' structure.
 204 This is a list of name, mode, uid, gid, size,
 205 write-date, checksum, link-type, and link-name."
 206   (cond ((< (length string) 512) nil)
 207         (;(some 'plusp string)           ; <-- oops, massive cycle hog!
 208          (or (not (= 0 (aref string 0))) ; This will do.
 209              (not (= 0 (aref string 101))))
 210          (let* ((name-end (1- tar-mode-offset))
 211                 (link-end (1- tar-magic-offset))
 212                 (uname-end (1- tar-gname-offset))
 213                 (gname-end (1- tar-dmaj-offset))
 214                 (link-p (aref string tar-linkp-offset))
 215                 (magic-str (substring string tar-magic-offset (1- tar-uname-offset)))
 216                 (uname-valid-p (or (string= "ustar  " magic-str) (string= "GNUtar " magic-str)))
 217                 name linkname
 218                 (nulsexp   "[^\000]*\000"))
 219            (when (string-match nulsexp string tar-name-offset)
 220              (setq name-end (min name-end (1- (match-end 0)))))
 221            (when (string-match nulsexp string tar-link-offset)
 222              (setq link-end (min link-end (1- (match-end 0)))))
 223            (when (string-match nulsexp string tar-uname-offset)
 224              (setq uname-end (min uname-end (1- (match-end 0)))))
 225            (when (string-match nulsexp string tar-gname-offset)
 226              (setq gname-end (min gname-end (1- (match-end 0)))))
 227            (setq name (substring string tar-name-offset name-end)
 228                  link-p (if (or (= link-p 0) (= link-p ?0))
 229                             nil
 230                           (- link-p ?0)))
 231            (setq linkname (substring string tar-link-offset link-end))
 232            (if default-enable-multibyte-characters
 233                (setq name
 234                      (decode-coding-string name
 235                                            (or file-name-coding-system
 236                                                default-file-name-coding-system
 237                                                'undecided))
 238                      linkname
 239                      (decode-coding-string linkname
 240                                            (or file-name-coding-system
 241                                                default-file-name-coding-system
 242                                                'undecided))))
 243            (if (and (null link-p) (string-match "/\\'" name)) (setq link-p 5)) ; directory
 244            (make-tar-header
 245              name
 246              (tar-parse-octal-integer string tar-mode-offset tar-uid-offset)
 247              (tar-parse-octal-integer string tar-uid-offset tar-gid-offset)
 248              (tar-parse-octal-integer string tar-gid-offset tar-size-offset)
 249              (tar-parse-octal-integer string tar-size-offset tar-time-offset)
 250              (tar-parse-octal-long-integer string tar-time-offset tar-chk-offset)
 251              (tar-parse-octal-integer string tar-chk-offset tar-linkp-offset)
 252              link-p
 253              linkname
 254              uname-valid-p
 255              (and uname-valid-p (substring string tar-uname-offset uname-end))
 256              (and uname-valid-p (substring string tar-gname-offset gname-end))
 257              (tar-parse-octal-integer string tar-dmaj-offset tar-dmin-offset)
 258              (tar-parse-octal-integer string tar-dmin-offset tar-end-offset)
 259              )))
 260         (t 'empty-tar-block)))
 261
 262
 263 (defun tar-parse-octal-integer (string &optional start end)
 264   (if (null start) (setq start 0))
 265   (if (null end) (setq end (length string)))
 266   (if (= (aref string start) 0)
 267       0
 268     (let ((n 0))
 269       (while (< start end)
 270         (setq n (if (< (aref string start) ?0) n
 271                   (+ (* n 8) (- (aref string start) ?0)))
 272               start (1+ start)))
 273       n)))
 274
 275 (defun tar-parse-octal-long-integer (string &optional start end)
 276   (if (null start) (setq start 0))
 277   (if (null end) (setq end (length string)))
 278   (if (= (aref string start) 0)
 279       (list 0 0)
 280     (let ((lo 0)
 281           (hi 0))
 282       (while (< start end)
 283         (if (>= (aref string start) ?0)
 284             (setq lo (+ (* lo 8) (- (aref string start) ?0))
 285                   hi (+ (* hi 8) (ash lo -16))
 286                   lo (logand lo 65535)))
 287         (setq start (1+ start)))
 288       (list hi lo))))
 289
 290 (defun tar-parse-octal-integer-safe (string)
 291   (if (zerop (length string)) (error "empty string"))
 292   (mapc (lambda (c)
 293           (if (or (< c ?0) (> c ?7))
 294               (error "`%c' is not an octal digit" c)))
 295         string)
 296   (tar-parse-octal-integer string))
 297
 298
 299 (defun tar-header-block-checksum (string)
 300   "Compute and return a tar-acceptable checksum for this block."
 301   (let* ((chk-field-start tar-chk-offset)
 302          (chk-field-end (+ chk-field-start 8))
 303          (sum 0)
 304          (i 0))
 305     ;; Add up all of the characters except the ones in the checksum field.
 306     ;; Add that field as if it were filled with spaces.
 307     (while (< i chk-field-start)
 308       (setq sum (+ sum (aref string i))
 309             i (1+ i)))
 310     (setq i chk-field-end)
 311     (while (< i 512)
 312       (setq sum (+ sum (aref string i))
 313             i (1+ i)))
 314     (+ sum (* 32 8))))
 315
 316 (defun tar-header-block-check-checksum (hblock desired-checksum file-name)
 317   "Beep and print a warning if the checksum doesn't match."
 318   (if (not (= desired-checksum (tar-header-block-checksum hblock)))
 319       (progn (beep) (message "Invalid checksum for file %s!" file-name))))
 320
 321 (defun tar-clip-time-string (time)
 322   (let ((str (current-time-string time)))
 323     (concat " " (substring str 4 16) (substring str 19 24))))
 324
 325 (defun tar-grind-file-mode (mode)
 326   "Construct a `-rw--r--r--' string indicating MODE.
 327 MODE should be an integer which is a file mode value."
 328   (string
 329    (if (zerop (logand 256 mode)) ?- ?r)
 330    (if (zerop (logand 128 mode)) ?- ?w)
 331    (if (zerop (logand 1024 mode)) (if (zerop (logand  64 mode)) ?- ?x) ?s)
 332    (if (zerop (logand  32 mode)) ?- ?r)
 333    (if (zerop (logand  16 mode)) ?- ?w)
 334    (if (zerop (logand 2048 mode)) (if (zerop (logand   8 mode)) ?- ?x) ?s)
 335    (if (zerop (logand   4 mode)) ?- ?r)
 336    (if (zerop (logand   2 mode)) ?- ?w)
 337    (if (zerop (logand   1 mode)) ?- ?x)))
 338
 339 (defun tar-header-block-summarize (tar-hblock &optional mod-p)
 340   "Return a line similar to the output of `tar -vtf'."
 341   (let ((name (tar-header-name tar-hblock))
 342         (mode (tar-header-mode tar-hblock))
 343         (uid (tar-header-uid tar-hblock))
 344         (gid (tar-header-gid tar-hblock))
 345         (uname (tar-header-uname tar-hblock))
 346         (gname (tar-header-gname tar-hblock))
 347         (size (tar-header-size tar-hblock))
 348         (time (tar-header-date tar-hblock))
 349         ;; (ck (tar-header-checksum tar-hblock))
 350         (type (tar-header-link-type tar-hblock))
 351         (link-name (tar-header-link-name tar-hblock)))
 352     (format "%c%c%s %7s/%-7s %7s%s %s%s"
 353             (if mod-p ?* ? )
 354             (cond ((or (eq type nil) (eq type 0)) ?-)
 355                   ((eq type 1) ?h)      ; link
 356                   ((eq type 2) ?l)      ; symlink
 357                   ((eq type 3) ?c)      ; char special
 358                   ((eq type 4) ?b)      ; block special
 359                   ((eq type 5) ?d)      ; directory
 360                   ((eq type 6) ?p)      ; FIFO/pipe
 361                   ((eq type 20) ?*)     ; directory listing
 362                   ((eq type 28) ?L)     ; next has longname
 363                   ((eq type 29) ?M)     ; multivolume continuation
 364                   ((eq type 35) ?S)     ; sparse
 365                   ((eq type 38) ?V)     ; volume header
 366                   ((eq type 55) ?H)     ; extended pax header
 367                   (t ?\s)
 368                   )
 369             (tar-grind-file-mode mode)
 370             (if (= 0 (length uname)) uid uname)
 371             (if (= 0 (length gname)) gid gname)
 372             size
 373             (if tar-mode-show-date (tar-clip-time-string time) "")
 374             (propertize name
 375                         'mouse-face 'highlight
 376                         'help-echo "mouse-2: extract this file into a buffer")
 377             (if (or (eq type 1) (eq type 2))
 378                 (concat (if (= type 1) " ==> " " --> ") link-name)
 379               ""))))
 380
 381 (defun tar-untar-buffer ()
 382   "Extract all archive members in the tar-file into the current directory."
 383   (interactive)
 384   (let ((multibyte enable-multibyte-characters))
 385     (unwind-protect
 386         (save-restriction
 387           (widen)
 388           (set-buffer-multibyte nil)
 389           (dolist (descriptor tar-parse-info)
 390             (let* ((tokens (tar-desc-tokens descriptor))
 391                    (name (tar-header-name tokens))
 392                    (dir (file-name-directory name))
 393                    (start (+ (tar-desc-data-start descriptor)
 394                              (- tar-header-offset (point-min))))
 395                    (end (+ start (tar-header-size tokens))))
 396               (unless (file-directory-p name)
 397                 (message "Extracting %s" name)
 398                 (if (and dir (not (file-exists-p dir)))
 399                     (make-directory dir t))
 400                 (unless (file-directory-p name)
 401                   (write-region start end name))
 402                 (set-file-modes name (tar-header-mode tokens))))))
 403       (set-buffer-multibyte multibyte))))
 404
 405 (defun tar-summarize-buffer ()
 406   "Parse the contents of the tar file in the current buffer.
 407 Place a dired-like listing on the front;
 408 then narrow to it, so that only that listing
 409 is visible (and the real data of the buffer is hidden)."
 410   (let ((modified (buffer-modified-p)))
 411     (set-buffer-multibyte nil)
 412     (let* ((result '())
 413            (pos (point-min))
 414            (progress-reporter
 415             (make-progress-reporter "Parsing tar file..."
 416                                     (point-min) (max 1 (- (buffer-size) 1024))))
 417            tokens)
 418       (while (and (<= (+ pos 512) (point-max))
 419                   (not (eq 'empty-tar-block
 420                            (setq tokens
 421                                  (tar-header-block-tokenize
 422                                   (buffer-substring pos (+ pos 512)))))))
 423         (setq pos (+ pos 512))
 424         (when (equal (tar-header-name tokens) "././@LongLink")
 425           ;; This is a GNU Tar long-file-name header.
 426           (let* ((size (tar-header-size tokens))
 427                  ;; -1 so as to strip the terminating 0 byte.
 428                  (name (buffer-substring pos (+ pos size -1))))
 429             (setq pos (+ pos (ash (ash (+ 511 size) -9) 9)))
 430             (setq tokens (tar-header-block-tokenize
 431                           (buffer-substring pos (+ pos 512))))
 432             (tar-setf (tar-header-name tokens) name)
 433             (setq pos (+ pos 512))))
 434         (progress-reporter-update progress-reporter pos)
 435         (if (memq (tar-header-link-type tokens) '(20 55))
 436             ;; Foo.  There's an extra empty block after these.
 437             (setq pos (+ pos 512)))
 438         (let ((size (tar-header-size tokens)))
 439           (if (< size 0)
 440               (error "%s has size %s - corrupted"
 441                      (tar-header-name tokens) size))
 442           ;;
 443           ;; This is just too slow.  Don't really need it anyway....
 444           ;;(tar-header-block-check-checksum
 445           ;;  hblock (tar-header-block-checksum hblock)
 446           ;;  (tar-header-name tokens))
 447
 448           (push (make-tar-desc pos tokens) result)
 449
 450           (and (null (tar-header-link-type tokens))
 451                (> size 0)
 452                ;; Round up to a multiple of 512.
 453                (setq pos (+ pos (ash (ash (+ 511 size) -9) 9))))))
 454       (make-local-variable 'tar-parse-info)
 455       (setq tar-parse-info (nreverse result))
 456       ;; A tar file should end with a block or two of nulls,
 457       ;; but let's not get a fatal error if it doesn't.
 458       (if (eq tokens 'empty-tar-block)
 459           (progress-reporter-done progress-reporter)
 460         (message "Warning: premature EOF parsing tar file")))
 461     (set-buffer-multibyte default-enable-multibyte-characters)
 462     (goto-char (point-min))
 463     (let ((inhibit-read-only t))
 464       ;; Collect summary lines and insert them all at once since tar files
 465       ;; can be pretty big.
 466       (let ((total-summaries
 467              (mapconcat
 468               (lambda (tar-desc)
 469                 (tar-header-block-summarize (tar-desc-tokens tar-desc)))
 470               tar-parse-info
 471               "\n")))
 472         (insert total-summaries "\n"))
 473       (narrow-to-region (point-min) (point))
 474       (set (make-local-variable 'tar-header-offset) (position-bytes (point)))
 475       (goto-char (point-min))
 476       (restore-buffer-modified-p modified))))
 477 \f
 478 (defvar tar-mode-map
 479   (let ((map (make-keymap)))
 480     (suppress-keymap map)
 481     (define-key map " " 'tar-next-line)
 482     (define-key map "C" 'tar-copy)
 483     (define-key map "d" 'tar-flag-deleted)
 484     (define-key map "\^D" 'tar-flag-deleted)
 485     (define-key map "e" 'tar-extract)
 486     (define-key map "f" 'tar-extract)
 487     (define-key map "\C-m" 'tar-extract)
 488     (define-key map [mouse-2] 'tar-mouse-extract)
 489     (define-key map "g" 'revert-buffer)
 490     (define-key map "h" 'describe-mode)
 491     (define-key map "n" 'tar-next-line)
 492     (define-key map "\^N" 'tar-next-line)
 493     (define-key map [down] 'tar-next-line)
 494     (define-key map "o" 'tar-extract-other-window)
 495     (define-key map "p" 'tar-previous-line)
 496     (define-key map "q" 'quit-window)
 497     (define-key map "\^P" 'tar-previous-line)
 498     (define-key map [up] 'tar-previous-line)
 499     (define-key map "R" 'tar-rename-entry)
 500     (define-key map "u" 'tar-unflag)
 501     (define-key map "v" 'tar-view)
 502     (define-key map "x" 'tar-expunge)
 503     (define-key map "\177" 'tar-unflag-backwards)
 504     (define-key map "E" 'tar-extract-other-window)
 505     (define-key map "M" 'tar-chmod-entry)
 506     (define-key map "G" 'tar-chgrp-entry)
 507     (define-key map "O" 'tar-chown-entry)
 508
 509     ;; Make menu bar items.
 510
 511     ;; Get rid of the Edit menu bar item to save space.
 512     (define-key map [menu-bar edit] 'undefined)
 513
 514     (define-key map [menu-bar immediate]
 515       (cons "Immediate" (make-sparse-keymap "Immediate")))
 516
 517     (define-key map [menu-bar immediate view]
 518       '("View This File" . tar-view))
 519     (define-key map [menu-bar immediate display]
 520       '("Display in Other Window" . tar-display-other-window))
 521     (define-key map [menu-bar immediate find-file-other-window]
 522       '("Find in Other Window" . tar-extract-other-window))
 523     (define-key map [menu-bar immediate find-file]
 524       '("Find This File" . tar-extract))
 525
 526     (define-key map [menu-bar mark]
 527       (cons "Mark" (make-sparse-keymap "Mark")))
 528
 529     (define-key map [menu-bar mark unmark-all]
 530       '("Unmark All" . tar-clear-modification-flags))
 531     (define-key map [menu-bar mark deletion]
 532       '("Flag" . tar-flag-deleted))
 533     (define-key map [menu-bar mark unmark]
 534       '("Unflag" . tar-unflag))
 535
 536     (define-key map [menu-bar operate]
 537       (cons "Operate" (make-sparse-keymap "Operate")))
 538
 539     (define-key map [menu-bar operate chown]
 540       '("Change Owner..." . tar-chown-entry))
 541     (define-key map [menu-bar operate chgrp]
 542       '("Change Group..." . tar-chgrp-entry))
 543     (define-key map [menu-bar operate chmod]
 544       '("Change Mode..." . tar-chmod-entry))
 545     (define-key map [menu-bar operate rename]
 546       '("Rename to..." . tar-rename-entry))
 547     (define-key map [menu-bar operate copy]
 548       '("Copy to..." . tar-copy))
 549     (define-key map [menu-bar operate expunge]
 550       '("Expunge Marked Files" . tar-expunge))
 551
 552     map)
 553   "Local keymap for Tar mode listings.")
 554
 555 \f
 556 ;; tar mode is suitable only for specially formatted data.
 557 (put 'tar-mode 'mode-class 'special)
 558 (put 'tar-subfile-mode 'mode-class 'special)
 559
 560 ;;;###autoload
 561 (define-derived-mode tar-mode nil "Tar"
 562   "Major mode for viewing a tar file as a dired-like listing of its contents.
 563 You can move around using the usual cursor motion commands.
 564 Letters no longer insert themselves.
 565 Type `e' to pull a file out of the tar file and into its own buffer;
 566 or click mouse-2 on the file's line in the Tar mode buffer.
 567 Type `c' to copy an entry from the tar file into another file on disk.
 568
 569 If you edit a sub-file of this archive (as with the `e' command) and
 570 save it with \\[save-buffer], the contents of that buffer will be
 571 saved back into the tar-file buffer; in this way you can edit a file
 572 inside of a tar archive without extracting it and re-archiving it.
 573
 574 See also: variables `tar-update-datestamp' and `tar-anal-blocksize'.
 575 \\{tar-mode-map}"
 576   ;; this is not interactive because you shouldn't be turning this
 577   ;; mode on and off.  You can corrupt things that way.
 578   ;; rms: with permanent locals, it should now be possible to make this work
 579   ;; interactively in some reasonable fashion.
 580   (make-local-variable 'tar-header-offset)
 581   (make-local-variable 'tar-parse-info)
 582   (set (make-local-variable 'require-final-newline) nil) ; binary data, dude...
 583   (set (make-local-variable 'revert-buffer-function) 'tar-mode-revert)
 584   (set (make-local-variable 'local-enable-local-variables) nil)
 585   (set (make-local-variable 'next-line-add-newlines) nil)
 586   ;; Prevent loss of data when saving the file.
 587   (set (make-local-variable 'file-precious-flag) t)
 588   (auto-save-mode 0)
 589   (set (make-local-variable 'write-contents-functions) '(tar-mode-write-file))
 590   (buffer-disable-undo)
 591   (widen)
 592   (if (and (boundp 'tar-header-offset) tar-header-offset)
 593       (narrow-to-region (point-min) (byte-to-position tar-header-offset))
 594     (tar-summarize-buffer)
 595     (tar-next-line 0)))
 596
 597
 598 (defun tar-subfile-mode (p)
 599   "Minor mode for editing an element of a tar-file.
 600 This mode arranges for \"saving\" this buffer to write the data
 601 into the tar-file buffer that it came from.  The changes will actually
 602 appear on disk when you save the tar-file's buffer."
 603   (interactive "P")
 604   (or (and (boundp 'tar-superior-buffer) tar-superior-buffer)
 605       (error "This buffer is not an element of a tar file"))
 606   ;; Don't do this, because it is redundant and wastes mode line space.
 607   ;;  (or (assq 'tar-subfile-mode minor-mode-alist)
 608   ;;      (setq minor-mode-alist (append minor-mode-alist
 609   ;;                                 (list '(tar-subfile-mode " TarFile")))))
 610   (make-local-variable 'tar-subfile-mode)
 611   (setq tar-subfile-mode
 612         (if (null p)
 613             (not tar-subfile-mode)
 614             (> (prefix-numeric-value p) 0)))
 615   (cond (tar-subfile-mode
 616          (add-hook 'write-file-functions 'tar-subfile-save-buffer nil t)
 617          ;; turn off auto-save.
 618          (auto-save-mode -1)
 619          (setq buffer-auto-save-file-name nil)
 620          (run-hooks 'tar-subfile-mode-hook))
 621         (t
 622          (remove-hook 'write-file-functions 'tar-subfile-save-buffer t))))
 623
 624
 625 ;; Revert the buffer and recompute the dired-like listing.
 626 (defun tar-mode-revert (&optional no-auto-save no-confirm)
 627   (let ((revert-buffer-function nil)
 628         (old-offset tar-header-offset)
 629         success)
 630     (setq tar-header-offset nil)
 631     (unwind-protect
 632         (and (revert-buffer t no-confirm)
 633              (progn (widen)
 634                     (setq success t)
 635                     (tar-mode)))
 636       ;; If the revert was canceled,
 637       ;; put back the old value of tar-header-offset.
 638       (or success
 639           (setq tar-header-offset old-offset)))))
 640
 641
 642 (defun tar-next-line (arg)
 643   "Move cursor vertically down ARG lines and to the start of the filename."
 644   (interactive "p")
 645   (forward-line arg)
 646   (if (eobp) nil (forward-char (if tar-mode-show-date 54 36))))
 647
 648 (defun tar-previous-line (arg)
 649   "Move cursor vertically up ARG lines and to the start of the filename."
 650   (interactive "p")
 651   (tar-next-line (- arg)))
 652
 653 (defun tar-current-descriptor (&optional noerror)
 654   "Return the tar-descriptor of the current line, or signals an error."
 655   ;; I wish lines had plists, like in ZMACS...
 656   (or (nth (count-lines (point-min)
 657                         (save-excursion (beginning-of-line) (point)))
 658            tar-parse-info)
 659       (if noerror
 660           nil
 661           (error "This line does not describe a tar-file entry"))))
 662
 663 (defun tar-get-descriptor ()
 664   (let* ((descriptor (tar-current-descriptor))
 665          (tokens (tar-desc-tokens descriptor))
 666          (size (tar-header-size tokens))
 667          (link-p (tar-header-link-type tokens)))
 668     (if link-p
 669         (error "This is %s, not a real file"
 670                (cond ((eq link-p 5) "a directory")
 671                      ((eq link-p 20) "a tar directory header")
 672                      ((eq link-p 28) "a next has longname")
 673                      ((eq link-p 29) "a multivolume-continuation")
 674                      ((eq link-p 35) "a sparse entry")
 675                      ((eq link-p 38) "a volume header")
 676                      ((eq link-p 55) "an extended pax header")
 677                      (t "a link"))))
 678     (if (zerop size) (message "This is a zero-length file"))
 679     descriptor))
 680
 681 (defun tar-mouse-extract (event)
 682   "Extract a file whose tar directory line you click on."
 683   (interactive "e")
 684   (save-excursion
 685     (set-buffer (window-buffer (posn-window (event-end event))))
 686     (save-excursion
 687       (goto-char (posn-point (event-end event)))
 688       ;; Just make sure this doesn't get an error.
 689       (tar-get-descriptor)))
 690   (select-window (posn-window (event-end event)))
 691   (goto-char (posn-point (event-end event)))
 692   (tar-extract))
 693
 694 (defun tar-file-name-handler (op &rest args)
 695   "Helper function for `tar-extract'."
 696   (or (eq op 'file-exists-p)
 697       (let ((file-name-handler-alist nil))
 698         (apply op args))))
 699
 700 (defun tar-extract (&optional other-window-p)
 701   "In Tar mode, extract this entry of the tar file into its own buffer."
 702   (interactive)
 703   (let* ((view-p (eq other-window-p 'view))
 704          (descriptor (tar-get-descriptor))
 705          (tokens (tar-desc-tokens descriptor))
 706          (name (tar-header-name tokens))
 707          (size (tar-header-size tokens))
 708          (start (+ (tar-desc-data-start descriptor)
 709                    (- tar-header-offset (point-min))))
 710          (end (+ start size)))
 711     (let* ((tar-buffer (current-buffer))
 712            (tar-buffer-multibyte enable-multibyte-characters)
 713            (tarname (buffer-name))
 714            (bufname (concat (file-name-nondirectory name)
 715                             " ("
 716                              tarname
 717                              ")"))
 718            (read-only-p (or buffer-read-only view-p))
 719            (new-buffer-file-name (expand-file-name
 720                                   ;; `:' is not allowed on Windows
 721                                   (concat tarname "!" name)))
 722            (buffer (get-file-buffer new-buffer-file-name))
 723            (just-created nil))
 724       (unless buffer
 725         (setq buffer (generate-new-buffer bufname))
 726         (setq bufname (buffer-name buffer))
 727         (setq just-created t)
 728         (unwind-protect
 729             (progn
 730               (widen)
 731               (set-buffer-multibyte nil)
 732               (save-excursion
 733                 (set-buffer buffer)
 734                 (let ((buffer-undo-list t))
 735                   (if enable-multibyte-characters
 736                       (progn
 737                         ;; We must avoid unibyte->multibyte conversion.
 738                         (set-buffer-multibyte nil)
 739                         (insert-buffer-substring tar-buffer start end)
 740                         (set-buffer-multibyte t))
 741                     (insert-buffer-substring tar-buffer start end))
 742                   (goto-char (point-min))
 743                   (setq buffer-file-name new-buffer-file-name)
 744                   (setq buffer-file-truename
 745                         (abbreviate-file-name buffer-file-name))
 746                   ;; We need to mimic the parts of insert-file-contents
 747                   ;; which determine the coding-system and decode the text.
 748                   (let ((coding
 749                          (or coding-system-for-read
 750                              (and set-auto-coding-function
 751                                   (save-excursion
 752                                     (funcall set-auto-coding-function
 753                                              name (- (point-max) (point)))))
 754                              ;; The following binding causes
 755                              ;; find-buffer-file-type-coding-system
 756                              ;; (defined on dos-w32.el) to act as if
 757                              ;; the file being extracted existed, so
 758                              ;; that the file's contents' encoding and
 759                              ;; EOL format are auto-detected.
 760                              (let ((file-name-handler-alist
 761                                     (if (featurep 'dos-w32)
 762                                         '(("" . tar-file-name-handler))
 763                                       file-name-handler-alist)))
 764                                (car (find-operation-coding-system
 765                                      'insert-file-contents
 766                                      (cons name (current-buffer)) t)))))
 767                         (multibyte enable-multibyte-characters)
 768                         (detected (detect-coding-region
 769                                    (point-min)
 770                                    (min (+ (point-min) 16384) (point-max)) t)))
 771                     (if coding
 772                         (or (numberp (coding-system-eol-type coding))
 773                             (vectorp (coding-system-eol-type detected))
 774                             (setq coding (coding-system-change-eol-conversion
 775                                           coding
 776                                           (coding-system-eol-type detected))))
 777                       (setq coding
 778                             (find-new-buffer-file-coding-system detected)))
 779                     (if (or (eq coding 'no-conversion)
 780                             (eq (coding-system-type coding) 5))
 781                         (setq multibyte (set-buffer-multibyte nil)))
 782                     (or multibyte
 783                         (setq coding
 784                               (coding-system-change-text-conversion
 785                                coding 'raw-text)))
 786                     (decode-coding-region (point-min) (point-max) coding)
 787                     ;; Force buffer-file-coding-system to what
 788                     ;; decode-coding-region actually used.
 789                     (set-buffer-file-coding-system last-coding-system-used t))
 790                   ;; Set the default-directory to the dir of the
 791                   ;; superior buffer.
 792                   (setq default-directory
 793                         (save-excursion
 794                           (set-buffer tar-buffer)
 795                           default-directory))
 796                   (normal-mode)  ; pick a mode.
 797                   (rename-buffer bufname)
 798                   (make-local-variable 'tar-superior-buffer)
 799                   (make-local-variable 'tar-superior-descriptor)
 800                   (setq tar-superior-buffer tar-buffer)
 801                   (setq tar-superior-descriptor descriptor)
 802                   (setq buffer-read-only read-only-p)
 803                   (set-buffer-modified-p nil))
 804                 (tar-subfile-mode 1))
 805               (set-buffer tar-buffer))
 806           (narrow-to-region (point-min) tar-header-offset)
 807           (set-buffer-multibyte tar-buffer-multibyte)))
 808       (if view-p
 809           (view-buffer buffer (and just-created 'kill-buffer))
 810         (if (eq other-window-p 'display)
 811             (display-buffer buffer)
 812           (if other-window-p
 813               (switch-to-buffer-other-window buffer)
 814             (switch-to-buffer buffer)))))))
 815
 816
 817 (defun tar-extract-other-window ()
 818   "In Tar mode, find this entry of the tar file in another window."
 819   (interactive)
 820   (tar-extract t))
 821
 822 (defun tar-display-other-window ()
 823   "In Tar mode, display this entry of the tar file in another window."
 824   (interactive)
 825   (tar-extract 'display))
 826
 827 (defun tar-view ()
 828   "In Tar mode, view the tar file entry on this line."
 829   (interactive)
 830   (tar-extract 'view))
 831
 832
 833 (defun tar-read-file-name (&optional prompt)
 834   "Read a file name with this line's entry as the default."
 835   (or prompt (setq prompt "Copy to: "))
 836   (let* ((default-file (expand-file-name
 837                         (tar-header-name (tar-desc-tokens
 838                                           (tar-current-descriptor)))))
 839          (target (expand-file-name
 840                   (read-file-name prompt
 841                                   (file-name-directory default-file)
 842                                   default-file nil))))
 843     (if (or (string= "" (file-name-nondirectory target))
 844             (file-directory-p target))
 845         (setq target (concat (if (string-match "/$" target)
 846                                  (substring target 0 (1- (match-end 0)))
 847                                  target)
 848                              "/"
 849                              (file-name-nondirectory default-file))))
 850     target))
 851
 852
 853 (defun tar-copy (&optional to-file)
 854   "In Tar mode, extract this entry of the tar file into a file on disk.
 855 If TO-FILE is not supplied, it is prompted for, defaulting to the name of
 856 the current tar-entry."
 857   (interactive (list (tar-read-file-name)))
 858   (let* ((descriptor (tar-get-descriptor))
 859          (tokens (tar-desc-tokens descriptor))
 860          (name (tar-header-name tokens))
 861          (size (tar-header-size tokens))
 862          (start (+ (tar-desc-data-start descriptor)
 863                    (- tar-header-offset (point-min))))
 864          (end (+ start size))
 865          (multibyte enable-multibyte-characters)
 866          (inhibit-file-name-handlers inhibit-file-name-handlers)
 867          (inhibit-file-name-operation inhibit-file-name-operation))
 868     (save-restriction
 869       (widen)
 870       ;; Inhibit compressing a subfile again if *both* name and
 871       ;; to-file are handled by jka-compr
 872       (if (and (eq (find-file-name-handler name 'write-region) 'jka-compr-handler)
 873                (eq (find-file-name-handler to-file 'write-region) 'jka-compr-handler))
 874           (setq inhibit-file-name-handlers
 875                 (cons 'jka-compr-handler
 876                       (and (eq inhibit-file-name-operation 'write-region)
 877                            inhibit-file-name-handlers))
 878                 inhibit-file-name-operation 'write-region))
 879       (unwind-protect
 880           (let ((coding-system-for-write 'no-conversion))
 881             (set-buffer-multibyte nil)
 882             (write-region start end to-file nil nil nil t))
 883         (set-buffer-multibyte multibyte)))
 884     (message "Copied tar entry %s to %s" name to-file)))
 885
 886 (defun tar-flag-deleted (p &optional unflag)
 887   "In Tar mode, mark this sub-file to be deleted from the tar file.
 888 With a prefix argument, mark that many files."
 889   (interactive "p")
 890   (beginning-of-line)
 891   (dotimes (i (abs p))
 892     (if (tar-current-descriptor unflag) ; barf if we're not on an entry-line.
 893         (progn
 894           (delete-char 1)
 895           (insert (if unflag " " "D"))))
 896     (forward-line (if (< p 0) -1 1)))
 897   (if (eobp) nil (forward-char 36)))
 898
 899 (defun tar-unflag (p)
 900   "In Tar mode, un-mark this sub-file if it is marked to be deleted.
 901 With a prefix argument, un-mark that many files forward."
 902   (interactive "p")
 903   (tar-flag-deleted p t))
 904
 905 (defun tar-unflag-backwards (p)
 906   "In Tar mode, un-mark this sub-file if it is marked to be deleted.
 907 With a prefix argument, un-mark that many files backward."
 908   (interactive "p")
 909   (tar-flag-deleted (- p) t))
 910
 911
 912 ;; When this function is called, it is sure that the buffer is unibyte.
 913 (defun tar-expunge-internal ()
 914   "Expunge the tar-entry specified by the current line."
 915   (let* ((descriptor (tar-current-descriptor))
 916          (tokens (tar-desc-tokens descriptor))
 917          ;; (line (tar-desc-data-start descriptor))
 918          (name (tar-header-name tokens))
 919          (size (tar-header-size tokens))
 920          (link-p (tar-header-link-type tokens))
 921          (start (tar-desc-data-start descriptor))
 922          (following-descs (cdr (memq descriptor tar-parse-info))))
 923     (if link-p (setq size 0)) ; size lies for hard-links.
 924     ;;
 925     ;; delete the current line...
 926     (beginning-of-line)
 927     (let ((line-start (point)))
 928       (end-of-line) (forward-char)
 929       ;; decrement the header-pointer to be in sync...
 930       (setq tar-header-offset (- tar-header-offset (- (point) line-start)))
 931       (delete-region line-start (point)))
 932     ;;
 933     ;; delete the data pointer...
 934     (setq tar-parse-info (delq descriptor tar-parse-info))
 935     ;;
 936     ;; delete the data from inside the file...
 937     (widen)
 938     (let* ((data-start (+ start (- tar-header-offset (point-min)) -512))
 939            (data-end (+ data-start 512 (ash (ash (+ size 511) -9) 9))))
 940       (delete-region data-start data-end)
 941       ;;
 942       ;; and finally, decrement the start-pointers of all following
 943       ;; entries in the archive.  This is a pig when deleting a bunch
 944       ;; of files at once - we could optimize this to only do the
 945       ;; iteration over the files that remain, or only iterate up to
 946       ;; the next file to be deleted.
 947       (let ((data-length (- data-end data-start)))
 948         (dolist (desc following-descs)
 949           (tar-setf (tar-desc-data-start desc)
 950                     (- (tar-desc-data-start desc) data-length))))
 951       ))
 952   (narrow-to-region (point-min) tar-header-offset))
 953
 954
 955 (defun tar-expunge (&optional noconfirm)
 956   "In Tar mode, delete all the archived files flagged for deletion.
 957 This does not modify the disk image; you must save the tar file itself
 958 for this to be permanent."
 959   (interactive)
 960   (if (or noconfirm
 961           (y-or-n-p "Expunge files marked for deletion? "))
 962       (let ((n 0)
 963             (multibyte enable-multibyte-characters))
 964         (save-excursion
 965           (widen)
 966           (set-buffer-multibyte nil)
 967           (goto-char (point-min))
 968           (while (not (eobp))
 969             (if (looking-at "D")
 970                 (progn (tar-expunge-internal)
 971                        (setq n (1+ n)))
 972                 (forward-line 1)))
 973           ;; after doing the deletions, add any padding that may be necessary.
 974           (tar-pad-to-blocksize)
 975           (widen)
 976           (set-buffer-multibyte multibyte)
 977           (narrow-to-region (point-min) tar-header-offset))
 978         (if (zerop n)
 979             (message "Nothing to expunge.")
 980             (message "%s files expunged.  Be sure to save this buffer." n)))))
 981
 982
 983 (defun tar-clear-modification-flags ()
 984   "Remove the stars at the beginning of each line."
 985   (interactive)
 986   (save-excursion
 987     (goto-char (point-min))
 988     (while (< (position-bytes (point)) tar-header-offset)
 989       (if (not (eq (following-char) ?\s))
 990           (progn (delete-char 1) (insert " ")))
 991       (forward-line 1))))
 992
 993
 994 (defun tar-chown-entry (new-uid)
 995   "Change the user-id associated with this entry in the tar file.
 996 If this tar file was written by GNU tar, then you will be able to edit
 997 the user id as a string; otherwise, you must edit it as a number.
 998 You can force editing as a number by calling this with a prefix arg.
 999 This does not modify the disk image; you must save the tar file itself
1000 for this to be permanent."
1001   (interactive (list
1002                  (let ((tokens (tar-desc-tokens (tar-current-descriptor))))
1003                    (if (or current-prefix-arg
1004                            (not (tar-header-magic tokens)))
1005                        (let (n)
1006                          (while (not (numberp (setq n (read-minibuffer
1007                                                         "New UID number: "
1008                                                         (format "%s" (tar-header-uid tokens)))))))
1009                          n)
1010                        (read-string "New UID string: " (tar-header-uname tokens))))))
1011   (cond ((stringp new-uid)
1012          (tar-setf (tar-header-uname (tar-desc-tokens (tar-current-descriptor)))
1013                    new-uid)
1014          (tar-alter-one-field tar-uname-offset (concat new-uid "\000")))
1015         (t
1016          (tar-setf (tar-header-uid (tar-desc-tokens (tar-current-descriptor)))
1017                    new-uid)
1018          (tar-alter-one-field tar-uid-offset
1019            (concat (substring (format "%6o" new-uid) 0 6) "\000 ")))))
1020
1021
1022 (defun tar-chgrp-entry (new-gid)
1023   "Change the group-id associated with this entry in the tar file.
1024 If this tar file was written by GNU tar, then you will be able to edit
1025 the group id as a string; otherwise, you must edit it as a number.
1026 You can force editing as a number by calling this with a prefix arg.
1027 This does not modify the disk image; you must save the tar file itself
1028 for this to be permanent."
1029   (interactive (list
1030                  (let ((tokens (tar-desc-tokens (tar-current-descriptor))))
1031                    (if (or current-prefix-arg
1032                            (not (tar-header-magic tokens)))
1033                        (let (n)
1034                          (while (not (numberp (setq n (read-minibuffer
1035                                                         "New GID number: "
1036                                                         (format "%s" (tar-header-gid tokens)))))))
1037                          n)
1038                        (read-string "New GID string: " (tar-header-gname tokens))))))
1039   (cond ((stringp new-gid)
1040          (tar-setf (tar-header-gname (tar-desc-tokens (tar-current-descriptor)))
1041                    new-gid)
1042          (tar-alter-one-field tar-gname-offset
1043            (concat new-gid "\000")))
1044         (t
1045          (tar-setf (tar-header-gid (tar-desc-tokens (tar-current-descriptor)))
1046                    new-gid)
1047          (tar-alter-one-field tar-gid-offset
1048            (concat (substring (format "%6o" new-gid) 0 6) "\000 ")))))
1049
1050 (defun tar-rename-entry (new-name)
1051   "Change the name associated with this entry in the tar file.
1052 This does not modify the disk image; you must save the tar file itself
1053 for this to be permanent."
1054   (interactive
1055     (list (read-string "New name: "
1056             (tar-header-name (tar-desc-tokens (tar-current-descriptor))))))
1057   (if (string= "" new-name) (error "zero length name"))
1058   (if (> (length new-name) 98) (error "name too long"))
1059   (tar-setf (tar-header-name (tar-desc-tokens (tar-current-descriptor)))
1060             new-name)
1061   (if (multibyte-string-p new-name)
1062       (setq new-name (encode-coding-string new-name
1063                                            (or file-name-coding-system
1064                                                default-file-name-coding-system))))
1065   (tar-alter-one-field 0
1066     (substring (concat new-name (make-string 99 0)) 0 99)))
1067
1068
1069 (defun tar-chmod-entry (new-mode)
1070   "Change the protection bits associated with this entry in the tar file.
1071 This does not modify the disk image; you must save the tar file itself
1072 for this to be permanent."
1073   (interactive (list (tar-parse-octal-integer-safe
1074                        (read-string "New protection (octal): "))))
1075   (tar-setf (tar-header-mode (tar-desc-tokens (tar-current-descriptor)))
1076             new-mode)
1077   (tar-alter-one-field tar-mode-offset
1078     (concat (substring (format "%6o" new-mode) 0 6) "\000 ")))
1079
1080
1081 (defun tar-alter-one-field (data-position new-data-string)
1082   (let* ((descriptor (tar-current-descriptor))
1083          (tokens (tar-desc-tokens descriptor))
1084          (multibyte enable-multibyte-characters))
1085     (unwind-protect
1086         (save-excursion
1087           ;;
1088           ;; update the header-line.
1089           (beginning-of-line)
1090           (let ((p (point)))
1091             (forward-line 1)
1092             (delete-region p (point))
1093             (insert (tar-header-block-summarize tokens) "\n")
1094             (setq tar-header-offset (position-bytes (point-max))))
1095
1096           (widen)
1097           (set-buffer-multibyte nil)
1098           (let* ((start (+ (tar-desc-data-start descriptor)
1099                            (- tar-header-offset (point-min))
1100                            -512)))
1101             ;;
1102             ;; delete the old field and insert a new one.
1103             (goto-char (+ start data-position))
1104             (delete-region (point) (+ (point) (length new-data-string))) ; <--
1105             (insert new-data-string) ; <--
1106             ;;
1107             ;; compute a new checksum and insert it.
1108             (let ((chk (tar-header-block-checksum
1109                         (buffer-substring start (+ start 512)))))
1110               (goto-char (+ start tar-chk-offset))
1111               (delete-region (point) (+ (point) 8))
1112               (insert (format "%6o" chk))
1113               (insert 0)
1114               (insert ? )
1115               (tar-setf (tar-header-checksum tokens) chk)
1116               ;;
1117               ;; ok, make sure we didn't botch it.
1118               (tar-header-block-check-checksum
1119                 (buffer-substring start (+ start 512))
1120                 chk (tar-header-name tokens))
1121               )))
1122       (narrow-to-region (point-min) tar-header-offset)
1123       (set-buffer-multibyte multibyte)
1124       (tar-next-line 0))))
1125
1126
1127 (defun tar-octal-time (timeval)
1128   ;; Format a timestamp as 11 octal digits.  Ghod, I hope this works...
1129   (let ((hibits (car timeval)) (lobits (car (cdr timeval))))
1130     (format "%05o%01o%05o"
1131             (lsh hibits -2)
1132             (logior (lsh (logand 3 hibits) 1)
1133                     (if (> (logand lobits 32768) 0) 1 0))
1134             (logand 32767 lobits)
1135             )))
1136
1137 (defun tar-subfile-save-buffer ()
1138   "In tar subfile mode, save this buffer into its parent tar-file buffer.
1139 This doesn't write anything to disk; you must save the parent tar-file buffer
1140 to make your changes permanent."
1141   (interactive)
1142   (if (not (and (boundp 'tar-superior-buffer) tar-superior-buffer))
1143     (error "This buffer has no superior tar file buffer"))
1144   (if (not (and (boundp 'tar-superior-descriptor) tar-superior-descriptor))
1145     (error "This buffer doesn't have an index into its superior tar file!"))
1146   (save-excursion
1147   (let ((subfile (current-buffer))
1148         (subfile-multibyte enable-multibyte-characters)
1149         (coding buffer-file-coding-system)
1150         (descriptor tar-superior-descriptor)
1151         subfile-size)
1152     ;; We must make the current buffer unibyte temporarily to avoid
1153     ;; multibyte->unibyte conversion in `insert-buffer-substring'.
1154     (set-buffer-multibyte nil)
1155     (setq subfile-size (buffer-size))
1156     (set-buffer tar-superior-buffer)
1157     (let* ((tokens (tar-desc-tokens descriptor))
1158            (start (tar-desc-data-start descriptor))
1159            (name (tar-header-name tokens))
1160            (size (tar-header-size tokens))
1161            (size-pad (ash (ash (+ size 511) -9) 9))
1162            (head (memq descriptor tar-parse-info))
1163            (following-descs (cdr head))
1164            (tar-buffer-multibyte enable-multibyte-characters))
1165       (if (not head)
1166         (error "Can't find this tar file entry in its parent tar file!"))
1167       (unwind-protect
1168        (save-excursion
1169         (widen)
1170         (set-buffer-multibyte nil)
1171         ;; delete the old data...
1172         (let* ((data-start (+ start (- tar-header-offset (point-min))))
1173                (data-end (+ data-start (ash (ash (+ size 511) -9) 9))))
1174           (delete-region data-start data-end)
1175           ;; insert the new data...
1176           (goto-char data-start)
1177           (insert-buffer-substring subfile)
1178           (setq subfile-size
1179                 (encode-coding-region
1180                  data-start (+ data-start subfile-size) coding))
1181           ;;
1182           ;; pad the new data out to a multiple of 512...
1183           (let ((subfile-size-pad (ash (ash (+ subfile-size 511) -9) 9)))
1184             (goto-char (+ data-start subfile-size))
1185             (insert (make-string (- subfile-size-pad subfile-size) 0))
1186             ;;
1187             ;; update the data pointer of this and all following files...
1188             (tar-setf (tar-header-size tokens) subfile-size)
1189             (let ((difference (- subfile-size-pad size-pad)))
1190               (dolist (desc following-descs)
1191                 (tar-setf (tar-desc-data-start desc)
1192                           (+ (tar-desc-data-start desc) difference))))
1193             ;;
1194             ;; Update the size field in the header block.
1195             (let ((header-start (- data-start 512)))
1196               (goto-char (+ header-start tar-size-offset))
1197               (delete-region (point) (+ (point) 12))
1198               (insert (format "%11o" subfile-size))
1199               (insert ? )
1200               ;;
1201               ;; Maybe update the datestamp.
1202               (if (not tar-update-datestamp)
1203                   nil
1204                 (goto-char (+ header-start tar-time-offset))
1205                 (delete-region (point) (+ (point) 12))
1206                 (insert (tar-octal-time (current-time)))
1207                 (insert ? ))
1208               ;;
1209               ;; compute a new checksum and insert it.
1210               (let ((chk (tar-header-block-checksum
1211                           (buffer-substring header-start data-start))))
1212                 (goto-char (+ header-start tar-chk-offset))
1213                 (delete-region (point) (+ (point) 8))
1214                 (insert (format "%6o" chk))
1215                 (insert 0)
1216                 (insert ? )
1217                 (tar-setf (tar-header-checksum tokens) chk)))
1218             ;;
1219             ;; alter the descriptor-line...
1220             ;;
1221             (let ((position (- (length tar-parse-info) (length head))))
1222               (goto-char (point-min))
1223               (next-line position)
1224               (beginning-of-line)
1225               (let ((p (point))
1226                     after
1227                     (m (set-marker (make-marker) tar-header-offset)))
1228                 (forward-line 1)
1229                 (setq after (point))
1230                 ;; Insert the new text after the old, before deleting,
1231                 ;; to preserve the window start.
1232                 (let ((line (tar-header-block-summarize tokens t)))
1233                   (insert-before-markers (string-as-unibyte line) "\n"))
1234                 (delete-region p after)
1235                 (setq tar-header-offset (marker-position m)))
1236               )))
1237         ;; after doing the insertion, add any final padding that may be necessary.
1238         (tar-pad-to-blocksize))
1239        (narrow-to-region (point-min) tar-header-offset)
1240        (set-buffer-multibyte tar-buffer-multibyte)))
1241     (set-buffer-modified-p t)   ; mark the tar file as modified
1242     (tar-next-line 0)
1243     (set-buffer subfile)
1244     ;; Restore the buffer multibyteness.
1245     (set-buffer-multibyte subfile-multibyte)
1246     (set-buffer-modified-p nil) ; mark the tar subfile as unmodified
1247     (message "Saved into tar-buffer `%s'.  Be sure to save that buffer!"
1248              (buffer-name tar-superior-buffer))
1249     ;; Prevent basic-save-buffer from changing our coding-system.
1250     (setq last-coding-system-used buffer-file-coding-system)
1251     ;; Prevent ordinary saving from happening.
1252     t)))
1253
1254
1255 ;; When this function is called, it is sure that the buffer is unibyte.
1256 (defun tar-pad-to-blocksize ()
1257   "If we are being anal about tar file blocksizes, fix up the current buffer.
1258 Leaves the region wide."
1259   (if (null tar-anal-blocksize)
1260       nil
1261     (widen)
1262     (let* ((last-desc (nth (1- (length tar-parse-info)) tar-parse-info))
1263            (start (tar-desc-data-start last-desc))
1264            (tokens (tar-desc-tokens last-desc))
1265            (link-p (tar-header-link-type tokens))
1266            (size (if link-p 0 (tar-header-size tokens)))
1267            (data-end (+ start size))
1268            (bbytes (ash tar-anal-blocksize 9))
1269            (pad-to (+ bbytes (* bbytes (/ (- data-end (point-min)) bbytes))))
1270            (inhibit-read-only t) ; ##
1271            )
1272       ;; If the padding after the last data is too long, delete some;
1273       ;; else insert some until we are padded out to the right number of blocks.
1274       ;;
1275       (let ((goal-end (+ (or tar-header-offset 0) pad-to)))
1276         (if (> (point-max) goal-end)
1277             (delete-region goal-end (point-max))
1278           (goto-char (point-max))
1279           (insert (make-string (- goal-end (point-max)) ?\0)))))))
1280
1281
1282 ;; Used in write-file-hook to write tar-files out correctly.
1283 (defun tar-mode-write-file ()
1284   (unwind-protect
1285       (save-excursion
1286         (widen)
1287         ;; Doing this here confuses things - the region gets left too wide!
1288         ;; I suppose this is run in a context where changing the buffer is bad.
1289         ;; (tar-pad-to-blocksize)
1290         ;; tar-header-offset turns out to be null for files fetched with W3,
1291         ;; at least.
1292         (let ((coding-system-for-write 'no-conversion))
1293           (write-region (if tar-header-offset
1294                             (byte-to-position tar-header-offset)
1295                           (point-min))
1296                         (point-max)
1297                         buffer-file-name nil t))
1298         (tar-clear-modification-flags)
1299         (set-buffer-modified-p nil))
1300     (narrow-to-region (point-min) (byte-to-position tar-header-offset)))
1301   ;; Return t because we've written the file.
1302   t)
1303 \f
1304 (provide 'tar-mode)
1305
1306 ;; arch-tag: 8a585a4a-340e-42c2-89e7-d3b1013a4b78
1307 ;;; tar-mode.el ends here